lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize detected_reinvoked_destructor);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # if this is an actual *setter* - just set it, no need to connect
 129       # and determine the driver
 130       !( %1$s and @_ > 1 )
 131         and
 132       # only fire when invoked on an instance, a valid class-based invocation
 133       # would e.g. be setting a default for an inherited accessor
 134       ref $_[0]
 135         and
 136       ! $_[0]->{_driver_determined}
 137         and
 138       ! $_[0]->{_in_determine_driver}
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227     local $?; # just in case the DBI destructor changes it somehow
 228
 229     # destroy just the object if not native to this process
 230     $_->_verify_pid for (grep
 231       { defined $_ }
 232       values %seek_and_destroy
 233     );
 234   }
 235
 236   sub CLONE {
 237     # As per DBI's recommendation, DBIC disconnects all handles as
 238     # soon as possible (DBIC will reconnect only on demand from within
 239     # the thread)
 240     my @instances = grep { defined $_ } values %seek_and_destroy;
 241     %seek_and_destroy = ();
 242
 243     for (@instances) {
 244       $_->_dbh(undef);
 245
 246       $_->transaction_depth(0);
 247       $_->savepoints([]);
 248
 249       # properly renumber existing refs
 250       $_->_arm_global_destructor
 251     }
 252   }
 253 }
 254
 255 sub DESTROY {
 256   return if &detected_reinvoked_destructor;
 257
 258   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 259   # some databases spew warnings on implicit disconnect
 260   local $SIG{__WARN__} = sub {};
 261   $_[0]->_dbh(undef);
 262
 263   # this op is necessary, since the very last perl runtime statement
 264   # triggers a global destruction shootout, and the $SIG localization
 265   # may very well be destroyed before perl actually gets to do the
 266   # $dbh undef
 267   1;
 268 }
 269
 270 # handle pid changes correctly - do not destroy parent's connection
 271 sub _verify_pid {
 272
 273   my $pid = $_[0]->_conn_pid;
 274
 275   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 276     $dbh->{InactiveDestroy} = 1;
 277     $_[0]->_dbh(undef);
 278     $_[0]->transaction_depth(0);
 279     $_[0]->savepoints([]);
 280   }
 281
 282   return;
 283 }
 284
 285 =head2 connect_info
 286
 287 This method is normally called by L<DBIx::Class::Schema/connection>, which
 288 encapsulates its argument list in an arrayref before passing them here.
 289
 290 The argument list may contain:
 291
 292 =over
 293
 294 =item *
 295
 296 The same 4-element argument set one would normally pass to
 297 L<DBI/connect>, optionally followed by
 298 L<extra attributes|/DBIx::Class specific connection attributes>
 299 recognized by DBIx::Class:
 300
 301   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 302
 303 =item *
 304
 305 A single code reference which returns a connected
 306 L<DBI database handle|DBI/connect> optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 308 by DBIx::Class:
 309
 310   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single hashref with all the attributes and the dsn/user/password
 315 mixed together:
 316
 317   $connect_info_args = [{
 318     dsn => $dsn,
 319     user => $user,
 320     password => $pass,
 321     %dbi_attributes,
 322     %extra_attributes,
 323   }];
 324
 325   $connect_info_args = [{
 326     dbh_maker => sub { DBI->connect (...) },
 327     %dbi_attributes,
 328     %extra_attributes,
 329   }];
 330
 331 This is particularly useful for L<Catalyst> based applications, allowing the
 332 following config (L<Config::General> style):
 333
 334   <Model::DB>
 335     schema_class   App::DB
 336     <connect_info>
 337       dsn          dbi:mysql:database=test
 338       user         testuser
 339       password     TestPass
 340       AutoCommit   1
 341     </connect_info>
 342   </Model::DB>
 343
 344 The C<dsn>/C<user>/C<password> combination can be substituted by the
 345 C<dbh_maker> key whose value is a coderef that returns a connected
 346 L<DBI database handle|DBI/connect>
 347
 348 =back
 349
 350 Please note that the L<DBI> docs recommend that you always explicitly
 351 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 352 recommends that it be set to I<1>, and that you perform transactions
 353 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 354 to I<1> if you do not do explicitly set it to zero.  This is the default
 355 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 356
 357 =head3 DBIx::Class specific connection attributes
 358
 359 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 360 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 361 the following connection options. These options can be mixed in with your other
 362 L<DBI> connection attributes, or placed in a separate hashref
 363 (C<\%extra_attributes>) as shown above.
 364
 365 Every time C<connect_info> is invoked, any previous settings for
 366 these options will be cleared before setting the new ones, regardless of
 367 whether any options are specified in the new C<connect_info>.
 368
 369
 370 =over
 371
 372 =item on_connect_do
 373
 374 Specifies things to do immediately after connecting or re-connecting to
 375 the database.  Its value may contain:
 376
 377 =over
 378
 379 =item a scalar
 380
 381 This contains one SQL statement to execute.
 382
 383 =item an array reference
 384
 385 This contains SQL statements to execute in order.  Each element contains
 386 a string or a code reference that returns a string.
 387
 388 =item a code reference
 389
 390 This contains some code to execute.  Unlike code references within an
 391 array reference, its return value is ignored.
 392
 393 =back
 394
 395 =item on_disconnect_do
 396
 397 Takes arguments in the same form as L</on_connect_do> and executes them
 398 immediately before disconnecting from the database.
 399
 400 Note, this only runs if you explicitly call L</disconnect> on the
 401 storage object.
 402
 403 =item on_connect_call
 404
 405 A more generalized form of L</on_connect_do> that calls the specified
 406 C<connect_call_METHOD> methods in your storage driver.
 407
 408   on_connect_do => 'select 1'
 409
 410 is equivalent to:
 411
 412   on_connect_call => [ [ do_sql => 'select 1' ] ]
 413
 414 Its values may contain:
 415
 416 =over
 417
 418 =item a scalar
 419
 420 Will call the C<connect_call_METHOD> method.
 421
 422 =item a code reference
 423
 424 Will execute C<< $code->($storage) >>
 425
 426 =item an array reference
 427
 428 Each value can be a method name or code reference.
 429
 430 =item an array of arrays
 431
 432 For each array, the first item is taken to be the C<connect_call_> method name
 433 or code reference, and the rest are parameters to it.
 434
 435 =back
 436
 437 Some predefined storage methods you may use:
 438
 439 =over
 440
 441 =item do_sql
 442
 443 Executes a SQL string or a code reference that returns a SQL string. This is
 444 what L</on_connect_do> and L</on_disconnect_do> use.
 445
 446 It can take:
 447
 448 =over
 449
 450 =item a scalar
 451
 452 Will execute the scalar as SQL.
 453
 454 =item an arrayref
 455
 456 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 457 attributes hashref and bind values.
 458
 459 =item a code reference
 460
 461 Will execute C<< $code->($storage) >> and execute the return array refs as
 462 above.
 463
 464 =back
 465
 466 =item datetime_setup
 467
 468 Execute any statements necessary to initialize the database session to return
 469 and accept datetime/timestamp values used with
 470 L<DBIx::Class::InflateColumn::DateTime>.
 471
 472 Only necessary for some databases, see your specific storage driver for
 473 implementation details.
 474
 475 =back
 476
 477 =item on_disconnect_call
 478
 479 Takes arguments in the same form as L</on_connect_call> and executes them
 480 immediately before disconnecting from the database.
 481
 482 Calls the C<disconnect_call_METHOD> methods as opposed to the
 483 C<connect_call_METHOD> methods called by L</on_connect_call>.
 484
 485 Note, this only runs if you explicitly call L</disconnect> on the
 486 storage object.
 487
 488 =item disable_sth_caching
 489
 490 If set to a true value, this option will disable the caching of
 491 statement handles via L<DBI/prepare_cached>.
 492
 493 =item limit_dialect
 494
 495 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 496 default L</sql_limit_dialect> setting of the storage (if any). For a list
 497 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 498
 499 =item quote_names
 500
 501 When true automatically sets L</quote_char> and L</name_sep> to the characters
 502 appropriate for your particular RDBMS. This option is preferred over specifying
 503 L</quote_char> directly.
 504
 505 =item quote_char
 506
 507 Specifies what characters to use to quote table and column names.
 508
 509 C<quote_char> expects either a single character, in which case is it
 510 is placed on either side of the table/column name, or an arrayref of length
 511 2 in which case the table/column name is placed between the elements.
 512
 513 For example under MySQL you should use C<< quote_char => '`' >>, and for
 514 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 515
 516 =item name_sep
 517
 518 This parameter is only useful in conjunction with C<quote_char>, and is used to
 519 specify the character that separates elements (schemas, tables, columns) from
 520 each other. If unspecified it defaults to the most commonly used C<.>.
 521
 522 =item unsafe
 523
 524 This Storage driver normally installs its own C<HandleError>, sets
 525 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 526 all database handles, including those supplied by a coderef.  It does this
 527 so that it can have consistent and useful error behavior.
 528
 529 If you set this option to a true value, Storage will not do its usual
 530 modifications to the database handle's attributes, and instead relies on
 531 the settings in your connect_info DBI options (or the values you set in
 532 your connection coderef, in the case that you are connecting via coderef).
 533
 534 Note that your custom settings can cause Storage to malfunction,
 535 especially if you set a C<HandleError> handler that suppresses exceptions
 536 and/or disable C<RaiseError>.
 537
 538 =item auto_savepoint
 539
 540 If this option is true, L<DBIx::Class> will use savepoints when nesting
 541 transactions, making it possible to recover from failure in the inner
 542 transaction without having to abort all outer transactions.
 543
 544 =item cursor_class
 545
 546 Use this argument to supply a cursor class other than the default
 547 L<DBIx::Class::Storage::DBI::Cursor>.
 548
 549 =back
 550
 551 Some real-life examples of arguments to L</connect_info> and
 552 L<DBIx::Class::Schema/connect>
 553
 554   # Simple SQLite connection
 555   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 556
 557   # Connect via subref
 558   ->connect_info([ sub { DBI->connect(...) } ]);
 559
 560   # Connect via subref in hashref
 561   ->connect_info([{
 562     dbh_maker => sub { DBI->connect(...) },
 563     on_connect_do => 'alter session ...',
 564   }]);
 565
 566   # A bit more complicated
 567   ->connect_info(
 568     [
 569       'dbi:Pg:dbname=foo',
 570       'postgres',
 571       'my_pg_password',
 572       { AutoCommit => 1 },
 573       { quote_char => q{"} },
 574     ]
 575   );
 576
 577   # Equivalent to the previous example
 578   ->connect_info(
 579     [
 580       'dbi:Pg:dbname=foo',
 581       'postgres',
 582       'my_pg_password',
 583       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 584     ]
 585   );
 586
 587   # Same, but with hashref as argument
 588   # See parse_connect_info for explanation
 589   ->connect_info(
 590     [{
 591       dsn         => 'dbi:Pg:dbname=foo',
 592       user        => 'postgres',
 593       password    => 'my_pg_password',
 594       AutoCommit  => 1,
 595       quote_char  => q{"},
 596       name_sep    => q{.},
 597     }]
 598   );
 599
 600   # Subref + DBIx::Class-specific connection options
 601   ->connect_info(
 602     [
 603       sub { DBI->connect(...) },
 604       {
 605           quote_char => q{`},
 606           name_sep => q{@},
 607           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 608           disable_sth_caching => 1,
 609       },
 610     ]
 611   );
 612
 613
 614
 615 =cut
 616
 617 sub connect_info {
 618   my ($self, $info) = @_;
 619
 620   return $self->_connect_info if !$info;
 621
 622   $self->_connect_info($info); # copy for _connect_info
 623
 624   $info = $self->_normalize_connect_info($info)
 625     if ref $info eq 'ARRAY';
 626
 627   my %attrs = (
 628     %{ $self->_default_dbi_connect_attributes || {} },
 629     %{ $info->{attributes} || {} },
 630   );
 631
 632   my @args = @{ $info->{arguments} };
 633
 634   if (keys %attrs and ref $args[0] ne 'CODE') {
 635     carp_unique (
 636         'You provided explicit AutoCommit => 0 in your connection_info. '
 637       . 'This is almost universally a bad idea (see the footnotes of '
 638       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 639       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 640       . 'this warning.'
 641     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 642
 643     push @args, \%attrs if keys %attrs;
 644   }
 645
 646   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 647   # OR a single-element coderef-based $dbh factory
 648   $self->_dbi_connect_info(\@args);
 649
 650   # extract the individual storage options
 651   for my $storage_opt (keys %{ $info->{storage_options} }) {
 652     my $value = $info->{storage_options}{$storage_opt};
 653
 654     $self->$storage_opt($value);
 655   }
 656
 657   # Extract the individual sqlmaker options
 658   #
 659   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 660   #  the new set of options
 661   $self->_sql_maker(undef);
 662   $self->_sql_maker_opts({});
 663
 664   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 665     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 666
 667     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 668   }
 669
 670   # FIXME - dirty:
 671   # save attributes in a separate accessor so they are always
 672   # introspectable, even in case of a CODE $dbhmaker
 673   $self->_dbic_connect_attributes (\%attrs);
 674
 675   return $self->_connect_info;
 676 }
 677
 678 sub _dbi_connect_info {
 679   my $self = shift;
 680
 681   return $self->{_dbi_connect_info} = $_[0]
 682     if @_;
 683
 684   my $conninfo = $self->{_dbi_connect_info} || [];
 685
 686   # last ditch effort to grab a DSN
 687   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 688     my @new_conninfo = @$conninfo;
 689     $new_conninfo[0] = $ENV{DBI_DSN};
 690     $conninfo = \@new_conninfo;
 691   }
 692
 693   return $conninfo;
 694 }
 695
 696
 697 sub _normalize_connect_info {
 698   my ($self, $info_arg) = @_;
 699   my %info;
 700
 701   my @args = @$info_arg;  # take a shallow copy for further mutilation
 702
 703   # combine/pre-parse arguments depending on invocation style
 704
 705   my %attrs;
 706   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 707     %attrs = %{ $args[1] || {} };
 708     @args = $args[0];
 709   }
 710   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 711     %attrs = %{$args[0]};
 712     @args = ();
 713     if (my $code = delete $attrs{dbh_maker}) {
 714       @args = $code;
 715
 716       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 717       if (@ignored) {
 718         carp sprintf (
 719             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 720           . "to the result of 'dbh_maker'",
 721
 722           join (', ', map { "'$_'" } (@ignored) ),
 723         );
 724       }
 725     }
 726     else {
 727       @args = delete @attrs{qw/dsn user password/};
 728     }
 729   }
 730   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 731     %attrs = (
 732       % { $args[3] || {} },
 733       % { $args[4] || {} },
 734     );
 735     @args = @args[0,1,2];
 736   }
 737
 738   $info{arguments} = \@args;
 739
 740   my @storage_opts = grep exists $attrs{$_},
 741     @storage_options, 'cursor_class';
 742
 743   @{ $info{storage_options} }{@storage_opts} =
 744     delete @attrs{@storage_opts} if @storage_opts;
 745
 746   my @sql_maker_opts = grep exists $attrs{$_},
 747     qw/limit_dialect quote_char name_sep quote_names/;
 748
 749   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 750     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 751
 752   $info{attributes} = \%attrs if %attrs;
 753
 754   return \%info;
 755 }
 756
 757 sub _default_dbi_connect_attributes () {
 758   +{
 759     AutoCommit => 1,
 760     PrintError => 0,
 761     RaiseError => 1,
 762     ShowErrorStatement => 1,
 763   };
 764 }
 765
 766 =head2 on_connect_do
 767
 768 This method is deprecated in favour of setting via L</connect_info>.
 769
 770 =cut
 771
 772 =head2 on_disconnect_do
 773
 774 This method is deprecated in favour of setting via L</connect_info>.
 775
 776 =cut
 777
 778 sub _parse_connect_do {
 779   my ($self, $type) = @_;
 780
 781   my $val = $self->$type;
 782   return () if not defined $val;
 783
 784   my @res;
 785
 786   if (not ref($val)) {
 787     push @res, [ 'do_sql', $val ];
 788   } elsif (ref($val) eq 'CODE') {
 789     push @res, $val;
 790   } elsif (ref($val) eq 'ARRAY') {
 791     push @res, map { [ 'do_sql', $_ ] } @$val;
 792   } else {
 793     $self->throw_exception("Invalid type for $type: ".ref($val));
 794   }
 795
 796   return \@res;
 797 }
 798
 799 =head2 dbh_do
 800
 801 Arguments: ($subref | $method_name), @extra_coderef_args?
 802
 803 Execute the given $subref or $method_name using the new exception-based
 804 connection management.
 805
 806 The first two arguments will be the storage object that C<dbh_do> was called
 807 on and a database handle to use.  Any additional arguments will be passed
 808 verbatim to the called subref as arguments 2 and onwards.
 809
 810 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 811 exception handling and reconnection (or failover in future subclasses).
 812
 813 Your subref should have no side-effects outside of the database, as
 814 there is the potential for your subref to be partially double-executed
 815 if the database connection was stale/dysfunctional.
 816
 817 Example:
 818
 819   my @stuff = $schema->storage->dbh_do(
 820     sub {
 821       my ($storage, $dbh, @cols) = @_;
 822       my $cols = join(q{, }, @cols);
 823       $dbh->selectrow_array("SELECT $cols FROM foo");
 824     },
 825     @column_list
 826   );
 827
 828 =cut
 829
 830 sub dbh_do {
 831   my $self = shift;
 832   my $run_target = shift; # either a coderef or a method name
 833
 834   # short circuit when we know there is no need for a runner
 835   #
 836   # FIXME - assumption may be wrong
 837   # the rationale for the txn_depth check is that if this block is a part
 838   # of a larger transaction, everything up to that point is screwed anyway
 839   return $self->$run_target($self->_get_dbh, @_)
 840     if $self->{_in_do_block} or $self->transaction_depth;
 841
 842   # take a ref instead of a copy, to preserve @_ aliasing
 843   # semantics within the coderef, but only if needed
 844   # (pseudoforking doesn't like this trick much)
 845   my $args = @_ ? \@_ : [];
 846
 847   DBIx::Class::Storage::BlockRunner->new(
 848     storage => $self,
 849     wrap_txn => 0,
 850     retry_handler => sub {
 851       $_[0]->failed_attempt_count == 1
 852         and
 853       ! $_[0]->storage->connected
 854     },
 855   )->run(sub {
 856     $self->$run_target ($self->_get_dbh, @$args )
 857   });
 858 }
 859
 860 sub txn_do {
 861   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 862   shift->next::method(@_);
 863 }
 864
 865 =head2 disconnect
 866
 867 Our C<disconnect> method also performs a rollback first if the
 868 database is not in C<AutoCommit> mode.
 869
 870 =cut
 871
 872 sub disconnect {
 873
 874   if( my $dbh = $_[0]->_dbh ) {
 875
 876     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 877       ( $_[0]->on_disconnect_call || () ),
 878       $_[0]->_parse_connect_do ('on_disconnect_do')
 879     );
 880
 881     # stops the "implicit rollback on disconnect" warning
 882     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 883
 884     %{ $dbh->{CachedKids} } = ();
 885     $dbh->disconnect;
 886     $_[0]->_dbh(undef);
 887   }
 888 }
 889
 890 =head2 with_deferred_fk_checks
 891
 892 =over 4
 893
 894 =item Arguments: C<$coderef>
 895
 896 =item Return Value: The return value of $coderef
 897
 898 =back
 899
 900 Storage specific method to run the code ref with FK checks deferred or
 901 in MySQL's case disabled entirely.
 902
 903 =cut
 904
 905 # Storage subclasses should override this
 906 sub with_deferred_fk_checks {
 907   #my ($self, $sub) = @_;
 908   $_[1]->();
 909 }
 910
 911 =head2 connected
 912
 913 =over
 914
 915 =item Arguments: none
 916
 917 =item Return Value: 1|0
 918
 919 =back
 920
 921 Verifies that the current database handle is active and ready to execute
 922 an SQL statement (e.g. the connection did not get stale, server is still
 923 answering, etc.) This method is used internally by L</dbh>.
 924
 925 =cut
 926
 927 sub connected {
 928   return 0 unless $_[0]->_seems_connected;
 929
 930   #be on the safe side
 931   local $_[0]->_dbh->{RaiseError} = 1;
 932
 933   return $_[0]->_ping;
 934 }
 935
 936 sub _seems_connected {
 937   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 938
 939   ($_[0]->_dbh || return 0)->FETCH('Active');
 940 }
 941
 942 sub _ping {
 943   ($_[0]->_dbh || return 0)->ping;
 944 }
 945
 946 sub ensure_connected {
 947   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 948 }
 949
 950 =head2 dbh
 951
 952 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 953 is guaranteed to be healthy by implicitly calling L</connected>, and if
 954 necessary performing a reconnection before returning. Keep in mind that this
 955 is very B<expensive> on some database engines. Consider using L</dbh_do>
 956 instead.
 957
 958 =cut
 959
 960 sub dbh {
 961   # maybe save a ping call
 962   $_[0]->_dbh
 963     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 964     : $_[0]->_populate_dbh
 965   ;
 966 }
 967
 968 # this is the internal "get dbh or connect (don't check)" method
 969 sub _get_dbh {
 970   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 971   $_[0]->_dbh || $_[0]->_populate_dbh;
 972 }
 973
 974 # *DELIBERATELY* not a setter (for the time being)
 975 # Too intertwined with everything else for any kind of sanity
 976 sub sql_maker {
 977   my $self = shift;
 978
 979   $self->throw_exception('sql_maker() is not a setter method') if @_;
 980
 981   unless ($self->_sql_maker) {
 982     my $sql_maker_class = $self->sql_maker_class;
 983
 984     my %opts = %{$self->_sql_maker_opts||{}};
 985     my $dialect =
 986       $opts{limit_dialect}
 987         ||
 988       $self->sql_limit_dialect
 989         ||
 990       do {
 991         my $s_class = (ref $self) || $self;
 992         carp_unique (
 993           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 994         . 'have not supplied an explicit limit_dialect in your connection_info. '
 995         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 996         . 'databases but can be (and often is) painfully slow. '
 997         . "Please file an RT ticket against '$s_class'"
 998         ) if $self->_dbi_connect_info->[0];
 999
1000         'GenericSubQ';
1001       }
1002     ;
1003
1004     my ($quote_char, $name_sep);
1005
1006     if ($opts{quote_names}) {
1007       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1008         my $s_class = (ref $self) || $self;
1009         carp_unique (
1010           "You requested 'quote_names' but your storage class ($s_class) does "
1011         . 'not explicitly define a default sql_quote_char and you have not '
1012         . 'supplied a quote_char as part of your connection_info. DBIC will '
1013         .q{default to the ANSI SQL standard quote '"', which works most of }
1014         . "the time. Please file an RT ticket against '$s_class'."
1015         );
1016
1017         '"'; # RV
1018       };
1019
1020       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1021     }
1022
1023     $self->_sql_maker($sql_maker_class->new(
1024       bindtype=>'columns',
1025       array_datatypes => 1,
1026       limit_dialect => $dialect,
1027       ($quote_char ? (quote_char => $quote_char) : ()),
1028       name_sep => ($name_sep || '.'),
1029       %opts,
1030     ));
1031   }
1032   return $self->_sql_maker;
1033 }
1034
1035 # nothing to do by default
1036 sub _rebless {}
1037 sub _init {}
1038
1039 sub _populate_dbh {
1040
1041   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1042
1043   $_[0]->_dbh_details({}); # reset everything we know
1044
1045   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1046   #$_[0]->_sql_maker(undef); # this may also end up being different
1047
1048   $_[0]->_dbh($_[0]->_connect);
1049
1050   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1051
1052   $_[0]->_determine_driver;
1053
1054   # Always set the transaction depth on connect, since
1055   #  there is no transaction in progress by definition
1056   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1057
1058   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1059
1060   $_[0]->_dbh;
1061 }
1062
1063 sub _run_connection_actions {
1064
1065   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1066     ( $_[0]->on_connect_call || () ),
1067     $_[0]->_parse_connect_do ('on_connect_do'),
1068   );
1069 }
1070
1071
1072
1073 sub set_use_dbms_capability {
1074   $_[0]->set_inherited ($_[1], $_[2]);
1075 }
1076
1077 sub get_use_dbms_capability {
1078   my ($self, $capname) = @_;
1079
1080   my $use = $self->get_inherited ($capname);
1081   return defined $use
1082     ? $use
1083     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1084   ;
1085 }
1086
1087 sub set_dbms_capability {
1088   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1089 }
1090
1091 sub get_dbms_capability {
1092   my ($self, $capname) = @_;
1093
1094   my $cap = $self->_dbh_details->{capability}{$capname};
1095
1096   unless (defined $cap) {
1097     if (my $meth = $self->can ("_determine$capname")) {
1098       $cap = $self->$meth ? 1 : 0;
1099     }
1100     else {
1101       $cap = 0;
1102     }
1103
1104     $self->set_dbms_capability ($capname, $cap);
1105   }
1106
1107   return $cap;
1108 }
1109
1110 sub _server_info {
1111   my $self = shift;
1112
1113   # FIXME - ideally this needs to be an ||= assignment, and the final
1114   # assignment at the end of this do{} should be gone entirely. However
1115   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1116   $self->_dbh_details->{info} || do {
1117
1118     # this guarantees that problematic conninfo won't be hidden
1119     # by the try{} below
1120     $self->ensure_connected;
1121
1122     my $info = {};
1123
1124     my $server_version = try {
1125       $self->_get_server_version
1126     } catch {
1127       # driver determination *may* use this codepath
1128       # in which case we must rethrow
1129       $self->throw_exception($_) if $self->{_in_determine_driver};
1130
1131       # $server_version on failure
1132       undef;
1133     };
1134
1135     if (defined $server_version) {
1136       $info->{dbms_version} = $server_version;
1137
1138       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1139       my @verparts = split (/\./, $numeric_version);
1140       if (
1141         @verparts
1142           &&
1143         $verparts[0] <= 999
1144       ) {
1145         # consider only up to 3 version parts, iff not more than 3 digits
1146         my @use_parts;
1147         while (@verparts && @use_parts < 3) {
1148           my $p = shift @verparts;
1149           last if $p > 999;
1150           push @use_parts, $p;
1151         }
1152         push @use_parts, 0 while @use_parts < 3;
1153
1154         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1155       }
1156     }
1157
1158     $self->_dbh_details->{info} = $info;
1159   };
1160 }
1161
1162 sub _get_server_version {
1163   shift->_dbh_get_info('SQL_DBMS_VER');
1164 }
1165
1166 sub _dbh_get_info {
1167   my ($self, $info) = @_;
1168
1169   if ($info =~ /[^0-9]/) {
1170     require DBI::Const::GetInfoType;
1171     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1172     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1173       unless defined $info;
1174   }
1175
1176   $self->_get_dbh->get_info($info);
1177 }
1178
1179 sub _describe_connection {
1180   require DBI::Const::GetInfoReturn;
1181
1182   my $self = shift;
1183
1184   my $drv;
1185   try {
1186     $drv = $self->_extract_driver_from_connect_info;
1187     $self->ensure_connected;
1188   };
1189
1190   $drv = "DBD::$drv" if $drv;
1191
1192   my $res = {
1193     DBIC_DSN => $self->_dbi_connect_info->[0],
1194     DBI_VER => DBI->VERSION,
1195     DBIC_VER => DBIx::Class->VERSION,
1196     DBIC_DRIVER => ref $self,
1197     $drv ? (
1198       DBD => $drv,
1199       DBD_VER => try { $drv->VERSION },
1200     ) : (),
1201   };
1202
1203   # try to grab data even if we never managed to connect
1204   # will cover us in cases of an oddly broken half-connect
1205   for my $inf (
1206     #keys %DBI::Const::GetInfoType::GetInfoType,
1207     qw/
1208       SQL_CURSOR_COMMIT_BEHAVIOR
1209       SQL_CURSOR_ROLLBACK_BEHAVIOR
1210       SQL_CURSOR_SENSITIVITY
1211       SQL_DATA_SOURCE_NAME
1212       SQL_DBMS_NAME
1213       SQL_DBMS_VER
1214       SQL_DEFAULT_TXN_ISOLATION
1215       SQL_DM_VER
1216       SQL_DRIVER_NAME
1217       SQL_DRIVER_ODBC_VER
1218       SQL_DRIVER_VER
1219       SQL_EXPRESSIONS_IN_ORDERBY
1220       SQL_GROUP_BY
1221       SQL_IDENTIFIER_CASE
1222       SQL_IDENTIFIER_QUOTE_CHAR
1223       SQL_MAX_CATALOG_NAME_LEN
1224       SQL_MAX_COLUMN_NAME_LEN
1225       SQL_MAX_IDENTIFIER_LEN
1226       SQL_MAX_TABLE_NAME_LEN
1227       SQL_MULTIPLE_ACTIVE_TXN
1228       SQL_MULT_RESULT_SETS
1229       SQL_NEED_LONG_DATA_LEN
1230       SQL_NON_NULLABLE_COLUMNS
1231       SQL_ODBC_VER
1232       SQL_QUALIFIER_NAME_SEPARATOR
1233       SQL_QUOTED_IDENTIFIER_CASE
1234       SQL_TXN_CAPABLE
1235       SQL_TXN_ISOLATION_OPTION
1236     /
1237   ) {
1238     # some drivers barf on things they do not know about instead
1239     # of returning undef
1240     my $v = try { $self->_dbh_get_info($inf) };
1241     next unless defined $v;
1242
1243     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1244     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1245     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1246   }
1247
1248   $res;
1249 }
1250
1251 sub _determine_driver {
1252   my ($self) = @_;
1253
1254   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1255     my $started_connected = 0;
1256     local $self->{_in_determine_driver} = 1;
1257
1258     if (ref($self) eq __PACKAGE__) {
1259       my $driver;
1260       if ($self->_dbh) { # we are connected
1261         $driver = $self->_dbh->{Driver}{Name};
1262         $started_connected = 1;
1263       }
1264       else {
1265         $driver = $self->_extract_driver_from_connect_info;
1266       }
1267
1268       if ($driver) {
1269         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1270         if ($self->load_optional_class($storage_class)) {
1271           mro::set_mro($storage_class, 'c3');
1272           bless $self, $storage_class;
1273           $self->_rebless();
1274         }
1275         else {
1276           $self->_warn_undetermined_driver(
1277             'This version of DBIC does not yet seem to supply a driver for '
1278           . "your particular RDBMS and/or connection method ('$driver')."
1279           );
1280         }
1281       }
1282       else {
1283         $self->_warn_undetermined_driver(
1284           'Unable to extract a driver name from connect info - this '
1285         . 'should not have happened.'
1286         );
1287       }
1288     }
1289
1290     $self->_driver_determined(1);
1291
1292     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1293
1294     if ($self->can('source_bind_attributes')) {
1295       $self->throw_exception(
1296         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1297       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1298       . 'If you are not sure how to proceed please contact the development team via '
1299       . DBIx::Class::_ENV_::HELP_URL
1300       );
1301     }
1302
1303     $self->_init; # run driver-specific initializations
1304
1305     $self->_run_connection_actions
1306         if !$started_connected && defined $self->_dbh;
1307   }
1308 }
1309
1310 sub _extract_driver_from_connect_info {
1311   my $self = shift;
1312
1313   my $drv;
1314
1315   # if connect_info is a CODEREF, we have no choice but to connect
1316   if (
1317     ref $self->_dbi_connect_info->[0]
1318       and
1319     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1320   ) {
1321     $self->_populate_dbh;
1322     $drv = $self->_dbh->{Driver}{Name};
1323   }
1324   else {
1325     # try to use dsn to not require being connected, the driver may still
1326     # force a connection later in _rebless to determine version
1327     # (dsn may not be supplied at all if all we do is make a mock-schema)
1328     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1329     $drv ||= $ENV{DBI_DRIVER};
1330   }
1331
1332   return $drv;
1333 }
1334
1335 sub _determine_connector_driver {
1336   my ($self, $conn) = @_;
1337
1338   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1339
1340   if (not $dbtype) {
1341     $self->_warn_undetermined_driver(
1342       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1343     . "$conn connector - this should not have happened."
1344     );
1345     return;
1346   }
1347
1348   $dbtype =~ s/\W/_/gi;
1349
1350   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1351   return if $self->isa($subclass);
1352
1353   if ($self->load_optional_class($subclass)) {
1354     bless $self, $subclass;
1355     $self->_rebless;
1356   }
1357   else {
1358     $self->_warn_undetermined_driver(
1359       'This version of DBIC does not yet seem to supply a driver for '
1360     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1361     );
1362   }
1363 }
1364
1365 sub _warn_undetermined_driver {
1366   my ($self, $msg) = @_;
1367
1368   require Data::Dumper::Concise;
1369
1370   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1371   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1372   . "does not go away, file a bugreport including the following info:\n"
1373   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1374   );
1375 }
1376
1377 sub _do_connection_actions {
1378   my ($self, $method_prefix, $call, @args) = @_;
1379
1380   try {
1381     if (not ref($call)) {
1382       my $method = $method_prefix . $call;
1383       $self->$method(@args);
1384     }
1385     elsif (ref($call) eq 'CODE') {
1386       $self->$call(@args);
1387     }
1388     elsif (ref($call) eq 'ARRAY') {
1389       if (ref($call->[0]) ne 'ARRAY') {
1390         $self->_do_connection_actions($method_prefix, $_) for @$call;
1391       }
1392       else {
1393         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1394       }
1395     }
1396     else {
1397       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1398     }
1399   }
1400   catch {
1401     if ( $method_prefix =~ /^connect/ ) {
1402       # this is an on_connect cycle - we can't just throw while leaving
1403       # a handle in an undefined state in our storage object
1404       # kill it with fire and rethrow
1405       $self->_dbh(undef);
1406       $self->throw_exception( $_[0] );
1407     }
1408     else {
1409       carp "Disconnect action failed: $_[0]";
1410     }
1411   };
1412
1413   return $self;
1414 }
1415
1416 sub connect_call_do_sql {
1417   my $self = shift;
1418   $self->_do_query(@_);
1419 }
1420
1421 sub disconnect_call_do_sql {
1422   my $self = shift;
1423   $self->_do_query(@_);
1424 }
1425
1426 =head2 connect_call_datetime_setup
1427
1428 A no-op stub method, provided so that one can always safely supply the
1429 L<connection option|/DBIx::Class specific connection attributes>
1430
1431  on_connect_call => 'datetime_setup'
1432
1433 This way one does not need to know in advance whether the underlying
1434 storage requires any sort of hand-holding when dealing with calendar
1435 data.
1436
1437 =cut
1438
1439 sub connect_call_datetime_setup { 1 }
1440
1441 sub _do_query {
1442   my ($self, $action) = @_;
1443
1444   if (ref $action eq 'CODE') {
1445     $action = $action->($self);
1446     $self->_do_query($_) foreach @$action;
1447   }
1448   else {
1449     # Most debuggers expect ($sql, @bind), so we need to exclude
1450     # the attribute hash which is the second argument to $dbh->do
1451     # furthermore the bind values are usually to be presented
1452     # as named arrayref pairs, so wrap those here too
1453     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1454     my $sql = shift @do_args;
1455     my $attrs = shift @do_args;
1456     my @bind = map { [ undef, $_ ] } @do_args;
1457
1458     $self->dbh_do(sub {
1459       $_[0]->_query_start($sql, \@bind);
1460       $_[1]->do($sql, $attrs, @do_args);
1461       $_[0]->_query_end($sql, \@bind);
1462     });
1463   }
1464
1465   return $self;
1466 }
1467
1468 sub _connect {
1469   my $self = shift;
1470
1471   my $info = $self->_dbi_connect_info;
1472
1473   $self->throw_exception("You did not provide any connection_info")
1474     unless defined $info->[0];
1475
1476   my ($old_connect_via, $dbh);
1477
1478   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1479
1480   # this odd anonymous coderef dereference is in fact really
1481   # necessary to avoid the unwanted effect described in perl5
1482   # RT#75792
1483   #
1484   # in addition the coderef itself can't reside inside the try{} block below
1485   # as it somehow triggers a leak under perl -d
1486   my $dbh_error_handler_installer = sub {
1487     weaken (my $weak_self = $_[0]);
1488
1489     # the coderef is blessed so we can distinguish it from externally
1490     # supplied handles (which must be preserved)
1491     $_[1]->{HandleError} = bless sub {
1492       if ($weak_self) {
1493         $weak_self->throw_exception("DBI Exception: $_[0]");
1494       }
1495       else {
1496         # the handler may be invoked by something totally out of
1497         # the scope of DBIC
1498         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1499       }
1500     }, '__DBIC__DBH__ERROR__HANDLER__';
1501   };
1502
1503   try {
1504     if(ref $info->[0] eq 'CODE') {
1505       $dbh = $info->[0]->();
1506     }
1507     else {
1508       require DBI;
1509       $dbh = DBI->connect(@$info);
1510     }
1511
1512     die $DBI::errstr unless $dbh;
1513
1514     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1515       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1516       . 'not continue',
1517       ref $info->[0] eq 'CODE'
1518         ? "Connection coderef $info->[0] returned a"
1519         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1520     ) unless $dbh->FETCH('Active');
1521
1522     # sanity checks unless asked otherwise
1523     unless ($self->unsafe) {
1524
1525       $self->throw_exception(
1526         'Refusing clobbering of {HandleError} installed on externally supplied '
1527        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1528       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1529
1530       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1531       # request, or an external handle. Complain and set anyway
1532       unless ($dbh->{RaiseError}) {
1533         carp( ref $info->[0] eq 'CODE'
1534
1535           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1536            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1537            .'attribute has been supplied'
1538
1539           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1540            .'unsafe => 1. Toggling RaiseError back to true'
1541         );
1542
1543         $dbh->{RaiseError} = 1;
1544       }
1545
1546       $dbh_error_handler_installer->($self, $dbh);
1547     }
1548   }
1549   catch {
1550     $self->throw_exception("DBI Connection failed: $_")
1551   };
1552
1553   $self->_dbh_autocommit($dbh->{AutoCommit});
1554   return $dbh;
1555 }
1556
1557 sub txn_begin {
1558   # this means we have not yet connected and do not know the AC status
1559   # (e.g. coderef $dbh), need a full-fledged connection check
1560   if (! defined $_[0]->_dbh_autocommit) {
1561     $_[0]->ensure_connected;
1562   }
1563   # Otherwise simply connect or re-connect on pid changes
1564   else {
1565     $_[0]->_get_dbh;
1566   }
1567
1568   shift->next::method(@_);
1569 }
1570
1571 sub _exec_txn_begin {
1572   my $self = shift;
1573
1574   # if the user is utilizing txn_do - good for him, otherwise we need to
1575   # ensure that the $dbh is healthy on BEGIN.
1576   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1577   # will be replaced by a failure of begin_work itself (which will be
1578   # then retried on reconnect)
1579   if ($self->{_in_do_block}) {
1580     $self->_dbh->begin_work;
1581   } else {
1582     $self->dbh_do(sub { $_[1]->begin_work });
1583   }
1584 }
1585
1586 sub txn_commit {
1587   my $self = shift;
1588
1589   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1590     unless $self->_seems_connected;
1591
1592   # esoteric case for folks using external $dbh handles
1593   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1594     carp "Storage transaction_depth 0 does not match "
1595         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1596     $self->transaction_depth(1);
1597   }
1598
1599   $self->next::method(@_);
1600
1601   # if AutoCommit is disabled txn_depth never goes to 0
1602   # as a new txn is started immediately on commit
1603   $self->transaction_depth(1) if (
1604     !$self->transaction_depth
1605       and
1606     defined $self->_dbh_autocommit
1607       and
1608     ! $self->_dbh_autocommit
1609   );
1610 }
1611
1612 sub _exec_txn_commit {
1613   shift->_dbh->commit;
1614 }
1615
1616 sub txn_rollback {
1617   my $self = shift;
1618
1619   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1620     unless $self->_seems_connected;
1621
1622   # esoteric case for folks using external $dbh handles
1623   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1624     carp "Storage transaction_depth 0 does not match "
1625         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1626     $self->transaction_depth(1);
1627   }
1628
1629   $self->next::method(@_);
1630
1631   # if AutoCommit is disabled txn_depth never goes to 0
1632   # as a new txn is started immediately on commit
1633   $self->transaction_depth(1) if (
1634     !$self->transaction_depth
1635       and
1636     defined $self->_dbh_autocommit
1637       and
1638     ! $self->_dbh_autocommit
1639   );
1640 }
1641
1642 sub _exec_txn_rollback {
1643   shift->_dbh->rollback;
1644 }
1645
1646 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1647 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1648   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1649     unless $_[0]->_seems_connected;
1650   shift->next::method(@_);
1651 EOS
1652
1653 # This used to be the top-half of _execute.  It was split out to make it
1654 #  easier to override in NoBindVars without duping the rest.  It takes up
1655 #  all of _execute's args, and emits $sql, @bind.
1656 sub _prep_for_execute {
1657   #my ($self, $op, $ident, $args) = @_;
1658   return shift->_gen_sql_bind(@_)
1659 }
1660
1661 sub _gen_sql_bind {
1662   my ($self, $op, $ident, $args) = @_;
1663
1664   my ($colinfos, $from);
1665   if ( blessed($ident) ) {
1666     $from = $ident->from;
1667     $colinfos = $ident->columns_info;
1668   }
1669
1670   my ($sql, $bind);
1671   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1672
1673   $bind = $self->_resolve_bindattrs(
1674     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1675   );
1676
1677   if (
1678     ! $ENV{DBIC_DT_SEARCH_OK}
1679       and
1680     $op eq 'select'
1681       and
1682     first {
1683       length ref $_->[1]
1684         and
1685       blessed($_->[1])
1686         and
1687       $_->[1]->isa('DateTime')
1688     } @$bind
1689   ) {
1690     carp_unique 'DateTime objects passed to search() are not supported '
1691       . 'properly (InflateColumn::DateTime formats and settings are not '
1692       . 'respected.) See ".. format a DateTime object for searching?" in '
1693       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1694       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1695   }
1696
1697   return( $sql, $bind );
1698 }
1699
1700 sub _resolve_bindattrs {
1701   my ($self, $ident, $bind, $colinfos) = @_;
1702
1703   my $resolve_bindinfo = sub {
1704     #my $infohash = shift;
1705
1706     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1707
1708     my $ret;
1709     if (my $col = $_[0]->{dbic_colname}) {
1710       $ret = { %{$_[0]} };
1711
1712       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1713         if $colinfos->{$col}{data_type};
1714
1715       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1716         if $colinfos->{$col}{size};
1717     }
1718
1719     $ret || $_[0];
1720   };
1721
1722   return [ map {
1723     my $resolved =
1724       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1725     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1726     : (ref $_->[0] eq 'HASH')           ? [(
1727                                             ! keys %{$_->[0]}
1728                                               or
1729                                             exists $_->[0]{dbd_attrs}
1730                                               or
1731                                             $_->[0]{sqlt_datatype}
1732                                            ) ? $_->[0]
1733                                              : $resolve_bindinfo->($_->[0])
1734                                            , $_->[1]
1735                                           ]
1736     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1737     :                                     [ $resolve_bindinfo->(
1738                                               { dbic_colname => $_->[0] }
1739                                             ), $_->[1] ]
1740     ;
1741
1742     if (
1743       ! exists $resolved->[0]{dbd_attrs}
1744         and
1745       ! $resolved->[0]{sqlt_datatype}
1746         and
1747       length ref $resolved->[1]
1748         and
1749       ! is_plain_value $resolved->[1]
1750     ) {
1751       require Data::Dumper;
1752       local $Data::Dumper::Maxdepth = 1;
1753       local $Data::Dumper::Terse = 1;
1754       local $Data::Dumper::Useqq = 1;
1755       local $Data::Dumper::Indent = 0;
1756       local $Data::Dumper::Pad = ' ';
1757       $self->throw_exception(
1758         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1759       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1760       );
1761     }
1762
1763     $resolved;
1764
1765   } @$bind ];
1766 }
1767
1768 sub _format_for_trace {
1769   #my ($self, $bind) = @_;
1770
1771   ### Turn @bind from something like this:
1772   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1773   ### to this:
1774   ###   ( "'1'", "'3'" )
1775
1776   map {
1777     defined( $_ && $_->[1] )
1778       ? qq{'$_->[1]'}
1779       : q{NULL}
1780   } @{$_[1] || []};
1781 }
1782
1783 sub _query_start {
1784   my ( $self, $sql, $bind ) = @_;
1785
1786   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1787     if $self->debug;
1788 }
1789
1790 sub _query_end {
1791   my ( $self, $sql, $bind ) = @_;
1792
1793   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1794     if $self->debug;
1795 }
1796
1797 sub _dbi_attrs_for_bind {
1798   #my ($self, $ident, $bind) = @_;
1799
1800   return [ map {
1801
1802     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1803
1804   : ! $_->{sqlt_datatype}   ? undef
1805
1806   :                           do {
1807
1808     # cache the result in the dbh_details hash, as it (usually) can not change
1809     # unless we connect to something else
1810     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1811     # the LOB storage
1812     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1813
1814     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1815       if ! exists $cache->{$_->{sqlt_datatype}};
1816
1817     $cache->{$_->{sqlt_datatype}};
1818
1819   } } map { $_->[0] } @{$_[2]} ];
1820 }
1821
1822 sub _execute {
1823   my ($self, $op, $ident, @args) = @_;
1824
1825   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1826
1827   # not even a PID check - we do not care about the state of the _dbh.
1828   # All we need is to get the appropriate drivers loaded if they aren't
1829   # already so that the assumption in ad7c50fc26e holds
1830   $self->_populate_dbh unless $self->_dbh;
1831
1832   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1833     $sql,
1834     $bind,
1835     $self->_dbi_attrs_for_bind($ident, $bind),
1836   );
1837 }
1838
1839 sub _dbh_execute {
1840   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1841
1842   $self->_query_start( $sql, $bind );
1843
1844   my $sth = $self->_bind_sth_params(
1845     $self->_prepare_sth($dbh, $sql),
1846     $bind,
1847     $bind_attrs,
1848   );
1849
1850   # Can this fail without throwing an exception anyways???
1851   my $rv = $sth->execute();
1852   $self->throw_exception(
1853     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1854   ) if !$rv;
1855
1856   $self->_query_end( $sql, $bind );
1857
1858   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1859 }
1860
1861 sub _prepare_sth {
1862   my ($self, $dbh, $sql) = @_;
1863
1864   # 3 is the if_active parameter which avoids active sth re-use
1865   my $sth = $self->disable_sth_caching
1866     ? $dbh->prepare($sql)
1867     : $dbh->prepare_cached($sql, {}, 3);
1868
1869   # XXX You would think RaiseError would make this impossible,
1870   #  but apparently that's not true :(
1871   $self->throw_exception(
1872     $dbh->errstr
1873       ||
1874     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1875             .'an exception and/or setting $dbh->errstr',
1876       length ($sql) > 20
1877         ? substr($sql, 0, 20) . '...'
1878         : $sql
1879       ,
1880       'DBD::' . $dbh->{Driver}{Name},
1881     )
1882   ) if !$sth;
1883
1884   $sth;
1885 }
1886
1887 sub _bind_sth_params {
1888   my ($self, $sth, $bind, $bind_attrs) = @_;
1889
1890   for my $i (0 .. $#$bind) {
1891     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1892       $sth->bind_param_inout(
1893         $i + 1, # bind params counts are 1-based
1894         $bind->[$i][1],
1895         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1896         $bind_attrs->[$i],
1897       );
1898     }
1899     else {
1900       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1901       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1902         ? "$bind->[$i][1]"
1903         : $bind->[$i][1]
1904       ;
1905
1906       $sth->bind_param(
1907         $i + 1,
1908         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1909         $v,
1910         $bind_attrs->[$i],
1911       );
1912     }
1913   }
1914
1915   $sth;
1916 }
1917
1918 sub _prefetch_autovalues {
1919   my ($self, $source, $colinfo, $to_insert) = @_;
1920
1921   my %values;
1922   for my $col (keys %$colinfo) {
1923     if (
1924       $colinfo->{$col}{auto_nextval}
1925         and
1926       (
1927         ! exists $to_insert->{$col}
1928           or
1929         is_literal_value($to_insert->{$col})
1930       )
1931     ) {
1932       $values{$col} = $self->_sequence_fetch(
1933         'NEXTVAL',
1934         ( $colinfo->{$col}{sequence} ||=
1935             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1936         ),
1937       );
1938     }
1939   }
1940
1941   \%values;
1942 }
1943
1944 sub insert {
1945   my ($self, $source, $to_insert) = @_;
1946
1947   my $col_infos = $source->columns_info;
1948
1949   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1950
1951   # fuse the values, but keep a separate list of prefetched_values so that
1952   # they can be fused once again with the final return
1953   $to_insert = { %$to_insert, %$prefetched_values };
1954
1955   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1956   # Investigate what does it take to s/defined/exists/
1957   my %pcols = map { $_ => 1 } $source->primary_columns;
1958   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1959   for my $col ($source->columns) {
1960     if ($col_infos->{$col}{is_auto_increment}) {
1961       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1962       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1963     }
1964
1965     # nothing to retrieve when explicit values are supplied
1966     next if (
1967       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1968     );
1969
1970     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1971     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1972       $pcols{$col}
1973         or
1974       $col_infos->{$col}{retrieve_on_insert}
1975     );
1976   };
1977
1978   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1979   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1980
1981   my ($sqla_opts, @ir_container);
1982   if (%retrieve_cols and $self->_use_insert_returning) {
1983     $sqla_opts->{returning_container} = \@ir_container
1984       if $self->_use_insert_returning_bound;
1985
1986     $sqla_opts->{returning} = [
1987       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1988     ];
1989   }
1990
1991   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1992
1993   my %returned_cols = %$to_insert;
1994   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1995     @ir_container = try {
1996       local $SIG{__WARN__} = sub {};
1997       my @r = $sth->fetchrow_array;
1998       $sth->finish;
1999       @r;
2000     } unless @ir_container;
2001
2002     @returned_cols{@$retlist} = @ir_container if @ir_container;
2003   }
2004   else {
2005     # pull in PK if needed and then everything else
2006     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2007
2008       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2009         unless $self->can('last_insert_id');
2010
2011       my @pri_values = $self->last_insert_id($source, @missing_pri);
2012
2013       $self->throw_exception( "Can't get last insert id" )
2014         unless (@pri_values == @missing_pri);
2015
2016       @returned_cols{@missing_pri} = @pri_values;
2017       delete @retrieve_cols{@missing_pri};
2018     }
2019
2020     # if there is more left to pull
2021     if (%retrieve_cols) {
2022       $self->throw_exception(
2023         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2024       ) unless %pcols;
2025
2026       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2027
2028       my $cur = DBIx::Class::ResultSet->new($source, {
2029         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2030         select => \@left_to_fetch,
2031       })->cursor;
2032
2033       @returned_cols{@left_to_fetch} = $cur->next;
2034
2035       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2036         if scalar $cur->next;
2037     }
2038   }
2039
2040   return { %$prefetched_values, %returned_cols };
2041 }
2042
2043 sub insert_bulk {
2044   carp_unique(
2045     'insert_bulk() should have never been exposed as a public method and '
2046   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2047   . 'use for this method please contact the development team via '
2048   . DBIx::Class::_ENV_::HELP_URL
2049   );
2050
2051   return '0E0' unless @{$_[3]||[]};
2052
2053   shift->_insert_bulk(@_);
2054 }
2055
2056 sub _insert_bulk {
2057   my ($self, $source, $cols, $data) = @_;
2058
2059   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2060     unless @{$data||[]};
2061
2062   my $colinfos = $source->columns_info($cols);
2063
2064   local $self->{_autoinc_supplied_for_op} =
2065     (grep { $_->{is_auto_increment} } values %$colinfos)
2066       ? 1
2067       : 0
2068   ;
2069
2070   # get a slice type index based on first row of data
2071   # a "column" in this context may refer to more than one bind value
2072   # e.g. \[ '?, ?', [...], [...] ]
2073   #
2074   # construct the value type index - a description of values types for every
2075   # per-column slice of $data:
2076   #
2077   # nonexistent - nonbind literal
2078   # 0 - regular value
2079   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2080   #
2081   # also construct the column hash to pass to the SQL generator. For plain
2082   # (non literal) values - convert the members of the first row into a
2083   # literal+bind combo, with extra positional info in the bind attr hashref.
2084   # This will allow us to match the order properly, and is so contrived
2085   # because a user-supplied literal/bind (or something else specific to a
2086   # resultsource and/or storage driver) can inject extra binds along the
2087   # way, so one can't rely on "shift positions" ordering at all. Also we
2088   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2089   # can be later matched up by address), because we want to supply a real
2090   # value on which perhaps e.g. datatype checks will be performed
2091   my ($proto_data, $serialized_bind_type_by_col_idx);
2092   for my $col_idx (0..$#$cols) {
2093     my $colname = $cols->[$col_idx];
2094     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2095       # no bind value at all - no type
2096
2097       $proto_data->{$colname} = $data->[0][$col_idx];
2098     }
2099     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2100       # repack, so we don't end up mangling the original \[]
2101       my ($sql, @bind) = @${$data->[0][$col_idx]};
2102
2103       # normalization of user supplied stuff
2104       my $resolved_bind = $self->_resolve_bindattrs(
2105         $source, \@bind, $colinfos,
2106       );
2107
2108       # store value-less (attrs only) bind info - we will be comparing all
2109       # supplied binds against this for sanity
2110       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2111
2112       $proto_data->{$colname} = \[ $sql, map { [
2113         # inject slice order to use for $proto_bind construction
2114           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2115             =>
2116           $resolved_bind->[$_][1]
2117         ] } (0 .. $#bind)
2118       ];
2119     }
2120     else {
2121       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2122
2123       $proto_data->{$colname} = \[ '?', [
2124         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2125           =>
2126         $data->[0][$col_idx]
2127       ] ];
2128     }
2129   }
2130
2131   my ($sql, $proto_bind) = $self->_prep_for_execute (
2132     'insert',
2133     $source,
2134     [ $proto_data ],
2135   );
2136
2137   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2138     # if the bindlist is empty and we had some dynamic binds, this means the
2139     # storage ate them away (e.g. the NoBindVars component) and interpolated
2140     # them directly into the SQL. This obviously can't be good for multi-inserts
2141     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2142   }
2143
2144   # sanity checks
2145   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2146   #
2147   # use an error reporting closure for convenience (less to pass)
2148   my $bad_slice_report_cref = sub {
2149     my ($msg, $r_idx, $c_idx) = @_;
2150     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2151       $msg,
2152       $cols->[$c_idx],
2153       do {
2154         require Data::Dumper::Concise;
2155         local $Data::Dumper::Maxdepth = 5;
2156         Data::Dumper::Concise::Dumper ({
2157           map { $cols->[$_] =>
2158             $data->[$r_idx][$_]
2159           } 0..$#$cols
2160         }),
2161       }
2162     );
2163   };
2164
2165   for my $col_idx (0..$#$cols) {
2166     my $reference_val = $data->[0][$col_idx];
2167
2168     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2169       my $val = $data->[$row_idx][$col_idx];
2170
2171       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2172         if (ref $val ne 'SCALAR') {
2173           $bad_slice_report_cref->(
2174             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2175             $row_idx,
2176             $col_idx,
2177           );
2178         }
2179         elsif ($$val ne $$reference_val) {
2180           $bad_slice_report_cref->(
2181             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2182             $row_idx,
2183             $col_idx,
2184           );
2185         }
2186       }
2187       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2188         if (is_literal_value($val)) {
2189           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2190         }
2191       }
2192       else {  # binds from a \[], compare type and attrs
2193         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2194           $bad_slice_report_cref->(
2195             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2196             $row_idx,
2197             $col_idx,
2198           );
2199         }
2200         # start drilling down and bail out early on identical refs
2201         elsif (
2202           $reference_val != $val
2203             or
2204           $$reference_val != $$val
2205         ) {
2206           if (${$val}->[0] ne ${$reference_val}->[0]) {
2207             $bad_slice_report_cref->(
2208               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2209               $row_idx,
2210               $col_idx,
2211             );
2212           }
2213           # need to check the bind attrs - a bind will happen only once for
2214           # the entire dataset, so any changes further down will be ignored.
2215           elsif (
2216             $serialized_bind_type_by_col_idx->{$col_idx}
2217               ne
2218             serialize [
2219               map
2220               { $_->[0] }
2221               @{$self->_resolve_bindattrs(
2222                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2223               )}
2224             ]
2225           ) {
2226             $bad_slice_report_cref->(
2227               'Differing bind attributes on literal/bind values not supported',
2228               $row_idx,
2229               $col_idx,
2230             );
2231           }
2232         }
2233       }
2234     }
2235   }
2236
2237   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2238   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2239   # scope guard
2240   my $guard = $self->txn_scope_guard;
2241
2242   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2243   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2244   my $rv = do {
2245     if (@$proto_bind) {
2246       # proto bind contains the information on which pieces of $data to pull
2247       # $cols is passed in only for prettier error-reporting
2248       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2249     }
2250     else {
2251       # bind_param_array doesn't work if there are no binds
2252       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2253     }
2254   };
2255
2256   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2257
2258   $guard->commit;
2259
2260   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2261 }
2262
2263 # execute_for_fetch is capable of returning data just fine (it means it
2264 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2265 # is the void-populate fast-path we will just ignore this altogether
2266 # for the time being.
2267 sub _dbh_execute_for_fetch {
2268   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2269
2270   # If we have any bind attributes to take care of, we will bind the
2271   # proto-bind data (which will never be used by execute_for_fetch)
2272   # However since column bindtypes are "sticky", this is sufficient
2273   # to get the DBD to apply the bindtype to all values later on
2274   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2275
2276   for my $i (0 .. $#$proto_bind) {
2277     $sth->bind_param (
2278       $i+1, # DBI bind indexes are 1-based
2279       $proto_bind->[$i][1],
2280       $bind_attrs->[$i],
2281     ) if defined $bind_attrs->[$i];
2282   }
2283
2284   # At this point $data slots named in the _bind_data_slice_idx of
2285   # each piece of $proto_bind are either \[]s or plain values to be
2286   # passed in. Construct the dispensing coderef. *NOTE* the order
2287   # of $data will differ from this of the ?s in the SQL (due to
2288   # alphabetical ordering by colname). We actually do want to
2289   # preserve this behavior so that prepare_cached has a better
2290   # chance of matching on unrelated calls
2291
2292   my $fetch_row_idx = -1; # saner loop this way
2293   my $fetch_tuple = sub {
2294     return undef if ++$fetch_row_idx > $#$data;
2295
2296     return [ map {
2297       my $v = ! defined $_->{_literal_bind_subindex}
2298
2299         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2300
2301         # There are no attributes to resolve here - we already did everything
2302         # when we constructed proto_bind. However we still want to sanity-check
2303         # what the user supplied, so pass stuff through to the resolver *anyway*
2304         : $self->_resolve_bindattrs (
2305             undef,  # a fake rsrc
2306             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2307             {},     # a fake column_info bag
2308           )->[0][1]
2309       ;
2310
2311       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2312       # For the time being forcibly stringify whatever is stringifiable
2313       (length ref $v and is_plain_value $v)
2314         ? "$v"
2315         : $v
2316       ;
2317     } map { $_->[0] } @$proto_bind ];
2318   };
2319
2320   my $tuple_status = [];
2321   my ($rv, $err);
2322   try {
2323     $rv = $sth->execute_for_fetch(
2324       $fetch_tuple,
2325       $tuple_status,
2326     );
2327   }
2328   catch {
2329     $err = shift;
2330   };
2331
2332   # Not all DBDs are create equal. Some throw on error, some return
2333   # an undef $rv, and some set $sth->err - try whatever we can
2334   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2335     ! defined $err
2336       and
2337     ( !defined $rv or $sth->err )
2338   );
2339
2340   # Statement must finish even if there was an exception.
2341   try {
2342     $sth->finish
2343   }
2344   catch {
2345     $err = shift unless defined $err
2346   };
2347
2348   if (defined $err) {
2349     my $i = 0;
2350     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2351
2352     $self->throw_exception("Unexpected populate error: $err")
2353       if ($i > $#$tuple_status);
2354
2355     require Data::Dumper::Concise;
2356     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2357       ($tuple_status->[$i][1] || $err),
2358       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2359     );
2360   }
2361
2362   return $rv;
2363 }
2364
2365 sub _dbh_execute_inserts_with_no_binds {
2366   my ($self, $sth, $count) = @_;
2367
2368   my $err;
2369   try {
2370     my $dbh = $self->_get_dbh;
2371     local $dbh->{RaiseError} = 1;
2372     local $dbh->{PrintError} = 0;
2373
2374     $sth->execute foreach 1..$count;
2375   }
2376   catch {
2377     $err = shift;
2378   };
2379
2380   # Make sure statement is finished even if there was an exception.
2381   try {
2382     $sth->finish
2383   }
2384   catch {
2385     $err = shift unless defined $err;
2386   };
2387
2388   $self->throw_exception($err) if defined $err;
2389
2390   return $count;
2391 }
2392
2393 sub update {
2394   #my ($self, $source, @args) = @_;
2395   shift->_execute('update', @_);
2396 }
2397
2398
2399 sub delete {
2400   #my ($self, $source, @args) = @_;
2401   shift->_execute('delete', @_);
2402 }
2403
2404 sub _select {
2405   my $self = shift;
2406   $self->_execute($self->_select_args(@_));
2407 }
2408
2409 sub _select_args_to_query {
2410   my $self = shift;
2411
2412   $self->throw_exception(
2413     "Unable to generate limited query representation with 'software_limit' enabled"
2414   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2415
2416   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2417   #  = $self->_select_args($ident, $select, $cond, $attrs);
2418   my ($op, $ident, @args) =
2419     $self->_select_args(@_);
2420
2421   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2422   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2423
2424   # reuse the bind arrayref
2425   unshift @{$bind}, "($sql)";
2426   \$bind;
2427 }
2428
2429 sub _select_args {
2430   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2431
2432   # FIXME - that kind of caching would be nice to have
2433   # however currently we *may* pass the same $orig_attrs
2434   # with different ident/select/where
2435   # the whole interface needs to be rethought, since it
2436   # was centered around the flawed SQLA API. We can do
2437   # soooooo much better now. But that is also another
2438   # battle...
2439   #return (
2440   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2441   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2442
2443   my $sql_maker = $self->sql_maker;
2444
2445   my $attrs = {
2446     %$orig_attrs,
2447     select => $select,
2448     from => $ident,
2449     where => $where,
2450   };
2451
2452   # Sanity check the attributes (SQLMaker does it too, but
2453   # in case of a software_limit we'll never reach there)
2454   if (defined $attrs->{offset}) {
2455     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2456       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2457   }
2458
2459   if (defined $attrs->{rows}) {
2460     $self->throw_exception("The rows attribute must be a positive integer if present")
2461       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2462   }
2463   elsif ($attrs->{offset}) {
2464     # MySQL actually recommends this approach.  I cringe.
2465     $attrs->{rows} = $sql_maker->__max_int;
2466   }
2467
2468   # see if we will need to tear the prefetch apart to satisfy group_by == select
2469   # this is *extremely tricky* to get right, I am still not sure I did
2470   #
2471   my ($prefetch_needs_subquery, @limit_args);
2472
2473   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2474     # we already know there is a valid group_by (we made it) and we know it is
2475     # intended to be based *only* on non-multi stuff
2476     # short circuit the group_by parsing below
2477     $prefetch_needs_subquery = 1;
2478   }
2479   elsif (
2480     # The rationale is that even if we do *not* have collapse, we still
2481     # need to wrap the core grouped select/group_by in a subquery
2482     # so that databases that care about group_by/select equivalence
2483     # are happy (this includes MySQL in strict_mode)
2484     # If any of the other joined tables are referenced in the group_by
2485     # however - the user is on their own
2486     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2487       and
2488     $attrs->{group_by}
2489       and
2490     @{$attrs->{group_by}}
2491       and
2492     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2493       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2494     }
2495   ) {
2496     # no aliases other than our own in group_by
2497     # if there are - do not allow subquery even if limit is present
2498     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2499   }
2500   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2501     # active collapse with a limit - that one is a no-brainer unless
2502     # overruled by a group_by above
2503     $prefetch_needs_subquery = 1;
2504   }
2505
2506   if ($prefetch_needs_subquery) {
2507     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2508   }
2509   elsif (! $attrs->{software_limit} ) {
2510     push @limit_args, (
2511       $attrs->{rows} || (),
2512       $attrs->{offset} || (),
2513     );
2514   }
2515
2516   # try to simplify the joinmap further (prune unreferenced type-single joins)
2517   if (
2518     ! $prefetch_needs_subquery  # already pruned
2519       and
2520     ref $attrs->{from}
2521       and
2522     reftype $attrs->{from} eq 'ARRAY'
2523       and
2524     @{$attrs->{from}} != 1
2525   ) {
2526     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2527   }
2528
2529   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2530   # during the result inflation stage we *need* to know what was the aliastype
2531   # map as sqla saw it when the final pieces of SQL were being assembled
2532   # Originally we simply carried around the entirety of $attrs, but this
2533   # resulted in resultsets that are being reused growing continuously, as
2534   # the hash in question grew deeper and deeper.
2535   # Instead hand-pick what to take with us here (we actually don't need much
2536   # at this point just the map itself)
2537   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2538
2539 ###
2540   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2541   #
2542   # This would be the point to deflate anything found in $attrs->{where}
2543   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2544   # expect a result object. And all we have is a resultsource (it is trivial
2545   # to extract deflator coderefs via $alias2source above).
2546   #
2547   # I don't see a way forward other than changing the way deflators are
2548   # invoked, and that's just bad...
2549 ###
2550
2551   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2552 }
2553
2554 # Returns a counting SELECT for a simple count
2555 # query. Abstracted so that a storage could override
2556 # this to { count => 'firstcol' } or whatever makes
2557 # sense as a performance optimization
2558 sub _count_select {
2559   #my ($self, $source, $rs_attrs) = @_;
2560   return { count => '*' };
2561 }
2562
2563 =head2 select
2564
2565 =over 4
2566
2567 =item Arguments: $ident, $select, $condition, $attrs
2568
2569 =back
2570
2571 Handle a SQL select statement.
2572
2573 =cut
2574
2575 sub select {
2576   my $self = shift;
2577   my ($ident, $select, $condition, $attrs) = @_;
2578   return $self->cursor_class->new($self, \@_, $attrs);
2579 }
2580
2581 sub select_single {
2582   my $self = shift;
2583   my ($rv, $sth, @bind) = $self->_select(@_);
2584   my @row = $sth->fetchrow_array;
2585   my @nextrow = $sth->fetchrow_array if @row;
2586   if(@row && @nextrow) {
2587     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2588   }
2589   # Need to call finish() to work round broken DBDs
2590   $sth->finish();
2591   return @row;
2592 }
2593
2594 =head2 sql_limit_dialect
2595
2596 This is an accessor for the default SQL limit dialect used by a particular
2597 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2598 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2599 see L<DBIx::Class::SQLMaker::LimitDialects>.
2600
2601 =cut
2602
2603 sub _dbh_columns_info_for {
2604   my ($self, $dbh, $table) = @_;
2605
2606   my %result;
2607
2608   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2609     try {
2610       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2611       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2612       $sth->execute();
2613       while ( my $info = $sth->fetchrow_hashref() ){
2614         my %column_info;
2615         $column_info{data_type}   = $info->{TYPE_NAME};
2616         $column_info{size}      = $info->{COLUMN_SIZE};
2617         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2618         $column_info{default_value} = $info->{COLUMN_DEF};
2619         my $col_name = $info->{COLUMN_NAME};
2620         $col_name =~ s/^\"(.*)\"$/$1/;
2621
2622         $result{$col_name} = \%column_info;
2623       }
2624     } catch {
2625       %result = ();
2626     };
2627
2628     return \%result if keys %result;
2629   }
2630
2631   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2632   $sth->execute;
2633
2634 ### The acrobatics with lc names is necessary to support both the legacy
2635 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2636 ### with column names differing in cas eonly (thanks pg!)
2637
2638   my ($columns, $seen_lcs);
2639
2640   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2641     idx => scalar keys %$columns,
2642     name => $_,
2643     lc_name => lc($_),
2644   } for @{$sth->{NAME}};
2645
2646   $seen_lcs->{$_->{lc_name}} == 1
2647     and
2648   $_->{name} = $_->{lc_name}
2649     for values %$columns;
2650
2651   for ( values %$columns ) {
2652     my $inf = {
2653       data_type => $sth->{TYPE}->[$_->{idx}],
2654       size => $sth->{PRECISION}->[$_->{idx}],
2655       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2656     };
2657
2658     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2659       @{$inf}{qw( data_type  size)} = ($1, $2);
2660     }
2661
2662     $result{$_->{name}} = $inf;
2663   }
2664
2665   $sth->finish;
2666
2667   if ($dbh->can('type_info')) {
2668     for my $inf (values %result) {
2669       next if ! defined $inf->{data_type};
2670
2671       $inf->{data_type} = (
2672         (
2673           (
2674             $dbh->type_info( $inf->{data_type} )
2675               ||
2676             next
2677           )
2678             ||
2679           next
2680         )->{TYPE_NAME}
2681           ||
2682         next
2683       );
2684
2685       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2686       # needs more testing in the future...
2687       $inf->{size} -= 4 if (
2688         ( $inf->{size}||0 > 4 )
2689           and
2690         $inf->{data_type} =~ qr/^text$/i
2691       );
2692     }
2693
2694   }
2695
2696   return \%result;
2697 }
2698
2699 sub columns_info_for {
2700   my ($self, $table) = @_;
2701   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2702 }
2703
2704 =head2 last_insert_id
2705
2706 Return the row id of the last insert.
2707
2708 =cut
2709
2710 sub _dbh_last_insert_id {
2711     my ($self, $dbh, $source, $col) = @_;
2712
2713     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2714
2715     return $id if defined $id;
2716
2717     my $class = ref $self;
2718     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2719 }
2720
2721 sub last_insert_id {
2722   my $self = shift;
2723   $self->_dbh_last_insert_id ($self->_dbh, @_);
2724 }
2725
2726 =head2 _native_data_type
2727
2728 =over 4
2729
2730 =item Arguments: $type_name
2731
2732 =back
2733
2734 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2735 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2736 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2737
2738 The default implementation returns C<undef>, implement in your Storage driver if
2739 you need this functionality.
2740
2741 Should map types from other databases to the native RDBMS type, for example
2742 C<VARCHAR2> to C<VARCHAR>.
2743
2744 Types with modifiers should map to the underlying data type. For example,
2745 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2746
2747 Composite types should map to the container type, for example
2748 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2749
2750 =cut
2751
2752 sub _native_data_type {
2753   #my ($self, $data_type) = @_;
2754   return undef
2755 }
2756
2757 # Check if placeholders are supported at all
2758 sub _determine_supports_placeholders {
2759   my $self = shift;
2760   my $dbh  = $self->_get_dbh;
2761
2762   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2763   # but it is inaccurate more often than not
2764   return try {
2765     local $dbh->{PrintError} = 0;
2766     local $dbh->{RaiseError} = 1;
2767     $dbh->do('select ?', {}, 1);
2768     1;
2769   }
2770   catch {
2771     0;
2772   };
2773 }
2774
2775 # Check if placeholders bound to non-string types throw exceptions
2776 #
2777 sub _determine_supports_typeless_placeholders {
2778   my $self = shift;
2779   my $dbh  = $self->_get_dbh;
2780
2781   return try {
2782     local $dbh->{PrintError} = 0;
2783     local $dbh->{RaiseError} = 1;
2784     # this specifically tests a bind that is NOT a string
2785     $dbh->do('select 1 where 1 = ?', {}, 1);
2786     1;
2787   }
2788   catch {
2789     0;
2790   };
2791 }
2792
2793 =head2 sqlt_type
2794
2795 Returns the database driver name.
2796
2797 =cut
2798
2799 sub sqlt_type {
2800   shift->_get_dbh->{Driver}->{Name};
2801 }
2802
2803 =head2 bind_attribute_by_data_type
2804
2805 Given a datatype from column info, returns a database specific bind
2806 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2807 let the database planner just handle it.
2808
2809 This method is always called after the driver has been determined and a DBI
2810 connection has been established. Therefore you can refer to C<DBI::$constant>
2811 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2812 the correct modules.
2813
2814 =cut
2815
2816 sub bind_attribute_by_data_type {
2817     return;
2818 }
2819
2820 =head2 is_datatype_numeric
2821
2822 Given a datatype from column_info, returns a boolean value indicating if
2823 the current RDBMS considers it a numeric value. This controls how
2824 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2825 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2826 be performed instead of the usual C<eq>.
2827
2828 =cut
2829
2830 sub is_datatype_numeric {
2831   #my ($self, $dt) = @_;
2832
2833   return 0 unless $_[1];
2834
2835   $_[1] =~ /^ (?:
2836     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2837   ) $/ix;
2838 }
2839
2840
2841 =head2 create_ddl_dir
2842
2843 =over 4
2844
2845 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2846
2847 =back
2848
2849 Creates a SQL file based on the Schema, for each of the specified
2850 database engines in C<\@databases> in the given directory.
2851 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2852
2853 Given a previous version number, this will also create a file containing
2854 the ALTER TABLE statements to transform the previous schema into the
2855 current one. Note that these statements may contain C<DROP TABLE> or
2856 C<DROP COLUMN> statements that can potentially destroy data.
2857
2858 The file names are created using the C<ddl_filename> method below, please
2859 override this method in your schema if you would like a different file
2860 name format. For the ALTER file, the same format is used, replacing
2861 $version in the name with "$preversion-$version".
2862
2863 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2864 The most common value for this would be C<< { add_drop_table => 1 } >>
2865 to have the SQL produced include a C<DROP TABLE> statement for each table
2866 created. For quoting purposes supply C<quote_identifiers>.
2867
2868 If no arguments are passed, then the following default values are assumed:
2869
2870 =over 4
2871
2872 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2873
2874 =item version    - $schema->schema_version
2875
2876 =item directory  - './'
2877
2878 =item preversion - <none>
2879
2880 =back
2881
2882 By default, C<\%sqlt_args> will have
2883
2884  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2885
2886 merged with the hash passed in. To disable any of those features, pass in a
2887 hashref like the following
2888
2889  { ignore_constraint_names => 0, # ... other options }
2890
2891
2892 WARNING: You are strongly advised to check all SQL files created, before applying
2893 them.
2894
2895 =cut
2896
2897 sub create_ddl_dir {
2898   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2899
2900   unless ($dir) {
2901     carp "No directory given, using ./\n";
2902     $dir = './';
2903   } else {
2904       -d $dir
2905         or
2906       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2907         or
2908       $self->throw_exception(
2909         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2910       );
2911   }
2912
2913   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2914
2915   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2916   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2917
2918   my $schema_version = $schema->schema_version || '1.x';
2919   $version ||= $schema_version;
2920
2921   $sqltargs = {
2922     add_drop_table => 1,
2923     ignore_constraint_names => 1,
2924     ignore_index_names => 1,
2925     quote_identifiers => $self->sql_maker->_quoting_enabled,
2926     %{$sqltargs || {}}
2927   };
2928
2929   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2930     $self->throw_exception("Can't create a ddl file without $missing");
2931   }
2932
2933   my $sqlt = SQL::Translator->new( $sqltargs );
2934
2935   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2936   my $sqlt_schema = $sqlt->translate({ data => $schema })
2937     or $self->throw_exception ($sqlt->error);
2938
2939   foreach my $db (@$databases) {
2940     $sqlt->reset();
2941     $sqlt->{schema} = $sqlt_schema;
2942     $sqlt->producer($db);
2943
2944     my $file;
2945     my $filename = $schema->ddl_filename($db, $version, $dir);
2946     if (-e $filename && ($version eq $schema_version )) {
2947       # if we are dumping the current version, overwrite the DDL
2948       carp "Overwriting existing DDL file - $filename";
2949       unlink($filename);
2950     }
2951
2952     my $output = $sqlt->translate;
2953     if(!$output) {
2954       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2955       next;
2956     }
2957     if(!open($file, ">$filename")) {
2958       $self->throw_exception("Can't open $filename for writing ($!)");
2959       next;
2960     }
2961     print $file $output;
2962     close($file);
2963
2964     next unless ($preversion);
2965
2966     require SQL::Translator::Diff;
2967
2968     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2969     if(!-e $prefilename) {
2970       carp("No previous schema file found ($prefilename)");
2971       next;
2972     }
2973
2974     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2975     if(-e $difffile) {
2976       carp("Overwriting existing diff file - $difffile");
2977       unlink($difffile);
2978     }
2979
2980     my $source_schema;
2981     {
2982       my $t = SQL::Translator->new($sqltargs);
2983       $t->debug( 0 );
2984       $t->trace( 0 );
2985
2986       $t->parser( $db )
2987         or $self->throw_exception ($t->error);
2988
2989       my $out = $t->translate( $prefilename )
2990         or $self->throw_exception ($t->error);
2991
2992       $source_schema = $t->schema;
2993
2994       $source_schema->name( $prefilename )
2995         unless ( $source_schema->name );
2996     }
2997
2998     # The "new" style of producers have sane normalization and can support
2999     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3000     # And we have to diff parsed SQL against parsed SQL.
3001     my $dest_schema = $sqlt_schema;
3002
3003     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3004       my $t = SQL::Translator->new($sqltargs);
3005       $t->debug( 0 );
3006       $t->trace( 0 );
3007
3008       $t->parser( $db )
3009         or $self->throw_exception ($t->error);
3010
3011       my $out = $t->translate( $filename )
3012         or $self->throw_exception ($t->error);
3013
3014       $dest_schema = $t->schema;
3015
3016       $dest_schema->name( $filename )
3017         unless $dest_schema->name;
3018     }
3019
3020     my $diff = do {
3021       # FIXME - this is a terrible workaround for
3022       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3023       # Fixing it in this sloppy manner so that we don't hve to
3024       # lockstep an SQLT release as well. Needs to be removed at
3025       # some point, and SQLT dep bumped
3026       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3027         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3028
3029       SQL::Translator::Diff::schema_diff($source_schema, $db,
3030                                          $dest_schema,   $db,
3031                                          $sqltargs
3032                                        );
3033     };
3034
3035     if(!open $file, ">$difffile") {
3036       $self->throw_exception("Can't write to $difffile ($!)");
3037       next;
3038     }
3039     print $file $diff;
3040     close($file);
3041   }
3042 }
3043
3044 =head2 deployment_statements
3045
3046 =over 4
3047
3048 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3049
3050 =back
3051
3052 Returns the statements used by L<DBIx::Class::Storage/deploy>
3053 and L<DBIx::Class::Schema/deploy>.
3054
3055 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3056 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3057
3058 C<$directory> is used to return statements from files in a previously created
3059 L</create_ddl_dir> directory and is optional. The filenames are constructed
3060 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3061
3062 If no C<$directory> is specified then the statements are constructed on the
3063 fly using L<SQL::Translator> and C<$version> is ignored.
3064
3065 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3066
3067 =cut
3068
3069 sub deployment_statements {
3070   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3071   $type ||= $self->sqlt_type;
3072   $version ||= $schema->schema_version || '1.x';
3073   $dir ||= './';
3074   my $filename = $schema->ddl_filename($type, $version, $dir);
3075   if(-f $filename)
3076   {
3077       # FIXME replace this block when a proper sane sql parser is available
3078       my $file;
3079       open($file, "<$filename")
3080         or $self->throw_exception("Can't open $filename ($!)");
3081       my @rows = <$file>;
3082       close($file);
3083       return join('', @rows);
3084   }
3085
3086   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3087     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3088   }
3089
3090   # sources needs to be a parser arg, but for simplicity allow at top level
3091   # coming in
3092   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3093       if exists $sqltargs->{sources};
3094
3095   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3096     unless exists $sqltargs->{quote_identifiers};
3097
3098   my $tr = SQL::Translator->new(
3099     producer => "SQL::Translator::Producer::${type}",
3100     %$sqltargs,
3101     parser => 'SQL::Translator::Parser::DBIx::Class',
3102     data => $schema,
3103   );
3104
3105   return preserve_context {
3106     $tr->translate
3107   } after => sub {
3108     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3109       unless defined $_[0];
3110   };
3111 }
3112
3113 # FIXME deploy() currently does not accurately report sql errors
3114 # Will always return true while errors are warned
3115 sub deploy {
3116   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3117   my $deploy = sub {
3118     my $line = shift;
3119     return if(!$line);
3120     return if($line =~ /^--/);
3121     # next if($line =~ /^DROP/m);
3122     return if($line =~ /^BEGIN TRANSACTION/m);
3123     return if($line =~ /^COMMIT/m);
3124     return if $line =~ /^\s+$/; # skip whitespace only
3125     $self->_query_start($line);
3126     try {
3127       # do a dbh_do cycle here, as we need some error checking in
3128       # place (even though we will ignore errors)
3129       $self->dbh_do (sub { $_[1]->do($line) });
3130     } catch {
3131       carp qq{$_ (running "${line}")};
3132     };
3133     $self->_query_end($line);
3134   };
3135   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3136   if (@statements > 1) {
3137     foreach my $statement (@statements) {
3138       $deploy->( $statement );
3139     }
3140   }
3141   elsif (@statements == 1) {
3142     # split on single line comments and end of statements
3143     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3144       $deploy->( $line );
3145     }
3146   }
3147 }
3148
3149 =head2 datetime_parser
3150
3151 Returns the datetime parser class
3152
3153 =cut
3154
3155 sub datetime_parser {
3156   my $self = shift;
3157   return $self->{datetime_parser} ||= do {
3158     $self->build_datetime_parser(@_);
3159   };
3160 }
3161
3162 =head2 datetime_parser_type
3163
3164 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3165
3166 =head2 build_datetime_parser
3167
3168 See L</datetime_parser>
3169
3170 =cut
3171
3172 sub build_datetime_parser {
3173   my $self = shift;
3174   my $type = $self->datetime_parser_type(@_);
3175   return $type;
3176 }
3177
3178
3179 =head2 is_replicating
3180
3181 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3182 replicate from a master database.  Default is undef, which is the result
3183 returned by databases that don't support replication.
3184
3185 =cut
3186
3187 sub is_replicating {
3188     return;
3189
3190 }
3191
3192 =head2 lag_behind_master
3193
3194 Returns a number that represents a certain amount of lag behind a master db
3195 when a given storage is replicating.  The number is database dependent, but
3196 starts at zero and increases with the amount of lag. Default in undef
3197
3198 =cut
3199
3200 sub lag_behind_master {
3201     return;
3202 }
3203
3204 =head2 relname_to_table_alias
3205
3206 =over 4
3207
3208 =item Arguments: $relname, $join_count
3209
3210 =item Return Value: $alias
3211
3212 =back
3213
3214 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3215 queries.
3216
3217 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3218 way these aliases are named.
3219
3220 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3221 otherwise C<"$relname">.
3222
3223 =cut
3224
3225 sub relname_to_table_alias {
3226   my ($self, $relname, $join_count) = @_;
3227
3228   my $alias = ($join_count && $join_count > 1 ?
3229     join('_', $relname, $join_count) : $relname);
3230
3231   return $alias;
3232 }
3233
3234 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3235 # version and it may be necessary to amend or override it for a specific storage
3236 # if such binds are necessary.
3237 sub _max_column_bytesize {
3238   my ($self, $attr) = @_;
3239
3240   my $max_size;
3241
3242   if ($attr->{sqlt_datatype}) {
3243     my $data_type = lc($attr->{sqlt_datatype});
3244
3245     if ($attr->{sqlt_size}) {
3246
3247       # String/sized-binary types
3248       if ($data_type =~ /^(?:
3249           l? (?:var)? char(?:acter)? (?:\s*varying)?
3250             |
3251           (?:var)? binary (?:\s*varying)?
3252             |
3253           raw
3254         )\b/x
3255       ) {
3256         $max_size = $attr->{sqlt_size};
3257       }
3258       # Other charset/unicode types, assume scale of 4
3259       elsif ($data_type =~ /^(?:
3260           national \s* character (?:\s*varying)?
3261             |
3262           nchar
3263             |
3264           univarchar
3265             |
3266           nvarchar
3267         )\b/x
3268       ) {
3269         $max_size = $attr->{sqlt_size} * 4;
3270       }
3271     }
3272
3273     if (!$max_size and !$self->_is_lob_type($data_type)) {
3274       $max_size = 100 # for all other (numeric?) datatypes
3275     }
3276   }
3277
3278   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3279 }
3280
3281 # Determine if a data_type is some type of BLOB
3282 sub _is_lob_type {
3283   my ($self, $data_type) = @_;
3284   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3285     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3286                                   |varchar|character\s*varying|nvarchar
3287                                   |national\s*character\s*varying))?\z/xi);
3288 }
3289
3290 sub _is_binary_lob_type {
3291   my ($self, $data_type) = @_;
3292   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3293     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3294 }
3295
3296 sub _is_text_lob_type {
3297   my ($self, $data_type) = @_;
3298   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3299     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3300                         |national\s*character\s*varying))\z/xi);
3301 }
3302
3303 # Determine if a data_type is some type of a binary type
3304 sub _is_binary_type {
3305   my ($self, $data_type) = @_;
3306   $data_type && ($self->_is_binary_lob_type($data_type)
3307     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3308 }
3309
3310 1;
3311
3312 =head1 USAGE NOTES
3313
3314 =head2 DBIx::Class and AutoCommit
3315
3316 DBIx::Class can do some wonderful magic with handling exceptions,
3317 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3318 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3319 transaction support.
3320
3321 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3322 in an assumed transaction between commits, and you're telling us you'd
3323 like to manage that manually.  A lot of the magic protections offered by
3324 this module will go away.  We can't protect you from exceptions due to database
3325 disconnects because we don't know anything about how to restart your
3326 transactions.  You're on your own for handling all sorts of exceptional
3327 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3328 be with raw DBI.
3329
3330 =head1 FURTHER QUESTIONS?
3331
3332 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3333
3334 =head1 COPYRIGHT AND LICENSE
3335
3336 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3337 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3338 redistribute it and/or modify it under the same terms as the
3339 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.