lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. This is a purely DRY optimization
  83 #
  84 # get_(use)_dbms_capability need to be called on the correct Storage
  85 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  86 # _determine_supports_X which obv. needs a correct driver as well
  87 my @rdbms_specific_methods = qw/
  88   sqlt_type
  89   deployment_statements
  90
  91   sql_maker
  92   cursor_class
  93
  94   build_datetime_parser
  95   datetime_parser_type
  96
  97   txn_begin
  98
  99   insert
 100   insert_bulk
 101   update
 102   delete
 103   select
 104   select_single
 105
 106   with_deferred_fk_checks
 107
 108   get_use_dbms_capability
 109   get_dbms_capability
 110
 111   _server_info
 112   _get_server_version
 113 /;
 114
 115 for my $meth (@rdbms_specific_methods) {
 116
 117   my $orig = __PACKAGE__->can ($meth)
 118     or die "$meth is not a ::Storage::DBI method!";
 119
 120   no strict qw/refs/;
 121   no warnings qw/redefine/;
 122   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 123     if (
 124       # only fire when invoked on an instance, a valid class-based invocation
 125       # would e.g. be setting a default for an inherited accessor
 126       ref $_[0]
 127         and
 128       ! $_[0]->{_driver_determined}
 129         and
 130       ! $_[0]->{_in_determine_driver}
 131         and
 132       ($_[0]->_dbi_connect_info||[])->[0]
 133     ) {
 134       $_[0]->_determine_driver;
 135
 136       # This for some reason crashes and burns on perl 5.8.1
 137       # IFF the method ends up throwing an exception
 138       #goto $_[0]->can ($meth);
 139
 140       my $cref = $_[0]->can ($meth);
 141       goto $cref;
 142     }
 143
 144     goto $orig;
 145   };
 146 }
 147
 148 =head1 NAME
 149
 150 DBIx::Class::Storage::DBI - DBI storage handler
 151
 152 =head1 SYNOPSIS
 153
 154   my $schema = MySchema->connect('dbi:SQLite:my.db');
 155
 156   $schema->storage->debug(1);
 157
 158   my @stuff = $schema->storage->dbh_do(
 159     sub {
 160       my ($storage, $dbh, @args) = @_;
 161       $dbh->do("DROP TABLE authors");
 162     },
 163     @column_list
 164   );
 165
 166   $schema->resultset('Book')->search({
 167      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 168   });
 169
 170 =head1 DESCRIPTION
 171
 172 This class represents the connection to an RDBMS via L<DBI>.  See
 173 L<DBIx::Class::Storage> for general information.  This pod only
 174 documents DBI-specific methods and behaviors.
 175
 176 =head1 METHODS
 177
 178 =cut
 179
 180 sub new {
 181   my $new = shift->next::method(@_);
 182
 183   $new->_sql_maker_opts({});
 184   $new->_dbh_details({});
 185   $new->{_in_do_block} = 0;
 186
 187   # read below to see what this does
 188   $new->_arm_global_destructor;
 189
 190   $new;
 191 }
 192
 193 # This is hack to work around perl shooting stuff in random
 194 # order on exit(). If we do not walk the remaining storage
 195 # objects in an END block, there is a *small but real* chance
 196 # of a fork()ed child to kill the parent's shared DBI handle,
 197 # *before perl reaches the DESTROY in this package*
 198 # Yes, it is ugly and effective.
 199 # Additionally this registry is used by the CLONE method to
 200 # make sure no handles are shared between threads
 201 {
 202   my %seek_and_destroy;
 203
 204   sub _arm_global_destructor {
 205     weaken (
 206       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 207     );
 208   }
 209
 210   END {
 211     local $?; # just in case the DBI destructor changes it somehow
 212
 213     # destroy just the object if not native to this process
 214     $_->_verify_pid for (grep
 215       { defined $_ }
 216       values %seek_and_destroy
 217     );
 218   }
 219
 220   sub CLONE {
 221     # As per DBI's recommendation, DBIC disconnects all handles as
 222     # soon as possible (DBIC will reconnect only on demand from within
 223     # the thread)
 224     my @instances = grep { defined $_ } values %seek_and_destroy;
 225     %seek_and_destroy = ();
 226
 227     for (@instances) {
 228       $_->_dbh(undef);
 229
 230       $_->transaction_depth(0);
 231       $_->savepoints([]);
 232
 233       # properly renumber existing refs
 234       $_->_arm_global_destructor
 235     }
 236   }
 237 }
 238
 239 sub DESTROY {
 240   my $self = shift;
 241
 242   # some databases spew warnings on implicit disconnect
 243   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 244   local $SIG{__WARN__} = sub {};
 245   $self->_dbh(undef);
 246
 247   # this op is necessary, since the very last perl runtime statement
 248   # triggers a global destruction shootout, and the $SIG localization
 249   # may very well be destroyed before perl actually gets to do the
 250   # $dbh undef
 251   1;
 252 }
 253
 254 # handle pid changes correctly - do not destroy parent's connection
 255 sub _verify_pid {
 256   my $self = shift;
 257
 258   my $pid = $self->_conn_pid;
 259   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 260     $dbh->{InactiveDestroy} = 1;
 261     $self->_dbh(undef);
 262     $self->transaction_depth(0);
 263     $self->savepoints([]);
 264   }
 265
 266   return;
 267 }
 268
 269 =head2 connect_info
 270
 271 This method is normally called by L<DBIx::Class::Schema/connection>, which
 272 encapsulates its argument list in an arrayref before passing them here.
 273
 274 The argument list may contain:
 275
 276 =over
 277
 278 =item *
 279
 280 The same 4-element argument set one would normally pass to
 281 L<DBI/connect>, optionally followed by
 282 L<extra attributes|/DBIx::Class specific connection attributes>
 283 recognized by DBIx::Class:
 284
 285   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 286
 287 =item *
 288
 289 A single code reference which returns a connected
 290 L<DBI database handle|DBI/connect> optionally followed by
 291 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 292 by DBIx::Class:
 293
 294   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 295
 296 =item *
 297
 298 A single hashref with all the attributes and the dsn/user/password
 299 mixed together:
 300
 301   $connect_info_args = [{
 302     dsn => $dsn,
 303     user => $user,
 304     password => $pass,
 305     %dbi_attributes,
 306     %extra_attributes,
 307   }];
 308
 309   $connect_info_args = [{
 310     dbh_maker => sub { DBI->connect (...) },
 311     %dbi_attributes,
 312     %extra_attributes,
 313   }];
 314
 315 This is particularly useful for L<Catalyst> based applications, allowing the
 316 following config (L<Config::General> style):
 317
 318   <Model::DB>
 319     schema_class   App::DB
 320     <connect_info>
 321       dsn          dbi:mysql:database=test
 322       user         testuser
 323       password     TestPass
 324       AutoCommit   1
 325     </connect_info>
 326   </Model::DB>
 327
 328 The C<dsn>/C<user>/C<password> combination can be substituted by the
 329 C<dbh_maker> key whose value is a coderef that returns a connected
 330 L<DBI database handle|DBI/connect>
 331
 332 =back
 333
 334 Please note that the L<DBI> docs recommend that you always explicitly
 335 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 336 recommends that it be set to I<1>, and that you perform transactions
 337 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 338 to I<1> if you do not do explicitly set it to zero.  This is the default
 339 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 340
 341 =head3 DBIx::Class specific connection attributes
 342
 343 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 344 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 345 the following connection options. These options can be mixed in with your other
 346 L<DBI> connection attributes, or placed in a separate hashref
 347 (C<\%extra_attributes>) as shown above.
 348
 349 Every time C<connect_info> is invoked, any previous settings for
 350 these options will be cleared before setting the new ones, regardless of
 351 whether any options are specified in the new C<connect_info>.
 352
 353
 354 =over
 355
 356 =item on_connect_do
 357
 358 Specifies things to do immediately after connecting or re-connecting to
 359 the database.  Its value may contain:
 360
 361 =over
 362
 363 =item a scalar
 364
 365 This contains one SQL statement to execute.
 366
 367 =item an array reference
 368
 369 This contains SQL statements to execute in order.  Each element contains
 370 a string or a code reference that returns a string.
 371
 372 =item a code reference
 373
 374 This contains some code to execute.  Unlike code references within an
 375 array reference, its return value is ignored.
 376
 377 =back
 378
 379 =item on_disconnect_do
 380
 381 Takes arguments in the same form as L</on_connect_do> and executes them
 382 immediately before disconnecting from the database.
 383
 384 Note, this only runs if you explicitly call L</disconnect> on the
 385 storage object.
 386
 387 =item on_connect_call
 388
 389 A more generalized form of L</on_connect_do> that calls the specified
 390 C<connect_call_METHOD> methods in your storage driver.
 391
 392   on_connect_do => 'select 1'
 393
 394 is equivalent to:
 395
 396   on_connect_call => [ [ do_sql => 'select 1' ] ]
 397
 398 Its values may contain:
 399
 400 =over
 401
 402 =item a scalar
 403
 404 Will call the C<connect_call_METHOD> method.
 405
 406 =item a code reference
 407
 408 Will execute C<< $code->($storage) >>
 409
 410 =item an array reference
 411
 412 Each value can be a method name or code reference.
 413
 414 =item an array of arrays
 415
 416 For each array, the first item is taken to be the C<connect_call_> method name
 417 or code reference, and the rest are parameters to it.
 418
 419 =back
 420
 421 Some predefined storage methods you may use:
 422
 423 =over
 424
 425 =item do_sql
 426
 427 Executes a SQL string or a code reference that returns a SQL string. This is
 428 what L</on_connect_do> and L</on_disconnect_do> use.
 429
 430 It can take:
 431
 432 =over
 433
 434 =item a scalar
 435
 436 Will execute the scalar as SQL.
 437
 438 =item an arrayref
 439
 440 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 441 attributes hashref and bind values.
 442
 443 =item a code reference
 444
 445 Will execute C<< $code->($storage) >> and execute the return array refs as
 446 above.
 447
 448 =back
 449
 450 =item datetime_setup
 451
 452 Execute any statements necessary to initialize the database session to return
 453 and accept datetime/timestamp values used with
 454 L<DBIx::Class::InflateColumn::DateTime>.
 455
 456 Only necessary for some databases, see your specific storage driver for
 457 implementation details.
 458
 459 =back
 460
 461 =item on_disconnect_call
 462
 463 Takes arguments in the same form as L</on_connect_call> and executes them
 464 immediately before disconnecting from the database.
 465
 466 Calls the C<disconnect_call_METHOD> methods as opposed to the
 467 C<connect_call_METHOD> methods called by L</on_connect_call>.
 468
 469 Note, this only runs if you explicitly call L</disconnect> on the
 470 storage object.
 471
 472 =item disable_sth_caching
 473
 474 If set to a true value, this option will disable the caching of
 475 statement handles via L<DBI/prepare_cached>.
 476
 477 =item limit_dialect
 478
 479 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 480 default L</sql_limit_dialect> setting of the storage (if any). For a list
 481 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 482
 483 =item quote_names
 484
 485 When true automatically sets L</quote_char> and L</name_sep> to the characters
 486 appropriate for your particular RDBMS. This option is preferred over specifying
 487 L</quote_char> directly.
 488
 489 =item quote_char
 490
 491 Specifies what characters to use to quote table and column names.
 492
 493 C<quote_char> expects either a single character, in which case is it
 494 is placed on either side of the table/column name, or an arrayref of length
 495 2 in which case the table/column name is placed between the elements.
 496
 497 For example under MySQL you should use C<< quote_char => '`' >>, and for
 498 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 499
 500 =item name_sep
 501
 502 This parameter is only useful in conjunction with C<quote_char>, and is used to
 503 specify the character that separates elements (schemas, tables, columns) from
 504 each other. If unspecified it defaults to the most commonly used C<.>.
 505
 506 =item unsafe
 507
 508 This Storage driver normally installs its own C<HandleError>, sets
 509 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 510 all database handles, including those supplied by a coderef.  It does this
 511 so that it can have consistent and useful error behavior.
 512
 513 If you set this option to a true value, Storage will not do its usual
 514 modifications to the database handle's attributes, and instead relies on
 515 the settings in your connect_info DBI options (or the values you set in
 516 your connection coderef, in the case that you are connecting via coderef).
 517
 518 Note that your custom settings can cause Storage to malfunction,
 519 especially if you set a C<HandleError> handler that suppresses exceptions
 520 and/or disable C<RaiseError>.
 521
 522 =item auto_savepoint
 523
 524 If this option is true, L<DBIx::Class> will use savepoints when nesting
 525 transactions, making it possible to recover from failure in the inner
 526 transaction without having to abort all outer transactions.
 527
 528 =item cursor_class
 529
 530 Use this argument to supply a cursor class other than the default
 531 L<DBIx::Class::Storage::DBI::Cursor>.
 532
 533 =back
 534
 535 Some real-life examples of arguments to L</connect_info> and
 536 L<DBIx::Class::Schema/connect>
 537
 538   # Simple SQLite connection
 539   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 540
 541   # Connect via subref
 542   ->connect_info([ sub { DBI->connect(...) } ]);
 543
 544   # Connect via subref in hashref
 545   ->connect_info([{
 546     dbh_maker => sub { DBI->connect(...) },
 547     on_connect_do => 'alter session ...',
 548   }]);
 549
 550   # A bit more complicated
 551   ->connect_info(
 552     [
 553       'dbi:Pg:dbname=foo',
 554       'postgres',
 555       'my_pg_password',
 556       { AutoCommit => 1 },
 557       { quote_char => q{"} },
 558     ]
 559   );
 560
 561   # Equivalent to the previous example
 562   ->connect_info(
 563     [
 564       'dbi:Pg:dbname=foo',
 565       'postgres',
 566       'my_pg_password',
 567       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 568     ]
 569   );
 570
 571   # Same, but with hashref as argument
 572   # See parse_connect_info for explanation
 573   ->connect_info(
 574     [{
 575       dsn         => 'dbi:Pg:dbname=foo',
 576       user        => 'postgres',
 577       password    => 'my_pg_password',
 578       AutoCommit  => 1,
 579       quote_char  => q{"},
 580       name_sep    => q{.},
 581     }]
 582   );
 583
 584   # Subref + DBIx::Class-specific connection options
 585   ->connect_info(
 586     [
 587       sub { DBI->connect(...) },
 588       {
 589           quote_char => q{`},
 590           name_sep => q{@},
 591           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 592           disable_sth_caching => 1,
 593       },
 594     ]
 595   );
 596
 597
 598
 599 =cut
 600
 601 sub connect_info {
 602   my ($self, $info) = @_;
 603
 604   return $self->_connect_info if !$info;
 605
 606   $self->_connect_info($info); # copy for _connect_info
 607
 608   $info = $self->_normalize_connect_info($info)
 609     if ref $info eq 'ARRAY';
 610
 611   for my $storage_opt (keys %{ $info->{storage_options} }) {
 612     my $value = $info->{storage_options}{$storage_opt};
 613
 614     $self->$storage_opt($value);
 615   }
 616
 617   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 618   #  the new set of options
 619   $self->_sql_maker(undef);
 620   $self->_sql_maker_opts({});
 621
 622   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 623     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 624
 625     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 626   }
 627
 628   my %attrs = (
 629     %{ $self->_default_dbi_connect_attributes || {} },
 630     %{ $info->{attributes} || {} },
 631   );
 632
 633   my @args = @{ $info->{arguments} };
 634
 635   if (keys %attrs and ref $args[0] ne 'CODE') {
 636     carp_unique (
 637         'You provided explicit AutoCommit => 0 in your connection_info. '
 638       . 'This is almost universally a bad idea (see the footnotes of '
 639       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 640       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 641       . 'this warning.'
 642     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 643
 644     push @args, \%attrs if keys %attrs;
 645   }
 646   $self->_dbi_connect_info(\@args);
 647
 648   # FIXME - dirty:
 649   # save attributes them in a separate accessor so they are always
 650   # introspectable, even in case of a CODE $dbhmaker
 651   $self->_dbic_connect_attributes (\%attrs);
 652
 653   return $self->_connect_info;
 654 }
 655
 656 sub _normalize_connect_info {
 657   my ($self, $info_arg) = @_;
 658   my %info;
 659
 660   my @args = @$info_arg;  # take a shallow copy for further mutilation
 661
 662   # combine/pre-parse arguments depending on invocation style
 663
 664   my %attrs;
 665   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 666     %attrs = %{ $args[1] || {} };
 667     @args = $args[0];
 668   }
 669   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 670     %attrs = %{$args[0]};
 671     @args = ();
 672     if (my $code = delete $attrs{dbh_maker}) {
 673       @args = $code;
 674
 675       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 676       if (@ignored) {
 677         carp sprintf (
 678             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 679           . "to the result of 'dbh_maker'",
 680
 681           join (', ', map { "'$_'" } (@ignored) ),
 682         );
 683       }
 684     }
 685     else {
 686       @args = delete @attrs{qw/dsn user password/};
 687     }
 688   }
 689   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 690     %attrs = (
 691       % { $args[3] || {} },
 692       % { $args[4] || {} },
 693     );
 694     @args = @args[0,1,2];
 695   }
 696
 697   $info{arguments} = \@args;
 698
 699   my @storage_opts = grep exists $attrs{$_},
 700     @storage_options, 'cursor_class';
 701
 702   @{ $info{storage_options} }{@storage_opts} =
 703     delete @attrs{@storage_opts} if @storage_opts;
 704
 705   my @sql_maker_opts = grep exists $attrs{$_},
 706     qw/limit_dialect quote_char name_sep quote_names/;
 707
 708   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 709     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 710
 711   $info{attributes} = \%attrs if %attrs;
 712
 713   return \%info;
 714 }
 715
 716 sub _default_dbi_connect_attributes () {
 717   +{
 718     AutoCommit => 1,
 719     PrintError => 0,
 720     RaiseError => 1,
 721     ShowErrorStatement => 1,
 722   };
 723 }
 724
 725 =head2 on_connect_do
 726
 727 This method is deprecated in favour of setting via L</connect_info>.
 728
 729 =cut
 730
 731 =head2 on_disconnect_do
 732
 733 This method is deprecated in favour of setting via L</connect_info>.
 734
 735 =cut
 736
 737 sub _parse_connect_do {
 738   my ($self, $type) = @_;
 739
 740   my $val = $self->$type;
 741   return () if not defined $val;
 742
 743   my @res;
 744
 745   if (not ref($val)) {
 746     push @res, [ 'do_sql', $val ];
 747   } elsif (ref($val) eq 'CODE') {
 748     push @res, $val;
 749   } elsif (ref($val) eq 'ARRAY') {
 750     push @res, map { [ 'do_sql', $_ ] } @$val;
 751   } else {
 752     $self->throw_exception("Invalid type for $type: ".ref($val));
 753   }
 754
 755   return \@res;
 756 }
 757
 758 =head2 dbh_do
 759
 760 Arguments: ($subref | $method_name), @extra_coderef_args?
 761
 762 Execute the given $subref or $method_name using the new exception-based
 763 connection management.
 764
 765 The first two arguments will be the storage object that C<dbh_do> was called
 766 on and a database handle to use.  Any additional arguments will be passed
 767 verbatim to the called subref as arguments 2 and onwards.
 768
 769 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 770 exception handling and reconnection (or failover in future subclasses).
 771
 772 Your subref should have no side-effects outside of the database, as
 773 there is the potential for your subref to be partially double-executed
 774 if the database connection was stale/dysfunctional.
 775
 776 Example:
 777
 778   my @stuff = $schema->storage->dbh_do(
 779     sub {
 780       my ($storage, $dbh, @cols) = @_;
 781       my $cols = join(q{, }, @cols);
 782       $dbh->selectrow_array("SELECT $cols FROM foo");
 783     },
 784     @column_list
 785   );
 786
 787 =cut
 788
 789 sub dbh_do {
 790   my $self = shift;
 791   my $run_target = shift;
 792
 793   # short circuit when we know there is no need for a runner
 794   #
 795   # FIXME - assumption may be wrong
 796   # the rationale for the txn_depth check is that if this block is a part
 797   # of a larger transaction, everything up to that point is screwed anyway
 798   return $self->$run_target($self->_get_dbh, @_)
 799     if $self->{_in_do_block} or $self->transaction_depth;
 800
 801   # take a ref instead of a copy, to preserve @_ aliasing
 802   # semantics within the coderef, but only if needed
 803   # (pseudoforking doesn't like this trick much)
 804   my $args = @_ ? \@_ : [];
 805
 806   DBIx::Class::Storage::BlockRunner->new(
 807     storage => $self,
 808     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 809     wrap_txn => 0,
 810     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 811   )->run;
 812 }
 813
 814 sub txn_do {
 815   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 816   shift->next::method(@_);
 817 }
 818
 819 =head2 disconnect
 820
 821 Our C<disconnect> method also performs a rollback first if the
 822 database is not in C<AutoCommit> mode.
 823
 824 =cut
 825
 826 sub disconnect {
 827   my ($self) = @_;
 828
 829   if( $self->_dbh ) {
 830     my @actions;
 831
 832     push @actions, ( $self->on_disconnect_call || () );
 833     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 834
 835     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 836
 837     # stops the "implicit rollback on disconnect" warning
 838     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 839
 840     %{ $self->_dbh->{CachedKids} } = ();
 841     $self->_dbh->disconnect;
 842     $self->_dbh(undef);
 843   }
 844 }
 845
 846 =head2 with_deferred_fk_checks
 847
 848 =over 4
 849
 850 =item Arguments: C<$coderef>
 851
 852 =item Return Value: The return value of $coderef
 853
 854 =back
 855
 856 Storage specific method to run the code ref with FK checks deferred or
 857 in MySQL's case disabled entirely.
 858
 859 =cut
 860
 861 # Storage subclasses should override this
 862 sub with_deferred_fk_checks {
 863   my ($self, $sub) = @_;
 864   $sub->();
 865 }
 866
 867 =head2 connected
 868
 869 =over
 870
 871 =item Arguments: none
 872
 873 =item Return Value: 1|0
 874
 875 =back
 876
 877 Verifies that the current database handle is active and ready to execute
 878 an SQL statement (e.g. the connection did not get stale, server is still
 879 answering, etc.) This method is used internally by L</dbh>.
 880
 881 =cut
 882
 883 sub connected {
 884   my $self = shift;
 885   return 0 unless $self->_seems_connected;
 886
 887   #be on the safe side
 888   local $self->_dbh->{RaiseError} = 1;
 889
 890   return $self->_ping;
 891 }
 892
 893 sub _seems_connected {
 894   my $self = shift;
 895
 896   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 897
 898   my $dbh = $self->_dbh
 899     or return 0;
 900
 901   return $dbh->FETCH('Active');
 902 }
 903
 904 sub _ping {
 905   my $self = shift;
 906
 907   my $dbh = $self->_dbh or return 0;
 908
 909   return $dbh->ping;
 910 }
 911
 912 sub ensure_connected {
 913   my ($self) = @_;
 914
 915   unless ($self->connected) {
 916     $self->_populate_dbh;
 917   }
 918 }
 919
 920 =head2 dbh
 921
 922 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 923 is guaranteed to be healthy by implicitly calling L</connected>, and if
 924 necessary performing a reconnection before returning. Keep in mind that this
 925 is very B<expensive> on some database engines. Consider using L</dbh_do>
 926 instead.
 927
 928 =cut
 929
 930 sub dbh {
 931   my ($self) = @_;
 932
 933   if (not $self->_dbh) {
 934     $self->_populate_dbh;
 935   } else {
 936     $self->ensure_connected;
 937   }
 938   return $self->_dbh;
 939 }
 940
 941 # this is the internal "get dbh or connect (don't check)" method
 942 sub _get_dbh {
 943   my $self = shift;
 944   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 945   $self->_populate_dbh unless $self->_dbh;
 946   return $self->_dbh;
 947 }
 948
 949 sub sql_maker {
 950   my ($self) = @_;
 951   unless ($self->_sql_maker) {
 952     my $sql_maker_class = $self->sql_maker_class;
 953
 954     my %opts = %{$self->_sql_maker_opts||{}};
 955     my $dialect =
 956       $opts{limit_dialect}
 957         ||
 958       $self->sql_limit_dialect
 959         ||
 960       do {
 961         my $s_class = (ref $self) || $self;
 962         carp_unique (
 963           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 964         . 'have not supplied an explicit limit_dialect in your connection_info. '
 965         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 966         . 'databases but can be (and often is) painfully slow. '
 967         . "Please file an RT ticket against '$s_class'"
 968         ) if $self->_dbi_connect_info->[0];
 969
 970         'GenericSubQ';
 971       }
 972     ;
 973
 974     my ($quote_char, $name_sep);
 975
 976     if ($opts{quote_names}) {
 977       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 978         my $s_class = (ref $self) || $self;
 979         carp_unique (
 980           "You requested 'quote_names' but your storage class ($s_class) does "
 981         . 'not explicitly define a default sql_quote_char and you have not '
 982         . 'supplied a quote_char as part of your connection_info. DBIC will '
 983         .q{default to the ANSI SQL standard quote '"', which works most of }
 984         . "the time. Please file an RT ticket against '$s_class'."
 985         );
 986
 987         '"'; # RV
 988       };
 989
 990       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 991     }
 992
 993     $self->_sql_maker($sql_maker_class->new(
 994       bindtype=>'columns',
 995       array_datatypes => 1,
 996       limit_dialect => $dialect,
 997       ($quote_char ? (quote_char => $quote_char) : ()),
 998       name_sep => ($name_sep || '.'),
 999       %opts,
1000     ));
1001   }
1002   return $self->_sql_maker;
1003 }
1004
1005 # nothing to do by default
1006 sub _rebless {}
1007 sub _init {}
1008
1009 sub _populate_dbh {
1010   my ($self) = @_;
1011
1012   my @info = @{$self->_dbi_connect_info || []};
1013   $self->_dbh(undef); # in case ->connected failed we might get sent here
1014   $self->_dbh_details({}); # reset everything we know
1015
1016   $self->_dbh($self->_connect(@info));
1017
1018   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1019
1020   $self->_determine_driver;
1021
1022   # Always set the transaction depth on connect, since
1023   #  there is no transaction in progress by definition
1024   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1025
1026   $self->_run_connection_actions unless $self->{_in_determine_driver};
1027 }
1028
1029 sub _run_connection_actions {
1030   my $self = shift;
1031   my @actions;
1032
1033   push @actions, ( $self->on_connect_call || () );
1034   push @actions, $self->_parse_connect_do ('on_connect_do');
1035
1036   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1037 }
1038
1039
1040
1041 sub set_use_dbms_capability {
1042   $_[0]->set_inherited ($_[1], $_[2]);
1043 }
1044
1045 sub get_use_dbms_capability {
1046   my ($self, $capname) = @_;
1047
1048   my $use = $self->get_inherited ($capname);
1049   return defined $use
1050     ? $use
1051     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1052   ;
1053 }
1054
1055 sub set_dbms_capability {
1056   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1057 }
1058
1059 sub get_dbms_capability {
1060   my ($self, $capname) = @_;
1061
1062   my $cap = $self->_dbh_details->{capability}{$capname};
1063
1064   unless (defined $cap) {
1065     if (my $meth = $self->can ("_determine$capname")) {
1066       $cap = $self->$meth ? 1 : 0;
1067     }
1068     else {
1069       $cap = 0;
1070     }
1071
1072     $self->set_dbms_capability ($capname, $cap);
1073   }
1074
1075   return $cap;
1076 }
1077
1078 sub _server_info {
1079   my $self = shift;
1080
1081   my $info;
1082   unless ($info = $self->_dbh_details->{info}) {
1083
1084     $info = {};
1085
1086     my $server_version = try {
1087       $self->_get_server_version
1088     } catch {
1089       # driver determination *may* use this codepath
1090       # in which case we must rethrow
1091       $self->throw_exception($_) if $self->{_in_determine_driver};
1092
1093       # $server_version on failure
1094       undef;
1095     };
1096
1097     if (defined $server_version) {
1098       $info->{dbms_version} = $server_version;
1099
1100       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1101       my @verparts = split (/\./, $numeric_version);
1102       if (
1103         @verparts
1104           &&
1105         $verparts[0] <= 999
1106       ) {
1107         # consider only up to 3 version parts, iff not more than 3 digits
1108         my @use_parts;
1109         while (@verparts && @use_parts < 3) {
1110           my $p = shift @verparts;
1111           last if $p > 999;
1112           push @use_parts, $p;
1113         }
1114         push @use_parts, 0 while @use_parts < 3;
1115
1116         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1117       }
1118     }
1119
1120     $self->_dbh_details->{info} = $info;
1121   }
1122
1123   return $info;
1124 }
1125
1126 sub _get_server_version {
1127   shift->_dbh_get_info('SQL_DBMS_VER');
1128 }
1129
1130 sub _dbh_get_info {
1131   my ($self, $info) = @_;
1132
1133   if ($info =~ /[^0-9]/) {
1134     require DBI::Const::GetInfoType;
1135     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1136     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1137       unless defined $info;
1138   }
1139
1140   $self->_get_dbh->get_info($info);
1141 }
1142
1143 sub _describe_connection {
1144   require DBI::Const::GetInfoReturn;
1145
1146   my $self = shift;
1147   $self->ensure_connected;
1148
1149   my $res = {
1150     DBIC_DSN => $self->_dbi_connect_info->[0],
1151     DBI_VER => DBI->VERSION,
1152     DBIC_VER => DBIx::Class->VERSION,
1153     DBIC_DRIVER => ref $self,
1154   };
1155
1156   for my $inf (
1157     #keys %DBI::Const::GetInfoType::GetInfoType,
1158     qw/
1159       SQL_CURSOR_COMMIT_BEHAVIOR
1160       SQL_CURSOR_ROLLBACK_BEHAVIOR
1161       SQL_CURSOR_SENSITIVITY
1162       SQL_DATA_SOURCE_NAME
1163       SQL_DBMS_NAME
1164       SQL_DBMS_VER
1165       SQL_DEFAULT_TXN_ISOLATION
1166       SQL_DM_VER
1167       SQL_DRIVER_NAME
1168       SQL_DRIVER_ODBC_VER
1169       SQL_DRIVER_VER
1170       SQL_EXPRESSIONS_IN_ORDERBY
1171       SQL_GROUP_BY
1172       SQL_IDENTIFIER_CASE
1173       SQL_IDENTIFIER_QUOTE_CHAR
1174       SQL_MAX_CATALOG_NAME_LEN
1175       SQL_MAX_COLUMN_NAME_LEN
1176       SQL_MAX_IDENTIFIER_LEN
1177       SQL_MAX_TABLE_NAME_LEN
1178       SQL_MULTIPLE_ACTIVE_TXN
1179       SQL_MULT_RESULT_SETS
1180       SQL_NEED_LONG_DATA_LEN
1181       SQL_NON_NULLABLE_COLUMNS
1182       SQL_ODBC_VER
1183       SQL_QUALIFIER_NAME_SEPARATOR
1184       SQL_QUOTED_IDENTIFIER_CASE
1185       SQL_TXN_CAPABLE
1186       SQL_TXN_ISOLATION_OPTION
1187     /
1188   ) {
1189     # some drivers barf on things they do not know about instead
1190     # of returning undef
1191     my $v = try { $self->_dbh_get_info($inf) };
1192     next unless defined $v;
1193
1194     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1195     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1196     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1197   }
1198
1199   $res;
1200 }
1201
1202 sub _determine_driver {
1203   my ($self) = @_;
1204
1205   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1206     my $started_connected = 0;
1207     local $self->{_in_determine_driver} = 1;
1208
1209     if (ref($self) eq __PACKAGE__) {
1210       my $driver;
1211       if ($self->_dbh) { # we are connected
1212         $driver = $self->_dbh->{Driver}{Name};
1213         $started_connected = 1;
1214       }
1215       else {
1216         # if connect_info is a CODEREF, we have no choice but to connect
1217         if (ref $self->_dbi_connect_info->[0] &&
1218             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1219           $self->_populate_dbh;
1220           $driver = $self->_dbh->{Driver}{Name};
1221         }
1222         else {
1223           # try to use dsn to not require being connected, the driver may still
1224           # force a connection in _rebless to determine version
1225           # (dsn may not be supplied at all if all we do is make a mock-schema)
1226           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1227           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1228           $driver ||= $ENV{DBI_DRIVER};
1229         }
1230       }
1231
1232       if ($driver) {
1233         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1234         if ($self->load_optional_class($storage_class)) {
1235           mro::set_mro($storage_class, 'c3');
1236           bless $self, $storage_class;
1237           $self->_rebless();
1238         }
1239         else {
1240           $self->_warn_undetermined_driver(
1241             'This version of DBIC does not yet seem to supply a driver for '
1242           . "your particular RDBMS and/or connection method ('$driver')."
1243           );
1244         }
1245       }
1246       else {
1247         $self->_warn_undetermined_driver(
1248           'Unable to extract a driver name from connect info - this '
1249         . 'should not have happened.'
1250         );
1251       }
1252     }
1253
1254     $self->_driver_determined(1);
1255
1256     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1257
1258     if ($self->can('source_bind_attributes')) {
1259       $self->throw_exception(
1260         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1261       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1262       . 'If you are not sure how to proceed please contact the development team via '
1263       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1264       );
1265     }
1266
1267     $self->_init; # run driver-specific initializations
1268
1269     $self->_run_connection_actions
1270         if !$started_connected && defined $self->_dbh;
1271   }
1272 }
1273
1274 sub _determine_connector_driver {
1275   my ($self, $conn) = @_;
1276
1277   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1278
1279   if (not $dbtype) {
1280     $self->_warn_undetermined_driver(
1281       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1282     . "$conn connector - this should not have happened."
1283     );
1284     return;
1285   }
1286
1287   $dbtype =~ s/\W/_/gi;
1288
1289   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1290   return if $self->isa($subclass);
1291
1292   if ($self->load_optional_class($subclass)) {
1293     bless $self, $subclass;
1294     $self->_rebless;
1295   }
1296   else {
1297     $self->_warn_undetermined_driver(
1298       'This version of DBIC does not yet seem to supply a driver for '
1299     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1300     );
1301   }
1302 }
1303
1304 sub _warn_undetermined_driver {
1305   my ($self, $msg) = @_;
1306
1307   require Data::Dumper::Concise;
1308
1309   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1310   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1311   . "does not go away, file a bugreport including the following info:\n"
1312   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1313   );
1314 }
1315
1316 sub _do_connection_actions {
1317   my $self          = shift;
1318   my $method_prefix = shift;
1319   my $call          = shift;
1320
1321   if (not ref($call)) {
1322     my $method = $method_prefix . $call;
1323     $self->$method(@_);
1324   } elsif (ref($call) eq 'CODE') {
1325     $self->$call(@_);
1326   } elsif (ref($call) eq 'ARRAY') {
1327     if (ref($call->[0]) ne 'ARRAY') {
1328       $self->_do_connection_actions($method_prefix, $_) for @$call;
1329     } else {
1330       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1331     }
1332   } else {
1333     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1334   }
1335
1336   return $self;
1337 }
1338
1339 sub connect_call_do_sql {
1340   my $self = shift;
1341   $self->_do_query(@_);
1342 }
1343
1344 sub disconnect_call_do_sql {
1345   my $self = shift;
1346   $self->_do_query(@_);
1347 }
1348
1349 # override in db-specific backend when necessary
1350 sub connect_call_datetime_setup { 1 }
1351
1352 sub _do_query {
1353   my ($self, $action) = @_;
1354
1355   if (ref $action eq 'CODE') {
1356     $action = $action->($self);
1357     $self->_do_query($_) foreach @$action;
1358   }
1359   else {
1360     # Most debuggers expect ($sql, @bind), so we need to exclude
1361     # the attribute hash which is the second argument to $dbh->do
1362     # furthermore the bind values are usually to be presented
1363     # as named arrayref pairs, so wrap those here too
1364     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1365     my $sql = shift @do_args;
1366     my $attrs = shift @do_args;
1367     my @bind = map { [ undef, $_ ] } @do_args;
1368
1369     $self->dbh_do(sub {
1370       $_[0]->_query_start($sql, \@bind);
1371       $_[1]->do($sql, $attrs, @do_args);
1372       $_[0]->_query_end($sql, \@bind);
1373     });
1374   }
1375
1376   return $self;
1377 }
1378
1379 sub _connect {
1380   my ($self, @info) = @_;
1381
1382   $self->throw_exception("You did not provide any connection_info")
1383     if ( ! defined $info[0] and ! $ENV{DBI_DSN} and ! $ENV{DBI_DRIVER} );
1384
1385   my ($old_connect_via, $dbh);
1386
1387   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1388
1389   try {
1390     if(ref $info[0] eq 'CODE') {
1391       $dbh = $info[0]->();
1392     }
1393     else {
1394       require DBI;
1395       $dbh = DBI->connect(@info);
1396     }
1397
1398     die $DBI::errstr unless $dbh;
1399
1400     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1401       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1402       . 'not continue',
1403       ref $info[0] eq 'CODE'
1404         ? "Connection coderef $info[0] returned a"
1405         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1406     ) unless $dbh->FETCH('Active');
1407
1408     # sanity checks unless asked otherwise
1409     unless ($self->unsafe) {
1410
1411       $self->throw_exception(
1412         'Refusing clobbering of {HandleError} installed on externally supplied '
1413        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1414       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1415
1416       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1417       # request, or an external handle. Complain and set anyway
1418       unless ($dbh->{RaiseError}) {
1419         carp( ref $info[0] eq 'CODE'
1420
1421           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1422            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1423            .'attribute has been supplied'
1424
1425           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1426            .'unsafe => 1. Toggling RaiseError back to true'
1427         );
1428
1429         $dbh->{RaiseError} = 1;
1430       }
1431
1432       # this odd anonymous coderef dereference is in fact really
1433       # necessary to avoid the unwanted effect described in perl5
1434       # RT#75792
1435       sub {
1436         my $weak_self = $_[0];
1437         weaken $weak_self;
1438
1439         # the coderef is blessed so we can distinguish it from externally
1440         # supplied handles (which must be preserved)
1441         $_[1]->{HandleError} = bless sub {
1442           if ($weak_self) {
1443             $weak_self->throw_exception("DBI Exception: $_[0]");
1444           }
1445           else {
1446             # the handler may be invoked by something totally out of
1447             # the scope of DBIC
1448             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1449           }
1450         }, '__DBIC__DBH__ERROR__HANDLER__';
1451       }->($self, $dbh);
1452     }
1453   }
1454   catch {
1455     $self->throw_exception("DBI Connection failed: $_")
1456   };
1457
1458   $self->_dbh_autocommit($dbh->{AutoCommit});
1459   $dbh;
1460 }
1461
1462 sub txn_begin {
1463   my $self = shift;
1464
1465   # this means we have not yet connected and do not know the AC status
1466   # (e.g. coderef $dbh), need a full-fledged connection check
1467   if (! defined $self->_dbh_autocommit) {
1468     $self->ensure_connected;
1469   }
1470   # Otherwise simply connect or re-connect on pid changes
1471   else {
1472     $self->_get_dbh;
1473   }
1474
1475   $self->next::method(@_);
1476 }
1477
1478 sub _exec_txn_begin {
1479   my $self = shift;
1480
1481   # if the user is utilizing txn_do - good for him, otherwise we need to
1482   # ensure that the $dbh is healthy on BEGIN.
1483   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1484   # will be replaced by a failure of begin_work itself (which will be
1485   # then retried on reconnect)
1486   if ($self->{_in_do_block}) {
1487     $self->_dbh->begin_work;
1488   } else {
1489     $self->dbh_do(sub { $_[1]->begin_work });
1490   }
1491 }
1492
1493 sub txn_commit {
1494   my $self = shift;
1495
1496   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1497   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1498     unless $self->_dbh;
1499
1500   # esoteric case for folks using external $dbh handles
1501   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1502     carp "Storage transaction_depth 0 does not match "
1503         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1504     $self->transaction_depth(1);
1505   }
1506
1507   $self->next::method(@_);
1508
1509   # if AutoCommit is disabled txn_depth never goes to 0
1510   # as a new txn is started immediately on commit
1511   $self->transaction_depth(1) if (
1512     !$self->transaction_depth
1513       and
1514     defined $self->_dbh_autocommit
1515       and
1516     ! $self->_dbh_autocommit
1517   );
1518 }
1519
1520 sub _exec_txn_commit {
1521   shift->_dbh->commit;
1522 }
1523
1524 sub txn_rollback {
1525   my $self = shift;
1526
1527   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1528   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1529     unless $self->_dbh;
1530
1531   # esoteric case for folks using external $dbh handles
1532   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1533     carp "Storage transaction_depth 0 does not match "
1534         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1535     $self->transaction_depth(1);
1536   }
1537
1538   $self->next::method(@_);
1539
1540   # if AutoCommit is disabled txn_depth never goes to 0
1541   # as a new txn is started immediately on commit
1542   $self->transaction_depth(1) if (
1543     !$self->transaction_depth
1544       and
1545     defined $self->_dbh_autocommit
1546       and
1547     ! $self->_dbh_autocommit
1548   );
1549 }
1550
1551 sub _exec_txn_rollback {
1552   shift->_dbh->rollback;
1553 }
1554
1555 # generate some identical methods
1556 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1557   no strict qw/refs/;
1558   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1559     my $self = shift;
1560     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1561     $self->throw_exception("Unable to $meth() on a disconnected storage")
1562       unless $self->_dbh;
1563     $self->next::method(@_);
1564   };
1565 }
1566
1567 # This used to be the top-half of _execute.  It was split out to make it
1568 #  easier to override in NoBindVars without duping the rest.  It takes up
1569 #  all of _execute's args, and emits $sql, @bind.
1570 sub _prep_for_execute {
1571   #my ($self, $op, $ident, $args) = @_;
1572   return shift->_gen_sql_bind(@_)
1573 }
1574
1575 sub _gen_sql_bind {
1576   my ($self, $op, $ident, $args) = @_;
1577
1578   my ($colinfos, $from);
1579   if ( blessed($ident) ) {
1580     $from = $ident->from;
1581     $colinfos = $ident->columns_info;
1582   }
1583
1584   my ($sql, $bind);
1585   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1586
1587   $bind = $self->_resolve_bindattrs(
1588     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1589   );
1590
1591   if (
1592     ! $ENV{DBIC_DT_SEARCH_OK}
1593       and
1594     $op eq 'select'
1595       and
1596     first {
1597       length ref $_->[1]
1598         and
1599       blessed($_->[1])
1600         and
1601       $_->[1]->isa('DateTime')
1602     } @$bind
1603   ) {
1604     carp_unique 'DateTime objects passed to search() are not supported '
1605       . 'properly (InflateColumn::DateTime formats and settings are not '
1606       . 'respected.) See "Formatting DateTime objects in queries" in '
1607       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1608       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1609   }
1610
1611   return( $sql, $bind );
1612 }
1613
1614 sub _resolve_bindattrs {
1615   my ($self, $ident, $bind, $colinfos) = @_;
1616
1617   $colinfos ||= {};
1618
1619   my $resolve_bindinfo = sub {
1620     #my $infohash = shift;
1621
1622     %$colinfos = %{ $self->_resolve_column_info($ident) }
1623       unless keys %$colinfos;
1624
1625     my $ret;
1626     if (my $col = $_[0]->{dbic_colname}) {
1627       $ret = { %{$_[0]} };
1628
1629       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1630         if $colinfos->{$col}{data_type};
1631
1632       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1633         if $colinfos->{$col}{size};
1634     }
1635
1636     $ret || $_[0];
1637   };
1638
1639   return [ map {
1640     my $resolved =
1641       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1642     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1643     : (ref $_->[0] eq 'HASH')           ? [ (exists $_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype})
1644                                               ? $_->[0]
1645                                               : $resolve_bindinfo->($_->[0])
1646                                             , $_->[1] ]
1647     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1648     :                                     [ $resolve_bindinfo->(
1649                                               { dbic_colname => $_->[0] }
1650                                             ), $_->[1] ]
1651     ;
1652
1653     if (
1654       ! exists $resolved->[0]{dbd_attrs}
1655         and
1656       ! $resolved->[0]{sqlt_datatype}
1657         and
1658       length ref $resolved->[1]
1659         and
1660       ! overload::Method($resolved->[1], '""')
1661     ) {
1662       require Data::Dumper;
1663       local $Data::Dumper::Maxdepth = 1;
1664       local $Data::Dumper::Terse = 1;
1665       local $Data::Dumper::Useqq = 1;
1666       local $Data::Dumper::Indent = 0;
1667       local $Data::Dumper::Pad = ' ';
1668       $self->throw_exception(
1669         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1670       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1671       );
1672     }
1673
1674     $resolved;
1675
1676   } @$bind ];
1677 }
1678
1679 sub _format_for_trace {
1680   #my ($self, $bind) = @_;
1681
1682   ### Turn @bind from something like this:
1683   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1684   ### to this:
1685   ###   ( "'1'", "'3'" )
1686
1687   map {
1688     defined( $_ && $_->[1] )
1689       ? qq{'$_->[1]'}
1690       : q{NULL}
1691   } @{$_[1] || []};
1692 }
1693
1694 sub _query_start {
1695   my ( $self, $sql, $bind ) = @_;
1696
1697   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1698     if $self->debug;
1699 }
1700
1701 sub _query_end {
1702   my ( $self, $sql, $bind ) = @_;
1703
1704   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1705     if $self->debug;
1706 }
1707
1708 sub _dbi_attrs_for_bind {
1709   my ($self, $ident, $bind) = @_;
1710
1711   my @attrs;
1712
1713   for (map { $_->[0] } @$bind) {
1714     push @attrs, do {
1715       if (exists $_->{dbd_attrs}) {
1716         $_->{dbd_attrs}
1717       }
1718       elsif($_->{sqlt_datatype}) {
1719         # cache the result in the dbh_details hash, as it can not change unless
1720         # we connect to something else
1721         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1722         if (not exists $cache->{$_->{sqlt_datatype}}) {
1723           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1724         }
1725         $cache->{$_->{sqlt_datatype}};
1726       }
1727       else {
1728         undef;  # always push something at this position
1729       }
1730     }
1731   }
1732
1733   return \@attrs;
1734 }
1735
1736 sub _execute {
1737   my ($self, $op, $ident, @args) = @_;
1738
1739   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1740
1741   # not even a PID check - we do not care about the state of the _dbh.
1742   # All we need is to get the appropriate drivers loaded if they aren't
1743   # already so that the assumption in ad7c50fc26e holds
1744   $self->_populate_dbh unless $self->_dbh;
1745
1746   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1747     $sql,
1748     $bind,
1749     $self->_dbi_attrs_for_bind($ident, $bind),
1750   );
1751 }
1752
1753 sub _dbh_execute {
1754   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1755
1756   $self->_query_start( $sql, $bind );
1757
1758   my $sth = $self->_bind_sth_params(
1759     $self->_prepare_sth($dbh, $sql),
1760     $bind,
1761     $bind_attrs,
1762   );
1763
1764   # Can this fail without throwing an exception anyways???
1765   my $rv = $sth->execute();
1766   $self->throw_exception(
1767     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1768   ) if !$rv;
1769
1770   $self->_query_end( $sql, $bind );
1771
1772   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1773 }
1774
1775 sub _prepare_sth {
1776   my ($self, $dbh, $sql) = @_;
1777
1778   # 3 is the if_active parameter which avoids active sth re-use
1779   my $sth = $self->disable_sth_caching
1780     ? $dbh->prepare($sql)
1781     : $dbh->prepare_cached($sql, {}, 3);
1782
1783   # XXX You would think RaiseError would make this impossible,
1784   #  but apparently that's not true :(
1785   $self->throw_exception(
1786     $dbh->errstr
1787       ||
1788     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1789             .'an exception and/or setting $dbh->errstr',
1790       length ($sql) > 20
1791         ? substr($sql, 0, 20) . '...'
1792         : $sql
1793       ,
1794       'DBD::' . $dbh->{Driver}{Name},
1795     )
1796   ) if !$sth;
1797
1798   $sth;
1799 }
1800
1801 sub _bind_sth_params {
1802   my ($self, $sth, $bind, $bind_attrs) = @_;
1803
1804   for my $i (0 .. $#$bind) {
1805     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1806       $sth->bind_param_inout(
1807         $i + 1, # bind params counts are 1-based
1808         $bind->[$i][1],
1809         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1810         $bind_attrs->[$i],
1811       );
1812     }
1813     else {
1814       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1815       # confirm with dbi-dev whether explicit stringification is needed
1816       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1817         ? "$bind->[$i][1]"
1818         : $bind->[$i][1]
1819       ;
1820       $sth->bind_param(
1821         $i + 1,
1822         $v,
1823         $bind_attrs->[$i],
1824       );
1825     }
1826   }
1827
1828   $sth;
1829 }
1830
1831 sub _prefetch_autovalues {
1832   my ($self, $source, $colinfo, $to_insert) = @_;
1833
1834   my %values;
1835   for my $col (keys %$colinfo) {
1836     if (
1837       $colinfo->{$col}{auto_nextval}
1838         and
1839       (
1840         ! exists $to_insert->{$col}
1841           or
1842         ref $to_insert->{$col} eq 'SCALAR'
1843           or
1844         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1845       )
1846     ) {
1847       $values{$col} = $self->_sequence_fetch(
1848         'NEXTVAL',
1849         ( $colinfo->{$col}{sequence} ||=
1850             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1851         ),
1852       );
1853     }
1854   }
1855
1856   \%values;
1857 }
1858
1859 sub insert {
1860   my ($self, $source, $to_insert) = @_;
1861
1862   my $col_infos = $source->columns_info;
1863
1864   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1865
1866   # fuse the values, but keep a separate list of prefetched_values so that
1867   # they can be fused once again with the final return
1868   $to_insert = { %$to_insert, %$prefetched_values };
1869
1870   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1871   # Investigate what does it take to s/defined/exists/
1872   my %pcols = map { $_ => 1 } $source->primary_columns;
1873   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1874   for my $col ($source->columns) {
1875     if ($col_infos->{$col}{is_auto_increment}) {
1876       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1877       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1878     }
1879
1880     # nothing to retrieve when explicit values are supplied
1881     next if (defined $to_insert->{$col} and ! (
1882       ref $to_insert->{$col} eq 'SCALAR'
1883         or
1884       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1885     ));
1886
1887     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1888     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1889       $pcols{$col}
1890         or
1891       $col_infos->{$col}{retrieve_on_insert}
1892     );
1893   };
1894
1895   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1896   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1897
1898   my ($sqla_opts, @ir_container);
1899   if (%retrieve_cols and $self->_use_insert_returning) {
1900     $sqla_opts->{returning_container} = \@ir_container
1901       if $self->_use_insert_returning_bound;
1902
1903     $sqla_opts->{returning} = [
1904       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1905     ];
1906   }
1907
1908   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1909
1910   my %returned_cols = %$to_insert;
1911   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1912     @ir_container = try {
1913       local $SIG{__WARN__} = sub {};
1914       my @r = $sth->fetchrow_array;
1915       $sth->finish;
1916       @r;
1917     } unless @ir_container;
1918
1919     @returned_cols{@$retlist} = @ir_container if @ir_container;
1920   }
1921   else {
1922     # pull in PK if needed and then everything else
1923     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1924
1925       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1926         unless $self->can('last_insert_id');
1927
1928       my @pri_values = $self->last_insert_id($source, @missing_pri);
1929
1930       $self->throw_exception( "Can't get last insert id" )
1931         unless (@pri_values == @missing_pri);
1932
1933       @returned_cols{@missing_pri} = @pri_values;
1934       delete @retrieve_cols{@missing_pri};
1935     }
1936
1937     # if there is more left to pull
1938     if (%retrieve_cols) {
1939       $self->throw_exception(
1940         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1941       ) unless %pcols;
1942
1943       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1944
1945       my $cur = DBIx::Class::ResultSet->new($source, {
1946         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1947         select => \@left_to_fetch,
1948       })->cursor;
1949
1950       @returned_cols{@left_to_fetch} = $cur->next;
1951
1952       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1953         if scalar $cur->next;
1954     }
1955   }
1956
1957   return { %$prefetched_values, %returned_cols };
1958 }
1959
1960 sub insert_bulk {
1961   my ($self, $source, $cols, $data) = @_;
1962
1963   my @col_range = (0..$#$cols);
1964
1965   # FIXME SUBOPTIMAL - most likely this is not necessary at all
1966   # confirm with dbi-dev whether explicit stringification is needed
1967   #
1968   # forcibly stringify whatever is stringifiable
1969   # ResultSet::populate() hands us a copy - safe to mangle
1970   for my $r (0 .. $#$data) {
1971     for my $c (0 .. $#{$data->[$r]}) {
1972       $data->[$r][$c] = "$data->[$r][$c]"
1973         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1974     }
1975   }
1976
1977   my $colinfos = $source->columns_info($cols);
1978
1979   local $self->{_autoinc_supplied_for_op} =
1980     (first { $_->{is_auto_increment} } values %$colinfos)
1981       ? 1
1982       : 0
1983   ;
1984
1985   # get a slice type index based on first row of data
1986   # a "column" in this context may refer to more than one bind value
1987   # e.g. \[ '?, ?', [...], [...] ]
1988   #
1989   # construct the value type index - a description of values types for every
1990   # per-column slice of $data:
1991   #
1992   # nonexistent - nonbind literal
1993   # 0 - regular value
1994   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1995   #
1996   # also construct the column hash to pass to the SQL generator. For plain
1997   # (non literal) values - convert the members of the first row into a
1998   # literal+bind combo, with extra positional info in the bind attr hashref.
1999   # This will allow us to match the order properly, and is so contrived
2000   # because a user-supplied literal/bind (or something else specific to a
2001   # resultsource and/or storage driver) can inject extra binds along the
2002   # way, so one can't rely on "shift positions" ordering at all. Also we
2003   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2004   # can be later matched up by address), because we want to supply a real
2005   # value on which perhaps e.g. datatype checks will be performed
2006   my ($proto_data, $value_type_by_col_idx);
2007   for my $i (@col_range) {
2008     my $colname = $cols->[$i];
2009     if (ref $data->[0][$i] eq 'SCALAR') {
2010       # no bind value at all - no type
2011
2012       $proto_data->{$colname} = $data->[0][$i];
2013     }
2014     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
2015       # repack, so we don't end up mangling the original \[]
2016       my ($sql, @bind) = @${$data->[0][$i]};
2017
2018       # normalization of user supplied stuff
2019       my $resolved_bind = $self->_resolve_bindattrs(
2020         $source, \@bind, $colinfos,
2021       );
2022
2023       # store value-less (attrs only) bind info - we will be comparing all
2024       # supplied binds against this for sanity
2025       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
2026
2027       $proto_data->{$colname} = \[ $sql, map { [
2028         # inject slice order to use for $proto_bind construction
2029           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
2030             =>
2031           $resolved_bind->[$_][1]
2032         ] } (0 .. $#bind)
2033       ];
2034     }
2035     else {
2036       $value_type_by_col_idx->{$i} = undef;
2037
2038       $proto_data->{$colname} = \[ '?', [
2039         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2040           =>
2041         $data->[0][$i]
2042       ] ];
2043     }
2044   }
2045
2046   my ($sql, $proto_bind) = $self->_prep_for_execute (
2047     'insert',
2048     $source,
2049     [ $proto_data ],
2050   );
2051
2052   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2053     # if the bindlist is empty and we had some dynamic binds, this means the
2054     # storage ate them away (e.g. the NoBindVars component) and interpolated
2055     # them directly into the SQL. This obviously can't be good for multi-inserts
2056     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2057   }
2058
2059   # sanity checks
2060   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2061   #
2062   # use an error reporting closure for convenience (less to pass)
2063   my $bad_slice_report_cref = sub {
2064     my ($msg, $r_idx, $c_idx) = @_;
2065     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2066       $msg,
2067       $cols->[$c_idx],
2068       do {
2069         require Data::Dumper::Concise;
2070         local $Data::Dumper::Maxdepth = 5;
2071         Data::Dumper::Concise::Dumper ({
2072           map { $cols->[$_] =>
2073             $data->[$r_idx][$_]
2074           } @col_range
2075         }),
2076       }
2077     );
2078   };
2079
2080   for my $col_idx (@col_range) {
2081     my $reference_val = $data->[0][$col_idx];
2082
2083     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2084       my $val = $data->[$row_idx][$col_idx];
2085
2086       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2087         if (ref $val ne 'SCALAR') {
2088           $bad_slice_report_cref->(
2089             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2090             $row_idx,
2091             $col_idx,
2092           );
2093         }
2094         elsif ($$val ne $$reference_val) {
2095           $bad_slice_report_cref->(
2096             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2097             $row_idx,
2098             $col_idx,
2099           );
2100         }
2101       }
2102       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2103         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2104           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2105         }
2106       }
2107       else {  # binds from a \[], compare type and attrs
2108         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2109           $bad_slice_report_cref->(
2110             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2111             $row_idx,
2112             $col_idx,
2113           );
2114         }
2115         # start drilling down and bail out early on identical refs
2116         elsif (
2117           $reference_val != $val
2118             or
2119           $$reference_val != $$val
2120         ) {
2121           if (${$val}->[0] ne ${$reference_val}->[0]) {
2122             $bad_slice_report_cref->(
2123               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2124               $row_idx,
2125               $col_idx,
2126             );
2127           }
2128           # need to check the bind attrs - a bind will happen only once for
2129           # the entire dataset, so any changes further down will be ignored.
2130           elsif (! Data::Compare::Compare(
2131             $value_type_by_col_idx->{$col_idx},
2132             [
2133               map
2134               { $_->[0] }
2135               @{$self->_resolve_bindattrs(
2136                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2137               )}
2138             ],
2139           )) {
2140             $bad_slice_report_cref->(
2141               'Differing bind attributes on literal/bind values not supported',
2142               $row_idx,
2143               $col_idx,
2144             );
2145           }
2146         }
2147       }
2148     }
2149   }
2150
2151   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2152   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2153   # scope guard
2154   my $guard = $self->txn_scope_guard;
2155
2156   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2157   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2158   my $rv = do {
2159     if (@$proto_bind) {
2160       # proto bind contains the information on which pieces of $data to pull
2161       # $cols is passed in only for prettier error-reporting
2162       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2163     }
2164     else {
2165       # bind_param_array doesn't work if there are no binds
2166       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2167     }
2168   };
2169
2170   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2171
2172   $guard->commit;
2173
2174   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2175 }
2176
2177 # execute_for_fetch is capable of returning data just fine (it means it
2178 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2179 # is the void-populate fast-path we will just ignore this altogether
2180 # for the time being.
2181 sub _dbh_execute_for_fetch {
2182   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2183
2184   my @idx_range = ( 0 .. $#$proto_bind );
2185
2186   # If we have any bind attributes to take care of, we will bind the
2187   # proto-bind data (which will never be used by execute_for_fetch)
2188   # However since column bindtypes are "sticky", this is sufficient
2189   # to get the DBD to apply the bindtype to all values later on
2190
2191   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2192
2193   for my $i (@idx_range) {
2194     $sth->bind_param (
2195       $i+1, # DBI bind indexes are 1-based
2196       $proto_bind->[$i][1],
2197       $bind_attrs->[$i],
2198     ) if defined $bind_attrs->[$i];
2199   }
2200
2201   # At this point $data slots named in the _bind_data_slice_idx of
2202   # each piece of $proto_bind are either \[]s or plain values to be
2203   # passed in. Construct the dispensing coderef. *NOTE* the order
2204   # of $data will differ from this of the ?s in the SQL (due to
2205   # alphabetical ordering by colname). We actually do want to
2206   # preserve this behavior so that prepare_cached has a better
2207   # chance of matching on unrelated calls
2208
2209   my $fetch_row_idx = -1; # saner loop this way
2210   my $fetch_tuple = sub {
2211     return undef if ++$fetch_row_idx > $#$data;
2212
2213     return [ map { defined $_->{_literal_bind_subindex}
2214       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2215          ->[ $_->{_literal_bind_subindex} ]
2216           ->[1]
2217       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2218     } map { $_->[0] } @$proto_bind];
2219   };
2220
2221   my $tuple_status = [];
2222   my ($rv, $err);
2223   try {
2224     $rv = $sth->execute_for_fetch(
2225       $fetch_tuple,
2226       $tuple_status,
2227     );
2228   }
2229   catch {
2230     $err = shift;
2231   };
2232
2233   # Not all DBDs are create equal. Some throw on error, some return
2234   # an undef $rv, and some set $sth->err - try whatever we can
2235   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2236     ! defined $err
2237       and
2238     ( !defined $rv or $sth->err )
2239   );
2240
2241   # Statement must finish even if there was an exception.
2242   try {
2243     $sth->finish
2244   }
2245   catch {
2246     $err = shift unless defined $err
2247   };
2248
2249   if (defined $err) {
2250     my $i = 0;
2251     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2252
2253     $self->throw_exception("Unexpected populate error: $err")
2254       if ($i > $#$tuple_status);
2255
2256     require Data::Dumper::Concise;
2257     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2258       ($tuple_status->[$i][1] || $err),
2259       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2260     );
2261   }
2262
2263   return $rv;
2264 }
2265
2266 sub _dbh_execute_inserts_with_no_binds {
2267   my ($self, $sth, $count) = @_;
2268
2269   my $err;
2270   try {
2271     my $dbh = $self->_get_dbh;
2272     local $dbh->{RaiseError} = 1;
2273     local $dbh->{PrintError} = 0;
2274
2275     $sth->execute foreach 1..$count;
2276   }
2277   catch {
2278     $err = shift;
2279   };
2280
2281   # Make sure statement is finished even if there was an exception.
2282   try {
2283     $sth->finish
2284   }
2285   catch {
2286     $err = shift unless defined $err;
2287   };
2288
2289   $self->throw_exception($err) if defined $err;
2290
2291   return $count;
2292 }
2293
2294 sub update {
2295   #my ($self, $source, @args) = @_;
2296   shift->_execute('update', @_);
2297 }
2298
2299
2300 sub delete {
2301   #my ($self, $source, @args) = @_;
2302   shift->_execute('delete', @_);
2303 }
2304
2305 sub _select {
2306   my $self = shift;
2307   $self->_execute($self->_select_args(@_));
2308 }
2309
2310 sub _select_args_to_query {
2311   my $self = shift;
2312
2313   $self->throw_exception(
2314     "Unable to generate limited query representation with 'software_limit' enabled"
2315   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2316
2317   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2318   #  = $self->_select_args($ident, $select, $cond, $attrs);
2319   my ($op, $ident, @args) =
2320     $self->_select_args(@_);
2321
2322   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2323   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2324
2325   # reuse the bind arrayref
2326   unshift @{$bind}, "($sql)";
2327   \$bind;
2328 }
2329
2330 sub _select_args {
2331   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2332
2333   # FIXME - that kind of caching would be nice to have
2334   # however currently we *may* pass the same $orig_attrs
2335   # with different ident/select/where
2336   # the whole interface needs to be rethought, since it
2337   # was centered around the flawed SQLA API. We can do
2338   # soooooo much better now. But that is also another
2339   # battle...
2340   #return (
2341   #  'select', @{$orig_attrs->{_sqlmaker_select_args}}
2342   #) if $orig_attrs->{_sqlmaker_select_args};
2343
2344   my $sql_maker = $self->sql_maker;
2345   my $alias2source = $self->_resolve_ident_sources ($ident);
2346
2347   my $attrs = {
2348     %$orig_attrs,
2349     select => $select,
2350     from => $ident,
2351     where => $where,
2352
2353     # limit dialects use this stuff
2354     # yes, some CDBICompat crap does not supply an {alias} >.<
2355     ( $orig_attrs->{alias} and $alias2source->{$orig_attrs->{alias}} )
2356       ? ( _rsroot_rsrc => $alias2source->{$orig_attrs->{alias}} )
2357       : ()
2358     ,
2359   };
2360
2361   # Sanity check the attributes (SQLMaker does it too, but
2362   # in case of a software_limit we'll never reach there)
2363   if (defined $attrs->{offset}) {
2364     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2365       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2366   }
2367
2368   if (defined $attrs->{rows}) {
2369     $self->throw_exception("The rows attribute must be a positive integer if present")
2370       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2371   }
2372   elsif ($attrs->{offset}) {
2373     # MySQL actually recommends this approach.  I cringe.
2374     $attrs->{rows} = $sql_maker->__max_int;
2375   }
2376
2377   # see if we will need to tear the prefetch apart to satisfy group_by == select
2378   # this is *extremely tricky* to get right, I am still not sure I did
2379   #
2380   my ($prefetch_needs_subquery, @limit_args);
2381
2382   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2383     # we already know there is a valid group_by and we know it is intended
2384     # to be based *only* on the main result columns
2385     # short circuit the group_by parsing below
2386     $prefetch_needs_subquery = 1;
2387   }
2388   elsif (
2389     # The rationale is that even if we do *not* have collapse, we still
2390     # need to wrap the core grouped select/group_by in a subquery
2391     # so that databases that care about group_by/select equivalence
2392     # are happy (this includes MySQL in strict_mode)
2393     # If any of the other joined tables are referenced in the group_by
2394     # however - the user is on their own
2395     ( $prefetch_needs_subquery or $attrs->{_related_results_construction} )
2396       and
2397     $attrs->{group_by}
2398       and
2399     @{$attrs->{group_by}}
2400       and
2401     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2402       $self->_resolve_aliastypes_from_select_args( $attrs->{from}, undef, undef, { group_by => $attrs->{group_by} } )
2403     }
2404   ) {
2405     # no aliases other than our own in group_by
2406     # if there are - do not allow subquery even if limit is present
2407     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2408   }
2409   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2410     # active collapse with a limit - that one is a no-brainer unless
2411     # overruled by a group_by above
2412     $prefetch_needs_subquery = 1;
2413   }
2414
2415   if ($prefetch_needs_subquery) {
2416     ($ident, $select, $where, $attrs) =
2417       $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2418   }
2419   elsif (! $attrs->{software_limit} ) {
2420     push @limit_args, (
2421       $attrs->{rows} || (),
2422       $attrs->{offset} || (),
2423     );
2424   }
2425
2426   # try to simplify the joinmap further (prune unreferenced type-single joins)
2427   if (
2428     ! $prefetch_needs_subquery  # already pruned
2429       and
2430     ref $ident
2431       and
2432     reftype $ident eq 'ARRAY'
2433       and
2434     @$ident != 1
2435   ) {
2436     ($ident, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2437   }
2438
2439 ###
2440   # This would be the point to deflate anything found in $where
2441   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2442   # expect a result object. And all we have is a resultsource (it is trivial
2443   # to extract deflator coderefs via $alias2source above).
2444   #
2445   # I don't see a way forward other than changing the way deflators are
2446   # invoked, and that's just bad...
2447 ###
2448
2449   return ( 'select', @{ $orig_attrs->{_sqlmaker_select_args} = [
2450     $ident, $select, $where, $attrs, @limit_args
2451   ]} );
2452 }
2453
2454 # Returns a counting SELECT for a simple count
2455 # query. Abstracted so that a storage could override
2456 # this to { count => 'firstcol' } or whatever makes
2457 # sense as a performance optimization
2458 sub _count_select {
2459   #my ($self, $source, $rs_attrs) = @_;
2460   return { count => '*' };
2461 }
2462
2463 =head2 select
2464
2465 =over 4
2466
2467 =item Arguments: $ident, $select, $condition, $attrs
2468
2469 =back
2470
2471 Handle a SQL select statement.
2472
2473 =cut
2474
2475 sub select {
2476   my $self = shift;
2477   my ($ident, $select, $condition, $attrs) = @_;
2478   return $self->cursor_class->new($self, \@_, $attrs);
2479 }
2480
2481 sub select_single {
2482   my $self = shift;
2483   my ($rv, $sth, @bind) = $self->_select(@_);
2484   my @row = $sth->fetchrow_array;
2485   my @nextrow = $sth->fetchrow_array if @row;
2486   if(@row && @nextrow) {
2487     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2488   }
2489   # Need to call finish() to work round broken DBDs
2490   $sth->finish();
2491   return @row;
2492 }
2493
2494 =head2 sql_limit_dialect
2495
2496 This is an accessor for the default SQL limit dialect used by a particular
2497 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2498 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2499 see L<DBIx::Class::SQLMaker::LimitDialects>.
2500
2501 =cut
2502
2503 sub _dbh_columns_info_for {
2504   my ($self, $dbh, $table) = @_;
2505
2506   if ($dbh->can('column_info')) {
2507     my %result;
2508     my $caught;
2509     try {
2510       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2511       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2512       $sth->execute();
2513       while ( my $info = $sth->fetchrow_hashref() ){
2514         my %column_info;
2515         $column_info{data_type}   = $info->{TYPE_NAME};
2516         $column_info{size}      = $info->{COLUMN_SIZE};
2517         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2518         $column_info{default_value} = $info->{COLUMN_DEF};
2519         my $col_name = $info->{COLUMN_NAME};
2520         $col_name =~ s/^\"(.*)\"$/$1/;
2521
2522         $result{$col_name} = \%column_info;
2523       }
2524     } catch {
2525       $caught = 1;
2526     };
2527     return \%result if !$caught && scalar keys %result;
2528   }
2529
2530   my %result;
2531   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2532   $sth->execute;
2533   my @columns = @{$sth->{NAME_lc}};
2534   for my $i ( 0 .. $#columns ){
2535     my %column_info;
2536     $column_info{data_type} = $sth->{TYPE}->[$i];
2537     $column_info{size} = $sth->{PRECISION}->[$i];
2538     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2539
2540     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2541       $column_info{data_type} = $1;
2542       $column_info{size}    = $2;
2543     }
2544
2545     $result{$columns[$i]} = \%column_info;
2546   }
2547   $sth->finish;
2548
2549   foreach my $col (keys %result) {
2550     my $colinfo = $result{$col};
2551     my $type_num = $colinfo->{data_type};
2552     my $type_name;
2553     if(defined $type_num && $dbh->can('type_info')) {
2554       my $type_info = $dbh->type_info($type_num);
2555       $type_name = $type_info->{TYPE_NAME} if $type_info;
2556       $colinfo->{data_type} = $type_name if $type_name;
2557     }
2558   }
2559
2560   return \%result;
2561 }
2562
2563 sub columns_info_for {
2564   my ($self, $table) = @_;
2565   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2566 }
2567
2568 =head2 last_insert_id
2569
2570 Return the row id of the last insert.
2571
2572 =cut
2573
2574 sub _dbh_last_insert_id {
2575     my ($self, $dbh, $source, $col) = @_;
2576
2577     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2578
2579     return $id if defined $id;
2580
2581     my $class = ref $self;
2582     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2583 }
2584
2585 sub last_insert_id {
2586   my $self = shift;
2587   $self->_dbh_last_insert_id ($self->_dbh, @_);
2588 }
2589
2590 =head2 _native_data_type
2591
2592 =over 4
2593
2594 =item Arguments: $type_name
2595
2596 =back
2597
2598 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2599 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2600 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2601
2602 The default implementation returns C<undef>, implement in your Storage driver if
2603 you need this functionality.
2604
2605 Should map types from other databases to the native RDBMS type, for example
2606 C<VARCHAR2> to C<VARCHAR>.
2607
2608 Types with modifiers should map to the underlying data type. For example,
2609 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2610
2611 Composite types should map to the container type, for example
2612 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2613
2614 =cut
2615
2616 sub _native_data_type {
2617   #my ($self, $data_type) = @_;
2618   return undef
2619 }
2620
2621 # Check if placeholders are supported at all
2622 sub _determine_supports_placeholders {
2623   my $self = shift;
2624   my $dbh  = $self->_get_dbh;
2625
2626   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2627   # but it is inaccurate more often than not
2628   return try {
2629     local $dbh->{PrintError} = 0;
2630     local $dbh->{RaiseError} = 1;
2631     $dbh->do('select ?', {}, 1);
2632     1;
2633   }
2634   catch {
2635     0;
2636   };
2637 }
2638
2639 # Check if placeholders bound to non-string types throw exceptions
2640 #
2641 sub _determine_supports_typeless_placeholders {
2642   my $self = shift;
2643   my $dbh  = $self->_get_dbh;
2644
2645   return try {
2646     local $dbh->{PrintError} = 0;
2647     local $dbh->{RaiseError} = 1;
2648     # this specifically tests a bind that is NOT a string
2649     $dbh->do('select 1 where 1 = ?', {}, 1);
2650     1;
2651   }
2652   catch {
2653     0;
2654   };
2655 }
2656
2657 =head2 sqlt_type
2658
2659 Returns the database driver name.
2660
2661 =cut
2662
2663 sub sqlt_type {
2664   shift->_get_dbh->{Driver}->{Name};
2665 }
2666
2667 =head2 bind_attribute_by_data_type
2668
2669 Given a datatype from column info, returns a database specific bind
2670 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2671 let the database planner just handle it.
2672
2673 This method is always called after the driver has been determined and a DBI
2674 connection has been established. Therefore you can refer to C<DBI::$constant>
2675 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2676 the correct modules.
2677
2678 =cut
2679
2680 sub bind_attribute_by_data_type {
2681     return;
2682 }
2683
2684 =head2 is_datatype_numeric
2685
2686 Given a datatype from column_info, returns a boolean value indicating if
2687 the current RDBMS considers it a numeric value. This controls how
2688 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2689 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2690 be performed instead of the usual C<eq>.
2691
2692 =cut
2693
2694 sub is_datatype_numeric {
2695   #my ($self, $dt) = @_;
2696
2697   return 0 unless $_[1];
2698
2699   $_[1] =~ /^ (?:
2700     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2701   ) $/ix;
2702 }
2703
2704
2705 =head2 create_ddl_dir
2706
2707 =over 4
2708
2709 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2710
2711 =back
2712
2713 Creates a SQL file based on the Schema, for each of the specified
2714 database engines in C<\@databases> in the given directory.
2715 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2716
2717 Given a previous version number, this will also create a file containing
2718 the ALTER TABLE statements to transform the previous schema into the
2719 current one. Note that these statements may contain C<DROP TABLE> or
2720 C<DROP COLUMN> statements that can potentially destroy data.
2721
2722 The file names are created using the C<ddl_filename> method below, please
2723 override this method in your schema if you would like a different file
2724 name format. For the ALTER file, the same format is used, replacing
2725 $version in the name with "$preversion-$version".
2726
2727 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2728 The most common value for this would be C<< { add_drop_table => 1 } >>
2729 to have the SQL produced include a C<DROP TABLE> statement for each table
2730 created. For quoting purposes supply C<quote_identifiers>.
2731
2732 If no arguments are passed, then the following default values are assumed:
2733
2734 =over 4
2735
2736 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2737
2738 =item version    - $schema->schema_version
2739
2740 =item directory  - './'
2741
2742 =item preversion - <none>
2743
2744 =back
2745
2746 By default, C<\%sqlt_args> will have
2747
2748  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2749
2750 merged with the hash passed in. To disable any of those features, pass in a
2751 hashref like the following
2752
2753  { ignore_constraint_names => 0, # ... other options }
2754
2755
2756 WARNING: You are strongly advised to check all SQL files created, before applying
2757 them.
2758
2759 =cut
2760
2761 sub create_ddl_dir {
2762   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2763
2764   unless ($dir) {
2765     carp "No directory given, using ./\n";
2766     $dir = './';
2767   } else {
2768       -d $dir
2769         or
2770       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2771         or
2772       $self->throw_exception(
2773         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2774       );
2775   }
2776
2777   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2778
2779   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2780   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2781
2782   my $schema_version = $schema->schema_version || '1.x';
2783   $version ||= $schema_version;
2784
2785   $sqltargs = {
2786     add_drop_table => 1,
2787     ignore_constraint_names => 1,
2788     ignore_index_names => 1,
2789     %{$sqltargs || {}}
2790   };
2791
2792   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2793     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2794   }
2795
2796   my $sqlt = SQL::Translator->new( $sqltargs );
2797
2798   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2799   my $sqlt_schema = $sqlt->translate({ data => $schema })
2800     or $self->throw_exception ($sqlt->error);
2801
2802   foreach my $db (@$databases) {
2803     $sqlt->reset();
2804     $sqlt->{schema} = $sqlt_schema;
2805     $sqlt->producer($db);
2806
2807     my $file;
2808     my $filename = $schema->ddl_filename($db, $version, $dir);
2809     if (-e $filename && ($version eq $schema_version )) {
2810       # if we are dumping the current version, overwrite the DDL
2811       carp "Overwriting existing DDL file - $filename";
2812       unlink($filename);
2813     }
2814
2815     my $output = $sqlt->translate;
2816     if(!$output) {
2817       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2818       next;
2819     }
2820     if(!open($file, ">$filename")) {
2821       $self->throw_exception("Can't open $filename for writing ($!)");
2822       next;
2823     }
2824     print $file $output;
2825     close($file);
2826
2827     next unless ($preversion);
2828
2829     require SQL::Translator::Diff;
2830
2831     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2832     if(!-e $prefilename) {
2833       carp("No previous schema file found ($prefilename)");
2834       next;
2835     }
2836
2837     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2838     if(-e $difffile) {
2839       carp("Overwriting existing diff file - $difffile");
2840       unlink($difffile);
2841     }
2842
2843     my $source_schema;
2844     {
2845       my $t = SQL::Translator->new($sqltargs);
2846       $t->debug( 0 );
2847       $t->trace( 0 );
2848
2849       $t->parser( $db )
2850         or $self->throw_exception ($t->error);
2851
2852       my $out = $t->translate( $prefilename )
2853         or $self->throw_exception ($t->error);
2854
2855       $source_schema = $t->schema;
2856
2857       $source_schema->name( $prefilename )
2858         unless ( $source_schema->name );
2859     }
2860
2861     # The "new" style of producers have sane normalization and can support
2862     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2863     # And we have to diff parsed SQL against parsed SQL.
2864     my $dest_schema = $sqlt_schema;
2865
2866     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2867       my $t = SQL::Translator->new($sqltargs);
2868       $t->debug( 0 );
2869       $t->trace( 0 );
2870
2871       $t->parser( $db )
2872         or $self->throw_exception ($t->error);
2873
2874       my $out = $t->translate( $filename )
2875         or $self->throw_exception ($t->error);
2876
2877       $dest_schema = $t->schema;
2878
2879       $dest_schema->name( $filename )
2880         unless $dest_schema->name;
2881     }
2882
2883     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2884                                                   $dest_schema,   $db,
2885                                                   $sqltargs
2886                                                  );
2887     if(!open $file, ">$difffile") {
2888       $self->throw_exception("Can't write to $difffile ($!)");
2889       next;
2890     }
2891     print $file $diff;
2892     close($file);
2893   }
2894 }
2895
2896 =head2 deployment_statements
2897
2898 =over 4
2899
2900 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2901
2902 =back
2903
2904 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2905
2906 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2907 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2908
2909 C<$directory> is used to return statements from files in a previously created
2910 L</create_ddl_dir> directory and is optional. The filenames are constructed
2911 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2912
2913 If no C<$directory> is specified then the statements are constructed on the
2914 fly using L<SQL::Translator> and C<$version> is ignored.
2915
2916 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2917
2918 =cut
2919
2920 sub deployment_statements {
2921   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2922   $type ||= $self->sqlt_type;
2923   $version ||= $schema->schema_version || '1.x';
2924   $dir ||= './';
2925   my $filename = $schema->ddl_filename($type, $version, $dir);
2926   if(-f $filename)
2927   {
2928       # FIXME replace this block when a proper sane sql parser is available
2929       my $file;
2930       open($file, "<$filename")
2931         or $self->throw_exception("Can't open $filename ($!)");
2932       my @rows = <$file>;
2933       close($file);
2934       return join('', @rows);
2935   }
2936
2937   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2938     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2939   }
2940
2941   # sources needs to be a parser arg, but for simplicity allow at top level
2942   # coming in
2943   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2944       if exists $sqltargs->{sources};
2945
2946   my $tr = SQL::Translator->new(
2947     producer => "SQL::Translator::Producer::${type}",
2948     %$sqltargs,
2949     parser => 'SQL::Translator::Parser::DBIx::Class',
2950     data => $schema,
2951   );
2952
2953   return preserve_context {
2954     $tr->translate
2955   } after => sub {
2956     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2957       unless defined $_[0];
2958   };
2959 }
2960
2961 # FIXME deploy() currently does not accurately report sql errors
2962 # Will always return true while errors are warned
2963 sub deploy {
2964   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2965   my $deploy = sub {
2966     my $line = shift;
2967     return if(!$line);
2968     return if($line =~ /^--/);
2969     # next if($line =~ /^DROP/m);
2970     return if($line =~ /^BEGIN TRANSACTION/m);
2971     return if($line =~ /^COMMIT/m);
2972     return if $line =~ /^\s+$/; # skip whitespace only
2973     $self->_query_start($line);
2974     try {
2975       # do a dbh_do cycle here, as we need some error checking in
2976       # place (even though we will ignore errors)
2977       $self->dbh_do (sub { $_[1]->do($line) });
2978     } catch {
2979       carp qq{$_ (running "${line}")};
2980     };
2981     $self->_query_end($line);
2982   };
2983   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2984   if (@statements > 1) {
2985     foreach my $statement (@statements) {
2986       $deploy->( $statement );
2987     }
2988   }
2989   elsif (@statements == 1) {
2990     # split on single line comments and end of statements
2991     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2992       $deploy->( $line );
2993     }
2994   }
2995 }
2996
2997 =head2 datetime_parser
2998
2999 Returns the datetime parser class
3000
3001 =cut
3002
3003 sub datetime_parser {
3004   my $self = shift;
3005   return $self->{datetime_parser} ||= do {
3006     $self->build_datetime_parser(@_);
3007   };
3008 }
3009
3010 =head2 datetime_parser_type
3011
3012 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3013
3014 =head2 build_datetime_parser
3015
3016 See L</datetime_parser>
3017
3018 =cut
3019
3020 sub build_datetime_parser {
3021   my $self = shift;
3022   my $type = $self->datetime_parser_type(@_);
3023   return $type;
3024 }
3025
3026
3027 =head2 is_replicating
3028
3029 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3030 replicate from a master database.  Default is undef, which is the result
3031 returned by databases that don't support replication.
3032
3033 =cut
3034
3035 sub is_replicating {
3036     return;
3037
3038 }
3039
3040 =head2 lag_behind_master
3041
3042 Returns a number that represents a certain amount of lag behind a master db
3043 when a given storage is replicating.  The number is database dependent, but
3044 starts at zero and increases with the amount of lag. Default in undef
3045
3046 =cut
3047
3048 sub lag_behind_master {
3049     return;
3050 }
3051
3052 =head2 relname_to_table_alias
3053
3054 =over 4
3055
3056 =item Arguments: $relname, $join_count
3057
3058 =item Return Value: $alias
3059
3060 =back
3061
3062 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3063 queries.
3064
3065 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3066 way these aliases are named.
3067
3068 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3069 otherwise C<"$relname">.
3070
3071 =cut
3072
3073 sub relname_to_table_alias {
3074   my ($self, $relname, $join_count) = @_;
3075
3076   my $alias = ($join_count && $join_count > 1 ?
3077     join('_', $relname, $join_count) : $relname);
3078
3079   return $alias;
3080 }
3081
3082 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3083 # version and it may be necessary to amend or override it for a specific storage
3084 # if such binds are necessary.
3085 sub _max_column_bytesize {
3086   my ($self, $attr) = @_;
3087
3088   my $max_size;
3089
3090   if ($attr->{sqlt_datatype}) {
3091     my $data_type = lc($attr->{sqlt_datatype});
3092
3093     if ($attr->{sqlt_size}) {
3094
3095       # String/sized-binary types
3096       if ($data_type =~ /^(?:
3097           l? (?:var)? char(?:acter)? (?:\s*varying)?
3098             |
3099           (?:var)? binary (?:\s*varying)?
3100             |
3101           raw
3102         )\b/x
3103       ) {
3104         $max_size = $attr->{sqlt_size};
3105       }
3106       # Other charset/unicode types, assume scale of 4
3107       elsif ($data_type =~ /^(?:
3108           national \s* character (?:\s*varying)?
3109             |
3110           nchar
3111             |
3112           univarchar
3113             |
3114           nvarchar
3115         )\b/x
3116       ) {
3117         $max_size = $attr->{sqlt_size} * 4;
3118       }
3119     }
3120
3121     if (!$max_size and !$self->_is_lob_type($data_type)) {
3122       $max_size = 100 # for all other (numeric?) datatypes
3123     }
3124   }
3125
3126   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3127 }
3128
3129 # Determine if a data_type is some type of BLOB
3130 sub _is_lob_type {
3131   my ($self, $data_type) = @_;
3132   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3133     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3134                                   |varchar|character\s*varying|nvarchar
3135                                   |national\s*character\s*varying))?\z/xi);
3136 }
3137
3138 sub _is_binary_lob_type {
3139   my ($self, $data_type) = @_;
3140   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3141     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3142 }
3143
3144 sub _is_text_lob_type {
3145   my ($self, $data_type) = @_;
3146   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3147     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3148                         |national\s*character\s*varying))\z/xi);
3149 }
3150
3151 # Determine if a data_type is some type of a binary type
3152 sub _is_binary_type {
3153   my ($self, $data_type) = @_;
3154   $data_type && ($self->_is_binary_lob_type($data_type)
3155     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3156 }
3157
3158 1;
3159
3160 =head1 USAGE NOTES
3161
3162 =head2 DBIx::Class and AutoCommit
3163
3164 DBIx::Class can do some wonderful magic with handling exceptions,
3165 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3166 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3167 transaction support.
3168
3169 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3170 in an assumed transaction between commits, and you're telling us you'd
3171 like to manage that manually.  A lot of the magic protections offered by
3172 this module will go away.  We can't protect you from exceptions due to database
3173 disconnects because we don't know anything about how to restart your
3174 transactions.  You're on your own for handling all sorts of exceptional
3175 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3176 be with raw DBI.
3177
3178
3179 =head1 AUTHOR AND CONTRIBUTORS
3180
3181 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3182
3183 =head1 LICENSE
3184
3185 You may distribute this code under the same terms as Perl itself.
3186
3187 =cut