lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  17        transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields, $params) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 127           ? ' AS col'.$self->{rownum_hack_count}++
 128           : '')
 129       } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.  Please note that the L<DBI> docs
 334 recommend that you always explicitly set C<AutoCommit> to either
 335 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 336 to C<1>, and that you perform transactions via our L</txn_do>
 337 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 338 set it to zero.  This is the default for most DBDs.  See below for more
 339 details.
 340
 341 In either case, if the final argument in your connect_info happens
 342 to be a hashref, C<connect_info> will look there for several
 343 connection-specific options:
 344
 345 =over 4
 346
 347 =item on_connect_do
 348
 349 This can be set to an arrayref of literal sql statements, which will
 350 be executed immediately after making the connection to the database
 351 every time we [re-]connect.
 352
 353 =item disable_sth_caching
 354
 355 If set to a true value, this option will disable the caching of
 356 statement handles via L<DBI/prepare_cached>.
 357
 358 =item limit_dialect
 359
 360 Sets the limit dialect. This is useful for JDBC-bridge among others
 361 where the remote SQL-dialect cannot be determined by the name of the
 362 driver alone.
 363
 364 =item quote_char
 365
 366 Specifies what characters to use to quote table and column names. If
 367 you use this you will want to specify L<name_sep> as well.
 368
 369 quote_char expects either a single character, in which case is it is placed
 370 on either side of the table/column, or an arrayref of length 2 in which case the
 371 table/column name is placed between the elements.
 372
 373 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 374 use C<quote_char =E<gt> [qw/[ ]/]>.
 375
 376 =item name_sep
 377
 378 This only needs to be used in conjunction with L<quote_char>, and is used to
 379 specify the charecter that seperates elements (schemas, tables, columns) from
 380 each other. In most cases this is simply a C<.>.
 381
 382 =item unsafe
 383
 384 This Storage driver normally installs its own C<HandleError>, sets
 385 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 386 all database handles, including those supplied by a coderef.  It does this
 387 so that it can have consistent and useful error behavior.
 388
 389 If you set this option to a true value, Storage will not do its usual
 390 modifications to the database handle's attributes, and instead relies on
 391 the settings in your connect_info DBI options (or the values you set in
 392 your connection coderef, in the case that you are connecting via coderef).
 393
 394 Note that your custom settings can cause Storage to malfunction,
 395 especially if you set a C<HandleError> handler that suppresses exceptions
 396 and/or disable C<RaiseError>.
 397
 398 =back
 399
 400 These options can be mixed in with your other L<DBI> connection attributes,
 401 or placed in a seperate hashref after all other normal L<DBI> connection
 402 arguments.
 403
 404 Every time C<connect_info> is invoked, any previous settings for
 405 these options will be cleared before setting the new ones, regardless of
 406 whether any options are specified in the new C<connect_info>.
 407
 408 Another Important Note:
 409
 410 DBIC can do some wonderful magic with handling exceptions,
 411 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 412 combined with C<txn_do> for transaction support.
 413
 414 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 415 in an assumed transaction between commits, and you're telling us you'd
 416 like to manage that manually.  A lot of DBIC's magic protections
 417 go away.  We can't protect you from exceptions due to database
 418 disconnects because we don't know anything about how to restart your
 419 transactions.  You're on your own for handling all sorts of exceptional
 420 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 421 be with raw DBI.
 422
 423 Examples:
 424
 425   # Simple SQLite connection
 426   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 427
 428   # Connect via subref
 429   ->connect_info([ sub { DBI->connect(...) } ]);
 430
 431   # A bit more complicated
 432   ->connect_info(
 433     [
 434       'dbi:Pg:dbname=foo',
 435       'postgres',
 436       'my_pg_password',
 437       { AutoCommit => 1 },
 438       { quote_char => q{"}, name_sep => q{.} },
 439     ]
 440   );
 441
 442   # Equivalent to the previous example
 443   ->connect_info(
 444     [
 445       'dbi:Pg:dbname=foo',
 446       'postgres',
 447       'my_pg_password',
 448       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 449     ]
 450   );
 451
 452   # Subref + DBIC-specific connection options
 453   ->connect_info(
 454     [
 455       sub { DBI->connect(...) },
 456       {
 457           quote_char => q{`},
 458           name_sep => q{@},
 459           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 460           disable_sth_caching => 1,
 461       },
 462     ]
 463   );
 464
 465 =cut
 466
 467 sub connect_info {
 468   my ($self, $info_arg) = @_;
 469
 470   return $self->_connect_info if !$info_arg;
 471
 472   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 473   #  the new set of options
 474   $self->_sql_maker(undef);
 475   $self->_sql_maker_opts({});
 476   $self->_connect_info([@$info_arg]); # copy for _connect_info
 477
 478   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 479
 480   my $last_info = $dbi_info->[-1];
 481   if(ref $last_info eq 'HASH') {
 482     $last_info = { %$last_info }; # so delete is non-destructive
 483     for my $storage_opt (qw/on_connect_do disable_sth_caching unsafe/) {
 484       if(my $value = delete $last_info->{$storage_opt}) {
 485         $self->$storage_opt($value);
 486       }
 487     }
 488     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 489       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 490         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 491       }
 492     }
 493     # re-insert modified hashref
 494     $dbi_info->[-1] = $last_info;
 495
 496     # Get rid of any trailing empty hashref
 497     pop(@$dbi_info) if !keys %$last_info;
 498   }
 499   $self->_dbi_connect_info($dbi_info);
 500
 501   $self->_connect_info;
 502 }
 503
 504 =head2 on_connect_do
 505
 506 This method is deprecated in favor of setting via L</connect_info>.
 507
 508 =head2 dbh_do
 509
 510 Arguments: $subref, @extra_coderef_args?
 511
 512 Execute the given subref using the new exception-based connection management.
 513
 514 The first two arguments will be the storage object that C<dbh_do> was called
 515 on and a database handle to use.  Any additional arguments will be passed
 516 verbatim to the called subref as arguments 2 and onwards.
 517
 518 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 519 exception handling and reconnection (or failover in future subclasses).
 520
 521 Your subref should have no side-effects outside of the database, as
 522 there is the potential for your subref to be partially double-executed
 523 if the database connection was stale/dysfunctional.
 524
 525 Example:
 526
 527   my @stuff = $schema->storage->dbh_do(
 528     sub {
 529       my ($storage, $dbh, @cols) = @_;
 530       my $cols = join(q{, }, @cols);
 531       $dbh->selectrow_array("SELECT $cols FROM foo");
 532     },
 533     @column_list
 534   );
 535
 536 =cut
 537
 538 sub dbh_do {
 539   my $self = shift;
 540   my $coderef = shift;
 541
 542   ref $coderef eq 'CODE' or $self->throw_exception
 543     ('$coderef must be a CODE reference');
 544
 545   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 546       || $self->{transaction_depth};
 547
 548   local $self->{_in_dbh_do} = 1;
 549
 550   my @result;
 551   my $want_array = wantarray;
 552
 553   eval {
 554     $self->_verify_pid if $self->_dbh;
 555     $self->_populate_dbh if !$self->_dbh;
 556     if($want_array) {
 557         @result = $coderef->($self, $self->_dbh, @_);
 558     }
 559     elsif(defined $want_array) {
 560         $result[0] = $coderef->($self, $self->_dbh, @_);
 561     }
 562     else {
 563         $coderef->($self, $self->_dbh, @_);
 564     }
 565   };
 566
 567   my $exception = $@;
 568   if(!$exception) { return $want_array ? @result : $result[0] }
 569
 570   $self->throw_exception($exception) if $self->connected;
 571
 572   # We were not connected - reconnect and retry, but let any
 573   #  exception fall right through this time
 574   $self->_populate_dbh;
 575   $coderef->($self, $self->_dbh, @_);
 576 }
 577
 578 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 579 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 580 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 581 sub txn_do {
 582   my $self = shift;
 583   my $coderef = shift;
 584
 585   ref $coderef eq 'CODE' or $self->throw_exception
 586     ('$coderef must be a CODE reference');
 587
 588   return $coderef->(@_) if $self->{transaction_depth};
 589
 590   local $self->{_in_dbh_do} = 1;
 591
 592   my @result;
 593   my $want_array = wantarray;
 594
 595   my $tried = 0;
 596   while(1) {
 597     eval {
 598       $self->_verify_pid if $self->_dbh;
 599       $self->_populate_dbh if !$self->_dbh;
 600
 601       $self->txn_begin;
 602       if($want_array) {
 603           @result = $coderef->(@_);
 604       }
 605       elsif(defined $want_array) {
 606           $result[0] = $coderef->(@_);
 607       }
 608       else {
 609           $coderef->(@_);
 610       }
 611       $self->txn_commit;
 612     };
 613
 614     my $exception = $@;
 615     if(!$exception) { return $want_array ? @result : $result[0] }
 616
 617     if($tried++ > 0 || $self->connected) {
 618       eval { $self->txn_rollback };
 619       my $rollback_exception = $@;
 620       if($rollback_exception) {
 621         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 622         $self->throw_exception($exception)  # propagate nested rollback
 623           if $rollback_exception =~ /$exception_class/;
 624
 625         $self->throw_exception(
 626           "Transaction aborted: ${exception}. "
 627           . "Rollback failed: ${rollback_exception}"
 628         );
 629       }
 630       $self->throw_exception($exception)
 631     }
 632
 633     # We were not connected, and was first try - reconnect and retry
 634     # via the while loop
 635     $self->_populate_dbh;
 636   }
 637 }
 638
 639 =head2 disconnect
 640
 641 Our C<disconnect> method also performs a rollback first if the
 642 database is not in C<AutoCommit> mode.
 643
 644 =cut
 645
 646 sub disconnect {
 647   my ($self) = @_;
 648
 649   if( $self->connected ) {
 650     $self->_dbh->rollback unless $self->_dbh_autocommit;
 651     $self->_dbh->disconnect;
 652     $self->_dbh(undef);
 653     $self->{_dbh_gen}++;
 654   }
 655 }
 656
 657 sub connected {
 658   my ($self) = @_;
 659
 660   if(my $dbh = $self->_dbh) {
 661       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 662           $self->_dbh(undef);
 663           $self->{_dbh_gen}++;
 664           return;
 665       }
 666       else {
 667           $self->_verify_pid;
 668       }
 669       return ($dbh->FETCH('Active') && $dbh->ping);
 670   }
 671
 672   return 0;
 673 }
 674
 675 # handle pid changes correctly
 676 #  NOTE: assumes $self->_dbh is a valid $dbh
 677 sub _verify_pid {
 678   my ($self) = @_;
 679
 680   return if $self->_conn_pid == $$;
 681
 682   $self->_dbh->{InactiveDestroy} = 1;
 683   $self->_dbh(undef);
 684   $self->{_dbh_gen}++;
 685
 686   return;
 687 }
 688
 689 sub ensure_connected {
 690   my ($self) = @_;
 691
 692   unless ($self->connected) {
 693     $self->_populate_dbh;
 694   }
 695 }
 696
 697 =head2 dbh
 698
 699 Returns the dbh - a data base handle of class L<DBI>.
 700
 701 =cut
 702
 703 sub dbh {
 704   my ($self) = @_;
 705
 706   $self->ensure_connected;
 707   return $self->_dbh;
 708 }
 709
 710 sub _sql_maker_args {
 711     my ($self) = @_;
 712
 713     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 714 }
 715
 716 sub sql_maker {
 717   my ($self) = @_;
 718   unless ($self->_sql_maker) {
 719     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 720   }
 721   return $self->_sql_maker;
 722 }
 723
 724 sub _populate_dbh {
 725   my ($self) = @_;
 726   my @info = @{$self->_dbi_connect_info || []};
 727   $self->_dbh($self->_connect(@info));
 728
 729   # Always set the transaction depth on connect, since
 730   #  there is no transaction in progress by definition
 731   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 732
 733   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 734     my $driver = $self->_dbh->{Driver}->{Name};
 735     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 736       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 737       $self->_rebless() if $self->can('_rebless');
 738     }
 739   }
 740
 741   # if on-connect sql statements are given execute them
 742   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 743     $self->debugobj->query_start($sql_statement) if $self->debug();
 744     $self->_dbh->do($sql_statement);
 745     $self->debugobj->query_end($sql_statement) if $self->debug();
 746   }
 747
 748   $self->_conn_pid($$);
 749   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 750 }
 751
 752 sub _connect {
 753   my ($self, @info) = @_;
 754
 755   $self->throw_exception("You failed to provide any connection info")
 756     if !@info;
 757
 758   my ($old_connect_via, $dbh);
 759
 760   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 761     $old_connect_via = $DBI::connect_via;
 762     $DBI::connect_via = 'connect';
 763   }
 764
 765   eval {
 766     if(ref $info[0] eq 'CODE') {
 767        $dbh = &{$info[0]}
 768     }
 769     else {
 770        $dbh = DBI->connect(@info);
 771     }
 772
 773     if(!$self->unsafe) {
 774       my $weak_self = $self;
 775       weaken($weak_self);
 776       $dbh->{HandleError} = sub {
 777           $weak_self->throw_exception("DBI Exception: $_[0]")
 778       };
 779       $dbh->{ShowErrorStatement} = 1;
 780       $dbh->{RaiseError} = 1;
 781       $dbh->{PrintError} = 0;
 782     }
 783   };
 784
 785   $DBI::connect_via = $old_connect_via if $old_connect_via;
 786
 787   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 788     if !$dbh || $@;
 789
 790   $self->_dbh_autocommit($dbh->{AutoCommit});
 791
 792   $dbh;
 793 }
 794
 795
 796 sub txn_begin {
 797   my $self = shift;
 798   $self->ensure_connected();
 799   if($self->{transaction_depth} == 0) {
 800     $self->debugobj->txn_begin()
 801       if $self->debug;
 802     # this isn't ->_dbh-> because
 803     #  we should reconnect on begin_work
 804     #  for AutoCommit users
 805     $self->dbh->begin_work;
 806   }
 807   $self->{transaction_depth}++;
 808 }
 809
 810 sub txn_commit {
 811   my $self = shift;
 812   if ($self->{transaction_depth} == 1) {
 813     my $dbh = $self->_dbh;
 814     $self->debugobj->txn_commit()
 815       if ($self->debug);
 816     $dbh->commit;
 817     $self->{transaction_depth} = 0
 818       if $self->_dbh_autocommit;
 819   }
 820   elsif($self->{transaction_depth} > 1) {
 821     $self->{transaction_depth}--
 822   }
 823 }
 824
 825 sub txn_rollback {
 826   my $self = shift;
 827   my $dbh = $self->_dbh;
 828   eval {
 829     if ($self->{transaction_depth} == 1) {
 830       $self->debugobj->txn_rollback()
 831         if ($self->debug);
 832       $self->{transaction_depth} = 0
 833         if $self->_dbh_autocommit;
 834       $dbh->rollback;
 835     }
 836     elsif($self->{transaction_depth} > 1) {
 837       $self->{transaction_depth}--;
 838     }
 839     else {
 840       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 841     }
 842   };
 843   if ($@) {
 844     my $error = $@;
 845     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 846     $error =~ /$exception_class/ and $self->throw_exception($error);
 847     # ensure that a failed rollback resets the transaction depth
 848     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 849     $self->throw_exception($error);
 850   }
 851 }
 852
 853 # This used to be the top-half of _execute.  It was split out to make it
 854 #  easier to override in NoBindVars without duping the rest.  It takes up
 855 #  all of _execute's args, and emits $sql, @bind.
 856 sub _prep_for_execute {
 857   my ($self, $op, $extra_bind, $ident, $args) = @_;
 858
 859   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 860   unshift(@bind,
 861     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 862       if $extra_bind;
 863
 864   return ($sql, \@bind);
 865 }
 866
 867 sub _dbh_execute {
 868   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 869
 870   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 871     $ident = $ident->from();
 872   }
 873
 874   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 875
 876   if ($self->debug) {
 877       my @debug_bind =
 878         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 879       $self->debugobj->query_start($sql, @debug_bind);
 880   }
 881
 882   my $sth = $self->sth($sql,$op);
 883
 884   my $placeholder_index = 1;
 885
 886   foreach my $bound (@$bind) {
 887     my $attributes = {};
 888     my($column_name, @data) = @$bound;
 889
 890     if ($bind_attributes) {
 891       $attributes = $bind_attributes->{$column_name}
 892       if defined $bind_attributes->{$column_name};
 893     }
 894
 895     foreach my $data (@data) {
 896       $data = ref $data ? ''.$data : $data; # stringify args
 897
 898       $sth->bind_param($placeholder_index, $data, $attributes);
 899       $placeholder_index++;
 900     }
 901   }
 902
 903   # Can this fail without throwing an exception anyways???
 904   my $rv = $sth->execute();
 905   $self->throw_exception($sth->errstr) if !$rv;
 906
 907   if ($self->debug) {
 908      my @debug_bind =
 909        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 910      $self->debugobj->query_end($sql, @debug_bind);
 911   }
 912
 913   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 914 }
 915
 916 sub _execute {
 917     my $self = shift;
 918     $self->dbh_do($self->can('_dbh_execute'), @_)
 919 }
 920
 921 sub insert {
 922   my ($self, $source, $to_insert) = @_;
 923
 924   my $ident = $source->from;
 925   my $bind_attributes = $self->source_bind_attributes($source);
 926
 927   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 928
 929   return $to_insert;
 930 }
 931
 932 ## Still not quite perfect, and EXPERIMENTAL
 933 ## Currently it is assumed that all values passed will be "normal", i.e. not
 934 ## scalar refs, or at least, all the same type as the first set, the statement is
 935 ## only prepped once.
 936 sub insert_bulk {
 937   my ($self, $source, $cols, $data) = @_;
 938   my %colvalues;
 939   my $table = $source->from;
 940   @colvalues{@$cols} = (0..$#$cols);
 941   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 942
 943   if ($self->debug) {
 944       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 945       $self->debugobj->query_start($sql, @debug_bind);
 946   }
 947   my $sth = $self->sth($sql);
 948
 949 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 950
 951   ## This must be an arrayref, else nothing works!
 952
 953   my $tuple_status = [];
 954
 955   ##use Data::Dumper;
 956   ##print STDERR Dumper( $data, $sql, [@bind] );
 957
 958   my $time = time();
 959
 960   ## Get the bind_attributes, if any exist
 961   my $bind_attributes = $self->source_bind_attributes($source);
 962
 963   ## Bind the values and execute
 964   my $placeholder_index = 1;
 965
 966   foreach my $bound (@bind) {
 967
 968     my $attributes = {};
 969     my ($column_name, $data_index) = @$bound;
 970
 971     if( $bind_attributes ) {
 972       $attributes = $bind_attributes->{$column_name}
 973       if defined $bind_attributes->{$column_name};
 974     }
 975
 976     my @data = map { $_->[$data_index] } @$data;
 977
 978     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 979     $placeholder_index++;
 980   }
 981   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
 982   $self->throw_exception($sth->errstr) if !$rv;
 983
 984   if ($self->debug) {
 985       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 986       $self->debugobj->query_end($sql, @debug_bind);
 987   }
 988   return (wantarray ? ($rv, $sth, @bind) : $rv);
 989 }
 990
 991 sub update {
 992   my $self = shift @_;
 993   my $source = shift @_;
 994   my $bind_attributes = $self->source_bind_attributes($source);
 995
 996   return $self->_execute('update' => [], $source, $bind_attributes, @_);
 997 }
 998
 999
1000 sub delete {
1001   my $self = shift @_;
1002   my $source = shift @_;
1003
1004   my $bind_attrs = {}; ## If ever it's needed...
1005
1006   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1007 }
1008
1009 sub _select {
1010   my ($self, $ident, $select, $condition, $attrs) = @_;
1011   my $order = $attrs->{order_by};
1012   if (ref $condition eq 'SCALAR') {
1013     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1014   }
1015   if (exists $attrs->{group_by} || $attrs->{having}) {
1016     $order = {
1017       group_by => $attrs->{group_by},
1018       having => $attrs->{having},
1019       ($order ? (order_by => $order) : ())
1020     };
1021   }
1022   my $bind_attrs = {}; ## Future support
1023   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1024   if ($attrs->{software_limit} ||
1025       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1026         $attrs->{software_limit} = 1;
1027   } else {
1028     $self->throw_exception("rows attribute must be positive if present")
1029       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1030
1031     # MySQL actually recommends this approach.  I cringe.
1032     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1033     push @args, $attrs->{rows}, $attrs->{offset};
1034   }
1035   return $self->_execute(@args);
1036 }
1037
1038 sub source_bind_attributes {
1039   my ($self, $source) = @_;
1040
1041   my $bind_attributes;
1042   foreach my $column ($source->columns) {
1043
1044     my $data_type = $source->column_info($column)->{data_type} || '';
1045     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1046      if $data_type;
1047   }
1048
1049   return $bind_attributes;
1050 }
1051
1052 =head2 select
1053
1054 =over 4
1055
1056 =item Arguments: $ident, $select, $condition, $attrs
1057
1058 =back
1059
1060 Handle a SQL select statement.
1061
1062 =cut
1063
1064 sub select {
1065   my $self = shift;
1066   my ($ident, $select, $condition, $attrs) = @_;
1067   return $self->cursor->new($self, \@_, $attrs);
1068 }
1069
1070 sub select_single {
1071   my $self = shift;
1072   my ($rv, $sth, @bind) = $self->_select(@_);
1073   my @row = $sth->fetchrow_array;
1074   # Need to call finish() to work round broken DBDs
1075   $sth->finish();
1076   return @row;
1077 }
1078
1079 =head2 sth
1080
1081 =over 4
1082
1083 =item Arguments: $sql
1084
1085 =back
1086
1087 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1088
1089 =cut
1090
1091 sub _dbh_sth {
1092   my ($self, $dbh, $sql) = @_;
1093
1094   # 3 is the if_active parameter which avoids active sth re-use
1095   my $sth = $self->disable_sth_caching
1096     ? $dbh->prepare($sql)
1097     : $dbh->prepare_cached($sql, {}, 3);
1098
1099   # XXX You would think RaiseError would make this impossible,
1100   #  but apparently that's not true :(
1101   $self->throw_exception($dbh->errstr) if !$sth;
1102
1103   $sth;
1104 }
1105
1106 sub sth {
1107   my ($self, $sql) = @_;
1108   $self->dbh_do($self->can('_dbh_sth'), $sql);
1109 }
1110
1111 sub _dbh_columns_info_for {
1112   my ($self, $dbh, $table) = @_;
1113
1114   if ($dbh->can('column_info')) {
1115     my %result;
1116     eval {
1117       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1118       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1119       $sth->execute();
1120       while ( my $info = $sth->fetchrow_hashref() ){
1121         my %column_info;
1122         $column_info{data_type}   = $info->{TYPE_NAME};
1123         $column_info{size}      = $info->{COLUMN_SIZE};
1124         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1125         $column_info{default_value} = $info->{COLUMN_DEF};
1126         my $col_name = $info->{COLUMN_NAME};
1127         $col_name =~ s/^\"(.*)\"$/$1/;
1128
1129         $result{$col_name} = \%column_info;
1130       }
1131     };
1132     return \%result if !$@ && scalar keys %result;
1133   }
1134
1135   my %result;
1136   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1137   $sth->execute;
1138   my @columns = @{$sth->{NAME_lc}};
1139   for my $i ( 0 .. $#columns ){
1140     my %column_info;
1141     $column_info{data_type} = $sth->{TYPE}->[$i];
1142     $column_info{size} = $sth->{PRECISION}->[$i];
1143     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1144
1145     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1146       $column_info{data_type} = $1;
1147       $column_info{size}    = $2;
1148     }
1149
1150     $result{$columns[$i]} = \%column_info;
1151   }
1152   $sth->finish;
1153
1154   foreach my $col (keys %result) {
1155     my $colinfo = $result{$col};
1156     my $type_num = $colinfo->{data_type};
1157     my $type_name;
1158     if(defined $type_num && $dbh->can('type_info')) {
1159       my $type_info = $dbh->type_info($type_num);
1160       $type_name = $type_info->{TYPE_NAME} if $type_info;
1161       $colinfo->{data_type} = $type_name if $type_name;
1162     }
1163   }
1164
1165   return \%result;
1166 }
1167
1168 sub columns_info_for {
1169   my ($self, $table) = @_;
1170   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1171 }
1172
1173 =head2 last_insert_id
1174
1175 Return the row id of the last insert.
1176
1177 =cut
1178
1179 sub _dbh_last_insert_id {
1180     my ($self, $dbh, $source, $col) = @_;
1181     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1182     $dbh->func('last_insert_rowid');
1183 }
1184
1185 sub last_insert_id {
1186   my $self = shift;
1187   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1188 }
1189
1190 =head2 sqlt_type
1191
1192 Returns the database driver name.
1193
1194 =cut
1195
1196 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1197
1198 =head2 bind_attribute_by_data_type
1199
1200 Given a datatype from column info, returns a database specific bind attribute for
1201 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1202 just handle it.
1203
1204 Generally only needed for special case column types, like bytea in postgres.
1205
1206 =cut
1207
1208 sub bind_attribute_by_data_type {
1209     return;
1210 }
1211
1212 =head2 create_ddl_dir
1213
1214 =over 4
1215
1216 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1217
1218 =back
1219
1220 Creates a SQL file based on the Schema, for each of the specified
1221 database types, in the given directory.
1222
1223 =cut
1224
1225 sub create_ddl_dir
1226 {
1227   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1228
1229   if(!$dir || !-d $dir)
1230   {
1231     warn "No directory given, using ./\n";
1232     $dir = "./";
1233   }
1234   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1235   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1236   $version ||= $schema->VERSION || '1.x';
1237   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1238
1239   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1240       . $self->_check_sqlt_message . q{'})
1241           if !$self->_check_sqlt_version;
1242
1243   my $sqlt = SQL::Translator->new({
1244 #      debug => 1,
1245       add_drop_table => 1,
1246   });
1247   foreach my $db (@$databases)
1248   {
1249     $sqlt->reset();
1250     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1251 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1252     $sqlt = $self->configure_sqlt($sqlt, $db);
1253     $sqlt->data($schema);
1254     $sqlt->producer($db);
1255
1256     my $file;
1257     my $filename = $schema->ddl_filename($db, $dir, $version);
1258     if(-e $filename)
1259     {
1260       warn("$filename already exists, skipping $db");
1261       next;
1262     }
1263
1264     my $output = $sqlt->translate;
1265     if(!$output)
1266     {
1267       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1268       next;
1269     }
1270     if(!open($file, ">$filename"))
1271     {
1272         $self->throw_exception("Can't open $filename for writing ($!)");
1273         next;
1274     }
1275     print $file $output;
1276     close($file);
1277
1278     if($preversion)
1279     {
1280       require SQL::Translator::Diff;
1281
1282       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1283 #      print "Previous version $prefilename\n";
1284       if(!-e $prefilename)
1285       {
1286         warn("No previous schema file found ($prefilename)");
1287         next;
1288       }
1289       #### We need to reparse the SQLite file we just wrote, so that
1290       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1291       ##   FIXME: rip Diff to pieces!
1292 #      my $target_schema = $sqlt->schema;
1293 #      unless ( $target_schema->name ) {
1294 #        $target_schema->name( $filename );
1295 #      }
1296       my @input;
1297       push @input, {file => $prefilename, parser => $db};
1298       push @input, {file => $filename, parser => $db};
1299       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1300         my $file   = $_->{'file'};
1301         my $parser = $_->{'parser'};
1302
1303         my $t = SQL::Translator->new;
1304         $t->debug( 0 );
1305         $t->trace( 0 );
1306         $t->parser( $parser )            or die $t->error;
1307         my $out = $t->translate( $file ) or die $t->error;
1308         my $schema = $t->schema;
1309         unless ( $schema->name ) {
1310           $schema->name( $file );
1311         }
1312         ($schema, $parser);
1313       } @input;
1314
1315       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1316                                                     $target_schema, $db,
1317                                                     {}
1318                                                    );
1319       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1320       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1321       if(-e $difffile)
1322       {
1323         warn("$difffile already exists, skipping");
1324         next;
1325       }
1326       if(!open $file, ">$difffile")
1327       {
1328         $self->throw_exception("Can't write to $difffile ($!)");
1329         next;
1330       }
1331       print $file $diff;
1332       close($file);
1333     }
1334   }
1335 }
1336
1337 sub configure_sqlt() {
1338   my $self = shift;
1339   my $tr = shift;
1340   my $db = shift || $self->sqlt_type;
1341   if ($db eq 'PostgreSQL') {
1342     $tr->quote_table_names(0);
1343     $tr->quote_field_names(0);
1344   }
1345   return $tr;
1346 }
1347
1348 =head2 deployment_statements
1349
1350 =over 4
1351
1352 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1353
1354 =back
1355
1356 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1357 The database driver name is given by C<$type>, though the value from
1358 L</sqlt_type> is used if it is not specified.
1359
1360 C<$directory> is used to return statements from files in a previously created
1361 L</create_ddl_dir> directory and is optional. The filenames are constructed
1362 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1363
1364 If no C<$directory> is specified then the statements are constructed on the
1365 fly using L<SQL::Translator> and C<$version> is ignored.
1366
1367 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1368
1369 =cut
1370
1371 sub deployment_statements {
1372   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1373   # Need to be connected to get the correct sqlt_type
1374   $self->ensure_connected() unless $type;
1375   $type ||= $self->sqlt_type;
1376   $version ||= $schema->VERSION || '1.x';
1377   $dir ||= './';
1378   my $filename = $schema->ddl_filename($type, $dir, $version);
1379   if(-f $filename)
1380   {
1381       my $file;
1382       open($file, "<$filename")
1383         or $self->throw_exception("Can't open $filename ($!)");
1384       my @rows = <$file>;
1385       close($file);
1386       return join('', @rows);
1387   }
1388
1389   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1390       . $self->_check_sqlt_message . q{'})
1391           if !$self->_check_sqlt_version;
1392
1393   require SQL::Translator::Parser::DBIx::Class;
1394   eval qq{use SQL::Translator::Producer::${type}};
1395   $self->throw_exception($@) if $@;
1396
1397   # sources needs to be a parser arg, but for simplicty allow at top level
1398   # coming in
1399   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1400       if exists $sqltargs->{sources};
1401
1402   my $tr = SQL::Translator->new(%$sqltargs);
1403   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1404   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1405
1406   return;
1407
1408 }
1409
1410 sub deploy {
1411   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1412   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1413     foreach my $line ( split(";\n", $statement)) {
1414       next if($line =~ /^--/);
1415       next if(!$line);
1416 #      next if($line =~ /^DROP/m);
1417       next if($line =~ /^BEGIN TRANSACTION/m);
1418       next if($line =~ /^COMMIT/m);
1419       next if $line =~ /^\s+$/; # skip whitespace only
1420       $self->debugobj->query_start($line) if $self->debug;
1421       eval {
1422         $self->dbh->do($line); # shouldn't be using ->dbh ?
1423       };
1424       if ($@) {
1425         warn qq{$@ (running "${line}")};
1426       }
1427       $self->debugobj->query_end($line) if $self->debug;
1428     }
1429   }
1430 }
1431
1432 =head2 datetime_parser
1433
1434 Returns the datetime parser class
1435
1436 =cut
1437
1438 sub datetime_parser {
1439   my $self = shift;
1440   return $self->{datetime_parser} ||= do {
1441     $self->ensure_connected;
1442     $self->build_datetime_parser(@_);
1443   };
1444 }
1445
1446 =head2 datetime_parser_type
1447
1448 Defines (returns) the datetime parser class - currently hardwired to
1449 L<DateTime::Format::MySQL>
1450
1451 =cut
1452
1453 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1454
1455 =head2 build_datetime_parser
1456
1457 See L</datetime_parser>
1458
1459 =cut
1460
1461 sub build_datetime_parser {
1462   my $self = shift;
1463   my $type = $self->datetime_parser_type(@_);
1464   eval "use ${type}";
1465   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1466   return $type;
1467 }
1468
1469 {
1470     my $_check_sqlt_version; # private
1471     my $_check_sqlt_message; # private
1472     sub _check_sqlt_version {
1473         return $_check_sqlt_version if defined $_check_sqlt_version;
1474         eval 'use SQL::Translator 0.08';
1475         $_check_sqlt_message = $@ ? $@ : '';
1476         $_check_sqlt_version = $@ ? 0 : 1;
1477     }
1478
1479     sub _check_sqlt_message {
1480         _check_sqlt_version if !defined $_check_sqlt_message;
1481         $_check_sqlt_message;
1482     }
1483 }
1484
1485 sub DESTROY {
1486   my $self = shift;
1487   return if !$self->_dbh;
1488   $self->_verify_pid;
1489   $self->_dbh(undef);
1490 }
1491
1492 1;
1493
1494 =head1 SQL METHODS
1495
1496 The module defines a set of methods within the DBIC::SQL::Abstract
1497 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1498 SQL query functions.
1499
1500 The following methods are extended:-
1501
1502 =over 4
1503
1504 =item delete
1505
1506 =item insert
1507
1508 =item select
1509
1510 =item update
1511
1512 =item limit_dialect
1513
1514 See L</connect_info> for details.
1515 For setting, this method is deprecated in favor of L</connect_info>.
1516
1517 =item quote_char
1518
1519 See L</connect_info> for details.
1520 For setting, this method is deprecated in favor of L</connect_info>.
1521
1522 =item name_sep
1523
1524 See L</connect_info> for details.
1525 For setting, this method is deprecated in favor of L</connect_info>.
1526
1527 =back
1528
1529 =head1 AUTHORS
1530
1531 Matt S. Trout <mst@shadowcatsystems.co.uk>
1532
1533 Andy Grundman <andy@hybridized.org>
1534
1535 =head1 LICENSE
1536
1537 You may distribute this code under the same terms as Perl itself.
1538
1539 =cut