lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching on_connect_do
  17        on_disconnect_do transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 BEGIN {
  23
  24 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  25
  26 use base qw/SQL::Abstract::Limit/;
  27
  28 # This prevents the caching of $dbh in S::A::L, I believe
  29 sub new {
  30   my $self = shift->SUPER::new(@_);
  31
  32   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  33   #   it with what it resolves to:
  34   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  35     if ref $self->{limit_dialect};
  36
  37   $self;
  38 }
  39
  40 sub _RowNumberOver {
  41   my ($self, $sql, $order, $rows, $offset ) = @_;
  42
  43   $offset += 1;
  44   my $last = $rows + $offset;
  45   my ( $order_by ) = $self->_order_by( $order );
  46
  47   $sql = <<"";
  48 SELECT * FROM
  49 (
  50    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  51       $sql
  52       $order_by
  53    ) Q1
  54 ) Q2
  55 WHERE ROW_NUM BETWEEN $offset AND $last
  56
  57   return $sql;
  58 }
  59
  60
  61 # While we're at it, this should make LIMIT queries more efficient,
  62 #  without digging into things too deeply
  63 use Scalar::Util 'blessed';
  64 sub _find_syntax {
  65   my ($self, $syntax) = @_;
  66   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  67   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  68     return 'RowNumberOver';
  69   }
  70
  71   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  72 }
  73
  74 sub select {
  75   my ($self, $table, $fields, $where, $order, @rest) = @_;
  76   $table = $self->_quote($table) unless ref($table);
  77   local $self->{rownum_hack_count} = 1
  78     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  79   @rest = (-1) unless defined $rest[0];
  80   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  81     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  82   local $self->{having_bind} = [];
  83   my ($sql, @ret) = $self->SUPER::select(
  84     $table, $self->_recurse_fields($fields), $where, $order, @rest
  85   );
  86   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  87 }
  88
  89 sub insert {
  90   my $self = shift;
  91   my $table = shift;
  92   $table = $self->_quote($table) unless ref($table);
  93   $self->SUPER::insert($table, @_);
  94 }
  95
  96 sub update {
  97   my $self = shift;
  98   my $table = shift;
  99   $table = $self->_quote($table) unless ref($table);
 100   $self->SUPER::update($table, @_);
 101 }
 102
 103 sub delete {
 104   my $self = shift;
 105   my $table = shift;
 106   $table = $self->_quote($table) unless ref($table);
 107   $self->SUPER::delete($table, @_);
 108 }
 109
 110 sub _emulate_limit {
 111   my $self = shift;
 112   if ($_[3] == -1) {
 113     return $_[1].$self->_order_by($_[2]);
 114   } else {
 115     return $self->SUPER::_emulate_limit(@_);
 116   }
 117 }
 118
 119 sub _recurse_fields {
 120   my ($self, $fields, $params) = @_;
 121   my $ref = ref $fields;
 122   return $self->_quote($fields) unless $ref;
 123   return $$fields if $ref eq 'SCALAR';
 124
 125   if ($ref eq 'ARRAY') {
 126     return join(', ', map {
 127       $self->_recurse_fields($_)
 128         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 129           ? ' AS col'.$self->{rownum_hack_count}++
 130           : '')
 131       } @$fields);
 132   } elsif ($ref eq 'HASH') {
 133     foreach my $func (keys %$fields) {
 134       return $self->_sqlcase($func)
 135         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 136     }
 137   }
 138 }
 139
 140 sub _order_by {
 141   my $self = shift;
 142   my $ret = '';
 143   my @extra;
 144   if (ref $_[0] eq 'HASH') {
 145     if (defined $_[0]->{group_by}) {
 146       $ret = $self->_sqlcase(' group by ')
 147         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 148     }
 149     if (defined $_[0]->{having}) {
 150       my $frag;
 151       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 152       push(@{$self->{having_bind}}, @extra);
 153       $ret .= $self->_sqlcase(' having ').$frag;
 154     }
 155     if (defined $_[0]->{order_by}) {
 156       $ret .= $self->_order_by($_[0]->{order_by});
 157     }
 158   } elsif (ref $_[0] eq 'SCALAR') {
 159     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 160   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 161     my @order = @{+shift};
 162     $ret = $self->_sqlcase(' order by ')
 163           .join(', ', map {
 164                         my $r = $self->_order_by($_, @_);
 165                         $r =~ s/^ ?ORDER BY //i;
 166                         $r;
 167                       } @order);
 168   } else {
 169     $ret = $self->SUPER::_order_by(@_);
 170   }
 171   return $ret;
 172 }
 173
 174 sub _order_directions {
 175   my ($self, $order) = @_;
 176   $order = $order->{order_by} if ref $order eq 'HASH';
 177   return $self->SUPER::_order_directions($order);
 178 }
 179
 180 sub _table {
 181   my ($self, $from) = @_;
 182   if (ref $from eq 'ARRAY') {
 183     return $self->_recurse_from(@$from);
 184   } elsif (ref $from eq 'HASH') {
 185     return $self->_make_as($from);
 186   } else {
 187     return $from; # would love to quote here but _table ends up getting called
 188                   # twice during an ->select without a limit clause due to
 189                   # the way S::A::Limit->select works. should maybe consider
 190                   # bypassing this and doing S::A::select($self, ...) in
 191                   # our select method above. meantime, quoting shims have
 192                   # been added to select/insert/update/delete here
 193   }
 194 }
 195
 196 sub _recurse_from {
 197   my ($self, $from, @join) = @_;
 198   my @sqlf;
 199   push(@sqlf, $self->_make_as($from));
 200   foreach my $j (@join) {
 201     my ($to, $on) = @$j;
 202
 203     # check whether a join type exists
 204     my $join_clause = '';
 205     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 206     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 207       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 208     } else {
 209       $join_clause = ' JOIN ';
 210     }
 211     push(@sqlf, $join_clause);
 212
 213     if (ref $to eq 'ARRAY') {
 214       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 215     } else {
 216       push(@sqlf, $self->_make_as($to));
 217     }
 218     push(@sqlf, ' ON ', $self->_join_condition($on));
 219   }
 220   return join('', @sqlf);
 221 }
 222
 223 sub _make_as {
 224   my ($self, $from) = @_;
 225   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 226                      reverse each %{$self->_skip_options($from)});
 227 }
 228
 229 sub _skip_options {
 230   my ($self, $hash) = @_;
 231   my $clean_hash = {};
 232   $clean_hash->{$_} = $hash->{$_}
 233     for grep {!/^-/} keys %$hash;
 234   return $clean_hash;
 235 }
 236
 237 sub _join_condition {
 238   my ($self, $cond) = @_;
 239   if (ref $cond eq 'HASH') {
 240     my %j;
 241     for (keys %$cond) {
 242       my $v = $cond->{$_};
 243       if (ref $v) {
 244         # XXX no throw_exception() in this package and croak() fails with strange results
 245         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 246             if ref($v) ne 'SCALAR';
 247         $j{$_} = $v;
 248       }
 249       else {
 250         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 251       }
 252     };
 253     return scalar($self->_recurse_where(\%j));
 254   } elsif (ref $cond eq 'ARRAY') {
 255     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 256   } else {
 257     die "Can't handle this yet!";
 258   }
 259 }
 260
 261 sub _quote {
 262   my ($self, $label) = @_;
 263   return '' unless defined $label;
 264   return "*" if $label eq '*';
 265   return $label unless $self->{quote_char};
 266   if(ref $self->{quote_char} eq "ARRAY"){
 267     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 268       if !defined $self->{name_sep};
 269     my $sep = $self->{name_sep};
 270     return join($self->{name_sep},
 271         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 272        split(/\Q$sep\E/,$label));
 273   }
 274   return $self->SUPER::_quote($label);
 275 }
 276
 277 sub limit_dialect {
 278     my $self = shift;
 279     $self->{limit_dialect} = shift if @_;
 280     return $self->{limit_dialect};
 281 }
 282
 283 sub quote_char {
 284     my $self = shift;
 285     $self->{quote_char} = shift if @_;
 286     return $self->{quote_char};
 287 }
 288
 289 sub name_sep {
 290     my $self = shift;
 291     $self->{name_sep} = shift if @_;
 292     return $self->{name_sep};
 293 }
 294
 295 } # End of BEGIN block
 296
 297 =head1 NAME
 298
 299 DBIx::Class::Storage::DBI - DBI storage handler
 300
 301 =head1 SYNOPSIS
 302
 303 =head1 DESCRIPTION
 304
 305 This class represents the connection to an RDBMS via L<DBI>.  See
 306 L<DBIx::Class::Storage> for general information.  This pod only
 307 documents DBI-specific methods and behaviors.
 308
 309 =head1 METHODS
 310
 311 =cut
 312
 313 sub new {
 314   my $new = shift->next::method(@_);
 315
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 Specifies things to do immediately after connecting or re-connecting to
 351 the database.  Its value may contain:
 352
 353 =over
 354
 355 =item an array reference
 356
 357 This contains SQL statements to execute in order.  Each element contains
 358 a string or a code reference that returns a string.
 359
 360 =item a code reference
 361
 362 This contains some code to execute.  Unlike code references within an
 363 array reference, its return value is ignored.
 364
 365 =back
 366
 367 =item on_disconnect_do
 368
 369 Takes arguments in the same for as L<on_connect_do> and executes them
 370 immediately before disconnecting from the database.
 371
 372 Note, this only runs if you explicitly call L<disconnect> on the
 373 storage object.
 374
 375 =item disable_sth_caching
 376
 377 If set to a true value, this option will disable the caching of
 378 statement handles via L<DBI/prepare_cached>.
 379
 380 =item limit_dialect
 381
 382 Sets the limit dialect. This is useful for JDBC-bridge among others
 383 where the remote SQL-dialect cannot be determined by the name of the
 384 driver alone.
 385
 386 =item quote_char
 387
 388 Specifies what characters to use to quote table and column names. If
 389 you use this you will want to specify L<name_sep> as well.
 390
 391 quote_char expects either a single character, in which case is it is placed
 392 on either side of the table/column, or an arrayref of length 2 in which case the
 393 table/column name is placed between the elements.
 394
 395 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 396 use C<quote_char =E<gt> [qw/[ ]/]>.
 397
 398 =item name_sep
 399
 400 This only needs to be used in conjunction with L<quote_char>, and is used to
 401 specify the charecter that seperates elements (schemas, tables, columns) from
 402 each other. In most cases this is simply a C<.>.
 403
 404 =item unsafe
 405
 406 This Storage driver normally installs its own C<HandleError>, sets
 407 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 408 all database handles, including those supplied by a coderef.  It does this
 409 so that it can have consistent and useful error behavior.
 410
 411 If you set this option to a true value, Storage will not do its usual
 412 modifications to the database handle's attributes, and instead relies on
 413 the settings in your connect_info DBI options (or the values you set in
 414 your connection coderef, in the case that you are connecting via coderef).
 415
 416 Note that your custom settings can cause Storage to malfunction,
 417 especially if you set a C<HandleError> handler that suppresses exceptions
 418 and/or disable C<RaiseError>.
 419
 420 =back
 421
 422 These options can be mixed in with your other L<DBI> connection attributes,
 423 or placed in a seperate hashref after all other normal L<DBI> connection
 424 arguments.
 425
 426 Every time C<connect_info> is invoked, any previous settings for
 427 these options will be cleared before setting the new ones, regardless of
 428 whether any options are specified in the new C<connect_info>.
 429
 430 Another Important Note:
 431
 432 DBIC can do some wonderful magic with handling exceptions,
 433 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 434 combined with C<txn_do> for transaction support.
 435
 436 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 437 in an assumed transaction between commits, and you're telling us you'd
 438 like to manage that manually.  A lot of DBIC's magic protections
 439 go away.  We can't protect you from exceptions due to database
 440 disconnects because we don't know anything about how to restart your
 441 transactions.  You're on your own for handling all sorts of exceptional
 442 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 443 be with raw DBI.
 444
 445 Examples:
 446
 447   # Simple SQLite connection
 448   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 449
 450   # Connect via subref
 451   ->connect_info([ sub { DBI->connect(...) } ]);
 452
 453   # A bit more complicated
 454   ->connect_info(
 455     [
 456       'dbi:Pg:dbname=foo',
 457       'postgres',
 458       'my_pg_password',
 459       { AutoCommit => 1 },
 460       { quote_char => q{"}, name_sep => q{.} },
 461     ]
 462   );
 463
 464   # Equivalent to the previous example
 465   ->connect_info(
 466     [
 467       'dbi:Pg:dbname=foo',
 468       'postgres',
 469       'my_pg_password',
 470       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 471     ]
 472   );
 473
 474   # Subref + DBIC-specific connection options
 475   ->connect_info(
 476     [
 477       sub { DBI->connect(...) },
 478       {
 479           quote_char => q{`},
 480           name_sep => q{@},
 481           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 482           disable_sth_caching => 1,
 483       },
 484     ]
 485   );
 486
 487 =cut
 488
 489 sub connect_info {
 490   my ($self, $info_arg) = @_;
 491
 492   return $self->_connect_info if !$info_arg;
 493
 494   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 495   #  the new set of options
 496   $self->_sql_maker(undef);
 497   $self->_sql_maker_opts({});
 498   $self->_connect_info([@$info_arg]); # copy for _connect_info
 499
 500   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 501
 502   my $last_info = $dbi_info->[-1];
 503   if(ref $last_info eq 'HASH') {
 504     $last_info = { %$last_info }; # so delete is non-destructive
 505     my @storage_option = qw(
 506       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 507     );
 508     for my $storage_opt (@storage_option) {
 509       if(my $value = delete $last_info->{$storage_opt}) {
 510         $self->$storage_opt($value);
 511       }
 512     }
 513     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 514       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 515         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 516       }
 517     }
 518     # re-insert modified hashref
 519     $dbi_info->[-1] = $last_info;
 520
 521     # Get rid of any trailing empty hashref
 522     pop(@$dbi_info) if !keys %$last_info;
 523   }
 524   $self->_dbi_connect_info($dbi_info);
 525
 526   $self->_connect_info;
 527 }
 528
 529 =head2 on_connect_do
 530
 531 This method is deprecated in favor of setting via L</connect_info>.
 532
 533 =head2 dbh_do
 534
 535 Arguments: $subref, @extra_coderef_args?
 536
 537 Execute the given subref using the new exception-based connection management.
 538
 539 The first two arguments will be the storage object that C<dbh_do> was called
 540 on and a database handle to use.  Any additional arguments will be passed
 541 verbatim to the called subref as arguments 2 and onwards.
 542
 543 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 544 exception handling and reconnection (or failover in future subclasses).
 545
 546 Your subref should have no side-effects outside of the database, as
 547 there is the potential for your subref to be partially double-executed
 548 if the database connection was stale/dysfunctional.
 549
 550 Example:
 551
 552   my @stuff = $schema->storage->dbh_do(
 553     sub {
 554       my ($storage, $dbh, @cols) = @_;
 555       my $cols = join(q{, }, @cols);
 556       $dbh->selectrow_array("SELECT $cols FROM foo");
 557     },
 558     @column_list
 559   );
 560
 561 =cut
 562
 563 sub dbh_do {
 564   my $self = shift;
 565   my $coderef = shift;
 566
 567   ref $coderef eq 'CODE' or $self->throw_exception
 568     ('$coderef must be a CODE reference');
 569
 570   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 571       || $self->{transaction_depth};
 572
 573   local $self->{_in_dbh_do} = 1;
 574
 575   my @result;
 576   my $want_array = wantarray;
 577
 578   eval {
 579     $self->_verify_pid if $self->_dbh;
 580     $self->_populate_dbh if !$self->_dbh;
 581     if($want_array) {
 582         @result = $coderef->($self, $self->_dbh, @_);
 583     }
 584     elsif(defined $want_array) {
 585         $result[0] = $coderef->($self, $self->_dbh, @_);
 586     }
 587     else {
 588         $coderef->($self, $self->_dbh, @_);
 589     }
 590   };
 591
 592   my $exception = $@;
 593   if(!$exception) { return $want_array ? @result : $result[0] }
 594
 595   $self->throw_exception($exception) if $self->connected;
 596
 597   # We were not connected - reconnect and retry, but let any
 598   #  exception fall right through this time
 599   $self->_populate_dbh;
 600   $coderef->($self, $self->_dbh, @_);
 601 }
 602
 603 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 604 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 605 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 606 sub txn_do {
 607   my $self = shift;
 608   my $coderef = shift;
 609
 610   ref $coderef eq 'CODE' or $self->throw_exception
 611     ('$coderef must be a CODE reference');
 612
 613   return $coderef->(@_) if $self->{transaction_depth};
 614
 615   local $self->{_in_dbh_do} = 1;
 616
 617   my @result;
 618   my $want_array = wantarray;
 619
 620   my $tried = 0;
 621   while(1) {
 622     eval {
 623       $self->_verify_pid if $self->_dbh;
 624       $self->_populate_dbh if !$self->_dbh;
 625
 626       $self->txn_begin;
 627       if($want_array) {
 628           @result = $coderef->(@_);
 629       }
 630       elsif(defined $want_array) {
 631           $result[0] = $coderef->(@_);
 632       }
 633       else {
 634           $coderef->(@_);
 635       }
 636       $self->txn_commit;
 637     };
 638
 639     my $exception = $@;
 640     if(!$exception) { return $want_array ? @result : $result[0] }
 641
 642     if($tried++ > 0 || $self->connected) {
 643       eval { $self->txn_rollback };
 644       my $rollback_exception = $@;
 645       if($rollback_exception) {
 646         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 647         $self->throw_exception($exception)  # propagate nested rollback
 648           if $rollback_exception =~ /$exception_class/;
 649
 650         $self->throw_exception(
 651           "Transaction aborted: ${exception}. "
 652           . "Rollback failed: ${rollback_exception}"
 653         );
 654       }
 655       $self->throw_exception($exception)
 656     }
 657
 658     # We were not connected, and was first try - reconnect and retry
 659     # via the while loop
 660     $self->_populate_dbh;
 661   }
 662 }
 663
 664 =head2 disconnect
 665
 666 Our C<disconnect> method also performs a rollback first if the
 667 database is not in C<AutoCommit> mode.
 668
 669 =cut
 670
 671 sub disconnect {
 672   my ($self) = @_;
 673
 674   if( $self->connected ) {
 675     my $connection_do = $self->on_disconnect_do;
 676     $self->_do_connection_actions($connection_do) if ref($connection_do);
 677
 678     $self->_dbh->rollback unless $self->_dbh_autocommit;
 679     $self->_dbh->disconnect;
 680     $self->_dbh(undef);
 681     $self->{_dbh_gen}++;
 682   }
 683 }
 684
 685 sub connected {
 686   my ($self) = @_;
 687
 688   if(my $dbh = $self->_dbh) {
 689       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 690           $self->_dbh(undef);
 691           $self->{_dbh_gen}++;
 692           return;
 693       }
 694       else {
 695           $self->_verify_pid;
 696           return 0 if !$self->_dbh;
 697       }
 698       return ($dbh->FETCH('Active') && $dbh->ping);
 699   }
 700
 701   return 0;
 702 }
 703
 704 # handle pid changes correctly
 705 #  NOTE: assumes $self->_dbh is a valid $dbh
 706 sub _verify_pid {
 707   my ($self) = @_;
 708
 709   return if $self->_conn_pid == $$;
 710
 711   $self->_dbh->{InactiveDestroy} = 1;
 712   $self->_dbh(undef);
 713   $self->{_dbh_gen}++;
 714
 715   return;
 716 }
 717
 718 sub ensure_connected {
 719   my ($self) = @_;
 720
 721   unless ($self->connected) {
 722     $self->_populate_dbh;
 723   }
 724 }
 725
 726 =head2 dbh
 727
 728 Returns the dbh - a data base handle of class L<DBI>.
 729
 730 =cut
 731
 732 sub dbh {
 733   my ($self) = @_;
 734
 735   $self->ensure_connected;
 736   return $self->_dbh;
 737 }
 738
 739 sub _sql_maker_args {
 740     my ($self) = @_;
 741
 742     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 743 }
 744
 745 sub sql_maker {
 746   my ($self) = @_;
 747   unless ($self->_sql_maker) {
 748     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 749   }
 750   return $self->_sql_maker;
 751 }
 752
 753 sub _populate_dbh {
 754   my ($self) = @_;
 755   my @info = @{$self->_dbi_connect_info || []};
 756   $self->_dbh($self->_connect(@info));
 757
 758   # Always set the transaction depth on connect, since
 759   #  there is no transaction in progress by definition
 760   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 761
 762   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 763     my $driver = $self->_dbh->{Driver}->{Name};
 764     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 765       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 766       $self->_rebless() if $self->can('_rebless');
 767     }
 768   }
 769
 770   my $connection_do = $self->on_connect_do;
 771   $self->_do_connection_actions($connection_do) if ref($connection_do);
 772
 773   $self->_conn_pid($$);
 774   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 775 }
 776
 777 sub _do_connection_actions {
 778   my $self = shift;
 779   my $connection_do = shift;
 780
 781   if (ref $connection_do eq 'ARRAY') {
 782     $self->_do_query($_) foreach @$connection_do;
 783   }
 784   elsif (ref $connection_do eq 'CODE') {
 785     $connection_do->();
 786   }
 787
 788   return $self;
 789 }
 790
 791 sub _do_query {
 792   my ($self, $action) = @_;
 793
 794   if (ref $action eq 'CODE') {
 795     $action->($self);
 796   }
 797   else {
 798     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 799     $self->_query_start(@to_run);
 800     $self->_dbh->do(@to_run);
 801     $self->_query_end(@to_run);
 802   }
 803
 804   return $self;
 805 }
 806
 807 sub _connect {
 808   my ($self, @info) = @_;
 809
 810   $self->throw_exception("You failed to provide any connection info")
 811     if !@info;
 812
 813   my ($old_connect_via, $dbh);
 814
 815   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 816     $old_connect_via = $DBI::connect_via;
 817     $DBI::connect_via = 'connect';
 818   }
 819
 820   eval {
 821     if(ref $info[0] eq 'CODE') {
 822        $dbh = &{$info[0]}
 823     }
 824     else {
 825        $dbh = DBI->connect(@info);
 826     }
 827
 828     if($dbh && !$self->unsafe) {
 829       my $weak_self = $self;
 830       weaken($weak_self);
 831       $dbh->{HandleError} = sub {
 832           $weak_self->throw_exception("DBI Exception: $_[0]")
 833       };
 834       $dbh->{ShowErrorStatement} = 1;
 835       $dbh->{RaiseError} = 1;
 836       $dbh->{PrintError} = 0;
 837     }
 838   };
 839
 840   $DBI::connect_via = $old_connect_via if $old_connect_via;
 841
 842   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 843     if !$dbh || $@;
 844
 845   $self->_dbh_autocommit($dbh->{AutoCommit});
 846
 847   $dbh;
 848 }
 849
 850
 851 sub txn_begin {
 852   my $self = shift;
 853   $self->ensure_connected();
 854   if($self->{transaction_depth} == 0) {
 855     $self->debugobj->txn_begin()
 856       if $self->debug;
 857     # this isn't ->_dbh-> because
 858     #  we should reconnect on begin_work
 859     #  for AutoCommit users
 860     $self->dbh->begin_work;
 861   }
 862   $self->{transaction_depth}++;
 863 }
 864
 865 sub txn_commit {
 866   my $self = shift;
 867   if ($self->{transaction_depth} == 1) {
 868     my $dbh = $self->_dbh;
 869     $self->debugobj->txn_commit()
 870       if ($self->debug);
 871     $dbh->commit;
 872     $self->{transaction_depth} = 0
 873       if $self->_dbh_autocommit;
 874   }
 875   elsif($self->{transaction_depth} > 1) {
 876     $self->{transaction_depth}--
 877   }
 878 }
 879
 880 sub txn_rollback {
 881   my $self = shift;
 882   my $dbh = $self->_dbh;
 883   eval {
 884     if ($self->{transaction_depth} == 1) {
 885       $self->debugobj->txn_rollback()
 886         if ($self->debug);
 887       $self->{transaction_depth} = 0
 888         if $self->_dbh_autocommit;
 889       $dbh->rollback;
 890     }
 891     elsif($self->{transaction_depth} > 1) {
 892       $self->{transaction_depth}--;
 893     }
 894     else {
 895       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 896     }
 897   };
 898   if ($@) {
 899     my $error = $@;
 900     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 901     $error =~ /$exception_class/ and $self->throw_exception($error);
 902     # ensure that a failed rollback resets the transaction depth
 903     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 904     $self->throw_exception($error);
 905   }
 906 }
 907
 908 # This used to be the top-half of _execute.  It was split out to make it
 909 #  easier to override in NoBindVars without duping the rest.  It takes up
 910 #  all of _execute's args, and emits $sql, @bind.
 911 sub _prep_for_execute {
 912   my ($self, $op, $extra_bind, $ident, $args) = @_;
 913
 914   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 915   unshift(@bind,
 916     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 917       if $extra_bind;
 918
 919   return ($sql, \@bind);
 920 }
 921
 922 sub _fix_bind_params {
 923     my ($self, @bind) = @_;
 924
 925     ### Turn @bind from something like this:
 926     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 927     ### to this:
 928     ###   ( "'1'", "'1'", "'3'" )
 929     return
 930         map {
 931             if ( defined( $_ && $_->[1] ) ) {
 932                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 933             }
 934             else { q{'NULL'}; }
 935         } @bind;
 936 }
 937
 938 sub _query_start {
 939     my ( $self, $sql, @bind ) = @_;
 940
 941     if ( $self->debug ) {
 942         @bind = $self->_fix_bind_params(@bind);
 943         $self->debugobj->query_start( $sql, @bind );
 944     }
 945 }
 946
 947 sub _query_end {
 948     my ( $self, $sql, @bind ) = @_;
 949
 950     if ( $self->debug ) {
 951         @bind = $self->_fix_bind_params(@bind);
 952         $self->debugobj->query_end( $sql, @bind );
 953     }
 954 }
 955
 956 sub _dbh_execute {
 957   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 958
 959   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 960     $ident = $ident->from();
 961   }
 962
 963   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 964
 965   $self->_query_start( $sql, @$bind );
 966
 967   my $sth = $self->sth($sql,$op);
 968
 969   my $placeholder_index = 1;
 970
 971   foreach my $bound (@$bind) {
 972     my $attributes = {};
 973     my($column_name, @data) = @$bound;
 974
 975     if ($bind_attributes) {
 976       $attributes = $bind_attributes->{$column_name}
 977       if defined $bind_attributes->{$column_name};
 978     }
 979
 980     foreach my $data (@data) {
 981       $data = ref $data ? ''.$data : $data; # stringify args
 982
 983       $sth->bind_param($placeholder_index, $data, $attributes);
 984       $placeholder_index++;
 985     }
 986   }
 987
 988   # Can this fail without throwing an exception anyways???
 989   my $rv = $sth->execute();
 990   $self->throw_exception($sth->errstr) if !$rv;
 991
 992   $self->_query_end( $sql, @$bind );
 993
 994   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 995 }
 996
 997 sub _execute {
 998     my $self = shift;
 999     $self->dbh_do($self->can('_dbh_execute'), @_)
1000 }
1001
1002 sub insert {
1003   my ($self, $source, $to_insert) = @_;
1004
1005   my $ident = $source->from;
1006   my $bind_attributes = $self->source_bind_attributes($source);
1007
1008   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1009
1010   return $to_insert;
1011 }
1012
1013 ## Still not quite perfect, and EXPERIMENTAL
1014 ## Currently it is assumed that all values passed will be "normal", i.e. not
1015 ## scalar refs, or at least, all the same type as the first set, the statement is
1016 ## only prepped once.
1017 sub insert_bulk {
1018   my ($self, $source, $cols, $data) = @_;
1019   my %colvalues;
1020   my $table = $source->from;
1021   @colvalues{@$cols} = (0..$#$cols);
1022   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1023
1024   $self->_query_start( $sql, @bind );
1025   my $sth = $self->sth($sql);
1026
1027 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1028
1029   ## This must be an arrayref, else nothing works!
1030
1031   my $tuple_status = [];
1032
1033   ##use Data::Dumper;
1034   ##print STDERR Dumper( $data, $sql, [@bind] );
1035
1036   my $time = time();
1037
1038   ## Get the bind_attributes, if any exist
1039   my $bind_attributes = $self->source_bind_attributes($source);
1040
1041   ## Bind the values and execute
1042   my $placeholder_index = 1;
1043
1044   foreach my $bound (@bind) {
1045
1046     my $attributes = {};
1047     my ($column_name, $data_index) = @$bound;
1048
1049     if( $bind_attributes ) {
1050       $attributes = $bind_attributes->{$column_name}
1051       if defined $bind_attributes->{$column_name};
1052     }
1053
1054     my @data = map { $_->[$data_index] } @$data;
1055
1056     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1057     $placeholder_index++;
1058   }
1059   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1060   $self->throw_exception($sth->errstr) if !$rv;
1061
1062   $self->_query_end( $sql, @bind );
1063   return (wantarray ? ($rv, $sth, @bind) : $rv);
1064 }
1065
1066 sub update {
1067   my $self = shift @_;
1068   my $source = shift @_;
1069   my $bind_attributes = $self->source_bind_attributes($source);
1070
1071   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1072 }
1073
1074
1075 sub delete {
1076   my $self = shift @_;
1077   my $source = shift @_;
1078
1079   my $bind_attrs = {}; ## If ever it's needed...
1080
1081   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1082 }
1083
1084 sub _select {
1085   my ($self, $ident, $select, $condition, $attrs) = @_;
1086   my $order = $attrs->{order_by};
1087   if (ref $condition eq 'SCALAR') {
1088     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1089   }
1090   if (exists $attrs->{group_by} || $attrs->{having}) {
1091     $order = {
1092       group_by => $attrs->{group_by},
1093       having => $attrs->{having},
1094       ($order ? (order_by => $order) : ())
1095     };
1096   }
1097   my $bind_attrs = {}; ## Future support
1098   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1099   if ($attrs->{software_limit} ||
1100       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1101         $attrs->{software_limit} = 1;
1102   } else {
1103     $self->throw_exception("rows attribute must be positive if present")
1104       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1105
1106     # MySQL actually recommends this approach.  I cringe.
1107     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1108     push @args, $attrs->{rows}, $attrs->{offset};
1109   }
1110   return $self->_execute(@args);
1111 }
1112
1113 sub source_bind_attributes {
1114   my ($self, $source) = @_;
1115
1116   my $bind_attributes;
1117   foreach my $column ($source->columns) {
1118
1119     my $data_type = $source->column_info($column)->{data_type} || '';
1120     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1121      if $data_type;
1122   }
1123
1124   return $bind_attributes;
1125 }
1126
1127 =head2 select
1128
1129 =over 4
1130
1131 =item Arguments: $ident, $select, $condition, $attrs
1132
1133 =back
1134
1135 Handle a SQL select statement.
1136
1137 =cut
1138
1139 sub select {
1140   my $self = shift;
1141   my ($ident, $select, $condition, $attrs) = @_;
1142   return $self->cursor_class->new($self, \@_, $attrs);
1143 }
1144
1145 sub select_single {
1146   my $self = shift;
1147   my ($rv, $sth, @bind) = $self->_select(@_);
1148   my @row = $sth->fetchrow_array;
1149   # Need to call finish() to work round broken DBDs
1150   $sth->finish();
1151   return @row;
1152 }
1153
1154 =head2 sth
1155
1156 =over 4
1157
1158 =item Arguments: $sql
1159
1160 =back
1161
1162 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1163
1164 =cut
1165
1166 sub _dbh_sth {
1167   my ($self, $dbh, $sql) = @_;
1168
1169   # 3 is the if_active parameter which avoids active sth re-use
1170   my $sth = $self->disable_sth_caching
1171     ? $dbh->prepare($sql)
1172     : $dbh->prepare_cached($sql, {}, 3);
1173
1174   # XXX You would think RaiseError would make this impossible,
1175   #  but apparently that's not true :(
1176   $self->throw_exception($dbh->errstr) if !$sth;
1177
1178   $sth;
1179 }
1180
1181 sub sth {
1182   my ($self, $sql) = @_;
1183   $self->dbh_do($self->can('_dbh_sth'), $sql);
1184 }
1185
1186 sub _dbh_columns_info_for {
1187   my ($self, $dbh, $table) = @_;
1188
1189   if ($dbh->can('column_info')) {
1190     my %result;
1191     eval {
1192       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1193       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1194       $sth->execute();
1195       while ( my $info = $sth->fetchrow_hashref() ){
1196         my %column_info;
1197         $column_info{data_type}   = $info->{TYPE_NAME};
1198         $column_info{size}      = $info->{COLUMN_SIZE};
1199         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1200         $column_info{default_value} = $info->{COLUMN_DEF};
1201         my $col_name = $info->{COLUMN_NAME};
1202         $col_name =~ s/^\"(.*)\"$/$1/;
1203
1204         $result{$col_name} = \%column_info;
1205       }
1206     };
1207     return \%result if !$@ && scalar keys %result;
1208   }
1209
1210   my %result;
1211   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1212   $sth->execute;
1213   my @columns = @{$sth->{NAME_lc}};
1214   for my $i ( 0 .. $#columns ){
1215     my %column_info;
1216     $column_info{data_type} = $sth->{TYPE}->[$i];
1217     $column_info{size} = $sth->{PRECISION}->[$i];
1218     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1219
1220     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1221       $column_info{data_type} = $1;
1222       $column_info{size}    = $2;
1223     }
1224
1225     $result{$columns[$i]} = \%column_info;
1226   }
1227   $sth->finish;
1228
1229   foreach my $col (keys %result) {
1230     my $colinfo = $result{$col};
1231     my $type_num = $colinfo->{data_type};
1232     my $type_name;
1233     if(defined $type_num && $dbh->can('type_info')) {
1234       my $type_info = $dbh->type_info($type_num);
1235       $type_name = $type_info->{TYPE_NAME} if $type_info;
1236       $colinfo->{data_type} = $type_name if $type_name;
1237     }
1238   }
1239
1240   return \%result;
1241 }
1242
1243 sub columns_info_for {
1244   my ($self, $table) = @_;
1245   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1246 }
1247
1248 =head2 last_insert_id
1249
1250 Return the row id of the last insert.
1251
1252 =cut
1253
1254 sub _dbh_last_insert_id {
1255     my ($self, $dbh, $source, $col) = @_;
1256     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1257     $dbh->func('last_insert_rowid');
1258 }
1259
1260 sub last_insert_id {
1261   my $self = shift;
1262   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1263 }
1264
1265 =head2 sqlt_type
1266
1267 Returns the database driver name.
1268
1269 =cut
1270
1271 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1272
1273 =head2 bind_attribute_by_data_type
1274
1275 Given a datatype from column info, returns a database specific bind attribute for
1276 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1277 just handle it.
1278
1279 Generally only needed for special case column types, like bytea in postgres.
1280
1281 =cut
1282
1283 sub bind_attribute_by_data_type {
1284     return;
1285 }
1286
1287 =head2 create_ddl_dir
1288
1289 =over 4
1290
1291 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1292
1293 =back
1294
1295 Creates a SQL file based on the Schema, for each of the specified
1296 database types, in the given directory.
1297
1298 =cut
1299
1300 sub create_ddl_dir
1301 {
1302   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1303
1304   if(!$dir || !-d $dir)
1305   {
1306     warn "No directory given, using ./\n";
1307     $dir = "./";
1308   }
1309   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1310   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1311   $version ||= $schema->VERSION || '1.x';
1312   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1313
1314   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1315       . $self->_check_sqlt_message . q{'})
1316           if !$self->_check_sqlt_version;
1317
1318   my $sqlt = SQL::Translator->new({
1319 #      debug => 1,
1320       add_drop_table => 1,
1321   });
1322   foreach my $db (@$databases)
1323   {
1324     $sqlt->reset();
1325     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1326 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1327     $sqlt = $self->configure_sqlt($sqlt, $db);
1328     $sqlt->data($schema);
1329     $sqlt->producer($db);
1330
1331     my $file;
1332     my $filename = $schema->ddl_filename($db, $dir, $version);
1333     if(-e $filename)
1334     {
1335       warn("$filename already exists, skipping $db");
1336       next;
1337     }
1338
1339     my $output = $sqlt->translate;
1340     if(!$output)
1341     {
1342       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1343       next;
1344     }
1345     if(!open($file, ">$filename"))
1346     {
1347         $self->throw_exception("Can't open $filename for writing ($!)");
1348         next;
1349     }
1350     print $file $output;
1351     close($file);
1352
1353     if($preversion)
1354     {
1355       require SQL::Translator::Diff;
1356
1357       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1358 #      print "Previous version $prefilename\n";
1359       if(!-e $prefilename)
1360       {
1361         warn("No previous schema file found ($prefilename)");
1362         next;
1363       }
1364       #### We need to reparse the SQLite file we just wrote, so that
1365       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1366       ##   FIXME: rip Diff to pieces!
1367 #      my $target_schema = $sqlt->schema;
1368 #      unless ( $target_schema->name ) {
1369 #        $target_schema->name( $filename );
1370 #      }
1371       my @input;
1372       push @input, {file => $prefilename, parser => $db};
1373       push @input, {file => $filename, parser => $db};
1374       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1375         my $file   = $_->{'file'};
1376         my $parser = $_->{'parser'};
1377
1378         my $t = SQL::Translator->new;
1379         $t->debug( 0 );
1380         $t->trace( 0 );
1381         $t->parser( $parser )            or die $t->error;
1382         my $out = $t->translate( $file ) or die $t->error;
1383         my $schema = $t->schema;
1384         unless ( $schema->name ) {
1385           $schema->name( $file );
1386         }
1387         ($schema, $parser);
1388       } @input;
1389
1390       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1391                                                     $target_schema, $db,
1392                                                     {}
1393                                                    );
1394       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1395       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1396       if(-e $difffile)
1397       {
1398         warn("$difffile already exists, skipping");
1399         next;
1400       }
1401       if(!open $file, ">$difffile")
1402       {
1403         $self->throw_exception("Can't write to $difffile ($!)");
1404         next;
1405       }
1406       print $file $diff;
1407       close($file);
1408     }
1409   }
1410 }
1411
1412 sub configure_sqlt() {
1413   my $self = shift;
1414   my $tr = shift;
1415   my $db = shift || $self->sqlt_type;
1416   if ($db eq 'PostgreSQL') {
1417     $tr->quote_table_names(0);
1418     $tr->quote_field_names(0);
1419   }
1420   return $tr;
1421 }
1422
1423 =head2 deployment_statements
1424
1425 =over 4
1426
1427 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1428
1429 =back
1430
1431 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1432 The database driver name is given by C<$type>, though the value from
1433 L</sqlt_type> is used if it is not specified.
1434
1435 C<$directory> is used to return statements from files in a previously created
1436 L</create_ddl_dir> directory and is optional. The filenames are constructed
1437 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1438
1439 If no C<$directory> is specified then the statements are constructed on the
1440 fly using L<SQL::Translator> and C<$version> is ignored.
1441
1442 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1443
1444 =cut
1445
1446 sub deployment_statements {
1447   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1448   # Need to be connected to get the correct sqlt_type
1449   $self->ensure_connected() unless $type;
1450   $type ||= $self->sqlt_type;
1451   $version ||= $schema->VERSION || '1.x';
1452   $dir ||= './';
1453   my $filename = $schema->ddl_filename($type, $dir, $version);
1454   if(-f $filename)
1455   {
1456       my $file;
1457       open($file, "<$filename")
1458         or $self->throw_exception("Can't open $filename ($!)");
1459       my @rows = <$file>;
1460       close($file);
1461       return join('', @rows);
1462   }
1463
1464   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1465       . $self->_check_sqlt_message . q{'})
1466           if !$self->_check_sqlt_version;
1467
1468   require SQL::Translator::Parser::DBIx::Class;
1469   eval qq{use SQL::Translator::Producer::${type}};
1470   $self->throw_exception($@) if $@;
1471
1472   # sources needs to be a parser arg, but for simplicty allow at top level
1473   # coming in
1474   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1475       if exists $sqltargs->{sources};
1476
1477   my $tr = SQL::Translator->new(%$sqltargs);
1478   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1479   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1480
1481   return;
1482
1483 }
1484
1485 sub deploy {
1486   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1487   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1488     foreach my $line ( split(";\n", $statement)) {
1489       next if($line =~ /^--/);
1490       next if(!$line);
1491 #      next if($line =~ /^DROP/m);
1492       next if($line =~ /^BEGIN TRANSACTION/m);
1493       next if($line =~ /^COMMIT/m);
1494       next if $line =~ /^\s+$/; # skip whitespace only
1495       $self->_query_start($line);
1496       eval {
1497         $self->dbh->do($line); # shouldn't be using ->dbh ?
1498       };
1499       if ($@) {
1500         warn qq{$@ (running "${line}")};
1501       }
1502       $self->_query_end($line);
1503     }
1504   }
1505 }
1506
1507 =head2 datetime_parser
1508
1509 Returns the datetime parser class
1510
1511 =cut
1512
1513 sub datetime_parser {
1514   my $self = shift;
1515   return $self->{datetime_parser} ||= do {
1516     $self->ensure_connected;
1517     $self->build_datetime_parser(@_);
1518   };
1519 }
1520
1521 =head2 datetime_parser_type
1522
1523 Defines (returns) the datetime parser class - currently hardwired to
1524 L<DateTime::Format::MySQL>
1525
1526 =cut
1527
1528 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1529
1530 =head2 build_datetime_parser
1531
1532 See L</datetime_parser>
1533
1534 =cut
1535
1536 sub build_datetime_parser {
1537   my $self = shift;
1538   my $type = $self->datetime_parser_type(@_);
1539   eval "use ${type}";
1540   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1541   return $type;
1542 }
1543
1544 {
1545     my $_check_sqlt_version; # private
1546     my $_check_sqlt_message; # private
1547     sub _check_sqlt_version {
1548         return $_check_sqlt_version if defined $_check_sqlt_version;
1549         eval 'use SQL::Translator 0.08';
1550         $_check_sqlt_message = $@ ? $@ : '';
1551         $_check_sqlt_version = $@ ? 0 : 1;
1552     }
1553
1554     sub _check_sqlt_message {
1555         _check_sqlt_version if !defined $_check_sqlt_message;
1556         $_check_sqlt_message;
1557     }
1558 }
1559
1560 sub DESTROY {
1561   my $self = shift;
1562   return if !$self->_dbh;
1563   $self->_verify_pid;
1564   $self->_dbh(undef);
1565 }
1566
1567 1;
1568
1569 =head1 SQL METHODS
1570
1571 The module defines a set of methods within the DBIC::SQL::Abstract
1572 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1573 SQL query functions.
1574
1575 The following methods are extended:-
1576
1577 =over 4
1578
1579 =item delete
1580
1581 =item insert
1582
1583 =item select
1584
1585 =item update
1586
1587 =item limit_dialect
1588
1589 See L</connect_info> for details.
1590 For setting, this method is deprecated in favor of L</connect_info>.
1591
1592 =item quote_char
1593
1594 See L</connect_info> for details.
1595 For setting, this method is deprecated in favor of L</connect_info>.
1596
1597 =item name_sep
1598
1599 See L</connect_info> for details.
1600 For setting, this method is deprecated in favor of L</connect_info>.
1601
1602 =back
1603
1604 =head1 AUTHORS
1605
1606 Matt S. Trout <mst@shadowcatsystems.co.uk>
1607
1608 Andy Grundman <andy@hybridized.org>
1609
1610 =head1 LICENSE
1611
1612 You may distribute this code under the same terms as Perl itself.
1613
1614 =cut