lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Carp::Clan qw/DBIx::Class/;
  14 BEGIN {
  15
  16 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  17
  18 use base qw/SQL::Abstract::Limit/;
  19
  20 sub select {
  21   my ($self, $table, $fields, $where, $order, @rest) = @_;
  22   $table = $self->_quote($table) unless ref($table);
  23   @rest = (-1) unless defined $rest[0];
  24   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  25     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  26   local $self->{having_bind} = [];
  27   my ($sql, @ret) = $self->SUPER::select(
  28     $table, $self->_recurse_fields($fields), $where, $order, @rest
  29   );
  30   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  31 }
  32
  33 sub insert {
  34   my $self = shift;
  35   my $table = shift;
  36   $table = $self->_quote($table) unless ref($table);
  37   $self->SUPER::insert($table, @_);
  38 }
  39
  40 sub update {
  41   my $self = shift;
  42   my $table = shift;
  43   $table = $self->_quote($table) unless ref($table);
  44   $self->SUPER::update($table, @_);
  45 }
  46
  47 sub delete {
  48   my $self = shift;
  49   my $table = shift;
  50   $table = $self->_quote($table) unless ref($table);
  51   $self->SUPER::delete($table, @_);
  52 }
  53
  54 sub _emulate_limit {
  55   my $self = shift;
  56   if ($_[3] == -1) {
  57     return $_[1].$self->_order_by($_[2]);
  58   } else {
  59     return $self->SUPER::_emulate_limit(@_);
  60   }
  61 }
  62
  63 sub _recurse_fields {
  64   my ($self, $fields) = @_;
  65   my $ref = ref $fields;
  66   return $self->_quote($fields) unless $ref;
  67   return $$fields if $ref eq 'SCALAR';
  68
  69   if ($ref eq 'ARRAY') {
  70     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  71   } elsif ($ref eq 'HASH') {
  72     foreach my $func (keys %$fields) {
  73       return $self->_sqlcase($func)
  74         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  75     }
  76   }
  77 }
  78
  79 sub _order_by {
  80   my $self = shift;
  81   my $ret = '';
  82   my @extra;
  83   if (ref $_[0] eq 'HASH') {
  84     if (defined $_[0]->{group_by}) {
  85       $ret = $self->_sqlcase(' group by ')
  86                .$self->_recurse_fields($_[0]->{group_by});
  87     }
  88     if (defined $_[0]->{having}) {
  89       my $frag;
  90       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  91       push(@{$self->{having_bind}}, @extra);
  92       $ret .= $self->_sqlcase(' having ').$frag;
  93     }
  94     if (defined $_[0]->{order_by}) {
  95       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  96     }
  97   } elsif(ref $_[0] eq 'SCALAR') {
  98     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  99   } else {
 100     $ret = $self->SUPER::_order_by(@_);
 101   }
 102   return $ret;
 103 }
 104
 105 sub _order_directions {
 106   my ($self, $order) = @_;
 107   $order = $order->{order_by} if ref $order eq 'HASH';
 108   return $self->SUPER::_order_directions($order);
 109 }
 110
 111 sub _table {
 112   my ($self, $from) = @_;
 113   if (ref $from eq 'ARRAY') {
 114     return $self->_recurse_from(@$from);
 115   } elsif (ref $from eq 'HASH') {
 116     return $self->_make_as($from);
 117   } else {
 118     return $from; # would love to quote here but _table ends up getting called
 119                   # twice during an ->select without a limit clause due to
 120                   # the way S::A::Limit->select works. should maybe consider
 121                   # bypassing this and doing S::A::select($self, ...) in
 122                   # our select method above. meantime, quoting shims have
 123                   # been added to select/insert/update/delete here
 124   }
 125 }
 126
 127 sub _recurse_from {
 128   my ($self, $from, @join) = @_;
 129   my @sqlf;
 130   push(@sqlf, $self->_make_as($from));
 131   foreach my $j (@join) {
 132     my ($to, $on) = @$j;
 133
 134     # check whether a join type exists
 135     my $join_clause = '';
 136     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 137       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 138     } else {
 139       $join_clause = ' JOIN ';
 140     }
 141     push(@sqlf, $join_clause);
 142
 143     if (ref $to eq 'ARRAY') {
 144       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 145     } else {
 146       push(@sqlf, $self->_make_as($to));
 147     }
 148     push(@sqlf, ' ON ', $self->_join_condition($on));
 149   }
 150   return join('', @sqlf);
 151 }
 152
 153 sub _make_as {
 154   my ($self, $from) = @_;
 155   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 156                      reverse each %{$self->_skip_options($from)});
 157 }
 158
 159 sub _skip_options {
 160   my ($self, $hash) = @_;
 161   my $clean_hash = {};
 162   $clean_hash->{$_} = $hash->{$_}
 163     for grep {!/^-/} keys %$hash;
 164   return $clean_hash;
 165 }
 166
 167 sub _join_condition {
 168   my ($self, $cond) = @_;
 169   if (ref $cond eq 'HASH') {
 170     my %j;
 171     for (keys %$cond) {
 172       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 173     };
 174     return $self->_recurse_where(\%j);
 175   } elsif (ref $cond eq 'ARRAY') {
 176     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 177   } else {
 178     die "Can't handle this yet!";
 179   }
 180 }
 181
 182 sub _quote {
 183   my ($self, $label) = @_;
 184   return '' unless defined $label;
 185   return "*" if $label eq '*';
 186   return $label unless $self->{quote_char};
 187   if(ref $self->{quote_char} eq "ARRAY"){
 188     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 189       if !defined $self->{name_sep};
 190     my $sep = $self->{name_sep};
 191     return join($self->{name_sep},
 192         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 193        split(/\Q$sep\E/,$label));
 194   }
 195   return $self->SUPER::_quote($label);
 196 }
 197
 198 sub _RowNum {
 199    my $self = shift;
 200    my $c;
 201    $_[0] =~ s/SELECT (.*?) FROM/
 202      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 203    $self->SUPER::_RowNum(@_);
 204 }
 205
 206 # Accessor for setting limit dialect. This is useful
 207 # for JDBC-bridge among others where the remote SQL-dialect cannot
 208 # be determined by the name of the driver alone.
 209 #
 210 sub limit_dialect {
 211     my $self = shift;
 212     $self->{limit_dialect} = shift if @_;
 213     return $self->{limit_dialect};
 214 }
 215
 216 sub quote_char {
 217     my $self = shift;
 218     $self->{quote_char} = shift if @_;
 219     return $self->{quote_char};
 220 }
 221
 222 sub name_sep {
 223     my $self = shift;
 224     $self->{name_sep} = shift if @_;
 225     return $self->{name_sep};
 226 }
 227
 228 } # End of BEGIN block
 229
 230 use base qw/DBIx::Class/;
 231
 232 __PACKAGE__->load_components(qw/AccessorGroup/);
 233
 234 __PACKAGE__->mk_group_accessors('simple' =>
 235   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugobj
 236      cursor on_connect_do transaction_depth/);
 237
 238 sub new {
 239   my $new = bless({}, ref $_[0] || $_[0]);
 240   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 241   $new->transaction_depth(0);
 242
 243   $new->debugobj(new DBIx::Class::Storage::Statistics());
 244
 245   my $fh;
 246   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 247      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 248     $fh = IO::File->new($1, 'w')
 249       or $new->throw_exception("Cannot open trace file $1");
 250   } else {
 251     $fh = IO::File->new('>&STDERR');
 252   }
 253   $new->debugfh($fh);
 254   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 255   return $new;
 256 }
 257
 258 sub throw_exception {
 259   my ($self, $msg) = @_;
 260   croak($msg);
 261 }
 262
 263 =head1 NAME
 264
 265 DBIx::Class::Storage::DBI - DBI storage handler
 266
 267 =head1 SYNOPSIS
 268
 269 =head1 DESCRIPTION
 270
 271 This class represents the connection to the database
 272
 273 =head1 METHODS
 274
 275 =cut
 276
 277 =head2 connect_info
 278
 279 Connection information arrayref.  Can either be the same arguments
 280 one would pass to DBI->connect, or a code-reference which returns
 281 a connected database handle.  In either case, there is an optional
 282 final element in the arrayref, which can hold a hashref of
 283 connection-specific Storage::DBI options.  These include
 284 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 285 C<quote_char>, and C<name_sep>.  Examples:
 286
 287   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 288   ->connect_info(sub { DBI->connect(...) });
 289   ->connect_info([ 'dbi:Pg:dbname=foo',
 290                    'postgres',
 291                    '',
 292                    { AutoCommit => 0 },
 293                    { quote_char => q{`}, name_sep => q{@} },
 294                  ]);
 295
 296 =head2 on_connect_do
 297
 298 Executes the sql statements given as a listref on every db connect.
 299
 300 =head2 quote_char
 301
 302 Specifies what characters to use to quote table and column names. If
 303 you use this you will want to specify L<name_sep> as well.
 304
 305 quote_char expectes either a single character, in which case is it is placed
 306 on either side of the table/column, or an array of length 2 in which case the
 307 table/column name is placed between the elements.
 308
 309 For example under MySQL you'd use C<quote_char('`')>, and user SQL Server you'd
 310 use C<quote_char(qw/[ ]/)>.
 311
 312 =head2 name_sep
 313
 314 This only needs to be used in conjunction with L<quote_char>, and is used to
 315 specify the charecter that seperates elements (schemas, tables, columns) from
 316 each other. In most cases this is simply a C<.>.
 317
 318 =head2 debug
 319
 320 Causes SQL trace information to be emitted on the C<debugobj> object.
 321 (or C<STDERR> if C<debugobj> has not specifically been set).
 322
 323 =head2 debugfh
 324
 325 Set or retrieve the filehandle used for trace/debug output.  This should be
 326 an IO::Handle compatible ojbect (only the C<print> method is used.  Initially
 327 set to be STDERR - although see information on the
 328 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 329
 330 =cut
 331
 332 sub debugfh {
 333     my $self = shift;
 334
 335     if ($self->debugobj->can('debugfh')) {
 336         return $self->debugobj->debugfh(@_);
 337     }
 338 }
 339
 340 =head2 debugobj
 341
 342 Sets or retrieves the object used for metric collection. Defaults to an instance
 343 of L<DBIx::Class::Storage::Statistics> that is campatible with the original
 344 method of using a coderef as a callback.  See the aforementioned Statistics
 345 class for more information.
 346
 347 =head2 debugcb
 348
 349 Sets a callback to be executed each time a statement is run; takes a sub
 350 reference.  Callback is executed as $sub->($op, $info) where $op is
 351 SELECT/INSERT/UPDATE/DELETE and $info is what would normally be printed.
 352
 353 See L<debugobj> for a better way.
 354
 355 =cut
 356
 357 sub debugcb {
 358     my $self = shift;
 359
 360     if ($self->debugobj->can('callback')) {
 361         return $self->debugobj->callback(@_);
 362     }
 363 }
 364
 365 sub disconnect {
 366   my ($self) = @_;
 367
 368   if( $self->connected ) {
 369     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 370     $self->_dbh->disconnect;
 371     $self->_dbh(undef);
 372   }
 373 }
 374
 375 sub connected {
 376   my ($self) = @_;
 377
 378   if(my $dbh = $self->_dbh) {
 379       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 380           $self->_sql_maker(undef);
 381           return $self->_dbh(undef);
 382       }
 383       elsif($self->_conn_pid != $$) {
 384           $self->_dbh->{InactiveDestroy} = 1;
 385           $self->_sql_maker(undef);
 386           return $self->_dbh(undef)
 387       }
 388       return ($dbh->FETCH('Active') && $dbh->ping);
 389   }
 390
 391   return 0;
 392 }
 393
 394 sub ensure_connected {
 395   my ($self) = @_;
 396
 397   unless ($self->connected) {
 398     $self->_populate_dbh;
 399   }
 400 }
 401
 402 =head2 dbh
 403
 404 Returns the dbh - a data base handle of class L<DBI>.
 405
 406 =cut
 407
 408 sub dbh {
 409   my ($self) = @_;
 410
 411   $self->ensure_connected;
 412   return $self->_dbh;
 413 }
 414
 415 sub _sql_maker_args {
 416     my ($self) = @_;
 417
 418     return ( limit_dialect => $self->dbh );
 419 }
 420
 421 sub sql_maker {
 422   my ($self) = @_;
 423   unless ($self->_sql_maker) {
 424     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 425   }
 426   return $self->_sql_maker;
 427 }
 428
 429 sub connect_info {
 430     my ($self, $info_arg) = @_;
 431
 432     if($info_arg) {
 433         my $info = [ @$info_arg ]; # copy because we can alter it
 434         my $last_info = $info->[-1];
 435         if(ref $last_info eq 'HASH') {
 436             my $used;
 437             if(my $on_connect_do = $last_info->{on_connect_do}) {
 438                $used = 1;
 439                $self->on_connect_do($on_connect_do);
 440             }
 441             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 442                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 443                     $used = 1;
 444                     $self->sql_maker->$sql_maker_opt($opt_val);
 445                 }
 446             }
 447
 448             # remove our options hashref if it was there, to avoid confusing
 449             #   DBI in the case the user didn't use all 4 DBI options, as in:
 450             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 451             pop(@$info) if $used;
 452         }
 453
 454         $self->_connect_info($info);
 455     }
 456
 457     $self->_connect_info;
 458 }
 459
 460 sub _populate_dbh {
 461   my ($self) = @_;
 462   my @info = @{$self->_connect_info || []};
 463   $self->_dbh($self->_connect(@info));
 464   my $driver = $self->_dbh->{Driver}->{Name};
 465   eval "require DBIx::Class::Storage::DBI::${driver}";
 466   unless ($@) {
 467     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 468     $self->_rebless() if $self->can('_rebless');
 469   }
 470   # if on-connect sql statements are given execute them
 471   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 472     $self->debugobj->query_start($sql_statement) if $self->debug();
 473     $self->_dbh->do($sql_statement);
 474     $self->debugobj->query_end($sql_statement) if $self->debug();
 475   }
 476
 477   $self->_conn_pid($$);
 478   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 479 }
 480
 481 sub _connect {
 482   my ($self, @info) = @_;
 483
 484   $self->throw_exception("You failed to provide any connection info")
 485       if !@info;
 486
 487   my ($old_connect_via, $dbh);
 488
 489   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 490       $old_connect_via = $DBI::connect_via;
 491       $DBI::connect_via = 'connect';
 492   }
 493
 494   eval {
 495     if(ref $info[0] eq 'CODE') {
 496         $dbh = &{$info[0]};
 497     }
 498     else {
 499         $dbh = DBI->connect(@info);
 500     }
 501   };
 502
 503   $DBI::connect_via = $old_connect_via if $old_connect_via;
 504
 505   if (!$dbh || $@) {
 506     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 507   }
 508
 509   $dbh;
 510 }
 511
 512 =head2 txn_begin
 513
 514 Calls begin_work on the current dbh.
 515
 516 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 517 an entire code block to be executed transactionally.
 518
 519 =cut
 520
 521 sub txn_begin {
 522   my $self = shift;
 523   if ($self->{transaction_depth}++ == 0) {
 524     my $dbh = $self->dbh;
 525     if ($dbh->{AutoCommit}) {
 526       $self->debugobj->txn_begin()
 527         if ($self->debug);
 528       $dbh->begin_work;
 529     }
 530   }
 531 }
 532
 533 =head2 txn_commit
 534
 535 Issues a commit against the current dbh.
 536
 537 =cut
 538
 539 sub txn_commit {
 540   my $self = shift;
 541   my $dbh = $self->dbh;
 542   if ($self->{transaction_depth} == 0) {
 543     unless ($dbh->{AutoCommit}) {
 544       $self->debugobj->txn_commit()
 545         if ($self->debug);
 546       $dbh->commit;
 547     }
 548   }
 549   else {
 550     if (--$self->{transaction_depth} == 0) {
 551       $self->debugobj->txn_commit()
 552         if ($self->debug);
 553       $dbh->commit;
 554     }
 555   }
 556 }
 557
 558 =head2 txn_rollback
 559
 560 Issues a rollback against the current dbh. A nested rollback will
 561 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 562 which allows the rollback to propagate to the outermost transaction.
 563
 564 =cut
 565
 566 sub txn_rollback {
 567   my $self = shift;
 568
 569   eval {
 570     my $dbh = $self->dbh;
 571     if ($self->{transaction_depth} == 0) {
 572       unless ($dbh->{AutoCommit}) {
 573         $self->debugobj->txn_rollback()
 574           if ($self->debug);
 575         $dbh->rollback;
 576       }
 577     }
 578     else {
 579       if (--$self->{transaction_depth} == 0) {
 580         $self->debugobj->txn_rollback()
 581           if ($self->debug);
 582         $dbh->rollback;
 583       }
 584       else {
 585         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 586       }
 587     }
 588   };
 589
 590   if ($@) {
 591     my $error = $@;
 592     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 593     $error =~ /$exception_class/ and $self->throw_exception($error);
 594     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 595     $self->throw_exception($error);          # resets the transaction depth
 596   }
 597 }
 598
 599 sub _execute {
 600   my ($self, $op, $extra_bind, $ident, @args) = @_;
 601   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 602   unshift(@bind, @$extra_bind) if $extra_bind;
 603   if ($self->debug) {
 604       my @debug_bind = map { defined $_ ? qq{'$_'} : q{'NULL'} } @bind;
 605       $self->debugobj->query_start($sql, @debug_bind);
 606   }
 607   my $sth = eval { $self->sth($sql,$op) };
 608
 609   if (!$sth || $@) {
 610     $self->throw_exception(
 611       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 612     );
 613   }
 614   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 615   my $rv;
 616   if ($sth) {
 617     my $time = time();
 618     $rv = eval { $sth->execute(@bind) };
 619
 620     if ($@ || !$rv) {
 621       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 622     }
 623   } else {
 624     $self->throw_exception("'$sql' did not generate a statement.");
 625   }
 626   if ($self->debug) {
 627       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 628       $self->debugobj->query_end($sql, @debug_bind);
 629   }
 630   return (wantarray ? ($rv, $sth, @bind) : $rv);
 631 }
 632
 633 sub insert {
 634   my ($self, $ident, $to_insert) = @_;
 635   $self->throw_exception(
 636     "Couldn't insert ".join(', ',
 637       map "$_ => $to_insert->{$_}", keys %$to_insert
 638     )." into ${ident}"
 639   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 640   return $to_insert;
 641 }
 642
 643 sub update {
 644   return shift->_execute('update' => [], @_);
 645 }
 646
 647 sub delete {
 648   return shift->_execute('delete' => [], @_);
 649 }
 650
 651 sub _select {
 652   my ($self, $ident, $select, $condition, $attrs) = @_;
 653   my $order = $attrs->{order_by};
 654   if (ref $condition eq 'SCALAR') {
 655     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 656   }
 657   if (exists $attrs->{group_by} || $attrs->{having}) {
 658     $order = {
 659       group_by => $attrs->{group_by},
 660       having => $attrs->{having},
 661       ($order ? (order_by => $order) : ())
 662     };
 663   }
 664   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 665   if ($attrs->{software_limit} ||
 666       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 667         $attrs->{software_limit} = 1;
 668   } else {
 669     $self->throw_exception("rows attribute must be positive if present")
 670       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
 671     push @args, $attrs->{rows}, $attrs->{offset};
 672   }
 673   return $self->_execute(@args);
 674 }
 675
 676 sub select {
 677   my $self = shift;
 678   my ($ident, $select, $condition, $attrs) = @_;
 679   return $self->cursor->new($self, \@_, $attrs);
 680 }
 681
 682 # Need to call finish() to work round broken DBDs
 683
 684 sub select_single {
 685   my $self = shift;
 686   my ($rv, $sth, @bind) = $self->_select(@_);
 687   my @row = $sth->fetchrow_array;
 688   $sth->finish();
 689   return @row;
 690 }
 691
 692 sub sth {
 693   my ($self, $sql) = @_;
 694   # 3 is the if_active parameter which avoids active sth re-use
 695   return $self->dbh->prepare_cached($sql, {}, 3);
 696 }
 697
 698 =head2 columns_info_for
 699
 700 Returns database type info for a given table columns.
 701
 702 =cut
 703
 704 sub columns_info_for {
 705   my ($self, $table) = @_;
 706
 707   my $dbh = $self->dbh;
 708
 709   if ($dbh->can('column_info')) {
 710     my %result;
 711     my $old_raise_err = $dbh->{RaiseError};
 712     my $old_print_err = $dbh->{PrintError};
 713     $dbh->{RaiseError} = 1;
 714     $dbh->{PrintError} = 0;
 715     eval {
 716       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
 717       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
 718       $sth->execute();
 719       while ( my $info = $sth->fetchrow_hashref() ){
 720         my %column_info;
 721         $column_info{data_type}   = $info->{TYPE_NAME};
 722         $column_info{size}      = $info->{COLUMN_SIZE};
 723         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 724         $column_info{default_value} = $info->{COLUMN_DEF};
 725         my $col_name = $info->{COLUMN_NAME};
 726         $col_name =~ s/^\"(.*)\"$/$1/;
 727
 728         $result{$col_name} = \%column_info;
 729       }
 730     };
 731     $dbh->{RaiseError} = $old_raise_err;
 732     $dbh->{PrintError} = $old_print_err;
 733     return \%result if !$@;
 734   }
 735
 736   my %result;
 737   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 738   $sth->execute;
 739   my @columns = @{$sth->{NAME_lc}};
 740   for my $i ( 0 .. $#columns ){
 741     my %column_info;
 742     my $type_num = $sth->{TYPE}->[$i];
 743     my $type_name;
 744     if(defined $type_num && $dbh->can('type_info')) {
 745       my $type_info = $dbh->type_info($type_num);
 746       $type_name = $type_info->{TYPE_NAME} if $type_info;
 747     }
 748     $column_info{data_type} = $type_name ? $type_name : $type_num;
 749     $column_info{size} = $sth->{PRECISION}->[$i];
 750     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 751
 752     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 753       $column_info{data_type} = $1;
 754       $column_info{size}    = $2;
 755     }
 756
 757     $result{$columns[$i]} = \%column_info;
 758   }
 759
 760   return \%result;
 761 }
 762
 763 sub last_insert_id {
 764   my ($self, $row) = @_;
 765
 766   return $self->dbh->func('last_insert_rowid');
 767
 768 }
 769
 770 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 771
 772 sub create_ddl_dir
 773 {
 774   my ($self, $schema, $databases, $version, $dir, $sqltargs) = @_;
 775
 776   if(!$dir || !-d $dir)
 777   {
 778     warn "No directory given, using ./\n";
 779     $dir = "./";
 780   }
 781   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
 782   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
 783   $version ||= $schema->VERSION || '1.x';
 784
 785   eval "use SQL::Translator";
 786   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 787
 788   my $sqlt = SQL::Translator->new({
 789 #      debug => 1,
 790       add_drop_table => 1,
 791   });
 792   foreach my $db (@$databases)
 793   {
 794     $sqlt->reset();
 795     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 796 #    $sqlt->parser_args({'DBIx::Class' => $schema);
 797     $sqlt->data($schema);
 798     $sqlt->producer($db);
 799
 800     my $file;
 801     my $filename = $schema->ddl_filename($db, $dir, $version);
 802     if(-e $filename)
 803     {
 804       $self->throw_exception("$filename already exists, skipping $db");
 805       next;
 806     }
 807     open($file, ">$filename")
 808       or $self->throw_exception("Can't open $filename for writing ($!)");
 809     my $output = $sqlt->translate;
 810 #use Data::Dumper;
 811 #    print join(":", keys %{$schema->source_registrations});
 812 #    print Dumper($sqlt->schema);
 813     if(!$output)
 814     {
 815       $self->throw_exception("Failed to translate to $db. (" . $sqlt->error . ")");
 816       next;
 817     }
 818     print $file $output;
 819     close($file);
 820   }
 821
 822 }
 823
 824 sub deployment_statements {
 825   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
 826   $type ||= $self->sqlt_type;
 827   $version ||= $schema->VERSION || '1.x';
 828   $dir ||= './';
 829   eval "use SQL::Translator";
 830   if(!$@)
 831   {
 832     eval "use SQL::Translator::Parser::DBIx::Class;";
 833     $self->throw_exception($@) if $@;
 834     eval "use SQL::Translator::Producer::${type};";
 835     $self->throw_exception($@) if $@;
 836     my $tr = SQL::Translator->new(%$sqltargs);
 837     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 838     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 839   }
 840
 841   my $filename = $schema->ddl_filename($type, $dir, $version);
 842   if(!-f $filename)
 843   {
 844 #      $schema->create_ddl_dir([ $type ], $version, $dir, $sqltargs);
 845       $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
 846       return;
 847   }
 848   my $file;
 849   open($file, "<$filename")
 850       or $self->throw_exception("Can't open $filename ($!)");
 851   my @rows = <$file>;
 852   close($file);
 853
 854   return join('', @rows);
 855
 856 }
 857
 858 sub deploy {
 859   my ($self, $schema, $type, $sqltargs) = @_;
 860   foreach my $statement ( $self->deployment_statements($schema, $type, undef, undef, $sqltargs) ) {
 861     for ( split(";\n", $statement)) {
 862       next if($_ =~ /^--/);
 863       next if(!$_);
 864 #      next if($_ =~ /^DROP/m);
 865       next if($_ =~ /^BEGIN TRANSACTION/m);
 866       next if($_ =~ /^COMMIT/m);
 867       $self->debugobj->query_begin($_) if $self->debug;
 868       $self->dbh->do($_) or warn "SQL was:\n $_";
 869       $self->debugobj->query_end($_) if $self->debug;
 870     }
 871   }
 872 }
 873
 874 sub datetime_parser {
 875   my $self = shift;
 876   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
 877 }
 878
 879 sub datetime_parser_type { "DateTime::Format::MySQL"; }
 880
 881 sub build_datetime_parser {
 882   my $self = shift;
 883   my $type = $self->datetime_parser_type(@_);
 884   eval "use ${type}";
 885   $self->throw_exception("Couldn't load ${type}: $@") if $@;
 886   return $type;
 887 }
 888
 889 sub DESTROY { shift->disconnect }
 890
 891 1;
 892
 893 =head1 ENVIRONMENT VARIABLES
 894
 895 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 896
 897 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 898 is produced (as when the L<debug> method is set).
 899
 900 If the value is of the form C<1=/path/name> then the trace output is
 901 written to the file C</path/name>.
 902
 903 This environment variable is checked when the storage object is first
 904 created (when you call connect on your schema).  So, run-time changes
 905 to this environment variable will not take effect unless you also
 906 re-connect on your schema.
 907
 908 =head1 AUTHORS
 909
 910 Matt S. Trout <mst@shadowcatsystems.co.uk>
 911
 912 Andy Grundman <andy@hybridized.org>
 913
 914 =head1 LICENSE
 915
 916 You may distribute this code under the same terms as Perl itself.
 917
 918 =cut
 919