lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use Data::Compare (); # no imports!!! guard against insane architecture
  16 use SQL::Abstract qw(is_plain_value is_literal_value);
  17 use DBIx::Class::_Util qw(quote_sub perlstring);
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. We also need to separate accessors
  83 # from plain old method calls, since an accessor called as a setter
  84 # does *not* need the driver determination loop fired (and in fact
  85 # can produce hard to find bugs, like e.g. losing on_connect_*
  86 # semantics on fresh connections)
  87 #
  88 # The construct below is simply a parameterized around()
  89 my $storage_accessor_idx = { map { $_ => 1 } qw(
  90   sqlt_type
  91   datetime_parser_type
  92
  93   sql_maker
  94   cursor_class
  95 )};
  96 for my $meth (keys %$storage_accessor_idx, qw(
  97   deployment_statements
  98
  99   build_datetime_parser
 100
 101   txn_begin
 102
 103   insert
 104   update
 105   delete
 106   select
 107   select_single
 108
 109   _insert_bulk
 110
 111   with_deferred_fk_checks
 112
 113   get_use_dbms_capability
 114   get_dbms_capability
 115
 116   _server_info
 117   _get_server_version
 118 )) {
 119
 120   my $orig = __PACKAGE__->can ($meth)
 121     or die "$meth is not a ::Storage::DBI method!";
 122
 123   my $is_getter = $storage_accessor_idx->{$meth} ? 0 : 1;
 124
 125   quote_sub
 126     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $is_getter, perlstring $meth ), { '$orig' => \$orig };
 127
 128     if (
 129       # only fire when invoked on an instance, a valid class-based invocation
 130       # would e.g. be setting a default for an inherited accessor
 131       ref $_[0]
 132         and
 133       ! $_[0]->{_driver_determined}
 134         and
 135       ! $_[0]->{_in_determine_driver}
 136         and
 137       # if this is a known *setter* - just set it, no need to connect
 138       # and determine the driver
 139       ( %1$s or @_ <= 1 )
 140         and
 141       # Only try to determine stuff if we have *something* that either is or can
 142       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 143       # to still be marginally useful
 144       $_[0]->_dbi_connect_info->[0]
 145     ) {
 146       $_[0]->_determine_driver;
 147
 148       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 149       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 150
 151       my $cref = $_[0]->can(%2$s);
 152       goto $cref;
 153     }
 154
 155     goto $orig;
 156 EOC
 157 }
 158
 159 =head1 NAME
 160
 161 DBIx::Class::Storage::DBI - DBI storage handler
 162
 163 =head1 SYNOPSIS
 164
 165   my $schema = MySchema->connect('dbi:SQLite:my.db');
 166
 167   $schema->storage->debug(1);
 168
 169   my @stuff = $schema->storage->dbh_do(
 170     sub {
 171       my ($storage, $dbh, @args) = @_;
 172       $dbh->do("DROP TABLE authors");
 173     },
 174     @column_list
 175   );
 176
 177   $schema->resultset('Book')->search({
 178      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 179   });
 180
 181 =head1 DESCRIPTION
 182
 183 This class represents the connection to an RDBMS via L<DBI>.  See
 184 L<DBIx::Class::Storage> for general information.  This pod only
 185 documents DBI-specific methods and behaviors.
 186
 187 =head1 METHODS
 188
 189 =cut
 190
 191 sub new {
 192   my $new = shift->next::method(@_);
 193
 194   $new->_sql_maker_opts({});
 195   $new->_dbh_details({});
 196   $new->{_in_do_block} = 0;
 197
 198   # read below to see what this does
 199   $new->_arm_global_destructor;
 200
 201   $new;
 202 }
 203
 204 # This is hack to work around perl shooting stuff in random
 205 # order on exit(). If we do not walk the remaining storage
 206 # objects in an END block, there is a *small but real* chance
 207 # of a fork()ed child to kill the parent's shared DBI handle,
 208 # *before perl reaches the DESTROY in this package*
 209 # Yes, it is ugly and effective.
 210 # Additionally this registry is used by the CLONE method to
 211 # make sure no handles are shared between threads
 212 {
 213   my %seek_and_destroy;
 214
 215   sub _arm_global_destructor {
 216
 217     # quick "garbage collection" pass - prevents the registry
 218     # from slowly growing with a bunch of undef-valued keys
 219     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 220       for keys %seek_and_destroy;
 221
 222     weaken (
 223       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 224     );
 225   }
 226
 227   END {
 228     local $?; # just in case the DBI destructor changes it somehow
 229
 230     # destroy just the object if not native to this process
 231     $_->_verify_pid for (grep
 232       { defined $_ }
 233       values %seek_and_destroy
 234     );
 235   }
 236
 237   sub CLONE {
 238     # As per DBI's recommendation, DBIC disconnects all handles as
 239     # soon as possible (DBIC will reconnect only on demand from within
 240     # the thread)
 241     my @instances = grep { defined $_ } values %seek_and_destroy;
 242     %seek_and_destroy = ();
 243
 244     for (@instances) {
 245       $_->_dbh(undef);
 246
 247       $_->transaction_depth(0);
 248       $_->savepoints([]);
 249
 250       # properly renumber existing refs
 251       $_->_arm_global_destructor
 252     }
 253   }
 254 }
 255
 256 sub DESTROY {
 257   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 258   # some databases spew warnings on implicit disconnect
 259   local $SIG{__WARN__} = sub {};
 260   $_[0]->_dbh(undef);
 261
 262   # this op is necessary, since the very last perl runtime statement
 263   # triggers a global destruction shootout, and the $SIG localization
 264   # may very well be destroyed before perl actually gets to do the
 265   # $dbh undef
 266   1;
 267 }
 268
 269 # handle pid changes correctly - do not destroy parent's connection
 270 sub _verify_pid {
 271
 272   my $pid = $_[0]->_conn_pid;
 273
 274   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 275     $dbh->{InactiveDestroy} = 1;
 276     $_[0]->_dbh(undef);
 277     $_[0]->transaction_depth(0);
 278     $_[0]->savepoints([]);
 279   }
 280
 281   return;
 282 }
 283
 284 =head2 connect_info
 285
 286 This method is normally called by L<DBIx::Class::Schema/connection>, which
 287 encapsulates its argument list in an arrayref before passing them here.
 288
 289 The argument list may contain:
 290
 291 =over
 292
 293 =item *
 294
 295 The same 4-element argument set one would normally pass to
 296 L<DBI/connect>, optionally followed by
 297 L<extra attributes|/DBIx::Class specific connection attributes>
 298 recognized by DBIx::Class:
 299
 300   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 301
 302 =item *
 303
 304 A single code reference which returns a connected
 305 L<DBI database handle|DBI/connect> optionally followed by
 306 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 307 by DBIx::Class:
 308
 309   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 310
 311 =item *
 312
 313 A single hashref with all the attributes and the dsn/user/password
 314 mixed together:
 315
 316   $connect_info_args = [{
 317     dsn => $dsn,
 318     user => $user,
 319     password => $pass,
 320     %dbi_attributes,
 321     %extra_attributes,
 322   }];
 323
 324   $connect_info_args = [{
 325     dbh_maker => sub { DBI->connect (...) },
 326     %dbi_attributes,
 327     %extra_attributes,
 328   }];
 329
 330 This is particularly useful for L<Catalyst> based applications, allowing the
 331 following config (L<Config::General> style):
 332
 333   <Model::DB>
 334     schema_class   App::DB
 335     <connect_info>
 336       dsn          dbi:mysql:database=test
 337       user         testuser
 338       password     TestPass
 339       AutoCommit   1
 340     </connect_info>
 341   </Model::DB>
 342
 343 The C<dsn>/C<user>/C<password> combination can be substituted by the
 344 C<dbh_maker> key whose value is a coderef that returns a connected
 345 L<DBI database handle|DBI/connect>
 346
 347 =back
 348
 349 Please note that the L<DBI> docs recommend that you always explicitly
 350 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 351 recommends that it be set to I<1>, and that you perform transactions
 352 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 353 to I<1> if you do not do explicitly set it to zero.  This is the default
 354 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 355
 356 =head3 DBIx::Class specific connection attributes
 357
 358 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 359 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 360 the following connection options. These options can be mixed in with your other
 361 L<DBI> connection attributes, or placed in a separate hashref
 362 (C<\%extra_attributes>) as shown above.
 363
 364 Every time C<connect_info> is invoked, any previous settings for
 365 these options will be cleared before setting the new ones, regardless of
 366 whether any options are specified in the new C<connect_info>.
 367
 368
 369 =over
 370
 371 =item on_connect_do
 372
 373 Specifies things to do immediately after connecting or re-connecting to
 374 the database.  Its value may contain:
 375
 376 =over
 377
 378 =item a scalar
 379
 380 This contains one SQL statement to execute.
 381
 382 =item an array reference
 383
 384 This contains SQL statements to execute in order.  Each element contains
 385 a string or a code reference that returns a string.
 386
 387 =item a code reference
 388
 389 This contains some code to execute.  Unlike code references within an
 390 array reference, its return value is ignored.
 391
 392 =back
 393
 394 =item on_disconnect_do
 395
 396 Takes arguments in the same form as L</on_connect_do> and executes them
 397 immediately before disconnecting from the database.
 398
 399 Note, this only runs if you explicitly call L</disconnect> on the
 400 storage object.
 401
 402 =item on_connect_call
 403
 404 A more generalized form of L</on_connect_do> that calls the specified
 405 C<connect_call_METHOD> methods in your storage driver.
 406
 407   on_connect_do => 'select 1'
 408
 409 is equivalent to:
 410
 411   on_connect_call => [ [ do_sql => 'select 1' ] ]
 412
 413 Its values may contain:
 414
 415 =over
 416
 417 =item a scalar
 418
 419 Will call the C<connect_call_METHOD> method.
 420
 421 =item a code reference
 422
 423 Will execute C<< $code->($storage) >>
 424
 425 =item an array reference
 426
 427 Each value can be a method name or code reference.
 428
 429 =item an array of arrays
 430
 431 For each array, the first item is taken to be the C<connect_call_> method name
 432 or code reference, and the rest are parameters to it.
 433
 434 =back
 435
 436 Some predefined storage methods you may use:
 437
 438 =over
 439
 440 =item do_sql
 441
 442 Executes a SQL string or a code reference that returns a SQL string. This is
 443 what L</on_connect_do> and L</on_disconnect_do> use.
 444
 445 It can take:
 446
 447 =over
 448
 449 =item a scalar
 450
 451 Will execute the scalar as SQL.
 452
 453 =item an arrayref
 454
 455 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 456 attributes hashref and bind values.
 457
 458 =item a code reference
 459
 460 Will execute C<< $code->($storage) >> and execute the return array refs as
 461 above.
 462
 463 =back
 464
 465 =item datetime_setup
 466
 467 Execute any statements necessary to initialize the database session to return
 468 and accept datetime/timestamp values used with
 469 L<DBIx::Class::InflateColumn::DateTime>.
 470
 471 Only necessary for some databases, see your specific storage driver for
 472 implementation details.
 473
 474 =back
 475
 476 =item on_disconnect_call
 477
 478 Takes arguments in the same form as L</on_connect_call> and executes them
 479 immediately before disconnecting from the database.
 480
 481 Calls the C<disconnect_call_METHOD> methods as opposed to the
 482 C<connect_call_METHOD> methods called by L</on_connect_call>.
 483
 484 Note, this only runs if you explicitly call L</disconnect> on the
 485 storage object.
 486
 487 =item disable_sth_caching
 488
 489 If set to a true value, this option will disable the caching of
 490 statement handles via L<DBI/prepare_cached>.
 491
 492 =item limit_dialect
 493
 494 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 495 default L</sql_limit_dialect> setting of the storage (if any). For a list
 496 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 497
 498 =item quote_names
 499
 500 When true automatically sets L</quote_char> and L</name_sep> to the characters
 501 appropriate for your particular RDBMS. This option is preferred over specifying
 502 L</quote_char> directly.
 503
 504 =item quote_char
 505
 506 Specifies what characters to use to quote table and column names.
 507
 508 C<quote_char> expects either a single character, in which case is it
 509 is placed on either side of the table/column name, or an arrayref of length
 510 2 in which case the table/column name is placed between the elements.
 511
 512 For example under MySQL you should use C<< quote_char => '`' >>, and for
 513 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 514
 515 =item name_sep
 516
 517 This parameter is only useful in conjunction with C<quote_char>, and is used to
 518 specify the character that separates elements (schemas, tables, columns) from
 519 each other. If unspecified it defaults to the most commonly used C<.>.
 520
 521 =item unsafe
 522
 523 This Storage driver normally installs its own C<HandleError>, sets
 524 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 525 all database handles, including those supplied by a coderef.  It does this
 526 so that it can have consistent and useful error behavior.
 527
 528 If you set this option to a true value, Storage will not do its usual
 529 modifications to the database handle's attributes, and instead relies on
 530 the settings in your connect_info DBI options (or the values you set in
 531 your connection coderef, in the case that you are connecting via coderef).
 532
 533 Note that your custom settings can cause Storage to malfunction,
 534 especially if you set a C<HandleError> handler that suppresses exceptions
 535 and/or disable C<RaiseError>.
 536
 537 =item auto_savepoint
 538
 539 If this option is true, L<DBIx::Class> will use savepoints when nesting
 540 transactions, making it possible to recover from failure in the inner
 541 transaction without having to abort all outer transactions.
 542
 543 =item cursor_class
 544
 545 Use this argument to supply a cursor class other than the default
 546 L<DBIx::Class::Storage::DBI::Cursor>.
 547
 548 =back
 549
 550 Some real-life examples of arguments to L</connect_info> and
 551 L<DBIx::Class::Schema/connect>
 552
 553   # Simple SQLite connection
 554   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 555
 556   # Connect via subref
 557   ->connect_info([ sub { DBI->connect(...) } ]);
 558
 559   # Connect via subref in hashref
 560   ->connect_info([{
 561     dbh_maker => sub { DBI->connect(...) },
 562     on_connect_do => 'alter session ...',
 563   }]);
 564
 565   # A bit more complicated
 566   ->connect_info(
 567     [
 568       'dbi:Pg:dbname=foo',
 569       'postgres',
 570       'my_pg_password',
 571       { AutoCommit => 1 },
 572       { quote_char => q{"} },
 573     ]
 574   );
 575
 576   # Equivalent to the previous example
 577   ->connect_info(
 578     [
 579       'dbi:Pg:dbname=foo',
 580       'postgres',
 581       'my_pg_password',
 582       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 583     ]
 584   );
 585
 586   # Same, but with hashref as argument
 587   # See parse_connect_info for explanation
 588   ->connect_info(
 589     [{
 590       dsn         => 'dbi:Pg:dbname=foo',
 591       user        => 'postgres',
 592       password    => 'my_pg_password',
 593       AutoCommit  => 1,
 594       quote_char  => q{"},
 595       name_sep    => q{.},
 596     }]
 597   );
 598
 599   # Subref + DBIx::Class-specific connection options
 600   ->connect_info(
 601     [
 602       sub { DBI->connect(...) },
 603       {
 604           quote_char => q{`},
 605           name_sep => q{@},
 606           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 607           disable_sth_caching => 1,
 608       },
 609     ]
 610   );
 611
 612
 613
 614 =cut
 615
 616 sub connect_info {
 617   my ($self, $info) = @_;
 618
 619   return $self->_connect_info if !$info;
 620
 621   $self->_connect_info($info); # copy for _connect_info
 622
 623   $info = $self->_normalize_connect_info($info)
 624     if ref $info eq 'ARRAY';
 625
 626   my %attrs = (
 627     %{ $self->_default_dbi_connect_attributes || {} },
 628     %{ $info->{attributes} || {} },
 629   );
 630
 631   my @args = @{ $info->{arguments} };
 632
 633   if (keys %attrs and ref $args[0] ne 'CODE') {
 634     carp_unique (
 635         'You provided explicit AutoCommit => 0 in your connection_info. '
 636       . 'This is almost universally a bad idea (see the footnotes of '
 637       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 638       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 639       . 'this warning.'
 640     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 641
 642     push @args, \%attrs if keys %attrs;
 643   }
 644
 645   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 646   # OR a single-element coderef-based $dbh factory
 647   $self->_dbi_connect_info(\@args);
 648
 649   # extract the individual storage options
 650   for my $storage_opt (keys %{ $info->{storage_options} }) {
 651     my $value = $info->{storage_options}{$storage_opt};
 652
 653     $self->$storage_opt($value);
 654   }
 655
 656   # Extract the individual sqlmaker options
 657   #
 658   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 659   #  the new set of options
 660   $self->_sql_maker(undef);
 661   $self->_sql_maker_opts({});
 662
 663   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 664     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 665
 666     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 667   }
 668
 669   # FIXME - dirty:
 670   # save attributes in a separate accessor so they are always
 671   # introspectable, even in case of a CODE $dbhmaker
 672   $self->_dbic_connect_attributes (\%attrs);
 673
 674   return $self->_connect_info;
 675 }
 676
 677 sub _dbi_connect_info {
 678   my $self = shift;
 679
 680   return $self->{_dbi_connect_info} = $_[0]
 681     if @_;
 682
 683   my $conninfo = $self->{_dbi_connect_info} || [];
 684
 685   # last ditch effort to grab a DSN
 686   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 687     my @new_conninfo = @$conninfo;
 688     $new_conninfo[0] = $ENV{DBI_DSN};
 689     $conninfo = \@new_conninfo;
 690   }
 691
 692   return $conninfo;
 693 }
 694
 695
 696 sub _normalize_connect_info {
 697   my ($self, $info_arg) = @_;
 698   my %info;
 699
 700   my @args = @$info_arg;  # take a shallow copy for further mutilation
 701
 702   # combine/pre-parse arguments depending on invocation style
 703
 704   my %attrs;
 705   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 706     %attrs = %{ $args[1] || {} };
 707     @args = $args[0];
 708   }
 709   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 710     %attrs = %{$args[0]};
 711     @args = ();
 712     if (my $code = delete $attrs{dbh_maker}) {
 713       @args = $code;
 714
 715       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 716       if (@ignored) {
 717         carp sprintf (
 718             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 719           . "to the result of 'dbh_maker'",
 720
 721           join (', ', map { "'$_'" } (@ignored) ),
 722         );
 723       }
 724     }
 725     else {
 726       @args = delete @attrs{qw/dsn user password/};
 727     }
 728   }
 729   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 730     %attrs = (
 731       % { $args[3] || {} },
 732       % { $args[4] || {} },
 733     );
 734     @args = @args[0,1,2];
 735   }
 736
 737   $info{arguments} = \@args;
 738
 739   my @storage_opts = grep exists $attrs{$_},
 740     @storage_options, 'cursor_class';
 741
 742   @{ $info{storage_options} }{@storage_opts} =
 743     delete @attrs{@storage_opts} if @storage_opts;
 744
 745   my @sql_maker_opts = grep exists $attrs{$_},
 746     qw/limit_dialect quote_char name_sep quote_names/;
 747
 748   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 749     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 750
 751   $info{attributes} = \%attrs if %attrs;
 752
 753   return \%info;
 754 }
 755
 756 sub _default_dbi_connect_attributes () {
 757   +{
 758     AutoCommit => 1,
 759     PrintError => 0,
 760     RaiseError => 1,
 761     ShowErrorStatement => 1,
 762   };
 763 }
 764
 765 =head2 on_connect_do
 766
 767 This method is deprecated in favour of setting via L</connect_info>.
 768
 769 =cut
 770
 771 =head2 on_disconnect_do
 772
 773 This method is deprecated in favour of setting via L</connect_info>.
 774
 775 =cut
 776
 777 sub _parse_connect_do {
 778   my ($self, $type) = @_;
 779
 780   my $val = $self->$type;
 781   return () if not defined $val;
 782
 783   my @res;
 784
 785   if (not ref($val)) {
 786     push @res, [ 'do_sql', $val ];
 787   } elsif (ref($val) eq 'CODE') {
 788     push @res, $val;
 789   } elsif (ref($val) eq 'ARRAY') {
 790     push @res, map { [ 'do_sql', $_ ] } @$val;
 791   } else {
 792     $self->throw_exception("Invalid type for $type: ".ref($val));
 793   }
 794
 795   return \@res;
 796 }
 797
 798 =head2 dbh_do
 799
 800 Arguments: ($subref | $method_name), @extra_coderef_args?
 801
 802 Execute the given $subref or $method_name using the new exception-based
 803 connection management.
 804
 805 The first two arguments will be the storage object that C<dbh_do> was called
 806 on and a database handle to use.  Any additional arguments will be passed
 807 verbatim to the called subref as arguments 2 and onwards.
 808
 809 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 810 exception handling and reconnection (or failover in future subclasses).
 811
 812 Your subref should have no side-effects outside of the database, as
 813 there is the potential for your subref to be partially double-executed
 814 if the database connection was stale/dysfunctional.
 815
 816 Example:
 817
 818   my @stuff = $schema->storage->dbh_do(
 819     sub {
 820       my ($storage, $dbh, @cols) = @_;
 821       my $cols = join(q{, }, @cols);
 822       $dbh->selectrow_array("SELECT $cols FROM foo");
 823     },
 824     @column_list
 825   );
 826
 827 =cut
 828
 829 sub dbh_do {
 830   my $self = shift;
 831   my $run_target = shift; # either a coderef or a method name
 832
 833   # short circuit when we know there is no need for a runner
 834   #
 835   # FIXME - assumption may be wrong
 836   # the rationale for the txn_depth check is that if this block is a part
 837   # of a larger transaction, everything up to that point is screwed anyway
 838   return $self->$run_target($self->_get_dbh, @_)
 839     if $self->{_in_do_block} or $self->transaction_depth;
 840
 841   # take a ref instead of a copy, to preserve @_ aliasing
 842   # semantics within the coderef, but only if needed
 843   # (pseudoforking doesn't like this trick much)
 844   my $args = @_ ? \@_ : [];
 845
 846   DBIx::Class::Storage::BlockRunner->new(
 847     storage => $self,
 848     wrap_txn => 0,
 849     retry_handler => sub {
 850       $_[0]->failed_attempt_count == 1
 851         and
 852       ! $_[0]->storage->connected
 853     },
 854   )->run(sub {
 855     $self->$run_target ($self->_get_dbh, @$args )
 856   });
 857 }
 858
 859 sub txn_do {
 860   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 861   shift->next::method(@_);
 862 }
 863
 864 =head2 disconnect
 865
 866 Our C<disconnect> method also performs a rollback first if the
 867 database is not in C<AutoCommit> mode.
 868
 869 =cut
 870
 871 sub disconnect {
 872
 873   if( my $dbh = $_[0]->_dbh ) {
 874
 875     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 876       ( $_[0]->on_disconnect_call || () ),
 877       $_[0]->_parse_connect_do ('on_disconnect_do')
 878     );
 879
 880     # stops the "implicit rollback on disconnect" warning
 881     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 882
 883     %{ $dbh->{CachedKids} } = ();
 884     $dbh->disconnect;
 885     $_[0]->_dbh(undef);
 886   }
 887 }
 888
 889 =head2 with_deferred_fk_checks
 890
 891 =over 4
 892
 893 =item Arguments: C<$coderef>
 894
 895 =item Return Value: The return value of $coderef
 896
 897 =back
 898
 899 Storage specific method to run the code ref with FK checks deferred or
 900 in MySQL's case disabled entirely.
 901
 902 =cut
 903
 904 # Storage subclasses should override this
 905 sub with_deferred_fk_checks {
 906   #my ($self, $sub) = @_;
 907   $_[1]->();
 908 }
 909
 910 =head2 connected
 911
 912 =over
 913
 914 =item Arguments: none
 915
 916 =item Return Value: 1|0
 917
 918 =back
 919
 920 Verifies that the current database handle is active and ready to execute
 921 an SQL statement (e.g. the connection did not get stale, server is still
 922 answering, etc.) This method is used internally by L</dbh>.
 923
 924 =cut
 925
 926 sub connected {
 927   return 0 unless $_[0]->_seems_connected;
 928
 929   #be on the safe side
 930   local $_[0]->_dbh->{RaiseError} = 1;
 931
 932   return $_[0]->_ping;
 933 }
 934
 935 sub _seems_connected {
 936   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 937
 938   ($_[0]->_dbh || return 0)->FETCH('Active');
 939 }
 940
 941 sub _ping {
 942   ($_[0]->_dbh || return 0)->ping;
 943 }
 944
 945 sub ensure_connected {
 946   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 947 }
 948
 949 =head2 dbh
 950
 951 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 952 is guaranteed to be healthy by implicitly calling L</connected>, and if
 953 necessary performing a reconnection before returning. Keep in mind that this
 954 is very B<expensive> on some database engines. Consider using L</dbh_do>
 955 instead.
 956
 957 =cut
 958
 959 sub dbh {
 960   # maybe save a ping call
 961   $_[0]->_dbh
 962     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 963     : $_[0]->_populate_dbh
 964   ;
 965 }
 966
 967 # this is the internal "get dbh or connect (don't check)" method
 968 sub _get_dbh {
 969   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 970   $_[0]->_dbh || $_[0]->_populate_dbh;
 971 }
 972
 973 # *DELIBERATELY* not a setter (for the time being)
 974 # Too intertwined with everything else for any kind of sanity
 975 sub sql_maker {
 976   my $self = shift;
 977
 978   $self->throw_exception('sql_maker() is not a setter method') if @_;
 979
 980   unless ($self->_sql_maker) {
 981     my $sql_maker_class = $self->sql_maker_class;
 982
 983     my %opts = %{$self->_sql_maker_opts||{}};
 984     my $dialect =
 985       $opts{limit_dialect}
 986         ||
 987       $self->sql_limit_dialect
 988         ||
 989       do {
 990         my $s_class = (ref $self) || $self;
 991         carp_unique (
 992           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 993         . 'have not supplied an explicit limit_dialect in your connection_info. '
 994         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 995         . 'databases but can be (and often is) painfully slow. '
 996         . "Please file an RT ticket against '$s_class'"
 997         ) if $self->_dbi_connect_info->[0];
 998
 999         'GenericSubQ';
1000       }
1001     ;
1002
1003     my ($quote_char, $name_sep);
1004
1005     if ($opts{quote_names}) {
1006       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1007         my $s_class = (ref $self) || $self;
1008         carp_unique (
1009           "You requested 'quote_names' but your storage class ($s_class) does "
1010         . 'not explicitly define a default sql_quote_char and you have not '
1011         . 'supplied a quote_char as part of your connection_info. DBIC will '
1012         .q{default to the ANSI SQL standard quote '"', which works most of }
1013         . "the time. Please file an RT ticket against '$s_class'."
1014         );
1015
1016         '"'; # RV
1017       };
1018
1019       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1020     }
1021
1022     $self->_sql_maker($sql_maker_class->new(
1023       bindtype=>'columns',
1024       array_datatypes => 1,
1025       limit_dialect => $dialect,
1026       ($quote_char ? (quote_char => $quote_char) : ()),
1027       name_sep => ($name_sep || '.'),
1028       %opts,
1029     ));
1030   }
1031   return $self->_sql_maker;
1032 }
1033
1034 # nothing to do by default
1035 sub _rebless {}
1036 sub _init {}
1037
1038 sub _populate_dbh {
1039
1040   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1041
1042   $_[0]->_dbh_details({}); # reset everything we know
1043
1044   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1045   #$_[0]->_sql_maker(undef); # this may also end up being different
1046
1047   $_[0]->_dbh($_[0]->_connect);
1048
1049   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1050
1051   $_[0]->_determine_driver;
1052
1053   # Always set the transaction depth on connect, since
1054   #  there is no transaction in progress by definition
1055   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1056
1057   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1058
1059   $_[0]->_dbh;
1060 }
1061
1062 sub _run_connection_actions {
1063
1064   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1065     ( $_[0]->on_connect_call || () ),
1066     $_[0]->_parse_connect_do ('on_connect_do'),
1067   );
1068 }
1069
1070
1071
1072 sub set_use_dbms_capability {
1073   $_[0]->set_inherited ($_[1], $_[2]);
1074 }
1075
1076 sub get_use_dbms_capability {
1077   my ($self, $capname) = @_;
1078
1079   my $use = $self->get_inherited ($capname);
1080   return defined $use
1081     ? $use
1082     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1083   ;
1084 }
1085
1086 sub set_dbms_capability {
1087   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1088 }
1089
1090 sub get_dbms_capability {
1091   my ($self, $capname) = @_;
1092
1093   my $cap = $self->_dbh_details->{capability}{$capname};
1094
1095   unless (defined $cap) {
1096     if (my $meth = $self->can ("_determine$capname")) {
1097       $cap = $self->$meth ? 1 : 0;
1098     }
1099     else {
1100       $cap = 0;
1101     }
1102
1103     $self->set_dbms_capability ($capname, $cap);
1104   }
1105
1106   return $cap;
1107 }
1108
1109 sub _server_info {
1110   my $self = shift;
1111
1112   my $info;
1113   unless ($info = $self->_dbh_details->{info}) {
1114
1115     $info = {};
1116
1117     my $server_version = try {
1118       $self->_get_server_version
1119     } catch {
1120       # driver determination *may* use this codepath
1121       # in which case we must rethrow
1122       $self->throw_exception($_) if $self->{_in_determine_driver};
1123
1124       # $server_version on failure
1125       undef;
1126     };
1127
1128     if (defined $server_version) {
1129       $info->{dbms_version} = $server_version;
1130
1131       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1132       my @verparts = split (/\./, $numeric_version);
1133       if (
1134         @verparts
1135           &&
1136         $verparts[0] <= 999
1137       ) {
1138         # consider only up to 3 version parts, iff not more than 3 digits
1139         my @use_parts;
1140         while (@verparts && @use_parts < 3) {
1141           my $p = shift @verparts;
1142           last if $p > 999;
1143           push @use_parts, $p;
1144         }
1145         push @use_parts, 0 while @use_parts < 3;
1146
1147         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1148       }
1149     }
1150
1151     $self->_dbh_details->{info} = $info;
1152   }
1153
1154   return $info;
1155 }
1156
1157 sub _get_server_version {
1158   shift->_dbh_get_info('SQL_DBMS_VER');
1159 }
1160
1161 sub _dbh_get_info {
1162   my ($self, $info) = @_;
1163
1164   if ($info =~ /[^0-9]/) {
1165     require DBI::Const::GetInfoType;
1166     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1167     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1168       unless defined $info;
1169   }
1170
1171   $self->_get_dbh->get_info($info);
1172 }
1173
1174 sub _describe_connection {
1175   require DBI::Const::GetInfoReturn;
1176
1177   my $self = shift;
1178
1179   my $drv;
1180   try {
1181     $drv = $self->_extract_driver_from_connect_info;
1182     $self->ensure_connected;
1183   };
1184
1185   $drv = "DBD::$drv" if $drv;
1186
1187   my $res = {
1188     DBIC_DSN => $self->_dbi_connect_info->[0],
1189     DBI_VER => DBI->VERSION,
1190     DBIC_VER => DBIx::Class->VERSION,
1191     DBIC_DRIVER => ref $self,
1192     $drv ? (
1193       DBD => $drv,
1194       DBD_VER => try { $drv->VERSION },
1195     ) : (),
1196   };
1197
1198   # try to grab data even if we never managed to connect
1199   # will cover us in cases of an oddly broken half-connect
1200   for my $inf (
1201     #keys %DBI::Const::GetInfoType::GetInfoType,
1202     qw/
1203       SQL_CURSOR_COMMIT_BEHAVIOR
1204       SQL_CURSOR_ROLLBACK_BEHAVIOR
1205       SQL_CURSOR_SENSITIVITY
1206       SQL_DATA_SOURCE_NAME
1207       SQL_DBMS_NAME
1208       SQL_DBMS_VER
1209       SQL_DEFAULT_TXN_ISOLATION
1210       SQL_DM_VER
1211       SQL_DRIVER_NAME
1212       SQL_DRIVER_ODBC_VER
1213       SQL_DRIVER_VER
1214       SQL_EXPRESSIONS_IN_ORDERBY
1215       SQL_GROUP_BY
1216       SQL_IDENTIFIER_CASE
1217       SQL_IDENTIFIER_QUOTE_CHAR
1218       SQL_MAX_CATALOG_NAME_LEN
1219       SQL_MAX_COLUMN_NAME_LEN
1220       SQL_MAX_IDENTIFIER_LEN
1221       SQL_MAX_TABLE_NAME_LEN
1222       SQL_MULTIPLE_ACTIVE_TXN
1223       SQL_MULT_RESULT_SETS
1224       SQL_NEED_LONG_DATA_LEN
1225       SQL_NON_NULLABLE_COLUMNS
1226       SQL_ODBC_VER
1227       SQL_QUALIFIER_NAME_SEPARATOR
1228       SQL_QUOTED_IDENTIFIER_CASE
1229       SQL_TXN_CAPABLE
1230       SQL_TXN_ISOLATION_OPTION
1231     /
1232   ) {
1233     # some drivers barf on things they do not know about instead
1234     # of returning undef
1235     my $v = try { $self->_dbh_get_info($inf) };
1236     next unless defined $v;
1237
1238     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1239     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1240     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1241   }
1242
1243   $res;
1244 }
1245
1246 sub _determine_driver {
1247   my ($self) = @_;
1248
1249   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1250     my $started_connected = 0;
1251     local $self->{_in_determine_driver} = 1;
1252
1253     if (ref($self) eq __PACKAGE__) {
1254       my $driver;
1255       if ($self->_dbh) { # we are connected
1256         $driver = $self->_dbh->{Driver}{Name};
1257         $started_connected = 1;
1258       }
1259       else {
1260         $driver = $self->_extract_driver_from_connect_info;
1261       }
1262
1263       if ($driver) {
1264         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1265         if ($self->load_optional_class($storage_class)) {
1266           mro::set_mro($storage_class, 'c3');
1267           bless $self, $storage_class;
1268           $self->_rebless();
1269         }
1270         else {
1271           $self->_warn_undetermined_driver(
1272             'This version of DBIC does not yet seem to supply a driver for '
1273           . "your particular RDBMS and/or connection method ('$driver')."
1274           );
1275         }
1276       }
1277       else {
1278         $self->_warn_undetermined_driver(
1279           'Unable to extract a driver name from connect info - this '
1280         . 'should not have happened.'
1281         );
1282       }
1283     }
1284
1285     $self->_driver_determined(1);
1286
1287     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1288
1289     if ($self->can('source_bind_attributes')) {
1290       $self->throw_exception(
1291         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1292       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1293       . 'If you are not sure how to proceed please contact the development team via '
1294       . DBIx::Class::_ENV_::HELP_URL
1295       );
1296     }
1297
1298     $self->_init; # run driver-specific initializations
1299
1300     $self->_run_connection_actions
1301         if !$started_connected && defined $self->_dbh;
1302   }
1303 }
1304
1305 sub _extract_driver_from_connect_info {
1306   my $self = shift;
1307
1308   my $drv;
1309
1310   # if connect_info is a CODEREF, we have no choice but to connect
1311   if (
1312     ref $self->_dbi_connect_info->[0]
1313       and
1314     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1315   ) {
1316     $self->_populate_dbh;
1317     $drv = $self->_dbh->{Driver}{Name};
1318   }
1319   else {
1320     # try to use dsn to not require being connected, the driver may still
1321     # force a connection later in _rebless to determine version
1322     # (dsn may not be supplied at all if all we do is make a mock-schema)
1323     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1324     $drv ||= $ENV{DBI_DRIVER};
1325   }
1326
1327   return $drv;
1328 }
1329
1330 sub _determine_connector_driver {
1331   my ($self, $conn) = @_;
1332
1333   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1334
1335   if (not $dbtype) {
1336     $self->_warn_undetermined_driver(
1337       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1338     . "$conn connector - this should not have happened."
1339     );
1340     return;
1341   }
1342
1343   $dbtype =~ s/\W/_/gi;
1344
1345   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1346   return if $self->isa($subclass);
1347
1348   if ($self->load_optional_class($subclass)) {
1349     bless $self, $subclass;
1350     $self->_rebless;
1351   }
1352   else {
1353     $self->_warn_undetermined_driver(
1354       'This version of DBIC does not yet seem to supply a driver for '
1355     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1356     );
1357   }
1358 }
1359
1360 sub _warn_undetermined_driver {
1361   my ($self, $msg) = @_;
1362
1363   require Data::Dumper::Concise;
1364
1365   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1366   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1367   . "does not go away, file a bugreport including the following info:\n"
1368   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1369   );
1370 }
1371
1372 sub _do_connection_actions {
1373   my $self          = shift;
1374   my $method_prefix = shift;
1375   my $call          = shift;
1376
1377   if (not ref($call)) {
1378     my $method = $method_prefix . $call;
1379     $self->$method(@_);
1380   } elsif (ref($call) eq 'CODE') {
1381     $self->$call(@_);
1382   } elsif (ref($call) eq 'ARRAY') {
1383     if (ref($call->[0]) ne 'ARRAY') {
1384       $self->_do_connection_actions($method_prefix, $_) for @$call;
1385     } else {
1386       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1387     }
1388   } else {
1389     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1390   }
1391
1392   return $self;
1393 }
1394
1395 sub connect_call_do_sql {
1396   my $self = shift;
1397   $self->_do_query(@_);
1398 }
1399
1400 sub disconnect_call_do_sql {
1401   my $self = shift;
1402   $self->_do_query(@_);
1403 }
1404
1405 =head2 connect_call_datetime_setup
1406
1407 A no-op stub method, provided so that one can always safely supply the
1408 L<connection option|/DBIx::Class specific connection attributes>
1409
1410  on_connect_call => 'datetime_setup'
1411
1412 This way one does not need to know in advance whether the underlying
1413 storage requires any sort of hand-holding when dealing with calendar
1414 data.
1415
1416 =cut
1417
1418 sub connect_call_datetime_setup { 1 }
1419
1420 sub _do_query {
1421   my ($self, $action) = @_;
1422
1423   if (ref $action eq 'CODE') {
1424     $action = $action->($self);
1425     $self->_do_query($_) foreach @$action;
1426   }
1427   else {
1428     # Most debuggers expect ($sql, @bind), so we need to exclude
1429     # the attribute hash which is the second argument to $dbh->do
1430     # furthermore the bind values are usually to be presented
1431     # as named arrayref pairs, so wrap those here too
1432     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1433     my $sql = shift @do_args;
1434     my $attrs = shift @do_args;
1435     my @bind = map { [ undef, $_ ] } @do_args;
1436
1437     $self->dbh_do(sub {
1438       $_[0]->_query_start($sql, \@bind);
1439       $_[1]->do($sql, $attrs, @do_args);
1440       $_[0]->_query_end($sql, \@bind);
1441     });
1442   }
1443
1444   return $self;
1445 }
1446
1447 sub _connect {
1448   my $self = shift;
1449
1450   my $info = $self->_dbi_connect_info;
1451
1452   $self->throw_exception("You did not provide any connection_info")
1453     unless defined $info->[0];
1454
1455   my ($old_connect_via, $dbh);
1456
1457   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1458
1459   # this odd anonymous coderef dereference is in fact really
1460   # necessary to avoid the unwanted effect described in perl5
1461   # RT#75792
1462   #
1463   # in addition the coderef itself can't reside inside the try{} block below
1464   # as it somehow triggers a leak under perl -d
1465   my $dbh_error_handler_installer = sub {
1466     weaken (my $weak_self = $_[0]);
1467
1468     # the coderef is blessed so we can distinguish it from externally
1469     # supplied handles (which must be preserved)
1470     $_[1]->{HandleError} = bless sub {
1471       if ($weak_self) {
1472         $weak_self->throw_exception("DBI Exception: $_[0]");
1473       }
1474       else {
1475         # the handler may be invoked by something totally out of
1476         # the scope of DBIC
1477         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1478       }
1479     }, '__DBIC__DBH__ERROR__HANDLER__';
1480   };
1481
1482   try {
1483     if(ref $info->[0] eq 'CODE') {
1484       $dbh = $info->[0]->();
1485     }
1486     else {
1487       require DBI;
1488       $dbh = DBI->connect(@$info);
1489     }
1490
1491     die $DBI::errstr unless $dbh;
1492
1493     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1494       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1495       . 'not continue',
1496       ref $info->[0] eq 'CODE'
1497         ? "Connection coderef $info->[0] returned a"
1498         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1499     ) unless $dbh->FETCH('Active');
1500
1501     # sanity checks unless asked otherwise
1502     unless ($self->unsafe) {
1503
1504       $self->throw_exception(
1505         'Refusing clobbering of {HandleError} installed on externally supplied '
1506        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1507       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1508
1509       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1510       # request, or an external handle. Complain and set anyway
1511       unless ($dbh->{RaiseError}) {
1512         carp( ref $info->[0] eq 'CODE'
1513
1514           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1515            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1516            .'attribute has been supplied'
1517
1518           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1519            .'unsafe => 1. Toggling RaiseError back to true'
1520         );
1521
1522         $dbh->{RaiseError} = 1;
1523       }
1524
1525       $dbh_error_handler_installer->($self, $dbh);
1526     }
1527   }
1528   catch {
1529     $self->throw_exception("DBI Connection failed: $_")
1530   };
1531
1532   $self->_dbh_autocommit($dbh->{AutoCommit});
1533   return $dbh;
1534 }
1535
1536 sub txn_begin {
1537   # this means we have not yet connected and do not know the AC status
1538   # (e.g. coderef $dbh), need a full-fledged connection check
1539   if (! defined $_[0]->_dbh_autocommit) {
1540     $_[0]->ensure_connected;
1541   }
1542   # Otherwise simply connect or re-connect on pid changes
1543   else {
1544     $_[0]->_get_dbh;
1545   }
1546
1547   shift->next::method(@_);
1548 }
1549
1550 sub _exec_txn_begin {
1551   my $self = shift;
1552
1553   # if the user is utilizing txn_do - good for him, otherwise we need to
1554   # ensure that the $dbh is healthy on BEGIN.
1555   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1556   # will be replaced by a failure of begin_work itself (which will be
1557   # then retried on reconnect)
1558   if ($self->{_in_do_block}) {
1559     $self->_dbh->begin_work;
1560   } else {
1561     $self->dbh_do(sub { $_[1]->begin_work });
1562   }
1563 }
1564
1565 sub txn_commit {
1566   my $self = shift;
1567
1568   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1569     unless $self->_seems_connected;
1570
1571   # esoteric case for folks using external $dbh handles
1572   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1573     carp "Storage transaction_depth 0 does not match "
1574         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1575     $self->transaction_depth(1);
1576   }
1577
1578   $self->next::method(@_);
1579
1580   # if AutoCommit is disabled txn_depth never goes to 0
1581   # as a new txn is started immediately on commit
1582   $self->transaction_depth(1) if (
1583     !$self->transaction_depth
1584       and
1585     defined $self->_dbh_autocommit
1586       and
1587     ! $self->_dbh_autocommit
1588   );
1589 }
1590
1591 sub _exec_txn_commit {
1592   shift->_dbh->commit;
1593 }
1594
1595 sub txn_rollback {
1596   my $self = shift;
1597
1598   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1599     unless $self->_seems_connected;
1600
1601   # esoteric case for folks using external $dbh handles
1602   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1603     carp "Storage transaction_depth 0 does not match "
1604         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1605     $self->transaction_depth(1);
1606   }
1607
1608   $self->next::method(@_);
1609
1610   # if AutoCommit is disabled txn_depth never goes to 0
1611   # as a new txn is started immediately on commit
1612   $self->transaction_depth(1) if (
1613     !$self->transaction_depth
1614       and
1615     defined $self->_dbh_autocommit
1616       and
1617     ! $self->_dbh_autocommit
1618   );
1619 }
1620
1621 sub _exec_txn_rollback {
1622   shift->_dbh->rollback;
1623 }
1624
1625 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1626 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1627   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1628     unless $_[0]->_seems_connected;
1629   shift->next::method(@_);
1630 EOS
1631
1632 # This used to be the top-half of _execute.  It was split out to make it
1633 #  easier to override in NoBindVars without duping the rest.  It takes up
1634 #  all of _execute's args, and emits $sql, @bind.
1635 sub _prep_for_execute {
1636   #my ($self, $op, $ident, $args) = @_;
1637   return shift->_gen_sql_bind(@_)
1638 }
1639
1640 sub _gen_sql_bind {
1641   my ($self, $op, $ident, $args) = @_;
1642
1643   my ($colinfos, $from);
1644   if ( blessed($ident) ) {
1645     $from = $ident->from;
1646     $colinfos = $ident->columns_info;
1647   }
1648
1649   my ($sql, $bind);
1650   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1651
1652   $bind = $self->_resolve_bindattrs(
1653     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1654   );
1655
1656   if (
1657     ! $ENV{DBIC_DT_SEARCH_OK}
1658       and
1659     $op eq 'select'
1660       and
1661     first {
1662       length ref $_->[1]
1663         and
1664       blessed($_->[1])
1665         and
1666       $_->[1]->isa('DateTime')
1667     } @$bind
1668   ) {
1669     carp_unique 'DateTime objects passed to search() are not supported '
1670       . 'properly (InflateColumn::DateTime formats and settings are not '
1671       . 'respected.) See "Formatting DateTime objects in queries" in '
1672       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1673       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1674   }
1675
1676   return( $sql, $bind );
1677 }
1678
1679 sub _resolve_bindattrs {
1680   my ($self, $ident, $bind, $colinfos) = @_;
1681
1682   my $resolve_bindinfo = sub {
1683     #my $infohash = shift;
1684
1685     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1686
1687     my $ret;
1688     if (my $col = $_[0]->{dbic_colname}) {
1689       $ret = { %{$_[0]} };
1690
1691       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1692         if $colinfos->{$col}{data_type};
1693
1694       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1695         if $colinfos->{$col}{size};
1696     }
1697
1698     $ret || $_[0];
1699   };
1700
1701   return [ map {
1702     my $resolved =
1703       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1704     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1705     : (ref $_->[0] eq 'HASH')           ? [(
1706                                             ! keys %{$_->[0]}
1707                                               or
1708                                             exists $_->[0]{dbd_attrs}
1709                                               or
1710                                             $_->[0]{sqlt_datatype}
1711                                            ) ? $_->[0]
1712                                              : $resolve_bindinfo->($_->[0])
1713                                            , $_->[1]
1714                                           ]
1715     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1716     :                                     [ $resolve_bindinfo->(
1717                                               { dbic_colname => $_->[0] }
1718                                             ), $_->[1] ]
1719     ;
1720
1721     if (
1722       ! exists $resolved->[0]{dbd_attrs}
1723         and
1724       ! $resolved->[0]{sqlt_datatype}
1725         and
1726       length ref $resolved->[1]
1727         and
1728       ! is_plain_value $resolved->[1]
1729     ) {
1730       require Data::Dumper;
1731       local $Data::Dumper::Maxdepth = 1;
1732       local $Data::Dumper::Terse = 1;
1733       local $Data::Dumper::Useqq = 1;
1734       local $Data::Dumper::Indent = 0;
1735       local $Data::Dumper::Pad = ' ';
1736       $self->throw_exception(
1737         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1738       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1739       );
1740     }
1741
1742     $resolved;
1743
1744   } @$bind ];
1745 }
1746
1747 sub _format_for_trace {
1748   #my ($self, $bind) = @_;
1749
1750   ### Turn @bind from something like this:
1751   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1752   ### to this:
1753   ###   ( "'1'", "'3'" )
1754
1755   map {
1756     defined( $_ && $_->[1] )
1757       ? qq{'$_->[1]'}
1758       : q{NULL}
1759   } @{$_[1] || []};
1760 }
1761
1762 sub _query_start {
1763   my ( $self, $sql, $bind ) = @_;
1764
1765   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1766     if $self->debug;
1767 }
1768
1769 sub _query_end {
1770   my ( $self, $sql, $bind ) = @_;
1771
1772   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1773     if $self->debug;
1774 }
1775
1776 sub _dbi_attrs_for_bind {
1777   my ($self, $ident, $bind) = @_;
1778
1779   my @attrs;
1780
1781   for (map { $_->[0] } @$bind) {
1782     push @attrs, do {
1783       if (exists $_->{dbd_attrs}) {
1784         $_->{dbd_attrs}
1785       }
1786       elsif($_->{sqlt_datatype}) {
1787         # cache the result in the dbh_details hash, as it can not change unless
1788         # we connect to something else
1789         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1790         if (not exists $cache->{$_->{sqlt_datatype}}) {
1791           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1792         }
1793         $cache->{$_->{sqlt_datatype}};
1794       }
1795       else {
1796         undef;  # always push something at this position
1797       }
1798     }
1799   }
1800
1801   return \@attrs;
1802 }
1803
1804 sub _execute {
1805   my ($self, $op, $ident, @args) = @_;
1806
1807   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1808
1809   # not even a PID check - we do not care about the state of the _dbh.
1810   # All we need is to get the appropriate drivers loaded if they aren't
1811   # already so that the assumption in ad7c50fc26e holds
1812   $self->_populate_dbh unless $self->_dbh;
1813
1814   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1815     $sql,
1816     $bind,
1817     $self->_dbi_attrs_for_bind($ident, $bind),
1818   );
1819 }
1820
1821 sub _dbh_execute {
1822   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1823
1824   $self->_query_start( $sql, $bind );
1825
1826   my $sth = $self->_bind_sth_params(
1827     $self->_prepare_sth($dbh, $sql),
1828     $bind,
1829     $bind_attrs,
1830   );
1831
1832   # Can this fail without throwing an exception anyways???
1833   my $rv = $sth->execute();
1834   $self->throw_exception(
1835     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1836   ) if !$rv;
1837
1838   $self->_query_end( $sql, $bind );
1839
1840   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1841 }
1842
1843 sub _prepare_sth {
1844   my ($self, $dbh, $sql) = @_;
1845
1846   # 3 is the if_active parameter which avoids active sth re-use
1847   my $sth = $self->disable_sth_caching
1848     ? $dbh->prepare($sql)
1849     : $dbh->prepare_cached($sql, {}, 3);
1850
1851   # XXX You would think RaiseError would make this impossible,
1852   #  but apparently that's not true :(
1853   $self->throw_exception(
1854     $dbh->errstr
1855       ||
1856     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1857             .'an exception and/or setting $dbh->errstr',
1858       length ($sql) > 20
1859         ? substr($sql, 0, 20) . '...'
1860         : $sql
1861       ,
1862       'DBD::' . $dbh->{Driver}{Name},
1863     )
1864   ) if !$sth;
1865
1866   $sth;
1867 }
1868
1869 sub _bind_sth_params {
1870   my ($self, $sth, $bind, $bind_attrs) = @_;
1871
1872   for my $i (0 .. $#$bind) {
1873     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1874       $sth->bind_param_inout(
1875         $i + 1, # bind params counts are 1-based
1876         $bind->[$i][1],
1877         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1878         $bind_attrs->[$i],
1879       );
1880     }
1881     else {
1882       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1883       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1884         ? "$bind->[$i][1]"
1885         : $bind->[$i][1]
1886       ;
1887
1888       $sth->bind_param(
1889         $i + 1,
1890         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1891         $v,
1892         $bind_attrs->[$i],
1893       );
1894     }
1895   }
1896
1897   $sth;
1898 }
1899
1900 sub _prefetch_autovalues {
1901   my ($self, $source, $colinfo, $to_insert) = @_;
1902
1903   my %values;
1904   for my $col (keys %$colinfo) {
1905     if (
1906       $colinfo->{$col}{auto_nextval}
1907         and
1908       (
1909         ! exists $to_insert->{$col}
1910           or
1911         is_literal_value($to_insert->{$col})
1912       )
1913     ) {
1914       $values{$col} = $self->_sequence_fetch(
1915         'NEXTVAL',
1916         ( $colinfo->{$col}{sequence} ||=
1917             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1918         ),
1919       );
1920     }
1921   }
1922
1923   \%values;
1924 }
1925
1926 sub insert {
1927   my ($self, $source, $to_insert) = @_;
1928
1929   my $col_infos = $source->columns_info;
1930
1931   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1932
1933   # fuse the values, but keep a separate list of prefetched_values so that
1934   # they can be fused once again with the final return
1935   $to_insert = { %$to_insert, %$prefetched_values };
1936
1937   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1938   # Investigate what does it take to s/defined/exists/
1939   my %pcols = map { $_ => 1 } $source->primary_columns;
1940   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1941   for my $col ($source->columns) {
1942     if ($col_infos->{$col}{is_auto_increment}) {
1943       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1944       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1945     }
1946
1947     # nothing to retrieve when explicit values are supplied
1948     next if (
1949       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1950     );
1951
1952     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1953     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1954       $pcols{$col}
1955         or
1956       $col_infos->{$col}{retrieve_on_insert}
1957     );
1958   };
1959
1960   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1961   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1962
1963   my ($sqla_opts, @ir_container);
1964   if (%retrieve_cols and $self->_use_insert_returning) {
1965     $sqla_opts->{returning_container} = \@ir_container
1966       if $self->_use_insert_returning_bound;
1967
1968     $sqla_opts->{returning} = [
1969       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1970     ];
1971   }
1972
1973   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1974
1975   my %returned_cols = %$to_insert;
1976   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1977     @ir_container = try {
1978       local $SIG{__WARN__} = sub {};
1979       my @r = $sth->fetchrow_array;
1980       $sth->finish;
1981       @r;
1982     } unless @ir_container;
1983
1984     @returned_cols{@$retlist} = @ir_container if @ir_container;
1985   }
1986   else {
1987     # pull in PK if needed and then everything else
1988     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1989
1990       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1991         unless $self->can('last_insert_id');
1992
1993       my @pri_values = $self->last_insert_id($source, @missing_pri);
1994
1995       $self->throw_exception( "Can't get last insert id" )
1996         unless (@pri_values == @missing_pri);
1997
1998       @returned_cols{@missing_pri} = @pri_values;
1999       delete @retrieve_cols{@missing_pri};
2000     }
2001
2002     # if there is more left to pull
2003     if (%retrieve_cols) {
2004       $self->throw_exception(
2005         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2006       ) unless %pcols;
2007
2008       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2009
2010       my $cur = DBIx::Class::ResultSet->new($source, {
2011         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2012         select => \@left_to_fetch,
2013       })->cursor;
2014
2015       @returned_cols{@left_to_fetch} = $cur->next;
2016
2017       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2018         if scalar $cur->next;
2019     }
2020   }
2021
2022   return { %$prefetched_values, %returned_cols };
2023 }
2024
2025 sub insert_bulk {
2026   carp_unique(
2027     'insert_bulk() should have never been exposed as a public method and '
2028   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2029   . 'use for this method please contact the development team via '
2030   . DBIx::Class::_ENV_::HELP_URL
2031   );
2032
2033   return '0E0' unless @{$_[3]||[]};
2034
2035   shift->_insert_bulk(@_);
2036 }
2037
2038 sub _insert_bulk {
2039   my ($self, $source, $cols, $data) = @_;
2040
2041   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2042     unless @{$data||[]};
2043
2044   my $colinfos = $source->columns_info($cols);
2045
2046   local $self->{_autoinc_supplied_for_op} =
2047     (grep { $_->{is_auto_increment} } values %$colinfos)
2048       ? 1
2049       : 0
2050   ;
2051
2052   # get a slice type index based on first row of data
2053   # a "column" in this context may refer to more than one bind value
2054   # e.g. \[ '?, ?', [...], [...] ]
2055   #
2056   # construct the value type index - a description of values types for every
2057   # per-column slice of $data:
2058   #
2059   # nonexistent - nonbind literal
2060   # 0 - regular value
2061   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2062   #
2063   # also construct the column hash to pass to the SQL generator. For plain
2064   # (non literal) values - convert the members of the first row into a
2065   # literal+bind combo, with extra positional info in the bind attr hashref.
2066   # This will allow us to match the order properly, and is so contrived
2067   # because a user-supplied literal/bind (or something else specific to a
2068   # resultsource and/or storage driver) can inject extra binds along the
2069   # way, so one can't rely on "shift positions" ordering at all. Also we
2070   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2071   # can be later matched up by address), because we want to supply a real
2072   # value on which perhaps e.g. datatype checks will be performed
2073   my ($proto_data, $value_type_by_col_idx);
2074   for my $col_idx (0..$#$cols) {
2075     my $colname = $cols->[$col_idx];
2076     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2077       # no bind value at all - no type
2078
2079       $proto_data->{$colname} = $data->[0][$col_idx];
2080     }
2081     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2082       # repack, so we don't end up mangling the original \[]
2083       my ($sql, @bind) = @${$data->[0][$col_idx]};
2084
2085       # normalization of user supplied stuff
2086       my $resolved_bind = $self->_resolve_bindattrs(
2087         $source, \@bind, $colinfos,
2088       );
2089
2090       # store value-less (attrs only) bind info - we will be comparing all
2091       # supplied binds against this for sanity
2092       $value_type_by_col_idx->{$col_idx} = [ map { $_->[0] } @$resolved_bind ];
2093
2094       $proto_data->{$colname} = \[ $sql, map { [
2095         # inject slice order to use for $proto_bind construction
2096           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2097             =>
2098           $resolved_bind->[$_][1]
2099         ] } (0 .. $#bind)
2100       ];
2101     }
2102     else {
2103       $value_type_by_col_idx->{$col_idx} = undef;
2104
2105       $proto_data->{$colname} = \[ '?', [
2106         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2107           =>
2108         $data->[0][$col_idx]
2109       ] ];
2110     }
2111   }
2112
2113   my ($sql, $proto_bind) = $self->_prep_for_execute (
2114     'insert',
2115     $source,
2116     [ $proto_data ],
2117   );
2118
2119   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2120     # if the bindlist is empty and we had some dynamic binds, this means the
2121     # storage ate them away (e.g. the NoBindVars component) and interpolated
2122     # them directly into the SQL. This obviously can't be good for multi-inserts
2123     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2124   }
2125
2126   # sanity checks
2127   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2128   #
2129   # use an error reporting closure for convenience (less to pass)
2130   my $bad_slice_report_cref = sub {
2131     my ($msg, $r_idx, $c_idx) = @_;
2132     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2133       $msg,
2134       $cols->[$c_idx],
2135       do {
2136         require Data::Dumper::Concise;
2137         local $Data::Dumper::Maxdepth = 5;
2138         Data::Dumper::Concise::Dumper ({
2139           map { $cols->[$_] =>
2140             $data->[$r_idx][$_]
2141           } 0..$#$cols
2142         }),
2143       }
2144     );
2145   };
2146
2147   for my $col_idx (0..$#$cols) {
2148     my $reference_val = $data->[0][$col_idx];
2149
2150     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2151       my $val = $data->[$row_idx][$col_idx];
2152
2153       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2154         if (ref $val ne 'SCALAR') {
2155           $bad_slice_report_cref->(
2156             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2157             $row_idx,
2158             $col_idx,
2159           );
2160         }
2161         elsif ($$val ne $$reference_val) {
2162           $bad_slice_report_cref->(
2163             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2164             $row_idx,
2165             $col_idx,
2166           );
2167         }
2168       }
2169       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2170         if (is_literal_value($val)) {
2171           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2172         }
2173       }
2174       else {  # binds from a \[], compare type and attrs
2175         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2176           $bad_slice_report_cref->(
2177             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2178             $row_idx,
2179             $col_idx,
2180           );
2181         }
2182         # start drilling down and bail out early on identical refs
2183         elsif (
2184           $reference_val != $val
2185             or
2186           $$reference_val != $$val
2187         ) {
2188           if (${$val}->[0] ne ${$reference_val}->[0]) {
2189             $bad_slice_report_cref->(
2190               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2191               $row_idx,
2192               $col_idx,
2193             );
2194           }
2195           # need to check the bind attrs - a bind will happen only once for
2196           # the entire dataset, so any changes further down will be ignored.
2197           elsif (! Data::Compare::Compare(
2198             $value_type_by_col_idx->{$col_idx},
2199             [
2200               map
2201               { $_->[0] }
2202               @{$self->_resolve_bindattrs(
2203                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2204               )}
2205             ],
2206           )) {
2207             $bad_slice_report_cref->(
2208               'Differing bind attributes on literal/bind values not supported',
2209               $row_idx,
2210               $col_idx,
2211             );
2212           }
2213         }
2214       }
2215     }
2216   }
2217
2218   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2219   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2220   # scope guard
2221   my $guard = $self->txn_scope_guard;
2222
2223   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2224   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2225   my $rv = do {
2226     if (@$proto_bind) {
2227       # proto bind contains the information on which pieces of $data to pull
2228       # $cols is passed in only for prettier error-reporting
2229       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2230     }
2231     else {
2232       # bind_param_array doesn't work if there are no binds
2233       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2234     }
2235   };
2236
2237   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2238
2239   $guard->commit;
2240
2241   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2242 }
2243
2244 # execute_for_fetch is capable of returning data just fine (it means it
2245 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2246 # is the void-populate fast-path we will just ignore this altogether
2247 # for the time being.
2248 sub _dbh_execute_for_fetch {
2249   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2250
2251   # If we have any bind attributes to take care of, we will bind the
2252   # proto-bind data (which will never be used by execute_for_fetch)
2253   # However since column bindtypes are "sticky", this is sufficient
2254   # to get the DBD to apply the bindtype to all values later on
2255   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2256
2257   for my $i (0 .. $#$proto_bind) {
2258     $sth->bind_param (
2259       $i+1, # DBI bind indexes are 1-based
2260       $proto_bind->[$i][1],
2261       $bind_attrs->[$i],
2262     ) if defined $bind_attrs->[$i];
2263   }
2264
2265   # At this point $data slots named in the _bind_data_slice_idx of
2266   # each piece of $proto_bind are either \[]s or plain values to be
2267   # passed in. Construct the dispensing coderef. *NOTE* the order
2268   # of $data will differ from this of the ?s in the SQL (due to
2269   # alphabetical ordering by colname). We actually do want to
2270   # preserve this behavior so that prepare_cached has a better
2271   # chance of matching on unrelated calls
2272
2273   my $fetch_row_idx = -1; # saner loop this way
2274   my $fetch_tuple = sub {
2275     return undef if ++$fetch_row_idx > $#$data;
2276
2277     return [ map {
2278       my $v = ! defined $_->{_literal_bind_subindex}
2279
2280         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2281
2282         # There are no attributes to resolve here - we already did everything
2283         # when we constructed proto_bind. However we still want to sanity-check
2284         # what the user supplied, so pass stuff through to the resolver *anyway*
2285         : $self->_resolve_bindattrs (
2286             undef,  # a fake rsrc
2287             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2288             {},     # a fake column_info bag
2289           )->[0][1]
2290       ;
2291
2292       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2293       # For the time being forcibly stringify whatever is stringifiable
2294       (length ref $v and is_plain_value $v)
2295         ? "$v"
2296         : $v
2297       ;
2298     } map { $_->[0] } @$proto_bind ];
2299   };
2300
2301   my $tuple_status = [];
2302   my ($rv, $err);
2303   try {
2304     $rv = $sth->execute_for_fetch(
2305       $fetch_tuple,
2306       $tuple_status,
2307     );
2308   }
2309   catch {
2310     $err = shift;
2311   };
2312
2313   # Not all DBDs are create equal. Some throw on error, some return
2314   # an undef $rv, and some set $sth->err - try whatever we can
2315   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2316     ! defined $err
2317       and
2318     ( !defined $rv or $sth->err )
2319   );
2320
2321   # Statement must finish even if there was an exception.
2322   try {
2323     $sth->finish
2324   }
2325   catch {
2326     $err = shift unless defined $err
2327   };
2328
2329   if (defined $err) {
2330     my $i = 0;
2331     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2332
2333     $self->throw_exception("Unexpected populate error: $err")
2334       if ($i > $#$tuple_status);
2335
2336     require Data::Dumper::Concise;
2337     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2338       ($tuple_status->[$i][1] || $err),
2339       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2340     );
2341   }
2342
2343   return $rv;
2344 }
2345
2346 sub _dbh_execute_inserts_with_no_binds {
2347   my ($self, $sth, $count) = @_;
2348
2349   my $err;
2350   try {
2351     my $dbh = $self->_get_dbh;
2352     local $dbh->{RaiseError} = 1;
2353     local $dbh->{PrintError} = 0;
2354
2355     $sth->execute foreach 1..$count;
2356   }
2357   catch {
2358     $err = shift;
2359   };
2360
2361   # Make sure statement is finished even if there was an exception.
2362   try {
2363     $sth->finish
2364   }
2365   catch {
2366     $err = shift unless defined $err;
2367   };
2368
2369   $self->throw_exception($err) if defined $err;
2370
2371   return $count;
2372 }
2373
2374 sub update {
2375   #my ($self, $source, @args) = @_;
2376   shift->_execute('update', @_);
2377 }
2378
2379
2380 sub delete {
2381   #my ($self, $source, @args) = @_;
2382   shift->_execute('delete', @_);
2383 }
2384
2385 sub _select {
2386   my $self = shift;
2387   $self->_execute($self->_select_args(@_));
2388 }
2389
2390 sub _select_args_to_query {
2391   my $self = shift;
2392
2393   $self->throw_exception(
2394     "Unable to generate limited query representation with 'software_limit' enabled"
2395   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2396
2397   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2398   #  = $self->_select_args($ident, $select, $cond, $attrs);
2399   my ($op, $ident, @args) =
2400     $self->_select_args(@_);
2401
2402   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2403   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2404
2405   # reuse the bind arrayref
2406   unshift @{$bind}, "($sql)";
2407   \$bind;
2408 }
2409
2410 sub _select_args {
2411   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2412
2413   # FIXME - that kind of caching would be nice to have
2414   # however currently we *may* pass the same $orig_attrs
2415   # with different ident/select/where
2416   # the whole interface needs to be rethought, since it
2417   # was centered around the flawed SQLA API. We can do
2418   # soooooo much better now. But that is also another
2419   # battle...
2420   #return (
2421   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2422   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2423
2424   my $sql_maker = $self->sql_maker;
2425
2426   my $attrs = {
2427     %$orig_attrs,
2428     select => $select,
2429     from => $ident,
2430     where => $where,
2431   };
2432
2433   # Sanity check the attributes (SQLMaker does it too, but
2434   # in case of a software_limit we'll never reach there)
2435   if (defined $attrs->{offset}) {
2436     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2437       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2438   }
2439
2440   if (defined $attrs->{rows}) {
2441     $self->throw_exception("The rows attribute must be a positive integer if present")
2442       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2443   }
2444   elsif ($attrs->{offset}) {
2445     # MySQL actually recommends this approach.  I cringe.
2446     $attrs->{rows} = $sql_maker->__max_int;
2447   }
2448
2449   # see if we will need to tear the prefetch apart to satisfy group_by == select
2450   # this is *extremely tricky* to get right, I am still not sure I did
2451   #
2452   my ($prefetch_needs_subquery, @limit_args);
2453
2454   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2455     # we already know there is a valid group_by (we made it) and we know it is
2456     # intended to be based *only* on non-multi stuff
2457     # short circuit the group_by parsing below
2458     $prefetch_needs_subquery = 1;
2459   }
2460   elsif (
2461     # The rationale is that even if we do *not* have collapse, we still
2462     # need to wrap the core grouped select/group_by in a subquery
2463     # so that databases that care about group_by/select equivalence
2464     # are happy (this includes MySQL in strict_mode)
2465     # If any of the other joined tables are referenced in the group_by
2466     # however - the user is on their own
2467     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2468       and
2469     $attrs->{group_by}
2470       and
2471     @{$attrs->{group_by}}
2472       and
2473     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2474       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2475     }
2476   ) {
2477     # no aliases other than our own in group_by
2478     # if there are - do not allow subquery even if limit is present
2479     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2480   }
2481   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2482     # active collapse with a limit - that one is a no-brainer unless
2483     # overruled by a group_by above
2484     $prefetch_needs_subquery = 1;
2485   }
2486
2487   if ($prefetch_needs_subquery) {
2488     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2489   }
2490   elsif (! $attrs->{software_limit} ) {
2491     push @limit_args, (
2492       $attrs->{rows} || (),
2493       $attrs->{offset} || (),
2494     );
2495   }
2496
2497   # try to simplify the joinmap further (prune unreferenced type-single joins)
2498   if (
2499     ! $prefetch_needs_subquery  # already pruned
2500       and
2501     ref $attrs->{from}
2502       and
2503     reftype $attrs->{from} eq 'ARRAY'
2504       and
2505     @{$attrs->{from}} != 1
2506   ) {
2507     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2508   }
2509
2510   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2511   # during the result inflation stage we *need* to know what was the aliastype
2512   # map as sqla saw it when the final pieces of SQL were being assembled
2513   # Originally we simply carried around the entirety of $attrs, but this
2514   # resulted in resultsets that are being reused growing continuously, as
2515   # the hash in question grew deeper and deeper.
2516   # Instead hand-pick what to take with us here (we actually don't need much
2517   # at this point just the map itself)
2518   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2519
2520 ###
2521   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2522   #
2523   # This would be the point to deflate anything found in $attrs->{where}
2524   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2525   # expect a result object. And all we have is a resultsource (it is trivial
2526   # to extract deflator coderefs via $alias2source above).
2527   #
2528   # I don't see a way forward other than changing the way deflators are
2529   # invoked, and that's just bad...
2530 ###
2531
2532   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2533 }
2534
2535 # Returns a counting SELECT for a simple count
2536 # query. Abstracted so that a storage could override
2537 # this to { count => 'firstcol' } or whatever makes
2538 # sense as a performance optimization
2539 sub _count_select {
2540   #my ($self, $source, $rs_attrs) = @_;
2541   return { count => '*' };
2542 }
2543
2544 =head2 select
2545
2546 =over 4
2547
2548 =item Arguments: $ident, $select, $condition, $attrs
2549
2550 =back
2551
2552 Handle a SQL select statement.
2553
2554 =cut
2555
2556 sub select {
2557   my $self = shift;
2558   my ($ident, $select, $condition, $attrs) = @_;
2559   return $self->cursor_class->new($self, \@_, $attrs);
2560 }
2561
2562 sub select_single {
2563   my $self = shift;
2564   my ($rv, $sth, @bind) = $self->_select(@_);
2565   my @row = $sth->fetchrow_array;
2566   my @nextrow = $sth->fetchrow_array if @row;
2567   if(@row && @nextrow) {
2568     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2569   }
2570   # Need to call finish() to work round broken DBDs
2571   $sth->finish();
2572   return @row;
2573 }
2574
2575 =head2 sql_limit_dialect
2576
2577 This is an accessor for the default SQL limit dialect used by a particular
2578 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2579 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2580 see L<DBIx::Class::SQLMaker::LimitDialects>.
2581
2582 =cut
2583
2584 sub _dbh_columns_info_for {
2585   my ($self, $dbh, $table) = @_;
2586
2587   if ($dbh->can('column_info')) {
2588     my %result;
2589     my $caught;
2590     try {
2591       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2592       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2593       $sth->execute();
2594       while ( my $info = $sth->fetchrow_hashref() ){
2595         my %column_info;
2596         $column_info{data_type}   = $info->{TYPE_NAME};
2597         $column_info{size}      = $info->{COLUMN_SIZE};
2598         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2599         $column_info{default_value} = $info->{COLUMN_DEF};
2600         my $col_name = $info->{COLUMN_NAME};
2601         $col_name =~ s/^\"(.*)\"$/$1/;
2602
2603         $result{$col_name} = \%column_info;
2604       }
2605     } catch {
2606       $caught = 1;
2607     };
2608     return \%result if !$caught && scalar keys %result;
2609   }
2610
2611   my %result;
2612   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2613   $sth->execute;
2614   my @columns = @{$sth->{NAME_lc}};
2615   for my $i ( 0 .. $#columns ){
2616     my %column_info;
2617     $column_info{data_type} = $sth->{TYPE}->[$i];
2618     $column_info{size} = $sth->{PRECISION}->[$i];
2619     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2620
2621     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2622       $column_info{data_type} = $1;
2623       $column_info{size}    = $2;
2624     }
2625
2626     $result{$columns[$i]} = \%column_info;
2627   }
2628   $sth->finish;
2629
2630   foreach my $col (keys %result) {
2631     my $colinfo = $result{$col};
2632     my $type_num = $colinfo->{data_type};
2633     my $type_name;
2634     if(defined $type_num && $dbh->can('type_info')) {
2635       my $type_info = $dbh->type_info($type_num);
2636       $type_name = $type_info->{TYPE_NAME} if $type_info;
2637       $colinfo->{data_type} = $type_name if $type_name;
2638     }
2639   }
2640
2641   return \%result;
2642 }
2643
2644 sub columns_info_for {
2645   my ($self, $table) = @_;
2646   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2647 }
2648
2649 =head2 last_insert_id
2650
2651 Return the row id of the last insert.
2652
2653 =cut
2654
2655 sub _dbh_last_insert_id {
2656     my ($self, $dbh, $source, $col) = @_;
2657
2658     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2659
2660     return $id if defined $id;
2661
2662     my $class = ref $self;
2663     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2664 }
2665
2666 sub last_insert_id {
2667   my $self = shift;
2668   $self->_dbh_last_insert_id ($self->_dbh, @_);
2669 }
2670
2671 =head2 _native_data_type
2672
2673 =over 4
2674
2675 =item Arguments: $type_name
2676
2677 =back
2678
2679 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2680 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2681 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2682
2683 The default implementation returns C<undef>, implement in your Storage driver if
2684 you need this functionality.
2685
2686 Should map types from other databases to the native RDBMS type, for example
2687 C<VARCHAR2> to C<VARCHAR>.
2688
2689 Types with modifiers should map to the underlying data type. For example,
2690 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2691
2692 Composite types should map to the container type, for example
2693 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2694
2695 =cut
2696
2697 sub _native_data_type {
2698   #my ($self, $data_type) = @_;
2699   return undef
2700 }
2701
2702 # Check if placeholders are supported at all
2703 sub _determine_supports_placeholders {
2704   my $self = shift;
2705   my $dbh  = $self->_get_dbh;
2706
2707   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2708   # but it is inaccurate more often than not
2709   return try {
2710     local $dbh->{PrintError} = 0;
2711     local $dbh->{RaiseError} = 1;
2712     $dbh->do('select ?', {}, 1);
2713     1;
2714   }
2715   catch {
2716     0;
2717   };
2718 }
2719
2720 # Check if placeholders bound to non-string types throw exceptions
2721 #
2722 sub _determine_supports_typeless_placeholders {
2723   my $self = shift;
2724   my $dbh  = $self->_get_dbh;
2725
2726   return try {
2727     local $dbh->{PrintError} = 0;
2728     local $dbh->{RaiseError} = 1;
2729     # this specifically tests a bind that is NOT a string
2730     $dbh->do('select 1 where 1 = ?', {}, 1);
2731     1;
2732   }
2733   catch {
2734     0;
2735   };
2736 }
2737
2738 =head2 sqlt_type
2739
2740 Returns the database driver name.
2741
2742 =cut
2743
2744 sub sqlt_type {
2745   shift->_get_dbh->{Driver}->{Name};
2746 }
2747
2748 =head2 bind_attribute_by_data_type
2749
2750 Given a datatype from column info, returns a database specific bind
2751 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2752 let the database planner just handle it.
2753
2754 This method is always called after the driver has been determined and a DBI
2755 connection has been established. Therefore you can refer to C<DBI::$constant>
2756 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2757 the correct modules.
2758
2759 =cut
2760
2761 sub bind_attribute_by_data_type {
2762     return;
2763 }
2764
2765 =head2 is_datatype_numeric
2766
2767 Given a datatype from column_info, returns a boolean value indicating if
2768 the current RDBMS considers it a numeric value. This controls how
2769 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2770 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2771 be performed instead of the usual C<eq>.
2772
2773 =cut
2774
2775 sub is_datatype_numeric {
2776   #my ($self, $dt) = @_;
2777
2778   return 0 unless $_[1];
2779
2780   $_[1] =~ /^ (?:
2781     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2782   ) $/ix;
2783 }
2784
2785
2786 =head2 create_ddl_dir
2787
2788 =over 4
2789
2790 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2791
2792 =back
2793
2794 Creates a SQL file based on the Schema, for each of the specified
2795 database engines in C<\@databases> in the given directory.
2796 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2797
2798 Given a previous version number, this will also create a file containing
2799 the ALTER TABLE statements to transform the previous schema into the
2800 current one. Note that these statements may contain C<DROP TABLE> or
2801 C<DROP COLUMN> statements that can potentially destroy data.
2802
2803 The file names are created using the C<ddl_filename> method below, please
2804 override this method in your schema if you would like a different file
2805 name format. For the ALTER file, the same format is used, replacing
2806 $version in the name with "$preversion-$version".
2807
2808 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2809 The most common value for this would be C<< { add_drop_table => 1 } >>
2810 to have the SQL produced include a C<DROP TABLE> statement for each table
2811 created. For quoting purposes supply C<quote_identifiers>.
2812
2813 If no arguments are passed, then the following default values are assumed:
2814
2815 =over 4
2816
2817 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2818
2819 =item version    - $schema->schema_version
2820
2821 =item directory  - './'
2822
2823 =item preversion - <none>
2824
2825 =back
2826
2827 By default, C<\%sqlt_args> will have
2828
2829  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2830
2831 merged with the hash passed in. To disable any of those features, pass in a
2832 hashref like the following
2833
2834  { ignore_constraint_names => 0, # ... other options }
2835
2836
2837 WARNING: You are strongly advised to check all SQL files created, before applying
2838 them.
2839
2840 =cut
2841
2842 sub create_ddl_dir {
2843   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2844
2845   unless ($dir) {
2846     carp "No directory given, using ./\n";
2847     $dir = './';
2848   } else {
2849       -d $dir
2850         or
2851       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2852         or
2853       $self->throw_exception(
2854         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2855       );
2856   }
2857
2858   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2859
2860   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2861   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2862
2863   my $schema_version = $schema->schema_version || '1.x';
2864   $version ||= $schema_version;
2865
2866   $sqltargs = {
2867     add_drop_table => 1,
2868     ignore_constraint_names => 1,
2869     ignore_index_names => 1,
2870     quote_identifiers => $self->sql_maker->_quoting_enabled,
2871     %{$sqltargs || {}}
2872   };
2873
2874   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2875     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2876   }
2877
2878   my $sqlt = SQL::Translator->new( $sqltargs );
2879
2880   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2881   my $sqlt_schema = $sqlt->translate({ data => $schema })
2882     or $self->throw_exception ($sqlt->error);
2883
2884   foreach my $db (@$databases) {
2885     $sqlt->reset();
2886     $sqlt->{schema} = $sqlt_schema;
2887     $sqlt->producer($db);
2888
2889     my $file;
2890     my $filename = $schema->ddl_filename($db, $version, $dir);
2891     if (-e $filename && ($version eq $schema_version )) {
2892       # if we are dumping the current version, overwrite the DDL
2893       carp "Overwriting existing DDL file - $filename";
2894       unlink($filename);
2895     }
2896
2897     my $output = $sqlt->translate;
2898     if(!$output) {
2899       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2900       next;
2901     }
2902     if(!open($file, ">$filename")) {
2903       $self->throw_exception("Can't open $filename for writing ($!)");
2904       next;
2905     }
2906     print $file $output;
2907     close($file);
2908
2909     next unless ($preversion);
2910
2911     require SQL::Translator::Diff;
2912
2913     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2914     if(!-e $prefilename) {
2915       carp("No previous schema file found ($prefilename)");
2916       next;
2917     }
2918
2919     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2920     if(-e $difffile) {
2921       carp("Overwriting existing diff file - $difffile");
2922       unlink($difffile);
2923     }
2924
2925     my $source_schema;
2926     {
2927       my $t = SQL::Translator->new($sqltargs);
2928       $t->debug( 0 );
2929       $t->trace( 0 );
2930
2931       $t->parser( $db )
2932         or $self->throw_exception ($t->error);
2933
2934       my $out = $t->translate( $prefilename )
2935         or $self->throw_exception ($t->error);
2936
2937       $source_schema = $t->schema;
2938
2939       $source_schema->name( $prefilename )
2940         unless ( $source_schema->name );
2941     }
2942
2943     # The "new" style of producers have sane normalization and can support
2944     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2945     # And we have to diff parsed SQL against parsed SQL.
2946     my $dest_schema = $sqlt_schema;
2947
2948     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2949       my $t = SQL::Translator->new($sqltargs);
2950       $t->debug( 0 );
2951       $t->trace( 0 );
2952
2953       $t->parser( $db )
2954         or $self->throw_exception ($t->error);
2955
2956       my $out = $t->translate( $filename )
2957         or $self->throw_exception ($t->error);
2958
2959       $dest_schema = $t->schema;
2960
2961       $dest_schema->name( $filename )
2962         unless $dest_schema->name;
2963     }
2964
2965     my $diff = do {
2966       # FIXME - this is a terrible workaround for
2967       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
2968       # Fixing it in this sloppy manner so that we don't hve to
2969       # lockstep an SQLT release as well. Needs to be removed at
2970       # some point, and SQLT dep bumped
2971       local $SQL::Translator::Producer::SQLite::NO_QUOTES
2972         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
2973
2974       SQL::Translator::Diff::schema_diff($source_schema, $db,
2975                                          $dest_schema,   $db,
2976                                          $sqltargs
2977                                        );
2978     };
2979
2980     if(!open $file, ">$difffile") {
2981       $self->throw_exception("Can't write to $difffile ($!)");
2982       next;
2983     }
2984     print $file $diff;
2985     close($file);
2986   }
2987 }
2988
2989 =head2 deployment_statements
2990
2991 =over 4
2992
2993 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2994
2995 =back
2996
2997 Returns the statements used by L<DBIx::Class::Storage/deploy>
2998 and L<DBIx::Class::Schema/deploy>.
2999
3000 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3001 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3002
3003 C<$directory> is used to return statements from files in a previously created
3004 L</create_ddl_dir> directory and is optional. The filenames are constructed
3005 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3006
3007 If no C<$directory> is specified then the statements are constructed on the
3008 fly using L<SQL::Translator> and C<$version> is ignored.
3009
3010 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3011
3012 =cut
3013
3014 sub deployment_statements {
3015   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3016   $type ||= $self->sqlt_type;
3017   $version ||= $schema->schema_version || '1.x';
3018   $dir ||= './';
3019   my $filename = $schema->ddl_filename($type, $version, $dir);
3020   if(-f $filename)
3021   {
3022       # FIXME replace this block when a proper sane sql parser is available
3023       my $file;
3024       open($file, "<$filename")
3025         or $self->throw_exception("Can't open $filename ($!)");
3026       my @rows = <$file>;
3027       close($file);
3028       return join('', @rows);
3029   }
3030
3031   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
3032     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
3033   }
3034
3035   # sources needs to be a parser arg, but for simplicity allow at top level
3036   # coming in
3037   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3038       if exists $sqltargs->{sources};
3039
3040   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3041     unless exists $sqltargs->{quote_identifiers};
3042
3043   my $tr = SQL::Translator->new(
3044     producer => "SQL::Translator::Producer::${type}",
3045     %$sqltargs,
3046     parser => 'SQL::Translator::Parser::DBIx::Class',
3047     data => $schema,
3048   );
3049
3050   return preserve_context {
3051     $tr->translate
3052   } after => sub {
3053     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3054       unless defined $_[0];
3055   };
3056 }
3057
3058 # FIXME deploy() currently does not accurately report sql errors
3059 # Will always return true while errors are warned
3060 sub deploy {
3061   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3062   my $deploy = sub {
3063     my $line = shift;
3064     return if(!$line);
3065     return if($line =~ /^--/);
3066     # next if($line =~ /^DROP/m);
3067     return if($line =~ /^BEGIN TRANSACTION/m);
3068     return if($line =~ /^COMMIT/m);
3069     return if $line =~ /^\s+$/; # skip whitespace only
3070     $self->_query_start($line);
3071     try {
3072       # do a dbh_do cycle here, as we need some error checking in
3073       # place (even though we will ignore errors)
3074       $self->dbh_do (sub { $_[1]->do($line) });
3075     } catch {
3076       carp qq{$_ (running "${line}")};
3077     };
3078     $self->_query_end($line);
3079   };
3080   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3081   if (@statements > 1) {
3082     foreach my $statement (@statements) {
3083       $deploy->( $statement );
3084     }
3085   }
3086   elsif (@statements == 1) {
3087     # split on single line comments and end of statements
3088     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3089       $deploy->( $line );
3090     }
3091   }
3092 }
3093
3094 =head2 datetime_parser
3095
3096 Returns the datetime parser class
3097
3098 =cut
3099
3100 sub datetime_parser {
3101   my $self = shift;
3102   return $self->{datetime_parser} ||= do {
3103     $self->build_datetime_parser(@_);
3104   };
3105 }
3106
3107 =head2 datetime_parser_type
3108
3109 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3110
3111 =head2 build_datetime_parser
3112
3113 See L</datetime_parser>
3114
3115 =cut
3116
3117 sub build_datetime_parser {
3118   my $self = shift;
3119   my $type = $self->datetime_parser_type(@_);
3120   return $type;
3121 }
3122
3123
3124 =head2 is_replicating
3125
3126 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3127 replicate from a master database.  Default is undef, which is the result
3128 returned by databases that don't support replication.
3129
3130 =cut
3131
3132 sub is_replicating {
3133     return;
3134
3135 }
3136
3137 =head2 lag_behind_master
3138
3139 Returns a number that represents a certain amount of lag behind a master db
3140 when a given storage is replicating.  The number is database dependent, but
3141 starts at zero and increases with the amount of lag. Default in undef
3142
3143 =cut
3144
3145 sub lag_behind_master {
3146     return;
3147 }
3148
3149 =head2 relname_to_table_alias
3150
3151 =over 4
3152
3153 =item Arguments: $relname, $join_count
3154
3155 =item Return Value: $alias
3156
3157 =back
3158
3159 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3160 queries.
3161
3162 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3163 way these aliases are named.
3164
3165 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3166 otherwise C<"$relname">.
3167
3168 =cut
3169
3170 sub relname_to_table_alias {
3171   my ($self, $relname, $join_count) = @_;
3172
3173   my $alias = ($join_count && $join_count > 1 ?
3174     join('_', $relname, $join_count) : $relname);
3175
3176   return $alias;
3177 }
3178
3179 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3180 # version and it may be necessary to amend or override it for a specific storage
3181 # if such binds are necessary.
3182 sub _max_column_bytesize {
3183   my ($self, $attr) = @_;
3184
3185   my $max_size;
3186
3187   if ($attr->{sqlt_datatype}) {
3188     my $data_type = lc($attr->{sqlt_datatype});
3189
3190     if ($attr->{sqlt_size}) {
3191
3192       # String/sized-binary types
3193       if ($data_type =~ /^(?:
3194           l? (?:var)? char(?:acter)? (?:\s*varying)?
3195             |
3196           (?:var)? binary (?:\s*varying)?
3197             |
3198           raw
3199         )\b/x
3200       ) {
3201         $max_size = $attr->{sqlt_size};
3202       }
3203       # Other charset/unicode types, assume scale of 4
3204       elsif ($data_type =~ /^(?:
3205           national \s* character (?:\s*varying)?
3206             |
3207           nchar
3208             |
3209           univarchar
3210             |
3211           nvarchar
3212         )\b/x
3213       ) {
3214         $max_size = $attr->{sqlt_size} * 4;
3215       }
3216     }
3217
3218     if (!$max_size and !$self->_is_lob_type($data_type)) {
3219       $max_size = 100 # for all other (numeric?) datatypes
3220     }
3221   }
3222
3223   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3224 }
3225
3226 # Determine if a data_type is some type of BLOB
3227 sub _is_lob_type {
3228   my ($self, $data_type) = @_;
3229   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3230     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3231                                   |varchar|character\s*varying|nvarchar
3232                                   |national\s*character\s*varying))?\z/xi);
3233 }
3234
3235 sub _is_binary_lob_type {
3236   my ($self, $data_type) = @_;
3237   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3238     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3239 }
3240
3241 sub _is_text_lob_type {
3242   my ($self, $data_type) = @_;
3243   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3244     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3245                         |national\s*character\s*varying))\z/xi);
3246 }
3247
3248 # Determine if a data_type is some type of a binary type
3249 sub _is_binary_type {
3250   my ($self, $data_type) = @_;
3251   $data_type && ($self->_is_binary_lob_type($data_type)
3252     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3253 }
3254
3255 1;
3256
3257 =head1 USAGE NOTES
3258
3259 =head2 DBIx::Class and AutoCommit
3260
3261 DBIx::Class can do some wonderful magic with handling exceptions,
3262 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3263 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3264 transaction support.
3265
3266 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3267 in an assumed transaction between commits, and you're telling us you'd
3268 like to manage that manually.  A lot of the magic protections offered by
3269 this module will go away.  We can't protect you from exceptions due to database
3270 disconnects because we don't know anything about how to restart your
3271 transactions.  You're on your own for handling all sorts of exceptional
3272 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3273 be with raw DBI.
3274
3275 =head1 FURTHER QUESTIONS?
3276
3277 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3278
3279 =head1 COPYRIGHT AND LICENSE
3280
3281 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3282 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3283 redistribute it and/or modify it under the same terms as the
3284 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.