lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9 use Carp::Clan qw/DBIx::Class/;
  10
  11 BEGIN {
  12
  13 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  14
  15 use base qw/SQL::Abstract::Limit/;
  16
  17 sub select {
  18   my ($self, $table, $fields, $where, $order, @rest) = @_;
  19   @rest = (-1) unless defined $rest[0];
  20   $self->SUPER::select($table, $self->_recurse_fields($fields),
  21                          $where, $order, @rest);
  22 }
  23
  24 sub _emulate_limit {
  25   my $self = shift;
  26   if ($_[3] == -1) {
  27     return $_[1].$self->_order_by($_[2]);
  28   } else {
  29     return $self->SUPER::_emulate_limit(@_);
  30   }
  31 }
  32
  33 sub _recurse_fields {
  34   my ($self, $fields) = @_;
  35   my $ref = ref $fields;
  36   return $self->_quote($fields) unless $ref;
  37   return $$fields if $ref eq 'SCALAR';
  38
  39   if ($ref eq 'ARRAY') {
  40     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  41   } elsif ($ref eq 'HASH') {
  42     foreach my $func (keys %$fields) {
  43       return $self->_sqlcase($func)
  44         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  45     }
  46   }
  47 }
  48
  49 sub _order_by {
  50   my $self = shift;
  51   my $ret = '';
  52   if (ref $_[0] eq 'HASH') {
  53     if (defined $_[0]->{group_by}) {
  54       $ret = $self->_sqlcase(' group by ')
  55                .$self->_recurse_fields($_[0]->{group_by});
  56     }
  57     if (defined $_[0]->{order_by}) {
  58       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  59     }
  60   } else {
  61     $ret = $self->SUPER::_order_by(@_);
  62   }
  63   return $ret;
  64 }
  65
  66 sub _table {
  67   my ($self, $from) = @_;
  68   if (ref $from eq 'ARRAY') {
  69     return $self->_recurse_from(@$from);
  70   } elsif (ref $from eq 'HASH') {
  71     return $self->_make_as($from);
  72   } else {
  73     return $from;
  74   }
  75 }
  76
  77 sub _recurse_from {
  78   my ($self, $from, @join) = @_;
  79   my @sqlf;
  80   push(@sqlf, $self->_make_as($from));
  81   foreach my $j (@join) {
  82     my ($to, $on) = @$j;
  83
  84     # check whether a join type exists
  85     my $join_clause = '';
  86     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  87       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  88     } else {
  89       $join_clause = ' JOIN ';
  90     }
  91     push(@sqlf, $join_clause);
  92
  93     if (ref $to eq 'ARRAY') {
  94       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  95     } else {
  96       push(@sqlf, $self->_make_as($to));
  97     }
  98     push(@sqlf, ' ON ', $self->_join_condition($on));
  99   }
 100   return join('', @sqlf);
 101 }
 102
 103 sub _make_as {
 104   my ($self, $from) = @_;
 105   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 106                            reverse each %{$self->_skip_options($from)});
 107 }
 108
 109 sub _skip_options {
 110   my ($self, $hash) = @_;
 111   my $clean_hash = {};
 112   $clean_hash->{$_} = $hash->{$_}
 113     for grep {!/^-/} keys %$hash;
 114   return $clean_hash;
 115 }
 116
 117 sub _join_condition {
 118   my ($self, $cond) = @_;
 119   if (ref $cond eq 'HASH') {
 120     my %j;
 121     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 122     return $self->_recurse_where(\%j);
 123   } elsif (ref $cond eq 'ARRAY') {
 124     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 125   } else {
 126     die "Can't handle this yet!";
 127   }
 128 }
 129
 130 sub _quote {
 131   my ($self, $label) = @_;
 132   return '' unless defined $label;
 133   return $label unless $self->{quote_char};
 134   return $self->SUPER::_quote($label);
 135 }
 136
 137 sub _RowNum {
 138    my $self = shift;
 139    my $c;
 140    $_[0] =~ s/SELECT (.*?) FROM/
 141      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 142    $self->SUPER::_RowNum(@_);
 143 }
 144
 145 # Accessor for setting limit dialect. This is useful
 146 # for JDBC-bridge among others where the remote SQL-dialect cannot
 147 # be determined by the name of the driver alone.
 148 #
 149 sub limit_dialect {
 150     my $self = shift;
 151     $self->{limit_dialect} = shift if @_;
 152     return $self->{limit_dialect};
 153 }
 154
 155 package DBIx::Class::Storage::DBI::DebugCallback;
 156
 157 sub print {
 158   my ($self, $string) = @_;
 159   $string =~ m/^(\w+)/;
 160   ${$self}->($1, $string);
 161 }
 162
 163 } # End of BEGIN block
 164
 165 use base qw/DBIx::Class/;
 166
 167 __PACKAGE__->load_components(qw/AccessorGroup/);
 168
 169 __PACKAGE__->mk_group_accessors('simple' =>
 170   qw/connect_info _dbh _sql_maker debug debugfh cursor on_connect_do transaction_depth/);
 171
 172 sub new {
 173   my $new = bless({}, ref $_[0] || $_[0]);
 174   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 175   $new->transaction_depth(0);
 176   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 177      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 178     $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
 179   } else {
 180     $new->debugfh(IO::File->new('>&STDERR'));
 181   }
 182   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 183   return $new;
 184 }
 185
 186 =head1 NAME
 187
 188 DBIx::Class::Storage::DBI - DBI storage handler
 189
 190 =head1 SYNOPSIS
 191
 192 =head1 DESCRIPTION
 193
 194 This class represents the connection to the database
 195
 196 =head1 METHODS
 197
 198 =cut
 199
 200 =head2 on_connect_do
 201
 202 Executes the sql statements given as a listref on every db connect.
 203
 204 =head2 debug
 205
 206 Causes SQL trace information to be emitted on C<debugfh> filehandle
 207 (or C<STDERR> if C<debugfh> has not specifically been set).
 208
 209 =head2 debugfh
 210
 211 Sets or retrieves the filehandle used for trace/debug output.  This
 212 should be an IO::Handle compatible object (only the C<print> method is
 213 used).  Initially set to be STDERR - although see information on the
 214 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 215
 216 =head2 debugcb
 217
 218 Sets a callback to be executed each time a statement is run; takes a sub
 219 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 220 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 221 be printed.
 222
 223 =cut
 224
 225 sub debugcb {
 226   my ($self, $cb) = @_;
 227   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 228   $self->debugfh($cb_obj);
 229 }
 230
 231 sub disconnect {
 232   my ($self) = @_;
 233
 234   if( $self->connected ) {
 235     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 236     $self->_dbh->disconnect;
 237     $self->_dbh(undef);
 238   }
 239 }
 240
 241 sub connected {
 242   my ($self) = @_;
 243
 244   my $dbh;
 245   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 246 }
 247
 248 sub ensure_connected {
 249   my ($self) = @_;
 250
 251   unless ($self->connected) {
 252     $self->_populate_dbh;
 253   }
 254 }
 255
 256 sub dbh {
 257   my ($self) = @_;
 258
 259   $self->ensure_connected;
 260   return $self->_dbh;
 261 }
 262
 263 sub sql_maker {
 264   my ($self) = @_;
 265   unless ($self->_sql_maker) {
 266     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 267   }
 268   return $self->_sql_maker;
 269 }
 270
 271 sub _populate_dbh {
 272   my ($self) = @_;
 273   my @info = @{$self->connect_info || []};
 274   $self->_dbh($self->_connect(@info));
 275
 276   # if on-connect sql statements are given execute them
 277   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 278     $self->_dbh->do($sql_statement);
 279   }
 280 }
 281
 282 sub _connect {
 283   my ($self, @info) = @_;
 284   return DBI->connect(@info);
 285 }
 286
 287 =head2 txn_begin
 288
 289 Calls begin_work on the current dbh.
 290
 291 =cut
 292
 293 sub txn_begin {
 294   my $self = shift;
 295   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 296 }
 297
 298 =head2 txn_commit
 299
 300 Issues a commit against the current dbh.
 301
 302 =cut
 303
 304 sub txn_commit {
 305   my $self = shift;
 306   if ($self->{transaction_depth} == 0) {
 307     $self->dbh->commit unless $self->dbh->{AutoCommit};
 308   }
 309   else {
 310     $self->dbh->commit if --$self->{transaction_depth} == 0;
 311   }
 312 }
 313
 314 =head2 txn_rollback
 315
 316 Issues a rollback against the current dbh.
 317
 318 =cut
 319
 320 sub txn_rollback {
 321   my $self = shift;
 322   if ($self->{transaction_depth} == 0) {
 323     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 324   }
 325   else {
 326     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 327   }
 328 }
 329
 330 sub _execute {
 331   my ($self, $op, $extra_bind, $ident, @args) = @_;
 332   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 333   unshift(@bind, @$extra_bind) if $extra_bind;
 334   if ($self->debug) {
 335       my @debug_bind = map { defined $_ ? $_ : 'NULL' } @bind;
 336       $self->debugfh->print("$sql: @debug_bind\n");
 337   }
 338   my $sth = $self->sth($sql,$op);
 339   croak "no sth generated via sql: $sql" unless $sth;
 340   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 341   my $rv;
 342   if ($sth) {
 343     $rv = $sth->execute(@bind);
 344   } else {
 345     croak "'$sql' did not generate a statement.";
 346   }
 347   return (wantarray ? ($rv, $sth, @bind) : $rv);
 348 }
 349
 350 sub insert {
 351   my ($self, $ident, $to_insert) = @_;
 352   croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 353     unless ($self->_execute('insert' => [], $ident, $to_insert));
 354   return $to_insert;
 355 }
 356
 357 sub update {
 358   return shift->_execute('update' => [], @_);
 359 }
 360
 361 sub delete {
 362   return shift->_execute('delete' => [], @_);
 363 }
 364
 365 sub _select {
 366   my ($self, $ident, $select, $condition, $attrs) = @_;
 367   my $order = $attrs->{order_by};
 368   if (ref $condition eq 'SCALAR') {
 369     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 370   }
 371   if (exists $attrs->{group_by}) {
 372     $order = { group_by => $attrs->{group_by},
 373                ($order ? (order_by => $order) : ()) };
 374   }
 375   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 376   if ($attrs->{software_limit} ||
 377       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 378         $attrs->{software_limit} = 1;
 379   } else {
 380     push @args, $attrs->{rows}, $attrs->{offset};
 381   }
 382   return $self->_execute(@args);
 383 }
 384
 385 sub select {
 386   my $self = shift;
 387   my ($ident, $select, $condition, $attrs) = @_;
 388   return $self->cursor->new($self, \@_, $attrs);
 389 }
 390
 391 # Need to call finish() to work round broken DBDs
 392
 393 sub select_single {
 394   my $self = shift;
 395   my ($rv, $sth, @bind) = $self->_select(@_);
 396   my @row = $sth->fetchrow_array;
 397   $sth->finish();
 398   return @row;
 399 }
 400
 401 sub sth {
 402   my ($self, $sql) = @_;
 403   # 3 is the if_active parameter which avoids active sth re-use
 404   return $self->dbh->prepare_cached($sql, {}, 3);
 405 }
 406
 407 =head2 columns_info_for
 408
 409 Returns database type info for a given table columns.
 410
 411 =cut
 412
 413 sub columns_info_for {
 414     my ($self, $table) = @_;
 415     my %result;
 416     if ( $self->dbh->can( 'column_info' ) ){
 417         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 418         $sth->execute();
 419         while ( my $info = $sth->fetchrow_hashref() ){
 420             my %column_info;
 421             $column_info{data_type} = $info->{TYPE_NAME};
 422             $column_info{size} = $info->{COLUMN_SIZE};
 423             $column_info{is_nullable} = $info->{NULLABLE};
 424             $result{$info->{COLUMN_NAME}} = \%column_info;
 425         }
 426     }else{
 427         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 428         $sth->execute;
 429         my @columns = @{$sth->{NAME}};
 430         for my $i ( 0 .. $#columns ){
 431             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 432         }
 433     }
 434     return \%result;
 435 }
 436
 437 sub DESTROY { shift->disconnect }
 438
 439 1;
 440
 441 =head1 ENVIRONMENT VARIABLES
 442
 443 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 444
 445 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 446 is produced (as when the L<debug> method is set).
 447
 448 If the value is of the form C<1=/path/name> then the trace output is
 449 written to the file C</path/name>.
 450
 451 =head1 AUTHORS
 452
 453 Matt S. Trout <mst@shadowcatsystems.co.uk>
 454
 455 Andy Grundman <andy@hybridized.org>
 456
 457 =head1 LICENSE
 458
 459 You may distribute this code under the same terms as Perl itself.
 460
 461 =cut
 462