lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  33
  34 BEGIN {
  35
  36 package # Hide from PAUSE
  37   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  38
  39 use base qw/SQL::Abstract::Limit/;
  40
  41 # This prevents the caching of $dbh in S::A::L, I believe
  42 sub new {
  43   my $self = shift->SUPER::new(@_);
  44
  45   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  46   #   it with what it resolves to:
  47   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  48     if ref $self->{limit_dialect};
  49
  50   $self;
  51 }
  52
  53 # DB2 is the only remaining DB using this. Even though we are not sure if
  54 # RowNumberOver is still needed here (should be part of SQLA) leave the
  55 # code in place
  56 sub _RowNumberOver {
  57   my ($self, $sql, $order, $rows, $offset ) = @_;
  58
  59   $offset += 1;
  60   my $last = $rows + $offset;
  61   my ( $order_by ) = $self->_order_by( $order );
  62
  63   $sql = <<"SQL";
  64 SELECT * FROM
  65 (
  66    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  67       $sql
  68       $order_by
  69    ) Q1
  70 ) Q2
  71 WHERE ROW_NUM BETWEEN $offset AND $last
  72
  73 SQL
  74
  75   return $sql;
  76 }
  77
  78
  79 # While we're at it, this should make LIMIT queries more efficient,
  80 #  without digging into things too deeply
  81 use Scalar::Util 'blessed';
  82 sub _find_syntax {
  83   my ($self, $syntax) = @_;
  84
  85   # DB2 is the only remaining DB using this. Even though we are not sure if
  86   # RowNumberOver is still needed here (should be part of SQLA) leave the
  87   # code in place
  88   my $dbhname = blessed($syntax) ? $syntax->{Driver}{Name} : $syntax;
  89   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  90     return 'RowNumberOver';
  91   }
  92
  93   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  94 }
  95
  96 sub select {
  97   my ($self, $table, $fields, $where, $order, @rest) = @_;
  98   if (ref $table eq 'SCALAR') {
  99     $table = $$table;
 100   }
 101   elsif (not ref $table) {
 102     $table = $self->_quote($table);
 103   }
 104   local $self->{rownum_hack_count} = 1
 105     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
 106   @rest = (-1) unless defined $rest[0];
 107   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 108     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 109   local $self->{having_bind} = [];
 110   my ($sql, @ret) = $self->SUPER::select(
 111     $table, $self->_recurse_fields($fields), $where, $order, @rest
 112   );
 113   $sql .=
 114     $self->{for} ?
 115     (
 116       $self->{for} eq 'update' ? ' FOR UPDATE' :
 117       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 118       ''
 119     ) :
 120     ''
 121   ;
 122   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 123 }
 124
 125 sub insert {
 126   my $self = shift;
 127   my $table = shift;
 128   $table = $self->_quote($table) unless ref($table);
 129   $self->SUPER::insert($table, @_);
 130 }
 131
 132 sub update {
 133   my $self = shift;
 134   my $table = shift;
 135   $table = $self->_quote($table) unless ref($table);
 136   $self->SUPER::update($table, @_);
 137 }
 138
 139 sub delete {
 140   my $self = shift;
 141   my $table = shift;
 142   $table = $self->_quote($table) unless ref($table);
 143   $self->SUPER::delete($table, @_);
 144 }
 145
 146 sub _emulate_limit {
 147   my $self = shift;
 148   if ($_[3] == -1) {
 149     return $_[1].$self->_order_by($_[2]);
 150   } else {
 151     return $self->SUPER::_emulate_limit(@_);
 152   }
 153 }
 154
 155 sub _recurse_fields {
 156   my ($self, $fields, $params) = @_;
 157   my $ref = ref $fields;
 158   return $self->_quote($fields) unless $ref;
 159   return $$fields if $ref eq 'SCALAR';
 160
 161   if ($ref eq 'ARRAY') {
 162     return join(', ', map {
 163       $self->_recurse_fields($_)
 164         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 165           ? ' AS col'.$self->{rownum_hack_count}++
 166           : '')
 167       } @$fields);
 168   } elsif ($ref eq 'HASH') {
 169     foreach my $func (keys %$fields) {
 170       return $self->_sqlcase($func)
 171         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 172     }
 173   }
 174   # Is the second check absolutely necessary?
 175   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 176     return $self->_bind_to_sql( $fields );
 177   }
 178   else {
 179     Carp::croak($ref . qq{ unexpected in _recurse_fields()})
 180   }
 181 }
 182
 183 sub _order_by {
 184   my $self = shift;
 185   my $ret = '';
 186   my @extra;
 187   if (ref $_[0] eq 'HASH') {
 188     if (defined $_[0]->{group_by}) {
 189       $ret = $self->_sqlcase(' group by ')
 190         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 191     }
 192     if (defined $_[0]->{having}) {
 193       my $frag;
 194       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 195       push(@{$self->{having_bind}}, @extra);
 196       $ret .= $self->_sqlcase(' having ').$frag;
 197     }
 198     if (defined $_[0]->{order_by}) {
 199       $ret .= $self->_order_by($_[0]->{order_by});
 200     }
 201     if (grep { $_ =~ /^-(desc|asc)/i } keys %{$_[0]}) {
 202       return $self->SUPER::_order_by($_[0]);
 203     }
 204   } elsif (ref $_[0] eq 'SCALAR') {
 205     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 206   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 207     my @order = @{+shift};
 208     $ret = $self->_sqlcase(' order by ')
 209           .join(', ', map {
 210                         my $r = $self->_order_by($_, @_);
 211                         $r =~ s/^ ?ORDER BY //i;
 212                         $r;
 213                       } @order);
 214   } else {
 215     $ret = $self->SUPER::_order_by(@_);
 216   }
 217   return $ret;
 218 }
 219
 220 sub _order_directions {
 221   my ($self, $order) = @_;
 222   $order = $order->{order_by} if ref $order eq 'HASH';
 223   return $self->SUPER::_order_directions($order);
 224 }
 225
 226 sub _table {
 227   my ($self, $from) = @_;
 228   if (ref $from eq 'ARRAY') {
 229     return $self->_recurse_from(@$from);
 230   } elsif (ref $from eq 'HASH') {
 231     return $self->_make_as($from);
 232   } else {
 233     return $from; # would love to quote here but _table ends up getting called
 234                   # twice during an ->select without a limit clause due to
 235                   # the way S::A::Limit->select works. should maybe consider
 236                   # bypassing this and doing S::A::select($self, ...) in
 237                   # our select method above. meantime, quoting shims have
 238                   # been added to select/insert/update/delete here
 239   }
 240 }
 241
 242 sub _recurse_from {
 243   my ($self, $from, @join) = @_;
 244   my @sqlf;
 245   push(@sqlf, $self->_make_as($from));
 246   foreach my $j (@join) {
 247     my ($to, $on) = @$j;
 248
 249     # check whether a join type exists
 250     my $join_clause = '';
 251     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 252     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 253       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 254     } else {
 255       $join_clause = ' JOIN ';
 256     }
 257     push(@sqlf, $join_clause);
 258
 259     if (ref $to eq 'ARRAY') {
 260       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 261     } else {
 262       push(@sqlf, $self->_make_as($to));
 263     }
 264     push(@sqlf, ' ON ', $self->_join_condition($on));
 265   }
 266   return join('', @sqlf);
 267 }
 268
 269 sub _bind_to_sql {
 270   my $self = shift;
 271   my $arr  = shift;
 272   my $sql = shift @$$arr;
 273   $sql =~ s/\?/$self->_quote((shift @$$arr)->[1])/eg;
 274   return $sql
 275 }
 276
 277 sub _make_as {
 278   my ($self, $from) = @_;
 279   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 280                         : ref $_ eq 'REF'    ? $self->_bind_to_sql($_)
 281                         : $self->_quote($_))
 282                        } reverse each %{$self->_skip_options($from)});
 283 }
 284
 285 sub _skip_options {
 286   my ($self, $hash) = @_;
 287   my $clean_hash = {};
 288   $clean_hash->{$_} = $hash->{$_}
 289     for grep {!/^-/} keys %$hash;
 290   return $clean_hash;
 291 }
 292
 293 sub _join_condition {
 294   my ($self, $cond) = @_;
 295   if (ref $cond eq 'HASH') {
 296     my %j;
 297     for (keys %$cond) {
 298       my $v = $cond->{$_};
 299       if (ref $v) {
 300         # XXX no throw_exception() in this package and croak() fails with strange results
 301         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 302             if ref($v) ne 'SCALAR';
 303         $j{$_} = $v;
 304       }
 305       else {
 306         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 307       }
 308     };
 309     return scalar($self->_recurse_where(\%j));
 310   } elsif (ref $cond eq 'ARRAY') {
 311     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 312   } else {
 313     die "Can't handle this yet!";
 314   }
 315 }
 316
 317 sub _quote {
 318   my ($self, $label) = @_;
 319   return '' unless defined $label;
 320   return "*" if $label eq '*';
 321   return $label unless $self->{quote_char};
 322   if(ref $self->{quote_char} eq "ARRAY"){
 323     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 324       if !defined $self->{name_sep};
 325     my $sep = $self->{name_sep};
 326     return join($self->{name_sep},
 327         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 328        split(/\Q$sep\E/,$label));
 329   }
 330   return $self->SUPER::_quote($label);
 331 }
 332
 333 sub limit_dialect {
 334     my $self = shift;
 335     $self->{limit_dialect} = shift if @_;
 336     return $self->{limit_dialect};
 337 }
 338
 339 sub quote_char {
 340     my $self = shift;
 341     $self->{quote_char} = shift if @_;
 342     return $self->{quote_char};
 343 }
 344
 345 sub name_sep {
 346     my $self = shift;
 347     $self->{name_sep} = shift if @_;
 348     return $self->{name_sep};
 349 }
 350
 351 } # End of BEGIN block
 352
 353 =head1 NAME
 354
 355 DBIx::Class::Storage::DBI - DBI storage handler
 356
 357 =head1 SYNOPSIS
 358
 359   my $schema = MySchema->connect('dbi:SQLite:my.db');
 360
 361   $schema->storage->debug(1);
 362   $schema->dbh_do("DROP TABLE authors");
 363
 364   $schema->resultset('Book')->search({
 365      written_on => $schema->storage->datetime_parser(DateTime->now)
 366   });
 367
 368 =head1 DESCRIPTION
 369
 370 This class represents the connection to an RDBMS via L<DBI>.  See
 371 L<DBIx::Class::Storage> for general information.  This pod only
 372 documents DBI-specific methods and behaviors.
 373
 374 =head1 METHODS
 375
 376 =cut
 377
 378 sub new {
 379   my $new = shift->next::method(@_);
 380
 381   $new->transaction_depth(0);
 382   $new->_sql_maker_opts({});
 383   $new->{savepoints} = [];
 384   $new->{_in_dbh_do} = 0;
 385   $new->{_dbh_gen} = 0;
 386
 387   $new;
 388 }
 389
 390 =head2 connect_info
 391
 392 This method is normally called by L<DBIx::Class::Schema/connection>, which
 393 encapsulates its argument list in an arrayref before passing them here.
 394
 395 The argument list may contain:
 396
 397 =over
 398
 399 =item *
 400
 401 The same 4-element argument set one would normally pass to
 402 L<DBI/connect>, optionally followed by
 403 L<extra attributes|/DBIx::Class specific connection attributes>
 404 recognized by DBIx::Class:
 405
 406   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 407
 408 =item *
 409
 410 A single code reference which returns a connected
 411 L<DBI database handle|DBI/connect> optionally followed by
 412 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 413 by DBIx::Class:
 414
 415   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 416
 417 =item *
 418
 419 A single hashref with all the attributes and the dsn/user/password
 420 mixed together:
 421
 422   $connect_info_args = [{
 423     dsn => $dsn,
 424     user => $user,
 425     password => $pass,
 426     %dbi_attributes,
 427     %extra_attributes,
 428   }];
 429
 430 This is particularly useful for L<Catalyst> based applications, allowing the
 431 following config (L<Config::General> style):
 432
 433   <Model::DB>
 434     schema_class   App::DB
 435     <connect_info>
 436       dsn          dbi:mysql:database=test
 437       user         testuser
 438       password     TestPass
 439       AutoCommit   1
 440     </connect_info>
 441   </Model::DB>
 442
 443 =back
 444
 445 Please note that the L<DBI> docs recommend that you always explicitly
 446 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 447 recommends that it be set to I<1>, and that you perform transactions
 448 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 449 to I<1> if you do not do explicitly set it to zero.  This is the default
 450 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 451
 452 =head3 DBIx::Class specific connection attributes
 453
 454 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 455 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 456 the following connection options. These options can be mixed in with your other
 457 L<DBI> connection attributes, or placed in a seperate hashref
 458 (C<\%extra_attributes>) as shown above.
 459
 460 Every time C<connect_info> is invoked, any previous settings for
 461 these options will be cleared before setting the new ones, regardless of
 462 whether any options are specified in the new C<connect_info>.
 463
 464
 465 =over
 466
 467 =item on_connect_do
 468
 469 Specifies things to do immediately after connecting or re-connecting to
 470 the database.  Its value may contain:
 471
 472 =over
 473
 474 =item an array reference
 475
 476 This contains SQL statements to execute in order.  Each element contains
 477 a string or a code reference that returns a string.
 478
 479 =item a code reference
 480
 481 This contains some code to execute.  Unlike code references within an
 482 array reference, its return value is ignored.
 483
 484 =back
 485
 486 =item on_disconnect_do
 487
 488 Takes arguments in the same form as L</on_connect_do> and executes them
 489 immediately before disconnecting from the database.
 490
 491 Note, this only runs if you explicitly call L</disconnect> on the
 492 storage object.
 493
 494 =item disable_sth_caching
 495
 496 If set to a true value, this option will disable the caching of
 497 statement handles via L<DBI/prepare_cached>.
 498
 499 =item limit_dialect
 500
 501 Sets the limit dialect. This is useful for JDBC-bridge among others
 502 where the remote SQL-dialect cannot be determined by the name of the
 503 driver alone. See also L<SQL::Abstract::Limit>.
 504
 505 =item quote_char
 506
 507 Specifies what characters to use to quote table and column names. If
 508 you use this you will want to specify L</name_sep> as well.
 509
 510 C<quote_char> expects either a single character, in which case is it
 511 is placed on either side of the table/column name, or an arrayref of length
 512 2 in which case the table/column name is placed between the elements.
 513
 514 For example under MySQL you should use C<< quote_char => '`' >>, and for
 515 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 516
 517 =item name_sep
 518
 519 This only needs to be used in conjunction with C<quote_char>, and is used to
 520 specify the charecter that seperates elements (schemas, tables, columns) from
 521 each other. In most cases this is simply a C<.>.
 522
 523 The consequences of not supplying this value is that L<SQL::Abstract>
 524 will assume DBIx::Class' uses of aliases to be complete column
 525 names. The output will look like I<"me.name"> when it should actually
 526 be I<"me"."name">.
 527
 528 =item unsafe
 529
 530 This Storage driver normally installs its own C<HandleError>, sets
 531 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 532 all database handles, including those supplied by a coderef.  It does this
 533 so that it can have consistent and useful error behavior.
 534
 535 If you set this option to a true value, Storage will not do its usual
 536 modifications to the database handle's attributes, and instead relies on
 537 the settings in your connect_info DBI options (or the values you set in
 538 your connection coderef, in the case that you are connecting via coderef).
 539
 540 Note that your custom settings can cause Storage to malfunction,
 541 especially if you set a C<HandleError> handler that suppresses exceptions
 542 and/or disable C<RaiseError>.
 543
 544 =item auto_savepoint
 545
 546 If this option is true, L<DBIx::Class> will use savepoints when nesting
 547 transactions, making it possible to recover from failure in the inner
 548 transaction without having to abort all outer transactions.
 549
 550 =item cursor_class
 551
 552 Use this argument to supply a cursor class other than the default
 553 L<DBIx::Class::Storage::DBI::Cursor>.
 554
 555 =back
 556
 557 Some real-life examples of arguments to L</connect_info> and
 558 L<DBIx::Class::Schema/connect>
 559
 560   # Simple SQLite connection
 561   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 562
 563   # Connect via subref
 564   ->connect_info([ sub { DBI->connect(...) } ]);
 565
 566   # A bit more complicated
 567   ->connect_info(
 568     [
 569       'dbi:Pg:dbname=foo',
 570       'postgres',
 571       'my_pg_password',
 572       { AutoCommit => 1 },
 573       { quote_char => q{"}, name_sep => q{.} },
 574     ]
 575   );
 576
 577   # Equivalent to the previous example
 578   ->connect_info(
 579     [
 580       'dbi:Pg:dbname=foo',
 581       'postgres',
 582       'my_pg_password',
 583       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 584     ]
 585   );
 586
 587   # Same, but with hashref as argument
 588   # See parse_connect_info for explanation
 589   ->connect_info(
 590     [{
 591       dsn         => 'dbi:Pg:dbname=foo',
 592       user        => 'postgres',
 593       password    => 'my_pg_password',
 594       AutoCommit  => 1,
 595       quote_char  => q{"},
 596       name_sep    => q{.},
 597     }]
 598   );
 599
 600   # Subref + DBIx::Class-specific connection options
 601   ->connect_info(
 602     [
 603       sub { DBI->connect(...) },
 604       {
 605           quote_char => q{`},
 606           name_sep => q{@},
 607           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 608           disable_sth_caching => 1,
 609       },
 610     ]
 611   );
 612
 613
 614
 615 =cut
 616
 617 sub connect_info {
 618   my ($self, $info_arg) = @_;
 619
 620   return $self->_connect_info if !$info_arg;
 621
 622   my @args = @$info_arg;  # take a shallow copy for further mutilation
 623   $self->_connect_info([@args]); # copy for _connect_info
 624
 625
 626   # combine/pre-parse arguments depending on invocation style
 627
 628   my %attrs;
 629   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 630     %attrs = %{ $args[1] || {} };
 631     @args = $args[0];
 632   }
 633   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 634     %attrs = %{$args[0]};
 635     @args = ();
 636     for (qw/password user dsn/) {
 637       unshift @args, delete $attrs{$_};
 638     }
 639   }
 640   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 641     %attrs = (
 642       % { $args[3] || {} },
 643       % { $args[4] || {} },
 644     );
 645     @args = @args[0,1,2];
 646   }
 647
 648   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 649   #  the new set of options
 650   $self->_sql_maker(undef);
 651   $self->_sql_maker_opts({});
 652
 653   if(keys %attrs) {
 654     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 655       if(my $value = delete $attrs{$storage_opt}) {
 656         $self->$storage_opt($value);
 657       }
 658     }
 659     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 660       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 661         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 662       }
 663     }
 664   }
 665
 666   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 667
 668   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 669   $self->_connect_info;
 670 }
 671
 672 =head2 on_connect_do
 673
 674 This method is deprecated in favour of setting via L</connect_info>.
 675
 676
 677 =head2 dbh_do
 678
 679 Arguments: ($subref | $method_name), @extra_coderef_args?
 680
 681 Execute the given $subref or $method_name using the new exception-based
 682 connection management.
 683
 684 The first two arguments will be the storage object that C<dbh_do> was called
 685 on and a database handle to use.  Any additional arguments will be passed
 686 verbatim to the called subref as arguments 2 and onwards.
 687
 688 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 689 exception handling and reconnection (or failover in future subclasses).
 690
 691 Your subref should have no side-effects outside of the database, as
 692 there is the potential for your subref to be partially double-executed
 693 if the database connection was stale/dysfunctional.
 694
 695 Example:
 696
 697   my @stuff = $schema->storage->dbh_do(
 698     sub {
 699       my ($storage, $dbh, @cols) = @_;
 700       my $cols = join(q{, }, @cols);
 701       $dbh->selectrow_array("SELECT $cols FROM foo");
 702     },
 703     @column_list
 704   );
 705
 706 =cut
 707
 708 sub dbh_do {
 709   my $self = shift;
 710   my $code = shift;
 711
 712   my $dbh = $self->_dbh;
 713
 714   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 715       || $self->{transaction_depth};
 716
 717   local $self->{_in_dbh_do} = 1;
 718
 719   my @result;
 720   my $want_array = wantarray;
 721
 722   eval {
 723     $self->_verify_pid if $dbh;
 724     if(!$self->_dbh) {
 725         $self->_populate_dbh;
 726         $dbh = $self->_dbh;
 727     }
 728
 729     if($want_array) {
 730         @result = $self->$code($dbh, @_);
 731     }
 732     elsif(defined $want_array) {
 733         $result[0] = $self->$code($dbh, @_);
 734     }
 735     else {
 736         $self->$code($dbh, @_);
 737     }
 738   };
 739
 740   my $exception = $@;
 741   if(!$exception) { return $want_array ? @result : $result[0] }
 742
 743   $self->throw_exception($exception) if $self->connected;
 744
 745   # We were not connected - reconnect and retry, but let any
 746   #  exception fall right through this time
 747   $self->_populate_dbh;
 748   $self->$code($self->_dbh, @_);
 749 }
 750
 751 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 752 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 753 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 754 sub txn_do {
 755   my $self = shift;
 756   my $coderef = shift;
 757
 758   ref $coderef eq 'CODE' or $self->throw_exception
 759     ('$coderef must be a CODE reference');
 760
 761   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 762
 763   local $self->{_in_dbh_do} = 1;
 764
 765   my @result;
 766   my $want_array = wantarray;
 767
 768   my $tried = 0;
 769   while(1) {
 770     eval {
 771       $self->_verify_pid if $self->_dbh;
 772       $self->_populate_dbh if !$self->_dbh;
 773
 774       $self->txn_begin;
 775       if($want_array) {
 776           @result = $coderef->(@_);
 777       }
 778       elsif(defined $want_array) {
 779           $result[0] = $coderef->(@_);
 780       }
 781       else {
 782           $coderef->(@_);
 783       }
 784       $self->txn_commit;
 785     };
 786
 787     my $exception = $@;
 788     if(!$exception) { return $want_array ? @result : $result[0] }
 789
 790     if($tried++ > 0 || $self->connected) {
 791       eval { $self->txn_rollback };
 792       my $rollback_exception = $@;
 793       if($rollback_exception) {
 794         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 795         $self->throw_exception($exception)  # propagate nested rollback
 796           if $rollback_exception =~ /$exception_class/;
 797
 798         $self->throw_exception(
 799           "Transaction aborted: ${exception}. "
 800           . "Rollback failed: ${rollback_exception}"
 801         );
 802       }
 803       $self->throw_exception($exception)
 804     }
 805
 806     # We were not connected, and was first try - reconnect and retry
 807     # via the while loop
 808     $self->_populate_dbh;
 809   }
 810 }
 811
 812 =head2 disconnect
 813
 814 Our C<disconnect> method also performs a rollback first if the
 815 database is not in C<AutoCommit> mode.
 816
 817 =cut
 818
 819 sub disconnect {
 820   my ($self) = @_;
 821
 822   if( $self->connected ) {
 823     my $connection_do = $self->on_disconnect_do;
 824     $self->_do_connection_actions($connection_do) if ref($connection_do);
 825
 826     $self->_dbh->rollback unless $self->_dbh_autocommit;
 827     $self->_dbh->disconnect;
 828     $self->_dbh(undef);
 829     $self->{_dbh_gen}++;
 830   }
 831 }
 832
 833 =head2 with_deferred_fk_checks
 834
 835 =over 4
 836
 837 =item Arguments: C<$coderef>
 838
 839 =item Return Value: The return value of $coderef
 840
 841 =back
 842
 843 Storage specific method to run the code ref with FK checks deferred or
 844 in MySQL's case disabled entirely.
 845
 846 =cut
 847
 848 # Storage subclasses should override this
 849 sub with_deferred_fk_checks {
 850   my ($self, $sub) = @_;
 851
 852   $sub->();
 853 }
 854
 855 sub connected {
 856   my ($self) = @_;
 857
 858   if(my $dbh = $self->_dbh) {
 859       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 860           $self->_dbh(undef);
 861           $self->{_dbh_gen}++;
 862           return;
 863       }
 864       else {
 865           $self->_verify_pid;
 866           return 0 if !$self->_dbh;
 867       }
 868       return ($dbh->FETCH('Active') && $dbh->ping);
 869   }
 870
 871   return 0;
 872 }
 873
 874 # handle pid changes correctly
 875 #  NOTE: assumes $self->_dbh is a valid $dbh
 876 sub _verify_pid {
 877   my ($self) = @_;
 878
 879   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 880
 881   $self->_dbh->{InactiveDestroy} = 1;
 882   $self->_dbh(undef);
 883   $self->{_dbh_gen}++;
 884
 885   return;
 886 }
 887
 888 sub ensure_connected {
 889   my ($self) = @_;
 890
 891   unless ($self->connected) {
 892     $self->_populate_dbh;
 893   }
 894 }
 895
 896 =head2 dbh
 897
 898 Returns the dbh - a data base handle of class L<DBI>.
 899
 900 =cut
 901
 902 sub dbh {
 903   my ($self) = @_;
 904
 905   $self->ensure_connected;
 906   return $self->_dbh;
 907 }
 908
 909 sub _sql_maker_args {
 910     my ($self) = @_;
 911
 912     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 913 }
 914
 915 sub sql_maker {
 916   my ($self) = @_;
 917   unless ($self->_sql_maker) {
 918     my $sql_maker_class = $self->sql_maker_class;
 919     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 920   }
 921   return $self->_sql_maker;
 922 }
 923
 924 sub _rebless {}
 925
 926 sub _populate_dbh {
 927   my ($self) = @_;
 928   my @info = @{$self->_dbi_connect_info || []};
 929   $self->_dbh($self->_connect(@info));
 930
 931   # Always set the transaction depth on connect, since
 932   #  there is no transaction in progress by definition
 933   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 934
 935   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 936     my $driver = $self->_dbh->{Driver}->{Name};
 937     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 938       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 939       $self->_rebless();
 940     }
 941   }
 942
 943   $self->_conn_pid($$);
 944   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 945
 946   my $connection_do = $self->on_connect_do;
 947   $self->_do_connection_actions($connection_do) if ref($connection_do);
 948 }
 949
 950 sub _do_connection_actions {
 951   my $self = shift;
 952   my $connection_do = shift;
 953
 954   if (ref $connection_do eq 'ARRAY') {
 955     $self->_do_query($_) foreach @$connection_do;
 956   }
 957   elsif (ref $connection_do eq 'CODE') {
 958     $connection_do->($self);
 959   }
 960
 961   return $self;
 962 }
 963
 964 sub _do_query {
 965   my ($self, $action) = @_;
 966
 967   if (ref $action eq 'CODE') {
 968     $action = $action->($self);
 969     $self->_do_query($_) foreach @$action;
 970   }
 971   else {
 972     # Most debuggers expect ($sql, @bind), so we need to exclude
 973     # the attribute hash which is the second argument to $dbh->do
 974     # furthermore the bind values are usually to be presented
 975     # as named arrayref pairs, so wrap those here too
 976     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 977     my $sql = shift @do_args;
 978     my $attrs = shift @do_args;
 979     my @bind = map { [ undef, $_ ] } @do_args;
 980
 981     $self->_query_start($sql, @bind);
 982     $self->_dbh->do($sql, $attrs, @do_args);
 983     $self->_query_end($sql, @bind);
 984   }
 985
 986   return $self;
 987 }
 988
 989 sub _connect {
 990   my ($self, @info) = @_;
 991
 992   $self->throw_exception("You failed to provide any connection info")
 993     if !@info;
 994
 995   my ($old_connect_via, $dbh);
 996
 997   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 998     $old_connect_via = $DBI::connect_via;
 999     $DBI::connect_via = 'connect';
1000   }
1001
1002   eval {
1003     if(ref $info[0] eq 'CODE') {
1004        $dbh = &{$info[0]}
1005     }
1006     else {
1007        $dbh = DBI->connect(@info);
1008     }
1009
1010     if($dbh && !$self->unsafe) {
1011       my $weak_self = $self;
1012       weaken($weak_self);
1013       $dbh->{HandleError} = sub {
1014           if ($weak_self) {
1015             $weak_self->throw_exception("DBI Exception: $_[0]");
1016           }
1017           else {
1018             croak ("DBI Exception: $_[0]");
1019           }
1020       };
1021       $dbh->{ShowErrorStatement} = 1;
1022       $dbh->{RaiseError} = 1;
1023       $dbh->{PrintError} = 0;
1024     }
1025   };
1026
1027   $DBI::connect_via = $old_connect_via if $old_connect_via;
1028
1029   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1030     if !$dbh || $@;
1031
1032   $self->_dbh_autocommit($dbh->{AutoCommit});
1033
1034   $dbh;
1035 }
1036
1037 sub svp_begin {
1038   my ($self, $name) = @_;
1039
1040   $name = $self->_svp_generate_name
1041     unless defined $name;
1042
1043   $self->throw_exception ("You can't use savepoints outside a transaction")
1044     if $self->{transaction_depth} == 0;
1045
1046   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1047     unless $self->can('_svp_begin');
1048
1049   push @{ $self->{savepoints} }, $name;
1050
1051   $self->debugobj->svp_begin($name) if $self->debug;
1052
1053   return $self->_svp_begin($name);
1054 }
1055
1056 sub svp_release {
1057   my ($self, $name) = @_;
1058
1059   $self->throw_exception ("You can't use savepoints outside a transaction")
1060     if $self->{transaction_depth} == 0;
1061
1062   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1063     unless $self->can('_svp_release');
1064
1065   if (defined $name) {
1066     $self->throw_exception ("Savepoint '$name' does not exist")
1067       unless grep { $_ eq $name } @{ $self->{savepoints} };
1068
1069     # Dig through the stack until we find the one we are releasing.  This keeps
1070     # the stack up to date.
1071     my $svp;
1072
1073     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1074   } else {
1075     $name = pop @{ $self->{savepoints} };
1076   }
1077
1078   $self->debugobj->svp_release($name) if $self->debug;
1079
1080   return $self->_svp_release($name);
1081 }
1082
1083 sub svp_rollback {
1084   my ($self, $name) = @_;
1085
1086   $self->throw_exception ("You can't use savepoints outside a transaction")
1087     if $self->{transaction_depth} == 0;
1088
1089   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1090     unless $self->can('_svp_rollback');
1091
1092   if (defined $name) {
1093       # If they passed us a name, verify that it exists in the stack
1094       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1095           $self->throw_exception("Savepoint '$name' does not exist!");
1096       }
1097
1098       # Dig through the stack until we find the one we are releasing.  This keeps
1099       # the stack up to date.
1100       while(my $s = pop(@{ $self->{savepoints} })) {
1101           last if($s eq $name);
1102       }
1103       # Add the savepoint back to the stack, as a rollback doesn't remove the
1104       # named savepoint, only everything after it.
1105       push(@{ $self->{savepoints} }, $name);
1106   } else {
1107       # We'll assume they want to rollback to the last savepoint
1108       $name = $self->{savepoints}->[-1];
1109   }
1110
1111   $self->debugobj->svp_rollback($name) if $self->debug;
1112
1113   return $self->_svp_rollback($name);
1114 }
1115
1116 sub _svp_generate_name {
1117     my ($self) = @_;
1118
1119     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1120 }
1121
1122 sub txn_begin {
1123   my $self = shift;
1124   $self->ensure_connected();
1125   if($self->{transaction_depth} == 0) {
1126     $self->debugobj->txn_begin()
1127       if $self->debug;
1128     # this isn't ->_dbh-> because
1129     #  we should reconnect on begin_work
1130     #  for AutoCommit users
1131     $self->dbh->begin_work;
1132   } elsif ($self->auto_savepoint) {
1133     $self->svp_begin;
1134   }
1135   $self->{transaction_depth}++;
1136 }
1137
1138 sub txn_commit {
1139   my $self = shift;
1140   if ($self->{transaction_depth} == 1) {
1141     my $dbh = $self->_dbh;
1142     $self->debugobj->txn_commit()
1143       if ($self->debug);
1144     $dbh->commit;
1145     $self->{transaction_depth} = 0
1146       if $self->_dbh_autocommit;
1147   }
1148   elsif($self->{transaction_depth} > 1) {
1149     $self->{transaction_depth}--;
1150     $self->svp_release
1151       if $self->auto_savepoint;
1152   }
1153 }
1154
1155 sub txn_rollback {
1156   my $self = shift;
1157   my $dbh = $self->_dbh;
1158   eval {
1159     if ($self->{transaction_depth} == 1) {
1160       $self->debugobj->txn_rollback()
1161         if ($self->debug);
1162       $self->{transaction_depth} = 0
1163         if $self->_dbh_autocommit;
1164       $dbh->rollback;
1165     }
1166     elsif($self->{transaction_depth} > 1) {
1167       $self->{transaction_depth}--;
1168       if ($self->auto_savepoint) {
1169         $self->svp_rollback;
1170         $self->svp_release;
1171       }
1172     }
1173     else {
1174       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1175     }
1176   };
1177   if ($@) {
1178     my $error = $@;
1179     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1180     $error =~ /$exception_class/ and $self->throw_exception($error);
1181     # ensure that a failed rollback resets the transaction depth
1182     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1183     $self->throw_exception($error);
1184   }
1185 }
1186
1187 # This used to be the top-half of _execute.  It was split out to make it
1188 #  easier to override in NoBindVars without duping the rest.  It takes up
1189 #  all of _execute's args, and emits $sql, @bind.
1190 sub _prep_for_execute {
1191   my ($self, $op, $extra_bind, $ident, $args) = @_;
1192
1193   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1194     $ident = $ident->from();
1195   }
1196
1197   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1198
1199   unshift(@bind,
1200     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1201       if $extra_bind;
1202   return ($sql, \@bind);
1203 }
1204
1205 sub _fix_bind_params {
1206     my ($self, @bind) = @_;
1207
1208     ### Turn @bind from something like this:
1209     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1210     ### to this:
1211     ###   ( "'1'", "'1'", "'3'" )
1212     return
1213         map {
1214             if ( defined( $_ && $_->[1] ) ) {
1215                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1216             }
1217             else { q{'NULL'}; }
1218         } @bind;
1219 }
1220
1221 sub _query_start {
1222     my ( $self, $sql, @bind ) = @_;
1223
1224     if ( $self->debug ) {
1225         @bind = $self->_fix_bind_params(@bind);
1226
1227         $self->debugobj->query_start( $sql, @bind );
1228     }
1229 }
1230
1231 sub _query_end {
1232     my ( $self, $sql, @bind ) = @_;
1233
1234     if ( $self->debug ) {
1235         @bind = $self->_fix_bind_params(@bind);
1236         $self->debugobj->query_end( $sql, @bind );
1237     }
1238 }
1239
1240 sub _dbh_execute {
1241   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1242
1243   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1244
1245   $self->_query_start( $sql, @$bind );
1246
1247   my $sth = $self->sth($sql,$op);
1248
1249   my $placeholder_index = 1;
1250
1251   foreach my $bound (@$bind) {
1252     my $attributes = {};
1253     my($column_name, @data) = @$bound;
1254
1255     if ($bind_attributes) {
1256       $attributes = $bind_attributes->{$column_name}
1257       if defined $bind_attributes->{$column_name};
1258     }
1259
1260     foreach my $data (@data) {
1261       my $ref = ref $data;
1262       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1263
1264       $sth->bind_param($placeholder_index, $data, $attributes);
1265       $placeholder_index++;
1266     }
1267   }
1268
1269   # Can this fail without throwing an exception anyways???
1270   my $rv = $sth->execute();
1271   $self->throw_exception($sth->errstr) if !$rv;
1272
1273   $self->_query_end( $sql, @$bind );
1274
1275   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1276 }
1277
1278 sub _execute {
1279     my $self = shift;
1280     $self->dbh_do('_dbh_execute', @_)
1281 }
1282
1283 sub insert {
1284   my ($self, $source, $to_insert) = @_;
1285
1286   my $ident = $source->from;
1287   my $bind_attributes = $self->source_bind_attributes($source);
1288
1289   my $updated_cols = {};
1290
1291   $self->ensure_connected;
1292   foreach my $col ( $source->columns ) {
1293     if ( !defined $to_insert->{$col} ) {
1294       my $col_info = $source->column_info($col);
1295
1296       if ( $col_info->{auto_nextval} ) {
1297         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1298       }
1299     }
1300   }
1301
1302   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1303
1304   return $updated_cols;
1305 }
1306
1307 ## Still not quite perfect, and EXPERIMENTAL
1308 ## Currently it is assumed that all values passed will be "normal", i.e. not
1309 ## scalar refs, or at least, all the same type as the first set, the statement is
1310 ## only prepped once.
1311 sub insert_bulk {
1312   my ($self, $source, $cols, $data) = @_;
1313   my %colvalues;
1314   my $table = $source->from;
1315   @colvalues{@$cols} = (0..$#$cols);
1316   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1317
1318   $self->_query_start( $sql, @bind );
1319   my $sth = $self->sth($sql);
1320
1321 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1322
1323   ## This must be an arrayref, else nothing works!
1324
1325   my $tuple_status = [];
1326
1327   ##use Data::Dumper;
1328   ##print STDERR Dumper( $data, $sql, [@bind] );
1329
1330   my $time = time();
1331
1332   ## Get the bind_attributes, if any exist
1333   my $bind_attributes = $self->source_bind_attributes($source);
1334
1335   ## Bind the values and execute
1336   my $placeholder_index = 1;
1337
1338   foreach my $bound (@bind) {
1339
1340     my $attributes = {};
1341     my ($column_name, $data_index) = @$bound;
1342
1343     if( $bind_attributes ) {
1344       $attributes = $bind_attributes->{$column_name}
1345       if defined $bind_attributes->{$column_name};
1346     }
1347
1348     my @data = map { $_->[$data_index] } @$data;
1349
1350     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1351     $placeholder_index++;
1352   }
1353   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1354   $self->throw_exception($sth->errstr) if !$rv;
1355
1356   $self->_query_end( $sql, @bind );
1357   return (wantarray ? ($rv, $sth, @bind) : $rv);
1358 }
1359
1360 sub update {
1361   my $self = shift @_;
1362   my $source = shift @_;
1363   my $bind_attributes = $self->source_bind_attributes($source);
1364
1365   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1366 }
1367
1368
1369 sub delete {
1370   my $self = shift @_;
1371   my $source = shift @_;
1372
1373   my $bind_attrs = {}; ## If ever it's needed...
1374
1375   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1376 }
1377
1378 sub _select {
1379   my $self = shift;
1380   my $sql_maker = $self->sql_maker;
1381   local $sql_maker->{for};
1382   return $self->_execute($self->_select_args(@_));
1383 }
1384
1385 sub _select_args {
1386   my ($self, $ident, $select, $condition, $attrs) = @_;
1387   my $order = $attrs->{order_by};
1388
1389   my $for = delete $attrs->{for};
1390   my $sql_maker = $self->sql_maker;
1391   $sql_maker->{for} = $for;
1392
1393   if (exists $attrs->{group_by} || $attrs->{having}) {
1394     $order = {
1395       group_by => $attrs->{group_by},
1396       having => $attrs->{having},
1397       ($order ? (order_by => $order) : ())
1398     };
1399   }
1400   my $bind_attrs = {}; ## Future support
1401   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1402   if ($attrs->{software_limit} ||
1403       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1404         $attrs->{software_limit} = 1;
1405   } else {
1406     $self->throw_exception("rows attribute must be positive if present")
1407       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1408
1409     # MySQL actually recommends this approach.  I cringe.
1410     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1411     push @args, $attrs->{rows}, $attrs->{offset};
1412   }
1413   return @args;
1414 }
1415
1416 sub source_bind_attributes {
1417   my ($self, $source) = @_;
1418
1419   my $bind_attributes;
1420   foreach my $column ($source->columns) {
1421
1422     my $data_type = $source->column_info($column)->{data_type} || '';
1423     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1424      if $data_type;
1425   }
1426
1427   return $bind_attributes;
1428 }
1429
1430 =head2 select
1431
1432 =over 4
1433
1434 =item Arguments: $ident, $select, $condition, $attrs
1435
1436 =back
1437
1438 Handle a SQL select statement.
1439
1440 =cut
1441
1442 sub select {
1443   my $self = shift;
1444   my ($ident, $select, $condition, $attrs) = @_;
1445   return $self->cursor_class->new($self, \@_, $attrs);
1446 }
1447
1448 sub select_single {
1449   my $self = shift;
1450   my ($rv, $sth, @bind) = $self->_select(@_);
1451   my @row = $sth->fetchrow_array;
1452   my @nextrow = $sth->fetchrow_array if @row;
1453   if(@row && @nextrow) {
1454     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1455   }
1456   # Need to call finish() to work round broken DBDs
1457   $sth->finish();
1458   return @row;
1459 }
1460
1461 =head2 sth
1462
1463 =over 4
1464
1465 =item Arguments: $sql
1466
1467 =back
1468
1469 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1470
1471 =cut
1472
1473 sub _dbh_sth {
1474   my ($self, $dbh, $sql) = @_;
1475
1476   # 3 is the if_active parameter which avoids active sth re-use
1477   my $sth = $self->disable_sth_caching
1478     ? $dbh->prepare($sql)
1479     : $dbh->prepare_cached($sql, {}, 3);
1480
1481   # XXX You would think RaiseError would make this impossible,
1482   #  but apparently that's not true :(
1483   $self->throw_exception($dbh->errstr) if !$sth;
1484
1485   $sth;
1486 }
1487
1488 sub sth {
1489   my ($self, $sql) = @_;
1490   $self->dbh_do('_dbh_sth', $sql);
1491 }
1492
1493 sub _dbh_columns_info_for {
1494   my ($self, $dbh, $table) = @_;
1495
1496   if ($dbh->can('column_info')) {
1497     my %result;
1498     eval {
1499       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1500       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1501       $sth->execute();
1502       while ( my $info = $sth->fetchrow_hashref() ){
1503         my %column_info;
1504         $column_info{data_type}   = $info->{TYPE_NAME};
1505         $column_info{size}      = $info->{COLUMN_SIZE};
1506         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1507         $column_info{default_value} = $info->{COLUMN_DEF};
1508         my $col_name = $info->{COLUMN_NAME};
1509         $col_name =~ s/^\"(.*)\"$/$1/;
1510
1511         $result{$col_name} = \%column_info;
1512       }
1513     };
1514     return \%result if !$@ && scalar keys %result;
1515   }
1516
1517   my %result;
1518   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1519   $sth->execute;
1520   my @columns = @{$sth->{NAME_lc}};
1521   for my $i ( 0 .. $#columns ){
1522     my %column_info;
1523     $column_info{data_type} = $sth->{TYPE}->[$i];
1524     $column_info{size} = $sth->{PRECISION}->[$i];
1525     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1526
1527     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1528       $column_info{data_type} = $1;
1529       $column_info{size}    = $2;
1530     }
1531
1532     $result{$columns[$i]} = \%column_info;
1533   }
1534   $sth->finish;
1535
1536   foreach my $col (keys %result) {
1537     my $colinfo = $result{$col};
1538     my $type_num = $colinfo->{data_type};
1539     my $type_name;
1540     if(defined $type_num && $dbh->can('type_info')) {
1541       my $type_info = $dbh->type_info($type_num);
1542       $type_name = $type_info->{TYPE_NAME} if $type_info;
1543       $colinfo->{data_type} = $type_name if $type_name;
1544     }
1545   }
1546
1547   return \%result;
1548 }
1549
1550 sub columns_info_for {
1551   my ($self, $table) = @_;
1552   $self->dbh_do('_dbh_columns_info_for', $table);
1553 }
1554
1555 =head2 last_insert_id
1556
1557 Return the row id of the last insert.
1558
1559 =cut
1560
1561 sub _dbh_last_insert_id {
1562     # All Storage's need to register their own _dbh_last_insert_id
1563     # the old SQLite-based method was highly inappropriate
1564
1565     my $self = shift;
1566     my $class = ref $self;
1567     $self->throw_exception (<<EOE);
1568
1569 No _dbh_last_insert_id() method found in $class.
1570 Since the method of obtaining the autoincrement id of the last insert
1571 operation varies greatly between different databases, this method must be
1572 individually implemented for every storage class.
1573 EOE
1574 }
1575
1576 sub last_insert_id {
1577   my $self = shift;
1578   $self->dbh_do('_dbh_last_insert_id', @_);
1579 }
1580
1581 =head2 sqlt_type
1582
1583 Returns the database driver name.
1584
1585 =cut
1586
1587 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1588
1589 =head2 bind_attribute_by_data_type
1590
1591 Given a datatype from column info, returns a database specific bind
1592 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1593 let the database planner just handle it.
1594
1595 Generally only needed for special case column types, like bytea in postgres.
1596
1597 =cut
1598
1599 sub bind_attribute_by_data_type {
1600     return;
1601 }
1602
1603 =head2 create_ddl_dir
1604
1605 =over 4
1606
1607 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1608
1609 =back
1610
1611 Creates a SQL file based on the Schema, for each of the specified
1612 database types, in the given directory.
1613
1614 By default, C<\%sqlt_args> will have
1615
1616  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1617
1618 merged with the hash passed in. To disable any of those features, pass in a
1619 hashref like the following
1620
1621  { ignore_constraint_names => 0, # ... other options }
1622
1623 =cut
1624
1625 sub create_ddl_dir {
1626   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1627
1628   if(!$dir || !-d $dir) {
1629     warn "No directory given, using ./\n";
1630     $dir = "./";
1631   }
1632   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1633   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1634
1635   my $schema_version = $schema->schema_version || '1.x';
1636   $version ||= $schema_version;
1637
1638   $sqltargs = {
1639     add_drop_table => 1,
1640     ignore_constraint_names => 1,
1641     ignore_index_names => 1,
1642     %{$sqltargs || {}}
1643   };
1644
1645   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1646       . $self->_check_sqlt_message . q{'})
1647           if !$self->_check_sqlt_version;
1648
1649   my $sqlt = SQL::Translator->new( $sqltargs );
1650
1651   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1652   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1653
1654   foreach my $db (@$databases) {
1655     $sqlt->reset();
1656     $sqlt->{schema} = $sqlt_schema;
1657     $sqlt->producer($db);
1658
1659     my $file;
1660     my $filename = $schema->ddl_filename($db, $version, $dir);
1661     if (-e $filename && ($version eq $schema_version )) {
1662       # if we are dumping the current version, overwrite the DDL
1663       warn "Overwriting existing DDL file - $filename";
1664       unlink($filename);
1665     }
1666
1667     my $output = $sqlt->translate;
1668     if(!$output) {
1669       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1670       next;
1671     }
1672     if(!open($file, ">$filename")) {
1673       $self->throw_exception("Can't open $filename for writing ($!)");
1674       next;
1675     }
1676     print $file $output;
1677     close($file);
1678
1679     next unless ($preversion);
1680
1681     require SQL::Translator::Diff;
1682
1683     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1684     if(!-e $prefilename) {
1685       warn("No previous schema file found ($prefilename)");
1686       next;
1687     }
1688
1689     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1690     if(-e $difffile) {
1691       warn("Overwriting existing diff file - $difffile");
1692       unlink($difffile);
1693     }
1694
1695     my $source_schema;
1696     {
1697       my $t = SQL::Translator->new($sqltargs);
1698       $t->debug( 0 );
1699       $t->trace( 0 );
1700       $t->parser( $db )                       or die $t->error;
1701       my $out = $t->translate( $prefilename ) or die $t->error;
1702       $source_schema = $t->schema;
1703       unless ( $source_schema->name ) {
1704         $source_schema->name( $prefilename );
1705       }
1706     }
1707
1708     # The "new" style of producers have sane normalization and can support
1709     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1710     # And we have to diff parsed SQL against parsed SQL.
1711     my $dest_schema = $sqlt_schema;
1712
1713     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1714       my $t = SQL::Translator->new($sqltargs);
1715       $t->debug( 0 );
1716       $t->trace( 0 );
1717       $t->parser( $db )                    or die $t->error;
1718       my $out = $t->translate( $filename ) or die $t->error;
1719       $dest_schema = $t->schema;
1720       $dest_schema->name( $filename )
1721         unless $dest_schema->name;
1722     }
1723
1724     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1725                                                   $dest_schema,   $db,
1726                                                   $sqltargs
1727                                                  );
1728     if(!open $file, ">$difffile") {
1729       $self->throw_exception("Can't write to $difffile ($!)");
1730       next;
1731     }
1732     print $file $diff;
1733     close($file);
1734   }
1735 }
1736
1737 =head2 deployment_statements
1738
1739 =over 4
1740
1741 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1742
1743 =back
1744
1745 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1746 The database driver name is given by C<$type>, though the value from
1747 L</sqlt_type> is used if it is not specified.
1748
1749 C<$directory> is used to return statements from files in a previously created
1750 L</create_ddl_dir> directory and is optional. The filenames are constructed
1751 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1752
1753 If no C<$directory> is specified then the statements are constructed on the
1754 fly using L<SQL::Translator> and C<$version> is ignored.
1755
1756 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1757
1758 =cut
1759
1760 sub deployment_statements {
1761   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1762   # Need to be connected to get the correct sqlt_type
1763   $self->ensure_connected() unless $type;
1764   $type ||= $self->sqlt_type;
1765   $version ||= $schema->schema_version || '1.x';
1766   $dir ||= './';
1767   my $filename = $schema->ddl_filename($type, $version, $dir);
1768   if(-f $filename)
1769   {
1770       my $file;
1771       open($file, "<$filename")
1772         or $self->throw_exception("Can't open $filename ($!)");
1773       my @rows = <$file>;
1774       close($file);
1775       return join('', @rows);
1776   }
1777
1778   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1779       . $self->_check_sqlt_message . q{'})
1780           if !$self->_check_sqlt_version;
1781
1782   require SQL::Translator::Parser::DBIx::Class;
1783   eval qq{use SQL::Translator::Producer::${type}};
1784   $self->throw_exception($@) if $@;
1785
1786   # sources needs to be a parser arg, but for simplicty allow at top level
1787   # coming in
1788   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1789       if exists $sqltargs->{sources};
1790
1791   my $tr = SQL::Translator->new(%$sqltargs);
1792   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1793   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1794 }
1795
1796 sub deploy {
1797   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1798   my $deploy = sub {
1799     my $line = shift;
1800     return if($line =~ /^--/);
1801     return if(!$line);
1802     # next if($line =~ /^DROP/m);
1803     return if($line =~ /^BEGIN TRANSACTION/m);
1804     return if($line =~ /^COMMIT/m);
1805     return if $line =~ /^\s+$/; # skip whitespace only
1806     $self->_query_start($line);
1807     eval {
1808       $self->dbh->do($line); # shouldn't be using ->dbh ?
1809     };
1810     if ($@) {
1811       warn qq{$@ (running "${line}")};
1812     }
1813     $self->_query_end($line);
1814   };
1815   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } );
1816   if (@statements > 1) {
1817     foreach my $statement (@statements) {
1818       $deploy->( $statement );
1819     }
1820   }
1821   elsif (@statements == 1) {
1822     foreach my $line ( split(";\n", $statements[0])) {
1823       $deploy->( $line );
1824     }
1825   }
1826 }
1827
1828 =head2 datetime_parser
1829
1830 Returns the datetime parser class
1831
1832 =cut
1833
1834 sub datetime_parser {
1835   my $self = shift;
1836   return $self->{datetime_parser} ||= do {
1837     $self->ensure_connected;
1838     $self->build_datetime_parser(@_);
1839   };
1840 }
1841
1842 =head2 datetime_parser_type
1843
1844 Defines (returns) the datetime parser class - currently hardwired to
1845 L<DateTime::Format::MySQL>
1846
1847 =cut
1848
1849 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1850
1851 =head2 build_datetime_parser
1852
1853 See L</datetime_parser>
1854
1855 =cut
1856
1857 sub build_datetime_parser {
1858   my $self = shift;
1859   my $type = $self->datetime_parser_type(@_);
1860   eval "use ${type}";
1861   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1862   return $type;
1863 }
1864
1865 {
1866     my $_check_sqlt_version; # private
1867     my $_check_sqlt_message; # private
1868     sub _check_sqlt_version {
1869         return $_check_sqlt_version if defined $_check_sqlt_version;
1870         eval 'use SQL::Translator "0.09003"';
1871         $_check_sqlt_message = $@ || '';
1872         $_check_sqlt_version = !$@;
1873     }
1874
1875     sub _check_sqlt_message {
1876         _check_sqlt_version if !defined $_check_sqlt_message;
1877         $_check_sqlt_message;
1878     }
1879 }
1880
1881 =head2 is_replicating
1882
1883 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1884 replicate from a master database.  Default is undef, which is the result
1885 returned by databases that don't support replication.
1886
1887 =cut
1888
1889 sub is_replicating {
1890     return;
1891
1892 }
1893
1894 =head2 lag_behind_master
1895
1896 Returns a number that represents a certain amount of lag behind a master db
1897 when a given storage is replicating.  The number is database dependent, but
1898 starts at zero and increases with the amount of lag. Default in undef
1899
1900 =cut
1901
1902 sub lag_behind_master {
1903     return;
1904 }
1905
1906 sub DESTROY {
1907   my $self = shift;
1908   return if !$self->_dbh;
1909   $self->_verify_pid;
1910   $self->_dbh(undef);
1911 }
1912
1913 1;
1914
1915 =head1 USAGE NOTES
1916
1917 =head2 DBIx::Class and AutoCommit
1918
1919 DBIx::Class can do some wonderful magic with handling exceptions,
1920 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1921 combined with C<txn_do> for transaction support.
1922
1923 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1924 in an assumed transaction between commits, and you're telling us you'd
1925 like to manage that manually.  A lot of the magic protections offered by
1926 this module will go away.  We can't protect you from exceptions due to database
1927 disconnects because we don't know anything about how to restart your
1928 transactions.  You're on your own for handling all sorts of exceptional
1929 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1930 be with raw DBI.
1931
1932
1933 =head1 SQL METHODS
1934
1935 The module defines a set of methods within the DBIC::SQL::Abstract
1936 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1937 SQL query functions.
1938
1939 The following methods are extended:-
1940
1941 =over 4
1942
1943 =item delete
1944
1945 =item insert
1946
1947 =item select
1948
1949 =item update
1950
1951 =item limit_dialect
1952
1953 See L</connect_info> for details.
1954
1955 =item quote_char
1956
1957 See L</connect_info> for details.
1958
1959 =item name_sep
1960
1961 See L</connect_info> for details.
1962
1963 =back
1964
1965 =head1 AUTHORS
1966
1967 Matt S. Trout <mst@shadowcatsystems.co.uk>
1968
1969 Andy Grundman <andy@hybridized.org>
1970
1971 =head1 LICENSE
1972
1973 You may distribute this code under the same terms as Perl itself.
1974
1975 =cut