lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(
  17   quote_sub perlstring serialize
  18   dbic_internal_try
  19   detected_reinvoked_destructor scope_guard
  20 );
  21 use namespace::clean;
  22
  23 # default cursor class, overridable in connect_info attributes
  24 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  25
  26 __PACKAGE__->mk_group_accessors('inherited' => qw/
  27   sql_limit_dialect sql_quote_char sql_name_sep
  28 /);
  29
  30 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  31
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  33 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  34
  35 __PACKAGE__->sql_name_sep('.');
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/
  38   _connect_info _dbic_connect_attributes _driver_determined
  39   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  40   _perform_autoinc_retrieval _autoinc_supplied_for_op
  41 /);
  42
  43 # the values for these accessors are picked out (and deleted) from
  44 # the attribute hashref passed to connect_info
  45 my @storage_options = qw/
  46   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  47   disable_sth_caching unsafe auto_savepoint
  48 /;
  49 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  50
  51
  52 # capability definitions, using a 2-tiered accessor system
  53 # The rationale is:
  54 #
  55 # A driver/user may define _use_X, which blindly without any checks says:
  56 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  57 # type accessor)
  58 #
  59 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  60 # accessor, which in turn calls _determine_supports_X, and stores the return
  61 # in a special slot on the storage object, which is wiped every time a $dbh
  62 # reconnection takes place (it is not guaranteed that upon reconnection we
  63 # will get the same rdbms version). _determine_supports_X does not need to
  64 # exist on a driver, as we ->can for it before calling.
  65
  66 my @capabilities = (qw/
  67   insert_returning
  68   insert_returning_bound
  69
  70   multicolumn_in
  71
  72   placeholders
  73   typeless_placeholders
  74
  75   join_optimizer
  76 /);
  77 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  78 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  79
  80 # on by default, not strictly a capability (pending rewrite)
  81 __PACKAGE__->_use_join_optimizer (1);
  82 sub _determine_supports_join_optimizer { 1 };
  83
  84 # Each of these methods need _determine_driver called before itself
  85 # in order to function reliably. We also need to separate accessors
  86 # from plain old method calls, since an accessor called as a setter
  87 # does *not* need the driver determination loop fired (and in fact
  88 # can produce hard to find bugs, like e.g. losing on_connect_*
  89 # semantics on fresh connections)
  90 #
  91 # The construct below is simply a parameterized around()
  92 my $storage_accessor_idx = { map { $_ => 1 } qw(
  93   sqlt_type
  94   datetime_parser_type
  95
  96   sql_maker
  97   cursor_class
  98 )};
  99 for my $meth (keys %$storage_accessor_idx, qw(
 100   deployment_statements
 101
 102   build_datetime_parser
 103
 104   txn_begin
 105
 106   insert
 107   update
 108   delete
 109   select
 110   select_single
 111
 112   _insert_bulk
 113
 114   with_deferred_fk_checks
 115
 116   get_use_dbms_capability
 117   get_dbms_capability
 118
 119   _server_info
 120   _get_server_version
 121 )) {
 122
 123   my $orig = __PACKAGE__->can ($meth)
 124     or die "$meth is not a ::Storage::DBI method!";
 125
 126   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 127
 128   quote_sub
 129     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 130
 131     if (
 132       # if this is an actual *setter* - just set it, no need to connect
 133       # and determine the driver
 134       !( %1$s and @_ > 1 )
 135         and
 136       # only fire when invoked on an instance, a valid class-based invocation
 137       # would e.g. be setting a default for an inherited accessor
 138       ref $_[0]
 139         and
 140       ! $_[0]->{_driver_determined}
 141         and
 142       ! $_[0]->{_in_determine_driver}
 143         and
 144       # Only try to determine stuff if we have *something* that either is or can
 145       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 146       # to still be marginally useful
 147       $_[0]->_dbi_connect_info->[0]
 148     ) {
 149       $_[0]->_determine_driver;
 150
 151       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 152       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 153
 154       my $cref = $_[0]->can(%2$s);
 155       goto $cref;
 156     }
 157
 158     goto $orig;
 159 EOC
 160 }
 161
 162 =head1 NAME
 163
 164 DBIx::Class::Storage::DBI - DBI storage handler
 165
 166 =head1 SYNOPSIS
 167
 168   my $schema = MySchema->connect('dbi:SQLite:my.db');
 169
 170   $schema->storage->debug(1);
 171
 172   my @stuff = $schema->storage->dbh_do(
 173     sub {
 174       my ($storage, $dbh, @args) = @_;
 175       $dbh->do("DROP TABLE authors");
 176     },
 177     @column_list
 178   );
 179
 180   $schema->resultset('Book')->search({
 181      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 182   });
 183
 184 =head1 DESCRIPTION
 185
 186 This class represents the connection to an RDBMS via L<DBI>.  See
 187 L<DBIx::Class::Storage> for general information.  This pod only
 188 documents DBI-specific methods and behaviors.
 189
 190 =head1 METHODS
 191
 192 =cut
 193
 194 sub new {
 195   my $new = shift->next::method(@_);
 196
 197   $new->_sql_maker_opts({});
 198   $new->_dbh_details({});
 199   $new->{_in_do_block} = 0;
 200
 201   # read below to see what this does
 202   $new->_arm_global_destructor;
 203
 204   $new;
 205 }
 206
 207 # This is hack to work around perl shooting stuff in random
 208 # order on exit(). If we do not walk the remaining storage
 209 # objects in an END block, there is a *small but real* chance
 210 # of a fork()ed child to kill the parent's shared DBI handle,
 211 # *before perl reaches the DESTROY in this package*
 212 # Yes, it is ugly and effective.
 213 # Additionally this registry is used by the CLONE method to
 214 # make sure no handles are shared between threads
 215 {
 216   my %seek_and_destroy;
 217
 218   sub _arm_global_destructor {
 219
 220     # quick "garbage collection" pass - prevents the registry
 221     # from slowly growing with a bunch of undef-valued keys
 222     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 223       for keys %seek_and_destroy;
 224
 225     weaken (
 226       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 227     );
 228   }
 229
 230   END {
 231
 232     if(
 233       ! DBIx::Class::_ENV_::BROKEN_FORK
 234         and
 235       my @instances = grep { defined $_ } values %seek_and_destroy
 236     ) {
 237       local $?; # just in case the DBI destructor changes it somehow
 238
 239       # disarm the handle if not native to this process (see comment on top)
 240       $_->_verify_pid for @instances;
 241     }
 242   }
 243
 244   sub CLONE {
 245     # As per DBI's recommendation, DBIC disconnects all handles as
 246     # soon as possible (DBIC will reconnect only on demand from within
 247     # the thread)
 248     my @instances = grep { defined $_ } values %seek_and_destroy;
 249     %seek_and_destroy = ();
 250
 251     for (@instances) {
 252       $_->_dbh(undef);
 253       $_->disconnect;
 254
 255       # properly renumber existing refs
 256       $_->_arm_global_destructor
 257     }
 258   }
 259 }
 260
 261 sub DESTROY {
 262   return if &detected_reinvoked_destructor;
 263
 264   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 265
 266   # some databases spew warnings on implicit disconnect
 267   return unless defined $_[0]->_dbh;
 268
 269   local $SIG{__WARN__} = sub {};
 270   $_[0]->_dbh(undef);
 271   # not calling ->disconnect here - we are being destroyed - nothing to reset
 272
 273   # this op is necessary, since the very last perl runtime statement
 274   # triggers a global destruction shootout, and the $SIG localization
 275   # may very well be destroyed before perl actually gets to do the
 276   # $dbh undef
 277   1;
 278 }
 279
 280 # handle pid changes correctly - do not destroy parent's connection
 281 sub _verify_pid {
 282
 283   my $pid = $_[0]->_conn_pid;
 284
 285   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 286     $dbh->{InactiveDestroy} = 1;
 287     $_[0]->_dbh(undef);
 288     $_[0]->disconnect;
 289   }
 290
 291   return;
 292 }
 293
 294 =head2 connect_info
 295
 296 This method is normally called by L<DBIx::Class::Schema/connection>, which
 297 encapsulates its argument list in an arrayref before passing them here.
 298
 299 The argument list may contain:
 300
 301 =over
 302
 303 =item *
 304
 305 The same 4-element argument set one would normally pass to
 306 L<DBI/connect>, optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes>
 308 recognized by DBIx::Class:
 309
 310   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single code reference which returns a connected
 315 L<DBI database handle|DBI/connect> optionally followed by
 316 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 317 by DBIx::Class:
 318
 319   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 320
 321 =item *
 322
 323 A single hashref with all the attributes and the dsn/user/password
 324 mixed together:
 325
 326   $connect_info_args = [{
 327     dsn => $dsn,
 328     user => $user,
 329     password => $pass,
 330     %dbi_attributes,
 331     %extra_attributes,
 332   }];
 333
 334   $connect_info_args = [{
 335     dbh_maker => sub { DBI->connect (...) },
 336     %dbi_attributes,
 337     %extra_attributes,
 338   }];
 339
 340 This is particularly useful for L<Catalyst> based applications, allowing the
 341 following config (L<Config::General> style):
 342
 343   <Model::DB>
 344     schema_class   App::DB
 345     <connect_info>
 346       dsn          dbi:mysql:database=test
 347       user         testuser
 348       password     TestPass
 349       AutoCommit   1
 350     </connect_info>
 351   </Model::DB>
 352
 353 The C<dsn>/C<user>/C<password> combination can be substituted by the
 354 C<dbh_maker> key whose value is a coderef that returns a connected
 355 L<DBI database handle|DBI/connect>
 356
 357 =back
 358
 359 Please note that the L<DBI> docs recommend that you always explicitly
 360 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 361 recommends that it be set to I<1>, and that you perform transactions
 362 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 363 to I<1> if you do not do explicitly set it to zero.  This is the default
 364 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 365
 366 =head3 DBIx::Class specific connection attributes
 367
 368 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 369 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 370 the following connection options. These options can be mixed in with your other
 371 L<DBI> connection attributes, or placed in a separate hashref
 372 (C<\%extra_attributes>) as shown above.
 373
 374 Every time C<connect_info> is invoked, any previous settings for
 375 these options will be cleared before setting the new ones, regardless of
 376 whether any options are specified in the new C<connect_info>.
 377
 378
 379 =over
 380
 381 =item on_connect_do
 382
 383 Specifies things to do immediately after connecting or re-connecting to
 384 the database.  Its value may contain:
 385
 386 =over
 387
 388 =item a scalar
 389
 390 This contains one SQL statement to execute.
 391
 392 =item an array reference
 393
 394 This contains SQL statements to execute in order.  Each element contains
 395 a string or a code reference that returns a string.
 396
 397 =item a code reference
 398
 399 This contains some code to execute.  Unlike code references within an
 400 array reference, its return value is ignored.
 401
 402 =back
 403
 404 =item on_disconnect_do
 405
 406 Takes arguments in the same form as L</on_connect_do> and executes them
 407 immediately before disconnecting from the database.
 408
 409 Note, this only runs if you explicitly call L</disconnect> on the
 410 storage object.
 411
 412 =item on_connect_call
 413
 414 A more generalized form of L</on_connect_do> that calls the specified
 415 C<connect_call_METHOD> methods in your storage driver.
 416
 417   on_connect_do => 'select 1'
 418
 419 is equivalent to:
 420
 421   on_connect_call => [ [ do_sql => 'select 1' ] ]
 422
 423 Its values may contain:
 424
 425 =over
 426
 427 =item a scalar
 428
 429 Will call the C<connect_call_METHOD> method.
 430
 431 =item a code reference
 432
 433 Will execute C<< $code->($storage) >>
 434
 435 =item an array reference
 436
 437 Each value can be a method name or code reference.
 438
 439 =item an array of arrays
 440
 441 For each array, the first item is taken to be the C<connect_call_> method name
 442 or code reference, and the rest are parameters to it.
 443
 444 =back
 445
 446 Some predefined storage methods you may use:
 447
 448 =over
 449
 450 =item do_sql
 451
 452 Executes a SQL string or a code reference that returns a SQL string. This is
 453 what L</on_connect_do> and L</on_disconnect_do> use.
 454
 455 It can take:
 456
 457 =over
 458
 459 =item a scalar
 460
 461 Will execute the scalar as SQL.
 462
 463 =item an arrayref
 464
 465 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 466 attributes hashref and bind values.
 467
 468 =item a code reference
 469
 470 Will execute C<< $code->($storage) >> and execute the return array refs as
 471 above.
 472
 473 =back
 474
 475 =item datetime_setup
 476
 477 Execute any statements necessary to initialize the database session to return
 478 and accept datetime/timestamp values used with
 479 L<DBIx::Class::InflateColumn::DateTime>.
 480
 481 Only necessary for some databases, see your specific storage driver for
 482 implementation details.
 483
 484 =back
 485
 486 =item on_disconnect_call
 487
 488 Takes arguments in the same form as L</on_connect_call> and executes them
 489 immediately before disconnecting from the database.
 490
 491 Calls the C<disconnect_call_METHOD> methods as opposed to the
 492 C<connect_call_METHOD> methods called by L</on_connect_call>.
 493
 494 Note, this only runs if you explicitly call L</disconnect> on the
 495 storage object.
 496
 497 =item disable_sth_caching
 498
 499 If set to a true value, this option will disable the caching of
 500 statement handles via L<DBI/prepare_cached>.
 501
 502 =item limit_dialect
 503
 504 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 505 default L</sql_limit_dialect> setting of the storage (if any). For a list
 506 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 507
 508 =item quote_names
 509
 510 When true automatically sets L</quote_char> and L</name_sep> to the characters
 511 appropriate for your particular RDBMS. This option is preferred over specifying
 512 L</quote_char> directly.
 513
 514 =item quote_char
 515
 516 Specifies what characters to use to quote table and column names.
 517
 518 C<quote_char> expects either a single character, in which case is it
 519 is placed on either side of the table/column name, or an arrayref of length
 520 2 in which case the table/column name is placed between the elements.
 521
 522 For example under MySQL you should use C<< quote_char => '`' >>, and for
 523 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 524
 525 =item name_sep
 526
 527 This parameter is only useful in conjunction with C<quote_char>, and is used to
 528 specify the character that separates elements (schemas, tables, columns) from
 529 each other. If unspecified it defaults to the most commonly used C<.>.
 530
 531 =item unsafe
 532
 533 This Storage driver normally installs its own C<HandleError>, sets
 534 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 535 all database handles, including those supplied by a coderef.  It does this
 536 so that it can have consistent and useful error behavior.
 537
 538 If you set this option to a true value, Storage will not do its usual
 539 modifications to the database handle's attributes, and instead relies on
 540 the settings in your connect_info DBI options (or the values you set in
 541 your connection coderef, in the case that you are connecting via coderef).
 542
 543 Note that your custom settings can cause Storage to malfunction,
 544 especially if you set a C<HandleError> handler that suppresses exceptions
 545 and/or disable C<RaiseError>.
 546
 547 =item auto_savepoint
 548
 549 If this option is true, L<DBIx::Class> will use savepoints when nesting
 550 transactions, making it possible to recover from failure in the inner
 551 transaction without having to abort all outer transactions.
 552
 553 =item cursor_class
 554
 555 Use this argument to supply a cursor class other than the default
 556 L<DBIx::Class::Storage::DBI::Cursor>.
 557
 558 =back
 559
 560 Some real-life examples of arguments to L</connect_info> and
 561 L<DBIx::Class::Schema/connect>
 562
 563   # Simple SQLite connection
 564   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 565
 566   # Connect via subref
 567   ->connect_info([ sub { DBI->connect(...) } ]);
 568
 569   # Connect via subref in hashref
 570   ->connect_info([{
 571     dbh_maker => sub { DBI->connect(...) },
 572     on_connect_do => 'alter session ...',
 573   }]);
 574
 575   # A bit more complicated
 576   ->connect_info(
 577     [
 578       'dbi:Pg:dbname=foo',
 579       'postgres',
 580       'my_pg_password',
 581       { AutoCommit => 1 },
 582       { quote_char => q{"} },
 583     ]
 584   );
 585
 586   # Equivalent to the previous example
 587   ->connect_info(
 588     [
 589       'dbi:Pg:dbname=foo',
 590       'postgres',
 591       'my_pg_password',
 592       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 593     ]
 594   );
 595
 596   # Same, but with hashref as argument
 597   # See parse_connect_info for explanation
 598   ->connect_info(
 599     [{
 600       dsn         => 'dbi:Pg:dbname=foo',
 601       user        => 'postgres',
 602       password    => 'my_pg_password',
 603       AutoCommit  => 1,
 604       quote_char  => q{"},
 605       name_sep    => q{.},
 606     }]
 607   );
 608
 609   # Subref + DBIx::Class-specific connection options
 610   ->connect_info(
 611     [
 612       sub { DBI->connect(...) },
 613       {
 614           quote_char => q{`},
 615           name_sep => q{@},
 616           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 617           disable_sth_caching => 1,
 618       },
 619     ]
 620   );
 621
 622
 623
 624 =cut
 625
 626 sub connect_info {
 627   my ($self, $info) = @_;
 628
 629   return $self->_connect_info if !$info;
 630
 631   $self->_connect_info($info); # copy for _connect_info
 632
 633   $info = $self->_normalize_connect_info($info)
 634     if ref $info eq 'ARRAY';
 635
 636   my %attrs = (
 637     %{ $self->_default_dbi_connect_attributes || {} },
 638     %{ $info->{attributes} || {} },
 639   );
 640
 641   my @args = @{ $info->{arguments} };
 642
 643   if (keys %attrs and ref $args[0] ne 'CODE') {
 644     carp_unique (
 645         'You provided explicit AutoCommit => 0 in your connection_info. '
 646       . 'This is almost universally a bad idea (see the footnotes of '
 647       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 648       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 649       . 'this warning.'
 650     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 651
 652     push @args, \%attrs if keys %attrs;
 653   }
 654
 655   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 656   # OR a single-element coderef-based $dbh factory
 657   $self->_dbi_connect_info(\@args);
 658
 659   # extract the individual storage options
 660   for my $storage_opt (keys %{ $info->{storage_options} }) {
 661     my $value = $info->{storage_options}{$storage_opt};
 662
 663     $self->$storage_opt($value);
 664   }
 665
 666   # Extract the individual sqlmaker options
 667   #
 668   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 669   #  the new set of options
 670   $self->_sql_maker(undef);
 671   $self->_sql_maker_opts({});
 672
 673   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 674     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 675
 676     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 677   }
 678
 679   # FIXME - dirty:
 680   # save attributes in a separate accessor so they are always
 681   # introspectable, even in case of a CODE $dbhmaker
 682   $self->_dbic_connect_attributes (\%attrs);
 683
 684   return $self->_connect_info;
 685 }
 686
 687 sub _dbi_connect_info {
 688   my $self = shift;
 689
 690   return $self->{_dbi_connect_info} = $_[0]
 691     if @_;
 692
 693   my $conninfo = $self->{_dbi_connect_info} || [];
 694
 695   # last ditch effort to grab a DSN
 696   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 697     my @new_conninfo = @$conninfo;
 698     $new_conninfo[0] = $ENV{DBI_DSN};
 699     $conninfo = \@new_conninfo;
 700   }
 701
 702   return $conninfo;
 703 }
 704
 705
 706 sub _normalize_connect_info {
 707   my ($self, $info_arg) = @_;
 708   my %info;
 709
 710   my @args = @$info_arg;  # take a shallow copy for further mutilation
 711
 712   # combine/pre-parse arguments depending on invocation style
 713
 714   my %attrs;
 715   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 716     %attrs = %{ $args[1] || {} };
 717     @args = $args[0];
 718   }
 719   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 720     %attrs = %{$args[0]};
 721     @args = ();
 722     if (my $code = delete $attrs{dbh_maker}) {
 723       @args = $code;
 724
 725       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 726       if (@ignored) {
 727         carp sprintf (
 728             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 729           . "to the result of 'dbh_maker'",
 730
 731           join (', ', map { "'$_'" } (@ignored) ),
 732         );
 733       }
 734     }
 735     else {
 736       @args = delete @attrs{qw/dsn user password/};
 737     }
 738   }
 739   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 740     %attrs = (
 741       % { $args[3] || {} },
 742       % { $args[4] || {} },
 743     );
 744     @args = @args[0,1,2];
 745   }
 746
 747   $info{arguments} = \@args;
 748
 749   my @storage_opts = grep exists $attrs{$_},
 750     @storage_options, 'cursor_class';
 751
 752   @{ $info{storage_options} }{@storage_opts} =
 753     delete @attrs{@storage_opts} if @storage_opts;
 754
 755   my @sql_maker_opts = grep exists $attrs{$_},
 756     qw/limit_dialect quote_char name_sep quote_names/;
 757
 758   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 759     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 760
 761   $info{attributes} = \%attrs if %attrs;
 762
 763   return \%info;
 764 }
 765
 766 sub _default_dbi_connect_attributes () {
 767   +{
 768     AutoCommit => 1,
 769     PrintError => 0,
 770     RaiseError => 1,
 771     ShowErrorStatement => 1,
 772   };
 773 }
 774
 775 =head2 on_connect_do
 776
 777 This method is deprecated in favour of setting via L</connect_info>.
 778
 779 =cut
 780
 781 =head2 on_disconnect_do
 782
 783 This method is deprecated in favour of setting via L</connect_info>.
 784
 785 =cut
 786
 787 sub _parse_connect_do {
 788   my ($self, $type) = @_;
 789
 790   my $val = $self->$type;
 791   return () if not defined $val;
 792
 793   my @res;
 794
 795   if (not ref($val)) {
 796     push @res, [ 'do_sql', $val ];
 797   } elsif (ref($val) eq 'CODE') {
 798     push @res, $val;
 799   } elsif (ref($val) eq 'ARRAY') {
 800     push @res, map { [ 'do_sql', $_ ] } @$val;
 801   } else {
 802     $self->throw_exception("Invalid type for $type: ".ref($val));
 803   }
 804
 805   return \@res;
 806 }
 807
 808 =head2 dbh_do
 809
 810 Arguments: ($subref | $method_name), @extra_coderef_args?
 811
 812 Execute the given $subref or $method_name using the new exception-based
 813 connection management.
 814
 815 The first two arguments will be the storage object that C<dbh_do> was called
 816 on and a database handle to use.  Any additional arguments will be passed
 817 verbatim to the called subref as arguments 2 and onwards.
 818
 819 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 820 exception handling and reconnection (or failover in future subclasses).
 821
 822 Your subref should have no side-effects outside of the database, as
 823 there is the potential for your subref to be partially double-executed
 824 if the database connection was stale/dysfunctional.
 825
 826 Example:
 827
 828   my @stuff = $schema->storage->dbh_do(
 829     sub {
 830       my ($storage, $dbh, @cols) = @_;
 831       my $cols = join(q{, }, @cols);
 832       $dbh->selectrow_array("SELECT $cols FROM foo");
 833     },
 834     @column_list
 835   );
 836
 837 =cut
 838
 839 sub dbh_do {
 840   my $self = shift;
 841   my $run_target = shift; # either a coderef or a method name
 842
 843   # short circuit when we know there is no need for a runner
 844   #
 845   # FIXME - assumption may be wrong
 846   # the rationale for the txn_depth check is that if this block is a part
 847   # of a larger transaction, everything up to that point is screwed anyway
 848   return $self->$run_target($self->_get_dbh, @_)
 849     if $self->{_in_do_block} or $self->transaction_depth;
 850
 851   # take a ref instead of a copy, to preserve @_ aliasing
 852   # semantics within the coderef, but only if needed
 853   # (pseudoforking doesn't like this trick much)
 854   my $args = @_ ? \@_ : [];
 855
 856   DBIx::Class::Storage::BlockRunner->new(
 857     storage => $self,
 858     wrap_txn => 0,
 859     retry_handler => sub {
 860       $_[0]->failed_attempt_count == 1
 861         and
 862       ! $_[0]->storage->connected
 863     },
 864   )->run(sub {
 865     $self->$run_target ($self->_get_dbh, @$args )
 866   });
 867 }
 868
 869 sub txn_do {
 870   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 871   shift->next::method(@_);
 872 }
 873
 874 =head2 disconnect
 875
 876 Our C<disconnect> method also performs a rollback first if the
 877 database is not in C<AutoCommit> mode.
 878
 879 =cut
 880
 881 sub disconnect {
 882   my $self = shift;
 883
 884   # this physical disconnect below might very well throw
 885   # in order to unambiguously reset the state - do the cleanup in guard
 886
 887   my $g = scope_guard {
 888     $self->_dbh(undef);
 889     $self->_dbh_details({});
 890     $self->transaction_depth(undef);
 891     $self->_dbh_autocommit(undef);
 892     $self->savepoints([]);
 893
 894     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 895     #$self->_sql_maker(undef); # this may also end up being different
 896   };
 897
 898   if( my $dbh = $self->_dbh ) {
 899
 900     $self->_do_connection_actions(disconnect_call_ => $_) for (
 901       ( $self->on_disconnect_call || () ),
 902       $self->_parse_connect_do ('on_disconnect_do')
 903     );
 904
 905     # stops the "implicit rollback on disconnect" warning
 906     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 907
 908     %{ $dbh->{CachedKids} } = ();
 909
 910     $dbh->disconnect;
 911   }
 912 }
 913
 914 =head2 with_deferred_fk_checks
 915
 916 =over 4
 917
 918 =item Arguments: C<$coderef>
 919
 920 =item Return Value: The return value of $coderef
 921
 922 =back
 923
 924 Storage specific method to run the code ref with FK checks deferred or
 925 in MySQL's case disabled entirely.
 926
 927 =cut
 928
 929 # Storage subclasses should override this
 930 sub with_deferred_fk_checks {
 931   #my ($self, $sub) = @_;
 932   $_[1]->();
 933 }
 934
 935 =head2 connected
 936
 937 =over
 938
 939 =item Arguments: none
 940
 941 =item Return Value: 1|0
 942
 943 =back
 944
 945 Verifies that the current database handle is active and ready to execute
 946 an SQL statement (e.g. the connection did not get stale, server is still
 947 answering, etc.) This method is used internally by L</dbh>.
 948
 949 =cut
 950
 951 sub connected {
 952   return 0 unless $_[0]->_seems_connected;
 953
 954   #be on the safe side
 955   local $_[0]->_dbh->{RaiseError} = 1;
 956
 957   return $_[0]->_ping;
 958 }
 959
 960 sub _seems_connected {
 961   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 962
 963   $_[0]->_dbh
 964     and
 965   $_[0]->_dbh->FETCH('Active')
 966     and
 967   return 1;
 968
 969   # explicitly reset all state
 970   $_[0]->disconnect;
 971   return 0;
 972 }
 973
 974 sub _ping {
 975   ($_[0]->_dbh || return 0)->ping;
 976 }
 977
 978 sub ensure_connected {
 979   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 980 }
 981
 982 =head2 dbh
 983
 984 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 985 is guaranteed to be healthy by implicitly calling L</connected>, and if
 986 necessary performing a reconnection before returning. Keep in mind that this
 987 is very B<expensive> on some database engines. Consider using L</dbh_do>
 988 instead.
 989
 990 =cut
 991
 992 sub dbh {
 993   # maybe save a ping call
 994   $_[0]->_dbh
 995     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 996     : $_[0]->_populate_dbh
 997   ;
 998 }
 999
1000 # this is the internal "get dbh or connect (don't check)" method
1001 sub _get_dbh {
1002   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1003   $_[0]->_dbh || $_[0]->_populate_dbh;
1004 }
1005
1006 # *DELIBERATELY* not a setter (for the time being)
1007 # Too intertwined with everything else for any kind of sanity
1008 sub sql_maker {
1009   my $self = shift;
1010
1011   $self->throw_exception('sql_maker() is not a setter method') if @_;
1012
1013   unless ($self->_sql_maker) {
1014     my $sql_maker_class = $self->sql_maker_class;
1015
1016     my %opts = %{$self->_sql_maker_opts||{}};
1017     my $dialect =
1018       $opts{limit_dialect}
1019         ||
1020       $self->sql_limit_dialect
1021         ||
1022       do {
1023         my $s_class = (ref $self) || $self;
1024         carp_unique (
1025           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1026         . 'have not supplied an explicit limit_dialect in your connection_info. '
1027         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1028         . 'databases but can be (and often is) painfully slow. '
1029         . "Please file an RT ticket against '$s_class'"
1030         ) if $self->_dbi_connect_info->[0];
1031
1032         'GenericSubQ';
1033       }
1034     ;
1035
1036     my ($quote_char, $name_sep);
1037
1038     if ($opts{quote_names}) {
1039       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1040         my $s_class = (ref $self) || $self;
1041         carp_unique (
1042           "You requested 'quote_names' but your storage class ($s_class) does "
1043         . 'not explicitly define a default sql_quote_char and you have not '
1044         . 'supplied a quote_char as part of your connection_info. DBIC will '
1045         .q{default to the ANSI SQL standard quote '"', which works most of }
1046         . "the time. Please file an RT ticket against '$s_class'."
1047         );
1048
1049         '"'; # RV
1050       };
1051
1052       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1053     }
1054
1055     $self->_sql_maker($sql_maker_class->new(
1056       bindtype=>'columns',
1057       array_datatypes => 1,
1058       limit_dialect => $dialect,
1059       ($quote_char ? (quote_char => $quote_char) : ()),
1060       name_sep => ($name_sep || '.'),
1061       %opts,
1062     ));
1063   }
1064   return $self->_sql_maker;
1065 }
1066
1067 # nothing to do by default
1068 sub _rebless {}
1069 sub _init {}
1070
1071 sub _populate_dbh {
1072
1073   # reset internal states
1074   # also in case ->connected failed we might get sent here
1075   $_[0]->disconnect;
1076
1077   $_[0]->_dbh($_[0]->_connect);
1078
1079   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1080
1081   $_[0]->_determine_driver;
1082
1083   # Always set the transaction depth on connect, since
1084   #  there is no transaction in progress by definition
1085   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1086
1087   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1088
1089   $_[0]->_dbh;
1090 }
1091
1092 sub _run_connection_actions {
1093
1094   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1095     ( $_[0]->on_connect_call || () ),
1096     $_[0]->_parse_connect_do ('on_connect_do'),
1097   );
1098 }
1099
1100
1101
1102 sub set_use_dbms_capability {
1103   $_[0]->set_inherited ($_[1], $_[2]);
1104 }
1105
1106 sub get_use_dbms_capability {
1107   my ($self, $capname) = @_;
1108
1109   my $use = $self->get_inherited ($capname);
1110   return defined $use
1111     ? $use
1112     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1113   ;
1114 }
1115
1116 sub set_dbms_capability {
1117   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1118 }
1119
1120 sub get_dbms_capability {
1121   my ($self, $capname) = @_;
1122
1123   my $cap = $self->_dbh_details->{capability}{$capname};
1124
1125   unless (defined $cap) {
1126     if (my $meth = $self->can ("_determine$capname")) {
1127       $cap = $self->$meth ? 1 : 0;
1128     }
1129     else {
1130       $cap = 0;
1131     }
1132
1133     $self->set_dbms_capability ($capname, $cap);
1134   }
1135
1136   return $cap;
1137 }
1138
1139 sub _server_info {
1140   my $self = shift;
1141
1142   # FIXME - ideally this needs to be an ||= assignment, and the final
1143   # assignment at the end of this do{} should be gone entirely. However
1144   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1145   $self->_dbh_details->{info} || do {
1146
1147     # this guarantees that problematic conninfo won't be hidden
1148     # by the try{} below
1149     $self->ensure_connected;
1150
1151     my $info = {};
1152
1153     my $server_version = dbic_internal_try {
1154       $self->_get_server_version
1155     } catch {
1156       # driver determination *may* use this codepath
1157       # in which case we must rethrow
1158       $self->throw_exception($_) if $self->{_in_determine_driver};
1159
1160       # $server_version on failure
1161       undef;
1162     };
1163
1164     if (defined $server_version) {
1165       $info->{dbms_version} = $server_version;
1166
1167       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1168       my @verparts = split (/\./, $numeric_version);
1169       if (
1170         @verparts
1171           &&
1172         $verparts[0] <= 999
1173       ) {
1174         # consider only up to 3 version parts, iff not more than 3 digits
1175         my @use_parts;
1176         while (@verparts && @use_parts < 3) {
1177           my $p = shift @verparts;
1178           last if $p > 999;
1179           push @use_parts, $p;
1180         }
1181         push @use_parts, 0 while @use_parts < 3;
1182
1183         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1184       }
1185     }
1186
1187     $self->_dbh_details->{info} = $info;
1188   };
1189 }
1190
1191 sub _get_server_version {
1192   shift->_dbh_get_info('SQL_DBMS_VER');
1193 }
1194
1195 sub _dbh_get_info {
1196   my ($self, $info) = @_;
1197
1198   if ($info =~ /[^0-9]/) {
1199     require DBI::Const::GetInfoType;
1200     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1201     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1202       unless defined $info;
1203   }
1204
1205   $self->_get_dbh->get_info($info);
1206 }
1207
1208 sub _describe_connection {
1209   require DBI::Const::GetInfoReturn;
1210
1211   my $self = shift;
1212
1213   my $drv;
1214   dbic_internal_try {
1215     $drv = $self->_extract_driver_from_connect_info;
1216     $self->ensure_connected;
1217   };
1218
1219   $drv = "DBD::$drv" if $drv;
1220
1221   my $res = {
1222     DBIC_DSN => $self->_dbi_connect_info->[0],
1223     DBI_VER => DBI->VERSION,
1224     DBIC_VER => DBIx::Class->VERSION,
1225     DBIC_DRIVER => ref $self,
1226     $drv ? (
1227       DBD => $drv,
1228       DBD_VER => dbic_internal_try { $drv->VERSION },
1229     ) : (),
1230   };
1231
1232   # try to grab data even if we never managed to connect
1233   # will cover us in cases of an oddly broken half-connect
1234   for my $inf (
1235     #keys %DBI::Const::GetInfoType::GetInfoType,
1236     qw/
1237       SQL_CURSOR_COMMIT_BEHAVIOR
1238       SQL_CURSOR_ROLLBACK_BEHAVIOR
1239       SQL_CURSOR_SENSITIVITY
1240       SQL_DATA_SOURCE_NAME
1241       SQL_DBMS_NAME
1242       SQL_DBMS_VER
1243       SQL_DEFAULT_TXN_ISOLATION
1244       SQL_DM_VER
1245       SQL_DRIVER_NAME
1246       SQL_DRIVER_ODBC_VER
1247       SQL_DRIVER_VER
1248       SQL_EXPRESSIONS_IN_ORDERBY
1249       SQL_GROUP_BY
1250       SQL_IDENTIFIER_CASE
1251       SQL_IDENTIFIER_QUOTE_CHAR
1252       SQL_MAX_CATALOG_NAME_LEN
1253       SQL_MAX_COLUMN_NAME_LEN
1254       SQL_MAX_IDENTIFIER_LEN
1255       SQL_MAX_TABLE_NAME_LEN
1256       SQL_MULTIPLE_ACTIVE_TXN
1257       SQL_MULT_RESULT_SETS
1258       SQL_NEED_LONG_DATA_LEN
1259       SQL_NON_NULLABLE_COLUMNS
1260       SQL_ODBC_VER
1261       SQL_QUALIFIER_NAME_SEPARATOR
1262       SQL_QUOTED_IDENTIFIER_CASE
1263       SQL_TXN_CAPABLE
1264       SQL_TXN_ISOLATION_OPTION
1265     /
1266   ) {
1267     # some drivers barf on things they do not know about instead
1268     # of returning undef
1269     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1270     next unless defined $v;
1271
1272     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1273     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1274     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1275   }
1276
1277   $res;
1278 }
1279
1280 sub _determine_driver {
1281   my ($self) = @_;
1282
1283   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1284     my $started_connected = 0;
1285     local $self->{_in_determine_driver} = 1;
1286
1287     if (ref($self) eq __PACKAGE__) {
1288       my $driver;
1289       if ($self->_dbh) { # we are connected
1290         $driver = $self->_dbh->{Driver}{Name};
1291         $started_connected = 1;
1292       }
1293       else {
1294         $driver = $self->_extract_driver_from_connect_info;
1295       }
1296
1297       if ($driver) {
1298         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1299         if ($self->load_optional_class($storage_class)) {
1300           mro::set_mro($storage_class, 'c3');
1301           bless $self, $storage_class;
1302           $self->_rebless();
1303         }
1304         else {
1305           $self->_warn_undetermined_driver(
1306             'This version of DBIC does not yet seem to supply a driver for '
1307           . "your particular RDBMS and/or connection method ('$driver')."
1308           );
1309         }
1310       }
1311       else {
1312         $self->_warn_undetermined_driver(
1313           'Unable to extract a driver name from connect info - this '
1314         . 'should not have happened.'
1315         );
1316       }
1317     }
1318
1319     $self->_driver_determined(1);
1320
1321     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1322
1323     if ($self->can('source_bind_attributes')) {
1324       $self->throw_exception(
1325         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1326       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1327       . 'If you are not sure how to proceed please contact the development team via '
1328       . DBIx::Class::_ENV_::HELP_URL
1329       );
1330     }
1331
1332     $self->_init; # run driver-specific initializations
1333
1334     $self->_run_connection_actions
1335         if !$started_connected && defined $self->_dbh;
1336   }
1337 }
1338
1339 sub _extract_driver_from_connect_info {
1340   my $self = shift;
1341
1342   my $drv;
1343
1344   # if connect_info is a CODEREF, we have no choice but to connect
1345   if (
1346     ref $self->_dbi_connect_info->[0]
1347       and
1348     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1349   ) {
1350     $self->_populate_dbh;
1351     $drv = $self->_dbh->{Driver}{Name};
1352   }
1353   else {
1354     # try to use dsn to not require being connected, the driver may still
1355     # force a connection later in _rebless to determine version
1356     # (dsn may not be supplied at all if all we do is make a mock-schema)
1357     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1358     $drv ||= $ENV{DBI_DRIVER};
1359   }
1360
1361   return $drv;
1362 }
1363
1364 sub _determine_connector_driver {
1365   my ($self, $conn) = @_;
1366
1367   my $dbtype = $self->_get_rdbms_name;
1368
1369   if (not $dbtype) {
1370     $self->_warn_undetermined_driver(
1371       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1372     . "$conn connector - this should not have happened."
1373     );
1374     return;
1375   }
1376
1377   $dbtype =~ s/\W/_/gi;
1378
1379   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1380   return if $self->isa($subclass);
1381
1382   if ($self->load_optional_class($subclass)) {
1383     bless $self, $subclass;
1384     $self->_rebless;
1385   }
1386   else {
1387     $self->_warn_undetermined_driver(
1388       'This version of DBIC does not yet seem to supply a driver for '
1389     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1390     );
1391   }
1392 }
1393
1394 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1395
1396 sub _warn_undetermined_driver {
1397   my ($self, $msg) = @_;
1398
1399   require Data::Dumper::Concise;
1400
1401   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1402   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1403   . "does not go away, file a bugreport including the following info:\n"
1404   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1405   );
1406 }
1407
1408 sub _do_connection_actions {
1409   my ($self, $method_prefix, $call, @args) = @_;
1410
1411   dbic_internal_try {
1412     if (not ref($call)) {
1413       my $method = $method_prefix . $call;
1414       $self->$method(@args);
1415     }
1416     elsif (ref($call) eq 'CODE') {
1417       $self->$call(@args);
1418     }
1419     elsif (ref($call) eq 'ARRAY') {
1420       if (ref($call->[0]) ne 'ARRAY') {
1421         $self->_do_connection_actions($method_prefix, $_) for @$call;
1422       }
1423       else {
1424         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1425       }
1426     }
1427     else {
1428       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1429     }
1430   }
1431   catch {
1432     if ( $method_prefix =~ /^connect/ ) {
1433       # this is an on_connect cycle - we can't just throw while leaving
1434       # a handle in an undefined state in our storage object
1435       # kill it with fire and rethrow
1436       $self->_dbh(undef);
1437       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1438       $self->throw_exception( $_[0] );
1439     }
1440     else {
1441       carp "Disconnect action failed: $_[0]";
1442     }
1443   };
1444
1445   return $self;
1446 }
1447
1448 sub connect_call_do_sql {
1449   my $self = shift;
1450   $self->_do_query(@_);
1451 }
1452
1453 sub disconnect_call_do_sql {
1454   my $self = shift;
1455   $self->_do_query(@_);
1456 }
1457
1458 =head2 connect_call_datetime_setup
1459
1460 A no-op stub method, provided so that one can always safely supply the
1461 L<connection option|/DBIx::Class specific connection attributes>
1462
1463  on_connect_call => 'datetime_setup'
1464
1465 This way one does not need to know in advance whether the underlying
1466 storage requires any sort of hand-holding when dealing with calendar
1467 data.
1468
1469 =cut
1470
1471 sub connect_call_datetime_setup { 1 }
1472
1473 sub _do_query {
1474   my ($self, $action) = @_;
1475
1476   if (ref $action eq 'CODE') {
1477     $action = $action->($self);
1478     $self->_do_query($_) foreach @$action;
1479   }
1480   else {
1481     # Most debuggers expect ($sql, @bind), so we need to exclude
1482     # the attribute hash which is the second argument to $dbh->do
1483     # furthermore the bind values are usually to be presented
1484     # as named arrayref pairs, so wrap those here too
1485     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1486     my $sql = shift @do_args;
1487     my $attrs = shift @do_args;
1488     my @bind = map { [ undef, $_ ] } @do_args;
1489
1490     $self->dbh_do(sub {
1491       $_[0]->_query_start($sql, \@bind);
1492       $_[1]->do($sql, $attrs, @do_args);
1493       $_[0]->_query_end($sql, \@bind);
1494     });
1495   }
1496
1497   return $self;
1498 }
1499
1500 sub _connect {
1501   my $self = shift;
1502
1503   my $info = $self->_dbi_connect_info;
1504
1505   $self->throw_exception("You did not provide any connection_info")
1506     unless defined $info->[0];
1507
1508   my ($old_connect_via, $dbh);
1509
1510   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1511
1512   # this odd anonymous coderef dereference is in fact really
1513   # necessary to avoid the unwanted effect described in perl5
1514   # RT#75792
1515   #
1516   # in addition the coderef itself can't reside inside the try{} block below
1517   # as it somehow triggers a leak under perl -d
1518   my $dbh_error_handler_installer = sub {
1519     weaken (my $weak_self = $_[0]);
1520
1521     # the coderef is blessed so we can distinguish it from externally
1522     # supplied handles (which must be preserved)
1523     $_[1]->{HandleError} = bless sub {
1524       if ($weak_self) {
1525         $weak_self->throw_exception("DBI Exception: $_[0]");
1526       }
1527       else {
1528         # the handler may be invoked by something totally out of
1529         # the scope of DBIC
1530         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1531       }
1532     }, '__DBIC__DBH__ERROR__HANDLER__';
1533   };
1534
1535   dbic_internal_try {
1536     if(ref $info->[0] eq 'CODE') {
1537       $dbh = $info->[0]->();
1538     }
1539     else {
1540       require DBI;
1541       $dbh = DBI->connect(@$info);
1542     }
1543
1544     die $DBI::errstr unless $dbh;
1545
1546     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1547       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1548       . 'not continue',
1549       ref $info->[0] eq 'CODE'
1550         ? "Connection coderef $info->[0] returned a"
1551         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1552     ) unless $dbh->FETCH('Active');
1553
1554     # sanity checks unless asked otherwise
1555     unless ($self->unsafe) {
1556
1557       $self->throw_exception(
1558         'Refusing clobbering of {HandleError} installed on externally supplied '
1559        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1560       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1561
1562       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1563       # request, or an external handle. Complain and set anyway
1564       unless ($dbh->{RaiseError}) {
1565         carp( ref $info->[0] eq 'CODE'
1566
1567           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1568            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1569            .'attribute has been supplied'
1570
1571           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1572            .'unsafe => 1. Toggling RaiseError back to true'
1573         );
1574
1575         $dbh->{RaiseError} = 1;
1576       }
1577
1578       $dbh_error_handler_installer->($self, $dbh);
1579     }
1580   }
1581   catch {
1582     $self->throw_exception("DBI Connection failed: $_")
1583   };
1584
1585   $self->_dbh_autocommit($dbh->{AutoCommit});
1586   return $dbh;
1587 }
1588
1589 sub txn_begin {
1590   # this means we have not yet connected and do not know the AC status
1591   # (e.g. coderef $dbh), need a full-fledged connection check
1592   if (! defined $_[0]->_dbh_autocommit) {
1593     $_[0]->ensure_connected;
1594   }
1595   # Otherwise simply connect or re-connect on pid changes
1596   else {
1597     $_[0]->_get_dbh;
1598   }
1599
1600   shift->next::method(@_);
1601 }
1602
1603 sub _exec_txn_begin {
1604   my $self = shift;
1605
1606   # if the user is utilizing txn_do - good for him, otherwise we need to
1607   # ensure that the $dbh is healthy on BEGIN.
1608   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1609   # will be replaced by a failure of begin_work itself (which will be
1610   # then retried on reconnect)
1611   if ($self->{_in_do_block}) {
1612     $self->_dbh->begin_work;
1613   } else {
1614     $self->dbh_do(sub { $_[1]->begin_work });
1615   }
1616 }
1617
1618 sub txn_commit {
1619   my $self = shift;
1620
1621   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1622     unless $self->_seems_connected;
1623
1624   # esoteric case for folks using external $dbh handles
1625   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1626     carp "Storage transaction_depth 0 does not match "
1627         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1628     $self->transaction_depth(1);
1629   }
1630
1631   $self->next::method(@_);
1632
1633   # if AutoCommit is disabled txn_depth never goes to 0
1634   # as a new txn is started immediately on commit
1635   $self->transaction_depth(1) if (
1636     !$self->transaction_depth
1637       and
1638     defined $self->_dbh_autocommit
1639       and
1640     ! $self->_dbh_autocommit
1641   );
1642 }
1643
1644 sub _exec_txn_commit {
1645   shift->_dbh->commit;
1646 }
1647
1648 sub txn_rollback {
1649   my $self = shift;
1650
1651   # do a minimal connectivity check due to weird shit like
1652   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1653   $self->throw_exception("lost connection to storage")
1654     unless $self->_seems_connected;
1655
1656   # esoteric case for folks using external $dbh handles
1657   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1658     carp "Storage transaction_depth 0 does not match "
1659         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1660     $self->transaction_depth(1);
1661   }
1662
1663   $self->next::method(@_);
1664
1665   # if AutoCommit is disabled txn_depth never goes to 0
1666   # as a new txn is started immediately on commit
1667   $self->transaction_depth(1) if (
1668     !$self->transaction_depth
1669       and
1670     defined $self->_dbh_autocommit
1671       and
1672     ! $self->_dbh_autocommit
1673   );
1674 }
1675
1676 sub _exec_txn_rollback {
1677   shift->_dbh->rollback;
1678 }
1679
1680 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1681 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1682   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1683     unless $_[0]->_seems_connected;
1684   shift->next::method(@_);
1685 EOS
1686
1687 # This used to be the top-half of _execute.  It was split out to make it
1688 #  easier to override in NoBindVars without duping the rest.  It takes up
1689 #  all of _execute's args, and emits $sql, @bind.
1690 sub _prep_for_execute {
1691   #my ($self, $op, $ident, $args) = @_;
1692   return shift->_gen_sql_bind(@_)
1693 }
1694
1695 sub _gen_sql_bind {
1696   my ($self, $op, $ident, $args) = @_;
1697
1698   my ($colinfos, $from);
1699   if ( blessed($ident) ) {
1700     $from = $ident->from;
1701     $colinfos = $ident->columns_info;
1702   }
1703
1704   my ($sql, $bind);
1705   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1706
1707   $bind = $self->_resolve_bindattrs(
1708     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1709   );
1710
1711   if (
1712     ! $ENV{DBIC_DT_SEARCH_OK}
1713       and
1714     $op eq 'select'
1715       and
1716     first {
1717       length ref $_->[1]
1718         and
1719       blessed($_->[1])
1720         and
1721       $_->[1]->isa('DateTime')
1722     } @$bind
1723   ) {
1724     carp_unique 'DateTime objects passed to search() are not supported '
1725       . 'properly (InflateColumn::DateTime formats and settings are not '
1726       . 'respected.) See ".. format a DateTime object for searching?" in '
1727       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1728       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1729   }
1730
1731   return( $sql, $bind );
1732 }
1733
1734 sub _resolve_bindattrs {
1735   my ($self, $ident, $bind, $colinfos) = @_;
1736
1737   my $resolve_bindinfo = sub {
1738     #my $infohash = shift;
1739
1740     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1741
1742     my $ret;
1743     if (my $col = $_[0]->{dbic_colname}) {
1744       $ret = { %{$_[0]} };
1745
1746       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1747         if $colinfos->{$col}{data_type};
1748
1749       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1750         if $colinfos->{$col}{size};
1751     }
1752
1753     $ret || $_[0];
1754   };
1755
1756   return [ map {
1757       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1758     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1759     : (ref $_->[0] eq 'HASH')           ? [(
1760                                             ! keys %{$_->[0]}
1761                                               or
1762                                             exists $_->[0]{dbd_attrs}
1763                                               or
1764                                             $_->[0]{sqlt_datatype}
1765                                            ) ? $_->[0]
1766                                              : $resolve_bindinfo->($_->[0])
1767                                            , $_->[1]
1768                                           ]
1769     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1770     :                                     [ $resolve_bindinfo->(
1771                                               { dbic_colname => $_->[0] }
1772                                             ), $_->[1] ]
1773   } @$bind ];
1774 }
1775
1776 sub _format_for_trace {
1777   #my ($self, $bind) = @_;
1778
1779   ### Turn @bind from something like this:
1780   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1781   ### to this:
1782   ###   ( "'1'", "'3'" )
1783
1784   map {
1785     defined( $_ && $_->[1] )
1786       ? qq{'$_->[1]'}
1787       : q{NULL}
1788   } @{$_[1] || []};
1789 }
1790
1791 sub _query_start {
1792   my ( $self, $sql, $bind ) = @_;
1793
1794   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1795     if $self->debug;
1796 }
1797
1798 sub _query_end {
1799   my ( $self, $sql, $bind ) = @_;
1800
1801   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1802     if $self->debug;
1803 }
1804
1805 sub _dbi_attrs_for_bind {
1806   #my ($self, $ident, $bind) = @_;
1807
1808   return [ map {
1809
1810     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1811
1812   : ! $_->{sqlt_datatype}   ? undef
1813
1814   :                           do {
1815
1816     # cache the result in the dbh_details hash, as it (usually) can not change
1817     # unless we connect to something else
1818     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1819     # the LOB storage
1820     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1821
1822     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1823       if ! exists $cache->{$_->{sqlt_datatype}};
1824
1825     $cache->{$_->{sqlt_datatype}};
1826
1827   } } map { $_->[0] } @{$_[2]} ];
1828 }
1829
1830 sub _execute {
1831   my ($self, $op, $ident, @args) = @_;
1832
1833   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1834
1835   # not even a PID check - we do not care about the state of the _dbh.
1836   # All we need is to get the appropriate drivers loaded if they aren't
1837   # already so that the assumption in ad7c50fc26e holds
1838   $self->_populate_dbh unless $self->_dbh;
1839
1840   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1841     $sql,
1842     $bind,
1843     $self->_dbi_attrs_for_bind($ident, $bind),
1844   );
1845 }
1846
1847 sub _dbh_execute {
1848   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1849
1850   $self->_query_start( $sql, $bind );
1851
1852   my $sth = $self->_bind_sth_params(
1853     $self->_prepare_sth($dbh, $sql),
1854     $bind,
1855     $bind_attrs,
1856   );
1857
1858   # Can this fail without throwing an exception anyways???
1859   my $rv = $sth->execute();
1860   $self->throw_exception(
1861     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1862   ) if !$rv;
1863
1864   $self->_query_end( $sql, $bind );
1865
1866   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1867 }
1868
1869 sub _prepare_sth {
1870   my ($self, $dbh, $sql) = @_;
1871
1872   # 3 is the if_active parameter which avoids active sth re-use
1873   my $sth = $self->disable_sth_caching
1874     ? $dbh->prepare($sql)
1875     : $dbh->prepare_cached($sql, {}, 3);
1876
1877   # XXX You would think RaiseError would make this impossible,
1878   #  but apparently that's not true :(
1879   $self->throw_exception(
1880     $dbh->errstr
1881       ||
1882     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1883             .'an exception and/or setting $dbh->errstr',
1884       length ($sql) > 20
1885         ? substr($sql, 0, 20) . '...'
1886         : $sql
1887       ,
1888       'DBD::' . $dbh->{Driver}{Name},
1889     )
1890   ) if !$sth;
1891
1892   $sth;
1893 }
1894
1895 sub _bind_sth_params {
1896   my ($self, $sth, $bind, $bind_attrs) = @_;
1897
1898   for my $i (0 .. $#$bind) {
1899     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1900       $sth->bind_param_inout(
1901         $i + 1, # bind params counts are 1-based
1902         $bind->[$i][1],
1903         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1904         $bind_attrs->[$i],
1905       );
1906     }
1907     else {
1908       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1909       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1910         ? "$bind->[$i][1]"
1911         : $bind->[$i][1]
1912       ;
1913
1914       $sth->bind_param(
1915         $i + 1,
1916         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1917         $v,
1918         $bind_attrs->[$i],
1919       );
1920     }
1921   }
1922
1923   $sth;
1924 }
1925
1926 sub _prefetch_autovalues {
1927   my ($self, $source, $colinfo, $to_insert) = @_;
1928
1929   my %values;
1930   for my $col (keys %$colinfo) {
1931     if (
1932       $colinfo->{$col}{auto_nextval}
1933         and
1934       (
1935         ! exists $to_insert->{$col}
1936           or
1937         is_literal_value($to_insert->{$col})
1938       )
1939     ) {
1940       $values{$col} = $self->_sequence_fetch(
1941         'NEXTVAL',
1942         ( $colinfo->{$col}{sequence} ||=
1943             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1944         ),
1945       );
1946     }
1947   }
1948
1949   \%values;
1950 }
1951
1952 sub insert {
1953   my ($self, $source, $to_insert) = @_;
1954
1955   my $col_infos = $source->columns_info;
1956
1957   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1958
1959   # fuse the values, but keep a separate list of prefetched_values so that
1960   # they can be fused once again with the final return
1961   $to_insert = { %$to_insert, %$prefetched_values };
1962
1963   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1964   # Investigate what does it take to s/defined/exists/
1965   my %pcols = map { $_ => 1 } $source->primary_columns;
1966   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1967   for my $col ($source->columns) {
1968     if ($col_infos->{$col}{is_auto_increment}) {
1969       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1970       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1971     }
1972
1973     # nothing to retrieve when explicit values are supplied
1974     next if (
1975       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1976     );
1977
1978     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1979     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1980       $pcols{$col}
1981         or
1982       $col_infos->{$col}{retrieve_on_insert}
1983     );
1984   };
1985
1986   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1987   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1988
1989   my ($sqla_opts, @ir_container);
1990   if (%retrieve_cols and $self->_use_insert_returning) {
1991     $sqla_opts->{returning_container} = \@ir_container
1992       if $self->_use_insert_returning_bound;
1993
1994     $sqla_opts->{returning} = [
1995       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1996     ];
1997   }
1998
1999   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2000
2001   my %returned_cols = %$to_insert;
2002   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2003
2004     unless( @ir_container ) {
2005       dbic_internal_try {
2006
2007         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2008         local $SIG{__WARN__} = sub {};
2009
2010         @ir_container = $sth->fetchrow_array;
2011         $sth->finish;
2012
2013       } catch {
2014         # Evict the $sth from the cache in case we got here, since the finish()
2015         # is crucial, at least on older Firebirds, possibly on other engines too
2016         #
2017         # It would be too complex to make this a proper subclass override,
2018         # and besides we already take the try{} penalty, adding a catch that
2019         # triggers infrequently is a no-brainer
2020         #
2021         if( my $kids = $self->_dbh->{CachedKids} ) {
2022           $kids->{$_} == $sth and delete $kids->{$_}
2023             for keys %$kids
2024         }
2025       };
2026     }
2027
2028     @returned_cols{@$retlist} = @ir_container if @ir_container;
2029   }
2030   else {
2031     # pull in PK if needed and then everything else
2032     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2033
2034       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2035         unless $self->can('last_insert_id');
2036
2037       my @pri_values = $self->last_insert_id($source, @missing_pri);
2038
2039       $self->throw_exception( "Can't get last insert id" )
2040         unless (@pri_values == @missing_pri);
2041
2042       @returned_cols{@missing_pri} = @pri_values;
2043       delete @retrieve_cols{@missing_pri};
2044     }
2045
2046     # if there is more left to pull
2047     if (%retrieve_cols) {
2048       $self->throw_exception(
2049         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2050       ) unless %pcols;
2051
2052       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2053
2054       my $cur = DBIx::Class::ResultSet->new($source, {
2055         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2056         select => \@left_to_fetch,
2057       })->cursor;
2058
2059       @returned_cols{@left_to_fetch} = $cur->next;
2060
2061       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2062         if scalar $cur->next;
2063     }
2064   }
2065
2066   return { %$prefetched_values, %returned_cols };
2067 }
2068
2069 sub insert_bulk {
2070   carp_unique(
2071     'insert_bulk() should have never been exposed as a public method and '
2072   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2073   . 'use for this method please contact the development team via '
2074   . DBIx::Class::_ENV_::HELP_URL
2075   );
2076
2077   return '0E0' unless @{$_[3]||[]};
2078
2079   shift->_insert_bulk(@_);
2080 }
2081
2082 sub _insert_bulk {
2083   my ($self, $source, $cols, $data) = @_;
2084
2085   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2086     unless @{$data||[]};
2087
2088   my $colinfos = $source->columns_info($cols);
2089
2090   local $self->{_autoinc_supplied_for_op} =
2091     (grep { $_->{is_auto_increment} } values %$colinfos)
2092       ? 1
2093       : 0
2094   ;
2095
2096   # get a slice type index based on first row of data
2097   # a "column" in this context may refer to more than one bind value
2098   # e.g. \[ '?, ?', [...], [...] ]
2099   #
2100   # construct the value type index - a description of values types for every
2101   # per-column slice of $data:
2102   #
2103   # nonexistent - nonbind literal
2104   # 0 - regular value
2105   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2106   #
2107   # also construct the column hash to pass to the SQL generator. For plain
2108   # (non literal) values - convert the members of the first row into a
2109   # literal+bind combo, with extra positional info in the bind attr hashref.
2110   # This will allow us to match the order properly, and is so contrived
2111   # because a user-supplied literal/bind (or something else specific to a
2112   # resultsource and/or storage driver) can inject extra binds along the
2113   # way, so one can't rely on "shift positions" ordering at all. Also we
2114   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2115   # can be later matched up by address), because we want to supply a real
2116   # value on which perhaps e.g. datatype checks will be performed
2117   my ($proto_data, $serialized_bind_type_by_col_idx);
2118   for my $col_idx (0..$#$cols) {
2119     my $colname = $cols->[$col_idx];
2120     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2121       # no bind value at all - no type
2122
2123       $proto_data->{$colname} = $data->[0][$col_idx];
2124     }
2125     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2126       # repack, so we don't end up mangling the original \[]
2127       my ($sql, @bind) = @${$data->[0][$col_idx]};
2128
2129       # normalization of user supplied stuff
2130       my $resolved_bind = $self->_resolve_bindattrs(
2131         $source, \@bind, $colinfos,
2132       );
2133
2134       # store value-less (attrs only) bind info - we will be comparing all
2135       # supplied binds against this for sanity
2136       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2137
2138       $proto_data->{$colname} = \[ $sql, map { [
2139         # inject slice order to use for $proto_bind construction
2140           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2141             =>
2142           $resolved_bind->[$_][1]
2143         ] } (0 .. $#bind)
2144       ];
2145     }
2146     else {
2147       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2148
2149       $proto_data->{$colname} = \[ '?', [
2150         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2151           =>
2152         $data->[0][$col_idx]
2153       ] ];
2154     }
2155   }
2156
2157   my ($sql, $proto_bind) = $self->_prep_for_execute (
2158     'insert',
2159     $source,
2160     [ $proto_data ],
2161   );
2162
2163   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2164     # if the bindlist is empty and we had some dynamic binds, this means the
2165     # storage ate them away (e.g. the NoBindVars component) and interpolated
2166     # them directly into the SQL. This obviously can't be good for multi-inserts
2167     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2168   }
2169
2170   # sanity checks
2171   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2172   #
2173   # use an error reporting closure for convenience (less to pass)
2174   my $bad_slice_report_cref = sub {
2175     my ($msg, $r_idx, $c_idx) = @_;
2176     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2177       $msg,
2178       $cols->[$c_idx],
2179       do {
2180         require Data::Dumper::Concise;
2181         local $Data::Dumper::Maxdepth = 5;
2182         Data::Dumper::Concise::Dumper ({
2183           map { $cols->[$_] =>
2184             $data->[$r_idx][$_]
2185           } 0..$#$cols
2186         }),
2187       }
2188     );
2189   };
2190
2191   for my $col_idx (0..$#$cols) {
2192     my $reference_val = $data->[0][$col_idx];
2193
2194     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2195       my $val = $data->[$row_idx][$col_idx];
2196
2197       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2198         if (ref $val ne 'SCALAR') {
2199           $bad_slice_report_cref->(
2200             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2201             $row_idx,
2202             $col_idx,
2203           );
2204         }
2205         elsif ($$val ne $$reference_val) {
2206           $bad_slice_report_cref->(
2207             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2208             $row_idx,
2209             $col_idx,
2210           );
2211         }
2212       }
2213       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2214         if (is_literal_value($val)) {
2215           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2216         }
2217       }
2218       else {  # binds from a \[], compare type and attrs
2219         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2220           $bad_slice_report_cref->(
2221             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2222             $row_idx,
2223             $col_idx,
2224           );
2225         }
2226         # start drilling down and bail out early on identical refs
2227         elsif (
2228           $reference_val != $val
2229             or
2230           $$reference_val != $$val
2231         ) {
2232           if (${$val}->[0] ne ${$reference_val}->[0]) {
2233             $bad_slice_report_cref->(
2234               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2235               $row_idx,
2236               $col_idx,
2237             );
2238           }
2239           # need to check the bind attrs - a bind will happen only once for
2240           # the entire dataset, so any changes further down will be ignored.
2241           elsif (
2242             $serialized_bind_type_by_col_idx->{$col_idx}
2243               ne
2244             serialize [
2245               map
2246               { $_->[0] }
2247               @{$self->_resolve_bindattrs(
2248                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2249               )}
2250             ]
2251           ) {
2252             $bad_slice_report_cref->(
2253               'Differing bind attributes on literal/bind values not supported',
2254               $row_idx,
2255               $col_idx,
2256             );
2257           }
2258         }
2259       }
2260     }
2261   }
2262
2263   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2264   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2265   # scope guard
2266   my $guard = $self->txn_scope_guard;
2267
2268   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2269   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2270   my $rv = do {
2271     if (@$proto_bind) {
2272       # proto bind contains the information on which pieces of $data to pull
2273       # $cols is passed in only for prettier error-reporting
2274       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2275     }
2276     else {
2277       # bind_param_array doesn't work if there are no binds
2278       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2279     }
2280   };
2281
2282   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2283
2284   $guard->commit;
2285
2286   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2287 }
2288
2289 # execute_for_fetch is capable of returning data just fine (it means it
2290 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2291 # is the void-populate fast-path we will just ignore this altogether
2292 # for the time being.
2293 sub _dbh_execute_for_fetch {
2294   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2295
2296   # If we have any bind attributes to take care of, we will bind the
2297   # proto-bind data (which will never be used by execute_for_fetch)
2298   # However since column bindtypes are "sticky", this is sufficient
2299   # to get the DBD to apply the bindtype to all values later on
2300   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2301
2302   for my $i (0 .. $#$proto_bind) {
2303     $sth->bind_param (
2304       $i+1, # DBI bind indexes are 1-based
2305       $proto_bind->[$i][1],
2306       $bind_attrs->[$i],
2307     ) if defined $bind_attrs->[$i];
2308   }
2309
2310   # At this point $data slots named in the _bind_data_slice_idx of
2311   # each piece of $proto_bind are either \[]s or plain values to be
2312   # passed in. Construct the dispensing coderef. *NOTE* the order
2313   # of $data will differ from this of the ?s in the SQL (due to
2314   # alphabetical ordering by colname). We actually do want to
2315   # preserve this behavior so that prepare_cached has a better
2316   # chance of matching on unrelated calls
2317
2318   my $fetch_row_idx = -1; # saner loop this way
2319   my $fetch_tuple = sub {
2320     return undef if ++$fetch_row_idx > $#$data;
2321
2322     return [ map {
2323       my $v = ! defined $_->{_literal_bind_subindex}
2324
2325         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2326
2327         # There are no attributes to resolve here - we already did everything
2328         # when we constructed proto_bind. However we still want to sanity-check
2329         # what the user supplied, so pass stuff through to the resolver *anyway*
2330         : $self->_resolve_bindattrs (
2331             undef,  # a fake rsrc
2332             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2333             {},     # a fake column_info bag
2334           )->[0][1]
2335       ;
2336
2337       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2338       # For the time being forcibly stringify whatever is stringifiable
2339       my $vref;
2340
2341       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2342     : defined blessed( $$vref )                             ? "$$vref"
2343                                                             : $$vref
2344     ;
2345     } map { $_->[0] } @$proto_bind ];
2346   };
2347
2348   my $tuple_status = [];
2349   my ($rv, $err);
2350   dbic_internal_try {
2351     $rv = $sth->execute_for_fetch(
2352       $fetch_tuple,
2353       $tuple_status,
2354     );
2355   }
2356   catch {
2357     $err = shift;
2358   };
2359
2360   # Not all DBDs are create equal. Some throw on error, some return
2361   # an undef $rv, and some set $sth->err - try whatever we can
2362   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2363     ! defined $err
2364       and
2365     ( !defined $rv or $sth->err )
2366   );
2367
2368   # Statement must finish even if there was an exception.
2369   dbic_internal_try {
2370     $sth->finish
2371   }
2372   catch {
2373     $err = shift unless defined $err
2374   };
2375
2376   if (defined $err) {
2377     my $i = 0;
2378     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2379
2380     $self->throw_exception("Unexpected populate error: $err")
2381       if ($i > $#$tuple_status);
2382
2383     require Data::Dumper::Concise;
2384     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2385       ($tuple_status->[$i][1] || $err),
2386       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2387     );
2388   }
2389
2390   return $rv;
2391 }
2392
2393 sub _dbh_execute_inserts_with_no_binds {
2394   my ($self, $sth, $count) = @_;
2395
2396   my $err;
2397   dbic_internal_try {
2398     my $dbh = $self->_get_dbh;
2399     local $dbh->{RaiseError} = 1;
2400     local $dbh->{PrintError} = 0;
2401
2402     $sth->execute foreach 1..$count;
2403   }
2404   catch {
2405     $err = shift;
2406   };
2407
2408   # Make sure statement is finished even if there was an exception.
2409   dbic_internal_try {
2410     $sth->finish
2411   }
2412   catch {
2413     $err = shift unless defined $err;
2414   };
2415
2416   $self->throw_exception($err) if defined $err;
2417
2418   return $count;
2419 }
2420
2421 sub update {
2422   #my ($self, $source, @args) = @_;
2423   shift->_execute('update', @_);
2424 }
2425
2426
2427 sub delete {
2428   #my ($self, $source, @args) = @_;
2429   shift->_execute('delete', @_);
2430 }
2431
2432 sub _select {
2433   my $self = shift;
2434   $self->_execute($self->_select_args(@_));
2435 }
2436
2437 sub _select_args_to_query {
2438   my $self = shift;
2439
2440   $self->throw_exception(
2441     "Unable to generate limited query representation with 'software_limit' enabled"
2442   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2443
2444   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2445   #  = $self->_select_args($ident, $select, $cond, $attrs);
2446   my ($op, $ident, @args) =
2447     $self->_select_args(@_);
2448
2449   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2450   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2451
2452   # reuse the bind arrayref
2453   unshift @{$bind}, "($sql)";
2454   \$bind;
2455 }
2456
2457 sub _select_args {
2458   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2459
2460   # FIXME - that kind of caching would be nice to have
2461   # however currently we *may* pass the same $orig_attrs
2462   # with different ident/select/where
2463   # the whole interface needs to be rethought, since it
2464   # was centered around the flawed SQLA API. We can do
2465   # soooooo much better now. But that is also another
2466   # battle...
2467   #return (
2468   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2469   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2470
2471   my $sql_maker = $self->sql_maker;
2472
2473   my $attrs = {
2474     %$orig_attrs,
2475     select => $select,
2476     from => $ident,
2477     where => $where,
2478   };
2479
2480   # MySQL actually recommends this approach.  I cringe.
2481   $attrs->{rows} ||= $sql_maker->__max_int
2482     if $attrs->{offset};
2483
2484   # see if we will need to tear the prefetch apart to satisfy group_by == select
2485   # this is *extremely tricky* to get right, I am still not sure I did
2486   #
2487   my ($prefetch_needs_subquery, @limit_args);
2488
2489   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2490     # we already know there is a valid group_by (we made it) and we know it is
2491     # intended to be based *only* on non-multi stuff
2492     # short circuit the group_by parsing below
2493     $prefetch_needs_subquery = 1;
2494   }
2495   elsif (
2496     # The rationale is that even if we do *not* have collapse, we still
2497     # need to wrap the core grouped select/group_by in a subquery
2498     # so that databases that care about group_by/select equivalence
2499     # are happy (this includes MySQL in strict_mode)
2500     # If any of the other joined tables are referenced in the group_by
2501     # however - the user is on their own
2502     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2503       and
2504     $attrs->{group_by}
2505       and
2506     @{$attrs->{group_by}}
2507       and
2508     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2509       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2510     }
2511   ) {
2512     # no aliases other than our own in group_by
2513     # if there are - do not allow subquery even if limit is present
2514     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2515   }
2516   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2517     # active collapse with a limit - that one is a no-brainer unless
2518     # overruled by a group_by above
2519     $prefetch_needs_subquery = 1;
2520   }
2521
2522   if ($prefetch_needs_subquery) {
2523     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2524   }
2525   elsif (! $attrs->{software_limit} ) {
2526     push @limit_args, (
2527       $attrs->{rows} || (),
2528       $attrs->{offset} || (),
2529     );
2530   }
2531
2532   # try to simplify the joinmap further (prune unreferenced type-single joins)
2533   if (
2534     ! $prefetch_needs_subquery  # already pruned
2535       and
2536     ref $attrs->{from}
2537       and
2538     reftype $attrs->{from} eq 'ARRAY'
2539       and
2540     @{$attrs->{from}} != 1
2541   ) {
2542     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2543   }
2544
2545   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2546   # during the result inflation stage we *need* to know what was the aliastype
2547   # map as sqla saw it when the final pieces of SQL were being assembled
2548   # Originally we simply carried around the entirety of $attrs, but this
2549   # resulted in resultsets that are being reused growing continuously, as
2550   # the hash in question grew deeper and deeper.
2551   # Instead hand-pick what to take with us here (we actually don't need much
2552   # at this point just the map itself)
2553   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2554
2555 ###
2556   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2557   #
2558   # This would be the point to deflate anything found in $attrs->{where}
2559   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2560   # expect a result object. And all we have is a resultsource (it is trivial
2561   # to extract deflator coderefs via $alias2source above).
2562   #
2563   # I don't see a way forward other than changing the way deflators are
2564   # invoked, and that's just bad...
2565 ###
2566
2567   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2568 }
2569
2570 # Returns a counting SELECT for a simple count
2571 # query. Abstracted so that a storage could override
2572 # this to { count => 'firstcol' } or whatever makes
2573 # sense as a performance optimization
2574 sub _count_select {
2575   #my ($self, $source, $rs_attrs) = @_;
2576   return { count => '*' };
2577 }
2578
2579 =head2 select
2580
2581 =over 4
2582
2583 =item Arguments: $ident, $select, $condition, $attrs
2584
2585 =back
2586
2587 Handle a SQL select statement.
2588
2589 =cut
2590
2591 sub select {
2592   my $self = shift;
2593   my ($ident, $select, $condition, $attrs) = @_;
2594   return $self->cursor_class->new($self, \@_, $attrs);
2595 }
2596
2597 sub select_single {
2598   my $self = shift;
2599   my ($rv, $sth, @bind) = $self->_select(@_);
2600   my @row = $sth->fetchrow_array;
2601   my @nextrow = $sth->fetchrow_array if @row;
2602   if(@row && @nextrow) {
2603     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2604   }
2605   # Need to call finish() to work round broken DBDs
2606   $sth->finish();
2607   return @row;
2608 }
2609
2610 =head2 sql_limit_dialect
2611
2612 This is an accessor for the default SQL limit dialect used by a particular
2613 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2614 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2615 see L<DBIx::Class::SQLMaker::LimitDialects>.
2616
2617 =cut
2618
2619 sub _dbh_columns_info_for {
2620   my ($self, $dbh, $table) = @_;
2621
2622   my %result;
2623
2624   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2625     dbic_internal_try {
2626       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2627       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2628       $sth->execute();
2629       while ( my $info = $sth->fetchrow_hashref() ){
2630         my %column_info;
2631         $column_info{data_type}   = $info->{TYPE_NAME};
2632         $column_info{size}      = $info->{COLUMN_SIZE};
2633         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2634         $column_info{default_value} = $info->{COLUMN_DEF};
2635         my $col_name = $info->{COLUMN_NAME};
2636         $col_name =~ s/^\"(.*)\"$/$1/;
2637
2638         $result{$col_name} = \%column_info;
2639       }
2640     } catch {
2641       %result = ();
2642     };
2643
2644     return \%result if keys %result;
2645   }
2646
2647   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2648   $sth->execute;
2649
2650 ### The acrobatics with lc names is necessary to support both the legacy
2651 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2652 ### with column names differing in cas eonly (thanks pg!)
2653
2654   my ($columns, $seen_lcs);
2655
2656   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2657     idx => scalar keys %$columns,
2658     name => $_,
2659     lc_name => lc($_),
2660   } for @{$sth->{NAME}};
2661
2662   $seen_lcs->{$_->{lc_name}} == 1
2663     and
2664   $_->{name} = $_->{lc_name}
2665     for values %$columns;
2666
2667   for ( values %$columns ) {
2668     my $inf = {
2669       data_type => $sth->{TYPE}->[$_->{idx}],
2670       size => $sth->{PRECISION}->[$_->{idx}],
2671       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2672     };
2673
2674     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2675       @{$inf}{qw( data_type  size)} = ($1, $2);
2676     }
2677
2678     $result{$_->{name}} = $inf;
2679   }
2680
2681   $sth->finish;
2682
2683   if ($dbh->can('type_info')) {
2684     for my $inf (values %result) {
2685       next if ! defined $inf->{data_type};
2686
2687       $inf->{data_type} = (
2688         (
2689           (
2690             $dbh->type_info( $inf->{data_type} )
2691               ||
2692             next
2693           )
2694             ||
2695           next
2696         )->{TYPE_NAME}
2697           ||
2698         next
2699       );
2700
2701       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2702       # needs more testing in the future...
2703       $inf->{size} -= 4 if (
2704         ( $inf->{size}||0 > 4 )
2705           and
2706         $inf->{data_type} =~ qr/^text$/i
2707       );
2708     }
2709
2710   }
2711
2712   return \%result;
2713 }
2714
2715 sub columns_info_for {
2716   my ($self, $table) = @_;
2717   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2718 }
2719
2720 =head2 last_insert_id
2721
2722 Return the row id of the last insert.
2723
2724 =cut
2725
2726 sub _dbh_last_insert_id {
2727     my ($self, $dbh, $source, $col) = @_;
2728
2729     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2730
2731     return $id if defined $id;
2732
2733     my $class = ref $self;
2734     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2735 }
2736
2737 sub last_insert_id {
2738   my $self = shift;
2739   $self->_dbh_last_insert_id ($self->_dbh, @_);
2740 }
2741
2742 =head2 _native_data_type
2743
2744 =over 4
2745
2746 =item Arguments: $type_name
2747
2748 =back
2749
2750 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2751 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2752 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2753
2754 The default implementation returns C<undef>, implement in your Storage driver if
2755 you need this functionality.
2756
2757 Should map types from other databases to the native RDBMS type, for example
2758 C<VARCHAR2> to C<VARCHAR>.
2759
2760 Types with modifiers should map to the underlying data type. For example,
2761 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2762
2763 Composite types should map to the container type, for example
2764 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2765
2766 =cut
2767
2768 sub _native_data_type {
2769   #my ($self, $data_type) = @_;
2770   return undef
2771 }
2772
2773 # Check if placeholders are supported at all
2774 sub _determine_supports_placeholders {
2775   my $self = shift;
2776   my $dbh  = $self->_get_dbh;
2777
2778   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2779   # but it is inaccurate more often than not
2780   ( dbic_internal_try {
2781     local $dbh->{PrintError} = 0;
2782     local $dbh->{RaiseError} = 1;
2783     $dbh->do('select ?', {}, 1);
2784     1;
2785   } )
2786     ? 1
2787     : 0
2788   ;
2789 }
2790
2791 # Check if placeholders bound to non-string types throw exceptions
2792 #
2793 sub _determine_supports_typeless_placeholders {
2794   my $self = shift;
2795   my $dbh  = $self->_get_dbh;
2796
2797   ( dbic_internal_try {
2798     local $dbh->{PrintError} = 0;
2799     local $dbh->{RaiseError} = 1;
2800     # this specifically tests a bind that is NOT a string
2801     $dbh->do('select 1 where 1 = ?', {}, 1);
2802     1;
2803   } )
2804     ? 1
2805     : 0
2806   ;
2807 }
2808
2809 =head2 sqlt_type
2810
2811 Returns the database driver name.
2812
2813 =cut
2814
2815 sub sqlt_type {
2816   shift->_get_dbh->{Driver}->{Name};
2817 }
2818
2819 =head2 bind_attribute_by_data_type
2820
2821 Given a datatype from column info, returns a database specific bind
2822 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2823 let the database planner just handle it.
2824
2825 This method is always called after the driver has been determined and a DBI
2826 connection has been established. Therefore you can refer to C<DBI::$constant>
2827 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2828 the correct modules.
2829
2830 =cut
2831
2832 sub bind_attribute_by_data_type {
2833     return;
2834 }
2835
2836 =head2 is_datatype_numeric
2837
2838 Given a datatype from column_info, returns a boolean value indicating if
2839 the current RDBMS considers it a numeric value. This controls how
2840 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2841 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2842 be performed instead of the usual C<eq>.
2843
2844 =cut
2845
2846 sub is_datatype_numeric {
2847   #my ($self, $dt) = @_;
2848
2849   return 0 unless $_[1];
2850
2851   $_[1] =~ /^ (?:
2852     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2853   ) $/ix;
2854 }
2855
2856
2857 =head2 create_ddl_dir
2858
2859 =over 4
2860
2861 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2862
2863 =back
2864
2865 Creates a SQL file based on the Schema, for each of the specified
2866 database engines in C<\@databases> in the given directory.
2867 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2868
2869 Given a previous version number, this will also create a file containing
2870 the ALTER TABLE statements to transform the previous schema into the
2871 current one. Note that these statements may contain C<DROP TABLE> or
2872 C<DROP COLUMN> statements that can potentially destroy data.
2873
2874 The file names are created using the C<ddl_filename> method below, please
2875 override this method in your schema if you would like a different file
2876 name format. For the ALTER file, the same format is used, replacing
2877 $version in the name with "$preversion-$version".
2878
2879 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2880 The most common value for this would be C<< { add_drop_table => 1 } >>
2881 to have the SQL produced include a C<DROP TABLE> statement for each table
2882 created. For quoting purposes supply C<quote_identifiers>.
2883
2884 If no arguments are passed, then the following default values are assumed:
2885
2886 =over 4
2887
2888 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2889
2890 =item version    - $schema->schema_version
2891
2892 =item directory  - './'
2893
2894 =item preversion - <none>
2895
2896 =back
2897
2898 By default, C<\%sqlt_args> will have
2899
2900  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2901
2902 merged with the hash passed in. To disable any of those features, pass in a
2903 hashref like the following
2904
2905  { ignore_constraint_names => 0, # ... other options }
2906
2907
2908 WARNING: You are strongly advised to check all SQL files created, before applying
2909 them.
2910
2911 =cut
2912
2913 sub create_ddl_dir {
2914   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2915
2916   unless ($dir) {
2917     carp "No directory given, using ./\n";
2918     $dir = './';
2919   } else {
2920       -d $dir
2921         or
2922       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2923         or
2924       $self->throw_exception(
2925         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2926       );
2927   }
2928
2929   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2930
2931   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2932   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2933
2934   my $schema_version = $schema->schema_version || '1.x';
2935   $version ||= $schema_version;
2936
2937   $sqltargs = {
2938     add_drop_table => 1,
2939     ignore_constraint_names => 1,
2940     ignore_index_names => 1,
2941     quote_identifiers => $self->sql_maker->_quoting_enabled,
2942     %{$sqltargs || {}}
2943   };
2944
2945   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2946     $self->throw_exception("Can't create a ddl file without $missing");
2947   }
2948
2949   my $sqlt = SQL::Translator->new( $sqltargs );
2950
2951   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2952   my $sqlt_schema = $sqlt->translate({ data => $schema })
2953     or $self->throw_exception ($sqlt->error);
2954
2955   foreach my $db (@$databases) {
2956     $sqlt->reset();
2957     $sqlt->{schema} = $sqlt_schema;
2958     $sqlt->producer($db);
2959
2960     my $file;
2961     my $filename = $schema->ddl_filename($db, $version, $dir);
2962     if (-e $filename && ($version eq $schema_version )) {
2963       # if we are dumping the current version, overwrite the DDL
2964       carp "Overwriting existing DDL file - $filename";
2965       unlink($filename);
2966     }
2967
2968     my $output = $sqlt->translate;
2969     if(!$output) {
2970       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2971       next;
2972     }
2973     if(!open($file, ">$filename")) {
2974       $self->throw_exception("Can't open $filename for writing ($!)");
2975       next;
2976     }
2977     print $file $output;
2978     close($file);
2979
2980     next unless ($preversion);
2981
2982     require SQL::Translator::Diff;
2983
2984     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2985     if(!-e $prefilename) {
2986       carp("No previous schema file found ($prefilename)");
2987       next;
2988     }
2989
2990     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2991     if(-e $difffile) {
2992       carp("Overwriting existing diff file - $difffile");
2993       unlink($difffile);
2994     }
2995
2996     my $source_schema;
2997     {
2998       my $t = SQL::Translator->new($sqltargs);
2999       $t->debug( 0 );
3000       $t->trace( 0 );
3001
3002       $t->parser( $db )
3003         or $self->throw_exception ($t->error);
3004
3005       my $out = $t->translate( $prefilename )
3006         or $self->throw_exception ($t->error);
3007
3008       $source_schema = $t->schema;
3009
3010       $source_schema->name( $prefilename )
3011         unless ( $source_schema->name );
3012     }
3013
3014     # The "new" style of producers have sane normalization and can support
3015     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3016     # And we have to diff parsed SQL against parsed SQL.
3017     my $dest_schema = $sqlt_schema;
3018
3019     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3020       my $t = SQL::Translator->new($sqltargs);
3021       $t->debug( 0 );
3022       $t->trace( 0 );
3023
3024       $t->parser( $db )
3025         or $self->throw_exception ($t->error);
3026
3027       my $out = $t->translate( $filename )
3028         or $self->throw_exception ($t->error);
3029
3030       $dest_schema = $t->schema;
3031
3032       $dest_schema->name( $filename )
3033         unless $dest_schema->name;
3034     }
3035
3036     my $diff = do {
3037       # FIXME - this is a terrible workaround for
3038       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3039       # Fixing it in this sloppy manner so that we don't hve to
3040       # lockstep an SQLT release as well. Needs to be removed at
3041       # some point, and SQLT dep bumped
3042       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3043         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3044
3045       SQL::Translator::Diff::schema_diff($source_schema, $db,
3046                                          $dest_schema,   $db,
3047                                          $sqltargs
3048                                        );
3049     };
3050
3051     if(!open $file, ">$difffile") {
3052       $self->throw_exception("Can't write to $difffile ($!)");
3053       next;
3054     }
3055     print $file $diff;
3056     close($file);
3057   }
3058 }
3059
3060 =head2 deployment_statements
3061
3062 =over 4
3063
3064 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3065
3066 =back
3067
3068 Returns the statements used by L<DBIx::Class::Storage/deploy>
3069 and L<DBIx::Class::Schema/deploy>.
3070
3071 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3072 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3073
3074 C<$directory> is used to return statements from files in a previously created
3075 L</create_ddl_dir> directory and is optional. The filenames are constructed
3076 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3077
3078 If no C<$directory> is specified then the statements are constructed on the
3079 fly using L<SQL::Translator> and C<$version> is ignored.
3080
3081 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3082
3083 =cut
3084
3085 sub deployment_statements {
3086   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3087   $type ||= $self->sqlt_type;
3088   $version ||= $schema->schema_version || '1.x';
3089   $dir ||= './';
3090   my $filename = $schema->ddl_filename($type, $version, $dir);
3091   if(-f $filename)
3092   {
3093       # FIXME replace this block when a proper sane sql parser is available
3094       my $file;
3095       open($file, "<$filename")
3096         or $self->throw_exception("Can't open $filename ($!)");
3097       my @rows = <$file>;
3098       close($file);
3099       return join('', @rows);
3100   }
3101
3102   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3103     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3104   }
3105
3106   # sources needs to be a parser arg, but for simplicity allow at top level
3107   # coming in
3108   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3109       if exists $sqltargs->{sources};
3110
3111   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3112     unless exists $sqltargs->{quote_identifiers};
3113
3114   my $tr = SQL::Translator->new(
3115     producer => "SQL::Translator::Producer::${type}",
3116     %$sqltargs,
3117     parser => 'SQL::Translator::Parser::DBIx::Class',
3118     data => $schema,
3119   );
3120
3121   return preserve_context {
3122     $tr->translate
3123   } after => sub {
3124     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3125       unless defined $_[0];
3126   };
3127 }
3128
3129 # FIXME deploy() currently does not accurately report sql errors
3130 # Will always return true while errors are warned
3131 sub deploy {
3132   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3133   my $deploy = sub {
3134     my $line = shift;
3135     return if(!$line);
3136     return if($line =~ /^--/);
3137     # next if($line =~ /^DROP/m);
3138     return if($line =~ /^BEGIN TRANSACTION/m);
3139     return if($line =~ /^COMMIT/m);
3140     return if $line =~ /^\s+$/; # skip whitespace only
3141     $self->_query_start($line);
3142     dbic_internal_try {
3143       # do a dbh_do cycle here, as we need some error checking in
3144       # place (even though we will ignore errors)
3145       $self->dbh_do (sub { $_[1]->do($line) });
3146     } catch {
3147       carp qq{$_ (running "${line}")};
3148     };
3149     $self->_query_end($line);
3150   };
3151   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3152   if (@statements > 1) {
3153     foreach my $statement (@statements) {
3154       $deploy->( $statement );
3155     }
3156   }
3157   elsif (@statements == 1) {
3158     # split on single line comments and end of statements
3159     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3160       $deploy->( $line );
3161     }
3162   }
3163 }
3164
3165 =head2 datetime_parser
3166
3167 Returns the datetime parser class
3168
3169 =cut
3170
3171 sub datetime_parser {
3172   my $self = shift;
3173   return $self->{datetime_parser} ||= do {
3174     $self->build_datetime_parser(@_);
3175   };
3176 }
3177
3178 =head2 datetime_parser_type
3179
3180 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3181
3182 =head2 build_datetime_parser
3183
3184 See L</datetime_parser>
3185
3186 =cut
3187
3188 sub build_datetime_parser {
3189   my $self = shift;
3190   my $type = $self->datetime_parser_type(@_);
3191   return $type;
3192 }
3193
3194
3195 =head2 is_replicating
3196
3197 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3198 replicate from a master database.  Default is undef, which is the result
3199 returned by databases that don't support replication.
3200
3201 =cut
3202
3203 sub is_replicating {
3204     return;
3205
3206 }
3207
3208 =head2 lag_behind_master
3209
3210 Returns a number that represents a certain amount of lag behind a master db
3211 when a given storage is replicating.  The number is database dependent, but
3212 starts at zero and increases with the amount of lag. Default in undef
3213
3214 =cut
3215
3216 sub lag_behind_master {
3217     return;
3218 }
3219
3220 =head2 relname_to_table_alias
3221
3222 =over 4
3223
3224 =item Arguments: $relname, $join_count
3225
3226 =item Return Value: $alias
3227
3228 =back
3229
3230 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3231 queries.
3232
3233 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3234 way these aliases are named.
3235
3236 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3237 otherwise C<"$relname">.
3238
3239 =cut
3240
3241 sub relname_to_table_alias {
3242   my ($self, $relname, $join_count) = @_;
3243
3244   my $alias = ($join_count && $join_count > 1 ?
3245     join('_', $relname, $join_count) : $relname);
3246
3247   return $alias;
3248 }
3249
3250 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3251 # version and it may be necessary to amend or override it for a specific storage
3252 # if such binds are necessary.
3253 sub _max_column_bytesize {
3254   my ($self, $attr) = @_;
3255
3256   my $max_size;
3257
3258   if ($attr->{sqlt_datatype}) {
3259     my $data_type = lc($attr->{sqlt_datatype});
3260
3261     if ($attr->{sqlt_size}) {
3262
3263       # String/sized-binary types
3264       if ($data_type =~ /^(?:
3265           l? (?:var)? char(?:acter)? (?:\s*varying)?
3266             |
3267           (?:var)? binary (?:\s*varying)?
3268             |
3269           raw
3270         )\b/x
3271       ) {
3272         $max_size = $attr->{sqlt_size};
3273       }
3274       # Other charset/unicode types, assume scale of 4
3275       elsif ($data_type =~ /^(?:
3276           national \s* character (?:\s*varying)?
3277             |
3278           nchar
3279             |
3280           univarchar
3281             |
3282           nvarchar
3283         )\b/x
3284       ) {
3285         $max_size = $attr->{sqlt_size} * 4;
3286       }
3287     }
3288
3289     if (!$max_size and !$self->_is_lob_type($data_type)) {
3290       $max_size = 100 # for all other (numeric?) datatypes
3291     }
3292   }
3293
3294   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3295 }
3296
3297 # Determine if a data_type is some type of BLOB
3298 sub _is_lob_type {
3299   my ($self, $data_type) = @_;
3300   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3301     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3302                                   |varchar|character\s*varying|nvarchar
3303                                   |national\s*character\s*varying))?\z/xi);
3304 }
3305
3306 sub _is_binary_lob_type {
3307   my ($self, $data_type) = @_;
3308   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3309     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3310 }
3311
3312 sub _is_text_lob_type {
3313   my ($self, $data_type) = @_;
3314   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3315     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3316                         |national\s*character\s*varying))\z/xi);
3317 }
3318
3319 # Determine if a data_type is some type of a binary type
3320 sub _is_binary_type {
3321   my ($self, $data_type) = @_;
3322   $data_type && ($self->_is_binary_lob_type($data_type)
3323     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3324 }
3325
3326 1;
3327
3328 =head1 USAGE NOTES
3329
3330 =head2 DBIx::Class and AutoCommit
3331
3332 DBIx::Class can do some wonderful magic with handling exceptions,
3333 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3334 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3335 transaction support.
3336
3337 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3338 in an assumed transaction between commits, and you're telling us you'd
3339 like to manage that manually.  A lot of the magic protections offered by
3340 this module will go away.  We can't protect you from exceptions due to database
3341 disconnects because we don't know anything about how to restart your
3342 transactions.  You're on your own for handling all sorts of exceptional
3343 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3344 be with raw DBI.
3345
3346 =head1 FURTHER QUESTIONS?
3347
3348 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3349
3350 =head1 COPYRIGHT AND LICENSE
3351
3352 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3353 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3354 redistribute it and/or modify it under the same terms as the
3355 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.