lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util qw/refaddr weaken reftype blessed/;
  15 use Data::Dumper::Concise 'Dumper';
  16 use Sub::Name 'subname';
  17 use Try::Tiny;
  18 use File::Path 'make_path';
  19 use namespace::clean;
  20
  21 __PACKAGE__->mk_group_accessors('simple' => qw/
  22   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  23   _dbh _server_info_hash _conn_pid _conn_tid _sql_maker _sql_maker_opts
  24   transaction_depth _dbh_autocommit  savepoints
  25 /);
  26
  27 # the values for these accessors are picked out (and deleted) from
  28 # the attribute hashref passed to connect_info
  29 my @storage_options = qw/
  30   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  31   disable_sth_caching unsafe auto_savepoint
  32 /;
  33 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  34
  35
  36 # default cursor class, overridable in connect_info attributes
  37 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  38
  39 __PACKAGE__->mk_group_accessors('inherited' => qw/
  40   sql_maker_class
  41   _supports_insert_returning
  42 /);
  43 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  44
  45 # Each of these methods need _determine_driver called before itself
  46 # in order to function reliably. This is a purely DRY optimization
  47 my @rdbms_specific_methods = qw/
  48   deployment_statements
  49   sqlt_type
  50   sql_maker
  51   build_datetime_parser
  52   datetime_parser_type
  53
  54   insert
  55   insert_bulk
  56   update
  57   delete
  58   select
  59   select_single
  60 /;
  61
  62 for my $meth (@rdbms_specific_methods) {
  63
  64   my $orig = __PACKAGE__->can ($meth)
  65     or next;
  66
  67   no strict qw/refs/;
  68   no warnings qw/redefine/;
  69   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
  70     if (not $_[0]->_driver_determined) {
  71       $_[0]->_determine_driver;
  72       goto $_[0]->can($meth);
  73     }
  74     $orig->(@_);
  75   };
  76 }
  77
  78
  79 =head1 NAME
  80
  81 DBIx::Class::Storage::DBI - DBI storage handler
  82
  83 =head1 SYNOPSIS
  84
  85   my $schema = MySchema->connect('dbi:SQLite:my.db');
  86
  87   $schema->storage->debug(1);
  88
  89   my @stuff = $schema->storage->dbh_do(
  90     sub {
  91       my ($storage, $dbh, @args) = @_;
  92       $dbh->do("DROP TABLE authors");
  93     },
  94     @column_list
  95   );
  96
  97   $schema->resultset('Book')->search({
  98      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
  99   });
 100
 101 =head1 DESCRIPTION
 102
 103 This class represents the connection to an RDBMS via L<DBI>.  See
 104 L<DBIx::Class::Storage> for general information.  This pod only
 105 documents DBI-specific methods and behaviors.
 106
 107 =head1 METHODS
 108
 109 =cut
 110
 111 sub new {
 112   my $new = shift->next::method(@_);
 113
 114   $new->transaction_depth(0);
 115   $new->_sql_maker_opts({});
 116   $new->{savepoints} = [];
 117   $new->{_in_dbh_do} = 0;
 118   $new->{_dbh_gen} = 0;
 119
 120   # read below to see what this does
 121   $new->_arm_global_destructor;
 122
 123   $new;
 124 }
 125
 126 # This is hack to work around perl shooting stuff in random
 127 # order on exit(). If we do not walk the remaining storage
 128 # objects in an END block, there is a *small but real* chance
 129 # of a fork()ed child to kill the parent's shared DBI handle,
 130 # *before perl reaches the DESTROY in this package*
 131 # Yes, it is ugly and effective.
 132 {
 133   my %seek_and_destroy;
 134
 135   sub _arm_global_destructor {
 136     my $self = shift;
 137     my $key = Scalar::Util::refaddr ($self);
 138     $seek_and_destroy{$key} = $self;
 139     Scalar::Util::weaken ($seek_and_destroy{$key});
 140   }
 141
 142   END {
 143     local $?; # just in case the DBI destructor changes it somehow
 144
 145     # destroy just the object if not native to this process/thread
 146     $_->_preserve_foreign_dbh for (grep
 147       { defined $_ }
 148       values %seek_and_destroy
 149     );
 150   }
 151 }
 152
 153 sub DESTROY {
 154   my $self = shift;
 155
 156   # destroy just the object if not native to this process/thread
 157   $self->_preserve_foreign_dbh;
 158
 159   # some databases need this to stop spewing warnings
 160   if (my $dbh = $self->_dbh) {
 161     try {
 162       %{ $dbh->{CachedKids} } = ();
 163       $dbh->disconnect;
 164     };
 165   }
 166
 167   $self->_dbh(undef);
 168 }
 169
 170 sub _preserve_foreign_dbh {
 171   my $self = shift;
 172
 173   return unless $self->_dbh;
 174
 175   $self->_verify_tid;
 176
 177   return unless $self->_dbh;
 178
 179   $self->_verify_pid;
 180
 181 }
 182
 183 # handle pid changes correctly - do not destroy parent's connection
 184 sub _verify_pid {
 185   my $self = shift;
 186
 187   return if ( defined $self->_conn_pid and $self->_conn_pid == $$ );
 188
 189   $self->_dbh->{InactiveDestroy} = 1;
 190   $self->_dbh(undef);
 191   $self->{_dbh_gen}++;
 192
 193   return;
 194 }
 195
 196 # very similar to above, but seems to FAIL if I set InactiveDestroy
 197 sub _verify_tid {
 198   my $self = shift;
 199
 200   if ( ! defined $self->_conn_tid ) {
 201     return; # no threads
 202   }
 203   elsif ( $self->_conn_tid == threads->tid ) {
 204     return; # same thread
 205   }
 206
 207   #$self->_dbh->{InactiveDestroy} = 1;  # why does t/51threads.t fail...?
 208   $self->_dbh(undef);
 209   $self->{_dbh_gen}++;
 210
 211   return;
 212 }
 213
 214
 215 =head2 connect_info
 216
 217 This method is normally called by L<DBIx::Class::Schema/connection>, which
 218 encapsulates its argument list in an arrayref before passing them here.
 219
 220 The argument list may contain:
 221
 222 =over
 223
 224 =item *
 225
 226 The same 4-element argument set one would normally pass to
 227 L<DBI/connect>, optionally followed by
 228 L<extra attributes|/DBIx::Class specific connection attributes>
 229 recognized by DBIx::Class:
 230
 231   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 232
 233 =item *
 234
 235 A single code reference which returns a connected
 236 L<DBI database handle|DBI/connect> optionally followed by
 237 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 238 by DBIx::Class:
 239
 240   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 241
 242 =item *
 243
 244 A single hashref with all the attributes and the dsn/user/password
 245 mixed together:
 246
 247   $connect_info_args = [{
 248     dsn => $dsn,
 249     user => $user,
 250     password => $pass,
 251     %dbi_attributes,
 252     %extra_attributes,
 253   }];
 254
 255   $connect_info_args = [{
 256     dbh_maker => sub { DBI->connect (...) },
 257     %dbi_attributes,
 258     %extra_attributes,
 259   }];
 260
 261 This is particularly useful for L<Catalyst> based applications, allowing the
 262 following config (L<Config::General> style):
 263
 264   <Model::DB>
 265     schema_class   App::DB
 266     <connect_info>
 267       dsn          dbi:mysql:database=test
 268       user         testuser
 269       password     TestPass
 270       AutoCommit   1
 271     </connect_info>
 272   </Model::DB>
 273
 274 The C<dsn>/C<user>/C<password> combination can be substituted by the
 275 C<dbh_maker> key whose value is a coderef that returns a connected
 276 L<DBI database handle|DBI/connect>
 277
 278 =back
 279
 280 Please note that the L<DBI> docs recommend that you always explicitly
 281 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 282 recommends that it be set to I<1>, and that you perform transactions
 283 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 284 to I<1> if you do not do explicitly set it to zero.  This is the default
 285 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 286
 287 =head3 DBIx::Class specific connection attributes
 288
 289 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 290 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 291 the following connection options. These options can be mixed in with your other
 292 L<DBI> connection attributes, or placed in a separate hashref
 293 (C<\%extra_attributes>) as shown above.
 294
 295 Every time C<connect_info> is invoked, any previous settings for
 296 these options will be cleared before setting the new ones, regardless of
 297 whether any options are specified in the new C<connect_info>.
 298
 299
 300 =over
 301
 302 =item on_connect_do
 303
 304 Specifies things to do immediately after connecting or re-connecting to
 305 the database.  Its value may contain:
 306
 307 =over
 308
 309 =item a scalar
 310
 311 This contains one SQL statement to execute.
 312
 313 =item an array reference
 314
 315 This contains SQL statements to execute in order.  Each element contains
 316 a string or a code reference that returns a string.
 317
 318 =item a code reference
 319
 320 This contains some code to execute.  Unlike code references within an
 321 array reference, its return value is ignored.
 322
 323 =back
 324
 325 =item on_disconnect_do
 326
 327 Takes arguments in the same form as L</on_connect_do> and executes them
 328 immediately before disconnecting from the database.
 329
 330 Note, this only runs if you explicitly call L</disconnect> on the
 331 storage object.
 332
 333 =item on_connect_call
 334
 335 A more generalized form of L</on_connect_do> that calls the specified
 336 C<connect_call_METHOD> methods in your storage driver.
 337
 338   on_connect_do => 'select 1'
 339
 340 is equivalent to:
 341
 342   on_connect_call => [ [ do_sql => 'select 1' ] ]
 343
 344 Its values may contain:
 345
 346 =over
 347
 348 =item a scalar
 349
 350 Will call the C<connect_call_METHOD> method.
 351
 352 =item a code reference
 353
 354 Will execute C<< $code->($storage) >>
 355
 356 =item an array reference
 357
 358 Each value can be a method name or code reference.
 359
 360 =item an array of arrays
 361
 362 For each array, the first item is taken to be the C<connect_call_> method name
 363 or code reference, and the rest are parameters to it.
 364
 365 =back
 366
 367 Some predefined storage methods you may use:
 368
 369 =over
 370
 371 =item do_sql
 372
 373 Executes a SQL string or a code reference that returns a SQL string. This is
 374 what L</on_connect_do> and L</on_disconnect_do> use.
 375
 376 It can take:
 377
 378 =over
 379
 380 =item a scalar
 381
 382 Will execute the scalar as SQL.
 383
 384 =item an arrayref
 385
 386 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 387 attributes hashref and bind values.
 388
 389 =item a code reference
 390
 391 Will execute C<< $code->($storage) >> and execute the return array refs as
 392 above.
 393
 394 =back
 395
 396 =item datetime_setup
 397
 398 Execute any statements necessary to initialize the database session to return
 399 and accept datetime/timestamp values used with
 400 L<DBIx::Class::InflateColumn::DateTime>.
 401
 402 Only necessary for some databases, see your specific storage driver for
 403 implementation details.
 404
 405 =back
 406
 407 =item on_disconnect_call
 408
 409 Takes arguments in the same form as L</on_connect_call> and executes them
 410 immediately before disconnecting from the database.
 411
 412 Calls the C<disconnect_call_METHOD> methods as opposed to the
 413 C<connect_call_METHOD> methods called by L</on_connect_call>.
 414
 415 Note, this only runs if you explicitly call L</disconnect> on the
 416 storage object.
 417
 418 =item disable_sth_caching
 419
 420 If set to a true value, this option will disable the caching of
 421 statement handles via L<DBI/prepare_cached>.
 422
 423 =item limit_dialect
 424
 425 Sets the limit dialect. This is useful for JDBC-bridge among others
 426 where the remote SQL-dialect cannot be determined by the name of the
 427 driver alone. See also L<SQL::Abstract::Limit>.
 428
 429 =item quote_char
 430
 431 Specifies what characters to use to quote table and column names. If
 432 you use this you will want to specify L</name_sep> as well.
 433
 434 C<quote_char> expects either a single character, in which case is it
 435 is placed on either side of the table/column name, or an arrayref of length
 436 2 in which case the table/column name is placed between the elements.
 437
 438 For example under MySQL you should use C<< quote_char => '`' >>, and for
 439 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 440
 441 =item name_sep
 442
 443 This only needs to be used in conjunction with C<quote_char>, and is used to
 444 specify the character that separates elements (schemas, tables, columns) from
 445 each other. In most cases this is simply a C<.>.
 446
 447 The consequences of not supplying this value is that L<SQL::Abstract>
 448 will assume DBIx::Class' uses of aliases to be complete column
 449 names. The output will look like I<"me.name"> when it should actually
 450 be I<"me"."name">.
 451
 452 =item unsafe
 453
 454 This Storage driver normally installs its own C<HandleError>, sets
 455 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 456 all database handles, including those supplied by a coderef.  It does this
 457 so that it can have consistent and useful error behavior.
 458
 459 If you set this option to a true value, Storage will not do its usual
 460 modifications to the database handle's attributes, and instead relies on
 461 the settings in your connect_info DBI options (or the values you set in
 462 your connection coderef, in the case that you are connecting via coderef).
 463
 464 Note that your custom settings can cause Storage to malfunction,
 465 especially if you set a C<HandleError> handler that suppresses exceptions
 466 and/or disable C<RaiseError>.
 467
 468 =item auto_savepoint
 469
 470 If this option is true, L<DBIx::Class> will use savepoints when nesting
 471 transactions, making it possible to recover from failure in the inner
 472 transaction without having to abort all outer transactions.
 473
 474 =item cursor_class
 475
 476 Use this argument to supply a cursor class other than the default
 477 L<DBIx::Class::Storage::DBI::Cursor>.
 478
 479 =back
 480
 481 Some real-life examples of arguments to L</connect_info> and
 482 L<DBIx::Class::Schema/connect>
 483
 484   # Simple SQLite connection
 485   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 486
 487   # Connect via subref
 488   ->connect_info([ sub { DBI->connect(...) } ]);
 489
 490   # Connect via subref in hashref
 491   ->connect_info([{
 492     dbh_maker => sub { DBI->connect(...) },
 493     on_connect_do => 'alter session ...',
 494   }]);
 495
 496   # A bit more complicated
 497   ->connect_info(
 498     [
 499       'dbi:Pg:dbname=foo',
 500       'postgres',
 501       'my_pg_password',
 502       { AutoCommit => 1 },
 503       { quote_char => q{"}, name_sep => q{.} },
 504     ]
 505   );
 506
 507   # Equivalent to the previous example
 508   ->connect_info(
 509     [
 510       'dbi:Pg:dbname=foo',
 511       'postgres',
 512       'my_pg_password',
 513       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 514     ]
 515   );
 516
 517   # Same, but with hashref as argument
 518   # See parse_connect_info for explanation
 519   ->connect_info(
 520     [{
 521       dsn         => 'dbi:Pg:dbname=foo',
 522       user        => 'postgres',
 523       password    => 'my_pg_password',
 524       AutoCommit  => 1,
 525       quote_char  => q{"},
 526       name_sep    => q{.},
 527     }]
 528   );
 529
 530   # Subref + DBIx::Class-specific connection options
 531   ->connect_info(
 532     [
 533       sub { DBI->connect(...) },
 534       {
 535           quote_char => q{`},
 536           name_sep => q{@},
 537           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 538           disable_sth_caching => 1,
 539       },
 540     ]
 541   );
 542
 543
 544
 545 =cut
 546
 547 sub connect_info {
 548   my ($self, $info) = @_;
 549
 550   return $self->_connect_info if !$info;
 551
 552   $self->_connect_info($info); # copy for _connect_info
 553
 554   $info = $self->_normalize_connect_info($info)
 555     if ref $info eq 'ARRAY';
 556
 557   for my $storage_opt (keys %{ $info->{storage_options} }) {
 558     my $value = $info->{storage_options}{$storage_opt};
 559
 560     $self->$storage_opt($value);
 561   }
 562
 563   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 564   #  the new set of options
 565   $self->_sql_maker(undef);
 566   $self->_sql_maker_opts({});
 567
 568   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 569     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 570
 571     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 572   }
 573
 574   my %attrs = (
 575     %{ $self->_default_dbi_connect_attributes || {} },
 576     %{ $info->{attributes} || {} },
 577   );
 578
 579   my @args = @{ $info->{arguments} };
 580
 581   $self->_dbi_connect_info([@args,
 582     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 583
 584   # FIXME - dirty:
 585   # save attributes them in a separate accessor so they are always
 586   # introspectable, even in case of a CODE $dbhmaker
 587   $self->_dbic_connect_attributes (\%attrs);
 588
 589   return $self->_connect_info;
 590 }
 591
 592 sub _normalize_connect_info {
 593   my ($self, $info_arg) = @_;
 594   my %info;
 595
 596   my @args = @$info_arg;  # take a shallow copy for further mutilation
 597
 598   # combine/pre-parse arguments depending on invocation style
 599
 600   my %attrs;
 601   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 602     %attrs = %{ $args[1] || {} };
 603     @args = $args[0];
 604   }
 605   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 606     %attrs = %{$args[0]};
 607     @args = ();
 608     if (my $code = delete $attrs{dbh_maker}) {
 609       @args = $code;
 610
 611       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 612       if (@ignored) {
 613         carp sprintf (
 614             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 615           . "to the result of 'dbh_maker'",
 616
 617           join (', ', map { "'$_'" } (@ignored) ),
 618         );
 619       }
 620     }
 621     else {
 622       @args = delete @attrs{qw/dsn user password/};
 623     }
 624   }
 625   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 626     %attrs = (
 627       % { $args[3] || {} },
 628       % { $args[4] || {} },
 629     );
 630     @args = @args[0,1,2];
 631   }
 632
 633   $info{arguments} = \@args;
 634
 635   my @storage_opts = grep exists $attrs{$_},
 636     @storage_options, 'cursor_class';
 637
 638   @{ $info{storage_options} }{@storage_opts} =
 639     delete @attrs{@storage_opts} if @storage_opts;
 640
 641   my @sql_maker_opts = grep exists $attrs{$_},
 642     qw/limit_dialect quote_char name_sep/;
 643
 644   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 645     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 646
 647   $info{attributes} = \%attrs if %attrs;
 648
 649   return \%info;
 650 }
 651
 652 sub _default_dbi_connect_attributes {
 653   return {
 654     AutoCommit => 1,
 655     RaiseError => 1,
 656     PrintError => 0,
 657   };
 658 }
 659
 660 =head2 on_connect_do
 661
 662 This method is deprecated in favour of setting via L</connect_info>.
 663
 664 =cut
 665
 666 =head2 on_disconnect_do
 667
 668 This method is deprecated in favour of setting via L</connect_info>.
 669
 670 =cut
 671
 672 sub _parse_connect_do {
 673   my ($self, $type) = @_;
 674
 675   my $val = $self->$type;
 676   return () if not defined $val;
 677
 678   my @res;
 679
 680   if (not ref($val)) {
 681     push @res, [ 'do_sql', $val ];
 682   } elsif (ref($val) eq 'CODE') {
 683     push @res, $val;
 684   } elsif (ref($val) eq 'ARRAY') {
 685     push @res, map { [ 'do_sql', $_ ] } @$val;
 686   } else {
 687     $self->throw_exception("Invalid type for $type: ".ref($val));
 688   }
 689
 690   return \@res;
 691 }
 692
 693 =head2 dbh_do
 694
 695 Arguments: ($subref | $method_name), @extra_coderef_args?
 696
 697 Execute the given $subref or $method_name using the new exception-based
 698 connection management.
 699
 700 The first two arguments will be the storage object that C<dbh_do> was called
 701 on and a database handle to use.  Any additional arguments will be passed
 702 verbatim to the called subref as arguments 2 and onwards.
 703
 704 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 705 exception handling and reconnection (or failover in future subclasses).
 706
 707 Your subref should have no side-effects outside of the database, as
 708 there is the potential for your subref to be partially double-executed
 709 if the database connection was stale/dysfunctional.
 710
 711 Example:
 712
 713   my @stuff = $schema->storage->dbh_do(
 714     sub {
 715       my ($storage, $dbh, @cols) = @_;
 716       my $cols = join(q{, }, @cols);
 717       $dbh->selectrow_array("SELECT $cols FROM foo");
 718     },
 719     @column_list
 720   );
 721
 722 =cut
 723
 724 sub dbh_do {
 725   my $self = shift;
 726   my $code = shift;
 727
 728   my $dbh = $self->_get_dbh;
 729
 730   return $self->$code($dbh, @_)
 731     if ( $self->{_in_dbh_do} || $self->{transaction_depth} );
 732
 733   local $self->{_in_dbh_do} = 1;
 734
 735   # take a ref instead of a copy, to preserve coderef @_ aliasing semantics
 736   my $args = \@_;
 737   return try {
 738     $self->$code ($dbh, @$args);
 739   } catch {
 740     $self->throw_exception($_) if $self->connected;
 741
 742     # We were not connected - reconnect and retry, but let any
 743     #  exception fall right through this time
 744     carp "Retrying $code after catching disconnected exception: $_"
 745       if $ENV{DBIC_DBIRETRY_DEBUG};
 746
 747     $self->_populate_dbh;
 748     $self->$code($self->_dbh, @$args);
 749   };
 750 }
 751
 752 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 753 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 754 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 755 sub txn_do {
 756   my $self = shift;
 757   my $coderef = shift;
 758
 759   ref $coderef eq 'CODE' or $self->throw_exception
 760     ('$coderef must be a CODE reference');
 761
 762   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 763
 764   local $self->{_in_dbh_do} = 1;
 765
 766   my @result;
 767   my $want_array = wantarray;
 768
 769   my $tried = 0;
 770   while(1) {
 771     my $exception;
 772
 773     # take a ref instead of a copy, to preserve coderef @_ aliasing semantics
 774     my $args = \@_;
 775
 776     try {
 777       $self->_get_dbh;
 778
 779       $self->txn_begin;
 780       if($want_array) {
 781           @result = $coderef->(@$args);
 782       }
 783       elsif(defined $want_array) {
 784           $result[0] = $coderef->(@$args);
 785       }
 786       else {
 787           $coderef->(@$args);
 788       }
 789       $self->txn_commit;
 790     } catch {
 791       $exception = $_;
 792     };
 793
 794     if(! defined $exception) { return $want_array ? @result : $result[0] }
 795
 796     if($tried++ || $self->connected) {
 797       my $rollback_exception;
 798       try { $self->txn_rollback } catch { $rollback_exception = shift };
 799       if(defined $rollback_exception) {
 800         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 801         $self->throw_exception($exception)  # propagate nested rollback
 802           if $rollback_exception =~ /$exception_class/;
 803
 804         $self->throw_exception(
 805           "Transaction aborted: ${exception}. "
 806           . "Rollback failed: ${rollback_exception}"
 807         );
 808       }
 809       $self->throw_exception($exception)
 810     }
 811
 812     # We were not connected, and was first try - reconnect and retry
 813     # via the while loop
 814     carp "Retrying $coderef after catching disconnected exception: $exception"
 815       if $ENV{DBIC_DBIRETRY_DEBUG};
 816     $self->_populate_dbh;
 817   }
 818 }
 819
 820 =head2 disconnect
 821
 822 Our C<disconnect> method also performs a rollback first if the
 823 database is not in C<AutoCommit> mode.
 824
 825 =cut
 826
 827 sub disconnect {
 828   my ($self) = @_;
 829
 830   if( $self->_dbh ) {
 831     my @actions;
 832
 833     push @actions, ( $self->on_disconnect_call || () );
 834     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 835
 836     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 837
 838     $self->_dbh_rollback unless $self->_dbh_autocommit;
 839
 840     %{ $self->_dbh->{CachedKids} } = ();
 841     $self->_dbh->disconnect;
 842     $self->_dbh(undef);
 843     $self->{_dbh_gen}++;
 844   }
 845 }
 846
 847 =head2 with_deferred_fk_checks
 848
 849 =over 4
 850
 851 =item Arguments: C<$coderef>
 852
 853 =item Return Value: The return value of $coderef
 854
 855 =back
 856
 857 Storage specific method to run the code ref with FK checks deferred or
 858 in MySQL's case disabled entirely.
 859
 860 =cut
 861
 862 # Storage subclasses should override this
 863 sub with_deferred_fk_checks {
 864   my ($self, $sub) = @_;
 865   $sub->();
 866 }
 867
 868 =head2 connected
 869
 870 =over
 871
 872 =item Arguments: none
 873
 874 =item Return Value: 1|0
 875
 876 =back
 877
 878 Verifies that the current database handle is active and ready to execute
 879 an SQL statement (e.g. the connection did not get stale, server is still
 880 answering, etc.) This method is used internally by L</dbh>.
 881
 882 =cut
 883
 884 sub connected {
 885   my $self = shift;
 886   return 0 unless $self->_seems_connected;
 887
 888   #be on the safe side
 889   local $self->_dbh->{RaiseError} = 1;
 890
 891   return $self->_ping;
 892 }
 893
 894 sub _seems_connected {
 895   my $self = shift;
 896
 897   $self->_preserve_foreign_dbh;
 898
 899   my $dbh = $self->_dbh
 900     or return 0;
 901
 902   return $dbh->FETCH('Active');
 903 }
 904
 905 sub _ping {
 906   my $self = shift;
 907
 908   my $dbh = $self->_dbh or return 0;
 909
 910   return $dbh->ping;
 911 }
 912
 913 sub ensure_connected {
 914   my ($self) = @_;
 915
 916   unless ($self->connected) {
 917     $self->_populate_dbh;
 918   }
 919 }
 920
 921 =head2 dbh
 922
 923 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 924 is guaranteed to be healthy by implicitly calling L</connected>, and if
 925 necessary performing a reconnection before returning. Keep in mind that this
 926 is very B<expensive> on some database engines. Consider using L</dbh_do>
 927 instead.
 928
 929 =cut
 930
 931 sub dbh {
 932   my ($self) = @_;
 933
 934   if (not $self->_dbh) {
 935     $self->_populate_dbh;
 936   } else {
 937     $self->ensure_connected;
 938   }
 939   return $self->_dbh;
 940 }
 941
 942 # this is the internal "get dbh or connect (don't check)" method
 943 sub _get_dbh {
 944   my $self = shift;
 945   $self->_preserve_foreign_dbh;
 946   $self->_populate_dbh unless $self->_dbh;
 947   return $self->_dbh;
 948 }
 949
 950 sub _sql_maker_args {
 951     my ($self) = @_;
 952
 953     return (
 954       bindtype=>'columns',
 955       array_datatypes => 1,
 956       limit_dialect => $self->_get_dbh,
 957       %{$self->_sql_maker_opts}
 958     );
 959 }
 960
 961 sub sql_maker {
 962   my ($self) = @_;
 963   unless ($self->_sql_maker) {
 964     my $sql_maker_class = $self->sql_maker_class;
 965     $self->ensure_class_loaded ($sql_maker_class);
 966     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 967   }
 968   return $self->_sql_maker;
 969 }
 970
 971 # nothing to do by default
 972 sub _rebless {}
 973 sub _init {}
 974
 975 sub _populate_dbh {
 976   my ($self) = @_;
 977
 978   my @info = @{$self->_dbi_connect_info || []};
 979   $self->_dbh(undef); # in case ->connected failed we might get sent here
 980   $self->_server_info_hash (undef);
 981   $self->_dbh($self->_connect(@info));
 982
 983   $self->_conn_pid($$);
 984   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 985
 986   $self->_determine_driver;
 987
 988   # Always set the transaction depth on connect, since
 989   #  there is no transaction in progress by definition
 990   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 991
 992   $self->_run_connection_actions unless $self->{_in_determine_driver};
 993 }
 994
 995 sub _run_connection_actions {
 996   my $self = shift;
 997   my @actions;
 998
 999   push @actions, ( $self->on_connect_call || () );
1000   push @actions, $self->_parse_connect_do ('on_connect_do');
1001
1002   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1003 }
1004
1005 sub _server_info {
1006   my $self = shift;
1007
1008   unless ($self->_server_info_hash) {
1009
1010     my %info;
1011
1012     my $server_version = try { $self->_get_server_version };
1013
1014     if (defined $server_version) {
1015       $info{dbms_version} = $server_version;
1016
1017       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1018       my @verparts = split (/\./, $numeric_version);
1019       if (
1020         @verparts
1021           &&
1022         $verparts[0] <= 999
1023       ) {
1024         # consider only up to 3 version parts, iff not more than 3 digits
1025         my @use_parts;
1026         while (@verparts && @use_parts < 3) {
1027           my $p = shift @verparts;
1028           last if $p > 999;
1029           push @use_parts, $p;
1030         }
1031         push @use_parts, 0 while @use_parts < 3;
1032
1033         $info{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1034       }
1035     }
1036
1037     $self->_server_info_hash(\%info);
1038   }
1039
1040   return $self->_server_info_hash
1041 }
1042
1043 sub _get_server_version {
1044   shift->_get_dbh->get_info(18);
1045 }
1046
1047 sub _determine_driver {
1048   my ($self) = @_;
1049
1050   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1051     my $started_connected = 0;
1052     local $self->{_in_determine_driver} = 1;
1053
1054     if (ref($self) eq __PACKAGE__) {
1055       my $driver;
1056       if ($self->_dbh) { # we are connected
1057         $driver = $self->_dbh->{Driver}{Name};
1058         $started_connected = 1;
1059       } else {
1060         # if connect_info is a CODEREF, we have no choice but to connect
1061         if (ref $self->_dbi_connect_info->[0] &&
1062             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1063           $self->_populate_dbh;
1064           $driver = $self->_dbh->{Driver}{Name};
1065         }
1066         else {
1067           # try to use dsn to not require being connected, the driver may still
1068           # force a connection in _rebless to determine version
1069           # (dsn may not be supplied at all if all we do is make a mock-schema)
1070           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1071           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1072           $driver ||= $ENV{DBI_DRIVER};
1073         }
1074       }
1075
1076       if ($driver) {
1077         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1078         if ($self->load_optional_class($storage_class)) {
1079           mro::set_mro($storage_class, 'c3');
1080           bless $self, $storage_class;
1081           $self->_rebless();
1082         }
1083       }
1084     }
1085
1086     $self->_driver_determined(1);
1087
1088     $self->_init; # run driver-specific initializations
1089
1090     $self->_run_connection_actions
1091         if !$started_connected && defined $self->_dbh;
1092   }
1093 }
1094
1095 sub _do_connection_actions {
1096   my $self          = shift;
1097   my $method_prefix = shift;
1098   my $call          = shift;
1099
1100   if (not ref($call)) {
1101     my $method = $method_prefix . $call;
1102     $self->$method(@_);
1103   } elsif (ref($call) eq 'CODE') {
1104     $self->$call(@_);
1105   } elsif (ref($call) eq 'ARRAY') {
1106     if (ref($call->[0]) ne 'ARRAY') {
1107       $self->_do_connection_actions($method_prefix, $_) for @$call;
1108     } else {
1109       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1110     }
1111   } else {
1112     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1113   }
1114
1115   return $self;
1116 }
1117
1118 sub connect_call_do_sql {
1119   my $self = shift;
1120   $self->_do_query(@_);
1121 }
1122
1123 sub disconnect_call_do_sql {
1124   my $self = shift;
1125   $self->_do_query(@_);
1126 }
1127
1128 # override in db-specific backend when necessary
1129 sub connect_call_datetime_setup { 1 }
1130
1131 sub _do_query {
1132   my ($self, $action) = @_;
1133
1134   if (ref $action eq 'CODE') {
1135     $action = $action->($self);
1136     $self->_do_query($_) foreach @$action;
1137   }
1138   else {
1139     # Most debuggers expect ($sql, @bind), so we need to exclude
1140     # the attribute hash which is the second argument to $dbh->do
1141     # furthermore the bind values are usually to be presented
1142     # as named arrayref pairs, so wrap those here too
1143     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1144     my $sql = shift @do_args;
1145     my $attrs = shift @do_args;
1146     my @bind = map { [ undef, $_ ] } @do_args;
1147
1148     $self->_query_start($sql, @bind);
1149     $self->_get_dbh->do($sql, $attrs, @do_args);
1150     $self->_query_end($sql, @bind);
1151   }
1152
1153   return $self;
1154 }
1155
1156 sub _connect {
1157   my ($self, @info) = @_;
1158
1159   $self->throw_exception("You failed to provide any connection info")
1160     if !@info;
1161
1162   my ($old_connect_via, $dbh);
1163
1164   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1165     $old_connect_via = $DBI::connect_via;
1166     $DBI::connect_via = 'connect';
1167   }
1168
1169   try {
1170     if(ref $info[0] eq 'CODE') {
1171        $dbh = $info[0]->();
1172     }
1173     else {
1174        $dbh = DBI->connect(@info);
1175     }
1176
1177     if (!$dbh) {
1178       die $DBI::errstr;
1179     }
1180
1181     unless ($self->unsafe) {
1182       my $weak_self = $self;
1183       weaken $weak_self;
1184       $dbh->{HandleError} = sub {
1185           if ($weak_self) {
1186             $weak_self->throw_exception("DBI Exception: $_[0]");
1187           }
1188           else {
1189             # the handler may be invoked by something totally out of
1190             # the scope of DBIC
1191             croak ("DBI Exception: $_[0]");
1192           }
1193       };
1194       $dbh->{ShowErrorStatement} = 1;
1195       $dbh->{RaiseError} = 1;
1196       $dbh->{PrintError} = 0;
1197     }
1198   }
1199   catch {
1200     $self->throw_exception("DBI Connection failed: $_")
1201   }
1202   finally {
1203     $DBI::connect_via = $old_connect_via if $old_connect_via;
1204   };
1205
1206   $self->_dbh_autocommit($dbh->{AutoCommit});
1207   $dbh;
1208 }
1209
1210 sub svp_begin {
1211   my ($self, $name) = @_;
1212
1213   $name = $self->_svp_generate_name
1214     unless defined $name;
1215
1216   $self->throw_exception ("You can't use savepoints outside a transaction")
1217     if $self->{transaction_depth} == 0;
1218
1219   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1220     unless $self->can('_svp_begin');
1221
1222   push @{ $self->{savepoints} }, $name;
1223
1224   $self->debugobj->svp_begin($name) if $self->debug;
1225
1226   return $self->_svp_begin($name);
1227 }
1228
1229 sub svp_release {
1230   my ($self, $name) = @_;
1231
1232   $self->throw_exception ("You can't use savepoints outside a transaction")
1233     if $self->{transaction_depth} == 0;
1234
1235   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1236     unless $self->can('_svp_release');
1237
1238   if (defined $name) {
1239     $self->throw_exception ("Savepoint '$name' does not exist")
1240       unless grep { $_ eq $name } @{ $self->{savepoints} };
1241
1242     # Dig through the stack until we find the one we are releasing.  This keeps
1243     # the stack up to date.
1244     my $svp;
1245
1246     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1247   } else {
1248     $name = pop @{ $self->{savepoints} };
1249   }
1250
1251   $self->debugobj->svp_release($name) if $self->debug;
1252
1253   return $self->_svp_release($name);
1254 }
1255
1256 sub svp_rollback {
1257   my ($self, $name) = @_;
1258
1259   $self->throw_exception ("You can't use savepoints outside a transaction")
1260     if $self->{transaction_depth} == 0;
1261
1262   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1263     unless $self->can('_svp_rollback');
1264
1265   if (defined $name) {
1266       # If they passed us a name, verify that it exists in the stack
1267       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1268           $self->throw_exception("Savepoint '$name' does not exist!");
1269       }
1270
1271       # Dig through the stack until we find the one we are releasing.  This keeps
1272       # the stack up to date.
1273       while(my $s = pop(@{ $self->{savepoints} })) {
1274           last if($s eq $name);
1275       }
1276       # Add the savepoint back to the stack, as a rollback doesn't remove the
1277       # named savepoint, only everything after it.
1278       push(@{ $self->{savepoints} }, $name);
1279   } else {
1280       # We'll assume they want to rollback to the last savepoint
1281       $name = $self->{savepoints}->[-1];
1282   }
1283
1284   $self->debugobj->svp_rollback($name) if $self->debug;
1285
1286   return $self->_svp_rollback($name);
1287 }
1288
1289 sub _svp_generate_name {
1290     my ($self) = @_;
1291
1292     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1293 }
1294
1295 sub txn_begin {
1296   my $self = shift;
1297
1298   # this means we have not yet connected and do not know the AC status
1299   # (e.g. coderef $dbh)
1300   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1301
1302   if($self->{transaction_depth} == 0) {
1303     $self->debugobj->txn_begin()
1304       if $self->debug;
1305     $self->_dbh_begin_work;
1306   }
1307   elsif ($self->auto_savepoint) {
1308     $self->svp_begin;
1309   }
1310   $self->{transaction_depth}++;
1311 }
1312
1313 sub _dbh_begin_work {
1314   my $self = shift;
1315
1316   # if the user is utilizing txn_do - good for him, otherwise we need to
1317   # ensure that the $dbh is healthy on BEGIN.
1318   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1319   # will be replaced by a failure of begin_work itself (which will be
1320   # then retried on reconnect)
1321   if ($self->{_in_dbh_do}) {
1322     $self->_dbh->begin_work;
1323   } else {
1324     $self->dbh_do(sub { $_[1]->begin_work });
1325   }
1326 }
1327
1328 sub txn_commit {
1329   my $self = shift;
1330   if ($self->{transaction_depth} == 1) {
1331     $self->debugobj->txn_commit()
1332       if ($self->debug);
1333     $self->_dbh_commit;
1334     $self->{transaction_depth} = 0
1335       if $self->_dbh_autocommit;
1336   }
1337   elsif($self->{transaction_depth} > 1) {
1338     $self->{transaction_depth}--;
1339     $self->svp_release
1340       if $self->auto_savepoint;
1341   }
1342 }
1343
1344 sub _dbh_commit {
1345   my $self = shift;
1346   my $dbh  = $self->_dbh
1347     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1348   $dbh->commit;
1349 }
1350
1351 sub txn_rollback {
1352   my $self = shift;
1353   my $dbh = $self->_dbh;
1354   try {
1355     if ($self->{transaction_depth} == 1) {
1356       $self->debugobj->txn_rollback()
1357         if ($self->debug);
1358       $self->{transaction_depth} = 0
1359         if $self->_dbh_autocommit;
1360       $self->_dbh_rollback;
1361     }
1362     elsif($self->{transaction_depth} > 1) {
1363       $self->{transaction_depth}--;
1364       if ($self->auto_savepoint) {
1365         $self->svp_rollback;
1366         $self->svp_release;
1367       }
1368     }
1369     else {
1370       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1371     }
1372   }
1373   catch {
1374     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1375
1376     if ($_ !~ /$exception_class/) {
1377       # ensure that a failed rollback resets the transaction depth
1378       $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1379     }
1380
1381     $self->throw_exception($_)
1382   };
1383 }
1384
1385 sub _dbh_rollback {
1386   my $self = shift;
1387   my $dbh  = $self->_dbh
1388     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1389   $dbh->rollback;
1390 }
1391
1392 # This used to be the top-half of _execute.  It was split out to make it
1393 #  easier to override in NoBindVars without duping the rest.  It takes up
1394 #  all of _execute's args, and emits $sql, @bind.
1395 sub _prep_for_execute {
1396   my ($self, $op, $extra_bind, $ident, $args) = @_;
1397
1398   if( blessed $ident && $ident->isa("DBIx::Class::ResultSource") ) {
1399     $ident = $ident->from();
1400   }
1401
1402   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1403
1404   unshift(@bind,
1405     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1406       if $extra_bind;
1407   return ($sql, \@bind);
1408 }
1409
1410
1411 sub _fix_bind_params {
1412     my ($self, @bind) = @_;
1413
1414     ### Turn @bind from something like this:
1415     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1416     ### to this:
1417     ###   ( "'1'", "'1'", "'3'" )
1418     return
1419         map {
1420             if ( defined( $_ && $_->[1] ) ) {
1421                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1422             }
1423             else { q{'NULL'}; }
1424         } @bind;
1425 }
1426
1427 sub _query_start {
1428     my ( $self, $sql, @bind ) = @_;
1429
1430     if ( $self->debug ) {
1431         @bind = $self->_fix_bind_params(@bind);
1432
1433         $self->debugobj->query_start( $sql, @bind );
1434     }
1435 }
1436
1437 sub _query_end {
1438     my ( $self, $sql, @bind ) = @_;
1439
1440     if ( $self->debug ) {
1441         @bind = $self->_fix_bind_params(@bind);
1442         $self->debugobj->query_end( $sql, @bind );
1443     }
1444 }
1445
1446 sub _dbh_execute {
1447   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1448
1449   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1450
1451   $self->_query_start( $sql, @$bind );
1452
1453   my $sth = $self->sth($sql,$op);
1454
1455   my $placeholder_index = 1;
1456
1457   foreach my $bound (@$bind) {
1458     my $attributes = {};
1459     my($column_name, @data) = @$bound;
1460
1461     if ($bind_attributes) {
1462       $attributes = $bind_attributes->{$column_name}
1463       if defined $bind_attributes->{$column_name};
1464     }
1465
1466     foreach my $data (@data) {
1467       my $ref = ref $data;
1468       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1469
1470       $sth->bind_param($placeholder_index, $data, $attributes);
1471       $placeholder_index++;
1472     }
1473   }
1474
1475   # Can this fail without throwing an exception anyways???
1476   my $rv = $sth->execute();
1477   $self->throw_exception(
1478     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1479   ) if !$rv;
1480
1481   $self->_query_end( $sql, @$bind );
1482
1483   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1484 }
1485
1486 sub _execute {
1487     my $self = shift;
1488     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1489 }
1490
1491 sub _prefetch_insert_auto_nextvals {
1492   my ($self, $source, $to_insert) = @_;
1493
1494   my $upd = {};
1495
1496   foreach my $col ( $source->columns ) {
1497     if ( !defined $to_insert->{$col} ) {
1498       my $col_info = $source->column_info($col);
1499
1500       if ( $col_info->{auto_nextval} ) {
1501         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1502           'nextval',
1503           $col_info->{sequence} ||=
1504             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1505         );
1506       }
1507     }
1508   }
1509
1510   return $upd;
1511 }
1512
1513 sub insert {
1514   my $self = shift;
1515   my ($source, $to_insert, $opts) = @_;
1516
1517   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1518
1519   my $bind_attributes = $self->source_bind_attributes($source);
1520
1521   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1522
1523   if ($opts->{returning}) {
1524     my @ret_cols = @{$opts->{returning}};
1525
1526     my @ret_vals = try {
1527       local $SIG{__WARN__} = sub {};
1528       my @r = $sth->fetchrow_array;
1529       $sth->finish;
1530       @r;
1531     };
1532
1533     my %ret;
1534     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1535
1536     $updated_cols = {
1537       %$updated_cols,
1538       %ret,
1539     };
1540   }
1541
1542   return $updated_cols;
1543 }
1544
1545 ## Currently it is assumed that all values passed will be "normal", i.e. not
1546 ## scalar refs, or at least, all the same type as the first set, the statement is
1547 ## only prepped once.
1548 sub insert_bulk {
1549   my ($self, $source, $cols, $data) = @_;
1550
1551   my %colvalues;
1552   @colvalues{@$cols} = (0..$#$cols);
1553
1554   for my $i (0..$#$cols) {
1555     my $first_val = $data->[0][$i];
1556     next unless ref $first_val eq 'SCALAR';
1557
1558     $colvalues{ $cols->[$i] } = $first_val;
1559   }
1560
1561   # check for bad data and stringify stringifiable objects
1562   my $bad_slice = sub {
1563     my ($msg, $col_idx, $slice_idx) = @_;
1564     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1565       $msg,
1566       $cols->[$col_idx],
1567       do {
1568         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1569         Dumper {
1570           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1571         },
1572       }
1573     );
1574   };
1575
1576   for my $datum_idx (0..$#$data) {
1577     my $datum = $data->[$datum_idx];
1578
1579     for my $col_idx (0..$#$cols) {
1580       my $val            = $datum->[$col_idx];
1581       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1582       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1583
1584       if ($is_literal_sql) {
1585         if (not ref $val) {
1586           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1587         }
1588         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1589           $bad_slice->("$reftype reference found where literal SQL expected",
1590             $col_idx, $datum_idx);
1591         }
1592         elsif ($$val ne $$sqla_bind){
1593           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1594             $col_idx, $datum_idx);
1595         }
1596       }
1597       elsif (my $reftype = ref $val) {
1598         require overload;
1599         if (overload::Method($val, '""')) {
1600           $datum->[$col_idx] = "".$val;
1601         }
1602         else {
1603           $bad_slice->("$reftype reference found where bind expected",
1604             $col_idx, $datum_idx);
1605         }
1606       }
1607     }
1608   }
1609
1610   my ($sql, $bind) = $self->_prep_for_execute (
1611     'insert', undef, $source, [\%colvalues]
1612   );
1613   my @bind = @$bind;
1614
1615   my $empty_bind = 1 if (not @bind) &&
1616     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1617
1618   if ((not @bind) && (not $empty_bind)) {
1619     $self->throw_exception(
1620       'Cannot insert_bulk without support for placeholders'
1621     );
1622   }
1623
1624   # neither _execute_array, nor _execute_inserts_with_no_binds are
1625   # atomic (even if _execute _array is a single call). Thus a safety
1626   # scope guard
1627   my $guard = $self->txn_scope_guard;
1628
1629   $self->_query_start( $sql, ['__BULK__'] );
1630   my $sth = $self->sth($sql);
1631   my $rv = do {
1632     if ($empty_bind) {
1633       # bind_param_array doesn't work if there are no binds
1634       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1635     }
1636     else {
1637 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1638       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1639     }
1640   };
1641
1642   $self->_query_end( $sql, ['__BULK__'] );
1643
1644   $guard->commit;
1645
1646   return (wantarray ? ($rv, $sth, @bind) : $rv);
1647 }
1648
1649 sub _execute_array {
1650   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1651
1652   ## This must be an arrayref, else nothing works!
1653   my $tuple_status = [];
1654
1655   ## Get the bind_attributes, if any exist
1656   my $bind_attributes = $self->source_bind_attributes($source);
1657
1658   ## Bind the values and execute
1659   my $placeholder_index = 1;
1660
1661   foreach my $bound (@$bind) {
1662
1663     my $attributes = {};
1664     my ($column_name, $data_index) = @$bound;
1665
1666     if( $bind_attributes ) {
1667       $attributes = $bind_attributes->{$column_name}
1668       if defined $bind_attributes->{$column_name};
1669     }
1670
1671     my @data = map { $_->[$data_index] } @$data;
1672
1673     $sth->bind_param_array(
1674       $placeholder_index,
1675       [@data],
1676       (%$attributes ?  $attributes : ()),
1677     );
1678     $placeholder_index++;
1679   }
1680
1681   my ($rv, $err);
1682   try {
1683     $rv = $self->_dbh_execute_array($sth, $tuple_status, @extra);
1684   }
1685   catch {
1686     $err = shift;
1687   }
1688   finally {
1689     # Statement must finish even if there was an exception.
1690     try {
1691       $sth->finish
1692     }
1693     catch {
1694       $err = shift unless defined $err
1695     };
1696   };
1697
1698   $err = $sth->errstr
1699     if (! defined $err and $sth->err);
1700
1701   if (defined $err) {
1702     my $i = 0;
1703     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1704
1705     $self->throw_exception("Unexpected populate error: $err")
1706       if ($i > $#$tuple_status);
1707
1708     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1709       ($tuple_status->[$i][1] || $err),
1710       Dumper { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) },
1711     );
1712   }
1713
1714   return $rv;
1715 }
1716
1717 sub _dbh_execute_array {
1718     my ($self, $sth, $tuple_status, @extra) = @_;
1719
1720     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1721 }
1722
1723 sub _dbh_execute_inserts_with_no_binds {
1724   my ($self, $sth, $count) = @_;
1725
1726   my $err;
1727   try {
1728     my $dbh = $self->_get_dbh;
1729     local $dbh->{RaiseError} = 1;
1730     local $dbh->{PrintError} = 0;
1731
1732     $sth->execute foreach 1..$count;
1733   }
1734   catch {
1735     $err = shift;
1736   }
1737   finally {
1738     # Make sure statement is finished even if there was an exception.
1739     try {
1740       $sth->finish
1741     }
1742     catch {
1743       $err = shift unless defined $err;
1744     };
1745   };
1746
1747   $self->throw_exception($err) if defined $err;
1748
1749   return $count;
1750 }
1751
1752 sub update {
1753   my ($self, $source, @args) = @_;
1754
1755   my $bind_attrs = $self->source_bind_attributes($source);
1756
1757   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1758 }
1759
1760
1761 sub delete {
1762   my ($self, $source, @args) = @_;
1763
1764   my $bind_attrs = $self->source_bind_attributes($source);
1765
1766   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1767 }
1768
1769 # We were sent here because the $rs contains a complex search
1770 # which will require a subquery to select the correct rows
1771 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1772 #
1773 # Generating a single PK column subquery is trivial and supported
1774 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1775 # Look at _multipk_update_delete()
1776 sub _subq_update_delete {
1777   my $self = shift;
1778   my ($rs, $op, $values) = @_;
1779
1780   my $rsrc = $rs->result_source;
1781
1782   # quick check if we got a sane rs on our hands
1783   my @pcols = $rsrc->_pri_cols;
1784
1785   my $sel = $rs->_resolved_attrs->{select};
1786   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1787
1788   if (
1789       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1790         ne
1791       join ("\x00", sort @$sel )
1792   ) {
1793     $self->throw_exception (
1794       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1795     );
1796   }
1797
1798   if (@pcols == 1) {
1799     return $self->$op (
1800       $rsrc,
1801       $op eq 'update' ? $values : (),
1802       { $pcols[0] => { -in => $rs->as_query } },
1803     );
1804   }
1805
1806   else {
1807     return $self->_multipk_update_delete (@_);
1808   }
1809 }
1810
1811 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1812 # resultset update/delete involving subqueries. So by default resort
1813 # to simple (and inefficient) delete_all style per-row opearations,
1814 # while allowing specific storages to override this with a faster
1815 # implementation.
1816 #
1817 sub _multipk_update_delete {
1818   return shift->_per_row_update_delete (@_);
1819 }
1820
1821 # This is the default loop used to delete/update rows for multi PK
1822 # resultsets, and used by mysql exclusively (because it can't do anything
1823 # else).
1824 #
1825 # We do not use $row->$op style queries, because resultset update/delete
1826 # is not expected to cascade (this is what delete_all/update_all is for).
1827 #
1828 # There should be no race conditions as the entire operation is rolled
1829 # in a transaction.
1830 #
1831 sub _per_row_update_delete {
1832   my $self = shift;
1833   my ($rs, $op, $values) = @_;
1834
1835   my $rsrc = $rs->result_source;
1836   my @pcols = $rsrc->_pri_cols;
1837
1838   my $guard = $self->txn_scope_guard;
1839
1840   # emulate the return value of $sth->execute for non-selects
1841   my $row_cnt = '0E0';
1842
1843   my $subrs_cur = $rs->cursor;
1844   my @all_pk = $subrs_cur->all;
1845   for my $pks ( @all_pk) {
1846
1847     my $cond;
1848     for my $i (0.. $#pcols) {
1849       $cond->{$pcols[$i]} = $pks->[$i];
1850     }
1851
1852     $self->$op (
1853       $rsrc,
1854       $op eq 'update' ? $values : (),
1855       $cond,
1856     );
1857
1858     $row_cnt++;
1859   }
1860
1861   $guard->commit;
1862
1863   return $row_cnt;
1864 }
1865
1866 sub _select {
1867   my $self = shift;
1868   $self->_execute($self->_select_args(@_));
1869 }
1870
1871 sub _select_args_to_query {
1872   my $self = shift;
1873
1874   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $rs_attrs, $rows, $offset)
1875   #  = $self->_select_args($ident, $select, $cond, $attrs);
1876   my ($op, $bind, $ident, $bind_attrs, @args) =
1877     $self->_select_args(@_);
1878
1879   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
1880   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1881   $prepared_bind ||= [];
1882
1883   return wantarray
1884     ? ($sql, $prepared_bind, $bind_attrs)
1885     : \[ "($sql)", @$prepared_bind ]
1886   ;
1887 }
1888
1889 sub _select_args {
1890   my ($self, $ident, $select, $where, $attrs) = @_;
1891
1892   my $sql_maker = $self->sql_maker;
1893   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1894
1895   $attrs = {
1896     %$attrs,
1897     select => $select,
1898     from => $ident,
1899     where => $where,
1900     $rs_alias && $alias2source->{$rs_alias}
1901       ? ( _rsroot_source_handle => $alias2source->{$rs_alias}->handle )
1902       : ()
1903     ,
1904   };
1905
1906   # calculate bind_attrs before possible $ident mangling
1907   my $bind_attrs = {};
1908   for my $alias (keys %$alias2source) {
1909     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1910     for my $col (keys %$bindtypes) {
1911
1912       my $fqcn = join ('.', $alias, $col);
1913       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1914
1915       # Unqialified column names are nice, but at the same time can be
1916       # rather ambiguous. What we do here is basically go along with
1917       # the loop, adding an unqualified column slot to $bind_attrs,
1918       # alongside the fully qualified name. As soon as we encounter
1919       # another column by that name (which would imply another table)
1920       # we unset the unqualified slot and never add any info to it
1921       # to avoid erroneous type binding. If this happens the users
1922       # only choice will be to fully qualify his column name
1923
1924       if (exists $bind_attrs->{$col}) {
1925         $bind_attrs->{$col} = {};
1926       }
1927       else {
1928         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1929       }
1930     }
1931   }
1932
1933   # adjust limits
1934   if (defined $attrs->{rows}) {
1935     $self->throw_exception("rows attribute must be positive if present")
1936       unless $attrs->{rows} > 0;
1937   }
1938   elsif (defined $attrs->{offset}) {
1939     # MySQL actually recommends this approach.  I cringe.
1940     $attrs->{rows} = $sql_maker->__max_int;
1941   }
1942
1943   my @limit;
1944
1945   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1946   # storage, unless software limit was requested
1947   if (
1948     #limited has_many
1949     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1950        ||
1951     # grouped prefetch (to satisfy group_by == select)
1952     ( $attrs->{group_by}
1953         &&
1954       @{$attrs->{group_by}}
1955         &&
1956       $attrs->{_prefetch_select}
1957         &&
1958       @{$attrs->{_prefetch_select}}
1959     )
1960   ) {
1961     ($ident, $select, $where, $attrs)
1962       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1963   }
1964   elsif (! $attrs->{software_limit} ) {
1965     push @limit, $attrs->{rows}, $attrs->{offset};
1966   }
1967
1968   # try to simplify the joinmap further (prune unreferenced type-single joins)
1969   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1970
1971 ###
1972   # This would be the point to deflate anything found in $where
1973   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1974   # expect a row object. And all we have is a resultsource (it is trivial
1975   # to extract deflator coderefs via $alias2source above).
1976   #
1977   # I don't see a way forward other than changing the way deflators are
1978   # invoked, and that's just bad...
1979 ###
1980
1981   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $attrs, @limit);
1982 }
1983
1984 # Returns a counting SELECT for a simple count
1985 # query. Abstracted so that a storage could override
1986 # this to { count => 'firstcol' } or whatever makes
1987 # sense as a performance optimization
1988 sub _count_select {
1989   #my ($self, $source, $rs_attrs) = @_;
1990   return { count => '*' };
1991 }
1992
1993
1994 sub source_bind_attributes {
1995   my ($self, $source) = @_;
1996
1997   my $bind_attributes;
1998   foreach my $column ($source->columns) {
1999
2000     my $data_type = $source->column_info($column)->{data_type} || '';
2001     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
2002      if $data_type;
2003   }
2004
2005   return $bind_attributes;
2006 }
2007
2008 =head2 select
2009
2010 =over 4
2011
2012 =item Arguments: $ident, $select, $condition, $attrs
2013
2014 =back
2015
2016 Handle a SQL select statement.
2017
2018 =cut
2019
2020 sub select {
2021   my $self = shift;
2022   my ($ident, $select, $condition, $attrs) = @_;
2023   return $self->cursor_class->new($self, \@_, $attrs);
2024 }
2025
2026 sub select_single {
2027   my $self = shift;
2028   my ($rv, $sth, @bind) = $self->_select(@_);
2029   my @row = $sth->fetchrow_array;
2030   my @nextrow = $sth->fetchrow_array if @row;
2031   if(@row && @nextrow) {
2032     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2033   }
2034   # Need to call finish() to work round broken DBDs
2035   $sth->finish();
2036   return @row;
2037 }
2038
2039 =head2 sth
2040
2041 =over 4
2042
2043 =item Arguments: $sql
2044
2045 =back
2046
2047 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2048
2049 =cut
2050
2051 sub _dbh_sth {
2052   my ($self, $dbh, $sql) = @_;
2053
2054   # 3 is the if_active parameter which avoids active sth re-use
2055   my $sth = $self->disable_sth_caching
2056     ? $dbh->prepare($sql)
2057     : $dbh->prepare_cached($sql, {}, 3);
2058
2059   # XXX You would think RaiseError would make this impossible,
2060   #  but apparently that's not true :(
2061   $self->throw_exception($dbh->errstr) if !$sth;
2062
2063   $sth;
2064 }
2065
2066 sub sth {
2067   my ($self, $sql) = @_;
2068   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2069 }
2070
2071 sub _dbh_columns_info_for {
2072   my ($self, $dbh, $table) = @_;
2073
2074   if ($dbh->can('column_info')) {
2075     my %result;
2076     my $caught;
2077     try {
2078       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2079       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2080       $sth->execute();
2081       while ( my $info = $sth->fetchrow_hashref() ){
2082         my %column_info;
2083         $column_info{data_type}   = $info->{TYPE_NAME};
2084         $column_info{size}      = $info->{COLUMN_SIZE};
2085         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2086         $column_info{default_value} = $info->{COLUMN_DEF};
2087         my $col_name = $info->{COLUMN_NAME};
2088         $col_name =~ s/^\"(.*)\"$/$1/;
2089
2090         $result{$col_name} = \%column_info;
2091       }
2092     } catch {
2093       $caught = 1;
2094     };
2095     return \%result if !$caught && scalar keys %result;
2096   }
2097
2098   my %result;
2099   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2100   $sth->execute;
2101   my @columns = @{$sth->{NAME_lc}};
2102   for my $i ( 0 .. $#columns ){
2103     my %column_info;
2104     $column_info{data_type} = $sth->{TYPE}->[$i];
2105     $column_info{size} = $sth->{PRECISION}->[$i];
2106     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2107
2108     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2109       $column_info{data_type} = $1;
2110       $column_info{size}    = $2;
2111     }
2112
2113     $result{$columns[$i]} = \%column_info;
2114   }
2115   $sth->finish;
2116
2117   foreach my $col (keys %result) {
2118     my $colinfo = $result{$col};
2119     my $type_num = $colinfo->{data_type};
2120     my $type_name;
2121     if(defined $type_num && $dbh->can('type_info')) {
2122       my $type_info = $dbh->type_info($type_num);
2123       $type_name = $type_info->{TYPE_NAME} if $type_info;
2124       $colinfo->{data_type} = $type_name if $type_name;
2125     }
2126   }
2127
2128   return \%result;
2129 }
2130
2131 sub columns_info_for {
2132   my ($self, $table) = @_;
2133   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2134 }
2135
2136 =head2 last_insert_id
2137
2138 Return the row id of the last insert.
2139
2140 =cut
2141
2142 sub _dbh_last_insert_id {
2143     my ($self, $dbh, $source, $col) = @_;
2144
2145     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2146
2147     return $id if defined $id;
2148
2149     my $class = ref $self;
2150     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2151 }
2152
2153 sub last_insert_id {
2154   my $self = shift;
2155   $self->_dbh_last_insert_id ($self->_dbh, @_);
2156 }
2157
2158 =head2 _native_data_type
2159
2160 =over 4
2161
2162 =item Arguments: $type_name
2163
2164 =back
2165
2166 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2167 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2168 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2169
2170 The default implementation returns C<undef>, implement in your Storage driver if
2171 you need this functionality.
2172
2173 Should map types from other databases to the native RDBMS type, for example
2174 C<VARCHAR2> to C<VARCHAR>.
2175
2176 Types with modifiers should map to the underlying data type. For example,
2177 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2178
2179 Composite types should map to the container type, for example
2180 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2181
2182 =cut
2183
2184 sub _native_data_type {
2185   #my ($self, $data_type) = @_;
2186   return undef
2187 }
2188
2189 # Check if placeholders are supported at all
2190 sub _placeholders_supported {
2191   my $self = shift;
2192   my $dbh  = $self->_get_dbh;
2193
2194   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2195   # but it is inaccurate more often than not
2196   return try {
2197     local $dbh->{PrintError} = 0;
2198     local $dbh->{RaiseError} = 1;
2199     $dbh->do('select ?', {}, 1);
2200     1;
2201   }
2202   catch {
2203     0;
2204   };
2205 }
2206
2207 # Check if placeholders bound to non-string types throw exceptions
2208 #
2209 sub _typeless_placeholders_supported {
2210   my $self = shift;
2211   my $dbh  = $self->_get_dbh;
2212
2213   return try {
2214     local $dbh->{PrintError} = 0;
2215     local $dbh->{RaiseError} = 1;
2216     # this specifically tests a bind that is NOT a string
2217     $dbh->do('select 1 where 1 = ?', {}, 1);
2218     1;
2219   }
2220   catch {
2221     0;
2222   };
2223 }
2224
2225 =head2 sqlt_type
2226
2227 Returns the database driver name.
2228
2229 =cut
2230
2231 sub sqlt_type {
2232   shift->_get_dbh->{Driver}->{Name};
2233 }
2234
2235 =head2 bind_attribute_by_data_type
2236
2237 Given a datatype from column info, returns a database specific bind
2238 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2239 let the database planner just handle it.
2240
2241 Generally only needed for special case column types, like bytea in postgres.
2242
2243 =cut
2244
2245 sub bind_attribute_by_data_type {
2246     return;
2247 }
2248
2249 =head2 is_datatype_numeric
2250
2251 Given a datatype from column_info, returns a boolean value indicating if
2252 the current RDBMS considers it a numeric value. This controls how
2253 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2254 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2255 be performed instead of the usual C<eq>.
2256
2257 =cut
2258
2259 sub is_datatype_numeric {
2260   my ($self, $dt) = @_;
2261
2262   return 0 unless $dt;
2263
2264   return $dt =~ /^ (?:
2265     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2266   ) $/ix;
2267 }
2268
2269
2270 =head2 create_ddl_dir
2271
2272 =over 4
2273
2274 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2275
2276 =back
2277
2278 Creates a SQL file based on the Schema, for each of the specified
2279 database engines in C<\@databases> in the given directory.
2280 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2281
2282 Given a previous version number, this will also create a file containing
2283 the ALTER TABLE statements to transform the previous schema into the
2284 current one. Note that these statements may contain C<DROP TABLE> or
2285 C<DROP COLUMN> statements that can potentially destroy data.
2286
2287 The file names are created using the C<ddl_filename> method below, please
2288 override this method in your schema if you would like a different file
2289 name format. For the ALTER file, the same format is used, replacing
2290 $version in the name with "$preversion-$version".
2291
2292 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2293 The most common value for this would be C<< { add_drop_table => 1 } >>
2294 to have the SQL produced include a C<DROP TABLE> statement for each table
2295 created. For quoting purposes supply C<quote_table_names> and
2296 C<quote_field_names>.
2297
2298 If no arguments are passed, then the following default values are assumed:
2299
2300 =over 4
2301
2302 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2303
2304 =item version    - $schema->schema_version
2305
2306 =item directory  - './'
2307
2308 =item preversion - <none>
2309
2310 =back
2311
2312 By default, C<\%sqlt_args> will have
2313
2314  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2315
2316 merged with the hash passed in. To disable any of those features, pass in a
2317 hashref like the following
2318
2319  { ignore_constraint_names => 0, # ... other options }
2320
2321
2322 WARNING: You are strongly advised to check all SQL files created, before applying
2323 them.
2324
2325 =cut
2326
2327 sub create_ddl_dir {
2328   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2329
2330   unless ($dir) {
2331     carp "No directory given, using ./\n";
2332     $dir = './';
2333   } else {
2334       -d $dir
2335         or
2336       make_path ("$dir")  # make_path does not like objects (i.e. Path::Class::Dir)
2337         or
2338       $self->throw_exception(
2339         "Failed to create '$dir': " . ($! || $@ || 'error unknow')
2340       );
2341   }
2342
2343   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2344
2345   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2346   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2347
2348   my $schema_version = $schema->schema_version || '1.x';
2349   $version ||= $schema_version;
2350
2351   $sqltargs = {
2352     add_drop_table => 1,
2353     ignore_constraint_names => 1,
2354     ignore_index_names => 1,
2355     %{$sqltargs || {}}
2356   };
2357
2358   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2359     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2360   }
2361
2362   my $sqlt = SQL::Translator->new( $sqltargs );
2363
2364   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2365   my $sqlt_schema = $sqlt->translate({ data => $schema })
2366     or $self->throw_exception ($sqlt->error);
2367
2368   foreach my $db (@$databases) {
2369     $sqlt->reset();
2370     $sqlt->{schema} = $sqlt_schema;
2371     $sqlt->producer($db);
2372
2373     my $file;
2374     my $filename = $schema->ddl_filename($db, $version, $dir);
2375     if (-e $filename && ($version eq $schema_version )) {
2376       # if we are dumping the current version, overwrite the DDL
2377       carp "Overwriting existing DDL file - $filename";
2378       unlink($filename);
2379     }
2380
2381     my $output = $sqlt->translate;
2382     if(!$output) {
2383       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2384       next;
2385     }
2386     if(!open($file, ">$filename")) {
2387       $self->throw_exception("Can't open $filename for writing ($!)");
2388       next;
2389     }
2390     print $file $output;
2391     close($file);
2392
2393     next unless ($preversion);
2394
2395     require SQL::Translator::Diff;
2396
2397     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2398     if(!-e $prefilename) {
2399       carp("No previous schema file found ($prefilename)");
2400       next;
2401     }
2402
2403     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2404     if(-e $difffile) {
2405       carp("Overwriting existing diff file - $difffile");
2406       unlink($difffile);
2407     }
2408
2409     my $source_schema;
2410     {
2411       my $t = SQL::Translator->new($sqltargs);
2412       $t->debug( 0 );
2413       $t->trace( 0 );
2414
2415       $t->parser( $db )
2416         or $self->throw_exception ($t->error);
2417
2418       my $out = $t->translate( $prefilename )
2419         or $self->throw_exception ($t->error);
2420
2421       $source_schema = $t->schema;
2422
2423       $source_schema->name( $prefilename )
2424         unless ( $source_schema->name );
2425     }
2426
2427     # The "new" style of producers have sane normalization and can support
2428     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2429     # And we have to diff parsed SQL against parsed SQL.
2430     my $dest_schema = $sqlt_schema;
2431
2432     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2433       my $t = SQL::Translator->new($sqltargs);
2434       $t->debug( 0 );
2435       $t->trace( 0 );
2436
2437       $t->parser( $db )
2438         or $self->throw_exception ($t->error);
2439
2440       my $out = $t->translate( $filename )
2441         or $self->throw_exception ($t->error);
2442
2443       $dest_schema = $t->schema;
2444
2445       $dest_schema->name( $filename )
2446         unless $dest_schema->name;
2447     }
2448
2449     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2450                                                   $dest_schema,   $db,
2451                                                   $sqltargs
2452                                                  );
2453     if(!open $file, ">$difffile") {
2454       $self->throw_exception("Can't write to $difffile ($!)");
2455       next;
2456     }
2457     print $file $diff;
2458     close($file);
2459   }
2460 }
2461
2462 =head2 deployment_statements
2463
2464 =over 4
2465
2466 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2467
2468 =back
2469
2470 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2471
2472 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2473 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2474
2475 C<$directory> is used to return statements from files in a previously created
2476 L</create_ddl_dir> directory and is optional. The filenames are constructed
2477 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2478
2479 If no C<$directory> is specified then the statements are constructed on the
2480 fly using L<SQL::Translator> and C<$version> is ignored.
2481
2482 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2483
2484 =cut
2485
2486 sub deployment_statements {
2487   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2488   $type ||= $self->sqlt_type;
2489   $version ||= $schema->schema_version || '1.x';
2490   $dir ||= './';
2491   my $filename = $schema->ddl_filename($type, $version, $dir);
2492   if(-f $filename)
2493   {
2494       my $file;
2495       open($file, "<$filename")
2496         or $self->throw_exception("Can't open $filename ($!)");
2497       my @rows = <$file>;
2498       close($file);
2499       return join('', @rows);
2500   }
2501
2502   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2503     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2504   }
2505
2506   # sources needs to be a parser arg, but for simplicty allow at top level
2507   # coming in
2508   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2509       if exists $sqltargs->{sources};
2510
2511   my $tr = SQL::Translator->new(
2512     producer => "SQL::Translator::Producer::${type}",
2513     %$sqltargs,
2514     parser => 'SQL::Translator::Parser::DBIx::Class',
2515     data => $schema,
2516   );
2517
2518   my @ret;
2519   my $wa = wantarray;
2520   if ($wa) {
2521     @ret = $tr->translate;
2522   }
2523   else {
2524     $ret[0] = $tr->translate;
2525   }
2526
2527   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2528     unless (@ret && defined $ret[0]);
2529
2530   return $wa ? @ret : $ret[0];
2531 }
2532
2533 sub deploy {
2534   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2535   my $deploy = sub {
2536     my $line = shift;
2537     return if($line =~ /^--/);
2538     return if(!$line);
2539     # next if($line =~ /^DROP/m);
2540     return if($line =~ /^BEGIN TRANSACTION/m);
2541     return if($line =~ /^COMMIT/m);
2542     return if $line =~ /^\s+$/; # skip whitespace only
2543     $self->_query_start($line);
2544     try {
2545       # do a dbh_do cycle here, as we need some error checking in
2546       # place (even though we will ignore errors)
2547       $self->dbh_do (sub { $_[1]->do($line) });
2548     } catch {
2549       carp qq{$_ (running "${line}")};
2550     };
2551     $self->_query_end($line);
2552   };
2553   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2554   if (@statements > 1) {
2555     foreach my $statement (@statements) {
2556       $deploy->( $statement );
2557     }
2558   }
2559   elsif (@statements == 1) {
2560     foreach my $line ( split(";\n", $statements[0])) {
2561       $deploy->( $line );
2562     }
2563   }
2564 }
2565
2566 =head2 datetime_parser
2567
2568 Returns the datetime parser class
2569
2570 =cut
2571
2572 sub datetime_parser {
2573   my $self = shift;
2574   return $self->{datetime_parser} ||= do {
2575     $self->build_datetime_parser(@_);
2576   };
2577 }
2578
2579 =head2 datetime_parser_type
2580
2581 Defines (returns) the datetime parser class - currently hardwired to
2582 L<DateTime::Format::MySQL>
2583
2584 =cut
2585
2586 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2587
2588 =head2 build_datetime_parser
2589
2590 See L</datetime_parser>
2591
2592 =cut
2593
2594 sub build_datetime_parser {
2595   my $self = shift;
2596   my $type = $self->datetime_parser_type(@_);
2597   $self->ensure_class_loaded ($type);
2598   return $type;
2599 }
2600
2601
2602 =head2 is_replicating
2603
2604 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2605 replicate from a master database.  Default is undef, which is the result
2606 returned by databases that don't support replication.
2607
2608 =cut
2609
2610 sub is_replicating {
2611     return;
2612
2613 }
2614
2615 =head2 lag_behind_master
2616
2617 Returns a number that represents a certain amount of lag behind a master db
2618 when a given storage is replicating.  The number is database dependent, but
2619 starts at zero and increases with the amount of lag. Default in undef
2620
2621 =cut
2622
2623 sub lag_behind_master {
2624     return;
2625 }
2626
2627 =head2 relname_to_table_alias
2628
2629 =over 4
2630
2631 =item Arguments: $relname, $join_count
2632
2633 =back
2634
2635 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2636 queries.
2637
2638 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2639 way these aliases are named.
2640
2641 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2642 otherwise C<"$relname">.
2643
2644 =cut
2645
2646 sub relname_to_table_alias {
2647   my ($self, $relname, $join_count) = @_;
2648
2649   my $alias = ($join_count && $join_count > 1 ?
2650     join('_', $relname, $join_count) : $relname);
2651
2652   return $alias;
2653 }
2654
2655 1;
2656
2657 =head1 USAGE NOTES
2658
2659 =head2 DBIx::Class and AutoCommit
2660
2661 DBIx::Class can do some wonderful magic with handling exceptions,
2662 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2663 (the default) combined with C<txn_do> for transaction support.
2664
2665 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2666 in an assumed transaction between commits, and you're telling us you'd
2667 like to manage that manually.  A lot of the magic protections offered by
2668 this module will go away.  We can't protect you from exceptions due to database
2669 disconnects because we don't know anything about how to restart your
2670 transactions.  You're on your own for handling all sorts of exceptional
2671 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2672 be with raw DBI.
2673
2674
2675 =head1 AUTHORS
2676
2677 Matt S. Trout <mst@shadowcatsystems.co.uk>
2678
2679 Andy Grundman <andy@hybridized.org>
2680
2681 =head1 LICENSE
2682
2683 You may distribute this code under the same terms as Perl itself.
2684
2685 =cut