lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize detected_reinvoked_destructor);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $is_getter = $storage_accessor_idx->{$meth} ? 0 : 1;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $is_getter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # only fire when invoked on an instance, a valid class-based invocation
 129       # would e.g. be setting a default for an inherited accessor
 130       ref $_[0]
 131         and
 132       ! $_[0]->{_driver_determined}
 133         and
 134       ! $_[0]->{_in_determine_driver}
 135         and
 136       # if this is a known *setter* - just set it, no need to connect
 137       # and determine the driver
 138       ( %1$s or @_ <= 1 )
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227     local $?; # just in case the DBI destructor changes it somehow
 228
 229     # destroy just the object if not native to this process
 230     $_->_verify_pid for (grep
 231       { defined $_ }
 232       values %seek_and_destroy
 233     );
 234   }
 235
 236   sub CLONE {
 237     # As per DBI's recommendation, DBIC disconnects all handles as
 238     # soon as possible (DBIC will reconnect only on demand from within
 239     # the thread)
 240     my @instances = grep { defined $_ } values %seek_and_destroy;
 241     %seek_and_destroy = ();
 242
 243     for (@instances) {
 244       $_->_dbh(undef);
 245
 246       $_->transaction_depth(0);
 247       $_->savepoints([]);
 248
 249       # properly renumber existing refs
 250       $_->_arm_global_destructor
 251     }
 252   }
 253 }
 254
 255 sub DESTROY {
 256   return if &detected_reinvoked_destructor;
 257
 258   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 259   # some databases spew warnings on implicit disconnect
 260   local $SIG{__WARN__} = sub {};
 261   $_[0]->_dbh(undef);
 262
 263   # this op is necessary, since the very last perl runtime statement
 264   # triggers a global destruction shootout, and the $SIG localization
 265   # may very well be destroyed before perl actually gets to do the
 266   # $dbh undef
 267   1;
 268 }
 269
 270 # handle pid changes correctly - do not destroy parent's connection
 271 sub _verify_pid {
 272
 273   my $pid = $_[0]->_conn_pid;
 274
 275   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 276     $dbh->{InactiveDestroy} = 1;
 277     $_[0]->_dbh(undef);
 278     $_[0]->transaction_depth(0);
 279     $_[0]->savepoints([]);
 280   }
 281
 282   return;
 283 }
 284
 285 =head2 connect_info
 286
 287 This method is normally called by L<DBIx::Class::Schema/connection>, which
 288 encapsulates its argument list in an arrayref before passing them here.
 289
 290 The argument list may contain:
 291
 292 =over
 293
 294 =item *
 295
 296 The same 4-element argument set one would normally pass to
 297 L<DBI/connect>, optionally followed by
 298 L<extra attributes|/DBIx::Class specific connection attributes>
 299 recognized by DBIx::Class:
 300
 301   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 302
 303 =item *
 304
 305 A single code reference which returns a connected
 306 L<DBI database handle|DBI/connect> optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 308 by DBIx::Class:
 309
 310   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single hashref with all the attributes and the dsn/user/password
 315 mixed together:
 316
 317   $connect_info_args = [{
 318     dsn => $dsn,
 319     user => $user,
 320     password => $pass,
 321     %dbi_attributes,
 322     %extra_attributes,
 323   }];
 324
 325   $connect_info_args = [{
 326     dbh_maker => sub { DBI->connect (...) },
 327     %dbi_attributes,
 328     %extra_attributes,
 329   }];
 330
 331 This is particularly useful for L<Catalyst> based applications, allowing the
 332 following config (L<Config::General> style):
 333
 334   <Model::DB>
 335     schema_class   App::DB
 336     <connect_info>
 337       dsn          dbi:mysql:database=test
 338       user         testuser
 339       password     TestPass
 340       AutoCommit   1
 341     </connect_info>
 342   </Model::DB>
 343
 344 The C<dsn>/C<user>/C<password> combination can be substituted by the
 345 C<dbh_maker> key whose value is a coderef that returns a connected
 346 L<DBI database handle|DBI/connect>
 347
 348 =back
 349
 350 Please note that the L<DBI> docs recommend that you always explicitly
 351 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 352 recommends that it be set to I<1>, and that you perform transactions
 353 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 354 to I<1> if you do not do explicitly set it to zero.  This is the default
 355 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 356
 357 =head3 DBIx::Class specific connection attributes
 358
 359 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 360 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 361 the following connection options. These options can be mixed in with your other
 362 L<DBI> connection attributes, or placed in a separate hashref
 363 (C<\%extra_attributes>) as shown above.
 364
 365 Every time C<connect_info> is invoked, any previous settings for
 366 these options will be cleared before setting the new ones, regardless of
 367 whether any options are specified in the new C<connect_info>.
 368
 369
 370 =over
 371
 372 =item on_connect_do
 373
 374 Specifies things to do immediately after connecting or re-connecting to
 375 the database.  Its value may contain:
 376
 377 =over
 378
 379 =item a scalar
 380
 381 This contains one SQL statement to execute.
 382
 383 =item an array reference
 384
 385 This contains SQL statements to execute in order.  Each element contains
 386 a string or a code reference that returns a string.
 387
 388 =item a code reference
 389
 390 This contains some code to execute.  Unlike code references within an
 391 array reference, its return value is ignored.
 392
 393 =back
 394
 395 =item on_disconnect_do
 396
 397 Takes arguments in the same form as L</on_connect_do> and executes them
 398 immediately before disconnecting from the database.
 399
 400 Note, this only runs if you explicitly call L</disconnect> on the
 401 storage object.
 402
 403 =item on_connect_call
 404
 405 A more generalized form of L</on_connect_do> that calls the specified
 406 C<connect_call_METHOD> methods in your storage driver.
 407
 408   on_connect_do => 'select 1'
 409
 410 is equivalent to:
 411
 412   on_connect_call => [ [ do_sql => 'select 1' ] ]
 413
 414 Its values may contain:
 415
 416 =over
 417
 418 =item a scalar
 419
 420 Will call the C<connect_call_METHOD> method.
 421
 422 =item a code reference
 423
 424 Will execute C<< $code->($storage) >>
 425
 426 =item an array reference
 427
 428 Each value can be a method name or code reference.
 429
 430 =item an array of arrays
 431
 432 For each array, the first item is taken to be the C<connect_call_> method name
 433 or code reference, and the rest are parameters to it.
 434
 435 =back
 436
 437 Some predefined storage methods you may use:
 438
 439 =over
 440
 441 =item do_sql
 442
 443 Executes a SQL string or a code reference that returns a SQL string. This is
 444 what L</on_connect_do> and L</on_disconnect_do> use.
 445
 446 It can take:
 447
 448 =over
 449
 450 =item a scalar
 451
 452 Will execute the scalar as SQL.
 453
 454 =item an arrayref
 455
 456 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 457 attributes hashref and bind values.
 458
 459 =item a code reference
 460
 461 Will execute C<< $code->($storage) >> and execute the return array refs as
 462 above.
 463
 464 =back
 465
 466 =item datetime_setup
 467
 468 Execute any statements necessary to initialize the database session to return
 469 and accept datetime/timestamp values used with
 470 L<DBIx::Class::InflateColumn::DateTime>.
 471
 472 Only necessary for some databases, see your specific storage driver for
 473 implementation details.
 474
 475 =back
 476
 477 =item on_disconnect_call
 478
 479 Takes arguments in the same form as L</on_connect_call> and executes them
 480 immediately before disconnecting from the database.
 481
 482 Calls the C<disconnect_call_METHOD> methods as opposed to the
 483 C<connect_call_METHOD> methods called by L</on_connect_call>.
 484
 485 Note, this only runs if you explicitly call L</disconnect> on the
 486 storage object.
 487
 488 =item disable_sth_caching
 489
 490 If set to a true value, this option will disable the caching of
 491 statement handles via L<DBI/prepare_cached>.
 492
 493 =item limit_dialect
 494
 495 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 496 default L</sql_limit_dialect> setting of the storage (if any). For a list
 497 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 498
 499 =item quote_names
 500
 501 When true automatically sets L</quote_char> and L</name_sep> to the characters
 502 appropriate for your particular RDBMS. This option is preferred over specifying
 503 L</quote_char> directly.
 504
 505 =item quote_char
 506
 507 Specifies what characters to use to quote table and column names.
 508
 509 C<quote_char> expects either a single character, in which case is it
 510 is placed on either side of the table/column name, or an arrayref of length
 511 2 in which case the table/column name is placed between the elements.
 512
 513 For example under MySQL you should use C<< quote_char => '`' >>, and for
 514 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 515
 516 =item name_sep
 517
 518 This parameter is only useful in conjunction with C<quote_char>, and is used to
 519 specify the character that separates elements (schemas, tables, columns) from
 520 each other. If unspecified it defaults to the most commonly used C<.>.
 521
 522 =item unsafe
 523
 524 This Storage driver normally installs its own C<HandleError>, sets
 525 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 526 all database handles, including those supplied by a coderef.  It does this
 527 so that it can have consistent and useful error behavior.
 528
 529 If you set this option to a true value, Storage will not do its usual
 530 modifications to the database handle's attributes, and instead relies on
 531 the settings in your connect_info DBI options (or the values you set in
 532 your connection coderef, in the case that you are connecting via coderef).
 533
 534 Note that your custom settings can cause Storage to malfunction,
 535 especially if you set a C<HandleError> handler that suppresses exceptions
 536 and/or disable C<RaiseError>.
 537
 538 =item auto_savepoint
 539
 540 If this option is true, L<DBIx::Class> will use savepoints when nesting
 541 transactions, making it possible to recover from failure in the inner
 542 transaction without having to abort all outer transactions.
 543
 544 =item cursor_class
 545
 546 Use this argument to supply a cursor class other than the default
 547 L<DBIx::Class::Storage::DBI::Cursor>.
 548
 549 =back
 550
 551 Some real-life examples of arguments to L</connect_info> and
 552 L<DBIx::Class::Schema/connect>
 553
 554   # Simple SQLite connection
 555   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 556
 557   # Connect via subref
 558   ->connect_info([ sub { DBI->connect(...) } ]);
 559
 560   # Connect via subref in hashref
 561   ->connect_info([{
 562     dbh_maker => sub { DBI->connect(...) },
 563     on_connect_do => 'alter session ...',
 564   }]);
 565
 566   # A bit more complicated
 567   ->connect_info(
 568     [
 569       'dbi:Pg:dbname=foo',
 570       'postgres',
 571       'my_pg_password',
 572       { AutoCommit => 1 },
 573       { quote_char => q{"} },
 574     ]
 575   );
 576
 577   # Equivalent to the previous example
 578   ->connect_info(
 579     [
 580       'dbi:Pg:dbname=foo',
 581       'postgres',
 582       'my_pg_password',
 583       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 584     ]
 585   );
 586
 587   # Same, but with hashref as argument
 588   # See parse_connect_info for explanation
 589   ->connect_info(
 590     [{
 591       dsn         => 'dbi:Pg:dbname=foo',
 592       user        => 'postgres',
 593       password    => 'my_pg_password',
 594       AutoCommit  => 1,
 595       quote_char  => q{"},
 596       name_sep    => q{.},
 597     }]
 598   );
 599
 600   # Subref + DBIx::Class-specific connection options
 601   ->connect_info(
 602     [
 603       sub { DBI->connect(...) },
 604       {
 605           quote_char => q{`},
 606           name_sep => q{@},
 607           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 608           disable_sth_caching => 1,
 609       },
 610     ]
 611   );
 612
 613
 614
 615 =cut
 616
 617 sub connect_info {
 618   my ($self, $info) = @_;
 619
 620   return $self->_connect_info if !$info;
 621
 622   $self->_connect_info($info); # copy for _connect_info
 623
 624   $info = $self->_normalize_connect_info($info)
 625     if ref $info eq 'ARRAY';
 626
 627   my %attrs = (
 628     %{ $self->_default_dbi_connect_attributes || {} },
 629     %{ $info->{attributes} || {} },
 630   );
 631
 632   my @args = @{ $info->{arguments} };
 633
 634   if (keys %attrs and ref $args[0] ne 'CODE') {
 635     carp_unique (
 636         'You provided explicit AutoCommit => 0 in your connection_info. '
 637       . 'This is almost universally a bad idea (see the footnotes of '
 638       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 639       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 640       . 'this warning.'
 641     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 642
 643     push @args, \%attrs if keys %attrs;
 644   }
 645
 646   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 647   # OR a single-element coderef-based $dbh factory
 648   $self->_dbi_connect_info(\@args);
 649
 650   # extract the individual storage options
 651   for my $storage_opt (keys %{ $info->{storage_options} }) {
 652     my $value = $info->{storage_options}{$storage_opt};
 653
 654     $self->$storage_opt($value);
 655   }
 656
 657   # Extract the individual sqlmaker options
 658   #
 659   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 660   #  the new set of options
 661   $self->_sql_maker(undef);
 662   $self->_sql_maker_opts({});
 663
 664   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 665     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 666
 667     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 668   }
 669
 670   # FIXME - dirty:
 671   # save attributes in a separate accessor so they are always
 672   # introspectable, even in case of a CODE $dbhmaker
 673   $self->_dbic_connect_attributes (\%attrs);
 674
 675   return $self->_connect_info;
 676 }
 677
 678 sub _dbi_connect_info {
 679   my $self = shift;
 680
 681   return $self->{_dbi_connect_info} = $_[0]
 682     if @_;
 683
 684   my $conninfo = $self->{_dbi_connect_info} || [];
 685
 686   # last ditch effort to grab a DSN
 687   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 688     my @new_conninfo = @$conninfo;
 689     $new_conninfo[0] = $ENV{DBI_DSN};
 690     $conninfo = \@new_conninfo;
 691   }
 692
 693   return $conninfo;
 694 }
 695
 696
 697 sub _normalize_connect_info {
 698   my ($self, $info_arg) = @_;
 699   my %info;
 700
 701   my @args = @$info_arg;  # take a shallow copy for further mutilation
 702
 703   # combine/pre-parse arguments depending on invocation style
 704
 705   my %attrs;
 706   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 707     %attrs = %{ $args[1] || {} };
 708     @args = $args[0];
 709   }
 710   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 711     %attrs = %{$args[0]};
 712     @args = ();
 713     if (my $code = delete $attrs{dbh_maker}) {
 714       @args = $code;
 715
 716       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 717       if (@ignored) {
 718         carp sprintf (
 719             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 720           . "to the result of 'dbh_maker'",
 721
 722           join (', ', map { "'$_'" } (@ignored) ),
 723         );
 724       }
 725     }
 726     else {
 727       @args = delete @attrs{qw/dsn user password/};
 728     }
 729   }
 730   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 731     %attrs = (
 732       % { $args[3] || {} },
 733       % { $args[4] || {} },
 734     );
 735     @args = @args[0,1,2];
 736   }
 737
 738   $info{arguments} = \@args;
 739
 740   my @storage_opts = grep exists $attrs{$_},
 741     @storage_options, 'cursor_class';
 742
 743   @{ $info{storage_options} }{@storage_opts} =
 744     delete @attrs{@storage_opts} if @storage_opts;
 745
 746   my @sql_maker_opts = grep exists $attrs{$_},
 747     qw/limit_dialect quote_char name_sep quote_names/;
 748
 749   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 750     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 751
 752   $info{attributes} = \%attrs if %attrs;
 753
 754   return \%info;
 755 }
 756
 757 sub _default_dbi_connect_attributes () {
 758   +{
 759     AutoCommit => 1,
 760     PrintError => 0,
 761     RaiseError => 1,
 762     ShowErrorStatement => 1,
 763   };
 764 }
 765
 766 =head2 on_connect_do
 767
 768 This method is deprecated in favour of setting via L</connect_info>.
 769
 770 =cut
 771
 772 =head2 on_disconnect_do
 773
 774 This method is deprecated in favour of setting via L</connect_info>.
 775
 776 =cut
 777
 778 sub _parse_connect_do {
 779   my ($self, $type) = @_;
 780
 781   my $val = $self->$type;
 782   return () if not defined $val;
 783
 784   my @res;
 785
 786   if (not ref($val)) {
 787     push @res, [ 'do_sql', $val ];
 788   } elsif (ref($val) eq 'CODE') {
 789     push @res, $val;
 790   } elsif (ref($val) eq 'ARRAY') {
 791     push @res, map { [ 'do_sql', $_ ] } @$val;
 792   } else {
 793     $self->throw_exception("Invalid type for $type: ".ref($val));
 794   }
 795
 796   return \@res;
 797 }
 798
 799 =head2 dbh_do
 800
 801 Arguments: ($subref | $method_name), @extra_coderef_args?
 802
 803 Execute the given $subref or $method_name using the new exception-based
 804 connection management.
 805
 806 The first two arguments will be the storage object that C<dbh_do> was called
 807 on and a database handle to use.  Any additional arguments will be passed
 808 verbatim to the called subref as arguments 2 and onwards.
 809
 810 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 811 exception handling and reconnection (or failover in future subclasses).
 812
 813 Your subref should have no side-effects outside of the database, as
 814 there is the potential for your subref to be partially double-executed
 815 if the database connection was stale/dysfunctional.
 816
 817 Example:
 818
 819   my @stuff = $schema->storage->dbh_do(
 820     sub {
 821       my ($storage, $dbh, @cols) = @_;
 822       my $cols = join(q{, }, @cols);
 823       $dbh->selectrow_array("SELECT $cols FROM foo");
 824     },
 825     @column_list
 826   );
 827
 828 =cut
 829
 830 sub dbh_do {
 831   my $self = shift;
 832   my $run_target = shift; # either a coderef or a method name
 833
 834   # short circuit when we know there is no need for a runner
 835   #
 836   # FIXME - assumption may be wrong
 837   # the rationale for the txn_depth check is that if this block is a part
 838   # of a larger transaction, everything up to that point is screwed anyway
 839   return $self->$run_target($self->_get_dbh, @_)
 840     if $self->{_in_do_block} or $self->transaction_depth;
 841
 842   # take a ref instead of a copy, to preserve @_ aliasing
 843   # semantics within the coderef, but only if needed
 844   # (pseudoforking doesn't like this trick much)
 845   my $args = @_ ? \@_ : [];
 846
 847   DBIx::Class::Storage::BlockRunner->new(
 848     storage => $self,
 849     wrap_txn => 0,
 850     retry_handler => sub {
 851       $_[0]->failed_attempt_count == 1
 852         and
 853       ! $_[0]->storage->connected
 854     },
 855   )->run(sub {
 856     $self->$run_target ($self->_get_dbh, @$args )
 857   });
 858 }
 859
 860 sub txn_do {
 861   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 862   shift->next::method(@_);
 863 }
 864
 865 =head2 disconnect
 866
 867 Our C<disconnect> method also performs a rollback first if the
 868 database is not in C<AutoCommit> mode.
 869
 870 =cut
 871
 872 sub disconnect {
 873
 874   if( my $dbh = $_[0]->_dbh ) {
 875
 876     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 877       ( $_[0]->on_disconnect_call || () ),
 878       $_[0]->_parse_connect_do ('on_disconnect_do')
 879     );
 880
 881     # stops the "implicit rollback on disconnect" warning
 882     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 883
 884     %{ $dbh->{CachedKids} } = ();
 885     $dbh->disconnect;
 886     $_[0]->_dbh(undef);
 887   }
 888 }
 889
 890 =head2 with_deferred_fk_checks
 891
 892 =over 4
 893
 894 =item Arguments: C<$coderef>
 895
 896 =item Return Value: The return value of $coderef
 897
 898 =back
 899
 900 Storage specific method to run the code ref with FK checks deferred or
 901 in MySQL's case disabled entirely.
 902
 903 =cut
 904
 905 # Storage subclasses should override this
 906 sub with_deferred_fk_checks {
 907   #my ($self, $sub) = @_;
 908   $_[1]->();
 909 }
 910
 911 =head2 connected
 912
 913 =over
 914
 915 =item Arguments: none
 916
 917 =item Return Value: 1|0
 918
 919 =back
 920
 921 Verifies that the current database handle is active and ready to execute
 922 an SQL statement (e.g. the connection did not get stale, server is still
 923 answering, etc.) This method is used internally by L</dbh>.
 924
 925 =cut
 926
 927 sub connected {
 928   return 0 unless $_[0]->_seems_connected;
 929
 930   #be on the safe side
 931   local $_[0]->_dbh->{RaiseError} = 1;
 932
 933   return $_[0]->_ping;
 934 }
 935
 936 sub _seems_connected {
 937   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 938
 939   ($_[0]->_dbh || return 0)->FETCH('Active');
 940 }
 941
 942 sub _ping {
 943   ($_[0]->_dbh || return 0)->ping;
 944 }
 945
 946 sub ensure_connected {
 947   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 948 }
 949
 950 =head2 dbh
 951
 952 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 953 is guaranteed to be healthy by implicitly calling L</connected>, and if
 954 necessary performing a reconnection before returning. Keep in mind that this
 955 is very B<expensive> on some database engines. Consider using L</dbh_do>
 956 instead.
 957
 958 =cut
 959
 960 sub dbh {
 961   # maybe save a ping call
 962   $_[0]->_dbh
 963     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 964     : $_[0]->_populate_dbh
 965   ;
 966 }
 967
 968 # this is the internal "get dbh or connect (don't check)" method
 969 sub _get_dbh {
 970   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 971   $_[0]->_dbh || $_[0]->_populate_dbh;
 972 }
 973
 974 # *DELIBERATELY* not a setter (for the time being)
 975 # Too intertwined with everything else for any kind of sanity
 976 sub sql_maker {
 977   my $self = shift;
 978
 979   $self->throw_exception('sql_maker() is not a setter method') if @_;
 980
 981   unless ($self->_sql_maker) {
 982     my $sql_maker_class = $self->sql_maker_class;
 983
 984     my %opts = %{$self->_sql_maker_opts||{}};
 985     my $dialect =
 986       $opts{limit_dialect}
 987         ||
 988       $self->sql_limit_dialect
 989         ||
 990       do {
 991         my $s_class = (ref $self) || $self;
 992         carp_unique (
 993           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 994         . 'have not supplied an explicit limit_dialect in your connection_info. '
 995         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 996         . 'databases but can be (and often is) painfully slow. '
 997         . "Please file an RT ticket against '$s_class'"
 998         ) if $self->_dbi_connect_info->[0];
 999
1000         'GenericSubQ';
1001       }
1002     ;
1003
1004     my ($quote_char, $name_sep);
1005
1006     if ($opts{quote_names}) {
1007       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1008         my $s_class = (ref $self) || $self;
1009         carp_unique (
1010           "You requested 'quote_names' but your storage class ($s_class) does "
1011         . 'not explicitly define a default sql_quote_char and you have not '
1012         . 'supplied a quote_char as part of your connection_info. DBIC will '
1013         .q{default to the ANSI SQL standard quote '"', which works most of }
1014         . "the time. Please file an RT ticket against '$s_class'."
1015         );
1016
1017         '"'; # RV
1018       };
1019
1020       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1021     }
1022
1023     $self->_sql_maker($sql_maker_class->new(
1024       bindtype=>'columns',
1025       array_datatypes => 1,
1026       limit_dialect => $dialect,
1027       ($quote_char ? (quote_char => $quote_char) : ()),
1028       name_sep => ($name_sep || '.'),
1029       %opts,
1030     ));
1031   }
1032   return $self->_sql_maker;
1033 }
1034
1035 # nothing to do by default
1036 sub _rebless {}
1037 sub _init {}
1038
1039 sub _populate_dbh {
1040
1041   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1042
1043   $_[0]->_dbh_details({}); # reset everything we know
1044
1045   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1046   #$_[0]->_sql_maker(undef); # this may also end up being different
1047
1048   $_[0]->_dbh($_[0]->_connect);
1049
1050   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1051
1052   $_[0]->_determine_driver;
1053
1054   # Always set the transaction depth on connect, since
1055   #  there is no transaction in progress by definition
1056   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1057
1058   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1059
1060   $_[0]->_dbh;
1061 }
1062
1063 sub _run_connection_actions {
1064
1065   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1066     ( $_[0]->on_connect_call || () ),
1067     $_[0]->_parse_connect_do ('on_connect_do'),
1068   );
1069 }
1070
1071
1072
1073 sub set_use_dbms_capability {
1074   $_[0]->set_inherited ($_[1], $_[2]);
1075 }
1076
1077 sub get_use_dbms_capability {
1078   my ($self, $capname) = @_;
1079
1080   my $use = $self->get_inherited ($capname);
1081   return defined $use
1082     ? $use
1083     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1084   ;
1085 }
1086
1087 sub set_dbms_capability {
1088   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1089 }
1090
1091 sub get_dbms_capability {
1092   my ($self, $capname) = @_;
1093
1094   my $cap = $self->_dbh_details->{capability}{$capname};
1095
1096   unless (defined $cap) {
1097     if (my $meth = $self->can ("_determine$capname")) {
1098       $cap = $self->$meth ? 1 : 0;
1099     }
1100     else {
1101       $cap = 0;
1102     }
1103
1104     $self->set_dbms_capability ($capname, $cap);
1105   }
1106
1107   return $cap;
1108 }
1109
1110 sub _server_info {
1111   my $self = shift;
1112
1113   my $info;
1114   unless ($info = $self->_dbh_details->{info}) {
1115
1116     $info = {};
1117     # this guarantees that problematic conninfo won't be hidden
1118     # by the try{} below
1119     $self->ensure_connected;
1120
1121     my $server_version = try {
1122       $self->_get_server_version
1123     } catch {
1124       # driver determination *may* use this codepath
1125       # in which case we must rethrow
1126       $self->throw_exception($_) if $self->{_in_determine_driver};
1127
1128       # $server_version on failure
1129       undef;
1130     };
1131
1132     if (defined $server_version) {
1133       $info->{dbms_version} = $server_version;
1134
1135       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1136       my @verparts = split (/\./, $numeric_version);
1137       if (
1138         @verparts
1139           &&
1140         $verparts[0] <= 999
1141       ) {
1142         # consider only up to 3 version parts, iff not more than 3 digits
1143         my @use_parts;
1144         while (@verparts && @use_parts < 3) {
1145           my $p = shift @verparts;
1146           last if $p > 999;
1147           push @use_parts, $p;
1148         }
1149         push @use_parts, 0 while @use_parts < 3;
1150
1151         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1152       }
1153     }
1154
1155     $self->_dbh_details->{info} = $info;
1156   }
1157
1158   return $info;
1159 }
1160
1161 sub _get_server_version {
1162   shift->_dbh_get_info('SQL_DBMS_VER');
1163 }
1164
1165 sub _dbh_get_info {
1166   my ($self, $info) = @_;
1167
1168   if ($info =~ /[^0-9]/) {
1169     require DBI::Const::GetInfoType;
1170     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1171     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1172       unless defined $info;
1173   }
1174
1175   $self->_get_dbh->get_info($info);
1176 }
1177
1178 sub _describe_connection {
1179   require DBI::Const::GetInfoReturn;
1180
1181   my $self = shift;
1182
1183   my $drv;
1184   try {
1185     $drv = $self->_extract_driver_from_connect_info;
1186     $self->ensure_connected;
1187   };
1188
1189   $drv = "DBD::$drv" if $drv;
1190
1191   my $res = {
1192     DBIC_DSN => $self->_dbi_connect_info->[0],
1193     DBI_VER => DBI->VERSION,
1194     DBIC_VER => DBIx::Class->VERSION,
1195     DBIC_DRIVER => ref $self,
1196     $drv ? (
1197       DBD => $drv,
1198       DBD_VER => try { $drv->VERSION },
1199     ) : (),
1200   };
1201
1202   # try to grab data even if we never managed to connect
1203   # will cover us in cases of an oddly broken half-connect
1204   for my $inf (
1205     #keys %DBI::Const::GetInfoType::GetInfoType,
1206     qw/
1207       SQL_CURSOR_COMMIT_BEHAVIOR
1208       SQL_CURSOR_ROLLBACK_BEHAVIOR
1209       SQL_CURSOR_SENSITIVITY
1210       SQL_DATA_SOURCE_NAME
1211       SQL_DBMS_NAME
1212       SQL_DBMS_VER
1213       SQL_DEFAULT_TXN_ISOLATION
1214       SQL_DM_VER
1215       SQL_DRIVER_NAME
1216       SQL_DRIVER_ODBC_VER
1217       SQL_DRIVER_VER
1218       SQL_EXPRESSIONS_IN_ORDERBY
1219       SQL_GROUP_BY
1220       SQL_IDENTIFIER_CASE
1221       SQL_IDENTIFIER_QUOTE_CHAR
1222       SQL_MAX_CATALOG_NAME_LEN
1223       SQL_MAX_COLUMN_NAME_LEN
1224       SQL_MAX_IDENTIFIER_LEN
1225       SQL_MAX_TABLE_NAME_LEN
1226       SQL_MULTIPLE_ACTIVE_TXN
1227       SQL_MULT_RESULT_SETS
1228       SQL_NEED_LONG_DATA_LEN
1229       SQL_NON_NULLABLE_COLUMNS
1230       SQL_ODBC_VER
1231       SQL_QUALIFIER_NAME_SEPARATOR
1232       SQL_QUOTED_IDENTIFIER_CASE
1233       SQL_TXN_CAPABLE
1234       SQL_TXN_ISOLATION_OPTION
1235     /
1236   ) {
1237     # some drivers barf on things they do not know about instead
1238     # of returning undef
1239     my $v = try { $self->_dbh_get_info($inf) };
1240     next unless defined $v;
1241
1242     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1243     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1244     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1245   }
1246
1247   $res;
1248 }
1249
1250 sub _determine_driver {
1251   my ($self) = @_;
1252
1253   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1254     my $started_connected = 0;
1255     local $self->{_in_determine_driver} = 1;
1256
1257     if (ref($self) eq __PACKAGE__) {
1258       my $driver;
1259       if ($self->_dbh) { # we are connected
1260         $driver = $self->_dbh->{Driver}{Name};
1261         $started_connected = 1;
1262       }
1263       else {
1264         $driver = $self->_extract_driver_from_connect_info;
1265       }
1266
1267       if ($driver) {
1268         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1269         if ($self->load_optional_class($storage_class)) {
1270           mro::set_mro($storage_class, 'c3');
1271           bless $self, $storage_class;
1272           $self->_rebless();
1273         }
1274         else {
1275           $self->_warn_undetermined_driver(
1276             'This version of DBIC does not yet seem to supply a driver for '
1277           . "your particular RDBMS and/or connection method ('$driver')."
1278           );
1279         }
1280       }
1281       else {
1282         $self->_warn_undetermined_driver(
1283           'Unable to extract a driver name from connect info - this '
1284         . 'should not have happened.'
1285         );
1286       }
1287     }
1288
1289     $self->_driver_determined(1);
1290
1291     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1292
1293     if ($self->can('source_bind_attributes')) {
1294       $self->throw_exception(
1295         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1296       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1297       . 'If you are not sure how to proceed please contact the development team via '
1298       . DBIx::Class::_ENV_::HELP_URL
1299       );
1300     }
1301
1302     $self->_init; # run driver-specific initializations
1303
1304     $self->_run_connection_actions
1305         if !$started_connected && defined $self->_dbh;
1306   }
1307 }
1308
1309 sub _extract_driver_from_connect_info {
1310   my $self = shift;
1311
1312   my $drv;
1313
1314   # if connect_info is a CODEREF, we have no choice but to connect
1315   if (
1316     ref $self->_dbi_connect_info->[0]
1317       and
1318     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1319   ) {
1320     $self->_populate_dbh;
1321     $drv = $self->_dbh->{Driver}{Name};
1322   }
1323   else {
1324     # try to use dsn to not require being connected, the driver may still
1325     # force a connection later in _rebless to determine version
1326     # (dsn may not be supplied at all if all we do is make a mock-schema)
1327     #
1328     # Use the same regex as the one used by DBI itself (even if the use of
1329     # \w is odd given unicode):
1330     # https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L621
1331     #
1332     # DO NOT use https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L559-566
1333     # as there is a long-standing precedent of not loading DBI.pm until the
1334     # very moment we are actually connecting
1335     #
1336     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:(\w*)/i;
1337     $drv ||= $ENV{DBI_DRIVER};
1338   }
1339
1340   return $drv;
1341 }
1342
1343 sub _determine_connector_driver {
1344   my ($self, $conn) = @_;
1345
1346   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1347
1348   if (not $dbtype) {
1349     $self->_warn_undetermined_driver(
1350       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1351     . "$conn connector - this should not have happened."
1352     );
1353     return;
1354   }
1355
1356   $dbtype =~ s/\W/_/gi;
1357
1358   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1359   return if $self->isa($subclass);
1360
1361   if ($self->load_optional_class($subclass)) {
1362     bless $self, $subclass;
1363     $self->_rebless;
1364   }
1365   else {
1366     $self->_warn_undetermined_driver(
1367       'This version of DBIC does not yet seem to supply a driver for '
1368     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1369     );
1370   }
1371 }
1372
1373 sub _warn_undetermined_driver {
1374   my ($self, $msg) = @_;
1375
1376   require Data::Dumper::Concise;
1377
1378   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1379   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1380   . "does not go away, file a bugreport including the following info:\n"
1381   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1382   );
1383 }
1384
1385 sub _do_connection_actions {
1386   my ($self, $method_prefix, $call, @args) = @_;
1387
1388   try {
1389     if (not ref($call)) {
1390       my $method = $method_prefix . $call;
1391       $self->$method(@args);
1392     }
1393     elsif (ref($call) eq 'CODE') {
1394       $self->$call(@args);
1395     }
1396     elsif (ref($call) eq 'ARRAY') {
1397       if (ref($call->[0]) ne 'ARRAY') {
1398         $self->_do_connection_actions($method_prefix, $_) for @$call;
1399       }
1400       else {
1401         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1402       }
1403     }
1404     else {
1405       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1406     }
1407   }
1408   catch {
1409     if ( $method_prefix =~ /^connect/ ) {
1410       # this is an on_connect cycle - we can't just throw while leaving
1411       # a handle in an undefined state in our storage object
1412       # kill it with fire and rethrow
1413       $self->_dbh(undef);
1414       $self->throw_exception( $_[0] );
1415     }
1416     else {
1417       carp "Disconnect action failed: $_[0]";
1418     }
1419   };
1420
1421   return $self;
1422 }
1423
1424 sub connect_call_do_sql {
1425   my $self = shift;
1426   $self->_do_query(@_);
1427 }
1428
1429 sub disconnect_call_do_sql {
1430   my $self = shift;
1431   $self->_do_query(@_);
1432 }
1433
1434 =head2 connect_call_datetime_setup
1435
1436 A no-op stub method, provided so that one can always safely supply the
1437 L<connection option|/DBIx::Class specific connection attributes>
1438
1439  on_connect_call => 'datetime_setup'
1440
1441 This way one does not need to know in advance whether the underlying
1442 storage requires any sort of hand-holding when dealing with calendar
1443 data.
1444
1445 =cut
1446
1447 sub connect_call_datetime_setup { 1 }
1448
1449 sub _do_query {
1450   my ($self, $action) = @_;
1451
1452   if (ref $action eq 'CODE') {
1453     $action = $action->($self);
1454     $self->_do_query($_) foreach @$action;
1455   }
1456   else {
1457     # Most debuggers expect ($sql, @bind), so we need to exclude
1458     # the attribute hash which is the second argument to $dbh->do
1459     # furthermore the bind values are usually to be presented
1460     # as named arrayref pairs, so wrap those here too
1461     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1462     my $sql = shift @do_args;
1463     my $attrs = shift @do_args;
1464     my @bind = map { [ undef, $_ ] } @do_args;
1465
1466     $self->dbh_do(sub {
1467       $_[0]->_query_start($sql, \@bind);
1468       $_[1]->do($sql, $attrs, @do_args);
1469       $_[0]->_query_end($sql, \@bind);
1470     });
1471   }
1472
1473   return $self;
1474 }
1475
1476 sub _connect {
1477   my $self = shift;
1478
1479   my $info = $self->_dbi_connect_info;
1480
1481   $self->throw_exception("You did not provide any connection_info")
1482     unless defined $info->[0];
1483
1484   my ($old_connect_via, $dbh);
1485
1486   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1487
1488   # this odd anonymous coderef dereference is in fact really
1489   # necessary to avoid the unwanted effect described in perl5
1490   # RT#75792
1491   #
1492   # in addition the coderef itself can't reside inside the try{} block below
1493   # as it somehow triggers a leak under perl -d
1494   my $dbh_error_handler_installer = sub {
1495     weaken (my $weak_self = $_[0]);
1496
1497     # the coderef is blessed so we can distinguish it from externally
1498     # supplied handles (which must be preserved)
1499     $_[1]->{HandleError} = bless sub {
1500       if ($weak_self) {
1501         $weak_self->throw_exception("DBI Exception: $_[0]");
1502       }
1503       else {
1504         # the handler may be invoked by something totally out of
1505         # the scope of DBIC
1506         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1507       }
1508     }, '__DBIC__DBH__ERROR__HANDLER__';
1509   };
1510
1511   try {
1512     if(ref $info->[0] eq 'CODE') {
1513       $dbh = $info->[0]->();
1514     }
1515     else {
1516       require DBI;
1517       $dbh = DBI->connect(@$info);
1518     }
1519
1520     die $DBI::errstr unless $dbh;
1521
1522     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1523       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1524       . 'not continue',
1525       ref $info->[0] eq 'CODE'
1526         ? "Connection coderef $info->[0] returned a"
1527         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1528     ) unless $dbh->FETCH('Active');
1529
1530     # sanity checks unless asked otherwise
1531     unless ($self->unsafe) {
1532
1533       $self->throw_exception(
1534         'Refusing clobbering of {HandleError} installed on externally supplied '
1535        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1536       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1537
1538       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1539       # request, or an external handle. Complain and set anyway
1540       unless ($dbh->{RaiseError}) {
1541         carp( ref $info->[0] eq 'CODE'
1542
1543           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1544            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1545            .'attribute has been supplied'
1546
1547           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1548            .'unsafe => 1. Toggling RaiseError back to true'
1549         );
1550
1551         $dbh->{RaiseError} = 1;
1552       }
1553
1554       $dbh_error_handler_installer->($self, $dbh);
1555     }
1556   }
1557   catch {
1558     $self->throw_exception("DBI Connection failed: $_")
1559   };
1560
1561   $self->_dbh_autocommit($dbh->{AutoCommit});
1562   return $dbh;
1563 }
1564
1565 sub txn_begin {
1566   # this means we have not yet connected and do not know the AC status
1567   # (e.g. coderef $dbh), need a full-fledged connection check
1568   if (! defined $_[0]->_dbh_autocommit) {
1569     $_[0]->ensure_connected;
1570   }
1571   # Otherwise simply connect or re-connect on pid changes
1572   else {
1573     $_[0]->_get_dbh;
1574   }
1575
1576   shift->next::method(@_);
1577 }
1578
1579 sub _exec_txn_begin {
1580   my $self = shift;
1581
1582   # if the user is utilizing txn_do - good for him, otherwise we need to
1583   # ensure that the $dbh is healthy on BEGIN.
1584   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1585   # will be replaced by a failure of begin_work itself (which will be
1586   # then retried on reconnect)
1587   if ($self->{_in_do_block}) {
1588     $self->_dbh->begin_work;
1589   } else {
1590     $self->dbh_do(sub { $_[1]->begin_work });
1591   }
1592 }
1593
1594 sub txn_commit {
1595   my $self = shift;
1596
1597   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1598     unless $self->_seems_connected;
1599
1600   # esoteric case for folks using external $dbh handles
1601   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1602     carp "Storage transaction_depth 0 does not match "
1603         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1604     $self->transaction_depth(1);
1605   }
1606
1607   $self->next::method(@_);
1608
1609   # if AutoCommit is disabled txn_depth never goes to 0
1610   # as a new txn is started immediately on commit
1611   $self->transaction_depth(1) if (
1612     !$self->transaction_depth
1613       and
1614     defined $self->_dbh_autocommit
1615       and
1616     ! $self->_dbh_autocommit
1617   );
1618 }
1619
1620 sub _exec_txn_commit {
1621   shift->_dbh->commit;
1622 }
1623
1624 sub txn_rollback {
1625   my $self = shift;
1626
1627   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1628     unless $self->_seems_connected;
1629
1630   # esoteric case for folks using external $dbh handles
1631   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1632     carp "Storage transaction_depth 0 does not match "
1633         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1634     $self->transaction_depth(1);
1635   }
1636
1637   $self->next::method(@_);
1638
1639   # if AutoCommit is disabled txn_depth never goes to 0
1640   # as a new txn is started immediately on commit
1641   $self->transaction_depth(1) if (
1642     !$self->transaction_depth
1643       and
1644     defined $self->_dbh_autocommit
1645       and
1646     ! $self->_dbh_autocommit
1647   );
1648 }
1649
1650 sub _exec_txn_rollback {
1651   shift->_dbh->rollback;
1652 }
1653
1654 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1655 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1656   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1657     unless $_[0]->_seems_connected;
1658   shift->next::method(@_);
1659 EOS
1660
1661 # This used to be the top-half of _execute.  It was split out to make it
1662 #  easier to override in NoBindVars without duping the rest.  It takes up
1663 #  all of _execute's args, and emits $sql, @bind.
1664 sub _prep_for_execute {
1665   #my ($self, $op, $ident, $args) = @_;
1666   return shift->_gen_sql_bind(@_)
1667 }
1668
1669 sub _gen_sql_bind {
1670   my ($self, $op, $ident, $args) = @_;
1671
1672   my ($colinfos, $from);
1673   if ( blessed($ident) ) {
1674     $from = $ident->from;
1675     $colinfos = $ident->columns_info;
1676   }
1677
1678   my ($sql, $bind);
1679   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1680
1681   $bind = $self->_resolve_bindattrs(
1682     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1683   );
1684
1685   if (
1686     ! $ENV{DBIC_DT_SEARCH_OK}
1687       and
1688     $op eq 'select'
1689       and
1690     first {
1691       length ref $_->[1]
1692         and
1693       blessed($_->[1])
1694         and
1695       $_->[1]->isa('DateTime')
1696     } @$bind
1697   ) {
1698     carp_unique 'DateTime objects passed to search() are not supported '
1699       . 'properly (InflateColumn::DateTime formats and settings are not '
1700       . 'respected.) See ".. format a DateTime object for searching?" in '
1701       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1702       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1703   }
1704
1705   return( $sql, $bind );
1706 }
1707
1708 sub _resolve_bindattrs {
1709   my ($self, $ident, $bind, $colinfos) = @_;
1710
1711   my $resolve_bindinfo = sub {
1712     #my $infohash = shift;
1713
1714     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1715
1716     my $ret;
1717     if (my $col = $_[0]->{dbic_colname}) {
1718       $ret = { %{$_[0]} };
1719
1720       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1721         if $colinfos->{$col}{data_type};
1722
1723       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1724         if $colinfos->{$col}{size};
1725     }
1726
1727     $ret || $_[0];
1728   };
1729
1730   return [ map {
1731     my $resolved =
1732       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1733     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1734     : (ref $_->[0] eq 'HASH')           ? [(
1735                                             ! keys %{$_->[0]}
1736                                               or
1737                                             exists $_->[0]{dbd_attrs}
1738                                               or
1739                                             $_->[0]{sqlt_datatype}
1740                                            ) ? $_->[0]
1741                                              : $resolve_bindinfo->($_->[0])
1742                                            , $_->[1]
1743                                           ]
1744     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1745     :                                     [ $resolve_bindinfo->(
1746                                               { dbic_colname => $_->[0] }
1747                                             ), $_->[1] ]
1748     ;
1749
1750     if (
1751       ! exists $resolved->[0]{dbd_attrs}
1752         and
1753       ! $resolved->[0]{sqlt_datatype}
1754         and
1755       length ref $resolved->[1]
1756         and
1757       ! is_plain_value $resolved->[1]
1758     ) {
1759       require Data::Dumper;
1760       local $Data::Dumper::Maxdepth = 1;
1761       local $Data::Dumper::Terse = 1;
1762       local $Data::Dumper::Useqq = 1;
1763       local $Data::Dumper::Indent = 0;
1764       local $Data::Dumper::Pad = ' ';
1765       $self->throw_exception(
1766         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1767       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1768       );
1769     }
1770
1771     $resolved;
1772
1773   } @$bind ];
1774 }
1775
1776 sub _format_for_trace {
1777   #my ($self, $bind) = @_;
1778
1779   ### Turn @bind from something like this:
1780   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1781   ### to this:
1782   ###   ( "'1'", "'3'" )
1783
1784   map {
1785     defined( $_ && $_->[1] )
1786       ? qq{'$_->[1]'}
1787       : q{NULL}
1788   } @{$_[1] || []};
1789 }
1790
1791 sub _query_start {
1792   my ( $self, $sql, $bind ) = @_;
1793
1794   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1795     if $self->debug;
1796 }
1797
1798 sub _query_end {
1799   my ( $self, $sql, $bind ) = @_;
1800
1801   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1802     if $self->debug;
1803 }
1804
1805 sub _dbi_attrs_for_bind {
1806   my ($self, $ident, $bind) = @_;
1807
1808   my @attrs;
1809
1810   for (map { $_->[0] } @$bind) {
1811     push @attrs, do {
1812       if (exists $_->{dbd_attrs}) {
1813         $_->{dbd_attrs}
1814       }
1815       elsif($_->{sqlt_datatype}) {
1816         # cache the result in the dbh_details hash, as it can not change unless
1817         # we connect to something else
1818         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1819         if (not exists $cache->{$_->{sqlt_datatype}}) {
1820           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1821         }
1822         $cache->{$_->{sqlt_datatype}};
1823       }
1824       else {
1825         undef;  # always push something at this position
1826       }
1827     }
1828   }
1829
1830   return \@attrs;
1831 }
1832
1833 sub _execute {
1834   my ($self, $op, $ident, @args) = @_;
1835
1836   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1837
1838   # not even a PID check - we do not care about the state of the _dbh.
1839   # All we need is to get the appropriate drivers loaded if they aren't
1840   # already so that the assumption in ad7c50fc26e holds
1841   $self->_populate_dbh unless $self->_dbh;
1842
1843   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1844     $sql,
1845     $bind,
1846     $self->_dbi_attrs_for_bind($ident, $bind),
1847   );
1848 }
1849
1850 sub _dbh_execute {
1851   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1852
1853   $self->_query_start( $sql, $bind );
1854
1855   my $sth = $self->_bind_sth_params(
1856     $self->_prepare_sth($dbh, $sql),
1857     $bind,
1858     $bind_attrs,
1859   );
1860
1861   # Can this fail without throwing an exception anyways???
1862   my $rv = $sth->execute();
1863   $self->throw_exception(
1864     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1865   ) if !$rv;
1866
1867   $self->_query_end( $sql, $bind );
1868
1869   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1870 }
1871
1872 sub _prepare_sth {
1873   my ($self, $dbh, $sql) = @_;
1874
1875   # 3 is the if_active parameter which avoids active sth re-use
1876   my $sth = $self->disable_sth_caching
1877     ? $dbh->prepare($sql)
1878     : $dbh->prepare_cached($sql, {}, 3);
1879
1880   # XXX You would think RaiseError would make this impossible,
1881   #  but apparently that's not true :(
1882   $self->throw_exception(
1883     $dbh->errstr
1884       ||
1885     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1886             .'an exception and/or setting $dbh->errstr',
1887       length ($sql) > 20
1888         ? substr($sql, 0, 20) . '...'
1889         : $sql
1890       ,
1891       'DBD::' . $dbh->{Driver}{Name},
1892     )
1893   ) if !$sth;
1894
1895   $sth;
1896 }
1897
1898 sub _bind_sth_params {
1899   my ($self, $sth, $bind, $bind_attrs) = @_;
1900
1901   for my $i (0 .. $#$bind) {
1902     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1903       $sth->bind_param_inout(
1904         $i + 1, # bind params counts are 1-based
1905         $bind->[$i][1],
1906         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1907         $bind_attrs->[$i],
1908       );
1909     }
1910     else {
1911       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1912       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1913         ? "$bind->[$i][1]"
1914         : $bind->[$i][1]
1915       ;
1916
1917       $sth->bind_param(
1918         $i + 1,
1919         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1920         $v,
1921         $bind_attrs->[$i],
1922       );
1923     }
1924   }
1925
1926   $sth;
1927 }
1928
1929 sub _prefetch_autovalues {
1930   my ($self, $source, $colinfo, $to_insert) = @_;
1931
1932   my %values;
1933   for my $col (keys %$colinfo) {
1934     if (
1935       $colinfo->{$col}{auto_nextval}
1936         and
1937       (
1938         ! exists $to_insert->{$col}
1939           or
1940         is_literal_value($to_insert->{$col})
1941       )
1942     ) {
1943       $values{$col} = $self->_sequence_fetch(
1944         'NEXTVAL',
1945         ( $colinfo->{$col}{sequence} ||=
1946             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1947         ),
1948       );
1949     }
1950   }
1951
1952   \%values;
1953 }
1954
1955 sub insert {
1956   my ($self, $source, $to_insert) = @_;
1957
1958   my $col_infos = $source->columns_info;
1959
1960   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1961
1962   # fuse the values, but keep a separate list of prefetched_values so that
1963   # they can be fused once again with the final return
1964   $to_insert = { %$to_insert, %$prefetched_values };
1965
1966   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1967   # Investigate what does it take to s/defined/exists/
1968   my %pcols = map { $_ => 1 } $source->primary_columns;
1969   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1970   for my $col ($source->columns) {
1971     if ($col_infos->{$col}{is_auto_increment}) {
1972       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1973       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1974     }
1975
1976     # nothing to retrieve when explicit values are supplied
1977     next if (
1978       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1979     );
1980
1981     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1982     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1983       $pcols{$col}
1984         or
1985       $col_infos->{$col}{retrieve_on_insert}
1986     );
1987   };
1988
1989   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1990   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1991
1992   my ($sqla_opts, @ir_container);
1993   if (%retrieve_cols and $self->_use_insert_returning) {
1994     $sqla_opts->{returning_container} = \@ir_container
1995       if $self->_use_insert_returning_bound;
1996
1997     $sqla_opts->{returning} = [
1998       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1999     ];
2000   }
2001
2002   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2003
2004   my %returned_cols = %$to_insert;
2005   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2006
2007     unless( @ir_container ) {
2008       try {
2009
2010         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2011         local $SIG{__WARN__} = sub {};
2012
2013         @ir_container = $sth->fetchrow_array;
2014         $sth->finish;
2015
2016       } catch {
2017         # Evict the $sth from the cache in case we got here, since the finish()
2018         # is crucial, at least on older Firebirds, possibly on other engines too
2019         #
2020         # It would be too complex to make this a proper subclass override,
2021         # and besides we already take the try{} penalty, adding a catch that
2022         # triggers infrequently is a no-brainer
2023         #
2024         if( my $kids = $self->_dbh->{CachedKids} ) {
2025           $kids->{$_} == $sth and delete $kids->{$_}
2026             for keys %$kids
2027         }
2028       };
2029     }
2030
2031     @returned_cols{@$retlist} = @ir_container if @ir_container;
2032   }
2033   else {
2034     # pull in PK if needed and then everything else
2035     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2036
2037       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2038         unless $self->can('last_insert_id');
2039
2040       my @pri_values = $self->last_insert_id($source, @missing_pri);
2041
2042       $self->throw_exception( "Can't get last insert id" )
2043         unless (@pri_values == @missing_pri);
2044
2045       @returned_cols{@missing_pri} = @pri_values;
2046       delete @retrieve_cols{@missing_pri};
2047     }
2048
2049     # if there is more left to pull
2050     if (%retrieve_cols) {
2051       $self->throw_exception(
2052         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2053       ) unless %pcols;
2054
2055       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2056
2057       my $cur = DBIx::Class::ResultSet->new($source, {
2058         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2059         select => \@left_to_fetch,
2060       })->cursor;
2061
2062       @returned_cols{@left_to_fetch} = $cur->next;
2063
2064       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2065         if scalar $cur->next;
2066     }
2067   }
2068
2069   return { %$prefetched_values, %returned_cols };
2070 }
2071
2072 sub insert_bulk {
2073   carp_unique(
2074     'insert_bulk() should have never been exposed as a public method and '
2075   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2076   . 'use for this method please contact the development team via '
2077   . DBIx::Class::_ENV_::HELP_URL
2078   );
2079
2080   return '0E0' unless @{$_[3]||[]};
2081
2082   shift->_insert_bulk(@_);
2083 }
2084
2085 sub _insert_bulk {
2086   my ($self, $source, $cols, $data) = @_;
2087
2088   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2089     unless @{$data||[]};
2090
2091   my $colinfos = $source->columns_info($cols);
2092
2093   local $self->{_autoinc_supplied_for_op} =
2094     (grep { $_->{is_auto_increment} } values %$colinfos)
2095       ? 1
2096       : 0
2097   ;
2098
2099   # get a slice type index based on first row of data
2100   # a "column" in this context may refer to more than one bind value
2101   # e.g. \[ '?, ?', [...], [...] ]
2102   #
2103   # construct the value type index - a description of values types for every
2104   # per-column slice of $data:
2105   #
2106   # nonexistent - nonbind literal
2107   # 0 - regular value
2108   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2109   #
2110   # also construct the column hash to pass to the SQL generator. For plain
2111   # (non literal) values - convert the members of the first row into a
2112   # literal+bind combo, with extra positional info in the bind attr hashref.
2113   # This will allow us to match the order properly, and is so contrived
2114   # because a user-supplied literal/bind (or something else specific to a
2115   # resultsource and/or storage driver) can inject extra binds along the
2116   # way, so one can't rely on "shift positions" ordering at all. Also we
2117   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2118   # can be later matched up by address), because we want to supply a real
2119   # value on which perhaps e.g. datatype checks will be performed
2120   my ($proto_data, $serialized_bind_type_by_col_idx);
2121   for my $col_idx (0..$#$cols) {
2122     my $colname = $cols->[$col_idx];
2123     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2124       # no bind value at all - no type
2125
2126       $proto_data->{$colname} = $data->[0][$col_idx];
2127     }
2128     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2129       # repack, so we don't end up mangling the original \[]
2130       my ($sql, @bind) = @${$data->[0][$col_idx]};
2131
2132       # normalization of user supplied stuff
2133       my $resolved_bind = $self->_resolve_bindattrs(
2134         $source, \@bind, $colinfos,
2135       );
2136
2137       # store value-less (attrs only) bind info - we will be comparing all
2138       # supplied binds against this for sanity
2139       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2140
2141       $proto_data->{$colname} = \[ $sql, map { [
2142         # inject slice order to use for $proto_bind construction
2143           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2144             =>
2145           $resolved_bind->[$_][1]
2146         ] } (0 .. $#bind)
2147       ];
2148     }
2149     else {
2150       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2151
2152       $proto_data->{$colname} = \[ '?', [
2153         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2154           =>
2155         $data->[0][$col_idx]
2156       ] ];
2157     }
2158   }
2159
2160   my ($sql, $proto_bind) = $self->_prep_for_execute (
2161     'insert',
2162     $source,
2163     [ $proto_data ],
2164   );
2165
2166   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2167     # if the bindlist is empty and we had some dynamic binds, this means the
2168     # storage ate them away (e.g. the NoBindVars component) and interpolated
2169     # them directly into the SQL. This obviously can't be good for multi-inserts
2170     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2171   }
2172
2173   # sanity checks
2174   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2175   #
2176   # use an error reporting closure for convenience (less to pass)
2177   my $bad_slice_report_cref = sub {
2178     my ($msg, $r_idx, $c_idx) = @_;
2179     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2180       $msg,
2181       $cols->[$c_idx],
2182       do {
2183         require Data::Dumper::Concise;
2184         local $Data::Dumper::Maxdepth = 5;
2185         Data::Dumper::Concise::Dumper ({
2186           map { $cols->[$_] =>
2187             $data->[$r_idx][$_]
2188           } 0..$#$cols
2189         }),
2190       }
2191     );
2192   };
2193
2194   for my $col_idx (0..$#$cols) {
2195     my $reference_val = $data->[0][$col_idx];
2196
2197     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2198       my $val = $data->[$row_idx][$col_idx];
2199
2200       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2201         if (ref $val ne 'SCALAR') {
2202           $bad_slice_report_cref->(
2203             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2204             $row_idx,
2205             $col_idx,
2206           );
2207         }
2208         elsif ($$val ne $$reference_val) {
2209           $bad_slice_report_cref->(
2210             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2211             $row_idx,
2212             $col_idx,
2213           );
2214         }
2215       }
2216       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2217         if (is_literal_value($val)) {
2218           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2219         }
2220       }
2221       else {  # binds from a \[], compare type and attrs
2222         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2223           $bad_slice_report_cref->(
2224             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2225             $row_idx,
2226             $col_idx,
2227           );
2228         }
2229         # start drilling down and bail out early on identical refs
2230         elsif (
2231           $reference_val != $val
2232             or
2233           $$reference_val != $$val
2234         ) {
2235           if (${$val}->[0] ne ${$reference_val}->[0]) {
2236             $bad_slice_report_cref->(
2237               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2238               $row_idx,
2239               $col_idx,
2240             );
2241           }
2242           # need to check the bind attrs - a bind will happen only once for
2243           # the entire dataset, so any changes further down will be ignored.
2244           elsif (
2245             $serialized_bind_type_by_col_idx->{$col_idx}
2246               ne
2247             serialize [
2248               map
2249               { $_->[0] }
2250               @{$self->_resolve_bindattrs(
2251                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2252               )}
2253             ]
2254           ) {
2255             $bad_slice_report_cref->(
2256               'Differing bind attributes on literal/bind values not supported',
2257               $row_idx,
2258               $col_idx,
2259             );
2260           }
2261         }
2262       }
2263     }
2264   }
2265
2266   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2267   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2268   # scope guard
2269   my $guard = $self->txn_scope_guard;
2270
2271   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2272   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2273   my $rv = do {
2274     if (@$proto_bind) {
2275       # proto bind contains the information on which pieces of $data to pull
2276       # $cols is passed in only for prettier error-reporting
2277       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2278     }
2279     else {
2280       # bind_param_array doesn't work if there are no binds
2281       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2282     }
2283   };
2284
2285   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2286
2287   $guard->commit;
2288
2289   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2290 }
2291
2292 # execute_for_fetch is capable of returning data just fine (it means it
2293 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2294 # is the void-populate fast-path we will just ignore this altogether
2295 # for the time being.
2296 sub _dbh_execute_for_fetch {
2297   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2298
2299   # If we have any bind attributes to take care of, we will bind the
2300   # proto-bind data (which will never be used by execute_for_fetch)
2301   # However since column bindtypes are "sticky", this is sufficient
2302   # to get the DBD to apply the bindtype to all values later on
2303   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2304
2305   for my $i (0 .. $#$proto_bind) {
2306     $sth->bind_param (
2307       $i+1, # DBI bind indexes are 1-based
2308       $proto_bind->[$i][1],
2309       $bind_attrs->[$i],
2310     ) if defined $bind_attrs->[$i];
2311   }
2312
2313   # At this point $data slots named in the _bind_data_slice_idx of
2314   # each piece of $proto_bind are either \[]s or plain values to be
2315   # passed in. Construct the dispensing coderef. *NOTE* the order
2316   # of $data will differ from this of the ?s in the SQL (due to
2317   # alphabetical ordering by colname). We actually do want to
2318   # preserve this behavior so that prepare_cached has a better
2319   # chance of matching on unrelated calls
2320
2321   my $fetch_row_idx = -1; # saner loop this way
2322   my $fetch_tuple = sub {
2323     return undef if ++$fetch_row_idx > $#$data;
2324
2325     return [ map {
2326       my $v = ! defined $_->{_literal_bind_subindex}
2327
2328         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2329
2330         # There are no attributes to resolve here - we already did everything
2331         # when we constructed proto_bind. However we still want to sanity-check
2332         # what the user supplied, so pass stuff through to the resolver *anyway*
2333         : $self->_resolve_bindattrs (
2334             undef,  # a fake rsrc
2335             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2336             {},     # a fake column_info bag
2337           )->[0][1]
2338       ;
2339
2340       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2341       # For the time being forcibly stringify whatever is stringifiable
2342       (length ref $v and is_plain_value $v)
2343         ? "$v"
2344         : $v
2345       ;
2346     } map { $_->[0] } @$proto_bind ];
2347   };
2348
2349   my $tuple_status = [];
2350   my ($rv, $err);
2351   try {
2352     $rv = $sth->execute_for_fetch(
2353       $fetch_tuple,
2354       $tuple_status,
2355     );
2356   }
2357   catch {
2358     $err = shift;
2359   };
2360
2361   # Not all DBDs are create equal. Some throw on error, some return
2362   # an undef $rv, and some set $sth->err - try whatever we can
2363   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2364     ! defined $err
2365       and
2366     ( !defined $rv or $sth->err )
2367   );
2368
2369   # Statement must finish even if there was an exception.
2370   try {
2371     $sth->finish
2372   }
2373   catch {
2374     $err = shift unless defined $err
2375   };
2376
2377   if (defined $err) {
2378     my $i = 0;
2379     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2380
2381     $self->throw_exception("Unexpected populate error: $err")
2382       if ($i > $#$tuple_status);
2383
2384     require Data::Dumper::Concise;
2385     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2386       ($tuple_status->[$i][1] || $err),
2387       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2388     );
2389   }
2390
2391   return $rv;
2392 }
2393
2394 sub _dbh_execute_inserts_with_no_binds {
2395   my ($self, $sth, $count) = @_;
2396
2397   my $err;
2398   try {
2399     my $dbh = $self->_get_dbh;
2400     local $dbh->{RaiseError} = 1;
2401     local $dbh->{PrintError} = 0;
2402
2403     $sth->execute foreach 1..$count;
2404   }
2405   catch {
2406     $err = shift;
2407   };
2408
2409   # Make sure statement is finished even if there was an exception.
2410   try {
2411     $sth->finish
2412   }
2413   catch {
2414     $err = shift unless defined $err;
2415   };
2416
2417   $self->throw_exception($err) if defined $err;
2418
2419   return $count;
2420 }
2421
2422 sub update {
2423   #my ($self, $source, @args) = @_;
2424   shift->_execute('update', @_);
2425 }
2426
2427
2428 sub delete {
2429   #my ($self, $source, @args) = @_;
2430   shift->_execute('delete', @_);
2431 }
2432
2433 sub _select {
2434   my $self = shift;
2435   $self->_execute($self->_select_args(@_));
2436 }
2437
2438 sub _select_args_to_query {
2439   my $self = shift;
2440
2441   $self->throw_exception(
2442     "Unable to generate limited query representation with 'software_limit' enabled"
2443   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2444
2445   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2446   #  = $self->_select_args($ident, $select, $cond, $attrs);
2447   my ($op, $ident, @args) =
2448     $self->_select_args(@_);
2449
2450   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2451   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2452
2453   # reuse the bind arrayref
2454   unshift @{$bind}, "($sql)";
2455   \$bind;
2456 }
2457
2458 sub _select_args {
2459   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2460
2461   # FIXME - that kind of caching would be nice to have
2462   # however currently we *may* pass the same $orig_attrs
2463   # with different ident/select/where
2464   # the whole interface needs to be rethought, since it
2465   # was centered around the flawed SQLA API. We can do
2466   # soooooo much better now. But that is also another
2467   # battle...
2468   #return (
2469   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2470   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2471
2472   my $sql_maker = $self->sql_maker;
2473
2474   my $attrs = {
2475     %$orig_attrs,
2476     select => $select,
2477     from => $ident,
2478     where => $where,
2479   };
2480
2481   # Sanity check the attributes (SQLMaker does it too, but
2482   # in case of a software_limit we'll never reach there)
2483   if (defined $attrs->{offset}) {
2484     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2485       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2486   }
2487
2488   if (defined $attrs->{rows}) {
2489     $self->throw_exception("The rows attribute must be a positive integer if present")
2490       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2491   }
2492   elsif ($attrs->{offset}) {
2493     # MySQL actually recommends this approach.  I cringe.
2494     $attrs->{rows} = $sql_maker->__max_int;
2495   }
2496
2497   # see if we will need to tear the prefetch apart to satisfy group_by == select
2498   # this is *extremely tricky* to get right, I am still not sure I did
2499   #
2500   my ($prefetch_needs_subquery, @limit_args);
2501
2502   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2503     # we already know there is a valid group_by (we made it) and we know it is
2504     # intended to be based *only* on non-multi stuff
2505     # short circuit the group_by parsing below
2506     $prefetch_needs_subquery = 1;
2507   }
2508   elsif (
2509     # The rationale is that even if we do *not* have collapse, we still
2510     # need to wrap the core grouped select/group_by in a subquery
2511     # so that databases that care about group_by/select equivalence
2512     # are happy (this includes MySQL in strict_mode)
2513     # If any of the other joined tables are referenced in the group_by
2514     # however - the user is on their own
2515     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2516       and
2517     $attrs->{group_by}
2518       and
2519     @{$attrs->{group_by}}
2520       and
2521     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2522       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2523     }
2524   ) {
2525     # no aliases other than our own in group_by
2526     # if there are - do not allow subquery even if limit is present
2527     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2528   }
2529   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2530     # active collapse with a limit - that one is a no-brainer unless
2531     # overruled by a group_by above
2532     $prefetch_needs_subquery = 1;
2533   }
2534
2535   if ($prefetch_needs_subquery) {
2536     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2537   }
2538   elsif (! $attrs->{software_limit} ) {
2539     push @limit_args, (
2540       $attrs->{rows} || (),
2541       $attrs->{offset} || (),
2542     );
2543   }
2544
2545   # try to simplify the joinmap further (prune unreferenced type-single joins)
2546   if (
2547     ! $prefetch_needs_subquery  # already pruned
2548       and
2549     ref $attrs->{from}
2550       and
2551     reftype $attrs->{from} eq 'ARRAY'
2552       and
2553     @{$attrs->{from}} != 1
2554   ) {
2555     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2556   }
2557
2558   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2559   # during the result inflation stage we *need* to know what was the aliastype
2560   # map as sqla saw it when the final pieces of SQL were being assembled
2561   # Originally we simply carried around the entirety of $attrs, but this
2562   # resulted in resultsets that are being reused growing continuously, as
2563   # the hash in question grew deeper and deeper.
2564   # Instead hand-pick what to take with us here (we actually don't need much
2565   # at this point just the map itself)
2566   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2567
2568 ###
2569   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2570   #
2571   # This would be the point to deflate anything found in $attrs->{where}
2572   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2573   # expect a result object. And all we have is a resultsource (it is trivial
2574   # to extract deflator coderefs via $alias2source above).
2575   #
2576   # I don't see a way forward other than changing the way deflators are
2577   # invoked, and that's just bad...
2578 ###
2579
2580   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2581 }
2582
2583 # Returns a counting SELECT for a simple count
2584 # query. Abstracted so that a storage could override
2585 # this to { count => 'firstcol' } or whatever makes
2586 # sense as a performance optimization
2587 sub _count_select {
2588   #my ($self, $source, $rs_attrs) = @_;
2589   return { count => '*' };
2590 }
2591
2592 =head2 select
2593
2594 =over 4
2595
2596 =item Arguments: $ident, $select, $condition, $attrs
2597
2598 =back
2599
2600 Handle a SQL select statement.
2601
2602 =cut
2603
2604 sub select {
2605   my $self = shift;
2606   my ($ident, $select, $condition, $attrs) = @_;
2607   return $self->cursor_class->new($self, \@_, $attrs);
2608 }
2609
2610 sub select_single {
2611   my $self = shift;
2612   my ($rv, $sth, @bind) = $self->_select(@_);
2613   my @row = $sth->fetchrow_array;
2614   my @nextrow = $sth->fetchrow_array if @row;
2615   if(@row && @nextrow) {
2616     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2617   }
2618   # Need to call finish() to work round broken DBDs
2619   $sth->finish();
2620   return @row;
2621 }
2622
2623 =head2 sql_limit_dialect
2624
2625 This is an accessor for the default SQL limit dialect used by a particular
2626 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2627 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2628 see L<DBIx::Class::SQLMaker::LimitDialects>.
2629
2630 =cut
2631
2632 sub _dbh_columns_info_for {
2633   my ($self, $dbh, $table) = @_;
2634
2635   if ($dbh->can('column_info')) {
2636     my %result;
2637     my $caught;
2638     try {
2639       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2640       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2641       $sth->execute();
2642       while ( my $info = $sth->fetchrow_hashref() ){
2643         my %column_info;
2644         $column_info{data_type}   = $info->{TYPE_NAME};
2645         $column_info{size}      = $info->{COLUMN_SIZE};
2646         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2647         $column_info{default_value} = $info->{COLUMN_DEF};
2648         my $col_name = $info->{COLUMN_NAME};
2649         $col_name =~ s/^\"(.*)\"$/$1/;
2650
2651         $result{$col_name} = \%column_info;
2652       }
2653     } catch {
2654       $caught = 1;
2655     };
2656     return \%result if !$caught && scalar keys %result;
2657   }
2658
2659   my %result;
2660   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2661   $sth->execute;
2662   my @columns = @{$sth->{NAME_lc}};
2663   for my $i ( 0 .. $#columns ){
2664     my %column_info;
2665     $column_info{data_type} = $sth->{TYPE}->[$i];
2666     $column_info{size} = $sth->{PRECISION}->[$i];
2667     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2668
2669     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2670       $column_info{data_type} = $1;
2671       $column_info{size}    = $2;
2672     }
2673
2674     $result{$columns[$i]} = \%column_info;
2675   }
2676   $sth->finish;
2677
2678   foreach my $col (keys %result) {
2679     my $colinfo = $result{$col};
2680     my $type_num = $colinfo->{data_type};
2681     my $type_name;
2682     if(defined $type_num && $dbh->can('type_info')) {
2683       my $type_info = $dbh->type_info($type_num);
2684       $type_name = $type_info->{TYPE_NAME} if $type_info;
2685       $colinfo->{data_type} = $type_name if $type_name;
2686     }
2687   }
2688
2689   return \%result;
2690 }
2691
2692 sub columns_info_for {
2693   my ($self, $table) = @_;
2694   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2695 }
2696
2697 =head2 last_insert_id
2698
2699 Return the row id of the last insert.
2700
2701 =cut
2702
2703 sub _dbh_last_insert_id {
2704     my ($self, $dbh, $source, $col) = @_;
2705
2706     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2707
2708     return $id if defined $id;
2709
2710     my $class = ref $self;
2711     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2712 }
2713
2714 sub last_insert_id {
2715   my $self = shift;
2716   $self->_dbh_last_insert_id ($self->_dbh, @_);
2717 }
2718
2719 =head2 _native_data_type
2720
2721 =over 4
2722
2723 =item Arguments: $type_name
2724
2725 =back
2726
2727 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2728 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2729 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2730
2731 The default implementation returns C<undef>, implement in your Storage driver if
2732 you need this functionality.
2733
2734 Should map types from other databases to the native RDBMS type, for example
2735 C<VARCHAR2> to C<VARCHAR>.
2736
2737 Types with modifiers should map to the underlying data type. For example,
2738 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2739
2740 Composite types should map to the container type, for example
2741 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2742
2743 =cut
2744
2745 sub _native_data_type {
2746   #my ($self, $data_type) = @_;
2747   return undef
2748 }
2749
2750 # Check if placeholders are supported at all
2751 sub _determine_supports_placeholders {
2752   my $self = shift;
2753   my $dbh  = $self->_get_dbh;
2754
2755   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2756   # but it is inaccurate more often than not
2757   return try {
2758     local $dbh->{PrintError} = 0;
2759     local $dbh->{RaiseError} = 1;
2760     $dbh->do('select ?', {}, 1);
2761     1;
2762   }
2763   catch {
2764     0;
2765   };
2766 }
2767
2768 # Check if placeholders bound to non-string types throw exceptions
2769 #
2770 sub _determine_supports_typeless_placeholders {
2771   my $self = shift;
2772   my $dbh  = $self->_get_dbh;
2773
2774   return try {
2775     local $dbh->{PrintError} = 0;
2776     local $dbh->{RaiseError} = 1;
2777     # this specifically tests a bind that is NOT a string
2778     $dbh->do('select 1 where 1 = ?', {}, 1);
2779     1;
2780   }
2781   catch {
2782     0;
2783   };
2784 }
2785
2786 =head2 sqlt_type
2787
2788 Returns the database driver name.
2789
2790 =cut
2791
2792 sub sqlt_type {
2793   shift->_get_dbh->{Driver}->{Name};
2794 }
2795
2796 =head2 bind_attribute_by_data_type
2797
2798 Given a datatype from column info, returns a database specific bind
2799 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2800 let the database planner just handle it.
2801
2802 This method is always called after the driver has been determined and a DBI
2803 connection has been established. Therefore you can refer to C<DBI::$constant>
2804 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2805 the correct modules.
2806
2807 =cut
2808
2809 sub bind_attribute_by_data_type {
2810     return;
2811 }
2812
2813 =head2 is_datatype_numeric
2814
2815 Given a datatype from column_info, returns a boolean value indicating if
2816 the current RDBMS considers it a numeric value. This controls how
2817 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2818 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2819 be performed instead of the usual C<eq>.
2820
2821 =cut
2822
2823 sub is_datatype_numeric {
2824   #my ($self, $dt) = @_;
2825
2826   return 0 unless $_[1];
2827
2828   $_[1] =~ /^ (?:
2829     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2830   ) $/ix;
2831 }
2832
2833
2834 =head2 create_ddl_dir
2835
2836 =over 4
2837
2838 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2839
2840 =back
2841
2842 Creates a SQL file based on the Schema, for each of the specified
2843 database engines in C<\@databases> in the given directory.
2844 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2845
2846 Given a previous version number, this will also create a file containing
2847 the ALTER TABLE statements to transform the previous schema into the
2848 current one. Note that these statements may contain C<DROP TABLE> or
2849 C<DROP COLUMN> statements that can potentially destroy data.
2850
2851 The file names are created using the C<ddl_filename> method below, please
2852 override this method in your schema if you would like a different file
2853 name format. For the ALTER file, the same format is used, replacing
2854 $version in the name with "$preversion-$version".
2855
2856 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2857 The most common value for this would be C<< { add_drop_table => 1 } >>
2858 to have the SQL produced include a C<DROP TABLE> statement for each table
2859 created. For quoting purposes supply C<quote_identifiers>.
2860
2861 If no arguments are passed, then the following default values are assumed:
2862
2863 =over 4
2864
2865 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2866
2867 =item version    - $schema->schema_version
2868
2869 =item directory  - './'
2870
2871 =item preversion - <none>
2872
2873 =back
2874
2875 By default, C<\%sqlt_args> will have
2876
2877  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2878
2879 merged with the hash passed in. To disable any of those features, pass in a
2880 hashref like the following
2881
2882  { ignore_constraint_names => 0, # ... other options }
2883
2884
2885 WARNING: You are strongly advised to check all SQL files created, before applying
2886 them.
2887
2888 =cut
2889
2890 sub create_ddl_dir {
2891   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2892
2893   unless ($dir) {
2894     carp "No directory given, using ./\n";
2895     $dir = './';
2896   } else {
2897       -d $dir
2898         or
2899       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2900         or
2901       $self->throw_exception(
2902         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2903       );
2904   }
2905
2906   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2907
2908   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2909   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2910
2911   my $schema_version = $schema->schema_version || '1.x';
2912   $version ||= $schema_version;
2913
2914   $sqltargs = {
2915     add_drop_table => 1,
2916     ignore_constraint_names => 1,
2917     ignore_index_names => 1,
2918     quote_identifiers => $self->sql_maker->_quoting_enabled,
2919     %{$sqltargs || {}}
2920   };
2921
2922   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2923     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2924   }
2925
2926   my $sqlt = SQL::Translator->new( $sqltargs );
2927
2928   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2929   my $sqlt_schema = $sqlt->translate({ data => $schema })
2930     or $self->throw_exception ($sqlt->error);
2931
2932   foreach my $db (@$databases) {
2933     $sqlt->reset();
2934     $sqlt->{schema} = $sqlt_schema;
2935     $sqlt->producer($db);
2936
2937     my $file;
2938     my $filename = $schema->ddl_filename($db, $version, $dir);
2939     if (-e $filename && ($version eq $schema_version )) {
2940       # if we are dumping the current version, overwrite the DDL
2941       carp "Overwriting existing DDL file - $filename";
2942       unlink($filename);
2943     }
2944
2945     my $output = $sqlt->translate;
2946     if(!$output) {
2947       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2948       next;
2949     }
2950     if(!open($file, ">$filename")) {
2951       $self->throw_exception("Can't open $filename for writing ($!)");
2952       next;
2953     }
2954     print $file $output;
2955     close($file);
2956
2957     next unless ($preversion);
2958
2959     require SQL::Translator::Diff;
2960
2961     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2962     if(!-e $prefilename) {
2963       carp("No previous schema file found ($prefilename)");
2964       next;
2965     }
2966
2967     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2968     if(-e $difffile) {
2969       carp("Overwriting existing diff file - $difffile");
2970       unlink($difffile);
2971     }
2972
2973     my $source_schema;
2974     {
2975       my $t = SQL::Translator->new($sqltargs);
2976       $t->debug( 0 );
2977       $t->trace( 0 );
2978
2979       $t->parser( $db )
2980         or $self->throw_exception ($t->error);
2981
2982       my $out = $t->translate( $prefilename )
2983         or $self->throw_exception ($t->error);
2984
2985       $source_schema = $t->schema;
2986
2987       $source_schema->name( $prefilename )
2988         unless ( $source_schema->name );
2989     }
2990
2991     # The "new" style of producers have sane normalization and can support
2992     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2993     # And we have to diff parsed SQL against parsed SQL.
2994     my $dest_schema = $sqlt_schema;
2995
2996     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2997       my $t = SQL::Translator->new($sqltargs);
2998       $t->debug( 0 );
2999       $t->trace( 0 );
3000
3001       $t->parser( $db )
3002         or $self->throw_exception ($t->error);
3003
3004       my $out = $t->translate( $filename )
3005         or $self->throw_exception ($t->error);
3006
3007       $dest_schema = $t->schema;
3008
3009       $dest_schema->name( $filename )
3010         unless $dest_schema->name;
3011     }
3012
3013     my $diff = do {
3014       # FIXME - this is a terrible workaround for
3015       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3016       # Fixing it in this sloppy manner so that we don't hve to
3017       # lockstep an SQLT release as well. Needs to be removed at
3018       # some point, and SQLT dep bumped
3019       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3020         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3021
3022       SQL::Translator::Diff::schema_diff($source_schema, $db,
3023                                          $dest_schema,   $db,
3024                                          $sqltargs
3025                                        );
3026     };
3027
3028     if(!open $file, ">$difffile") {
3029       $self->throw_exception("Can't write to $difffile ($!)");
3030       next;
3031     }
3032     print $file $diff;
3033     close($file);
3034   }
3035 }
3036
3037 =head2 deployment_statements
3038
3039 =over 4
3040
3041 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3042
3043 =back
3044
3045 Returns the statements used by L<DBIx::Class::Storage/deploy>
3046 and L<DBIx::Class::Schema/deploy>.
3047
3048 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3049 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3050
3051 C<$directory> is used to return statements from files in a previously created
3052 L</create_ddl_dir> directory and is optional. The filenames are constructed
3053 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3054
3055 If no C<$directory> is specified then the statements are constructed on the
3056 fly using L<SQL::Translator> and C<$version> is ignored.
3057
3058 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3059
3060 =cut
3061
3062 sub deployment_statements {
3063   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3064   $type ||= $self->sqlt_type;
3065   $version ||= $schema->schema_version || '1.x';
3066   $dir ||= './';
3067   my $filename = $schema->ddl_filename($type, $version, $dir);
3068   if(-f $filename)
3069   {
3070       # FIXME replace this block when a proper sane sql parser is available
3071       my $file;
3072       open($file, "<$filename")
3073         or $self->throw_exception("Can't open $filename ($!)");
3074       my @rows = <$file>;
3075       close($file);
3076       return join('', @rows);
3077   }
3078
3079   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
3080     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
3081   }
3082
3083   # sources needs to be a parser arg, but for simplicity allow at top level
3084   # coming in
3085   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3086       if exists $sqltargs->{sources};
3087
3088   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3089     unless exists $sqltargs->{quote_identifiers};
3090
3091   my $tr = SQL::Translator->new(
3092     producer => "SQL::Translator::Producer::${type}",
3093     %$sqltargs,
3094     parser => 'SQL::Translator::Parser::DBIx::Class',
3095     data => $schema,
3096   );
3097
3098   return preserve_context {
3099     $tr->translate
3100   } after => sub {
3101     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3102       unless defined $_[0];
3103   };
3104 }
3105
3106 # FIXME deploy() currently does not accurately report sql errors
3107 # Will always return true while errors are warned
3108 sub deploy {
3109   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3110   my $deploy = sub {
3111     my $line = shift;
3112     return if(!$line);
3113     return if($line =~ /^--/);
3114     # next if($line =~ /^DROP/m);
3115     return if($line =~ /^BEGIN TRANSACTION/m);
3116     return if($line =~ /^COMMIT/m);
3117     return if $line =~ /^\s+$/; # skip whitespace only
3118     $self->_query_start($line);
3119     try {
3120       # do a dbh_do cycle here, as we need some error checking in
3121       # place (even though we will ignore errors)
3122       $self->dbh_do (sub { $_[1]->do($line) });
3123     } catch {
3124       carp qq{$_ (running "${line}")};
3125     };
3126     $self->_query_end($line);
3127   };
3128   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3129   if (@statements > 1) {
3130     foreach my $statement (@statements) {
3131       $deploy->( $statement );
3132     }
3133   }
3134   elsif (@statements == 1) {
3135     # split on single line comments and end of statements
3136     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3137       $deploy->( $line );
3138     }
3139   }
3140 }
3141
3142 =head2 datetime_parser
3143
3144 Returns the datetime parser class
3145
3146 =cut
3147
3148 sub datetime_parser {
3149   my $self = shift;
3150   return $self->{datetime_parser} ||= do {
3151     $self->build_datetime_parser(@_);
3152   };
3153 }
3154
3155 =head2 datetime_parser_type
3156
3157 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3158
3159 =head2 build_datetime_parser
3160
3161 See L</datetime_parser>
3162
3163 =cut
3164
3165 sub build_datetime_parser {
3166   my $self = shift;
3167   my $type = $self->datetime_parser_type(@_);
3168   return $type;
3169 }
3170
3171
3172 =head2 is_replicating
3173
3174 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3175 replicate from a master database.  Default is undef, which is the result
3176 returned by databases that don't support replication.
3177
3178 =cut
3179
3180 sub is_replicating {
3181     return;
3182
3183 }
3184
3185 =head2 lag_behind_master
3186
3187 Returns a number that represents a certain amount of lag behind a master db
3188 when a given storage is replicating.  The number is database dependent, but
3189 starts at zero and increases with the amount of lag. Default in undef
3190
3191 =cut
3192
3193 sub lag_behind_master {
3194     return;
3195 }
3196
3197 =head2 relname_to_table_alias
3198
3199 =over 4
3200
3201 =item Arguments: $relname, $join_count
3202
3203 =item Return Value: $alias
3204
3205 =back
3206
3207 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3208 queries.
3209
3210 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3211 way these aliases are named.
3212
3213 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3214 otherwise C<"$relname">.
3215
3216 =cut
3217
3218 sub relname_to_table_alias {
3219   my ($self, $relname, $join_count) = @_;
3220
3221   my $alias = ($join_count && $join_count > 1 ?
3222     join('_', $relname, $join_count) : $relname);
3223
3224   return $alias;
3225 }
3226
3227 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3228 # version and it may be necessary to amend or override it for a specific storage
3229 # if such binds are necessary.
3230 sub _max_column_bytesize {
3231   my ($self, $attr) = @_;
3232
3233   my $max_size;
3234
3235   if ($attr->{sqlt_datatype}) {
3236     my $data_type = lc($attr->{sqlt_datatype});
3237
3238     if ($attr->{sqlt_size}) {
3239
3240       # String/sized-binary types
3241       if ($data_type =~ /^(?:
3242           l? (?:var)? char(?:acter)? (?:\s*varying)?
3243             |
3244           (?:var)? binary (?:\s*varying)?
3245             |
3246           raw
3247         )\b/x
3248       ) {
3249         $max_size = $attr->{sqlt_size};
3250       }
3251       # Other charset/unicode types, assume scale of 4
3252       elsif ($data_type =~ /^(?:
3253           national \s* character (?:\s*varying)?
3254             |
3255           nchar
3256             |
3257           univarchar
3258             |
3259           nvarchar
3260         )\b/x
3261       ) {
3262         $max_size = $attr->{sqlt_size} * 4;
3263       }
3264     }
3265
3266     if (!$max_size and !$self->_is_lob_type($data_type)) {
3267       $max_size = 100 # for all other (numeric?) datatypes
3268     }
3269   }
3270
3271   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3272 }
3273
3274 # Determine if a data_type is some type of BLOB
3275 sub _is_lob_type {
3276   my ($self, $data_type) = @_;
3277   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3278     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3279                                   |varchar|character\s*varying|nvarchar
3280                                   |national\s*character\s*varying))?\z/xi);
3281 }
3282
3283 sub _is_binary_lob_type {
3284   my ($self, $data_type) = @_;
3285   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3286     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3287 }
3288
3289 sub _is_text_lob_type {
3290   my ($self, $data_type) = @_;
3291   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3292     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3293                         |national\s*character\s*varying))\z/xi);
3294 }
3295
3296 # Determine if a data_type is some type of a binary type
3297 sub _is_binary_type {
3298   my ($self, $data_type) = @_;
3299   $data_type && ($self->_is_binary_lob_type($data_type)
3300     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3301 }
3302
3303 1;
3304
3305 =head1 USAGE NOTES
3306
3307 =head2 DBIx::Class and AutoCommit
3308
3309 DBIx::Class can do some wonderful magic with handling exceptions,
3310 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3311 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3312 transaction support.
3313
3314 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3315 in an assumed transaction between commits, and you're telling us you'd
3316 like to manage that manually.  A lot of the magic protections offered by
3317 this module will go away.  We can't protect you from exceptions due to database
3318 disconnects because we don't know anything about how to restart your
3319 transactions.  You're on your own for handling all sorts of exceptional
3320 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3321 be with raw DBI.
3322
3323 =head1 FURTHER QUESTIONS?
3324
3325 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3326
3327 =head1 COPYRIGHT AND LICENSE
3328
3329 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3330 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3331 redistribute it and/or modify it under the same terms as the
3332 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.