lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use DBI::Const::GetInfoType (); # no import of retarded global hash
  19 use namespace::clean;
  20
  21 # default cursor class, overridable in connect_info attributes
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/
  25   sql_limit_dialect sql_quote_char sql_name_sep
  26 /);
  27
  28 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  29
  30 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  31 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  32
  33 __PACKAGE__->sql_name_sep('.');
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/
  36   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  37   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  38   _perform_autoinc_retrieval _autoinc_supplied_for_op
  39 /);
  40
  41 # the values for these accessors are picked out (and deleted) from
  42 # the attribute hashref passed to connect_info
  43 my @storage_options = qw/
  44   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  45   disable_sth_caching unsafe auto_savepoint
  46 /;
  47 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  48
  49
  50 # capability definitions, using a 2-tiered accessor system
  51 # The rationale is:
  52 #
  53 # A driver/user may define _use_X, which blindly without any checks says:
  54 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  55 # type accessor)
  56 #
  57 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  58 # accessor, which in turn calls _determine_supports_X, and stores the return
  59 # in a special slot on the storage object, which is wiped every time a $dbh
  60 # reconnection takes place (it is not guaranteed that upon reconnection we
  61 # will get the same rdbms version). _determine_supports_X does not need to
  62 # exist on a driver, as we ->can for it before calling.
  63
  64 my @capabilities = (qw/
  65   insert_returning
  66   insert_returning_bound
  67
  68   multicolumn_in
  69
  70   placeholders
  71   typeless_placeholders
  72
  73   join_optimizer
  74 /);
  75 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  76 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  77
  78 # on by default, not strictly a capability (pending rewrite)
  79 __PACKAGE__->_use_join_optimizer (1);
  80 sub _determine_supports_join_optimizer { 1 };
  81
  82 # Each of these methods need _determine_driver called before itself
  83 # in order to function reliably. This is a purely DRY optimization
  84 #
  85 # get_(use)_dbms_capability need to be called on the correct Storage
  86 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  87 # _determine_supports_X which obv. needs a correct driver as well
  88 my @rdbms_specific_methods = qw/
  89   sqlt_type
  90   sql_maker
  91   build_datetime_parser
  92   datetime_parser_type
  93
  94   txn_begin
  95   insert
  96   insert_bulk
  97   update
  98   delete
  99   select
 100   select_single
 101   with_deferred_fk_checks
 102
 103   get_use_dbms_capability
 104   get_dbms_capability
 105
 106   _server_info
 107   _get_server_version
 108 /;
 109
 110 for my $meth (@rdbms_specific_methods) {
 111
 112   my $orig = __PACKAGE__->can ($meth)
 113     or die "$meth is not a ::Storage::DBI method!";
 114
 115   no strict qw/refs/;
 116   no warnings qw/redefine/;
 117   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 118     if (
 119       # only fire when invoked on an instance, a valid class-based invocation
 120       # would e.g. be setting a default for an inherited accessor
 121       ref $_[0]
 122         and
 123       ! $_[0]->_driver_determined
 124         and
 125       ! $_[0]->{_in_determine_driver}
 126     ) {
 127       $_[0]->_determine_driver;
 128
 129       # This for some reason crashes and burns on perl 5.8.1
 130       # IFF the method ends up throwing an exception
 131       #goto $_[0]->can ($meth);
 132
 133       my $cref = $_[0]->can ($meth);
 134       goto $cref;
 135     }
 136
 137     goto $orig;
 138   };
 139 }
 140
 141 =head1 NAME
 142
 143 DBIx::Class::Storage::DBI - DBI storage handler
 144
 145 =head1 SYNOPSIS
 146
 147   my $schema = MySchema->connect('dbi:SQLite:my.db');
 148
 149   $schema->storage->debug(1);
 150
 151   my @stuff = $schema->storage->dbh_do(
 152     sub {
 153       my ($storage, $dbh, @args) = @_;
 154       $dbh->do("DROP TABLE authors");
 155     },
 156     @column_list
 157   );
 158
 159   $schema->resultset('Book')->search({
 160      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 161   });
 162
 163 =head1 DESCRIPTION
 164
 165 This class represents the connection to an RDBMS via L<DBI>.  See
 166 L<DBIx::Class::Storage> for general information.  This pod only
 167 documents DBI-specific methods and behaviors.
 168
 169 =head1 METHODS
 170
 171 =cut
 172
 173 sub new {
 174   my $new = shift->next::method(@_);
 175
 176   $new->_sql_maker_opts({});
 177   $new->_dbh_details({});
 178   $new->{_in_do_block} = 0;
 179
 180   # read below to see what this does
 181   $new->_arm_global_destructor;
 182
 183   $new;
 184 }
 185
 186 # This is hack to work around perl shooting stuff in random
 187 # order on exit(). If we do not walk the remaining storage
 188 # objects in an END block, there is a *small but real* chance
 189 # of a fork()ed child to kill the parent's shared DBI handle,
 190 # *before perl reaches the DESTROY in this package*
 191 # Yes, it is ugly and effective.
 192 # Additionally this registry is used by the CLONE method to
 193 # make sure no handles are shared between threads
 194 {
 195   my %seek_and_destroy;
 196
 197   sub _arm_global_destructor {
 198     weaken (
 199       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 200     );
 201   }
 202
 203   END {
 204     local $?; # just in case the DBI destructor changes it somehow
 205
 206     # destroy just the object if not native to this process
 207     $_->_verify_pid for (grep
 208       { defined $_ }
 209       values %seek_and_destroy
 210     );
 211   }
 212
 213   sub CLONE {
 214     # As per DBI's recommendation, DBIC disconnects all handles as
 215     # soon as possible (DBIC will reconnect only on demand from within
 216     # the thread)
 217     my @instances = grep { defined $_ } values %seek_and_destroy;
 218     %seek_and_destroy = ();
 219
 220     for (@instances) {
 221       $_->_dbh(undef);
 222
 223       $_->transaction_depth(0);
 224       $_->savepoints([]);
 225
 226       # properly renumber existing refs
 227       $_->_arm_global_destructor
 228     }
 229   }
 230 }
 231
 232 sub DESTROY {
 233   my $self = shift;
 234
 235   # some databases spew warnings on implicit disconnect
 236   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 237   local $SIG{__WARN__} = sub {};
 238   $self->_dbh(undef);
 239
 240   # this op is necessary, since the very last perl runtime statement
 241   # triggers a global destruction shootout, and the $SIG localization
 242   # may very well be destroyed before perl actually gets to do the
 243   # $dbh undef
 244   1;
 245 }
 246
 247 # handle pid changes correctly - do not destroy parent's connection
 248 sub _verify_pid {
 249   my $self = shift;
 250
 251   my $pid = $self->_conn_pid;
 252   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 253     $dbh->{InactiveDestroy} = 1;
 254     $self->_dbh(undef);
 255     $self->transaction_depth(0);
 256     $self->savepoints([]);
 257   }
 258
 259   return;
 260 }
 261
 262 =head2 connect_info
 263
 264 This method is normally called by L<DBIx::Class::Schema/connection>, which
 265 encapsulates its argument list in an arrayref before passing them here.
 266
 267 The argument list may contain:
 268
 269 =over
 270
 271 =item *
 272
 273 The same 4-element argument set one would normally pass to
 274 L<DBI/connect>, optionally followed by
 275 L<extra attributes|/DBIx::Class specific connection attributes>
 276 recognized by DBIx::Class:
 277
 278   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 279
 280 =item *
 281
 282 A single code reference which returns a connected
 283 L<DBI database handle|DBI/connect> optionally followed by
 284 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 285 by DBIx::Class:
 286
 287   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 288
 289 =item *
 290
 291 A single hashref with all the attributes and the dsn/user/password
 292 mixed together:
 293
 294   $connect_info_args = [{
 295     dsn => $dsn,
 296     user => $user,
 297     password => $pass,
 298     %dbi_attributes,
 299     %extra_attributes,
 300   }];
 301
 302   $connect_info_args = [{
 303     dbh_maker => sub { DBI->connect (...) },
 304     %dbi_attributes,
 305     %extra_attributes,
 306   }];
 307
 308 This is particularly useful for L<Catalyst> based applications, allowing the
 309 following config (L<Config::General> style):
 310
 311   <Model::DB>
 312     schema_class   App::DB
 313     <connect_info>
 314       dsn          dbi:mysql:database=test
 315       user         testuser
 316       password     TestPass
 317       AutoCommit   1
 318     </connect_info>
 319   </Model::DB>
 320
 321 The C<dsn>/C<user>/C<password> combination can be substituted by the
 322 C<dbh_maker> key whose value is a coderef that returns a connected
 323 L<DBI database handle|DBI/connect>
 324
 325 =back
 326
 327 Please note that the L<DBI> docs recommend that you always explicitly
 328 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 329 recommends that it be set to I<1>, and that you perform transactions
 330 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 331 to I<1> if you do not do explicitly set it to zero.  This is the default
 332 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 333
 334 =head3 DBIx::Class specific connection attributes
 335
 336 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 337 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 338 the following connection options. These options can be mixed in with your other
 339 L<DBI> connection attributes, or placed in a separate hashref
 340 (C<\%extra_attributes>) as shown above.
 341
 342 Every time C<connect_info> is invoked, any previous settings for
 343 these options will be cleared before setting the new ones, regardless of
 344 whether any options are specified in the new C<connect_info>.
 345
 346
 347 =over
 348
 349 =item on_connect_do
 350
 351 Specifies things to do immediately after connecting or re-connecting to
 352 the database.  Its value may contain:
 353
 354 =over
 355
 356 =item a scalar
 357
 358 This contains one SQL statement to execute.
 359
 360 =item an array reference
 361
 362 This contains SQL statements to execute in order.  Each element contains
 363 a string or a code reference that returns a string.
 364
 365 =item a code reference
 366
 367 This contains some code to execute.  Unlike code references within an
 368 array reference, its return value is ignored.
 369
 370 =back
 371
 372 =item on_disconnect_do
 373
 374 Takes arguments in the same form as L</on_connect_do> and executes them
 375 immediately before disconnecting from the database.
 376
 377 Note, this only runs if you explicitly call L</disconnect> on the
 378 storage object.
 379
 380 =item on_connect_call
 381
 382 A more generalized form of L</on_connect_do> that calls the specified
 383 C<connect_call_METHOD> methods in your storage driver.
 384
 385   on_connect_do => 'select 1'
 386
 387 is equivalent to:
 388
 389   on_connect_call => [ [ do_sql => 'select 1' ] ]
 390
 391 Its values may contain:
 392
 393 =over
 394
 395 =item a scalar
 396
 397 Will call the C<connect_call_METHOD> method.
 398
 399 =item a code reference
 400
 401 Will execute C<< $code->($storage) >>
 402
 403 =item an array reference
 404
 405 Each value can be a method name or code reference.
 406
 407 =item an array of arrays
 408
 409 For each array, the first item is taken to be the C<connect_call_> method name
 410 or code reference, and the rest are parameters to it.
 411
 412 =back
 413
 414 Some predefined storage methods you may use:
 415
 416 =over
 417
 418 =item do_sql
 419
 420 Executes a SQL string or a code reference that returns a SQL string. This is
 421 what L</on_connect_do> and L</on_disconnect_do> use.
 422
 423 It can take:
 424
 425 =over
 426
 427 =item a scalar
 428
 429 Will execute the scalar as SQL.
 430
 431 =item an arrayref
 432
 433 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 434 attributes hashref and bind values.
 435
 436 =item a code reference
 437
 438 Will execute C<< $code->($storage) >> and execute the return array refs as
 439 above.
 440
 441 =back
 442
 443 =item datetime_setup
 444
 445 Execute any statements necessary to initialize the database session to return
 446 and accept datetime/timestamp values used with
 447 L<DBIx::Class::InflateColumn::DateTime>.
 448
 449 Only necessary for some databases, see your specific storage driver for
 450 implementation details.
 451
 452 =back
 453
 454 =item on_disconnect_call
 455
 456 Takes arguments in the same form as L</on_connect_call> and executes them
 457 immediately before disconnecting from the database.
 458
 459 Calls the C<disconnect_call_METHOD> methods as opposed to the
 460 C<connect_call_METHOD> methods called by L</on_connect_call>.
 461
 462 Note, this only runs if you explicitly call L</disconnect> on the
 463 storage object.
 464
 465 =item disable_sth_caching
 466
 467 If set to a true value, this option will disable the caching of
 468 statement handles via L<DBI/prepare_cached>.
 469
 470 =item limit_dialect
 471
 472 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 473 default L</sql_limit_dialect> setting of the storage (if any). For a list
 474 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 475
 476 =item quote_names
 477
 478 When true automatically sets L</quote_char> and L</name_sep> to the characters
 479 appropriate for your particular RDBMS. This option is preferred over specifying
 480 L</quote_char> directly.
 481
 482 =item quote_char
 483
 484 Specifies what characters to use to quote table and column names.
 485
 486 C<quote_char> expects either a single character, in which case is it
 487 is placed on either side of the table/column name, or an arrayref of length
 488 2 in which case the table/column name is placed between the elements.
 489
 490 For example under MySQL you should use C<< quote_char => '`' >>, and for
 491 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 492
 493 =item name_sep
 494
 495 This parameter is only useful in conjunction with C<quote_char>, and is used to
 496 specify the character that separates elements (schemas, tables, columns) from
 497 each other. If unspecified it defaults to the most commonly used C<.>.
 498
 499 =item unsafe
 500
 501 This Storage driver normally installs its own C<HandleError>, sets
 502 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 503 all database handles, including those supplied by a coderef.  It does this
 504 so that it can have consistent and useful error behavior.
 505
 506 If you set this option to a true value, Storage will not do its usual
 507 modifications to the database handle's attributes, and instead relies on
 508 the settings in your connect_info DBI options (or the values you set in
 509 your connection coderef, in the case that you are connecting via coderef).
 510
 511 Note that your custom settings can cause Storage to malfunction,
 512 especially if you set a C<HandleError> handler that suppresses exceptions
 513 and/or disable C<RaiseError>.
 514
 515 =item auto_savepoint
 516
 517 If this option is true, L<DBIx::Class> will use savepoints when nesting
 518 transactions, making it possible to recover from failure in the inner
 519 transaction without having to abort all outer transactions.
 520
 521 =item cursor_class
 522
 523 Use this argument to supply a cursor class other than the default
 524 L<DBIx::Class::Storage::DBI::Cursor>.
 525
 526 =back
 527
 528 Some real-life examples of arguments to L</connect_info> and
 529 L<DBIx::Class::Schema/connect>
 530
 531   # Simple SQLite connection
 532   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 533
 534   # Connect via subref
 535   ->connect_info([ sub { DBI->connect(...) } ]);
 536
 537   # Connect via subref in hashref
 538   ->connect_info([{
 539     dbh_maker => sub { DBI->connect(...) },
 540     on_connect_do => 'alter session ...',
 541   }]);
 542
 543   # A bit more complicated
 544   ->connect_info(
 545     [
 546       'dbi:Pg:dbname=foo',
 547       'postgres',
 548       'my_pg_password',
 549       { AutoCommit => 1 },
 550       { quote_char => q{"} },
 551     ]
 552   );
 553
 554   # Equivalent to the previous example
 555   ->connect_info(
 556     [
 557       'dbi:Pg:dbname=foo',
 558       'postgres',
 559       'my_pg_password',
 560       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 561     ]
 562   );
 563
 564   # Same, but with hashref as argument
 565   # See parse_connect_info for explanation
 566   ->connect_info(
 567     [{
 568       dsn         => 'dbi:Pg:dbname=foo',
 569       user        => 'postgres',
 570       password    => 'my_pg_password',
 571       AutoCommit  => 1,
 572       quote_char  => q{"},
 573       name_sep    => q{.},
 574     }]
 575   );
 576
 577   # Subref + DBIx::Class-specific connection options
 578   ->connect_info(
 579     [
 580       sub { DBI->connect(...) },
 581       {
 582           quote_char => q{`},
 583           name_sep => q{@},
 584           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 585           disable_sth_caching => 1,
 586       },
 587     ]
 588   );
 589
 590
 591
 592 =cut
 593
 594 sub connect_info {
 595   my ($self, $info) = @_;
 596
 597   return $self->_connect_info if !$info;
 598
 599   $self->_connect_info($info); # copy for _connect_info
 600
 601   $info = $self->_normalize_connect_info($info)
 602     if ref $info eq 'ARRAY';
 603
 604   for my $storage_opt (keys %{ $info->{storage_options} }) {
 605     my $value = $info->{storage_options}{$storage_opt};
 606
 607     $self->$storage_opt($value);
 608   }
 609
 610   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 611   #  the new set of options
 612   $self->_sql_maker(undef);
 613   $self->_sql_maker_opts({});
 614
 615   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 616     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 617
 618     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 619   }
 620
 621   my %attrs = (
 622     %{ $self->_default_dbi_connect_attributes || {} },
 623     %{ $info->{attributes} || {} },
 624   );
 625
 626   my @args = @{ $info->{arguments} };
 627
 628   if (keys %attrs and ref $args[0] ne 'CODE') {
 629     carp
 630         'You provided explicit AutoCommit => 0 in your connection_info. '
 631       . 'This is almost universally a bad idea (see the footnotes of '
 632       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 633       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 634       . 'this warning.'
 635       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 636
 637     push @args, \%attrs if keys %attrs;
 638   }
 639   $self->_dbi_connect_info(\@args);
 640
 641   # FIXME - dirty:
 642   # save attributes them in a separate accessor so they are always
 643   # introspectable, even in case of a CODE $dbhmaker
 644   $self->_dbic_connect_attributes (\%attrs);
 645
 646   return $self->_connect_info;
 647 }
 648
 649 sub _normalize_connect_info {
 650   my ($self, $info_arg) = @_;
 651   my %info;
 652
 653   my @args = @$info_arg;  # take a shallow copy for further mutilation
 654
 655   # combine/pre-parse arguments depending on invocation style
 656
 657   my %attrs;
 658   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 659     %attrs = %{ $args[1] || {} };
 660     @args = $args[0];
 661   }
 662   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 663     %attrs = %{$args[0]};
 664     @args = ();
 665     if (my $code = delete $attrs{dbh_maker}) {
 666       @args = $code;
 667
 668       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 669       if (@ignored) {
 670         carp sprintf (
 671             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 672           . "to the result of 'dbh_maker'",
 673
 674           join (', ', map { "'$_'" } (@ignored) ),
 675         );
 676       }
 677     }
 678     else {
 679       @args = delete @attrs{qw/dsn user password/};
 680     }
 681   }
 682   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 683     %attrs = (
 684       % { $args[3] || {} },
 685       % { $args[4] || {} },
 686     );
 687     @args = @args[0,1,2];
 688   }
 689
 690   $info{arguments} = \@args;
 691
 692   my @storage_opts = grep exists $attrs{$_},
 693     @storage_options, 'cursor_class';
 694
 695   @{ $info{storage_options} }{@storage_opts} =
 696     delete @attrs{@storage_opts} if @storage_opts;
 697
 698   my @sql_maker_opts = grep exists $attrs{$_},
 699     qw/limit_dialect quote_char name_sep quote_names/;
 700
 701   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 702     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 703
 704   $info{attributes} = \%attrs if %attrs;
 705
 706   return \%info;
 707 }
 708
 709 sub _default_dbi_connect_attributes () {
 710   +{
 711     AutoCommit => 1,
 712     PrintError => 0,
 713     RaiseError => 1,
 714     ShowErrorStatement => 1,
 715   };
 716 }
 717
 718 =head2 on_connect_do
 719
 720 This method is deprecated in favour of setting via L</connect_info>.
 721
 722 =cut
 723
 724 =head2 on_disconnect_do
 725
 726 This method is deprecated in favour of setting via L</connect_info>.
 727
 728 =cut
 729
 730 sub _parse_connect_do {
 731   my ($self, $type) = @_;
 732
 733   my $val = $self->$type;
 734   return () if not defined $val;
 735
 736   my @res;
 737
 738   if (not ref($val)) {
 739     push @res, [ 'do_sql', $val ];
 740   } elsif (ref($val) eq 'CODE') {
 741     push @res, $val;
 742   } elsif (ref($val) eq 'ARRAY') {
 743     push @res, map { [ 'do_sql', $_ ] } @$val;
 744   } else {
 745     $self->throw_exception("Invalid type for $type: ".ref($val));
 746   }
 747
 748   return \@res;
 749 }
 750
 751 =head2 dbh_do
 752
 753 Arguments: ($subref | $method_name), @extra_coderef_args?
 754
 755 Execute the given $subref or $method_name using the new exception-based
 756 connection management.
 757
 758 The first two arguments will be the storage object that C<dbh_do> was called
 759 on and a database handle to use.  Any additional arguments will be passed
 760 verbatim to the called subref as arguments 2 and onwards.
 761
 762 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 763 exception handling and reconnection (or failover in future subclasses).
 764
 765 Your subref should have no side-effects outside of the database, as
 766 there is the potential for your subref to be partially double-executed
 767 if the database connection was stale/dysfunctional.
 768
 769 Example:
 770
 771   my @stuff = $schema->storage->dbh_do(
 772     sub {
 773       my ($storage, $dbh, @cols) = @_;
 774       my $cols = join(q{, }, @cols);
 775       $dbh->selectrow_array("SELECT $cols FROM foo");
 776     },
 777     @column_list
 778   );
 779
 780 =cut
 781
 782 sub dbh_do {
 783   my $self = shift;
 784   my $run_target = shift;
 785
 786   # short circuit when we know there is no need for a runner
 787   #
 788   # FIXME - asumption may be wrong
 789   # the rationale for the txn_depth check is that if this block is a part
 790   # of a larger transaction, everything up to that point is screwed anyway
 791   return $self->$run_target($self->_get_dbh, @_)
 792     if $self->{_in_do_block} or $self->transaction_depth;
 793
 794   # take a ref instead of a copy, to preserve @_ aliasing
 795   # semantics within the coderef, but only if needed
 796   # (pseudoforking doesn't like this trick much)
 797   my $args = @_ ? \@_ : [];
 798
 799   DBIx::Class::Storage::BlockRunner->new(
 800     storage => $self,
 801     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 802     wrap_txn => 0,
 803     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 804   )->run;
 805 }
 806
 807 sub txn_do {
 808   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 809   shift->next::method(@_);
 810 }
 811
 812 =head2 disconnect
 813
 814 Our C<disconnect> method also performs a rollback first if the
 815 database is not in C<AutoCommit> mode.
 816
 817 =cut
 818
 819 sub disconnect {
 820   my ($self) = @_;
 821
 822   if( $self->_dbh ) {
 823     my @actions;
 824
 825     push @actions, ( $self->on_disconnect_call || () );
 826     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 827
 828     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 829
 830     # stops the "implicit rollback on disconnect" warning
 831     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 832
 833     %{ $self->_dbh->{CachedKids} } = ();
 834     $self->_dbh->disconnect;
 835     $self->_dbh(undef);
 836   }
 837 }
 838
 839 =head2 with_deferred_fk_checks
 840
 841 =over 4
 842
 843 =item Arguments: C<$coderef>
 844
 845 =item Return Value: The return value of $coderef
 846
 847 =back
 848
 849 Storage specific method to run the code ref with FK checks deferred or
 850 in MySQL's case disabled entirely.
 851
 852 =cut
 853
 854 # Storage subclasses should override this
 855 sub with_deferred_fk_checks {
 856   my ($self, $sub) = @_;
 857   $sub->();
 858 }
 859
 860 =head2 connected
 861
 862 =over
 863
 864 =item Arguments: none
 865
 866 =item Return Value: 1|0
 867
 868 =back
 869
 870 Verifies that the current database handle is active and ready to execute
 871 an SQL statement (e.g. the connection did not get stale, server is still
 872 answering, etc.) This method is used internally by L</dbh>.
 873
 874 =cut
 875
 876 sub connected {
 877   my $self = shift;
 878   return 0 unless $self->_seems_connected;
 879
 880   #be on the safe side
 881   local $self->_dbh->{RaiseError} = 1;
 882
 883   return $self->_ping;
 884 }
 885
 886 sub _seems_connected {
 887   my $self = shift;
 888
 889   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 890
 891   my $dbh = $self->_dbh
 892     or return 0;
 893
 894   return $dbh->FETCH('Active');
 895 }
 896
 897 sub _ping {
 898   my $self = shift;
 899
 900   my $dbh = $self->_dbh or return 0;
 901
 902   return $dbh->ping;
 903 }
 904
 905 sub ensure_connected {
 906   my ($self) = @_;
 907
 908   unless ($self->connected) {
 909     $self->_populate_dbh;
 910   }
 911 }
 912
 913 =head2 dbh
 914
 915 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 916 is guaranteed to be healthy by implicitly calling L</connected>, and if
 917 necessary performing a reconnection before returning. Keep in mind that this
 918 is very B<expensive> on some database engines. Consider using L</dbh_do>
 919 instead.
 920
 921 =cut
 922
 923 sub dbh {
 924   my ($self) = @_;
 925
 926   if (not $self->_dbh) {
 927     $self->_populate_dbh;
 928   } else {
 929     $self->ensure_connected;
 930   }
 931   return $self->_dbh;
 932 }
 933
 934 # this is the internal "get dbh or connect (don't check)" method
 935 sub _get_dbh {
 936   my $self = shift;
 937   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 938   $self->_populate_dbh unless $self->_dbh;
 939   return $self->_dbh;
 940 }
 941
 942 sub sql_maker {
 943   my ($self) = @_;
 944   unless ($self->_sql_maker) {
 945     my $sql_maker_class = $self->sql_maker_class;
 946
 947     my %opts = %{$self->_sql_maker_opts||{}};
 948     my $dialect =
 949       $opts{limit_dialect}
 950         ||
 951       $self->sql_limit_dialect
 952         ||
 953       do {
 954         my $s_class = (ref $self) || $self;
 955         carp (
 956           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 957         . 'have not supplied an explicit limit_dialect in your connection_info. '
 958         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 959         . 'databases but can be (and often is) painfully slow. '
 960         . "Please file an RT ticket against '$s_class' ."
 961         );
 962
 963         'GenericSubQ';
 964       }
 965     ;
 966
 967     my ($quote_char, $name_sep);
 968
 969     if ($opts{quote_names}) {
 970       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 971         my $s_class = (ref $self) || $self;
 972         carp (
 973           "You requested 'quote_names' but your storage class ($s_class) does "
 974         . 'not explicitly define a default sql_quote_char and you have not '
 975         . 'supplied a quote_char as part of your connection_info. DBIC will '
 976         .q{default to the ANSI SQL standard quote '"', which works most of }
 977         . "the time. Please file an RT ticket against '$s_class'."
 978         );
 979
 980         '"'; # RV
 981       };
 982
 983       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 984     }
 985
 986     $self->_sql_maker($sql_maker_class->new(
 987       bindtype=>'columns',
 988       array_datatypes => 1,
 989       limit_dialect => $dialect,
 990       ($quote_char ? (quote_char => $quote_char) : ()),
 991       name_sep => ($name_sep || '.'),
 992       %opts,
 993     ));
 994   }
 995   return $self->_sql_maker;
 996 }
 997
 998 # nothing to do by default
 999 sub _rebless {}
1000 sub _init {}
1001
1002 sub _populate_dbh {
1003   my ($self) = @_;
1004
1005   my @info = @{$self->_dbi_connect_info || []};
1006   $self->_dbh(undef); # in case ->connected failed we might get sent here
1007   $self->_dbh_details({}); # reset everything we know
1008
1009   $self->_dbh($self->_connect(@info));
1010
1011   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1012
1013   $self->_determine_driver;
1014
1015   # Always set the transaction depth on connect, since
1016   #  there is no transaction in progress by definition
1017   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1018
1019   $self->_run_connection_actions unless $self->{_in_determine_driver};
1020 }
1021
1022 sub _run_connection_actions {
1023   my $self = shift;
1024   my @actions;
1025
1026   push @actions, ( $self->on_connect_call || () );
1027   push @actions, $self->_parse_connect_do ('on_connect_do');
1028
1029   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1030 }
1031
1032
1033
1034 sub set_use_dbms_capability {
1035   $_[0]->set_inherited ($_[1], $_[2]);
1036 }
1037
1038 sub get_use_dbms_capability {
1039   my ($self, $capname) = @_;
1040
1041   my $use = $self->get_inherited ($capname);
1042   return defined $use
1043     ? $use
1044     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1045   ;
1046 }
1047
1048 sub set_dbms_capability {
1049   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1050 }
1051
1052 sub get_dbms_capability {
1053   my ($self, $capname) = @_;
1054
1055   my $cap = $self->_dbh_details->{capability}{$capname};
1056
1057   unless (defined $cap) {
1058     if (my $meth = $self->can ("_determine$capname")) {
1059       $cap = $self->$meth ? 1 : 0;
1060     }
1061     else {
1062       $cap = 0;
1063     }
1064
1065     $self->set_dbms_capability ($capname, $cap);
1066   }
1067
1068   return $cap;
1069 }
1070
1071 sub _server_info {
1072   my $self = shift;
1073
1074   my $info;
1075   unless ($info = $self->_dbh_details->{info}) {
1076
1077     $info = {};
1078
1079     my $server_version = try {
1080       $self->_get_server_version
1081     } catch {
1082       # driver determination *may* use this codepath
1083       # in which case we must rethrow
1084       $self->throw_exception($_) if $self->{_in_determine_driver};
1085
1086       # $server_version on failure
1087       undef;
1088     };
1089
1090     if (defined $server_version) {
1091       $info->{dbms_version} = $server_version;
1092
1093       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1094       my @verparts = split (/\./, $numeric_version);
1095       if (
1096         @verparts
1097           &&
1098         $verparts[0] <= 999
1099       ) {
1100         # consider only up to 3 version parts, iff not more than 3 digits
1101         my @use_parts;
1102         while (@verparts && @use_parts < 3) {
1103           my $p = shift @verparts;
1104           last if $p > 999;
1105           push @use_parts, $p;
1106         }
1107         push @use_parts, 0 while @use_parts < 3;
1108
1109         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1110       }
1111     }
1112
1113     $self->_dbh_details->{info} = $info;
1114   }
1115
1116   return $info;
1117 }
1118
1119 sub _get_server_version {
1120   shift->_dbh_get_info('SQL_DBMS_VER');
1121 }
1122
1123 sub _dbh_get_info {
1124   my ($self, $info) = @_;
1125
1126   if ($info =~ /[^0-9]/) {
1127     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1128     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1129       unless defined $info;
1130   }
1131
1132   return $self->_get_dbh->get_info($info);
1133 }
1134
1135 sub _describe_connection {
1136   require DBI::Const::GetInfoReturn;
1137
1138   my $self = shift;
1139   $self->ensure_connected;
1140
1141   my $res = {
1142     DBIC_DSN => $self->_dbi_connect_info->[0],
1143     DBI_VER => DBI->VERSION,
1144     DBIC_VER => DBIx::Class->VERSION,
1145     DBIC_DRIVER => ref $self,
1146   };
1147
1148   for my $inf (
1149     #keys %DBI::Const::GetInfoType::GetInfoType,
1150     qw/
1151       SQL_CURSOR_COMMIT_BEHAVIOR
1152       SQL_CURSOR_ROLLBACK_BEHAVIOR
1153       SQL_CURSOR_SENSITIVITY
1154       SQL_DATA_SOURCE_NAME
1155       SQL_DBMS_NAME
1156       SQL_DBMS_VER
1157       SQL_DEFAULT_TXN_ISOLATION
1158       SQL_DM_VER
1159       SQL_DRIVER_NAME
1160       SQL_DRIVER_ODBC_VER
1161       SQL_DRIVER_VER
1162       SQL_EXPRESSIONS_IN_ORDERBY
1163       SQL_GROUP_BY
1164       SQL_IDENTIFIER_CASE
1165       SQL_IDENTIFIER_QUOTE_CHAR
1166       SQL_MAX_CATALOG_NAME_LEN
1167       SQL_MAX_COLUMN_NAME_LEN
1168       SQL_MAX_IDENTIFIER_LEN
1169       SQL_MAX_TABLE_NAME_LEN
1170       SQL_MULTIPLE_ACTIVE_TXN
1171       SQL_MULT_RESULT_SETS
1172       SQL_NEED_LONG_DATA_LEN
1173       SQL_NON_NULLABLE_COLUMNS
1174       SQL_ODBC_VER
1175       SQL_QUALIFIER_NAME_SEPARATOR
1176       SQL_QUOTED_IDENTIFIER_CASE
1177       SQL_TXN_CAPABLE
1178       SQL_TXN_ISOLATION_OPTION
1179     /
1180   ) {
1181     my $v = $self->_dbh_get_info($inf);
1182     next unless defined $v;
1183
1184     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1185     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1186     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1187   }
1188
1189   $res;
1190 }
1191
1192 sub _determine_driver {
1193   my ($self) = @_;
1194
1195   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1196     my $started_connected = 0;
1197     local $self->{_in_determine_driver} = 1;
1198
1199     if (ref($self) eq __PACKAGE__) {
1200       my $driver;
1201       if ($self->_dbh) { # we are connected
1202         $driver = $self->_dbh->{Driver}{Name};
1203         $started_connected = 1;
1204       }
1205       else {
1206         # if connect_info is a CODEREF, we have no choice but to connect
1207         if (ref $self->_dbi_connect_info->[0] &&
1208             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1209           $self->_populate_dbh;
1210           $driver = $self->_dbh->{Driver}{Name};
1211         }
1212         else {
1213           # try to use dsn to not require being connected, the driver may still
1214           # force a connection in _rebless to determine version
1215           # (dsn may not be supplied at all if all we do is make a mock-schema)
1216           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1217           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1218           $driver ||= $ENV{DBI_DRIVER};
1219         }
1220       }
1221
1222       if ($driver) {
1223         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1224         if ($self->load_optional_class($storage_class)) {
1225           mro::set_mro($storage_class, 'c3');
1226           bless $self, $storage_class;
1227           $self->_rebless();
1228         }
1229         else {
1230           $self->_warn_undetermined_driver(
1231             'This version of DBIC does not yet seem to supply a driver for '
1232           . "your particular RDBMS and/or connection method ('$driver')."
1233           );
1234         }
1235       }
1236       else {
1237         $self->_warn_undetermined_driver(
1238           'Unable to extract a driver name from connect info - this '
1239         . 'should not have happened.'
1240         );
1241       }
1242     }
1243
1244     $self->_driver_determined(1);
1245
1246     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1247
1248     if ($self->can('source_bind_attributes')) {
1249       $self->throw_exception(
1250         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1251       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1252       . 'If you are not sure how to proceed please contact the development team via '
1253       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1254       );
1255     }
1256
1257     $self->_init; # run driver-specific initializations
1258
1259     $self->_run_connection_actions
1260         if !$started_connected && defined $self->_dbh;
1261   }
1262 }
1263
1264 sub _determine_connector_driver {
1265   my ($self, $conn) = @_;
1266
1267   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1268
1269   if (not $dbtype) {
1270     $self->_warn_undetermined_driver(
1271       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1272     . "$conn connector - this should not have happened."
1273     );
1274     return;
1275   }
1276
1277   $dbtype =~ s/\W/_/gi;
1278
1279   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1280   return if $self->isa($subclass);
1281
1282   if ($self->load_optional_class($subclass)) {
1283     bless $self, $subclass;
1284     $self->_rebless;
1285   }
1286   else {
1287     $self->_warn_undetermined_driver(
1288       'This version of DBIC does not yet seem to supply a driver for '
1289     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1290     );
1291   }
1292 }
1293
1294 sub _warn_undetermined_driver {
1295   my ($self, $msg) = @_;
1296
1297   require Data::Dumper::Concise;
1298
1299   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1300   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1301   . "does not go away, file a bugreport including the following info:\n"
1302   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1303   );
1304 }
1305
1306 sub _do_connection_actions {
1307   my $self          = shift;
1308   my $method_prefix = shift;
1309   my $call          = shift;
1310
1311   if (not ref($call)) {
1312     my $method = $method_prefix . $call;
1313     $self->$method(@_);
1314   } elsif (ref($call) eq 'CODE') {
1315     $self->$call(@_);
1316   } elsif (ref($call) eq 'ARRAY') {
1317     if (ref($call->[0]) ne 'ARRAY') {
1318       $self->_do_connection_actions($method_prefix, $_) for @$call;
1319     } else {
1320       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1321     }
1322   } else {
1323     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1324   }
1325
1326   return $self;
1327 }
1328
1329 sub connect_call_do_sql {
1330   my $self = shift;
1331   $self->_do_query(@_);
1332 }
1333
1334 sub disconnect_call_do_sql {
1335   my $self = shift;
1336   $self->_do_query(@_);
1337 }
1338
1339 # override in db-specific backend when necessary
1340 sub connect_call_datetime_setup { 1 }
1341
1342 sub _do_query {
1343   my ($self, $action) = @_;
1344
1345   if (ref $action eq 'CODE') {
1346     $action = $action->($self);
1347     $self->_do_query($_) foreach @$action;
1348   }
1349   else {
1350     # Most debuggers expect ($sql, @bind), so we need to exclude
1351     # the attribute hash which is the second argument to $dbh->do
1352     # furthermore the bind values are usually to be presented
1353     # as named arrayref pairs, so wrap those here too
1354     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1355     my $sql = shift @do_args;
1356     my $attrs = shift @do_args;
1357     my @bind = map { [ undef, $_ ] } @do_args;
1358
1359     $self->dbh_do(sub {
1360       $_[0]->_query_start($sql, \@bind);
1361       $_[1]->do($sql, $attrs, @do_args);
1362       $_[0]->_query_end($sql, \@bind);
1363     });
1364   }
1365
1366   return $self;
1367 }
1368
1369 sub _connect {
1370   my ($self, @info) = @_;
1371
1372   $self->throw_exception("You failed to provide any connection info")
1373     if !@info;
1374
1375   my ($old_connect_via, $dbh);
1376
1377   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1378
1379   try {
1380     if(ref $info[0] eq 'CODE') {
1381       $dbh = $info[0]->();
1382     }
1383     else {
1384       require DBI;
1385       $dbh = DBI->connect(@info);
1386     }
1387
1388     die $DBI::errstr unless $dbh;
1389
1390     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1391       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1392       . 'not continue',
1393       ref $info[0] eq 'CODE'
1394         ? "Connection coderef $info[0] returned a"
1395         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1396     ) unless $dbh->FETCH('Active');
1397
1398     # sanity checks unless asked otherwise
1399     unless ($self->unsafe) {
1400
1401       $self->throw_exception(
1402         'Refusing clobbering of {HandleError} installed on externally supplied '
1403        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1404       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1405
1406       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1407       # request, or an external handle. Complain and set anyway
1408       unless ($dbh->{RaiseError}) {
1409         carp( ref $info[0] eq 'CODE'
1410
1411           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1412            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1413            .'attribute has been supplied'
1414
1415           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1416            .'unsafe => 1. Toggling RaiseError back to true'
1417         );
1418
1419         $dbh->{RaiseError} = 1;
1420       }
1421
1422       # this odd anonymous coderef dereference is in fact really
1423       # necessary to avoid the unwanted effect described in perl5
1424       # RT#75792
1425       sub {
1426         my $weak_self = $_[0];
1427         weaken $weak_self;
1428
1429         # the coderef is blessed so we can distinguish it from externally
1430         # supplied handles (which must be preserved)
1431         $_[1]->{HandleError} = bless sub {
1432           if ($weak_self) {
1433             $weak_self->throw_exception("DBI Exception: $_[0]");
1434           }
1435           else {
1436             # the handler may be invoked by something totally out of
1437             # the scope of DBIC
1438             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1439           }
1440         }, '__DBIC__DBH__ERROR__HANDLER__';
1441       }->($self, $dbh);
1442     }
1443   }
1444   catch {
1445     $self->throw_exception("DBI Connection failed: $_")
1446   };
1447
1448   $self->_dbh_autocommit($dbh->{AutoCommit});
1449   $dbh;
1450 }
1451
1452 sub txn_begin {
1453   my $self = shift;
1454
1455   # this means we have not yet connected and do not know the AC status
1456   # (e.g. coderef $dbh), need a full-fledged connection check
1457   if (! defined $self->_dbh_autocommit) {
1458     $self->ensure_connected;
1459   }
1460   # Otherwise simply connect or re-connect on pid changes
1461   else {
1462     $self->_get_dbh;
1463   }
1464
1465   $self->next::method(@_);
1466 }
1467
1468 sub _exec_txn_begin {
1469   my $self = shift;
1470
1471   # if the user is utilizing txn_do - good for him, otherwise we need to
1472   # ensure that the $dbh is healthy on BEGIN.
1473   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1474   # will be replaced by a failure of begin_work itself (which will be
1475   # then retried on reconnect)
1476   if ($self->{_in_do_block}) {
1477     $self->_dbh->begin_work;
1478   } else {
1479     $self->dbh_do(sub { $_[1]->begin_work });
1480   }
1481 }
1482
1483 sub txn_commit {
1484   my $self = shift;
1485
1486   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1487   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1488     unless $self->_dbh;
1489
1490   # esoteric case for folks using external $dbh handles
1491   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1492     carp "Storage transaction_depth 0 does not match "
1493         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1494     $self->transaction_depth(1);
1495   }
1496
1497   $self->next::method(@_);
1498
1499   # if AutoCommit is disabled txn_depth never goes to 0
1500   # as a new txn is started immediately on commit
1501   $self->transaction_depth(1) if (
1502     !$self->transaction_depth
1503       and
1504     defined $self->_dbh_autocommit
1505       and
1506     ! $self->_dbh_autocommit
1507   );
1508 }
1509
1510 sub _exec_txn_commit {
1511   shift->_dbh->commit;
1512 }
1513
1514 sub txn_rollback {
1515   my $self = shift;
1516
1517   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1518   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1519     unless $self->_dbh;
1520
1521   # esoteric case for folks using external $dbh handles
1522   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1523     carp "Storage transaction_depth 0 does not match "
1524         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1525     $self->transaction_depth(1);
1526   }
1527
1528   $self->next::method(@_);
1529
1530   # if AutoCommit is disabled txn_depth never goes to 0
1531   # as a new txn is started immediately on commit
1532   $self->transaction_depth(1) if (
1533     !$self->transaction_depth
1534       and
1535     defined $self->_dbh_autocommit
1536       and
1537     ! $self->_dbh_autocommit
1538   );
1539 }
1540
1541 sub _exec_txn_rollback {
1542   shift->_dbh->rollback;
1543 }
1544
1545 # generate some identical methods
1546 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1547   no strict qw/refs/;
1548   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1549     my $self = shift;
1550     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1551     $self->throw_exception("Unable to $meth() on a disconnected storage")
1552       unless $self->_dbh;
1553     $self->next::method(@_);
1554   };
1555 }
1556
1557 # This used to be the top-half of _execute.  It was split out to make it
1558 #  easier to override in NoBindVars without duping the rest.  It takes up
1559 #  all of _execute's args, and emits $sql, @bind.
1560 sub _prep_for_execute {
1561   #my ($self, $op, $ident, $args) = @_;
1562   return shift->_gen_sql_bind(@_)
1563 }
1564
1565 sub _gen_sql_bind {
1566   my ($self, $op, $ident, $args) = @_;
1567
1568   my ($colinfos, $from);
1569   if ( blessed($ident) ) {
1570     $from = $ident->from;
1571     $colinfos = $ident->columns_info;
1572   }
1573
1574   my ($sql, @bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1575
1576   if (
1577     ! $ENV{DBIC_DT_SEARCH_OK}
1578       and
1579     $op eq 'select'
1580       and
1581     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1582   ) {
1583     carp_unique 'DateTime objects passed to search() are not supported '
1584       . 'properly (InflateColumn::DateTime formats and settings are not '
1585       . 'respected.) See "Formatting DateTime objects in queries" in '
1586       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1587       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1588   }
1589
1590   return( $sql, $self->_resolve_bindattrs(
1591     $ident, [ @{$args->[2]{bind}||[]}, @bind ], $colinfos
1592   ));
1593 }
1594
1595 sub _resolve_bindattrs {
1596   my ($self, $ident, $bind, $colinfos) = @_;
1597
1598   $colinfos ||= {};
1599
1600   my $resolve_bindinfo = sub {
1601     #my $infohash = shift;
1602
1603     %$colinfos = %{ $self->_resolve_column_info($ident) }
1604       unless keys %$colinfos;
1605
1606     my $ret;
1607     if (my $col = $_[0]->{dbic_colname}) {
1608       $ret = { %{$_[0]} };
1609
1610       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1611         if $colinfos->{$col}{data_type};
1612
1613       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1614         if $colinfos->{$col}{size};
1615     }
1616
1617     $ret || $_[0];
1618   };
1619
1620   return [ map {
1621     if (ref $_ ne 'ARRAY') {
1622       [{}, $_]
1623     }
1624     elsif (! defined $_->[0]) {
1625       [{}, $_->[1]]
1626     }
1627     elsif (ref $_->[0] eq 'HASH') {
1628       [
1629         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1630         $_->[1]
1631       ]
1632     }
1633     elsif (ref $_->[0] eq 'SCALAR') {
1634       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1635     }
1636     else {
1637       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1638     }
1639   } @$bind ];
1640 }
1641
1642 sub _format_for_trace {
1643   #my ($self, $bind) = @_;
1644
1645   ### Turn @bind from something like this:
1646   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1647   ### to this:
1648   ###   ( "'1'", "'3'" )
1649
1650   map {
1651     defined( $_ && $_->[1] )
1652       ? qq{'$_->[1]'}
1653       : q{NULL}
1654   } @{$_[1] || []};
1655 }
1656
1657 sub _query_start {
1658   my ( $self, $sql, $bind ) = @_;
1659
1660   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1661     if $self->debug;
1662 }
1663
1664 sub _query_end {
1665   my ( $self, $sql, $bind ) = @_;
1666
1667   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1668     if $self->debug;
1669 }
1670
1671 sub _dbi_attrs_for_bind {
1672   my ($self, $ident, $bind) = @_;
1673
1674   my @attrs;
1675
1676   for (map { $_->[0] } @$bind) {
1677     push @attrs, do {
1678       if (exists $_->{dbd_attrs}) {
1679         $_->{dbd_attrs}
1680       }
1681       elsif($_->{sqlt_datatype}) {
1682         # cache the result in the dbh_details hash, as it can not change unless
1683         # we connect to something else
1684         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1685         if (not exists $cache->{$_->{sqlt_datatype}}) {
1686           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1687         }
1688         $cache->{$_->{sqlt_datatype}};
1689       }
1690       else {
1691         undef;  # always push something at this position
1692       }
1693     }
1694   }
1695
1696   return \@attrs;
1697 }
1698
1699 sub _execute {
1700   my ($self, $op, $ident, @args) = @_;
1701
1702   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1703
1704   shift->dbh_do(    # retry over disconnects
1705     '_dbh_execute',
1706     $sql,
1707     $bind,
1708     $ident,
1709   );
1710 }
1711
1712 sub _dbh_execute {
1713   my ($self, undef, $sql, $bind, $ident) = @_;
1714
1715   $self->_query_start( $sql, $bind );
1716
1717   my $bind_attrs = $self->_dbi_attrs_for_bind($ident, $bind);
1718
1719   my $sth = $self->_sth($sql);
1720
1721   for my $i (0 .. $#$bind) {
1722     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1723       $sth->bind_param_inout(
1724         $i + 1, # bind params counts are 1-based
1725         $bind->[$i][1],
1726         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1727         $bind_attrs->[$i],
1728       );
1729     }
1730     else {
1731       $sth->bind_param(
1732         $i + 1,
1733         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1734           ? "$bind->[$i][1]"
1735           : $bind->[$i][1]
1736         ,
1737         $bind_attrs->[$i],
1738       );
1739     }
1740   }
1741
1742   # Can this fail without throwing an exception anyways???
1743   my $rv = $sth->execute();
1744   $self->throw_exception(
1745     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1746   ) if !$rv;
1747
1748   $self->_query_end( $sql, $bind );
1749
1750   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1751 }
1752
1753 sub _prefetch_autovalues {
1754   my ($self, $source, $colinfo, $to_insert) = @_;
1755
1756   my %values;
1757   for my $col (keys %$colinfo) {
1758     if (
1759       $colinfo->{$col}{auto_nextval}
1760         and
1761       (
1762         ! exists $to_insert->{$col}
1763           or
1764         ref $to_insert->{$col} eq 'SCALAR'
1765           or
1766         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1767       )
1768     ) {
1769       $values{$col} = $self->_sequence_fetch(
1770         'NEXTVAL',
1771         ( $colinfo->{$col}{sequence} ||=
1772             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1773         ),
1774       );
1775     }
1776   }
1777
1778   \%values;
1779 }
1780
1781 sub insert {
1782   my ($self, $source, $to_insert) = @_;
1783
1784   my $col_infos = $source->columns_info;
1785
1786   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1787
1788   # fuse the values, but keep a separate list of prefetched_values so that
1789   # they can be fused once again with the final return
1790   $to_insert = { %$to_insert, %$prefetched_values };
1791
1792   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1793   # Investigate what does it take to s/defined/exists/
1794   my %pcols = map { $_ => 1 } $source->primary_columns;
1795   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1796   for my $col ($source->columns) {
1797     if ($col_infos->{$col}{is_auto_increment}) {
1798       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1799       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1800     }
1801
1802     # nothing to retrieve when explicit values are supplied
1803     next if (defined $to_insert->{$col} and ! (
1804       ref $to_insert->{$col} eq 'SCALAR'
1805         or
1806       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1807     ));
1808
1809     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1810     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1811       $pcols{$col}
1812         or
1813       $col_infos->{$col}{retrieve_on_insert}
1814     );
1815   };
1816
1817   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1818   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1819
1820   my ($sqla_opts, @ir_container);
1821   if (%retrieve_cols and $self->_use_insert_returning) {
1822     $sqla_opts->{returning_container} = \@ir_container
1823       if $self->_use_insert_returning_bound;
1824
1825     $sqla_opts->{returning} = [
1826       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1827     ];
1828   }
1829
1830   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1831
1832   my %returned_cols = %$to_insert;
1833   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1834     @ir_container = try {
1835       local $SIG{__WARN__} = sub {};
1836       my @r = $sth->fetchrow_array;
1837       $sth->finish;
1838       @r;
1839     } unless @ir_container;
1840
1841     @returned_cols{@$retlist} = @ir_container if @ir_container;
1842   }
1843   else {
1844     # pull in PK if needed and then everything else
1845     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1846
1847       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1848         unless $self->can('last_insert_id');
1849
1850       my @pri_values = $self->last_insert_id($source, @missing_pri);
1851
1852       $self->throw_exception( "Can't get last insert id" )
1853         unless (@pri_values == @missing_pri);
1854
1855       @returned_cols{@missing_pri} = @pri_values;
1856       delete $retrieve_cols{$_} for @missing_pri;
1857     }
1858
1859     # if there is more left to pull
1860     if (%retrieve_cols) {
1861       $self->throw_exception(
1862         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1863       ) unless %pcols;
1864
1865       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1866
1867       my $cur = DBIx::Class::ResultSet->new($source, {
1868         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1869         select => \@left_to_fetch,
1870       })->cursor;
1871
1872       @returned_cols{@left_to_fetch} = $cur->next;
1873
1874       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1875         if scalar $cur->next;
1876     }
1877   }
1878
1879   return { %$prefetched_values, %returned_cols };
1880 }
1881
1882 sub insert_bulk {
1883   my ($self, $source, $cols, $data) = @_;
1884
1885   my @col_range = (0..$#$cols);
1886
1887   # FIXME - perhaps this is not even needed? does DBI stringify?
1888   #
1889   # forcibly stringify whatever is stringifiable
1890   # ResultSet::populate() hands us a copy - safe to mangle
1891   for my $r (0 .. $#$data) {
1892     for my $c (0 .. $#{$data->[$r]}) {
1893       $data->[$r][$c] = "$data->[$r][$c]"
1894         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1895     }
1896   }
1897
1898   my $colinfos = $source->columns_info($cols);
1899
1900   local $self->{_autoinc_supplied_for_op} =
1901     (first { $_->{is_auto_increment} } values %$colinfos)
1902       ? 1
1903       : 0
1904   ;
1905
1906   # get a slice type index based on first row of data
1907   # a "column" in this context may refer to more than one bind value
1908   # e.g. \[ '?, ?', [...], [...] ]
1909   #
1910   # construct the value type index - a description of values types for every
1911   # per-column slice of $data:
1912   #
1913   # nonexistent - nonbind literal
1914   # 0 - regular value
1915   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1916   #
1917   # also construct the column hash to pass to the SQL generator. For plain
1918   # (non literal) values - convert the members of the first row into a
1919   # literal+bind combo, with extra positional info in the bind attr hashref.
1920   # This will allow us to match the order properly, and is so contrived
1921   # because a user-supplied literal/bind (or something else specific to a
1922   # resultsource and/or storage driver) can inject extra binds along the
1923   # way, so one can't rely on "shift positions" ordering at all. Also we
1924   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1925   # can be later matched up by address), because we want to supply a real
1926   # value on which perhaps e.g. datatype checks will be performed
1927   my ($proto_data, $value_type_by_col_idx);
1928   for my $i (@col_range) {
1929     my $colname = $cols->[$i];
1930     if (ref $data->[0][$i] eq 'SCALAR') {
1931       # no bind value at all - no type
1932
1933       $proto_data->{$colname} = $data->[0][$i];
1934     }
1935     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1936       # repack, so we don't end up mangling the original \[]
1937       my ($sql, @bind) = @${$data->[0][$i]};
1938
1939       # normalization of user supplied stuff
1940       my $resolved_bind = $self->_resolve_bindattrs(
1941         $source, \@bind, $colinfos,
1942       );
1943
1944       # store value-less (attrs only) bind info - we will be comparing all
1945       # supplied binds against this for sanity
1946       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1947
1948       $proto_data->{$colname} = \[ $sql, map { [
1949         # inject slice order to use for $proto_bind construction
1950           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
1951             =>
1952           $resolved_bind->[$_][1]
1953         ] } (0 .. $#bind)
1954       ];
1955     }
1956     else {
1957       $value_type_by_col_idx->{$i} = undef;
1958
1959       $proto_data->{$colname} = \[ '?', [
1960         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1961           =>
1962         $data->[0][$i]
1963       ] ];
1964     }
1965   }
1966
1967   my ($sql, $proto_bind) = $self->_prep_for_execute (
1968     'insert',
1969     $source,
1970     [ $proto_data ],
1971   );
1972
1973   if (! @$proto_bind and keys %$value_type_by_col_idx) {
1974     # if the bindlist is empty and we had some dynamic binds, this means the
1975     # storage ate them away (e.g. the NoBindVars component) and interpolated
1976     # them directly into the SQL. This obviously can't be good for multi-inserts
1977     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1978   }
1979
1980   # sanity checks
1981   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1982   #
1983   # use an error reporting closure for convenience (less to pass)
1984   my $bad_slice_report_cref = sub {
1985     my ($msg, $r_idx, $c_idx) = @_;
1986     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1987       $msg,
1988       $cols->[$c_idx],
1989       do {
1990         require Data::Dumper::Concise;
1991         local $Data::Dumper::Maxdepth = 5;
1992         Data::Dumper::Concise::Dumper ({
1993           map { $cols->[$_] =>
1994             $data->[$r_idx][$_]
1995           } @col_range
1996         }),
1997       }
1998     );
1999   };
2000
2001   for my $col_idx (@col_range) {
2002     my $reference_val = $data->[0][$col_idx];
2003
2004     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2005       my $val = $data->[$row_idx][$col_idx];
2006
2007       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2008         if (ref $val ne 'SCALAR') {
2009           $bad_slice_report_cref->(
2010             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2011             $row_idx,
2012             $col_idx,
2013           );
2014         }
2015         elsif ($$val ne $$reference_val) {
2016           $bad_slice_report_cref->(
2017             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2018             $row_idx,
2019             $col_idx,
2020           );
2021         }
2022       }
2023       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2024         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2025           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2026         }
2027       }
2028       else {  # binds from a \[], compare type and attrs
2029         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2030           $bad_slice_report_cref->(
2031             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2032             $row_idx,
2033             $col_idx,
2034           );
2035         }
2036         # start drilling down and bail out early on identical refs
2037         elsif (
2038           $reference_val != $val
2039             or
2040           $$reference_val != $$val
2041         ) {
2042           if (${$val}->[0] ne ${$reference_val}->[0]) {
2043             $bad_slice_report_cref->(
2044               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2045               $row_idx,
2046               $col_idx,
2047             );
2048           }
2049           # need to check the bind attrs - a bind will happen only once for
2050           # the entire dataset, so any changes further down will be ignored.
2051           elsif (! Data::Compare::Compare(
2052             $value_type_by_col_idx->{$col_idx},
2053             [
2054               map
2055               { $_->[0] }
2056               @{$self->_resolve_bindattrs(
2057                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2058               )}
2059             ],
2060           )) {
2061             $bad_slice_report_cref->(
2062               'Differing bind attributes on literal/bind values not supported',
2063               $row_idx,
2064               $col_idx,
2065             );
2066           }
2067         }
2068       }
2069     }
2070   }
2071
2072   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2073   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2074   # scope guard
2075   my $guard = $self->txn_scope_guard;
2076
2077   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2078   my $sth = $self->_sth($sql);
2079   my $rv = do {
2080     if (@$proto_bind) {
2081       # proto bind contains the information on which pieces of $data to pull
2082       # $cols is passed in only for prettier error-reporting
2083       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2084     }
2085     else {
2086       # bind_param_array doesn't work if there are no binds
2087       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2088     }
2089   };
2090
2091   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2092
2093   $guard->commit;
2094
2095   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2096 }
2097
2098 # execute_for_fetch is capable of returning data just fine (it means it
2099 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2100 # is the void-populate fast-path we will just ignore this altogether
2101 # for the time being.
2102 sub _dbh_execute_for_fetch {
2103   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2104
2105   my @idx_range = ( 0 .. $#$proto_bind );
2106
2107   # If we have any bind attributes to take care of, we will bind the
2108   # proto-bind data (which will never be used by execute_for_fetch)
2109   # However since column bindtypes are "sticky", this is sufficient
2110   # to get the DBD to apply the bindtype to all values later on
2111
2112   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2113
2114   for my $i (@idx_range) {
2115     $sth->bind_param (
2116       $i+1, # DBI bind indexes are 1-based
2117       $proto_bind->[$i][1],
2118       $bind_attrs->[$i],
2119     ) if defined $bind_attrs->[$i];
2120   }
2121
2122   # At this point $data slots named in the _bind_data_slice_idx of
2123   # each piece of $proto_bind are either \[]s or plain values to be
2124   # passed in. Construct the dispensing coderef. *NOTE* the order
2125   # of $data will differ from this of the ?s in the SQL (due to
2126   # alphabetical ordering by colname). We actually do want to
2127   # preserve this behavior so that prepare_cached has a better
2128   # chance of matching on unrelated calls
2129
2130   my $fetch_row_idx = -1; # saner loop this way
2131   my $fetch_tuple = sub {
2132     return undef if ++$fetch_row_idx > $#$data;
2133
2134     return [ map { defined $_->{_literal_bind_subindex}
2135       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2136          ->[ $_->{_literal_bind_subindex} ]
2137           ->[1]
2138       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2139     } map { $_->[0] } @$proto_bind];
2140   };
2141
2142   my $tuple_status = [];
2143   my ($rv, $err);
2144   try {
2145     $rv = $sth->execute_for_fetch(
2146       $fetch_tuple,
2147       $tuple_status,
2148     );
2149   }
2150   catch {
2151     $err = shift;
2152   };
2153
2154   # Not all DBDs are create equal. Some throw on error, some return
2155   # an undef $rv, and some set $sth->err - try whatever we can
2156   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2157     ! defined $err
2158       and
2159     ( !defined $rv or $sth->err )
2160   );
2161
2162   # Statement must finish even if there was an exception.
2163   try {
2164     $sth->finish
2165   }
2166   catch {
2167     $err = shift unless defined $err
2168   };
2169
2170   if (defined $err) {
2171     my $i = 0;
2172     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2173
2174     $self->throw_exception("Unexpected populate error: $err")
2175       if ($i > $#$tuple_status);
2176
2177     require Data::Dumper::Concise;
2178     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2179       ($tuple_status->[$i][1] || $err),
2180       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2181     );
2182   }
2183
2184   return $rv;
2185 }
2186
2187 sub _dbh_execute_inserts_with_no_binds {
2188   my ($self, $sth, $count) = @_;
2189
2190   my $err;
2191   try {
2192     my $dbh = $self->_get_dbh;
2193     local $dbh->{RaiseError} = 1;
2194     local $dbh->{PrintError} = 0;
2195
2196     $sth->execute foreach 1..$count;
2197   }
2198   catch {
2199     $err = shift;
2200   };
2201
2202   # Make sure statement is finished even if there was an exception.
2203   try {
2204     $sth->finish
2205   }
2206   catch {
2207     $err = shift unless defined $err;
2208   };
2209
2210   $self->throw_exception($err) if defined $err;
2211
2212   return $count;
2213 }
2214
2215 sub update {
2216   #my ($self, $source, @args) = @_;
2217   shift->_execute('update', @_);
2218 }
2219
2220
2221 sub delete {
2222   #my ($self, $source, @args) = @_;
2223   shift->_execute('delete', @_);
2224 }
2225
2226 sub _select {
2227   my $self = shift;
2228   $self->_execute($self->_select_args(@_));
2229 }
2230
2231 sub _select_args_to_query {
2232   my $self = shift;
2233
2234   $self->throw_exception(
2235     "Unable to generate limited query representation with 'software_limit' enabled"
2236   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2237
2238   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2239   #  = $self->_select_args($ident, $select, $cond, $attrs);
2240   my ($op, $ident, @args) =
2241     $self->_select_args(@_);
2242
2243   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2244   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2245   $prepared_bind ||= [];
2246
2247   return wantarray
2248     ? ($sql, $prepared_bind)
2249     : \[ "($sql)", @$prepared_bind ]
2250   ;
2251 }
2252
2253 sub _select_args {
2254   my ($self, $ident, $select, $where, $attrs) = @_;
2255
2256   my $sql_maker = $self->sql_maker;
2257   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2258
2259   $attrs = {
2260     %$attrs,
2261     select => $select,
2262     from => $ident,
2263     where => $where,
2264     $rs_alias && $alias2source->{$rs_alias}
2265       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2266       : ()
2267     ,
2268   };
2269
2270   # Sanity check the attributes (SQLMaker does it too, but
2271   # in case of a software_limit we'll never reach there)
2272   if (defined $attrs->{offset}) {
2273     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2274       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2275   }
2276
2277   if (defined $attrs->{rows}) {
2278     $self->throw_exception("The rows attribute must be a positive integer if present")
2279       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2280   }
2281   elsif ($attrs->{offset}) {
2282     # MySQL actually recommends this approach.  I cringe.
2283     $attrs->{rows} = $sql_maker->__max_int;
2284   }
2285
2286   my @limit;
2287
2288   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2289   # storage, unless software limit was requested
2290   if (
2291     # limited collapsing has_many
2292     ( $attrs->{rows} && $attrs->{collapse} )
2293        ||
2294     # grouped prefetch (to satisfy group_by == select)
2295     ( $attrs->{group_by}
2296         &&
2297       @{$attrs->{group_by}}
2298         &&
2299       $attrs->{_prefetch_selector_range}
2300     )
2301   ) {
2302     ($ident, $select, $where, $attrs)
2303       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2304   }
2305   elsif (! $attrs->{software_limit} ) {
2306     push @limit, (
2307       $attrs->{rows} || (),
2308       $attrs->{offset} || (),
2309     );
2310   }
2311
2312   # try to simplify the joinmap further (prune unreferenced type-single joins)
2313   if (
2314     ref $ident
2315       and
2316     reftype $ident eq 'ARRAY'
2317       and
2318     @$ident != 1
2319   ) {
2320     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2321   }
2322
2323 ###
2324   # This would be the point to deflate anything found in $where
2325   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2326   # expect a result object. And all we have is a resultsource (it is trivial
2327   # to extract deflator coderefs via $alias2source above).
2328   #
2329   # I don't see a way forward other than changing the way deflators are
2330   # invoked, and that's just bad...
2331 ###
2332
2333   return ('select', $ident, $select, $where, $attrs, @limit);
2334 }
2335
2336 # Returns a counting SELECT for a simple count
2337 # query. Abstracted so that a storage could override
2338 # this to { count => 'firstcol' } or whatever makes
2339 # sense as a performance optimization
2340 sub _count_select {
2341   #my ($self, $source, $rs_attrs) = @_;
2342   return { count => '*' };
2343 }
2344
2345 =head2 select
2346
2347 =over 4
2348
2349 =item Arguments: $ident, $select, $condition, $attrs
2350
2351 =back
2352
2353 Handle a SQL select statement.
2354
2355 =cut
2356
2357 sub select {
2358   my $self = shift;
2359   my ($ident, $select, $condition, $attrs) = @_;
2360   return $self->cursor_class->new($self, \@_, $attrs);
2361 }
2362
2363 sub select_single {
2364   my $self = shift;
2365   my ($rv, $sth, @bind) = $self->_select(@_);
2366   my @row = $sth->fetchrow_array;
2367   my @nextrow = $sth->fetchrow_array if @row;
2368   if(@row && @nextrow) {
2369     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2370   }
2371   # Need to call finish() to work round broken DBDs
2372   $sth->finish();
2373   return @row;
2374 }
2375
2376 =head2 sql_limit_dialect
2377
2378 This is an accessor for the default SQL limit dialect used by a particular
2379 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2380 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2381 see L<DBIx::Class::SQLMaker::LimitDialects>.
2382
2383 =cut
2384
2385 sub _dbh_sth {
2386   my ($self, $dbh, $sql) = @_;
2387
2388   # 3 is the if_active parameter which avoids active sth re-use
2389   my $sth = $self->disable_sth_caching
2390     ? $dbh->prepare($sql)
2391     : $dbh->prepare_cached($sql, {}, 3);
2392
2393   # XXX You would think RaiseError would make this impossible,
2394   #  but apparently that's not true :(
2395   $self->throw_exception(
2396     $dbh->errstr
2397       ||
2398     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2399             .'an exception and/or setting $dbh->errstr',
2400       length ($sql) > 20
2401         ? substr($sql, 0, 20) . '...'
2402         : $sql
2403       ,
2404       'DBD::' . $dbh->{Driver}{Name},
2405     )
2406   ) if !$sth;
2407
2408   $sth;
2409 }
2410
2411 sub sth {
2412   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2413   shift->_sth(@_);
2414 }
2415
2416 sub _sth {
2417   my ($self, $sql) = @_;
2418   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2419 }
2420
2421 sub _dbh_columns_info_for {
2422   my ($self, $dbh, $table) = @_;
2423
2424   if ($dbh->can('column_info')) {
2425     my %result;
2426     my $caught;
2427     try {
2428       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2429       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2430       $sth->execute();
2431       while ( my $info = $sth->fetchrow_hashref() ){
2432         my %column_info;
2433         $column_info{data_type}   = $info->{TYPE_NAME};
2434         $column_info{size}      = $info->{COLUMN_SIZE};
2435         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2436         $column_info{default_value} = $info->{COLUMN_DEF};
2437         my $col_name = $info->{COLUMN_NAME};
2438         $col_name =~ s/^\"(.*)\"$/$1/;
2439
2440         $result{$col_name} = \%column_info;
2441       }
2442     } catch {
2443       $caught = 1;
2444     };
2445     return \%result if !$caught && scalar keys %result;
2446   }
2447
2448   my %result;
2449   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2450   $sth->execute;
2451   my @columns = @{$sth->{NAME_lc}};
2452   for my $i ( 0 .. $#columns ){
2453     my %column_info;
2454     $column_info{data_type} = $sth->{TYPE}->[$i];
2455     $column_info{size} = $sth->{PRECISION}->[$i];
2456     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2457
2458     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2459       $column_info{data_type} = $1;
2460       $column_info{size}    = $2;
2461     }
2462
2463     $result{$columns[$i]} = \%column_info;
2464   }
2465   $sth->finish;
2466
2467   foreach my $col (keys %result) {
2468     my $colinfo = $result{$col};
2469     my $type_num = $colinfo->{data_type};
2470     my $type_name;
2471     if(defined $type_num && $dbh->can('type_info')) {
2472       my $type_info = $dbh->type_info($type_num);
2473       $type_name = $type_info->{TYPE_NAME} if $type_info;
2474       $colinfo->{data_type} = $type_name if $type_name;
2475     }
2476   }
2477
2478   return \%result;
2479 }
2480
2481 sub columns_info_for {
2482   my ($self, $table) = @_;
2483   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2484 }
2485
2486 =head2 last_insert_id
2487
2488 Return the row id of the last insert.
2489
2490 =cut
2491
2492 sub _dbh_last_insert_id {
2493     my ($self, $dbh, $source, $col) = @_;
2494
2495     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2496
2497     return $id if defined $id;
2498
2499     my $class = ref $self;
2500     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2501 }
2502
2503 sub last_insert_id {
2504   my $self = shift;
2505   $self->_dbh_last_insert_id ($self->_dbh, @_);
2506 }
2507
2508 =head2 _native_data_type
2509
2510 =over 4
2511
2512 =item Arguments: $type_name
2513
2514 =back
2515
2516 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2517 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2518 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2519
2520 The default implementation returns C<undef>, implement in your Storage driver if
2521 you need this functionality.
2522
2523 Should map types from other databases to the native RDBMS type, for example
2524 C<VARCHAR2> to C<VARCHAR>.
2525
2526 Types with modifiers should map to the underlying data type. For example,
2527 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2528
2529 Composite types should map to the container type, for example
2530 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2531
2532 =cut
2533
2534 sub _native_data_type {
2535   #my ($self, $data_type) = @_;
2536   return undef
2537 }
2538
2539 # Check if placeholders are supported at all
2540 sub _determine_supports_placeholders {
2541   my $self = shift;
2542   my $dbh  = $self->_get_dbh;
2543
2544   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2545   # but it is inaccurate more often than not
2546   return try {
2547     local $dbh->{PrintError} = 0;
2548     local $dbh->{RaiseError} = 1;
2549     $dbh->do('select ?', {}, 1);
2550     1;
2551   }
2552   catch {
2553     0;
2554   };
2555 }
2556
2557 # Check if placeholders bound to non-string types throw exceptions
2558 #
2559 sub _determine_supports_typeless_placeholders {
2560   my $self = shift;
2561   my $dbh  = $self->_get_dbh;
2562
2563   return try {
2564     local $dbh->{PrintError} = 0;
2565     local $dbh->{RaiseError} = 1;
2566     # this specifically tests a bind that is NOT a string
2567     $dbh->do('select 1 where 1 = ?', {}, 1);
2568     1;
2569   }
2570   catch {
2571     0;
2572   };
2573 }
2574
2575 =head2 sqlt_type
2576
2577 Returns the database driver name.
2578
2579 =cut
2580
2581 sub sqlt_type {
2582   shift->_get_dbh->{Driver}->{Name};
2583 }
2584
2585 =head2 bind_attribute_by_data_type
2586
2587 Given a datatype from column info, returns a database specific bind
2588 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2589 let the database planner just handle it.
2590
2591 This method is always called after the driver has been determined and a DBI
2592 connection has been established. Therefore you can refer to C<DBI::$constant>
2593 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2594 the correct modules.
2595
2596 =cut
2597
2598 sub bind_attribute_by_data_type {
2599     return;
2600 }
2601
2602 =head2 is_datatype_numeric
2603
2604 Given a datatype from column_info, returns a boolean value indicating if
2605 the current RDBMS considers it a numeric value. This controls how
2606 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2607 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2608 be performed instead of the usual C<eq>.
2609
2610 =cut
2611
2612 sub is_datatype_numeric {
2613   #my ($self, $dt) = @_;
2614
2615   return 0 unless $_[1];
2616
2617   $_[1] =~ /^ (?:
2618     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2619   ) $/ix;
2620 }
2621
2622
2623 =head2 create_ddl_dir
2624
2625 =over 4
2626
2627 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2628
2629 =back
2630
2631 Creates a SQL file based on the Schema, for each of the specified
2632 database engines in C<\@databases> in the given directory.
2633 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2634
2635 Given a previous version number, this will also create a file containing
2636 the ALTER TABLE statements to transform the previous schema into the
2637 current one. Note that these statements may contain C<DROP TABLE> or
2638 C<DROP COLUMN> statements that can potentially destroy data.
2639
2640 The file names are created using the C<ddl_filename> method below, please
2641 override this method in your schema if you would like a different file
2642 name format. For the ALTER file, the same format is used, replacing
2643 $version in the name with "$preversion-$version".
2644
2645 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2646 The most common value for this would be C<< { add_drop_table => 1 } >>
2647 to have the SQL produced include a C<DROP TABLE> statement for each table
2648 created. For quoting purposes supply C<quote_table_names> and
2649 C<quote_field_names>.
2650
2651 If no arguments are passed, then the following default values are assumed:
2652
2653 =over 4
2654
2655 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2656
2657 =item version    - $schema->schema_version
2658
2659 =item directory  - './'
2660
2661 =item preversion - <none>
2662
2663 =back
2664
2665 By default, C<\%sqlt_args> will have
2666
2667  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2668
2669 merged with the hash passed in. To disable any of those features, pass in a
2670 hashref like the following
2671
2672  { ignore_constraint_names => 0, # ... other options }
2673
2674
2675 WARNING: You are strongly advised to check all SQL files created, before applying
2676 them.
2677
2678 =cut
2679
2680 sub create_ddl_dir {
2681   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2682
2683   unless ($dir) {
2684     carp "No directory given, using ./\n";
2685     $dir = './';
2686   } else {
2687       -d $dir
2688         or
2689       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2690         or
2691       $self->throw_exception(
2692         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2693       );
2694   }
2695
2696   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2697
2698   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2699   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2700
2701   my $schema_version = $schema->schema_version || '1.x';
2702   $version ||= $schema_version;
2703
2704   $sqltargs = {
2705     add_drop_table => 1,
2706     ignore_constraint_names => 1,
2707     ignore_index_names => 1,
2708     %{$sqltargs || {}}
2709   };
2710
2711   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2712     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2713   }
2714
2715   my $sqlt = SQL::Translator->new( $sqltargs );
2716
2717   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2718   my $sqlt_schema = $sqlt->translate({ data => $schema })
2719     or $self->throw_exception ($sqlt->error);
2720
2721   foreach my $db (@$databases) {
2722     $sqlt->reset();
2723     $sqlt->{schema} = $sqlt_schema;
2724     $sqlt->producer($db);
2725
2726     my $file;
2727     my $filename = $schema->ddl_filename($db, $version, $dir);
2728     if (-e $filename && ($version eq $schema_version )) {
2729       # if we are dumping the current version, overwrite the DDL
2730       carp "Overwriting existing DDL file - $filename";
2731       unlink($filename);
2732     }
2733
2734     my $output = $sqlt->translate;
2735     if(!$output) {
2736       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2737       next;
2738     }
2739     if(!open($file, ">$filename")) {
2740       $self->throw_exception("Can't open $filename for writing ($!)");
2741       next;
2742     }
2743     print $file $output;
2744     close($file);
2745
2746     next unless ($preversion);
2747
2748     require SQL::Translator::Diff;
2749
2750     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2751     if(!-e $prefilename) {
2752       carp("No previous schema file found ($prefilename)");
2753       next;
2754     }
2755
2756     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2757     if(-e $difffile) {
2758       carp("Overwriting existing diff file - $difffile");
2759       unlink($difffile);
2760     }
2761
2762     my $source_schema;
2763     {
2764       my $t = SQL::Translator->new($sqltargs);
2765       $t->debug( 0 );
2766       $t->trace( 0 );
2767
2768       $t->parser( $db )
2769         or $self->throw_exception ($t->error);
2770
2771       my $out = $t->translate( $prefilename )
2772         or $self->throw_exception ($t->error);
2773
2774       $source_schema = $t->schema;
2775
2776       $source_schema->name( $prefilename )
2777         unless ( $source_schema->name );
2778     }
2779
2780     # The "new" style of producers have sane normalization and can support
2781     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2782     # And we have to diff parsed SQL against parsed SQL.
2783     my $dest_schema = $sqlt_schema;
2784
2785     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2786       my $t = SQL::Translator->new($sqltargs);
2787       $t->debug( 0 );
2788       $t->trace( 0 );
2789
2790       $t->parser( $db )
2791         or $self->throw_exception ($t->error);
2792
2793       my $out = $t->translate( $filename )
2794         or $self->throw_exception ($t->error);
2795
2796       $dest_schema = $t->schema;
2797
2798       $dest_schema->name( $filename )
2799         unless $dest_schema->name;
2800     }
2801
2802     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2803                                                   $dest_schema,   $db,
2804                                                   $sqltargs
2805                                                  );
2806     if(!open $file, ">$difffile") {
2807       $self->throw_exception("Can't write to $difffile ($!)");
2808       next;
2809     }
2810     print $file $diff;
2811     close($file);
2812   }
2813 }
2814
2815 =head2 deployment_statements
2816
2817 =over 4
2818
2819 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2820
2821 =back
2822
2823 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2824
2825 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2826 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2827
2828 C<$directory> is used to return statements from files in a previously created
2829 L</create_ddl_dir> directory and is optional. The filenames are constructed
2830 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2831
2832 If no C<$directory> is specified then the statements are constructed on the
2833 fly using L<SQL::Translator> and C<$version> is ignored.
2834
2835 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2836
2837 =cut
2838
2839 sub deployment_statements {
2840   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2841   $type ||= $self->sqlt_type;
2842   $version ||= $schema->schema_version || '1.x';
2843   $dir ||= './';
2844   my $filename = $schema->ddl_filename($type, $version, $dir);
2845   if(-f $filename)
2846   {
2847       # FIXME replace this block when a proper sane sql parser is available
2848       my $file;
2849       open($file, "<$filename")
2850         or $self->throw_exception("Can't open $filename ($!)");
2851       my @rows = <$file>;
2852       close($file);
2853       return join('', @rows);
2854   }
2855
2856   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2857     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2858   }
2859
2860   # sources needs to be a parser arg, but for simplicty allow at top level
2861   # coming in
2862   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2863       if exists $sqltargs->{sources};
2864
2865   my $tr = SQL::Translator->new(
2866     producer => "SQL::Translator::Producer::${type}",
2867     %$sqltargs,
2868     parser => 'SQL::Translator::Parser::DBIx::Class',
2869     data => $schema,
2870   );
2871
2872   return preserve_context {
2873     $tr->translate
2874   } after => sub {
2875     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2876       unless defined $_[0];
2877   };
2878 }
2879
2880 # FIXME deploy() currently does not accurately report sql errors
2881 # Will always return true while errors are warned
2882 sub deploy {
2883   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2884   my $deploy = sub {
2885     my $line = shift;
2886     return if(!$line);
2887     return if($line =~ /^--/);
2888     # next if($line =~ /^DROP/m);
2889     return if($line =~ /^BEGIN TRANSACTION/m);
2890     return if($line =~ /^COMMIT/m);
2891     return if $line =~ /^\s+$/; # skip whitespace only
2892     $self->_query_start($line);
2893     try {
2894       # do a dbh_do cycle here, as we need some error checking in
2895       # place (even though we will ignore errors)
2896       $self->dbh_do (sub { $_[1]->do($line) });
2897     } catch {
2898       carp qq{$_ (running "${line}")};
2899     };
2900     $self->_query_end($line);
2901   };
2902   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2903   if (@statements > 1) {
2904     foreach my $statement (@statements) {
2905       $deploy->( $statement );
2906     }
2907   }
2908   elsif (@statements == 1) {
2909     # split on single line comments and end of statements
2910     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2911       $deploy->( $line );
2912     }
2913   }
2914 }
2915
2916 =head2 datetime_parser
2917
2918 Returns the datetime parser class
2919
2920 =cut
2921
2922 sub datetime_parser {
2923   my $self = shift;
2924   return $self->{datetime_parser} ||= do {
2925     $self->build_datetime_parser(@_);
2926   };
2927 }
2928
2929 =head2 datetime_parser_type
2930
2931 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2932
2933 =head2 build_datetime_parser
2934
2935 See L</datetime_parser>
2936
2937 =cut
2938
2939 sub build_datetime_parser {
2940   my $self = shift;
2941   my $type = $self->datetime_parser_type(@_);
2942   return $type;
2943 }
2944
2945
2946 =head2 is_replicating
2947
2948 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2949 replicate from a master database.  Default is undef, which is the result
2950 returned by databases that don't support replication.
2951
2952 =cut
2953
2954 sub is_replicating {
2955     return;
2956
2957 }
2958
2959 =head2 lag_behind_master
2960
2961 Returns a number that represents a certain amount of lag behind a master db
2962 when a given storage is replicating.  The number is database dependent, but
2963 starts at zero and increases with the amount of lag. Default in undef
2964
2965 =cut
2966
2967 sub lag_behind_master {
2968     return;
2969 }
2970
2971 =head2 relname_to_table_alias
2972
2973 =over 4
2974
2975 =item Arguments: $relname, $join_count
2976
2977 =item Return Value: $alias
2978
2979 =back
2980
2981 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2982 queries.
2983
2984 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2985 way these aliases are named.
2986
2987 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2988 otherwise C<"$relname">.
2989
2990 =cut
2991
2992 sub relname_to_table_alias {
2993   my ($self, $relname, $join_count) = @_;
2994
2995   my $alias = ($join_count && $join_count > 1 ?
2996     join('_', $relname, $join_count) : $relname);
2997
2998   return $alias;
2999 }
3000
3001 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3002 # version and it may be necessary to amend or override it for a specific storage
3003 # if such binds are necessary.
3004 sub _max_column_bytesize {
3005   my ($self, $attr) = @_;
3006
3007   my $max_size;
3008
3009   if ($attr->{sqlt_datatype}) {
3010     my $data_type = lc($attr->{sqlt_datatype});
3011
3012     if ($attr->{sqlt_size}) {
3013
3014       # String/sized-binary types
3015       if ($data_type =~ /^(?:
3016           l? (?:var)? char(?:acter)? (?:\s*varying)?
3017             |
3018           (?:var)? binary (?:\s*varying)?
3019             |
3020           raw
3021         )\b/x
3022       ) {
3023         $max_size = $attr->{sqlt_size};
3024       }
3025       # Other charset/unicode types, assume scale of 4
3026       elsif ($data_type =~ /^(?:
3027           national \s* character (?:\s*varying)?
3028             |
3029           nchar
3030             |
3031           univarchar
3032             |
3033           nvarchar
3034         )\b/x
3035       ) {
3036         $max_size = $attr->{sqlt_size} * 4;
3037       }
3038     }
3039
3040     if (!$max_size and !$self->_is_lob_type($data_type)) {
3041       $max_size = 100 # for all other (numeric?) datatypes
3042     }
3043   }
3044
3045   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3046 }
3047
3048 # Determine if a data_type is some type of BLOB
3049 sub _is_lob_type {
3050   my ($self, $data_type) = @_;
3051   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3052     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3053                                   |varchar|character\s*varying|nvarchar
3054                                   |national\s*character\s*varying))?\z/xi);
3055 }
3056
3057 sub _is_binary_lob_type {
3058   my ($self, $data_type) = @_;
3059   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3060     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3061 }
3062
3063 sub _is_text_lob_type {
3064   my ($self, $data_type) = @_;
3065   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3066     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3067                         |national\s*character\s*varying))\z/xi);
3068 }
3069
3070 # Determine if a data_type is some type of a binary type
3071 sub _is_binary_type {
3072   my ($self, $data_type) = @_;
3073   $data_type && ($self->_is_binary_lob_type($data_type)
3074     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3075 }
3076
3077 1;
3078
3079 =head1 USAGE NOTES
3080
3081 =head2 DBIx::Class and AutoCommit
3082
3083 DBIx::Class can do some wonderful magic with handling exceptions,
3084 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3085 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3086 transaction support.
3087
3088 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3089 in an assumed transaction between commits, and you're telling us you'd
3090 like to manage that manually.  A lot of the magic protections offered by
3091 this module will go away.  We can't protect you from exceptions due to database
3092 disconnects because we don't know anything about how to restart your
3093 transactions.  You're on your own for handling all sorts of exceptional
3094 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3095 be with raw DBI.
3096
3097
3098 =head1 AUTHOR AND CONTRIBUTORS
3099
3100 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3101
3102 =head1 LICENSE
3103
3104 You may distribute this code under the same terms as Perl itself.
3105
3106 =cut