lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Context::Preserve 'preserve_context';
  16 use Try::Tiny;
  17 use overload ();
  18 use Data::Compare (); # no imports!!! guard against insane architecture
  19 use DBI::Const::GetInfoType (); # no import of retarded global hash
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. This is a purely DRY optimization
  85 #
  86 # get_(use)_dbms_capability need to be called on the correct Storage
  87 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  88 # _determine_supports_X which obv. needs a correct driver as well
  89 my @rdbms_specific_methods = qw/
  90   deployment_statements
  91   sqlt_type
  92   sql_maker
  93   build_datetime_parser
  94   datetime_parser_type
  95
  96   txn_begin
  97   insert
  98   insert_bulk
  99   update
 100   delete
 101   select
 102   select_single
 103   with_deferred_fk_checks
 104
 105   get_use_dbms_capability
 106   get_dbms_capability
 107
 108   _server_info
 109   _get_server_version
 110 /;
 111
 112 for my $meth (@rdbms_specific_methods) {
 113
 114   my $orig = __PACKAGE__->can ($meth)
 115     or die "$meth is not a ::Storage::DBI method!";
 116
 117   no strict qw/refs/;
 118   no warnings qw/redefine/;
 119   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 120     if (
 121       # only fire when invoked on an instance, a valid class-based invocation
 122       # would e.g. be setting a default for an inherited accessor
 123       ref $_[0]
 124         and
 125       ! $_[0]->_driver_determined
 126         and
 127       ! $_[0]->{_in_determine_driver}
 128     ) {
 129       $_[0]->_determine_driver;
 130
 131       # This for some reason crashes and burns on perl 5.8.1
 132       # IFF the method ends up throwing an exception
 133       #goto $_[0]->can ($meth);
 134
 135       my $cref = $_[0]->can ($meth);
 136       goto $cref;
 137     }
 138
 139     goto $orig;
 140   };
 141 }
 142
 143 =head1 NAME
 144
 145 DBIx::Class::Storage::DBI - DBI storage handler
 146
 147 =head1 SYNOPSIS
 148
 149   my $schema = MySchema->connect('dbi:SQLite:my.db');
 150
 151   $schema->storage->debug(1);
 152
 153   my @stuff = $schema->storage->dbh_do(
 154     sub {
 155       my ($storage, $dbh, @args) = @_;
 156       $dbh->do("DROP TABLE authors");
 157     },
 158     @column_list
 159   );
 160
 161   $schema->resultset('Book')->search({
 162      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 163   });
 164
 165 =head1 DESCRIPTION
 166
 167 This class represents the connection to an RDBMS via L<DBI>.  See
 168 L<DBIx::Class::Storage> for general information.  This pod only
 169 documents DBI-specific methods and behaviors.
 170
 171 =head1 METHODS
 172
 173 =cut
 174
 175 sub new {
 176   my $new = shift->next::method(@_);
 177
 178   $new->_sql_maker_opts({});
 179   $new->_dbh_details({});
 180   $new->{_in_do_block} = 0;
 181   $new->{_dbh_gen} = 0;
 182
 183   # read below to see what this does
 184   $new->_arm_global_destructor;
 185
 186   $new;
 187 }
 188
 189 # This is hack to work around perl shooting stuff in random
 190 # order on exit(). If we do not walk the remaining storage
 191 # objects in an END block, there is a *small but real* chance
 192 # of a fork()ed child to kill the parent's shared DBI handle,
 193 # *before perl reaches the DESTROY in this package*
 194 # Yes, it is ugly and effective.
 195 # Additionally this registry is used by the CLONE method to
 196 # make sure no handles are shared between threads
 197 {
 198   my %seek_and_destroy;
 199
 200   sub _arm_global_destructor {
 201     weaken (
 202       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 203     );
 204   }
 205
 206   END {
 207     local $?; # just in case the DBI destructor changes it somehow
 208
 209     # destroy just the object if not native to this process
 210     $_->_verify_pid for (grep
 211       { defined $_ }
 212       values %seek_and_destroy
 213     );
 214   }
 215
 216   sub CLONE {
 217     # As per DBI's recommendation, DBIC disconnects all handles as
 218     # soon as possible (DBIC will reconnect only on demand from within
 219     # the thread)
 220     my @instances = grep { defined $_ } values %seek_and_destroy;
 221     for (@instances) {
 222       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 223       $_->_dbh(undef);
 224
 225       $_->transaction_depth(0);
 226       $_->savepoints([]);
 227     }
 228
 229     # properly renumber all existing refs
 230     %seek_and_destroy = ();
 231     $_->_arm_global_destructor for @instances;
 232   }
 233 }
 234
 235 sub DESTROY {
 236   my $self = shift;
 237
 238   # some databases spew warnings on implicit disconnect
 239   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 240   local $SIG{__WARN__} = sub {};
 241   $self->_dbh(undef);
 242
 243   # this op is necessary, since the very last perl runtime statement
 244   # triggers a global destruction shootout, and the $SIG localization
 245   # may very well be destroyed before perl actually gets to do the
 246   # $dbh undef
 247   1;
 248 }
 249
 250 # handle pid changes correctly - do not destroy parent's connection
 251 sub _verify_pid {
 252   my $self = shift;
 253
 254   my $pid = $self->_conn_pid;
 255   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 256     $dbh->{InactiveDestroy} = 1;
 257     $self->{_dbh_gen}++;
 258     $self->_dbh(undef);
 259     $self->transaction_depth(0);
 260     $self->savepoints([]);
 261   }
 262
 263   return;
 264 }
 265
 266 =head2 connect_info
 267
 268 This method is normally called by L<DBIx::Class::Schema/connection>, which
 269 encapsulates its argument list in an arrayref before passing them here.
 270
 271 The argument list may contain:
 272
 273 =over
 274
 275 =item *
 276
 277 The same 4-element argument set one would normally pass to
 278 L<DBI/connect>, optionally followed by
 279 L<extra attributes|/DBIx::Class specific connection attributes>
 280 recognized by DBIx::Class:
 281
 282   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 283
 284 =item *
 285
 286 A single code reference which returns a connected
 287 L<DBI database handle|DBI/connect> optionally followed by
 288 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 289 by DBIx::Class:
 290
 291   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 292
 293 =item *
 294
 295 A single hashref with all the attributes and the dsn/user/password
 296 mixed together:
 297
 298   $connect_info_args = [{
 299     dsn => $dsn,
 300     user => $user,
 301     password => $pass,
 302     %dbi_attributes,
 303     %extra_attributes,
 304   }];
 305
 306   $connect_info_args = [{
 307     dbh_maker => sub { DBI->connect (...) },
 308     %dbi_attributes,
 309     %extra_attributes,
 310   }];
 311
 312 This is particularly useful for L<Catalyst> based applications, allowing the
 313 following config (L<Config::General> style):
 314
 315   <Model::DB>
 316     schema_class   App::DB
 317     <connect_info>
 318       dsn          dbi:mysql:database=test
 319       user         testuser
 320       password     TestPass
 321       AutoCommit   1
 322     </connect_info>
 323   </Model::DB>
 324
 325 The C<dsn>/C<user>/C<password> combination can be substituted by the
 326 C<dbh_maker> key whose value is a coderef that returns a connected
 327 L<DBI database handle|DBI/connect>
 328
 329 =back
 330
 331 Please note that the L<DBI> docs recommend that you always explicitly
 332 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 333 recommends that it be set to I<1>, and that you perform transactions
 334 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 335 to I<1> if you do not do explicitly set it to zero.  This is the default
 336 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 337
 338 =head3 DBIx::Class specific connection attributes
 339
 340 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 341 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 342 the following connection options. These options can be mixed in with your other
 343 L<DBI> connection attributes, or placed in a separate hashref
 344 (C<\%extra_attributes>) as shown above.
 345
 346 Every time C<connect_info> is invoked, any previous settings for
 347 these options will be cleared before setting the new ones, regardless of
 348 whether any options are specified in the new C<connect_info>.
 349
 350
 351 =over
 352
 353 =item on_connect_do
 354
 355 Specifies things to do immediately after connecting or re-connecting to
 356 the database.  Its value may contain:
 357
 358 =over
 359
 360 =item a scalar
 361
 362 This contains one SQL statement to execute.
 363
 364 =item an array reference
 365
 366 This contains SQL statements to execute in order.  Each element contains
 367 a string or a code reference that returns a string.
 368
 369 =item a code reference
 370
 371 This contains some code to execute.  Unlike code references within an
 372 array reference, its return value is ignored.
 373
 374 =back
 375
 376 =item on_disconnect_do
 377
 378 Takes arguments in the same form as L</on_connect_do> and executes them
 379 immediately before disconnecting from the database.
 380
 381 Note, this only runs if you explicitly call L</disconnect> on the
 382 storage object.
 383
 384 =item on_connect_call
 385
 386 A more generalized form of L</on_connect_do> that calls the specified
 387 C<connect_call_METHOD> methods in your storage driver.
 388
 389   on_connect_do => 'select 1'
 390
 391 is equivalent to:
 392
 393   on_connect_call => [ [ do_sql => 'select 1' ] ]
 394
 395 Its values may contain:
 396
 397 =over
 398
 399 =item a scalar
 400
 401 Will call the C<connect_call_METHOD> method.
 402
 403 =item a code reference
 404
 405 Will execute C<< $code->($storage) >>
 406
 407 =item an array reference
 408
 409 Each value can be a method name or code reference.
 410
 411 =item an array of arrays
 412
 413 For each array, the first item is taken to be the C<connect_call_> method name
 414 or code reference, and the rest are parameters to it.
 415
 416 =back
 417
 418 Some predefined storage methods you may use:
 419
 420 =over
 421
 422 =item do_sql
 423
 424 Executes a SQL string or a code reference that returns a SQL string. This is
 425 what L</on_connect_do> and L</on_disconnect_do> use.
 426
 427 It can take:
 428
 429 =over
 430
 431 =item a scalar
 432
 433 Will execute the scalar as SQL.
 434
 435 =item an arrayref
 436
 437 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 438 attributes hashref and bind values.
 439
 440 =item a code reference
 441
 442 Will execute C<< $code->($storage) >> and execute the return array refs as
 443 above.
 444
 445 =back
 446
 447 =item datetime_setup
 448
 449 Execute any statements necessary to initialize the database session to return
 450 and accept datetime/timestamp values used with
 451 L<DBIx::Class::InflateColumn::DateTime>.
 452
 453 Only necessary for some databases, see your specific storage driver for
 454 implementation details.
 455
 456 =back
 457
 458 =item on_disconnect_call
 459
 460 Takes arguments in the same form as L</on_connect_call> and executes them
 461 immediately before disconnecting from the database.
 462
 463 Calls the C<disconnect_call_METHOD> methods as opposed to the
 464 C<connect_call_METHOD> methods called by L</on_connect_call>.
 465
 466 Note, this only runs if you explicitly call L</disconnect> on the
 467 storage object.
 468
 469 =item disable_sth_caching
 470
 471 If set to a true value, this option will disable the caching of
 472 statement handles via L<DBI/prepare_cached>.
 473
 474 =item limit_dialect
 475
 476 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 477 default L</sql_limit_dialect> setting of the storage (if any). For a list
 478 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 479
 480 =item quote_names
 481
 482 When true automatically sets L</quote_char> and L</name_sep> to the characters
 483 appropriate for your particular RDBMS. This option is preferred over specifying
 484 L</quote_char> directly.
 485
 486 =item quote_char
 487
 488 Specifies what characters to use to quote table and column names.
 489
 490 C<quote_char> expects either a single character, in which case is it
 491 is placed on either side of the table/column name, or an arrayref of length
 492 2 in which case the table/column name is placed between the elements.
 493
 494 For example under MySQL you should use C<< quote_char => '`' >>, and for
 495 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 496
 497 =item name_sep
 498
 499 This parameter is only useful in conjunction with C<quote_char>, and is used to
 500 specify the character that separates elements (schemas, tables, columns) from
 501 each other. If unspecified it defaults to the most commonly used C<.>.
 502
 503 =item unsafe
 504
 505 This Storage driver normally installs its own C<HandleError>, sets
 506 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 507 all database handles, including those supplied by a coderef.  It does this
 508 so that it can have consistent and useful error behavior.
 509
 510 If you set this option to a true value, Storage will not do its usual
 511 modifications to the database handle's attributes, and instead relies on
 512 the settings in your connect_info DBI options (or the values you set in
 513 your connection coderef, in the case that you are connecting via coderef).
 514
 515 Note that your custom settings can cause Storage to malfunction,
 516 especially if you set a C<HandleError> handler that suppresses exceptions
 517 and/or disable C<RaiseError>.
 518
 519 =item auto_savepoint
 520
 521 If this option is true, L<DBIx::Class> will use savepoints when nesting
 522 transactions, making it possible to recover from failure in the inner
 523 transaction without having to abort all outer transactions.
 524
 525 =item cursor_class
 526
 527 Use this argument to supply a cursor class other than the default
 528 L<DBIx::Class::Storage::DBI::Cursor>.
 529
 530 =back
 531
 532 Some real-life examples of arguments to L</connect_info> and
 533 L<DBIx::Class::Schema/connect>
 534
 535   # Simple SQLite connection
 536   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 537
 538   # Connect via subref
 539   ->connect_info([ sub { DBI->connect(...) } ]);
 540
 541   # Connect via subref in hashref
 542   ->connect_info([{
 543     dbh_maker => sub { DBI->connect(...) },
 544     on_connect_do => 'alter session ...',
 545   }]);
 546
 547   # A bit more complicated
 548   ->connect_info(
 549     [
 550       'dbi:Pg:dbname=foo',
 551       'postgres',
 552       'my_pg_password',
 553       { AutoCommit => 1 },
 554       { quote_char => q{"} },
 555     ]
 556   );
 557
 558   # Equivalent to the previous example
 559   ->connect_info(
 560     [
 561       'dbi:Pg:dbname=foo',
 562       'postgres',
 563       'my_pg_password',
 564       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 565     ]
 566   );
 567
 568   # Same, but with hashref as argument
 569   # See parse_connect_info for explanation
 570   ->connect_info(
 571     [{
 572       dsn         => 'dbi:Pg:dbname=foo',
 573       user        => 'postgres',
 574       password    => 'my_pg_password',
 575       AutoCommit  => 1,
 576       quote_char  => q{"},
 577       name_sep    => q{.},
 578     }]
 579   );
 580
 581   # Subref + DBIx::Class-specific connection options
 582   ->connect_info(
 583     [
 584       sub { DBI->connect(...) },
 585       {
 586           quote_char => q{`},
 587           name_sep => q{@},
 588           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 589           disable_sth_caching => 1,
 590       },
 591     ]
 592   );
 593
 594
 595
 596 =cut
 597
 598 sub connect_info {
 599   my ($self, $info) = @_;
 600
 601   return $self->_connect_info if !$info;
 602
 603   $self->_connect_info($info); # copy for _connect_info
 604
 605   $info = $self->_normalize_connect_info($info)
 606     if ref $info eq 'ARRAY';
 607
 608   for my $storage_opt (keys %{ $info->{storage_options} }) {
 609     my $value = $info->{storage_options}{$storage_opt};
 610
 611     $self->$storage_opt($value);
 612   }
 613
 614   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 615   #  the new set of options
 616   $self->_sql_maker(undef);
 617   $self->_sql_maker_opts({});
 618
 619   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 620     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 621
 622     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 623   }
 624
 625   my %attrs = (
 626     %{ $self->_default_dbi_connect_attributes || {} },
 627     %{ $info->{attributes} || {} },
 628   );
 629
 630   my @args = @{ $info->{arguments} };
 631
 632   if (keys %attrs and ref $args[0] ne 'CODE') {
 633     carp
 634         'You provided explicit AutoCommit => 0 in your connection_info. '
 635       . 'This is almost universally a bad idea (see the footnotes of '
 636       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 637       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 638       . 'this warning.'
 639       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 640
 641     push @args, \%attrs if keys %attrs;
 642   }
 643   $self->_dbi_connect_info(\@args);
 644
 645   # FIXME - dirty:
 646   # save attributes them in a separate accessor so they are always
 647   # introspectable, even in case of a CODE $dbhmaker
 648   $self->_dbic_connect_attributes (\%attrs);
 649
 650   return $self->_connect_info;
 651 }
 652
 653 sub _normalize_connect_info {
 654   my ($self, $info_arg) = @_;
 655   my %info;
 656
 657   my @args = @$info_arg;  # take a shallow copy for further mutilation
 658
 659   # combine/pre-parse arguments depending on invocation style
 660
 661   my %attrs;
 662   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 663     %attrs = %{ $args[1] || {} };
 664     @args = $args[0];
 665   }
 666   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 667     %attrs = %{$args[0]};
 668     @args = ();
 669     if (my $code = delete $attrs{dbh_maker}) {
 670       @args = $code;
 671
 672       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 673       if (@ignored) {
 674         carp sprintf (
 675             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 676           . "to the result of 'dbh_maker'",
 677
 678           join (', ', map { "'$_'" } (@ignored) ),
 679         );
 680       }
 681     }
 682     else {
 683       @args = delete @attrs{qw/dsn user password/};
 684     }
 685   }
 686   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 687     %attrs = (
 688       % { $args[3] || {} },
 689       % { $args[4] || {} },
 690     );
 691     @args = @args[0,1,2];
 692   }
 693
 694   $info{arguments} = \@args;
 695
 696   my @storage_opts = grep exists $attrs{$_},
 697     @storage_options, 'cursor_class';
 698
 699   @{ $info{storage_options} }{@storage_opts} =
 700     delete @attrs{@storage_opts} if @storage_opts;
 701
 702   my @sql_maker_opts = grep exists $attrs{$_},
 703     qw/limit_dialect quote_char name_sep quote_names/;
 704
 705   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 706     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 707
 708   $info{attributes} = \%attrs if %attrs;
 709
 710   return \%info;
 711 }
 712
 713 sub _default_dbi_connect_attributes () {
 714   +{
 715     AutoCommit => 1,
 716     PrintError => 0,
 717     RaiseError => 1,
 718     ShowErrorStatement => 1,
 719   };
 720 }
 721
 722 =head2 on_connect_do
 723
 724 This method is deprecated in favour of setting via L</connect_info>.
 725
 726 =cut
 727
 728 =head2 on_disconnect_do
 729
 730 This method is deprecated in favour of setting via L</connect_info>.
 731
 732 =cut
 733
 734 sub _parse_connect_do {
 735   my ($self, $type) = @_;
 736
 737   my $val = $self->$type;
 738   return () if not defined $val;
 739
 740   my @res;
 741
 742   if (not ref($val)) {
 743     push @res, [ 'do_sql', $val ];
 744   } elsif (ref($val) eq 'CODE') {
 745     push @res, $val;
 746   } elsif (ref($val) eq 'ARRAY') {
 747     push @res, map { [ 'do_sql', $_ ] } @$val;
 748   } else {
 749     $self->throw_exception("Invalid type for $type: ".ref($val));
 750   }
 751
 752   return \@res;
 753 }
 754
 755 =head2 dbh_do
 756
 757 Arguments: ($subref | $method_name), @extra_coderef_args?
 758
 759 Execute the given $subref or $method_name using the new exception-based
 760 connection management.
 761
 762 The first two arguments will be the storage object that C<dbh_do> was called
 763 on and a database handle to use.  Any additional arguments will be passed
 764 verbatim to the called subref as arguments 2 and onwards.
 765
 766 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 767 exception handling and reconnection (or failover in future subclasses).
 768
 769 Your subref should have no side-effects outside of the database, as
 770 there is the potential for your subref to be partially double-executed
 771 if the database connection was stale/dysfunctional.
 772
 773 Example:
 774
 775   my @stuff = $schema->storage->dbh_do(
 776     sub {
 777       my ($storage, $dbh, @cols) = @_;
 778       my $cols = join(q{, }, @cols);
 779       $dbh->selectrow_array("SELECT $cols FROM foo");
 780     },
 781     @column_list
 782   );
 783
 784 =cut
 785
 786 sub dbh_do {
 787   my $self = shift;
 788   my $run_target = shift;
 789
 790   # short circuit when we know there is no need for a runner
 791   #
 792   # FIXME - asumption may be wrong
 793   # the rationale for the txn_depth check is that if this block is a part
 794   # of a larger transaction, everything up to that point is screwed anyway
 795   return $self->$run_target($self->_get_dbh, @_)
 796     if $self->{_in_do_block} or $self->transaction_depth;
 797
 798   my $args = \@_;
 799
 800   DBIx::Class::Storage::BlockRunner->new(
 801     storage => $self,
 802     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 803     wrap_txn => 0,
 804     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 805   )->run;
 806 }
 807
 808 sub txn_do {
 809   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 810   shift->next::method(@_);
 811 }
 812
 813 =head2 disconnect
 814
 815 Our C<disconnect> method also performs a rollback first if the
 816 database is not in C<AutoCommit> mode.
 817
 818 =cut
 819
 820 sub disconnect {
 821   my ($self) = @_;
 822
 823   if( $self->_dbh ) {
 824     my @actions;
 825
 826     push @actions, ( $self->on_disconnect_call || () );
 827     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 828
 829     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 830
 831     # stops the "implicit rollback on disconnect" warning
 832     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 833
 834     %{ $self->_dbh->{CachedKids} } = ();
 835     $self->_dbh->disconnect;
 836     $self->_dbh(undef);
 837     $self->{_dbh_gen}++;
 838   }
 839 }
 840
 841 =head2 with_deferred_fk_checks
 842
 843 =over 4
 844
 845 =item Arguments: C<$coderef>
 846
 847 =item Return Value: The return value of $coderef
 848
 849 =back
 850
 851 Storage specific method to run the code ref with FK checks deferred or
 852 in MySQL's case disabled entirely.
 853
 854 =cut
 855
 856 # Storage subclasses should override this
 857 sub with_deferred_fk_checks {
 858   my ($self, $sub) = @_;
 859   $sub->();
 860 }
 861
 862 =head2 connected
 863
 864 =over
 865
 866 =item Arguments: none
 867
 868 =item Return Value: 1|0
 869
 870 =back
 871
 872 Verifies that the current database handle is active and ready to execute
 873 an SQL statement (e.g. the connection did not get stale, server is still
 874 answering, etc.) This method is used internally by L</dbh>.
 875
 876 =cut
 877
 878 sub connected {
 879   my $self = shift;
 880   return 0 unless $self->_seems_connected;
 881
 882   #be on the safe side
 883   local $self->_dbh->{RaiseError} = 1;
 884
 885   return $self->_ping;
 886 }
 887
 888 sub _seems_connected {
 889   my $self = shift;
 890
 891   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 892
 893   my $dbh = $self->_dbh
 894     or return 0;
 895
 896   return $dbh->FETCH('Active');
 897 }
 898
 899 sub _ping {
 900   my $self = shift;
 901
 902   my $dbh = $self->_dbh or return 0;
 903
 904   return $dbh->ping;
 905 }
 906
 907 sub ensure_connected {
 908   my ($self) = @_;
 909
 910   unless ($self->connected) {
 911     $self->_populate_dbh;
 912   }
 913 }
 914
 915 =head2 dbh
 916
 917 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 918 is guaranteed to be healthy by implicitly calling L</connected>, and if
 919 necessary performing a reconnection before returning. Keep in mind that this
 920 is very B<expensive> on some database engines. Consider using L</dbh_do>
 921 instead.
 922
 923 =cut
 924
 925 sub dbh {
 926   my ($self) = @_;
 927
 928   if (not $self->_dbh) {
 929     $self->_populate_dbh;
 930   } else {
 931     $self->ensure_connected;
 932   }
 933   return $self->_dbh;
 934 }
 935
 936 # this is the internal "get dbh or connect (don't check)" method
 937 sub _get_dbh {
 938   my $self = shift;
 939   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 940   $self->_populate_dbh unless $self->_dbh;
 941   return $self->_dbh;
 942 }
 943
 944 sub sql_maker {
 945   my ($self) = @_;
 946   unless ($self->_sql_maker) {
 947     my $sql_maker_class = $self->sql_maker_class;
 948
 949     my %opts = %{$self->_sql_maker_opts||{}};
 950     my $dialect =
 951       $opts{limit_dialect}
 952         ||
 953       $self->sql_limit_dialect
 954         ||
 955       do {
 956         my $s_class = (ref $self) || $self;
 957         carp (
 958           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 959         . 'have not supplied an explicit limit_dialect in your connection_info. '
 960         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 961         . 'databases but can be (and often is) painfully slow. '
 962         . "Please file an RT ticket against '$s_class' ."
 963         );
 964
 965         'GenericSubQ';
 966       }
 967     ;
 968
 969     my ($quote_char, $name_sep);
 970
 971     if ($opts{quote_names}) {
 972       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 973         my $s_class = (ref $self) || $self;
 974         carp (
 975           "You requested 'quote_names' but your storage class ($s_class) does "
 976         . 'not explicitly define a default sql_quote_char and you have not '
 977         . 'supplied a quote_char as part of your connection_info. DBIC will '
 978         .q{default to the ANSI SQL standard quote '"', which works most of }
 979         . "the time. Please file an RT ticket against '$s_class'."
 980         );
 981
 982         '"'; # RV
 983       };
 984
 985       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 986     }
 987
 988     $self->_sql_maker($sql_maker_class->new(
 989       bindtype=>'columns',
 990       array_datatypes => 1,
 991       limit_dialect => $dialect,
 992       ($quote_char ? (quote_char => $quote_char) : ()),
 993       name_sep => ($name_sep || '.'),
 994       %opts,
 995     ));
 996   }
 997   return $self->_sql_maker;
 998 }
 999
1000 # nothing to do by default
1001 sub _rebless {}
1002 sub _init {}
1003
1004 sub _populate_dbh {
1005   my ($self) = @_;
1006
1007   my @info = @{$self->_dbi_connect_info || []};
1008   $self->_dbh(undef); # in case ->connected failed we might get sent here
1009   $self->_dbh_details({}); # reset everything we know
1010
1011   $self->_dbh($self->_connect(@info));
1012
1013   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1014
1015   $self->_determine_driver;
1016
1017   # Always set the transaction depth on connect, since
1018   #  there is no transaction in progress by definition
1019   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1020
1021   $self->_run_connection_actions unless $self->{_in_determine_driver};
1022 }
1023
1024 sub _run_connection_actions {
1025   my $self = shift;
1026   my @actions;
1027
1028   push @actions, ( $self->on_connect_call || () );
1029   push @actions, $self->_parse_connect_do ('on_connect_do');
1030
1031   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1032 }
1033
1034
1035
1036 sub set_use_dbms_capability {
1037   $_[0]->set_inherited ($_[1], $_[2]);
1038 }
1039
1040 sub get_use_dbms_capability {
1041   my ($self, $capname) = @_;
1042
1043   my $use = $self->get_inherited ($capname);
1044   return defined $use
1045     ? $use
1046     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1047   ;
1048 }
1049
1050 sub set_dbms_capability {
1051   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1052 }
1053
1054 sub get_dbms_capability {
1055   my ($self, $capname) = @_;
1056
1057   my $cap = $self->_dbh_details->{capability}{$capname};
1058
1059   unless (defined $cap) {
1060     if (my $meth = $self->can ("_determine$capname")) {
1061       $cap = $self->$meth ? 1 : 0;
1062     }
1063     else {
1064       $cap = 0;
1065     }
1066
1067     $self->set_dbms_capability ($capname, $cap);
1068   }
1069
1070   return $cap;
1071 }
1072
1073 sub _server_info {
1074   my $self = shift;
1075
1076   my $info;
1077   unless ($info = $self->_dbh_details->{info}) {
1078
1079     $info = {};
1080
1081     my $server_version = try {
1082       $self->_get_server_version
1083     } catch {
1084       # driver determination *may* use this codepath
1085       # in which case we must rethrow
1086       $self->throw_exception($_) if $self->{_in_determine_driver};
1087
1088       # $server_version on failure
1089       undef;
1090     };
1091
1092     if (defined $server_version) {
1093       $info->{dbms_version} = $server_version;
1094
1095       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1096       my @verparts = split (/\./, $numeric_version);
1097       if (
1098         @verparts
1099           &&
1100         $verparts[0] <= 999
1101       ) {
1102         # consider only up to 3 version parts, iff not more than 3 digits
1103         my @use_parts;
1104         while (@verparts && @use_parts < 3) {
1105           my $p = shift @verparts;
1106           last if $p > 999;
1107           push @use_parts, $p;
1108         }
1109         push @use_parts, 0 while @use_parts < 3;
1110
1111         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1112       }
1113     }
1114
1115     $self->_dbh_details->{info} = $info;
1116   }
1117
1118   return $info;
1119 }
1120
1121 sub _get_server_version {
1122   shift->_dbh_get_info('SQL_DBMS_VER');
1123 }
1124
1125 sub _dbh_get_info {
1126   my ($self, $info) = @_;
1127
1128   if ($info =~ /[^0-9]/) {
1129     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1130     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1131       unless defined $info;
1132   }
1133
1134   return $self->_get_dbh->get_info($info);
1135 }
1136
1137 sub _describe_connection {
1138   require DBI::Const::GetInfoReturn;
1139
1140   my $self = shift;
1141   $self->ensure_connected;
1142
1143   my $res = {
1144     DBIC_DSN => $self->_dbi_connect_info->[0],
1145     DBI_VER => DBI->VERSION,
1146     DBIC_VER => DBIx::Class->VERSION,
1147     DBIC_DRIVER => ref $self,
1148   };
1149
1150   for my $inf (
1151     #keys %DBI::Const::GetInfoType::GetInfoType,
1152     qw/
1153       SQL_CURSOR_COMMIT_BEHAVIOR
1154       SQL_CURSOR_ROLLBACK_BEHAVIOR
1155       SQL_CURSOR_SENSITIVITY
1156       SQL_DATA_SOURCE_NAME
1157       SQL_DBMS_NAME
1158       SQL_DBMS_VER
1159       SQL_DEFAULT_TXN_ISOLATION
1160       SQL_DM_VER
1161       SQL_DRIVER_NAME
1162       SQL_DRIVER_ODBC_VER
1163       SQL_DRIVER_VER
1164       SQL_EXPRESSIONS_IN_ORDERBY
1165       SQL_GROUP_BY
1166       SQL_IDENTIFIER_CASE
1167       SQL_IDENTIFIER_QUOTE_CHAR
1168       SQL_MAX_CATALOG_NAME_LEN
1169       SQL_MAX_COLUMN_NAME_LEN
1170       SQL_MAX_IDENTIFIER_LEN
1171       SQL_MAX_TABLE_NAME_LEN
1172       SQL_MULTIPLE_ACTIVE_TXN
1173       SQL_MULT_RESULT_SETS
1174       SQL_NEED_LONG_DATA_LEN
1175       SQL_NON_NULLABLE_COLUMNS
1176       SQL_ODBC_VER
1177       SQL_QUALIFIER_NAME_SEPARATOR
1178       SQL_QUOTED_IDENTIFIER_CASE
1179       SQL_TXN_CAPABLE
1180       SQL_TXN_ISOLATION_OPTION
1181     /
1182   ) {
1183     my $v = $self->_dbh_get_info($inf);
1184     next unless defined $v;
1185
1186     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1187     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1188     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1189   }
1190
1191   $res;
1192 }
1193
1194 sub _determine_driver {
1195   my ($self) = @_;
1196
1197   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1198     my $started_connected = 0;
1199     local $self->{_in_determine_driver} = 1;
1200
1201     if (ref($self) eq __PACKAGE__) {
1202       my $driver;
1203       if ($self->_dbh) { # we are connected
1204         $driver = $self->_dbh->{Driver}{Name};
1205         $started_connected = 1;
1206       }
1207       else {
1208         # if connect_info is a CODEREF, we have no choice but to connect
1209         if (ref $self->_dbi_connect_info->[0] &&
1210             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1211           $self->_populate_dbh;
1212           $driver = $self->_dbh->{Driver}{Name};
1213         }
1214         else {
1215           # try to use dsn to not require being connected, the driver may still
1216           # force a connection in _rebless to determine version
1217           # (dsn may not be supplied at all if all we do is make a mock-schema)
1218           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1219           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1220           $driver ||= $ENV{DBI_DRIVER};
1221         }
1222       }
1223
1224       if ($driver) {
1225         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1226         if ($self->load_optional_class($storage_class)) {
1227           mro::set_mro($storage_class, 'c3');
1228           bless $self, $storage_class;
1229           $self->_rebless();
1230         }
1231         else {
1232           $self->_warn_undetermined_driver(
1233             'This version of DBIC does not yet seem to supply a driver for '
1234           . "your particular RDBMS and/or connection method ('$driver')."
1235           );
1236         }
1237       }
1238       else {
1239         $self->_warn_undetermined_driver(
1240           'Unable to extract a driver name from connect info - this '
1241         . 'should not have happened.'
1242         );
1243       }
1244     }
1245
1246     $self->_driver_determined(1);
1247
1248     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1249
1250     if ($self->can('source_bind_attributes')) {
1251       $self->throw_exception(
1252         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1253       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1254       . 'If you are not sure how to proceed please contact the development team via '
1255       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1256       );
1257     }
1258
1259     $self->_init; # run driver-specific initializations
1260
1261     $self->_run_connection_actions
1262         if !$started_connected && defined $self->_dbh;
1263   }
1264 }
1265
1266 sub _determine_connector_driver {
1267   my ($self, $conn) = @_;
1268
1269   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1270
1271   if (not $dbtype) {
1272     $self->_warn_undetermined_driver(
1273       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1274     . "$conn connector - this should not have happened."
1275     );
1276     return;
1277   }
1278
1279   $dbtype =~ s/\W/_/gi;
1280
1281   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1282   return if $self->isa($subclass);
1283
1284   if ($self->load_optional_class($subclass)) {
1285     bless $self, $subclass;
1286     $self->_rebless;
1287   }
1288   else {
1289     $self->_warn_undetermined_driver(
1290       'This version of DBIC does not yet seem to supply a driver for '
1291     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1292     );
1293   }
1294 }
1295
1296 sub _warn_undetermined_driver {
1297   my ($self, $msg) = @_;
1298
1299   require Data::Dumper::Concise;
1300
1301   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1302   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1303   . "does not go away, file a bugreport including the following info:\n"
1304   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1305   );
1306 }
1307
1308 sub _do_connection_actions {
1309   my $self          = shift;
1310   my $method_prefix = shift;
1311   my $call          = shift;
1312
1313   if (not ref($call)) {
1314     my $method = $method_prefix . $call;
1315     $self->$method(@_);
1316   } elsif (ref($call) eq 'CODE') {
1317     $self->$call(@_);
1318   } elsif (ref($call) eq 'ARRAY') {
1319     if (ref($call->[0]) ne 'ARRAY') {
1320       $self->_do_connection_actions($method_prefix, $_) for @$call;
1321     } else {
1322       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1323     }
1324   } else {
1325     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1326   }
1327
1328   return $self;
1329 }
1330
1331 sub connect_call_do_sql {
1332   my $self = shift;
1333   $self->_do_query(@_);
1334 }
1335
1336 sub disconnect_call_do_sql {
1337   my $self = shift;
1338   $self->_do_query(@_);
1339 }
1340
1341 # override in db-specific backend when necessary
1342 sub connect_call_datetime_setup { 1 }
1343
1344 sub _do_query {
1345   my ($self, $action) = @_;
1346
1347   if (ref $action eq 'CODE') {
1348     $action = $action->($self);
1349     $self->_do_query($_) foreach @$action;
1350   }
1351   else {
1352     # Most debuggers expect ($sql, @bind), so we need to exclude
1353     # the attribute hash which is the second argument to $dbh->do
1354     # furthermore the bind values are usually to be presented
1355     # as named arrayref pairs, so wrap those here too
1356     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1357     my $sql = shift @do_args;
1358     my $attrs = shift @do_args;
1359     my @bind = map { [ undef, $_ ] } @do_args;
1360
1361     $self->dbh_do(sub {
1362       $_[0]->_query_start($sql, \@bind);
1363       $_[1]->do($sql, $attrs, @do_args);
1364       $_[0]->_query_end($sql, \@bind);
1365     });
1366   }
1367
1368   return $self;
1369 }
1370
1371 sub _connect {
1372   my ($self, @info) = @_;
1373
1374   $self->throw_exception("You failed to provide any connection info")
1375     if !@info;
1376
1377   my ($old_connect_via, $dbh);
1378
1379   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1380
1381   try {
1382     if(ref $info[0] eq 'CODE') {
1383       $dbh = $info[0]->();
1384     }
1385     else {
1386       require DBI;
1387       $dbh = DBI->connect(@info);
1388     }
1389
1390     if (!$dbh) {
1391       die $DBI::errstr;
1392     }
1393
1394     unless ($self->unsafe) {
1395
1396       $self->throw_exception(
1397         'Refusing clobbering of {HandleError} installed on externally supplied '
1398        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1399       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1400
1401       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1402       # request, or an external handle. Complain and set anyway
1403       unless ($dbh->{RaiseError}) {
1404         carp( ref $info[0] eq 'CODE'
1405
1406           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1407            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1408            .'attribute has been supplied'
1409
1410           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1411            .'unsafe => 1. Toggling RaiseError back to true'
1412         );
1413
1414         $dbh->{RaiseError} = 1;
1415       }
1416
1417       # this odd anonymous coderef dereference is in fact really
1418       # necessary to avoid the unwanted effect described in perl5
1419       # RT#75792
1420       sub {
1421         my $weak_self = $_[0];
1422         weaken $weak_self;
1423
1424         # the coderef is blessed so we can distinguish it from externally
1425         # supplied handles (which must be preserved)
1426         $_[1]->{HandleError} = bless sub {
1427           if ($weak_self) {
1428             $weak_self->throw_exception("DBI Exception: $_[0]");
1429           }
1430           else {
1431             # the handler may be invoked by something totally out of
1432             # the scope of DBIC
1433             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1434           }
1435         }, '__DBIC__DBH__ERROR__HANDLER__';
1436       }->($self, $dbh);
1437     }
1438   }
1439   catch {
1440     $self->throw_exception("DBI Connection failed: $_")
1441   };
1442
1443   $self->_dbh_autocommit($dbh->{AutoCommit});
1444   $dbh;
1445 }
1446
1447 sub txn_begin {
1448   my $self = shift;
1449
1450   # this means we have not yet connected and do not know the AC status
1451   # (e.g. coderef $dbh), need a full-fledged connection check
1452   if (! defined $self->_dbh_autocommit) {
1453     $self->ensure_connected;
1454   }
1455   # Otherwise simply connect or re-connect on pid changes
1456   else {
1457     $self->_get_dbh;
1458   }
1459
1460   $self->next::method(@_);
1461 }
1462
1463 sub _exec_txn_begin {
1464   my $self = shift;
1465
1466   # if the user is utilizing txn_do - good for him, otherwise we need to
1467   # ensure that the $dbh is healthy on BEGIN.
1468   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1469   # will be replaced by a failure of begin_work itself (which will be
1470   # then retried on reconnect)
1471   if ($self->{_in_do_block}) {
1472     $self->_dbh->begin_work;
1473   } else {
1474     $self->dbh_do(sub { $_[1]->begin_work });
1475   }
1476 }
1477
1478 sub txn_commit {
1479   my $self = shift;
1480
1481   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1482   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1483     unless $self->_dbh;
1484
1485   # esoteric case for folks using external $dbh handles
1486   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1487     carp "Storage transaction_depth 0 does not match "
1488         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1489     $self->transaction_depth(1);
1490   }
1491
1492   $self->next::method(@_);
1493
1494   # if AutoCommit is disabled txn_depth never goes to 0
1495   # as a new txn is started immediately on commit
1496   $self->transaction_depth(1) if (
1497     !$self->transaction_depth
1498       and
1499     defined $self->_dbh_autocommit
1500       and
1501     ! $self->_dbh_autocommit
1502   );
1503 }
1504
1505 sub _exec_txn_commit {
1506   shift->_dbh->commit;
1507 }
1508
1509 sub txn_rollback {
1510   my $self = shift;
1511
1512   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1513   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1514     unless $self->_dbh;
1515
1516   # esoteric case for folks using external $dbh handles
1517   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1518     carp "Storage transaction_depth 0 does not match "
1519         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1520     $self->transaction_depth(1);
1521   }
1522
1523   $self->next::method(@_);
1524
1525   # if AutoCommit is disabled txn_depth never goes to 0
1526   # as a new txn is started immediately on commit
1527   $self->transaction_depth(1) if (
1528     !$self->transaction_depth
1529       and
1530     defined $self->_dbh_autocommit
1531       and
1532     ! $self->_dbh_autocommit
1533   );
1534 }
1535
1536 sub _exec_txn_rollback {
1537   shift->_dbh->rollback;
1538 }
1539
1540 # generate some identical methods
1541 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1542   no strict qw/refs/;
1543   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1544     my $self = shift;
1545     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1546     $self->throw_exception("Unable to $meth() on a disconnected storage")
1547       unless $self->_dbh;
1548     $self->next::method(@_);
1549   };
1550 }
1551
1552 # This used to be the top-half of _execute.  It was split out to make it
1553 #  easier to override in NoBindVars without duping the rest.  It takes up
1554 #  all of _execute's args, and emits $sql, @bind.
1555 sub _prep_for_execute {
1556   #my ($self, $op, $ident, $args) = @_;
1557   return shift->_gen_sql_bind(@_)
1558 }
1559
1560 sub _gen_sql_bind {
1561   my ($self, $op, $ident, $args) = @_;
1562
1563   my ($colinfos, $from);
1564   if ( blessed($ident) ) {
1565     $from = $ident->from;
1566     $colinfos = $ident->columns_info;
1567   }
1568
1569   my ($sql, @bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1570
1571   if (
1572     ! $ENV{DBIC_DT_SEARCH_OK}
1573       and
1574     $op eq 'select'
1575       and
1576     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1577   ) {
1578     carp_unique 'DateTime objects passed to search() are not supported '
1579       . 'properly (InflateColumn::DateTime formats and settings are not '
1580       . 'respected.) See "Formatting DateTime objects in queries" in '
1581       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1582       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1583   }
1584
1585   return( $sql, $self->_resolve_bindattrs(
1586     $ident, [ @{$args->[2]{bind}||[]}, @bind ], $colinfos
1587   ));
1588 }
1589
1590 sub _resolve_bindattrs {
1591   my ($self, $ident, $bind, $colinfos) = @_;
1592
1593   $colinfos ||= {};
1594
1595   my $resolve_bindinfo = sub {
1596     #my $infohash = shift;
1597
1598     %$colinfos = %{ $self->_resolve_column_info($ident) }
1599       unless keys %$colinfos;
1600
1601     my $ret;
1602     if (my $col = $_[0]->{dbic_colname}) {
1603       $ret = { %{$_[0]} };
1604
1605       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1606         if $colinfos->{$col}{data_type};
1607
1608       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1609         if $colinfos->{$col}{size};
1610     }
1611
1612     $ret || $_[0];
1613   };
1614
1615   return [ map {
1616     if (ref $_ ne 'ARRAY') {
1617       [{}, $_]
1618     }
1619     elsif (! defined $_->[0]) {
1620       [{}, $_->[1]]
1621     }
1622     elsif (ref $_->[0] eq 'HASH') {
1623       [
1624         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1625         $_->[1]
1626       ]
1627     }
1628     elsif (ref $_->[0] eq 'SCALAR') {
1629       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1630     }
1631     else {
1632       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1633     }
1634   } @$bind ];
1635 }
1636
1637 sub _format_for_trace {
1638   #my ($self, $bind) = @_;
1639
1640   ### Turn @bind from something like this:
1641   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1642   ### to this:
1643   ###   ( "'1'", "'3'" )
1644
1645   map {
1646     defined( $_ && $_->[1] )
1647       ? qq{'$_->[1]'}
1648       : q{NULL}
1649   } @{$_[1] || []};
1650 }
1651
1652 sub _query_start {
1653   my ( $self, $sql, $bind ) = @_;
1654
1655   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1656     if $self->debug;
1657 }
1658
1659 sub _query_end {
1660   my ( $self, $sql, $bind ) = @_;
1661
1662   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1663     if $self->debug;
1664 }
1665
1666 sub _dbi_attrs_for_bind {
1667   my ($self, $ident, $bind) = @_;
1668
1669   my @attrs;
1670
1671   for (map { $_->[0] } @$bind) {
1672     push @attrs, do {
1673       if (exists $_->{dbd_attrs}) {
1674         $_->{dbd_attrs}
1675       }
1676       elsif($_->{sqlt_datatype}) {
1677         # cache the result in the dbh_details hash, as it can not change unless
1678         # we connect to something else
1679         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1680         if (not exists $cache->{$_->{sqlt_datatype}}) {
1681           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1682         }
1683         $cache->{$_->{sqlt_datatype}};
1684       }
1685       else {
1686         undef;  # always push something at this position
1687       }
1688     }
1689   }
1690
1691   return \@attrs;
1692 }
1693
1694 sub _execute {
1695   my ($self, $op, $ident, @args) = @_;
1696
1697   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1698
1699   shift->dbh_do(    # retry over disconnects
1700     '_dbh_execute',
1701     $sql,
1702     $bind,
1703     $ident,
1704   );
1705 }
1706
1707 sub _dbh_execute {
1708   my ($self, undef, $sql, $bind, $ident) = @_;
1709
1710   $self->_query_start( $sql, $bind );
1711
1712   my $bind_attrs = $self->_dbi_attrs_for_bind($ident, $bind);
1713
1714   my $sth = $self->_sth($sql);
1715
1716   for my $i (0 .. $#$bind) {
1717     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1718       $sth->bind_param_inout(
1719         $i + 1, # bind params counts are 1-based
1720         $bind->[$i][1],
1721         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1722         $bind_attrs->[$i],
1723       );
1724     }
1725     else {
1726       $sth->bind_param(
1727         $i + 1,
1728         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1729           ? "$bind->[$i][1]"
1730           : $bind->[$i][1]
1731         ,
1732         $bind_attrs->[$i],
1733       );
1734     }
1735   }
1736
1737   # Can this fail without throwing an exception anyways???
1738   my $rv = $sth->execute();
1739   $self->throw_exception(
1740     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1741   ) if !$rv;
1742
1743   $self->_query_end( $sql, $bind );
1744
1745   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1746 }
1747
1748 sub _prefetch_autovalues {
1749   my ($self, $source, $to_insert) = @_;
1750
1751   my $colinfo = $source->columns_info;
1752
1753   my %values;
1754   for my $col (keys %$colinfo) {
1755     if (
1756       $colinfo->{$col}{auto_nextval}
1757         and
1758       (
1759         ! exists $to_insert->{$col}
1760           or
1761         ref $to_insert->{$col} eq 'SCALAR'
1762           or
1763         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1764       )
1765     ) {
1766       $values{$col} = $self->_sequence_fetch(
1767         'NEXTVAL',
1768         ( $colinfo->{$col}{sequence} ||=
1769             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1770         ),
1771       );
1772     }
1773   }
1774
1775   \%values;
1776 }
1777
1778 sub insert {
1779   my ($self, $source, $to_insert) = @_;
1780
1781   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1782
1783   # fuse the values, but keep a separate list of prefetched_values so that
1784   # they can be fused once again with the final return
1785   $to_insert = { %$to_insert, %$prefetched_values };
1786
1787   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1788   # Investigate what does it take to s/defined/exists/
1789   my $col_infos = $source->columns_info;
1790   my %pcols = map { $_ => 1 } $source->primary_columns;
1791   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1792   for my $col ($source->columns) {
1793     if ($col_infos->{$col}{is_auto_increment}) {
1794       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1795       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1796     }
1797
1798     # nothing to retrieve when explicit values are supplied
1799     next if (defined $to_insert->{$col} and ! (
1800       ref $to_insert->{$col} eq 'SCALAR'
1801         or
1802       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1803     ));
1804
1805     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1806     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1807       $pcols{$col}
1808         or
1809       $col_infos->{$col}{retrieve_on_insert}
1810     );
1811   };
1812
1813   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1814   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1815
1816   my ($sqla_opts, @ir_container);
1817   if (%retrieve_cols and $self->_use_insert_returning) {
1818     $sqla_opts->{returning_container} = \@ir_container
1819       if $self->_use_insert_returning_bound;
1820
1821     $sqla_opts->{returning} = [
1822       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1823     ];
1824   }
1825
1826   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1827
1828   my %returned_cols = %$to_insert;
1829   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1830     @ir_container = try {
1831       local $SIG{__WARN__} = sub {};
1832       my @r = $sth->fetchrow_array;
1833       $sth->finish;
1834       @r;
1835     } unless @ir_container;
1836
1837     @returned_cols{@$retlist} = @ir_container if @ir_container;
1838   }
1839   else {
1840     # pull in PK if needed and then everything else
1841     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1842
1843       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1844         unless $self->can('last_insert_id');
1845
1846       my @pri_values = $self->last_insert_id($source, @missing_pri);
1847
1848       $self->throw_exception( "Can't get last insert id" )
1849         unless (@pri_values == @missing_pri);
1850
1851       @returned_cols{@missing_pri} = @pri_values;
1852       delete $retrieve_cols{$_} for @missing_pri;
1853     }
1854
1855     # if there is more left to pull
1856     if (%retrieve_cols) {
1857       $self->throw_exception(
1858         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1859       ) unless %pcols;
1860
1861       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1862
1863       my $cur = DBIx::Class::ResultSet->new($source, {
1864         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1865         select => \@left_to_fetch,
1866       })->cursor;
1867
1868       @returned_cols{@left_to_fetch} = $cur->next;
1869
1870       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1871         if scalar $cur->next;
1872     }
1873   }
1874
1875   return { %$prefetched_values, %returned_cols };
1876 }
1877
1878 sub insert_bulk {
1879   my ($self, $source, $cols, $data) = @_;
1880
1881   my @col_range = (0..$#$cols);
1882
1883   # FIXME - perhaps this is not even needed? does DBI stringify?
1884   #
1885   # forcibly stringify whatever is stringifiable
1886   # ResultSet::populate() hands us a copy - safe to mangle
1887   for my $r (0 .. $#$data) {
1888     for my $c (0 .. $#{$data->[$r]}) {
1889       $data->[$r][$c] = "$data->[$r][$c]"
1890         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1891     }
1892   }
1893
1894   my $colinfos = $source->columns_info($cols);
1895
1896   local $self->{_autoinc_supplied_for_op} =
1897     (first { $_->{is_auto_increment} } values %$colinfos)
1898       ? 1
1899       : 0
1900   ;
1901
1902   # get a slice type index based on first row of data
1903   # a "column" in this context may refer to more than one bind value
1904   # e.g. \[ '?, ?', [...], [...] ]
1905   #
1906   # construct the value type index - a description of values types for every
1907   # per-column slice of $data:
1908   #
1909   # nonexistent - nonbind literal
1910   # 0 - regular value
1911   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1912   #
1913   # also construct the column hash to pass to the SQL generator. For plain
1914   # (non literal) values - convert the members of the first row into a
1915   # literal+bind combo, with extra positional info in the bind attr hashref.
1916   # This will allow us to match the order properly, and is so contrived
1917   # because a user-supplied literal/bind (or something else specific to a
1918   # resultsource and/or storage driver) can inject extra binds along the
1919   # way, so one can't rely on "shift positions" ordering at all. Also we
1920   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1921   # can be later matched up by address), because we want to supply a real
1922   # value on which perhaps e.g. datatype checks will be performed
1923   my ($proto_data, $value_type_by_col_idx);
1924   for my $i (@col_range) {
1925     my $colname = $cols->[$i];
1926     if (ref $data->[0][$i] eq 'SCALAR') {
1927       # no bind value at all - no type
1928
1929       $proto_data->{$colname} = $data->[0][$i];
1930     }
1931     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1932       # repack, so we don't end up mangling the original \[]
1933       my ($sql, @bind) = @${$data->[0][$i]};
1934
1935       # normalization of user supplied stuff
1936       my $resolved_bind = $self->_resolve_bindattrs(
1937         $source, \@bind, $colinfos,
1938       );
1939
1940       # store value-less (attrs only) bind info - we will be comparing all
1941       # supplied binds against this for sanity
1942       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1943
1944       $proto_data->{$colname} = \[ $sql, map { [
1945         # inject slice order to use for $proto_bind construction
1946           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
1947             =>
1948           $resolved_bind->[$_][1]
1949         ] } (0 .. $#bind)
1950       ];
1951     }
1952     else {
1953       $value_type_by_col_idx->{$i} = undef;
1954
1955       $proto_data->{$colname} = \[ '?', [
1956         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1957           =>
1958         $data->[0][$i]
1959       ] ];
1960     }
1961   }
1962
1963   my ($sql, $proto_bind) = $self->_prep_for_execute (
1964     'insert',
1965     $source,
1966     [ $proto_data ],
1967   );
1968
1969   if (! @$proto_bind and keys %$value_type_by_col_idx) {
1970     # if the bindlist is empty and we had some dynamic binds, this means the
1971     # storage ate them away (e.g. the NoBindVars component) and interpolated
1972     # them directly into the SQL. This obviously can't be good for multi-inserts
1973     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1974   }
1975
1976   # sanity checks
1977   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1978   #
1979   # use an error reporting closure for convenience (less to pass)
1980   my $bad_slice_report_cref = sub {
1981     my ($msg, $r_idx, $c_idx) = @_;
1982     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1983       $msg,
1984       $cols->[$c_idx],
1985       do {
1986         require Data::Dumper::Concise;
1987         local $Data::Dumper::Maxdepth = 5;
1988         Data::Dumper::Concise::Dumper ({
1989           map { $cols->[$_] =>
1990             $data->[$r_idx][$_]
1991           } @col_range
1992         }),
1993       }
1994     );
1995   };
1996
1997   for my $col_idx (@col_range) {
1998     my $reference_val = $data->[0][$col_idx];
1999
2000     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2001       my $val = $data->[$row_idx][$col_idx];
2002
2003       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2004         if (ref $val ne 'SCALAR') {
2005           $bad_slice_report_cref->(
2006             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2007             $row_idx,
2008             $col_idx,
2009           );
2010         }
2011         elsif ($$val ne $$reference_val) {
2012           $bad_slice_report_cref->(
2013             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2014             $row_idx,
2015             $col_idx,
2016           );
2017         }
2018       }
2019       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2020         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2021           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2022         }
2023       }
2024       else {  # binds from a \[], compare type and attrs
2025         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2026           $bad_slice_report_cref->(
2027             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2028             $row_idx,
2029             $col_idx,
2030           );
2031         }
2032         # start drilling down and bail out early on identical refs
2033         elsif (
2034           $reference_val != $val
2035             or
2036           $$reference_val != $$val
2037         ) {
2038           if (${$val}->[0] ne ${$reference_val}->[0]) {
2039             $bad_slice_report_cref->(
2040               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2041               $row_idx,
2042               $col_idx,
2043             );
2044           }
2045           # need to check the bind attrs - a bind will happen only once for
2046           # the entire dataset, so any changes further down will be ignored.
2047           elsif (! Data::Compare::Compare(
2048             $value_type_by_col_idx->{$col_idx},
2049             [
2050               map
2051               { $_->[0] }
2052               @{$self->_resolve_bindattrs(
2053                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2054               )}
2055             ],
2056           )) {
2057             $bad_slice_report_cref->(
2058               'Differing bind attributes on literal/bind values not supported',
2059               $row_idx,
2060               $col_idx,
2061             );
2062           }
2063         }
2064       }
2065     }
2066   }
2067
2068   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2069   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2070   # scope guard
2071   my $guard = $self->txn_scope_guard;
2072
2073   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2074   my $sth = $self->_sth($sql);
2075   my $rv = do {
2076     if (@$proto_bind) {
2077       # proto bind contains the information on which pieces of $data to pull
2078       # $cols is passed in only for prettier error-reporting
2079       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2080     }
2081     else {
2082       # bind_param_array doesn't work if there are no binds
2083       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2084     }
2085   };
2086
2087   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2088
2089   $guard->commit;
2090
2091   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2092 }
2093
2094 # execute_for_fetch is capable of returning data just fine (it means it
2095 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2096 # is the void-populate fast-path we will just ignore this altogether
2097 # for the time being.
2098 sub _dbh_execute_for_fetch {
2099   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2100
2101   my @idx_range = ( 0 .. $#$proto_bind );
2102
2103   # If we have any bind attributes to take care of, we will bind the
2104   # proto-bind data (which will never be used by execute_for_fetch)
2105   # However since column bindtypes are "sticky", this is sufficient
2106   # to get the DBD to apply the bindtype to all values later on
2107
2108   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2109
2110   for my $i (@idx_range) {
2111     $sth->bind_param (
2112       $i+1, # DBI bind indexes are 1-based
2113       $proto_bind->[$i][1],
2114       $bind_attrs->[$i],
2115     ) if defined $bind_attrs->[$i];
2116   }
2117
2118   # At this point $data slots named in the _bind_data_slice_idx of
2119   # each piece of $proto_bind are either \[]s or plain values to be
2120   # passed in. Construct the dispensing coderef. *NOTE* the order
2121   # of $data will differ from this of the ?s in the SQL (due to
2122   # alphabetical ordering by colname). We actually do want to
2123   # preserve this behavior so that prepare_cached has a better
2124   # chance of matching on unrelated calls
2125
2126   my $fetch_row_idx = -1; # saner loop this way
2127   my $fetch_tuple = sub {
2128     return undef if ++$fetch_row_idx > $#$data;
2129
2130     return [ map { defined $_->{_literal_bind_subindex}
2131       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2132          ->[ $_->{_literal_bind_subindex} ]
2133           ->[1]
2134       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2135     } map { $_->[0] } @$proto_bind];
2136   };
2137
2138   my $tuple_status = [];
2139   my ($rv, $err);
2140   try {
2141     $rv = $sth->execute_for_fetch(
2142       $fetch_tuple,
2143       $tuple_status,
2144     );
2145   }
2146   catch {
2147     $err = shift;
2148   };
2149
2150   # Not all DBDs are create equal. Some throw on error, some return
2151   # an undef $rv, and some set $sth->err - try whatever we can
2152   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2153     ! defined $err
2154       and
2155     ( !defined $rv or $sth->err )
2156   );
2157
2158   # Statement must finish even if there was an exception.
2159   try {
2160     $sth->finish
2161   }
2162   catch {
2163     $err = shift unless defined $err
2164   };
2165
2166   if (defined $err) {
2167     my $i = 0;
2168     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2169
2170     $self->throw_exception("Unexpected populate error: $err")
2171       if ($i > $#$tuple_status);
2172
2173     require Data::Dumper::Concise;
2174     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2175       ($tuple_status->[$i][1] || $err),
2176       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2177     );
2178   }
2179
2180   return $rv;
2181 }
2182
2183 sub _dbh_execute_inserts_with_no_binds {
2184   my ($self, $sth, $count) = @_;
2185
2186   my $err;
2187   try {
2188     my $dbh = $self->_get_dbh;
2189     local $dbh->{RaiseError} = 1;
2190     local $dbh->{PrintError} = 0;
2191
2192     $sth->execute foreach 1..$count;
2193   }
2194   catch {
2195     $err = shift;
2196   };
2197
2198   # Make sure statement is finished even if there was an exception.
2199   try {
2200     $sth->finish
2201   }
2202   catch {
2203     $err = shift unless defined $err;
2204   };
2205
2206   $self->throw_exception($err) if defined $err;
2207
2208   return $count;
2209 }
2210
2211 sub update {
2212   #my ($self, $source, @args) = @_;
2213   shift->_execute('update', @_);
2214 }
2215
2216
2217 sub delete {
2218   #my ($self, $source, @args) = @_;
2219   shift->_execute('delete', @_);
2220 }
2221
2222 sub _select {
2223   my $self = shift;
2224   $self->_execute($self->_select_args(@_));
2225 }
2226
2227 sub _select_args_to_query {
2228   my $self = shift;
2229
2230   $self->throw_exception(
2231     "Unable to generate limited query representation with 'software_limit' enabled"
2232   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2233
2234   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2235   #  = $self->_select_args($ident, $select, $cond, $attrs);
2236   my ($op, $ident, @args) =
2237     $self->_select_args(@_);
2238
2239   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2240   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2241   $prepared_bind ||= [];
2242
2243   return wantarray
2244     ? ($sql, $prepared_bind)
2245     : \[ "($sql)", @$prepared_bind ]
2246   ;
2247 }
2248
2249 sub _select_args {
2250   my ($self, $ident, $select, $where, $attrs) = @_;
2251
2252   my $sql_maker = $self->sql_maker;
2253   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2254
2255   $attrs = {
2256     %$attrs,
2257     select => $select,
2258     from => $ident,
2259     where => $where,
2260     $rs_alias && $alias2source->{$rs_alias}
2261       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2262       : ()
2263     ,
2264   };
2265
2266   # Sanity check the attributes (SQLMaker does it too, but
2267   # in case of a software_limit we'll never reach there)
2268   if (defined $attrs->{offset}) {
2269     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2270       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2271   }
2272
2273   if (defined $attrs->{rows}) {
2274     $self->throw_exception("The rows attribute must be a positive integer if present")
2275       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2276   }
2277   elsif ($attrs->{offset}) {
2278     # MySQL actually recommends this approach.  I cringe.
2279     $attrs->{rows} = $sql_maker->__max_int;
2280   }
2281
2282   my @limit;
2283
2284   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2285   # storage, unless software limit was requested
2286   if (
2287     #limited has_many
2288     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2289        ||
2290     # grouped prefetch (to satisfy group_by == select)
2291     ( $attrs->{group_by}
2292         &&
2293       @{$attrs->{group_by}}
2294         &&
2295       $attrs->{_prefetch_selector_range}
2296     )
2297   ) {
2298     ($ident, $select, $where, $attrs)
2299       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2300   }
2301   elsif (! $attrs->{software_limit} ) {
2302     push @limit, (
2303       $attrs->{rows} || (),
2304       $attrs->{offset} || (),
2305     );
2306   }
2307
2308   # try to simplify the joinmap further (prune unreferenced type-single joins)
2309   if (
2310     ref $ident
2311       and
2312     reftype $ident eq 'ARRAY'
2313       and
2314     @$ident != 1
2315   ) {
2316     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2317   }
2318
2319 ###
2320   # This would be the point to deflate anything found in $where
2321   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2322   # expect a result object. And all we have is a resultsource (it is trivial
2323   # to extract deflator coderefs via $alias2source above).
2324   #
2325   # I don't see a way forward other than changing the way deflators are
2326   # invoked, and that's just bad...
2327 ###
2328
2329   return ('select', $ident, $select, $where, $attrs, @limit);
2330 }
2331
2332 # Returns a counting SELECT for a simple count
2333 # query. Abstracted so that a storage could override
2334 # this to { count => 'firstcol' } or whatever makes
2335 # sense as a performance optimization
2336 sub _count_select {
2337   #my ($self, $source, $rs_attrs) = @_;
2338   return { count => '*' };
2339 }
2340
2341 =head2 select
2342
2343 =over 4
2344
2345 =item Arguments: $ident, $select, $condition, $attrs
2346
2347 =back
2348
2349 Handle a SQL select statement.
2350
2351 =cut
2352
2353 sub select {
2354   my $self = shift;
2355   my ($ident, $select, $condition, $attrs) = @_;
2356   return $self->cursor_class->new($self, \@_, $attrs);
2357 }
2358
2359 sub select_single {
2360   my $self = shift;
2361   my ($rv, $sth, @bind) = $self->_select(@_);
2362   my @row = $sth->fetchrow_array;
2363   my @nextrow = $sth->fetchrow_array if @row;
2364   if(@row && @nextrow) {
2365     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2366   }
2367   # Need to call finish() to work round broken DBDs
2368   $sth->finish();
2369   return @row;
2370 }
2371
2372 =head2 sql_limit_dialect
2373
2374 This is an accessor for the default SQL limit dialect used by a particular
2375 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2376 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2377 see L<DBIx::Class::SQLMaker::LimitDialects>.
2378
2379 =cut
2380
2381 sub _dbh_sth {
2382   my ($self, $dbh, $sql) = @_;
2383
2384   # 3 is the if_active parameter which avoids active sth re-use
2385   my $sth = $self->disable_sth_caching
2386     ? $dbh->prepare($sql)
2387     : $dbh->prepare_cached($sql, {}, 3);
2388
2389   # XXX You would think RaiseError would make this impossible,
2390   #  but apparently that's not true :(
2391   $self->throw_exception(
2392     $dbh->errstr
2393       ||
2394     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2395             .'an exception and/or setting $dbh->errstr',
2396       length ($sql) > 20
2397         ? substr($sql, 0, 20) . '...'
2398         : $sql
2399       ,
2400       'DBD::' . $dbh->{Driver}{Name},
2401     )
2402   ) if !$sth;
2403
2404   $sth;
2405 }
2406
2407 sub sth {
2408   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2409   shift->_sth(@_);
2410 }
2411
2412 sub _sth {
2413   my ($self, $sql) = @_;
2414   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2415 }
2416
2417 sub _dbh_columns_info_for {
2418   my ($self, $dbh, $table) = @_;
2419
2420   if ($dbh->can('column_info')) {
2421     my %result;
2422     my $caught;
2423     try {
2424       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2425       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2426       $sth->execute();
2427       while ( my $info = $sth->fetchrow_hashref() ){
2428         my %column_info;
2429         $column_info{data_type}   = $info->{TYPE_NAME};
2430         $column_info{size}      = $info->{COLUMN_SIZE};
2431         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2432         $column_info{default_value} = $info->{COLUMN_DEF};
2433         my $col_name = $info->{COLUMN_NAME};
2434         $col_name =~ s/^\"(.*)\"$/$1/;
2435
2436         $result{$col_name} = \%column_info;
2437       }
2438     } catch {
2439       $caught = 1;
2440     };
2441     return \%result if !$caught && scalar keys %result;
2442   }
2443
2444   my %result;
2445   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2446   $sth->execute;
2447   my @columns = @{$sth->{NAME_lc}};
2448   for my $i ( 0 .. $#columns ){
2449     my %column_info;
2450     $column_info{data_type} = $sth->{TYPE}->[$i];
2451     $column_info{size} = $sth->{PRECISION}->[$i];
2452     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2453
2454     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2455       $column_info{data_type} = $1;
2456       $column_info{size}    = $2;
2457     }
2458
2459     $result{$columns[$i]} = \%column_info;
2460   }
2461   $sth->finish;
2462
2463   foreach my $col (keys %result) {
2464     my $colinfo = $result{$col};
2465     my $type_num = $colinfo->{data_type};
2466     my $type_name;
2467     if(defined $type_num && $dbh->can('type_info')) {
2468       my $type_info = $dbh->type_info($type_num);
2469       $type_name = $type_info->{TYPE_NAME} if $type_info;
2470       $colinfo->{data_type} = $type_name if $type_name;
2471     }
2472   }
2473
2474   return \%result;
2475 }
2476
2477 sub columns_info_for {
2478   my ($self, $table) = @_;
2479   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2480 }
2481
2482 =head2 last_insert_id
2483
2484 Return the row id of the last insert.
2485
2486 =cut
2487
2488 sub _dbh_last_insert_id {
2489     my ($self, $dbh, $source, $col) = @_;
2490
2491     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2492
2493     return $id if defined $id;
2494
2495     my $class = ref $self;
2496     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2497 }
2498
2499 sub last_insert_id {
2500   my $self = shift;
2501   $self->_dbh_last_insert_id ($self->_dbh, @_);
2502 }
2503
2504 =head2 _native_data_type
2505
2506 =over 4
2507
2508 =item Arguments: $type_name
2509
2510 =back
2511
2512 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2513 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2514 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2515
2516 The default implementation returns C<undef>, implement in your Storage driver if
2517 you need this functionality.
2518
2519 Should map types from other databases to the native RDBMS type, for example
2520 C<VARCHAR2> to C<VARCHAR>.
2521
2522 Types with modifiers should map to the underlying data type. For example,
2523 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2524
2525 Composite types should map to the container type, for example
2526 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2527
2528 =cut
2529
2530 sub _native_data_type {
2531   #my ($self, $data_type) = @_;
2532   return undef
2533 }
2534
2535 # Check if placeholders are supported at all
2536 sub _determine_supports_placeholders {
2537   my $self = shift;
2538   my $dbh  = $self->_get_dbh;
2539
2540   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2541   # but it is inaccurate more often than not
2542   return try {
2543     local $dbh->{PrintError} = 0;
2544     local $dbh->{RaiseError} = 1;
2545     $dbh->do('select ?', {}, 1);
2546     1;
2547   }
2548   catch {
2549     0;
2550   };
2551 }
2552
2553 # Check if placeholders bound to non-string types throw exceptions
2554 #
2555 sub _determine_supports_typeless_placeholders {
2556   my $self = shift;
2557   my $dbh  = $self->_get_dbh;
2558
2559   return try {
2560     local $dbh->{PrintError} = 0;
2561     local $dbh->{RaiseError} = 1;
2562     # this specifically tests a bind that is NOT a string
2563     $dbh->do('select 1 where 1 = ?', {}, 1);
2564     1;
2565   }
2566   catch {
2567     0;
2568   };
2569 }
2570
2571 =head2 sqlt_type
2572
2573 Returns the database driver name.
2574
2575 =cut
2576
2577 sub sqlt_type {
2578   shift->_get_dbh->{Driver}->{Name};
2579 }
2580
2581 =head2 bind_attribute_by_data_type
2582
2583 Given a datatype from column info, returns a database specific bind
2584 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2585 let the database planner just handle it.
2586
2587 This method is always called after the driver has been determined and a DBI
2588 connection has been established. Therefore you can refer to C<DBI::$constant>
2589 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2590 the correct modules.
2591
2592 =cut
2593
2594 sub bind_attribute_by_data_type {
2595     return;
2596 }
2597
2598 =head2 is_datatype_numeric
2599
2600 Given a datatype from column_info, returns a boolean value indicating if
2601 the current RDBMS considers it a numeric value. This controls how
2602 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2603 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2604 be performed instead of the usual C<eq>.
2605
2606 =cut
2607
2608 sub is_datatype_numeric {
2609   #my ($self, $dt) = @_;
2610
2611   return 0 unless $_[1];
2612
2613   $_[1] =~ /^ (?:
2614     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2615   ) $/ix;
2616 }
2617
2618
2619 =head2 create_ddl_dir
2620
2621 =over 4
2622
2623 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2624
2625 =back
2626
2627 Creates a SQL file based on the Schema, for each of the specified
2628 database engines in C<\@databases> in the given directory.
2629 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2630
2631 Given a previous version number, this will also create a file containing
2632 the ALTER TABLE statements to transform the previous schema into the
2633 current one. Note that these statements may contain C<DROP TABLE> or
2634 C<DROP COLUMN> statements that can potentially destroy data.
2635
2636 The file names are created using the C<ddl_filename> method below, please
2637 override this method in your schema if you would like a different file
2638 name format. For the ALTER file, the same format is used, replacing
2639 $version in the name with "$preversion-$version".
2640
2641 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2642 The most common value for this would be C<< { add_drop_table => 1 } >>
2643 to have the SQL produced include a C<DROP TABLE> statement for each table
2644 created. For quoting purposes supply C<quote_table_names> and
2645 C<quote_field_names>.
2646
2647 If no arguments are passed, then the following default values are assumed:
2648
2649 =over 4
2650
2651 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2652
2653 =item version    - $schema->schema_version
2654
2655 =item directory  - './'
2656
2657 =item preversion - <none>
2658
2659 =back
2660
2661 By default, C<\%sqlt_args> will have
2662
2663  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2664
2665 merged with the hash passed in. To disable any of those features, pass in a
2666 hashref like the following
2667
2668  { ignore_constraint_names => 0, # ... other options }
2669
2670
2671 WARNING: You are strongly advised to check all SQL files created, before applying
2672 them.
2673
2674 =cut
2675
2676 sub create_ddl_dir {
2677   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2678
2679   unless ($dir) {
2680     carp "No directory given, using ./\n";
2681     $dir = './';
2682   } else {
2683       -d $dir
2684         or
2685       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2686         or
2687       $self->throw_exception(
2688         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2689       );
2690   }
2691
2692   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2693
2694   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2695   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2696
2697   my $schema_version = $schema->schema_version || '1.x';
2698   $version ||= $schema_version;
2699
2700   $sqltargs = {
2701     add_drop_table => 1,
2702     ignore_constraint_names => 1,
2703     ignore_index_names => 1,
2704     %{$sqltargs || {}}
2705   };
2706
2707   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2708     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2709   }
2710
2711   my $sqlt = SQL::Translator->new( $sqltargs );
2712
2713   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2714   my $sqlt_schema = $sqlt->translate({ data => $schema })
2715     or $self->throw_exception ($sqlt->error);
2716
2717   foreach my $db (@$databases) {
2718     $sqlt->reset();
2719     $sqlt->{schema} = $sqlt_schema;
2720     $sqlt->producer($db);
2721
2722     my $file;
2723     my $filename = $schema->ddl_filename($db, $version, $dir);
2724     if (-e $filename && ($version eq $schema_version )) {
2725       # if we are dumping the current version, overwrite the DDL
2726       carp "Overwriting existing DDL file - $filename";
2727       unlink($filename);
2728     }
2729
2730     my $output = $sqlt->translate;
2731     if(!$output) {
2732       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2733       next;
2734     }
2735     if(!open($file, ">$filename")) {
2736       $self->throw_exception("Can't open $filename for writing ($!)");
2737       next;
2738     }
2739     print $file $output;
2740     close($file);
2741
2742     next unless ($preversion);
2743
2744     require SQL::Translator::Diff;
2745
2746     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2747     if(!-e $prefilename) {
2748       carp("No previous schema file found ($prefilename)");
2749       next;
2750     }
2751
2752     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2753     if(-e $difffile) {
2754       carp("Overwriting existing diff file - $difffile");
2755       unlink($difffile);
2756     }
2757
2758     my $source_schema;
2759     {
2760       my $t = SQL::Translator->new($sqltargs);
2761       $t->debug( 0 );
2762       $t->trace( 0 );
2763
2764       $t->parser( $db )
2765         or $self->throw_exception ($t->error);
2766
2767       my $out = $t->translate( $prefilename )
2768         or $self->throw_exception ($t->error);
2769
2770       $source_schema = $t->schema;
2771
2772       $source_schema->name( $prefilename )
2773         unless ( $source_schema->name );
2774     }
2775
2776     # The "new" style of producers have sane normalization and can support
2777     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2778     # And we have to diff parsed SQL against parsed SQL.
2779     my $dest_schema = $sqlt_schema;
2780
2781     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2782       my $t = SQL::Translator->new($sqltargs);
2783       $t->debug( 0 );
2784       $t->trace( 0 );
2785
2786       $t->parser( $db )
2787         or $self->throw_exception ($t->error);
2788
2789       my $out = $t->translate( $filename )
2790         or $self->throw_exception ($t->error);
2791
2792       $dest_schema = $t->schema;
2793
2794       $dest_schema->name( $filename )
2795         unless $dest_schema->name;
2796     }
2797
2798     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2799                                                   $dest_schema,   $db,
2800                                                   $sqltargs
2801                                                  );
2802     if(!open $file, ">$difffile") {
2803       $self->throw_exception("Can't write to $difffile ($!)");
2804       next;
2805     }
2806     print $file $diff;
2807     close($file);
2808   }
2809 }
2810
2811 =head2 deployment_statements
2812
2813 =over 4
2814
2815 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2816
2817 =back
2818
2819 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2820
2821 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2822 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2823
2824 C<$directory> is used to return statements from files in a previously created
2825 L</create_ddl_dir> directory and is optional. The filenames are constructed
2826 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2827
2828 If no C<$directory> is specified then the statements are constructed on the
2829 fly using L<SQL::Translator> and C<$version> is ignored.
2830
2831 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2832
2833 =cut
2834
2835 sub deployment_statements {
2836   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2837   $type ||= $self->sqlt_type;
2838   $version ||= $schema->schema_version || '1.x';
2839   $dir ||= './';
2840   my $filename = $schema->ddl_filename($type, $version, $dir);
2841   if(-f $filename)
2842   {
2843       # FIXME replace this block when a proper sane sql parser is available
2844       my $file;
2845       open($file, "<$filename")
2846         or $self->throw_exception("Can't open $filename ($!)");
2847       my @rows = <$file>;
2848       close($file);
2849       return join('', @rows);
2850   }
2851
2852   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2853     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2854   }
2855
2856   # sources needs to be a parser arg, but for simplicty allow at top level
2857   # coming in
2858   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2859       if exists $sqltargs->{sources};
2860
2861   my $tr = SQL::Translator->new(
2862     producer => "SQL::Translator::Producer::${type}",
2863     %$sqltargs,
2864     parser => 'SQL::Translator::Parser::DBIx::Class',
2865     data => $schema,
2866   );
2867
2868   return preserve_context {
2869     $tr->translate
2870   } after => sub {
2871     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2872       unless defined $_[0];
2873   };
2874 }
2875
2876 # FIXME deploy() currently does not accurately report sql errors
2877 # Will always return true while errors are warned
2878 sub deploy {
2879   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2880   my $deploy = sub {
2881     my $line = shift;
2882     return if(!$line);
2883     return if($line =~ /^--/);
2884     # next if($line =~ /^DROP/m);
2885     return if($line =~ /^BEGIN TRANSACTION/m);
2886     return if($line =~ /^COMMIT/m);
2887     return if $line =~ /^\s+$/; # skip whitespace only
2888     $self->_query_start($line);
2889     try {
2890       # do a dbh_do cycle here, as we need some error checking in
2891       # place (even though we will ignore errors)
2892       $self->dbh_do (sub { $_[1]->do($line) });
2893     } catch {
2894       carp qq{$_ (running "${line}")};
2895     };
2896     $self->_query_end($line);
2897   };
2898   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2899   if (@statements > 1) {
2900     foreach my $statement (@statements) {
2901       $deploy->( $statement );
2902     }
2903   }
2904   elsif (@statements == 1) {
2905     # split on single line comments and end of statements
2906     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2907       $deploy->( $line );
2908     }
2909   }
2910 }
2911
2912 =head2 datetime_parser
2913
2914 Returns the datetime parser class
2915
2916 =cut
2917
2918 sub datetime_parser {
2919   my $self = shift;
2920   return $self->{datetime_parser} ||= do {
2921     $self->build_datetime_parser(@_);
2922   };
2923 }
2924
2925 =head2 datetime_parser_type
2926
2927 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2928
2929 =head2 build_datetime_parser
2930
2931 See L</datetime_parser>
2932
2933 =cut
2934
2935 sub build_datetime_parser {
2936   my $self = shift;
2937   my $type = $self->datetime_parser_type(@_);
2938   return $type;
2939 }
2940
2941
2942 =head2 is_replicating
2943
2944 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2945 replicate from a master database.  Default is undef, which is the result
2946 returned by databases that don't support replication.
2947
2948 =cut
2949
2950 sub is_replicating {
2951     return;
2952
2953 }
2954
2955 =head2 lag_behind_master
2956
2957 Returns a number that represents a certain amount of lag behind a master db
2958 when a given storage is replicating.  The number is database dependent, but
2959 starts at zero and increases with the amount of lag. Default in undef
2960
2961 =cut
2962
2963 sub lag_behind_master {
2964     return;
2965 }
2966
2967 =head2 relname_to_table_alias
2968
2969 =over 4
2970
2971 =item Arguments: $relname, $join_count
2972
2973 =item Return Value: $alias
2974
2975 =back
2976
2977 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2978 queries.
2979
2980 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2981 way these aliases are named.
2982
2983 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2984 otherwise C<"$relname">.
2985
2986 =cut
2987
2988 sub relname_to_table_alias {
2989   my ($self, $relname, $join_count) = @_;
2990
2991   my $alias = ($join_count && $join_count > 1 ?
2992     join('_', $relname, $join_count) : $relname);
2993
2994   return $alias;
2995 }
2996
2997 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
2998 # version and it may be necessary to amend or override it for a specific storage
2999 # if such binds are necessary.
3000 sub _max_column_bytesize {
3001   my ($self, $attr) = @_;
3002
3003   my $max_size;
3004
3005   if ($attr->{sqlt_datatype}) {
3006     my $data_type = lc($attr->{sqlt_datatype});
3007
3008     if ($attr->{sqlt_size}) {
3009
3010       # String/sized-binary types
3011       if ($data_type =~ /^(?:
3012           l? (?:var)? char(?:acter)? (?:\s*varying)?
3013             |
3014           (?:var)? binary (?:\s*varying)?
3015             |
3016           raw
3017         )\b/x
3018       ) {
3019         $max_size = $attr->{sqlt_size};
3020       }
3021       # Other charset/unicode types, assume scale of 4
3022       elsif ($data_type =~ /^(?:
3023           national \s* character (?:\s*varying)?
3024             |
3025           nchar
3026             |
3027           univarchar
3028             |
3029           nvarchar
3030         )\b/x
3031       ) {
3032         $max_size = $attr->{sqlt_size} * 4;
3033       }
3034     }
3035
3036     if (!$max_size and !$self->_is_lob_type($data_type)) {
3037       $max_size = 100 # for all other (numeric?) datatypes
3038     }
3039   }
3040
3041   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3042 }
3043
3044 # Determine if a data_type is some type of BLOB
3045 sub _is_lob_type {
3046   my ($self, $data_type) = @_;
3047   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3048     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3049                                   |varchar|character\s*varying|nvarchar
3050                                   |national\s*character\s*varying))?\z/xi);
3051 }
3052
3053 sub _is_binary_lob_type {
3054   my ($self, $data_type) = @_;
3055   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3056     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3057 }
3058
3059 sub _is_text_lob_type {
3060   my ($self, $data_type) = @_;
3061   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3062     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3063                         |national\s*character\s*varying))\z/xi);
3064 }
3065
3066 # Determine if a data_type is some type of a binary type
3067 sub _is_binary_type {
3068   my ($self, $data_type) = @_;
3069   $data_type && ($self->_is_binary_lob_type($data_type)
3070     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3071 }
3072
3073 1;
3074
3075 =head1 USAGE NOTES
3076
3077 =head2 DBIx::Class and AutoCommit
3078
3079 DBIx::Class can do some wonderful magic with handling exceptions,
3080 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3081 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3082 transaction support.
3083
3084 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3085 in an assumed transaction between commits, and you're telling us you'd
3086 like to manage that manually.  A lot of the magic protections offered by
3087 this module will go away.  We can't protect you from exceptions due to database
3088 disconnects because we don't know anything about how to restart your
3089 transactions.  You're on your own for handling all sorts of exceptional
3090 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3091 be with raw DBI.
3092
3093
3094 =head1 AUTHOR AND CONTRIBUTORS
3095
3096 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3097
3098 =head1 LICENSE
3099
3100 You may distribute this code under the same terms as Perl itself.
3101
3102 =cut