lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Context::Preserve 'preserve_context';
  16 use Try::Tiny;
  17 use overload ();
  18 use Data::Compare (); # no imports!!! guard against insane architecture
  19 use DBI::Const::GetInfoType (); # no import of retarded global hash
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. This is a purely DRY optimization
  85 #
  86 # get_(use)_dbms_capability need to be called on the correct Storage
  87 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  88 # _determine_supports_X which obv. needs a correct driver as well
  89 my @rdbms_specific_methods = qw/
  90   deployment_statements
  91   sqlt_type
  92   sql_maker
  93   build_datetime_parser
  94   datetime_parser_type
  95
  96   txn_begin
  97   insert
  98   insert_bulk
  99   update
 100   delete
 101   select
 102   select_single
 103   with_deferred_fk_checks
 104
 105   get_use_dbms_capability
 106   get_dbms_capability
 107
 108   _server_info
 109   _get_server_version
 110 /;
 111
 112 for my $meth (@rdbms_specific_methods) {
 113
 114   my $orig = __PACKAGE__->can ($meth)
 115     or die "$meth is not a ::Storage::DBI method!";
 116
 117   no strict qw/refs/;
 118   no warnings qw/redefine/;
 119   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 120     if (
 121       # only fire when invoked on an instance, a valid class-based invocation
 122       # would e.g. be setting a default for an inherited accessor
 123       ref $_[0]
 124         and
 125       ! $_[0]->_driver_determined
 126         and
 127       ! $_[0]->{_in_determine_driver}
 128     ) {
 129       $_[0]->_determine_driver;
 130
 131       # This for some reason crashes and burns on perl 5.8.1
 132       # IFF the method ends up throwing an exception
 133       #goto $_[0]->can ($meth);
 134
 135       my $cref = $_[0]->can ($meth);
 136       goto $cref;
 137     }
 138
 139     goto $orig;
 140   };
 141 }
 142
 143 =head1 NAME
 144
 145 DBIx::Class::Storage::DBI - DBI storage handler
 146
 147 =head1 SYNOPSIS
 148
 149   my $schema = MySchema->connect('dbi:SQLite:my.db');
 150
 151   $schema->storage->debug(1);
 152
 153   my @stuff = $schema->storage->dbh_do(
 154     sub {
 155       my ($storage, $dbh, @args) = @_;
 156       $dbh->do("DROP TABLE authors");
 157     },
 158     @column_list
 159   );
 160
 161   $schema->resultset('Book')->search({
 162      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 163   });
 164
 165 =head1 DESCRIPTION
 166
 167 This class represents the connection to an RDBMS via L<DBI>.  See
 168 L<DBIx::Class::Storage> for general information.  This pod only
 169 documents DBI-specific methods and behaviors.
 170
 171 =head1 METHODS
 172
 173 =cut
 174
 175 sub new {
 176   my $new = shift->next::method(@_);
 177
 178   $new->_sql_maker_opts({});
 179   $new->_dbh_details({});
 180   $new->{_in_do_block} = 0;
 181   $new->{_dbh_gen} = 0;
 182
 183   # read below to see what this does
 184   $new->_arm_global_destructor;
 185
 186   $new;
 187 }
 188
 189 # This is hack to work around perl shooting stuff in random
 190 # order on exit(). If we do not walk the remaining storage
 191 # objects in an END block, there is a *small but real* chance
 192 # of a fork()ed child to kill the parent's shared DBI handle,
 193 # *before perl reaches the DESTROY in this package*
 194 # Yes, it is ugly and effective.
 195 # Additionally this registry is used by the CLONE method to
 196 # make sure no handles are shared between threads
 197 {
 198   my %seek_and_destroy;
 199
 200   sub _arm_global_destructor {
 201     my $self = shift;
 202     my $key = refaddr ($self);
 203     $seek_and_destroy{$key} = $self;
 204     weaken ($seek_and_destroy{$key});
 205   }
 206
 207   END {
 208     local $?; # just in case the DBI destructor changes it somehow
 209
 210     # destroy just the object if not native to this process/thread
 211     $_->_verify_pid for (grep
 212       { defined $_ }
 213       values %seek_and_destroy
 214     );
 215   }
 216
 217   sub CLONE {
 218     # As per DBI's recommendation, DBIC disconnects all handles as
 219     # soon as possible (DBIC will reconnect only on demand from within
 220     # the thread)
 221     for (values %seek_and_destroy) {
 222       next unless $_;
 223       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 224       $_->_dbh(undef);
 225
 226       $_->transaction_depth(0);
 227       $_->savepoints([]);
 228     }
 229   }
 230 }
 231
 232 sub DESTROY {
 233   my $self = shift;
 234
 235   # some databases spew warnings on implicit disconnect
 236   $self->_verify_pid;
 237   local $SIG{__WARN__} = sub {};
 238   $self->_dbh(undef);
 239
 240   # this op is necessary, since the very last perl runtime statement
 241   # triggers a global destruction shootout, and the $SIG localization
 242   # may very well be destroyed before perl actually gets to do the
 243   # $dbh undef
 244   1;
 245 }
 246
 247 # handle pid changes correctly - do not destroy parent's connection
 248 sub _verify_pid {
 249   my $self = shift;
 250
 251   my $pid = $self->_conn_pid;
 252   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 253     $dbh->{InactiveDestroy} = 1;
 254     $self->{_dbh_gen}++;
 255     $self->_dbh(undef);
 256     $self->transaction_depth(0);
 257     $self->savepoints([]);
 258   }
 259
 260   return;
 261 }
 262
 263 =head2 connect_info
 264
 265 This method is normally called by L<DBIx::Class::Schema/connection>, which
 266 encapsulates its argument list in an arrayref before passing them here.
 267
 268 The argument list may contain:
 269
 270 =over
 271
 272 =item *
 273
 274 The same 4-element argument set one would normally pass to
 275 L<DBI/connect>, optionally followed by
 276 L<extra attributes|/DBIx::Class specific connection attributes>
 277 recognized by DBIx::Class:
 278
 279   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 280
 281 =item *
 282
 283 A single code reference which returns a connected
 284 L<DBI database handle|DBI/connect> optionally followed by
 285 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 286 by DBIx::Class:
 287
 288   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 289
 290 =item *
 291
 292 A single hashref with all the attributes and the dsn/user/password
 293 mixed together:
 294
 295   $connect_info_args = [{
 296     dsn => $dsn,
 297     user => $user,
 298     password => $pass,
 299     %dbi_attributes,
 300     %extra_attributes,
 301   }];
 302
 303   $connect_info_args = [{
 304     dbh_maker => sub { DBI->connect (...) },
 305     %dbi_attributes,
 306     %extra_attributes,
 307   }];
 308
 309 This is particularly useful for L<Catalyst> based applications, allowing the
 310 following config (L<Config::General> style):
 311
 312   <Model::DB>
 313     schema_class   App::DB
 314     <connect_info>
 315       dsn          dbi:mysql:database=test
 316       user         testuser
 317       password     TestPass
 318       AutoCommit   1
 319     </connect_info>
 320   </Model::DB>
 321
 322 The C<dsn>/C<user>/C<password> combination can be substituted by the
 323 C<dbh_maker> key whose value is a coderef that returns a connected
 324 L<DBI database handle|DBI/connect>
 325
 326 =back
 327
 328 Please note that the L<DBI> docs recommend that you always explicitly
 329 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 330 recommends that it be set to I<1>, and that you perform transactions
 331 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 332 to I<1> if you do not do explicitly set it to zero.  This is the default
 333 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 334
 335 =head3 DBIx::Class specific connection attributes
 336
 337 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 338 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 339 the following connection options. These options can be mixed in with your other
 340 L<DBI> connection attributes, or placed in a separate hashref
 341 (C<\%extra_attributes>) as shown above.
 342
 343 Every time C<connect_info> is invoked, any previous settings for
 344 these options will be cleared before setting the new ones, regardless of
 345 whether any options are specified in the new C<connect_info>.
 346
 347
 348 =over
 349
 350 =item on_connect_do
 351
 352 Specifies things to do immediately after connecting or re-connecting to
 353 the database.  Its value may contain:
 354
 355 =over
 356
 357 =item a scalar
 358
 359 This contains one SQL statement to execute.
 360
 361 =item an array reference
 362
 363 This contains SQL statements to execute in order.  Each element contains
 364 a string or a code reference that returns a string.
 365
 366 =item a code reference
 367
 368 This contains some code to execute.  Unlike code references within an
 369 array reference, its return value is ignored.
 370
 371 =back
 372
 373 =item on_disconnect_do
 374
 375 Takes arguments in the same form as L</on_connect_do> and executes them
 376 immediately before disconnecting from the database.
 377
 378 Note, this only runs if you explicitly call L</disconnect> on the
 379 storage object.
 380
 381 =item on_connect_call
 382
 383 A more generalized form of L</on_connect_do> that calls the specified
 384 C<connect_call_METHOD> methods in your storage driver.
 385
 386   on_connect_do => 'select 1'
 387
 388 is equivalent to:
 389
 390   on_connect_call => [ [ do_sql => 'select 1' ] ]
 391
 392 Its values may contain:
 393
 394 =over
 395
 396 =item a scalar
 397
 398 Will call the C<connect_call_METHOD> method.
 399
 400 =item a code reference
 401
 402 Will execute C<< $code->($storage) >>
 403
 404 =item an array reference
 405
 406 Each value can be a method name or code reference.
 407
 408 =item an array of arrays
 409
 410 For each array, the first item is taken to be the C<connect_call_> method name
 411 or code reference, and the rest are parameters to it.
 412
 413 =back
 414
 415 Some predefined storage methods you may use:
 416
 417 =over
 418
 419 =item do_sql
 420
 421 Executes a SQL string or a code reference that returns a SQL string. This is
 422 what L</on_connect_do> and L</on_disconnect_do> use.
 423
 424 It can take:
 425
 426 =over
 427
 428 =item a scalar
 429
 430 Will execute the scalar as SQL.
 431
 432 =item an arrayref
 433
 434 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 435 attributes hashref and bind values.
 436
 437 =item a code reference
 438
 439 Will execute C<< $code->($storage) >> and execute the return array refs as
 440 above.
 441
 442 =back
 443
 444 =item datetime_setup
 445
 446 Execute any statements necessary to initialize the database session to return
 447 and accept datetime/timestamp values used with
 448 L<DBIx::Class::InflateColumn::DateTime>.
 449
 450 Only necessary for some databases, see your specific storage driver for
 451 implementation details.
 452
 453 =back
 454
 455 =item on_disconnect_call
 456
 457 Takes arguments in the same form as L</on_connect_call> and executes them
 458 immediately before disconnecting from the database.
 459
 460 Calls the C<disconnect_call_METHOD> methods as opposed to the
 461 C<connect_call_METHOD> methods called by L</on_connect_call>.
 462
 463 Note, this only runs if you explicitly call L</disconnect> on the
 464 storage object.
 465
 466 =item disable_sth_caching
 467
 468 If set to a true value, this option will disable the caching of
 469 statement handles via L<DBI/prepare_cached>.
 470
 471 =item limit_dialect
 472
 473 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 474 default L</sql_limit_dialect> setting of the storage (if any). For a list
 475 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 476
 477 =item quote_names
 478
 479 When true automatically sets L</quote_char> and L</name_sep> to the characters
 480 appropriate for your particular RDBMS. This option is preferred over specifying
 481 L</quote_char> directly.
 482
 483 =item quote_char
 484
 485 Specifies what characters to use to quote table and column names.
 486
 487 C<quote_char> expects either a single character, in which case is it
 488 is placed on either side of the table/column name, or an arrayref of length
 489 2 in which case the table/column name is placed between the elements.
 490
 491 For example under MySQL you should use C<< quote_char => '`' >>, and for
 492 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 493
 494 =item name_sep
 495
 496 This parameter is only useful in conjunction with C<quote_char>, and is used to
 497 specify the character that separates elements (schemas, tables, columns) from
 498 each other. If unspecified it defaults to the most commonly used C<.>.
 499
 500 =item unsafe
 501
 502 This Storage driver normally installs its own C<HandleError>, sets
 503 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 504 all database handles, including those supplied by a coderef.  It does this
 505 so that it can have consistent and useful error behavior.
 506
 507 If you set this option to a true value, Storage will not do its usual
 508 modifications to the database handle's attributes, and instead relies on
 509 the settings in your connect_info DBI options (or the values you set in
 510 your connection coderef, in the case that you are connecting via coderef).
 511
 512 Note that your custom settings can cause Storage to malfunction,
 513 especially if you set a C<HandleError> handler that suppresses exceptions
 514 and/or disable C<RaiseError>.
 515
 516 =item auto_savepoint
 517
 518 If this option is true, L<DBIx::Class> will use savepoints when nesting
 519 transactions, making it possible to recover from failure in the inner
 520 transaction without having to abort all outer transactions.
 521
 522 =item cursor_class
 523
 524 Use this argument to supply a cursor class other than the default
 525 L<DBIx::Class::Storage::DBI::Cursor>.
 526
 527 =back
 528
 529 Some real-life examples of arguments to L</connect_info> and
 530 L<DBIx::Class::Schema/connect>
 531
 532   # Simple SQLite connection
 533   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 534
 535   # Connect via subref
 536   ->connect_info([ sub { DBI->connect(...) } ]);
 537
 538   # Connect via subref in hashref
 539   ->connect_info([{
 540     dbh_maker => sub { DBI->connect(...) },
 541     on_connect_do => 'alter session ...',
 542   }]);
 543
 544   # A bit more complicated
 545   ->connect_info(
 546     [
 547       'dbi:Pg:dbname=foo',
 548       'postgres',
 549       'my_pg_password',
 550       { AutoCommit => 1 },
 551       { quote_char => q{"} },
 552     ]
 553   );
 554
 555   # Equivalent to the previous example
 556   ->connect_info(
 557     [
 558       'dbi:Pg:dbname=foo',
 559       'postgres',
 560       'my_pg_password',
 561       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 562     ]
 563   );
 564
 565   # Same, but with hashref as argument
 566   # See parse_connect_info for explanation
 567   ->connect_info(
 568     [{
 569       dsn         => 'dbi:Pg:dbname=foo',
 570       user        => 'postgres',
 571       password    => 'my_pg_password',
 572       AutoCommit  => 1,
 573       quote_char  => q{"},
 574       name_sep    => q{.},
 575     }]
 576   );
 577
 578   # Subref + DBIx::Class-specific connection options
 579   ->connect_info(
 580     [
 581       sub { DBI->connect(...) },
 582       {
 583           quote_char => q{`},
 584           name_sep => q{@},
 585           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 586           disable_sth_caching => 1,
 587       },
 588     ]
 589   );
 590
 591
 592
 593 =cut
 594
 595 sub connect_info {
 596   my ($self, $info) = @_;
 597
 598   return $self->_connect_info if !$info;
 599
 600   $self->_connect_info($info); # copy for _connect_info
 601
 602   $info = $self->_normalize_connect_info($info)
 603     if ref $info eq 'ARRAY';
 604
 605   for my $storage_opt (keys %{ $info->{storage_options} }) {
 606     my $value = $info->{storage_options}{$storage_opt};
 607
 608     $self->$storage_opt($value);
 609   }
 610
 611   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 612   #  the new set of options
 613   $self->_sql_maker(undef);
 614   $self->_sql_maker_opts({});
 615
 616   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 617     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 618
 619     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 620   }
 621
 622   my %attrs = (
 623     %{ $self->_default_dbi_connect_attributes || {} },
 624     %{ $info->{attributes} || {} },
 625   );
 626
 627   my @args = @{ $info->{arguments} };
 628
 629   if (keys %attrs and ref $args[0] ne 'CODE') {
 630     carp
 631         'You provided explicit AutoCommit => 0 in your connection_info. '
 632       . 'This is almost universally a bad idea (see the footnotes of '
 633       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 634       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 635       . 'this warning.'
 636       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 637
 638     push @args, \%attrs if keys %attrs;
 639   }
 640   $self->_dbi_connect_info(\@args);
 641
 642   # FIXME - dirty:
 643   # save attributes them in a separate accessor so they are always
 644   # introspectable, even in case of a CODE $dbhmaker
 645   $self->_dbic_connect_attributes (\%attrs);
 646
 647   return $self->_connect_info;
 648 }
 649
 650 sub _normalize_connect_info {
 651   my ($self, $info_arg) = @_;
 652   my %info;
 653
 654   my @args = @$info_arg;  # take a shallow copy for further mutilation
 655
 656   # combine/pre-parse arguments depending on invocation style
 657
 658   my %attrs;
 659   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 660     %attrs = %{ $args[1] || {} };
 661     @args = $args[0];
 662   }
 663   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 664     %attrs = %{$args[0]};
 665     @args = ();
 666     if (my $code = delete $attrs{dbh_maker}) {
 667       @args = $code;
 668
 669       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 670       if (@ignored) {
 671         carp sprintf (
 672             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 673           . "to the result of 'dbh_maker'",
 674
 675           join (', ', map { "'$_'" } (@ignored) ),
 676         );
 677       }
 678     }
 679     else {
 680       @args = delete @attrs{qw/dsn user password/};
 681     }
 682   }
 683   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 684     %attrs = (
 685       % { $args[3] || {} },
 686       % { $args[4] || {} },
 687     );
 688     @args = @args[0,1,2];
 689   }
 690
 691   $info{arguments} = \@args;
 692
 693   my @storage_opts = grep exists $attrs{$_},
 694     @storage_options, 'cursor_class';
 695
 696   @{ $info{storage_options} }{@storage_opts} =
 697     delete @attrs{@storage_opts} if @storage_opts;
 698
 699   my @sql_maker_opts = grep exists $attrs{$_},
 700     qw/limit_dialect quote_char name_sep quote_names/;
 701
 702   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 703     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 704
 705   $info{attributes} = \%attrs if %attrs;
 706
 707   return \%info;
 708 }
 709
 710 sub _default_dbi_connect_attributes () {
 711   +{
 712     AutoCommit => 1,
 713     PrintError => 0,
 714     RaiseError => 1,
 715     ShowErrorStatement => 1,
 716   };
 717 }
 718
 719 =head2 on_connect_do
 720
 721 This method is deprecated in favour of setting via L</connect_info>.
 722
 723 =cut
 724
 725 =head2 on_disconnect_do
 726
 727 This method is deprecated in favour of setting via L</connect_info>.
 728
 729 =cut
 730
 731 sub _parse_connect_do {
 732   my ($self, $type) = @_;
 733
 734   my $val = $self->$type;
 735   return () if not defined $val;
 736
 737   my @res;
 738
 739   if (not ref($val)) {
 740     push @res, [ 'do_sql', $val ];
 741   } elsif (ref($val) eq 'CODE') {
 742     push @res, $val;
 743   } elsif (ref($val) eq 'ARRAY') {
 744     push @res, map { [ 'do_sql', $_ ] } @$val;
 745   } else {
 746     $self->throw_exception("Invalid type for $type: ".ref($val));
 747   }
 748
 749   return \@res;
 750 }
 751
 752 =head2 dbh_do
 753
 754 Arguments: ($subref | $method_name), @extra_coderef_args?
 755
 756 Execute the given $subref or $method_name using the new exception-based
 757 connection management.
 758
 759 The first two arguments will be the storage object that C<dbh_do> was called
 760 on and a database handle to use.  Any additional arguments will be passed
 761 verbatim to the called subref as arguments 2 and onwards.
 762
 763 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 764 exception handling and reconnection (or failover in future subclasses).
 765
 766 Your subref should have no side-effects outside of the database, as
 767 there is the potential for your subref to be partially double-executed
 768 if the database connection was stale/dysfunctional.
 769
 770 Example:
 771
 772   my @stuff = $schema->storage->dbh_do(
 773     sub {
 774       my ($storage, $dbh, @cols) = @_;
 775       my $cols = join(q{, }, @cols);
 776       $dbh->selectrow_array("SELECT $cols FROM foo");
 777     },
 778     @column_list
 779   );
 780
 781 =cut
 782
 783 sub dbh_do {
 784   my $self = shift;
 785   my $run_target = shift;
 786
 787   # short circuit when we know there is no need for a runner
 788   #
 789   # FIXME - asumption may be wrong
 790   # the rationale for the txn_depth check is that if this block is a part
 791   # of a larger transaction, everything up to that point is screwed anyway
 792   return $self->$run_target($self->_get_dbh, @_)
 793     if $self->{_in_do_block} or $self->transaction_depth;
 794
 795   my $args = \@_;
 796
 797   DBIx::Class::Storage::BlockRunner->new(
 798     storage => $self,
 799     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 800     wrap_txn => 0,
 801     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 802   )->run;
 803 }
 804
 805 sub txn_do {
 806   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 807   shift->next::method(@_);
 808 }
 809
 810 =head2 disconnect
 811
 812 Our C<disconnect> method also performs a rollback first if the
 813 database is not in C<AutoCommit> mode.
 814
 815 =cut
 816
 817 sub disconnect {
 818   my ($self) = @_;
 819
 820   if( $self->_dbh ) {
 821     my @actions;
 822
 823     push @actions, ( $self->on_disconnect_call || () );
 824     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 825
 826     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 827
 828     # stops the "implicit rollback on disconnect" warning
 829     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 830
 831     %{ $self->_dbh->{CachedKids} } = ();
 832     $self->_dbh->disconnect;
 833     $self->_dbh(undef);
 834     $self->{_dbh_gen}++;
 835   }
 836 }
 837
 838 =head2 with_deferred_fk_checks
 839
 840 =over 4
 841
 842 =item Arguments: C<$coderef>
 843
 844 =item Return Value: The return value of $coderef
 845
 846 =back
 847
 848 Storage specific method to run the code ref with FK checks deferred or
 849 in MySQL's case disabled entirely.
 850
 851 =cut
 852
 853 # Storage subclasses should override this
 854 sub with_deferred_fk_checks {
 855   my ($self, $sub) = @_;
 856   $sub->();
 857 }
 858
 859 =head2 connected
 860
 861 =over
 862
 863 =item Arguments: none
 864
 865 =item Return Value: 1|0
 866
 867 =back
 868
 869 Verifies that the current database handle is active and ready to execute
 870 an SQL statement (e.g. the connection did not get stale, server is still
 871 answering, etc.) This method is used internally by L</dbh>.
 872
 873 =cut
 874
 875 sub connected {
 876   my $self = shift;
 877   return 0 unless $self->_seems_connected;
 878
 879   #be on the safe side
 880   local $self->_dbh->{RaiseError} = 1;
 881
 882   return $self->_ping;
 883 }
 884
 885 sub _seems_connected {
 886   my $self = shift;
 887
 888   $self->_verify_pid;
 889
 890   my $dbh = $self->_dbh
 891     or return 0;
 892
 893   return $dbh->FETCH('Active');
 894 }
 895
 896 sub _ping {
 897   my $self = shift;
 898
 899   my $dbh = $self->_dbh or return 0;
 900
 901   return $dbh->ping;
 902 }
 903
 904 sub ensure_connected {
 905   my ($self) = @_;
 906
 907   unless ($self->connected) {
 908     $self->_populate_dbh;
 909   }
 910 }
 911
 912 =head2 dbh
 913
 914 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 915 is guaranteed to be healthy by implicitly calling L</connected>, and if
 916 necessary performing a reconnection before returning. Keep in mind that this
 917 is very B<expensive> on some database engines. Consider using L</dbh_do>
 918 instead.
 919
 920 =cut
 921
 922 sub dbh {
 923   my ($self) = @_;
 924
 925   if (not $self->_dbh) {
 926     $self->_populate_dbh;
 927   } else {
 928     $self->ensure_connected;
 929   }
 930   return $self->_dbh;
 931 }
 932
 933 # this is the internal "get dbh or connect (don't check)" method
 934 sub _get_dbh {
 935   my $self = shift;
 936   $self->_verify_pid;
 937   $self->_populate_dbh unless $self->_dbh;
 938   return $self->_dbh;
 939 }
 940
 941 sub sql_maker {
 942   my ($self) = @_;
 943   unless ($self->_sql_maker) {
 944     my $sql_maker_class = $self->sql_maker_class;
 945
 946     my %opts = %{$self->_sql_maker_opts||{}};
 947     my $dialect =
 948       $opts{limit_dialect}
 949         ||
 950       $self->sql_limit_dialect
 951         ||
 952       do {
 953         my $s_class = (ref $self) || $self;
 954         carp (
 955           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 956         . 'have not supplied an explicit limit_dialect in your connection_info. '
 957         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 958         . 'databases but can be (and often is) painfully slow. '
 959         . "Please file an RT ticket against '$s_class' ."
 960         );
 961
 962         'GenericSubQ';
 963       }
 964     ;
 965
 966     my ($quote_char, $name_sep);
 967
 968     if ($opts{quote_names}) {
 969       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 970         my $s_class = (ref $self) || $self;
 971         carp (
 972           "You requested 'quote_names' but your storage class ($s_class) does "
 973         . 'not explicitly define a default sql_quote_char and you have not '
 974         . 'supplied a quote_char as part of your connection_info. DBIC will '
 975         .q{default to the ANSI SQL standard quote '"', which works most of }
 976         . "the time. Please file an RT ticket against '$s_class'."
 977         );
 978
 979         '"'; # RV
 980       };
 981
 982       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 983     }
 984
 985     $self->_sql_maker($sql_maker_class->new(
 986       bindtype=>'columns',
 987       array_datatypes => 1,
 988       limit_dialect => $dialect,
 989       ($quote_char ? (quote_char => $quote_char) : ()),
 990       name_sep => ($name_sep || '.'),
 991       %opts,
 992     ));
 993   }
 994   return $self->_sql_maker;
 995 }
 996
 997 # nothing to do by default
 998 sub _rebless {}
 999 sub _init {}
1000
1001 sub _populate_dbh {
1002   my ($self) = @_;
1003
1004   my @info = @{$self->_dbi_connect_info || []};
1005   $self->_dbh(undef); # in case ->connected failed we might get sent here
1006   $self->_dbh_details({}); # reset everything we know
1007
1008   $self->_dbh($self->_connect(@info));
1009
1010   $self->_conn_pid($$) if $^O ne 'MSWin32'; # on win32 these are in fact threads
1011
1012   $self->_determine_driver;
1013
1014   # Always set the transaction depth on connect, since
1015   #  there is no transaction in progress by definition
1016   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1017
1018   $self->_run_connection_actions unless $self->{_in_determine_driver};
1019 }
1020
1021 sub _run_connection_actions {
1022   my $self = shift;
1023   my @actions;
1024
1025   push @actions, ( $self->on_connect_call || () );
1026   push @actions, $self->_parse_connect_do ('on_connect_do');
1027
1028   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1029 }
1030
1031
1032
1033 sub set_use_dbms_capability {
1034   $_[0]->set_inherited ($_[1], $_[2]);
1035 }
1036
1037 sub get_use_dbms_capability {
1038   my ($self, $capname) = @_;
1039
1040   my $use = $self->get_inherited ($capname);
1041   return defined $use
1042     ? $use
1043     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1044   ;
1045 }
1046
1047 sub set_dbms_capability {
1048   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1049 }
1050
1051 sub get_dbms_capability {
1052   my ($self, $capname) = @_;
1053
1054   my $cap = $self->_dbh_details->{capability}{$capname};
1055
1056   unless (defined $cap) {
1057     if (my $meth = $self->can ("_determine$capname")) {
1058       $cap = $self->$meth ? 1 : 0;
1059     }
1060     else {
1061       $cap = 0;
1062     }
1063
1064     $self->set_dbms_capability ($capname, $cap);
1065   }
1066
1067   return $cap;
1068 }
1069
1070 sub _server_info {
1071   my $self = shift;
1072
1073   my $info;
1074   unless ($info = $self->_dbh_details->{info}) {
1075
1076     $info = {};
1077
1078     my $server_version;
1079     try {
1080       $server_version = $self->_get_server_version;
1081     }
1082     catch {
1083       if ($self->{_in_determine_driver}) {
1084         $self->throw_exception($_);
1085       }
1086       $server_version = undef;
1087     };
1088
1089     if (defined $server_version) {
1090       $info->{dbms_version} = $server_version;
1091
1092       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1093       my @verparts = split (/\./, $numeric_version);
1094       if (
1095         @verparts
1096           &&
1097         $verparts[0] <= 999
1098       ) {
1099         # consider only up to 3 version parts, iff not more than 3 digits
1100         my @use_parts;
1101         while (@verparts && @use_parts < 3) {
1102           my $p = shift @verparts;
1103           last if $p > 999;
1104           push @use_parts, $p;
1105         }
1106         push @use_parts, 0 while @use_parts < 3;
1107
1108         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1109       }
1110     }
1111
1112     $self->_dbh_details->{info} = $info;
1113   }
1114
1115   return $info;
1116 }
1117
1118 sub _get_server_version {
1119   shift->_dbh_get_info('SQL_DBMS_VER');
1120 }
1121
1122 sub _dbh_get_info {
1123   my ($self, $info) = @_;
1124
1125   if ($info =~ /[^0-9]/) {
1126     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1127     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1128       unless defined $info;
1129   }
1130
1131   my $res;
1132
1133   try {
1134     $res = $self->_get_dbh->get_info($info);
1135   }
1136   catch {
1137     if ($self->{_in_determine_driver}) {
1138       $self->throw_exception($_);
1139     }
1140     $res = undef;
1141   };
1142
1143   return $res;
1144 }
1145
1146 sub _determine_driver {
1147   my ($self) = @_;
1148
1149   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1150     my $started_connected = 0;
1151     local $self->{_in_determine_driver} = 1;
1152
1153     if (ref($self) eq __PACKAGE__) {
1154       my $driver;
1155       if ($self->_dbh) { # we are connected
1156         $driver = $self->_dbh->{Driver}{Name};
1157         $started_connected = 1;
1158       } else {
1159         # if connect_info is a CODEREF, we have no choice but to connect
1160         if (ref $self->_dbi_connect_info->[0] &&
1161             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1162           $self->_populate_dbh;
1163           $driver = $self->_dbh->{Driver}{Name};
1164         }
1165         else {
1166           # try to use dsn to not require being connected, the driver may still
1167           # force a connection in _rebless to determine version
1168           # (dsn may not be supplied at all if all we do is make a mock-schema)
1169           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1170           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1171           $driver ||= $ENV{DBI_DRIVER};
1172         }
1173       }
1174
1175       if ($driver) {
1176         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1177         if ($self->load_optional_class($storage_class)) {
1178           mro::set_mro($storage_class, 'c3');
1179           bless $self, $storage_class;
1180           $self->_rebless();
1181         }
1182       }
1183     }
1184
1185     $self->_driver_determined(1);
1186
1187     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1188
1189     $self->_init; # run driver-specific initializations
1190
1191     $self->_run_connection_actions
1192         if !$started_connected && defined $self->_dbh;
1193   }
1194 }
1195
1196 sub _do_connection_actions {
1197   my $self          = shift;
1198   my $method_prefix = shift;
1199   my $call          = shift;
1200
1201   if (not ref($call)) {
1202     my $method = $method_prefix . $call;
1203     $self->$method(@_);
1204   } elsif (ref($call) eq 'CODE') {
1205     $self->$call(@_);
1206   } elsif (ref($call) eq 'ARRAY') {
1207     if (ref($call->[0]) ne 'ARRAY') {
1208       $self->_do_connection_actions($method_prefix, $_) for @$call;
1209     } else {
1210       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1211     }
1212   } else {
1213     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1214   }
1215
1216   return $self;
1217 }
1218
1219 sub connect_call_do_sql {
1220   my $self = shift;
1221   $self->_do_query(@_);
1222 }
1223
1224 sub disconnect_call_do_sql {
1225   my $self = shift;
1226   $self->_do_query(@_);
1227 }
1228
1229 # override in db-specific backend when necessary
1230 sub connect_call_datetime_setup { 1 }
1231
1232 sub _do_query {
1233   my ($self, $action) = @_;
1234
1235   if (ref $action eq 'CODE') {
1236     $action = $action->($self);
1237     $self->_do_query($_) foreach @$action;
1238   }
1239   else {
1240     # Most debuggers expect ($sql, @bind), so we need to exclude
1241     # the attribute hash which is the second argument to $dbh->do
1242     # furthermore the bind values are usually to be presented
1243     # as named arrayref pairs, so wrap those here too
1244     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1245     my $sql = shift @do_args;
1246     my $attrs = shift @do_args;
1247     my @bind = map { [ undef, $_ ] } @do_args;
1248
1249     $self->dbh_do(sub {
1250       $_[0]->_query_start($sql, \@bind);
1251       $_[1]->do($sql, $attrs, @do_args);
1252       $_[0]->_query_end($sql, \@bind);
1253     });
1254   }
1255
1256   return $self;
1257 }
1258
1259 sub _connect {
1260   my ($self, @info) = @_;
1261
1262   $self->throw_exception("You failed to provide any connection info")
1263     if !@info;
1264
1265   my ($old_connect_via, $dbh);
1266
1267   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1268
1269   try {
1270     if(ref $info[0] eq 'CODE') {
1271       $dbh = $info[0]->();
1272     }
1273     else {
1274       require DBI;
1275       $dbh = DBI->connect(@info);
1276     }
1277
1278     if (!$dbh) {
1279       die $DBI::errstr;
1280     }
1281
1282     unless ($self->unsafe) {
1283
1284       $self->throw_exception(
1285         'Refusing clobbering of {HandleError} installed on externally supplied '
1286        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1287       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1288
1289       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1290       # request, or an external handle. Complain and set anyway
1291       unless ($dbh->{RaiseError}) {
1292         carp( ref $info[0] eq 'CODE'
1293
1294           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1295            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1296            .'attribute has been supplied'
1297
1298           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1299            .'unsafe => 1. Toggling RaiseError back to true'
1300         );
1301
1302         $dbh->{RaiseError} = 1;
1303       }
1304
1305       # this odd anonymous coderef dereference is in fact really
1306       # necessary to avoid the unwanted effect described in perl5
1307       # RT#75792
1308       sub {
1309         my $weak_self = $_[0];
1310         weaken $weak_self;
1311
1312         # the coderef is blessed so we can distinguish it from externally
1313         # supplied handles (which must be preserved)
1314         $_[1]->{HandleError} = bless sub {
1315           if ($weak_self) {
1316             $weak_self->throw_exception("DBI Exception: $_[0]");
1317           }
1318           else {
1319             # the handler may be invoked by something totally out of
1320             # the scope of DBIC
1321             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1322           }
1323         }, '__DBIC__DBH__ERROR__HANDLER__';
1324       }->($self, $dbh);
1325     }
1326   }
1327   catch {
1328     $self->throw_exception("DBI Connection failed: $_")
1329   };
1330
1331   $self->_dbh_autocommit($dbh->{AutoCommit});
1332   $dbh;
1333 }
1334
1335 sub txn_begin {
1336   my $self = shift;
1337
1338   # this means we have not yet connected and do not know the AC status
1339   # (e.g. coderef $dbh), need a full-fledged connection check
1340   if (! defined $self->_dbh_autocommit) {
1341     $self->ensure_connected;
1342   }
1343   # Otherwise simply connect or re-connect on pid changes
1344   else {
1345     $self->_get_dbh;
1346   }
1347
1348   $self->next::method(@_);
1349 }
1350
1351 sub _exec_txn_begin {
1352   my $self = shift;
1353
1354   # if the user is utilizing txn_do - good for him, otherwise we need to
1355   # ensure that the $dbh is healthy on BEGIN.
1356   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1357   # will be replaced by a failure of begin_work itself (which will be
1358   # then retried on reconnect)
1359   if ($self->{_in_do_block}) {
1360     $self->_dbh->begin_work;
1361   } else {
1362     $self->dbh_do(sub { $_[1]->begin_work });
1363   }
1364 }
1365
1366 sub txn_commit {
1367   my $self = shift;
1368
1369   $self->_verify_pid if $self->_dbh;
1370   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1371     unless $self->_dbh;
1372
1373   # esoteric case for folks using external $dbh handles
1374   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1375     carp "Storage transaction_depth 0 does not match "
1376         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1377     $self->transaction_depth(1);
1378   }
1379
1380   $self->next::method(@_);
1381
1382   # if AutoCommit is disabled txn_depth never goes to 0
1383   # as a new txn is started immediately on commit
1384   $self->transaction_depth(1) if (
1385     !$self->transaction_depth
1386       and
1387     defined $self->_dbh_autocommit
1388       and
1389     ! $self->_dbh_autocommit
1390   );
1391 }
1392
1393 sub _exec_txn_commit {
1394   shift->_dbh->commit;
1395 }
1396
1397 sub txn_rollback {
1398   my $self = shift;
1399
1400   $self->_verify_pid if $self->_dbh;
1401   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1402     unless $self->_dbh;
1403
1404   # esoteric case for folks using external $dbh handles
1405   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1406     carp "Storage transaction_depth 0 does not match "
1407         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1408     $self->transaction_depth(1);
1409   }
1410
1411   $self->next::method(@_);
1412
1413   # if AutoCommit is disabled txn_depth never goes to 0
1414   # as a new txn is started immediately on commit
1415   $self->transaction_depth(1) if (
1416     !$self->transaction_depth
1417       and
1418     defined $self->_dbh_autocommit
1419       and
1420     ! $self->_dbh_autocommit
1421   );
1422 }
1423
1424 sub _exec_txn_rollback {
1425   shift->_dbh->rollback;
1426 }
1427
1428 # generate some identical methods
1429 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1430   no strict qw/refs/;
1431   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1432     my $self = shift;
1433     $self->_verify_pid if $self->_dbh;
1434     $self->throw_exception("Unable to $meth() on a disconnected storage")
1435       unless $self->_dbh;
1436     $self->next::method(@_);
1437   };
1438 }
1439
1440 # This used to be the top-half of _execute.  It was split out to make it
1441 #  easier to override in NoBindVars without duping the rest.  It takes up
1442 #  all of _execute's args, and emits $sql, @bind.
1443 sub _prep_for_execute {
1444   #my ($self, $op, $ident, $args) = @_;
1445   return shift->_gen_sql_bind(@_)
1446 }
1447
1448 sub _gen_sql_bind {
1449   my ($self, $op, $ident, $args) = @_;
1450
1451   my ($sql, @bind) = $self->sql_maker->$op(
1452     blessed($ident) ? $ident->from : $ident,
1453     @$args,
1454   );
1455
1456   if (
1457     ! $ENV{DBIC_DT_SEARCH_OK}
1458       and
1459     $op eq 'select'
1460       and
1461     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1462   ) {
1463     carp_unique 'DateTime objects passed to search() are not supported '
1464       . 'properly (InflateColumn::DateTime formats and settings are not '
1465       . 'respected.) See "Formatting DateTime objects in queries" in '
1466       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1467       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1468   }
1469
1470   return( $sql, $self->_resolve_bindattrs(
1471     $ident, [ @{$args->[2]{bind}||[]}, @bind ]
1472   ));
1473 }
1474
1475 sub _resolve_bindattrs {
1476   my ($self, $ident, $bind, $colinfos) = @_;
1477
1478   $colinfos ||= {};
1479
1480   my $resolve_bindinfo = sub {
1481     #my $infohash = shift;
1482
1483     %$colinfos = %{ $self->_resolve_column_info($ident) }
1484       unless keys %$colinfos;
1485
1486     my $ret;
1487     if (my $col = $_[0]->{dbic_colname}) {
1488       $ret = { %{$_[0]} };
1489
1490       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1491         if $colinfos->{$col}{data_type};
1492
1493       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1494         if $colinfos->{$col}{size};
1495     }
1496
1497     $ret || $_[0];
1498   };
1499
1500   return [ map {
1501     if (ref $_ ne 'ARRAY') {
1502       [{}, $_]
1503     }
1504     elsif (! defined $_->[0]) {
1505       [{}, $_->[1]]
1506     }
1507     elsif (ref $_->[0] eq 'HASH') {
1508       [
1509         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1510         $_->[1]
1511       ]
1512     }
1513     elsif (ref $_->[0] eq 'SCALAR') {
1514       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1515     }
1516     else {
1517       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1518     }
1519   } @$bind ];
1520 }
1521
1522 sub _format_for_trace {
1523   #my ($self, $bind) = @_;
1524
1525   ### Turn @bind from something like this:
1526   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1527   ### to this:
1528   ###   ( "'1'", "'3'" )
1529
1530   map {
1531     defined( $_ && $_->[1] )
1532       ? qq{'$_->[1]'}
1533       : q{NULL}
1534   } @{$_[1] || []};
1535 }
1536
1537 sub _query_start {
1538   my ( $self, $sql, $bind ) = @_;
1539
1540   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1541     if $self->debug;
1542 }
1543
1544 sub _query_end {
1545   my ( $self, $sql, $bind ) = @_;
1546
1547   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1548     if $self->debug;
1549 }
1550
1551 my $sba_compat;
1552 sub _dbi_attrs_for_bind {
1553   my ($self, $ident, $bind) = @_;
1554
1555   if (! defined $sba_compat) {
1556     $self->_determine_driver;
1557     $sba_compat = $self->can('source_bind_attributes') == \&source_bind_attributes
1558       ? 0
1559       : 1
1560     ;
1561   }
1562
1563   my $sba_attrs;
1564   if ($sba_compat) {
1565     my $class = ref $self;
1566     carp_unique (
1567       "The source_bind_attributes() override in $class relies on a deprecated codepath. "
1568      .'You are strongly advised to switch your code to override bind_attribute_by_datatype() '
1569      .'instead. This legacy compat shim will also disappear some time before DBIC 0.09'
1570     );
1571
1572     my $sba_attrs = $self->source_bind_attributes
1573   }
1574
1575   my @attrs;
1576
1577   for (map { $_->[0] } @$bind) {
1578     push @attrs, do {
1579       if (exists $_->{dbd_attrs}) {
1580         $_->{dbd_attrs}
1581       }
1582       elsif($_->{sqlt_datatype}) {
1583         # cache the result in the dbh_details hash, as it can not change unless
1584         # we connect to something else
1585         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1586         if (not exists $cache->{$_->{sqlt_datatype}}) {
1587           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1588         }
1589         $cache->{$_->{sqlt_datatype}};
1590       }
1591       elsif ($sba_attrs and $_->{dbic_colname}) {
1592         $sba_attrs->{$_->{dbic_colname}} || undef;
1593       }
1594       else {
1595         undef;  # always push something at this position
1596       }
1597     }
1598   }
1599
1600   return \@attrs;
1601 }
1602
1603 sub _execute {
1604   my ($self, $op, $ident, @args) = @_;
1605
1606   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1607
1608   shift->dbh_do(    # retry over disconnects
1609     '_dbh_execute',
1610     $sql,
1611     $bind,
1612     $self->_dbi_attrs_for_bind($ident, $bind)
1613   );
1614 }
1615
1616 sub _dbh_execute {
1617   my ($self, undef, $sql, $bind, $bind_attrs) = @_;
1618
1619   $self->_query_start( $sql, $bind );
1620   my $sth = $self->_sth($sql);
1621
1622   for my $i (0 .. $#$bind) {
1623     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1624       $sth->bind_param_inout(
1625         $i + 1, # bind params counts are 1-based
1626         $bind->[$i][1],
1627         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1628         $bind_attrs->[$i],
1629       );
1630     }
1631     else {
1632       $sth->bind_param(
1633         $i + 1,
1634         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1635           ? "$bind->[$i][1]"
1636           : $bind->[$i][1]
1637         ,
1638         $bind_attrs->[$i],
1639       );
1640     }
1641   }
1642
1643   # Can this fail without throwing an exception anyways???
1644   my $rv = $sth->execute();
1645   $self->throw_exception(
1646     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1647   ) if !$rv;
1648
1649   $self->_query_end( $sql, $bind );
1650
1651   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1652 }
1653
1654 sub _prefetch_autovalues {
1655   my ($self, $source, $to_insert) = @_;
1656
1657   my $colinfo = $source->columns_info;
1658
1659   my %values;
1660   for my $col (keys %$colinfo) {
1661     if (
1662       $colinfo->{$col}{auto_nextval}
1663         and
1664       (
1665         ! exists $to_insert->{$col}
1666           or
1667         ref $to_insert->{$col} eq 'SCALAR'
1668           or
1669         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1670       )
1671     ) {
1672       $values{$col} = $self->_sequence_fetch(
1673         'NEXTVAL',
1674         ( $colinfo->{$col}{sequence} ||=
1675             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1676         ),
1677       );
1678     }
1679   }
1680
1681   \%values;
1682 }
1683
1684 sub insert {
1685   my ($self, $source, $to_insert) = @_;
1686
1687   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1688
1689   # fuse the values, but keep a separate list of prefetched_values so that
1690   # they can be fused once again with the final return
1691   $to_insert = { %$to_insert, %$prefetched_values };
1692
1693   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1694   # Investigate what does it take to s/defined/exists/
1695   my $col_infos = $source->columns_info;
1696   my %pcols = map { $_ => 1 } $source->primary_columns;
1697   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1698   for my $col ($source->columns) {
1699     if ($col_infos->{$col}{is_auto_increment}) {
1700       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1701       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1702     }
1703
1704     # nothing to retrieve when explicit values are supplied
1705     next if (defined $to_insert->{$col} and ! (
1706       ref $to_insert->{$col} eq 'SCALAR'
1707         or
1708       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1709     ));
1710
1711     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1712     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1713       $pcols{$col}
1714         or
1715       $col_infos->{$col}{retrieve_on_insert}
1716     );
1717   };
1718
1719   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1720   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1721
1722   my ($sqla_opts, @ir_container);
1723   if (%retrieve_cols and $self->_use_insert_returning) {
1724     $sqla_opts->{returning_container} = \@ir_container
1725       if $self->_use_insert_returning_bound;
1726
1727     $sqla_opts->{returning} = [
1728       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1729     ];
1730   }
1731
1732   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1733
1734   my %returned_cols = %$to_insert;
1735   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1736     @ir_container = try {
1737       local $SIG{__WARN__} = sub {};
1738       my @r = $sth->fetchrow_array;
1739       $sth->finish;
1740       @r;
1741     } unless @ir_container;
1742
1743     @returned_cols{@$retlist} = @ir_container if @ir_container;
1744   }
1745   else {
1746     # pull in PK if needed and then everything else
1747     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1748
1749       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1750         unless $self->can('last_insert_id');
1751
1752       my @pri_values = $self->last_insert_id($source, @missing_pri);
1753
1754       $self->throw_exception( "Can't get last insert id" )
1755         unless (@pri_values == @missing_pri);
1756
1757       @returned_cols{@missing_pri} = @pri_values;
1758       delete $retrieve_cols{$_} for @missing_pri;
1759     }
1760
1761     # if there is more left to pull
1762     if (%retrieve_cols) {
1763       $self->throw_exception(
1764         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1765       ) unless %pcols;
1766
1767       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1768
1769       my $cur = DBIx::Class::ResultSet->new($source, {
1770         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1771         select => \@left_to_fetch,
1772       })->cursor;
1773
1774       @returned_cols{@left_to_fetch} = $cur->next;
1775
1776       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1777         if scalar $cur->next;
1778     }
1779   }
1780
1781   return { %$prefetched_values, %returned_cols };
1782 }
1783
1784 sub insert_bulk {
1785   my ($self, $source, $cols, $data) = @_;
1786
1787   my @col_range = (0..$#$cols);
1788
1789   # FIXME - perhaps this is not even needed? does DBI stringify?
1790   #
1791   # forcibly stringify whatever is stringifiable
1792   # ResultSet::populate() hands us a copy - safe to mangle
1793   for my $r (0 .. $#$data) {
1794     for my $c (0 .. $#{$data->[$r]}) {
1795       $data->[$r][$c] = "$data->[$r][$c]"
1796         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1797     }
1798   }
1799
1800   my $colinfos = $source->columns_info($cols);
1801
1802   local $self->{_autoinc_supplied_for_op} =
1803     (first { $_->{is_auto_increment} } values %$colinfos)
1804       ? 1
1805       : 0
1806   ;
1807
1808   # get a slice type index based on first row of data
1809   # a "column" in this context may refer to more than one bind value
1810   # e.g. \[ '?, ?', [...], [...] ]
1811   #
1812   # construct the value type index - a description of values types for every
1813   # per-column slice of $data:
1814   #
1815   # nonexistent - nonbind literal
1816   # 0 - regular value
1817   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1818   #
1819   # also construct the column hash to pass to the SQL generator. For plain
1820   # (non literal) values - convert the members of the first row into a
1821   # literal+bind combo, with extra positional info in the bind attr hashref.
1822   # This will allow us to match the order properly, and is so contrived
1823   # because a user-supplied literal/bind (or something else specific to a
1824   # resultsource and/or storage driver) can inject extra binds along the
1825   # way, so one can't rely on "shift positions" ordering at all. Also we
1826   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1827   # can be later matched up by address), because we want to supply a real
1828   # value on which perhaps e.g. datatype checks will be performed
1829   my ($proto_data, $value_type_idx);
1830   for my $i (@col_range) {
1831     my $colname = $cols->[$i];
1832     if (ref $data->[0][$i] eq 'SCALAR') {
1833       # no bind value at all - no type
1834
1835       $proto_data->{$colname} = $data->[0][$i];
1836     }
1837     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1838       # repack, so we don't end up mangling the original \[]
1839       my ($sql, @bind) = @${$data->[0][$i]};
1840
1841       # normalization of user supplied stuff
1842       my $resolved_bind = $self->_resolve_bindattrs(
1843         $source, \@bind, $colinfos,
1844       );
1845
1846       # store value-less (attrs only) bind info - we will be comparing all
1847       # supplied binds against this for sanity
1848       $value_type_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1849
1850       $proto_data->{$colname} = \[ $sql, map { [
1851         # inject slice order to use for $proto_bind construction
1852           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i }
1853             =>
1854           $resolved_bind->[$_][1]
1855         ] } (0 .. $#bind)
1856       ];
1857     }
1858     else {
1859       $value_type_idx->{$i} = 0;
1860
1861       $proto_data->{$colname} = \[ '?', [
1862         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1863           =>
1864         $data->[0][$i]
1865       ] ];
1866     }
1867   }
1868
1869   my ($sql, $proto_bind) = $self->_prep_for_execute (
1870     'insert',
1871     $source,
1872     [ $proto_data ],
1873   );
1874
1875   if (! @$proto_bind and keys %$value_type_idx) {
1876     # if the bindlist is empty and we had some dynamic binds, this means the
1877     # storage ate them away (e.g. the NoBindVars component) and interpolated
1878     # them directly into the SQL. This obviously can't be good for multi-inserts
1879     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1880   }
1881
1882   # sanity checks
1883   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1884   #
1885   # use an error reporting closure for convenience (less to pass)
1886   my $bad_slice_report_cref = sub {
1887     my ($msg, $r_idx, $c_idx) = @_;
1888     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1889       $msg,
1890       $cols->[$c_idx],
1891       do {
1892         require Data::Dumper::Concise;
1893         local $Data::Dumper::Maxdepth = 5;
1894         Data::Dumper::Concise::Dumper ({
1895           map { $cols->[$_] =>
1896             $data->[$r_idx][$_]
1897           } @col_range
1898         }),
1899       }
1900     );
1901   };
1902
1903   for my $col_idx (@col_range) {
1904     my $reference_val = $data->[0][$col_idx];
1905
1906     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
1907       my $val = $data->[$row_idx][$col_idx];
1908
1909       if (! exists $value_type_idx->{$col_idx}) { # literal no binds
1910         if (ref $val ne 'SCALAR') {
1911           $bad_slice_report_cref->(
1912             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
1913             $row_idx,
1914             $col_idx,
1915           );
1916         }
1917         elsif ($$val ne $$reference_val) {
1918           $bad_slice_report_cref->(
1919             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
1920             $row_idx,
1921             $col_idx,
1922           );
1923         }
1924       }
1925       elsif (! $value_type_idx->{$col_idx} ) {  # regular non-literal value
1926         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
1927           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
1928         }
1929       }
1930       else {  # binds from a \[], compare type and attrs
1931         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
1932           $bad_slice_report_cref->(
1933             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
1934             $row_idx,
1935             $col_idx,
1936           );
1937         }
1938         # start drilling down and bail out early on identical refs
1939         elsif (
1940           $reference_val != $val
1941             or
1942           $$reference_val != $$val
1943         ) {
1944           if (${$val}->[0] ne ${$reference_val}->[0]) {
1945             $bad_slice_report_cref->(
1946               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
1947               $row_idx,
1948               $col_idx,
1949             );
1950           }
1951           # need to check the bind attrs - a bind will happen only once for
1952           # the entire dataset, so any changes further down will be ignored.
1953           elsif (! Data::Compare::Compare(
1954             $value_type_idx->{$col_idx},
1955             [
1956               map
1957               { $_->[0] }
1958               @{$self->_resolve_bindattrs(
1959                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
1960               )}
1961             ],
1962           )) {
1963             $bad_slice_report_cref->(
1964               'Differing bind attributes on literal/bind values not supported',
1965               $row_idx,
1966               $col_idx,
1967             );
1968           }
1969         }
1970       }
1971     }
1972   }
1973
1974   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
1975   # are atomic (even if execute_for_fetch is a single call). Thus a safety
1976   # scope guard
1977   my $guard = $self->txn_scope_guard;
1978
1979   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
1980   my $sth = $self->_sth($sql);
1981   my $rv = do {
1982     if (@$proto_bind) {
1983       # proto bind contains the information on which pieces of $data to pull
1984       # $cols is passed in only for prettier error-reporting
1985       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
1986     }
1987     else {
1988       # bind_param_array doesn't work if there are no binds
1989       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1990     }
1991   };
1992
1993   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
1994
1995   $guard->commit;
1996
1997   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
1998 }
1999
2000 # execute_for_fetch is capable of returning data just fine (it means it
2001 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2002 # is the void-populate fast-path we will just ignore this altogether
2003 # for the time being.
2004 sub _dbh_execute_for_fetch {
2005   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2006
2007   my @idx_range = ( 0 .. $#$proto_bind );
2008
2009   # If we have any bind attributes to take care of, we will bind the
2010   # proto-bind data (which will never be used by execute_for_fetch)
2011   # However since column bindtypes are "sticky", this is sufficient
2012   # to get the DBD to apply the bindtype to all values later on
2013
2014   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2015
2016   for my $i (@idx_range) {
2017     $sth->bind_param (
2018       $i+1, # DBI bind indexes are 1-based
2019       $proto_bind->[$i][1],
2020       $bind_attrs->[$i],
2021     ) if defined $bind_attrs->[$i];
2022   }
2023
2024   # At this point $data slots named in the _bind_data_slice_idx of
2025   # each piece of $proto_bind are either \[]s or plain values to be
2026   # passed in. Construct the dispensing coderef. *NOTE* the order
2027   # of $data will differ from this of the ?s in the SQL (due to
2028   # alphabetical ordering by colname). We actually do want to
2029   # preserve this behavior so that prepare_cached has a better
2030   # chance of matching on unrelated calls
2031   my %data_reorder = map { $proto_bind->[$_][0]{_bind_data_slice_idx} => $_ } @idx_range;
2032
2033   my $fetch_row_idx = -1; # saner loop this way
2034   my $fetch_tuple = sub {
2035     return undef if ++$fetch_row_idx > $#$data;
2036
2037     return [ map
2038       { (ref $_ eq 'REF' and ref $$_ eq 'ARRAY')
2039         ? map { $_->[-1] } @{$$_}[1 .. $#$$_]
2040         : $_
2041       }
2042       map
2043         { $data->[$fetch_row_idx][$_]}
2044         sort
2045           { $data_reorder{$a} <=> $data_reorder{$b} }
2046           keys %data_reorder
2047     ];
2048   };
2049
2050   my $tuple_status = [];
2051   my ($rv, $err);
2052   try {
2053     $rv = $sth->execute_for_fetch(
2054       $fetch_tuple,
2055       $tuple_status,
2056     );
2057   }
2058   catch {
2059     $err = shift;
2060   };
2061
2062   # Not all DBDs are create equal. Some throw on error, some return
2063   # an undef $rv, and some set $sth->err - try whatever we can
2064   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2065     ! defined $err
2066       and
2067     ( !defined $rv or $sth->err )
2068   );
2069
2070   # Statement must finish even if there was an exception.
2071   try {
2072     $sth->finish
2073   }
2074   catch {
2075     $err = shift unless defined $err
2076   };
2077
2078   if (defined $err) {
2079     my $i = 0;
2080     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2081
2082     $self->throw_exception("Unexpected populate error: $err")
2083       if ($i > $#$tuple_status);
2084
2085     require Data::Dumper::Concise;
2086     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2087       ($tuple_status->[$i][1] || $err),
2088       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2089     );
2090   }
2091
2092   return $rv;
2093 }
2094
2095 sub _dbh_execute_inserts_with_no_binds {
2096   my ($self, $sth, $count) = @_;
2097
2098   my $err;
2099   try {
2100     my $dbh = $self->_get_dbh;
2101     local $dbh->{RaiseError} = 1;
2102     local $dbh->{PrintError} = 0;
2103
2104     $sth->execute foreach 1..$count;
2105   }
2106   catch {
2107     $err = shift;
2108   };
2109
2110   # Make sure statement is finished even if there was an exception.
2111   try {
2112     $sth->finish
2113   }
2114   catch {
2115     $err = shift unless defined $err;
2116   };
2117
2118   $self->throw_exception($err) if defined $err;
2119
2120   return $count;
2121 }
2122
2123 sub update {
2124   #my ($self, $source, @args) = @_;
2125   shift->_execute('update', @_);
2126 }
2127
2128
2129 sub delete {
2130   #my ($self, $source, @args) = @_;
2131   shift->_execute('delete', @_);
2132 }
2133
2134 sub _select {
2135   my $self = shift;
2136   $self->_execute($self->_select_args(@_));
2137 }
2138
2139 sub _select_args_to_query {
2140   my $self = shift;
2141
2142   $self->throw_exception(
2143     "Unable to generate limited query representation with 'software_limit' enabled"
2144   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2145
2146   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2147   #  = $self->_select_args($ident, $select, $cond, $attrs);
2148   my ($op, $ident, @args) =
2149     $self->_select_args(@_);
2150
2151   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2152   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2153   $prepared_bind ||= [];
2154
2155   return wantarray
2156     ? ($sql, $prepared_bind)
2157     : \[ "($sql)", @$prepared_bind ]
2158   ;
2159 }
2160
2161 sub _select_args {
2162   my ($self, $ident, $select, $where, $attrs) = @_;
2163
2164   my $sql_maker = $self->sql_maker;
2165   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2166
2167   $attrs = {
2168     %$attrs,
2169     select => $select,
2170     from => $ident,
2171     where => $where,
2172     $rs_alias && $alias2source->{$rs_alias}
2173       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2174       : ()
2175     ,
2176   };
2177
2178   # Sanity check the attributes (SQLMaker does it too, but
2179   # in case of a software_limit we'll never reach there)
2180   if (defined $attrs->{offset}) {
2181     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2182       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2183   }
2184
2185   if (defined $attrs->{rows}) {
2186     $self->throw_exception("The rows attribute must be a positive integer if present")
2187       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2188   }
2189   elsif ($attrs->{offset}) {
2190     # MySQL actually recommends this approach.  I cringe.
2191     $attrs->{rows} = $sql_maker->__max_int;
2192   }
2193
2194   my @limit;
2195
2196   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2197   # storage, unless software limit was requested
2198   if (
2199     #limited has_many
2200     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2201        ||
2202     # grouped prefetch (to satisfy group_by == select)
2203     ( $attrs->{group_by}
2204         &&
2205       @{$attrs->{group_by}}
2206         &&
2207       $attrs->{_prefetch_selector_range}
2208     )
2209   ) {
2210     ($ident, $select, $where, $attrs)
2211       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2212   }
2213   elsif (! $attrs->{software_limit} ) {
2214     push @limit, (
2215       $attrs->{rows} || (),
2216       $attrs->{offset} || (),
2217     );
2218   }
2219
2220   # try to simplify the joinmap further (prune unreferenced type-single joins)
2221   if (
2222     ref $ident
2223       and
2224     reftype $ident eq 'ARRAY'
2225       and
2226     @$ident != 1
2227   ) {
2228     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2229   }
2230
2231 ###
2232   # This would be the point to deflate anything found in $where
2233   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2234   # expect a row object. And all we have is a resultsource (it is trivial
2235   # to extract deflator coderefs via $alias2source above).
2236   #
2237   # I don't see a way forward other than changing the way deflators are
2238   # invoked, and that's just bad...
2239 ###
2240
2241   return ('select', $ident, $select, $where, $attrs, @limit);
2242 }
2243
2244 # Returns a counting SELECT for a simple count
2245 # query. Abstracted so that a storage could override
2246 # this to { count => 'firstcol' } or whatever makes
2247 # sense as a performance optimization
2248 sub _count_select {
2249   #my ($self, $source, $rs_attrs) = @_;
2250   return { count => '*' };
2251 }
2252
2253 sub source_bind_attributes {
2254   shift->throw_exception(
2255     'source_bind_attributes() was never meant to be a callable public method - '
2256    .'please contact the DBIC dev-team and describe your use case so that a reasonable '
2257    .'solution can be provided'
2258    ."\nhttp://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT"
2259   );
2260 }
2261
2262 =head2 select
2263
2264 =over 4
2265
2266 =item Arguments: $ident, $select, $condition, $attrs
2267
2268 =back
2269
2270 Handle a SQL select statement.
2271
2272 =cut
2273
2274 sub select {
2275   my $self = shift;
2276   my ($ident, $select, $condition, $attrs) = @_;
2277   return $self->cursor_class->new($self, \@_, $attrs);
2278 }
2279
2280 sub select_single {
2281   my $self = shift;
2282   my ($rv, $sth, @bind) = $self->_select(@_);
2283   my @row = $sth->fetchrow_array;
2284   my @nextrow = $sth->fetchrow_array if @row;
2285   if(@row && @nextrow) {
2286     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2287   }
2288   # Need to call finish() to work round broken DBDs
2289   $sth->finish();
2290   return @row;
2291 }
2292
2293 =head2 sql_limit_dialect
2294
2295 This is an accessor for the default SQL limit dialect used by a particular
2296 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2297 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2298 see L<DBIx::Class::SQLMaker::LimitDialects>.
2299
2300 =cut
2301
2302 sub _dbh_sth {
2303   my ($self, $dbh, $sql) = @_;
2304
2305   # 3 is the if_active parameter which avoids active sth re-use
2306   my $sth = $self->disable_sth_caching
2307     ? $dbh->prepare($sql)
2308     : $dbh->prepare_cached($sql, {}, 3);
2309
2310   # XXX You would think RaiseError would make this impossible,
2311   #  but apparently that's not true :(
2312   $self->throw_exception(
2313     $dbh->errstr
2314       ||
2315     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2316             .'an exception and/or setting $dbh->errstr',
2317       length ($sql) > 20
2318         ? substr($sql, 0, 20) . '...'
2319         : $sql
2320       ,
2321       'DBD::' . $dbh->{Driver}{Name},
2322     )
2323   ) if !$sth;
2324
2325   $sth;
2326 }
2327
2328 sub sth {
2329   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2330   shift->_sth(@_);
2331 }
2332
2333 sub _sth {
2334   my ($self, $sql) = @_;
2335   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2336 }
2337
2338 sub _dbh_columns_info_for {
2339   my ($self, $dbh, $table) = @_;
2340
2341   if ($dbh->can('column_info')) {
2342     my %result;
2343     my $caught;
2344     try {
2345       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2346       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2347       $sth->execute();
2348       while ( my $info = $sth->fetchrow_hashref() ){
2349         my %column_info;
2350         $column_info{data_type}   = $info->{TYPE_NAME};
2351         $column_info{size}      = $info->{COLUMN_SIZE};
2352         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2353         $column_info{default_value} = $info->{COLUMN_DEF};
2354         my $col_name = $info->{COLUMN_NAME};
2355         $col_name =~ s/^\"(.*)\"$/$1/;
2356
2357         $result{$col_name} = \%column_info;
2358       }
2359     } catch {
2360       $caught = 1;
2361     };
2362     return \%result if !$caught && scalar keys %result;
2363   }
2364
2365   my %result;
2366   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2367   $sth->execute;
2368   my @columns = @{$sth->{NAME_lc}};
2369   for my $i ( 0 .. $#columns ){
2370     my %column_info;
2371     $column_info{data_type} = $sth->{TYPE}->[$i];
2372     $column_info{size} = $sth->{PRECISION}->[$i];
2373     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2374
2375     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2376       $column_info{data_type} = $1;
2377       $column_info{size}    = $2;
2378     }
2379
2380     $result{$columns[$i]} = \%column_info;
2381   }
2382   $sth->finish;
2383
2384   foreach my $col (keys %result) {
2385     my $colinfo = $result{$col};
2386     my $type_num = $colinfo->{data_type};
2387     my $type_name;
2388     if(defined $type_num && $dbh->can('type_info')) {
2389       my $type_info = $dbh->type_info($type_num);
2390       $type_name = $type_info->{TYPE_NAME} if $type_info;
2391       $colinfo->{data_type} = $type_name if $type_name;
2392     }
2393   }
2394
2395   return \%result;
2396 }
2397
2398 sub columns_info_for {
2399   my ($self, $table) = @_;
2400   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2401 }
2402
2403 =head2 last_insert_id
2404
2405 Return the row id of the last insert.
2406
2407 =cut
2408
2409 sub _dbh_last_insert_id {
2410     my ($self, $dbh, $source, $col) = @_;
2411
2412     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2413
2414     return $id if defined $id;
2415
2416     my $class = ref $self;
2417     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2418 }
2419
2420 sub last_insert_id {
2421   my $self = shift;
2422   $self->_dbh_last_insert_id ($self->_dbh, @_);
2423 }
2424
2425 =head2 _native_data_type
2426
2427 =over 4
2428
2429 =item Arguments: $type_name
2430
2431 =back
2432
2433 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2434 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2435 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2436
2437 The default implementation returns C<undef>, implement in your Storage driver if
2438 you need this functionality.
2439
2440 Should map types from other databases to the native RDBMS type, for example
2441 C<VARCHAR2> to C<VARCHAR>.
2442
2443 Types with modifiers should map to the underlying data type. For example,
2444 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2445
2446 Composite types should map to the container type, for example
2447 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2448
2449 =cut
2450
2451 sub _native_data_type {
2452   #my ($self, $data_type) = @_;
2453   return undef
2454 }
2455
2456 # Check if placeholders are supported at all
2457 sub _determine_supports_placeholders {
2458   my $self = shift;
2459   my $dbh  = $self->_get_dbh;
2460
2461   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2462   # but it is inaccurate more often than not
2463   return try {
2464     local $dbh->{PrintError} = 0;
2465     local $dbh->{RaiseError} = 1;
2466     $dbh->do('select ?', {}, 1);
2467     1;
2468   }
2469   catch {
2470     0;
2471   };
2472 }
2473
2474 # Check if placeholders bound to non-string types throw exceptions
2475 #
2476 sub _determine_supports_typeless_placeholders {
2477   my $self = shift;
2478   my $dbh  = $self->_get_dbh;
2479
2480   return try {
2481     local $dbh->{PrintError} = 0;
2482     local $dbh->{RaiseError} = 1;
2483     # this specifically tests a bind that is NOT a string
2484     $dbh->do('select 1 where 1 = ?', {}, 1);
2485     1;
2486   }
2487   catch {
2488     0;
2489   };
2490 }
2491
2492 =head2 sqlt_type
2493
2494 Returns the database driver name.
2495
2496 =cut
2497
2498 sub sqlt_type {
2499   shift->_get_dbh->{Driver}->{Name};
2500 }
2501
2502 =head2 bind_attribute_by_data_type
2503
2504 Given a datatype from column info, returns a database specific bind
2505 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2506 let the database planner just handle it.
2507
2508 Generally only needed for special case column types, like bytea in postgres.
2509
2510 =cut
2511
2512 sub bind_attribute_by_data_type {
2513     return;
2514 }
2515
2516 =head2 is_datatype_numeric
2517
2518 Given a datatype from column_info, returns a boolean value indicating if
2519 the current RDBMS considers it a numeric value. This controls how
2520 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2521 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2522 be performed instead of the usual C<eq>.
2523
2524 =cut
2525
2526 sub is_datatype_numeric {
2527   #my ($self, $dt) = @_;
2528
2529   return 0 unless $_[1];
2530
2531   $_[1] =~ /^ (?:
2532     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2533   ) $/ix;
2534 }
2535
2536
2537 =head2 create_ddl_dir
2538
2539 =over 4
2540
2541 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2542
2543 =back
2544
2545 Creates a SQL file based on the Schema, for each of the specified
2546 database engines in C<\@databases> in the given directory.
2547 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2548
2549 Given a previous version number, this will also create a file containing
2550 the ALTER TABLE statements to transform the previous schema into the
2551 current one. Note that these statements may contain C<DROP TABLE> or
2552 C<DROP COLUMN> statements that can potentially destroy data.
2553
2554 The file names are created using the C<ddl_filename> method below, please
2555 override this method in your schema if you would like a different file
2556 name format. For the ALTER file, the same format is used, replacing
2557 $version in the name with "$preversion-$version".
2558
2559 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2560 The most common value for this would be C<< { add_drop_table => 1 } >>
2561 to have the SQL produced include a C<DROP TABLE> statement for each table
2562 created. For quoting purposes supply C<quote_table_names> and
2563 C<quote_field_names>.
2564
2565 If no arguments are passed, then the following default values are assumed:
2566
2567 =over 4
2568
2569 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2570
2571 =item version    - $schema->schema_version
2572
2573 =item directory  - './'
2574
2575 =item preversion - <none>
2576
2577 =back
2578
2579 By default, C<\%sqlt_args> will have
2580
2581  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2582
2583 merged with the hash passed in. To disable any of those features, pass in a
2584 hashref like the following
2585
2586  { ignore_constraint_names => 0, # ... other options }
2587
2588
2589 WARNING: You are strongly advised to check all SQL files created, before applying
2590 them.
2591
2592 =cut
2593
2594 sub create_ddl_dir {
2595   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2596
2597   unless ($dir) {
2598     carp "No directory given, using ./\n";
2599     $dir = './';
2600   } else {
2601       -d $dir
2602         or
2603       (require File::Path and File::Path::make_path ("$dir"))  # make_path does not like objects (i.e. Path::Class::Dir)
2604         or
2605       $self->throw_exception(
2606         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2607       );
2608   }
2609
2610   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2611
2612   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2613   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2614
2615   my $schema_version = $schema->schema_version || '1.x';
2616   $version ||= $schema_version;
2617
2618   $sqltargs = {
2619     add_drop_table => 1,
2620     ignore_constraint_names => 1,
2621     ignore_index_names => 1,
2622     %{$sqltargs || {}}
2623   };
2624
2625   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2626     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2627   }
2628
2629   my $sqlt = SQL::Translator->new( $sqltargs );
2630
2631   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2632   my $sqlt_schema = $sqlt->translate({ data => $schema })
2633     or $self->throw_exception ($sqlt->error);
2634
2635   foreach my $db (@$databases) {
2636     $sqlt->reset();
2637     $sqlt->{schema} = $sqlt_schema;
2638     $sqlt->producer($db);
2639
2640     my $file;
2641     my $filename = $schema->ddl_filename($db, $version, $dir);
2642     if (-e $filename && ($version eq $schema_version )) {
2643       # if we are dumping the current version, overwrite the DDL
2644       carp "Overwriting existing DDL file - $filename";
2645       unlink($filename);
2646     }
2647
2648     my $output = $sqlt->translate;
2649     if(!$output) {
2650       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2651       next;
2652     }
2653     if(!open($file, ">$filename")) {
2654       $self->throw_exception("Can't open $filename for writing ($!)");
2655       next;
2656     }
2657     print $file $output;
2658     close($file);
2659
2660     next unless ($preversion);
2661
2662     require SQL::Translator::Diff;
2663
2664     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2665     if(!-e $prefilename) {
2666       carp("No previous schema file found ($prefilename)");
2667       next;
2668     }
2669
2670     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2671     if(-e $difffile) {
2672       carp("Overwriting existing diff file - $difffile");
2673       unlink($difffile);
2674     }
2675
2676     my $source_schema;
2677     {
2678       my $t = SQL::Translator->new($sqltargs);
2679       $t->debug( 0 );
2680       $t->trace( 0 );
2681
2682       $t->parser( $db )
2683         or $self->throw_exception ($t->error);
2684
2685       my $out = $t->translate( $prefilename )
2686         or $self->throw_exception ($t->error);
2687
2688       $source_schema = $t->schema;
2689
2690       $source_schema->name( $prefilename )
2691         unless ( $source_schema->name );
2692     }
2693
2694     # The "new" style of producers have sane normalization and can support
2695     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2696     # And we have to diff parsed SQL against parsed SQL.
2697     my $dest_schema = $sqlt_schema;
2698
2699     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2700       my $t = SQL::Translator->new($sqltargs);
2701       $t->debug( 0 );
2702       $t->trace( 0 );
2703
2704       $t->parser( $db )
2705         or $self->throw_exception ($t->error);
2706
2707       my $out = $t->translate( $filename )
2708         or $self->throw_exception ($t->error);
2709
2710       $dest_schema = $t->schema;
2711
2712       $dest_schema->name( $filename )
2713         unless $dest_schema->name;
2714     }
2715
2716     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2717                                                   $dest_schema,   $db,
2718                                                   $sqltargs
2719                                                  );
2720     if(!open $file, ">$difffile") {
2721       $self->throw_exception("Can't write to $difffile ($!)");
2722       next;
2723     }
2724     print $file $diff;
2725     close($file);
2726   }
2727 }
2728
2729 =head2 deployment_statements
2730
2731 =over 4
2732
2733 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2734
2735 =back
2736
2737 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2738
2739 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2740 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2741
2742 C<$directory> is used to return statements from files in a previously created
2743 L</create_ddl_dir> directory and is optional. The filenames are constructed
2744 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2745
2746 If no C<$directory> is specified then the statements are constructed on the
2747 fly using L<SQL::Translator> and C<$version> is ignored.
2748
2749 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2750
2751 =cut
2752
2753 sub deployment_statements {
2754   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2755   $type ||= $self->sqlt_type;
2756   $version ||= $schema->schema_version || '1.x';
2757   $dir ||= './';
2758   my $filename = $schema->ddl_filename($type, $version, $dir);
2759   if(-f $filename)
2760   {
2761       # FIXME replace this block when a proper sane sql parser is available
2762       my $file;
2763       open($file, "<$filename")
2764         or $self->throw_exception("Can't open $filename ($!)");
2765       my @rows = <$file>;
2766       close($file);
2767       return join('', @rows);
2768   }
2769
2770   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2771     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2772   }
2773
2774   # sources needs to be a parser arg, but for simplicty allow at top level
2775   # coming in
2776   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2777       if exists $sqltargs->{sources};
2778
2779   my $tr = SQL::Translator->new(
2780     producer => "SQL::Translator::Producer::${type}",
2781     %$sqltargs,
2782     parser => 'SQL::Translator::Parser::DBIx::Class',
2783     data => $schema,
2784   );
2785
2786   return preserve_context {
2787     $tr->translate
2788   } after => sub {
2789     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2790       unless defined $_[0];
2791   };
2792 }
2793
2794 # FIXME deploy() currently does not accurately report sql errors
2795 # Will always return true while errors are warned
2796 sub deploy {
2797   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2798   my $deploy = sub {
2799     my $line = shift;
2800     return if(!$line);
2801     return if($line =~ /^--/);
2802     # next if($line =~ /^DROP/m);
2803     return if($line =~ /^BEGIN TRANSACTION/m);
2804     return if($line =~ /^COMMIT/m);
2805     return if $line =~ /^\s+$/; # skip whitespace only
2806     $self->_query_start($line);
2807     try {
2808       # do a dbh_do cycle here, as we need some error checking in
2809       # place (even though we will ignore errors)
2810       $self->dbh_do (sub { $_[1]->do($line) });
2811     } catch {
2812       carp qq{$_ (running "${line}")};
2813     };
2814     $self->_query_end($line);
2815   };
2816   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2817   if (@statements > 1) {
2818     foreach my $statement (@statements) {
2819       $deploy->( $statement );
2820     }
2821   }
2822   elsif (@statements == 1) {
2823     # split on single line comments and end of statements
2824     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2825       $deploy->( $line );
2826     }
2827   }
2828 }
2829
2830 =head2 datetime_parser
2831
2832 Returns the datetime parser class
2833
2834 =cut
2835
2836 sub datetime_parser {
2837   my $self = shift;
2838   return $self->{datetime_parser} ||= do {
2839     $self->build_datetime_parser(@_);
2840   };
2841 }
2842
2843 =head2 datetime_parser_type
2844
2845 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2846
2847 =head2 build_datetime_parser
2848
2849 See L</datetime_parser>
2850
2851 =cut
2852
2853 sub build_datetime_parser {
2854   my $self = shift;
2855   my $type = $self->datetime_parser_type(@_);
2856   return $type;
2857 }
2858
2859
2860 =head2 is_replicating
2861
2862 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2863 replicate from a master database.  Default is undef, which is the result
2864 returned by databases that don't support replication.
2865
2866 =cut
2867
2868 sub is_replicating {
2869     return;
2870
2871 }
2872
2873 =head2 lag_behind_master
2874
2875 Returns a number that represents a certain amount of lag behind a master db
2876 when a given storage is replicating.  The number is database dependent, but
2877 starts at zero and increases with the amount of lag. Default in undef
2878
2879 =cut
2880
2881 sub lag_behind_master {
2882     return;
2883 }
2884
2885 =head2 relname_to_table_alias
2886
2887 =over 4
2888
2889 =item Arguments: $relname, $join_count
2890
2891 =back
2892
2893 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2894 queries.
2895
2896 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2897 way these aliases are named.
2898
2899 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2900 otherwise C<"$relname">.
2901
2902 =cut
2903
2904 sub relname_to_table_alias {
2905   my ($self, $relname, $join_count) = @_;
2906
2907   my $alias = ($join_count && $join_count > 1 ?
2908     join('_', $relname, $join_count) : $relname);
2909
2910   return $alias;
2911 }
2912
2913 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
2914 # version and it may be necessary to amend or override it for a specific storage
2915 # if such binds are necessary.
2916 sub _max_column_bytesize {
2917   my ($self, $attr) = @_;
2918
2919   my $max_size;
2920
2921   if ($attr->{sqlt_datatype}) {
2922     my $data_type = lc($attr->{sqlt_datatype});
2923
2924     if ($attr->{sqlt_size}) {
2925
2926       # String/sized-binary types
2927       if ($data_type =~ /^(?:
2928           l? (?:var)? char(?:acter)? (?:\s*varying)?
2929             |
2930           (?:var)? binary (?:\s*varying)?
2931             |
2932           raw
2933         )\b/x
2934       ) {
2935         $max_size = $attr->{sqlt_size};
2936       }
2937       # Other charset/unicode types, assume scale of 4
2938       elsif ($data_type =~ /^(?:
2939           national \s* character (?:\s*varying)?
2940             |
2941           nchar
2942             |
2943           univarchar
2944             |
2945           nvarchar
2946         )\b/x
2947       ) {
2948         $max_size = $attr->{sqlt_size} * 4;
2949       }
2950     }
2951
2952     if (!$max_size and !$self->_is_lob_type($data_type)) {
2953       $max_size = 100 # for all other (numeric?) datatypes
2954     }
2955   }
2956
2957   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
2958 }
2959
2960 # Determine if a data_type is some type of BLOB
2961 sub _is_lob_type {
2962   my ($self, $data_type) = @_;
2963   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
2964     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
2965                                   |varchar|character\s*varying|nvarchar
2966                                   |national\s*character\s*varying))?\z/xi);
2967 }
2968
2969 sub _is_binary_lob_type {
2970   my ($self, $data_type) = @_;
2971   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
2972     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
2973 }
2974
2975 sub _is_text_lob_type {
2976   my ($self, $data_type) = @_;
2977   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
2978     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
2979                         |national\s*character\s*varying))\z/xi);
2980 }
2981
2982 # Determine if a data_type is some type of a binary type
2983 sub _is_binary_type {
2984   my ($self, $data_type) = @_;
2985   $data_type && ($self->_is_binary_lob_type($data_type)
2986     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
2987 }
2988
2989 1;
2990
2991 =head1 USAGE NOTES
2992
2993 =head2 DBIx::Class and AutoCommit
2994
2995 DBIx::Class can do some wonderful magic with handling exceptions,
2996 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2997 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
2998 transaction support.
2999
3000 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3001 in an assumed transaction between commits, and you're telling us you'd
3002 like to manage that manually.  A lot of the magic protections offered by
3003 this module will go away.  We can't protect you from exceptions due to database
3004 disconnects because we don't know anything about how to restart your
3005 transactions.  You're on your own for handling all sorts of exceptional
3006 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3007 be with raw DBI.
3008
3009
3010 =head1 AUTHORS
3011
3012 Matt S. Trout <mst@shadowcatsystems.co.uk>
3013
3014 Andy Grundman <andy@hybridized.org>
3015
3016 =head1 LICENSE
3017
3018 You may distribute this code under the same terms as Perl itself.
3019
3020 =cut