lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  33
  34 BEGIN {
  35
  36 package # Hide from PAUSE
  37   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  38
  39 use base qw/SQL::Abstract::Limit/;
  40
  41 # This prevents the caching of $dbh in S::A::L, I believe
  42 sub new {
  43   my $self = shift->SUPER::new(@_);
  44
  45   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  46   #   it with what it resolves to:
  47   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  48     if ref $self->{limit_dialect};
  49
  50   $self;
  51 }
  52
  53 sub _RowNumberOver {
  54   my ($self, $sql, $order, $rows, $offset ) = @_;
  55
  56   $offset += 1;
  57   my $last = $rows + $offset;
  58   my ( $order_by ) = $self->_order_by( $order );
  59
  60   $sql = <<"";
  61 SELECT * FROM
  62 (
  63    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  64       $sql
  65       $order_by
  66    ) Q1
  67 ) Q2
  68 WHERE ROW_NUM BETWEEN $offset AND $last
  69
  70   return $sql;
  71 }
  72
  73
  74 # While we're at it, this should make LIMIT queries more efficient,
  75 #  without digging into things too deeply
  76 use Scalar::Util 'blessed';
  77 sub _find_syntax {
  78   my ($self, $syntax) = @_;
  79   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  80   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  81     return 'RowNumberOver';
  82   }
  83
  84   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  85 }
  86
  87 sub select {
  88   my ($self, $table, $fields, $where, $order, @rest) = @_;
  89   if (ref $table eq 'SCALAR') {
  90     $table = $$table;
  91   }
  92   elsif (not ref $table) {
  93     $table = $self->_quote($table);
  94   }
  95   local $self->{rownum_hack_count} = 1
  96     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  97   @rest = (-1) unless defined $rest[0];
  98   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  99     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 100   local $self->{having_bind} = [];
 101   my ($sql, @ret) = $self->SUPER::select(
 102     $table, $self->_recurse_fields($fields), $where, $order, @rest
 103   );
 104   $sql .=
 105     $self->{for} ?
 106     (
 107       $self->{for} eq 'update' ? ' FOR UPDATE' :
 108       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 109       ''
 110     ) :
 111     ''
 112   ;
 113   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 114 }
 115
 116 sub insert {
 117   my $self = shift;
 118   my $table = shift;
 119   $table = $self->_quote($table) unless ref($table);
 120   $self->SUPER::insert($table, @_);
 121 }
 122
 123 sub update {
 124   my $self = shift;
 125   my $table = shift;
 126   $table = $self->_quote($table) unless ref($table);
 127   $self->SUPER::update($table, @_);
 128 }
 129
 130 sub delete {
 131   my $self = shift;
 132   my $table = shift;
 133   $table = $self->_quote($table) unless ref($table);
 134   $self->SUPER::delete($table, @_);
 135 }
 136
 137 sub _emulate_limit {
 138   my $self = shift;
 139   if ($_[3] == -1) {
 140     return $_[1].$self->_order_by($_[2]);
 141   } else {
 142     return $self->SUPER::_emulate_limit(@_);
 143   }
 144 }
 145
 146 sub _recurse_fields {
 147   my ($self, $fields, $params) = @_;
 148   my $ref = ref $fields;
 149   return $self->_quote($fields) unless $ref;
 150   return $$fields if $ref eq 'SCALAR';
 151
 152   if ($ref eq 'ARRAY') {
 153     return join(', ', map {
 154       $self->_recurse_fields($_)
 155         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 156           ? ' AS col'.$self->{rownum_hack_count}++
 157           : '')
 158       } @$fields);
 159   } elsif ($ref eq 'HASH') {
 160     foreach my $func (keys %$fields) {
 161       return $self->_sqlcase($func)
 162         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 163     }
 164   }
 165 }
 166
 167 sub _order_by {
 168   my $self = shift;
 169   my $ret = '';
 170   my @extra;
 171   if (ref $_[0] eq 'HASH') {
 172     if (defined $_[0]->{group_by}) {
 173       $ret = $self->_sqlcase(' group by ')
 174         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 175     }
 176     if (defined $_[0]->{having}) {
 177       my $frag;
 178       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 179       push(@{$self->{having_bind}}, @extra);
 180       $ret .= $self->_sqlcase(' having ').$frag;
 181     }
 182     if (defined $_[0]->{order_by}) {
 183       $ret .= $self->_order_by($_[0]->{order_by});
 184     }
 185   } elsif (ref $_[0] eq 'SCALAR') {
 186     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 187   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 188     my @order = @{+shift};
 189     $ret = $self->_sqlcase(' order by ')
 190           .join(', ', map {
 191                         my $r = $self->_order_by($_, @_);
 192                         $r =~ s/^ ?ORDER BY //i;
 193                         $r;
 194                       } @order);
 195   } else {
 196     $ret = $self->SUPER::_order_by(@_);
 197   }
 198   return $ret;
 199 }
 200
 201 sub _order_directions {
 202   my ($self, $order) = @_;
 203   $order = $order->{order_by} if ref $order eq 'HASH';
 204   return $self->SUPER::_order_directions($order);
 205 }
 206
 207 sub _table {
 208   my ($self, $from) = @_;
 209   if (ref $from eq 'ARRAY') {
 210     return $self->_recurse_from(@$from);
 211   } elsif (ref $from eq 'HASH') {
 212     return $self->_make_as($from);
 213   } else {
 214     return $from; # would love to quote here but _table ends up getting called
 215                   # twice during an ->select without a limit clause due to
 216                   # the way S::A::Limit->select works. should maybe consider
 217                   # bypassing this and doing S::A::select($self, ...) in
 218                   # our select method above. meantime, quoting shims have
 219                   # been added to select/insert/update/delete here
 220   }
 221 }
 222
 223 sub _recurse_from {
 224   my ($self, $from, @join) = @_;
 225   my @sqlf;
 226   push(@sqlf, $self->_make_as($from));
 227   foreach my $j (@join) {
 228     my ($to, $on) = @$j;
 229
 230     # check whether a join type exists
 231     my $join_clause = '';
 232     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 233     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 234       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 235     } else {
 236       $join_clause = ' JOIN ';
 237     }
 238     push(@sqlf, $join_clause);
 239
 240     if (ref $to eq 'ARRAY') {
 241       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 242     } else {
 243       push(@sqlf, $self->_make_as($to));
 244     }
 245     push(@sqlf, ' ON ', $self->_join_condition($on));
 246   }
 247   return join('', @sqlf);
 248 }
 249
 250 sub _make_as {
 251   my ($self, $from) = @_;
 252   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 253                      reverse each %{$self->_skip_options($from)});
 254 }
 255
 256 sub _skip_options {
 257   my ($self, $hash) = @_;
 258   my $clean_hash = {};
 259   $clean_hash->{$_} = $hash->{$_}
 260     for grep {!/^-/} keys %$hash;
 261   return $clean_hash;
 262 }
 263
 264 sub _join_condition {
 265   my ($self, $cond) = @_;
 266   if (ref $cond eq 'HASH') {
 267     my %j;
 268     for (keys %$cond) {
 269       my $v = $cond->{$_};
 270       if (ref $v) {
 271         # XXX no throw_exception() in this package and croak() fails with strange results
 272         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 273             if ref($v) ne 'SCALAR';
 274         $j{$_} = $v;
 275       }
 276       else {
 277         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 278       }
 279     };
 280     return scalar($self->_recurse_where(\%j));
 281   } elsif (ref $cond eq 'ARRAY') {
 282     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 283   } else {
 284     die "Can't handle this yet!";
 285   }
 286 }
 287
 288 sub _quote {
 289   my ($self, $label) = @_;
 290   return '' unless defined $label;
 291   return "*" if $label eq '*';
 292   return $label unless $self->{quote_char};
 293   if(ref $self->{quote_char} eq "ARRAY"){
 294     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 295       if !defined $self->{name_sep};
 296     my $sep = $self->{name_sep};
 297     return join($self->{name_sep},
 298         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 299        split(/\Q$sep\E/,$label));
 300   }
 301   return $self->SUPER::_quote($label);
 302 }
 303
 304 sub limit_dialect {
 305     my $self = shift;
 306     $self->{limit_dialect} = shift if @_;
 307     return $self->{limit_dialect};
 308 }
 309
 310 sub quote_char {
 311     my $self = shift;
 312     $self->{quote_char} = shift if @_;
 313     return $self->{quote_char};
 314 }
 315
 316 sub name_sep {
 317     my $self = shift;
 318     $self->{name_sep} = shift if @_;
 319     return $self->{name_sep};
 320 }
 321
 322 } # End of BEGIN block
 323
 324 =head1 NAME
 325
 326 DBIx::Class::Storage::DBI - DBI storage handler
 327
 328 =head1 SYNOPSIS
 329
 330   my $schema = MySchema->connect('dbi:SQLite:my.db');
 331
 332   $schema->storage->debug(1);
 333   $schema->dbh_do("DROP TABLE authors");
 334
 335   $schema->resultset('Book')->search({
 336      written_on => $schema->storage->datetime_parser(DateTime->now)
 337   });
 338
 339 =head1 DESCRIPTION
 340
 341 This class represents the connection to an RDBMS via L<DBI>.  See
 342 L<DBIx::Class::Storage> for general information.  This pod only
 343 documents DBI-specific methods and behaviors.
 344
 345 =head1 METHODS
 346
 347 =cut
 348
 349 sub new {
 350   my $new = shift->next::method(@_);
 351
 352   $new->transaction_depth(0);
 353   $new->_sql_maker_opts({});
 354   $new->{savepoints} = [];
 355   $new->{_in_dbh_do} = 0;
 356   $new->{_dbh_gen} = 0;
 357
 358   $new;
 359 }
 360
 361 =head2 connect_info
 362
 363 This method is normally called by L<DBIx::Class::Schema/connection>, which
 364 encapsulates its argument list in an arrayref before passing them here.
 365
 366 The argument list may contain:
 367
 368 =over
 369
 370 =item *
 371
 372 The same 4-element argument set one would normally pass to
 373 L<DBI/connect>, optionally followed by
 374 L<extra attributes|/DBIx::Class specific connection attributes>
 375 recognized by DBIx::Class:
 376
 377   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 378
 379 =item *
 380
 381 A single code reference which returns a connected
 382 L<DBI database handle|DBI/connect> optionally followed by
 383 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 384 by DBIx::Class:
 385
 386   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 387
 388 =item *
 389
 390 A single hashref with all the attributes and the dsn/user/password
 391 mixed together:
 392
 393   $connect_info_args = [{
 394     dsn => $dsn,
 395     user => $user,
 396     password => $pass,
 397     %dbi_attributes,
 398     %extra_attributes,
 399   }];
 400
 401 This is particularly useful for L<Catalyst> based applications, allowing the
 402 following config (L<Config::General> style):
 403
 404   <Model::DB>
 405     schema_class   App::DB
 406     <connect_info>
 407       dsn          dbi:mysql:database=test
 408       user         testuser
 409       password     TestPass
 410       AutoCommit   1
 411     </connect_info>
 412   </Model::DB>
 413
 414 =back
 415
 416 Please note that the L<DBI> docs recommend that you always explicitly
 417 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 418 recommends that it be set to I<1>, and that you perform transactions
 419 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 420 to I<1> if you do not do explicitly set it to zero.  This is the default
 421 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 422
 423 =head3 DBIx::Class specific connection attributes
 424
 425 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 426 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 427 the following connection options. These options can be mixed in with your other
 428 L<DBI> connection attributes, or placed in a seperate hashref
 429 (C<\%extra_attributes>) as shown above.
 430
 431 Every time C<connect_info> is invoked, any previous settings for
 432 these options will be cleared before setting the new ones, regardless of
 433 whether any options are specified in the new C<connect_info>.
 434
 435
 436 =over
 437
 438 =item on_connect_do
 439
 440 Specifies things to do immediately after connecting or re-connecting to
 441 the database.  Its value may contain:
 442
 443 =over
 444
 445 =item an array reference
 446
 447 This contains SQL statements to execute in order.  Each element contains
 448 a string or a code reference that returns a string.
 449
 450 =item a code reference
 451
 452 This contains some code to execute.  Unlike code references within an
 453 array reference, its return value is ignored.
 454
 455 =back
 456
 457 =item on_disconnect_do
 458
 459 Takes arguments in the same form as L</on_connect_do> and executes them
 460 immediately before disconnecting from the database.
 461
 462 Note, this only runs if you explicitly call L</disconnect> on the
 463 storage object.
 464
 465 =item disable_sth_caching
 466
 467 If set to a true value, this option will disable the caching of
 468 statement handles via L<DBI/prepare_cached>.
 469
 470 =item limit_dialect
 471
 472 Sets the limit dialect. This is useful for JDBC-bridge among others
 473 where the remote SQL-dialect cannot be determined by the name of the
 474 driver alone. See also L<SQL::Abstract::Limit>.
 475
 476 =item quote_char
 477
 478 Specifies what characters to use to quote table and column names. If
 479 you use this you will want to specify L</name_sep> as well.
 480
 481 C<quote_char> expects either a single character, in which case is it
 482 is placed on either side of the table/column name, or an arrayref of length
 483 2 in which case the table/column name is placed between the elements.
 484
 485 For example under MySQL you should use C<< quote_char => '`' >>, and for
 486 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 487
 488 =item name_sep
 489
 490 This only needs to be used in conjunction with C<quote_char>, and is used to
 491 specify the charecter that seperates elements (schemas, tables, columns) from
 492 each other. In most cases this is simply a C<.>.
 493
 494 The consequences of not supplying this value is that L<SQL::Abstract>
 495 will assume DBIx::Class' uses of aliases to be complete column
 496 names. The output will look like I<"me.name"> when it should actually
 497 be I<"me"."name">.
 498
 499 =item unsafe
 500
 501 This Storage driver normally installs its own C<HandleError>, sets
 502 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 503 all database handles, including those supplied by a coderef.  It does this
 504 so that it can have consistent and useful error behavior.
 505
 506 If you set this option to a true value, Storage will not do its usual
 507 modifications to the database handle's attributes, and instead relies on
 508 the settings in your connect_info DBI options (or the values you set in
 509 your connection coderef, in the case that you are connecting via coderef).
 510
 511 Note that your custom settings can cause Storage to malfunction,
 512 especially if you set a C<HandleError> handler that suppresses exceptions
 513 and/or disable C<RaiseError>.
 514
 515 =item auto_savepoint
 516
 517 If this option is true, L<DBIx::Class> will use savepoints when nesting
 518 transactions, making it possible to recover from failure in the inner
 519 transaction without having to abort all outer transactions.
 520
 521 =item cursor_class
 522
 523 Use this argument to supply a cursor class other than the default
 524 L<DBIx::Class::Storage::DBI::Cursor>.
 525
 526 =back
 527
 528 Some real-life examples of arguments to L</connect_info> and
 529 L<DBIx::Class::Schema/connect>
 530
 531   # Simple SQLite connection
 532   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 533
 534   # Connect via subref
 535   ->connect_info([ sub { DBI->connect(...) } ]);
 536
 537   # A bit more complicated
 538   ->connect_info(
 539     [
 540       'dbi:Pg:dbname=foo',
 541       'postgres',
 542       'my_pg_password',
 543       { AutoCommit => 1 },
 544       { quote_char => q{"}, name_sep => q{.} },
 545     ]
 546   );
 547
 548   # Equivalent to the previous example
 549   ->connect_info(
 550     [
 551       'dbi:Pg:dbname=foo',
 552       'postgres',
 553       'my_pg_password',
 554       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 555     ]
 556   );
 557
 558   # Same, but with hashref as argument
 559   # See parse_connect_info for explanation
 560   ->connect_info(
 561     [{
 562       dsn         => 'dbi:Pg:dbname=foo',
 563       user        => 'postgres',
 564       password    => 'my_pg_password',
 565       AutoCommit  => 1,
 566       quote_char  => q{"},
 567       name_sep    => q{.},
 568     }]
 569   );
 570
 571   # Subref + DBIx::Class-specific connection options
 572   ->connect_info(
 573     [
 574       sub { DBI->connect(...) },
 575       {
 576           quote_char => q{`},
 577           name_sep => q{@},
 578           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 579           disable_sth_caching => 1,
 580       },
 581     ]
 582   );
 583
 584
 585
 586 =cut
 587
 588 sub connect_info {
 589   my ($self, $info_arg) = @_;
 590
 591   return $self->_connect_info if !$info_arg;
 592
 593   my @args = @$info_arg;  # take a shallow copy for further mutilation
 594   $self->_connect_info([@args]); # copy for _connect_info
 595
 596
 597   # combine/pre-parse arguments depending on invocation style
 598
 599   my %attrs;
 600   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 601     %attrs = %{ $args[1] || {} };
 602     @args = $args[0];
 603   }
 604   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 605     %attrs = %{$args[0]};
 606     @args = ();
 607     for (qw/password user dsn/) {
 608       unshift @args, delete $attrs{$_};
 609     }
 610   }
 611   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 612     %attrs = (
 613       % { $args[3] || {} },
 614       % { $args[4] || {} },
 615     );
 616     @args = @args[0,1,2];
 617   }
 618
 619   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 620   #  the new set of options
 621   $self->_sql_maker(undef);
 622   $self->_sql_maker_opts({});
 623
 624   if(keys %attrs) {
 625     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 626       if(my $value = delete $attrs{$storage_opt}) {
 627         $self->$storage_opt($value);
 628       }
 629     }
 630     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 631       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 632         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 633       }
 634     }
 635   }
 636
 637   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 638
 639   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 640   $self->_connect_info;
 641 }
 642
 643 =head2 on_connect_do
 644
 645 This method is deprecated in favour of setting via L</connect_info>.
 646
 647
 648 =head2 dbh_do
 649
 650 Arguments: ($subref | $method_name), @extra_coderef_args?
 651
 652 Execute the given $subref or $method_name using the new exception-based
 653 connection management.
 654
 655 The first two arguments will be the storage object that C<dbh_do> was called
 656 on and a database handle to use.  Any additional arguments will be passed
 657 verbatim to the called subref as arguments 2 and onwards.
 658
 659 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 660 exception handling and reconnection (or failover in future subclasses).
 661
 662 Your subref should have no side-effects outside of the database, as
 663 there is the potential for your subref to be partially double-executed
 664 if the database connection was stale/dysfunctional.
 665
 666 Example:
 667
 668   my @stuff = $schema->storage->dbh_do(
 669     sub {
 670       my ($storage, $dbh, @cols) = @_;
 671       my $cols = join(q{, }, @cols);
 672       $dbh->selectrow_array("SELECT $cols FROM foo");
 673     },
 674     @column_list
 675   );
 676
 677 =cut
 678
 679 sub dbh_do {
 680   my $self = shift;
 681   my $code = shift;
 682
 683   my $dbh = $self->_dbh;
 684
 685   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 686       || $self->{transaction_depth};
 687
 688   local $self->{_in_dbh_do} = 1;
 689
 690   my @result;
 691   my $want_array = wantarray;
 692
 693   eval {
 694     $self->_verify_pid if $dbh;
 695     if(!$self->_dbh) {
 696         $self->_populate_dbh;
 697         $dbh = $self->_dbh;
 698     }
 699
 700     if($want_array) {
 701         @result = $self->$code($dbh, @_);
 702     }
 703     elsif(defined $want_array) {
 704         $result[0] = $self->$code($dbh, @_);
 705     }
 706     else {
 707         $self->$code($dbh, @_);
 708     }
 709   };
 710
 711   my $exception = $@;
 712   if(!$exception) { return $want_array ? @result : $result[0] }
 713
 714   $self->throw_exception($exception) if $self->connected;
 715
 716   # We were not connected - reconnect and retry, but let any
 717   #  exception fall right through this time
 718   $self->_populate_dbh;
 719   $self->$code($self->_dbh, @_);
 720 }
 721
 722 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 723 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 724 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 725 sub txn_do {
 726   my $self = shift;
 727   my $coderef = shift;
 728
 729   ref $coderef eq 'CODE' or $self->throw_exception
 730     ('$coderef must be a CODE reference');
 731
 732   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 733
 734   local $self->{_in_dbh_do} = 1;
 735
 736   my @result;
 737   my $want_array = wantarray;
 738
 739   my $tried = 0;
 740   while(1) {
 741     eval {
 742       $self->_verify_pid if $self->_dbh;
 743       $self->_populate_dbh if !$self->_dbh;
 744
 745       $self->txn_begin;
 746       if($want_array) {
 747           @result = $coderef->(@_);
 748       }
 749       elsif(defined $want_array) {
 750           $result[0] = $coderef->(@_);
 751       }
 752       else {
 753           $coderef->(@_);
 754       }
 755       $self->txn_commit;
 756     };
 757
 758     my $exception = $@;
 759     if(!$exception) { return $want_array ? @result : $result[0] }
 760
 761     if($tried++ > 0 || $self->connected) {
 762       eval { $self->txn_rollback };
 763       my $rollback_exception = $@;
 764       if($rollback_exception) {
 765         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 766         $self->throw_exception($exception)  # propagate nested rollback
 767           if $rollback_exception =~ /$exception_class/;
 768
 769         $self->throw_exception(
 770           "Transaction aborted: ${exception}. "
 771           . "Rollback failed: ${rollback_exception}"
 772         );
 773       }
 774       $self->throw_exception($exception)
 775     }
 776
 777     # We were not connected, and was first try - reconnect and retry
 778     # via the while loop
 779     $self->_populate_dbh;
 780   }
 781 }
 782
 783 =head2 disconnect
 784
 785 Our C<disconnect> method also performs a rollback first if the
 786 database is not in C<AutoCommit> mode.
 787
 788 =cut
 789
 790 sub disconnect {
 791   my ($self) = @_;
 792
 793   if( $self->connected ) {
 794     my $connection_do = $self->on_disconnect_do;
 795     $self->_do_connection_actions($connection_do) if ref($connection_do);
 796
 797     $self->_dbh->rollback unless $self->_dbh_autocommit;
 798     $self->_dbh->disconnect;
 799     $self->_dbh(undef);
 800     $self->{_dbh_gen}++;
 801   }
 802 }
 803
 804 =head2 with_deferred_fk_checks
 805
 806 =over 4
 807
 808 =item Arguments: C<$coderef>
 809
 810 =item Return Value: The return value of $coderef
 811
 812 =back
 813
 814 Storage specific method to run the code ref with FK checks deferred or
 815 in MySQL's case disabled entirely.
 816
 817 =cut
 818
 819 # Storage subclasses should override this
 820 sub with_deferred_fk_checks {
 821   my ($self, $sub) = @_;
 822
 823   $sub->();
 824 }
 825
 826 sub connected {
 827   my ($self) = @_;
 828
 829   if(my $dbh = $self->_dbh) {
 830       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 831           $self->_dbh(undef);
 832           $self->{_dbh_gen}++;
 833           return;
 834       }
 835       else {
 836           $self->_verify_pid;
 837           return 0 if !$self->_dbh;
 838       }
 839       return ($dbh->FETCH('Active') && $dbh->ping);
 840   }
 841
 842   return 0;
 843 }
 844
 845 # handle pid changes correctly
 846 #  NOTE: assumes $self->_dbh is a valid $dbh
 847 sub _verify_pid {
 848   my ($self) = @_;
 849
 850   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 851
 852   $self->_dbh->{InactiveDestroy} = 1;
 853   $self->_dbh(undef);
 854   $self->{_dbh_gen}++;
 855
 856   return;
 857 }
 858
 859 sub ensure_connected {
 860   my ($self) = @_;
 861
 862   unless ($self->connected) {
 863     $self->_populate_dbh;
 864   }
 865 }
 866
 867 =head2 dbh
 868
 869 Returns the dbh - a data base handle of class L<DBI>.
 870
 871 =cut
 872
 873 sub dbh {
 874   my ($self) = @_;
 875
 876   $self->ensure_connected;
 877   return $self->_dbh;
 878 }
 879
 880 sub _sql_maker_args {
 881     my ($self) = @_;
 882
 883     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 884 }
 885
 886 sub sql_maker {
 887   my ($self) = @_;
 888   unless ($self->_sql_maker) {
 889     my $sql_maker_class = $self->sql_maker_class;
 890     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 891   }
 892   return $self->_sql_maker;
 893 }
 894
 895 sub _rebless {}
 896
 897 sub _populate_dbh {
 898   my ($self) = @_;
 899   my @info = @{$self->_dbi_connect_info || []};
 900   $self->_dbh($self->_connect(@info));
 901
 902   # Always set the transaction depth on connect, since
 903   #  there is no transaction in progress by definition
 904   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 905
 906   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 907     my $driver = $self->_dbh->{Driver}->{Name};
 908     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 909       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 910       $self->_rebless();
 911     }
 912   }
 913
 914   my $connection_do = $self->on_connect_do;
 915   $self->_do_connection_actions($connection_do) if ref($connection_do);
 916
 917   $self->_conn_pid($$);
 918   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 919 }
 920
 921 sub _do_connection_actions {
 922   my $self = shift;
 923   my $connection_do = shift;
 924
 925   if (ref $connection_do eq 'ARRAY') {
 926     $self->_do_query($_) foreach @$connection_do;
 927   }
 928   elsif (ref $connection_do eq 'CODE') {
 929     $connection_do->();
 930   }
 931
 932   return $self;
 933 }
 934
 935 sub _do_query {
 936   my ($self, $action) = @_;
 937
 938   if (ref $action eq 'CODE') {
 939     $action = $action->($self);
 940     $self->_do_query($_) foreach @$action;
 941   }
 942   else {
 943     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 944     $self->_query_start(@to_run);
 945     $self->_dbh->do(@to_run);
 946     $self->_query_end(@to_run);
 947   }
 948
 949   return $self;
 950 }
 951
 952 sub _connect {
 953   my ($self, @info) = @_;
 954
 955   $self->throw_exception("You failed to provide any connection info")
 956     if !@info;
 957
 958   my ($old_connect_via, $dbh);
 959
 960   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 961     $old_connect_via = $DBI::connect_via;
 962     $DBI::connect_via = 'connect';
 963   }
 964
 965   eval {
 966     if(ref $info[0] eq 'CODE') {
 967        $dbh = &{$info[0]}
 968     }
 969     else {
 970        $dbh = DBI->connect(@info);
 971     }
 972
 973     if($dbh && !$self->unsafe) {
 974       my $weak_self = $self;
 975       weaken($weak_self);
 976       $dbh->{HandleError} = sub {
 977           if ($weak_self) {
 978             $weak_self->throw_exception("DBI Exception: $_[0]");
 979           }
 980           else {
 981             croak ("DBI Exception: $_[0]");
 982           }
 983       };
 984       $dbh->{ShowErrorStatement} = 1;
 985       $dbh->{RaiseError} = 1;
 986       $dbh->{PrintError} = 0;
 987     }
 988   };
 989
 990   $DBI::connect_via = $old_connect_via if $old_connect_via;
 991
 992   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 993     if !$dbh || $@;
 994
 995   $self->_dbh_autocommit($dbh->{AutoCommit});
 996
 997   $dbh;
 998 }
 999
1000 sub svp_begin {
1001   my ($self, $name) = @_;
1002
1003   $name = $self->_svp_generate_name
1004     unless defined $name;
1005
1006   $self->throw_exception ("You can't use savepoints outside a transaction")
1007     if $self->{transaction_depth} == 0;
1008
1009   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1010     unless $self->can('_svp_begin');
1011
1012   push @{ $self->{savepoints} }, $name;
1013
1014   $self->debugobj->svp_begin($name) if $self->debug;
1015
1016   return $self->_svp_begin($name);
1017 }
1018
1019 sub svp_release {
1020   my ($self, $name) = @_;
1021
1022   $self->throw_exception ("You can't use savepoints outside a transaction")
1023     if $self->{transaction_depth} == 0;
1024
1025   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1026     unless $self->can('_svp_release');
1027
1028   if (defined $name) {
1029     $self->throw_exception ("Savepoint '$name' does not exist")
1030       unless grep { $_ eq $name } @{ $self->{savepoints} };
1031
1032     # Dig through the stack until we find the one we are releasing.  This keeps
1033     # the stack up to date.
1034     my $svp;
1035
1036     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1037   } else {
1038     $name = pop @{ $self->{savepoints} };
1039   }
1040
1041   $self->debugobj->svp_release($name) if $self->debug;
1042
1043   return $self->_svp_release($name);
1044 }
1045
1046 sub svp_rollback {
1047   my ($self, $name) = @_;
1048
1049   $self->throw_exception ("You can't use savepoints outside a transaction")
1050     if $self->{transaction_depth} == 0;
1051
1052   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1053     unless $self->can('_svp_rollback');
1054
1055   if (defined $name) {
1056       # If they passed us a name, verify that it exists in the stack
1057       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1058           $self->throw_exception("Savepoint '$name' does not exist!");
1059       }
1060
1061       # Dig through the stack until we find the one we are releasing.  This keeps
1062       # the stack up to date.
1063       while(my $s = pop(@{ $self->{savepoints} })) {
1064           last if($s eq $name);
1065       }
1066       # Add the savepoint back to the stack, as a rollback doesn't remove the
1067       # named savepoint, only everything after it.
1068       push(@{ $self->{savepoints} }, $name);
1069   } else {
1070       # We'll assume they want to rollback to the last savepoint
1071       $name = $self->{savepoints}->[-1];
1072   }
1073
1074   $self->debugobj->svp_rollback($name) if $self->debug;
1075
1076   return $self->_svp_rollback($name);
1077 }
1078
1079 sub _svp_generate_name {
1080     my ($self) = @_;
1081
1082     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1083 }
1084
1085 sub txn_begin {
1086   my $self = shift;
1087   $self->ensure_connected();
1088   if($self->{transaction_depth} == 0) {
1089     $self->debugobj->txn_begin()
1090       if $self->debug;
1091     # this isn't ->_dbh-> because
1092     #  we should reconnect on begin_work
1093     #  for AutoCommit users
1094     $self->dbh->begin_work;
1095   } elsif ($self->auto_savepoint) {
1096     $self->svp_begin;
1097   }
1098   $self->{transaction_depth}++;
1099 }
1100
1101 sub txn_commit {
1102   my $self = shift;
1103   if ($self->{transaction_depth} == 1) {
1104     my $dbh = $self->_dbh;
1105     $self->debugobj->txn_commit()
1106       if ($self->debug);
1107     $dbh->commit;
1108     $self->{transaction_depth} = 0
1109       if $self->_dbh_autocommit;
1110   }
1111   elsif($self->{transaction_depth} > 1) {
1112     $self->{transaction_depth}--;
1113     $self->svp_release
1114       if $self->auto_savepoint;
1115   }
1116 }
1117
1118 sub txn_rollback {
1119   my $self = shift;
1120   my $dbh = $self->_dbh;
1121   eval {
1122     if ($self->{transaction_depth} == 1) {
1123       $self->debugobj->txn_rollback()
1124         if ($self->debug);
1125       $self->{transaction_depth} = 0
1126         if $self->_dbh_autocommit;
1127       $dbh->rollback;
1128     }
1129     elsif($self->{transaction_depth} > 1) {
1130       $self->{transaction_depth}--;
1131       if ($self->auto_savepoint) {
1132         $self->svp_rollback;
1133         $self->svp_release;
1134       }
1135     }
1136     else {
1137       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1138     }
1139   };
1140   if ($@) {
1141     my $error = $@;
1142     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1143     $error =~ /$exception_class/ and $self->throw_exception($error);
1144     # ensure that a failed rollback resets the transaction depth
1145     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1146     $self->throw_exception($error);
1147   }
1148 }
1149
1150 # This used to be the top-half of _execute.  It was split out to make it
1151 #  easier to override in NoBindVars without duping the rest.  It takes up
1152 #  all of _execute's args, and emits $sql, @bind.
1153 sub _prep_for_execute {
1154   my ($self, $op, $extra_bind, $ident, $args) = @_;
1155
1156   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1157   unshift(@bind,
1158     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1159       if $extra_bind;
1160
1161   return ($sql, \@bind);
1162 }
1163
1164 sub _fix_bind_params {
1165     my ($self, @bind) = @_;
1166
1167     ### Turn @bind from something like this:
1168     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1169     ### to this:
1170     ###   ( "'1'", "'1'", "'3'" )
1171     return
1172         map {
1173             if ( defined( $_ && $_->[1] ) ) {
1174                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1175             }
1176             else { q{'NULL'}; }
1177         } @bind;
1178 }
1179
1180 sub _query_start {
1181     my ( $self, $sql, @bind ) = @_;
1182
1183     if ( $self->debug ) {
1184         @bind = $self->_fix_bind_params(@bind);
1185
1186         $self->debugobj->query_start( $sql, @bind );
1187     }
1188 }
1189
1190 sub _query_end {
1191     my ( $self, $sql, @bind ) = @_;
1192
1193     if ( $self->debug ) {
1194         @bind = $self->_fix_bind_params(@bind);
1195         $self->debugobj->query_end( $sql, @bind );
1196     }
1197 }
1198
1199 sub _dbh_execute {
1200   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1201
1202   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1203     $ident = $ident->from();
1204   }
1205
1206   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1207
1208   $self->_query_start( $sql, @$bind );
1209
1210   my $sth = $self->sth($sql,$op);
1211
1212   my $placeholder_index = 1;
1213
1214   foreach my $bound (@$bind) {
1215     my $attributes = {};
1216     my($column_name, @data) = @$bound;
1217
1218     if ($bind_attributes) {
1219       $attributes = $bind_attributes->{$column_name}
1220       if defined $bind_attributes->{$column_name};
1221     }
1222
1223     foreach my $data (@data) {
1224       $data = ref $data ? ''.$data : $data; # stringify args
1225
1226       $sth->bind_param($placeholder_index, $data, $attributes);
1227       $placeholder_index++;
1228     }
1229   }
1230
1231   # Can this fail without throwing an exception anyways???
1232   my $rv = $sth->execute();
1233   $self->throw_exception($sth->errstr) if !$rv;
1234
1235   $self->_query_end( $sql, @$bind );
1236
1237   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1238 }
1239
1240 sub _execute {
1241     my $self = shift;
1242     $self->dbh_do('_dbh_execute', @_)
1243 }
1244
1245 sub insert {
1246   my ($self, $source, $to_insert) = @_;
1247
1248   my $ident = $source->from;
1249   my $bind_attributes = $self->source_bind_attributes($source);
1250
1251   $self->ensure_connected;
1252   foreach my $col ( $source->columns ) {
1253     if ( !defined $to_insert->{$col} ) {
1254       my $col_info = $source->column_info($col);
1255
1256       if ( $col_info->{auto_nextval} ) {
1257         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1258       }
1259     }
1260   }
1261
1262   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1263
1264   return $to_insert;
1265 }
1266
1267 ## Still not quite perfect, and EXPERIMENTAL
1268 ## Currently it is assumed that all values passed will be "normal", i.e. not
1269 ## scalar refs, or at least, all the same type as the first set, the statement is
1270 ## only prepped once.
1271 sub insert_bulk {
1272   my ($self, $source, $cols, $data) = @_;
1273   my %colvalues;
1274   my $table = $source->from;
1275   @colvalues{@$cols} = (0..$#$cols);
1276   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1277
1278   $self->_query_start( $sql, @bind );
1279   my $sth = $self->sth($sql);
1280
1281 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1282
1283   ## This must be an arrayref, else nothing works!
1284
1285   my $tuple_status = [];
1286
1287   ##use Data::Dumper;
1288   ##print STDERR Dumper( $data, $sql, [@bind] );
1289
1290   my $time = time();
1291
1292   ## Get the bind_attributes, if any exist
1293   my $bind_attributes = $self->source_bind_attributes($source);
1294
1295   ## Bind the values and execute
1296   my $placeholder_index = 1;
1297
1298   foreach my $bound (@bind) {
1299
1300     my $attributes = {};
1301     my ($column_name, $data_index) = @$bound;
1302
1303     if( $bind_attributes ) {
1304       $attributes = $bind_attributes->{$column_name}
1305       if defined $bind_attributes->{$column_name};
1306     }
1307
1308     my @data = map { $_->[$data_index] } @$data;
1309
1310     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1311     $placeholder_index++;
1312   }
1313   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1314   $self->throw_exception($sth->errstr) if !$rv;
1315
1316   $self->_query_end( $sql, @bind );
1317   return (wantarray ? ($rv, $sth, @bind) : $rv);
1318 }
1319
1320 sub update {
1321   my $self = shift @_;
1322   my $source = shift @_;
1323   my $bind_attributes = $self->source_bind_attributes($source);
1324
1325   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1326 }
1327
1328
1329 sub delete {
1330   my $self = shift @_;
1331   my $source = shift @_;
1332
1333   my $bind_attrs = {}; ## If ever it's needed...
1334
1335   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1336 }
1337
1338 sub _select {
1339   my ($self, $ident, $select, $condition, $attrs) = @_;
1340   my $order = $attrs->{order_by};
1341
1342   if (ref $condition eq 'SCALAR') {
1343     my $unwrap = ${$condition};
1344     if ($unwrap =~ s/ORDER BY (.*)$//i) {
1345       $order = $1;
1346       $condition = \$unwrap;
1347     }
1348   }
1349
1350   my $for = delete $attrs->{for};
1351   my $sql_maker = $self->sql_maker;
1352   local $sql_maker->{for} = $for;
1353
1354   if (exists $attrs->{group_by} || $attrs->{having}) {
1355     $order = {
1356       group_by => $attrs->{group_by},
1357       having => $attrs->{having},
1358       ($order ? (order_by => $order) : ())
1359     };
1360   }
1361   my $bind_attrs = {}; ## Future support
1362   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1363   if ($attrs->{software_limit} ||
1364       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1365         $attrs->{software_limit} = 1;
1366   } else {
1367     $self->throw_exception("rows attribute must be positive if present")
1368       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1369
1370     # MySQL actually recommends this approach.  I cringe.
1371     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1372     push @args, $attrs->{rows}, $attrs->{offset};
1373   }
1374
1375   return $self->_execute(@args);
1376 }
1377
1378 sub source_bind_attributes {
1379   my ($self, $source) = @_;
1380
1381   my $bind_attributes;
1382   foreach my $column ($source->columns) {
1383
1384     my $data_type = $source->column_info($column)->{data_type} || '';
1385     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1386      if $data_type;
1387   }
1388
1389   return $bind_attributes;
1390 }
1391
1392 =head2 select
1393
1394 =over 4
1395
1396 =item Arguments: $ident, $select, $condition, $attrs
1397
1398 =back
1399
1400 Handle a SQL select statement.
1401
1402 =cut
1403
1404 sub select {
1405   my $self = shift;
1406   my ($ident, $select, $condition, $attrs) = @_;
1407   return $self->cursor_class->new($self, \@_, $attrs);
1408 }
1409
1410 sub select_single {
1411   my $self = shift;
1412   my ($rv, $sth, @bind) = $self->_select(@_);
1413   my @row = $sth->fetchrow_array;
1414   my @nextrow = $sth->fetchrow_array if @row;
1415   if(@row && @nextrow) {
1416     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1417   }
1418   # Need to call finish() to work round broken DBDs
1419   $sth->finish();
1420   return @row;
1421 }
1422
1423 =head2 sth
1424
1425 =over 4
1426
1427 =item Arguments: $sql
1428
1429 =back
1430
1431 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1432
1433 =cut
1434
1435 sub _dbh_sth {
1436   my ($self, $dbh, $sql) = @_;
1437
1438   # 3 is the if_active parameter which avoids active sth re-use
1439   my $sth = $self->disable_sth_caching
1440     ? $dbh->prepare($sql)
1441     : $dbh->prepare_cached($sql, {}, 3);
1442
1443   # XXX You would think RaiseError would make this impossible,
1444   #  but apparently that's not true :(
1445   $self->throw_exception($dbh->errstr) if !$sth;
1446
1447   $sth;
1448 }
1449
1450 sub sth {
1451   my ($self, $sql) = @_;
1452   $self->dbh_do('_dbh_sth', $sql);
1453 }
1454
1455 sub _dbh_columns_info_for {
1456   my ($self, $dbh, $table) = @_;
1457
1458   if ($dbh->can('column_info')) {
1459     my %result;
1460     eval {
1461       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1462       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1463       $sth->execute();
1464       while ( my $info = $sth->fetchrow_hashref() ){
1465         my %column_info;
1466         $column_info{data_type}   = $info->{TYPE_NAME};
1467         $column_info{size}      = $info->{COLUMN_SIZE};
1468         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1469         $column_info{default_value} = $info->{COLUMN_DEF};
1470         my $col_name = $info->{COLUMN_NAME};
1471         $col_name =~ s/^\"(.*)\"$/$1/;
1472
1473         $result{$col_name} = \%column_info;
1474       }
1475     };
1476     return \%result if !$@ && scalar keys %result;
1477   }
1478
1479   my %result;
1480   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1481   $sth->execute;
1482   my @columns = @{$sth->{NAME_lc}};
1483   for my $i ( 0 .. $#columns ){
1484     my %column_info;
1485     $column_info{data_type} = $sth->{TYPE}->[$i];
1486     $column_info{size} = $sth->{PRECISION}->[$i];
1487     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1488
1489     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1490       $column_info{data_type} = $1;
1491       $column_info{size}    = $2;
1492     }
1493
1494     $result{$columns[$i]} = \%column_info;
1495   }
1496   $sth->finish;
1497
1498   foreach my $col (keys %result) {
1499     my $colinfo = $result{$col};
1500     my $type_num = $colinfo->{data_type};
1501     my $type_name;
1502     if(defined $type_num && $dbh->can('type_info')) {
1503       my $type_info = $dbh->type_info($type_num);
1504       $type_name = $type_info->{TYPE_NAME} if $type_info;
1505       $colinfo->{data_type} = $type_name if $type_name;
1506     }
1507   }
1508
1509   return \%result;
1510 }
1511
1512 sub columns_info_for {
1513   my ($self, $table) = @_;
1514   $self->dbh_do('_dbh_columns_info_for', $table);
1515 }
1516
1517 =head2 last_insert_id
1518
1519 Return the row id of the last insert.
1520
1521 =cut
1522
1523 sub _dbh_last_insert_id {
1524     my ($self, $dbh, $source, $col) = @_;
1525     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1526     $dbh->func('last_insert_rowid');
1527 }
1528
1529 sub last_insert_id {
1530   my $self = shift;
1531   $self->dbh_do('_dbh_last_insert_id', @_);
1532 }
1533
1534 =head2 sqlt_type
1535
1536 Returns the database driver name.
1537
1538 =cut
1539
1540 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1541
1542 =head2 bind_attribute_by_data_type
1543
1544 Given a datatype from column info, returns a database specific bind
1545 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1546 let the database planner just handle it.
1547
1548 Generally only needed for special case column types, like bytea in postgres.
1549
1550 =cut
1551
1552 sub bind_attribute_by_data_type {
1553     return;
1554 }
1555
1556 =head2 create_ddl_dir
1557
1558 =over 4
1559
1560 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1561
1562 =back
1563
1564 Creates a SQL file based on the Schema, for each of the specified
1565 database types, in the given directory.
1566
1567 By default, C<\%sqlt_args> will have
1568
1569  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1570
1571 merged with the hash passed in. To disable any of those features, pass in a
1572 hashref like the following
1573
1574  { ignore_constraint_names => 0, # ... other options }
1575
1576 =cut
1577
1578 sub create_ddl_dir {
1579   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1580
1581   if(!$dir || !-d $dir) {
1582     warn "No directory given, using ./\n";
1583     $dir = "./";
1584   }
1585   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1586   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1587
1588   my $schema_version = $schema->schema_version || '1.x';
1589   $version ||= $schema_version;
1590
1591   $sqltargs = {
1592     add_drop_table => 1,
1593     ignore_constraint_names => 1,
1594     ignore_index_names => 1,
1595     %{$sqltargs || {}}
1596   };
1597
1598   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1599       . $self->_check_sqlt_message . q{'})
1600           if !$self->_check_sqlt_version;
1601
1602   my $sqlt = SQL::Translator->new( $sqltargs );
1603
1604   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1605   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1606
1607   foreach my $db (@$databases) {
1608     $sqlt->reset();
1609     $sqlt = $self->configure_sqlt($sqlt, $db);
1610     $sqlt->{schema} = $sqlt_schema;
1611     $sqlt->producer($db);
1612
1613     my $file;
1614     my $filename = $schema->ddl_filename($db, $version, $dir);
1615     if (-e $filename && ($version eq $schema_version )) {
1616       # if we are dumping the current version, overwrite the DDL
1617       warn "Overwriting existing DDL file - $filename";
1618       unlink($filename);
1619     }
1620
1621     my $output = $sqlt->translate;
1622     if(!$output) {
1623       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1624       next;
1625     }
1626     if(!open($file, ">$filename")) {
1627       $self->throw_exception("Can't open $filename for writing ($!)");
1628       next;
1629     }
1630     print $file $output;
1631     close($file);
1632
1633     next unless ($preversion);
1634
1635     require SQL::Translator::Diff;
1636
1637     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1638     if(!-e $prefilename) {
1639       warn("No previous schema file found ($prefilename)");
1640       next;
1641     }
1642
1643     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1644     if(-e $difffile) {
1645       warn("Overwriting existing diff file - $difffile");
1646       unlink($difffile);
1647     }
1648
1649     my $source_schema;
1650     {
1651       my $t = SQL::Translator->new($sqltargs);
1652       $t->debug( 0 );
1653       $t->trace( 0 );
1654       $t->parser( $db )                       or die $t->error;
1655       $t = $self->configure_sqlt($t, $db);
1656       my $out = $t->translate( $prefilename ) or die $t->error;
1657       $source_schema = $t->schema;
1658       unless ( $source_schema->name ) {
1659         $source_schema->name( $prefilename );
1660       }
1661     }
1662
1663     # The "new" style of producers have sane normalization and can support
1664     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1665     # And we have to diff parsed SQL against parsed SQL.
1666     my $dest_schema = $sqlt_schema;
1667
1668     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1669       my $t = SQL::Translator->new($sqltargs);
1670       $t->debug( 0 );
1671       $t->trace( 0 );
1672       $t->parser( $db )                    or die $t->error;
1673       $t = $self->configure_sqlt($t, $db);
1674       my $out = $t->translate( $filename ) or die $t->error;
1675       $dest_schema = $t->schema;
1676       $dest_schema->name( $filename )
1677         unless $dest_schema->name;
1678     }
1679
1680     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1681                                                   $dest_schema,   $db,
1682                                                   $sqltargs
1683                                                  );
1684     if(!open $file, ">$difffile") {
1685       $self->throw_exception("Can't write to $difffile ($!)");
1686       next;
1687     }
1688     print $file $diff;
1689     close($file);
1690   }
1691 }
1692
1693 sub configure_sqlt() {
1694   my $self = shift;
1695   my $tr = shift;
1696   my $db = shift || $self->sqlt_type;
1697   if ($db eq 'PostgreSQL') {
1698     $tr->quote_table_names(0);
1699     $tr->quote_field_names(0);
1700   }
1701   return $tr;
1702 }
1703
1704 =head2 deployment_statements
1705
1706 =over 4
1707
1708 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1709
1710 =back
1711
1712 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1713 The database driver name is given by C<$type>, though the value from
1714 L</sqlt_type> is used if it is not specified.
1715
1716 C<$directory> is used to return statements from files in a previously created
1717 L</create_ddl_dir> directory and is optional. The filenames are constructed
1718 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1719
1720 If no C<$directory> is specified then the statements are constructed on the
1721 fly using L<SQL::Translator> and C<$version> is ignored.
1722
1723 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1724
1725 =cut
1726
1727 sub deployment_statements {
1728   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1729   # Need to be connected to get the correct sqlt_type
1730   $self->ensure_connected() unless $type;
1731   $type ||= $self->sqlt_type;
1732   $version ||= $schema->schema_version || '1.x';
1733   $dir ||= './';
1734   my $filename = $schema->ddl_filename($type, $dir, $version);
1735   if(-f $filename)
1736   {
1737       my $file;
1738       open($file, "<$filename")
1739         or $self->throw_exception("Can't open $filename ($!)");
1740       my @rows = <$file>;
1741       close($file);
1742       return join('', @rows);
1743   }
1744
1745   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1746       . $self->_check_sqlt_message . q{'})
1747           if !$self->_check_sqlt_version;
1748
1749   require SQL::Translator::Parser::DBIx::Class;
1750   eval qq{use SQL::Translator::Producer::${type}};
1751   $self->throw_exception($@) if $@;
1752
1753   # sources needs to be a parser arg, but for simplicty allow at top level
1754   # coming in
1755   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1756       if exists $sqltargs->{sources};
1757
1758   my $tr = SQL::Translator->new(%$sqltargs);
1759   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1760   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1761 }
1762
1763 sub deploy {
1764   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1765   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1766     foreach my $line ( split(";\n", $statement)) {
1767       next if($line =~ /^--/);
1768       next if(!$line);
1769 #      next if($line =~ /^DROP/m);
1770       next if($line =~ /^BEGIN TRANSACTION/m);
1771       next if($line =~ /^COMMIT/m);
1772       next if $line =~ /^\s+$/; # skip whitespace only
1773       $self->_query_start($line);
1774       eval {
1775         $self->dbh->do($line); # shouldn't be using ->dbh ?
1776       };
1777       if ($@) {
1778         warn qq{$@ (running "${line}")};
1779       }
1780       $self->_query_end($line);
1781     }
1782   }
1783 }
1784
1785 =head2 datetime_parser
1786
1787 Returns the datetime parser class
1788
1789 =cut
1790
1791 sub datetime_parser {
1792   my $self = shift;
1793   return $self->{datetime_parser} ||= do {
1794     $self->ensure_connected;
1795     $self->build_datetime_parser(@_);
1796   };
1797 }
1798
1799 =head2 datetime_parser_type
1800
1801 Defines (returns) the datetime parser class - currently hardwired to
1802 L<DateTime::Format::MySQL>
1803
1804 =cut
1805
1806 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1807
1808 =head2 build_datetime_parser
1809
1810 See L</datetime_parser>
1811
1812 =cut
1813
1814 sub build_datetime_parser {
1815   my $self = shift;
1816   my $type = $self->datetime_parser_type(@_);
1817   eval "use ${type}";
1818   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1819   return $type;
1820 }
1821
1822 {
1823     my $_check_sqlt_version; # private
1824     my $_check_sqlt_message; # private
1825     sub _check_sqlt_version {
1826         return $_check_sqlt_version if defined $_check_sqlt_version;
1827         eval 'use SQL::Translator "0.09"';
1828         $_check_sqlt_message = $@ || '';
1829         $_check_sqlt_version = !$@;
1830     }
1831
1832     sub _check_sqlt_message {
1833         _check_sqlt_version if !defined $_check_sqlt_message;
1834         $_check_sqlt_message;
1835     }
1836 }
1837
1838 =head2 is_replicating
1839
1840 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1841 replicate from a master database.  Default is undef, which is the result
1842 returned by databases that don't support replication.
1843
1844 =cut
1845
1846 sub is_replicating {
1847     return;
1848
1849 }
1850
1851 =head2 lag_behind_master
1852
1853 Returns a number that represents a certain amount of lag behind a master db
1854 when a given storage is replicating.  The number is database dependent, but
1855 starts at zero and increases with the amount of lag. Default in undef
1856
1857 =cut
1858
1859 sub lag_behind_master {
1860     return;
1861 }
1862
1863 sub DESTROY {
1864   my $self = shift;
1865   return if !$self->_dbh;
1866   $self->_verify_pid;
1867   $self->_dbh(undef);
1868 }
1869
1870 1;
1871
1872 =head1 USAGE NOTES
1873
1874 =head2 DBIx::Class and AutoCommit
1875
1876 DBIx::Class can do some wonderful magic with handling exceptions,
1877 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1878 combined with C<txn_do> for transaction support.
1879
1880 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1881 in an assumed transaction between commits, and you're telling us you'd
1882 like to manage that manually.  A lot of the magic protections offered by
1883 this module will go away.  We can't protect you from exceptions due to database
1884 disconnects because we don't know anything about how to restart your
1885 transactions.  You're on your own for handling all sorts of exceptional
1886 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1887 be with raw DBI.
1888
1889
1890 =head1 SQL METHODS
1891
1892 The module defines a set of methods within the DBIC::SQL::Abstract
1893 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1894 SQL query functions.
1895
1896 The following methods are extended:-
1897
1898 =over 4
1899
1900 =item delete
1901
1902 =item insert
1903
1904 =item select
1905
1906 =item update
1907
1908 =item limit_dialect
1909
1910 See L</connect_info> for details.
1911
1912 =item quote_char
1913
1914 See L</connect_info> for details.
1915
1916 =item name_sep
1917
1918 See L</connect_info> for details.
1919
1920 =back
1921
1922 =head1 AUTHORS
1923
1924 Matt S. Trout <mst@shadowcatsystems.co.uk>
1925
1926 Andy Grundman <andy@hybridized.org>
1927
1928 =head1 LICENSE
1929
1930 You may distribute this code under the same terms as Perl itself.
1931
1932 =cut