lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use DBIx::Class::SQLAHacks;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14 use List::Util();
  15
  16 __PACKAGE__->mk_group_accessors('simple' =>
  17     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  18        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  19 );
  20
  21 # the values for these accessors are picked out (and deleted) from
  22 # the attribute hashref passed to connect_info
  23 my @storage_options = qw/
  24   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  25 /;
  26 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  27
  28
  29 # default cursor class, overridable in connect_info attributes
  30 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  31
  32 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  33 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  34
  35
  36 =head1 NAME
  37
  38 DBIx::Class::Storage::DBI - DBI storage handler
  39
  40 =head1 SYNOPSIS
  41
  42   my $schema = MySchema->connect('dbi:SQLite:my.db');
  43
  44   $schema->storage->debug(1);
  45   $schema->dbh_do("DROP TABLE authors");
  46
  47   $schema->resultset('Book')->search({
  48      written_on => $schema->storage->datetime_parser(DateTime->now)
  49   });
  50
  51 =head1 DESCRIPTION
  52
  53 This class represents the connection to an RDBMS via L<DBI>.  See
  54 L<DBIx::Class::Storage> for general information.  This pod only
  55 documents DBI-specific methods and behaviors.
  56
  57 =head1 METHODS
  58
  59 =cut
  60
  61 sub new {
  62   my $new = shift->next::method(@_);
  63
  64   $new->transaction_depth(0);
  65   $new->_sql_maker_opts({});
  66   $new->{savepoints} = [];
  67   $new->{_in_dbh_do} = 0;
  68   $new->{_dbh_gen} = 0;
  69
  70   $new;
  71 }
  72
  73 =head2 connect_info
  74
  75 This method is normally called by L<DBIx::Class::Schema/connection>, which
  76 encapsulates its argument list in an arrayref before passing them here.
  77
  78 The argument list may contain:
  79
  80 =over
  81
  82 =item *
  83
  84 The same 4-element argument set one would normally pass to
  85 L<DBI/connect>, optionally followed by
  86 L<extra attributes|/DBIx::Class specific connection attributes>
  87 recognized by DBIx::Class:
  88
  89   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
  90
  91 =item *
  92
  93 A single code reference which returns a connected
  94 L<DBI database handle|DBI/connect> optionally followed by
  95 L<extra attributes|/DBIx::Class specific connection attributes> recognized
  96 by DBIx::Class:
  97
  98   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
  99
 100 =item *
 101
 102 A single hashref with all the attributes and the dsn/user/password
 103 mixed together:
 104
 105   $connect_info_args = [{
 106     dsn => $dsn,
 107     user => $user,
 108     password => $pass,
 109     %dbi_attributes,
 110     %extra_attributes,
 111   }];
 112
 113 This is particularly useful for L<Catalyst> based applications, allowing the
 114 following config (L<Config::General> style):
 115
 116   <Model::DB>
 117     schema_class   App::DB
 118     <connect_info>
 119       dsn          dbi:mysql:database=test
 120       user         testuser
 121       password     TestPass
 122       AutoCommit   1
 123     </connect_info>
 124   </Model::DB>
 125
 126 =back
 127
 128 Please note that the L<DBI> docs recommend that you always explicitly
 129 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 130 recommends that it be set to I<1>, and that you perform transactions
 131 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 132 to I<1> if you do not do explicitly set it to zero.  This is the default
 133 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 134
 135 =head3 DBIx::Class specific connection attributes
 136
 137 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 138 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 139 the following connection options. These options can be mixed in with your other
 140 L<DBI> connection attributes, or placed in a seperate hashref
 141 (C<\%extra_attributes>) as shown above.
 142
 143 Every time C<connect_info> is invoked, any previous settings for
 144 these options will be cleared before setting the new ones, regardless of
 145 whether any options are specified in the new C<connect_info>.
 146
 147
 148 =over
 149
 150 =item on_connect_do
 151
 152 Specifies things to do immediately after connecting or re-connecting to
 153 the database.  Its value may contain:
 154
 155 =over
 156
 157 =item a scalar
 158
 159 This contains one SQL statement to execute.
 160
 161 =item an array reference
 162
 163 This contains SQL statements to execute in order.  Each element contains
 164 a string or a code reference that returns a string.
 165
 166 =item a code reference
 167
 168 This contains some code to execute.  Unlike code references within an
 169 array reference, its return value is ignored.
 170
 171 =back
 172
 173 =item on_disconnect_do
 174
 175 Takes arguments in the same form as L</on_connect_do> and executes them
 176 immediately before disconnecting from the database.
 177
 178 Note, this only runs if you explicitly call L</disconnect> on the
 179 storage object.
 180
 181 =item disable_sth_caching
 182
 183 If set to a true value, this option will disable the caching of
 184 statement handles via L<DBI/prepare_cached>.
 185
 186 =item limit_dialect
 187
 188 Sets the limit dialect. This is useful for JDBC-bridge among others
 189 where the remote SQL-dialect cannot be determined by the name of the
 190 driver alone. See also L<SQL::Abstract::Limit>.
 191
 192 =item quote_char
 193
 194 Specifies what characters to use to quote table and column names. If
 195 you use this you will want to specify L</name_sep> as well.
 196
 197 C<quote_char> expects either a single character, in which case is it
 198 is placed on either side of the table/column name, or an arrayref of length
 199 2 in which case the table/column name is placed between the elements.
 200
 201 For example under MySQL you should use C<< quote_char => '`' >>, and for
 202 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 203
 204 =item name_sep
 205
 206 This only needs to be used in conjunction with C<quote_char>, and is used to
 207 specify the charecter that seperates elements (schemas, tables, columns) from
 208 each other. In most cases this is simply a C<.>.
 209
 210 The consequences of not supplying this value is that L<SQL::Abstract>
 211 will assume DBIx::Class' uses of aliases to be complete column
 212 names. The output will look like I<"me.name"> when it should actually
 213 be I<"me"."name">.
 214
 215 =item unsafe
 216
 217 This Storage driver normally installs its own C<HandleError>, sets
 218 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 219 all database handles, including those supplied by a coderef.  It does this
 220 so that it can have consistent and useful error behavior.
 221
 222 If you set this option to a true value, Storage will not do its usual
 223 modifications to the database handle's attributes, and instead relies on
 224 the settings in your connect_info DBI options (or the values you set in
 225 your connection coderef, in the case that you are connecting via coderef).
 226
 227 Note that your custom settings can cause Storage to malfunction,
 228 especially if you set a C<HandleError> handler that suppresses exceptions
 229 and/or disable C<RaiseError>.
 230
 231 =item auto_savepoint
 232
 233 If this option is true, L<DBIx::Class> will use savepoints when nesting
 234 transactions, making it possible to recover from failure in the inner
 235 transaction without having to abort all outer transactions.
 236
 237 =item cursor_class
 238
 239 Use this argument to supply a cursor class other than the default
 240 L<DBIx::Class::Storage::DBI::Cursor>.
 241
 242 =back
 243
 244 Some real-life examples of arguments to L</connect_info> and
 245 L<DBIx::Class::Schema/connect>
 246
 247   # Simple SQLite connection
 248   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 249
 250   # Connect via subref
 251   ->connect_info([ sub { DBI->connect(...) } ]);
 252
 253   # A bit more complicated
 254   ->connect_info(
 255     [
 256       'dbi:Pg:dbname=foo',
 257       'postgres',
 258       'my_pg_password',
 259       { AutoCommit => 1 },
 260       { quote_char => q{"}, name_sep => q{.} },
 261     ]
 262   );
 263
 264   # Equivalent to the previous example
 265   ->connect_info(
 266     [
 267       'dbi:Pg:dbname=foo',
 268       'postgres',
 269       'my_pg_password',
 270       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 271     ]
 272   );
 273
 274   # Same, but with hashref as argument
 275   # See parse_connect_info for explanation
 276   ->connect_info(
 277     [{
 278       dsn         => 'dbi:Pg:dbname=foo',
 279       user        => 'postgres',
 280       password    => 'my_pg_password',
 281       AutoCommit  => 1,
 282       quote_char  => q{"},
 283       name_sep    => q{.},
 284     }]
 285   );
 286
 287   # Subref + DBIx::Class-specific connection options
 288   ->connect_info(
 289     [
 290       sub { DBI->connect(...) },
 291       {
 292           quote_char => q{`},
 293           name_sep => q{@},
 294           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 295           disable_sth_caching => 1,
 296       },
 297     ]
 298   );
 299
 300
 301
 302 =cut
 303
 304 sub connect_info {
 305   my ($self, $info_arg) = @_;
 306
 307   return $self->_connect_info if !$info_arg;
 308
 309   my @args = @$info_arg;  # take a shallow copy for further mutilation
 310   $self->_connect_info([@args]); # copy for _connect_info
 311
 312
 313   # combine/pre-parse arguments depending on invocation style
 314
 315   my %attrs;
 316   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 317     %attrs = %{ $args[1] || {} };
 318     @args = $args[0];
 319   }
 320   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 321     %attrs = %{$args[0]};
 322     @args = ();
 323     for (qw/password user dsn/) {
 324       unshift @args, delete $attrs{$_};
 325     }
 326   }
 327   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 328     %attrs = (
 329       % { $args[3] || {} },
 330       % { $args[4] || {} },
 331     );
 332     @args = @args[0,1,2];
 333   }
 334
 335   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 336   #  the new set of options
 337   $self->_sql_maker(undef);
 338   $self->_sql_maker_opts({});
 339
 340   if(keys %attrs) {
 341     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 342       if(my $value = delete $attrs{$storage_opt}) {
 343         $self->$storage_opt($value);
 344       }
 345     }
 346     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 347       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 348         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 349       }
 350     }
 351   }
 352
 353   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 354
 355   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 356   $self->_connect_info;
 357 }
 358
 359 =head2 on_connect_do
 360
 361 This method is deprecated in favour of setting via L</connect_info>.
 362
 363
 364 =head2 dbh_do
 365
 366 Arguments: ($subref | $method_name), @extra_coderef_args?
 367
 368 Execute the given $subref or $method_name using the new exception-based
 369 connection management.
 370
 371 The first two arguments will be the storage object that C<dbh_do> was called
 372 on and a database handle to use.  Any additional arguments will be passed
 373 verbatim to the called subref as arguments 2 and onwards.
 374
 375 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 376 exception handling and reconnection (or failover in future subclasses).
 377
 378 Your subref should have no side-effects outside of the database, as
 379 there is the potential for your subref to be partially double-executed
 380 if the database connection was stale/dysfunctional.
 381
 382 Example:
 383
 384   my @stuff = $schema->storage->dbh_do(
 385     sub {
 386       my ($storage, $dbh, @cols) = @_;
 387       my $cols = join(q{, }, @cols);
 388       $dbh->selectrow_array("SELECT $cols FROM foo");
 389     },
 390     @column_list
 391   );
 392
 393 =cut
 394
 395 sub dbh_do {
 396   my $self = shift;
 397   my $code = shift;
 398
 399   my $dbh = $self->_dbh;
 400
 401   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 402       || $self->{transaction_depth};
 403
 404   local $self->{_in_dbh_do} = 1;
 405
 406   my @result;
 407   my $want_array = wantarray;
 408
 409   eval {
 410     $self->_verify_pid if $dbh;
 411     if(!$self->_dbh) {
 412         $self->_populate_dbh;
 413         $dbh = $self->_dbh;
 414     }
 415
 416     if($want_array) {
 417         @result = $self->$code($dbh, @_);
 418     }
 419     elsif(defined $want_array) {
 420         $result[0] = $self->$code($dbh, @_);
 421     }
 422     else {
 423         $self->$code($dbh, @_);
 424     }
 425   };
 426
 427   my $exception = $@;
 428   if(!$exception) { return $want_array ? @result : $result[0] }
 429
 430   $self->throw_exception($exception) if $self->connected;
 431
 432   # We were not connected - reconnect and retry, but let any
 433   #  exception fall right through this time
 434   $self->_populate_dbh;
 435   $self->$code($self->_dbh, @_);
 436 }
 437
 438 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 439 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 440 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 441 sub txn_do {
 442   my $self = shift;
 443   my $coderef = shift;
 444
 445   ref $coderef eq 'CODE' or $self->throw_exception
 446     ('$coderef must be a CODE reference');
 447
 448   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 449
 450   local $self->{_in_dbh_do} = 1;
 451
 452   my @result;
 453   my $want_array = wantarray;
 454
 455   my $tried = 0;
 456   while(1) {
 457     eval {
 458       $self->_verify_pid if $self->_dbh;
 459       $self->_populate_dbh if !$self->_dbh;
 460
 461       $self->txn_begin;
 462       if($want_array) {
 463           @result = $coderef->(@_);
 464       }
 465       elsif(defined $want_array) {
 466           $result[0] = $coderef->(@_);
 467       }
 468       else {
 469           $coderef->(@_);
 470       }
 471       $self->txn_commit;
 472     };
 473
 474     my $exception = $@;
 475     if(!$exception) { return $want_array ? @result : $result[0] }
 476
 477     if($tried++ > 0 || $self->connected) {
 478       eval { $self->txn_rollback };
 479       my $rollback_exception = $@;
 480       if($rollback_exception) {
 481         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 482         $self->throw_exception($exception)  # propagate nested rollback
 483           if $rollback_exception =~ /$exception_class/;
 484
 485         $self->throw_exception(
 486           "Transaction aborted: ${exception}. "
 487           . "Rollback failed: ${rollback_exception}"
 488         );
 489       }
 490       $self->throw_exception($exception)
 491     }
 492
 493     # We were not connected, and was first try - reconnect and retry
 494     # via the while loop
 495     $self->_populate_dbh;
 496   }
 497 }
 498
 499 =head2 disconnect
 500
 501 Our C<disconnect> method also performs a rollback first if the
 502 database is not in C<AutoCommit> mode.
 503
 504 =cut
 505
 506 sub disconnect {
 507   my ($self) = @_;
 508
 509   if( $self->connected ) {
 510     my $connection_do = $self->on_disconnect_do;
 511     $self->_do_connection_actions($connection_do) if ref($connection_do);
 512
 513     $self->_dbh->rollback unless $self->_dbh_autocommit;
 514     $self->_dbh->disconnect;
 515     $self->_dbh(undef);
 516     $self->{_dbh_gen}++;
 517   }
 518 }
 519
 520 =head2 with_deferred_fk_checks
 521
 522 =over 4
 523
 524 =item Arguments: C<$coderef>
 525
 526 =item Return Value: The return value of $coderef
 527
 528 =back
 529
 530 Storage specific method to run the code ref with FK checks deferred or
 531 in MySQL's case disabled entirely.
 532
 533 =cut
 534
 535 # Storage subclasses should override this
 536 sub with_deferred_fk_checks {
 537   my ($self, $sub) = @_;
 538
 539   $sub->();
 540 }
 541
 542 sub connected {
 543   my ($self) = @_;
 544
 545   if(my $dbh = $self->_dbh) {
 546       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 547           $self->_dbh(undef);
 548           $self->{_dbh_gen}++;
 549           return;
 550       }
 551       else {
 552           $self->_verify_pid;
 553           return 0 if !$self->_dbh;
 554       }
 555       return ($dbh->FETCH('Active') && $dbh->ping);
 556   }
 557
 558   return 0;
 559 }
 560
 561 # handle pid changes correctly
 562 #  NOTE: assumes $self->_dbh is a valid $dbh
 563 sub _verify_pid {
 564   my ($self) = @_;
 565
 566   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 567
 568   $self->_dbh->{InactiveDestroy} = 1;
 569   $self->_dbh(undef);
 570   $self->{_dbh_gen}++;
 571
 572   return;
 573 }
 574
 575 sub ensure_connected {
 576   my ($self) = @_;
 577
 578   unless ($self->connected) {
 579     $self->_populate_dbh;
 580   }
 581 }
 582
 583 =head2 dbh
 584
 585 Returns the dbh - a data base handle of class L<DBI>.
 586
 587 =cut
 588
 589 sub dbh {
 590   my ($self) = @_;
 591
 592   $self->ensure_connected;
 593   return $self->_dbh;
 594 }
 595
 596 sub _sql_maker_args {
 597     my ($self) = @_;
 598
 599     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 600 }
 601
 602 sub sql_maker {
 603   my ($self) = @_;
 604   unless ($self->_sql_maker) {
 605     my $sql_maker_class = $self->sql_maker_class;
 606     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 607   }
 608   return $self->_sql_maker;
 609 }
 610
 611 sub _rebless {}
 612
 613 sub _populate_dbh {
 614   my ($self) = @_;
 615   my @info = @{$self->_dbi_connect_info || []};
 616   $self->_dbh($self->_connect(@info));
 617
 618   $self->_conn_pid($$);
 619   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 620
 621   $self->_determine_driver;
 622
 623   # Always set the transaction depth on connect, since
 624   #  there is no transaction in progress by definition
 625   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 626
 627   my $connection_do = $self->on_connect_do;
 628   $self->_do_connection_actions($connection_do) if $connection_do;
 629 }
 630
 631 sub _determine_driver {
 632   my ($self) = @_;
 633
 634   if (ref $self eq 'DBIx::Class::Storage::DBI') {
 635     my $driver;
 636
 637     if ($self->_dbh) { # we are connected
 638       $driver = $self->_dbh->{Driver}{Name};
 639     } else {
 640       # try to use dsn to not require being connected, the driver may still
 641       # force a connection in _rebless to determine version
 642       ($driver) = $self->_dbi_connect_info->[0] =~ /dbi:([^:]+):/i;
 643     }
 644
 645     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 646       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 647       $self->_rebless();
 648     }
 649   }
 650 }
 651
 652 sub _do_connection_actions {
 653   my $self = shift;
 654   my $connection_do = shift;
 655
 656   if (!ref $connection_do) {
 657     $self->_do_query($connection_do);
 658   }
 659   elsif (ref $connection_do eq 'ARRAY') {
 660     $self->_do_query($_) foreach @$connection_do;
 661   }
 662   elsif (ref $connection_do eq 'CODE') {
 663     $connection_do->($self);
 664   }
 665   else {
 666     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref $connection_do) );
 667   }
 668
 669   return $self;
 670 }
 671
 672 sub _do_query {
 673   my ($self, $action) = @_;
 674
 675   if (ref $action eq 'CODE') {
 676     $action = $action->($self);
 677     $self->_do_query($_) foreach @$action;
 678   }
 679   else {
 680     # Most debuggers expect ($sql, @bind), so we need to exclude
 681     # the attribute hash which is the second argument to $dbh->do
 682     # furthermore the bind values are usually to be presented
 683     # as named arrayref pairs, so wrap those here too
 684     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 685     my $sql = shift @do_args;
 686     my $attrs = shift @do_args;
 687     my @bind = map { [ undef, $_ ] } @do_args;
 688
 689     $self->_query_start($sql, @bind);
 690     $self->_dbh->do($sql, $attrs, @do_args);
 691     $self->_query_end($sql, @bind);
 692   }
 693
 694   return $self;
 695 }
 696
 697 sub _connect {
 698   my ($self, @info) = @_;
 699
 700   $self->throw_exception("You failed to provide any connection info")
 701     if !@info;
 702
 703   my ($old_connect_via, $dbh);
 704
 705   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 706     $old_connect_via = $DBI::connect_via;
 707     $DBI::connect_via = 'connect';
 708   }
 709
 710   eval {
 711     if(ref $info[0] eq 'CODE') {
 712        $dbh = &{$info[0]}
 713     }
 714     else {
 715        $dbh = DBI->connect(@info);
 716     }
 717
 718     if($dbh && !$self->unsafe) {
 719       my $weak_self = $self;
 720       weaken($weak_self);
 721       $dbh->{HandleError} = sub {
 722           if ($weak_self) {
 723             $weak_self->throw_exception("DBI Exception: $_[0]");
 724           }
 725           else {
 726             croak ("DBI Exception: $_[0]");
 727           }
 728       };
 729       $dbh->{ShowErrorStatement} = 1;
 730       $dbh->{RaiseError} = 1;
 731       $dbh->{PrintError} = 0;
 732     }
 733   };
 734
 735   $DBI::connect_via = $old_connect_via if $old_connect_via;
 736
 737   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 738     if !$dbh || $@;
 739
 740   $self->_dbh_autocommit($dbh->{AutoCommit});
 741
 742   $dbh;
 743 }
 744
 745 sub svp_begin {
 746   my ($self, $name) = @_;
 747
 748   $name = $self->_svp_generate_name
 749     unless defined $name;
 750
 751   $self->throw_exception ("You can't use savepoints outside a transaction")
 752     if $self->{transaction_depth} == 0;
 753
 754   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 755     unless $self->can('_svp_begin');
 756
 757   push @{ $self->{savepoints} }, $name;
 758
 759   $self->debugobj->svp_begin($name) if $self->debug;
 760
 761   return $self->_svp_begin($name);
 762 }
 763
 764 sub svp_release {
 765   my ($self, $name) = @_;
 766
 767   $self->throw_exception ("You can't use savepoints outside a transaction")
 768     if $self->{transaction_depth} == 0;
 769
 770   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 771     unless $self->can('_svp_release');
 772
 773   if (defined $name) {
 774     $self->throw_exception ("Savepoint '$name' does not exist")
 775       unless grep { $_ eq $name } @{ $self->{savepoints} };
 776
 777     # Dig through the stack until we find the one we are releasing.  This keeps
 778     # the stack up to date.
 779     my $svp;
 780
 781     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 782   } else {
 783     $name = pop @{ $self->{savepoints} };
 784   }
 785
 786   $self->debugobj->svp_release($name) if $self->debug;
 787
 788   return $self->_svp_release($name);
 789 }
 790
 791 sub svp_rollback {
 792   my ($self, $name) = @_;
 793
 794   $self->throw_exception ("You can't use savepoints outside a transaction")
 795     if $self->{transaction_depth} == 0;
 796
 797   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 798     unless $self->can('_svp_rollback');
 799
 800   if (defined $name) {
 801       # If they passed us a name, verify that it exists in the stack
 802       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 803           $self->throw_exception("Savepoint '$name' does not exist!");
 804       }
 805
 806       # Dig through the stack until we find the one we are releasing.  This keeps
 807       # the stack up to date.
 808       while(my $s = pop(@{ $self->{savepoints} })) {
 809           last if($s eq $name);
 810       }
 811       # Add the savepoint back to the stack, as a rollback doesn't remove the
 812       # named savepoint, only everything after it.
 813       push(@{ $self->{savepoints} }, $name);
 814   } else {
 815       # We'll assume they want to rollback to the last savepoint
 816       $name = $self->{savepoints}->[-1];
 817   }
 818
 819   $self->debugobj->svp_rollback($name) if $self->debug;
 820
 821   return $self->_svp_rollback($name);
 822 }
 823
 824 sub _svp_generate_name {
 825     my ($self) = @_;
 826
 827     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 828 }
 829
 830 sub txn_begin {
 831   my $self = shift;
 832   $self->ensure_connected();
 833   if($self->{transaction_depth} == 0) {
 834     $self->debugobj->txn_begin()
 835       if $self->debug;
 836     # this isn't ->_dbh-> because
 837     #  we should reconnect on begin_work
 838     #  for AutoCommit users
 839     $self->dbh->begin_work;
 840   } elsif ($self->auto_savepoint) {
 841     $self->svp_begin;
 842   }
 843   $self->{transaction_depth}++;
 844 }
 845
 846 sub txn_commit {
 847   my $self = shift;
 848   if ($self->{transaction_depth} == 1) {
 849     my $dbh = $self->_dbh;
 850     $self->debugobj->txn_commit()
 851       if ($self->debug);
 852     $dbh->commit;
 853     $self->{transaction_depth} = 0
 854       if $self->_dbh_autocommit;
 855   }
 856   elsif($self->{transaction_depth} > 1) {
 857     $self->{transaction_depth}--;
 858     $self->svp_release
 859       if $self->auto_savepoint;
 860   }
 861 }
 862
 863 sub txn_rollback {
 864   my $self = shift;
 865   my $dbh = $self->_dbh;
 866   eval {
 867     if ($self->{transaction_depth} == 1) {
 868       $self->debugobj->txn_rollback()
 869         if ($self->debug);
 870       $self->{transaction_depth} = 0
 871         if $self->_dbh_autocommit;
 872       $dbh->rollback;
 873     }
 874     elsif($self->{transaction_depth} > 1) {
 875       $self->{transaction_depth}--;
 876       if ($self->auto_savepoint) {
 877         $self->svp_rollback;
 878         $self->svp_release;
 879       }
 880     }
 881     else {
 882       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 883     }
 884   };
 885   if ($@) {
 886     my $error = $@;
 887     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 888     $error =~ /$exception_class/ and $self->throw_exception($error);
 889     # ensure that a failed rollback resets the transaction depth
 890     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 891     $self->throw_exception($error);
 892   }
 893 }
 894
 895 # This used to be the top-half of _execute.  It was split out to make it
 896 #  easier to override in NoBindVars without duping the rest.  It takes up
 897 #  all of _execute's args, and emits $sql, @bind.
 898 sub _prep_for_execute {
 899   my ($self, $op, $extra_bind, $ident, $args) = @_;
 900
 901   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 902     $ident = $ident->from();
 903   }
 904
 905   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 906
 907   unshift(@bind,
 908     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 909       if $extra_bind;
 910   return ($sql, \@bind);
 911 }
 912
 913 sub _fix_bind_params {
 914     my ($self, @bind) = @_;
 915
 916     ### Turn @bind from something like this:
 917     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 918     ### to this:
 919     ###   ( "'1'", "'1'", "'3'" )
 920     return
 921         map {
 922             if ( defined( $_ && $_->[1] ) ) {
 923                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 924             }
 925             else { q{'NULL'}; }
 926         } @bind;
 927 }
 928
 929 sub _query_start {
 930     my ( $self, $sql, @bind ) = @_;
 931
 932     if ( $self->debug ) {
 933         @bind = $self->_fix_bind_params(@bind);
 934
 935         $self->debugobj->query_start( $sql, @bind );
 936     }
 937 }
 938
 939 sub _query_end {
 940     my ( $self, $sql, @bind ) = @_;
 941
 942     if ( $self->debug ) {
 943         @bind = $self->_fix_bind_params(@bind);
 944         $self->debugobj->query_end( $sql, @bind );
 945     }
 946 }
 947
 948 sub _dbh_execute {
 949   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 950
 951   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 952
 953   $self->_query_start( $sql, @$bind );
 954
 955   my $sth = $self->sth($sql,$op);
 956
 957   my $placeholder_index = 1;
 958
 959   foreach my $bound (@$bind) {
 960     my $attributes = {};
 961     my($column_name, @data) = @$bound;
 962
 963     if ($bind_attributes) {
 964       $attributes = $bind_attributes->{$column_name}
 965       if defined $bind_attributes->{$column_name};
 966     }
 967
 968     foreach my $data (@data) {
 969       my $ref = ref $data;
 970       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
 971
 972       $sth->bind_param($placeholder_index, $data, $attributes);
 973       $placeholder_index++;
 974     }
 975   }
 976
 977   # Can this fail without throwing an exception anyways???
 978   my $rv = $sth->execute();
 979   $self->throw_exception($sth->errstr) if !$rv;
 980
 981   $self->_query_end( $sql, @$bind );
 982
 983   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 984 }
 985
 986 sub _execute {
 987     my $self = shift;
 988     $self->dbh_do('_dbh_execute', @_)
 989 }
 990
 991 sub insert {
 992   my ($self, $source, $to_insert) = @_;
 993
 994   my $ident = $source->from;
 995   my $bind_attributes = $self->source_bind_attributes($source);
 996
 997   my $updated_cols = {};
 998
 999   $self->ensure_connected;
1000   foreach my $col ( $source->columns ) {
1001     if ( !defined $to_insert->{$col} ) {
1002       my $col_info = $source->column_info($col);
1003
1004       if ( $col_info->{auto_nextval} ) {
1005         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1006       }
1007     }
1008   }
1009
1010   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1011
1012   return $updated_cols;
1013 }
1014
1015 ## Still not quite perfect, and EXPERIMENTAL
1016 ## Currently it is assumed that all values passed will be "normal", i.e. not
1017 ## scalar refs, or at least, all the same type as the first set, the statement is
1018 ## only prepped once.
1019 sub insert_bulk {
1020   my ($self, $source, $cols, $data) = @_;
1021   my %colvalues;
1022   my $table = $source->from;
1023   @colvalues{@$cols} = (0..$#$cols);
1024   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1025
1026   $self->_query_start( $sql, @bind );
1027   my $sth = $self->sth($sql);
1028
1029 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1030
1031   ## This must be an arrayref, else nothing works!
1032   my $tuple_status = [];
1033
1034   ## Get the bind_attributes, if any exist
1035   my $bind_attributes = $self->source_bind_attributes($source);
1036
1037   ## Bind the values and execute
1038   my $placeholder_index = 1;
1039
1040   foreach my $bound (@bind) {
1041
1042     my $attributes = {};
1043     my ($column_name, $data_index) = @$bound;
1044
1045     if( $bind_attributes ) {
1046       $attributes = $bind_attributes->{$column_name}
1047       if defined $bind_attributes->{$column_name};
1048     }
1049
1050     my @data = map { $_->[$data_index] } @$data;
1051
1052     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1053     $placeholder_index++;
1054   }
1055   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1056   $self->throw_exception($sth->errstr) if !$rv;
1057
1058   $self->_query_end( $sql, @bind );
1059   return (wantarray ? ($rv, $sth, @bind) : $rv);
1060 }
1061
1062 sub update {
1063   my $self = shift @_;
1064   my $source = shift @_;
1065   my $bind_attributes = $self->source_bind_attributes($source);
1066
1067   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1068 }
1069
1070
1071 sub delete {
1072   my $self = shift @_;
1073   my $source = shift @_;
1074
1075   my $bind_attrs = {}; ## If ever it's needed...
1076
1077   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1078 }
1079
1080 # We were sent here because the $rs contains a complex search
1081 # which will require a subquery to select the correct rows
1082 # (i.e. joined or limited resultsets)
1083 #
1084 # Genarating a single PK column subquery is trivial and supported
1085 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1086 # Look at _multipk_update_delete()
1087 sub subq_update_delete {
1088   my $self = shift;
1089   my ($rs, $op, $values) = @_;
1090
1091   my $rsrc = $rs->result_source;
1092
1093   # we already check this, but double check naively just in case. Should be removed soon
1094   my $sel = $rs->_resolved_attrs->{select};
1095   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1096   my @pcols = $rsrc->primary_columns;
1097   if (@$sel != @pcols) {
1098     $self->throw_exception (
1099       'Subquery update/delete can not be called on resultsets selecting a'
1100      .' number of columns different than the number of primary keys'
1101     );
1102   }
1103
1104   if (@pcols == 1) {
1105     return $self->$op (
1106       $rsrc,
1107       $op eq 'update' ? $values : (),
1108       { $pcols[0] => { -in => $rs->as_query } },
1109     );
1110   }
1111
1112   else {
1113     return $self->_multipk_update_delete (@_);
1114   }
1115 }
1116
1117 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1118 # resultset update/delete involving subqueries. So by default resort
1119 # to simple (and inefficient) delete_all style per-row opearations,
1120 # while allowing specific storages to override this with a faster
1121 # implementation.
1122 #
1123 sub _multipk_update_delete {
1124   return shift->_per_row_update_delete (@_);
1125 }
1126
1127 # This is the default loop used to delete/update rows for multi PK
1128 # resultsets, and used by mysql exclusively (because it can't do anything
1129 # else).
1130 #
1131 # We do not use $row->$op style queries, because resultset update/delete
1132 # is not expected to cascade (this is what delete_all/update_all is for).
1133 #
1134 # There should be no race conditions as the entire operation is rolled
1135 # in a transaction.
1136 #
1137 sub _per_row_update_delete {
1138   my $self = shift;
1139   my ($rs, $op, $values) = @_;
1140
1141   my $rsrc = $rs->result_source;
1142   my @pcols = $rsrc->primary_columns;
1143
1144   my $guard = $self->txn_scope_guard;
1145
1146   # emulate the return value of $sth->execute for non-selects
1147   my $row_cnt = '0E0';
1148
1149   my $subrs_cur = $rs->cursor;
1150   while (my @pks = $subrs_cur->next) {
1151
1152     my $cond;
1153     for my $i (0.. $#pcols) {
1154       $cond->{$pcols[$i]} = $pks[$i];
1155     }
1156
1157     $self->$op (
1158       $rsrc,
1159       $op eq 'update' ? $values : (),
1160       $cond,
1161     );
1162
1163     $row_cnt++;
1164   }
1165
1166   $guard->commit;
1167
1168   return $row_cnt;
1169 }
1170
1171 sub _select {
1172   my $self = shift;
1173   my $sql_maker = $self->sql_maker;
1174   local $sql_maker->{for};
1175   return $self->_execute($self->_select_args(@_));
1176 }
1177
1178 sub _select_args {
1179   my ($self, $ident, $select, $condition, $attrs) = @_;
1180   my $order = $attrs->{order_by};
1181
1182   my $for = delete $attrs->{for};
1183   my $sql_maker = $self->sql_maker;
1184   $sql_maker->{for} = $for;
1185
1186   my @in_order_attrs = qw/group_by having _virtual_order_by/;
1187   if (List::Util::first { exists $attrs->{$_} } (@in_order_attrs) ) {
1188     $order = {
1189       ($order
1190         ? (order_by => $order)
1191         : ()
1192       ),
1193       ( map { $_ => $attrs->{$_} } (@in_order_attrs) )
1194     };
1195   }
1196   my $bind_attrs = {}; ## Future support
1197   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1198   if ($attrs->{software_limit} ||
1199       $sql_maker->_default_limit_syntax eq "GenericSubQ") {
1200         $attrs->{software_limit} = 1;
1201   } else {
1202     $self->throw_exception("rows attribute must be positive if present")
1203       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1204
1205     # MySQL actually recommends this approach.  I cringe.
1206     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1207     push @args, $attrs->{rows}, $attrs->{offset};
1208   }
1209   return @args;
1210 }
1211
1212 sub source_bind_attributes {
1213   my ($self, $source) = @_;
1214
1215   my $bind_attributes;
1216   foreach my $column ($source->columns) {
1217
1218     my $data_type = $source->column_info($column)->{data_type} || '';
1219     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1220      if $data_type;
1221   }
1222
1223   return $bind_attributes;
1224 }
1225
1226 =head2 select
1227
1228 =over 4
1229
1230 =item Arguments: $ident, $select, $condition, $attrs
1231
1232 =back
1233
1234 Handle a SQL select statement.
1235
1236 =cut
1237
1238 sub select {
1239   my $self = shift;
1240   my ($ident, $select, $condition, $attrs) = @_;
1241   return $self->cursor_class->new($self, \@_, $attrs);
1242 }
1243
1244 sub select_single {
1245   my $self = shift;
1246   my ($rv, $sth, @bind) = $self->_select(@_);
1247   my @row = $sth->fetchrow_array;
1248   my @nextrow = $sth->fetchrow_array if @row;
1249   if(@row && @nextrow) {
1250     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1251   }
1252   # Need to call finish() to work round broken DBDs
1253   $sth->finish();
1254   return @row;
1255 }
1256
1257 =head2 sth
1258
1259 =over 4
1260
1261 =item Arguments: $sql
1262
1263 =back
1264
1265 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1266
1267 =cut
1268
1269 sub _dbh_sth {
1270   my ($self, $dbh, $sql) = @_;
1271
1272   # 3 is the if_active parameter which avoids active sth re-use
1273   my $sth = $self->disable_sth_caching
1274     ? $dbh->prepare($sql)
1275     : $dbh->prepare_cached($sql, {}, 3);
1276
1277   # XXX You would think RaiseError would make this impossible,
1278   #  but apparently that's not true :(
1279   $self->throw_exception($dbh->errstr) if !$sth;
1280
1281   $sth;
1282 }
1283
1284 sub sth {
1285   my ($self, $sql) = @_;
1286   $self->dbh_do('_dbh_sth', $sql);
1287 }
1288
1289 sub _dbh_columns_info_for {
1290   my ($self, $dbh, $table) = @_;
1291
1292   if ($dbh->can('column_info')) {
1293     my %result;
1294     eval {
1295       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1296       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1297       $sth->execute();
1298       while ( my $info = $sth->fetchrow_hashref() ){
1299         my %column_info;
1300         $column_info{data_type}   = $info->{TYPE_NAME};
1301         $column_info{size}      = $info->{COLUMN_SIZE};
1302         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1303         $column_info{default_value} = $info->{COLUMN_DEF};
1304         my $col_name = $info->{COLUMN_NAME};
1305         $col_name =~ s/^\"(.*)\"$/$1/;
1306
1307         $result{$col_name} = \%column_info;
1308       }
1309     };
1310     return \%result if !$@ && scalar keys %result;
1311   }
1312
1313   my %result;
1314   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1315   $sth->execute;
1316   my @columns = @{$sth->{NAME_lc}};
1317   for my $i ( 0 .. $#columns ){
1318     my %column_info;
1319     $column_info{data_type} = $sth->{TYPE}->[$i];
1320     $column_info{size} = $sth->{PRECISION}->[$i];
1321     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1322
1323     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1324       $column_info{data_type} = $1;
1325       $column_info{size}    = $2;
1326     }
1327
1328     $result{$columns[$i]} = \%column_info;
1329   }
1330   $sth->finish;
1331
1332   foreach my $col (keys %result) {
1333     my $colinfo = $result{$col};
1334     my $type_num = $colinfo->{data_type};
1335     my $type_name;
1336     if(defined $type_num && $dbh->can('type_info')) {
1337       my $type_info = $dbh->type_info($type_num);
1338       $type_name = $type_info->{TYPE_NAME} if $type_info;
1339       $colinfo->{data_type} = $type_name if $type_name;
1340     }
1341   }
1342
1343   return \%result;
1344 }
1345
1346 sub columns_info_for {
1347   my ($self, $table) = @_;
1348   $self->dbh_do('_dbh_columns_info_for', $table);
1349 }
1350
1351 =head2 last_insert_id
1352
1353 Return the row id of the last insert.
1354
1355 =cut
1356
1357 sub _dbh_last_insert_id {
1358     # All Storage's need to register their own _dbh_last_insert_id
1359     # the old SQLite-based method was highly inappropriate
1360
1361     my $self = shift;
1362     my $class = ref $self;
1363     $self->throw_exception (<<EOE);
1364
1365 No _dbh_last_insert_id() method found in $class.
1366 Since the method of obtaining the autoincrement id of the last insert
1367 operation varies greatly between different databases, this method must be
1368 individually implemented for every storage class.
1369 EOE
1370 }
1371
1372 sub last_insert_id {
1373   my $self = shift;
1374   $self->dbh_do('_dbh_last_insert_id', @_);
1375 }
1376
1377 =head2 sqlt_type
1378
1379 Returns the database driver name.
1380
1381 =cut
1382
1383 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1384
1385 =head2 bind_attribute_by_data_type
1386
1387 Given a datatype from column info, returns a database specific bind
1388 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1389 let the database planner just handle it.
1390
1391 Generally only needed for special case column types, like bytea in postgres.
1392
1393 =cut
1394
1395 sub bind_attribute_by_data_type {
1396     return;
1397 }
1398
1399 =head2 create_ddl_dir
1400
1401 =over 4
1402
1403 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1404
1405 =back
1406
1407 Creates a SQL file based on the Schema, for each of the specified
1408 database types, in the given directory.
1409
1410 By default, C<\%sqlt_args> will have
1411
1412  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1413
1414 merged with the hash passed in. To disable any of those features, pass in a
1415 hashref like the following
1416
1417  { ignore_constraint_names => 0, # ... other options }
1418
1419 =cut
1420
1421 sub create_ddl_dir {
1422   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1423
1424   if(!$dir || !-d $dir) {
1425     carp "No directory given, using ./\n";
1426     $dir = "./";
1427   }
1428   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1429   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1430
1431   my $schema_version = $schema->schema_version || '1.x';
1432   $version ||= $schema_version;
1433
1434   $sqltargs = {
1435     add_drop_table => 1,
1436     ignore_constraint_names => 1,
1437     ignore_index_names => 1,
1438     %{$sqltargs || {}}
1439   };
1440
1441   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1442       . $self->_check_sqlt_message . q{'})
1443           if !$self->_check_sqlt_version;
1444
1445   my $sqlt = SQL::Translator->new( $sqltargs );
1446
1447   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1448   my $sqlt_schema = $sqlt->translate({ data => $schema })
1449     or $self->throw_exception ($sqlt->error);
1450
1451   foreach my $db (@$databases) {
1452     $sqlt->reset();
1453     $sqlt->{schema} = $sqlt_schema;
1454     $sqlt->producer($db);
1455
1456     my $file;
1457     my $filename = $schema->ddl_filename($db, $version, $dir);
1458     if (-e $filename && ($version eq $schema_version )) {
1459       # if we are dumping the current version, overwrite the DDL
1460       carp "Overwriting existing DDL file - $filename";
1461       unlink($filename);
1462     }
1463
1464     my $output = $sqlt->translate;
1465     if(!$output) {
1466       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1467       next;
1468     }
1469     if(!open($file, ">$filename")) {
1470       $self->throw_exception("Can't open $filename for writing ($!)");
1471       next;
1472     }
1473     print $file $output;
1474     close($file);
1475
1476     next unless ($preversion);
1477
1478     require SQL::Translator::Diff;
1479
1480     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1481     if(!-e $prefilename) {
1482       carp("No previous schema file found ($prefilename)");
1483       next;
1484     }
1485
1486     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1487     if(-e $difffile) {
1488       carp("Overwriting existing diff file - $difffile");
1489       unlink($difffile);
1490     }
1491
1492     my $source_schema;
1493     {
1494       my $t = SQL::Translator->new($sqltargs);
1495       $t->debug( 0 );
1496       $t->trace( 0 );
1497
1498       $t->parser( $db )
1499         or $self->throw_exception ($t->error);
1500
1501       my $out = $t->translate( $prefilename )
1502         or $self->throw_exception ($t->error);
1503
1504       $source_schema = $t->schema;
1505
1506       $source_schema->name( $prefilename )
1507         unless ( $source_schema->name );
1508     }
1509
1510     # The "new" style of producers have sane normalization and can support
1511     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1512     # And we have to diff parsed SQL against parsed SQL.
1513     my $dest_schema = $sqlt_schema;
1514
1515     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1516       my $t = SQL::Translator->new($sqltargs);
1517       $t->debug( 0 );
1518       $t->trace( 0 );
1519
1520       $t->parser( $db )
1521         or $self->throw_exception ($t->error);
1522
1523       my $out = $t->translate( $filename )
1524         or $self->throw_exception ($t->error);
1525
1526       $dest_schema = $t->schema;
1527
1528       $dest_schema->name( $filename )
1529         unless $dest_schema->name;
1530     }
1531
1532     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1533                                                   $dest_schema,   $db,
1534                                                   $sqltargs
1535                                                  );
1536     if(!open $file, ">$difffile") {
1537       $self->throw_exception("Can't write to $difffile ($!)");
1538       next;
1539     }
1540     print $file $diff;
1541     close($file);
1542   }
1543 }
1544
1545 =head2 deployment_statements
1546
1547 =over 4
1548
1549 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1550
1551 =back
1552
1553 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1554 The database driver name is given by C<$type>, though the value from
1555 L</sqlt_type> is used if it is not specified.
1556
1557 C<$directory> is used to return statements from files in a previously created
1558 L</create_ddl_dir> directory and is optional. The filenames are constructed
1559 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1560
1561 If no C<$directory> is specified then the statements are constructed on the
1562 fly using L<SQL::Translator> and C<$version> is ignored.
1563
1564 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1565
1566 =cut
1567
1568 sub deployment_statements {
1569   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1570   # Need to be connected to get the correct sqlt_type
1571   $self->ensure_connected() unless $type;
1572   $type ||= $self->sqlt_type;
1573   $version ||= $schema->schema_version || '1.x';
1574   $dir ||= './';
1575   my $filename = $schema->ddl_filename($type, $version, $dir);
1576   if(-f $filename)
1577   {
1578       my $file;
1579       open($file, "<$filename")
1580         or $self->throw_exception("Can't open $filename ($!)");
1581       my @rows = <$file>;
1582       close($file);
1583       return join('', @rows);
1584   }
1585
1586   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1587       . $self->_check_sqlt_message . q{'})
1588           if !$self->_check_sqlt_version;
1589
1590   require SQL::Translator::Parser::DBIx::Class;
1591   eval qq{use SQL::Translator::Producer::${type}};
1592   $self->throw_exception($@) if $@;
1593
1594   # sources needs to be a parser arg, but for simplicty allow at top level
1595   # coming in
1596   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1597       if exists $sqltargs->{sources};
1598
1599   my $tr = SQL::Translator->new(%$sqltargs);
1600   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1601   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1602 }
1603
1604 sub deploy {
1605   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1606   my $deploy = sub {
1607     my $line = shift;
1608     return if($line =~ /^--/);
1609     return if(!$line);
1610     # next if($line =~ /^DROP/m);
1611     return if($line =~ /^BEGIN TRANSACTION/m);
1612     return if($line =~ /^COMMIT/m);
1613     return if $line =~ /^\s+$/; # skip whitespace only
1614     $self->_query_start($line);
1615     eval {
1616       $self->dbh->do($line); # shouldn't be using ->dbh ?
1617     };
1618     if ($@) {
1619       carp qq{$@ (running "${line}")};
1620     }
1621     $self->_query_end($line);
1622   };
1623   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } );
1624   if (@statements > 1) {
1625     foreach my $statement (@statements) {
1626       $deploy->( $statement );
1627     }
1628   }
1629   elsif (@statements == 1) {
1630     foreach my $line ( split(";\n", $statements[0])) {
1631       $deploy->( $line );
1632     }
1633   }
1634 }
1635
1636 =head2 datetime_parser
1637
1638 Returns the datetime parser class
1639
1640 =cut
1641
1642 sub datetime_parser {
1643   my $self = shift;
1644   return $self->{datetime_parser} ||= do {
1645     $self->ensure_connected;
1646     $self->build_datetime_parser(@_);
1647   };
1648 }
1649
1650 =head2 datetime_parser_type
1651
1652 Defines (returns) the datetime parser class - currently hardwired to
1653 L<DateTime::Format::MySQL>
1654
1655 =cut
1656
1657 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1658
1659 =head2 build_datetime_parser
1660
1661 See L</datetime_parser>
1662
1663 =cut
1664
1665 sub build_datetime_parser {
1666   my $self = shift;
1667   my $type = $self->datetime_parser_type(@_);
1668   eval "use ${type}";
1669   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1670   return $type;
1671 }
1672
1673 {
1674     my $_check_sqlt_version; # private
1675     my $_check_sqlt_message; # private
1676     sub _check_sqlt_version {
1677         return $_check_sqlt_version if defined $_check_sqlt_version;
1678         eval 'use SQL::Translator "0.09003"';
1679         $_check_sqlt_message = $@ || '';
1680         $_check_sqlt_version = !$@;
1681     }
1682
1683     sub _check_sqlt_message {
1684         _check_sqlt_version if !defined $_check_sqlt_message;
1685         $_check_sqlt_message;
1686     }
1687 }
1688
1689 =head2 is_replicating
1690
1691 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1692 replicate from a master database.  Default is undef, which is the result
1693 returned by databases that don't support replication.
1694
1695 =cut
1696
1697 sub is_replicating {
1698     return;
1699
1700 }
1701
1702 =head2 lag_behind_master
1703
1704 Returns a number that represents a certain amount of lag behind a master db
1705 when a given storage is replicating.  The number is database dependent, but
1706 starts at zero and increases with the amount of lag. Default in undef
1707
1708 =cut
1709
1710 sub lag_behind_master {
1711     return;
1712 }
1713
1714 sub DESTROY {
1715   my $self = shift;
1716   return if !$self->_dbh;
1717   $self->_verify_pid;
1718   $self->_dbh(undef);
1719 }
1720
1721 1;
1722
1723 =head1 USAGE NOTES
1724
1725 =head2 DBIx::Class and AutoCommit
1726
1727 DBIx::Class can do some wonderful magic with handling exceptions,
1728 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1729 combined with C<txn_do> for transaction support.
1730
1731 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1732 in an assumed transaction between commits, and you're telling us you'd
1733 like to manage that manually.  A lot of the magic protections offered by
1734 this module will go away.  We can't protect you from exceptions due to database
1735 disconnects because we don't know anything about how to restart your
1736 transactions.  You're on your own for handling all sorts of exceptional
1737 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1738 be with raw DBI.
1739
1740
1741
1742 =head1 AUTHORS
1743
1744 Matt S. Trout <mst@shadowcatsystems.co.uk>
1745
1746 Andy Grundman <andy@hybridized.org>
1747
1748 =head1 LICENSE
1749
1750 You may distribute this code under the same terms as Perl itself.
1751
1752 =cut