lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use DBI::Const::GetInfoType (); # no import of retarded global hash
  19 use namespace::clean;
  20
  21 # default cursor class, overridable in connect_info attributes
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/
  25   sql_limit_dialect sql_quote_char sql_name_sep
  26 /);
  27
  28 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  29
  30 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  31 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  32
  33 __PACKAGE__->sql_name_sep('.');
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/
  36   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  37   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  38   _perform_autoinc_retrieval _autoinc_supplied_for_op
  39 /);
  40
  41 # the values for these accessors are picked out (and deleted) from
  42 # the attribute hashref passed to connect_info
  43 my @storage_options = qw/
  44   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  45   disable_sth_caching unsafe auto_savepoint
  46 /;
  47 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  48
  49
  50 # capability definitions, using a 2-tiered accessor system
  51 # The rationale is:
  52 #
  53 # A driver/user may define _use_X, which blindly without any checks says:
  54 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  55 # type accessor)
  56 #
  57 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  58 # accessor, which in turn calls _determine_supports_X, and stores the return
  59 # in a special slot on the storage object, which is wiped every time a $dbh
  60 # reconnection takes place (it is not guaranteed that upon reconnection we
  61 # will get the same rdbms version). _determine_supports_X does not need to
  62 # exist on a driver, as we ->can for it before calling.
  63
  64 my @capabilities = (qw/
  65   insert_returning
  66   insert_returning_bound
  67
  68   multicolumn_in
  69
  70   placeholders
  71   typeless_placeholders
  72
  73   join_optimizer
  74 /);
  75 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  76 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  77
  78 # on by default, not strictly a capability (pending rewrite)
  79 __PACKAGE__->_use_join_optimizer (1);
  80 sub _determine_supports_join_optimizer { 1 };
  81
  82 # Each of these methods need _determine_driver called before itself
  83 # in order to function reliably. This is a purely DRY optimization
  84 #
  85 # get_(use)_dbms_capability need to be called on the correct Storage
  86 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  87 # _determine_supports_X which obv. needs a correct driver as well
  88 my @rdbms_specific_methods = qw/
  89   sqlt_type
  90   sql_maker
  91   build_datetime_parser
  92   datetime_parser_type
  93
  94   txn_begin
  95   insert
  96   insert_bulk
  97   update
  98   delete
  99   select
 100   select_single
 101   with_deferred_fk_checks
 102
 103   get_use_dbms_capability
 104   get_dbms_capability
 105
 106   _server_info
 107   _get_server_version
 108 /;
 109
 110 for my $meth (@rdbms_specific_methods) {
 111
 112   my $orig = __PACKAGE__->can ($meth)
 113     or die "$meth is not a ::Storage::DBI method!";
 114
 115   no strict qw/refs/;
 116   no warnings qw/redefine/;
 117   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 118     if (
 119       # only fire when invoked on an instance, a valid class-based invocation
 120       # would e.g. be setting a default for an inherited accessor
 121       ref $_[0]
 122         and
 123       ! $_[0]->_driver_determined
 124         and
 125       ! $_[0]->{_in_determine_driver}
 126     ) {
 127       $_[0]->_determine_driver;
 128
 129       # This for some reason crashes and burns on perl 5.8.1
 130       # IFF the method ends up throwing an exception
 131       #goto $_[0]->can ($meth);
 132
 133       my $cref = $_[0]->can ($meth);
 134       goto $cref;
 135     }
 136
 137     goto $orig;
 138   };
 139 }
 140
 141 =head1 NAME
 142
 143 DBIx::Class::Storage::DBI - DBI storage handler
 144
 145 =head1 SYNOPSIS
 146
 147   my $schema = MySchema->connect('dbi:SQLite:my.db');
 148
 149   $schema->storage->debug(1);
 150
 151   my @stuff = $schema->storage->dbh_do(
 152     sub {
 153       my ($storage, $dbh, @args) = @_;
 154       $dbh->do("DROP TABLE authors");
 155     },
 156     @column_list
 157   );
 158
 159   $schema->resultset('Book')->search({
 160      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 161   });
 162
 163 =head1 DESCRIPTION
 164
 165 This class represents the connection to an RDBMS via L<DBI>.  See
 166 L<DBIx::Class::Storage> for general information.  This pod only
 167 documents DBI-specific methods and behaviors.
 168
 169 =head1 METHODS
 170
 171 =cut
 172
 173 sub new {
 174   my $new = shift->next::method(@_);
 175
 176   $new->_sql_maker_opts({});
 177   $new->_dbh_details({});
 178   $new->{_in_do_block} = 0;
 179
 180   # read below to see what this does
 181   $new->_arm_global_destructor;
 182
 183   $new;
 184 }
 185
 186 # This is hack to work around perl shooting stuff in random
 187 # order on exit(). If we do not walk the remaining storage
 188 # objects in an END block, there is a *small but real* chance
 189 # of a fork()ed child to kill the parent's shared DBI handle,
 190 # *before perl reaches the DESTROY in this package*
 191 # Yes, it is ugly and effective.
 192 # Additionally this registry is used by the CLONE method to
 193 # make sure no handles are shared between threads
 194 {
 195   my %seek_and_destroy;
 196
 197   sub _arm_global_destructor {
 198     weaken (
 199       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 200     );
 201   }
 202
 203   END {
 204     local $?; # just in case the DBI destructor changes it somehow
 205
 206     # destroy just the object if not native to this process
 207     $_->_verify_pid for (grep
 208       { defined $_ }
 209       values %seek_and_destroy
 210     );
 211   }
 212
 213   sub CLONE {
 214     # As per DBI's recommendation, DBIC disconnects all handles as
 215     # soon as possible (DBIC will reconnect only on demand from within
 216     # the thread)
 217     my @instances = grep { defined $_ } values %seek_and_destroy;
 218     %seek_and_destroy = ();
 219
 220     for (@instances) {
 221       $_->_dbh(undef);
 222
 223       $_->transaction_depth(0);
 224       $_->savepoints([]);
 225
 226       # properly renumber existing refs
 227       $_->_arm_global_destructor
 228     }
 229   }
 230 }
 231
 232 sub DESTROY {
 233   my $self = shift;
 234
 235   # some databases spew warnings on implicit disconnect
 236   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 237   local $SIG{__WARN__} = sub {};
 238   $self->_dbh(undef);
 239
 240   # this op is necessary, since the very last perl runtime statement
 241   # triggers a global destruction shootout, and the $SIG localization
 242   # may very well be destroyed before perl actually gets to do the
 243   # $dbh undef
 244   1;
 245 }
 246
 247 # handle pid changes correctly - do not destroy parent's connection
 248 sub _verify_pid {
 249   my $self = shift;
 250
 251   my $pid = $self->_conn_pid;
 252   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 253     $dbh->{InactiveDestroy} = 1;
 254     $self->_dbh(undef);
 255     $self->transaction_depth(0);
 256     $self->savepoints([]);
 257   }
 258
 259   return;
 260 }
 261
 262 =head2 connect_info
 263
 264 This method is normally called by L<DBIx::Class::Schema/connection>, which
 265 encapsulates its argument list in an arrayref before passing them here.
 266
 267 The argument list may contain:
 268
 269 =over
 270
 271 =item *
 272
 273 The same 4-element argument set one would normally pass to
 274 L<DBI/connect>, optionally followed by
 275 L<extra attributes|/DBIx::Class specific connection attributes>
 276 recognized by DBIx::Class:
 277
 278   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 279
 280 =item *
 281
 282 A single code reference which returns a connected
 283 L<DBI database handle|DBI/connect> optionally followed by
 284 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 285 by DBIx::Class:
 286
 287   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 288
 289 =item *
 290
 291 A single hashref with all the attributes and the dsn/user/password
 292 mixed together:
 293
 294   $connect_info_args = [{
 295     dsn => $dsn,
 296     user => $user,
 297     password => $pass,
 298     %dbi_attributes,
 299     %extra_attributes,
 300   }];
 301
 302   $connect_info_args = [{
 303     dbh_maker => sub { DBI->connect (...) },
 304     %dbi_attributes,
 305     %extra_attributes,
 306   }];
 307
 308 This is particularly useful for L<Catalyst> based applications, allowing the
 309 following config (L<Config::General> style):
 310
 311   <Model::DB>
 312     schema_class   App::DB
 313     <connect_info>
 314       dsn          dbi:mysql:database=test
 315       user         testuser
 316       password     TestPass
 317       AutoCommit   1
 318     </connect_info>
 319   </Model::DB>
 320
 321 The C<dsn>/C<user>/C<password> combination can be substituted by the
 322 C<dbh_maker> key whose value is a coderef that returns a connected
 323 L<DBI database handle|DBI/connect>
 324
 325 =back
 326
 327 Please note that the L<DBI> docs recommend that you always explicitly
 328 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 329 recommends that it be set to I<1>, and that you perform transactions
 330 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 331 to I<1> if you do not do explicitly set it to zero.  This is the default
 332 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 333
 334 =head3 DBIx::Class specific connection attributes
 335
 336 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 337 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 338 the following connection options. These options can be mixed in with your other
 339 L<DBI> connection attributes, or placed in a separate hashref
 340 (C<\%extra_attributes>) as shown above.
 341
 342 Every time C<connect_info> is invoked, any previous settings for
 343 these options will be cleared before setting the new ones, regardless of
 344 whether any options are specified in the new C<connect_info>.
 345
 346
 347 =over
 348
 349 =item on_connect_do
 350
 351 Specifies things to do immediately after connecting or re-connecting to
 352 the database.  Its value may contain:
 353
 354 =over
 355
 356 =item a scalar
 357
 358 This contains one SQL statement to execute.
 359
 360 =item an array reference
 361
 362 This contains SQL statements to execute in order.  Each element contains
 363 a string or a code reference that returns a string.
 364
 365 =item a code reference
 366
 367 This contains some code to execute.  Unlike code references within an
 368 array reference, its return value is ignored.
 369
 370 =back
 371
 372 =item on_disconnect_do
 373
 374 Takes arguments in the same form as L</on_connect_do> and executes them
 375 immediately before disconnecting from the database.
 376
 377 Note, this only runs if you explicitly call L</disconnect> on the
 378 storage object.
 379
 380 =item on_connect_call
 381
 382 A more generalized form of L</on_connect_do> that calls the specified
 383 C<connect_call_METHOD> methods in your storage driver.
 384
 385   on_connect_do => 'select 1'
 386
 387 is equivalent to:
 388
 389   on_connect_call => [ [ do_sql => 'select 1' ] ]
 390
 391 Its values may contain:
 392
 393 =over
 394
 395 =item a scalar
 396
 397 Will call the C<connect_call_METHOD> method.
 398
 399 =item a code reference
 400
 401 Will execute C<< $code->($storage) >>
 402
 403 =item an array reference
 404
 405 Each value can be a method name or code reference.
 406
 407 =item an array of arrays
 408
 409 For each array, the first item is taken to be the C<connect_call_> method name
 410 or code reference, and the rest are parameters to it.
 411
 412 =back
 413
 414 Some predefined storage methods you may use:
 415
 416 =over
 417
 418 =item do_sql
 419
 420 Executes a SQL string or a code reference that returns a SQL string. This is
 421 what L</on_connect_do> and L</on_disconnect_do> use.
 422
 423 It can take:
 424
 425 =over
 426
 427 =item a scalar
 428
 429 Will execute the scalar as SQL.
 430
 431 =item an arrayref
 432
 433 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 434 attributes hashref and bind values.
 435
 436 =item a code reference
 437
 438 Will execute C<< $code->($storage) >> and execute the return array refs as
 439 above.
 440
 441 =back
 442
 443 =item datetime_setup
 444
 445 Execute any statements necessary to initialize the database session to return
 446 and accept datetime/timestamp values used with
 447 L<DBIx::Class::InflateColumn::DateTime>.
 448
 449 Only necessary for some databases, see your specific storage driver for
 450 implementation details.
 451
 452 =back
 453
 454 =item on_disconnect_call
 455
 456 Takes arguments in the same form as L</on_connect_call> and executes them
 457 immediately before disconnecting from the database.
 458
 459 Calls the C<disconnect_call_METHOD> methods as opposed to the
 460 C<connect_call_METHOD> methods called by L</on_connect_call>.
 461
 462 Note, this only runs if you explicitly call L</disconnect> on the
 463 storage object.
 464
 465 =item disable_sth_caching
 466
 467 If set to a true value, this option will disable the caching of
 468 statement handles via L<DBI/prepare_cached>.
 469
 470 =item limit_dialect
 471
 472 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 473 default L</sql_limit_dialect> setting of the storage (if any). For a list
 474 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 475
 476 =item quote_names
 477
 478 When true automatically sets L</quote_char> and L</name_sep> to the characters
 479 appropriate for your particular RDBMS. This option is preferred over specifying
 480 L</quote_char> directly.
 481
 482 =item quote_char
 483
 484 Specifies what characters to use to quote table and column names.
 485
 486 C<quote_char> expects either a single character, in which case is it
 487 is placed on either side of the table/column name, or an arrayref of length
 488 2 in which case the table/column name is placed between the elements.
 489
 490 For example under MySQL you should use C<< quote_char => '`' >>, and for
 491 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 492
 493 =item name_sep
 494
 495 This parameter is only useful in conjunction with C<quote_char>, and is used to
 496 specify the character that separates elements (schemas, tables, columns) from
 497 each other. If unspecified it defaults to the most commonly used C<.>.
 498
 499 =item unsafe
 500
 501 This Storage driver normally installs its own C<HandleError>, sets
 502 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 503 all database handles, including those supplied by a coderef.  It does this
 504 so that it can have consistent and useful error behavior.
 505
 506 If you set this option to a true value, Storage will not do its usual
 507 modifications to the database handle's attributes, and instead relies on
 508 the settings in your connect_info DBI options (or the values you set in
 509 your connection coderef, in the case that you are connecting via coderef).
 510
 511 Note that your custom settings can cause Storage to malfunction,
 512 especially if you set a C<HandleError> handler that suppresses exceptions
 513 and/or disable C<RaiseError>.
 514
 515 =item auto_savepoint
 516
 517 If this option is true, L<DBIx::Class> will use savepoints when nesting
 518 transactions, making it possible to recover from failure in the inner
 519 transaction without having to abort all outer transactions.
 520
 521 =item cursor_class
 522
 523 Use this argument to supply a cursor class other than the default
 524 L<DBIx::Class::Storage::DBI::Cursor>.
 525
 526 =back
 527
 528 Some real-life examples of arguments to L</connect_info> and
 529 L<DBIx::Class::Schema/connect>
 530
 531   # Simple SQLite connection
 532   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 533
 534   # Connect via subref
 535   ->connect_info([ sub { DBI->connect(...) } ]);
 536
 537   # Connect via subref in hashref
 538   ->connect_info([{
 539     dbh_maker => sub { DBI->connect(...) },
 540     on_connect_do => 'alter session ...',
 541   }]);
 542
 543   # A bit more complicated
 544   ->connect_info(
 545     [
 546       'dbi:Pg:dbname=foo',
 547       'postgres',
 548       'my_pg_password',
 549       { AutoCommit => 1 },
 550       { quote_char => q{"} },
 551     ]
 552   );
 553
 554   # Equivalent to the previous example
 555   ->connect_info(
 556     [
 557       'dbi:Pg:dbname=foo',
 558       'postgres',
 559       'my_pg_password',
 560       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 561     ]
 562   );
 563
 564   # Same, but with hashref as argument
 565   # See parse_connect_info for explanation
 566   ->connect_info(
 567     [{
 568       dsn         => 'dbi:Pg:dbname=foo',
 569       user        => 'postgres',
 570       password    => 'my_pg_password',
 571       AutoCommit  => 1,
 572       quote_char  => q{"},
 573       name_sep    => q{.},
 574     }]
 575   );
 576
 577   # Subref + DBIx::Class-specific connection options
 578   ->connect_info(
 579     [
 580       sub { DBI->connect(...) },
 581       {
 582           quote_char => q{`},
 583           name_sep => q{@},
 584           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 585           disable_sth_caching => 1,
 586       },
 587     ]
 588   );
 589
 590
 591
 592 =cut
 593
 594 sub connect_info {
 595   my ($self, $info) = @_;
 596
 597   return $self->_connect_info if !$info;
 598
 599   $self->_connect_info($info); # copy for _connect_info
 600
 601   $info = $self->_normalize_connect_info($info)
 602     if ref $info eq 'ARRAY';
 603
 604   for my $storage_opt (keys %{ $info->{storage_options} }) {
 605     my $value = $info->{storage_options}{$storage_opt};
 606
 607     $self->$storage_opt($value);
 608   }
 609
 610   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 611   #  the new set of options
 612   $self->_sql_maker(undef);
 613   $self->_sql_maker_opts({});
 614
 615   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 616     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 617
 618     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 619   }
 620
 621   my %attrs = (
 622     %{ $self->_default_dbi_connect_attributes || {} },
 623     %{ $info->{attributes} || {} },
 624   );
 625
 626   my @args = @{ $info->{arguments} };
 627
 628   if (keys %attrs and ref $args[0] ne 'CODE') {
 629     carp
 630         'You provided explicit AutoCommit => 0 in your connection_info. '
 631       . 'This is almost universally a bad idea (see the footnotes of '
 632       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 633       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 634       . 'this warning.'
 635       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 636
 637     push @args, \%attrs if keys %attrs;
 638   }
 639   $self->_dbi_connect_info(\@args);
 640
 641   # FIXME - dirty:
 642   # save attributes them in a separate accessor so they are always
 643   # introspectable, even in case of a CODE $dbhmaker
 644   $self->_dbic_connect_attributes (\%attrs);
 645
 646   return $self->_connect_info;
 647 }
 648
 649 sub _normalize_connect_info {
 650   my ($self, $info_arg) = @_;
 651   my %info;
 652
 653   my @args = @$info_arg;  # take a shallow copy for further mutilation
 654
 655   # combine/pre-parse arguments depending on invocation style
 656
 657   my %attrs;
 658   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 659     %attrs = %{ $args[1] || {} };
 660     @args = $args[0];
 661   }
 662   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 663     %attrs = %{$args[0]};
 664     @args = ();
 665     if (my $code = delete $attrs{dbh_maker}) {
 666       @args = $code;
 667
 668       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 669       if (@ignored) {
 670         carp sprintf (
 671             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 672           . "to the result of 'dbh_maker'",
 673
 674           join (', ', map { "'$_'" } (@ignored) ),
 675         );
 676       }
 677     }
 678     else {
 679       @args = delete @attrs{qw/dsn user password/};
 680     }
 681   }
 682   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 683     %attrs = (
 684       % { $args[3] || {} },
 685       % { $args[4] || {} },
 686     );
 687     @args = @args[0,1,2];
 688   }
 689
 690   $info{arguments} = \@args;
 691
 692   my @storage_opts = grep exists $attrs{$_},
 693     @storage_options, 'cursor_class';
 694
 695   @{ $info{storage_options} }{@storage_opts} =
 696     delete @attrs{@storage_opts} if @storage_opts;
 697
 698   my @sql_maker_opts = grep exists $attrs{$_},
 699     qw/limit_dialect quote_char name_sep quote_names/;
 700
 701   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 702     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 703
 704   $info{attributes} = \%attrs if %attrs;
 705
 706   return \%info;
 707 }
 708
 709 sub _default_dbi_connect_attributes () {
 710   +{
 711     AutoCommit => 1,
 712     PrintError => 0,
 713     RaiseError => 1,
 714     ShowErrorStatement => 1,
 715   };
 716 }
 717
 718 =head2 on_connect_do
 719
 720 This method is deprecated in favour of setting via L</connect_info>.
 721
 722 =cut
 723
 724 =head2 on_disconnect_do
 725
 726 This method is deprecated in favour of setting via L</connect_info>.
 727
 728 =cut
 729
 730 sub _parse_connect_do {
 731   my ($self, $type) = @_;
 732
 733   my $val = $self->$type;
 734   return () if not defined $val;
 735
 736   my @res;
 737
 738   if (not ref($val)) {
 739     push @res, [ 'do_sql', $val ];
 740   } elsif (ref($val) eq 'CODE') {
 741     push @res, $val;
 742   } elsif (ref($val) eq 'ARRAY') {
 743     push @res, map { [ 'do_sql', $_ ] } @$val;
 744   } else {
 745     $self->throw_exception("Invalid type for $type: ".ref($val));
 746   }
 747
 748   return \@res;
 749 }
 750
 751 =head2 dbh_do
 752
 753 Arguments: ($subref | $method_name), @extra_coderef_args?
 754
 755 Execute the given $subref or $method_name using the new exception-based
 756 connection management.
 757
 758 The first two arguments will be the storage object that C<dbh_do> was called
 759 on and a database handle to use.  Any additional arguments will be passed
 760 verbatim to the called subref as arguments 2 and onwards.
 761
 762 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 763 exception handling and reconnection (or failover in future subclasses).
 764
 765 Your subref should have no side-effects outside of the database, as
 766 there is the potential for your subref to be partially double-executed
 767 if the database connection was stale/dysfunctional.
 768
 769 Example:
 770
 771   my @stuff = $schema->storage->dbh_do(
 772     sub {
 773       my ($storage, $dbh, @cols) = @_;
 774       my $cols = join(q{, }, @cols);
 775       $dbh->selectrow_array("SELECT $cols FROM foo");
 776     },
 777     @column_list
 778   );
 779
 780 =cut
 781
 782 sub dbh_do {
 783   my $self = shift;
 784   my $run_target = shift;
 785
 786   # short circuit when we know there is no need for a runner
 787   #
 788   # FIXME - asumption may be wrong
 789   # the rationale for the txn_depth check is that if this block is a part
 790   # of a larger transaction, everything up to that point is screwed anyway
 791   return $self->$run_target($self->_get_dbh, @_)
 792     if $self->{_in_do_block} or $self->transaction_depth;
 793
 794   # take a ref instead of a copy, to preserve @_ aliasing
 795   # semantics within the coderef, but only if needed
 796   # (pseudoforking doesn't like this trick much)
 797   my $args = @_ ? \@_ : [];
 798
 799   DBIx::Class::Storage::BlockRunner->new(
 800     storage => $self,
 801     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 802     wrap_txn => 0,
 803     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 804   )->run;
 805 }
 806
 807 sub txn_do {
 808   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 809   shift->next::method(@_);
 810 }
 811
 812 =head2 disconnect
 813
 814 Our C<disconnect> method also performs a rollback first if the
 815 database is not in C<AutoCommit> mode.
 816
 817 =cut
 818
 819 sub disconnect {
 820   my ($self) = @_;
 821
 822   if( $self->_dbh ) {
 823     my @actions;
 824
 825     push @actions, ( $self->on_disconnect_call || () );
 826     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 827
 828     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 829
 830     # stops the "implicit rollback on disconnect" warning
 831     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 832
 833     %{ $self->_dbh->{CachedKids} } = ();
 834     $self->_dbh->disconnect;
 835     $self->_dbh(undef);
 836   }
 837 }
 838
 839 =head2 with_deferred_fk_checks
 840
 841 =over 4
 842
 843 =item Arguments: C<$coderef>
 844
 845 =item Return Value: The return value of $coderef
 846
 847 =back
 848
 849 Storage specific method to run the code ref with FK checks deferred or
 850 in MySQL's case disabled entirely.
 851
 852 =cut
 853
 854 # Storage subclasses should override this
 855 sub with_deferred_fk_checks {
 856   my ($self, $sub) = @_;
 857   $sub->();
 858 }
 859
 860 =head2 connected
 861
 862 =over
 863
 864 =item Arguments: none
 865
 866 =item Return Value: 1|0
 867
 868 =back
 869
 870 Verifies that the current database handle is active and ready to execute
 871 an SQL statement (e.g. the connection did not get stale, server is still
 872 answering, etc.) This method is used internally by L</dbh>.
 873
 874 =cut
 875
 876 sub connected {
 877   my $self = shift;
 878   return 0 unless $self->_seems_connected;
 879
 880   #be on the safe side
 881   local $self->_dbh->{RaiseError} = 1;
 882
 883   return $self->_ping;
 884 }
 885
 886 sub _seems_connected {
 887   my $self = shift;
 888
 889   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 890
 891   my $dbh = $self->_dbh
 892     or return 0;
 893
 894   return $dbh->FETCH('Active');
 895 }
 896
 897 sub _ping {
 898   my $self = shift;
 899
 900   my $dbh = $self->_dbh or return 0;
 901
 902   return $dbh->ping;
 903 }
 904
 905 sub ensure_connected {
 906   my ($self) = @_;
 907
 908   unless ($self->connected) {
 909     $self->_populate_dbh;
 910   }
 911 }
 912
 913 =head2 dbh
 914
 915 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 916 is guaranteed to be healthy by implicitly calling L</connected>, and if
 917 necessary performing a reconnection before returning. Keep in mind that this
 918 is very B<expensive> on some database engines. Consider using L</dbh_do>
 919 instead.
 920
 921 =cut
 922
 923 sub dbh {
 924   my ($self) = @_;
 925
 926   if (not $self->_dbh) {
 927     $self->_populate_dbh;
 928   } else {
 929     $self->ensure_connected;
 930   }
 931   return $self->_dbh;
 932 }
 933
 934 # this is the internal "get dbh or connect (don't check)" method
 935 sub _get_dbh {
 936   my $self = shift;
 937   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 938   $self->_populate_dbh unless $self->_dbh;
 939   return $self->_dbh;
 940 }
 941
 942 sub sql_maker {
 943   my ($self) = @_;
 944   unless ($self->_sql_maker) {
 945     my $sql_maker_class = $self->sql_maker_class;
 946
 947     my %opts = %{$self->_sql_maker_opts||{}};
 948     my $dialect =
 949       $opts{limit_dialect}
 950         ||
 951       $self->sql_limit_dialect
 952         ||
 953       do {
 954         my $s_class = (ref $self) || $self;
 955         carp (
 956           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 957         . 'have not supplied an explicit limit_dialect in your connection_info. '
 958         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 959         . 'databases but can be (and often is) painfully slow. '
 960         . "Please file an RT ticket against '$s_class' ."
 961         );
 962
 963         'GenericSubQ';
 964       }
 965     ;
 966
 967     my ($quote_char, $name_sep);
 968
 969     if ($opts{quote_names}) {
 970       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 971         my $s_class = (ref $self) || $self;
 972         carp (
 973           "You requested 'quote_names' but your storage class ($s_class) does "
 974         . 'not explicitly define a default sql_quote_char and you have not '
 975         . 'supplied a quote_char as part of your connection_info. DBIC will '
 976         .q{default to the ANSI SQL standard quote '"', which works most of }
 977         . "the time. Please file an RT ticket against '$s_class'."
 978         );
 979
 980         '"'; # RV
 981       };
 982
 983       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 984     }
 985
 986     $self->_sql_maker($sql_maker_class->new(
 987       bindtype=>'columns',
 988       array_datatypes => 1,
 989       limit_dialect => $dialect,
 990       ($quote_char ? (quote_char => $quote_char) : ()),
 991       name_sep => ($name_sep || '.'),
 992       %opts,
 993     ));
 994   }
 995   return $self->_sql_maker;
 996 }
 997
 998 # nothing to do by default
 999 sub _rebless {}
1000 sub _init {}
1001
1002 sub _populate_dbh {
1003   my ($self) = @_;
1004
1005   my @info = @{$self->_dbi_connect_info || []};
1006   $self->_dbh(undef); # in case ->connected failed we might get sent here
1007   $self->_dbh_details({}); # reset everything we know
1008
1009   $self->_dbh($self->_connect(@info));
1010
1011   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1012
1013   $self->_determine_driver;
1014
1015   # Always set the transaction depth on connect, since
1016   #  there is no transaction in progress by definition
1017   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1018
1019   $self->_run_connection_actions unless $self->{_in_determine_driver};
1020 }
1021
1022 sub _run_connection_actions {
1023   my $self = shift;
1024   my @actions;
1025
1026   push @actions, ( $self->on_connect_call || () );
1027   push @actions, $self->_parse_connect_do ('on_connect_do');
1028
1029   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1030 }
1031
1032
1033
1034 sub set_use_dbms_capability {
1035   $_[0]->set_inherited ($_[1], $_[2]);
1036 }
1037
1038 sub get_use_dbms_capability {
1039   my ($self, $capname) = @_;
1040
1041   my $use = $self->get_inherited ($capname);
1042   return defined $use
1043     ? $use
1044     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1045   ;
1046 }
1047
1048 sub set_dbms_capability {
1049   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1050 }
1051
1052 sub get_dbms_capability {
1053   my ($self, $capname) = @_;
1054
1055   my $cap = $self->_dbh_details->{capability}{$capname};
1056
1057   unless (defined $cap) {
1058     if (my $meth = $self->can ("_determine$capname")) {
1059       $cap = $self->$meth ? 1 : 0;
1060     }
1061     else {
1062       $cap = 0;
1063     }
1064
1065     $self->set_dbms_capability ($capname, $cap);
1066   }
1067
1068   return $cap;
1069 }
1070
1071 sub _server_info {
1072   my $self = shift;
1073
1074   my $info;
1075   unless ($info = $self->_dbh_details->{info}) {
1076
1077     $info = {};
1078
1079     my $server_version = try {
1080       $self->_get_server_version
1081     } catch {
1082       # driver determination *may* use this codepath
1083       # in which case we must rethrow
1084       $self->throw_exception($_) if $self->{_in_determine_driver};
1085
1086       # $server_version on failure
1087       undef;
1088     };
1089
1090     if (defined $server_version) {
1091       $info->{dbms_version} = $server_version;
1092
1093       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1094       my @verparts = split (/\./, $numeric_version);
1095       if (
1096         @verparts
1097           &&
1098         $verparts[0] <= 999
1099       ) {
1100         # consider only up to 3 version parts, iff not more than 3 digits
1101         my @use_parts;
1102         while (@verparts && @use_parts < 3) {
1103           my $p = shift @verparts;
1104           last if $p > 999;
1105           push @use_parts, $p;
1106         }
1107         push @use_parts, 0 while @use_parts < 3;
1108
1109         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1110       }
1111     }
1112
1113     $self->_dbh_details->{info} = $info;
1114   }
1115
1116   return $info;
1117 }
1118
1119 sub _get_server_version {
1120   shift->_dbh_get_info('SQL_DBMS_VER');
1121 }
1122
1123 sub _dbh_get_info {
1124   my ($self, $info) = @_;
1125
1126   if ($info =~ /[^0-9]/) {
1127     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1128     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1129       unless defined $info;
1130   }
1131
1132   return $self->_get_dbh->get_info($info);
1133 }
1134
1135 sub _describe_connection {
1136   require DBI::Const::GetInfoReturn;
1137
1138   my $self = shift;
1139   $self->ensure_connected;
1140
1141   my $res = {
1142     DBIC_DSN => $self->_dbi_connect_info->[0],
1143     DBI_VER => DBI->VERSION,
1144     DBIC_VER => DBIx::Class->VERSION,
1145     DBIC_DRIVER => ref $self,
1146   };
1147
1148   for my $inf (
1149     #keys %DBI::Const::GetInfoType::GetInfoType,
1150     qw/
1151       SQL_CURSOR_COMMIT_BEHAVIOR
1152       SQL_CURSOR_ROLLBACK_BEHAVIOR
1153       SQL_CURSOR_SENSITIVITY
1154       SQL_DATA_SOURCE_NAME
1155       SQL_DBMS_NAME
1156       SQL_DBMS_VER
1157       SQL_DEFAULT_TXN_ISOLATION
1158       SQL_DM_VER
1159       SQL_DRIVER_NAME
1160       SQL_DRIVER_ODBC_VER
1161       SQL_DRIVER_VER
1162       SQL_EXPRESSIONS_IN_ORDERBY
1163       SQL_GROUP_BY
1164       SQL_IDENTIFIER_CASE
1165       SQL_IDENTIFIER_QUOTE_CHAR
1166       SQL_MAX_CATALOG_NAME_LEN
1167       SQL_MAX_COLUMN_NAME_LEN
1168       SQL_MAX_IDENTIFIER_LEN
1169       SQL_MAX_TABLE_NAME_LEN
1170       SQL_MULTIPLE_ACTIVE_TXN
1171       SQL_MULT_RESULT_SETS
1172       SQL_NEED_LONG_DATA_LEN
1173       SQL_NON_NULLABLE_COLUMNS
1174       SQL_ODBC_VER
1175       SQL_QUALIFIER_NAME_SEPARATOR
1176       SQL_QUOTED_IDENTIFIER_CASE
1177       SQL_TXN_CAPABLE
1178       SQL_TXN_ISOLATION_OPTION
1179     /
1180   ) {
1181     # some drivers barf on things they do not know about instead
1182     # of returning undef
1183     my $v = try { $self->_dbh_get_info($inf) };
1184     next unless defined $v;
1185
1186     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1187     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1188     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1189   }
1190
1191   $res;
1192 }
1193
1194 sub _determine_driver {
1195   my ($self) = @_;
1196
1197   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1198     my $started_connected = 0;
1199     local $self->{_in_determine_driver} = 1;
1200
1201     if (ref($self) eq __PACKAGE__) {
1202       my $driver;
1203       if ($self->_dbh) { # we are connected
1204         $driver = $self->_dbh->{Driver}{Name};
1205         $started_connected = 1;
1206       }
1207       else {
1208         # if connect_info is a CODEREF, we have no choice but to connect
1209         if (ref $self->_dbi_connect_info->[0] &&
1210             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1211           $self->_populate_dbh;
1212           $driver = $self->_dbh->{Driver}{Name};
1213         }
1214         else {
1215           # try to use dsn to not require being connected, the driver may still
1216           # force a connection in _rebless to determine version
1217           # (dsn may not be supplied at all if all we do is make a mock-schema)
1218           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1219           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1220           $driver ||= $ENV{DBI_DRIVER};
1221         }
1222       }
1223
1224       if ($driver) {
1225         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1226         if ($self->load_optional_class($storage_class)) {
1227           mro::set_mro($storage_class, 'c3');
1228           bless $self, $storage_class;
1229           $self->_rebless();
1230         }
1231         else {
1232           $self->_warn_undetermined_driver(
1233             'This version of DBIC does not yet seem to supply a driver for '
1234           . "your particular RDBMS and/or connection method ('$driver')."
1235           );
1236         }
1237       }
1238       else {
1239         $self->_warn_undetermined_driver(
1240           'Unable to extract a driver name from connect info - this '
1241         . 'should not have happened.'
1242         );
1243       }
1244     }
1245
1246     $self->_driver_determined(1);
1247
1248     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1249
1250     if ($self->can('source_bind_attributes')) {
1251       $self->throw_exception(
1252         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1253       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1254       . 'If you are not sure how to proceed please contact the development team via '
1255       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1256       );
1257     }
1258
1259     $self->_init; # run driver-specific initializations
1260
1261     $self->_run_connection_actions
1262         if !$started_connected && defined $self->_dbh;
1263   }
1264 }
1265
1266 sub _determine_connector_driver {
1267   my ($self, $conn) = @_;
1268
1269   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1270
1271   if (not $dbtype) {
1272     $self->_warn_undetermined_driver(
1273       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1274     . "$conn connector - this should not have happened."
1275     );
1276     return;
1277   }
1278
1279   $dbtype =~ s/\W/_/gi;
1280
1281   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1282   return if $self->isa($subclass);
1283
1284   if ($self->load_optional_class($subclass)) {
1285     bless $self, $subclass;
1286     $self->_rebless;
1287   }
1288   else {
1289     $self->_warn_undetermined_driver(
1290       'This version of DBIC does not yet seem to supply a driver for '
1291     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1292     );
1293   }
1294 }
1295
1296 sub _warn_undetermined_driver {
1297   my ($self, $msg) = @_;
1298
1299   require Data::Dumper::Concise;
1300
1301   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1302   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1303   . "does not go away, file a bugreport including the following info:\n"
1304   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1305   );
1306 }
1307
1308 sub _do_connection_actions {
1309   my $self          = shift;
1310   my $method_prefix = shift;
1311   my $call          = shift;
1312
1313   if (not ref($call)) {
1314     my $method = $method_prefix . $call;
1315     $self->$method(@_);
1316   } elsif (ref($call) eq 'CODE') {
1317     $self->$call(@_);
1318   } elsif (ref($call) eq 'ARRAY') {
1319     if (ref($call->[0]) ne 'ARRAY') {
1320       $self->_do_connection_actions($method_prefix, $_) for @$call;
1321     } else {
1322       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1323     }
1324   } else {
1325     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1326   }
1327
1328   return $self;
1329 }
1330
1331 sub connect_call_do_sql {
1332   my $self = shift;
1333   $self->_do_query(@_);
1334 }
1335
1336 sub disconnect_call_do_sql {
1337   my $self = shift;
1338   $self->_do_query(@_);
1339 }
1340
1341 # override in db-specific backend when necessary
1342 sub connect_call_datetime_setup { 1 }
1343
1344 sub _do_query {
1345   my ($self, $action) = @_;
1346
1347   if (ref $action eq 'CODE') {
1348     $action = $action->($self);
1349     $self->_do_query($_) foreach @$action;
1350   }
1351   else {
1352     # Most debuggers expect ($sql, @bind), so we need to exclude
1353     # the attribute hash which is the second argument to $dbh->do
1354     # furthermore the bind values are usually to be presented
1355     # as named arrayref pairs, so wrap those here too
1356     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1357     my $sql = shift @do_args;
1358     my $attrs = shift @do_args;
1359     my @bind = map { [ undef, $_ ] } @do_args;
1360
1361     $self->dbh_do(sub {
1362       $_[0]->_query_start($sql, \@bind);
1363       $_[1]->do($sql, $attrs, @do_args);
1364       $_[0]->_query_end($sql, \@bind);
1365     });
1366   }
1367
1368   return $self;
1369 }
1370
1371 sub _connect {
1372   my ($self, @info) = @_;
1373
1374   $self->throw_exception("You failed to provide any connection info")
1375     if !@info;
1376
1377   my ($old_connect_via, $dbh);
1378
1379   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1380
1381   try {
1382     if(ref $info[0] eq 'CODE') {
1383       $dbh = $info[0]->();
1384     }
1385     else {
1386       require DBI;
1387       $dbh = DBI->connect(@info);
1388     }
1389
1390     die $DBI::errstr unless $dbh;
1391
1392     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1393       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1394       . 'not continue',
1395       ref $info[0] eq 'CODE'
1396         ? "Connection coderef $info[0] returned a"
1397         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1398     ) unless $dbh->FETCH('Active');
1399
1400     # sanity checks unless asked otherwise
1401     unless ($self->unsafe) {
1402
1403       $self->throw_exception(
1404         'Refusing clobbering of {HandleError} installed on externally supplied '
1405        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1406       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1407
1408       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1409       # request, or an external handle. Complain and set anyway
1410       unless ($dbh->{RaiseError}) {
1411         carp( ref $info[0] eq 'CODE'
1412
1413           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1414            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1415            .'attribute has been supplied'
1416
1417           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1418            .'unsafe => 1. Toggling RaiseError back to true'
1419         );
1420
1421         $dbh->{RaiseError} = 1;
1422       }
1423
1424       # this odd anonymous coderef dereference is in fact really
1425       # necessary to avoid the unwanted effect described in perl5
1426       # RT#75792
1427       sub {
1428         my $weak_self = $_[0];
1429         weaken $weak_self;
1430
1431         # the coderef is blessed so we can distinguish it from externally
1432         # supplied handles (which must be preserved)
1433         $_[1]->{HandleError} = bless sub {
1434           if ($weak_self) {
1435             $weak_self->throw_exception("DBI Exception: $_[0]");
1436           }
1437           else {
1438             # the handler may be invoked by something totally out of
1439             # the scope of DBIC
1440             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1441           }
1442         }, '__DBIC__DBH__ERROR__HANDLER__';
1443       }->($self, $dbh);
1444     }
1445   }
1446   catch {
1447     $self->throw_exception("DBI Connection failed: $_")
1448   };
1449
1450   $self->_dbh_autocommit($dbh->{AutoCommit});
1451   $dbh;
1452 }
1453
1454 sub txn_begin {
1455   my $self = shift;
1456
1457   # this means we have not yet connected and do not know the AC status
1458   # (e.g. coderef $dbh), need a full-fledged connection check
1459   if (! defined $self->_dbh_autocommit) {
1460     $self->ensure_connected;
1461   }
1462   # Otherwise simply connect or re-connect on pid changes
1463   else {
1464     $self->_get_dbh;
1465   }
1466
1467   $self->next::method(@_);
1468 }
1469
1470 sub _exec_txn_begin {
1471   my $self = shift;
1472
1473   # if the user is utilizing txn_do - good for him, otherwise we need to
1474   # ensure that the $dbh is healthy on BEGIN.
1475   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1476   # will be replaced by a failure of begin_work itself (which will be
1477   # then retried on reconnect)
1478   if ($self->{_in_do_block}) {
1479     $self->_dbh->begin_work;
1480   } else {
1481     $self->dbh_do(sub { $_[1]->begin_work });
1482   }
1483 }
1484
1485 sub txn_commit {
1486   my $self = shift;
1487
1488   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1489   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1490     unless $self->_dbh;
1491
1492   # esoteric case for folks using external $dbh handles
1493   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1494     carp "Storage transaction_depth 0 does not match "
1495         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1496     $self->transaction_depth(1);
1497   }
1498
1499   $self->next::method(@_);
1500
1501   # if AutoCommit is disabled txn_depth never goes to 0
1502   # as a new txn is started immediately on commit
1503   $self->transaction_depth(1) if (
1504     !$self->transaction_depth
1505       and
1506     defined $self->_dbh_autocommit
1507       and
1508     ! $self->_dbh_autocommit
1509   );
1510 }
1511
1512 sub _exec_txn_commit {
1513   shift->_dbh->commit;
1514 }
1515
1516 sub txn_rollback {
1517   my $self = shift;
1518
1519   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1520   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1521     unless $self->_dbh;
1522
1523   # esoteric case for folks using external $dbh handles
1524   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1525     carp "Storage transaction_depth 0 does not match "
1526         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1527     $self->transaction_depth(1);
1528   }
1529
1530   $self->next::method(@_);
1531
1532   # if AutoCommit is disabled txn_depth never goes to 0
1533   # as a new txn is started immediately on commit
1534   $self->transaction_depth(1) if (
1535     !$self->transaction_depth
1536       and
1537     defined $self->_dbh_autocommit
1538       and
1539     ! $self->_dbh_autocommit
1540   );
1541 }
1542
1543 sub _exec_txn_rollback {
1544   shift->_dbh->rollback;
1545 }
1546
1547 # generate some identical methods
1548 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1549   no strict qw/refs/;
1550   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1551     my $self = shift;
1552     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1553     $self->throw_exception("Unable to $meth() on a disconnected storage")
1554       unless $self->_dbh;
1555     $self->next::method(@_);
1556   };
1557 }
1558
1559 # This used to be the top-half of _execute.  It was split out to make it
1560 #  easier to override in NoBindVars without duping the rest.  It takes up
1561 #  all of _execute's args, and emits $sql, @bind.
1562 sub _prep_for_execute {
1563   #my ($self, $op, $ident, $args) = @_;
1564   return shift->_gen_sql_bind(@_)
1565 }
1566
1567 sub _gen_sql_bind {
1568   my ($self, $op, $ident, $args) = @_;
1569
1570   my ($colinfos, $from);
1571   if ( blessed($ident) ) {
1572     $from = $ident->from;
1573     $colinfos = $ident->columns_info;
1574   }
1575
1576   my ($sql, @bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1577
1578   if (
1579     ! $ENV{DBIC_DT_SEARCH_OK}
1580       and
1581     $op eq 'select'
1582       and
1583     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1584   ) {
1585     carp_unique 'DateTime objects passed to search() are not supported '
1586       . 'properly (InflateColumn::DateTime formats and settings are not '
1587       . 'respected.) See "Formatting DateTime objects in queries" in '
1588       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1589       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1590   }
1591
1592   return( $sql, $self->_resolve_bindattrs(
1593     $ident, [ @{$args->[2]{bind}||[]}, @bind ], $colinfos
1594   ));
1595 }
1596
1597 sub _resolve_bindattrs {
1598   my ($self, $ident, $bind, $colinfos) = @_;
1599
1600   $colinfos ||= {};
1601
1602   my $resolve_bindinfo = sub {
1603     #my $infohash = shift;
1604
1605     %$colinfos = %{ $self->_resolve_column_info($ident) }
1606       unless keys %$colinfos;
1607
1608     my $ret;
1609     if (my $col = $_[0]->{dbic_colname}) {
1610       $ret = { %{$_[0]} };
1611
1612       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1613         if $colinfos->{$col}{data_type};
1614
1615       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1616         if $colinfos->{$col}{size};
1617     }
1618
1619     $ret || $_[0];
1620   };
1621
1622   return [ map {
1623     if (ref $_ ne 'ARRAY') {
1624       [{}, $_]
1625     }
1626     elsif (! defined $_->[0]) {
1627       [{}, $_->[1]]
1628     }
1629     elsif (ref $_->[0] eq 'HASH') {
1630       [
1631         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1632         $_->[1]
1633       ]
1634     }
1635     elsif (ref $_->[0] eq 'SCALAR') {
1636       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1637     }
1638     else {
1639       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1640     }
1641   } @$bind ];
1642 }
1643
1644 sub _format_for_trace {
1645   #my ($self, $bind) = @_;
1646
1647   ### Turn @bind from something like this:
1648   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1649   ### to this:
1650   ###   ( "'1'", "'3'" )
1651
1652   map {
1653     defined( $_ && $_->[1] )
1654       ? qq{'$_->[1]'}
1655       : q{NULL}
1656   } @{$_[1] || []};
1657 }
1658
1659 sub _query_start {
1660   my ( $self, $sql, $bind ) = @_;
1661
1662   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1663     if $self->debug;
1664 }
1665
1666 sub _query_end {
1667   my ( $self, $sql, $bind ) = @_;
1668
1669   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1670     if $self->debug;
1671 }
1672
1673 sub _dbi_attrs_for_bind {
1674   my ($self, $ident, $bind) = @_;
1675
1676   my @attrs;
1677
1678   for (map { $_->[0] } @$bind) {
1679     push @attrs, do {
1680       if (exists $_->{dbd_attrs}) {
1681         $_->{dbd_attrs}
1682       }
1683       elsif($_->{sqlt_datatype}) {
1684         # cache the result in the dbh_details hash, as it can not change unless
1685         # we connect to something else
1686         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1687         if (not exists $cache->{$_->{sqlt_datatype}}) {
1688           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1689         }
1690         $cache->{$_->{sqlt_datatype}};
1691       }
1692       else {
1693         undef;  # always push something at this position
1694       }
1695     }
1696   }
1697
1698   return \@attrs;
1699 }
1700
1701 sub _execute {
1702   my ($self, $op, $ident, @args) = @_;
1703
1704   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1705
1706   # not even a PID check - we do not care about the state of the _dbh.
1707   # All we need is to get the appropriate drivers loaded if they aren't
1708   # already so that the assumption in ad7c50fc26e holds
1709   $self->_populate_dbh unless $self->_dbh;
1710
1711   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1712     $sql,
1713     $bind,
1714     $self->_dbi_attrs_for_bind($ident, $bind),
1715   );
1716 }
1717
1718 sub _dbh_execute {
1719   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1720
1721   $self->_query_start( $sql, $bind );
1722
1723   my $sth = $self->_bind_sth_params(
1724     $self->_prepare_sth($dbh, $sql),
1725     $bind,
1726     $bind_attrs,
1727   );
1728
1729   # Can this fail without throwing an exception anyways???
1730   my $rv = $sth->execute();
1731   $self->throw_exception(
1732     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1733   ) if !$rv;
1734
1735   $self->_query_end( $sql, $bind );
1736
1737   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1738 }
1739
1740 sub _prepare_sth {
1741   my ($self, $dbh, $sql) = @_;
1742
1743   # 3 is the if_active parameter which avoids active sth re-use
1744   my $sth = $self->disable_sth_caching
1745     ? $dbh->prepare($sql)
1746     : $dbh->prepare_cached($sql, {}, 3);
1747
1748   # XXX You would think RaiseError would make this impossible,
1749   #  but apparently that's not true :(
1750   $self->throw_exception(
1751     $dbh->errstr
1752       ||
1753     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1754             .'an exception and/or setting $dbh->errstr',
1755       length ($sql) > 20
1756         ? substr($sql, 0, 20) . '...'
1757         : $sql
1758       ,
1759       'DBD::' . $dbh->{Driver}{Name},
1760     )
1761   ) if !$sth;
1762
1763   $sth;
1764 }
1765
1766 sub _bind_sth_params {
1767   my ($self, $sth, $bind, $bind_attrs) = @_;
1768
1769   for my $i (0 .. $#$bind) {
1770     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1771       $sth->bind_param_inout(
1772         $i + 1, # bind params counts are 1-based
1773         $bind->[$i][1],
1774         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1775         $bind_attrs->[$i],
1776       );
1777     }
1778     else {
1779       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1780       # confirm with dbi-dev whether explicit stringification is needed
1781       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1782         ? "$bind->[$i][1]"
1783         : $bind->[$i][1]
1784       ;
1785       $sth->bind_param(
1786         $i + 1,
1787         $v,
1788         $bind_attrs->[$i],
1789       );
1790     }
1791   }
1792
1793   $sth;
1794 }
1795
1796 sub _prefetch_autovalues {
1797   my ($self, $source, $colinfo, $to_insert) = @_;
1798
1799   my %values;
1800   for my $col (keys %$colinfo) {
1801     if (
1802       $colinfo->{$col}{auto_nextval}
1803         and
1804       (
1805         ! exists $to_insert->{$col}
1806           or
1807         ref $to_insert->{$col} eq 'SCALAR'
1808           or
1809         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1810       )
1811     ) {
1812       $values{$col} = $self->_sequence_fetch(
1813         'NEXTVAL',
1814         ( $colinfo->{$col}{sequence} ||=
1815             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1816         ),
1817       );
1818     }
1819   }
1820
1821   \%values;
1822 }
1823
1824 sub insert {
1825   my ($self, $source, $to_insert) = @_;
1826
1827   my $col_infos = $source->columns_info;
1828
1829   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1830
1831   # fuse the values, but keep a separate list of prefetched_values so that
1832   # they can be fused once again with the final return
1833   $to_insert = { %$to_insert, %$prefetched_values };
1834
1835   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1836   # Investigate what does it take to s/defined/exists/
1837   my %pcols = map { $_ => 1 } $source->primary_columns;
1838   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1839   for my $col ($source->columns) {
1840     if ($col_infos->{$col}{is_auto_increment}) {
1841       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1842       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1843     }
1844
1845     # nothing to retrieve when explicit values are supplied
1846     next if (defined $to_insert->{$col} and ! (
1847       ref $to_insert->{$col} eq 'SCALAR'
1848         or
1849       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1850     ));
1851
1852     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1853     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1854       $pcols{$col}
1855         or
1856       $col_infos->{$col}{retrieve_on_insert}
1857     );
1858   };
1859
1860   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1861   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1862
1863   my ($sqla_opts, @ir_container);
1864   if (%retrieve_cols and $self->_use_insert_returning) {
1865     $sqla_opts->{returning_container} = \@ir_container
1866       if $self->_use_insert_returning_bound;
1867
1868     $sqla_opts->{returning} = [
1869       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1870     ];
1871   }
1872
1873   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1874
1875   my %returned_cols = %$to_insert;
1876   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1877     @ir_container = try {
1878       local $SIG{__WARN__} = sub {};
1879       my @r = $sth->fetchrow_array;
1880       $sth->finish;
1881       @r;
1882     } unless @ir_container;
1883
1884     @returned_cols{@$retlist} = @ir_container if @ir_container;
1885   }
1886   else {
1887     # pull in PK if needed and then everything else
1888     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1889
1890       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1891         unless $self->can('last_insert_id');
1892
1893       my @pri_values = $self->last_insert_id($source, @missing_pri);
1894
1895       $self->throw_exception( "Can't get last insert id" )
1896         unless (@pri_values == @missing_pri);
1897
1898       @returned_cols{@missing_pri} = @pri_values;
1899       delete @retrieve_cols{@missing_pri};
1900     }
1901
1902     # if there is more left to pull
1903     if (%retrieve_cols) {
1904       $self->throw_exception(
1905         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1906       ) unless %pcols;
1907
1908       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1909
1910       my $cur = DBIx::Class::ResultSet->new($source, {
1911         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1912         select => \@left_to_fetch,
1913       })->cursor;
1914
1915       @returned_cols{@left_to_fetch} = $cur->next;
1916
1917       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1918         if scalar $cur->next;
1919     }
1920   }
1921
1922   return { %$prefetched_values, %returned_cols };
1923 }
1924
1925 sub insert_bulk {
1926   my ($self, $source, $cols, $data) = @_;
1927
1928   my @col_range = (0..$#$cols);
1929
1930   # FIXME SUBOPTIMAL - most likely this is not necessary at all
1931   # confirm with dbi-dev whether explicit stringification is needed
1932   #
1933   # forcibly stringify whatever is stringifiable
1934   # ResultSet::populate() hands us a copy - safe to mangle
1935   for my $r (0 .. $#$data) {
1936     for my $c (0 .. $#{$data->[$r]}) {
1937       $data->[$r][$c] = "$data->[$r][$c]"
1938         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1939     }
1940   }
1941
1942   my $colinfos = $source->columns_info($cols);
1943
1944   local $self->{_autoinc_supplied_for_op} =
1945     (first { $_->{is_auto_increment} } values %$colinfos)
1946       ? 1
1947       : 0
1948   ;
1949
1950   # get a slice type index based on first row of data
1951   # a "column" in this context may refer to more than one bind value
1952   # e.g. \[ '?, ?', [...], [...] ]
1953   #
1954   # construct the value type index - a description of values types for every
1955   # per-column slice of $data:
1956   #
1957   # nonexistent - nonbind literal
1958   # 0 - regular value
1959   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1960   #
1961   # also construct the column hash to pass to the SQL generator. For plain
1962   # (non literal) values - convert the members of the first row into a
1963   # literal+bind combo, with extra positional info in the bind attr hashref.
1964   # This will allow us to match the order properly, and is so contrived
1965   # because a user-supplied literal/bind (or something else specific to a
1966   # resultsource and/or storage driver) can inject extra binds along the
1967   # way, so one can't rely on "shift positions" ordering at all. Also we
1968   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1969   # can be later matched up by address), because we want to supply a real
1970   # value on which perhaps e.g. datatype checks will be performed
1971   my ($proto_data, $value_type_by_col_idx);
1972   for my $i (@col_range) {
1973     my $colname = $cols->[$i];
1974     if (ref $data->[0][$i] eq 'SCALAR') {
1975       # no bind value at all - no type
1976
1977       $proto_data->{$colname} = $data->[0][$i];
1978     }
1979     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1980       # repack, so we don't end up mangling the original \[]
1981       my ($sql, @bind) = @${$data->[0][$i]};
1982
1983       # normalization of user supplied stuff
1984       my $resolved_bind = $self->_resolve_bindattrs(
1985         $source, \@bind, $colinfos,
1986       );
1987
1988       # store value-less (attrs only) bind info - we will be comparing all
1989       # supplied binds against this for sanity
1990       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1991
1992       $proto_data->{$colname} = \[ $sql, map { [
1993         # inject slice order to use for $proto_bind construction
1994           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
1995             =>
1996           $resolved_bind->[$_][1]
1997         ] } (0 .. $#bind)
1998       ];
1999     }
2000     else {
2001       $value_type_by_col_idx->{$i} = undef;
2002
2003       $proto_data->{$colname} = \[ '?', [
2004         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2005           =>
2006         $data->[0][$i]
2007       ] ];
2008     }
2009   }
2010
2011   my ($sql, $proto_bind) = $self->_prep_for_execute (
2012     'insert',
2013     $source,
2014     [ $proto_data ],
2015   );
2016
2017   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2018     # if the bindlist is empty and we had some dynamic binds, this means the
2019     # storage ate them away (e.g. the NoBindVars component) and interpolated
2020     # them directly into the SQL. This obviously can't be good for multi-inserts
2021     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2022   }
2023
2024   # sanity checks
2025   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2026   #
2027   # use an error reporting closure for convenience (less to pass)
2028   my $bad_slice_report_cref = sub {
2029     my ($msg, $r_idx, $c_idx) = @_;
2030     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2031       $msg,
2032       $cols->[$c_idx],
2033       do {
2034         require Data::Dumper::Concise;
2035         local $Data::Dumper::Maxdepth = 5;
2036         Data::Dumper::Concise::Dumper ({
2037           map { $cols->[$_] =>
2038             $data->[$r_idx][$_]
2039           } @col_range
2040         }),
2041       }
2042     );
2043   };
2044
2045   for my $col_idx (@col_range) {
2046     my $reference_val = $data->[0][$col_idx];
2047
2048     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2049       my $val = $data->[$row_idx][$col_idx];
2050
2051       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2052         if (ref $val ne 'SCALAR') {
2053           $bad_slice_report_cref->(
2054             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2055             $row_idx,
2056             $col_idx,
2057           );
2058         }
2059         elsif ($$val ne $$reference_val) {
2060           $bad_slice_report_cref->(
2061             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2062             $row_idx,
2063             $col_idx,
2064           );
2065         }
2066       }
2067       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2068         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2069           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2070         }
2071       }
2072       else {  # binds from a \[], compare type and attrs
2073         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2074           $bad_slice_report_cref->(
2075             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2076             $row_idx,
2077             $col_idx,
2078           );
2079         }
2080         # start drilling down and bail out early on identical refs
2081         elsif (
2082           $reference_val != $val
2083             or
2084           $$reference_val != $$val
2085         ) {
2086           if (${$val}->[0] ne ${$reference_val}->[0]) {
2087             $bad_slice_report_cref->(
2088               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2089               $row_idx,
2090               $col_idx,
2091             );
2092           }
2093           # need to check the bind attrs - a bind will happen only once for
2094           # the entire dataset, so any changes further down will be ignored.
2095           elsif (! Data::Compare::Compare(
2096             $value_type_by_col_idx->{$col_idx},
2097             [
2098               map
2099               { $_->[0] }
2100               @{$self->_resolve_bindattrs(
2101                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2102               )}
2103             ],
2104           )) {
2105             $bad_slice_report_cref->(
2106               'Differing bind attributes on literal/bind values not supported',
2107               $row_idx,
2108               $col_idx,
2109             );
2110           }
2111         }
2112       }
2113     }
2114   }
2115
2116   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2117   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2118   # scope guard
2119   my $guard = $self->txn_scope_guard;
2120
2121   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2122   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2123   my $rv = do {
2124     if (@$proto_bind) {
2125       # proto bind contains the information on which pieces of $data to pull
2126       # $cols is passed in only for prettier error-reporting
2127       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2128     }
2129     else {
2130       # bind_param_array doesn't work if there are no binds
2131       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2132     }
2133   };
2134
2135   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2136
2137   $guard->commit;
2138
2139   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2140 }
2141
2142 # execute_for_fetch is capable of returning data just fine (it means it
2143 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2144 # is the void-populate fast-path we will just ignore this altogether
2145 # for the time being.
2146 sub _dbh_execute_for_fetch {
2147   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2148
2149   my @idx_range = ( 0 .. $#$proto_bind );
2150
2151   # If we have any bind attributes to take care of, we will bind the
2152   # proto-bind data (which will never be used by execute_for_fetch)
2153   # However since column bindtypes are "sticky", this is sufficient
2154   # to get the DBD to apply the bindtype to all values later on
2155
2156   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2157
2158   for my $i (@idx_range) {
2159     $sth->bind_param (
2160       $i+1, # DBI bind indexes are 1-based
2161       $proto_bind->[$i][1],
2162       $bind_attrs->[$i],
2163     ) if defined $bind_attrs->[$i];
2164   }
2165
2166   # At this point $data slots named in the _bind_data_slice_idx of
2167   # each piece of $proto_bind are either \[]s or plain values to be
2168   # passed in. Construct the dispensing coderef. *NOTE* the order
2169   # of $data will differ from this of the ?s in the SQL (due to
2170   # alphabetical ordering by colname). We actually do want to
2171   # preserve this behavior so that prepare_cached has a better
2172   # chance of matching on unrelated calls
2173
2174   my $fetch_row_idx = -1; # saner loop this way
2175   my $fetch_tuple = sub {
2176     return undef if ++$fetch_row_idx > $#$data;
2177
2178     return [ map { defined $_->{_literal_bind_subindex}
2179       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2180          ->[ $_->{_literal_bind_subindex} ]
2181           ->[1]
2182       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2183     } map { $_->[0] } @$proto_bind];
2184   };
2185
2186   my $tuple_status = [];
2187   my ($rv, $err);
2188   try {
2189     $rv = $sth->execute_for_fetch(
2190       $fetch_tuple,
2191       $tuple_status,
2192     );
2193   }
2194   catch {
2195     $err = shift;
2196   };
2197
2198   # Not all DBDs are create equal. Some throw on error, some return
2199   # an undef $rv, and some set $sth->err - try whatever we can
2200   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2201     ! defined $err
2202       and
2203     ( !defined $rv or $sth->err )
2204   );
2205
2206   # Statement must finish even if there was an exception.
2207   try {
2208     $sth->finish
2209   }
2210   catch {
2211     $err = shift unless defined $err
2212   };
2213
2214   if (defined $err) {
2215     my $i = 0;
2216     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2217
2218     $self->throw_exception("Unexpected populate error: $err")
2219       if ($i > $#$tuple_status);
2220
2221     require Data::Dumper::Concise;
2222     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2223       ($tuple_status->[$i][1] || $err),
2224       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2225     );
2226   }
2227
2228   return $rv;
2229 }
2230
2231 sub _dbh_execute_inserts_with_no_binds {
2232   my ($self, $sth, $count) = @_;
2233
2234   my $err;
2235   try {
2236     my $dbh = $self->_get_dbh;
2237     local $dbh->{RaiseError} = 1;
2238     local $dbh->{PrintError} = 0;
2239
2240     $sth->execute foreach 1..$count;
2241   }
2242   catch {
2243     $err = shift;
2244   };
2245
2246   # Make sure statement is finished even if there was an exception.
2247   try {
2248     $sth->finish
2249   }
2250   catch {
2251     $err = shift unless defined $err;
2252   };
2253
2254   $self->throw_exception($err) if defined $err;
2255
2256   return $count;
2257 }
2258
2259 sub update {
2260   #my ($self, $source, @args) = @_;
2261   shift->_execute('update', @_);
2262 }
2263
2264
2265 sub delete {
2266   #my ($self, $source, @args) = @_;
2267   shift->_execute('delete', @_);
2268 }
2269
2270 sub _select {
2271   my $self = shift;
2272   $self->_execute($self->_select_args(@_));
2273 }
2274
2275 sub _select_args_to_query {
2276   my $self = shift;
2277
2278   $self->throw_exception(
2279     "Unable to generate limited query representation with 'software_limit' enabled"
2280   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2281
2282   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2283   #  = $self->_select_args($ident, $select, $cond, $attrs);
2284   my ($op, $ident, @args) =
2285     $self->_select_args(@_);
2286
2287   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2288   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2289
2290   # reuse the bind arrayref
2291   unshift @{$bind}, "($sql)";
2292   \$bind;
2293 }
2294
2295 sub _select_args {
2296   my ($self, $ident, $select, $where, $attrs) = @_;
2297
2298   my $sql_maker = $self->sql_maker;
2299   my $alias2source = $self->_resolve_ident_sources ($ident);
2300
2301   $attrs = {
2302     %$attrs,
2303     select => $select,
2304     from => $ident,
2305     where => $where,
2306
2307     # limit dialects use this stuff
2308     # yes, some CDBICompat crap does not supply an {alias} >.<
2309     ( $attrs->{alias} and $alias2source->{$attrs->{alias}} )
2310       ? ( _rsroot_rsrc => $alias2source->{$attrs->{alias}} )
2311       : ()
2312     ,
2313   };
2314
2315   # Sanity check the attributes (SQLMaker does it too, but
2316   # in case of a software_limit we'll never reach there)
2317   if (defined $attrs->{offset}) {
2318     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2319       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2320   }
2321
2322   if (defined $attrs->{rows}) {
2323     $self->throw_exception("The rows attribute must be a positive integer if present")
2324       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2325   }
2326   elsif ($attrs->{offset}) {
2327     # MySQL actually recommends this approach.  I cringe.
2328     $attrs->{rows} = $sql_maker->__max_int;
2329   }
2330
2331   # see if we will need to tear the prefetch apart to satisfy group_by == select
2332   # this is *extremely tricky* to get right, I am still not sure I did
2333   #
2334   my ($prefetch_needs_subquery, @limit_args);
2335
2336   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2337     # we already know there is a valid group_by and we know it is intended
2338     # to be based *only* on the main result columns
2339     # short circuit the group_by parsing below
2340     $prefetch_needs_subquery = 1;
2341   }
2342   elsif (
2343     # The rationale is that even if we do *not* have collapse, we still
2344     # need to wrap the core grouped select/group_by in a subquery
2345     # so that databases that care about group_by/select equivalence
2346     # are happy (this includes MySQL in strict_mode)
2347     # If any of the other joined tables are referenced in the group_by
2348     # however - the user is on their own
2349     ( $prefetch_needs_subquery or $attrs->{_related_results_construction} )
2350       and
2351     $attrs->{group_by}
2352       and
2353     @{$attrs->{group_by}}
2354       and
2355     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2356       $self->_resolve_aliastypes_from_select_args( $attrs->{from}, undef, undef, { group_by => $attrs->{group_by} } )
2357     }
2358   ) {
2359     # no aliases other than our own in group_by
2360     # if there are - do not allow subquery even if limit is present
2361     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2362   }
2363   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2364     # active collapse with a limit - that one is a no-brainer unless
2365     # overruled by a group_by above
2366     $prefetch_needs_subquery = 1;
2367   }
2368
2369   if ($prefetch_needs_subquery) {
2370     ($ident, $select, $where, $attrs) =
2371       $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2372   }
2373   elsif (! $attrs->{software_limit} ) {
2374     push @limit_args, (
2375       $attrs->{rows} || (),
2376       $attrs->{offset} || (),
2377     );
2378   }
2379
2380   # try to simplify the joinmap further (prune unreferenced type-single joins)
2381   if (
2382     ! $prefetch_needs_subquery  # already pruned
2383       and
2384     ref $ident
2385       and
2386     reftype $ident eq 'ARRAY'
2387       and
2388     @$ident != 1
2389   ) {
2390     ($ident) = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2391   }
2392
2393 ###
2394   # This would be the point to deflate anything found in $where
2395   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2396   # expect a result object. And all we have is a resultsource (it is trivial
2397   # to extract deflator coderefs via $alias2source above).
2398   #
2399   # I don't see a way forward other than changing the way deflators are
2400   # invoked, and that's just bad...
2401 ###
2402
2403   return ('select', $ident, $select, $where, $attrs, @limit_args);
2404 }
2405
2406 # Returns a counting SELECT for a simple count
2407 # query. Abstracted so that a storage could override
2408 # this to { count => 'firstcol' } or whatever makes
2409 # sense as a performance optimization
2410 sub _count_select {
2411   #my ($self, $source, $rs_attrs) = @_;
2412   return { count => '*' };
2413 }
2414
2415 =head2 select
2416
2417 =over 4
2418
2419 =item Arguments: $ident, $select, $condition, $attrs
2420
2421 =back
2422
2423 Handle a SQL select statement.
2424
2425 =cut
2426
2427 sub select {
2428   my $self = shift;
2429   my ($ident, $select, $condition, $attrs) = @_;
2430   return $self->cursor_class->new($self, \@_, $attrs);
2431 }
2432
2433 sub select_single {
2434   my $self = shift;
2435   my ($rv, $sth, @bind) = $self->_select(@_);
2436   my @row = $sth->fetchrow_array;
2437   my @nextrow = $sth->fetchrow_array if @row;
2438   if(@row && @nextrow) {
2439     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2440   }
2441   # Need to call finish() to work round broken DBDs
2442   $sth->finish();
2443   return @row;
2444 }
2445
2446 =head2 sql_limit_dialect
2447
2448 This is an accessor for the default SQL limit dialect used by a particular
2449 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2450 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2451 see L<DBIx::Class::SQLMaker::LimitDialects>.
2452
2453 =cut
2454
2455 sub _dbh_columns_info_for {
2456   my ($self, $dbh, $table) = @_;
2457
2458   if ($dbh->can('column_info')) {
2459     my %result;
2460     my $caught;
2461     try {
2462       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2463       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2464       $sth->execute();
2465       while ( my $info = $sth->fetchrow_hashref() ){
2466         my %column_info;
2467         $column_info{data_type}   = $info->{TYPE_NAME};
2468         $column_info{size}      = $info->{COLUMN_SIZE};
2469         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2470         $column_info{default_value} = $info->{COLUMN_DEF};
2471         my $col_name = $info->{COLUMN_NAME};
2472         $col_name =~ s/^\"(.*)\"$/$1/;
2473
2474         $result{$col_name} = \%column_info;
2475       }
2476     } catch {
2477       $caught = 1;
2478     };
2479     return \%result if !$caught && scalar keys %result;
2480   }
2481
2482   my %result;
2483   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2484   $sth->execute;
2485   my @columns = @{$sth->{NAME_lc}};
2486   for my $i ( 0 .. $#columns ){
2487     my %column_info;
2488     $column_info{data_type} = $sth->{TYPE}->[$i];
2489     $column_info{size} = $sth->{PRECISION}->[$i];
2490     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2491
2492     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2493       $column_info{data_type} = $1;
2494       $column_info{size}    = $2;
2495     }
2496
2497     $result{$columns[$i]} = \%column_info;
2498   }
2499   $sth->finish;
2500
2501   foreach my $col (keys %result) {
2502     my $colinfo = $result{$col};
2503     my $type_num = $colinfo->{data_type};
2504     my $type_name;
2505     if(defined $type_num && $dbh->can('type_info')) {
2506       my $type_info = $dbh->type_info($type_num);
2507       $type_name = $type_info->{TYPE_NAME} if $type_info;
2508       $colinfo->{data_type} = $type_name if $type_name;
2509     }
2510   }
2511
2512   return \%result;
2513 }
2514
2515 sub columns_info_for {
2516   my ($self, $table) = @_;
2517   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2518 }
2519
2520 =head2 last_insert_id
2521
2522 Return the row id of the last insert.
2523
2524 =cut
2525
2526 sub _dbh_last_insert_id {
2527     my ($self, $dbh, $source, $col) = @_;
2528
2529     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2530
2531     return $id if defined $id;
2532
2533     my $class = ref $self;
2534     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2535 }
2536
2537 sub last_insert_id {
2538   my $self = shift;
2539   $self->_dbh_last_insert_id ($self->_dbh, @_);
2540 }
2541
2542 =head2 _native_data_type
2543
2544 =over 4
2545
2546 =item Arguments: $type_name
2547
2548 =back
2549
2550 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2551 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2552 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2553
2554 The default implementation returns C<undef>, implement in your Storage driver if
2555 you need this functionality.
2556
2557 Should map types from other databases to the native RDBMS type, for example
2558 C<VARCHAR2> to C<VARCHAR>.
2559
2560 Types with modifiers should map to the underlying data type. For example,
2561 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2562
2563 Composite types should map to the container type, for example
2564 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2565
2566 =cut
2567
2568 sub _native_data_type {
2569   #my ($self, $data_type) = @_;
2570   return undef
2571 }
2572
2573 # Check if placeholders are supported at all
2574 sub _determine_supports_placeholders {
2575   my $self = shift;
2576   my $dbh  = $self->_get_dbh;
2577
2578   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2579   # but it is inaccurate more often than not
2580   return try {
2581     local $dbh->{PrintError} = 0;
2582     local $dbh->{RaiseError} = 1;
2583     $dbh->do('select ?', {}, 1);
2584     1;
2585   }
2586   catch {
2587     0;
2588   };
2589 }
2590
2591 # Check if placeholders bound to non-string types throw exceptions
2592 #
2593 sub _determine_supports_typeless_placeholders {
2594   my $self = shift;
2595   my $dbh  = $self->_get_dbh;
2596
2597   return try {
2598     local $dbh->{PrintError} = 0;
2599     local $dbh->{RaiseError} = 1;
2600     # this specifically tests a bind that is NOT a string
2601     $dbh->do('select 1 where 1 = ?', {}, 1);
2602     1;
2603   }
2604   catch {
2605     0;
2606   };
2607 }
2608
2609 =head2 sqlt_type
2610
2611 Returns the database driver name.
2612
2613 =cut
2614
2615 sub sqlt_type {
2616   shift->_get_dbh->{Driver}->{Name};
2617 }
2618
2619 =head2 bind_attribute_by_data_type
2620
2621 Given a datatype from column info, returns a database specific bind
2622 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2623 let the database planner just handle it.
2624
2625 This method is always called after the driver has been determined and a DBI
2626 connection has been established. Therefore you can refer to C<DBI::$constant>
2627 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2628 the correct modules.
2629
2630 =cut
2631
2632 sub bind_attribute_by_data_type {
2633     return;
2634 }
2635
2636 =head2 is_datatype_numeric
2637
2638 Given a datatype from column_info, returns a boolean value indicating if
2639 the current RDBMS considers it a numeric value. This controls how
2640 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2641 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2642 be performed instead of the usual C<eq>.
2643
2644 =cut
2645
2646 sub is_datatype_numeric {
2647   #my ($self, $dt) = @_;
2648
2649   return 0 unless $_[1];
2650
2651   $_[1] =~ /^ (?:
2652     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2653   ) $/ix;
2654 }
2655
2656
2657 =head2 create_ddl_dir
2658
2659 =over 4
2660
2661 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2662
2663 =back
2664
2665 Creates a SQL file based on the Schema, for each of the specified
2666 database engines in C<\@databases> in the given directory.
2667 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2668
2669 Given a previous version number, this will also create a file containing
2670 the ALTER TABLE statements to transform the previous schema into the
2671 current one. Note that these statements may contain C<DROP TABLE> or
2672 C<DROP COLUMN> statements that can potentially destroy data.
2673
2674 The file names are created using the C<ddl_filename> method below, please
2675 override this method in your schema if you would like a different file
2676 name format. For the ALTER file, the same format is used, replacing
2677 $version in the name with "$preversion-$version".
2678
2679 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2680 The most common value for this would be C<< { add_drop_table => 1 } >>
2681 to have the SQL produced include a C<DROP TABLE> statement for each table
2682 created. For quoting purposes supply C<quote_identifiers>.
2683
2684 If no arguments are passed, then the following default values are assumed:
2685
2686 =over 4
2687
2688 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2689
2690 =item version    - $schema->schema_version
2691
2692 =item directory  - './'
2693
2694 =item preversion - <none>
2695
2696 =back
2697
2698 By default, C<\%sqlt_args> will have
2699
2700  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2701
2702 merged with the hash passed in. To disable any of those features, pass in a
2703 hashref like the following
2704
2705  { ignore_constraint_names => 0, # ... other options }
2706
2707
2708 WARNING: You are strongly advised to check all SQL files created, before applying
2709 them.
2710
2711 =cut
2712
2713 sub create_ddl_dir {
2714   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2715
2716   unless ($dir) {
2717     carp "No directory given, using ./\n";
2718     $dir = './';
2719   } else {
2720       -d $dir
2721         or
2722       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2723         or
2724       $self->throw_exception(
2725         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2726       );
2727   }
2728
2729   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2730
2731   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2732   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2733
2734   my $schema_version = $schema->schema_version || '1.x';
2735   $version ||= $schema_version;
2736
2737   $sqltargs = {
2738     add_drop_table => 1,
2739     ignore_constraint_names => 1,
2740     ignore_index_names => 1,
2741     %{$sqltargs || {}}
2742   };
2743
2744   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2745     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2746   }
2747
2748   my $sqlt = SQL::Translator->new( $sqltargs );
2749
2750   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2751   my $sqlt_schema = $sqlt->translate({ data => $schema })
2752     or $self->throw_exception ($sqlt->error);
2753
2754   foreach my $db (@$databases) {
2755     $sqlt->reset();
2756     $sqlt->{schema} = $sqlt_schema;
2757     $sqlt->producer($db);
2758
2759     my $file;
2760     my $filename = $schema->ddl_filename($db, $version, $dir);
2761     if (-e $filename && ($version eq $schema_version )) {
2762       # if we are dumping the current version, overwrite the DDL
2763       carp "Overwriting existing DDL file - $filename";
2764       unlink($filename);
2765     }
2766
2767     my $output = $sqlt->translate;
2768     if(!$output) {
2769       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2770       next;
2771     }
2772     if(!open($file, ">$filename")) {
2773       $self->throw_exception("Can't open $filename for writing ($!)");
2774       next;
2775     }
2776     print $file $output;
2777     close($file);
2778
2779     next unless ($preversion);
2780
2781     require SQL::Translator::Diff;
2782
2783     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2784     if(!-e $prefilename) {
2785       carp("No previous schema file found ($prefilename)");
2786       next;
2787     }
2788
2789     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2790     if(-e $difffile) {
2791       carp("Overwriting existing diff file - $difffile");
2792       unlink($difffile);
2793     }
2794
2795     my $source_schema;
2796     {
2797       my $t = SQL::Translator->new($sqltargs);
2798       $t->debug( 0 );
2799       $t->trace( 0 );
2800
2801       $t->parser( $db )
2802         or $self->throw_exception ($t->error);
2803
2804       my $out = $t->translate( $prefilename )
2805         or $self->throw_exception ($t->error);
2806
2807       $source_schema = $t->schema;
2808
2809       $source_schema->name( $prefilename )
2810         unless ( $source_schema->name );
2811     }
2812
2813     # The "new" style of producers have sane normalization and can support
2814     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2815     # And we have to diff parsed SQL against parsed SQL.
2816     my $dest_schema = $sqlt_schema;
2817
2818     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2819       my $t = SQL::Translator->new($sqltargs);
2820       $t->debug( 0 );
2821       $t->trace( 0 );
2822
2823       $t->parser( $db )
2824         or $self->throw_exception ($t->error);
2825
2826       my $out = $t->translate( $filename )
2827         or $self->throw_exception ($t->error);
2828
2829       $dest_schema = $t->schema;
2830
2831       $dest_schema->name( $filename )
2832         unless $dest_schema->name;
2833     }
2834
2835     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2836                                                   $dest_schema,   $db,
2837                                                   $sqltargs
2838                                                  );
2839     if(!open $file, ">$difffile") {
2840       $self->throw_exception("Can't write to $difffile ($!)");
2841       next;
2842     }
2843     print $file $diff;
2844     close($file);
2845   }
2846 }
2847
2848 =head2 deployment_statements
2849
2850 =over 4
2851
2852 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2853
2854 =back
2855
2856 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2857
2858 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2859 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2860
2861 C<$directory> is used to return statements from files in a previously created
2862 L</create_ddl_dir> directory and is optional. The filenames are constructed
2863 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2864
2865 If no C<$directory> is specified then the statements are constructed on the
2866 fly using L<SQL::Translator> and C<$version> is ignored.
2867
2868 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2869
2870 =cut
2871
2872 sub deployment_statements {
2873   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2874   $type ||= $self->sqlt_type;
2875   $version ||= $schema->schema_version || '1.x';
2876   $dir ||= './';
2877   my $filename = $schema->ddl_filename($type, $version, $dir);
2878   if(-f $filename)
2879   {
2880       # FIXME replace this block when a proper sane sql parser is available
2881       my $file;
2882       open($file, "<$filename")
2883         or $self->throw_exception("Can't open $filename ($!)");
2884       my @rows = <$file>;
2885       close($file);
2886       return join('', @rows);
2887   }
2888
2889   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2890     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2891   }
2892
2893   # sources needs to be a parser arg, but for simplicty allow at top level
2894   # coming in
2895   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2896       if exists $sqltargs->{sources};
2897
2898   my $tr = SQL::Translator->new(
2899     producer => "SQL::Translator::Producer::${type}",
2900     %$sqltargs,
2901     parser => 'SQL::Translator::Parser::DBIx::Class',
2902     data => $schema,
2903   );
2904
2905   return preserve_context {
2906     $tr->translate
2907   } after => sub {
2908     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2909       unless defined $_[0];
2910   };
2911 }
2912
2913 # FIXME deploy() currently does not accurately report sql errors
2914 # Will always return true while errors are warned
2915 sub deploy {
2916   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2917   my $deploy = sub {
2918     my $line = shift;
2919     return if(!$line);
2920     return if($line =~ /^--/);
2921     # next if($line =~ /^DROP/m);
2922     return if($line =~ /^BEGIN TRANSACTION/m);
2923     return if($line =~ /^COMMIT/m);
2924     return if $line =~ /^\s+$/; # skip whitespace only
2925     $self->_query_start($line);
2926     try {
2927       # do a dbh_do cycle here, as we need some error checking in
2928       # place (even though we will ignore errors)
2929       $self->dbh_do (sub { $_[1]->do($line) });
2930     } catch {
2931       carp qq{$_ (running "${line}")};
2932     };
2933     $self->_query_end($line);
2934   };
2935   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2936   if (@statements > 1) {
2937     foreach my $statement (@statements) {
2938       $deploy->( $statement );
2939     }
2940   }
2941   elsif (@statements == 1) {
2942     # split on single line comments and end of statements
2943     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2944       $deploy->( $line );
2945     }
2946   }
2947 }
2948
2949 =head2 datetime_parser
2950
2951 Returns the datetime parser class
2952
2953 =cut
2954
2955 sub datetime_parser {
2956   my $self = shift;
2957   return $self->{datetime_parser} ||= do {
2958     $self->build_datetime_parser(@_);
2959   };
2960 }
2961
2962 =head2 datetime_parser_type
2963
2964 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2965
2966 =head2 build_datetime_parser
2967
2968 See L</datetime_parser>
2969
2970 =cut
2971
2972 sub build_datetime_parser {
2973   my $self = shift;
2974   my $type = $self->datetime_parser_type(@_);
2975   return $type;
2976 }
2977
2978
2979 =head2 is_replicating
2980
2981 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2982 replicate from a master database.  Default is undef, which is the result
2983 returned by databases that don't support replication.
2984
2985 =cut
2986
2987 sub is_replicating {
2988     return;
2989
2990 }
2991
2992 =head2 lag_behind_master
2993
2994 Returns a number that represents a certain amount of lag behind a master db
2995 when a given storage is replicating.  The number is database dependent, but
2996 starts at zero and increases with the amount of lag. Default in undef
2997
2998 =cut
2999
3000 sub lag_behind_master {
3001     return;
3002 }
3003
3004 =head2 relname_to_table_alias
3005
3006 =over 4
3007
3008 =item Arguments: $relname, $join_count
3009
3010 =item Return Value: $alias
3011
3012 =back
3013
3014 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3015 queries.
3016
3017 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3018 way these aliases are named.
3019
3020 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3021 otherwise C<"$relname">.
3022
3023 =cut
3024
3025 sub relname_to_table_alias {
3026   my ($self, $relname, $join_count) = @_;
3027
3028   my $alias = ($join_count && $join_count > 1 ?
3029     join('_', $relname, $join_count) : $relname);
3030
3031   return $alias;
3032 }
3033
3034 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3035 # version and it may be necessary to amend or override it for a specific storage
3036 # if such binds are necessary.
3037 sub _max_column_bytesize {
3038   my ($self, $attr) = @_;
3039
3040   my $max_size;
3041
3042   if ($attr->{sqlt_datatype}) {
3043     my $data_type = lc($attr->{sqlt_datatype});
3044
3045     if ($attr->{sqlt_size}) {
3046
3047       # String/sized-binary types
3048       if ($data_type =~ /^(?:
3049           l? (?:var)? char(?:acter)? (?:\s*varying)?
3050             |
3051           (?:var)? binary (?:\s*varying)?
3052             |
3053           raw
3054         )\b/x
3055       ) {
3056         $max_size = $attr->{sqlt_size};
3057       }
3058       # Other charset/unicode types, assume scale of 4
3059       elsif ($data_type =~ /^(?:
3060           national \s* character (?:\s*varying)?
3061             |
3062           nchar
3063             |
3064           univarchar
3065             |
3066           nvarchar
3067         )\b/x
3068       ) {
3069         $max_size = $attr->{sqlt_size} * 4;
3070       }
3071     }
3072
3073     if (!$max_size and !$self->_is_lob_type($data_type)) {
3074       $max_size = 100 # for all other (numeric?) datatypes
3075     }
3076   }
3077
3078   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3079 }
3080
3081 # Determine if a data_type is some type of BLOB
3082 sub _is_lob_type {
3083   my ($self, $data_type) = @_;
3084   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3085     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3086                                   |varchar|character\s*varying|nvarchar
3087                                   |national\s*character\s*varying))?\z/xi);
3088 }
3089
3090 sub _is_binary_lob_type {
3091   my ($self, $data_type) = @_;
3092   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3093     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3094 }
3095
3096 sub _is_text_lob_type {
3097   my ($self, $data_type) = @_;
3098   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3099     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3100                         |national\s*character\s*varying))\z/xi);
3101 }
3102
3103 # Determine if a data_type is some type of a binary type
3104 sub _is_binary_type {
3105   my ($self, $data_type) = @_;
3106   $data_type && ($self->_is_binary_lob_type($data_type)
3107     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3108 }
3109
3110 1;
3111
3112 =head1 USAGE NOTES
3113
3114 =head2 DBIx::Class and AutoCommit
3115
3116 DBIx::Class can do some wonderful magic with handling exceptions,
3117 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3118 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3119 transaction support.
3120
3121 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3122 in an assumed transaction between commits, and you're telling us you'd
3123 like to manage that manually.  A lot of the magic protections offered by
3124 this module will go away.  We can't protect you from exceptions due to database
3125 disconnects because we don't know anything about how to restart your
3126 transactions.  You're on your own for handling all sorts of exceptional
3127 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3128 be with raw DBI.
3129
3130
3131 =head1 AUTHOR AND CONTRIBUTORS
3132
3133 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3134
3135 =head1 LICENSE
3136
3137 You may distribute this code under the same terms as Perl itself.
3138
3139 =cut