lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(
  17   quote_sub perlstring serialize dump_value
  18   dbic_internal_try
  19   detected_reinvoked_destructor scope_guard
  20   mkdir_p
  21 );
  22 use namespace::clean;
  23
  24 # default cursor class, overridable in connect_info attributes
  25 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  26
  27 __PACKAGE__->mk_group_accessors('inherited' => qw/
  28   sql_limit_dialect sql_quote_char sql_name_sep
  29 /);
  30
  31 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  32
  33 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  34 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  35
  36 __PACKAGE__->sql_name_sep('.');
  37
  38 __PACKAGE__->mk_group_accessors('simple' => qw/
  39   _connect_info _dbic_connect_attributes _driver_determined
  40   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  41   _perform_autoinc_retrieval _autoinc_supplied_for_op
  42 /);
  43
  44 # the values for these accessors are picked out (and deleted) from
  45 # the attribute hashref passed to connect_info
  46 my @storage_options = qw/
  47   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  48   disable_sth_caching unsafe auto_savepoint
  49 /;
  50 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  51
  52
  53 # capability definitions, using a 2-tiered accessor system
  54 # The rationale is:
  55 #
  56 # A driver/user may define _use_X, which blindly without any checks says:
  57 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  58 # type accessor)
  59 #
  60 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  61 # accessor, which in turn calls _determine_supports_X, and stores the return
  62 # in a special slot on the storage object, which is wiped every time a $dbh
  63 # reconnection takes place (it is not guaranteed that upon reconnection we
  64 # will get the same rdbms version). _determine_supports_X does not need to
  65 # exist on a driver, as we ->can for it before calling.
  66
  67 my @capabilities = (qw/
  68   insert_returning
  69   insert_returning_bound
  70
  71   multicolumn_in
  72
  73   placeholders
  74   typeless_placeholders
  75
  76   join_optimizer
  77 /);
  78 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  79 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  80
  81 # on by default, not strictly a capability (pending rewrite)
  82 __PACKAGE__->_use_join_optimizer (1);
  83 sub _determine_supports_join_optimizer { 1 };
  84
  85 # Each of these methods need _determine_driver called before itself
  86 # in order to function reliably. We also need to separate accessors
  87 # from plain old method calls, since an accessor called as a setter
  88 # does *not* need the driver determination loop fired (and in fact
  89 # can produce hard to find bugs, like e.g. losing on_connect_*
  90 # semantics on fresh connections)
  91 #
  92 # The construct below is simply a parameterized around()
  93 my $storage_accessor_idx = { map { $_ => 1 } qw(
  94   sqlt_type
  95   datetime_parser_type
  96
  97   sql_maker
  98   cursor_class
  99 )};
 100 for my $meth (keys %$storage_accessor_idx, qw(
 101   deployment_statements
 102
 103   build_datetime_parser
 104
 105   txn_begin
 106
 107   insert
 108   update
 109   delete
 110   select
 111   select_single
 112
 113   _insert_bulk
 114
 115   with_deferred_fk_checks
 116
 117   get_use_dbms_capability
 118   get_dbms_capability
 119
 120   _server_info
 121   _get_server_version
 122 )) {
 123
 124   my $orig = __PACKAGE__->can ($meth)
 125     or die "$meth is not a ::Storage::DBI method!";
 126
 127   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 128
 129   quote_sub
 130     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 131
 132     if (
 133       # if this is an actual *setter* - just set it, no need to connect
 134       # and determine the driver
 135       !( %1$s and @_ > 1 )
 136         and
 137       # only fire when invoked on an instance, a valid class-based invocation
 138       # would e.g. be setting a default for an inherited accessor
 139       ref $_[0]
 140         and
 141       ! $_[0]->{_driver_determined}
 142         and
 143       ! $_[0]->{_in_determine_driver}
 144         and
 145       # Only try to determine stuff if we have *something* that either is or can
 146       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 147       # to still be marginally useful
 148       $_[0]->_dbi_connect_info->[0]
 149     ) {
 150       $_[0]->_determine_driver;
 151
 152       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 153       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 154
 155       my $cref = $_[0]->can(%2$s);
 156       goto $cref;
 157     }
 158
 159     goto $orig;
 160 EOC
 161 }
 162
 163 =head1 NAME
 164
 165 DBIx::Class::Storage::DBI - DBI storage handler
 166
 167 =head1 SYNOPSIS
 168
 169   my $schema = MySchema->connect('dbi:SQLite:my.db');
 170
 171   $schema->storage->debug(1);
 172
 173   my @stuff = $schema->storage->dbh_do(
 174     sub {
 175       my ($storage, $dbh, @args) = @_;
 176       $dbh->do("DROP TABLE authors");
 177     },
 178     @column_list
 179   );
 180
 181   $schema->resultset('Book')->search({
 182      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 183   });
 184
 185 =head1 DESCRIPTION
 186
 187 This class represents the connection to an RDBMS via L<DBI>.  See
 188 L<DBIx::Class::Storage> for general information.  This pod only
 189 documents DBI-specific methods and behaviors.
 190
 191 =head1 METHODS
 192
 193 =cut
 194
 195 sub new {
 196   my $new = shift->next::method(@_);
 197
 198   $new->_sql_maker_opts({});
 199   $new->_dbh_details({});
 200   $new->{_in_do_block} = 0;
 201
 202   # read below to see what this does
 203   $new->_arm_global_destructor;
 204
 205   $new;
 206 }
 207
 208 # This is hack to work around perl shooting stuff in random
 209 # order on exit(). If we do not walk the remaining storage
 210 # objects in an END block, there is a *small but real* chance
 211 # of a fork()ed child to kill the parent's shared DBI handle,
 212 # *before perl reaches the DESTROY in this package*
 213 # Yes, it is ugly and effective.
 214 # Additionally this registry is used by the CLONE method to
 215 # make sure no handles are shared between threads
 216 {
 217   my %seek_and_destroy;
 218
 219   sub _arm_global_destructor {
 220
 221     # quick "garbage collection" pass - prevents the registry
 222     # from slowly growing with a bunch of undef-valued keys
 223     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 224       for keys %seek_and_destroy;
 225
 226     weaken (
 227       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 228     );
 229
 230     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 231     # collected before leaving this scope. Depending on the code above, this
 232     # may very well be just a preventive measure guarding future modifications
 233     undef;
 234   }
 235
 236   END {
 237
 238     if(
 239       ! DBIx::Class::_ENV_::BROKEN_FORK
 240         and
 241       my @instances = grep { defined $_ } values %seek_and_destroy
 242     ) {
 243       local $?; # just in case the DBI destructor changes it somehow
 244
 245       # disarm the handle if not native to this process (see comment on top)
 246       $_->_verify_pid for @instances;
 247     }
 248
 249     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 250     # collected before leaving this scope. Depending on the code above, this
 251     # may very well be just a preventive measure guarding future modifications
 252     undef;
 253   }
 254
 255   sub CLONE {
 256     # As per DBI's recommendation, DBIC disconnects all handles as
 257     # soon as possible (DBIC will reconnect only on demand from within
 258     # the thread)
 259     my @instances = grep { defined $_ } values %seek_and_destroy;
 260     %seek_and_destroy = ();
 261
 262     for (@instances) {
 263       $_->_dbh(undef);
 264       $_->disconnect;
 265
 266       # properly renumber existing refs
 267       $_->_arm_global_destructor
 268     }
 269
 270     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 271     # collected before leaving this scope. Depending on the code above, this
 272     # may very well be just a preventive measure guarding future modifications
 273     undef;
 274   }
 275 }
 276
 277 sub DESTROY {
 278   return if &detected_reinvoked_destructor;
 279
 280   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 281
 282   # some databases spew warnings on implicit disconnect
 283   return unless defined $_[0]->_dbh;
 284
 285   local $SIG{__WARN__} = sub {};
 286   $_[0]->_dbh(undef);
 287   # not calling ->disconnect here - we are being destroyed - nothing to reset
 288
 289   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 290   # collected before leaving this scope. Depending on the code above, this
 291   # may very well be just a preventive measure guarding future modifications
 292   undef;
 293 }
 294
 295 # handle pid changes correctly - do not destroy parent's connection
 296 sub _verify_pid {
 297
 298   my $pid = $_[0]->_conn_pid;
 299
 300   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 301     $dbh->{InactiveDestroy} = 1;
 302     $_[0]->_dbh(undef);
 303     $_[0]->disconnect;
 304   }
 305
 306   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 307   # collected before leaving this scope. Depending on the code above, this
 308   # may very well be just a preventive measure guarding future modifications
 309   undef;
 310 }
 311
 312 =head2 connect_info
 313
 314 This method is normally called by L<DBIx::Class::Schema/connection>, which
 315 encapsulates its argument list in an arrayref before passing them here.
 316
 317 The argument list may contain:
 318
 319 =over
 320
 321 =item *
 322
 323 The same 4-element argument set one would normally pass to
 324 L<DBI/connect>, optionally followed by
 325 L<extra attributes|/DBIx::Class specific connection attributes>
 326 recognized by DBIx::Class:
 327
 328   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 329
 330 =item *
 331
 332 A single code reference which returns a connected
 333 L<DBI database handle|DBI/connect> optionally followed by
 334 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 335 by DBIx::Class:
 336
 337   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 338
 339 =item *
 340
 341 A single hashref with all the attributes and the dsn/user/password
 342 mixed together:
 343
 344   $connect_info_args = [{
 345     dsn => $dsn,
 346     user => $user,
 347     password => $pass,
 348     %dbi_attributes,
 349     %extra_attributes,
 350   }];
 351
 352   $connect_info_args = [{
 353     dbh_maker => sub { DBI->connect (...) },
 354     %dbi_attributes,
 355     %extra_attributes,
 356   }];
 357
 358 This is particularly useful for L<Catalyst> based applications, allowing the
 359 following config (L<Config::General> style):
 360
 361   <Model::DB>
 362     schema_class   App::DB
 363     <connect_info>
 364       dsn          dbi:mysql:database=test
 365       user         testuser
 366       password     TestPass
 367       AutoCommit   1
 368     </connect_info>
 369   </Model::DB>
 370
 371 The C<dsn>/C<user>/C<password> combination can be substituted by the
 372 C<dbh_maker> key whose value is a coderef that returns a connected
 373 L<DBI database handle|DBI/connect>
 374
 375 =back
 376
 377 Please note that the L<DBI> docs recommend that you always explicitly
 378 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 379 recommends that it be set to I<1>, and that you perform transactions
 380 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 381 to I<1> if you do not do explicitly set it to zero.  This is the default
 382 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 383
 384 =head3 DBIx::Class specific connection attributes
 385
 386 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 387 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 388 the following connection options. These options can be mixed in with your other
 389 L<DBI> connection attributes, or placed in a separate hashref
 390 (C<\%extra_attributes>) as shown above.
 391
 392 Every time C<connect_info> is invoked, any previous settings for
 393 these options will be cleared before setting the new ones, regardless of
 394 whether any options are specified in the new C<connect_info>.
 395
 396
 397 =over
 398
 399 =item on_connect_do
 400
 401 Specifies things to do immediately after connecting or re-connecting to
 402 the database.  Its value may contain:
 403
 404 =over
 405
 406 =item a scalar
 407
 408 This contains one SQL statement to execute.
 409
 410 =item an array reference
 411
 412 This contains SQL statements to execute in order.  Each element contains
 413 a string or a code reference that returns a string.
 414
 415 =item a code reference
 416
 417 This contains some code to execute.  Unlike code references within an
 418 array reference, its return value is ignored.
 419
 420 =back
 421
 422 =item on_disconnect_do
 423
 424 Takes arguments in the same form as L</on_connect_do> and executes them
 425 immediately before disconnecting from the database.
 426
 427 Note, this only runs if you explicitly call L</disconnect> on the
 428 storage object.
 429
 430 =item on_connect_call
 431
 432 A more generalized form of L</on_connect_do> that calls the specified
 433 C<connect_call_METHOD> methods in your storage driver.
 434
 435   on_connect_do => 'select 1'
 436
 437 is equivalent to:
 438
 439   on_connect_call => [ [ do_sql => 'select 1' ] ]
 440
 441 Its values may contain:
 442
 443 =over
 444
 445 =item a scalar
 446
 447 Will call the C<connect_call_METHOD> method.
 448
 449 =item a code reference
 450
 451 Will execute C<< $code->($storage) >>
 452
 453 =item an array reference
 454
 455 Each value can be a method name or code reference.
 456
 457 =item an array of arrays
 458
 459 For each array, the first item is taken to be the C<connect_call_> method name
 460 or code reference, and the rest are parameters to it.
 461
 462 =back
 463
 464 Some predefined storage methods you may use:
 465
 466 =over
 467
 468 =item do_sql
 469
 470 Executes a SQL string or a code reference that returns a SQL string. This is
 471 what L</on_connect_do> and L</on_disconnect_do> use.
 472
 473 It can take:
 474
 475 =over
 476
 477 =item a scalar
 478
 479 Will execute the scalar as SQL.
 480
 481 =item an arrayref
 482
 483 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 484 attributes hashref and bind values.
 485
 486 =item a code reference
 487
 488 Will execute C<< $code->($storage) >> and execute the return array refs as
 489 above.
 490
 491 =back
 492
 493 =item datetime_setup
 494
 495 Execute any statements necessary to initialize the database session to return
 496 and accept datetime/timestamp values used with
 497 L<DBIx::Class::InflateColumn::DateTime>.
 498
 499 Only necessary for some databases, see your specific storage driver for
 500 implementation details.
 501
 502 =back
 503
 504 =item on_disconnect_call
 505
 506 Takes arguments in the same form as L</on_connect_call> and executes them
 507 immediately before disconnecting from the database.
 508
 509 Calls the C<disconnect_call_METHOD> methods as opposed to the
 510 C<connect_call_METHOD> methods called by L</on_connect_call>.
 511
 512 Note, this only runs if you explicitly call L</disconnect> on the
 513 storage object.
 514
 515 =item disable_sth_caching
 516
 517 If set to a true value, this option will disable the caching of
 518 statement handles via L<DBI/prepare_cached>.
 519
 520 =item limit_dialect
 521
 522 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 523 default L</sql_limit_dialect> setting of the storage (if any). For a list
 524 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 525
 526 =item quote_names
 527
 528 When true automatically sets L</quote_char> and L</name_sep> to the characters
 529 appropriate for your particular RDBMS. This option is preferred over specifying
 530 L</quote_char> directly.
 531
 532 =item quote_char
 533
 534 Specifies what characters to use to quote table and column names.
 535
 536 C<quote_char> expects either a single character, in which case is it
 537 is placed on either side of the table/column name, or an arrayref of length
 538 2 in which case the table/column name is placed between the elements.
 539
 540 For example under MySQL you should use C<< quote_char => '`' >>, and for
 541 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 542
 543 =item name_sep
 544
 545 This parameter is only useful in conjunction with C<quote_char>, and is used to
 546 specify the character that separates elements (schemas, tables, columns) from
 547 each other. If unspecified it defaults to the most commonly used C<.>.
 548
 549 =item unsafe
 550
 551 This Storage driver normally installs its own C<HandleError>, sets
 552 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 553 all database handles, including those supplied by a coderef.  It does this
 554 so that it can have consistent and useful error behavior.
 555
 556 If you set this option to a true value, Storage will not do its usual
 557 modifications to the database handle's attributes, and instead relies on
 558 the settings in your connect_info DBI options (or the values you set in
 559 your connection coderef, in the case that you are connecting via coderef).
 560
 561 Note that your custom settings can cause Storage to malfunction,
 562 especially if you set a C<HandleError> handler that suppresses exceptions
 563 and/or disable C<RaiseError>.
 564
 565 =item auto_savepoint
 566
 567 If this option is true, L<DBIx::Class> will use savepoints when nesting
 568 transactions, making it possible to recover from failure in the inner
 569 transaction without having to abort all outer transactions.
 570
 571 =item cursor_class
 572
 573 Use this argument to supply a cursor class other than the default
 574 L<DBIx::Class::Storage::DBI::Cursor>.
 575
 576 =back
 577
 578 Some real-life examples of arguments to L</connect_info> and
 579 L<DBIx::Class::Schema/connect>
 580
 581   # Simple SQLite connection
 582   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 583
 584   # Connect via subref
 585   ->connect_info([ sub { DBI->connect(...) } ]);
 586
 587   # Connect via subref in hashref
 588   ->connect_info([{
 589     dbh_maker => sub { DBI->connect(...) },
 590     on_connect_do => 'alter session ...',
 591   }]);
 592
 593   # A bit more complicated
 594   ->connect_info(
 595     [
 596       'dbi:Pg:dbname=foo',
 597       'postgres',
 598       'my_pg_password',
 599       { AutoCommit => 1 },
 600       { quote_char => q{"} },
 601     ]
 602   );
 603
 604   # Equivalent to the previous example
 605   ->connect_info(
 606     [
 607       'dbi:Pg:dbname=foo',
 608       'postgres',
 609       'my_pg_password',
 610       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 611     ]
 612   );
 613
 614   # Same, but with hashref as argument
 615   # See parse_connect_info for explanation
 616   ->connect_info(
 617     [{
 618       dsn         => 'dbi:Pg:dbname=foo',
 619       user        => 'postgres',
 620       password    => 'my_pg_password',
 621       AutoCommit  => 1,
 622       quote_char  => q{"},
 623       name_sep    => q{.},
 624     }]
 625   );
 626
 627   # Subref + DBIx::Class-specific connection options
 628   ->connect_info(
 629     [
 630       sub { DBI->connect(...) },
 631       {
 632           quote_char => q{`},
 633           name_sep => q{@},
 634           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 635           disable_sth_caching => 1,
 636       },
 637     ]
 638   );
 639
 640
 641
 642 =cut
 643
 644 sub connect_info {
 645   my ($self, $info) = @_;
 646
 647   return $self->_connect_info if !$info;
 648
 649   $self->_connect_info($info); # copy for _connect_info
 650
 651   $info = $self->_normalize_connect_info($info)
 652     if ref $info eq 'ARRAY';
 653
 654   my %attrs = (
 655     %{ $self->_default_dbi_connect_attributes || {} },
 656     %{ $info->{attributes} || {} },
 657   );
 658
 659   my @args = @{ $info->{arguments} };
 660
 661   if (keys %attrs and ref $args[0] ne 'CODE') {
 662     carp_unique (
 663         'You provided explicit AutoCommit => 0 in your connection_info. '
 664       . 'This is almost universally a bad idea (see the footnotes of '
 665       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 666       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 667       . 'this warning.'
 668     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 669
 670     push @args, \%attrs if keys %attrs;
 671   }
 672
 673   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 674   # OR a single-element coderef-based $dbh factory
 675   $self->_dbi_connect_info(\@args);
 676
 677   # extract the individual storage options
 678   for my $storage_opt (keys %{ $info->{storage_options} }) {
 679     my $value = $info->{storage_options}{$storage_opt};
 680
 681     $self->$storage_opt($value);
 682   }
 683
 684   # Extract the individual sqlmaker options
 685   #
 686   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 687   #  the new set of options
 688   $self->_sql_maker(undef);
 689   $self->_sql_maker_opts({});
 690
 691   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 692     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 693
 694     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 695   }
 696
 697   # FIXME - dirty:
 698   # save attributes in a separate accessor so they are always
 699   # introspectable, even in case of a CODE $dbhmaker
 700   $self->_dbic_connect_attributes (\%attrs);
 701
 702   return $self->_connect_info;
 703 }
 704
 705 sub _dbi_connect_info {
 706   my $self = shift;
 707
 708   return $self->{_dbi_connect_info} = $_[0]
 709     if @_;
 710
 711   my $conninfo = $self->{_dbi_connect_info} || [];
 712
 713   # last ditch effort to grab a DSN
 714   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 715     my @new_conninfo = @$conninfo;
 716     $new_conninfo[0] = $ENV{DBI_DSN};
 717     $conninfo = \@new_conninfo;
 718   }
 719
 720   return $conninfo;
 721 }
 722
 723
 724 sub _normalize_connect_info {
 725   my ($self, $info_arg) = @_;
 726   my %info;
 727
 728   my @args = @$info_arg;  # take a shallow copy for further mutilation
 729
 730   # combine/pre-parse arguments depending on invocation style
 731
 732   my %attrs;
 733   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 734     %attrs = %{ $args[1] || {} };
 735     @args = $args[0];
 736   }
 737   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 738     %attrs = %{$args[0]};
 739     @args = ();
 740     if (my $code = delete $attrs{dbh_maker}) {
 741       @args = $code;
 742
 743       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 744       if (@ignored) {
 745         carp sprintf (
 746             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 747           . "to the result of 'dbh_maker'",
 748
 749           join (', ', map { "'$_'" } (@ignored) ),
 750         );
 751       }
 752     }
 753     else {
 754       @args = delete @attrs{qw/dsn user password/};
 755     }
 756   }
 757   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 758     %attrs = (
 759       % { $args[3] || {} },
 760       % { $args[4] || {} },
 761     );
 762     @args = @args[0,1,2];
 763   }
 764
 765   $info{arguments} = \@args;
 766
 767   my @storage_opts = grep exists $attrs{$_},
 768     @storage_options, 'cursor_class';
 769
 770   @{ $info{storage_options} }{@storage_opts} =
 771     delete @attrs{@storage_opts} if @storage_opts;
 772
 773   my @sql_maker_opts = grep exists $attrs{$_},
 774     qw/limit_dialect quote_char name_sep quote_names/;
 775
 776   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 777     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 778
 779   $info{attributes} = \%attrs if %attrs;
 780
 781   return \%info;
 782 }
 783
 784 sub _default_dbi_connect_attributes () {
 785   +{
 786     AutoCommit => 1,
 787     PrintError => 0,
 788     RaiseError => 1,
 789     ShowErrorStatement => 1,
 790   };
 791 }
 792
 793 =head2 on_connect_do
 794
 795 This method is deprecated in favour of setting via L</connect_info>.
 796
 797 =cut
 798
 799 =head2 on_disconnect_do
 800
 801 This method is deprecated in favour of setting via L</connect_info>.
 802
 803 =cut
 804
 805 sub _parse_connect_do {
 806   my ($self, $type) = @_;
 807
 808   my $val = $self->$type;
 809   return () if not defined $val;
 810
 811   my @res;
 812
 813   if (not ref($val)) {
 814     push @res, [ 'do_sql', $val ];
 815   } elsif (ref($val) eq 'CODE') {
 816     push @res, $val;
 817   } elsif (ref($val) eq 'ARRAY') {
 818     push @res, map { [ 'do_sql', $_ ] } @$val;
 819   } else {
 820     $self->throw_exception("Invalid type for $type: ".ref($val));
 821   }
 822
 823   return \@res;
 824 }
 825
 826 =head2 dbh_do
 827
 828 Arguments: ($subref | $method_name), @extra_coderef_args?
 829
 830 Execute the given $subref or $method_name using the new exception-based
 831 connection management.
 832
 833 The first two arguments will be the storage object that C<dbh_do> was called
 834 on and a database handle to use.  Any additional arguments will be passed
 835 verbatim to the called subref as arguments 2 and onwards.
 836
 837 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 838 exception handling and reconnection (or failover in future subclasses).
 839
 840 Your subref should have no side-effects outside of the database, as
 841 there is the potential for your subref to be partially double-executed
 842 if the database connection was stale/dysfunctional.
 843
 844 Example:
 845
 846   my @stuff = $schema->storage->dbh_do(
 847     sub {
 848       my ($storage, $dbh, @cols) = @_;
 849       my $cols = join(q{, }, @cols);
 850       $dbh->selectrow_array("SELECT $cols FROM foo");
 851     },
 852     @column_list
 853   );
 854
 855 =cut
 856
 857 sub dbh_do {
 858   my $self = shift;
 859   my $run_target = shift; # either a coderef or a method name
 860
 861   # short circuit when we know there is no need for a runner
 862   #
 863   # FIXME - assumption may be wrong
 864   # the rationale for the txn_depth check is that if this block is a part
 865   # of a larger transaction, everything up to that point is screwed anyway
 866   return $self->$run_target($self->_get_dbh, @_)
 867     if $self->{_in_do_block} or $self->transaction_depth;
 868
 869   # take a ref instead of a copy, to preserve @_ aliasing
 870   # semantics within the coderef, but only if needed
 871   # (pseudoforking doesn't like this trick much)
 872   my $args = @_ ? \@_ : [];
 873
 874   DBIx::Class::Storage::BlockRunner->new(
 875     storage => $self,
 876     wrap_txn => 0,
 877     retry_handler => sub {
 878       $_[0]->failed_attempt_count == 1
 879         and
 880       ! $_[0]->storage->connected
 881     },
 882   )->run(sub {
 883     $self->$run_target ($self->_get_dbh, @$args )
 884   });
 885 }
 886
 887 sub txn_do {
 888   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 889   shift->next::method(@_);
 890 }
 891
 892 =head2 disconnect
 893
 894 Our C<disconnect> method also performs a rollback first if the
 895 database is not in C<AutoCommit> mode.
 896
 897 =cut
 898
 899 sub disconnect {
 900   my $self = shift;
 901
 902   # this physical disconnect below might very well throw
 903   # in order to unambiguously reset the state - do the cleanup in guard
 904
 905   my $g = scope_guard {
 906
 907     defined( $self->_dbh )
 908       and dbic_internal_try { $self->_dbh->disconnect };
 909
 910     $self->_dbh(undef);
 911     $self->_dbh_details({});
 912     $self->transaction_depth(undef);
 913     $self->_dbh_autocommit(undef);
 914     $self->savepoints([]);
 915
 916     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 917     #$self->_sql_maker(undef); # this may also end up being different
 918   };
 919
 920   if( $self->_dbh ) {
 921
 922     $self->_do_connection_actions(disconnect_call_ => $_) for (
 923       ( $self->on_disconnect_call || () ),
 924       $self->_parse_connect_do ('on_disconnect_do')
 925     );
 926
 927     # stops the "implicit rollback on disconnect" warning
 928     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 929   }
 930
 931   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 932   # collected before leaving this scope. Depending on the code above, this
 933   # may very well be just a preventive measure guarding future modifications
 934   undef;
 935 }
 936
 937 =head2 with_deferred_fk_checks
 938
 939 =over 4
 940
 941 =item Arguments: C<$coderef>
 942
 943 =item Return Value: The return value of $coderef
 944
 945 =back
 946
 947 Storage specific method to run the code ref with FK checks deferred or
 948 in MySQL's case disabled entirely.
 949
 950 =cut
 951
 952 # Storage subclasses should override this
 953 sub with_deferred_fk_checks {
 954   #my ($self, $sub) = @_;
 955   $_[1]->();
 956 }
 957
 958 =head2 connected
 959
 960 =over
 961
 962 =item Arguments: none
 963
 964 =item Return Value: 1|0
 965
 966 =back
 967
 968 Verifies that the current database handle is active and ready to execute
 969 an SQL statement (e.g. the connection did not get stale, server is still
 970 answering, etc.) This method is used internally by L</dbh>.
 971
 972 =cut
 973
 974 sub connected {
 975   return 0 unless $_[0]->_seems_connected;
 976
 977   #be on the safe side
 978   local $_[0]->_dbh->{RaiseError} = 1;
 979
 980   return $_[0]->_ping;
 981 }
 982
 983 sub _seems_connected {
 984   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 985
 986   $_[0]->_dbh
 987     and
 988   $_[0]->_dbh->FETCH('Active')
 989     and
 990   return 1;
 991
 992   # explicitly reset all state
 993   $_[0]->disconnect;
 994   return 0;
 995 }
 996
 997 sub _ping {
 998   ($_[0]->_dbh || return 0)->ping;
 999 }
1000
1001 sub ensure_connected {
1002   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
1003 }
1004
1005 =head2 dbh
1006
1007 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
1008 is guaranteed to be healthy by implicitly calling L</connected>, and if
1009 necessary performing a reconnection before returning. Keep in mind that this
1010 is very B<expensive> on some database engines. Consider using L</dbh_do>
1011 instead.
1012
1013 =cut
1014
1015 sub dbh {
1016   # maybe save a ping call
1017   $_[0]->_dbh
1018     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
1019     : $_[0]->_populate_dbh
1020   ;
1021 }
1022
1023 # this is the internal "get dbh or connect (don't check)" method
1024 sub _get_dbh {
1025   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1026   $_[0]->_dbh || $_[0]->_populate_dbh;
1027 }
1028
1029 # *DELIBERATELY* not a setter (for the time being)
1030 # Too intertwined with everything else for any kind of sanity
1031 sub sql_maker {
1032   my $self = shift;
1033
1034   $self->throw_exception('sql_maker() is not a setter method') if @_;
1035
1036   unless ($self->_sql_maker) {
1037     my $sql_maker_class = $self->sql_maker_class;
1038
1039     my %opts = %{$self->_sql_maker_opts||{}};
1040     my $dialect =
1041       $opts{limit_dialect}
1042         ||
1043       $self->sql_limit_dialect
1044         ||
1045       do {
1046         my $s_class = (ref $self) || $self;
1047         carp_unique (
1048           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1049         . 'have not supplied an explicit limit_dialect in your connection_info. '
1050         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1051         . 'databases but can be (and often is) painfully slow. '
1052         . "Please file an RT ticket against '$s_class'"
1053         ) if $self->_dbi_connect_info->[0];
1054
1055         'GenericSubQ';
1056       }
1057     ;
1058
1059     my ($quote_char, $name_sep);
1060
1061     if ($opts{quote_names}) {
1062       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1063         my $s_class = (ref $self) || $self;
1064         carp_unique (
1065           "You requested 'quote_names' but your storage class ($s_class) does "
1066         . 'not explicitly define a default sql_quote_char and you have not '
1067         . 'supplied a quote_char as part of your connection_info. DBIC will '
1068         .q{default to the ANSI SQL standard quote '"', which works most of }
1069         . "the time. Please file an RT ticket against '$s_class'."
1070         );
1071
1072         '"'; # RV
1073       };
1074
1075       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1076     }
1077
1078     $self->_sql_maker($sql_maker_class->new(
1079       bindtype=>'columns',
1080       array_datatypes => 1,
1081       limit_dialect => $dialect,
1082       ($quote_char ? (quote_char => $quote_char) : ()),
1083       name_sep => ($name_sep || '.'),
1084       %opts,
1085     ));
1086   }
1087   return $self->_sql_maker;
1088 }
1089
1090 # nothing to do by default
1091 sub _rebless {}
1092 sub _init {}
1093
1094 sub _populate_dbh {
1095
1096   # reset internal states
1097   # also in case ->connected failed we might get sent here
1098   $_[0]->disconnect;
1099
1100   $_[0]->_dbh($_[0]->_connect);
1101
1102   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1103
1104   $_[0]->_determine_driver;
1105
1106   # Always set the transaction depth on connect, since
1107   #  there is no transaction in progress by definition
1108   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1109
1110   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1111
1112   $_[0]->_dbh;
1113 }
1114
1115 sub _run_connection_actions {
1116
1117   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1118     ( $_[0]->on_connect_call || () ),
1119     $_[0]->_parse_connect_do ('on_connect_do'),
1120   );
1121 }
1122
1123
1124
1125 sub set_use_dbms_capability {
1126   $_[0]->set_inherited ($_[1], $_[2]);
1127 }
1128
1129 sub get_use_dbms_capability {
1130   my ($self, $capname) = @_;
1131
1132   my $use = $self->get_inherited ($capname);
1133   return defined $use
1134     ? $use
1135     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1136   ;
1137 }
1138
1139 sub set_dbms_capability {
1140   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1141 }
1142
1143 sub get_dbms_capability {
1144   my ($self, $capname) = @_;
1145
1146   my $cap = $self->_dbh_details->{capability}{$capname};
1147
1148   unless (defined $cap) {
1149     if (my $meth = $self->can ("_determine$capname")) {
1150       $cap = $self->$meth ? 1 : 0;
1151     }
1152     else {
1153       $cap = 0;
1154     }
1155
1156     $self->set_dbms_capability ($capname, $cap);
1157   }
1158
1159   return $cap;
1160 }
1161
1162 sub _server_info {
1163   my $self = shift;
1164
1165   # FIXME - ideally this needs to be an ||= assignment, and the final
1166   # assignment at the end of this do{} should be gone entirely. However
1167   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1168   $self->_dbh_details->{info} || do {
1169
1170     # this guarantees that problematic conninfo won't be hidden
1171     # by the try{} below
1172     $self->ensure_connected;
1173
1174     my $info = {};
1175
1176     my $server_version = dbic_internal_try {
1177       $self->_get_server_version
1178     } catch {
1179       # driver determination *may* use this codepath
1180       # in which case we must rethrow
1181       $self->throw_exception($_) if $self->{_in_determine_driver};
1182
1183       # $server_version on failure
1184       undef;
1185     };
1186
1187     if (defined $server_version) {
1188       $info->{dbms_version} = $server_version;
1189
1190       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1191       my @verparts = split (/\./, $numeric_version);
1192       if (
1193         @verparts
1194           &&
1195         $verparts[0] <= 999
1196       ) {
1197         # consider only up to 3 version parts, iff not more than 3 digits
1198         my @use_parts;
1199         while (@verparts && @use_parts < 3) {
1200           my $p = shift @verparts;
1201           last if $p > 999;
1202           push @use_parts, $p;
1203         }
1204         push @use_parts, 0 while @use_parts < 3;
1205
1206         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1207       }
1208     }
1209
1210     $self->_dbh_details->{info} = $info;
1211   };
1212 }
1213
1214 sub _get_server_version {
1215   shift->_dbh_get_info('SQL_DBMS_VER');
1216 }
1217
1218 sub _dbh_get_info {
1219   my ($self, $info) = @_;
1220
1221   if ($info =~ /[^0-9]/) {
1222     require DBI::Const::GetInfoType;
1223     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1224     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1225       unless defined $info;
1226   }
1227
1228   $self->_get_dbh->get_info($info);
1229 }
1230
1231 sub _describe_connection {
1232   require DBI::Const::GetInfoReturn;
1233
1234   my $self = shift;
1235
1236   my $drv;
1237   dbic_internal_try {
1238     $drv = $self->_extract_driver_from_connect_info;
1239     $self->ensure_connected;
1240   };
1241
1242   $drv = "DBD::$drv" if $drv;
1243
1244   my $res = {
1245     DBIC_DSN => $self->_dbi_connect_info->[0],
1246     DBI_VER => DBI->VERSION,
1247     DBIC_VER => DBIx::Class->VERSION,
1248     DBIC_DRIVER => ref $self,
1249     $drv ? (
1250       DBD => $drv,
1251       DBD_VER => dbic_internal_try { $drv->VERSION },
1252     ) : (),
1253   };
1254
1255   # try to grab data even if we never managed to connect
1256   # will cover us in cases of an oddly broken half-connect
1257   for my $inf (
1258     #keys %DBI::Const::GetInfoType::GetInfoType,
1259     qw/
1260       SQL_CURSOR_COMMIT_BEHAVIOR
1261       SQL_CURSOR_ROLLBACK_BEHAVIOR
1262       SQL_CURSOR_SENSITIVITY
1263       SQL_DATA_SOURCE_NAME
1264       SQL_DBMS_NAME
1265       SQL_DBMS_VER
1266       SQL_DEFAULT_TXN_ISOLATION
1267       SQL_DM_VER
1268       SQL_DRIVER_NAME
1269       SQL_DRIVER_ODBC_VER
1270       SQL_DRIVER_VER
1271       SQL_EXPRESSIONS_IN_ORDERBY
1272       SQL_GROUP_BY
1273       SQL_IDENTIFIER_CASE
1274       SQL_IDENTIFIER_QUOTE_CHAR
1275       SQL_MAX_CATALOG_NAME_LEN
1276       SQL_MAX_COLUMN_NAME_LEN
1277       SQL_MAX_IDENTIFIER_LEN
1278       SQL_MAX_TABLE_NAME_LEN
1279       SQL_MULTIPLE_ACTIVE_TXN
1280       SQL_MULT_RESULT_SETS
1281       SQL_NEED_LONG_DATA_LEN
1282       SQL_NON_NULLABLE_COLUMNS
1283       SQL_ODBC_VER
1284       SQL_QUALIFIER_NAME_SEPARATOR
1285       SQL_QUOTED_IDENTIFIER_CASE
1286       SQL_TXN_CAPABLE
1287       SQL_TXN_ISOLATION_OPTION
1288     /
1289   ) {
1290     # some drivers barf on things they do not know about instead
1291     # of returning undef
1292     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1293     next unless defined $v;
1294
1295     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1296     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1297     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1298   }
1299
1300   $res;
1301 }
1302
1303 sub _determine_driver {
1304   my ($self) = @_;
1305
1306   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1307     my $started_connected = 0;
1308     local $self->{_in_determine_driver} = 1;
1309
1310     if (ref($self) eq __PACKAGE__) {
1311       my $driver;
1312       if ($self->_dbh) { # we are connected
1313         $driver = $self->_dbh->{Driver}{Name};
1314         $started_connected = 1;
1315       }
1316       else {
1317         $driver = $self->_extract_driver_from_connect_info;
1318       }
1319
1320       if ($driver) {
1321         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1322         if ($self->load_optional_class($storage_class)) {
1323           mro::set_mro($storage_class, 'c3');
1324           bless $self, $storage_class;
1325           $self->_rebless();
1326         }
1327         else {
1328           $self->_warn_undetermined_driver(
1329             'This version of DBIC does not yet seem to supply a driver for '
1330           . "your particular RDBMS and/or connection method ('$driver')."
1331           );
1332         }
1333       }
1334       else {
1335         $self->_warn_undetermined_driver(
1336           'Unable to extract a driver name from connect info - this '
1337         . 'should not have happened.'
1338         );
1339       }
1340     }
1341
1342     $self->_driver_determined(1);
1343
1344     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1345
1346     if ($self->can('source_bind_attributes')) {
1347       $self->throw_exception(
1348         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1349       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1350       . 'If you are not sure how to proceed please contact the development team via '
1351       . DBIx::Class::_ENV_::HELP_URL
1352       );
1353     }
1354
1355     $self->_init; # run driver-specific initializations
1356
1357     $self->_run_connection_actions
1358         if !$started_connected && defined $self->_dbh;
1359   }
1360 }
1361
1362 sub _extract_driver_from_connect_info {
1363   my $self = shift;
1364
1365   my $drv;
1366
1367   # if connect_info is a CODEREF, we have no choice but to connect
1368   if (
1369     ref $self->_dbi_connect_info->[0]
1370       and
1371     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1372   ) {
1373     $self->_populate_dbh;
1374     $drv = $self->_dbh->{Driver}{Name};
1375   }
1376   else {
1377     # try to use dsn to not require being connected, the driver may still
1378     # force a connection later in _rebless to determine version
1379     # (dsn may not be supplied at all if all we do is make a mock-schema)
1380     #
1381     # Use the same regex as the one used by DBI itself (even if the use of
1382     # \w is odd given unicode):
1383     # https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L621
1384     #
1385     # DO NOT use https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L559-566
1386     # as there is a long-standing precedent of not loading DBI.pm until the
1387     # very moment we are actually connecting
1388     #
1389     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:(\w*)/i;
1390     $drv ||= $ENV{DBI_DRIVER};
1391   }
1392
1393   return $drv;
1394 }
1395
1396 sub _determine_connector_driver {
1397   my ($self, $conn) = @_;
1398
1399   my $dbtype = $self->_get_rdbms_name;
1400
1401   if (not $dbtype) {
1402     $self->_warn_undetermined_driver(
1403       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1404     . "$conn connector - this should not have happened."
1405     );
1406     return;
1407   }
1408
1409   $dbtype =~ s/\W/_/gi;
1410
1411   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1412   return if $self->isa($subclass);
1413
1414   if ($self->load_optional_class($subclass)) {
1415     bless $self, $subclass;
1416     $self->_rebless;
1417   }
1418   else {
1419     $self->_warn_undetermined_driver(
1420       'This version of DBIC does not yet seem to supply a driver for '
1421     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1422     );
1423   }
1424 }
1425
1426 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1427
1428 sub _warn_undetermined_driver {
1429   my ($self, $msg) = @_;
1430
1431   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1432   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1433   . "does not go away, file a bugreport including the following info:\n"
1434   . dump_value $self->_describe_connection
1435   );
1436 }
1437
1438 sub _do_connection_actions {
1439   my ($self, $method_prefix, $call, @args) = @_;
1440
1441   dbic_internal_try {
1442     if (not ref($call)) {
1443       my $method = $method_prefix . $call;
1444       $self->$method(@args);
1445     }
1446     elsif (ref($call) eq 'CODE') {
1447       $self->$call(@args);
1448     }
1449     elsif (ref($call) eq 'ARRAY') {
1450       if (ref($call->[0]) ne 'ARRAY') {
1451         $self->_do_connection_actions($method_prefix, $_) for @$call;
1452       }
1453       else {
1454         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1455       }
1456     }
1457     else {
1458       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1459     }
1460   }
1461   catch {
1462     if ( $method_prefix =~ /^connect/ ) {
1463       # this is an on_connect cycle - we can't just throw while leaving
1464       # a handle in an undefined state in our storage object
1465       # kill it with fire and rethrow
1466       $self->_dbh(undef);
1467       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1468       $self->throw_exception( $_[0] );
1469     }
1470     else {
1471       carp "Disconnect action failed: $_[0]";
1472     }
1473   };
1474
1475   return $self;
1476 }
1477
1478 sub connect_call_do_sql {
1479   my $self = shift;
1480   $self->_do_query(@_);
1481 }
1482
1483 sub disconnect_call_do_sql {
1484   my $self = shift;
1485   $self->_do_query(@_);
1486 }
1487
1488 =head2 connect_call_datetime_setup
1489
1490 A no-op stub method, provided so that one can always safely supply the
1491 L<connection option|/DBIx::Class specific connection attributes>
1492
1493  on_connect_call => 'datetime_setup'
1494
1495 This way one does not need to know in advance whether the underlying
1496 storage requires any sort of hand-holding when dealing with calendar
1497 data.
1498
1499 =cut
1500
1501 sub connect_call_datetime_setup { 1 }
1502
1503 sub _do_query {
1504   my ($self, $action) = @_;
1505
1506   if (ref $action eq 'CODE') {
1507     $action = $action->($self);
1508     $self->_do_query($_) foreach @$action;
1509   }
1510   else {
1511     # Most debuggers expect ($sql, @bind), so we need to exclude
1512     # the attribute hash which is the second argument to $dbh->do
1513     # furthermore the bind values are usually to be presented
1514     # as named arrayref pairs, so wrap those here too
1515     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1516     my $sql = shift @do_args;
1517     my $attrs = shift @do_args;
1518     my @bind = map { [ undef, $_ ] } @do_args;
1519
1520     $self->dbh_do(sub {
1521       $_[0]->_query_start($sql, \@bind);
1522       $_[1]->do($sql, $attrs, @do_args);
1523       $_[0]->_query_end($sql, \@bind);
1524     });
1525   }
1526
1527   return $self;
1528 }
1529
1530 sub _connect {
1531   my $self = shift;
1532
1533   my $info = $self->_dbi_connect_info;
1534
1535   $self->throw_exception("You did not provide any connection_info")
1536     unless defined $info->[0];
1537
1538   my ($old_connect_via, $dbh);
1539
1540   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1541
1542   # this odd anonymous coderef dereference is in fact really
1543   # necessary to avoid the unwanted effect described in perl5
1544   # RT#75792
1545   #
1546   # in addition the coderef itself can't reside inside the try{} block below
1547   # as it somehow triggers a leak under perl -d
1548   my $dbh_error_handler_installer = sub {
1549     weaken (my $weak_self = $_[0]);
1550
1551     # the coderef is blessed so we can distinguish it from externally
1552     # supplied handles (which must be preserved)
1553     $_[1]->{HandleError} = bless sub {
1554       if ($weak_self) {
1555         $weak_self->throw_exception("DBI Exception: $_[0]");
1556       }
1557       else {
1558         # the handler may be invoked by something totally out of
1559         # the scope of DBIC
1560         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1561       }
1562     }, '__DBIC__DBH__ERROR__HANDLER__';
1563   };
1564
1565   dbic_internal_try {
1566     if(ref $info->[0] eq 'CODE') {
1567       $dbh = $info->[0]->();
1568     }
1569     else {
1570       require DBI;
1571       $dbh = DBI->connect(@$info);
1572     }
1573
1574     die $DBI::errstr unless $dbh;
1575
1576     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1577       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1578       . 'not continue',
1579       ref $info->[0] eq 'CODE'
1580         ? "Connection coderef $info->[0] returned a"
1581         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1582     ) unless $dbh->FETCH('Active');
1583
1584     # sanity checks unless asked otherwise
1585     unless ($self->unsafe) {
1586
1587       $self->throw_exception(
1588         'Refusing clobbering of {HandleError} installed on externally supplied '
1589        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1590       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1591
1592       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1593       # request, or an external handle. Complain and set anyway
1594       unless ($dbh->{RaiseError}) {
1595         carp( ref $info->[0] eq 'CODE'
1596
1597           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1598            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1599            .'attribute has been supplied'
1600
1601           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1602            .'unsafe => 1. Toggling RaiseError back to true'
1603         );
1604
1605         $dbh->{RaiseError} = 1;
1606       }
1607
1608       $dbh_error_handler_installer->($self, $dbh);
1609     }
1610   }
1611   catch {
1612     $self->throw_exception("DBI Connection failed: $_")
1613   };
1614
1615   $self->_dbh_autocommit($dbh->{AutoCommit});
1616   return $dbh;
1617 }
1618
1619 sub txn_begin {
1620   # this means we have not yet connected and do not know the AC status
1621   # (e.g. coderef $dbh), need a full-fledged connection check
1622   if (! defined $_[0]->_dbh_autocommit) {
1623     $_[0]->ensure_connected;
1624   }
1625   # Otherwise simply connect or re-connect on pid changes
1626   else {
1627     $_[0]->_get_dbh;
1628   }
1629
1630   shift->next::method(@_);
1631 }
1632
1633 sub _exec_txn_begin {
1634   my $self = shift;
1635
1636   # if the user is utilizing txn_do - good for him, otherwise we need to
1637   # ensure that the $dbh is healthy on BEGIN.
1638   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1639   # will be replaced by a failure of begin_work itself (which will be
1640   # then retried on reconnect)
1641   if ($self->{_in_do_block}) {
1642     $self->_dbh->begin_work;
1643   } else {
1644     $self->dbh_do(sub { $_[1]->begin_work });
1645   }
1646 }
1647
1648 sub txn_commit {
1649   my $self = shift;
1650
1651   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1652     unless $self->_seems_connected;
1653
1654   # esoteric case for folks using external $dbh handles
1655   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1656     carp "Storage transaction_depth 0 does not match "
1657         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1658     $self->transaction_depth(1);
1659   }
1660
1661   $self->next::method(@_);
1662
1663   # if AutoCommit is disabled txn_depth never goes to 0
1664   # as a new txn is started immediately on commit
1665   $self->transaction_depth(1) if (
1666     !$self->transaction_depth
1667       and
1668     defined $self->_dbh_autocommit
1669       and
1670     ! $self->_dbh_autocommit
1671   );
1672 }
1673
1674 sub _exec_txn_commit {
1675   shift->_dbh->commit;
1676 }
1677
1678 sub txn_rollback {
1679   my $self = shift;
1680
1681   # do a minimal connectivity check due to weird shit like
1682   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1683   $self->throw_exception("lost connection to storage")
1684     unless $self->_seems_connected;
1685
1686   # esoteric case for folks using external $dbh handles
1687   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1688     carp "Storage transaction_depth 0 does not match "
1689         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1690     $self->transaction_depth(1);
1691   }
1692
1693   $self->next::method(@_);
1694
1695   # if AutoCommit is disabled txn_depth never goes to 0
1696   # as a new txn is started immediately on commit
1697   $self->transaction_depth(1) if (
1698     !$self->transaction_depth
1699       and
1700     defined $self->_dbh_autocommit
1701       and
1702     ! $self->_dbh_autocommit
1703   );
1704 }
1705
1706 sub _exec_txn_rollback {
1707   shift->_dbh->rollback;
1708 }
1709
1710 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1711 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1712   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1713     unless $_[0]->_seems_connected;
1714   shift->next::method(@_);
1715 EOS
1716
1717 # This used to be the top-half of _execute.  It was split out to make it
1718 #  easier to override in NoBindVars without duping the rest.  It takes up
1719 #  all of _execute's args, and emits $sql, @bind.
1720 sub _prep_for_execute {
1721   #my ($self, $op, $ident, $args) = @_;
1722   return shift->_gen_sql_bind(@_)
1723 }
1724
1725 sub _gen_sql_bind {
1726   my ($self, $op, $ident, $args) = @_;
1727
1728   my ($colinfos, $from);
1729   if ( blessed($ident) ) {
1730     $from = $ident->from;
1731     $colinfos = $ident->columns_info;
1732   }
1733
1734   my ($sql, $bind);
1735   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1736
1737   $bind = $self->_resolve_bindattrs(
1738     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1739   );
1740
1741   if (
1742     ! $ENV{DBIC_DT_SEARCH_OK}
1743       and
1744     $op eq 'select'
1745       and
1746     first {
1747       length ref $_->[1]
1748         and
1749       blessed($_->[1])
1750         and
1751       $_->[1]->isa('DateTime')
1752     } @$bind
1753   ) {
1754     carp_unique 'DateTime objects passed to search() are not supported '
1755       . 'properly (InflateColumn::DateTime formats and settings are not '
1756       . 'respected.) See ".. format a DateTime object for searching?" in '
1757       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1758       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1759   }
1760
1761   return( $sql, $bind );
1762 }
1763
1764 sub _resolve_bindattrs {
1765   my ($self, $ident, $bind, $colinfos) = @_;
1766
1767   my $resolve_bindinfo = sub {
1768     #my $infohash = shift;
1769
1770     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1771
1772     my $ret;
1773     if (my $col = $_[0]->{dbic_colname}) {
1774       $ret = { %{$_[0]} };
1775
1776       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1777         if $colinfos->{$col}{data_type};
1778
1779       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1780         if $colinfos->{$col}{size};
1781     }
1782
1783     $ret || $_[0];
1784   };
1785
1786   return [ map {
1787       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1788     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1789     : (ref $_->[0] eq 'HASH')           ? [(
1790                                             ! keys %{$_->[0]}
1791                                               or
1792                                             exists $_->[0]{dbd_attrs}
1793                                               or
1794                                             $_->[0]{sqlt_datatype}
1795                                            ) ? $_->[0]
1796                                              : $resolve_bindinfo->($_->[0])
1797                                            , $_->[1]
1798                                           ]
1799     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1800     :                                     [ $resolve_bindinfo->(
1801                                               { dbic_colname => $_->[0] }
1802                                             ), $_->[1] ]
1803   } @$bind ];
1804 }
1805
1806 sub _format_for_trace {
1807   #my ($self, $bind) = @_;
1808
1809   ### Turn @bind from something like this:
1810   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1811   ### to this:
1812   ###   ( "'1'", "'3'" )
1813
1814   map {
1815     defined( $_ && $_->[1] )
1816       ? qq{'$_->[1]'}
1817       : q{NULL}
1818   } @{$_[1] || []};
1819 }
1820
1821 sub _query_start {
1822   my ( $self, $sql, $bind ) = @_;
1823
1824   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1825     if $self->debug;
1826 }
1827
1828 sub _query_end {
1829   my ( $self, $sql, $bind ) = @_;
1830
1831   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1832     if $self->debug;
1833 }
1834
1835 sub _dbi_attrs_for_bind {
1836   #my ($self, $ident, $bind) = @_;
1837
1838   return [ map {
1839
1840     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1841
1842   : ! $_->{sqlt_datatype}   ? undef
1843
1844   :                           do {
1845
1846     # cache the result in the dbh_details hash, as it (usually) can not change
1847     # unless we connect to something else
1848     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1849     # the LOB storage
1850     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1851
1852     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1853       if ! exists $cache->{$_->{sqlt_datatype}};
1854
1855     $cache->{$_->{sqlt_datatype}};
1856
1857   } } map { $_->[0] } @{$_[2]} ];
1858 }
1859
1860 sub _execute {
1861   my ($self, $op, $ident, @args) = @_;
1862
1863   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1864
1865   # not even a PID check - we do not care about the state of the _dbh.
1866   # All we need is to get the appropriate drivers loaded if they aren't
1867   # already so that the assumption in ad7c50fc26e holds
1868   $self->_populate_dbh unless $self->_dbh;
1869
1870   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1871     $sql,
1872     $bind,
1873     $self->_dbi_attrs_for_bind($ident, $bind),
1874   );
1875 }
1876
1877 sub _dbh_execute {
1878   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1879
1880   $self->_query_start( $sql, $bind );
1881
1882   my $sth = $self->_bind_sth_params(
1883     $self->_prepare_sth($dbh, $sql),
1884     $bind,
1885     $bind_attrs,
1886   );
1887
1888   # Can this fail without throwing an exception anyways???
1889   my $rv = $sth->execute();
1890   $self->throw_exception(
1891     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1892   ) if !$rv;
1893
1894   $self->_query_end( $sql, $bind );
1895
1896   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1897 }
1898
1899 sub _prepare_sth {
1900   my ($self, $dbh, $sql) = @_;
1901
1902   # 3 is the if_active parameter which avoids active sth re-use
1903   my $sth = $self->disable_sth_caching
1904     ? $dbh->prepare($sql)
1905     : $dbh->prepare_cached($sql, {}, 3);
1906
1907   # XXX You would think RaiseError would make this impossible,
1908   #  but apparently that's not true :(
1909   $self->throw_exception(
1910     $dbh->errstr
1911       ||
1912     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1913             .'an exception and/or setting $dbh->errstr',
1914       length ($sql) > 20
1915         ? substr($sql, 0, 20) . '...'
1916         : $sql
1917       ,
1918       'DBD::' . $dbh->{Driver}{Name},
1919     )
1920   ) if !$sth;
1921
1922   $sth;
1923 }
1924
1925 sub _bind_sth_params {
1926   my ($self, $sth, $bind, $bind_attrs) = @_;
1927
1928   for my $i (0 .. $#$bind) {
1929     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1930       $sth->bind_param_inout(
1931         $i + 1, # bind params counts are 1-based
1932         $bind->[$i][1],
1933         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1934         $bind_attrs->[$i],
1935       );
1936     }
1937     else {
1938       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1939       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1940         ? "$bind->[$i][1]"
1941         : $bind->[$i][1]
1942       ;
1943
1944       $sth->bind_param(
1945         $i + 1,
1946         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1947         $v,
1948         $bind_attrs->[$i],
1949       );
1950     }
1951   }
1952
1953   $sth;
1954 }
1955
1956 sub _prefetch_autovalues {
1957   my ($self, $source, $colinfo, $to_insert) = @_;
1958
1959   my %values;
1960   for my $col (keys %$colinfo) {
1961     if (
1962       $colinfo->{$col}{auto_nextval}
1963         and
1964       (
1965         ! exists $to_insert->{$col}
1966           or
1967         is_literal_value($to_insert->{$col})
1968       )
1969     ) {
1970       $values{$col} = $self->_sequence_fetch(
1971         'NEXTVAL',
1972         ( $colinfo->{$col}{sequence} ||=
1973             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1974         ),
1975       );
1976     }
1977   }
1978
1979   \%values;
1980 }
1981
1982 sub insert {
1983   my ($self, $source, $to_insert) = @_;
1984
1985   my $col_infos = $source->columns_info;
1986
1987   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1988
1989   # fuse the values, but keep a separate list of prefetched_values so that
1990   # they can be fused once again with the final return
1991   $to_insert = { %$to_insert, %$prefetched_values };
1992
1993   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1994   # Investigate what does it take to s/defined/exists/
1995   my %pcols = map { $_ => 1 } $source->primary_columns;
1996   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1997   for my $col ($source->columns) {
1998     if ($col_infos->{$col}{is_auto_increment}) {
1999       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
2000       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
2001     }
2002
2003     # nothing to retrieve when explicit values are supplied
2004     next if (
2005       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
2006     );
2007
2008     # the 'scalar keys' is a trick to preserve the ->columns declaration order
2009     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
2010       $pcols{$col}
2011         or
2012       $col_infos->{$col}{retrieve_on_insert}
2013     );
2014   };
2015
2016   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
2017   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
2018
2019   my ($sqla_opts, @ir_container);
2020   if (%retrieve_cols and $self->_use_insert_returning) {
2021     $sqla_opts->{returning_container} = \@ir_container
2022       if $self->_use_insert_returning_bound;
2023
2024     $sqla_opts->{returning} = [
2025       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
2026     ];
2027   }
2028
2029   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2030
2031   my %returned_cols = %$to_insert;
2032   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2033
2034     unless( @ir_container ) {
2035       dbic_internal_try {
2036
2037         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2038         local $SIG{__WARN__} = sub {};
2039
2040         @ir_container = $sth->fetchrow_array;
2041         $sth->finish;
2042
2043       } catch {
2044         # Evict the $sth from the cache in case we got here, since the finish()
2045         # is crucial, at least on older Firebirds, possibly on other engines too
2046         #
2047         # It would be too complex to make this a proper subclass override,
2048         # and besides we already take the try{} penalty, adding a catch that
2049         # triggers infrequently is a no-brainer
2050         #
2051         if( my $kids = $self->_dbh->{CachedKids} ) {
2052           $kids->{$_} == $sth and delete $kids->{$_}
2053             for keys %$kids
2054         }
2055       };
2056     }
2057
2058     @returned_cols{@$retlist} = @ir_container if @ir_container;
2059   }
2060   else {
2061     # pull in PK if needed and then everything else
2062     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2063
2064       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2065         unless $self->can('last_insert_id');
2066
2067       my @pri_values = $self->last_insert_id($source, @missing_pri);
2068
2069       $self->throw_exception( "Can't get last insert id" )
2070         unless (@pri_values == @missing_pri);
2071
2072       @returned_cols{@missing_pri} = @pri_values;
2073       delete @retrieve_cols{@missing_pri};
2074     }
2075
2076     # if there is more left to pull
2077     if (%retrieve_cols) {
2078       $self->throw_exception(
2079         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2080       ) unless %pcols;
2081
2082       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2083
2084       my $cur = DBIx::Class::ResultSet->new($source, {
2085         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2086         select => \@left_to_fetch,
2087       })->cursor;
2088
2089       @returned_cols{@left_to_fetch} = $cur->next;
2090
2091       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2092         if scalar $cur->next;
2093     }
2094   }
2095
2096   return { %$prefetched_values, %returned_cols };
2097 }
2098
2099 sub insert_bulk {
2100   carp_unique(
2101     'insert_bulk() should have never been exposed as a public method and '
2102   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2103   . 'use for this method please contact the development team via '
2104   . DBIx::Class::_ENV_::HELP_URL
2105   );
2106
2107   return '0E0' unless @{$_[3]||[]};
2108
2109   shift->_insert_bulk(@_);
2110 }
2111
2112 sub _insert_bulk {
2113   my ($self, $source, $cols, $data) = @_;
2114
2115   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2116     unless @{$data||[]};
2117
2118   my $colinfos = $source->columns_info($cols);
2119
2120   local $self->{_autoinc_supplied_for_op} =
2121     (grep { $_->{is_auto_increment} } values %$colinfos)
2122       ? 1
2123       : 0
2124   ;
2125
2126   # get a slice type index based on first row of data
2127   # a "column" in this context may refer to more than one bind value
2128   # e.g. \[ '?, ?', [...], [...] ]
2129   #
2130   # construct the value type index - a description of values types for every
2131   # per-column slice of $data:
2132   #
2133   # nonexistent - nonbind literal
2134   # 0 - regular value
2135   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2136   #
2137   # also construct the column hash to pass to the SQL generator. For plain
2138   # (non literal) values - convert the members of the first row into a
2139   # literal+bind combo, with extra positional info in the bind attr hashref.
2140   # This will allow us to match the order properly, and is so contrived
2141   # because a user-supplied literal/bind (or something else specific to a
2142   # resultsource and/or storage driver) can inject extra binds along the
2143   # way, so one can't rely on "shift positions" ordering at all. Also we
2144   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2145   # can be later matched up by address), because we want to supply a real
2146   # value on which perhaps e.g. datatype checks will be performed
2147   my ($proto_data, $serialized_bind_type_by_col_idx);
2148   for my $col_idx (0..$#$cols) {
2149     my $colname = $cols->[$col_idx];
2150     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2151       # no bind value at all - no type
2152
2153       $proto_data->{$colname} = $data->[0][$col_idx];
2154     }
2155     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2156       # repack, so we don't end up mangling the original \[]
2157       my ($sql, @bind) = @${$data->[0][$col_idx]};
2158
2159       # normalization of user supplied stuff
2160       my $resolved_bind = $self->_resolve_bindattrs(
2161         $source, \@bind, $colinfos,
2162       );
2163
2164       # store value-less (attrs only) bind info - we will be comparing all
2165       # supplied binds against this for sanity
2166       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2167
2168       $proto_data->{$colname} = \[ $sql, map { [
2169         # inject slice order to use for $proto_bind construction
2170           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2171             =>
2172           $resolved_bind->[$_][1]
2173         ] } (0 .. $#bind)
2174       ];
2175     }
2176     else {
2177       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2178
2179       $proto_data->{$colname} = \[ '?', [
2180         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2181           =>
2182         $data->[0][$col_idx]
2183       ] ];
2184     }
2185   }
2186
2187   my ($sql, $proto_bind) = $self->_prep_for_execute (
2188     'insert',
2189     $source,
2190     [ $proto_data ],
2191   );
2192
2193   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2194     # if the bindlist is empty and we had some dynamic binds, this means the
2195     # storage ate them away (e.g. the NoBindVars component) and interpolated
2196     # them directly into the SQL. This obviously can't be good for multi-inserts
2197     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2198   }
2199
2200   # sanity checks
2201   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2202   #
2203   # use an error reporting closure for convenience (less to pass)
2204   my $bad_slice_report_cref = sub {
2205     my ($msg, $r_idx, $c_idx) = @_;
2206     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2207       $msg,
2208       $cols->[$c_idx],
2209       do {
2210         local $Data::Dumper::Maxdepth = 5;
2211         dump_value {
2212           map { $cols->[$_] =>
2213             $data->[$r_idx][$_]
2214           } 0..$#$cols
2215         };
2216       }
2217     );
2218   };
2219
2220   for my $col_idx (0..$#$cols) {
2221     my $reference_val = $data->[0][$col_idx];
2222
2223     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2224       my $val = $data->[$row_idx][$col_idx];
2225
2226       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2227         if (ref $val ne 'SCALAR') {
2228           $bad_slice_report_cref->(
2229             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2230             $row_idx,
2231             $col_idx,
2232           );
2233         }
2234         elsif ($$val ne $$reference_val) {
2235           $bad_slice_report_cref->(
2236             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2237             $row_idx,
2238             $col_idx,
2239           );
2240         }
2241       }
2242       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2243         if (is_literal_value($val)) {
2244           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2245         }
2246       }
2247       else {  # binds from a \[], compare type and attrs
2248         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2249           $bad_slice_report_cref->(
2250             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2251             $row_idx,
2252             $col_idx,
2253           );
2254         }
2255         # start drilling down and bail out early on identical refs
2256         elsif (
2257           $reference_val != $val
2258             or
2259           $$reference_val != $$val
2260         ) {
2261           if (${$val}->[0] ne ${$reference_val}->[0]) {
2262             $bad_slice_report_cref->(
2263               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2264               $row_idx,
2265               $col_idx,
2266             );
2267           }
2268           # need to check the bind attrs - a bind will happen only once for
2269           # the entire dataset, so any changes further down will be ignored.
2270           elsif (
2271             $serialized_bind_type_by_col_idx->{$col_idx}
2272               ne
2273             serialize [
2274               map
2275               { $_->[0] }
2276               @{$self->_resolve_bindattrs(
2277                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2278               )}
2279             ]
2280           ) {
2281             $bad_slice_report_cref->(
2282               'Differing bind attributes on literal/bind values not supported',
2283               $row_idx,
2284               $col_idx,
2285             );
2286           }
2287         }
2288       }
2289     }
2290   }
2291
2292   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2293   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2294   # scope guard
2295   my $guard = $self->txn_scope_guard;
2296
2297   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2298   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2299   my $rv = do {
2300     if (@$proto_bind) {
2301       # proto bind contains the information on which pieces of $data to pull
2302       # $cols is passed in only for prettier error-reporting
2303       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2304     }
2305     else {
2306       # bind_param_array doesn't work if there are no binds
2307       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2308     }
2309   };
2310
2311   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2312
2313   $guard->commit;
2314
2315   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2316 }
2317
2318 # execute_for_fetch is capable of returning data just fine (it means it
2319 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2320 # is the void-populate fast-path we will just ignore this altogether
2321 # for the time being.
2322 sub _dbh_execute_for_fetch {
2323   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2324
2325   # If we have any bind attributes to take care of, we will bind the
2326   # proto-bind data (which will never be used by execute_for_fetch)
2327   # However since column bindtypes are "sticky", this is sufficient
2328   # to get the DBD to apply the bindtype to all values later on
2329   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2330
2331   for my $i (0 .. $#$proto_bind) {
2332     $sth->bind_param (
2333       $i+1, # DBI bind indexes are 1-based
2334       $proto_bind->[$i][1],
2335       $bind_attrs->[$i],
2336     ) if defined $bind_attrs->[$i];
2337   }
2338
2339   # At this point $data slots named in the _bind_data_slice_idx of
2340   # each piece of $proto_bind are either \[]s or plain values to be
2341   # passed in. Construct the dispensing coderef. *NOTE* the order
2342   # of $data will differ from this of the ?s in the SQL (due to
2343   # alphabetical ordering by colname). We actually do want to
2344   # preserve this behavior so that prepare_cached has a better
2345   # chance of matching on unrelated calls
2346
2347   my $fetch_row_idx = -1; # saner loop this way
2348   my $fetch_tuple = sub {
2349     return undef if ++$fetch_row_idx > $#$data;
2350
2351     return [ map {
2352       my $v = ! defined $_->{_literal_bind_subindex}
2353
2354         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2355
2356         # There are no attributes to resolve here - we already did everything
2357         # when we constructed proto_bind. However we still want to sanity-check
2358         # what the user supplied, so pass stuff through to the resolver *anyway*
2359         : $self->_resolve_bindattrs (
2360             undef,  # a fake rsrc
2361             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2362             {},     # a fake column_info bag
2363           )->[0][1]
2364       ;
2365
2366       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2367       # For the time being forcibly stringify whatever is stringifiable
2368       my $vref;
2369
2370       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2371     : defined blessed( $$vref )                             ? "$$vref"
2372                                                             : $$vref
2373     ;
2374     } map { $_->[0] } @$proto_bind ];
2375   };
2376
2377   my $tuple_status = [];
2378   my ($rv, $err);
2379   dbic_internal_try {
2380     $rv = $sth->execute_for_fetch(
2381       $fetch_tuple,
2382       $tuple_status,
2383     );
2384   }
2385   catch {
2386     $err = shift;
2387   };
2388
2389   # Not all DBDs are create equal. Some throw on error, some return
2390   # an undef $rv, and some set $sth->err - try whatever we can
2391   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2392     ! defined $err
2393       and
2394     ( !defined $rv or $sth->err )
2395   );
2396
2397   # Statement must finish even if there was an exception.
2398   dbic_internal_try {
2399     $sth->finish
2400   }
2401   catch {
2402     $err = shift unless defined $err
2403   };
2404
2405   if (defined $err) {
2406     my $i = 0;
2407     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2408
2409     $self->throw_exception("Unexpected populate error: $err")
2410       if ($i > $#$tuple_status);
2411
2412     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2413       ($tuple_status->[$i][1] || $err),
2414       dump_value { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) },
2415     );
2416   }
2417
2418   return $rv;
2419 }
2420
2421 sub _dbh_execute_inserts_with_no_binds {
2422   my ($self, $sth, $count) = @_;
2423
2424   my $err;
2425   dbic_internal_try {
2426     my $dbh = $self->_get_dbh;
2427     local $dbh->{RaiseError} = 1;
2428     local $dbh->{PrintError} = 0;
2429
2430     $sth->execute foreach 1..$count;
2431   }
2432   catch {
2433     $err = shift;
2434   };
2435
2436   # Make sure statement is finished even if there was an exception.
2437   dbic_internal_try {
2438     $sth->finish
2439   }
2440   catch {
2441     $err = shift unless defined $err;
2442   };
2443
2444   $self->throw_exception($err) if defined $err;
2445
2446   return $count;
2447 }
2448
2449 sub update {
2450   #my ($self, $source, @args) = @_;
2451   shift->_execute('update', @_);
2452 }
2453
2454
2455 sub delete {
2456   #my ($self, $source, @args) = @_;
2457   shift->_execute('delete', @_);
2458 }
2459
2460 sub _select {
2461   my $self = shift;
2462   $self->_execute($self->_select_args(@_));
2463 }
2464
2465 sub _select_args_to_query {
2466   my $self = shift;
2467
2468   $self->throw_exception(
2469     "Unable to generate limited query representation with 'software_limit' enabled"
2470   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2471
2472   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2473   #  = $self->_select_args($ident, $select, $cond, $attrs);
2474   my ($op, $ident, @args) =
2475     $self->_select_args(@_);
2476
2477   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2478   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2479
2480   # reuse the bind arrayref
2481   unshift @{$bind}, "($sql)";
2482   \$bind;
2483 }
2484
2485 sub _select_args {
2486   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2487
2488   # FIXME - that kind of caching would be nice to have
2489   # however currently we *may* pass the same $orig_attrs
2490   # with different ident/select/where
2491   # the whole interface needs to be rethought, since it
2492   # was centered around the flawed SQLA API. We can do
2493   # soooooo much better now. But that is also another
2494   # battle...
2495   #return (
2496   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2497   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2498
2499   my $sql_maker = $self->sql_maker;
2500
2501   my $attrs = {
2502     %$orig_attrs,
2503     select => $select,
2504     from => $ident,
2505     where => $where,
2506   };
2507
2508   # MySQL actually recommends this approach.  I cringe.
2509   $attrs->{rows} ||= $sql_maker->__max_int
2510     if $attrs->{offset};
2511
2512   # see if we will need to tear the prefetch apart to satisfy group_by == select
2513   # this is *extremely tricky* to get right, I am still not sure I did
2514   #
2515   my ($prefetch_needs_subquery, @limit_args);
2516
2517   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2518     # we already know there is a valid group_by (we made it) and we know it is
2519     # intended to be based *only* on non-multi stuff
2520     # short circuit the group_by parsing below
2521     $prefetch_needs_subquery = 1;
2522   }
2523   elsif (
2524     # The rationale is that even if we do *not* have collapse, we still
2525     # need to wrap the core grouped select/group_by in a subquery
2526     # so that databases that care about group_by/select equivalence
2527     # are happy (this includes MySQL in strict_mode)
2528     # If any of the other joined tables are referenced in the group_by
2529     # however - the user is on their own
2530     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2531       and
2532     $attrs->{group_by}
2533       and
2534     @{$attrs->{group_by}}
2535       and
2536     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2537       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2538     }
2539   ) {
2540     # no aliases other than our own in group_by
2541     # if there are - do not allow subquery even if limit is present
2542     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2543   }
2544   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2545     # active collapse with a limit - that one is a no-brainer unless
2546     # overruled by a group_by above
2547     $prefetch_needs_subquery = 1;
2548   }
2549
2550   if ($prefetch_needs_subquery) {
2551     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2552   }
2553   elsif (! $attrs->{software_limit} ) {
2554     push @limit_args, (
2555       $attrs->{rows} || (),
2556       $attrs->{offset} || (),
2557     );
2558   }
2559
2560   # try to simplify the joinmap further (prune unreferenced type-single joins)
2561   if (
2562     ! $prefetch_needs_subquery  # already pruned
2563       and
2564     ref $attrs->{from}
2565       and
2566     reftype $attrs->{from} eq 'ARRAY'
2567       and
2568     @{$attrs->{from}} != 1
2569   ) {
2570     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2571   }
2572
2573   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2574   # during the result inflation stage we *need* to know what was the aliastype
2575   # map as sqla saw it when the final pieces of SQL were being assembled
2576   # Originally we simply carried around the entirety of $attrs, but this
2577   # resulted in resultsets that are being reused growing continuously, as
2578   # the hash in question grew deeper and deeper.
2579   # Instead hand-pick what to take with us here (we actually don't need much
2580   # at this point just the map itself)
2581   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2582
2583 ###
2584   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2585   #
2586   # This would be the point to deflate anything found in $attrs->{where}
2587   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2588   # expect a result object. And all we have is a resultsource (it is trivial
2589   # to extract deflator coderefs via $alias2source above).
2590   #
2591   # I don't see a way forward other than changing the way deflators are
2592   # invoked, and that's just bad...
2593 ###
2594
2595   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2596 }
2597
2598 # Returns a counting SELECT for a simple count
2599 # query. Abstracted so that a storage could override
2600 # this to { count => 'firstcol' } or whatever makes
2601 # sense as a performance optimization
2602 sub _count_select {
2603   #my ($self, $source, $rs_attrs) = @_;
2604   return { count => '*' };
2605 }
2606
2607 =head2 select
2608
2609 =over 4
2610
2611 =item Arguments: $ident, $select, $condition, $attrs
2612
2613 =back
2614
2615 Handle a SQL select statement.
2616
2617 =cut
2618
2619 sub select {
2620   my $self = shift;
2621   my ($ident, $select, $condition, $attrs) = @_;
2622   return $self->cursor_class->new($self, \@_, $attrs);
2623 }
2624
2625 sub select_single {
2626   my $self = shift;
2627   my ($rv, $sth, @bind) = $self->_select(@_);
2628   my @row = $sth->fetchrow_array;
2629   my @nextrow = $sth->fetchrow_array if @row;
2630   if(@row && @nextrow) {
2631     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2632   }
2633   # Need to call finish() to work round broken DBDs
2634   $sth->finish();
2635   return @row;
2636 }
2637
2638 =head2 sql_limit_dialect
2639
2640 This is an accessor for the default SQL limit dialect used by a particular
2641 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2642 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2643 see L<DBIx::Class::SQLMaker::LimitDialects>.
2644
2645 =cut
2646
2647 sub _dbh_columns_info_for {
2648   my ($self, $dbh, $table) = @_;
2649
2650   my %result;
2651
2652   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2653     dbic_internal_try {
2654       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2655       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2656       $sth->execute();
2657       while ( my $info = $sth->fetchrow_hashref() ){
2658         my %column_info;
2659         $column_info{data_type}   = $info->{TYPE_NAME};
2660         $column_info{size}      = $info->{COLUMN_SIZE};
2661         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2662         $column_info{default_value} = $info->{COLUMN_DEF};
2663         my $col_name = $info->{COLUMN_NAME};
2664         $col_name =~ s/^\"(.*)\"$/$1/;
2665
2666         $result{$col_name} = \%column_info;
2667       }
2668     } catch {
2669       %result = ();
2670     };
2671
2672     return \%result if keys %result;
2673   }
2674
2675   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2676   $sth->execute;
2677
2678 ### The acrobatics with lc names is necessary to support both the legacy
2679 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2680 ### with column names differing in cas eonly (thanks pg!)
2681
2682   my ($columns, $seen_lcs);
2683
2684   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2685     idx => scalar keys %$columns,
2686     name => $_,
2687     lc_name => lc($_),
2688   } for @{$sth->{NAME}};
2689
2690   $seen_lcs->{$_->{lc_name}} == 1
2691     and
2692   $_->{name} = $_->{lc_name}
2693     for values %$columns;
2694
2695   for ( values %$columns ) {
2696     my $inf = {
2697       data_type => $sth->{TYPE}->[$_->{idx}],
2698       size => $sth->{PRECISION}->[$_->{idx}],
2699       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2700     };
2701
2702     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2703       @{$inf}{qw( data_type  size)} = ($1, $2);
2704     }
2705
2706     $result{$_->{name}} = $inf;
2707   }
2708
2709   $sth->finish;
2710
2711   if ($dbh->can('type_info')) {
2712     for my $inf (values %result) {
2713       next if ! defined $inf->{data_type};
2714
2715       $inf->{data_type} = (
2716         (
2717           (
2718             $dbh->type_info( $inf->{data_type} )
2719               ||
2720             next
2721           )
2722             ||
2723           next
2724         )->{TYPE_NAME}
2725           ||
2726         next
2727       );
2728
2729       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2730       # needs more testing in the future...
2731       $inf->{size} -= 4 if (
2732         ( $inf->{size}||0 > 4 )
2733           and
2734         $inf->{data_type} =~ qr/^text$/i
2735       );
2736     }
2737
2738   }
2739
2740   return \%result;
2741 }
2742
2743 sub columns_info_for {
2744   my ($self, $table) = @_;
2745   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2746 }
2747
2748 =head2 last_insert_id
2749
2750 Return the row id of the last insert.
2751
2752 =cut
2753
2754 sub _dbh_last_insert_id {
2755     my ($self, $dbh, $source, $col) = @_;
2756
2757     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2758
2759     return $id if defined $id;
2760
2761     my $class = ref $self;
2762     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2763 }
2764
2765 sub last_insert_id {
2766   my $self = shift;
2767   $self->_dbh_last_insert_id ($self->_dbh, @_);
2768 }
2769
2770 =head2 _native_data_type
2771
2772 =over 4
2773
2774 =item Arguments: $type_name
2775
2776 =back
2777
2778 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2779 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2780 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2781
2782 The default implementation returns C<undef>, implement in your Storage driver if
2783 you need this functionality.
2784
2785 Should map types from other databases to the native RDBMS type, for example
2786 C<VARCHAR2> to C<VARCHAR>.
2787
2788 Types with modifiers should map to the underlying data type. For example,
2789 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2790
2791 Composite types should map to the container type, for example
2792 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2793
2794 =cut
2795
2796 sub _native_data_type {
2797   #my ($self, $data_type) = @_;
2798   return undef
2799 }
2800
2801 # Check if placeholders are supported at all
2802 sub _determine_supports_placeholders {
2803   my $self = shift;
2804   my $dbh  = $self->_get_dbh;
2805
2806   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2807   # but it is inaccurate more often than not
2808   ( dbic_internal_try {
2809     local $dbh->{PrintError} = 0;
2810     local $dbh->{RaiseError} = 1;
2811     $dbh->do('select ?', {}, 1);
2812     1;
2813   } )
2814     ? 1
2815     : 0
2816   ;
2817 }
2818
2819 # Check if placeholders bound to non-string types throw exceptions
2820 #
2821 sub _determine_supports_typeless_placeholders {
2822   my $self = shift;
2823   my $dbh  = $self->_get_dbh;
2824
2825   ( dbic_internal_try {
2826     local $dbh->{PrintError} = 0;
2827     local $dbh->{RaiseError} = 1;
2828     # this specifically tests a bind that is NOT a string
2829     $dbh->do('select 1 where 1 = ?', {}, 1);
2830     1;
2831   } )
2832     ? 1
2833     : 0
2834   ;
2835 }
2836
2837 =head2 sqlt_type
2838
2839 Returns the database driver name.
2840
2841 =cut
2842
2843 sub sqlt_type {
2844   shift->_get_dbh->{Driver}->{Name};
2845 }
2846
2847 =head2 bind_attribute_by_data_type
2848
2849 Given a datatype from column info, returns a database specific bind
2850 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2851 let the database planner just handle it.
2852
2853 This method is always called after the driver has been determined and a DBI
2854 connection has been established. Therefore you can refer to C<DBI::$constant>
2855 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2856 the correct modules.
2857
2858 =cut
2859
2860 sub bind_attribute_by_data_type {
2861     return;
2862 }
2863
2864 =head2 is_datatype_numeric
2865
2866 Given a datatype from column_info, returns a boolean value indicating if
2867 the current RDBMS considers it a numeric value. This controls how
2868 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2869 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2870 be performed instead of the usual C<eq>.
2871
2872 =cut
2873
2874 sub is_datatype_numeric {
2875   #my ($self, $dt) = @_;
2876
2877   return 0 unless $_[1];
2878
2879   $_[1] =~ /^ (?:
2880     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2881   ) $/ix;
2882 }
2883
2884
2885 =head2 create_ddl_dir
2886
2887 =over 4
2888
2889 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2890
2891 =back
2892
2893 Creates a SQL file based on the Schema, for each of the specified
2894 database engines in C<\@databases> in the given directory.
2895 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2896
2897 Given a previous version number, this will also create a file containing
2898 the ALTER TABLE statements to transform the previous schema into the
2899 current one. Note that these statements may contain C<DROP TABLE> or
2900 C<DROP COLUMN> statements that can potentially destroy data.
2901
2902 The file names are created using the C<ddl_filename> method below, please
2903 override this method in your schema if you would like a different file
2904 name format. For the ALTER file, the same format is used, replacing
2905 $version in the name with "$preversion-$version".
2906
2907 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2908 The most common value for this would be C<< { add_drop_table => 1 } >>
2909 to have the SQL produced include a C<DROP TABLE> statement for each table
2910 created. For quoting purposes supply C<quote_identifiers>.
2911
2912 If no arguments are passed, then the following default values are assumed:
2913
2914 =over 4
2915
2916 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2917
2918 =item version    - $schema->schema_version
2919
2920 =item directory  - './'
2921
2922 =item preversion - <none>
2923
2924 =back
2925
2926 By default, C<\%sqlt_args> will have
2927
2928  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2929
2930 merged with the hash passed in. To disable any of those features, pass in a
2931 hashref like the following
2932
2933  { ignore_constraint_names => 0, # ... other options }
2934
2935
2936 WARNING: You are strongly advised to check all SQL files created, before applying
2937 them.
2938
2939 =cut
2940
2941 sub create_ddl_dir {
2942   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2943
2944   require DBIx::Class::Optional::Dependencies;
2945   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2946     $self->throw_exception("Can't create a ddl file without $missing");
2947   }
2948
2949   if (!$dir) {
2950     carp "No directory given, using ./\n";
2951     $dir = './';
2952   }
2953   else {
2954     mkdir_p( $dir ) unless -d $dir;
2955   }
2956
2957   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2958   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2959
2960   my $schema_version = $schema->schema_version || '1.x';
2961   $version ||= $schema_version;
2962
2963   $sqltargs = {
2964     add_drop_table => 1,
2965     ignore_constraint_names => 1,
2966     ignore_index_names => 1,
2967     quote_identifiers => $self->sql_maker->_quoting_enabled,
2968     %{$sqltargs || {}}
2969   };
2970
2971   my $sqlt = SQL::Translator->new( $sqltargs );
2972
2973   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2974   my $sqlt_schema = $sqlt->translate({ data => $schema })
2975     or $self->throw_exception ($sqlt->error);
2976
2977   foreach my $db (@$databases) {
2978     $sqlt->reset();
2979     $sqlt->{schema} = $sqlt_schema;
2980     $sqlt->producer($db);
2981
2982     my $file;
2983     my $filename = $schema->ddl_filename($db, $version, $dir);
2984     if (-e $filename && ($version eq $schema_version )) {
2985       # if we are dumping the current version, overwrite the DDL
2986       carp "Overwriting existing DDL file - $filename";
2987       unlink($filename);
2988     }
2989
2990     my $output = $sqlt->translate;
2991     if(!$output) {
2992       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2993       next;
2994     }
2995     if(!open($file, ">$filename")) {
2996       $self->throw_exception("Can't open $filename for writing ($!)");
2997       next;
2998     }
2999     print $file $output;
3000     close($file);
3001
3002     next unless ($preversion);
3003
3004     require SQL::Translator::Diff;
3005
3006     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
3007     if(!-e $prefilename) {
3008       carp("No previous schema file found ($prefilename)");
3009       next;
3010     }
3011
3012     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
3013     if(-e $difffile) {
3014       carp("Overwriting existing diff file - $difffile");
3015       unlink($difffile);
3016     }
3017
3018     my $source_schema;
3019     {
3020       my $t = SQL::Translator->new($sqltargs);
3021       $t->debug( 0 );
3022       $t->trace( 0 );
3023
3024       $t->parser( $db )
3025         or $self->throw_exception ($t->error);
3026
3027       my $out = $t->translate( $prefilename )
3028         or $self->throw_exception ($t->error);
3029
3030       $source_schema = $t->schema;
3031
3032       $source_schema->name( $prefilename )
3033         unless ( $source_schema->name );
3034     }
3035
3036     # The "new" style of producers have sane normalization and can support
3037     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3038     # And we have to diff parsed SQL against parsed SQL.
3039     my $dest_schema = $sqlt_schema;
3040
3041     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3042       my $t = SQL::Translator->new($sqltargs);
3043       $t->debug( 0 );
3044       $t->trace( 0 );
3045
3046       $t->parser( $db )
3047         or $self->throw_exception ($t->error);
3048
3049       my $out = $t->translate( $filename )
3050         or $self->throw_exception ($t->error);
3051
3052       $dest_schema = $t->schema;
3053
3054       $dest_schema->name( $filename )
3055         unless $dest_schema->name;
3056     }
3057
3058     my $diff = do {
3059       # FIXME - this is a terrible workaround for
3060       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3061       # Fixing it in this sloppy manner so that we don't hve to
3062       # lockstep an SQLT release as well. Needs to be removed at
3063       # some point, and SQLT dep bumped
3064       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3065         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3066
3067       SQL::Translator::Diff::schema_diff($source_schema, $db,
3068                                          $dest_schema,   $db,
3069                                          $sqltargs
3070                                        );
3071     };
3072
3073     if(!open $file, ">$difffile") {
3074       $self->throw_exception("Can't write to $difffile ($!)");
3075       next;
3076     }
3077     print $file $diff;
3078     close($file);
3079   }
3080 }
3081
3082 =head2 deployment_statements
3083
3084 =over 4
3085
3086 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3087
3088 =back
3089
3090 Returns the statements used by L<DBIx::Class::Storage/deploy>
3091 and L<DBIx::Class::Schema/deploy>.
3092
3093 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3094 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3095
3096 C<$directory> is used to return statements from files in a previously created
3097 L</create_ddl_dir> directory and is optional. The filenames are constructed
3098 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3099
3100 If no C<$directory> is specified then the statements are constructed on the
3101 fly using L<SQL::Translator> and C<$version> is ignored.
3102
3103 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3104
3105 =cut
3106
3107 sub deployment_statements {
3108   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3109   $type ||= $self->sqlt_type;
3110   $version ||= $schema->schema_version || '1.x';
3111   $dir ||= './';
3112   my $filename = $schema->ddl_filename($type, $version, $dir);
3113   if(-f $filename)
3114   {
3115       # FIXME replace this block when a proper sane sql parser is available
3116       my $file;
3117       open($file, "<$filename")
3118         or $self->throw_exception("Can't open $filename ($!)");
3119       my @rows = <$file>;
3120       close($file);
3121       return join('', @rows);
3122   }
3123
3124   require DBIx::Class::Optional::Dependencies;
3125   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3126     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3127   }
3128
3129   # sources needs to be a parser arg, but for simplicity allow at top level
3130   # coming in
3131   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3132       if exists $sqltargs->{sources};
3133
3134   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3135     unless exists $sqltargs->{quote_identifiers};
3136
3137   my $tr = SQL::Translator->new(
3138     producer => "SQL::Translator::Producer::${type}",
3139     %$sqltargs,
3140     parser => 'SQL::Translator::Parser::DBIx::Class',
3141     data => $schema,
3142   );
3143
3144   return preserve_context {
3145     $tr->translate
3146   } after => sub {
3147     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3148       unless defined $_[0];
3149   };
3150 }
3151
3152 # FIXME deploy() currently does not accurately report sql errors
3153 # Will always return true while errors are warned
3154 sub deploy {
3155   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3156   my $deploy = sub {
3157     my $line = shift;
3158     return if(!$line);
3159     return if($line =~ /^--/);
3160     # next if($line =~ /^DROP/m);
3161     return if($line =~ /^BEGIN TRANSACTION/m);
3162     return if($line =~ /^COMMIT/m);
3163     return if $line =~ /^\s+$/; # skip whitespace only
3164     $self->_query_start($line);
3165     dbic_internal_try {
3166       # do a dbh_do cycle here, as we need some error checking in
3167       # place (even though we will ignore errors)
3168       $self->dbh_do (sub { $_[1]->do($line) });
3169     } catch {
3170       carp qq{$_ (running "${line}")};
3171     };
3172     $self->_query_end($line);
3173   };
3174   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3175   if (@statements > 1) {
3176     foreach my $statement (@statements) {
3177       $deploy->( $statement );
3178     }
3179   }
3180   elsif (@statements == 1) {
3181     # split on single line comments and end of statements
3182     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3183       $deploy->( $line );
3184     }
3185   }
3186 }
3187
3188 =head2 datetime_parser
3189
3190 Returns the datetime parser class
3191
3192 =cut
3193
3194 sub datetime_parser {
3195   my $self = shift;
3196   return $self->{datetime_parser} ||= do {
3197     $self->build_datetime_parser(@_);
3198   };
3199 }
3200
3201 =head2 datetime_parser_type
3202
3203 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3204
3205 =head2 build_datetime_parser
3206
3207 See L</datetime_parser>
3208
3209 =cut
3210
3211 sub build_datetime_parser {
3212   my $self = shift;
3213   my $type = $self->datetime_parser_type(@_);
3214   return $type;
3215 }
3216
3217
3218 =head2 is_replicating
3219
3220 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3221 replicate from a master database.  Default is undef, which is the result
3222 returned by databases that don't support replication.
3223
3224 =cut
3225
3226 sub is_replicating {
3227     return;
3228
3229 }
3230
3231 =head2 lag_behind_master
3232
3233 Returns a number that represents a certain amount of lag behind a master db
3234 when a given storage is replicating.  The number is database dependent, but
3235 starts at zero and increases with the amount of lag. Default in undef
3236
3237 =cut
3238
3239 sub lag_behind_master {
3240     return;
3241 }
3242
3243 =head2 relname_to_table_alias
3244
3245 =over 4
3246
3247 =item Arguments: $relname, $join_count
3248
3249 =item Return Value: $alias
3250
3251 =back
3252
3253 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3254 queries.
3255
3256 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3257 way these aliases are named.
3258
3259 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3260 otherwise C<"$relname">.
3261
3262 =cut
3263
3264 sub relname_to_table_alias {
3265   my ($self, $relname, $join_count) = @_;
3266
3267   my $alias = ($join_count && $join_count > 1 ?
3268     join('_', $relname, $join_count) : $relname);
3269
3270   return $alias;
3271 }
3272
3273 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3274 # version and it may be necessary to amend or override it for a specific storage
3275 # if such binds are necessary.
3276 sub _max_column_bytesize {
3277   my ($self, $attr) = @_;
3278
3279   my $max_size;
3280
3281   if ($attr->{sqlt_datatype}) {
3282     my $data_type = lc($attr->{sqlt_datatype});
3283
3284     if ($attr->{sqlt_size}) {
3285
3286       # String/sized-binary types
3287       if ($data_type =~ /^(?:
3288           l? (?:var)? char(?:acter)? (?:\s*varying)?
3289             |
3290           (?:var)? binary (?:\s*varying)?
3291             |
3292           raw
3293         )\b/x
3294       ) {
3295         $max_size = $attr->{sqlt_size};
3296       }
3297       # Other charset/unicode types, assume scale of 4
3298       elsif ($data_type =~ /^(?:
3299           national \s* character (?:\s*varying)?
3300             |
3301           nchar
3302             |
3303           univarchar
3304             |
3305           nvarchar
3306         )\b/x
3307       ) {
3308         $max_size = $attr->{sqlt_size} * 4;
3309       }
3310     }
3311
3312     if (!$max_size and !$self->_is_lob_type($data_type)) {
3313       $max_size = 100 # for all other (numeric?) datatypes
3314     }
3315   }
3316
3317   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3318 }
3319
3320 # Determine if a data_type is some type of BLOB
3321 sub _is_lob_type {
3322   my ($self, $data_type) = @_;
3323   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3324     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3325                                   |varchar|character\s*varying|nvarchar
3326                                   |national\s*character\s*varying))?\z/xi);
3327 }
3328
3329 sub _is_binary_lob_type {
3330   my ($self, $data_type) = @_;
3331   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3332     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3333 }
3334
3335 sub _is_text_lob_type {
3336   my ($self, $data_type) = @_;
3337   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3338     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3339                         |national\s*character\s*varying))\z/xi);
3340 }
3341
3342 # Determine if a data_type is some type of a binary type
3343 sub _is_binary_type {
3344   my ($self, $data_type) = @_;
3345   $data_type && ($self->_is_binary_lob_type($data_type)
3346     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3347 }
3348
3349 1;
3350
3351 =head1 USAGE NOTES
3352
3353 =head2 DBIx::Class and AutoCommit
3354
3355 DBIx::Class can do some wonderful magic with handling exceptions,
3356 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3357 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3358 transaction support.
3359
3360 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3361 in an assumed transaction between commits, and you're telling us you'd
3362 like to manage that manually.  A lot of the magic protections offered by
3363 this module will go away.  We can't protect you from exceptions due to database
3364 disconnects because we don't know anything about how to restart your
3365 transactions.  You're on your own for handling all sorts of exceptional
3366 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3367 be with raw DBI.
3368
3369 =head1 FURTHER QUESTIONS?
3370
3371 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3372
3373 =head1 COPYRIGHT AND LICENSE
3374
3375 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3376 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3377 redistribute it and/or modify it under the same terms as the
3378 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.