lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9 use Carp::Clan qw/DBIx::Class/;
  10
  11 BEGIN {
  12
  13 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  14
  15 use base qw/SQL::Abstract::Limit/;
  16
  17 sub select {
  18   my ($self, $table, $fields, $where, $order, @rest) = @_;
  19   @rest = (-1) unless defined $rest[0];
  20   $self->SUPER::select($table, $self->_recurse_fields($fields),
  21                          $where, $order, @rest);
  22 }
  23
  24 sub _emulate_limit {
  25   my $self = shift;
  26   if ($_[3] == -1) {
  27     return $_[1].$self->_order_by($_[2]);
  28   } else {
  29     return $self->SUPER::_emulate_limit(@_);
  30   }
  31 }
  32
  33 sub _recurse_fields {
  34   my ($self, $fields) = @_;
  35   my $ref = ref $fields;
  36   return $self->_quote($fields) unless $ref;
  37   return $$fields if $ref eq 'SCALAR';
  38
  39   if ($ref eq 'ARRAY') {
  40     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  41   } elsif ($ref eq 'HASH') {
  42     foreach my $func (keys %$fields) {
  43       return $self->_sqlcase($func)
  44         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  45     }
  46   }
  47 }
  48
  49 sub _order_by {
  50   my $self = shift;
  51   my $ret = '';
  52   if (ref $_[0] eq 'HASH') {
  53     if (defined $_[0]->{group_by}) {
  54       $ret = $self->_sqlcase(' group by ')
  55                .$self->_recurse_fields($_[0]->{group_by});
  56     }
  57     if (defined $_[0]->{order_by}) {
  58       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  59     }
  60   } else {
  61     $ret = $self->SUPER::_order_by(@_);
  62   }
  63   return $ret;
  64 }
  65
  66 sub _table {
  67   my ($self, $from) = @_;
  68   if (ref $from eq 'ARRAY') {
  69     return $self->_recurse_from(@$from);
  70   } elsif (ref $from eq 'HASH') {
  71     return $self->_make_as($from);
  72   } else {
  73     return $from;
  74   }
  75 }
  76
  77 sub _recurse_from {
  78   my ($self, $from, @join) = @_;
  79   my @sqlf;
  80   push(@sqlf, $self->_make_as($from));
  81   foreach my $j (@join) {
  82     my ($to, $on) = @$j;
  83
  84     # check whether a join type exists
  85     my $join_clause = '';
  86     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  87       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  88     } else {
  89       $join_clause = ' JOIN ';
  90     }
  91     push(@sqlf, $join_clause);
  92
  93     if (ref $to eq 'ARRAY') {
  94       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  95     } else {
  96       push(@sqlf, $self->_make_as($to));
  97     }
  98     push(@sqlf, ' ON ', $self->_join_condition($on));
  99   }
 100   return join('', @sqlf);
 101 }
 102
 103 sub _make_as {
 104   my ($self, $from) = @_;
 105   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 106                            reverse each %{$self->_skip_options($from)});
 107 }
 108
 109 sub _skip_options {
 110   my ($self, $hash) = @_;
 111   my $clean_hash = {};
 112   $clean_hash->{$_} = $hash->{$_}
 113     for grep {!/^-/} keys %$hash;
 114   return $clean_hash;
 115 }
 116
 117 sub _join_condition {
 118   my ($self, $cond) = @_;
 119   if (ref $cond eq 'HASH') {
 120     my %j;
 121     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 122     return $self->_recurse_where(\%j);
 123   } elsif (ref $cond eq 'ARRAY') {
 124     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 125   } else {
 126     die "Can't handle this yet!";
 127   }
 128 }
 129
 130 sub _quote {
 131   my ($self, $label) = @_;
 132   return '' unless defined $label;
 133   return $label unless $self->{quote_char};
 134   return $self->SUPER::_quote($label);
 135 }
 136
 137 sub _RowNum {
 138    my $self = shift;
 139    my $c;
 140    $_[0] =~ s/SELECT (.*?) FROM/
 141      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 142    $self->SUPER::_RowNum(@_);
 143 }
 144
 145 # Accessor for setting limit dialect. This is useful
 146 # for JDBC-bridge among others where the remote SQL-dialect cannot
 147 # be determined by the name of the driver alone.
 148 #
 149 sub limit_dialect {
 150     my $self = shift;
 151     $self->{limit_dialect} = shift if @_;
 152     return $self->{limit_dialect};
 153 }
 154
 155 package DBIx::Class::Storage::DBI::DebugCallback;
 156
 157 sub print {
 158   my ($self, $string) = @_;
 159   $string =~ m/^(\w+)/;
 160   ${$self}->($1, $string);
 161 }
 162
 163 } # End of BEGIN block
 164
 165 use base qw/DBIx::Class/;
 166
 167 __PACKAGE__->load_components(qw/AccessorGroup/);
 168
 169 __PACKAGE__->mk_group_accessors('simple' =>
 170   qw/connect_info _dbh _sql_maker _connection_pid debug debugfh cursor
 171      on_connect_do transaction_depth/);
 172
 173 sub new {
 174   my $new = bless({}, ref $_[0] || $_[0]);
 175   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 176   $new->transaction_depth(0);
 177   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 178      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 179     $new->debugfh(IO::File->new($1, 'w')||croak "Cannot open trace file $1");
 180   } else {
 181     $new->debugfh(IO::File->new('>&STDERR'));
 182   }
 183   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 184   return $new;
 185 }
 186
 187 =head1 NAME
 188
 189 DBIx::Class::Storage::DBI - DBI storage handler
 190
 191 =head1 SYNOPSIS
 192
 193 =head1 DESCRIPTION
 194
 195 This class represents the connection to the database
 196
 197 =head1 METHODS
 198
 199 =cut
 200
 201 =head2 on_connect_do
 202
 203 Executes the sql statements given as a listref on every db connect.
 204
 205 =head2 debug
 206
 207 Causes SQL trace information to be emitted on C<debugfh> filehandle
 208 (or C<STDERR> if C<debugfh> has not specifically been set).
 209
 210 =head2 debugfh
 211
 212 Sets or retrieves the filehandle used for trace/debug output.  This
 213 should be an IO::Handle compatible object (only the C<print> method is
 214 used).  Initially set to be STDERR - although see information on the
 215 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 216
 217 =head2 debugcb
 218
 219 Sets a callback to be executed each time a statement is run; takes a sub
 220 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 221 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 222 be printed.
 223
 224 =cut
 225
 226 sub debugcb {
 227   my ($self, $cb) = @_;
 228   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 229   $self->debugfh($cb_obj);
 230 }
 231
 232 sub disconnect {
 233   my ($self) = @_;
 234
 235   if( $self->connected ) {
 236     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 237     $self->_dbh->disconnect;
 238     $self->_dbh(undef);
 239   }
 240 }
 241
 242 sub connected {
 243   my ($self) = @_;
 244
 245   my $dbh;
 246   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 247 }
 248
 249 sub ensure_connected {
 250   my ($self) = @_;
 251
 252   unless ($self->connected) {
 253     $self->_populate_dbh;
 254   }
 255 }
 256
 257 sub dbh {
 258   my ($self) = @_;
 259
 260   $self->_dbh(undef)
 261     if $self->_connection_pid && $self->_connection_pid != $$;
 262   $self->ensure_connected;
 263   return $self->_dbh;
 264 }
 265
 266 sub sql_maker {
 267   my ($self) = @_;
 268   unless ($self->_sql_maker) {
 269     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 270   }
 271   return $self->_sql_maker;
 272 }
 273
 274 sub _populate_dbh {
 275   my ($self) = @_;
 276   my @info = @{$self->connect_info || []};
 277   $self->_dbh($self->_connect(@info));
 278
 279   # if on-connect sql statements are given execute them
 280   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 281     $self->_dbh->do($sql_statement);
 282   }
 283
 284   $self->_connection_pid($$);
 285 }
 286
 287 sub _connect {
 288   my ($self, @info) = @_;
 289
 290   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 291       my $old_connect_via = $DBI::connect_via;
 292       $DBI::connect_via = 'connect';
 293       my $dbh = DBI->connect(@info);
 294       $DBI::connect_via = $old_connect_via;
 295       return $dbh;
 296   }
 297
 298   DBI->connect(@info);
 299 }
 300
 301 =head2 txn_begin
 302
 303 Calls begin_work on the current dbh.
 304
 305 =cut
 306
 307 sub txn_begin {
 308   my $self = shift;
 309   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 310 }
 311
 312 =head2 txn_commit
 313
 314 Issues a commit against the current dbh.
 315
 316 =cut
 317
 318 sub txn_commit {
 319   my $self = shift;
 320   if ($self->{transaction_depth} == 0) {
 321     $self->dbh->commit unless $self->dbh->{AutoCommit};
 322   }
 323   else {
 324     $self->dbh->commit if --$self->{transaction_depth} == 0;
 325   }
 326 }
 327
 328 =head2 txn_rollback
 329
 330 Issues a rollback against the current dbh.
 331
 332 =cut
 333
 334 sub txn_rollback {
 335   my $self = shift;
 336   if ($self->{transaction_depth} == 0) {
 337     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 338   }
 339   else {
 340     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 341   }
 342 }
 343
 344 sub _execute {
 345   my ($self, $op, $extra_bind, $ident, @args) = @_;
 346   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 347   unshift(@bind, @$extra_bind) if $extra_bind;
 348   if ($self->debug) {
 349       my @debug_bind = map { defined $_ ? $_ : 'NULL' } @bind;
 350       $self->debugfh->print("$sql: @debug_bind\n");
 351   }
 352   my $sth = $self->sth($sql,$op);
 353   croak "no sth generated via sql: $sql" unless $sth;
 354   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 355   my $rv;
 356   if ($sth) {
 357     $rv = $sth->execute(@bind);
 358   } else {
 359     croak "'$sql' did not generate a statement.";
 360   }
 361   return (wantarray ? ($rv, $sth, @bind) : $rv);
 362 }
 363
 364 sub insert {
 365   my ($self, $ident, $to_insert) = @_;
 366   croak( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 367     unless ($self->_execute('insert' => [], $ident, $to_insert));
 368   return $to_insert;
 369 }
 370
 371 sub update {
 372   return shift->_execute('update' => [], @_);
 373 }
 374
 375 sub delete {
 376   return shift->_execute('delete' => [], @_);
 377 }
 378
 379 sub _select {
 380   my ($self, $ident, $select, $condition, $attrs) = @_;
 381   my $order = $attrs->{order_by};
 382   if (ref $condition eq 'SCALAR') {
 383     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 384   }
 385   if (exists $attrs->{group_by}) {
 386     $order = { group_by => $attrs->{group_by},
 387                ($order ? (order_by => $order) : ()) };
 388   }
 389   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 390   if ($attrs->{software_limit} ||
 391       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 392         $attrs->{software_limit} = 1;
 393   } else {
 394     push @args, $attrs->{rows}, $attrs->{offset};
 395   }
 396   return $self->_execute(@args);
 397 }
 398
 399 sub select {
 400   my $self = shift;
 401   my ($ident, $select, $condition, $attrs) = @_;
 402   return $self->cursor->new($self, \@_, $attrs);
 403 }
 404
 405 # Need to call finish() to work round broken DBDs
 406
 407 sub select_single {
 408   my $self = shift;
 409   my ($rv, $sth, @bind) = $self->_select(@_);
 410   my @row = $sth->fetchrow_array;
 411   $sth->finish();
 412   return @row;
 413 }
 414
 415 sub sth {
 416   my ($self, $sql) = @_;
 417   # 3 is the if_active parameter which avoids active sth re-use
 418   return $self->dbh->prepare_cached($sql, {}, 3);
 419 }
 420
 421 =head2 columns_info_for
 422
 423 Returns database type info for a given table columns.
 424
 425 =cut
 426
 427 sub columns_info_for {
 428     my ($self, $table) = @_;
 429     my %result;
 430     if ( $self->dbh->can( 'column_info' ) ){
 431         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 432         $sth->execute();
 433         while ( my $info = $sth->fetchrow_hashref() ){
 434             my %column_info;
 435             $column_info{data_type} = $info->{TYPE_NAME};
 436             $column_info{size} = $info->{COLUMN_SIZE};
 437             $column_info{is_nullable} = $info->{NULLABLE};
 438             $result{$info->{COLUMN_NAME}} = \%column_info;
 439         }
 440     }else{
 441         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 442         $sth->execute;
 443         my @columns = @{$sth->{NAME}};
 444         for my $i ( 0 .. $#columns ){
 445             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 446         }
 447     }
 448     return \%result;
 449 }
 450
 451 sub DESTROY { shift->disconnect }
 452
 453 1;
 454
 455 =head1 ENVIRONMENT VARIABLES
 456
 457 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 458
 459 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 460 is produced (as when the L<debug> method is set).
 461
 462 If the value is of the form C<1=/path/name> then the trace output is
 463 written to the file C</path/name>.
 464
 465 =head1 AUTHORS
 466
 467 Matt S. Trout <mst@shadowcatsystems.co.uk>
 468
 469 Andy Grundman <andy@hybridized.org>
 470
 471 =head1 LICENSE
 472
 473 You may distribute this code under the same terms as Perl itself.
 474
 475 =cut
 476