lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Try::Tiny;
  16 use overload ();
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts
  36   transaction_depth _dbh_autocommit  savepoints
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65   placeholders
  66   typeless_placeholders
  67   join_optimizer
  68 /);
  69 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  70 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  71
  72 # on by default, not strictly a capability (pending rewrite)
  73 __PACKAGE__->_use_join_optimizer (1);
  74 sub _determine_supports_join_optimizer { 1 };
  75
  76 # Each of these methods need _determine_driver called before itself
  77 # in order to function reliably. This is a purely DRY optimization
  78 #
  79 # get_(use)_dbms_capability need to be called on the correct Storage
  80 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  81 # _determine_supports_X which obv. needs a correct driver as well
  82 my @rdbms_specific_methods = qw/
  83   deployment_statements
  84   sqlt_type
  85   sql_maker
  86   build_datetime_parser
  87   datetime_parser_type
  88
  89   insert
  90   insert_bulk
  91   update
  92   delete
  93   select
  94   select_single
  95
  96   get_use_dbms_capability
  97   get_dbms_capability
  98
  99   _server_info
 100   _get_server_version
 101 /;
 102
 103 for my $meth (@rdbms_specific_methods) {
 104
 105   my $orig = __PACKAGE__->can ($meth)
 106     or die "$meth is not a ::Storage::DBI method!";
 107
 108   no strict qw/refs/;
 109   no warnings qw/redefine/;
 110   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 111     if (
 112       # only fire when invoked on an instance, a valid class-based invocation
 113       # would e.g. be setting a default for an inherited accessor
 114       ref $_[0]
 115         and
 116       ! $_[0]->_driver_determined
 117         and
 118       ! $_[0]->{_in_determine_driver}
 119     ) {
 120       $_[0]->_determine_driver;
 121
 122       # This for some reason crashes and burns on perl 5.8.1
 123       # IFF the method ends up throwing an exception
 124       #goto $_[0]->can ($meth);
 125
 126       my $cref = $_[0]->can ($meth);
 127       goto $cref;
 128     }
 129
 130     goto $orig;
 131   };
 132 }
 133
 134
 135 =head1 NAME
 136
 137 DBIx::Class::Storage::DBI - DBI storage handler
 138
 139 =head1 SYNOPSIS
 140
 141   my $schema = MySchema->connect('dbi:SQLite:my.db');
 142
 143   $schema->storage->debug(1);
 144
 145   my @stuff = $schema->storage->dbh_do(
 146     sub {
 147       my ($storage, $dbh, @args) = @_;
 148       $dbh->do("DROP TABLE authors");
 149     },
 150     @column_list
 151   );
 152
 153   $schema->resultset('Book')->search({
 154      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 155   });
 156
 157 =head1 DESCRIPTION
 158
 159 This class represents the connection to an RDBMS via L<DBI>.  See
 160 L<DBIx::Class::Storage> for general information.  This pod only
 161 documents DBI-specific methods and behaviors.
 162
 163 =head1 METHODS
 164
 165 =cut
 166
 167 sub new {
 168   my $new = shift->next::method(@_);
 169
 170   $new->transaction_depth(0);
 171   $new->_sql_maker_opts({});
 172   $new->_dbh_details({});
 173   $new->{savepoints} = [];
 174   $new->{_in_dbh_do} = 0;
 175   $new->{_dbh_gen} = 0;
 176
 177   # read below to see what this does
 178   $new->_arm_global_destructor;
 179
 180   $new;
 181 }
 182
 183 # This is hack to work around perl shooting stuff in random
 184 # order on exit(). If we do not walk the remaining storage
 185 # objects in an END block, there is a *small but real* chance
 186 # of a fork()ed child to kill the parent's shared DBI handle,
 187 # *before perl reaches the DESTROY in this package*
 188 # Yes, it is ugly and effective.
 189 # Additionally this registry is used by the CLONE method to
 190 # make sure no handles are shared between threads
 191 {
 192   my %seek_and_destroy;
 193
 194   sub _arm_global_destructor {
 195     my $self = shift;
 196     my $key = refaddr ($self);
 197     $seek_and_destroy{$key} = $self;
 198     weaken ($seek_and_destroy{$key});
 199   }
 200
 201   END {
 202     local $?; # just in case the DBI destructor changes it somehow
 203
 204     # destroy just the object if not native to this process/thread
 205     $_->_verify_pid for (grep
 206       { defined $_ }
 207       values %seek_and_destroy
 208     );
 209   }
 210
 211   sub CLONE {
 212     # As per DBI's recommendation, DBIC disconnects all handles as
 213     # soon as possible (DBIC will reconnect only on demand from within
 214     # the thread)
 215     for (values %seek_and_destroy) {
 216       next unless $_;
 217       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 218       $_->_dbh(undef);
 219     }
 220   }
 221 }
 222
 223 sub DESTROY {
 224   my $self = shift;
 225
 226   # some databases spew warnings on implicit disconnect
 227   local $SIG{__WARN__} = sub {};
 228   $self->_dbh(undef);
 229
 230   # this op is necessary, since the very last perl runtime statement
 231   # triggers a global destruction shootout, and the $SIG localization
 232   # may very well be destroyed before perl actually gets to do the
 233   # $dbh undef
 234   1;
 235 }
 236
 237 # handle pid changes correctly - do not destroy parent's connection
 238 sub _verify_pid {
 239   my $self = shift;
 240
 241   my $pid = $self->_conn_pid;
 242   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 243     $dbh->{InactiveDestroy} = 1;
 244     $self->{_dbh_gen}++;
 245     $self->_dbh(undef);
 246   }
 247
 248   return;
 249 }
 250
 251 =head2 connect_info
 252
 253 This method is normally called by L<DBIx::Class::Schema/connection>, which
 254 encapsulates its argument list in an arrayref before passing them here.
 255
 256 The argument list may contain:
 257
 258 =over
 259
 260 =item *
 261
 262 The same 4-element argument set one would normally pass to
 263 L<DBI/connect>, optionally followed by
 264 L<extra attributes|/DBIx::Class specific connection attributes>
 265 recognized by DBIx::Class:
 266
 267   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 268
 269 =item *
 270
 271 A single code reference which returns a connected
 272 L<DBI database handle|DBI/connect> optionally followed by
 273 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 274 by DBIx::Class:
 275
 276   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 277
 278 =item *
 279
 280 A single hashref with all the attributes and the dsn/user/password
 281 mixed together:
 282
 283   $connect_info_args = [{
 284     dsn => $dsn,
 285     user => $user,
 286     password => $pass,
 287     %dbi_attributes,
 288     %extra_attributes,
 289   }];
 290
 291   $connect_info_args = [{
 292     dbh_maker => sub { DBI->connect (...) },
 293     %dbi_attributes,
 294     %extra_attributes,
 295   }];
 296
 297 This is particularly useful for L<Catalyst> based applications, allowing the
 298 following config (L<Config::General> style):
 299
 300   <Model::DB>
 301     schema_class   App::DB
 302     <connect_info>
 303       dsn          dbi:mysql:database=test
 304       user         testuser
 305       password     TestPass
 306       AutoCommit   1
 307     </connect_info>
 308   </Model::DB>
 309
 310 The C<dsn>/C<user>/C<password> combination can be substituted by the
 311 C<dbh_maker> key whose value is a coderef that returns a connected
 312 L<DBI database handle|DBI/connect>
 313
 314 =back
 315
 316 Please note that the L<DBI> docs recommend that you always explicitly
 317 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 318 recommends that it be set to I<1>, and that you perform transactions
 319 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 320 to I<1> if you do not do explicitly set it to zero.  This is the default
 321 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 322
 323 =head3 DBIx::Class specific connection attributes
 324
 325 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 326 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 327 the following connection options. These options can be mixed in with your other
 328 L<DBI> connection attributes, or placed in a separate hashref
 329 (C<\%extra_attributes>) as shown above.
 330
 331 Every time C<connect_info> is invoked, any previous settings for
 332 these options will be cleared before setting the new ones, regardless of
 333 whether any options are specified in the new C<connect_info>.
 334
 335
 336 =over
 337
 338 =item on_connect_do
 339
 340 Specifies things to do immediately after connecting or re-connecting to
 341 the database.  Its value may contain:
 342
 343 =over
 344
 345 =item a scalar
 346
 347 This contains one SQL statement to execute.
 348
 349 =item an array reference
 350
 351 This contains SQL statements to execute in order.  Each element contains
 352 a string or a code reference that returns a string.
 353
 354 =item a code reference
 355
 356 This contains some code to execute.  Unlike code references within an
 357 array reference, its return value is ignored.
 358
 359 =back
 360
 361 =item on_disconnect_do
 362
 363 Takes arguments in the same form as L</on_connect_do> and executes them
 364 immediately before disconnecting from the database.
 365
 366 Note, this only runs if you explicitly call L</disconnect> on the
 367 storage object.
 368
 369 =item on_connect_call
 370
 371 A more generalized form of L</on_connect_do> that calls the specified
 372 C<connect_call_METHOD> methods in your storage driver.
 373
 374   on_connect_do => 'select 1'
 375
 376 is equivalent to:
 377
 378   on_connect_call => [ [ do_sql => 'select 1' ] ]
 379
 380 Its values may contain:
 381
 382 =over
 383
 384 =item a scalar
 385
 386 Will call the C<connect_call_METHOD> method.
 387
 388 =item a code reference
 389
 390 Will execute C<< $code->($storage) >>
 391
 392 =item an array reference
 393
 394 Each value can be a method name or code reference.
 395
 396 =item an array of arrays
 397
 398 For each array, the first item is taken to be the C<connect_call_> method name
 399 or code reference, and the rest are parameters to it.
 400
 401 =back
 402
 403 Some predefined storage methods you may use:
 404
 405 =over
 406
 407 =item do_sql
 408
 409 Executes a SQL string or a code reference that returns a SQL string. This is
 410 what L</on_connect_do> and L</on_disconnect_do> use.
 411
 412 It can take:
 413
 414 =over
 415
 416 =item a scalar
 417
 418 Will execute the scalar as SQL.
 419
 420 =item an arrayref
 421
 422 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 423 attributes hashref and bind values.
 424
 425 =item a code reference
 426
 427 Will execute C<< $code->($storage) >> and execute the return array refs as
 428 above.
 429
 430 =back
 431
 432 =item datetime_setup
 433
 434 Execute any statements necessary to initialize the database session to return
 435 and accept datetime/timestamp values used with
 436 L<DBIx::Class::InflateColumn::DateTime>.
 437
 438 Only necessary for some databases, see your specific storage driver for
 439 implementation details.
 440
 441 =back
 442
 443 =item on_disconnect_call
 444
 445 Takes arguments in the same form as L</on_connect_call> and executes them
 446 immediately before disconnecting from the database.
 447
 448 Calls the C<disconnect_call_METHOD> methods as opposed to the
 449 C<connect_call_METHOD> methods called by L</on_connect_call>.
 450
 451 Note, this only runs if you explicitly call L</disconnect> on the
 452 storage object.
 453
 454 =item disable_sth_caching
 455
 456 If set to a true value, this option will disable the caching of
 457 statement handles via L<DBI/prepare_cached>.
 458
 459 =item limit_dialect
 460
 461 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 462 default L</sql_limit_dialect> setting of the storage (if any). For a list
 463 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 464
 465 =item quote_names
 466
 467 When true automatically sets L</quote_char> and L</name_sep> to the characters
 468 appropriate for your particular RDBMS. This option is preferred over specifying
 469 L</quote_char> directly.
 470
 471 =item quote_char
 472
 473 Specifies what characters to use to quote table and column names.
 474
 475 C<quote_char> expects either a single character, in which case is it
 476 is placed on either side of the table/column name, or an arrayref of length
 477 2 in which case the table/column name is placed between the elements.
 478
 479 For example under MySQL you should use C<< quote_char => '`' >>, and for
 480 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 481
 482 =item name_sep
 483
 484 This parameter is only useful in conjunction with C<quote_char>, and is used to
 485 specify the character that separates elements (schemas, tables, columns) from
 486 each other. If unspecified it defaults to the most commonly used C<.>.
 487
 488 =item unsafe
 489
 490 This Storage driver normally installs its own C<HandleError>, sets
 491 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 492 all database handles, including those supplied by a coderef.  It does this
 493 so that it can have consistent and useful error behavior.
 494
 495 If you set this option to a true value, Storage will not do its usual
 496 modifications to the database handle's attributes, and instead relies on
 497 the settings in your connect_info DBI options (or the values you set in
 498 your connection coderef, in the case that you are connecting via coderef).
 499
 500 Note that your custom settings can cause Storage to malfunction,
 501 especially if you set a C<HandleError> handler that suppresses exceptions
 502 and/or disable C<RaiseError>.
 503
 504 =item auto_savepoint
 505
 506 If this option is true, L<DBIx::Class> will use savepoints when nesting
 507 transactions, making it possible to recover from failure in the inner
 508 transaction without having to abort all outer transactions.
 509
 510 =item cursor_class
 511
 512 Use this argument to supply a cursor class other than the default
 513 L<DBIx::Class::Storage::DBI::Cursor>.
 514
 515 =back
 516
 517 Some real-life examples of arguments to L</connect_info> and
 518 L<DBIx::Class::Schema/connect>
 519
 520   # Simple SQLite connection
 521   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 522
 523   # Connect via subref
 524   ->connect_info([ sub { DBI->connect(...) } ]);
 525
 526   # Connect via subref in hashref
 527   ->connect_info([{
 528     dbh_maker => sub { DBI->connect(...) },
 529     on_connect_do => 'alter session ...',
 530   }]);
 531
 532   # A bit more complicated
 533   ->connect_info(
 534     [
 535       'dbi:Pg:dbname=foo',
 536       'postgres',
 537       'my_pg_password',
 538       { AutoCommit => 1 },
 539       { quote_char => q{"} },
 540     ]
 541   );
 542
 543   # Equivalent to the previous example
 544   ->connect_info(
 545     [
 546       'dbi:Pg:dbname=foo',
 547       'postgres',
 548       'my_pg_password',
 549       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 550     ]
 551   );
 552
 553   # Same, but with hashref as argument
 554   # See parse_connect_info for explanation
 555   ->connect_info(
 556     [{
 557       dsn         => 'dbi:Pg:dbname=foo',
 558       user        => 'postgres',
 559       password    => 'my_pg_password',
 560       AutoCommit  => 1,
 561       quote_char  => q{"},
 562       name_sep    => q{.},
 563     }]
 564   );
 565
 566   # Subref + DBIx::Class-specific connection options
 567   ->connect_info(
 568     [
 569       sub { DBI->connect(...) },
 570       {
 571           quote_char => q{`},
 572           name_sep => q{@},
 573           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 574           disable_sth_caching => 1,
 575       },
 576     ]
 577   );
 578
 579
 580
 581 =cut
 582
 583 sub connect_info {
 584   my ($self, $info) = @_;
 585
 586   return $self->_connect_info if !$info;
 587
 588   $self->_connect_info($info); # copy for _connect_info
 589
 590   $info = $self->_normalize_connect_info($info)
 591     if ref $info eq 'ARRAY';
 592
 593   for my $storage_opt (keys %{ $info->{storage_options} }) {
 594     my $value = $info->{storage_options}{$storage_opt};
 595
 596     $self->$storage_opt($value);
 597   }
 598
 599   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 600   #  the new set of options
 601   $self->_sql_maker(undef);
 602   $self->_sql_maker_opts({});
 603
 604   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 605     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 606
 607     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 608   }
 609
 610   my %attrs = (
 611     %{ $self->_default_dbi_connect_attributes || {} },
 612     %{ $info->{attributes} || {} },
 613   );
 614
 615   my @args = @{ $info->{arguments} };
 616
 617   if (keys %attrs and ref $args[0] ne 'CODE') {
 618     carp
 619         'You provided explicit AutoCommit => 0 in your connection_info. '
 620       . 'This is almost universally a bad idea (see the footnotes of '
 621       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 622       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 623       . 'this warning.'
 624       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 625
 626     push @args, \%attrs if keys %attrs;
 627   }
 628   $self->_dbi_connect_info(\@args);
 629
 630   # FIXME - dirty:
 631   # save attributes them in a separate accessor so they are always
 632   # introspectable, even in case of a CODE $dbhmaker
 633   $self->_dbic_connect_attributes (\%attrs);
 634
 635   return $self->_connect_info;
 636 }
 637
 638 sub _normalize_connect_info {
 639   my ($self, $info_arg) = @_;
 640   my %info;
 641
 642   my @args = @$info_arg;  # take a shallow copy for further mutilation
 643
 644   # combine/pre-parse arguments depending on invocation style
 645
 646   my %attrs;
 647   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 648     %attrs = %{ $args[1] || {} };
 649     @args = $args[0];
 650   }
 651   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 652     %attrs = %{$args[0]};
 653     @args = ();
 654     if (my $code = delete $attrs{dbh_maker}) {
 655       @args = $code;
 656
 657       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 658       if (@ignored) {
 659         carp sprintf (
 660             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 661           . "to the result of 'dbh_maker'",
 662
 663           join (', ', map { "'$_'" } (@ignored) ),
 664         );
 665       }
 666     }
 667     else {
 668       @args = delete @attrs{qw/dsn user password/};
 669     }
 670   }
 671   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 672     %attrs = (
 673       % { $args[3] || {} },
 674       % { $args[4] || {} },
 675     );
 676     @args = @args[0,1,2];
 677   }
 678
 679   $info{arguments} = \@args;
 680
 681   my @storage_opts = grep exists $attrs{$_},
 682     @storage_options, 'cursor_class';
 683
 684   @{ $info{storage_options} }{@storage_opts} =
 685     delete @attrs{@storage_opts} if @storage_opts;
 686
 687   my @sql_maker_opts = grep exists $attrs{$_},
 688     qw/limit_dialect quote_char name_sep quote_names/;
 689
 690   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 691     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 692
 693   $info{attributes} = \%attrs if %attrs;
 694
 695   return \%info;
 696 }
 697
 698 sub _default_dbi_connect_attributes () {
 699   +{
 700     AutoCommit => 1,
 701     PrintError => 0,
 702     RaiseError => 1,
 703     ShowErrorStatement => 1,
 704   };
 705 }
 706
 707 =head2 on_connect_do
 708
 709 This method is deprecated in favour of setting via L</connect_info>.
 710
 711 =cut
 712
 713 =head2 on_disconnect_do
 714
 715 This method is deprecated in favour of setting via L</connect_info>.
 716
 717 =cut
 718
 719 sub _parse_connect_do {
 720   my ($self, $type) = @_;
 721
 722   my $val = $self->$type;
 723   return () if not defined $val;
 724
 725   my @res;
 726
 727   if (not ref($val)) {
 728     push @res, [ 'do_sql', $val ];
 729   } elsif (ref($val) eq 'CODE') {
 730     push @res, $val;
 731   } elsif (ref($val) eq 'ARRAY') {
 732     push @res, map { [ 'do_sql', $_ ] } @$val;
 733   } else {
 734     $self->throw_exception("Invalid type for $type: ".ref($val));
 735   }
 736
 737   return \@res;
 738 }
 739
 740 =head2 dbh_do
 741
 742 Arguments: ($subref | $method_name), @extra_coderef_args?
 743
 744 Execute the given $subref or $method_name using the new exception-based
 745 connection management.
 746
 747 The first two arguments will be the storage object that C<dbh_do> was called
 748 on and a database handle to use.  Any additional arguments will be passed
 749 verbatim to the called subref as arguments 2 and onwards.
 750
 751 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 752 exception handling and reconnection (or failover in future subclasses).
 753
 754 Your subref should have no side-effects outside of the database, as
 755 there is the potential for your subref to be partially double-executed
 756 if the database connection was stale/dysfunctional.
 757
 758 Example:
 759
 760   my @stuff = $schema->storage->dbh_do(
 761     sub {
 762       my ($storage, $dbh, @cols) = @_;
 763       my $cols = join(q{, }, @cols);
 764       $dbh->selectrow_array("SELECT $cols FROM foo");
 765     },
 766     @column_list
 767   );
 768
 769 =cut
 770
 771 sub dbh_do {
 772   my $self = shift;
 773   my $code = shift;
 774
 775   my $dbh = $self->_get_dbh;
 776
 777   return $self->$code($dbh, @_)
 778     if ( $self->{_in_dbh_do} || $self->{transaction_depth} );
 779
 780   local $self->{_in_dbh_do} = 1;
 781
 782   # take a ref instead of a copy, to preserve coderef @_ aliasing semantics
 783   my $args = \@_;
 784   return try {
 785     $self->$code ($dbh, @$args);
 786   } catch {
 787     $self->throw_exception($_) if $self->connected;
 788
 789     # We were not connected - reconnect and retry, but let any
 790     #  exception fall right through this time
 791     carp "Retrying $code after catching disconnected exception: $_"
 792       if $ENV{DBIC_DBIRETRY_DEBUG};
 793
 794     $self->_populate_dbh;
 795     $self->$code($self->_dbh, @$args);
 796   };
 797 }
 798
 799 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 800 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 801 # via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 802 sub txn_do {
 803   my $self = shift;
 804   my $coderef = shift;
 805
 806   ref $coderef eq 'CODE' or $self->throw_exception
 807     ('$coderef must be a CODE reference');
 808
 809   local $self->{_in_dbh_do} = 1;
 810
 811   my @result;
 812   my $want = wantarray;
 813
 814   my $tried = 0;
 815   while(1) {
 816     my $exception;
 817
 818     # take a ref instead of a copy, to preserve coderef @_ aliasing semantics
 819     my $args = \@_;
 820
 821     try {
 822       $self->txn_begin;
 823       my $txn_start_depth = $self->transaction_depth;
 824       if($want) {
 825           @result = $coderef->(@$args);
 826       }
 827       elsif(defined $want) {
 828           $result[0] = $coderef->(@$args);
 829       }
 830       else {
 831           $coderef->(@$args);
 832       }
 833
 834       my $delta_txn = $txn_start_depth - $self->transaction_depth;
 835       if ($delta_txn == 0) {
 836         $self->txn_commit;
 837       }
 838       elsif ($delta_txn != 1) {
 839         # an off-by-one would mean we fired a rollback
 840         carp "Unexpected reduction of transaction depth by $delta_txn after execution of $coderef";
 841       }
 842     } catch {
 843       $exception = $_;
 844     };
 845
 846     if(! defined $exception) { return wantarray ? @result : $result[0] }
 847
 848     if($self->transaction_depth > 1 || $tried++ || $self->connected) {
 849       my $rollback_exception;
 850       try { $self->txn_rollback } catch { $rollback_exception = shift };
 851       if(defined $rollback_exception) {
 852         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 853         $self->throw_exception($exception)  # propagate nested rollback
 854           if $rollback_exception =~ /$exception_class/;
 855
 856         $self->throw_exception(
 857           "Transaction aborted: ${exception}. "
 858           . "Rollback failed: ${rollback_exception}"
 859         );
 860       }
 861       $self->throw_exception($exception)
 862     }
 863
 864     # We were not connected, and was first try - reconnect and retry
 865     # via the while loop
 866     carp "Retrying $coderef after catching disconnected exception: $exception"
 867       if $ENV{DBIC_TXNRETRY_DEBUG};
 868     $self->_populate_dbh;
 869   }
 870 }
 871
 872 =head2 disconnect
 873
 874 Our C<disconnect> method also performs a rollback first if the
 875 database is not in C<AutoCommit> mode.
 876
 877 =cut
 878
 879 sub disconnect {
 880   my ($self) = @_;
 881
 882   if( $self->_dbh ) {
 883     my @actions;
 884
 885     push @actions, ( $self->on_disconnect_call || () );
 886     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 887
 888     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 889
 890     $self->_dbh_rollback unless $self->_dbh_autocommit;
 891
 892     %{ $self->_dbh->{CachedKids} } = ();
 893     $self->_dbh->disconnect;
 894     $self->_dbh(undef);
 895     $self->{_dbh_gen}++;
 896   }
 897 }
 898
 899 =head2 with_deferred_fk_checks
 900
 901 =over 4
 902
 903 =item Arguments: C<$coderef>
 904
 905 =item Return Value: The return value of $coderef
 906
 907 =back
 908
 909 Storage specific method to run the code ref with FK checks deferred or
 910 in MySQL's case disabled entirely.
 911
 912 =cut
 913
 914 # Storage subclasses should override this
 915 sub with_deferred_fk_checks {
 916   my ($self, $sub) = @_;
 917   $sub->();
 918 }
 919
 920 =head2 connected
 921
 922 =over
 923
 924 =item Arguments: none
 925
 926 =item Return Value: 1|0
 927
 928 =back
 929
 930 Verifies that the current database handle is active and ready to execute
 931 an SQL statement (e.g. the connection did not get stale, server is still
 932 answering, etc.) This method is used internally by L</dbh>.
 933
 934 =cut
 935
 936 sub connected {
 937   my $self = shift;
 938   return 0 unless $self->_seems_connected;
 939
 940   #be on the safe side
 941   local $self->_dbh->{RaiseError} = 1;
 942
 943   return $self->_ping;
 944 }
 945
 946 sub _seems_connected {
 947   my $self = shift;
 948
 949   $self->_verify_pid;
 950
 951   my $dbh = $self->_dbh
 952     or return 0;
 953
 954   return $dbh->FETCH('Active');
 955 }
 956
 957 sub _ping {
 958   my $self = shift;
 959
 960   my $dbh = $self->_dbh or return 0;
 961
 962   return $dbh->ping;
 963 }
 964
 965 sub ensure_connected {
 966   my ($self) = @_;
 967
 968   unless ($self->connected) {
 969     $self->_populate_dbh;
 970   }
 971 }
 972
 973 =head2 dbh
 974
 975 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 976 is guaranteed to be healthy by implicitly calling L</connected>, and if
 977 necessary performing a reconnection before returning. Keep in mind that this
 978 is very B<expensive> on some database engines. Consider using L</dbh_do>
 979 instead.
 980
 981 =cut
 982
 983 sub dbh {
 984   my ($self) = @_;
 985
 986   if (not $self->_dbh) {
 987     $self->_populate_dbh;
 988   } else {
 989     $self->ensure_connected;
 990   }
 991   return $self->_dbh;
 992 }
 993
 994 # this is the internal "get dbh or connect (don't check)" method
 995 sub _get_dbh {
 996   my $self = shift;
 997   $self->_verify_pid;
 998   $self->_populate_dbh unless $self->_dbh;
 999   return $self->_dbh;
1000 }
1001
1002 sub sql_maker {
1003   my ($self) = @_;
1004   unless ($self->_sql_maker) {
1005     my $sql_maker_class = $self->sql_maker_class;
1006
1007     my %opts = %{$self->_sql_maker_opts||{}};
1008     my $dialect =
1009       $opts{limit_dialect}
1010         ||
1011       $self->sql_limit_dialect
1012         ||
1013       do {
1014         my $s_class = (ref $self) || $self;
1015         carp (
1016           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1017         . 'have not supplied an explicit limit_dialect in your connection_info. '
1018         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1019         . 'databases but can be (and often is) painfully slow. '
1020         . "Please file an RT ticket against '$s_class' ."
1021         );
1022
1023         'GenericSubQ';
1024       }
1025     ;
1026
1027     my ($quote_char, $name_sep);
1028
1029     if ($opts{quote_names}) {
1030       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1031         my $s_class = (ref $self) || $self;
1032         carp (
1033           "You requested 'quote_names' but your storage class ($s_class) does "
1034         . 'not explicitly define a default sql_quote_char and you have not '
1035         . 'supplied a quote_char as part of your connection_info. DBIC will '
1036         .q{default to the ANSI SQL standard quote '"', which works most of }
1037         . "the time. Please file an RT ticket against '$s_class'."
1038         );
1039
1040         '"'; # RV
1041       };
1042
1043       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1044     }
1045
1046     $self->_sql_maker($sql_maker_class->new(
1047       bindtype=>'columns',
1048       array_datatypes => 1,
1049       limit_dialect => $dialect,
1050       ($quote_char ? (quote_char => $quote_char) : ()),
1051       name_sep => ($name_sep || '.'),
1052       %opts,
1053     ));
1054   }
1055   return $self->_sql_maker;
1056 }
1057
1058 # nothing to do by default
1059 sub _rebless {}
1060 sub _init {}
1061
1062 sub _populate_dbh {
1063   my ($self) = @_;
1064
1065   my @info = @{$self->_dbi_connect_info || []};
1066   $self->_dbh(undef); # in case ->connected failed we might get sent here
1067   $self->_dbh_details({}); # reset everything we know
1068
1069   $self->_dbh($self->_connect(@info));
1070
1071   $self->_conn_pid($$) if $^O ne 'MSWin32'; # on win32 these are in fact threads
1072
1073   $self->_determine_driver;
1074
1075   # Always set the transaction depth on connect, since
1076   #  there is no transaction in progress by definition
1077   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1078
1079   $self->_run_connection_actions unless $self->{_in_determine_driver};
1080 }
1081
1082 sub _run_connection_actions {
1083   my $self = shift;
1084   my @actions;
1085
1086   push @actions, ( $self->on_connect_call || () );
1087   push @actions, $self->_parse_connect_do ('on_connect_do');
1088
1089   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1090 }
1091
1092
1093
1094 sub set_use_dbms_capability {
1095   $_[0]->set_inherited ($_[1], $_[2]);
1096 }
1097
1098 sub get_use_dbms_capability {
1099   my ($self, $capname) = @_;
1100
1101   my $use = $self->get_inherited ($capname);
1102   return defined $use
1103     ? $use
1104     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1105   ;
1106 }
1107
1108 sub set_dbms_capability {
1109   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1110 }
1111
1112 sub get_dbms_capability {
1113   my ($self, $capname) = @_;
1114
1115   my $cap = $self->_dbh_details->{capability}{$capname};
1116
1117   unless (defined $cap) {
1118     if (my $meth = $self->can ("_determine$capname")) {
1119       $cap = $self->$meth ? 1 : 0;
1120     }
1121     else {
1122       $cap = 0;
1123     }
1124
1125     $self->set_dbms_capability ($capname, $cap);
1126   }
1127
1128   return $cap;
1129 }
1130
1131 sub _server_info {
1132   my $self = shift;
1133
1134   my $info;
1135   unless ($info = $self->_dbh_details->{info}) {
1136
1137     $info = {};
1138
1139     my $server_version = try { $self->_get_server_version };
1140
1141     if (defined $server_version) {
1142       $info->{dbms_version} = $server_version;
1143
1144       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1145       my @verparts = split (/\./, $numeric_version);
1146       if (
1147         @verparts
1148           &&
1149         $verparts[0] <= 999
1150       ) {
1151         # consider only up to 3 version parts, iff not more than 3 digits
1152         my @use_parts;
1153         while (@verparts && @use_parts < 3) {
1154           my $p = shift @verparts;
1155           last if $p > 999;
1156           push @use_parts, $p;
1157         }
1158         push @use_parts, 0 while @use_parts < 3;
1159
1160         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1161       }
1162     }
1163
1164     $self->_dbh_details->{info} = $info;
1165   }
1166
1167   return $info;
1168 }
1169
1170 sub _get_server_version {
1171   shift->_dbh_get_info(18);
1172 }
1173
1174 sub _dbh_get_info {
1175   my ($self, $info) = @_;
1176
1177   return try { $self->_get_dbh->get_info($info) } || undef;
1178 }
1179
1180 sub _determine_driver {
1181   my ($self) = @_;
1182
1183   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1184     my $started_connected = 0;
1185     local $self->{_in_determine_driver} = 1;
1186
1187     if (ref($self) eq __PACKAGE__) {
1188       my $driver;
1189       if ($self->_dbh) { # we are connected
1190         $driver = $self->_dbh->{Driver}{Name};
1191         $started_connected = 1;
1192       } else {
1193         # if connect_info is a CODEREF, we have no choice but to connect
1194         if (ref $self->_dbi_connect_info->[0] &&
1195             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1196           $self->_populate_dbh;
1197           $driver = $self->_dbh->{Driver}{Name};
1198         }
1199         else {
1200           # try to use dsn to not require being connected, the driver may still
1201           # force a connection in _rebless to determine version
1202           # (dsn may not be supplied at all if all we do is make a mock-schema)
1203           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1204           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1205           $driver ||= $ENV{DBI_DRIVER};
1206         }
1207       }
1208
1209       if ($driver) {
1210         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1211         if ($self->load_optional_class($storage_class)) {
1212           mro::set_mro($storage_class, 'c3');
1213           bless $self, $storage_class;
1214           $self->_rebless();
1215         }
1216       }
1217     }
1218
1219     $self->_driver_determined(1);
1220
1221     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1222
1223     $self->_init; # run driver-specific initializations
1224
1225     $self->_run_connection_actions
1226         if !$started_connected && defined $self->_dbh;
1227   }
1228 }
1229
1230 sub _do_connection_actions {
1231   my $self          = shift;
1232   my $method_prefix = shift;
1233   my $call          = shift;
1234
1235   if (not ref($call)) {
1236     my $method = $method_prefix . $call;
1237     $self->$method(@_);
1238   } elsif (ref($call) eq 'CODE') {
1239     $self->$call(@_);
1240   } elsif (ref($call) eq 'ARRAY') {
1241     if (ref($call->[0]) ne 'ARRAY') {
1242       $self->_do_connection_actions($method_prefix, $_) for @$call;
1243     } else {
1244       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1245     }
1246   } else {
1247     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1248   }
1249
1250   return $self;
1251 }
1252
1253 sub connect_call_do_sql {
1254   my $self = shift;
1255   $self->_do_query(@_);
1256 }
1257
1258 sub disconnect_call_do_sql {
1259   my $self = shift;
1260   $self->_do_query(@_);
1261 }
1262
1263 # override in db-specific backend when necessary
1264 sub connect_call_datetime_setup { 1 }
1265
1266 sub _do_query {
1267   my ($self, $action) = @_;
1268
1269   if (ref $action eq 'CODE') {
1270     $action = $action->($self);
1271     $self->_do_query($_) foreach @$action;
1272   }
1273   else {
1274     # Most debuggers expect ($sql, @bind), so we need to exclude
1275     # the attribute hash which is the second argument to $dbh->do
1276     # furthermore the bind values are usually to be presented
1277     # as named arrayref pairs, so wrap those here too
1278     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1279     my $sql = shift @do_args;
1280     my $attrs = shift @do_args;
1281     my @bind = map { [ undef, $_ ] } @do_args;
1282
1283     $self->_query_start($sql, \@bind);
1284     $self->_get_dbh->do($sql, $attrs, @do_args);
1285     $self->_query_end($sql, \@bind);
1286   }
1287
1288   return $self;
1289 }
1290
1291 sub _connect {
1292   my ($self, @info) = @_;
1293
1294   $self->throw_exception("You failed to provide any connection info")
1295     if !@info;
1296
1297   my ($old_connect_via, $dbh);
1298
1299   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1300     $old_connect_via = $DBI::connect_via;
1301     $DBI::connect_via = 'connect';
1302   }
1303
1304   try {
1305     if(ref $info[0] eq 'CODE') {
1306       $dbh = $info[0]->();
1307     }
1308     else {
1309       require DBI;
1310       $dbh = DBI->connect(@info);
1311     }
1312
1313     if (!$dbh) {
1314       die $DBI::errstr;
1315     }
1316
1317     unless ($self->unsafe) {
1318
1319       $self->throw_exception(
1320         'Refusing clobbering of {HandleError} installed on externally supplied '
1321        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1322       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1323
1324       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1325       # request, or an external handle. Complain and set anyway
1326       unless ($dbh->{RaiseError}) {
1327         carp( ref $info[0] eq 'CODE'
1328
1329           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1330            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1331            .'attribute has been supplied'
1332
1333           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1334            .'unsafe => 1. Toggling RaiseError back to true'
1335         );
1336
1337         $dbh->{RaiseError} = 1;
1338       }
1339
1340       # this odd anonymous coderef dereference is in fact really
1341       # necessary to avoid the unwanted effect described in perl5
1342       # RT#75792
1343       sub {
1344         my $weak_self = $_[0];
1345         weaken $weak_self;
1346
1347         # the coderef is blessed so we can distinguish it from externally
1348         # supplied handles (which must be preserved)
1349         $_[1]->{HandleError} = bless sub {
1350           if ($weak_self) {
1351             $weak_self->throw_exception("DBI Exception: $_[0]");
1352           }
1353           else {
1354             # the handler may be invoked by something totally out of
1355             # the scope of DBIC
1356             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1357           }
1358         }, '__DBIC__DBH__ERROR__HANDLER__';
1359       }->($self, $dbh);
1360     }
1361   }
1362   catch {
1363     $self->throw_exception("DBI Connection failed: $_")
1364   }
1365   finally {
1366     $DBI::connect_via = $old_connect_via if $old_connect_via;
1367   };
1368
1369   $self->_dbh_autocommit($dbh->{AutoCommit});
1370   $dbh;
1371 }
1372
1373 sub svp_begin {
1374   my ($self, $name) = @_;
1375
1376   $name = $self->_svp_generate_name
1377     unless defined $name;
1378
1379   $self->throw_exception ("You can't use savepoints outside a transaction")
1380     if $self->{transaction_depth} == 0;
1381
1382   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1383     unless $self->can('_svp_begin');
1384
1385   push @{ $self->{savepoints} }, $name;
1386
1387   $self->debugobj->svp_begin($name) if $self->debug;
1388
1389   return $self->_svp_begin($name);
1390 }
1391
1392 sub svp_release {
1393   my ($self, $name) = @_;
1394
1395   $self->throw_exception ("You can't use savepoints outside a transaction")
1396     if $self->{transaction_depth} == 0;
1397
1398   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1399     unless $self->can('_svp_release');
1400
1401   if (defined $name) {
1402     $self->throw_exception ("Savepoint '$name' does not exist")
1403       unless grep { $_ eq $name } @{ $self->{savepoints} };
1404
1405     # Dig through the stack until we find the one we are releasing.  This keeps
1406     # the stack up to date.
1407     my $svp;
1408
1409     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1410   } else {
1411     $name = pop @{ $self->{savepoints} };
1412   }
1413
1414   $self->debugobj->svp_release($name) if $self->debug;
1415
1416   return $self->_svp_release($name);
1417 }
1418
1419 sub svp_rollback {
1420   my ($self, $name) = @_;
1421
1422   $self->throw_exception ("You can't use savepoints outside a transaction")
1423     if $self->{transaction_depth} == 0;
1424
1425   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1426     unless $self->can('_svp_rollback');
1427
1428   if (defined $name) {
1429       # If they passed us a name, verify that it exists in the stack
1430       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1431           $self->throw_exception("Savepoint '$name' does not exist!");
1432       }
1433
1434       # Dig through the stack until we find the one we are releasing.  This keeps
1435       # the stack up to date.
1436       while(my $s = pop(@{ $self->{savepoints} })) {
1437           last if($s eq $name);
1438       }
1439       # Add the savepoint back to the stack, as a rollback doesn't remove the
1440       # named savepoint, only everything after it.
1441       push(@{ $self->{savepoints} }, $name);
1442   } else {
1443       # We'll assume they want to rollback to the last savepoint
1444       $name = $self->{savepoints}->[-1];
1445   }
1446
1447   $self->debugobj->svp_rollback($name) if $self->debug;
1448
1449   return $self->_svp_rollback($name);
1450 }
1451
1452 sub _svp_generate_name {
1453   my ($self) = @_;
1454   return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1455 }
1456
1457 sub txn_begin {
1458   my $self = shift;
1459
1460   # this means we have not yet connected and do not know the AC status
1461   # (e.g. coderef $dbh)
1462   if (! defined $self->_dbh_autocommit) {
1463     $self->ensure_connected;
1464   }
1465   # otherwise re-connect on pid changes, so
1466   # that the txn_depth is adjusted properly
1467   # the lightweight _get_dbh is good enoug here
1468   # (only superficial handle check, no pings)
1469   else {
1470     $self->_get_dbh;
1471   }
1472
1473   if($self->transaction_depth == 0) {
1474     $self->debugobj->txn_begin()
1475       if $self->debug;
1476     $self->_dbh_begin_work;
1477   }
1478   elsif ($self->auto_savepoint) {
1479     $self->svp_begin;
1480   }
1481   $self->{transaction_depth}++;
1482 }
1483
1484 sub _dbh_begin_work {
1485   my $self = shift;
1486
1487   # if the user is utilizing txn_do - good for him, otherwise we need to
1488   # ensure that the $dbh is healthy on BEGIN.
1489   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1490   # will be replaced by a failure of begin_work itself (which will be
1491   # then retried on reconnect)
1492   if ($self->{_in_dbh_do}) {
1493     $self->_dbh->begin_work;
1494   } else {
1495     $self->dbh_do(sub { $_[1]->begin_work });
1496   }
1497 }
1498
1499 sub txn_commit {
1500   my $self = shift;
1501   if (! $self->_dbh) {
1502     $self->throw_exception('cannot COMMIT on a disconnected handle');
1503   }
1504   elsif ($self->{transaction_depth} == 1) {
1505     $self->debugobj->txn_commit()
1506       if ($self->debug);
1507     $self->_dbh_commit;
1508     $self->{transaction_depth} = 0
1509       if $self->_dbh_autocommit;
1510   }
1511   elsif($self->{transaction_depth} > 1) {
1512     $self->{transaction_depth}--;
1513     $self->svp_release
1514       if $self->auto_savepoint;
1515   }
1516   elsif (! $self->_dbh->FETCH('AutoCommit') ) {
1517
1518     carp "Storage transaction_depth $self->{transaction_depth} does not match "
1519         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1520
1521     $self->debugobj->txn_commit()
1522       if ($self->debug);
1523     $self->_dbh_commit;
1524     $self->{transaction_depth} = 0
1525       if $self->_dbh_autocommit;
1526   }
1527   else {
1528     $self->throw_exception( 'Refusing to commit without a started transaction' );
1529   }
1530 }
1531
1532 sub _dbh_commit {
1533   my $self = shift;
1534   my $dbh  = $self->_dbh
1535     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1536   $dbh->commit;
1537 }
1538
1539 sub txn_rollback {
1540   my $self = shift;
1541   my $dbh = $self->_dbh;
1542   try {
1543     if ($self->{transaction_depth} == 1) {
1544       $self->debugobj->txn_rollback()
1545         if ($self->debug);
1546       $self->{transaction_depth} = 0
1547         if $self->_dbh_autocommit;
1548       $self->_dbh_rollback;
1549     }
1550     elsif($self->{transaction_depth} > 1) {
1551       $self->{transaction_depth}--;
1552       if ($self->auto_savepoint) {
1553         $self->svp_rollback;
1554         $self->svp_release;
1555       }
1556     }
1557     else {
1558       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1559     }
1560   }
1561   catch {
1562     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1563
1564     if ($_ !~ /$exception_class/) {
1565       # ensure that a failed rollback resets the transaction depth
1566       $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1567     }
1568
1569     $self->throw_exception($_)
1570   };
1571 }
1572
1573 sub _dbh_rollback {
1574   my $self = shift;
1575   my $dbh  = $self->_dbh
1576     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1577   $dbh->rollback;
1578 }
1579
1580 # This used to be the top-half of _execute.  It was split out to make it
1581 #  easier to override in NoBindVars without duping the rest.  It takes up
1582 #  all of _execute's args, and emits $sql, @bind.
1583 sub _prep_for_execute {
1584   my ($self, $op, $ident, $args) = @_;
1585
1586   my ($sql, @bind) = $self->sql_maker->$op(
1587     blessed($ident) ? $ident->from : $ident,
1588     @$args,
1589   );
1590
1591   my (@final_bind, $colinfos);
1592   my $resolve_bindinfo = sub {
1593     $colinfos ||= $self->_resolve_column_info($ident);
1594     if (my $col = $_[1]->{dbic_colname}) {
1595       $_[1]->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1596         if $colinfos->{$col}{data_type};
1597       $_[1]->{sqlt_size} ||= $colinfos->{$col}{size}
1598         if $colinfos->{$col}{size};
1599     }
1600     $_[1];
1601   };
1602
1603   for my $e (@{$args->[2]{bind}||[]}, @bind) {
1604     push @final_bind, [ do {
1605       if (ref $e ne 'ARRAY') {
1606         ({}, $e)
1607       }
1608       elsif (! defined $e->[0]) {
1609         ({}, $e->[1])
1610       }
1611       elsif (ref $e->[0] eq 'HASH') {
1612         (
1613           (first { $e->[0]{$_} } qw/dbd_attrs sqlt_datatype/) ? $e->[0] : $self->$resolve_bindinfo($e->[0]),
1614           $e->[1]
1615         )
1616       }
1617       elsif (ref $e->[0] eq 'SCALAR') {
1618         ( { sqlt_datatype => ${$e->[0]} }, $e->[1] )
1619       }
1620       else {
1621         ( $self->$resolve_bindinfo({ dbic_colname => $e->[0] }), $e->[1] )
1622       }
1623     }];
1624   }
1625
1626   ($sql, \@final_bind);
1627 }
1628
1629 sub _format_for_trace {
1630   #my ($self, $bind) = @_;
1631
1632   ### Turn @bind from something like this:
1633   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1634   ### to this:
1635   ###   ( "'1'", "'3'" )
1636
1637   map {
1638     defined( $_ && $_->[1] )
1639       ? qq{'$_->[1]'}
1640       : q{NULL}
1641   } @{$_[1] || []};
1642 }
1643
1644 sub _query_start {
1645   my ( $self, $sql, $bind ) = @_;
1646
1647   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1648     if $self->debug;
1649 }
1650
1651 sub _query_end {
1652   my ( $self, $sql, $bind ) = @_;
1653
1654   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1655     if $self->debug;
1656 }
1657
1658 my $sba_compat;
1659 sub _dbi_attrs_for_bind {
1660   my ($self, $ident, $bind) = @_;
1661
1662   if (! defined $sba_compat) {
1663     $self->_determine_driver;
1664     $sba_compat = $self->can('source_bind_attributes') == \&source_bind_attributes
1665       ? 0
1666       : 1
1667     ;
1668   }
1669
1670   my $sba_attrs;
1671   if ($sba_compat) {
1672     my $class = ref $self;
1673     carp_unique (
1674       "The source_bind_attributes() override in $class relies on a deprecated codepath. "
1675      .'You are strongly advised to switch your code to override bind_attribute_by_datatype() '
1676      .'instead. This legacy compat shim will also disappear some time before DBIC 0.09'
1677     );
1678
1679     my $sba_attrs = $self->source_bind_attributes
1680   }
1681
1682   my @attrs;
1683
1684   for (map { $_->[0] } @$bind) {
1685     push @attrs, do {
1686       if ($_->{dbd_attrs}) {
1687         $_->{dbd_attrs}
1688       }
1689       elsif($_->{sqlt_datatype}) {
1690         $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1691       }
1692       elsif ($sba_attrs and $_->{dbic_colname}) {
1693         $sba_attrs->{$_->{dbic_colname}} || undef;
1694       }
1695       else {
1696         undef;  # always push something at this position
1697       }
1698     }
1699   }
1700
1701   return \@attrs;
1702 }
1703
1704 sub _execute {
1705   my ($self, $op, $ident, @args) = @_;
1706
1707   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1708
1709   shift->dbh_do(    # retry over disconnects
1710     '_dbh_execute',
1711     $sql,
1712     $bind,
1713     $self->_dbi_attrs_for_bind($ident, $bind)
1714   );
1715 }
1716
1717 sub _dbh_execute {
1718   my ($self, undef, $sql, $bind, $bind_attrs) = @_;
1719
1720   $self->_query_start( $sql, $bind );
1721   my $sth = $self->_sth($sql);
1722
1723   for my $i (0 .. $#$bind) {
1724     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1725       $sth->bind_param_inout(
1726         $i + 1, # bind params counts are 1-based
1727         $bind->[$i][1],
1728         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1729         $bind_attrs->[$i],
1730       );
1731     }
1732     else {
1733       $sth->bind_param(
1734         $i + 1,
1735         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1736           ? "$bind->[$i][1]"
1737           : $bind->[$i][1]
1738         ,
1739         $bind_attrs->[$i],
1740       );
1741     }
1742   }
1743
1744   # Can this fail without throwing an exception anyways???
1745   my $rv = $sth->execute();
1746   $self->throw_exception(
1747     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1748   ) if !$rv;
1749
1750   $self->_query_end( $sql, $bind );
1751
1752   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1753 }
1754
1755 sub _prefetch_autovalues {
1756   my ($self, $source, $to_insert) = @_;
1757
1758   my $colinfo = $source->columns_info;
1759
1760   my %values;
1761   for my $col (keys %$colinfo) {
1762     if (
1763       $colinfo->{$col}{auto_nextval}
1764         and
1765       (
1766         ! exists $to_insert->{$col}
1767           or
1768         ref $to_insert->{$col} eq 'SCALAR'
1769       )
1770     ) {
1771       $values{$col} = $self->_sequence_fetch(
1772         'NEXTVAL',
1773         ( $colinfo->{$col}{sequence} ||=
1774             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1775         ),
1776       );
1777     }
1778   }
1779
1780   \%values;
1781 }
1782
1783 sub insert {
1784   my ($self, $source, $to_insert) = @_;
1785
1786   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1787
1788   # fuse the values
1789   $to_insert = { %$to_insert, %$prefetched_values };
1790
1791   # list of primary keys we try to fetch from the database
1792   # both not-exsists and scalarrefs are considered
1793   my %fetch_pks;
1794   for ($source->primary_columns) {
1795     $fetch_pks{$_} = scalar keys %fetch_pks  # so we can preserve order for prettyness
1796       if ! exists $to_insert->{$_} or ref $to_insert->{$_} eq 'SCALAR';
1797   }
1798
1799   my ($sqla_opts, @ir_container);
1800   if ($self->_use_insert_returning) {
1801
1802     # retain order as declared in the resultsource
1803     for (sort { $fetch_pks{$a} <=> $fetch_pks{$b} } keys %fetch_pks ) {
1804       push @{$sqla_opts->{returning}}, $_;
1805       $sqla_opts->{returning_container} = \@ir_container
1806         if $self->_use_insert_returning_bound;
1807     }
1808   }
1809
1810   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1811
1812   my %returned_cols;
1813
1814   if (my $retlist = $sqla_opts->{returning}) {
1815     @ir_container = try {
1816       local $SIG{__WARN__} = sub {};
1817       my @r = $sth->fetchrow_array;
1818       $sth->finish;
1819       @r;
1820     } unless @ir_container;
1821
1822     @returned_cols{@$retlist} = @ir_container if @ir_container;
1823   }
1824
1825   return { %$prefetched_values, %returned_cols };
1826 }
1827
1828
1829 ## Currently it is assumed that all values passed will be "normal", i.e. not
1830 ## scalar refs, or at least, all the same type as the first set, the statement is
1831 ## only prepped once.
1832 sub insert_bulk {
1833   my ($self, $source, $cols, $data) = @_;
1834
1835   my %colvalues;
1836   @colvalues{@$cols} = (0..$#$cols);
1837
1838   for my $i (0..$#$cols) {
1839     my $first_val = $data->[0][$i];
1840     next unless ref $first_val eq 'SCALAR';
1841
1842     $colvalues{ $cols->[$i] } = $first_val;
1843   }
1844
1845   # check for bad data and stringify stringifiable objects
1846   my $bad_slice = sub {
1847     my ($msg, $col_idx, $slice_idx) = @_;
1848     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1849       $msg,
1850       $cols->[$col_idx],
1851       do {
1852         require Data::Dumper::Concise;
1853         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1854         Data::Dumper::Concise::Dumper ({
1855           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1856         }),
1857       }
1858     );
1859   };
1860
1861   for my $datum_idx (0..$#$data) {
1862     my $datum = $data->[$datum_idx];
1863
1864     for my $col_idx (0..$#$cols) {
1865       my $val            = $datum->[$col_idx];
1866       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1867       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1868
1869       if ($is_literal_sql) {
1870         if (not ref $val) {
1871           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1872         }
1873         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1874           $bad_slice->("$reftype reference found where literal SQL expected",
1875             $col_idx, $datum_idx);
1876         }
1877         elsif ($$val ne $$sqla_bind){
1878           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1879             $col_idx, $datum_idx);
1880         }
1881       }
1882       elsif (my $reftype = ref $val) {
1883         require overload;
1884         if (overload::Method($val, '""')) {
1885           $datum->[$col_idx] = "".$val;
1886         }
1887         else {
1888           $bad_slice->("$reftype reference found where bind expected",
1889             $col_idx, $datum_idx);
1890         }
1891       }
1892     }
1893   }
1894
1895   my ($sql, $bind) = $self->_prep_for_execute (
1896     'insert', $source, [\%colvalues]
1897   );
1898
1899   if (! @$bind) {
1900     # if the bindlist is empty - make sure all "values" are in fact
1901     # literal scalarrefs. If not the case this means the storage ate
1902     # them away (e.g. the NoBindVars component) and interpolated them
1903     # directly into the SQL. This obviosly can't be good for multi-inserts
1904
1905     $self->throw_exception('Cannot insert_bulk without support for placeholders')
1906       if first { ref $_ ne 'SCALAR' } values %colvalues;
1907   }
1908
1909   # neither _execute_array, nor _execute_inserts_with_no_binds are
1910   # atomic (even if _execute _array is a single call). Thus a safety
1911   # scope guard
1912   my $guard = $self->txn_scope_guard;
1913
1914   $self->_query_start( $sql, @$bind ? [[undef => '__BULK_INSERT__' ]] : () );
1915   my $sth = $self->_sth($sql);
1916   my $rv = do {
1917     if (@$bind) {
1918       #@bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1919       $self->_execute_array( $source, $sth, $bind, $cols, $data );
1920     }
1921     else {
1922       # bind_param_array doesn't work if there are no binds
1923       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1924     }
1925   };
1926
1927   $self->_query_end( $sql, @$bind ? [[ undef => '__BULK_INSERT__' ]] : () );
1928
1929   $guard->commit;
1930
1931   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1932 }
1933
1934 sub _execute_array {
1935   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1936
1937   ## This must be an arrayref, else nothing works!
1938   my $tuple_status = [];
1939
1940   # $bind contains colnames as keys and dbic-col-index as values
1941   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $bind);
1942
1943   # Bind the values by column slices
1944   for my $i (0 .. $#$bind) {
1945     my $dbic_data_index = $bind->[$i][1];
1946
1947     $sth->bind_param_array(
1948       $i+1, # DBI bind indexes are 1-based
1949       [ map { $_->[$dbic_data_index] } @$data ],
1950       defined $bind_attrs->[$i] ? $bind_attrs->[$i] : (), # some DBDs throw up when given an undef
1951     );
1952   }
1953
1954   my ($rv, $err);
1955   try {
1956     $rv = $self->_dbh_execute_array($sth, $tuple_status, @extra);
1957   }
1958   catch {
1959     $err = shift;
1960   };
1961
1962   # Not all DBDs are create equal. Some throw on error, some return
1963   # an undef $rv, and some set $sth->err - try whatever we can
1964   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
1965     ! defined $err
1966       and
1967     ( !defined $rv or $sth->err )
1968   );
1969
1970   # Statement must finish even if there was an exception.
1971   try {
1972     $sth->finish
1973   }
1974   catch {
1975     $err = shift unless defined $err
1976   };
1977
1978   if (defined $err) {
1979     my $i = 0;
1980     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1981
1982     $self->throw_exception("Unexpected populate error: $err")
1983       if ($i > $#$tuple_status);
1984
1985     require Data::Dumper::Concise;
1986     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1987       ($tuple_status->[$i][1] || $err),
1988       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
1989     );
1990   }
1991
1992   return $rv;
1993 }
1994
1995 sub _dbh_execute_array {
1996     my ($self, $sth, $tuple_status, @extra) = @_;
1997
1998     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1999 }
2000
2001 sub _dbh_execute_inserts_with_no_binds {
2002   my ($self, $sth, $count) = @_;
2003
2004   my $err;
2005   try {
2006     my $dbh = $self->_get_dbh;
2007     local $dbh->{RaiseError} = 1;
2008     local $dbh->{PrintError} = 0;
2009
2010     $sth->execute foreach 1..$count;
2011   }
2012   catch {
2013     $err = shift;
2014   };
2015
2016   # Make sure statement is finished even if there was an exception.
2017   try {
2018     $sth->finish
2019   }
2020   catch {
2021     $err = shift unless defined $err;
2022   };
2023
2024   $self->throw_exception($err) if defined $err;
2025
2026   return $count;
2027 }
2028
2029 sub update {
2030   #my ($self, $source, @args) = @_;
2031   shift->_execute('update', @_);
2032 }
2033
2034
2035 sub delete {
2036   #my ($self, $source, @args) = @_;
2037   shift->_execute('delete', @_);
2038 }
2039
2040 # We were sent here because the $rs contains a complex search
2041 # which will require a subquery to select the correct rows
2042 # (i.e. joined or limited resultsets, or non-introspectable conditions)
2043 #
2044 # Generating a single PK column subquery is trivial and supported
2045 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
2046 # Look at _multipk_update_delete()
2047 sub _subq_update_delete {
2048   my $self = shift;
2049   my ($rs, $op, $values) = @_;
2050
2051   my $rsrc = $rs->result_source;
2052
2053   # quick check if we got a sane rs on our hands
2054   my @pcols = $rsrc->_pri_cols;
2055
2056   my $sel = $rs->_resolved_attrs->{select};
2057   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
2058
2059   if (
2060       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
2061         ne
2062       join ("\x00", sort @$sel )
2063   ) {
2064     $self->throw_exception (
2065       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
2066     );
2067   }
2068
2069   if (@pcols == 1) {
2070     return $self->$op (
2071       $rsrc,
2072       $op eq 'update' ? $values : (),
2073       { $pcols[0] => { -in => $rs->as_query } },
2074     );
2075   }
2076
2077   else {
2078     return $self->_multipk_update_delete (@_);
2079   }
2080 }
2081
2082 # ANSI SQL does not provide a reliable way to perform a multicol-PK
2083 # resultset update/delete involving subqueries. So by default resort
2084 # to simple (and inefficient) delete_all style per-row opearations,
2085 # while allowing specific storages to override this with a faster
2086 # implementation.
2087 #
2088 sub _multipk_update_delete {
2089   return shift->_per_row_update_delete (@_);
2090 }
2091
2092 # This is the default loop used to delete/update rows for multi PK
2093 # resultsets, and used by mysql exclusively (because it can't do anything
2094 # else).
2095 #
2096 # We do not use $row->$op style queries, because resultset update/delete
2097 # is not expected to cascade (this is what delete_all/update_all is for).
2098 #
2099 # There should be no race conditions as the entire operation is rolled
2100 # in a transaction.
2101 #
2102 sub _per_row_update_delete {
2103   my $self = shift;
2104   my ($rs, $op, $values) = @_;
2105
2106   my $rsrc = $rs->result_source;
2107   my @pcols = $rsrc->_pri_cols;
2108
2109   my $guard = $self->txn_scope_guard;
2110
2111   # emulate the return value of $sth->execute for non-selects
2112   my $row_cnt = '0E0';
2113
2114   my $subrs_cur = $rs->cursor;
2115   my @all_pk = $subrs_cur->all;
2116   for my $pks ( @all_pk) {
2117
2118     my $cond;
2119     for my $i (0.. $#pcols) {
2120       $cond->{$pcols[$i]} = $pks->[$i];
2121     }
2122
2123     $self->$op (
2124       $rsrc,
2125       $op eq 'update' ? $values : (),
2126       $cond,
2127     );
2128
2129     $row_cnt++;
2130   }
2131
2132   $guard->commit;
2133
2134   return $row_cnt;
2135 }
2136
2137 sub _select {
2138   my $self = shift;
2139   $self->_execute($self->_select_args(@_));
2140 }
2141
2142 sub _select_args_to_query {
2143   my $self = shift;
2144
2145   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2146   #  = $self->_select_args($ident, $select, $cond, $attrs);
2147   my ($op, $ident, @args) =
2148     $self->_select_args(@_);
2149
2150   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2151   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $ident, \@args);
2152   $prepared_bind ||= [];
2153
2154   return wantarray
2155     ? ($sql, $prepared_bind)
2156     : \[ "($sql)", @$prepared_bind ]
2157   ;
2158 }
2159
2160 sub _select_args {
2161   my ($self, $ident, $select, $where, $attrs) = @_;
2162
2163   my $sql_maker = $self->sql_maker;
2164   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2165
2166   $attrs = {
2167     %$attrs,
2168     select => $select,
2169     from => $ident,
2170     where => $where,
2171     $rs_alias && $alias2source->{$rs_alias}
2172       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2173       : ()
2174     ,
2175   };
2176
2177   # Sanity check the attributes (SQLMaker does it too, but
2178   # in case of a software_limit we'll never reach there)
2179   if (defined $attrs->{offset}) {
2180     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2181       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2182   }
2183
2184   if (defined $attrs->{rows}) {
2185     $self->throw_exception("The rows attribute must be a positive integer if present")
2186       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2187   }
2188   elsif ($attrs->{offset}) {
2189     # MySQL actually recommends this approach.  I cringe.
2190     $attrs->{rows} = $sql_maker->__max_int;
2191   }
2192
2193   my @limit;
2194
2195   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2196   # storage, unless software limit was requested
2197   if (
2198     #limited has_many
2199     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2200        ||
2201     # grouped prefetch (to satisfy group_by == select)
2202     ( $attrs->{group_by}
2203         &&
2204       @{$attrs->{group_by}}
2205         &&
2206       $attrs->{_prefetch_selector_range}
2207     )
2208   ) {
2209     ($ident, $select, $where, $attrs)
2210       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2211   }
2212   elsif (! $attrs->{software_limit} ) {
2213     push @limit, (
2214       $attrs->{rows} || (),
2215       $attrs->{offset} || (),
2216     );
2217   }
2218
2219   # try to simplify the joinmap further (prune unreferenced type-single joins)
2220   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2221
2222 ###
2223   # This would be the point to deflate anything found in $where
2224   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2225   # expect a row object. And all we have is a resultsource (it is trivial
2226   # to extract deflator coderefs via $alias2source above).
2227   #
2228   # I don't see a way forward other than changing the way deflators are
2229   # invoked, and that's just bad...
2230 ###
2231
2232   return ('select', $ident, $select, $where, $attrs, @limit);
2233 }
2234
2235 # Returns a counting SELECT for a simple count
2236 # query. Abstracted so that a storage could override
2237 # this to { count => 'firstcol' } or whatever makes
2238 # sense as a performance optimization
2239 sub _count_select {
2240   #my ($self, $source, $rs_attrs) = @_;
2241   return { count => '*' };
2242 }
2243
2244 sub source_bind_attributes {
2245   shift->throw_exception(
2246     'source_bind_attributes() was never meant to be a callable public method - '
2247    .'please contact the DBIC dev-team and describe your use case so that a reasonable '
2248    .'solution can be provided'
2249    ."\nhttp://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT"
2250   );
2251 }
2252
2253 =head2 select
2254
2255 =over 4
2256
2257 =item Arguments: $ident, $select, $condition, $attrs
2258
2259 =back
2260
2261 Handle a SQL select statement.
2262
2263 =cut
2264
2265 sub select {
2266   my $self = shift;
2267   my ($ident, $select, $condition, $attrs) = @_;
2268   return $self->cursor_class->new($self, \@_, $attrs);
2269 }
2270
2271 sub select_single {
2272   my $self = shift;
2273   my ($rv, $sth, @bind) = $self->_select(@_);
2274   my @row = $sth->fetchrow_array;
2275   my @nextrow = $sth->fetchrow_array if @row;
2276   if(@row && @nextrow) {
2277     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2278   }
2279   # Need to call finish() to work round broken DBDs
2280   $sth->finish();
2281   return @row;
2282 }
2283
2284 =head2 sql_limit_dialect
2285
2286 This is an accessor for the default SQL limit dialect used by a particular
2287 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2288 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2289 see L<DBIx::Class::SQLMaker::LimitDialects>.
2290
2291 =head2 sth
2292
2293 =over 4
2294
2295 =item Arguments: $sql
2296
2297 =back
2298
2299 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2300
2301 =cut
2302
2303 sub _dbh_sth {
2304   my ($self, $dbh, $sql) = @_;
2305
2306   # 3 is the if_active parameter which avoids active sth re-use
2307   my $sth = $self->disable_sth_caching
2308     ? $dbh->prepare($sql)
2309     : $dbh->prepare_cached($sql, {}, 3);
2310
2311   # XXX You would think RaiseError would make this impossible,
2312   #  but apparently that's not true :(
2313   $self->throw_exception(
2314     $dbh->errstr
2315       ||
2316     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2317             .'an exception and/or setting $dbh->errstr',
2318       length ($sql) > 20
2319         ? substr($sql, 0, 20) . '...'
2320         : $sql
2321       ,
2322       'DBD::' . $dbh->{Driver}{Name},
2323     )
2324   ) if !$sth;
2325
2326   $sth;
2327 }
2328
2329 sub sth {
2330   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2331   shift->_sth(@_);
2332 }
2333
2334 sub _sth {
2335   my ($self, $sql) = @_;
2336   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2337 }
2338
2339 sub _dbh_columns_info_for {
2340   my ($self, $dbh, $table) = @_;
2341
2342   if ($dbh->can('column_info')) {
2343     my %result;
2344     my $caught;
2345     try {
2346       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2347       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2348       $sth->execute();
2349       while ( my $info = $sth->fetchrow_hashref() ){
2350         my %column_info;
2351         $column_info{data_type}   = $info->{TYPE_NAME};
2352         $column_info{size}      = $info->{COLUMN_SIZE};
2353         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2354         $column_info{default_value} = $info->{COLUMN_DEF};
2355         my $col_name = $info->{COLUMN_NAME};
2356         $col_name =~ s/^\"(.*)\"$/$1/;
2357
2358         $result{$col_name} = \%column_info;
2359       }
2360     } catch {
2361       $caught = 1;
2362     };
2363     return \%result if !$caught && scalar keys %result;
2364   }
2365
2366   my %result;
2367   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2368   $sth->execute;
2369   my @columns = @{$sth->{NAME_lc}};
2370   for my $i ( 0 .. $#columns ){
2371     my %column_info;
2372     $column_info{data_type} = $sth->{TYPE}->[$i];
2373     $column_info{size} = $sth->{PRECISION}->[$i];
2374     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2375
2376     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2377       $column_info{data_type} = $1;
2378       $column_info{size}    = $2;
2379     }
2380
2381     $result{$columns[$i]} = \%column_info;
2382   }
2383   $sth->finish;
2384
2385   foreach my $col (keys %result) {
2386     my $colinfo = $result{$col};
2387     my $type_num = $colinfo->{data_type};
2388     my $type_name;
2389     if(defined $type_num && $dbh->can('type_info')) {
2390       my $type_info = $dbh->type_info($type_num);
2391       $type_name = $type_info->{TYPE_NAME} if $type_info;
2392       $colinfo->{data_type} = $type_name if $type_name;
2393     }
2394   }
2395
2396   return \%result;
2397 }
2398
2399 sub columns_info_for {
2400   my ($self, $table) = @_;
2401   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2402 }
2403
2404 =head2 last_insert_id
2405
2406 Return the row id of the last insert.
2407
2408 =cut
2409
2410 sub _dbh_last_insert_id {
2411     my ($self, $dbh, $source, $col) = @_;
2412
2413     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2414
2415     return $id if defined $id;
2416
2417     my $class = ref $self;
2418     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2419 }
2420
2421 sub last_insert_id {
2422   my $self = shift;
2423   $self->_dbh_last_insert_id ($self->_dbh, @_);
2424 }
2425
2426 =head2 _native_data_type
2427
2428 =over 4
2429
2430 =item Arguments: $type_name
2431
2432 =back
2433
2434 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2435 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2436 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2437
2438 The default implementation returns C<undef>, implement in your Storage driver if
2439 you need this functionality.
2440
2441 Should map types from other databases to the native RDBMS type, for example
2442 C<VARCHAR2> to C<VARCHAR>.
2443
2444 Types with modifiers should map to the underlying data type. For example,
2445 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2446
2447 Composite types should map to the container type, for example
2448 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2449
2450 =cut
2451
2452 sub _native_data_type {
2453   #my ($self, $data_type) = @_;
2454   return undef
2455 }
2456
2457 # Check if placeholders are supported at all
2458 sub _determine_supports_placeholders {
2459   my $self = shift;
2460   my $dbh  = $self->_get_dbh;
2461
2462   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2463   # but it is inaccurate more often than not
2464   return try {
2465     local $dbh->{PrintError} = 0;
2466     local $dbh->{RaiseError} = 1;
2467     $dbh->do('select ?', {}, 1);
2468     1;
2469   }
2470   catch {
2471     0;
2472   };
2473 }
2474
2475 # Check if placeholders bound to non-string types throw exceptions
2476 #
2477 sub _determine_supports_typeless_placeholders {
2478   my $self = shift;
2479   my $dbh  = $self->_get_dbh;
2480
2481   return try {
2482     local $dbh->{PrintError} = 0;
2483     local $dbh->{RaiseError} = 1;
2484     # this specifically tests a bind that is NOT a string
2485     $dbh->do('select 1 where 1 = ?', {}, 1);
2486     1;
2487   }
2488   catch {
2489     0;
2490   };
2491 }
2492
2493 =head2 sqlt_type
2494
2495 Returns the database driver name.
2496
2497 =cut
2498
2499 sub sqlt_type {
2500   shift->_get_dbh->{Driver}->{Name};
2501 }
2502
2503 =head2 bind_attribute_by_data_type
2504
2505 Given a datatype from column info, returns a database specific bind
2506 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2507 let the database planner just handle it.
2508
2509 Generally only needed for special case column types, like bytea in postgres.
2510
2511 =cut
2512
2513 sub bind_attribute_by_data_type {
2514     return;
2515 }
2516
2517 =head2 is_datatype_numeric
2518
2519 Given a datatype from column_info, returns a boolean value indicating if
2520 the current RDBMS considers it a numeric value. This controls how
2521 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2522 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2523 be performed instead of the usual C<eq>.
2524
2525 =cut
2526
2527 sub is_datatype_numeric {
2528   #my ($self, $dt) = @_;
2529
2530   return 0 unless $_[1];
2531
2532   $_[1] =~ /^ (?:
2533     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2534   ) $/ix;
2535 }
2536
2537
2538 =head2 create_ddl_dir
2539
2540 =over 4
2541
2542 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2543
2544 =back
2545
2546 Creates a SQL file based on the Schema, for each of the specified
2547 database engines in C<\@databases> in the given directory.
2548 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2549
2550 Given a previous version number, this will also create a file containing
2551 the ALTER TABLE statements to transform the previous schema into the
2552 current one. Note that these statements may contain C<DROP TABLE> or
2553 C<DROP COLUMN> statements that can potentially destroy data.
2554
2555 The file names are created using the C<ddl_filename> method below, please
2556 override this method in your schema if you would like a different file
2557 name format. For the ALTER file, the same format is used, replacing
2558 $version in the name with "$preversion-$version".
2559
2560 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2561 The most common value for this would be C<< { add_drop_table => 1 } >>
2562 to have the SQL produced include a C<DROP TABLE> statement for each table
2563 created. For quoting purposes supply C<quote_table_names> and
2564 C<quote_field_names>.
2565
2566 If no arguments are passed, then the following default values are assumed:
2567
2568 =over 4
2569
2570 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2571
2572 =item version    - $schema->schema_version
2573
2574 =item directory  - './'
2575
2576 =item preversion - <none>
2577
2578 =back
2579
2580 By default, C<\%sqlt_args> will have
2581
2582  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2583
2584 merged with the hash passed in. To disable any of those features, pass in a
2585 hashref like the following
2586
2587  { ignore_constraint_names => 0, # ... other options }
2588
2589
2590 WARNING: You are strongly advised to check all SQL files created, before applying
2591 them.
2592
2593 =cut
2594
2595 sub create_ddl_dir {
2596   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2597
2598   unless ($dir) {
2599     carp "No directory given, using ./\n";
2600     $dir = './';
2601   } else {
2602       -d $dir
2603         or
2604       (require File::Path and File::Path::make_path ("$dir"))  # make_path does not like objects (i.e. Path::Class::Dir)
2605         or
2606       $self->throw_exception(
2607         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2608       );
2609   }
2610
2611   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2612
2613   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2614   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2615
2616   my $schema_version = $schema->schema_version || '1.x';
2617   $version ||= $schema_version;
2618
2619   $sqltargs = {
2620     add_drop_table => 1,
2621     ignore_constraint_names => 1,
2622     ignore_index_names => 1,
2623     %{$sqltargs || {}}
2624   };
2625
2626   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2627     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2628   }
2629
2630   my $sqlt = SQL::Translator->new( $sqltargs );
2631
2632   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2633   my $sqlt_schema = $sqlt->translate({ data => $schema })
2634     or $self->throw_exception ($sqlt->error);
2635
2636   foreach my $db (@$databases) {
2637     $sqlt->reset();
2638     $sqlt->{schema} = $sqlt_schema;
2639     $sqlt->producer($db);
2640
2641     my $file;
2642     my $filename = $schema->ddl_filename($db, $version, $dir);
2643     if (-e $filename && ($version eq $schema_version )) {
2644       # if we are dumping the current version, overwrite the DDL
2645       carp "Overwriting existing DDL file - $filename";
2646       unlink($filename);
2647     }
2648
2649     my $output = $sqlt->translate;
2650     if(!$output) {
2651       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2652       next;
2653     }
2654     if(!open($file, ">$filename")) {
2655       $self->throw_exception("Can't open $filename for writing ($!)");
2656       next;
2657     }
2658     print $file $output;
2659     close($file);
2660
2661     next unless ($preversion);
2662
2663     require SQL::Translator::Diff;
2664
2665     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2666     if(!-e $prefilename) {
2667       carp("No previous schema file found ($prefilename)");
2668       next;
2669     }
2670
2671     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2672     if(-e $difffile) {
2673       carp("Overwriting existing diff file - $difffile");
2674       unlink($difffile);
2675     }
2676
2677     my $source_schema;
2678     {
2679       my $t = SQL::Translator->new($sqltargs);
2680       $t->debug( 0 );
2681       $t->trace( 0 );
2682
2683       $t->parser( $db )
2684         or $self->throw_exception ($t->error);
2685
2686       my $out = $t->translate( $prefilename )
2687         or $self->throw_exception ($t->error);
2688
2689       $source_schema = $t->schema;
2690
2691       $source_schema->name( $prefilename )
2692         unless ( $source_schema->name );
2693     }
2694
2695     # The "new" style of producers have sane normalization and can support
2696     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2697     # And we have to diff parsed SQL against parsed SQL.
2698     my $dest_schema = $sqlt_schema;
2699
2700     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2701       my $t = SQL::Translator->new($sqltargs);
2702       $t->debug( 0 );
2703       $t->trace( 0 );
2704
2705       $t->parser( $db )
2706         or $self->throw_exception ($t->error);
2707
2708       my $out = $t->translate( $filename )
2709         or $self->throw_exception ($t->error);
2710
2711       $dest_schema = $t->schema;
2712
2713       $dest_schema->name( $filename )
2714         unless $dest_schema->name;
2715     }
2716
2717     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2718                                                   $dest_schema,   $db,
2719                                                   $sqltargs
2720                                                  );
2721     if(!open $file, ">$difffile") {
2722       $self->throw_exception("Can't write to $difffile ($!)");
2723       next;
2724     }
2725     print $file $diff;
2726     close($file);
2727   }
2728 }
2729
2730 =head2 deployment_statements
2731
2732 =over 4
2733
2734 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2735
2736 =back
2737
2738 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2739
2740 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2741 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2742
2743 C<$directory> is used to return statements from files in a previously created
2744 L</create_ddl_dir> directory and is optional. The filenames are constructed
2745 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2746
2747 If no C<$directory> is specified then the statements are constructed on the
2748 fly using L<SQL::Translator> and C<$version> is ignored.
2749
2750 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2751
2752 =cut
2753
2754 sub deployment_statements {
2755   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2756   $type ||= $self->sqlt_type;
2757   $version ||= $schema->schema_version || '1.x';
2758   $dir ||= './';
2759   my $filename = $schema->ddl_filename($type, $version, $dir);
2760   if(-f $filename)
2761   {
2762       # FIXME replace this block when a proper sane sql parser is available
2763       my $file;
2764       open($file, "<$filename")
2765         or $self->throw_exception("Can't open $filename ($!)");
2766       my @rows = <$file>;
2767       close($file);
2768       return join('', @rows);
2769   }
2770
2771   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2772     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2773   }
2774
2775   # sources needs to be a parser arg, but for simplicty allow at top level
2776   # coming in
2777   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2778       if exists $sqltargs->{sources};
2779
2780   my $tr = SQL::Translator->new(
2781     producer => "SQL::Translator::Producer::${type}",
2782     %$sqltargs,
2783     parser => 'SQL::Translator::Parser::DBIx::Class',
2784     data => $schema,
2785   );
2786
2787   my @ret;
2788   if (wantarray) {
2789     @ret = $tr->translate;
2790   }
2791   else {
2792     $ret[0] = $tr->translate;
2793   }
2794
2795   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2796     unless (@ret && defined $ret[0]);
2797
2798   return wantarray ? @ret : $ret[0];
2799 }
2800
2801 # FIXME deploy() currently does not accurately report sql errors
2802 # Will always return true while errors are warned
2803 sub deploy {
2804   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2805   my $deploy = sub {
2806     my $line = shift;
2807     return if(!$line);
2808     return if($line =~ /^--/);
2809     # next if($line =~ /^DROP/m);
2810     return if($line =~ /^BEGIN TRANSACTION/m);
2811     return if($line =~ /^COMMIT/m);
2812     return if $line =~ /^\s+$/; # skip whitespace only
2813     $self->_query_start($line);
2814     try {
2815       # do a dbh_do cycle here, as we need some error checking in
2816       # place (even though we will ignore errors)
2817       $self->dbh_do (sub { $_[1]->do($line) });
2818     } catch {
2819       carp qq{$_ (running "${line}")};
2820     };
2821     $self->_query_end($line);
2822   };
2823   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2824   if (@statements > 1) {
2825     foreach my $statement (@statements) {
2826       $deploy->( $statement );
2827     }
2828   }
2829   elsif (@statements == 1) {
2830     # split on single line comments and end of statements
2831     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2832       $deploy->( $line );
2833     }
2834   }
2835 }
2836
2837 =head2 datetime_parser
2838
2839 Returns the datetime parser class
2840
2841 =cut
2842
2843 sub datetime_parser {
2844   my $self = shift;
2845   return $self->{datetime_parser} ||= do {
2846     $self->build_datetime_parser(@_);
2847   };
2848 }
2849
2850 =head2 datetime_parser_type
2851
2852 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2853
2854 =head2 build_datetime_parser
2855
2856 See L</datetime_parser>
2857
2858 =cut
2859
2860 sub build_datetime_parser {
2861   my $self = shift;
2862   my $type = $self->datetime_parser_type(@_);
2863   return $type;
2864 }
2865
2866
2867 =head2 is_replicating
2868
2869 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2870 replicate from a master database.  Default is undef, which is the result
2871 returned by databases that don't support replication.
2872
2873 =cut
2874
2875 sub is_replicating {
2876     return;
2877
2878 }
2879
2880 =head2 lag_behind_master
2881
2882 Returns a number that represents a certain amount of lag behind a master db
2883 when a given storage is replicating.  The number is database dependent, but
2884 starts at zero and increases with the amount of lag. Default in undef
2885
2886 =cut
2887
2888 sub lag_behind_master {
2889     return;
2890 }
2891
2892 =head2 relname_to_table_alias
2893
2894 =over 4
2895
2896 =item Arguments: $relname, $join_count
2897
2898 =back
2899
2900 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2901 queries.
2902
2903 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2904 way these aliases are named.
2905
2906 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2907 otherwise C<"$relname">.
2908
2909 =cut
2910
2911 sub relname_to_table_alias {
2912   my ($self, $relname, $join_count) = @_;
2913
2914   my $alias = ($join_count && $join_count > 1 ?
2915     join('_', $relname, $join_count) : $relname);
2916
2917   return $alias;
2918 }
2919
2920 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
2921 # version and it may be necessary to amend or override it for a specific storage
2922 # if such binds are necessary.
2923 sub _max_column_bytesize {
2924   my ($self, $attr) = @_;
2925
2926   my $max_size;
2927
2928   if ($attr->{sqlt_datatype}) {
2929     my $data_type = lc($attr->{sqlt_datatype});
2930
2931     if ($attr->{sqlt_size}) {
2932
2933       # String/sized-binary types
2934       if ($data_type =~ /^(?:
2935           l? (?:var)? char(?:acter)? (?:\s*varying)?
2936             |
2937           (?:var)? binary (?:\s*varying)?
2938             |
2939           raw
2940         )\b/x
2941       ) {
2942         $max_size = $attr->{sqlt_size};
2943       }
2944       # Other charset/unicode types, assume scale of 4
2945       elsif ($data_type =~ /^(?:
2946           national \s* character (?:\s*varying)?
2947             |
2948           nchar
2949             |
2950           univarchar
2951             |
2952           nvarchar
2953         )\b/x
2954       ) {
2955         $max_size = $attr->{sqlt_size} * 4;
2956       }
2957     }
2958
2959     if (!$max_size and !$self->_is_lob_type($data_type)) {
2960       $max_size = 100 # for all other (numeric?) datatypes
2961     }
2962   }
2963
2964   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
2965 }
2966
2967 # Determine if a data_type is some type of BLOB
2968 sub _is_lob_type {
2969   my ($self, $data_type) = @_;
2970   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
2971     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
2972                                   |varchar|character\s*varying|nvarchar
2973                                   |national\s*character\s*varying))?\z/xi);
2974 }
2975
2976 sub _is_binary_lob_type {
2977   my ($self, $data_type) = @_;
2978   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
2979     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
2980 }
2981
2982 sub _is_text_lob_type {
2983   my ($self, $data_type) = @_;
2984   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
2985     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
2986                         |national\s*character\s*varying))\z/xi);
2987 }
2988
2989 1;
2990
2991 =head1 USAGE NOTES
2992
2993 =head2 DBIx::Class and AutoCommit
2994
2995 DBIx::Class can do some wonderful magic with handling exceptions,
2996 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2997 (the default) combined with C<txn_do> for transaction support.
2998
2999 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3000 in an assumed transaction between commits, and you're telling us you'd
3001 like to manage that manually.  A lot of the magic protections offered by
3002 this module will go away.  We can't protect you from exceptions due to database
3003 disconnects because we don't know anything about how to restart your
3004 transactions.  You're on your own for handling all sorts of exceptional
3005 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3006 be with raw DBI.
3007
3008
3009 =head1 AUTHORS
3010
3011 Matt S. Trout <mst@shadowcatsystems.co.uk>
3012
3013 Andy Grundman <andy@hybridized.org>
3014
3015 =head1 LICENSE
3016
3017 You may distribute this code under the same terms as Perl itself.
3018
3019 =cut