lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use DBI::Const::GetInfoType (); # no import of retarded global hash
  19 use namespace::clean;
  20
  21 # default cursor class, overridable in connect_info attributes
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/
  25   sql_limit_dialect sql_quote_char sql_name_sep
  26 /);
  27
  28 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  29
  30 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  31 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  32
  33 __PACKAGE__->sql_name_sep('.');
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/
  36   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  37   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  38   _perform_autoinc_retrieval _autoinc_supplied_for_op
  39 /);
  40
  41 # the values for these accessors are picked out (and deleted) from
  42 # the attribute hashref passed to connect_info
  43 my @storage_options = qw/
  44   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  45   disable_sth_caching unsafe auto_savepoint
  46 /;
  47 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  48
  49
  50 # capability definitions, using a 2-tiered accessor system
  51 # The rationale is:
  52 #
  53 # A driver/user may define _use_X, which blindly without any checks says:
  54 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  55 # type accessor)
  56 #
  57 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  58 # accessor, which in turn calls _determine_supports_X, and stores the return
  59 # in a special slot on the storage object, which is wiped every time a $dbh
  60 # reconnection takes place (it is not guaranteed that upon reconnection we
  61 # will get the same rdbms version). _determine_supports_X does not need to
  62 # exist on a driver, as we ->can for it before calling.
  63
  64 my @capabilities = (qw/
  65   insert_returning
  66   insert_returning_bound
  67
  68   multicolumn_in
  69
  70   placeholders
  71   typeless_placeholders
  72
  73   join_optimizer
  74 /);
  75 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  76 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  77
  78 # on by default, not strictly a capability (pending rewrite)
  79 __PACKAGE__->_use_join_optimizer (1);
  80 sub _determine_supports_join_optimizer { 1 };
  81
  82 # Each of these methods need _determine_driver called before itself
  83 # in order to function reliably. This is a purely DRY optimization
  84 #
  85 # get_(use)_dbms_capability need to be called on the correct Storage
  86 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  87 # _determine_supports_X which obv. needs a correct driver as well
  88 my @rdbms_specific_methods = qw/
  89   sqlt_type
  90   sql_maker
  91   build_datetime_parser
  92   datetime_parser_type
  93
  94   txn_begin
  95   insert
  96   insert_bulk
  97   update
  98   delete
  99   select
 100   select_single
 101   with_deferred_fk_checks
 102
 103   get_use_dbms_capability
 104   get_dbms_capability
 105
 106   _server_info
 107   _get_server_version
 108 /;
 109
 110 for my $meth (@rdbms_specific_methods) {
 111
 112   my $orig = __PACKAGE__->can ($meth)
 113     or die "$meth is not a ::Storage::DBI method!";
 114
 115   no strict qw/refs/;
 116   no warnings qw/redefine/;
 117   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 118     if (
 119       # only fire when invoked on an instance, a valid class-based invocation
 120       # would e.g. be setting a default for an inherited accessor
 121       ref $_[0]
 122         and
 123       ! $_[0]->_driver_determined
 124         and
 125       ! $_[0]->{_in_determine_driver}
 126     ) {
 127       $_[0]->_determine_driver;
 128
 129       # This for some reason crashes and burns on perl 5.8.1
 130       # IFF the method ends up throwing an exception
 131       #goto $_[0]->can ($meth);
 132
 133       my $cref = $_[0]->can ($meth);
 134       goto $cref;
 135     }
 136
 137     goto $orig;
 138   };
 139 }
 140
 141 =head1 NAME
 142
 143 DBIx::Class::Storage::DBI - DBI storage handler
 144
 145 =head1 SYNOPSIS
 146
 147   my $schema = MySchema->connect('dbi:SQLite:my.db');
 148
 149   $schema->storage->debug(1);
 150
 151   my @stuff = $schema->storage->dbh_do(
 152     sub {
 153       my ($storage, $dbh, @args) = @_;
 154       $dbh->do("DROP TABLE authors");
 155     },
 156     @column_list
 157   );
 158
 159   $schema->resultset('Book')->search({
 160      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 161   });
 162
 163 =head1 DESCRIPTION
 164
 165 This class represents the connection to an RDBMS via L<DBI>.  See
 166 L<DBIx::Class::Storage> for general information.  This pod only
 167 documents DBI-specific methods and behaviors.
 168
 169 =head1 METHODS
 170
 171 =cut
 172
 173 sub new {
 174   my $new = shift->next::method(@_);
 175
 176   $new->_sql_maker_opts({});
 177   $new->_dbh_details({});
 178   $new->{_in_do_block} = 0;
 179   $new->{_dbh_gen} = 0;
 180
 181   # read below to see what this does
 182   $new->_arm_global_destructor;
 183
 184   $new;
 185 }
 186
 187 # This is hack to work around perl shooting stuff in random
 188 # order on exit(). If we do not walk the remaining storage
 189 # objects in an END block, there is a *small but real* chance
 190 # of a fork()ed child to kill the parent's shared DBI handle,
 191 # *before perl reaches the DESTROY in this package*
 192 # Yes, it is ugly and effective.
 193 # Additionally this registry is used by the CLONE method to
 194 # make sure no handles are shared between threads
 195 {
 196   my %seek_and_destroy;
 197
 198   sub _arm_global_destructor {
 199     weaken (
 200       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 201     );
 202   }
 203
 204   END {
 205     local $?; # just in case the DBI destructor changes it somehow
 206
 207     # destroy just the object if not native to this process
 208     $_->_verify_pid for (grep
 209       { defined $_ }
 210       values %seek_and_destroy
 211     );
 212   }
 213
 214   sub CLONE {
 215     # As per DBI's recommendation, DBIC disconnects all handles as
 216     # soon as possible (DBIC will reconnect only on demand from within
 217     # the thread)
 218     my @instances = grep { defined $_ } values %seek_and_destroy;
 219     for (@instances) {
 220       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 221       $_->_dbh(undef);
 222
 223       $_->transaction_depth(0);
 224       $_->savepoints([]);
 225     }
 226
 227     # properly renumber all existing refs
 228     %seek_and_destroy = ();
 229     $_->_arm_global_destructor for @instances;
 230   }
 231 }
 232
 233 sub DESTROY {
 234   my $self = shift;
 235
 236   # some databases spew warnings on implicit disconnect
 237   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 238   local $SIG{__WARN__} = sub {};
 239   $self->_dbh(undef);
 240
 241   # this op is necessary, since the very last perl runtime statement
 242   # triggers a global destruction shootout, and the $SIG localization
 243   # may very well be destroyed before perl actually gets to do the
 244   # $dbh undef
 245   1;
 246 }
 247
 248 # handle pid changes correctly - do not destroy parent's connection
 249 sub _verify_pid {
 250   my $self = shift;
 251
 252   my $pid = $self->_conn_pid;
 253   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 254     $dbh->{InactiveDestroy} = 1;
 255     $self->{_dbh_gen}++;
 256     $self->_dbh(undef);
 257     $self->transaction_depth(0);
 258     $self->savepoints([]);
 259   }
 260
 261   return;
 262 }
 263
 264 =head2 connect_info
 265
 266 This method is normally called by L<DBIx::Class::Schema/connection>, which
 267 encapsulates its argument list in an arrayref before passing them here.
 268
 269 The argument list may contain:
 270
 271 =over
 272
 273 =item *
 274
 275 The same 4-element argument set one would normally pass to
 276 L<DBI/connect>, optionally followed by
 277 L<extra attributes|/DBIx::Class specific connection attributes>
 278 recognized by DBIx::Class:
 279
 280   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 281
 282 =item *
 283
 284 A single code reference which returns a connected
 285 L<DBI database handle|DBI/connect> optionally followed by
 286 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 287 by DBIx::Class:
 288
 289   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 290
 291 =item *
 292
 293 A single hashref with all the attributes and the dsn/user/password
 294 mixed together:
 295
 296   $connect_info_args = [{
 297     dsn => $dsn,
 298     user => $user,
 299     password => $pass,
 300     %dbi_attributes,
 301     %extra_attributes,
 302   }];
 303
 304   $connect_info_args = [{
 305     dbh_maker => sub { DBI->connect (...) },
 306     %dbi_attributes,
 307     %extra_attributes,
 308   }];
 309
 310 This is particularly useful for L<Catalyst> based applications, allowing the
 311 following config (L<Config::General> style):
 312
 313   <Model::DB>
 314     schema_class   App::DB
 315     <connect_info>
 316       dsn          dbi:mysql:database=test
 317       user         testuser
 318       password     TestPass
 319       AutoCommit   1
 320     </connect_info>
 321   </Model::DB>
 322
 323 The C<dsn>/C<user>/C<password> combination can be substituted by the
 324 C<dbh_maker> key whose value is a coderef that returns a connected
 325 L<DBI database handle|DBI/connect>
 326
 327 =back
 328
 329 Please note that the L<DBI> docs recommend that you always explicitly
 330 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 331 recommends that it be set to I<1>, and that you perform transactions
 332 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 333 to I<1> if you do not do explicitly set it to zero.  This is the default
 334 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 335
 336 =head3 DBIx::Class specific connection attributes
 337
 338 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 339 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 340 the following connection options. These options can be mixed in with your other
 341 L<DBI> connection attributes, or placed in a separate hashref
 342 (C<\%extra_attributes>) as shown above.
 343
 344 Every time C<connect_info> is invoked, any previous settings for
 345 these options will be cleared before setting the new ones, regardless of
 346 whether any options are specified in the new C<connect_info>.
 347
 348
 349 =over
 350
 351 =item on_connect_do
 352
 353 Specifies things to do immediately after connecting or re-connecting to
 354 the database.  Its value may contain:
 355
 356 =over
 357
 358 =item a scalar
 359
 360 This contains one SQL statement to execute.
 361
 362 =item an array reference
 363
 364 This contains SQL statements to execute in order.  Each element contains
 365 a string or a code reference that returns a string.
 366
 367 =item a code reference
 368
 369 This contains some code to execute.  Unlike code references within an
 370 array reference, its return value is ignored.
 371
 372 =back
 373
 374 =item on_disconnect_do
 375
 376 Takes arguments in the same form as L</on_connect_do> and executes them
 377 immediately before disconnecting from the database.
 378
 379 Note, this only runs if you explicitly call L</disconnect> on the
 380 storage object.
 381
 382 =item on_connect_call
 383
 384 A more generalized form of L</on_connect_do> that calls the specified
 385 C<connect_call_METHOD> methods in your storage driver.
 386
 387   on_connect_do => 'select 1'
 388
 389 is equivalent to:
 390
 391   on_connect_call => [ [ do_sql => 'select 1' ] ]
 392
 393 Its values may contain:
 394
 395 =over
 396
 397 =item a scalar
 398
 399 Will call the C<connect_call_METHOD> method.
 400
 401 =item a code reference
 402
 403 Will execute C<< $code->($storage) >>
 404
 405 =item an array reference
 406
 407 Each value can be a method name or code reference.
 408
 409 =item an array of arrays
 410
 411 For each array, the first item is taken to be the C<connect_call_> method name
 412 or code reference, and the rest are parameters to it.
 413
 414 =back
 415
 416 Some predefined storage methods you may use:
 417
 418 =over
 419
 420 =item do_sql
 421
 422 Executes a SQL string or a code reference that returns a SQL string. This is
 423 what L</on_connect_do> and L</on_disconnect_do> use.
 424
 425 It can take:
 426
 427 =over
 428
 429 =item a scalar
 430
 431 Will execute the scalar as SQL.
 432
 433 =item an arrayref
 434
 435 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 436 attributes hashref and bind values.
 437
 438 =item a code reference
 439
 440 Will execute C<< $code->($storage) >> and execute the return array refs as
 441 above.
 442
 443 =back
 444
 445 =item datetime_setup
 446
 447 Execute any statements necessary to initialize the database session to return
 448 and accept datetime/timestamp values used with
 449 L<DBIx::Class::InflateColumn::DateTime>.
 450
 451 Only necessary for some databases, see your specific storage driver for
 452 implementation details.
 453
 454 =back
 455
 456 =item on_disconnect_call
 457
 458 Takes arguments in the same form as L</on_connect_call> and executes them
 459 immediately before disconnecting from the database.
 460
 461 Calls the C<disconnect_call_METHOD> methods as opposed to the
 462 C<connect_call_METHOD> methods called by L</on_connect_call>.
 463
 464 Note, this only runs if you explicitly call L</disconnect> on the
 465 storage object.
 466
 467 =item disable_sth_caching
 468
 469 If set to a true value, this option will disable the caching of
 470 statement handles via L<DBI/prepare_cached>.
 471
 472 =item limit_dialect
 473
 474 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 475 default L</sql_limit_dialect> setting of the storage (if any). For a list
 476 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 477
 478 =item quote_names
 479
 480 When true automatically sets L</quote_char> and L</name_sep> to the characters
 481 appropriate for your particular RDBMS. This option is preferred over specifying
 482 L</quote_char> directly.
 483
 484 =item quote_char
 485
 486 Specifies what characters to use to quote table and column names.
 487
 488 C<quote_char> expects either a single character, in which case is it
 489 is placed on either side of the table/column name, or an arrayref of length
 490 2 in which case the table/column name is placed between the elements.
 491
 492 For example under MySQL you should use C<< quote_char => '`' >>, and for
 493 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 494
 495 =item name_sep
 496
 497 This parameter is only useful in conjunction with C<quote_char>, and is used to
 498 specify the character that separates elements (schemas, tables, columns) from
 499 each other. If unspecified it defaults to the most commonly used C<.>.
 500
 501 =item unsafe
 502
 503 This Storage driver normally installs its own C<HandleError>, sets
 504 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 505 all database handles, including those supplied by a coderef.  It does this
 506 so that it can have consistent and useful error behavior.
 507
 508 If you set this option to a true value, Storage will not do its usual
 509 modifications to the database handle's attributes, and instead relies on
 510 the settings in your connect_info DBI options (or the values you set in
 511 your connection coderef, in the case that you are connecting via coderef).
 512
 513 Note that your custom settings can cause Storage to malfunction,
 514 especially if you set a C<HandleError> handler that suppresses exceptions
 515 and/or disable C<RaiseError>.
 516
 517 =item auto_savepoint
 518
 519 If this option is true, L<DBIx::Class> will use savepoints when nesting
 520 transactions, making it possible to recover from failure in the inner
 521 transaction without having to abort all outer transactions.
 522
 523 =item cursor_class
 524
 525 Use this argument to supply a cursor class other than the default
 526 L<DBIx::Class::Storage::DBI::Cursor>.
 527
 528 =back
 529
 530 Some real-life examples of arguments to L</connect_info> and
 531 L<DBIx::Class::Schema/connect>
 532
 533   # Simple SQLite connection
 534   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 535
 536   # Connect via subref
 537   ->connect_info([ sub { DBI->connect(...) } ]);
 538
 539   # Connect via subref in hashref
 540   ->connect_info([{
 541     dbh_maker => sub { DBI->connect(...) },
 542     on_connect_do => 'alter session ...',
 543   }]);
 544
 545   # A bit more complicated
 546   ->connect_info(
 547     [
 548       'dbi:Pg:dbname=foo',
 549       'postgres',
 550       'my_pg_password',
 551       { AutoCommit => 1 },
 552       { quote_char => q{"} },
 553     ]
 554   );
 555
 556   # Equivalent to the previous example
 557   ->connect_info(
 558     [
 559       'dbi:Pg:dbname=foo',
 560       'postgres',
 561       'my_pg_password',
 562       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 563     ]
 564   );
 565
 566   # Same, but with hashref as argument
 567   # See parse_connect_info for explanation
 568   ->connect_info(
 569     [{
 570       dsn         => 'dbi:Pg:dbname=foo',
 571       user        => 'postgres',
 572       password    => 'my_pg_password',
 573       AutoCommit  => 1,
 574       quote_char  => q{"},
 575       name_sep    => q{.},
 576     }]
 577   );
 578
 579   # Subref + DBIx::Class-specific connection options
 580   ->connect_info(
 581     [
 582       sub { DBI->connect(...) },
 583       {
 584           quote_char => q{`},
 585           name_sep => q{@},
 586           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 587           disable_sth_caching => 1,
 588       },
 589     ]
 590   );
 591
 592
 593
 594 =cut
 595
 596 sub connect_info {
 597   my ($self, $info) = @_;
 598
 599   return $self->_connect_info if !$info;
 600
 601   $self->_connect_info($info); # copy for _connect_info
 602
 603   $info = $self->_normalize_connect_info($info)
 604     if ref $info eq 'ARRAY';
 605
 606   for my $storage_opt (keys %{ $info->{storage_options} }) {
 607     my $value = $info->{storage_options}{$storage_opt};
 608
 609     $self->$storage_opt($value);
 610   }
 611
 612   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 613   #  the new set of options
 614   $self->_sql_maker(undef);
 615   $self->_sql_maker_opts({});
 616
 617   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 618     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 619
 620     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 621   }
 622
 623   my %attrs = (
 624     %{ $self->_default_dbi_connect_attributes || {} },
 625     %{ $info->{attributes} || {} },
 626   );
 627
 628   my @args = @{ $info->{arguments} };
 629
 630   if (keys %attrs and ref $args[0] ne 'CODE') {
 631     carp
 632         'You provided explicit AutoCommit => 0 in your connection_info. '
 633       . 'This is almost universally a bad idea (see the footnotes of '
 634       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 635       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 636       . 'this warning.'
 637       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 638
 639     push @args, \%attrs if keys %attrs;
 640   }
 641   $self->_dbi_connect_info(\@args);
 642
 643   # FIXME - dirty:
 644   # save attributes them in a separate accessor so they are always
 645   # introspectable, even in case of a CODE $dbhmaker
 646   $self->_dbic_connect_attributes (\%attrs);
 647
 648   return $self->_connect_info;
 649 }
 650
 651 sub _normalize_connect_info {
 652   my ($self, $info_arg) = @_;
 653   my %info;
 654
 655   my @args = @$info_arg;  # take a shallow copy for further mutilation
 656
 657   # combine/pre-parse arguments depending on invocation style
 658
 659   my %attrs;
 660   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 661     %attrs = %{ $args[1] || {} };
 662     @args = $args[0];
 663   }
 664   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 665     %attrs = %{$args[0]};
 666     @args = ();
 667     if (my $code = delete $attrs{dbh_maker}) {
 668       @args = $code;
 669
 670       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 671       if (@ignored) {
 672         carp sprintf (
 673             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 674           . "to the result of 'dbh_maker'",
 675
 676           join (', ', map { "'$_'" } (@ignored) ),
 677         );
 678       }
 679     }
 680     else {
 681       @args = delete @attrs{qw/dsn user password/};
 682     }
 683   }
 684   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 685     %attrs = (
 686       % { $args[3] || {} },
 687       % { $args[4] || {} },
 688     );
 689     @args = @args[0,1,2];
 690   }
 691
 692   $info{arguments} = \@args;
 693
 694   my @storage_opts = grep exists $attrs{$_},
 695     @storage_options, 'cursor_class';
 696
 697   @{ $info{storage_options} }{@storage_opts} =
 698     delete @attrs{@storage_opts} if @storage_opts;
 699
 700   my @sql_maker_opts = grep exists $attrs{$_},
 701     qw/limit_dialect quote_char name_sep quote_names/;
 702
 703   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 704     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 705
 706   $info{attributes} = \%attrs if %attrs;
 707
 708   return \%info;
 709 }
 710
 711 sub _default_dbi_connect_attributes () {
 712   +{
 713     AutoCommit => 1,
 714     PrintError => 0,
 715     RaiseError => 1,
 716     ShowErrorStatement => 1,
 717   };
 718 }
 719
 720 =head2 on_connect_do
 721
 722 This method is deprecated in favour of setting via L</connect_info>.
 723
 724 =cut
 725
 726 =head2 on_disconnect_do
 727
 728 This method is deprecated in favour of setting via L</connect_info>.
 729
 730 =cut
 731
 732 sub _parse_connect_do {
 733   my ($self, $type) = @_;
 734
 735   my $val = $self->$type;
 736   return () if not defined $val;
 737
 738   my @res;
 739
 740   if (not ref($val)) {
 741     push @res, [ 'do_sql', $val ];
 742   } elsif (ref($val) eq 'CODE') {
 743     push @res, $val;
 744   } elsif (ref($val) eq 'ARRAY') {
 745     push @res, map { [ 'do_sql', $_ ] } @$val;
 746   } else {
 747     $self->throw_exception("Invalid type for $type: ".ref($val));
 748   }
 749
 750   return \@res;
 751 }
 752
 753 =head2 dbh_do
 754
 755 Arguments: ($subref | $method_name), @extra_coderef_args?
 756
 757 Execute the given $subref or $method_name using the new exception-based
 758 connection management.
 759
 760 The first two arguments will be the storage object that C<dbh_do> was called
 761 on and a database handle to use.  Any additional arguments will be passed
 762 verbatim to the called subref as arguments 2 and onwards.
 763
 764 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 765 exception handling and reconnection (or failover in future subclasses).
 766
 767 Your subref should have no side-effects outside of the database, as
 768 there is the potential for your subref to be partially double-executed
 769 if the database connection was stale/dysfunctional.
 770
 771 Example:
 772
 773   my @stuff = $schema->storage->dbh_do(
 774     sub {
 775       my ($storage, $dbh, @cols) = @_;
 776       my $cols = join(q{, }, @cols);
 777       $dbh->selectrow_array("SELECT $cols FROM foo");
 778     },
 779     @column_list
 780   );
 781
 782 =cut
 783
 784 sub dbh_do {
 785   my $self = shift;
 786   my $run_target = shift;
 787
 788   # short circuit when we know there is no need for a runner
 789   #
 790   # FIXME - asumption may be wrong
 791   # the rationale for the txn_depth check is that if this block is a part
 792   # of a larger transaction, everything up to that point is screwed anyway
 793   return $self->$run_target($self->_get_dbh, @_)
 794     if $self->{_in_do_block} or $self->transaction_depth;
 795
 796   # take a ref instead of a copy, to preserve @_ aliasing
 797   # semantics within the coderef, but only if needed
 798   # (pseudoforking doesn't like this trick much)
 799   my $args = @_ ? \@_ : [];
 800
 801   DBIx::Class::Storage::BlockRunner->new(
 802     storage => $self,
 803     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 804     wrap_txn => 0,
 805     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 806   )->run;
 807 }
 808
 809 sub txn_do {
 810   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 811   shift->next::method(@_);
 812 }
 813
 814 =head2 disconnect
 815
 816 Our C<disconnect> method also performs a rollback first if the
 817 database is not in C<AutoCommit> mode.
 818
 819 =cut
 820
 821 sub disconnect {
 822   my ($self) = @_;
 823
 824   if( $self->_dbh ) {
 825     my @actions;
 826
 827     push @actions, ( $self->on_disconnect_call || () );
 828     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 829
 830     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 831
 832     # stops the "implicit rollback on disconnect" warning
 833     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 834
 835     %{ $self->_dbh->{CachedKids} } = ();
 836     $self->_dbh->disconnect;
 837     $self->_dbh(undef);
 838     $self->{_dbh_gen}++;
 839   }
 840 }
 841
 842 =head2 with_deferred_fk_checks
 843
 844 =over 4
 845
 846 =item Arguments: C<$coderef>
 847
 848 =item Return Value: The return value of $coderef
 849
 850 =back
 851
 852 Storage specific method to run the code ref with FK checks deferred or
 853 in MySQL's case disabled entirely.
 854
 855 =cut
 856
 857 # Storage subclasses should override this
 858 sub with_deferred_fk_checks {
 859   my ($self, $sub) = @_;
 860   $sub->();
 861 }
 862
 863 =head2 connected
 864
 865 =over
 866
 867 =item Arguments: none
 868
 869 =item Return Value: 1|0
 870
 871 =back
 872
 873 Verifies that the current database handle is active and ready to execute
 874 an SQL statement (e.g. the connection did not get stale, server is still
 875 answering, etc.) This method is used internally by L</dbh>.
 876
 877 =cut
 878
 879 sub connected {
 880   my $self = shift;
 881   return 0 unless $self->_seems_connected;
 882
 883   #be on the safe side
 884   local $self->_dbh->{RaiseError} = 1;
 885
 886   return $self->_ping;
 887 }
 888
 889 sub _seems_connected {
 890   my $self = shift;
 891
 892   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 893
 894   my $dbh = $self->_dbh
 895     or return 0;
 896
 897   return $dbh->FETCH('Active');
 898 }
 899
 900 sub _ping {
 901   my $self = shift;
 902
 903   my $dbh = $self->_dbh or return 0;
 904
 905   return $dbh->ping;
 906 }
 907
 908 sub ensure_connected {
 909   my ($self) = @_;
 910
 911   unless ($self->connected) {
 912     $self->_populate_dbh;
 913   }
 914 }
 915
 916 =head2 dbh
 917
 918 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 919 is guaranteed to be healthy by implicitly calling L</connected>, and if
 920 necessary performing a reconnection before returning. Keep in mind that this
 921 is very B<expensive> on some database engines. Consider using L</dbh_do>
 922 instead.
 923
 924 =cut
 925
 926 sub dbh {
 927   my ($self) = @_;
 928
 929   if (not $self->_dbh) {
 930     $self->_populate_dbh;
 931   } else {
 932     $self->ensure_connected;
 933   }
 934   return $self->_dbh;
 935 }
 936
 937 # this is the internal "get dbh or connect (don't check)" method
 938 sub _get_dbh {
 939   my $self = shift;
 940   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 941   $self->_populate_dbh unless $self->_dbh;
 942   return $self->_dbh;
 943 }
 944
 945 sub sql_maker {
 946   my ($self) = @_;
 947   unless ($self->_sql_maker) {
 948     my $sql_maker_class = $self->sql_maker_class;
 949
 950     my %opts = %{$self->_sql_maker_opts||{}};
 951     my $dialect =
 952       $opts{limit_dialect}
 953         ||
 954       $self->sql_limit_dialect
 955         ||
 956       do {
 957         my $s_class = (ref $self) || $self;
 958         carp (
 959           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 960         . 'have not supplied an explicit limit_dialect in your connection_info. '
 961         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 962         . 'databases but can be (and often is) painfully slow. '
 963         . "Please file an RT ticket against '$s_class' ."
 964         );
 965
 966         'GenericSubQ';
 967       }
 968     ;
 969
 970     my ($quote_char, $name_sep);
 971
 972     if ($opts{quote_names}) {
 973       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 974         my $s_class = (ref $self) || $self;
 975         carp (
 976           "You requested 'quote_names' but your storage class ($s_class) does "
 977         . 'not explicitly define a default sql_quote_char and you have not '
 978         . 'supplied a quote_char as part of your connection_info. DBIC will '
 979         .q{default to the ANSI SQL standard quote '"', which works most of }
 980         . "the time. Please file an RT ticket against '$s_class'."
 981         );
 982
 983         '"'; # RV
 984       };
 985
 986       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 987     }
 988
 989     $self->_sql_maker($sql_maker_class->new(
 990       bindtype=>'columns',
 991       array_datatypes => 1,
 992       limit_dialect => $dialect,
 993       ($quote_char ? (quote_char => $quote_char) : ()),
 994       name_sep => ($name_sep || '.'),
 995       %opts,
 996     ));
 997   }
 998   return $self->_sql_maker;
 999 }
1000
1001 # nothing to do by default
1002 sub _rebless {}
1003 sub _init {}
1004
1005 sub _populate_dbh {
1006   my ($self) = @_;
1007
1008   my @info = @{$self->_dbi_connect_info || []};
1009   $self->_dbh(undef); # in case ->connected failed we might get sent here
1010   $self->_dbh_details({}); # reset everything we know
1011
1012   $self->_dbh($self->_connect(@info));
1013
1014   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1015
1016   $self->_determine_driver;
1017
1018   # Always set the transaction depth on connect, since
1019   #  there is no transaction in progress by definition
1020   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1021
1022   $self->_run_connection_actions unless $self->{_in_determine_driver};
1023 }
1024
1025 sub _run_connection_actions {
1026   my $self = shift;
1027   my @actions;
1028
1029   push @actions, ( $self->on_connect_call || () );
1030   push @actions, $self->_parse_connect_do ('on_connect_do');
1031
1032   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1033 }
1034
1035
1036
1037 sub set_use_dbms_capability {
1038   $_[0]->set_inherited ($_[1], $_[2]);
1039 }
1040
1041 sub get_use_dbms_capability {
1042   my ($self, $capname) = @_;
1043
1044   my $use = $self->get_inherited ($capname);
1045   return defined $use
1046     ? $use
1047     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1048   ;
1049 }
1050
1051 sub set_dbms_capability {
1052   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1053 }
1054
1055 sub get_dbms_capability {
1056   my ($self, $capname) = @_;
1057
1058   my $cap = $self->_dbh_details->{capability}{$capname};
1059
1060   unless (defined $cap) {
1061     if (my $meth = $self->can ("_determine$capname")) {
1062       $cap = $self->$meth ? 1 : 0;
1063     }
1064     else {
1065       $cap = 0;
1066     }
1067
1068     $self->set_dbms_capability ($capname, $cap);
1069   }
1070
1071   return $cap;
1072 }
1073
1074 sub _server_info {
1075   my $self = shift;
1076
1077   my $info;
1078   unless ($info = $self->_dbh_details->{info}) {
1079
1080     $info = {};
1081
1082     my $server_version = try {
1083       $self->_get_server_version
1084     } catch {
1085       # driver determination *may* use this codepath
1086       # in which case we must rethrow
1087       $self->throw_exception($_) if $self->{_in_determine_driver};
1088
1089       # $server_version on failure
1090       undef;
1091     };
1092
1093     if (defined $server_version) {
1094       $info->{dbms_version} = $server_version;
1095
1096       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1097       my @verparts = split (/\./, $numeric_version);
1098       if (
1099         @verparts
1100           &&
1101         $verparts[0] <= 999
1102       ) {
1103         # consider only up to 3 version parts, iff not more than 3 digits
1104         my @use_parts;
1105         while (@verparts && @use_parts < 3) {
1106           my $p = shift @verparts;
1107           last if $p > 999;
1108           push @use_parts, $p;
1109         }
1110         push @use_parts, 0 while @use_parts < 3;
1111
1112         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1113       }
1114     }
1115
1116     $self->_dbh_details->{info} = $info;
1117   }
1118
1119   return $info;
1120 }
1121
1122 sub _get_server_version {
1123   shift->_dbh_get_info('SQL_DBMS_VER');
1124 }
1125
1126 sub _dbh_get_info {
1127   my ($self, $info) = @_;
1128
1129   if ($info =~ /[^0-9]/) {
1130     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1131     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1132       unless defined $info;
1133   }
1134
1135   return $self->_get_dbh->get_info($info);
1136 }
1137
1138 sub _describe_connection {
1139   require DBI::Const::GetInfoReturn;
1140
1141   my $self = shift;
1142   $self->ensure_connected;
1143
1144   my $res = {
1145     DBIC_DSN => $self->_dbi_connect_info->[0],
1146     DBI_VER => DBI->VERSION,
1147     DBIC_VER => DBIx::Class->VERSION,
1148     DBIC_DRIVER => ref $self,
1149   };
1150
1151   for my $inf (
1152     #keys %DBI::Const::GetInfoType::GetInfoType,
1153     qw/
1154       SQL_CURSOR_COMMIT_BEHAVIOR
1155       SQL_CURSOR_ROLLBACK_BEHAVIOR
1156       SQL_CURSOR_SENSITIVITY
1157       SQL_DATA_SOURCE_NAME
1158       SQL_DBMS_NAME
1159       SQL_DBMS_VER
1160       SQL_DEFAULT_TXN_ISOLATION
1161       SQL_DM_VER
1162       SQL_DRIVER_NAME
1163       SQL_DRIVER_ODBC_VER
1164       SQL_DRIVER_VER
1165       SQL_EXPRESSIONS_IN_ORDERBY
1166       SQL_GROUP_BY
1167       SQL_IDENTIFIER_CASE
1168       SQL_IDENTIFIER_QUOTE_CHAR
1169       SQL_MAX_CATALOG_NAME_LEN
1170       SQL_MAX_COLUMN_NAME_LEN
1171       SQL_MAX_IDENTIFIER_LEN
1172       SQL_MAX_TABLE_NAME_LEN
1173       SQL_MULTIPLE_ACTIVE_TXN
1174       SQL_MULT_RESULT_SETS
1175       SQL_NEED_LONG_DATA_LEN
1176       SQL_NON_NULLABLE_COLUMNS
1177       SQL_ODBC_VER
1178       SQL_QUALIFIER_NAME_SEPARATOR
1179       SQL_QUOTED_IDENTIFIER_CASE
1180       SQL_TXN_CAPABLE
1181       SQL_TXN_ISOLATION_OPTION
1182     /
1183   ) {
1184     my $v = $self->_dbh_get_info($inf);
1185     next unless defined $v;
1186
1187     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1188     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1189     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1190   }
1191
1192   $res;
1193 }
1194
1195 sub _determine_driver {
1196   my ($self) = @_;
1197
1198   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1199     my $started_connected = 0;
1200     local $self->{_in_determine_driver} = 1;
1201
1202     if (ref($self) eq __PACKAGE__) {
1203       my $driver;
1204       if ($self->_dbh) { # we are connected
1205         $driver = $self->_dbh->{Driver}{Name};
1206         $started_connected = 1;
1207       }
1208       else {
1209         # if connect_info is a CODEREF, we have no choice but to connect
1210         if (ref $self->_dbi_connect_info->[0] &&
1211             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1212           $self->_populate_dbh;
1213           $driver = $self->_dbh->{Driver}{Name};
1214         }
1215         else {
1216           # try to use dsn to not require being connected, the driver may still
1217           # force a connection in _rebless to determine version
1218           # (dsn may not be supplied at all if all we do is make a mock-schema)
1219           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1220           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1221           $driver ||= $ENV{DBI_DRIVER};
1222         }
1223       }
1224
1225       if ($driver) {
1226         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1227         if ($self->load_optional_class($storage_class)) {
1228           mro::set_mro($storage_class, 'c3');
1229           bless $self, $storage_class;
1230           $self->_rebless();
1231         }
1232         else {
1233           $self->_warn_undetermined_driver(
1234             'This version of DBIC does not yet seem to supply a driver for '
1235           . "your particular RDBMS and/or connection method ('$driver')."
1236           );
1237         }
1238       }
1239       else {
1240         $self->_warn_undetermined_driver(
1241           'Unable to extract a driver name from connect info - this '
1242         . 'should not have happened.'
1243         );
1244       }
1245     }
1246
1247     $self->_driver_determined(1);
1248
1249     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1250
1251     if ($self->can('source_bind_attributes')) {
1252       $self->throw_exception(
1253         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1254       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1255       . 'If you are not sure how to proceed please contact the development team via '
1256       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1257       );
1258     }
1259
1260     $self->_init; # run driver-specific initializations
1261
1262     $self->_run_connection_actions
1263         if !$started_connected && defined $self->_dbh;
1264   }
1265 }
1266
1267 sub _determine_connector_driver {
1268   my ($self, $conn) = @_;
1269
1270   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1271
1272   if (not $dbtype) {
1273     $self->_warn_undetermined_driver(
1274       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1275     . "$conn connector - this should not have happened."
1276     );
1277     return;
1278   }
1279
1280   $dbtype =~ s/\W/_/gi;
1281
1282   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1283   return if $self->isa($subclass);
1284
1285   if ($self->load_optional_class($subclass)) {
1286     bless $self, $subclass;
1287     $self->_rebless;
1288   }
1289   else {
1290     $self->_warn_undetermined_driver(
1291       'This version of DBIC does not yet seem to supply a driver for '
1292     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1293     );
1294   }
1295 }
1296
1297 sub _warn_undetermined_driver {
1298   my ($self, $msg) = @_;
1299
1300   require Data::Dumper::Concise;
1301
1302   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1303   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1304   . "does not go away, file a bugreport including the following info:\n"
1305   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1306   );
1307 }
1308
1309 sub _do_connection_actions {
1310   my $self          = shift;
1311   my $method_prefix = shift;
1312   my $call          = shift;
1313
1314   if (not ref($call)) {
1315     my $method = $method_prefix . $call;
1316     $self->$method(@_);
1317   } elsif (ref($call) eq 'CODE') {
1318     $self->$call(@_);
1319   } elsif (ref($call) eq 'ARRAY') {
1320     if (ref($call->[0]) ne 'ARRAY') {
1321       $self->_do_connection_actions($method_prefix, $_) for @$call;
1322     } else {
1323       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1324     }
1325   } else {
1326     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1327   }
1328
1329   return $self;
1330 }
1331
1332 sub connect_call_do_sql {
1333   my $self = shift;
1334   $self->_do_query(@_);
1335 }
1336
1337 sub disconnect_call_do_sql {
1338   my $self = shift;
1339   $self->_do_query(@_);
1340 }
1341
1342 # override in db-specific backend when necessary
1343 sub connect_call_datetime_setup { 1 }
1344
1345 sub _do_query {
1346   my ($self, $action) = @_;
1347
1348   if (ref $action eq 'CODE') {
1349     $action = $action->($self);
1350     $self->_do_query($_) foreach @$action;
1351   }
1352   else {
1353     # Most debuggers expect ($sql, @bind), so we need to exclude
1354     # the attribute hash which is the second argument to $dbh->do
1355     # furthermore the bind values are usually to be presented
1356     # as named arrayref pairs, so wrap those here too
1357     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1358     my $sql = shift @do_args;
1359     my $attrs = shift @do_args;
1360     my @bind = map { [ undef, $_ ] } @do_args;
1361
1362     $self->dbh_do(sub {
1363       $_[0]->_query_start($sql, \@bind);
1364       $_[1]->do($sql, $attrs, @do_args);
1365       $_[0]->_query_end($sql, \@bind);
1366     });
1367   }
1368
1369   return $self;
1370 }
1371
1372 sub _connect {
1373   my ($self, @info) = @_;
1374
1375   $self->throw_exception("You failed to provide any connection info")
1376     if !@info;
1377
1378   my ($old_connect_via, $dbh);
1379
1380   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1381
1382   try {
1383     if(ref $info[0] eq 'CODE') {
1384       $dbh = $info[0]->();
1385     }
1386     else {
1387       require DBI;
1388       $dbh = DBI->connect(@info);
1389     }
1390
1391     die $DBI::errstr unless $dbh;
1392
1393     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1394       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1395       . 'not continue',
1396       ref $info[0] eq 'CODE'
1397         ? "Connection coderef $info[0] returned a"
1398         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1399     ) unless $dbh->FETCH('Active');
1400
1401     # sanity checks unless asked otherwise
1402     unless ($self->unsafe) {
1403
1404       $self->throw_exception(
1405         'Refusing clobbering of {HandleError} installed on externally supplied '
1406        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1407       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1408
1409       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1410       # request, or an external handle. Complain and set anyway
1411       unless ($dbh->{RaiseError}) {
1412         carp( ref $info[0] eq 'CODE'
1413
1414           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1415            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1416            .'attribute has been supplied'
1417
1418           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1419            .'unsafe => 1. Toggling RaiseError back to true'
1420         );
1421
1422         $dbh->{RaiseError} = 1;
1423       }
1424
1425       # this odd anonymous coderef dereference is in fact really
1426       # necessary to avoid the unwanted effect described in perl5
1427       # RT#75792
1428       sub {
1429         my $weak_self = $_[0];
1430         weaken $weak_self;
1431
1432         # the coderef is blessed so we can distinguish it from externally
1433         # supplied handles (which must be preserved)
1434         $_[1]->{HandleError} = bless sub {
1435           if ($weak_self) {
1436             $weak_self->throw_exception("DBI Exception: $_[0]");
1437           }
1438           else {
1439             # the handler may be invoked by something totally out of
1440             # the scope of DBIC
1441             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1442           }
1443         }, '__DBIC__DBH__ERROR__HANDLER__';
1444       }->($self, $dbh);
1445     }
1446   }
1447   catch {
1448     $self->throw_exception("DBI Connection failed: $_")
1449   };
1450
1451   $self->_dbh_autocommit($dbh->{AutoCommit});
1452   $dbh;
1453 }
1454
1455 sub txn_begin {
1456   my $self = shift;
1457
1458   # this means we have not yet connected and do not know the AC status
1459   # (e.g. coderef $dbh), need a full-fledged connection check
1460   if (! defined $self->_dbh_autocommit) {
1461     $self->ensure_connected;
1462   }
1463   # Otherwise simply connect or re-connect on pid changes
1464   else {
1465     $self->_get_dbh;
1466   }
1467
1468   $self->next::method(@_);
1469 }
1470
1471 sub _exec_txn_begin {
1472   my $self = shift;
1473
1474   # if the user is utilizing txn_do - good for him, otherwise we need to
1475   # ensure that the $dbh is healthy on BEGIN.
1476   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1477   # will be replaced by a failure of begin_work itself (which will be
1478   # then retried on reconnect)
1479   if ($self->{_in_do_block}) {
1480     $self->_dbh->begin_work;
1481   } else {
1482     $self->dbh_do(sub { $_[1]->begin_work });
1483   }
1484 }
1485
1486 sub txn_commit {
1487   my $self = shift;
1488
1489   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1490   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1491     unless $self->_dbh;
1492
1493   # esoteric case for folks using external $dbh handles
1494   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1495     carp "Storage transaction_depth 0 does not match "
1496         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1497     $self->transaction_depth(1);
1498   }
1499
1500   $self->next::method(@_);
1501
1502   # if AutoCommit is disabled txn_depth never goes to 0
1503   # as a new txn is started immediately on commit
1504   $self->transaction_depth(1) if (
1505     !$self->transaction_depth
1506       and
1507     defined $self->_dbh_autocommit
1508       and
1509     ! $self->_dbh_autocommit
1510   );
1511 }
1512
1513 sub _exec_txn_commit {
1514   shift->_dbh->commit;
1515 }
1516
1517 sub txn_rollback {
1518   my $self = shift;
1519
1520   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1521   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1522     unless $self->_dbh;
1523
1524   # esoteric case for folks using external $dbh handles
1525   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1526     carp "Storage transaction_depth 0 does not match "
1527         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1528     $self->transaction_depth(1);
1529   }
1530
1531   $self->next::method(@_);
1532
1533   # if AutoCommit is disabled txn_depth never goes to 0
1534   # as a new txn is started immediately on commit
1535   $self->transaction_depth(1) if (
1536     !$self->transaction_depth
1537       and
1538     defined $self->_dbh_autocommit
1539       and
1540     ! $self->_dbh_autocommit
1541   );
1542 }
1543
1544 sub _exec_txn_rollback {
1545   shift->_dbh->rollback;
1546 }
1547
1548 # generate some identical methods
1549 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1550   no strict qw/refs/;
1551   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1552     my $self = shift;
1553     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1554     $self->throw_exception("Unable to $meth() on a disconnected storage")
1555       unless $self->_dbh;
1556     $self->next::method(@_);
1557   };
1558 }
1559
1560 # This used to be the top-half of _execute.  It was split out to make it
1561 #  easier to override in NoBindVars without duping the rest.  It takes up
1562 #  all of _execute's args, and emits $sql, @bind.
1563 sub _prep_for_execute {
1564   #my ($self, $op, $ident, $args) = @_;
1565   return shift->_gen_sql_bind(@_)
1566 }
1567
1568 sub _gen_sql_bind {
1569   my ($self, $op, $ident, $args) = @_;
1570
1571   my ($colinfos, $from);
1572   if ( blessed($ident) ) {
1573     $from = $ident->from;
1574     $colinfos = $ident->columns_info;
1575   }
1576
1577   my ($sql, @bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1578
1579   if (
1580     ! $ENV{DBIC_DT_SEARCH_OK}
1581       and
1582     $op eq 'select'
1583       and
1584     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1585   ) {
1586     carp_unique 'DateTime objects passed to search() are not supported '
1587       . 'properly (InflateColumn::DateTime formats and settings are not '
1588       . 'respected.) See "Formatting DateTime objects in queries" in '
1589       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1590       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1591   }
1592
1593   return( $sql, $self->_resolve_bindattrs(
1594     $ident, [ @{$args->[2]{bind}||[]}, @bind ], $colinfos
1595   ));
1596 }
1597
1598 sub _resolve_bindattrs {
1599   my ($self, $ident, $bind, $colinfos) = @_;
1600
1601   $colinfos ||= {};
1602
1603   my $resolve_bindinfo = sub {
1604     #my $infohash = shift;
1605
1606     %$colinfos = %{ $self->_resolve_column_info($ident) }
1607       unless keys %$colinfos;
1608
1609     my $ret;
1610     if (my $col = $_[0]->{dbic_colname}) {
1611       $ret = { %{$_[0]} };
1612
1613       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1614         if $colinfos->{$col}{data_type};
1615
1616       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1617         if $colinfos->{$col}{size};
1618     }
1619
1620     $ret || $_[0];
1621   };
1622
1623   return [ map {
1624     if (ref $_ ne 'ARRAY') {
1625       [{}, $_]
1626     }
1627     elsif (! defined $_->[0]) {
1628       [{}, $_->[1]]
1629     }
1630     elsif (ref $_->[0] eq 'HASH') {
1631       [
1632         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1633         $_->[1]
1634       ]
1635     }
1636     elsif (ref $_->[0] eq 'SCALAR') {
1637       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1638     }
1639     else {
1640       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1641     }
1642   } @$bind ];
1643 }
1644
1645 sub _format_for_trace {
1646   #my ($self, $bind) = @_;
1647
1648   ### Turn @bind from something like this:
1649   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1650   ### to this:
1651   ###   ( "'1'", "'3'" )
1652
1653   map {
1654     defined( $_ && $_->[1] )
1655       ? qq{'$_->[1]'}
1656       : q{NULL}
1657   } @{$_[1] || []};
1658 }
1659
1660 sub _query_start {
1661   my ( $self, $sql, $bind ) = @_;
1662
1663   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1664     if $self->debug;
1665 }
1666
1667 sub _query_end {
1668   my ( $self, $sql, $bind ) = @_;
1669
1670   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1671     if $self->debug;
1672 }
1673
1674 sub _dbi_attrs_for_bind {
1675   my ($self, $ident, $bind) = @_;
1676
1677   my @attrs;
1678
1679   for (map { $_->[0] } @$bind) {
1680     push @attrs, do {
1681       if (exists $_->{dbd_attrs}) {
1682         $_->{dbd_attrs}
1683       }
1684       elsif($_->{sqlt_datatype}) {
1685         # cache the result in the dbh_details hash, as it can not change unless
1686         # we connect to something else
1687         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1688         if (not exists $cache->{$_->{sqlt_datatype}}) {
1689           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1690         }
1691         $cache->{$_->{sqlt_datatype}};
1692       }
1693       else {
1694         undef;  # always push something at this position
1695       }
1696     }
1697   }
1698
1699   return \@attrs;
1700 }
1701
1702 sub _execute {
1703   my ($self, $op, $ident, @args) = @_;
1704
1705   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1706
1707   shift->dbh_do(    # retry over disconnects
1708     '_dbh_execute',
1709     $sql,
1710     $bind,
1711     $ident,
1712   );
1713 }
1714
1715 sub _dbh_execute {
1716   my ($self, undef, $sql, $bind, $ident) = @_;
1717
1718   $self->_query_start( $sql, $bind );
1719
1720   my $bind_attrs = $self->_dbi_attrs_for_bind($ident, $bind);
1721
1722   my $sth = $self->_sth($sql);
1723
1724   for my $i (0 .. $#$bind) {
1725     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1726       $sth->bind_param_inout(
1727         $i + 1, # bind params counts are 1-based
1728         $bind->[$i][1],
1729         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1730         $bind_attrs->[$i],
1731       );
1732     }
1733     else {
1734       $sth->bind_param(
1735         $i + 1,
1736         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1737           ? "$bind->[$i][1]"
1738           : $bind->[$i][1]
1739         ,
1740         $bind_attrs->[$i],
1741       );
1742     }
1743   }
1744
1745   # Can this fail without throwing an exception anyways???
1746   my $rv = $sth->execute();
1747   $self->throw_exception(
1748     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1749   ) if !$rv;
1750
1751   $self->_query_end( $sql, $bind );
1752
1753   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1754 }
1755
1756 sub _prefetch_autovalues {
1757   my ($self, $source, $colinfo, $to_insert) = @_;
1758
1759   my %values;
1760   for my $col (keys %$colinfo) {
1761     if (
1762       $colinfo->{$col}{auto_nextval}
1763         and
1764       (
1765         ! exists $to_insert->{$col}
1766           or
1767         ref $to_insert->{$col} eq 'SCALAR'
1768           or
1769         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1770       )
1771     ) {
1772       $values{$col} = $self->_sequence_fetch(
1773         'NEXTVAL',
1774         ( $colinfo->{$col}{sequence} ||=
1775             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1776         ),
1777       );
1778     }
1779   }
1780
1781   \%values;
1782 }
1783
1784 sub insert {
1785   my ($self, $source, $to_insert) = @_;
1786
1787   my $col_infos = $source->columns_info;
1788
1789   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1790
1791   # fuse the values, but keep a separate list of prefetched_values so that
1792   # they can be fused once again with the final return
1793   $to_insert = { %$to_insert, %$prefetched_values };
1794
1795   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1796   # Investigate what does it take to s/defined/exists/
1797   my %pcols = map { $_ => 1 } $source->primary_columns;
1798   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1799   for my $col ($source->columns) {
1800     if ($col_infos->{$col}{is_auto_increment}) {
1801       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1802       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1803     }
1804
1805     # nothing to retrieve when explicit values are supplied
1806     next if (defined $to_insert->{$col} and ! (
1807       ref $to_insert->{$col} eq 'SCALAR'
1808         or
1809       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1810     ));
1811
1812     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1813     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1814       $pcols{$col}
1815         or
1816       $col_infos->{$col}{retrieve_on_insert}
1817     );
1818   };
1819
1820   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1821   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1822
1823   my ($sqla_opts, @ir_container);
1824   if (%retrieve_cols and $self->_use_insert_returning) {
1825     $sqla_opts->{returning_container} = \@ir_container
1826       if $self->_use_insert_returning_bound;
1827
1828     $sqla_opts->{returning} = [
1829       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1830     ];
1831   }
1832
1833   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1834
1835   my %returned_cols = %$to_insert;
1836   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1837     @ir_container = try {
1838       local $SIG{__WARN__} = sub {};
1839       my @r = $sth->fetchrow_array;
1840       $sth->finish;
1841       @r;
1842     } unless @ir_container;
1843
1844     @returned_cols{@$retlist} = @ir_container if @ir_container;
1845   }
1846   else {
1847     # pull in PK if needed and then everything else
1848     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1849
1850       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1851         unless $self->can('last_insert_id');
1852
1853       my @pri_values = $self->last_insert_id($source, @missing_pri);
1854
1855       $self->throw_exception( "Can't get last insert id" )
1856         unless (@pri_values == @missing_pri);
1857
1858       @returned_cols{@missing_pri} = @pri_values;
1859       delete $retrieve_cols{$_} for @missing_pri;
1860     }
1861
1862     # if there is more left to pull
1863     if (%retrieve_cols) {
1864       $self->throw_exception(
1865         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1866       ) unless %pcols;
1867
1868       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1869
1870       my $cur = DBIx::Class::ResultSet->new($source, {
1871         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1872         select => \@left_to_fetch,
1873       })->cursor;
1874
1875       @returned_cols{@left_to_fetch} = $cur->next;
1876
1877       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1878         if scalar $cur->next;
1879     }
1880   }
1881
1882   return { %$prefetched_values, %returned_cols };
1883 }
1884
1885 sub insert_bulk {
1886   my ($self, $source, $cols, $data) = @_;
1887
1888   my @col_range = (0..$#$cols);
1889
1890   # FIXME - perhaps this is not even needed? does DBI stringify?
1891   #
1892   # forcibly stringify whatever is stringifiable
1893   # ResultSet::populate() hands us a copy - safe to mangle
1894   for my $r (0 .. $#$data) {
1895     for my $c (0 .. $#{$data->[$r]}) {
1896       $data->[$r][$c] = "$data->[$r][$c]"
1897         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1898     }
1899   }
1900
1901   my $colinfos = $source->columns_info($cols);
1902
1903   local $self->{_autoinc_supplied_for_op} =
1904     (first { $_->{is_auto_increment} } values %$colinfos)
1905       ? 1
1906       : 0
1907   ;
1908
1909   # get a slice type index based on first row of data
1910   # a "column" in this context may refer to more than one bind value
1911   # e.g. \[ '?, ?', [...], [...] ]
1912   #
1913   # construct the value type index - a description of values types for every
1914   # per-column slice of $data:
1915   #
1916   # nonexistent - nonbind literal
1917   # 0 - regular value
1918   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1919   #
1920   # also construct the column hash to pass to the SQL generator. For plain
1921   # (non literal) values - convert the members of the first row into a
1922   # literal+bind combo, with extra positional info in the bind attr hashref.
1923   # This will allow us to match the order properly, and is so contrived
1924   # because a user-supplied literal/bind (or something else specific to a
1925   # resultsource and/or storage driver) can inject extra binds along the
1926   # way, so one can't rely on "shift positions" ordering at all. Also we
1927   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1928   # can be later matched up by address), because we want to supply a real
1929   # value on which perhaps e.g. datatype checks will be performed
1930   my ($proto_data, $value_type_by_col_idx);
1931   for my $i (@col_range) {
1932     my $colname = $cols->[$i];
1933     if (ref $data->[0][$i] eq 'SCALAR') {
1934       # no bind value at all - no type
1935
1936       $proto_data->{$colname} = $data->[0][$i];
1937     }
1938     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1939       # repack, so we don't end up mangling the original \[]
1940       my ($sql, @bind) = @${$data->[0][$i]};
1941
1942       # normalization of user supplied stuff
1943       my $resolved_bind = $self->_resolve_bindattrs(
1944         $source, \@bind, $colinfos,
1945       );
1946
1947       # store value-less (attrs only) bind info - we will be comparing all
1948       # supplied binds against this for sanity
1949       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1950
1951       $proto_data->{$colname} = \[ $sql, map { [
1952         # inject slice order to use for $proto_bind construction
1953           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
1954             =>
1955           $resolved_bind->[$_][1]
1956         ] } (0 .. $#bind)
1957       ];
1958     }
1959     else {
1960       $value_type_by_col_idx->{$i} = undef;
1961
1962       $proto_data->{$colname} = \[ '?', [
1963         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1964           =>
1965         $data->[0][$i]
1966       ] ];
1967     }
1968   }
1969
1970   my ($sql, $proto_bind) = $self->_prep_for_execute (
1971     'insert',
1972     $source,
1973     [ $proto_data ],
1974   );
1975
1976   if (! @$proto_bind and keys %$value_type_by_col_idx) {
1977     # if the bindlist is empty and we had some dynamic binds, this means the
1978     # storage ate them away (e.g. the NoBindVars component) and interpolated
1979     # them directly into the SQL. This obviously can't be good for multi-inserts
1980     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1981   }
1982
1983   # sanity checks
1984   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1985   #
1986   # use an error reporting closure for convenience (less to pass)
1987   my $bad_slice_report_cref = sub {
1988     my ($msg, $r_idx, $c_idx) = @_;
1989     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1990       $msg,
1991       $cols->[$c_idx],
1992       do {
1993         require Data::Dumper::Concise;
1994         local $Data::Dumper::Maxdepth = 5;
1995         Data::Dumper::Concise::Dumper ({
1996           map { $cols->[$_] =>
1997             $data->[$r_idx][$_]
1998           } @col_range
1999         }),
2000       }
2001     );
2002   };
2003
2004   for my $col_idx (@col_range) {
2005     my $reference_val = $data->[0][$col_idx];
2006
2007     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2008       my $val = $data->[$row_idx][$col_idx];
2009
2010       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2011         if (ref $val ne 'SCALAR') {
2012           $bad_slice_report_cref->(
2013             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2014             $row_idx,
2015             $col_idx,
2016           );
2017         }
2018         elsif ($$val ne $$reference_val) {
2019           $bad_slice_report_cref->(
2020             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2021             $row_idx,
2022             $col_idx,
2023           );
2024         }
2025       }
2026       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2027         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2028           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2029         }
2030       }
2031       else {  # binds from a \[], compare type and attrs
2032         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2033           $bad_slice_report_cref->(
2034             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2035             $row_idx,
2036             $col_idx,
2037           );
2038         }
2039         # start drilling down and bail out early on identical refs
2040         elsif (
2041           $reference_val != $val
2042             or
2043           $$reference_val != $$val
2044         ) {
2045           if (${$val}->[0] ne ${$reference_val}->[0]) {
2046             $bad_slice_report_cref->(
2047               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2048               $row_idx,
2049               $col_idx,
2050             );
2051           }
2052           # need to check the bind attrs - a bind will happen only once for
2053           # the entire dataset, so any changes further down will be ignored.
2054           elsif (! Data::Compare::Compare(
2055             $value_type_by_col_idx->{$col_idx},
2056             [
2057               map
2058               { $_->[0] }
2059               @{$self->_resolve_bindattrs(
2060                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2061               )}
2062             ],
2063           )) {
2064             $bad_slice_report_cref->(
2065               'Differing bind attributes on literal/bind values not supported',
2066               $row_idx,
2067               $col_idx,
2068             );
2069           }
2070         }
2071       }
2072     }
2073   }
2074
2075   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2076   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2077   # scope guard
2078   my $guard = $self->txn_scope_guard;
2079
2080   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2081   my $sth = $self->_sth($sql);
2082   my $rv = do {
2083     if (@$proto_bind) {
2084       # proto bind contains the information on which pieces of $data to pull
2085       # $cols is passed in only for prettier error-reporting
2086       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2087     }
2088     else {
2089       # bind_param_array doesn't work if there are no binds
2090       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2091     }
2092   };
2093
2094   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2095
2096   $guard->commit;
2097
2098   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2099 }
2100
2101 # execute_for_fetch is capable of returning data just fine (it means it
2102 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2103 # is the void-populate fast-path we will just ignore this altogether
2104 # for the time being.
2105 sub _dbh_execute_for_fetch {
2106   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2107
2108   my @idx_range = ( 0 .. $#$proto_bind );
2109
2110   # If we have any bind attributes to take care of, we will bind the
2111   # proto-bind data (which will never be used by execute_for_fetch)
2112   # However since column bindtypes are "sticky", this is sufficient
2113   # to get the DBD to apply the bindtype to all values later on
2114
2115   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2116
2117   for my $i (@idx_range) {
2118     $sth->bind_param (
2119       $i+1, # DBI bind indexes are 1-based
2120       $proto_bind->[$i][1],
2121       $bind_attrs->[$i],
2122     ) if defined $bind_attrs->[$i];
2123   }
2124
2125   # At this point $data slots named in the _bind_data_slice_idx of
2126   # each piece of $proto_bind are either \[]s or plain values to be
2127   # passed in. Construct the dispensing coderef. *NOTE* the order
2128   # of $data will differ from this of the ?s in the SQL (due to
2129   # alphabetical ordering by colname). We actually do want to
2130   # preserve this behavior so that prepare_cached has a better
2131   # chance of matching on unrelated calls
2132
2133   my $fetch_row_idx = -1; # saner loop this way
2134   my $fetch_tuple = sub {
2135     return undef if ++$fetch_row_idx > $#$data;
2136
2137     return [ map { defined $_->{_literal_bind_subindex}
2138       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2139          ->[ $_->{_literal_bind_subindex} ]
2140           ->[1]
2141       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2142     } map { $_->[0] } @$proto_bind];
2143   };
2144
2145   my $tuple_status = [];
2146   my ($rv, $err);
2147   try {
2148     $rv = $sth->execute_for_fetch(
2149       $fetch_tuple,
2150       $tuple_status,
2151     );
2152   }
2153   catch {
2154     $err = shift;
2155   };
2156
2157   # Not all DBDs are create equal. Some throw on error, some return
2158   # an undef $rv, and some set $sth->err - try whatever we can
2159   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2160     ! defined $err
2161       and
2162     ( !defined $rv or $sth->err )
2163   );
2164
2165   # Statement must finish even if there was an exception.
2166   try {
2167     $sth->finish
2168   }
2169   catch {
2170     $err = shift unless defined $err
2171   };
2172
2173   if (defined $err) {
2174     my $i = 0;
2175     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2176
2177     $self->throw_exception("Unexpected populate error: $err")
2178       if ($i > $#$tuple_status);
2179
2180     require Data::Dumper::Concise;
2181     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2182       ($tuple_status->[$i][1] || $err),
2183       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2184     );
2185   }
2186
2187   return $rv;
2188 }
2189
2190 sub _dbh_execute_inserts_with_no_binds {
2191   my ($self, $sth, $count) = @_;
2192
2193   my $err;
2194   try {
2195     my $dbh = $self->_get_dbh;
2196     local $dbh->{RaiseError} = 1;
2197     local $dbh->{PrintError} = 0;
2198
2199     $sth->execute foreach 1..$count;
2200   }
2201   catch {
2202     $err = shift;
2203   };
2204
2205   # Make sure statement is finished even if there was an exception.
2206   try {
2207     $sth->finish
2208   }
2209   catch {
2210     $err = shift unless defined $err;
2211   };
2212
2213   $self->throw_exception($err) if defined $err;
2214
2215   return $count;
2216 }
2217
2218 sub update {
2219   #my ($self, $source, @args) = @_;
2220   shift->_execute('update', @_);
2221 }
2222
2223
2224 sub delete {
2225   #my ($self, $source, @args) = @_;
2226   shift->_execute('delete', @_);
2227 }
2228
2229 sub _select {
2230   my $self = shift;
2231   $self->_execute($self->_select_args(@_));
2232 }
2233
2234 sub _select_args_to_query {
2235   my $self = shift;
2236
2237   $self->throw_exception(
2238     "Unable to generate limited query representation with 'software_limit' enabled"
2239   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2240
2241   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2242   #  = $self->_select_args($ident, $select, $cond, $attrs);
2243   my ($op, $ident, @args) =
2244     $self->_select_args(@_);
2245
2246   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2247   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2248   $prepared_bind ||= [];
2249
2250   return wantarray
2251     ? ($sql, $prepared_bind)
2252     : \[ "($sql)", @$prepared_bind ]
2253   ;
2254 }
2255
2256 sub _select_args {
2257   my ($self, $ident, $select, $where, $attrs) = @_;
2258
2259   my $sql_maker = $self->sql_maker;
2260   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2261
2262   $attrs = {
2263     %$attrs,
2264     select => $select,
2265     from => $ident,
2266     where => $where,
2267     $rs_alias && $alias2source->{$rs_alias}
2268       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2269       : ()
2270     ,
2271   };
2272
2273   # Sanity check the attributes (SQLMaker does it too, but
2274   # in case of a software_limit we'll never reach there)
2275   if (defined $attrs->{offset}) {
2276     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2277       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2278   }
2279
2280   if (defined $attrs->{rows}) {
2281     $self->throw_exception("The rows attribute must be a positive integer if present")
2282       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2283   }
2284   elsif ($attrs->{offset}) {
2285     # MySQL actually recommends this approach.  I cringe.
2286     $attrs->{rows} = $sql_maker->__max_int;
2287   }
2288
2289   my @limit;
2290
2291   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2292   # storage, unless software limit was requested
2293   if (
2294     # limited collapsing has_many
2295     ( $attrs->{rows} && $attrs->{collapse} )
2296        ||
2297     # grouped prefetch (to satisfy group_by == select)
2298     ( $attrs->{group_by}
2299         &&
2300       @{$attrs->{group_by}}
2301         &&
2302       $attrs->{_prefetch_selector_range}
2303     )
2304   ) {
2305     ($ident, $select, $where, $attrs)
2306       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2307   }
2308   elsif (! $attrs->{software_limit} ) {
2309     push @limit, (
2310       $attrs->{rows} || (),
2311       $attrs->{offset} || (),
2312     );
2313   }
2314
2315   # try to simplify the joinmap further (prune unreferenced type-single joins)
2316   if (
2317     ref $ident
2318       and
2319     reftype $ident eq 'ARRAY'
2320       and
2321     @$ident != 1
2322   ) {
2323     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2324   }
2325
2326 ###
2327   # This would be the point to deflate anything found in $where
2328   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2329   # expect a result object. And all we have is a resultsource (it is trivial
2330   # to extract deflator coderefs via $alias2source above).
2331   #
2332   # I don't see a way forward other than changing the way deflators are
2333   # invoked, and that's just bad...
2334 ###
2335
2336   return ('select', $ident, $select, $where, $attrs, @limit);
2337 }
2338
2339 # Returns a counting SELECT for a simple count
2340 # query. Abstracted so that a storage could override
2341 # this to { count => 'firstcol' } or whatever makes
2342 # sense as a performance optimization
2343 sub _count_select {
2344   #my ($self, $source, $rs_attrs) = @_;
2345   return { count => '*' };
2346 }
2347
2348 =head2 select
2349
2350 =over 4
2351
2352 =item Arguments: $ident, $select, $condition, $attrs
2353
2354 =back
2355
2356 Handle a SQL select statement.
2357
2358 =cut
2359
2360 sub select {
2361   my $self = shift;
2362   my ($ident, $select, $condition, $attrs) = @_;
2363   return $self->cursor_class->new($self, \@_, $attrs);
2364 }
2365
2366 sub select_single {
2367   my $self = shift;
2368   my ($rv, $sth, @bind) = $self->_select(@_);
2369   my @row = $sth->fetchrow_array;
2370   my @nextrow = $sth->fetchrow_array if @row;
2371   if(@row && @nextrow) {
2372     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2373   }
2374   # Need to call finish() to work round broken DBDs
2375   $sth->finish();
2376   return @row;
2377 }
2378
2379 =head2 sql_limit_dialect
2380
2381 This is an accessor for the default SQL limit dialect used by a particular
2382 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2383 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2384 see L<DBIx::Class::SQLMaker::LimitDialects>.
2385
2386 =cut
2387
2388 sub _dbh_sth {
2389   my ($self, $dbh, $sql) = @_;
2390
2391   # 3 is the if_active parameter which avoids active sth re-use
2392   my $sth = $self->disable_sth_caching
2393     ? $dbh->prepare($sql)
2394     : $dbh->prepare_cached($sql, {}, 3);
2395
2396   # XXX You would think RaiseError would make this impossible,
2397   #  but apparently that's not true :(
2398   $self->throw_exception(
2399     $dbh->errstr
2400       ||
2401     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2402             .'an exception and/or setting $dbh->errstr',
2403       length ($sql) > 20
2404         ? substr($sql, 0, 20) . '...'
2405         : $sql
2406       ,
2407       'DBD::' . $dbh->{Driver}{Name},
2408     )
2409   ) if !$sth;
2410
2411   $sth;
2412 }
2413
2414 sub sth {
2415   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2416   shift->_sth(@_);
2417 }
2418
2419 sub _sth {
2420   my ($self, $sql) = @_;
2421   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2422 }
2423
2424 sub _dbh_columns_info_for {
2425   my ($self, $dbh, $table) = @_;
2426
2427   if ($dbh->can('column_info')) {
2428     my %result;
2429     my $caught;
2430     try {
2431       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2432       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2433       $sth->execute();
2434       while ( my $info = $sth->fetchrow_hashref() ){
2435         my %column_info;
2436         $column_info{data_type}   = $info->{TYPE_NAME};
2437         $column_info{size}      = $info->{COLUMN_SIZE};
2438         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2439         $column_info{default_value} = $info->{COLUMN_DEF};
2440         my $col_name = $info->{COLUMN_NAME};
2441         $col_name =~ s/^\"(.*)\"$/$1/;
2442
2443         $result{$col_name} = \%column_info;
2444       }
2445     } catch {
2446       $caught = 1;
2447     };
2448     return \%result if !$caught && scalar keys %result;
2449   }
2450
2451   my %result;
2452   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2453   $sth->execute;
2454   my @columns = @{$sth->{NAME_lc}};
2455   for my $i ( 0 .. $#columns ){
2456     my %column_info;
2457     $column_info{data_type} = $sth->{TYPE}->[$i];
2458     $column_info{size} = $sth->{PRECISION}->[$i];
2459     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2460
2461     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2462       $column_info{data_type} = $1;
2463       $column_info{size}    = $2;
2464     }
2465
2466     $result{$columns[$i]} = \%column_info;
2467   }
2468   $sth->finish;
2469
2470   foreach my $col (keys %result) {
2471     my $colinfo = $result{$col};
2472     my $type_num = $colinfo->{data_type};
2473     my $type_name;
2474     if(defined $type_num && $dbh->can('type_info')) {
2475       my $type_info = $dbh->type_info($type_num);
2476       $type_name = $type_info->{TYPE_NAME} if $type_info;
2477       $colinfo->{data_type} = $type_name if $type_name;
2478     }
2479   }
2480
2481   return \%result;
2482 }
2483
2484 sub columns_info_for {
2485   my ($self, $table) = @_;
2486   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2487 }
2488
2489 =head2 last_insert_id
2490
2491 Return the row id of the last insert.
2492
2493 =cut
2494
2495 sub _dbh_last_insert_id {
2496     my ($self, $dbh, $source, $col) = @_;
2497
2498     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2499
2500     return $id if defined $id;
2501
2502     my $class = ref $self;
2503     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2504 }
2505
2506 sub last_insert_id {
2507   my $self = shift;
2508   $self->_dbh_last_insert_id ($self->_dbh, @_);
2509 }
2510
2511 =head2 _native_data_type
2512
2513 =over 4
2514
2515 =item Arguments: $type_name
2516
2517 =back
2518
2519 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2520 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2521 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2522
2523 The default implementation returns C<undef>, implement in your Storage driver if
2524 you need this functionality.
2525
2526 Should map types from other databases to the native RDBMS type, for example
2527 C<VARCHAR2> to C<VARCHAR>.
2528
2529 Types with modifiers should map to the underlying data type. For example,
2530 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2531
2532 Composite types should map to the container type, for example
2533 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2534
2535 =cut
2536
2537 sub _native_data_type {
2538   #my ($self, $data_type) = @_;
2539   return undef
2540 }
2541
2542 # Check if placeholders are supported at all
2543 sub _determine_supports_placeholders {
2544   my $self = shift;
2545   my $dbh  = $self->_get_dbh;
2546
2547   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2548   # but it is inaccurate more often than not
2549   return try {
2550     local $dbh->{PrintError} = 0;
2551     local $dbh->{RaiseError} = 1;
2552     $dbh->do('select ?', {}, 1);
2553     1;
2554   }
2555   catch {
2556     0;
2557   };
2558 }
2559
2560 # Check if placeholders bound to non-string types throw exceptions
2561 #
2562 sub _determine_supports_typeless_placeholders {
2563   my $self = shift;
2564   my $dbh  = $self->_get_dbh;
2565
2566   return try {
2567     local $dbh->{PrintError} = 0;
2568     local $dbh->{RaiseError} = 1;
2569     # this specifically tests a bind that is NOT a string
2570     $dbh->do('select 1 where 1 = ?', {}, 1);
2571     1;
2572   }
2573   catch {
2574     0;
2575   };
2576 }
2577
2578 =head2 sqlt_type
2579
2580 Returns the database driver name.
2581
2582 =cut
2583
2584 sub sqlt_type {
2585   shift->_get_dbh->{Driver}->{Name};
2586 }
2587
2588 =head2 bind_attribute_by_data_type
2589
2590 Given a datatype from column info, returns a database specific bind
2591 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2592 let the database planner just handle it.
2593
2594 This method is always called after the driver has been determined and a DBI
2595 connection has been established. Therefore you can refer to C<DBI::$constant>
2596 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2597 the correct modules.
2598
2599 =cut
2600
2601 sub bind_attribute_by_data_type {
2602     return;
2603 }
2604
2605 =head2 is_datatype_numeric
2606
2607 Given a datatype from column_info, returns a boolean value indicating if
2608 the current RDBMS considers it a numeric value. This controls how
2609 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2610 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2611 be performed instead of the usual C<eq>.
2612
2613 =cut
2614
2615 sub is_datatype_numeric {
2616   #my ($self, $dt) = @_;
2617
2618   return 0 unless $_[1];
2619
2620   $_[1] =~ /^ (?:
2621     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2622   ) $/ix;
2623 }
2624
2625
2626 =head2 create_ddl_dir
2627
2628 =over 4
2629
2630 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2631
2632 =back
2633
2634 Creates a SQL file based on the Schema, for each of the specified
2635 database engines in C<\@databases> in the given directory.
2636 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2637
2638 Given a previous version number, this will also create a file containing
2639 the ALTER TABLE statements to transform the previous schema into the
2640 current one. Note that these statements may contain C<DROP TABLE> or
2641 C<DROP COLUMN> statements that can potentially destroy data.
2642
2643 The file names are created using the C<ddl_filename> method below, please
2644 override this method in your schema if you would like a different file
2645 name format. For the ALTER file, the same format is used, replacing
2646 $version in the name with "$preversion-$version".
2647
2648 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2649 The most common value for this would be C<< { add_drop_table => 1 } >>
2650 to have the SQL produced include a C<DROP TABLE> statement for each table
2651 created. For quoting purposes supply C<quote_table_names> and
2652 C<quote_field_names>.
2653
2654 If no arguments are passed, then the following default values are assumed:
2655
2656 =over 4
2657
2658 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2659
2660 =item version    - $schema->schema_version
2661
2662 =item directory  - './'
2663
2664 =item preversion - <none>
2665
2666 =back
2667
2668 By default, C<\%sqlt_args> will have
2669
2670  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2671
2672 merged with the hash passed in. To disable any of those features, pass in a
2673 hashref like the following
2674
2675  { ignore_constraint_names => 0, # ... other options }
2676
2677
2678 WARNING: You are strongly advised to check all SQL files created, before applying
2679 them.
2680
2681 =cut
2682
2683 sub create_ddl_dir {
2684   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2685
2686   unless ($dir) {
2687     carp "No directory given, using ./\n";
2688     $dir = './';
2689   } else {
2690       -d $dir
2691         or
2692       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2693         or
2694       $self->throw_exception(
2695         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2696       );
2697   }
2698
2699   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2700
2701   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2702   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2703
2704   my $schema_version = $schema->schema_version || '1.x';
2705   $version ||= $schema_version;
2706
2707   $sqltargs = {
2708     add_drop_table => 1,
2709     ignore_constraint_names => 1,
2710     ignore_index_names => 1,
2711     %{$sqltargs || {}}
2712   };
2713
2714   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2715     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2716   }
2717
2718   my $sqlt = SQL::Translator->new( $sqltargs );
2719
2720   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2721   my $sqlt_schema = $sqlt->translate({ data => $schema })
2722     or $self->throw_exception ($sqlt->error);
2723
2724   foreach my $db (@$databases) {
2725     $sqlt->reset();
2726     $sqlt->{schema} = $sqlt_schema;
2727     $sqlt->producer($db);
2728
2729     my $file;
2730     my $filename = $schema->ddl_filename($db, $version, $dir);
2731     if (-e $filename && ($version eq $schema_version )) {
2732       # if we are dumping the current version, overwrite the DDL
2733       carp "Overwriting existing DDL file - $filename";
2734       unlink($filename);
2735     }
2736
2737     my $output = $sqlt->translate;
2738     if(!$output) {
2739       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2740       next;
2741     }
2742     if(!open($file, ">$filename")) {
2743       $self->throw_exception("Can't open $filename for writing ($!)");
2744       next;
2745     }
2746     print $file $output;
2747     close($file);
2748
2749     next unless ($preversion);
2750
2751     require SQL::Translator::Diff;
2752
2753     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2754     if(!-e $prefilename) {
2755       carp("No previous schema file found ($prefilename)");
2756       next;
2757     }
2758
2759     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2760     if(-e $difffile) {
2761       carp("Overwriting existing diff file - $difffile");
2762       unlink($difffile);
2763     }
2764
2765     my $source_schema;
2766     {
2767       my $t = SQL::Translator->new($sqltargs);
2768       $t->debug( 0 );
2769       $t->trace( 0 );
2770
2771       $t->parser( $db )
2772         or $self->throw_exception ($t->error);
2773
2774       my $out = $t->translate( $prefilename )
2775         or $self->throw_exception ($t->error);
2776
2777       $source_schema = $t->schema;
2778
2779       $source_schema->name( $prefilename )
2780         unless ( $source_schema->name );
2781     }
2782
2783     # The "new" style of producers have sane normalization and can support
2784     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2785     # And we have to diff parsed SQL against parsed SQL.
2786     my $dest_schema = $sqlt_schema;
2787
2788     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2789       my $t = SQL::Translator->new($sqltargs);
2790       $t->debug( 0 );
2791       $t->trace( 0 );
2792
2793       $t->parser( $db )
2794         or $self->throw_exception ($t->error);
2795
2796       my $out = $t->translate( $filename )
2797         or $self->throw_exception ($t->error);
2798
2799       $dest_schema = $t->schema;
2800
2801       $dest_schema->name( $filename )
2802         unless $dest_schema->name;
2803     }
2804
2805     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2806                                                   $dest_schema,   $db,
2807                                                   $sqltargs
2808                                                  );
2809     if(!open $file, ">$difffile") {
2810       $self->throw_exception("Can't write to $difffile ($!)");
2811       next;
2812     }
2813     print $file $diff;
2814     close($file);
2815   }
2816 }
2817
2818 =head2 deployment_statements
2819
2820 =over 4
2821
2822 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2823
2824 =back
2825
2826 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2827
2828 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2829 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2830
2831 C<$directory> is used to return statements from files in a previously created
2832 L</create_ddl_dir> directory and is optional. The filenames are constructed
2833 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2834
2835 If no C<$directory> is specified then the statements are constructed on the
2836 fly using L<SQL::Translator> and C<$version> is ignored.
2837
2838 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2839
2840 =cut
2841
2842 sub deployment_statements {
2843   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2844   $type ||= $self->sqlt_type;
2845   $version ||= $schema->schema_version || '1.x';
2846   $dir ||= './';
2847   my $filename = $schema->ddl_filename($type, $version, $dir);
2848   if(-f $filename)
2849   {
2850       # FIXME replace this block when a proper sane sql parser is available
2851       my $file;
2852       open($file, "<$filename")
2853         or $self->throw_exception("Can't open $filename ($!)");
2854       my @rows = <$file>;
2855       close($file);
2856       return join('', @rows);
2857   }
2858
2859   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2860     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2861   }
2862
2863   # sources needs to be a parser arg, but for simplicty allow at top level
2864   # coming in
2865   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2866       if exists $sqltargs->{sources};
2867
2868   my $tr = SQL::Translator->new(
2869     producer => "SQL::Translator::Producer::${type}",
2870     %$sqltargs,
2871     parser => 'SQL::Translator::Parser::DBIx::Class',
2872     data => $schema,
2873   );
2874
2875   return preserve_context {
2876     $tr->translate
2877   } after => sub {
2878     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2879       unless defined $_[0];
2880   };
2881 }
2882
2883 # FIXME deploy() currently does not accurately report sql errors
2884 # Will always return true while errors are warned
2885 sub deploy {
2886   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2887   my $deploy = sub {
2888     my $line = shift;
2889     return if(!$line);
2890     return if($line =~ /^--/);
2891     # next if($line =~ /^DROP/m);
2892     return if($line =~ /^BEGIN TRANSACTION/m);
2893     return if($line =~ /^COMMIT/m);
2894     return if $line =~ /^\s+$/; # skip whitespace only
2895     $self->_query_start($line);
2896     try {
2897       # do a dbh_do cycle here, as we need some error checking in
2898       # place (even though we will ignore errors)
2899       $self->dbh_do (sub { $_[1]->do($line) });
2900     } catch {
2901       carp qq{$_ (running "${line}")};
2902     };
2903     $self->_query_end($line);
2904   };
2905   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2906   if (@statements > 1) {
2907     foreach my $statement (@statements) {
2908       $deploy->( $statement );
2909     }
2910   }
2911   elsif (@statements == 1) {
2912     # split on single line comments and end of statements
2913     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2914       $deploy->( $line );
2915     }
2916   }
2917 }
2918
2919 =head2 datetime_parser
2920
2921 Returns the datetime parser class
2922
2923 =cut
2924
2925 sub datetime_parser {
2926   my $self = shift;
2927   return $self->{datetime_parser} ||= do {
2928     $self->build_datetime_parser(@_);
2929   };
2930 }
2931
2932 =head2 datetime_parser_type
2933
2934 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2935
2936 =head2 build_datetime_parser
2937
2938 See L</datetime_parser>
2939
2940 =cut
2941
2942 sub build_datetime_parser {
2943   my $self = shift;
2944   my $type = $self->datetime_parser_type(@_);
2945   return $type;
2946 }
2947
2948
2949 =head2 is_replicating
2950
2951 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2952 replicate from a master database.  Default is undef, which is the result
2953 returned by databases that don't support replication.
2954
2955 =cut
2956
2957 sub is_replicating {
2958     return;
2959
2960 }
2961
2962 =head2 lag_behind_master
2963
2964 Returns a number that represents a certain amount of lag behind a master db
2965 when a given storage is replicating.  The number is database dependent, but
2966 starts at zero and increases with the amount of lag. Default in undef
2967
2968 =cut
2969
2970 sub lag_behind_master {
2971     return;
2972 }
2973
2974 =head2 relname_to_table_alias
2975
2976 =over 4
2977
2978 =item Arguments: $relname, $join_count
2979
2980 =item Return Value: $alias
2981
2982 =back
2983
2984 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2985 queries.
2986
2987 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2988 way these aliases are named.
2989
2990 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2991 otherwise C<"$relname">.
2992
2993 =cut
2994
2995 sub relname_to_table_alias {
2996   my ($self, $relname, $join_count) = @_;
2997
2998   my $alias = ($join_count && $join_count > 1 ?
2999     join('_', $relname, $join_count) : $relname);
3000
3001   return $alias;
3002 }
3003
3004 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3005 # version and it may be necessary to amend or override it for a specific storage
3006 # if such binds are necessary.
3007 sub _max_column_bytesize {
3008   my ($self, $attr) = @_;
3009
3010   my $max_size;
3011
3012   if ($attr->{sqlt_datatype}) {
3013     my $data_type = lc($attr->{sqlt_datatype});
3014
3015     if ($attr->{sqlt_size}) {
3016
3017       # String/sized-binary types
3018       if ($data_type =~ /^(?:
3019           l? (?:var)? char(?:acter)? (?:\s*varying)?
3020             |
3021           (?:var)? binary (?:\s*varying)?
3022             |
3023           raw
3024         )\b/x
3025       ) {
3026         $max_size = $attr->{sqlt_size};
3027       }
3028       # Other charset/unicode types, assume scale of 4
3029       elsif ($data_type =~ /^(?:
3030           national \s* character (?:\s*varying)?
3031             |
3032           nchar
3033             |
3034           univarchar
3035             |
3036           nvarchar
3037         )\b/x
3038       ) {
3039         $max_size = $attr->{sqlt_size} * 4;
3040       }
3041     }
3042
3043     if (!$max_size and !$self->_is_lob_type($data_type)) {
3044       $max_size = 100 # for all other (numeric?) datatypes
3045     }
3046   }
3047
3048   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3049 }
3050
3051 # Determine if a data_type is some type of BLOB
3052 sub _is_lob_type {
3053   my ($self, $data_type) = @_;
3054   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3055     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3056                                   |varchar|character\s*varying|nvarchar
3057                                   |national\s*character\s*varying))?\z/xi);
3058 }
3059
3060 sub _is_binary_lob_type {
3061   my ($self, $data_type) = @_;
3062   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3063     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3064 }
3065
3066 sub _is_text_lob_type {
3067   my ($self, $data_type) = @_;
3068   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3069     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3070                         |national\s*character\s*varying))\z/xi);
3071 }
3072
3073 # Determine if a data_type is some type of a binary type
3074 sub _is_binary_type {
3075   my ($self, $data_type) = @_;
3076   $data_type && ($self->_is_binary_lob_type($data_type)
3077     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3078 }
3079
3080 1;
3081
3082 =head1 USAGE NOTES
3083
3084 =head2 DBIx::Class and AutoCommit
3085
3086 DBIx::Class can do some wonderful magic with handling exceptions,
3087 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3088 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3089 transaction support.
3090
3091 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3092 in an assumed transaction between commits, and you're telling us you'd
3093 like to manage that manually.  A lot of the magic protections offered by
3094 this module will go away.  We can't protect you from exceptions due to database
3095 disconnects because we don't know anything about how to restart your
3096 transactions.  You're on your own for handling all sorts of exceptional
3097 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3098 be with raw DBI.
3099
3100
3101 =head1 AUTHOR AND CONTRIBUTORS
3102
3103 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3104
3105 =head1 LICENSE
3106
3107 You may distribute this code under the same terms as Perl itself.
3108
3109 =cut