lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(
  17   quote_sub perlstring serialize
  18   dbic_internal_try
  19   detected_reinvoked_destructor scope_guard
  20 );
  21 use namespace::clean;
  22
  23 # default cursor class, overridable in connect_info attributes
  24 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  25
  26 __PACKAGE__->mk_group_accessors('inherited' => qw/
  27   sql_limit_dialect sql_quote_char sql_name_sep
  28 /);
  29
  30 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  31
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  33 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  34
  35 __PACKAGE__->sql_name_sep('.');
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/
  38   _connect_info _dbic_connect_attributes _driver_determined
  39   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  40   _perform_autoinc_retrieval _autoinc_supplied_for_op
  41 /);
  42
  43 # the values for these accessors are picked out (and deleted) from
  44 # the attribute hashref passed to connect_info
  45 my @storage_options = qw/
  46   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  47   disable_sth_caching unsafe auto_savepoint
  48 /;
  49 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  50
  51
  52 # capability definitions, using a 2-tiered accessor system
  53 # The rationale is:
  54 #
  55 # A driver/user may define _use_X, which blindly without any checks says:
  56 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  57 # type accessor)
  58 #
  59 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  60 # accessor, which in turn calls _determine_supports_X, and stores the return
  61 # in a special slot on the storage object, which is wiped every time a $dbh
  62 # reconnection takes place (it is not guaranteed that upon reconnection we
  63 # will get the same rdbms version). _determine_supports_X does not need to
  64 # exist on a driver, as we ->can for it before calling.
  65
  66 my @capabilities = (qw/
  67   insert_returning
  68   insert_returning_bound
  69
  70   multicolumn_in
  71
  72   placeholders
  73   typeless_placeholders
  74
  75   join_optimizer
  76 /);
  77 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  78 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  79
  80 # on by default, not strictly a capability (pending rewrite)
  81 __PACKAGE__->_use_join_optimizer (1);
  82 sub _determine_supports_join_optimizer { 1 };
  83
  84 # Each of these methods need _determine_driver called before itself
  85 # in order to function reliably. We also need to separate accessors
  86 # from plain old method calls, since an accessor called as a setter
  87 # does *not* need the driver determination loop fired (and in fact
  88 # can produce hard to find bugs, like e.g. losing on_connect_*
  89 # semantics on fresh connections)
  90 #
  91 # The construct below is simply a parameterized around()
  92 my $storage_accessor_idx = { map { $_ => 1 } qw(
  93   sqlt_type
  94   datetime_parser_type
  95
  96   sql_maker
  97   cursor_class
  98 )};
  99 for my $meth (keys %$storage_accessor_idx, qw(
 100   deployment_statements
 101
 102   build_datetime_parser
 103
 104   txn_begin
 105
 106   insert
 107   update
 108   delete
 109   select
 110   select_single
 111
 112   _insert_bulk
 113
 114   with_deferred_fk_checks
 115
 116   get_use_dbms_capability
 117   get_dbms_capability
 118
 119   _server_info
 120   _get_server_version
 121 )) {
 122
 123   my $orig = __PACKAGE__->can ($meth)
 124     or die "$meth is not a ::Storage::DBI method!";
 125
 126   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 127
 128   quote_sub
 129     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 130
 131     if (
 132       # if this is an actual *setter* - just set it, no need to connect
 133       # and determine the driver
 134       !( %1$s and @_ > 1 )
 135         and
 136       # only fire when invoked on an instance, a valid class-based invocation
 137       # would e.g. be setting a default for an inherited accessor
 138       ref $_[0]
 139         and
 140       ! $_[0]->{_driver_determined}
 141         and
 142       ! $_[0]->{_in_determine_driver}
 143         and
 144       # Only try to determine stuff if we have *something* that either is or can
 145       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 146       # to still be marginally useful
 147       $_[0]->_dbi_connect_info->[0]
 148     ) {
 149       $_[0]->_determine_driver;
 150
 151       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 152       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 153
 154       my $cref = $_[0]->can(%2$s);
 155       goto $cref;
 156     }
 157
 158     goto $orig;
 159 EOC
 160 }
 161
 162 =head1 NAME
 163
 164 DBIx::Class::Storage::DBI - DBI storage handler
 165
 166 =head1 SYNOPSIS
 167
 168   my $schema = MySchema->connect('dbi:SQLite:my.db');
 169
 170   $schema->storage->debug(1);
 171
 172   my @stuff = $schema->storage->dbh_do(
 173     sub {
 174       my ($storage, $dbh, @args) = @_;
 175       $dbh->do("DROP TABLE authors");
 176     },
 177     @column_list
 178   );
 179
 180   $schema->resultset('Book')->search({
 181      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 182   });
 183
 184 =head1 DESCRIPTION
 185
 186 This class represents the connection to an RDBMS via L<DBI>.  See
 187 L<DBIx::Class::Storage> for general information.  This pod only
 188 documents DBI-specific methods and behaviors.
 189
 190 =head1 METHODS
 191
 192 =cut
 193
 194 sub new {
 195   my $new = shift->next::method(@_);
 196
 197   $new->_sql_maker_opts({});
 198   $new->_dbh_details({});
 199   $new->{_in_do_block} = 0;
 200
 201   # read below to see what this does
 202   $new->_arm_global_destructor;
 203
 204   $new;
 205 }
 206
 207 # This is hack to work around perl shooting stuff in random
 208 # order on exit(). If we do not walk the remaining storage
 209 # objects in an END block, there is a *small but real* chance
 210 # of a fork()ed child to kill the parent's shared DBI handle,
 211 # *before perl reaches the DESTROY in this package*
 212 # Yes, it is ugly and effective.
 213 # Additionally this registry is used by the CLONE method to
 214 # make sure no handles are shared between threads
 215 {
 216   my %seek_and_destroy;
 217
 218   sub _arm_global_destructor {
 219
 220     # quick "garbage collection" pass - prevents the registry
 221     # from slowly growing with a bunch of undef-valued keys
 222     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 223       for keys %seek_and_destroy;
 224
 225     weaken (
 226       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 227     );
 228   }
 229
 230   END {
 231
 232     if(
 233       ! DBIx::Class::_ENV_::BROKEN_FORK
 234         and
 235       my @instances = grep { defined $_ } values %seek_and_destroy
 236     ) {
 237       local $?; # just in case the DBI destructor changes it somehow
 238
 239       # disarm the handle if not native to this process (see comment on top)
 240       $_->_verify_pid for @instances;
 241     }
 242   }
 243
 244   sub CLONE {
 245     # As per DBI's recommendation, DBIC disconnects all handles as
 246     # soon as possible (DBIC will reconnect only on demand from within
 247     # the thread)
 248     my @instances = grep { defined $_ } values %seek_and_destroy;
 249     %seek_and_destroy = ();
 250
 251     for (@instances) {
 252       $_->_dbh(undef);
 253       $_->disconnect;
 254
 255       # properly renumber existing refs
 256       $_->_arm_global_destructor
 257     }
 258   }
 259 }
 260
 261 sub DESTROY {
 262   return if &detected_reinvoked_destructor;
 263
 264   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 265
 266   # some databases spew warnings on implicit disconnect
 267   return unless defined $_[0]->_dbh;
 268
 269   local $SIG{__WARN__} = sub {};
 270   $_[0]->_dbh(undef);
 271   # not calling ->disconnect here - we are being destroyed - nothing to reset
 272
 273   # this op is necessary, since the very last perl runtime statement
 274   # triggers a global destruction shootout, and the $SIG localization
 275   # may very well be destroyed before perl actually gets to do the
 276   # $dbh undef
 277   1;
 278 }
 279
 280 # handle pid changes correctly - do not destroy parent's connection
 281 sub _verify_pid {
 282
 283   my $pid = $_[0]->_conn_pid;
 284
 285   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 286     $dbh->{InactiveDestroy} = 1;
 287     $_[0]->_dbh(undef);
 288     $_[0]->disconnect;
 289   }
 290
 291   return;
 292 }
 293
 294 =head2 connect_info
 295
 296 This method is normally called by L<DBIx::Class::Schema/connection>, which
 297 encapsulates its argument list in an arrayref before passing them here.
 298
 299 The argument list may contain:
 300
 301 =over
 302
 303 =item *
 304
 305 The same 4-element argument set one would normally pass to
 306 L<DBI/connect>, optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes>
 308 recognized by DBIx::Class:
 309
 310   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single code reference which returns a connected
 315 L<DBI database handle|DBI/connect> optionally followed by
 316 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 317 by DBIx::Class:
 318
 319   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 320
 321 =item *
 322
 323 A single hashref with all the attributes and the dsn/user/password
 324 mixed together:
 325
 326   $connect_info_args = [{
 327     dsn => $dsn,
 328     user => $user,
 329     password => $pass,
 330     %dbi_attributes,
 331     %extra_attributes,
 332   }];
 333
 334   $connect_info_args = [{
 335     dbh_maker => sub { DBI->connect (...) },
 336     %dbi_attributes,
 337     %extra_attributes,
 338   }];
 339
 340 This is particularly useful for L<Catalyst> based applications, allowing the
 341 following config (L<Config::General> style):
 342
 343   <Model::DB>
 344     schema_class   App::DB
 345     <connect_info>
 346       dsn          dbi:mysql:database=test
 347       user         testuser
 348       password     TestPass
 349       AutoCommit   1
 350     </connect_info>
 351   </Model::DB>
 352
 353 The C<dsn>/C<user>/C<password> combination can be substituted by the
 354 C<dbh_maker> key whose value is a coderef that returns a connected
 355 L<DBI database handle|DBI/connect>
 356
 357 =back
 358
 359 Please note that the L<DBI> docs recommend that you always explicitly
 360 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 361 recommends that it be set to I<1>, and that you perform transactions
 362 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 363 to I<1> if you do not do explicitly set it to zero.  This is the default
 364 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 365
 366 =head3 DBIx::Class specific connection attributes
 367
 368 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 369 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 370 the following connection options. These options can be mixed in with your other
 371 L<DBI> connection attributes, or placed in a separate hashref
 372 (C<\%extra_attributes>) as shown above.
 373
 374 Every time C<connect_info> is invoked, any previous settings for
 375 these options will be cleared before setting the new ones, regardless of
 376 whether any options are specified in the new C<connect_info>.
 377
 378
 379 =over
 380
 381 =item on_connect_do
 382
 383 Specifies things to do immediately after connecting or re-connecting to
 384 the database.  Its value may contain:
 385
 386 =over
 387
 388 =item a scalar
 389
 390 This contains one SQL statement to execute.
 391
 392 =item an array reference
 393
 394 This contains SQL statements to execute in order.  Each element contains
 395 a string or a code reference that returns a string.
 396
 397 =item a code reference
 398
 399 This contains some code to execute.  Unlike code references within an
 400 array reference, its return value is ignored.
 401
 402 =back
 403
 404 =item on_disconnect_do
 405
 406 Takes arguments in the same form as L</on_connect_do> and executes them
 407 immediately before disconnecting from the database.
 408
 409 Note, this only runs if you explicitly call L</disconnect> on the
 410 storage object.
 411
 412 =item on_connect_call
 413
 414 A more generalized form of L</on_connect_do> that calls the specified
 415 C<connect_call_METHOD> methods in your storage driver.
 416
 417   on_connect_do => 'select 1'
 418
 419 is equivalent to:
 420
 421   on_connect_call => [ [ do_sql => 'select 1' ] ]
 422
 423 Its values may contain:
 424
 425 =over
 426
 427 =item a scalar
 428
 429 Will call the C<connect_call_METHOD> method.
 430
 431 =item a code reference
 432
 433 Will execute C<< $code->($storage) >>
 434
 435 =item an array reference
 436
 437 Each value can be a method name or code reference.
 438
 439 =item an array of arrays
 440
 441 For each array, the first item is taken to be the C<connect_call_> method name
 442 or code reference, and the rest are parameters to it.
 443
 444 =back
 445
 446 Some predefined storage methods you may use:
 447
 448 =over
 449
 450 =item do_sql
 451
 452 Executes a SQL string or a code reference that returns a SQL string. This is
 453 what L</on_connect_do> and L</on_disconnect_do> use.
 454
 455 It can take:
 456
 457 =over
 458
 459 =item a scalar
 460
 461 Will execute the scalar as SQL.
 462
 463 =item an arrayref
 464
 465 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 466 attributes hashref and bind values.
 467
 468 =item a code reference
 469
 470 Will execute C<< $code->($storage) >> and execute the return array refs as
 471 above.
 472
 473 =back
 474
 475 =item datetime_setup
 476
 477 Execute any statements necessary to initialize the database session to return
 478 and accept datetime/timestamp values used with
 479 L<DBIx::Class::InflateColumn::DateTime>.
 480
 481 Only necessary for some databases, see your specific storage driver for
 482 implementation details.
 483
 484 =back
 485
 486 =item on_disconnect_call
 487
 488 Takes arguments in the same form as L</on_connect_call> and executes them
 489 immediately before disconnecting from the database.
 490
 491 Calls the C<disconnect_call_METHOD> methods as opposed to the
 492 C<connect_call_METHOD> methods called by L</on_connect_call>.
 493
 494 Note, this only runs if you explicitly call L</disconnect> on the
 495 storage object.
 496
 497 =item disable_sth_caching
 498
 499 If set to a true value, this option will disable the caching of
 500 statement handles via L<DBI/prepare_cached>.
 501
 502 =item limit_dialect
 503
 504 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 505 default L</sql_limit_dialect> setting of the storage (if any). For a list
 506 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 507
 508 =item quote_names
 509
 510 When true automatically sets L</quote_char> and L</name_sep> to the characters
 511 appropriate for your particular RDBMS. This option is preferred over specifying
 512 L</quote_char> directly.
 513
 514 =item quote_char
 515
 516 Specifies what characters to use to quote table and column names.
 517
 518 C<quote_char> expects either a single character, in which case is it
 519 is placed on either side of the table/column name, or an arrayref of length
 520 2 in which case the table/column name is placed between the elements.
 521
 522 For example under MySQL you should use C<< quote_char => '`' >>, and for
 523 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 524
 525 =item name_sep
 526
 527 This parameter is only useful in conjunction with C<quote_char>, and is used to
 528 specify the character that separates elements (schemas, tables, columns) from
 529 each other. If unspecified it defaults to the most commonly used C<.>.
 530
 531 =item unsafe
 532
 533 This Storage driver normally installs its own C<HandleError>, sets
 534 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 535 all database handles, including those supplied by a coderef.  It does this
 536 so that it can have consistent and useful error behavior.
 537
 538 If you set this option to a true value, Storage will not do its usual
 539 modifications to the database handle's attributes, and instead relies on
 540 the settings in your connect_info DBI options (or the values you set in
 541 your connection coderef, in the case that you are connecting via coderef).
 542
 543 Note that your custom settings can cause Storage to malfunction,
 544 especially if you set a C<HandleError> handler that suppresses exceptions
 545 and/or disable C<RaiseError>.
 546
 547 =item auto_savepoint
 548
 549 If this option is true, L<DBIx::Class> will use savepoints when nesting
 550 transactions, making it possible to recover from failure in the inner
 551 transaction without having to abort all outer transactions.
 552
 553 =item cursor_class
 554
 555 Use this argument to supply a cursor class other than the default
 556 L<DBIx::Class::Storage::DBI::Cursor>.
 557
 558 =back
 559
 560 Some real-life examples of arguments to L</connect_info> and
 561 L<DBIx::Class::Schema/connect>
 562
 563   # Simple SQLite connection
 564   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 565
 566   # Connect via subref
 567   ->connect_info([ sub { DBI->connect(...) } ]);
 568
 569   # Connect via subref in hashref
 570   ->connect_info([{
 571     dbh_maker => sub { DBI->connect(...) },
 572     on_connect_do => 'alter session ...',
 573   }]);
 574
 575   # A bit more complicated
 576   ->connect_info(
 577     [
 578       'dbi:Pg:dbname=foo',
 579       'postgres',
 580       'my_pg_password',
 581       { AutoCommit => 1 },
 582       { quote_char => q{"} },
 583     ]
 584   );
 585
 586   # Equivalent to the previous example
 587   ->connect_info(
 588     [
 589       'dbi:Pg:dbname=foo',
 590       'postgres',
 591       'my_pg_password',
 592       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 593     ]
 594   );
 595
 596   # Same, but with hashref as argument
 597   # See parse_connect_info for explanation
 598   ->connect_info(
 599     [{
 600       dsn         => 'dbi:Pg:dbname=foo',
 601       user        => 'postgres',
 602       password    => 'my_pg_password',
 603       AutoCommit  => 1,
 604       quote_char  => q{"},
 605       name_sep    => q{.},
 606     }]
 607   );
 608
 609   # Subref + DBIx::Class-specific connection options
 610   ->connect_info(
 611     [
 612       sub { DBI->connect(...) },
 613       {
 614           quote_char => q{`},
 615           name_sep => q{@},
 616           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 617           disable_sth_caching => 1,
 618       },
 619     ]
 620   );
 621
 622
 623
 624 =cut
 625
 626 sub connect_info {
 627   my ($self, $info) = @_;
 628
 629   return $self->_connect_info if !$info;
 630
 631   $self->_connect_info($info); # copy for _connect_info
 632
 633   $info = $self->_normalize_connect_info($info)
 634     if ref $info eq 'ARRAY';
 635
 636   my %attrs = (
 637     %{ $self->_default_dbi_connect_attributes || {} },
 638     %{ $info->{attributes} || {} },
 639   );
 640
 641   my @args = @{ $info->{arguments} };
 642
 643   if (keys %attrs and ref $args[0] ne 'CODE') {
 644     carp_unique (
 645         'You provided explicit AutoCommit => 0 in your connection_info. '
 646       . 'This is almost universally a bad idea (see the footnotes of '
 647       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 648       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 649       . 'this warning.'
 650     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 651
 652     push @args, \%attrs if keys %attrs;
 653   }
 654
 655   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 656   # OR a single-element coderef-based $dbh factory
 657   $self->_dbi_connect_info(\@args);
 658
 659   # extract the individual storage options
 660   for my $storage_opt (keys %{ $info->{storage_options} }) {
 661     my $value = $info->{storage_options}{$storage_opt};
 662
 663     $self->$storage_opt($value);
 664   }
 665
 666   # Extract the individual sqlmaker options
 667   #
 668   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 669   #  the new set of options
 670   $self->_sql_maker(undef);
 671   $self->_sql_maker_opts({});
 672
 673   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 674     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 675
 676     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 677   }
 678
 679   # FIXME - dirty:
 680   # save attributes in a separate accessor so they are always
 681   # introspectable, even in case of a CODE $dbhmaker
 682   $self->_dbic_connect_attributes (\%attrs);
 683
 684   return $self->_connect_info;
 685 }
 686
 687 sub _dbi_connect_info {
 688   my $self = shift;
 689
 690   return $self->{_dbi_connect_info} = $_[0]
 691     if @_;
 692
 693   my $conninfo = $self->{_dbi_connect_info} || [];
 694
 695   # last ditch effort to grab a DSN
 696   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 697     my @new_conninfo = @$conninfo;
 698     $new_conninfo[0] = $ENV{DBI_DSN};
 699     $conninfo = \@new_conninfo;
 700   }
 701
 702   return $conninfo;
 703 }
 704
 705
 706 sub _normalize_connect_info {
 707   my ($self, $info_arg) = @_;
 708   my %info;
 709
 710   my @args = @$info_arg;  # take a shallow copy for further mutilation
 711
 712   # combine/pre-parse arguments depending on invocation style
 713
 714   my %attrs;
 715   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 716     %attrs = %{ $args[1] || {} };
 717     @args = $args[0];
 718   }
 719   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 720     %attrs = %{$args[0]};
 721     @args = ();
 722     if (my $code = delete $attrs{dbh_maker}) {
 723       @args = $code;
 724
 725       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 726       if (@ignored) {
 727         carp sprintf (
 728             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 729           . "to the result of 'dbh_maker'",
 730
 731           join (', ', map { "'$_'" } (@ignored) ),
 732         );
 733       }
 734     }
 735     else {
 736       @args = delete @attrs{qw/dsn user password/};
 737     }
 738   }
 739   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 740     %attrs = (
 741       % { $args[3] || {} },
 742       % { $args[4] || {} },
 743     );
 744     @args = @args[0,1,2];
 745   }
 746
 747   $info{arguments} = \@args;
 748
 749   my @storage_opts = grep exists $attrs{$_},
 750     @storage_options, 'cursor_class';
 751
 752   @{ $info{storage_options} }{@storage_opts} =
 753     delete @attrs{@storage_opts} if @storage_opts;
 754
 755   my @sql_maker_opts = grep exists $attrs{$_},
 756     qw/limit_dialect quote_char name_sep quote_names/;
 757
 758   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 759     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 760
 761   $info{attributes} = \%attrs if %attrs;
 762
 763   return \%info;
 764 }
 765
 766 sub _default_dbi_connect_attributes () {
 767   +{
 768     AutoCommit => 1,
 769     PrintError => 0,
 770     RaiseError => 1,
 771     ShowErrorStatement => 1,
 772   };
 773 }
 774
 775 =head2 on_connect_do
 776
 777 This method is deprecated in favour of setting via L</connect_info>.
 778
 779 =cut
 780
 781 =head2 on_disconnect_do
 782
 783 This method is deprecated in favour of setting via L</connect_info>.
 784
 785 =cut
 786
 787 sub _parse_connect_do {
 788   my ($self, $type) = @_;
 789
 790   my $val = $self->$type;
 791   return () if not defined $val;
 792
 793   my @res;
 794
 795   if (not ref($val)) {
 796     push @res, [ 'do_sql', $val ];
 797   } elsif (ref($val) eq 'CODE') {
 798     push @res, $val;
 799   } elsif (ref($val) eq 'ARRAY') {
 800     push @res, map { [ 'do_sql', $_ ] } @$val;
 801   } else {
 802     $self->throw_exception("Invalid type for $type: ".ref($val));
 803   }
 804
 805   return \@res;
 806 }
 807
 808 =head2 dbh_do
 809
 810 Arguments: ($subref | $method_name), @extra_coderef_args?
 811
 812 Execute the given $subref or $method_name using the new exception-based
 813 connection management.
 814
 815 The first two arguments will be the storage object that C<dbh_do> was called
 816 on and a database handle to use.  Any additional arguments will be passed
 817 verbatim to the called subref as arguments 2 and onwards.
 818
 819 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 820 exception handling and reconnection (or failover in future subclasses).
 821
 822 Your subref should have no side-effects outside of the database, as
 823 there is the potential for your subref to be partially double-executed
 824 if the database connection was stale/dysfunctional.
 825
 826 Example:
 827
 828   my @stuff = $schema->storage->dbh_do(
 829     sub {
 830       my ($storage, $dbh, @cols) = @_;
 831       my $cols = join(q{, }, @cols);
 832       $dbh->selectrow_array("SELECT $cols FROM foo");
 833     },
 834     @column_list
 835   );
 836
 837 =cut
 838
 839 sub dbh_do {
 840   my $self = shift;
 841   my $run_target = shift; # either a coderef or a method name
 842
 843   # short circuit when we know there is no need for a runner
 844   #
 845   # FIXME - assumption may be wrong
 846   # the rationale for the txn_depth check is that if this block is a part
 847   # of a larger transaction, everything up to that point is screwed anyway
 848   return $self->$run_target($self->_get_dbh, @_)
 849     if $self->{_in_do_block} or $self->transaction_depth;
 850
 851   # take a ref instead of a copy, to preserve @_ aliasing
 852   # semantics within the coderef, but only if needed
 853   # (pseudoforking doesn't like this trick much)
 854   my $args = @_ ? \@_ : [];
 855
 856   DBIx::Class::Storage::BlockRunner->new(
 857     storage => $self,
 858     wrap_txn => 0,
 859     retry_handler => sub {
 860       $_[0]->failed_attempt_count == 1
 861         and
 862       ! $_[0]->storage->connected
 863     },
 864   )->run(sub {
 865     $self->$run_target ($self->_get_dbh, @$args )
 866   });
 867 }
 868
 869 sub txn_do {
 870   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 871   shift->next::method(@_);
 872 }
 873
 874 =head2 disconnect
 875
 876 Our C<disconnect> method also performs a rollback first if the
 877 database is not in C<AutoCommit> mode.
 878
 879 =cut
 880
 881 sub disconnect {
 882   my $self = shift;
 883
 884   # this physical disconnect below might very well throw
 885   # in order to unambiguously reset the state - do the cleanup in guard
 886
 887   my $g = scope_guard {
 888
 889     {
 890       local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT;
 891       eval { $self->_dbh->disconnect };
 892     }
 893
 894     $self->_dbh(undef);
 895     $self->_dbh_details({});
 896     $self->transaction_depth(undef);
 897     $self->_dbh_autocommit(undef);
 898     $self->savepoints([]);
 899
 900     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 901     #$self->_sql_maker(undef); # this may also end up being different
 902   };
 903
 904   # FIXME FIXME FIXME
 905   # Something is wrong with CAG - it seems to delay GC in PP mode
 906   # If the below if() is changed to:
 907   #
 908   #   if( $self->_dbh ) {
 909   #
 910   # The the following will reproducibly warn as the weakref in a $txn_guard
 911   # is *NOT* deallocated by the time the $txn_guard destructor runs at
 912   # https://github.com/dbsrgits/dbix-class/blob/84efb6d7/lib/DBIx/Class/Storage/TxnScopeGuard.pm#L82
 913   #
 914   # perl -Ilib -e '
 915   #   BEGIN { warn $ENV{CAG_USE_XS} = ( time % 2 ) };
 916   #   use DBIx::Class::Schema;
 917   #   my $s = DBIx::Class::Schema->connect("dbi:SQLite::memory:");
 918   #   my $g = $s->txn_scope_guard;
 919   #   $s->storage->disconnect
 920   # '
 921   if( $self->{_dbh} ) { # do not use accessor - see above
 922
 923     $self->_do_connection_actions(disconnect_call_ => $_) for (
 924       ( $self->on_disconnect_call || () ),
 925       $self->_parse_connect_do ('on_disconnect_do')
 926     );
 927
 928     # stops the "implicit rollback on disconnect" warning
 929     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 930   }
 931 }
 932
 933 =head2 with_deferred_fk_checks
 934
 935 =over 4
 936
 937 =item Arguments: C<$coderef>
 938
 939 =item Return Value: The return value of $coderef
 940
 941 =back
 942
 943 Storage specific method to run the code ref with FK checks deferred or
 944 in MySQL's case disabled entirely.
 945
 946 =cut
 947
 948 # Storage subclasses should override this
 949 sub with_deferred_fk_checks {
 950   #my ($self, $sub) = @_;
 951   $_[1]->();
 952 }
 953
 954 =head2 connected
 955
 956 =over
 957
 958 =item Arguments: none
 959
 960 =item Return Value: 1|0
 961
 962 =back
 963
 964 Verifies that the current database handle is active and ready to execute
 965 an SQL statement (e.g. the connection did not get stale, server is still
 966 answering, etc.) This method is used internally by L</dbh>.
 967
 968 =cut
 969
 970 sub connected {
 971   return 0 unless $_[0]->_seems_connected;
 972
 973   #be on the safe side
 974   local $_[0]->_dbh->{RaiseError} = 1;
 975
 976   return $_[0]->_ping;
 977 }
 978
 979 sub _seems_connected {
 980   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 981
 982   $_[0]->_dbh
 983     and
 984   $_[0]->_dbh->FETCH('Active')
 985     and
 986   return 1;
 987
 988   # explicitly reset all state
 989   $_[0]->disconnect;
 990   return 0;
 991 }
 992
 993 sub _ping {
 994   ($_[0]->_dbh || return 0)->ping;
 995 }
 996
 997 sub ensure_connected {
 998   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 999 }
1000
1001 =head2 dbh
1002
1003 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
1004 is guaranteed to be healthy by implicitly calling L</connected>, and if
1005 necessary performing a reconnection before returning. Keep in mind that this
1006 is very B<expensive> on some database engines. Consider using L</dbh_do>
1007 instead.
1008
1009 =cut
1010
1011 sub dbh {
1012   # maybe save a ping call
1013   $_[0]->_dbh
1014     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
1015     : $_[0]->_populate_dbh
1016   ;
1017 }
1018
1019 # this is the internal "get dbh or connect (don't check)" method
1020 sub _get_dbh {
1021   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1022   $_[0]->_dbh || $_[0]->_populate_dbh;
1023 }
1024
1025 # *DELIBERATELY* not a setter (for the time being)
1026 # Too intertwined with everything else for any kind of sanity
1027 sub sql_maker {
1028   my $self = shift;
1029
1030   $self->throw_exception('sql_maker() is not a setter method') if @_;
1031
1032   unless ($self->_sql_maker) {
1033     my $sql_maker_class = $self->sql_maker_class;
1034
1035     my %opts = %{$self->_sql_maker_opts||{}};
1036     my $dialect =
1037       $opts{limit_dialect}
1038         ||
1039       $self->sql_limit_dialect
1040         ||
1041       do {
1042         my $s_class = (ref $self) || $self;
1043         carp_unique (
1044           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1045         . 'have not supplied an explicit limit_dialect in your connection_info. '
1046         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1047         . 'databases but can be (and often is) painfully slow. '
1048         . "Please file an RT ticket against '$s_class'"
1049         ) if $self->_dbi_connect_info->[0];
1050
1051         'GenericSubQ';
1052       }
1053     ;
1054
1055     my ($quote_char, $name_sep);
1056
1057     if ($opts{quote_names}) {
1058       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1059         my $s_class = (ref $self) || $self;
1060         carp_unique (
1061           "You requested 'quote_names' but your storage class ($s_class) does "
1062         . 'not explicitly define a default sql_quote_char and you have not '
1063         . 'supplied a quote_char as part of your connection_info. DBIC will '
1064         .q{default to the ANSI SQL standard quote '"', which works most of }
1065         . "the time. Please file an RT ticket against '$s_class'."
1066         );
1067
1068         '"'; # RV
1069       };
1070
1071       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1072     }
1073
1074     $self->_sql_maker($sql_maker_class->new(
1075       bindtype=>'columns',
1076       array_datatypes => 1,
1077       limit_dialect => $dialect,
1078       ($quote_char ? (quote_char => $quote_char) : ()),
1079       name_sep => ($name_sep || '.'),
1080       %opts,
1081     ));
1082   }
1083   return $self->_sql_maker;
1084 }
1085
1086 # nothing to do by default
1087 sub _rebless {}
1088 sub _init {}
1089
1090 sub _populate_dbh {
1091
1092   # reset internal states
1093   # also in case ->connected failed we might get sent here
1094   $_[0]->disconnect;
1095
1096   $_[0]->_dbh($_[0]->_connect);
1097
1098   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1099
1100   $_[0]->_determine_driver;
1101
1102   # Always set the transaction depth on connect, since
1103   #  there is no transaction in progress by definition
1104   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1105
1106   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1107
1108   $_[0]->_dbh;
1109 }
1110
1111 sub _run_connection_actions {
1112
1113   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1114     ( $_[0]->on_connect_call || () ),
1115     $_[0]->_parse_connect_do ('on_connect_do'),
1116   );
1117 }
1118
1119
1120
1121 sub set_use_dbms_capability {
1122   $_[0]->set_inherited ($_[1], $_[2]);
1123 }
1124
1125 sub get_use_dbms_capability {
1126   my ($self, $capname) = @_;
1127
1128   my $use = $self->get_inherited ($capname);
1129   return defined $use
1130     ? $use
1131     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1132   ;
1133 }
1134
1135 sub set_dbms_capability {
1136   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1137 }
1138
1139 sub get_dbms_capability {
1140   my ($self, $capname) = @_;
1141
1142   my $cap = $self->_dbh_details->{capability}{$capname};
1143
1144   unless (defined $cap) {
1145     if (my $meth = $self->can ("_determine$capname")) {
1146       $cap = $self->$meth ? 1 : 0;
1147     }
1148     else {
1149       $cap = 0;
1150     }
1151
1152     $self->set_dbms_capability ($capname, $cap);
1153   }
1154
1155   return $cap;
1156 }
1157
1158 sub _server_info {
1159   my $self = shift;
1160
1161   # FIXME - ideally this needs to be an ||= assignment, and the final
1162   # assignment at the end of this do{} should be gone entirely. However
1163   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1164   $self->_dbh_details->{info} || do {
1165
1166     # this guarantees that problematic conninfo won't be hidden
1167     # by the try{} below
1168     $self->ensure_connected;
1169
1170     my $info = {};
1171
1172     my $server_version = dbic_internal_try {
1173       $self->_get_server_version
1174     } catch {
1175       # driver determination *may* use this codepath
1176       # in which case we must rethrow
1177       $self->throw_exception($_) if $self->{_in_determine_driver};
1178
1179       # $server_version on failure
1180       undef;
1181     };
1182
1183     if (defined $server_version) {
1184       $info->{dbms_version} = $server_version;
1185
1186       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1187       my @verparts = split (/\./, $numeric_version);
1188       if (
1189         @verparts
1190           &&
1191         $verparts[0] <= 999
1192       ) {
1193         # consider only up to 3 version parts, iff not more than 3 digits
1194         my @use_parts;
1195         while (@verparts && @use_parts < 3) {
1196           my $p = shift @verparts;
1197           last if $p > 999;
1198           push @use_parts, $p;
1199         }
1200         push @use_parts, 0 while @use_parts < 3;
1201
1202         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1203       }
1204     }
1205
1206     $self->_dbh_details->{info} = $info;
1207   };
1208 }
1209
1210 sub _get_server_version {
1211   shift->_dbh_get_info('SQL_DBMS_VER');
1212 }
1213
1214 sub _dbh_get_info {
1215   my ($self, $info) = @_;
1216
1217   if ($info =~ /[^0-9]/) {
1218     require DBI::Const::GetInfoType;
1219     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1220     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1221       unless defined $info;
1222   }
1223
1224   $self->_get_dbh->get_info($info);
1225 }
1226
1227 sub _describe_connection {
1228   require DBI::Const::GetInfoReturn;
1229
1230   my $self = shift;
1231
1232   my $drv;
1233   dbic_internal_try {
1234     $drv = $self->_extract_driver_from_connect_info;
1235     $self->ensure_connected;
1236   };
1237
1238   $drv = "DBD::$drv" if $drv;
1239
1240   my $res = {
1241     DBIC_DSN => $self->_dbi_connect_info->[0],
1242     DBI_VER => DBI->VERSION,
1243     DBIC_VER => DBIx::Class->VERSION,
1244     DBIC_DRIVER => ref $self,
1245     $drv ? (
1246       DBD => $drv,
1247       DBD_VER => dbic_internal_try { $drv->VERSION },
1248     ) : (),
1249   };
1250
1251   # try to grab data even if we never managed to connect
1252   # will cover us in cases of an oddly broken half-connect
1253   for my $inf (
1254     #keys %DBI::Const::GetInfoType::GetInfoType,
1255     qw/
1256       SQL_CURSOR_COMMIT_BEHAVIOR
1257       SQL_CURSOR_ROLLBACK_BEHAVIOR
1258       SQL_CURSOR_SENSITIVITY
1259       SQL_DATA_SOURCE_NAME
1260       SQL_DBMS_NAME
1261       SQL_DBMS_VER
1262       SQL_DEFAULT_TXN_ISOLATION
1263       SQL_DM_VER
1264       SQL_DRIVER_NAME
1265       SQL_DRIVER_ODBC_VER
1266       SQL_DRIVER_VER
1267       SQL_EXPRESSIONS_IN_ORDERBY
1268       SQL_GROUP_BY
1269       SQL_IDENTIFIER_CASE
1270       SQL_IDENTIFIER_QUOTE_CHAR
1271       SQL_MAX_CATALOG_NAME_LEN
1272       SQL_MAX_COLUMN_NAME_LEN
1273       SQL_MAX_IDENTIFIER_LEN
1274       SQL_MAX_TABLE_NAME_LEN
1275       SQL_MULTIPLE_ACTIVE_TXN
1276       SQL_MULT_RESULT_SETS
1277       SQL_NEED_LONG_DATA_LEN
1278       SQL_NON_NULLABLE_COLUMNS
1279       SQL_ODBC_VER
1280       SQL_QUALIFIER_NAME_SEPARATOR
1281       SQL_QUOTED_IDENTIFIER_CASE
1282       SQL_TXN_CAPABLE
1283       SQL_TXN_ISOLATION_OPTION
1284     /
1285   ) {
1286     # some drivers barf on things they do not know about instead
1287     # of returning undef
1288     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1289     next unless defined $v;
1290
1291     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1292     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1293     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1294   }
1295
1296   $res;
1297 }
1298
1299 sub _determine_driver {
1300   my ($self) = @_;
1301
1302   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1303     my $started_connected = 0;
1304     local $self->{_in_determine_driver} = 1;
1305
1306     if (ref($self) eq __PACKAGE__) {
1307       my $driver;
1308       if ($self->_dbh) { # we are connected
1309         $driver = $self->_dbh->{Driver}{Name};
1310         $started_connected = 1;
1311       }
1312       else {
1313         $driver = $self->_extract_driver_from_connect_info;
1314       }
1315
1316       if ($driver) {
1317         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1318         if ($self->load_optional_class($storage_class)) {
1319           mro::set_mro($storage_class, 'c3');
1320           bless $self, $storage_class;
1321           $self->_rebless();
1322         }
1323         else {
1324           $self->_warn_undetermined_driver(
1325             'This version of DBIC does not yet seem to supply a driver for '
1326           . "your particular RDBMS and/or connection method ('$driver')."
1327           );
1328         }
1329       }
1330       else {
1331         $self->_warn_undetermined_driver(
1332           'Unable to extract a driver name from connect info - this '
1333         . 'should not have happened.'
1334         );
1335       }
1336     }
1337
1338     $self->_driver_determined(1);
1339
1340     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1341
1342     if ($self->can('source_bind_attributes')) {
1343       $self->throw_exception(
1344         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1345       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1346       . 'If you are not sure how to proceed please contact the development team via '
1347       . DBIx::Class::_ENV_::HELP_URL
1348       );
1349     }
1350
1351     $self->_init; # run driver-specific initializations
1352
1353     $self->_run_connection_actions
1354         if !$started_connected && defined $self->_dbh;
1355   }
1356 }
1357
1358 sub _extract_driver_from_connect_info {
1359   my $self = shift;
1360
1361   my $drv;
1362
1363   # if connect_info is a CODEREF, we have no choice but to connect
1364   if (
1365     ref $self->_dbi_connect_info->[0]
1366       and
1367     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1368   ) {
1369     $self->_populate_dbh;
1370     $drv = $self->_dbh->{Driver}{Name};
1371   }
1372   else {
1373     # try to use dsn to not require being connected, the driver may still
1374     # force a connection later in _rebless to determine version
1375     # (dsn may not be supplied at all if all we do is make a mock-schema)
1376     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1377     $drv ||= $ENV{DBI_DRIVER};
1378   }
1379
1380   return $drv;
1381 }
1382
1383 sub _determine_connector_driver {
1384   my ($self, $conn) = @_;
1385
1386   my $dbtype = $self->_get_rdbms_name;
1387
1388   if (not $dbtype) {
1389     $self->_warn_undetermined_driver(
1390       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1391     . "$conn connector - this should not have happened."
1392     );
1393     return;
1394   }
1395
1396   $dbtype =~ s/\W/_/gi;
1397
1398   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1399   return if $self->isa($subclass);
1400
1401   if ($self->load_optional_class($subclass)) {
1402     bless $self, $subclass;
1403     $self->_rebless;
1404   }
1405   else {
1406     $self->_warn_undetermined_driver(
1407       'This version of DBIC does not yet seem to supply a driver for '
1408     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1409     );
1410   }
1411 }
1412
1413 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1414
1415 sub _warn_undetermined_driver {
1416   my ($self, $msg) = @_;
1417
1418   require Data::Dumper::Concise;
1419
1420   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1421   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1422   . "does not go away, file a bugreport including the following info:\n"
1423   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1424   );
1425 }
1426
1427 sub _do_connection_actions {
1428   my ($self, $method_prefix, $call, @args) = @_;
1429
1430   dbic_internal_try {
1431     if (not ref($call)) {
1432       my $method = $method_prefix . $call;
1433       $self->$method(@args);
1434     }
1435     elsif (ref($call) eq 'CODE') {
1436       $self->$call(@args);
1437     }
1438     elsif (ref($call) eq 'ARRAY') {
1439       if (ref($call->[0]) ne 'ARRAY') {
1440         $self->_do_connection_actions($method_prefix, $_) for @$call;
1441       }
1442       else {
1443         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1444       }
1445     }
1446     else {
1447       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1448     }
1449   }
1450   catch {
1451     if ( $method_prefix =~ /^connect/ ) {
1452       # this is an on_connect cycle - we can't just throw while leaving
1453       # a handle in an undefined state in our storage object
1454       # kill it with fire and rethrow
1455       $self->_dbh(undef);
1456       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1457       $self->throw_exception( $_[0] );
1458     }
1459     else {
1460       carp "Disconnect action failed: $_[0]";
1461     }
1462   };
1463
1464   return $self;
1465 }
1466
1467 sub connect_call_do_sql {
1468   my $self = shift;
1469   $self->_do_query(@_);
1470 }
1471
1472 sub disconnect_call_do_sql {
1473   my $self = shift;
1474   $self->_do_query(@_);
1475 }
1476
1477 =head2 connect_call_datetime_setup
1478
1479 A no-op stub method, provided so that one can always safely supply the
1480 L<connection option|/DBIx::Class specific connection attributes>
1481
1482  on_connect_call => 'datetime_setup'
1483
1484 This way one does not need to know in advance whether the underlying
1485 storage requires any sort of hand-holding when dealing with calendar
1486 data.
1487
1488 =cut
1489
1490 sub connect_call_datetime_setup { 1 }
1491
1492 sub _do_query {
1493   my ($self, $action) = @_;
1494
1495   if (ref $action eq 'CODE') {
1496     $action = $action->($self);
1497     $self->_do_query($_) foreach @$action;
1498   }
1499   else {
1500     # Most debuggers expect ($sql, @bind), so we need to exclude
1501     # the attribute hash which is the second argument to $dbh->do
1502     # furthermore the bind values are usually to be presented
1503     # as named arrayref pairs, so wrap those here too
1504     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1505     my $sql = shift @do_args;
1506     my $attrs = shift @do_args;
1507     my @bind = map { [ undef, $_ ] } @do_args;
1508
1509     $self->dbh_do(sub {
1510       $_[0]->_query_start($sql, \@bind);
1511       $_[1]->do($sql, $attrs, @do_args);
1512       $_[0]->_query_end($sql, \@bind);
1513     });
1514   }
1515
1516   return $self;
1517 }
1518
1519 sub _connect {
1520   my $self = shift;
1521
1522   my $info = $self->_dbi_connect_info;
1523
1524   $self->throw_exception("You did not provide any connection_info")
1525     unless defined $info->[0];
1526
1527   my ($old_connect_via, $dbh);
1528
1529   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1530
1531   # this odd anonymous coderef dereference is in fact really
1532   # necessary to avoid the unwanted effect described in perl5
1533   # RT#75792
1534   #
1535   # in addition the coderef itself can't reside inside the try{} block below
1536   # as it somehow triggers a leak under perl -d
1537   my $dbh_error_handler_installer = sub {
1538     weaken (my $weak_self = $_[0]);
1539
1540     # the coderef is blessed so we can distinguish it from externally
1541     # supplied handles (which must be preserved)
1542     $_[1]->{HandleError} = bless sub {
1543       if ($weak_self) {
1544         $weak_self->throw_exception("DBI Exception: $_[0]");
1545       }
1546       else {
1547         # the handler may be invoked by something totally out of
1548         # the scope of DBIC
1549         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1550       }
1551     }, '__DBIC__DBH__ERROR__HANDLER__';
1552   };
1553
1554   dbic_internal_try {
1555     if(ref $info->[0] eq 'CODE') {
1556       $dbh = $info->[0]->();
1557     }
1558     else {
1559       require DBI;
1560       $dbh = DBI->connect(@$info);
1561     }
1562
1563     die $DBI::errstr unless $dbh;
1564
1565     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1566       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1567       . 'not continue',
1568       ref $info->[0] eq 'CODE'
1569         ? "Connection coderef $info->[0] returned a"
1570         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1571     ) unless $dbh->FETCH('Active');
1572
1573     # sanity checks unless asked otherwise
1574     unless ($self->unsafe) {
1575
1576       $self->throw_exception(
1577         'Refusing clobbering of {HandleError} installed on externally supplied '
1578        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1579       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1580
1581       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1582       # request, or an external handle. Complain and set anyway
1583       unless ($dbh->{RaiseError}) {
1584         carp( ref $info->[0] eq 'CODE'
1585
1586           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1587            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1588            .'attribute has been supplied'
1589
1590           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1591            .'unsafe => 1. Toggling RaiseError back to true'
1592         );
1593
1594         $dbh->{RaiseError} = 1;
1595       }
1596
1597       $dbh_error_handler_installer->($self, $dbh);
1598     }
1599   }
1600   catch {
1601     $self->throw_exception("DBI Connection failed: $_")
1602   };
1603
1604   $self->_dbh_autocommit($dbh->{AutoCommit});
1605   return $dbh;
1606 }
1607
1608 sub txn_begin {
1609   # this means we have not yet connected and do not know the AC status
1610   # (e.g. coderef $dbh), need a full-fledged connection check
1611   if (! defined $_[0]->_dbh_autocommit) {
1612     $_[0]->ensure_connected;
1613   }
1614   # Otherwise simply connect or re-connect on pid changes
1615   else {
1616     $_[0]->_get_dbh;
1617   }
1618
1619   shift->next::method(@_);
1620 }
1621
1622 sub _exec_txn_begin {
1623   my $self = shift;
1624
1625   # if the user is utilizing txn_do - good for him, otherwise we need to
1626   # ensure that the $dbh is healthy on BEGIN.
1627   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1628   # will be replaced by a failure of begin_work itself (which will be
1629   # then retried on reconnect)
1630   if ($self->{_in_do_block}) {
1631     $self->_dbh->begin_work;
1632   } else {
1633     $self->dbh_do(sub { $_[1]->begin_work });
1634   }
1635 }
1636
1637 sub txn_commit {
1638   my $self = shift;
1639
1640   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1641     unless $self->_seems_connected;
1642
1643   # esoteric case for folks using external $dbh handles
1644   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1645     carp "Storage transaction_depth 0 does not match "
1646         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1647     $self->transaction_depth(1);
1648   }
1649
1650   $self->next::method(@_);
1651
1652   # if AutoCommit is disabled txn_depth never goes to 0
1653   # as a new txn is started immediately on commit
1654   $self->transaction_depth(1) if (
1655     !$self->transaction_depth
1656       and
1657     defined $self->_dbh_autocommit
1658       and
1659     ! $self->_dbh_autocommit
1660   );
1661 }
1662
1663 sub _exec_txn_commit {
1664   shift->_dbh->commit;
1665 }
1666
1667 sub txn_rollback {
1668   my $self = shift;
1669
1670   # do a minimal connectivity check due to weird shit like
1671   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1672   $self->throw_exception("lost connection to storage")
1673     unless $self->_seems_connected;
1674
1675   # esoteric case for folks using external $dbh handles
1676   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1677     carp "Storage transaction_depth 0 does not match "
1678         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1679     $self->transaction_depth(1);
1680   }
1681
1682   $self->next::method(@_);
1683
1684   # if AutoCommit is disabled txn_depth never goes to 0
1685   # as a new txn is started immediately on commit
1686   $self->transaction_depth(1) if (
1687     !$self->transaction_depth
1688       and
1689     defined $self->_dbh_autocommit
1690       and
1691     ! $self->_dbh_autocommit
1692   );
1693 }
1694
1695 sub _exec_txn_rollback {
1696   shift->_dbh->rollback;
1697 }
1698
1699 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1700 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1701   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1702     unless $_[0]->_seems_connected;
1703   shift->next::method(@_);
1704 EOS
1705
1706 # This used to be the top-half of _execute.  It was split out to make it
1707 #  easier to override in NoBindVars without duping the rest.  It takes up
1708 #  all of _execute's args, and emits $sql, @bind.
1709 sub _prep_for_execute {
1710   #my ($self, $op, $ident, $args) = @_;
1711   return shift->_gen_sql_bind(@_)
1712 }
1713
1714 sub _gen_sql_bind {
1715   my ($self, $op, $ident, $args) = @_;
1716
1717   my ($colinfos, $from);
1718   if ( blessed($ident) ) {
1719     $from = $ident->from;
1720     $colinfos = $ident->columns_info;
1721   }
1722
1723   my ($sql, $bind);
1724   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1725
1726   $bind = $self->_resolve_bindattrs(
1727     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1728   );
1729
1730   if (
1731     ! $ENV{DBIC_DT_SEARCH_OK}
1732       and
1733     $op eq 'select'
1734       and
1735     first {
1736       length ref $_->[1]
1737         and
1738       blessed($_->[1])
1739         and
1740       $_->[1]->isa('DateTime')
1741     } @$bind
1742   ) {
1743     carp_unique 'DateTime objects passed to search() are not supported '
1744       . 'properly (InflateColumn::DateTime formats and settings are not '
1745       . 'respected.) See ".. format a DateTime object for searching?" in '
1746       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1747       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1748   }
1749
1750   return( $sql, $bind );
1751 }
1752
1753 sub _resolve_bindattrs {
1754   my ($self, $ident, $bind, $colinfos) = @_;
1755
1756   my $resolve_bindinfo = sub {
1757     #my $infohash = shift;
1758
1759     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1760
1761     my $ret;
1762     if (my $col = $_[0]->{dbic_colname}) {
1763       $ret = { %{$_[0]} };
1764
1765       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1766         if $colinfos->{$col}{data_type};
1767
1768       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1769         if $colinfos->{$col}{size};
1770     }
1771
1772     $ret || $_[0];
1773   };
1774
1775   return [ map {
1776       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1777     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1778     : (ref $_->[0] eq 'HASH')           ? [(
1779                                             ! keys %{$_->[0]}
1780                                               or
1781                                             exists $_->[0]{dbd_attrs}
1782                                               or
1783                                             $_->[0]{sqlt_datatype}
1784                                            ) ? $_->[0]
1785                                              : $resolve_bindinfo->($_->[0])
1786                                            , $_->[1]
1787                                           ]
1788     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1789     :                                     [ $resolve_bindinfo->(
1790                                               { dbic_colname => $_->[0] }
1791                                             ), $_->[1] ]
1792   } @$bind ];
1793 }
1794
1795 sub _format_for_trace {
1796   #my ($self, $bind) = @_;
1797
1798   ### Turn @bind from something like this:
1799   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1800   ### to this:
1801   ###   ( "'1'", "'3'" )
1802
1803   map {
1804     defined( $_ && $_->[1] )
1805       ? qq{'$_->[1]'}
1806       : q{NULL}
1807   } @{$_[1] || []};
1808 }
1809
1810 sub _query_start {
1811   my ( $self, $sql, $bind ) = @_;
1812
1813   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1814     if $self->debug;
1815 }
1816
1817 sub _query_end {
1818   my ( $self, $sql, $bind ) = @_;
1819
1820   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1821     if $self->debug;
1822 }
1823
1824 sub _dbi_attrs_for_bind {
1825   #my ($self, $ident, $bind) = @_;
1826
1827   return [ map {
1828
1829     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1830
1831   : ! $_->{sqlt_datatype}   ? undef
1832
1833   :                           do {
1834
1835     # cache the result in the dbh_details hash, as it (usually) can not change
1836     # unless we connect to something else
1837     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1838     # the LOB storage
1839     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1840
1841     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1842       if ! exists $cache->{$_->{sqlt_datatype}};
1843
1844     $cache->{$_->{sqlt_datatype}};
1845
1846   } } map { $_->[0] } @{$_[2]} ];
1847 }
1848
1849 sub _execute {
1850   my ($self, $op, $ident, @args) = @_;
1851
1852   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1853
1854   # not even a PID check - we do not care about the state of the _dbh.
1855   # All we need is to get the appropriate drivers loaded if they aren't
1856   # already so that the assumption in ad7c50fc26e holds
1857   $self->_populate_dbh unless $self->_dbh;
1858
1859   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1860     $sql,
1861     $bind,
1862     $self->_dbi_attrs_for_bind($ident, $bind),
1863   );
1864 }
1865
1866 sub _dbh_execute {
1867   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1868
1869   $self->_query_start( $sql, $bind );
1870
1871   my $sth = $self->_bind_sth_params(
1872     $self->_prepare_sth($dbh, $sql),
1873     $bind,
1874     $bind_attrs,
1875   );
1876
1877   # Can this fail without throwing an exception anyways???
1878   my $rv = $sth->execute();
1879   $self->throw_exception(
1880     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1881   ) if !$rv;
1882
1883   $self->_query_end( $sql, $bind );
1884
1885   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1886 }
1887
1888 sub _prepare_sth {
1889   my ($self, $dbh, $sql) = @_;
1890
1891   # 3 is the if_active parameter which avoids active sth re-use
1892   my $sth = $self->disable_sth_caching
1893     ? $dbh->prepare($sql)
1894     : $dbh->prepare_cached($sql, {}, 3);
1895
1896   # XXX You would think RaiseError would make this impossible,
1897   #  but apparently that's not true :(
1898   $self->throw_exception(
1899     $dbh->errstr
1900       ||
1901     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1902             .'an exception and/or setting $dbh->errstr',
1903       length ($sql) > 20
1904         ? substr($sql, 0, 20) . '...'
1905         : $sql
1906       ,
1907       'DBD::' . $dbh->{Driver}{Name},
1908     )
1909   ) if !$sth;
1910
1911   $sth;
1912 }
1913
1914 sub _bind_sth_params {
1915   my ($self, $sth, $bind, $bind_attrs) = @_;
1916
1917   for my $i (0 .. $#$bind) {
1918     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1919       $sth->bind_param_inout(
1920         $i + 1, # bind params counts are 1-based
1921         $bind->[$i][1],
1922         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1923         $bind_attrs->[$i],
1924       );
1925     }
1926     else {
1927       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1928       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1929         ? "$bind->[$i][1]"
1930         : $bind->[$i][1]
1931       ;
1932
1933       $sth->bind_param(
1934         $i + 1,
1935         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1936         $v,
1937         $bind_attrs->[$i],
1938       );
1939     }
1940   }
1941
1942   $sth;
1943 }
1944
1945 sub _prefetch_autovalues {
1946   my ($self, $source, $colinfo, $to_insert) = @_;
1947
1948   my %values;
1949   for my $col (keys %$colinfo) {
1950     if (
1951       $colinfo->{$col}{auto_nextval}
1952         and
1953       (
1954         ! exists $to_insert->{$col}
1955           or
1956         is_literal_value($to_insert->{$col})
1957       )
1958     ) {
1959       $values{$col} = $self->_sequence_fetch(
1960         'NEXTVAL',
1961         ( $colinfo->{$col}{sequence} ||=
1962             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1963         ),
1964       );
1965     }
1966   }
1967
1968   \%values;
1969 }
1970
1971 sub insert {
1972   my ($self, $source, $to_insert) = @_;
1973
1974   my $col_infos = $source->columns_info;
1975
1976   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1977
1978   # fuse the values, but keep a separate list of prefetched_values so that
1979   # they can be fused once again with the final return
1980   $to_insert = { %$to_insert, %$prefetched_values };
1981
1982   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1983   # Investigate what does it take to s/defined/exists/
1984   my %pcols = map { $_ => 1 } $source->primary_columns;
1985   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1986   for my $col ($source->columns) {
1987     if ($col_infos->{$col}{is_auto_increment}) {
1988       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1989       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1990     }
1991
1992     # nothing to retrieve when explicit values are supplied
1993     next if (
1994       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1995     );
1996
1997     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1998     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1999       $pcols{$col}
2000         or
2001       $col_infos->{$col}{retrieve_on_insert}
2002     );
2003   };
2004
2005   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
2006   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
2007
2008   my ($sqla_opts, @ir_container);
2009   if (%retrieve_cols and $self->_use_insert_returning) {
2010     $sqla_opts->{returning_container} = \@ir_container
2011       if $self->_use_insert_returning_bound;
2012
2013     $sqla_opts->{returning} = [
2014       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
2015     ];
2016   }
2017
2018   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2019
2020   my %returned_cols = %$to_insert;
2021   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2022
2023     unless( @ir_container ) {
2024       dbic_internal_try {
2025
2026         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2027         local $SIG{__WARN__} = sub {};
2028
2029         @ir_container = $sth->fetchrow_array;
2030         $sth->finish;
2031
2032       } catch {
2033         # Evict the $sth from the cache in case we got here, since the finish()
2034         # is crucial, at least on older Firebirds, possibly on other engines too
2035         #
2036         # It would be too complex to make this a proper subclass override,
2037         # and besides we already take the try{} penalty, adding a catch that
2038         # triggers infrequently is a no-brainer
2039         #
2040         if( my $kids = $self->_dbh->{CachedKids} ) {
2041           $kids->{$_} == $sth and delete $kids->{$_}
2042             for keys %$kids
2043         }
2044       };
2045     }
2046
2047     @returned_cols{@$retlist} = @ir_container if @ir_container;
2048   }
2049   else {
2050     # pull in PK if needed and then everything else
2051     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2052
2053       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2054         unless $self->can('last_insert_id');
2055
2056       my @pri_values = $self->last_insert_id($source, @missing_pri);
2057
2058       $self->throw_exception( "Can't get last insert id" )
2059         unless (@pri_values == @missing_pri);
2060
2061       @returned_cols{@missing_pri} = @pri_values;
2062       delete @retrieve_cols{@missing_pri};
2063     }
2064
2065     # if there is more left to pull
2066     if (%retrieve_cols) {
2067       $self->throw_exception(
2068         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2069       ) unless %pcols;
2070
2071       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2072
2073       my $cur = DBIx::Class::ResultSet->new($source, {
2074         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2075         select => \@left_to_fetch,
2076       })->cursor;
2077
2078       @returned_cols{@left_to_fetch} = $cur->next;
2079
2080       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2081         if scalar $cur->next;
2082     }
2083   }
2084
2085   return { %$prefetched_values, %returned_cols };
2086 }
2087
2088 sub insert_bulk {
2089   carp_unique(
2090     'insert_bulk() should have never been exposed as a public method and '
2091   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2092   . 'use for this method please contact the development team via '
2093   . DBIx::Class::_ENV_::HELP_URL
2094   );
2095
2096   return '0E0' unless @{$_[3]||[]};
2097
2098   shift->_insert_bulk(@_);
2099 }
2100
2101 sub _insert_bulk {
2102   my ($self, $source, $cols, $data) = @_;
2103
2104   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2105     unless @{$data||[]};
2106
2107   my $colinfos = $source->columns_info($cols);
2108
2109   local $self->{_autoinc_supplied_for_op} =
2110     (grep { $_->{is_auto_increment} } values %$colinfos)
2111       ? 1
2112       : 0
2113   ;
2114
2115   # get a slice type index based on first row of data
2116   # a "column" in this context may refer to more than one bind value
2117   # e.g. \[ '?, ?', [...], [...] ]
2118   #
2119   # construct the value type index - a description of values types for every
2120   # per-column slice of $data:
2121   #
2122   # nonexistent - nonbind literal
2123   # 0 - regular value
2124   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2125   #
2126   # also construct the column hash to pass to the SQL generator. For plain
2127   # (non literal) values - convert the members of the first row into a
2128   # literal+bind combo, with extra positional info in the bind attr hashref.
2129   # This will allow us to match the order properly, and is so contrived
2130   # because a user-supplied literal/bind (or something else specific to a
2131   # resultsource and/or storage driver) can inject extra binds along the
2132   # way, so one can't rely on "shift positions" ordering at all. Also we
2133   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2134   # can be later matched up by address), because we want to supply a real
2135   # value on which perhaps e.g. datatype checks will be performed
2136   my ($proto_data, $serialized_bind_type_by_col_idx);
2137   for my $col_idx (0..$#$cols) {
2138     my $colname = $cols->[$col_idx];
2139     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2140       # no bind value at all - no type
2141
2142       $proto_data->{$colname} = $data->[0][$col_idx];
2143     }
2144     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2145       # repack, so we don't end up mangling the original \[]
2146       my ($sql, @bind) = @${$data->[0][$col_idx]};
2147
2148       # normalization of user supplied stuff
2149       my $resolved_bind = $self->_resolve_bindattrs(
2150         $source, \@bind, $colinfos,
2151       );
2152
2153       # store value-less (attrs only) bind info - we will be comparing all
2154       # supplied binds against this for sanity
2155       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2156
2157       $proto_data->{$colname} = \[ $sql, map { [
2158         # inject slice order to use for $proto_bind construction
2159           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2160             =>
2161           $resolved_bind->[$_][1]
2162         ] } (0 .. $#bind)
2163       ];
2164     }
2165     else {
2166       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2167
2168       $proto_data->{$colname} = \[ '?', [
2169         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2170           =>
2171         $data->[0][$col_idx]
2172       ] ];
2173     }
2174   }
2175
2176   my ($sql, $proto_bind) = $self->_prep_for_execute (
2177     'insert',
2178     $source,
2179     [ $proto_data ],
2180   );
2181
2182   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2183     # if the bindlist is empty and we had some dynamic binds, this means the
2184     # storage ate them away (e.g. the NoBindVars component) and interpolated
2185     # them directly into the SQL. This obviously can't be good for multi-inserts
2186     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2187   }
2188
2189   # sanity checks
2190   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2191   #
2192   # use an error reporting closure for convenience (less to pass)
2193   my $bad_slice_report_cref = sub {
2194     my ($msg, $r_idx, $c_idx) = @_;
2195     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2196       $msg,
2197       $cols->[$c_idx],
2198       do {
2199         require Data::Dumper::Concise;
2200         local $Data::Dumper::Maxdepth = 5;
2201         Data::Dumper::Concise::Dumper ({
2202           map { $cols->[$_] =>
2203             $data->[$r_idx][$_]
2204           } 0..$#$cols
2205         }),
2206       }
2207     );
2208   };
2209
2210   for my $col_idx (0..$#$cols) {
2211     my $reference_val = $data->[0][$col_idx];
2212
2213     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2214       my $val = $data->[$row_idx][$col_idx];
2215
2216       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2217         if (ref $val ne 'SCALAR') {
2218           $bad_slice_report_cref->(
2219             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2220             $row_idx,
2221             $col_idx,
2222           );
2223         }
2224         elsif ($$val ne $$reference_val) {
2225           $bad_slice_report_cref->(
2226             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2227             $row_idx,
2228             $col_idx,
2229           );
2230         }
2231       }
2232       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2233         if (is_literal_value($val)) {
2234           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2235         }
2236       }
2237       else {  # binds from a \[], compare type and attrs
2238         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2239           $bad_slice_report_cref->(
2240             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2241             $row_idx,
2242             $col_idx,
2243           );
2244         }
2245         # start drilling down and bail out early on identical refs
2246         elsif (
2247           $reference_val != $val
2248             or
2249           $$reference_val != $$val
2250         ) {
2251           if (${$val}->[0] ne ${$reference_val}->[0]) {
2252             $bad_slice_report_cref->(
2253               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2254               $row_idx,
2255               $col_idx,
2256             );
2257           }
2258           # need to check the bind attrs - a bind will happen only once for
2259           # the entire dataset, so any changes further down will be ignored.
2260           elsif (
2261             $serialized_bind_type_by_col_idx->{$col_idx}
2262               ne
2263             serialize [
2264               map
2265               { $_->[0] }
2266               @{$self->_resolve_bindattrs(
2267                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2268               )}
2269             ]
2270           ) {
2271             $bad_slice_report_cref->(
2272               'Differing bind attributes on literal/bind values not supported',
2273               $row_idx,
2274               $col_idx,
2275             );
2276           }
2277         }
2278       }
2279     }
2280   }
2281
2282   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2283   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2284   # scope guard
2285   my $guard = $self->txn_scope_guard;
2286
2287   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2288   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2289   my $rv = do {
2290     if (@$proto_bind) {
2291       # proto bind contains the information on which pieces of $data to pull
2292       # $cols is passed in only for prettier error-reporting
2293       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2294     }
2295     else {
2296       # bind_param_array doesn't work if there are no binds
2297       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2298     }
2299   };
2300
2301   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2302
2303   $guard->commit;
2304
2305   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2306 }
2307
2308 # execute_for_fetch is capable of returning data just fine (it means it
2309 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2310 # is the void-populate fast-path we will just ignore this altogether
2311 # for the time being.
2312 sub _dbh_execute_for_fetch {
2313   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2314
2315   # If we have any bind attributes to take care of, we will bind the
2316   # proto-bind data (which will never be used by execute_for_fetch)
2317   # However since column bindtypes are "sticky", this is sufficient
2318   # to get the DBD to apply the bindtype to all values later on
2319   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2320
2321   for my $i (0 .. $#$proto_bind) {
2322     $sth->bind_param (
2323       $i+1, # DBI bind indexes are 1-based
2324       $proto_bind->[$i][1],
2325       $bind_attrs->[$i],
2326     ) if defined $bind_attrs->[$i];
2327   }
2328
2329   # At this point $data slots named in the _bind_data_slice_idx of
2330   # each piece of $proto_bind are either \[]s or plain values to be
2331   # passed in. Construct the dispensing coderef. *NOTE* the order
2332   # of $data will differ from this of the ?s in the SQL (due to
2333   # alphabetical ordering by colname). We actually do want to
2334   # preserve this behavior so that prepare_cached has a better
2335   # chance of matching on unrelated calls
2336
2337   my $fetch_row_idx = -1; # saner loop this way
2338   my $fetch_tuple = sub {
2339     return undef if ++$fetch_row_idx > $#$data;
2340
2341     return [ map {
2342       my $v = ! defined $_->{_literal_bind_subindex}
2343
2344         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2345
2346         # There are no attributes to resolve here - we already did everything
2347         # when we constructed proto_bind. However we still want to sanity-check
2348         # what the user supplied, so pass stuff through to the resolver *anyway*
2349         : $self->_resolve_bindattrs (
2350             undef,  # a fake rsrc
2351             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2352             {},     # a fake column_info bag
2353           )->[0][1]
2354       ;
2355
2356       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2357       # For the time being forcibly stringify whatever is stringifiable
2358       my $vref;
2359
2360       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2361     : defined blessed( $$vref )                             ? "$$vref"
2362                                                             : $$vref
2363     ;
2364     } map { $_->[0] } @$proto_bind ];
2365   };
2366
2367   my $tuple_status = [];
2368   my ($rv, $err);
2369   dbic_internal_try {
2370     $rv = $sth->execute_for_fetch(
2371       $fetch_tuple,
2372       $tuple_status,
2373     );
2374   }
2375   catch {
2376     $err = shift;
2377   };
2378
2379   # Not all DBDs are create equal. Some throw on error, some return
2380   # an undef $rv, and some set $sth->err - try whatever we can
2381   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2382     ! defined $err
2383       and
2384     ( !defined $rv or $sth->err )
2385   );
2386
2387   # Statement must finish even if there was an exception.
2388   dbic_internal_try {
2389     $sth->finish
2390   }
2391   catch {
2392     $err = shift unless defined $err
2393   };
2394
2395   if (defined $err) {
2396     my $i = 0;
2397     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2398
2399     $self->throw_exception("Unexpected populate error: $err")
2400       if ($i > $#$tuple_status);
2401
2402     require Data::Dumper::Concise;
2403     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2404       ($tuple_status->[$i][1] || $err),
2405       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2406     );
2407   }
2408
2409   return $rv;
2410 }
2411
2412 sub _dbh_execute_inserts_with_no_binds {
2413   my ($self, $sth, $count) = @_;
2414
2415   my $err;
2416   dbic_internal_try {
2417     my $dbh = $self->_get_dbh;
2418     local $dbh->{RaiseError} = 1;
2419     local $dbh->{PrintError} = 0;
2420
2421     $sth->execute foreach 1..$count;
2422   }
2423   catch {
2424     $err = shift;
2425   };
2426
2427   # Make sure statement is finished even if there was an exception.
2428   dbic_internal_try {
2429     $sth->finish
2430   }
2431   catch {
2432     $err = shift unless defined $err;
2433   };
2434
2435   $self->throw_exception($err) if defined $err;
2436
2437   return $count;
2438 }
2439
2440 sub update {
2441   #my ($self, $source, @args) = @_;
2442   shift->_execute('update', @_);
2443 }
2444
2445
2446 sub delete {
2447   #my ($self, $source, @args) = @_;
2448   shift->_execute('delete', @_);
2449 }
2450
2451 sub _select {
2452   my $self = shift;
2453   $self->_execute($self->_select_args(@_));
2454 }
2455
2456 sub _select_args_to_query {
2457   my $self = shift;
2458
2459   $self->throw_exception(
2460     "Unable to generate limited query representation with 'software_limit' enabled"
2461   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2462
2463   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2464   #  = $self->_select_args($ident, $select, $cond, $attrs);
2465   my ($op, $ident, @args) =
2466     $self->_select_args(@_);
2467
2468   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2469   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2470
2471   # reuse the bind arrayref
2472   unshift @{$bind}, "($sql)";
2473   \$bind;
2474 }
2475
2476 sub _select_args {
2477   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2478
2479   # FIXME - that kind of caching would be nice to have
2480   # however currently we *may* pass the same $orig_attrs
2481   # with different ident/select/where
2482   # the whole interface needs to be rethought, since it
2483   # was centered around the flawed SQLA API. We can do
2484   # soooooo much better now. But that is also another
2485   # battle...
2486   #return (
2487   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2488   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2489
2490   my $sql_maker = $self->sql_maker;
2491
2492   my $attrs = {
2493     %$orig_attrs,
2494     select => $select,
2495     from => $ident,
2496     where => $where,
2497   };
2498
2499   # MySQL actually recommends this approach.  I cringe.
2500   $attrs->{rows} ||= $sql_maker->__max_int
2501     if $attrs->{offset};
2502
2503   # see if we will need to tear the prefetch apart to satisfy group_by == select
2504   # this is *extremely tricky* to get right, I am still not sure I did
2505   #
2506   my ($prefetch_needs_subquery, @limit_args);
2507
2508   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2509     # we already know there is a valid group_by (we made it) and we know it is
2510     # intended to be based *only* on non-multi stuff
2511     # short circuit the group_by parsing below
2512     $prefetch_needs_subquery = 1;
2513   }
2514   elsif (
2515     # The rationale is that even if we do *not* have collapse, we still
2516     # need to wrap the core grouped select/group_by in a subquery
2517     # so that databases that care about group_by/select equivalence
2518     # are happy (this includes MySQL in strict_mode)
2519     # If any of the other joined tables are referenced in the group_by
2520     # however - the user is on their own
2521     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2522       and
2523     $attrs->{group_by}
2524       and
2525     @{$attrs->{group_by}}
2526       and
2527     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2528       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2529     }
2530   ) {
2531     # no aliases other than our own in group_by
2532     # if there are - do not allow subquery even if limit is present
2533     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2534   }
2535   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2536     # active collapse with a limit - that one is a no-brainer unless
2537     # overruled by a group_by above
2538     $prefetch_needs_subquery = 1;
2539   }
2540
2541   if ($prefetch_needs_subquery) {
2542     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2543   }
2544   elsif (! $attrs->{software_limit} ) {
2545     push @limit_args, (
2546       $attrs->{rows} || (),
2547       $attrs->{offset} || (),
2548     );
2549   }
2550
2551   # try to simplify the joinmap further (prune unreferenced type-single joins)
2552   if (
2553     ! $prefetch_needs_subquery  # already pruned
2554       and
2555     ref $attrs->{from}
2556       and
2557     reftype $attrs->{from} eq 'ARRAY'
2558       and
2559     @{$attrs->{from}} != 1
2560   ) {
2561     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2562   }
2563
2564   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2565   # during the result inflation stage we *need* to know what was the aliastype
2566   # map as sqla saw it when the final pieces of SQL were being assembled
2567   # Originally we simply carried around the entirety of $attrs, but this
2568   # resulted in resultsets that are being reused growing continuously, as
2569   # the hash in question grew deeper and deeper.
2570   # Instead hand-pick what to take with us here (we actually don't need much
2571   # at this point just the map itself)
2572   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2573
2574 ###
2575   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2576   #
2577   # This would be the point to deflate anything found in $attrs->{where}
2578   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2579   # expect a result object. And all we have is a resultsource (it is trivial
2580   # to extract deflator coderefs via $alias2source above).
2581   #
2582   # I don't see a way forward other than changing the way deflators are
2583   # invoked, and that's just bad...
2584 ###
2585
2586   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2587 }
2588
2589 # Returns a counting SELECT for a simple count
2590 # query. Abstracted so that a storage could override
2591 # this to { count => 'firstcol' } or whatever makes
2592 # sense as a performance optimization
2593 sub _count_select {
2594   #my ($self, $source, $rs_attrs) = @_;
2595   return { count => '*' };
2596 }
2597
2598 =head2 select
2599
2600 =over 4
2601
2602 =item Arguments: $ident, $select, $condition, $attrs
2603
2604 =back
2605
2606 Handle a SQL select statement.
2607
2608 =cut
2609
2610 sub select {
2611   my $self = shift;
2612   my ($ident, $select, $condition, $attrs) = @_;
2613   return $self->cursor_class->new($self, \@_, $attrs);
2614 }
2615
2616 sub select_single {
2617   my $self = shift;
2618   my ($rv, $sth, @bind) = $self->_select(@_);
2619   my @row = $sth->fetchrow_array;
2620   my @nextrow = $sth->fetchrow_array if @row;
2621   if(@row && @nextrow) {
2622     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2623   }
2624   # Need to call finish() to work round broken DBDs
2625   $sth->finish();
2626   return @row;
2627 }
2628
2629 =head2 sql_limit_dialect
2630
2631 This is an accessor for the default SQL limit dialect used by a particular
2632 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2633 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2634 see L<DBIx::Class::SQLMaker::LimitDialects>.
2635
2636 =cut
2637
2638 sub _dbh_columns_info_for {
2639   my ($self, $dbh, $table) = @_;
2640
2641   my %result;
2642
2643   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2644     dbic_internal_try {
2645       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2646       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2647       $sth->execute();
2648       while ( my $info = $sth->fetchrow_hashref() ){
2649         my %column_info;
2650         $column_info{data_type}   = $info->{TYPE_NAME};
2651         $column_info{size}      = $info->{COLUMN_SIZE};
2652         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2653         $column_info{default_value} = $info->{COLUMN_DEF};
2654         my $col_name = $info->{COLUMN_NAME};
2655         $col_name =~ s/^\"(.*)\"$/$1/;
2656
2657         $result{$col_name} = \%column_info;
2658       }
2659     } catch {
2660       %result = ();
2661     };
2662
2663     return \%result if keys %result;
2664   }
2665
2666   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2667   $sth->execute;
2668
2669 ### The acrobatics with lc names is necessary to support both the legacy
2670 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2671 ### with column names differing in cas eonly (thanks pg!)
2672
2673   my ($columns, $seen_lcs);
2674
2675   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2676     idx => scalar keys %$columns,
2677     name => $_,
2678     lc_name => lc($_),
2679   } for @{$sth->{NAME}};
2680
2681   $seen_lcs->{$_->{lc_name}} == 1
2682     and
2683   $_->{name} = $_->{lc_name}
2684     for values %$columns;
2685
2686   for ( values %$columns ) {
2687     my $inf = {
2688       data_type => $sth->{TYPE}->[$_->{idx}],
2689       size => $sth->{PRECISION}->[$_->{idx}],
2690       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2691     };
2692
2693     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2694       @{$inf}{qw( data_type  size)} = ($1, $2);
2695     }
2696
2697     $result{$_->{name}} = $inf;
2698   }
2699
2700   $sth->finish;
2701
2702   if ($dbh->can('type_info')) {
2703     for my $inf (values %result) {
2704       next if ! defined $inf->{data_type};
2705
2706       $inf->{data_type} = (
2707         (
2708           (
2709             $dbh->type_info( $inf->{data_type} )
2710               ||
2711             next
2712           )
2713             ||
2714           next
2715         )->{TYPE_NAME}
2716           ||
2717         next
2718       );
2719
2720       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2721       # needs more testing in the future...
2722       $inf->{size} -= 4 if (
2723         ( $inf->{size}||0 > 4 )
2724           and
2725         $inf->{data_type} =~ qr/^text$/i
2726       );
2727     }
2728
2729   }
2730
2731   return \%result;
2732 }
2733
2734 sub columns_info_for {
2735   my ($self, $table) = @_;
2736   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2737 }
2738
2739 =head2 last_insert_id
2740
2741 Return the row id of the last insert.
2742
2743 =cut
2744
2745 sub _dbh_last_insert_id {
2746     my ($self, $dbh, $source, $col) = @_;
2747
2748     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2749
2750     return $id if defined $id;
2751
2752     my $class = ref $self;
2753     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2754 }
2755
2756 sub last_insert_id {
2757   my $self = shift;
2758   $self->_dbh_last_insert_id ($self->_dbh, @_);
2759 }
2760
2761 =head2 _native_data_type
2762
2763 =over 4
2764
2765 =item Arguments: $type_name
2766
2767 =back
2768
2769 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2770 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2771 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2772
2773 The default implementation returns C<undef>, implement in your Storage driver if
2774 you need this functionality.
2775
2776 Should map types from other databases to the native RDBMS type, for example
2777 C<VARCHAR2> to C<VARCHAR>.
2778
2779 Types with modifiers should map to the underlying data type. For example,
2780 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2781
2782 Composite types should map to the container type, for example
2783 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2784
2785 =cut
2786
2787 sub _native_data_type {
2788   #my ($self, $data_type) = @_;
2789   return undef
2790 }
2791
2792 # Check if placeholders are supported at all
2793 sub _determine_supports_placeholders {
2794   my $self = shift;
2795   my $dbh  = $self->_get_dbh;
2796
2797   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2798   # but it is inaccurate more often than not
2799   ( dbic_internal_try {
2800     local $dbh->{PrintError} = 0;
2801     local $dbh->{RaiseError} = 1;
2802     $dbh->do('select ?', {}, 1);
2803     1;
2804   } )
2805     ? 1
2806     : 0
2807   ;
2808 }
2809
2810 # Check if placeholders bound to non-string types throw exceptions
2811 #
2812 sub _determine_supports_typeless_placeholders {
2813   my $self = shift;
2814   my $dbh  = $self->_get_dbh;
2815
2816   ( dbic_internal_try {
2817     local $dbh->{PrintError} = 0;
2818     local $dbh->{RaiseError} = 1;
2819     # this specifically tests a bind that is NOT a string
2820     $dbh->do('select 1 where 1 = ?', {}, 1);
2821     1;
2822   } )
2823     ? 1
2824     : 0
2825   ;
2826 }
2827
2828 =head2 sqlt_type
2829
2830 Returns the database driver name.
2831
2832 =cut
2833
2834 sub sqlt_type {
2835   shift->_get_dbh->{Driver}->{Name};
2836 }
2837
2838 =head2 bind_attribute_by_data_type
2839
2840 Given a datatype from column info, returns a database specific bind
2841 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2842 let the database planner just handle it.
2843
2844 This method is always called after the driver has been determined and a DBI
2845 connection has been established. Therefore you can refer to C<DBI::$constant>
2846 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2847 the correct modules.
2848
2849 =cut
2850
2851 sub bind_attribute_by_data_type {
2852     return;
2853 }
2854
2855 =head2 is_datatype_numeric
2856
2857 Given a datatype from column_info, returns a boolean value indicating if
2858 the current RDBMS considers it a numeric value. This controls how
2859 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2860 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2861 be performed instead of the usual C<eq>.
2862
2863 =cut
2864
2865 sub is_datatype_numeric {
2866   #my ($self, $dt) = @_;
2867
2868   return 0 unless $_[1];
2869
2870   $_[1] =~ /^ (?:
2871     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2872   ) $/ix;
2873 }
2874
2875
2876 =head2 create_ddl_dir
2877
2878 =over 4
2879
2880 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2881
2882 =back
2883
2884 Creates a SQL file based on the Schema, for each of the specified
2885 database engines in C<\@databases> in the given directory.
2886 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2887
2888 Given a previous version number, this will also create a file containing
2889 the ALTER TABLE statements to transform the previous schema into the
2890 current one. Note that these statements may contain C<DROP TABLE> or
2891 C<DROP COLUMN> statements that can potentially destroy data.
2892
2893 The file names are created using the C<ddl_filename> method below, please
2894 override this method in your schema if you would like a different file
2895 name format. For the ALTER file, the same format is used, replacing
2896 $version in the name with "$preversion-$version".
2897
2898 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2899 The most common value for this would be C<< { add_drop_table => 1 } >>
2900 to have the SQL produced include a C<DROP TABLE> statement for each table
2901 created. For quoting purposes supply C<quote_identifiers>.
2902
2903 If no arguments are passed, then the following default values are assumed:
2904
2905 =over 4
2906
2907 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2908
2909 =item version    - $schema->schema_version
2910
2911 =item directory  - './'
2912
2913 =item preversion - <none>
2914
2915 =back
2916
2917 By default, C<\%sqlt_args> will have
2918
2919  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2920
2921 merged with the hash passed in. To disable any of those features, pass in a
2922 hashref like the following
2923
2924  { ignore_constraint_names => 0, # ... other options }
2925
2926
2927 WARNING: You are strongly advised to check all SQL files created, before applying
2928 them.
2929
2930 =cut
2931
2932 sub create_ddl_dir {
2933   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2934
2935   unless ($dir) {
2936     carp "No directory given, using ./\n";
2937     $dir = './';
2938   } else {
2939       -d $dir
2940         or
2941       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2942         or
2943       $self->throw_exception(
2944         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2945       );
2946   }
2947
2948   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2949
2950   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2951   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2952
2953   my $schema_version = $schema->schema_version || '1.x';
2954   $version ||= $schema_version;
2955
2956   $sqltargs = {
2957     add_drop_table => 1,
2958     ignore_constraint_names => 1,
2959     ignore_index_names => 1,
2960     quote_identifiers => $self->sql_maker->_quoting_enabled,
2961     %{$sqltargs || {}}
2962   };
2963
2964   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2965     $self->throw_exception("Can't create a ddl file without $missing");
2966   }
2967
2968   my $sqlt = SQL::Translator->new( $sqltargs );
2969
2970   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2971   my $sqlt_schema = $sqlt->translate({ data => $schema })
2972     or $self->throw_exception ($sqlt->error);
2973
2974   foreach my $db (@$databases) {
2975     $sqlt->reset();
2976     $sqlt->{schema} = $sqlt_schema;
2977     $sqlt->producer($db);
2978
2979     my $file;
2980     my $filename = $schema->ddl_filename($db, $version, $dir);
2981     if (-e $filename && ($version eq $schema_version )) {
2982       # if we are dumping the current version, overwrite the DDL
2983       carp "Overwriting existing DDL file - $filename";
2984       unlink($filename);
2985     }
2986
2987     my $output = $sqlt->translate;
2988     if(!$output) {
2989       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2990       next;
2991     }
2992     if(!open($file, ">$filename")) {
2993       $self->throw_exception("Can't open $filename for writing ($!)");
2994       next;
2995     }
2996     print $file $output;
2997     close($file);
2998
2999     next unless ($preversion);
3000
3001     require SQL::Translator::Diff;
3002
3003     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
3004     if(!-e $prefilename) {
3005       carp("No previous schema file found ($prefilename)");
3006       next;
3007     }
3008
3009     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
3010     if(-e $difffile) {
3011       carp("Overwriting existing diff file - $difffile");
3012       unlink($difffile);
3013     }
3014
3015     my $source_schema;
3016     {
3017       my $t = SQL::Translator->new($sqltargs);
3018       $t->debug( 0 );
3019       $t->trace( 0 );
3020
3021       $t->parser( $db )
3022         or $self->throw_exception ($t->error);
3023
3024       my $out = $t->translate( $prefilename )
3025         or $self->throw_exception ($t->error);
3026
3027       $source_schema = $t->schema;
3028
3029       $source_schema->name( $prefilename )
3030         unless ( $source_schema->name );
3031     }
3032
3033     # The "new" style of producers have sane normalization and can support
3034     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3035     # And we have to diff parsed SQL against parsed SQL.
3036     my $dest_schema = $sqlt_schema;
3037
3038     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3039       my $t = SQL::Translator->new($sqltargs);
3040       $t->debug( 0 );
3041       $t->trace( 0 );
3042
3043       $t->parser( $db )
3044         or $self->throw_exception ($t->error);
3045
3046       my $out = $t->translate( $filename )
3047         or $self->throw_exception ($t->error);
3048
3049       $dest_schema = $t->schema;
3050
3051       $dest_schema->name( $filename )
3052         unless $dest_schema->name;
3053     }
3054
3055     my $diff = do {
3056       # FIXME - this is a terrible workaround for
3057       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3058       # Fixing it in this sloppy manner so that we don't hve to
3059       # lockstep an SQLT release as well. Needs to be removed at
3060       # some point, and SQLT dep bumped
3061       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3062         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3063
3064       SQL::Translator::Diff::schema_diff($source_schema, $db,
3065                                          $dest_schema,   $db,
3066                                          $sqltargs
3067                                        );
3068     };
3069
3070     if(!open $file, ">$difffile") {
3071       $self->throw_exception("Can't write to $difffile ($!)");
3072       next;
3073     }
3074     print $file $diff;
3075     close($file);
3076   }
3077 }
3078
3079 =head2 deployment_statements
3080
3081 =over 4
3082
3083 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3084
3085 =back
3086
3087 Returns the statements used by L<DBIx::Class::Storage/deploy>
3088 and L<DBIx::Class::Schema/deploy>.
3089
3090 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3091 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3092
3093 C<$directory> is used to return statements from files in a previously created
3094 L</create_ddl_dir> directory and is optional. The filenames are constructed
3095 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3096
3097 If no C<$directory> is specified then the statements are constructed on the
3098 fly using L<SQL::Translator> and C<$version> is ignored.
3099
3100 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3101
3102 =cut
3103
3104 sub deployment_statements {
3105   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3106   $type ||= $self->sqlt_type;
3107   $version ||= $schema->schema_version || '1.x';
3108   $dir ||= './';
3109   my $filename = $schema->ddl_filename($type, $version, $dir);
3110   if(-f $filename)
3111   {
3112       # FIXME replace this block when a proper sane sql parser is available
3113       my $file;
3114       open($file, "<$filename")
3115         or $self->throw_exception("Can't open $filename ($!)");
3116       my @rows = <$file>;
3117       close($file);
3118       return join('', @rows);
3119   }
3120
3121   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3122     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3123   }
3124
3125   # sources needs to be a parser arg, but for simplicity allow at top level
3126   # coming in
3127   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3128       if exists $sqltargs->{sources};
3129
3130   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3131     unless exists $sqltargs->{quote_identifiers};
3132
3133   my $tr = SQL::Translator->new(
3134     producer => "SQL::Translator::Producer::${type}",
3135     %$sqltargs,
3136     parser => 'SQL::Translator::Parser::DBIx::Class',
3137     data => $schema,
3138   );
3139
3140   return preserve_context {
3141     $tr->translate
3142   } after => sub {
3143     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3144       unless defined $_[0];
3145   };
3146 }
3147
3148 # FIXME deploy() currently does not accurately report sql errors
3149 # Will always return true while errors are warned
3150 sub deploy {
3151   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3152   my $deploy = sub {
3153     my $line = shift;
3154     return if(!$line);
3155     return if($line =~ /^--/);
3156     # next if($line =~ /^DROP/m);
3157     return if($line =~ /^BEGIN TRANSACTION/m);
3158     return if($line =~ /^COMMIT/m);
3159     return if $line =~ /^\s+$/; # skip whitespace only
3160     $self->_query_start($line);
3161     dbic_internal_try {
3162       # do a dbh_do cycle here, as we need some error checking in
3163       # place (even though we will ignore errors)
3164       $self->dbh_do (sub { $_[1]->do($line) });
3165     } catch {
3166       carp qq{$_ (running "${line}")};
3167     };
3168     $self->_query_end($line);
3169   };
3170   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3171   if (@statements > 1) {
3172     foreach my $statement (@statements) {
3173       $deploy->( $statement );
3174     }
3175   }
3176   elsif (@statements == 1) {
3177     # split on single line comments and end of statements
3178     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3179       $deploy->( $line );
3180     }
3181   }
3182 }
3183
3184 =head2 datetime_parser
3185
3186 Returns the datetime parser class
3187
3188 =cut
3189
3190 sub datetime_parser {
3191   my $self = shift;
3192   return $self->{datetime_parser} ||= do {
3193     $self->build_datetime_parser(@_);
3194   };
3195 }
3196
3197 =head2 datetime_parser_type
3198
3199 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3200
3201 =head2 build_datetime_parser
3202
3203 See L</datetime_parser>
3204
3205 =cut
3206
3207 sub build_datetime_parser {
3208   my $self = shift;
3209   my $type = $self->datetime_parser_type(@_);
3210   return $type;
3211 }
3212
3213
3214 =head2 is_replicating
3215
3216 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3217 replicate from a master database.  Default is undef, which is the result
3218 returned by databases that don't support replication.
3219
3220 =cut
3221
3222 sub is_replicating {
3223     return;
3224
3225 }
3226
3227 =head2 lag_behind_master
3228
3229 Returns a number that represents a certain amount of lag behind a master db
3230 when a given storage is replicating.  The number is database dependent, but
3231 starts at zero and increases with the amount of lag. Default in undef
3232
3233 =cut
3234
3235 sub lag_behind_master {
3236     return;
3237 }
3238
3239 =head2 relname_to_table_alias
3240
3241 =over 4
3242
3243 =item Arguments: $relname, $join_count
3244
3245 =item Return Value: $alias
3246
3247 =back
3248
3249 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3250 queries.
3251
3252 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3253 way these aliases are named.
3254
3255 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3256 otherwise C<"$relname">.
3257
3258 =cut
3259
3260 sub relname_to_table_alias {
3261   my ($self, $relname, $join_count) = @_;
3262
3263   my $alias = ($join_count && $join_count > 1 ?
3264     join('_', $relname, $join_count) : $relname);
3265
3266   return $alias;
3267 }
3268
3269 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3270 # version and it may be necessary to amend or override it for a specific storage
3271 # if such binds are necessary.
3272 sub _max_column_bytesize {
3273   my ($self, $attr) = @_;
3274
3275   my $max_size;
3276
3277   if ($attr->{sqlt_datatype}) {
3278     my $data_type = lc($attr->{sqlt_datatype});
3279
3280     if ($attr->{sqlt_size}) {
3281
3282       # String/sized-binary types
3283       if ($data_type =~ /^(?:
3284           l? (?:var)? char(?:acter)? (?:\s*varying)?
3285             |
3286           (?:var)? binary (?:\s*varying)?
3287             |
3288           raw
3289         )\b/x
3290       ) {
3291         $max_size = $attr->{sqlt_size};
3292       }
3293       # Other charset/unicode types, assume scale of 4
3294       elsif ($data_type =~ /^(?:
3295           national \s* character (?:\s*varying)?
3296             |
3297           nchar
3298             |
3299           univarchar
3300             |
3301           nvarchar
3302         )\b/x
3303       ) {
3304         $max_size = $attr->{sqlt_size} * 4;
3305       }
3306     }
3307
3308     if (!$max_size and !$self->_is_lob_type($data_type)) {
3309       $max_size = 100 # for all other (numeric?) datatypes
3310     }
3311   }
3312
3313   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3314 }
3315
3316 # Determine if a data_type is some type of BLOB
3317 sub _is_lob_type {
3318   my ($self, $data_type) = @_;
3319   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3320     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3321                                   |varchar|character\s*varying|nvarchar
3322                                   |national\s*character\s*varying))?\z/xi);
3323 }
3324
3325 sub _is_binary_lob_type {
3326   my ($self, $data_type) = @_;
3327   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3328     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3329 }
3330
3331 sub _is_text_lob_type {
3332   my ($self, $data_type) = @_;
3333   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3334     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3335                         |national\s*character\s*varying))\z/xi);
3336 }
3337
3338 # Determine if a data_type is some type of a binary type
3339 sub _is_binary_type {
3340   my ($self, $data_type) = @_;
3341   $data_type && ($self->_is_binary_lob_type($data_type)
3342     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3343 }
3344
3345 1;
3346
3347 =head1 USAGE NOTES
3348
3349 =head2 DBIx::Class and AutoCommit
3350
3351 DBIx::Class can do some wonderful magic with handling exceptions,
3352 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3353 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3354 transaction support.
3355
3356 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3357 in an assumed transaction between commits, and you're telling us you'd
3358 like to manage that manually.  A lot of the magic protections offered by
3359 this module will go away.  We can't protect you from exceptions due to database
3360 disconnects because we don't know anything about how to restart your
3361 transactions.  You're on your own for handling all sorts of exceptional
3362 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3363 be with raw DBI.
3364
3365 =head1 FURTHER QUESTIONS?
3366
3367 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3368
3369 =head1 COPYRIGHT AND LICENSE
3370
3371 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3372 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3373 redistribute it and/or modify it under the same terms as the
3374 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.