lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use Context::Preserve 'preserve_context';
  13 use Try::Tiny;
  14 use SQL::Abstract qw(is_plain_value is_literal_value);
  15 use DBIx::Class::_Util qw(
  16   quote_sub perlstring serialize dump_value
  17   dbic_internal_try
  18   detected_reinvoked_destructor scope_guard
  19   mkdir_p
  20 );
  21 use namespace::clean;
  22
  23 # default cursor class, overridable in connect_info attributes
  24 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  25
  26 __PACKAGE__->mk_group_accessors('inherited' => qw/
  27   sql_limit_dialect sql_quote_char sql_name_sep
  28 /);
  29
  30 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  31
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  33 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  34
  35 __PACKAGE__->sql_name_sep('.');
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/
  38   _connect_info _dbic_connect_attributes _driver_determined
  39   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  40   _perform_autoinc_retrieval _autoinc_supplied_for_op
  41 /);
  42
  43 # the values for these accessors are picked out (and deleted) from
  44 # the attribute hashref passed to connect_info
  45 my @storage_options = qw/
  46   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  47   disable_sth_caching unsafe auto_savepoint
  48 /;
  49 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  50
  51
  52 # capability definitions, using a 2-tiered accessor system
  53 # The rationale is:
  54 #
  55 # A driver/user may define _use_X, which blindly without any checks says:
  56 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  57 # type accessor)
  58 #
  59 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  60 # accessor, which in turn calls _determine_supports_X, and stores the return
  61 # in a special slot on the storage object, which is wiped every time a $dbh
  62 # reconnection takes place (it is not guaranteed that upon reconnection we
  63 # will get the same rdbms version). _determine_supports_X does not need to
  64 # exist on a driver, as we ->can for it before calling.
  65
  66 my @capabilities = (qw/
  67   insert_returning
  68   insert_returning_bound
  69
  70   multicolumn_in
  71
  72   placeholders
  73   typeless_placeholders
  74
  75   join_optimizer
  76 /);
  77 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  78 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  79
  80 # on by default, not strictly a capability (pending rewrite)
  81 __PACKAGE__->_use_join_optimizer (1);
  82 sub _determine_supports_join_optimizer { 1 };
  83
  84 # Each of these methods need _determine_driver called before itself
  85 # in order to function reliably. We also need to separate accessors
  86 # from plain old method calls, since an accessor called as a setter
  87 # does *not* need the driver determination loop fired (and in fact
  88 # can produce hard to find bugs, like e.g. losing on_connect_*
  89 # semantics on fresh connections)
  90 #
  91 # The construct below is simply a parameterized around()
  92 my $storage_accessor_idx = { map { $_ => 1 } qw(
  93   sqlt_type
  94   datetime_parser_type
  95
  96   sql_maker
  97   cursor_class
  98 )};
  99 for my $meth (keys %$storage_accessor_idx, qw(
 100   deployment_statements
 101
 102   build_datetime_parser
 103
 104   txn_begin
 105
 106   insert
 107   update
 108   delete
 109   select
 110   select_single
 111
 112   _insert_bulk
 113
 114   with_deferred_fk_checks
 115
 116   get_use_dbms_capability
 117   get_dbms_capability
 118
 119   _server_info
 120   _get_server_version
 121 )) {
 122
 123   my $orig = __PACKAGE__->can ($meth)
 124     or die "$meth is not a ::Storage::DBI method!";
 125
 126   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 127
 128   quote_sub
 129     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 130
 131     if (
 132       # if this is an actual *setter* - just set it, no need to connect
 133       # and determine the driver
 134       !( %1$s and @_ > 1 )
 135         and
 136       # only fire when invoked on an instance, a valid class-based invocation
 137       # would e.g. be setting a default for an inherited accessor
 138       ref $_[0]
 139         and
 140       ! $_[0]->{_driver_determined}
 141         and
 142       ! $_[0]->{_in_determine_driver}
 143         and
 144       # Only try to determine stuff if we have *something* that either is or can
 145       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 146       # to still be marginally useful
 147       $_[0]->_dbi_connect_info->[0]
 148     ) {
 149       $_[0]->_determine_driver;
 150
 151       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 152       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 153
 154       my $cref = $_[0]->can(%2$s);
 155       goto $cref;
 156     }
 157
 158     goto $orig;
 159 EOC
 160 }
 161
 162 =head1 NAME
 163
 164 DBIx::Class::Storage::DBI - DBI storage handler
 165
 166 =head1 SYNOPSIS
 167
 168   my $schema = MySchema->connect('dbi:SQLite:my.db');
 169
 170   $schema->storage->debug(1);
 171
 172   my @stuff = $schema->storage->dbh_do(
 173     sub {
 174       my ($storage, $dbh, @args) = @_;
 175       $dbh->do("DROP TABLE authors");
 176     },
 177     @column_list
 178   );
 179
 180   $schema->resultset('Book')->search({
 181      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 182   });
 183
 184 =head1 DESCRIPTION
 185
 186 This class represents the connection to an RDBMS via L<DBI>.  See
 187 L<DBIx::Class::Storage> for general information.  This pod only
 188 documents DBI-specific methods and behaviors.
 189
 190 =head1 METHODS
 191
 192 =cut
 193
 194 sub new {
 195   my $new = shift->next::method(@_);
 196
 197   $new->_sql_maker_opts({});
 198   $new->_dbh_details({});
 199   $new->{_in_do_block} = 0;
 200
 201   # read below to see what this does
 202   $new->_arm_global_destructor;
 203
 204   $new;
 205 }
 206
 207 # This is hack to work around perl shooting stuff in random
 208 # order on exit(). If we do not walk the remaining storage
 209 # objects in an END block, there is a *small but real* chance
 210 # of a fork()ed child to kill the parent's shared DBI handle,
 211 # *before perl reaches the DESTROY in this package*
 212 # Yes, it is ugly and effective.
 213 # Additionally this registry is used by the CLONE method to
 214 # make sure no handles are shared between threads
 215 {
 216   my %seek_and_destroy;
 217
 218   sub _arm_global_destructor {
 219
 220     # quick "garbage collection" pass - prevents the registry
 221     # from slowly growing with a bunch of undef-valued keys
 222     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 223       for keys %seek_and_destroy;
 224
 225     weaken (
 226       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 227     );
 228
 229     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 230     # collected before leaving this scope. Depending on the code above, this
 231     # may very well be just a preventive measure guarding future modifications
 232     undef;
 233   }
 234
 235   END {
 236
 237     if(
 238       ! DBIx::Class::_ENV_::BROKEN_FORK
 239         and
 240       my @instances = grep { defined $_ } values %seek_and_destroy
 241     ) {
 242       local $?; # just in case the DBI destructor changes it somehow
 243
 244       # disarm the handle if not native to this process (see comment on top)
 245       $_->_verify_pid for @instances;
 246     }
 247
 248     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 249     # collected before leaving this scope. Depending on the code above, this
 250     # may very well be just a preventive measure guarding future modifications
 251     undef;
 252   }
 253
 254   sub DBIx::Class::__DBI_Storage_iThreads_handler__::CLONE {
 255     # As per DBI's recommendation, DBIC disconnects all handles as
 256     # soon as possible (DBIC will reconnect only on demand from within
 257     # the thread)
 258     my @instances = grep { defined $_ } values %seek_and_destroy;
 259     %seek_and_destroy = ();
 260
 261     for (@instances) {
 262       $_->_dbh(undef);
 263       $_->disconnect;
 264
 265       # properly renumber existing refs
 266       $_->_arm_global_destructor
 267     }
 268
 269     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 270     # collected before leaving this scope. Depending on the code above, this
 271     # may very well be just a preventive measure guarding future modifications
 272     undef;
 273   }
 274 }
 275
 276 sub DESTROY {
 277   return if &detected_reinvoked_destructor;
 278
 279   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 280
 281   # some databases spew warnings on implicit disconnect
 282   return unless defined $_[0]->_dbh;
 283
 284   local $SIG{__WARN__} = sub {};
 285   $_[0]->_dbh(undef);
 286   # not calling ->disconnect here - we are being destroyed - nothing to reset
 287
 288   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 289   # collected before leaving this scope. Depending on the code above, this
 290   # may very well be just a preventive measure guarding future modifications
 291   undef;
 292 }
 293
 294 # handle pid changes correctly - do not destroy parent's connection
 295 sub _verify_pid {
 296
 297   my $pid = $_[0]->_conn_pid;
 298
 299   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 300     $dbh->{InactiveDestroy} = 1;
 301     $_[0]->_dbh(undef);
 302     $_[0]->disconnect;
 303   }
 304
 305   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 306   # collected before leaving this scope. Depending on the code above, this
 307   # may very well be just a preventive measure guarding future modifications
 308   undef;
 309 }
 310
 311 =head2 connect_info
 312
 313 This method is normally called by L<DBIx::Class::Schema/connection>, which
 314 encapsulates its argument list in an arrayref before passing them here.
 315
 316 The argument list may contain:
 317
 318 =over
 319
 320 =item *
 321
 322 The same 4-element argument set one would normally pass to
 323 L<DBI/connect>, optionally followed by
 324 L<extra attributes|/DBIx::Class specific connection attributes>
 325 recognized by DBIx::Class:
 326
 327   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 328
 329 =item *
 330
 331 A single code reference which returns a connected
 332 L<DBI database handle|DBI/connect> optionally followed by
 333 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 334 by DBIx::Class:
 335
 336   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 337
 338 =item *
 339
 340 A single hashref with all the attributes and the dsn/user/password
 341 mixed together:
 342
 343   $connect_info_args = [{
 344     dsn => $dsn,
 345     user => $user,
 346     password => $pass,
 347     %dbi_attributes,
 348     %extra_attributes,
 349   }];
 350
 351   $connect_info_args = [{
 352     dbh_maker => sub { DBI->connect (...) },
 353     %dbi_attributes,
 354     %extra_attributes,
 355   }];
 356
 357 This is particularly useful for L<Catalyst> based applications, allowing the
 358 following config (L<Config::General> style):
 359
 360   <Model::DB>
 361     schema_class   App::DB
 362     <connect_info>
 363       dsn          dbi:mysql:database=test
 364       user         testuser
 365       password     TestPass
 366       AutoCommit   1
 367     </connect_info>
 368   </Model::DB>
 369
 370 The C<dsn>/C<user>/C<password> combination can be substituted by the
 371 C<dbh_maker> key whose value is a coderef that returns a connected
 372 L<DBI database handle|DBI/connect>
 373
 374 =back
 375
 376 Please note that the L<DBI> docs recommend that you always explicitly
 377 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 378 recommends that it be set to I<1>, and that you perform transactions
 379 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 380 to I<1> if you do not do explicitly set it to zero.  This is the default
 381 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 382
 383 =head3 DBIx::Class specific connection attributes
 384
 385 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 386 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 387 the following connection options. These options can be mixed in with your other
 388 L<DBI> connection attributes, or placed in a separate hashref
 389 (C<\%extra_attributes>) as shown above.
 390
 391 Every time C<connect_info> is invoked, any previous settings for
 392 these options will be cleared before setting the new ones, regardless of
 393 whether any options are specified in the new C<connect_info>.
 394
 395
 396 =over
 397
 398 =item on_connect_do
 399
 400 Specifies things to do immediately after connecting or re-connecting to
 401 the database.  Its value may contain:
 402
 403 =over
 404
 405 =item a scalar
 406
 407 This contains one SQL statement to execute.
 408
 409 =item an array reference
 410
 411 This contains SQL statements to execute in order.  Each element contains
 412 a string or a code reference that returns a string.
 413
 414 =item a code reference
 415
 416 This contains some code to execute.  Unlike code references within an
 417 array reference, its return value is ignored.
 418
 419 =back
 420
 421 =item on_disconnect_do
 422
 423 Takes arguments in the same form as L</on_connect_do> and executes them
 424 immediately before disconnecting from the database.
 425
 426 Note, this only runs if you explicitly call L</disconnect> on the
 427 storage object.
 428
 429 =item on_connect_call
 430
 431 A more generalized form of L</on_connect_do> that calls the specified
 432 C<connect_call_METHOD> methods in your storage driver.
 433
 434   on_connect_do => 'select 1'
 435
 436 is equivalent to:
 437
 438   on_connect_call => [ [ do_sql => 'select 1' ] ]
 439
 440 Its values may contain:
 441
 442 =over
 443
 444 =item a scalar
 445
 446 Will call the C<connect_call_METHOD> method.
 447
 448 =item a code reference
 449
 450 Will execute C<< $code->($storage) >>
 451
 452 =item an array reference
 453
 454 Each value can be a method name or code reference.
 455
 456 =item an array of arrays
 457
 458 For each array, the first item is taken to be the C<connect_call_> method name
 459 or code reference, and the rest are parameters to it.
 460
 461 =back
 462
 463 Some predefined storage methods you may use:
 464
 465 =over
 466
 467 =item do_sql
 468
 469 Executes a SQL string or a code reference that returns a SQL string. This is
 470 what L</on_connect_do> and L</on_disconnect_do> use.
 471
 472 It can take:
 473
 474 =over
 475
 476 =item a scalar
 477
 478 Will execute the scalar as SQL.
 479
 480 =item an arrayref
 481
 482 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 483 attributes hashref and bind values.
 484
 485 =item a code reference
 486
 487 Will execute C<< $code->($storage) >> and execute the return array refs as
 488 above.
 489
 490 =back
 491
 492 =item datetime_setup
 493
 494 Execute any statements necessary to initialize the database session to return
 495 and accept datetime/timestamp values used with
 496 L<DBIx::Class::InflateColumn::DateTime>.
 497
 498 Only necessary for some databases, see your specific storage driver for
 499 implementation details.
 500
 501 =back
 502
 503 =item on_disconnect_call
 504
 505 Takes arguments in the same form as L</on_connect_call> and executes them
 506 immediately before disconnecting from the database.
 507
 508 Calls the C<disconnect_call_METHOD> methods as opposed to the
 509 C<connect_call_METHOD> methods called by L</on_connect_call>.
 510
 511 Note, this only runs if you explicitly call L</disconnect> on the
 512 storage object.
 513
 514 =item disable_sth_caching
 515
 516 If set to a true value, this option will disable the caching of
 517 statement handles via L<DBI/prepare_cached>.
 518
 519 =item limit_dialect
 520
 521 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 522 default L</sql_limit_dialect> setting of the storage (if any). For a list
 523 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 524
 525 =item quote_names
 526
 527 When true automatically sets L</quote_char> and L</name_sep> to the characters
 528 appropriate for your particular RDBMS. This option is preferred over specifying
 529 L</quote_char> directly.
 530
 531 =item quote_char
 532
 533 Specifies what characters to use to quote table and column names.
 534
 535 C<quote_char> expects either a single character, in which case is it
 536 is placed on either side of the table/column name, or an arrayref of length
 537 2 in which case the table/column name is placed between the elements.
 538
 539 For example under MySQL you should use C<< quote_char => '`' >>, and for
 540 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 541
 542 =item name_sep
 543
 544 This parameter is only useful in conjunction with C<quote_char>, and is used to
 545 specify the character that separates elements (schemas, tables, columns) from
 546 each other. If unspecified it defaults to the most commonly used C<.>.
 547
 548 =item unsafe
 549
 550 This Storage driver normally installs its own C<HandleError>, sets
 551 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 552 all database handles, including those supplied by a coderef.  It does this
 553 so that it can have consistent and useful error behavior.
 554
 555 If you set this option to a true value, Storage will not do its usual
 556 modifications to the database handle's attributes, and instead relies on
 557 the settings in your connect_info DBI options (or the values you set in
 558 your connection coderef, in the case that you are connecting via coderef).
 559
 560 Note that your custom settings can cause Storage to malfunction,
 561 especially if you set a C<HandleError> handler that suppresses exceptions
 562 and/or disable C<RaiseError>.
 563
 564 =item auto_savepoint
 565
 566 If this option is true, L<DBIx::Class> will use savepoints when nesting
 567 transactions, making it possible to recover from failure in the inner
 568 transaction without having to abort all outer transactions.
 569
 570 =item cursor_class
 571
 572 Use this argument to supply a cursor class other than the default
 573 L<DBIx::Class::Storage::DBI::Cursor>.
 574
 575 =back
 576
 577 Some real-life examples of arguments to L</connect_info> and
 578 L<DBIx::Class::Schema/connect>
 579
 580   # Simple SQLite connection
 581   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 582
 583   # Connect via subref
 584   ->connect_info([ sub { DBI->connect(...) } ]);
 585
 586   # Connect via subref in hashref
 587   ->connect_info([{
 588     dbh_maker => sub { DBI->connect(...) },
 589     on_connect_do => 'alter session ...',
 590   }]);
 591
 592   # A bit more complicated
 593   ->connect_info(
 594     [
 595       'dbi:Pg:dbname=foo',
 596       'postgres',
 597       'my_pg_password',
 598       { AutoCommit => 1 },
 599       { quote_char => q{"} },
 600     ]
 601   );
 602
 603   # Equivalent to the previous example
 604   ->connect_info(
 605     [
 606       'dbi:Pg:dbname=foo',
 607       'postgres',
 608       'my_pg_password',
 609       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 610     ]
 611   );
 612
 613   # Same, but with hashref as argument
 614   # See parse_connect_info for explanation
 615   ->connect_info(
 616     [{
 617       dsn         => 'dbi:Pg:dbname=foo',
 618       user        => 'postgres',
 619       password    => 'my_pg_password',
 620       AutoCommit  => 1,
 621       quote_char  => q{"},
 622       name_sep    => q{.},
 623     }]
 624   );
 625
 626   # Subref + DBIx::Class-specific connection options
 627   ->connect_info(
 628     [
 629       sub { DBI->connect(...) },
 630       {
 631           quote_char => q{`},
 632           name_sep => q{@},
 633           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 634           disable_sth_caching => 1,
 635       },
 636     ]
 637   );
 638
 639
 640
 641 =cut
 642
 643 sub connect_info {
 644   my ($self, $info) = @_;
 645
 646   return $self->_connect_info if !$info;
 647
 648   $self->_connect_info($info); # copy for _connect_info
 649
 650   $info = $self->_normalize_connect_info($info)
 651     if ref $info eq 'ARRAY';
 652
 653   my %attrs = (
 654     %{ $self->_default_dbi_connect_attributes || {} },
 655     %{ $info->{attributes} || {} },
 656   );
 657
 658   my @args = @{ $info->{arguments} };
 659
 660   if (keys %attrs and ref $args[0] ne 'CODE') {
 661     carp_unique (
 662         'You provided explicit AutoCommit => 0 in your connection_info. '
 663       . 'This is almost universally a bad idea (see the footnotes of '
 664       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 665       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 666       . 'this warning.'
 667     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 668
 669     push @args, \%attrs if keys %attrs;
 670   }
 671
 672   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 673   # OR a single-element coderef-based $dbh factory
 674   $self->_dbi_connect_info(\@args);
 675
 676   # extract the individual storage options
 677   for my $storage_opt (keys %{ $info->{storage_options} }) {
 678     my $value = $info->{storage_options}{$storage_opt};
 679
 680     $self->$storage_opt($value);
 681   }
 682
 683   # Extract the individual sqlmaker options
 684   #
 685   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 686   #  the new set of options
 687   $self->_sql_maker(undef);
 688   $self->_sql_maker_opts({});
 689
 690   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 691     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 692
 693     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 694   }
 695
 696   # FIXME - dirty:
 697   # save attributes in a separate accessor so they are always
 698   # introspectable, even in case of a CODE $dbhmaker
 699   $self->_dbic_connect_attributes (\%attrs);
 700
 701   return $self->_connect_info;
 702 }
 703
 704 sub _dbi_connect_info {
 705   my $self = shift;
 706
 707   return $self->{_dbi_connect_info} = $_[0]
 708     if @_;
 709
 710   my $conninfo = $self->{_dbi_connect_info} || [];
 711
 712   # last ditch effort to grab a DSN
 713   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 714     my @new_conninfo = @$conninfo;
 715     $new_conninfo[0] = $ENV{DBI_DSN};
 716     $conninfo = \@new_conninfo;
 717   }
 718
 719   return $conninfo;
 720 }
 721
 722
 723 sub _normalize_connect_info {
 724   my ($self, $info_arg) = @_;
 725   my %info;
 726
 727   my @args = @$info_arg;  # take a shallow copy for further mutilation
 728
 729   # combine/pre-parse arguments depending on invocation style
 730
 731   my %attrs;
 732   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 733     %attrs = %{ $args[1] || {} };
 734     @args = $args[0];
 735   }
 736   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 737     %attrs = %{$args[0]};
 738     @args = ();
 739     if (my $code = delete $attrs{dbh_maker}) {
 740       @args = $code;
 741
 742       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 743       if (@ignored) {
 744         carp sprintf (
 745             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 746           . "to the result of 'dbh_maker'",
 747
 748           join (', ', map { "'$_'" } (@ignored) ),
 749         );
 750       }
 751     }
 752     else {
 753       @args = delete @attrs{qw/dsn user password/};
 754     }
 755   }
 756   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 757     %attrs = (
 758       % { $args[3] || {} },
 759       % { $args[4] || {} },
 760     );
 761     @args = @args[0,1,2];
 762   }
 763
 764   $info{arguments} = \@args;
 765
 766   my @storage_opts = grep exists $attrs{$_},
 767     @storage_options, 'cursor_class';
 768
 769   @{ $info{storage_options} }{@storage_opts} =
 770     delete @attrs{@storage_opts} if @storage_opts;
 771
 772   my @sql_maker_opts = grep exists $attrs{$_},
 773     qw/limit_dialect quote_char name_sep quote_names/;
 774
 775   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 776     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 777
 778   $info{attributes} = \%attrs if %attrs;
 779
 780   return \%info;
 781 }
 782
 783 sub _default_dbi_connect_attributes () {
 784   +{
 785     AutoCommit => 1,
 786     PrintError => 0,
 787     RaiseError => 1,
 788     ShowErrorStatement => 1,
 789   };
 790 }
 791
 792 =head2 on_connect_do
 793
 794 This method is deprecated in favour of setting via L</connect_info>.
 795
 796 =cut
 797
 798 =head2 on_disconnect_do
 799
 800 This method is deprecated in favour of setting via L</connect_info>.
 801
 802 =cut
 803
 804 sub _parse_connect_do {
 805   my ($self, $type) = @_;
 806
 807   my $val = $self->$type;
 808   return () if not defined $val;
 809
 810   my @res;
 811
 812   if (not ref($val)) {
 813     push @res, [ 'do_sql', $val ];
 814   } elsif (ref($val) eq 'CODE') {
 815     push @res, $val;
 816   } elsif (ref($val) eq 'ARRAY') {
 817     push @res, map { [ 'do_sql', $_ ] } @$val;
 818   } else {
 819     $self->throw_exception("Invalid type for $type: ".ref($val));
 820   }
 821
 822   return \@res;
 823 }
 824
 825 =head2 dbh_do
 826
 827 Arguments: ($subref | $method_name), @extra_coderef_args?
 828
 829 Execute the given $subref or $method_name using the new exception-based
 830 connection management.
 831
 832 The first two arguments will be the storage object that C<dbh_do> was called
 833 on and a database handle to use.  Any additional arguments will be passed
 834 verbatim to the called subref as arguments 2 and onwards.
 835
 836 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 837 exception handling and reconnection (or failover in future subclasses).
 838
 839 Your subref should have no side-effects outside of the database, as
 840 there is the potential for your subref to be partially double-executed
 841 if the database connection was stale/dysfunctional.
 842
 843 Example:
 844
 845   my @stuff = $schema->storage->dbh_do(
 846     sub {
 847       my ($storage, $dbh, @cols) = @_;
 848       my $cols = join(q{, }, @cols);
 849       $dbh->selectrow_array("SELECT $cols FROM foo");
 850     },
 851     @column_list
 852   );
 853
 854 =cut
 855
 856 sub dbh_do {
 857   my $self = shift;
 858   my $run_target = shift; # either a coderef or a method name
 859
 860   # short circuit when we know there is no need for a runner
 861   #
 862   # FIXME - assumption may be wrong
 863   # the rationale for the txn_depth check is that if this block is a part
 864   # of a larger transaction, everything up to that point is screwed anyway
 865   return $self->$run_target($self->_get_dbh, @_)
 866     if $self->{_in_do_block} or $self->transaction_depth;
 867
 868   # take a ref instead of a copy, to preserve @_ aliasing
 869   # semantics within the coderef, but only if needed
 870   # (pseudoforking doesn't like this trick much)
 871   my $args = @_ ? \@_ : [];
 872
 873   DBIx::Class::Storage::BlockRunner->new(
 874     storage => $self,
 875     wrap_txn => 0,
 876     retry_handler => sub {
 877       $_[0]->failed_attempt_count == 1
 878         and
 879       ! $_[0]->storage->connected
 880     },
 881   )->run(sub {
 882     $self->$run_target ($self->_get_dbh, @$args )
 883   });
 884 }
 885
 886 sub txn_do {
 887   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 888   shift->next::method(@_);
 889 }
 890
 891 =head2 disconnect
 892
 893 Our C<disconnect> method also performs a rollback first if the
 894 database is not in C<AutoCommit> mode.
 895
 896 =cut
 897
 898 sub disconnect {
 899   my $self = shift;
 900
 901   # this physical disconnect below might very well throw
 902   # in order to unambiguously reset the state - do the cleanup in guard
 903
 904   my $g = scope_guard {
 905
 906     defined( $self->_dbh )
 907       and dbic_internal_try { $self->_dbh->disconnect };
 908
 909     $self->_dbh(undef);
 910     $self->_dbh_details({});
 911     $self->transaction_depth(undef);
 912     $self->_dbh_autocommit(undef);
 913     $self->savepoints([]);
 914
 915     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 916     #$self->_sql_maker(undef); # this may also end up being different
 917   };
 918
 919   if( $self->_dbh ) {
 920
 921     $self->_do_connection_actions(disconnect_call_ => $_) for (
 922       ( $self->on_disconnect_call || () ),
 923       $self->_parse_connect_do ('on_disconnect_do')
 924     );
 925
 926     # stops the "implicit rollback on disconnect" warning
 927     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 928   }
 929
 930   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 931   # collected before leaving this scope. Depending on the code above, this
 932   # may very well be just a preventive measure guarding future modifications
 933   undef;
 934 }
 935
 936 =head2 with_deferred_fk_checks
 937
 938 =over 4
 939
 940 =item Arguments: C<$coderef>
 941
 942 =item Return Value: The return value of $coderef
 943
 944 =back
 945
 946 Storage specific method to run the code ref with FK checks deferred or
 947 in MySQL's case disabled entirely.
 948
 949 =cut
 950
 951 # Storage subclasses should override this
 952 sub with_deferred_fk_checks {
 953   #my ($self, $sub) = @_;
 954   $_[1]->();
 955 }
 956
 957 =head2 connected
 958
 959 =over
 960
 961 =item Arguments: none
 962
 963 =item Return Value: 1|0
 964
 965 =back
 966
 967 Verifies that the current database handle is active and ready to execute
 968 an SQL statement (e.g. the connection did not get stale, server is still
 969 answering, etc.) This method is used internally by L</dbh>.
 970
 971 =cut
 972
 973 sub connected {
 974   return 0 unless $_[0]->_seems_connected;
 975
 976   #be on the safe side
 977   local $_[0]->_dbh->{RaiseError} = 1;
 978
 979   return $_[0]->_ping;
 980 }
 981
 982 sub _seems_connected {
 983   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 984
 985   $_[0]->_dbh
 986     and
 987   $_[0]->_dbh->FETCH('Active')
 988     and
 989   return 1;
 990
 991   # explicitly reset all state
 992   $_[0]->disconnect;
 993   return 0;
 994 }
 995
 996 sub _ping {
 997   ($_[0]->_dbh || return 0)->ping;
 998 }
 999
1000 sub ensure_connected {
1001   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
1002 }
1003
1004 =head2 dbh
1005
1006 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
1007 is guaranteed to be healthy by implicitly calling L</connected>, and if
1008 necessary performing a reconnection before returning. Keep in mind that this
1009 is very B<expensive> on some database engines. Consider using L</dbh_do>
1010 instead.
1011
1012 =cut
1013
1014 sub dbh {
1015   # maybe save a ping call
1016   $_[0]->_dbh
1017     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
1018     : $_[0]->_populate_dbh
1019   ;
1020 }
1021
1022 # this is the internal "get dbh or connect (don't check)" method
1023 sub _get_dbh {
1024   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1025   $_[0]->_dbh || $_[0]->_populate_dbh;
1026 }
1027
1028 # *DELIBERATELY* not a setter (for the time being)
1029 # Too intertwined with everything else for any kind of sanity
1030 sub sql_maker {
1031   my $self = shift;
1032
1033   $self->throw_exception('sql_maker() is not a setter method') if @_;
1034
1035   unless ($self->_sql_maker) {
1036     my $sql_maker_class = $self->sql_maker_class;
1037
1038     my %opts = %{$self->_sql_maker_opts||{}};
1039     my $dialect =
1040       $opts{limit_dialect}
1041         ||
1042       $self->sql_limit_dialect
1043         ||
1044       do {
1045         my $s_class = (ref $self) || $self;
1046         carp_unique (
1047           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1048         . 'have not supplied an explicit limit_dialect in your connection_info. '
1049         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1050         . 'databases but can be (and often is) painfully slow. '
1051         . "Please file an RT ticket against '$s_class'"
1052         ) if $self->_dbi_connect_info->[0];
1053
1054         'GenericSubQ';
1055       }
1056     ;
1057
1058     my ($quote_char, $name_sep);
1059
1060     if ($opts{quote_names}) {
1061       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1062         my $s_class = (ref $self) || $self;
1063         carp_unique (
1064           "You requested 'quote_names' but your storage class ($s_class) does "
1065         . 'not explicitly define a default sql_quote_char and you have not '
1066         . 'supplied a quote_char as part of your connection_info. DBIC will '
1067         .q{default to the ANSI SQL standard quote '"', which works most of }
1068         . "the time. Please file an RT ticket against '$s_class'."
1069         );
1070
1071         '"'; # RV
1072       };
1073
1074       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1075     }
1076
1077     $self->_sql_maker($sql_maker_class->new(
1078       bindtype=>'columns',
1079       array_datatypes => 1,
1080       limit_dialect => $dialect,
1081       ($quote_char ? (quote_char => $quote_char) : ()),
1082       name_sep => ($name_sep || '.'),
1083       %opts,
1084     ));
1085   }
1086   return $self->_sql_maker;
1087 }
1088
1089 # nothing to do by default
1090 sub _rebless {}
1091 sub _init {}
1092
1093 sub _populate_dbh {
1094
1095   # reset internal states
1096   # also in case ->connected failed we might get sent here
1097   $_[0]->disconnect;
1098
1099   $_[0]->_dbh($_[0]->_connect);
1100
1101   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1102
1103   $_[0]->_determine_driver;
1104
1105   # Always set the transaction depth on connect, since
1106   #  there is no transaction in progress by definition
1107   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1108
1109   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1110
1111   $_[0]->_dbh;
1112 }
1113
1114 sub _run_connection_actions {
1115
1116   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1117     ( $_[0]->on_connect_call || () ),
1118     $_[0]->_parse_connect_do ('on_connect_do'),
1119   );
1120 }
1121
1122
1123
1124 sub set_use_dbms_capability {
1125   $_[0]->set_inherited ($_[1], $_[2]);
1126 }
1127
1128 sub get_use_dbms_capability {
1129   my ($self, $capname) = @_;
1130
1131   my $use = $self->get_inherited ($capname);
1132   return defined $use
1133     ? $use
1134     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1135   ;
1136 }
1137
1138 sub set_dbms_capability {
1139   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1140 }
1141
1142 sub get_dbms_capability {
1143   my ($self, $capname) = @_;
1144
1145   my $cap = $self->_dbh_details->{capability}{$capname};
1146
1147   unless (defined $cap) {
1148     if (my $meth = $self->can ("_determine$capname")) {
1149       $cap = $self->$meth ? 1 : 0;
1150     }
1151     else {
1152       $cap = 0;
1153     }
1154
1155     $self->set_dbms_capability ($capname, $cap);
1156   }
1157
1158   return $cap;
1159 }
1160
1161 sub _server_info {
1162   my $self = shift;
1163
1164   # FIXME - ideally this needs to be an ||= assignment, and the final
1165   # assignment at the end of this do{} should be gone entirely. However
1166   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1167   $self->_dbh_details->{info} || do {
1168
1169     # this guarantees that problematic conninfo won't be hidden
1170     # by the try{} below
1171     $self->ensure_connected;
1172
1173     my $info = {};
1174
1175     my $server_version = dbic_internal_try {
1176       $self->_get_server_version
1177     } catch {
1178       # driver determination *may* use this codepath
1179       # in which case we must rethrow
1180       $self->throw_exception($_) if $self->{_in_determine_driver};
1181
1182       # $server_version on failure
1183       undef;
1184     };
1185
1186     if (defined $server_version) {
1187       $info->{dbms_version} = $server_version;
1188
1189       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1190       my @verparts = split (/\./, $numeric_version);
1191       if (
1192         @verparts
1193           &&
1194         $verparts[0] <= 999
1195       ) {
1196         # consider only up to 3 version parts, iff not more than 3 digits
1197         my @use_parts;
1198         while (@verparts && @use_parts < 3) {
1199           my $p = shift @verparts;
1200           last if $p > 999;
1201           push @use_parts, $p;
1202         }
1203         push @use_parts, 0 while @use_parts < 3;
1204
1205         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1206       }
1207     }
1208
1209     $self->_dbh_details->{info} = $info;
1210   };
1211 }
1212
1213 sub _get_server_version {
1214   shift->_dbh_get_info('SQL_DBMS_VER');
1215 }
1216
1217 sub _dbh_get_info {
1218   my ($self, $info) = @_;
1219
1220   if ($info =~ /[^0-9]/) {
1221     require DBI::Const::GetInfoType;
1222     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1223     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1224       unless defined $info;
1225   }
1226
1227   $self->_get_dbh->get_info($info);
1228 }
1229
1230 sub _describe_connection {
1231   require DBI::Const::GetInfoReturn;
1232
1233   my $self = shift;
1234
1235   my $drv;
1236   dbic_internal_try {
1237     $drv = $self->_extract_driver_from_connect_info;
1238     $self->ensure_connected;
1239   };
1240
1241   $drv = "DBD::$drv" if $drv;
1242
1243   my $res = {
1244     DBIC_DSN => $self->_dbi_connect_info->[0],
1245     DBI_VER => DBI->VERSION,
1246     DBIC_VER => DBIx::Class->VERSION,
1247     DBIC_DRIVER => ref $self,
1248     $drv ? (
1249       DBD => $drv,
1250       DBD_VER => dbic_internal_try { $drv->VERSION },
1251     ) : (),
1252   };
1253
1254   # try to grab data even if we never managed to connect
1255   # will cover us in cases of an oddly broken half-connect
1256   for my $inf (
1257     #keys %DBI::Const::GetInfoType::GetInfoType,
1258     qw/
1259       SQL_CURSOR_COMMIT_BEHAVIOR
1260       SQL_CURSOR_ROLLBACK_BEHAVIOR
1261       SQL_CURSOR_SENSITIVITY
1262       SQL_DATA_SOURCE_NAME
1263       SQL_DBMS_NAME
1264       SQL_DBMS_VER
1265       SQL_DEFAULT_TXN_ISOLATION
1266       SQL_DM_VER
1267       SQL_DRIVER_NAME
1268       SQL_DRIVER_ODBC_VER
1269       SQL_DRIVER_VER
1270       SQL_EXPRESSIONS_IN_ORDERBY
1271       SQL_GROUP_BY
1272       SQL_IDENTIFIER_CASE
1273       SQL_IDENTIFIER_QUOTE_CHAR
1274       SQL_MAX_CATALOG_NAME_LEN
1275       SQL_MAX_COLUMN_NAME_LEN
1276       SQL_MAX_IDENTIFIER_LEN
1277       SQL_MAX_TABLE_NAME_LEN
1278       SQL_MULTIPLE_ACTIVE_TXN
1279       SQL_MULT_RESULT_SETS
1280       SQL_NEED_LONG_DATA_LEN
1281       SQL_NON_NULLABLE_COLUMNS
1282       SQL_ODBC_VER
1283       SQL_QUALIFIER_NAME_SEPARATOR
1284       SQL_QUOTED_IDENTIFIER_CASE
1285       SQL_TXN_CAPABLE
1286       SQL_TXN_ISOLATION_OPTION
1287     /
1288   ) {
1289     # some drivers barf on things they do not know about instead
1290     # of returning undef
1291     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1292     next unless defined $v;
1293
1294     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1295     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1296     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1297   }
1298
1299   $res;
1300 }
1301
1302 sub _determine_driver {
1303   my ($self) = @_;
1304
1305   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1306     my $started_connected = 0;
1307
1308     local $self->{_in_determine_driver} = 1
1309       unless $self->{_in_determine_driver};
1310
1311     if (ref($self) eq __PACKAGE__) {
1312       my $driver;
1313       if ($self->_dbh) { # we are connected
1314         $driver = $self->_dbh->{Driver}{Name};
1315         $started_connected = 1;
1316       }
1317       else {
1318         $driver = $self->_extract_driver_from_connect_info;
1319       }
1320
1321       if ($driver) {
1322         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1323         if ($self->load_optional_class($storage_class)) {
1324
1325           no strict 'refs';
1326           mro::set_mro($storage_class, 'c3') if
1327             (
1328               ${"${storage_class}::__INITIAL_MRO_UPON_DBIC_LOAD__"}
1329                 ||= mro::get_mro($storage_class)
1330             )
1331               ne
1332             'c3'
1333           ;
1334
1335           bless $self, $storage_class;
1336           $self->_rebless();
1337         }
1338         else {
1339           $self->_warn_undetermined_driver(
1340             'This version of DBIC does not yet seem to supply a driver for '
1341           . "your particular RDBMS and/or connection method ('$driver')."
1342           );
1343         }
1344       }
1345       else {
1346         $self->_warn_undetermined_driver(
1347           'Unable to extract a driver name from connect info - this '
1348         . 'should not have happened.'
1349         );
1350       }
1351     }
1352
1353     $self->_driver_determined(1);
1354
1355     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1356
1357     if ($self->can('source_bind_attributes')) {
1358       $self->throw_exception(
1359         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1360       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1361       . 'If you are not sure how to proceed please contact the development team via '
1362       . DBIx::Class::_ENV_::HELP_URL
1363       );
1364     }
1365
1366     $self->_init; # run driver-specific initializations
1367
1368     $self->_run_connection_actions
1369         if !$started_connected && defined $self->_dbh;
1370   }
1371 }
1372
1373 sub _extract_driver_from_connect_info {
1374   my $self = shift;
1375
1376   my $drv;
1377
1378   # if connect_info is a CODEREF, we have no choice but to connect
1379   if (
1380     ref $self->_dbi_connect_info->[0]
1381       and
1382     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1383   ) {
1384     $self->_populate_dbh;
1385     $drv = $self->_dbh->{Driver}{Name};
1386   }
1387   else {
1388     # try to use dsn to not require being connected, the driver may still
1389     # force a connection later in _rebless to determine version
1390     # (dsn may not be supplied at all if all we do is make a mock-schema)
1391     #
1392     # Use the same regex as the one used by DBI itself (even if the use of
1393     # \w is odd given unicode):
1394     # https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L621
1395     #
1396     # DO NOT use https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L559-566
1397     # as there is a long-standing precedent of not loading DBI.pm until the
1398     # very moment we are actually connecting
1399     #
1400     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:(\w*)/i;
1401     $drv ||= $ENV{DBI_DRIVER};
1402   }
1403
1404   return $drv;
1405 }
1406
1407 sub _determine_connector_driver {
1408   my ($self, $conn) = @_;
1409
1410   my $dbtype = $self->_get_rdbms_name;
1411
1412   if (not $dbtype) {
1413     $self->_warn_undetermined_driver(
1414       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1415     . "$conn connector - this should not have happened."
1416     );
1417     return;
1418   }
1419
1420   $dbtype =~ s/\W/_/gi;
1421
1422   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1423   return if $self->isa($subclass);
1424
1425   if ($self->load_optional_class($subclass)) {
1426     bless $self, $subclass;
1427     $self->_rebless;
1428   }
1429   else {
1430     $self->_warn_undetermined_driver(
1431       'This version of DBIC does not yet seem to supply a driver for '
1432     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1433     );
1434   }
1435 }
1436
1437 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1438
1439 sub _warn_undetermined_driver {
1440   my ($self, $msg) = @_;
1441
1442   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1443   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1444   . "does not go away, file a bugreport including the following info:\n"
1445   . dump_value $self->_describe_connection
1446   );
1447 }
1448
1449 sub _do_connection_actions {
1450   my ($self, $method_prefix, $call, @args) = @_;
1451
1452   dbic_internal_try {
1453     if (not ref($call)) {
1454       my $method = $method_prefix . $call;
1455       $self->$method(@args);
1456     }
1457     elsif (ref($call) eq 'CODE') {
1458       $self->$call(@args);
1459     }
1460     elsif (ref($call) eq 'ARRAY') {
1461       if (ref($call->[0]) ne 'ARRAY') {
1462         $self->_do_connection_actions($method_prefix, $_) for @$call;
1463       }
1464       else {
1465         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1466       }
1467     }
1468     else {
1469       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1470     }
1471   }
1472   catch {
1473     if ( $method_prefix =~ /^connect/ ) {
1474       # this is an on_connect cycle - we can't just throw while leaving
1475       # a handle in an undefined state in our storage object
1476       # kill it with fire and rethrow
1477       $self->_dbh(undef);
1478       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1479       $self->throw_exception( $_[0] );
1480     }
1481     else {
1482       carp "Disconnect action failed: $_[0]";
1483     }
1484   };
1485
1486   return $self;
1487 }
1488
1489 sub connect_call_do_sql {
1490   my $self = shift;
1491   $self->_do_query(@_);
1492 }
1493
1494 sub disconnect_call_do_sql {
1495   my $self = shift;
1496   $self->_do_query(@_);
1497 }
1498
1499 =head2 connect_call_datetime_setup
1500
1501 A no-op stub method, provided so that one can always safely supply the
1502 L<connection option|/DBIx::Class specific connection attributes>
1503
1504  on_connect_call => 'datetime_setup'
1505
1506 This way one does not need to know in advance whether the underlying
1507 storage requires any sort of hand-holding when dealing with calendar
1508 data.
1509
1510 =cut
1511
1512 sub connect_call_datetime_setup { 1 }
1513
1514 sub _do_query {
1515   my ($self, $action) = @_;
1516
1517   if (ref $action eq 'CODE') {
1518     $action = $action->($self);
1519     $self->_do_query($_) foreach @$action;
1520   }
1521   else {
1522     # Most debuggers expect ($sql, @bind), so we need to exclude
1523     # the attribute hash which is the second argument to $dbh->do
1524     # furthermore the bind values are usually to be presented
1525     # as named arrayref pairs, so wrap those here too
1526     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1527     my $sql = shift @do_args;
1528     my $attrs = shift @do_args;
1529     my @bind = map { [ undef, $_ ] } @do_args;
1530
1531     $self->dbh_do(sub {
1532       $_[0]->_query_start($sql, \@bind);
1533       $_[1]->do($sql, $attrs, @do_args);
1534       $_[0]->_query_end($sql, \@bind);
1535     });
1536   }
1537
1538   return $self;
1539 }
1540
1541 sub _connect {
1542   my $self = shift;
1543
1544   my $info = $self->_dbi_connect_info;
1545
1546   $self->throw_exception("You did not provide any connection_info")
1547     unless defined $info->[0];
1548
1549   my ($old_connect_via, $dbh);
1550
1551   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1552
1553   # this odd anonymous coderef dereference is in fact really
1554   # necessary to avoid the unwanted effect described in perl5
1555   # RT#75792
1556   #
1557   # in addition the coderef itself can't reside inside the try{} block below
1558   # as it somehow triggers a leak under perl -d
1559   my $dbh_error_handler_installer = sub {
1560     weaken (my $weak_self = $_[0]);
1561
1562     # the coderef is blessed so we can distinguish it from externally
1563     # supplied handles (which must be preserved)
1564     $_[1]->{HandleError} = bless sub {
1565       if ($weak_self) {
1566         $weak_self->throw_exception("DBI Exception: $_[0]");
1567       }
1568       else {
1569         # the handler may be invoked by something totally out of
1570         # the scope of DBIC
1571         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1572       }
1573     }, '__DBIC__DBH__ERROR__HANDLER__';
1574   };
1575
1576   dbic_internal_try {
1577     if(ref $info->[0] eq 'CODE') {
1578       $dbh = $info->[0]->();
1579     }
1580     else {
1581       require DBI;
1582       $dbh = DBI->connect(@$info);
1583     }
1584
1585     die $DBI::errstr unless $dbh;
1586
1587     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1588       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1589       . 'not continue',
1590       ref $info->[0] eq 'CODE'
1591         ? "Connection coderef $info->[0] returned a"
1592         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1593     ) unless $dbh->FETCH('Active');
1594
1595     # sanity checks unless asked otherwise
1596     unless ($self->unsafe) {
1597
1598       $self->throw_exception(
1599         'Refusing clobbering of {HandleError} installed on externally supplied '
1600        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1601       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1602
1603       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1604       # request, or an external handle. Complain and set anyway
1605       unless ($dbh->{RaiseError}) {
1606         carp( ref $info->[0] eq 'CODE'
1607
1608           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1609            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1610            .'attribute has been supplied'
1611
1612           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1613            .'unsafe => 1. Toggling RaiseError back to true'
1614         );
1615
1616         $dbh->{RaiseError} = 1;
1617       }
1618
1619       $dbh_error_handler_installer->($self, $dbh);
1620     }
1621   }
1622   catch {
1623     $self->throw_exception("DBI Connection failed: $_")
1624   };
1625
1626   $self->_dbh_autocommit($dbh->{AutoCommit});
1627   return $dbh;
1628 }
1629
1630 sub txn_begin {
1631   # this means we have not yet connected and do not know the AC status
1632   # (e.g. coderef $dbh), need a full-fledged connection check
1633   if (! defined $_[0]->_dbh_autocommit) {
1634     $_[0]->ensure_connected;
1635   }
1636   # Otherwise simply connect or re-connect on pid changes
1637   else {
1638     $_[0]->_get_dbh;
1639   }
1640
1641   shift->next::method(@_);
1642 }
1643
1644 sub _exec_txn_begin {
1645   my $self = shift;
1646
1647   # if the user is utilizing txn_do - good for him, otherwise we need to
1648   # ensure that the $dbh is healthy on BEGIN.
1649   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1650   # will be replaced by a failure of begin_work itself (which will be
1651   # then retried on reconnect)
1652   if ($self->{_in_do_block}) {
1653     $self->_dbh->begin_work;
1654   } else {
1655     $self->dbh_do(sub { $_[1]->begin_work });
1656   }
1657 }
1658
1659 sub txn_commit {
1660   my $self = shift;
1661
1662   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1663     unless $self->_seems_connected;
1664
1665   # esoteric case for folks using external $dbh handles
1666   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1667     carp "Storage transaction_depth 0 does not match "
1668         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1669     $self->transaction_depth(1);
1670   }
1671
1672   $self->next::method(@_);
1673
1674   # if AutoCommit is disabled txn_depth never goes to 0
1675   # as a new txn is started immediately on commit
1676   $self->transaction_depth(1) if (
1677     !$self->transaction_depth
1678       and
1679     defined $self->_dbh_autocommit
1680       and
1681     ! $self->_dbh_autocommit
1682   );
1683 }
1684
1685 sub _exec_txn_commit {
1686   shift->_dbh->commit;
1687 }
1688
1689 sub txn_rollback {
1690   my $self = shift;
1691
1692   # do a minimal connectivity check due to weird shit like
1693   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1694   $self->throw_exception("lost connection to storage")
1695     unless $self->_seems_connected;
1696
1697   # esoteric case for folks using external $dbh handles
1698   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1699     carp "Storage transaction_depth 0 does not match "
1700         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1701     $self->transaction_depth(1);
1702   }
1703
1704   $self->next::method(@_);
1705
1706   # if AutoCommit is disabled txn_depth never goes to 0
1707   # as a new txn is started immediately on commit
1708   $self->transaction_depth(1) if (
1709     !$self->transaction_depth
1710       and
1711     defined $self->_dbh_autocommit
1712       and
1713     ! $self->_dbh_autocommit
1714   );
1715 }
1716
1717 sub _exec_txn_rollback {
1718   shift->_dbh->rollback;
1719 }
1720
1721 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1722 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1723   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1724     unless $_[0]->_seems_connected;
1725   shift->next::method(@_);
1726 EOS
1727
1728 # This used to be the top-half of _execute.  It was split out to make it
1729 #  easier to override in NoBindVars without duping the rest.  It takes up
1730 #  all of _execute's args, and emits $sql, @bind.
1731 sub _prep_for_execute {
1732   #my ($self, $op, $ident, $args) = @_;
1733   return shift->_gen_sql_bind(@_)
1734 }
1735
1736 sub _gen_sql_bind {
1737   my ($self, $op, $ident, $args) = @_;
1738
1739   my ($colinfos, $from);
1740   if ( blessed($ident) ) {
1741     $from = $ident->from;
1742     $colinfos = $ident->columns_info;
1743   }
1744
1745   my ($sql, $bind);
1746   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1747
1748   $bind = $self->_resolve_bindattrs(
1749     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1750   );
1751
1752   if (
1753     ! $ENV{DBIC_DT_SEARCH_OK}
1754       and
1755     $op eq 'select'
1756       and
1757     grep {
1758       length ref $_->[1]
1759         and
1760       blessed($_->[1])
1761         and
1762       $_->[1]->isa('DateTime')
1763     } @$bind
1764   ) {
1765     carp_unique 'DateTime objects passed to search() are not supported '
1766       . 'properly (InflateColumn::DateTime formats and settings are not '
1767       . 'respected.) See ".. format a DateTime object for searching?" in '
1768       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1769       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1770   }
1771
1772   return( $sql, $bind );
1773 }
1774
1775 sub _resolve_bindattrs {
1776   my ($self, $ident, $bind, $colinfos) = @_;
1777
1778   my $resolve_bindinfo = sub {
1779     #my $infohash = shift;
1780
1781     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1782
1783     my $ret;
1784     if (my $col = $_[0]->{dbic_colname}) {
1785       $ret = { %{$_[0]} };
1786
1787       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1788         if $colinfos->{$col}{data_type};
1789
1790       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1791         if $colinfos->{$col}{size};
1792     }
1793
1794     $ret || $_[0];
1795   };
1796
1797   return [ map {
1798       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1799     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1800     : (ref $_->[0] eq 'HASH')           ? [(
1801                                             ! keys %{$_->[0]}
1802                                               or
1803                                             exists $_->[0]{dbd_attrs}
1804                                               or
1805                                             $_->[0]{sqlt_datatype}
1806                                            ) ? $_->[0]
1807                                              : $resolve_bindinfo->($_->[0])
1808                                            , $_->[1]
1809                                           ]
1810     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1811     :                                     [ $resolve_bindinfo->(
1812                                               { dbic_colname => $_->[0] }
1813                                             ), $_->[1] ]
1814   } @$bind ];
1815 }
1816
1817 sub _format_for_trace {
1818   #my ($self, $bind) = @_;
1819
1820   ### Turn @bind from something like this:
1821   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1822   ### to this:
1823   ###   ( "'1'", "'3'" )
1824
1825   map {
1826     defined( $_ && $_->[1] )
1827       ? sprintf( "'%s'", "$_->[1]" )  # because overload
1828       : q{NULL}
1829   } @{$_[1] || []};
1830 }
1831
1832 sub _query_start {
1833   my ( $self, $sql, $bind ) = @_;
1834
1835   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1836     if $self->debug;
1837 }
1838
1839 sub _query_end {
1840   my ( $self, $sql, $bind ) = @_;
1841
1842   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1843     if $self->debug;
1844 }
1845
1846 sub _dbi_attrs_for_bind {
1847   #my ($self, $ident, $bind) = @_;
1848
1849   return [ map {
1850
1851     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1852
1853   : ! $_->{sqlt_datatype}   ? undef
1854
1855   :                           do {
1856
1857     # cache the result in the dbh_details hash, as it (usually) can not change
1858     # unless we connect to something else
1859     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1860     # the LOB storage
1861     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1862
1863     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1864       if ! exists $cache->{$_->{sqlt_datatype}};
1865
1866     $cache->{$_->{sqlt_datatype}};
1867
1868   } } map { $_->[0] } @{$_[2]} ];
1869 }
1870
1871 sub _execute {
1872   my ($self, $op, $ident, @args) = @_;
1873
1874   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1875
1876   # not even a PID check - we do not care about the state of the _dbh.
1877   # All we need is to get the appropriate drivers loaded if they aren't
1878   # already so that the assumption in ad7c50fc26e holds
1879   $self->_populate_dbh unless $self->_dbh;
1880
1881   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1882     $sql,
1883     $bind,
1884     $self->_dbi_attrs_for_bind($ident, $bind),
1885   );
1886 }
1887
1888 sub _dbh_execute {
1889   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1890
1891   $self->_query_start( $sql, $bind );
1892
1893   my $sth = $self->_bind_sth_params(
1894     $self->_prepare_sth($dbh, $sql),
1895     $bind,
1896     $bind_attrs,
1897   );
1898
1899   # Can this fail without throwing an exception anyways???
1900   my $rv = $sth->execute();
1901   $self->throw_exception(
1902     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1903   ) if !$rv;
1904
1905   $self->_query_end( $sql, $bind );
1906
1907   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1908 }
1909
1910 sub _prepare_sth {
1911   my ($self, $dbh, $sql) = @_;
1912
1913   # 3 is the if_active parameter which avoids active sth re-use
1914   my $sth = $self->disable_sth_caching
1915     ? $dbh->prepare($sql)
1916     : $dbh->prepare_cached($sql, {}, 3);
1917
1918   # XXX You would think RaiseError would make this impossible,
1919   #  but apparently that's not true :(
1920   $self->throw_exception(
1921     $dbh->errstr
1922       ||
1923     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1924             .'an exception and/or setting $dbh->errstr',
1925       length ($sql) > 20
1926         ? substr($sql, 0, 20) . '...'
1927         : $sql
1928       ,
1929       'DBD::' . $dbh->{Driver}{Name},
1930     )
1931   ) if !$sth;
1932
1933   $sth;
1934 }
1935
1936 sub _bind_sth_params {
1937   my ($self, $sth, $bind, $bind_attrs) = @_;
1938
1939   for my $i (0 .. $#$bind) {
1940     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1941       $sth->bind_param_inout(
1942         $i + 1, # bind params counts are 1-based
1943         $bind->[$i][1],
1944         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1945         $bind_attrs->[$i],
1946       );
1947     }
1948     else {
1949       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1950       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1951         ? "$bind->[$i][1]"
1952         : $bind->[$i][1]
1953       ;
1954
1955       $sth->bind_param(
1956         $i + 1,
1957         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1958         $v,
1959         $bind_attrs->[$i],
1960       );
1961     }
1962   }
1963
1964   $sth;
1965 }
1966
1967 sub _prefetch_autovalues {
1968   my ($self, $source, $colinfo, $to_insert) = @_;
1969
1970   my %values;
1971   for my $col (keys %$colinfo) {
1972     if (
1973       $colinfo->{$col}{auto_nextval}
1974         and
1975       (
1976         ! exists $to_insert->{$col}
1977           or
1978         is_literal_value($to_insert->{$col})
1979       )
1980     ) {
1981       $values{$col} = $self->_sequence_fetch(
1982         'NEXTVAL',
1983         ( $colinfo->{$col}{sequence} ||=
1984             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1985         ),
1986       );
1987     }
1988   }
1989
1990   \%values;
1991 }
1992
1993 sub insert {
1994   my ($self, $source, $to_insert) = @_;
1995
1996   my $col_infos = $source->columns_info;
1997
1998   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1999
2000   # fuse the values, but keep a separate list of prefetched_values so that
2001   # they can be fused once again with the final return
2002   $to_insert = { %$to_insert, %$prefetched_values };
2003
2004   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
2005   # Investigate what does it take to s/defined/exists/
2006   my %pcols = map { $_ => 1 } $source->primary_columns;
2007   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
2008   for my $col ($source->columns) {
2009     if ($col_infos->{$col}{is_auto_increment}) {
2010       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
2011       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
2012     }
2013
2014     # nothing to retrieve when explicit values are supplied
2015     next if (
2016       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
2017     );
2018
2019     # the 'scalar keys' is a trick to preserve the ->columns declaration order
2020     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
2021       $pcols{$col}
2022         or
2023       $col_infos->{$col}{retrieve_on_insert}
2024     );
2025   };
2026
2027   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
2028   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
2029
2030   my ($sqla_opts, @ir_container);
2031   if (%retrieve_cols and $self->_use_insert_returning) {
2032     $sqla_opts->{returning_container} = \@ir_container
2033       if $self->_use_insert_returning_bound;
2034
2035     $sqla_opts->{returning} = [
2036       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
2037     ];
2038   }
2039
2040   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2041
2042   my %returned_cols = %$to_insert;
2043   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2044
2045     unless( @ir_container ) {
2046       dbic_internal_try {
2047
2048         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2049         local $SIG{__WARN__} = sub {};
2050
2051         @ir_container = $sth->fetchrow_array;
2052         $sth->finish;
2053
2054       } catch {
2055         # Evict the $sth from the cache in case we got here, since the finish()
2056         # is crucial, at least on older Firebirds, possibly on other engines too
2057         #
2058         # It would be too complex to make this a proper subclass override,
2059         # and besides we already take the try{} penalty, adding a catch that
2060         # triggers infrequently is a no-brainer
2061         #
2062         if( my $kids = $self->_dbh->{CachedKids} ) {
2063           $kids->{$_} == $sth and delete $kids->{$_}
2064             for keys %$kids
2065         }
2066       };
2067     }
2068
2069     @returned_cols{@$retlist} = @ir_container if @ir_container;
2070   }
2071   else {
2072     # pull in PK if needed and then everything else
2073     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2074
2075       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2076         unless $self->can('last_insert_id');
2077
2078       my @pri_values = $self->last_insert_id($source, @missing_pri);
2079
2080       $self->throw_exception( "Can't get last insert id" )
2081         unless (@pri_values == @missing_pri);
2082
2083       @returned_cols{@missing_pri} = @pri_values;
2084       delete @retrieve_cols{@missing_pri};
2085     }
2086
2087     # if there is more left to pull
2088     if (%retrieve_cols) {
2089       $self->throw_exception(
2090         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2091       ) unless %pcols;
2092
2093       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2094
2095       my $cur = DBIx::Class::ResultSet->new($source, {
2096         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2097         select => \@left_to_fetch,
2098       })->cursor;
2099
2100       @returned_cols{@left_to_fetch} = $cur->next;
2101
2102       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2103         if scalar $cur->next;
2104     }
2105   }
2106
2107   return { %$prefetched_values, %returned_cols };
2108 }
2109
2110 sub insert_bulk {
2111   carp_unique(
2112     'insert_bulk() should have never been exposed as a public method and '
2113   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2114   . 'use for this method please contact the development team via '
2115   . DBIx::Class::_ENV_::HELP_URL
2116   );
2117
2118   return '0E0' unless @{$_[3]||[]};
2119
2120   shift->_insert_bulk(@_);
2121 }
2122
2123 sub _insert_bulk {
2124   my ($self, $source, $cols, $data) = @_;
2125
2126   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2127     unless @{$data||[]};
2128
2129   my $colinfos = $source->columns_info($cols);
2130
2131   local $self->{_autoinc_supplied_for_op} =
2132     (grep { $_->{is_auto_increment} } values %$colinfos)
2133       ? 1
2134       : 0
2135   ;
2136
2137   # get a slice type index based on first row of data
2138   # a "column" in this context may refer to more than one bind value
2139   # e.g. \[ '?, ?', [...], [...] ]
2140   #
2141   # construct the value type index - a description of values types for every
2142   # per-column slice of $data:
2143   #
2144   # nonexistent - nonbind literal
2145   # 0 - regular value
2146   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2147   #
2148   # also construct the column hash to pass to the SQL generator. For plain
2149   # (non literal) values - convert the members of the first row into a
2150   # literal+bind combo, with extra positional info in the bind attr hashref.
2151   # This will allow us to match the order properly, and is so contrived
2152   # because a user-supplied literal/bind (or something else specific to a
2153   # resultsource and/or storage driver) can inject extra binds along the
2154   # way, so one can't rely on "shift positions" ordering at all. Also we
2155   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2156   # can be later matched up by address), because we want to supply a real
2157   # value on which perhaps e.g. datatype checks will be performed
2158   my ($proto_data, $serialized_bind_type_by_col_idx);
2159   for my $col_idx (0..$#$cols) {
2160     my $colname = $cols->[$col_idx];
2161     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2162       # no bind value at all - no type
2163
2164       $proto_data->{$colname} = $data->[0][$col_idx];
2165     }
2166     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2167       # repack, so we don't end up mangling the original \[]
2168       my ($sql, @bind) = @${$data->[0][$col_idx]};
2169
2170       # normalization of user supplied stuff
2171       my $resolved_bind = $self->_resolve_bindattrs(
2172         $source, \@bind, $colinfos,
2173       );
2174
2175       # store value-less (attrs only) bind info - we will be comparing all
2176       # supplied binds against this for sanity
2177       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2178
2179       $proto_data->{$colname} = \[ $sql, map { [
2180         # inject slice order to use for $proto_bind construction
2181           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2182             =>
2183           $resolved_bind->[$_][1]
2184         ] } (0 .. $#bind)
2185       ];
2186     }
2187     else {
2188       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2189
2190       $proto_data->{$colname} = \[ '?', [
2191         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2192           =>
2193         $data->[0][$col_idx]
2194       ] ];
2195     }
2196   }
2197
2198   my ($sql, $proto_bind) = $self->_prep_for_execute (
2199     'insert',
2200     $source,
2201     [ $proto_data ],
2202   );
2203
2204   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2205     # if the bindlist is empty and we had some dynamic binds, this means the
2206     # storage ate them away (e.g. the NoBindVars component) and interpolated
2207     # them directly into the SQL. This obviously can't be good for multi-inserts
2208     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2209   }
2210
2211   # sanity checks
2212   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2213   #
2214   # use an error reporting closure for convenience (less to pass)
2215   my $bad_slice_report_cref = sub {
2216     my ($msg, $r_idx, $c_idx) = @_;
2217     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2218       $msg,
2219       $cols->[$c_idx],
2220       do {
2221         local $Data::Dumper::Maxdepth = 5;
2222         dump_value {
2223           map { $cols->[$_] =>
2224             $data->[$r_idx][$_]
2225           } 0..$#$cols
2226         };
2227       }
2228     );
2229   };
2230
2231   for my $col_idx (0..$#$cols) {
2232     my $reference_val = $data->[0][$col_idx];
2233
2234     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2235       my $val = $data->[$row_idx][$col_idx];
2236
2237       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2238         if (ref $val ne 'SCALAR') {
2239           $bad_slice_report_cref->(
2240             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2241             $row_idx,
2242             $col_idx,
2243           );
2244         }
2245         elsif ($$val ne $$reference_val) {
2246           $bad_slice_report_cref->(
2247             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2248             $row_idx,
2249             $col_idx,
2250           );
2251         }
2252       }
2253       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2254         if (is_literal_value($val)) {
2255           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2256         }
2257       }
2258       else {  # binds from a \[], compare type and attrs
2259         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2260           $bad_slice_report_cref->(
2261             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2262             $row_idx,
2263             $col_idx,
2264           );
2265         }
2266         # start drilling down and bail out early on identical refs
2267         elsif (
2268           $reference_val != $val
2269             or
2270           $$reference_val != $$val
2271         ) {
2272           if (${$val}->[0] ne ${$reference_val}->[0]) {
2273             $bad_slice_report_cref->(
2274               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2275               $row_idx,
2276               $col_idx,
2277             );
2278           }
2279           # need to check the bind attrs - a bind will happen only once for
2280           # the entire dataset, so any changes further down will be ignored.
2281           elsif (
2282             $serialized_bind_type_by_col_idx->{$col_idx}
2283               ne
2284             serialize [
2285               map
2286               { $_->[0] }
2287               @{$self->_resolve_bindattrs(
2288                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2289               )}
2290             ]
2291           ) {
2292             $bad_slice_report_cref->(
2293               'Differing bind attributes on literal/bind values not supported',
2294               $row_idx,
2295               $col_idx,
2296             );
2297           }
2298         }
2299       }
2300     }
2301   }
2302
2303   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2304   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2305   # scope guard
2306   my $guard = $self->txn_scope_guard;
2307
2308   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2309   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2310   my $rv = do {
2311     if (@$proto_bind) {
2312       # proto bind contains the information on which pieces of $data to pull
2313       # $cols is passed in only for prettier error-reporting
2314       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2315     }
2316     else {
2317       # bind_param_array doesn't work if there are no binds
2318       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2319     }
2320   };
2321
2322   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2323
2324   $guard->commit;
2325
2326   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2327 }
2328
2329 # execute_for_fetch is capable of returning data just fine (it means it
2330 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2331 # is the void-populate fast-path we will just ignore this altogether
2332 # for the time being.
2333 sub _dbh_execute_for_fetch {
2334   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2335
2336   # If we have any bind attributes to take care of, we will bind the
2337   # proto-bind data (which will never be used by execute_for_fetch)
2338   # However since column bindtypes are "sticky", this is sufficient
2339   # to get the DBD to apply the bindtype to all values later on
2340   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2341
2342   for my $i (0 .. $#$proto_bind) {
2343     $sth->bind_param (
2344       $i+1, # DBI bind indexes are 1-based
2345       $proto_bind->[$i][1],
2346       $bind_attrs->[$i],
2347     ) if defined $bind_attrs->[$i];
2348   }
2349
2350   # At this point $data slots named in the _bind_data_slice_idx of
2351   # each piece of $proto_bind are either \[]s or plain values to be
2352   # passed in. Construct the dispensing coderef. *NOTE* the order
2353   # of $data will differ from this of the ?s in the SQL (due to
2354   # alphabetical ordering by colname). We actually do want to
2355   # preserve this behavior so that prepare_cached has a better
2356   # chance of matching on unrelated calls
2357
2358   my $fetch_row_idx = -1; # saner loop this way
2359   my $fetch_tuple = sub {
2360     return undef if ++$fetch_row_idx > $#$data;
2361
2362     return [ map {
2363       my $v = ! defined $_->{_literal_bind_subindex}
2364
2365         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2366
2367         # There are no attributes to resolve here - we already did everything
2368         # when we constructed proto_bind. However we still want to sanity-check
2369         # what the user supplied, so pass stuff through to the resolver *anyway*
2370         : $self->_resolve_bindattrs (
2371             undef,  # a fake rsrc
2372             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2373             {},     # a fake column_info bag
2374           )->[0][1]
2375       ;
2376
2377       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2378       # For the time being forcibly stringify whatever is stringifiable
2379       my $vref;
2380
2381       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2382     : defined blessed( $$vref )                             ? "$$vref"
2383                                                             : $$vref
2384     ;
2385     } map { $_->[0] } @$proto_bind ];
2386   };
2387
2388   my $tuple_status = [];
2389   my ($rv, $err);
2390   dbic_internal_try {
2391     $rv = $sth->execute_for_fetch(
2392       $fetch_tuple,
2393       $tuple_status,
2394     );
2395   }
2396   catch {
2397     $err = shift;
2398   };
2399
2400   # Not all DBDs are create equal. Some throw on error, some return
2401   # an undef $rv, and some set $sth->err - try whatever we can
2402   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2403     ! defined $err
2404       and
2405     ( !defined $rv or $sth->err )
2406   );
2407
2408   # Statement must finish even if there was an exception.
2409   dbic_internal_try {
2410     $sth->finish
2411   }
2412   catch {
2413     $err = shift unless defined $err
2414   };
2415
2416   if (defined $err) {
2417     my $i = 0;
2418     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2419
2420     $self->throw_exception("Unexpected populate error: $err")
2421       if ($i > $#$tuple_status);
2422
2423     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2424       ($tuple_status->[$i][1] || $err),
2425       dump_value { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) },
2426     );
2427   }
2428
2429   return $rv;
2430 }
2431
2432 sub _dbh_execute_inserts_with_no_binds {
2433   my ($self, $sth, $count) = @_;
2434
2435   my $err;
2436   dbic_internal_try {
2437     my $dbh = $self->_get_dbh;
2438     local $dbh->{RaiseError} = 1;
2439     local $dbh->{PrintError} = 0;
2440
2441     $sth->execute foreach 1..$count;
2442   }
2443   catch {
2444     $err = shift;
2445   };
2446
2447   # Make sure statement is finished even if there was an exception.
2448   dbic_internal_try {
2449     $sth->finish
2450   }
2451   catch {
2452     $err = shift unless defined $err;
2453   };
2454
2455   $self->throw_exception($err) if defined $err;
2456
2457   return $count;
2458 }
2459
2460 sub update {
2461   #my ($self, $source, @args) = @_;
2462   shift->_execute('update', @_);
2463 }
2464
2465
2466 sub delete {
2467   #my ($self, $source, @args) = @_;
2468   shift->_execute('delete', @_);
2469 }
2470
2471 sub _select {
2472   my $self = shift;
2473   $self->_execute($self->_select_args(@_));
2474 }
2475
2476 sub _select_args_to_query {
2477   my $self = shift;
2478
2479   $self->throw_exception(
2480     "Unable to generate limited query representation with 'software_limit' enabled"
2481   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2482
2483   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2484   #  = $self->_select_args($ident, $select, $cond, $attrs);
2485   my ($op, $ident, @args) =
2486     $self->_select_args(@_);
2487
2488   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2489   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2490
2491   # reuse the bind arrayref
2492   unshift @{$bind}, "($sql)";
2493   \$bind;
2494 }
2495
2496 sub _select_args {
2497   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2498
2499   # FIXME - that kind of caching would be nice to have
2500   # however currently we *may* pass the same $orig_attrs
2501   # with different ident/select/where
2502   # the whole interface needs to be rethought, since it
2503   # was centered around the flawed SQLA API. We can do
2504   # soooooo much better now. But that is also another
2505   # battle...
2506   #return (
2507   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2508   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2509
2510   my $sql_maker = $self->sql_maker;
2511
2512   my $attrs = {
2513     %$orig_attrs,
2514     select => $select,
2515     from => $ident,
2516     where => $where,
2517   };
2518
2519   # MySQL actually recommends this approach.  I cringe.
2520   $attrs->{rows} ||= $sql_maker->__max_int
2521     if $attrs->{offset};
2522
2523   # see if we will need to tear the prefetch apart to satisfy group_by == select
2524   # this is *extremely tricky* to get right, I am still not sure I did
2525   #
2526   my ($prefetch_needs_subquery, @limit_args);
2527
2528   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2529     # we already know there is a valid group_by (we made it) and we know it is
2530     # intended to be based *only* on non-multi stuff
2531     # short circuit the group_by parsing below
2532     $prefetch_needs_subquery = 1;
2533   }
2534   elsif (
2535     # The rationale is that even if we do *not* have collapse, we still
2536     # need to wrap the core grouped select/group_by in a subquery
2537     # so that databases that care about group_by/select equivalence
2538     # are happy (this includes MySQL in strict_mode)
2539     # If any of the other joined tables are referenced in the group_by
2540     # however - the user is on their own
2541     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2542       and
2543     $attrs->{group_by}
2544       and
2545     @{$attrs->{group_by}}
2546       and
2547     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2548       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2549     }
2550   ) {
2551     # no aliases other than our own in group_by
2552     # if there are - do not allow subquery even if limit is present
2553     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2554   }
2555   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2556     # active collapse with a limit - that one is a no-brainer unless
2557     # overruled by a group_by above
2558     $prefetch_needs_subquery = 1;
2559   }
2560
2561   if ($prefetch_needs_subquery) {
2562     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2563   }
2564   elsif (! $attrs->{software_limit} ) {
2565     push @limit_args, (
2566       $attrs->{rows} || (),
2567       $attrs->{offset} || (),
2568     );
2569   }
2570
2571   # try to simplify the joinmap further (prune unreferenced type-single joins)
2572   if (
2573     ! $prefetch_needs_subquery  # already pruned
2574       and
2575     ref $attrs->{from}
2576       and
2577     reftype $attrs->{from} eq 'ARRAY'
2578       and
2579     @{$attrs->{from}} != 1
2580   ) {
2581     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2582   }
2583
2584   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2585   # during the result inflation stage we *need* to know what was the aliastype
2586   # map as sqla saw it when the final pieces of SQL were being assembled
2587   # Originally we simply carried around the entirety of $attrs, but this
2588   # resulted in resultsets that are being reused growing continuously, as
2589   # the hash in question grew deeper and deeper.
2590   # Instead hand-pick what to take with us here (we actually don't need much
2591   # at this point just the map itself)
2592   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2593
2594 ###
2595   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2596   #
2597   # This would be the point to deflate anything found in $attrs->{where}
2598   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2599   # expect a result object. And all we have is a resultsource (it is trivial
2600   # to extract deflator coderefs via $alias2source above).
2601   #
2602   # I don't see a way forward other than changing the way deflators are
2603   # invoked, and that's just bad...
2604 ###
2605
2606   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2607 }
2608
2609 # Returns a counting SELECT for a simple count
2610 # query. Abstracted so that a storage could override
2611 # this to { count => 'firstcol' } or whatever makes
2612 # sense as a performance optimization
2613 sub _count_select {
2614   #my ($self, $source, $rs_attrs) = @_;
2615   return { count => '*' };
2616 }
2617
2618 =head2 select
2619
2620 =over 4
2621
2622 =item Arguments: $ident, $select, $condition, $attrs
2623
2624 =back
2625
2626 Handle a SQL select statement.
2627
2628 =cut
2629
2630 sub select {
2631   my $self = shift;
2632   my ($ident, $select, $condition, $attrs) = @_;
2633   return $self->cursor_class->new($self, \@_, $attrs);
2634 }
2635
2636 sub select_single {
2637   my $self = shift;
2638   my ($rv, $sth, @bind) = $self->_select(@_);
2639   my @row = $sth->fetchrow_array;
2640   my @nextrow = $sth->fetchrow_array if @row;
2641   if(@row && @nextrow) {
2642     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2643   }
2644   # Need to call finish() to work round broken DBDs
2645   $sth->finish();
2646   return @row;
2647 }
2648
2649 =head2 sql_limit_dialect
2650
2651 This is an accessor for the default SQL limit dialect used by a particular
2652 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2653 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2654 see L<DBIx::Class::SQLMaker::LimitDialects>.
2655
2656 =cut
2657
2658 sub _dbh_columns_info_for {
2659   my ($self, $dbh, $table) = @_;
2660
2661   my %result;
2662
2663   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2664     dbic_internal_try {
2665       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2666       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2667       $sth->execute();
2668       while ( my $info = $sth->fetchrow_hashref() ){
2669         my %column_info;
2670         $column_info{data_type}   = $info->{TYPE_NAME};
2671         $column_info{size}      = $info->{COLUMN_SIZE};
2672         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2673         $column_info{default_value} = $info->{COLUMN_DEF};
2674         my $col_name = $info->{COLUMN_NAME};
2675         $col_name =~ s/^\"(.*)\"$/$1/;
2676
2677         $result{$col_name} = \%column_info;
2678       }
2679     } catch {
2680       %result = ();
2681     };
2682
2683     return \%result if keys %result;
2684   }
2685
2686   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2687   $sth->execute;
2688
2689 ### The acrobatics with lc names is necessary to support both the legacy
2690 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2691 ### with column names differing in cas eonly (thanks pg!)
2692
2693   my ($columns, $seen_lcs);
2694
2695   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2696     idx => scalar keys %$columns,
2697     name => $_,
2698     lc_name => lc($_),
2699   } for @{$sth->{NAME}};
2700
2701   $seen_lcs->{$_->{lc_name}} == 1
2702     and
2703   $_->{name} = $_->{lc_name}
2704     for values %$columns;
2705
2706   for ( values %$columns ) {
2707     my $inf = {
2708       data_type => $sth->{TYPE}->[$_->{idx}],
2709       size => $sth->{PRECISION}->[$_->{idx}],
2710       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2711     };
2712
2713     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2714       @{$inf}{qw( data_type  size)} = ($1, $2);
2715     }
2716
2717     $result{$_->{name}} = $inf;
2718   }
2719
2720   $sth->finish;
2721
2722   if ($dbh->can('type_info')) {
2723     for my $inf (values %result) {
2724       next if ! defined $inf->{data_type};
2725
2726       $inf->{data_type} = (
2727         (
2728           (
2729             $dbh->type_info( $inf->{data_type} )
2730               ||
2731             next
2732           )
2733             ||
2734           next
2735         )->{TYPE_NAME}
2736           ||
2737         next
2738       );
2739
2740       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2741       # needs more testing in the future...
2742       $inf->{size} -= 4 if (
2743         ( $inf->{size}||0 > 4 )
2744           and
2745         $inf->{data_type} =~ qr/^text$/i
2746       );
2747     }
2748
2749   }
2750
2751   return \%result;
2752 }
2753
2754 sub columns_info_for {
2755   my ($self, $table) = @_;
2756   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2757 }
2758
2759 =head2 last_insert_id
2760
2761 Return the row id of the last insert.
2762
2763 =cut
2764
2765 sub _dbh_last_insert_id {
2766     my ($self, $dbh, $source, $col) = @_;
2767
2768     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2769
2770     return $id if defined $id;
2771
2772     my $class = ref $self;
2773     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2774 }
2775
2776 sub last_insert_id {
2777   my $self = shift;
2778   $self->_dbh_last_insert_id ($self->_dbh, @_);
2779 }
2780
2781 =head2 _native_data_type
2782
2783 =over 4
2784
2785 =item Arguments: $type_name
2786
2787 =back
2788
2789 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2790 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2791 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2792
2793 The default implementation returns C<undef>, implement in your Storage driver if
2794 you need this functionality.
2795
2796 Should map types from other databases to the native RDBMS type, for example
2797 C<VARCHAR2> to C<VARCHAR>.
2798
2799 Types with modifiers should map to the underlying data type. For example,
2800 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2801
2802 Composite types should map to the container type, for example
2803 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2804
2805 =cut
2806
2807 sub _native_data_type {
2808   #my ($self, $data_type) = @_;
2809   return undef
2810 }
2811
2812 # Check if placeholders are supported at all
2813 sub _determine_supports_placeholders {
2814   my $self = shift;
2815   my $dbh  = $self->_get_dbh;
2816
2817   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2818   # but it is inaccurate more often than not
2819   ( dbic_internal_try {
2820     local $dbh->{PrintError} = 0;
2821     local $dbh->{RaiseError} = 1;
2822     $dbh->do('select ?', {}, 1);
2823     1;
2824   } )
2825     ? 1
2826     : 0
2827   ;
2828 }
2829
2830 # Check if placeholders bound to non-string types throw exceptions
2831 #
2832 sub _determine_supports_typeless_placeholders {
2833   my $self = shift;
2834   my $dbh  = $self->_get_dbh;
2835
2836   ( dbic_internal_try {
2837     local $dbh->{PrintError} = 0;
2838     local $dbh->{RaiseError} = 1;
2839     # this specifically tests a bind that is NOT a string
2840     $dbh->do('select 1 where 1 = ?', {}, 1);
2841     1;
2842   } )
2843     ? 1
2844     : 0
2845   ;
2846 }
2847
2848 =head2 sqlt_type
2849
2850 Returns the database driver name.
2851
2852 =cut
2853
2854 sub sqlt_type {
2855   shift->_get_dbh->{Driver}->{Name};
2856 }
2857
2858 =head2 bind_attribute_by_data_type
2859
2860 Given a datatype from column info, returns a database specific bind
2861 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2862 let the database planner just handle it.
2863
2864 This method is always called after the driver has been determined and a DBI
2865 connection has been established. Therefore you can refer to C<DBI::$constant>
2866 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2867 the correct modules.
2868
2869 =cut
2870
2871 sub bind_attribute_by_data_type {
2872     return;
2873 }
2874
2875 =head2 is_datatype_numeric
2876
2877 Given a datatype from column_info, returns a boolean value indicating if
2878 the current RDBMS considers it a numeric value. This controls how
2879 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2880 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2881 be performed instead of the usual C<eq>.
2882
2883 =cut
2884
2885 sub is_datatype_numeric {
2886   #my ($self, $dt) = @_;
2887
2888   return 0 unless $_[1];
2889
2890   $_[1] =~ /^ (?:
2891     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2892   ) $/ix;
2893 }
2894
2895
2896 =head2 create_ddl_dir
2897
2898 =over 4
2899
2900 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2901
2902 =back
2903
2904 Creates a SQL file based on the Schema, for each of the specified
2905 database engines in C<\@databases> in the given directory.
2906 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2907
2908 Given a previous version number, this will also create a file containing
2909 the ALTER TABLE statements to transform the previous schema into the
2910 current one. Note that these statements may contain C<DROP TABLE> or
2911 C<DROP COLUMN> statements that can potentially destroy data.
2912
2913 The file names are created using the C<ddl_filename> method below, please
2914 override this method in your schema if you would like a different file
2915 name format. For the ALTER file, the same format is used, replacing
2916 $version in the name with "$preversion-$version".
2917
2918 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2919 The most common value for this would be C<< { add_drop_table => 1 } >>
2920 to have the SQL produced include a C<DROP TABLE> statement for each table
2921 created. For quoting purposes supply C<quote_identifiers>.
2922
2923 If no arguments are passed, then the following default values are assumed:
2924
2925 =over 4
2926
2927 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2928
2929 =item version    - $schema->schema_version
2930
2931 =item directory  - './'
2932
2933 =item preversion - <none>
2934
2935 =back
2936
2937 By default, C<\%sqlt_args> will have
2938
2939  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2940
2941 merged with the hash passed in. To disable any of those features, pass in a
2942 hashref like the following
2943
2944  { ignore_constraint_names => 0, # ... other options }
2945
2946
2947 WARNING: You are strongly advised to check all SQL files created, before applying
2948 them.
2949
2950 =cut
2951
2952 sub create_ddl_dir {
2953   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2954
2955   require DBIx::Class::Optional::Dependencies;
2956   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2957     $self->throw_exception("Can't create a ddl file without $missing");
2958   }
2959
2960   if (!$dir) {
2961     carp "No directory given, using ./\n";
2962     $dir = './';
2963   }
2964   else {
2965     mkdir_p( $dir ) unless -d $dir;
2966   }
2967
2968   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2969   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2970
2971   my $schema_version = $schema->schema_version || '1.x';
2972   $version ||= $schema_version;
2973
2974   $sqltargs = {
2975     add_drop_table => 1,
2976     ignore_constraint_names => 1,
2977     ignore_index_names => 1,
2978     quote_identifiers => $self->sql_maker->_quoting_enabled,
2979     %{$sqltargs || {}}
2980   };
2981
2982   my $sqlt = SQL::Translator->new( $sqltargs );
2983
2984   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2985   my $sqlt_schema = $sqlt->translate({ data => $schema })
2986     or $self->throw_exception ($sqlt->error);
2987
2988   foreach my $db (@$databases) {
2989     $sqlt->reset();
2990     $sqlt->{schema} = $sqlt_schema;
2991     $sqlt->producer($db);
2992
2993     my $file;
2994     my $filename = $schema->ddl_filename($db, $version, $dir);
2995     if (-e $filename && ($version eq $schema_version )) {
2996       # if we are dumping the current version, overwrite the DDL
2997       carp "Overwriting existing DDL file - $filename";
2998       unlink($filename);
2999     }
3000
3001     my $output = $sqlt->translate;
3002     if(!$output) {
3003       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
3004       next;
3005     }
3006     if(!open($file, ">$filename")) {
3007       $self->throw_exception("Can't open $filename for writing ($!)");
3008       next;
3009     }
3010     print $file $output;
3011     close($file);
3012
3013     next unless ($preversion);
3014
3015     require SQL::Translator::Diff;
3016
3017     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
3018     if(!-e $prefilename) {
3019       carp("No previous schema file found ($prefilename)");
3020       next;
3021     }
3022
3023     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
3024     if(-e $difffile) {
3025       carp("Overwriting existing diff file - $difffile");
3026       unlink($difffile);
3027     }
3028
3029     my $source_schema;
3030     {
3031       my $t = SQL::Translator->new($sqltargs);
3032       $t->debug( 0 );
3033       $t->trace( 0 );
3034
3035       $t->parser( $db )
3036         or $self->throw_exception ($t->error);
3037
3038       my $out = $t->translate( $prefilename )
3039         or $self->throw_exception ($t->error);
3040
3041       $source_schema = $t->schema;
3042
3043       $source_schema->name( $prefilename )
3044         unless ( $source_schema->name );
3045     }
3046
3047     # The "new" style of producers have sane normalization and can support
3048     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3049     # And we have to diff parsed SQL against parsed SQL.
3050     my $dest_schema = $sqlt_schema;
3051
3052     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3053       my $t = SQL::Translator->new($sqltargs);
3054       $t->debug( 0 );
3055       $t->trace( 0 );
3056
3057       $t->parser( $db )
3058         or $self->throw_exception ($t->error);
3059
3060       my $out = $t->translate( $filename )
3061         or $self->throw_exception ($t->error);
3062
3063       $dest_schema = $t->schema;
3064
3065       $dest_schema->name( $filename )
3066         unless $dest_schema->name;
3067     }
3068
3069     my $diff = do {
3070       # FIXME - this is a terrible workaround for
3071       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3072       # Fixing it in this sloppy manner so that we don't hve to
3073       # lockstep an SQLT release as well. Needs to be removed at
3074       # some point, and SQLT dep bumped
3075       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3076         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3077
3078       SQL::Translator::Diff::schema_diff($source_schema, $db,
3079                                          $dest_schema,   $db,
3080                                          $sqltargs
3081                                        );
3082     };
3083
3084     if(!open $file, ">$difffile") {
3085       $self->throw_exception("Can't write to $difffile ($!)");
3086       next;
3087     }
3088     print $file $diff;
3089     close($file);
3090   }
3091 }
3092
3093 =head2 deployment_statements
3094
3095 =over 4
3096
3097 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3098
3099 =back
3100
3101 Returns the statements used by L<DBIx::Class::Storage/deploy>
3102 and L<DBIx::Class::Schema/deploy>.
3103
3104 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3105 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3106
3107 C<$directory> is used to return statements from files in a previously created
3108 L</create_ddl_dir> directory and is optional. The filenames are constructed
3109 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3110
3111 If no C<$directory> is specified then the statements are constructed on the
3112 fly using L<SQL::Translator> and C<$version> is ignored.
3113
3114 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3115
3116 =cut
3117
3118 sub deployment_statements {
3119   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3120
3121   $self->throw_exception(
3122     'Calling deployment_statements() in void context makes no sense'
3123   ) unless defined wantarray;
3124
3125   $type ||= $self->sqlt_type;
3126   $version ||= $schema->schema_version || '1.x';
3127   $dir ||= './';
3128   my $filename = $schema->ddl_filename($type, $version, $dir);
3129   if(-f $filename)
3130   {
3131       # FIXME replace this block when a proper sane sql parser is available
3132       my $file;
3133       open($file, "<$filename")
3134         or $self->throw_exception("Can't open $filename ($!)");
3135       my @rows = <$file>;
3136       close($file);
3137       return join('', @rows);
3138   }
3139
3140   require DBIx::Class::Optional::Dependencies;
3141   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3142     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3143   }
3144
3145   # sources needs to be a parser arg, but for simplicity allow at top level
3146   # coming in
3147   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3148       if exists $sqltargs->{sources};
3149
3150   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3151     unless exists $sqltargs->{quote_identifiers};
3152
3153   my $tr = SQL::Translator->new(
3154     producer => "SQL::Translator::Producer::${type}",
3155     %$sqltargs,
3156     parser => 'SQL::Translator::Parser::DBIx::Class',
3157     data => $schema,
3158   );
3159
3160   return preserve_context {
3161     $tr->translate
3162   } after => sub {
3163     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3164       unless defined $_[0];
3165   };
3166 }
3167
3168 # FIXME deploy() currently does not accurately report sql errors
3169 # Will always return true while errors are warned
3170 sub deploy {
3171   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3172   my $deploy = sub {
3173     my $line = shift;
3174     return if(!$line);
3175     return if($line =~ /^--/);
3176     # next if($line =~ /^DROP/m);
3177     return if($line =~ /^BEGIN TRANSACTION/m);
3178     return if($line =~ /^COMMIT/m);
3179     return if $line =~ /^\s+$/; # skip whitespace only
3180     $self->_query_start($line);
3181     dbic_internal_try {
3182       # do a dbh_do cycle here, as we need some error checking in
3183       # place (even though we will ignore errors)
3184       $self->dbh_do (sub { $_[1]->do($line) });
3185     } catch {
3186       carp qq{$_ (running "${line}")};
3187     };
3188     $self->_query_end($line);
3189   };
3190   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3191   if (@statements > 1) {
3192     foreach my $statement (@statements) {
3193       $deploy->( $statement );
3194     }
3195   }
3196   elsif (@statements == 1) {
3197     # split on single line comments and end of statements
3198     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3199       $deploy->( $line );
3200     }
3201   }
3202 }
3203
3204 =head2 datetime_parser
3205
3206 Returns the datetime parser class
3207
3208 =cut
3209
3210 sub datetime_parser {
3211   my $self = shift;
3212   return $self->{datetime_parser} ||= do {
3213     $self->build_datetime_parser(@_);
3214   };
3215 }
3216
3217 =head2 datetime_parser_type
3218
3219 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3220
3221 =head2 build_datetime_parser
3222
3223 See L</datetime_parser>
3224
3225 =cut
3226
3227 sub build_datetime_parser {
3228   my $self = shift;
3229   my $type = $self->datetime_parser_type(@_);
3230   return $type;
3231 }
3232
3233
3234 =head2 is_replicating
3235
3236 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3237 replicate from a master database.  Default is undef, which is the result
3238 returned by databases that don't support replication.
3239
3240 =cut
3241
3242 sub is_replicating {
3243     return;
3244
3245 }
3246
3247 =head2 lag_behind_master
3248
3249 Returns a number that represents a certain amount of lag behind a master db
3250 when a given storage is replicating.  The number is database dependent, but
3251 starts at zero and increases with the amount of lag. Default in undef
3252
3253 =cut
3254
3255 sub lag_behind_master {
3256     return;
3257 }
3258
3259 =head2 relname_to_table_alias
3260
3261 =over 4
3262
3263 =item Arguments: $relname, $join_count
3264
3265 =item Return Value: $alias
3266
3267 =back
3268
3269 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3270 queries.
3271
3272 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3273 way these aliases are named.
3274
3275 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3276 otherwise C<"$relname">.
3277
3278 =cut
3279
3280 sub relname_to_table_alias {
3281   my ($self, $relname, $join_count) = @_;
3282
3283   my $alias = ($join_count && $join_count > 1 ?
3284     join('_', $relname, $join_count) : $relname);
3285
3286   return $alias;
3287 }
3288
3289 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3290 # version and it may be necessary to amend or override it for a specific storage
3291 # if such binds are necessary.
3292 sub _max_column_bytesize {
3293   my ($self, $attr) = @_;
3294
3295   my $max_size;
3296
3297   if ($attr->{sqlt_datatype}) {
3298     my $data_type = lc($attr->{sqlt_datatype});
3299
3300     if ($attr->{sqlt_size}) {
3301
3302       # String/sized-binary types
3303       if ($data_type =~ /^(?:
3304           l? (?:var)? char(?:acter)? (?:\s*varying)?
3305             |
3306           (?:var)? binary (?:\s*varying)?
3307             |
3308           raw
3309         )\b/x
3310       ) {
3311         $max_size = $attr->{sqlt_size};
3312       }
3313       # Other charset/unicode types, assume scale of 4
3314       elsif ($data_type =~ /^(?:
3315           national \s* character (?:\s*varying)?
3316             |
3317           nchar
3318             |
3319           univarchar
3320             |
3321           nvarchar
3322         )\b/x
3323       ) {
3324         $max_size = $attr->{sqlt_size} * 4;
3325       }
3326     }
3327
3328     if (!$max_size and !$self->_is_lob_type($data_type)) {
3329       $max_size = 100 # for all other (numeric?) datatypes
3330     }
3331   }
3332
3333   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3334 }
3335
3336 # Determine if a data_type is some type of BLOB
3337 sub _is_lob_type {
3338   my ($self, $data_type) = @_;
3339   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3340     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3341                                   |varchar|character\s*varying|nvarchar
3342                                   |national\s*character\s*varying))?\z/xi);
3343 }
3344
3345 sub _is_binary_lob_type {
3346   my ($self, $data_type) = @_;
3347   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3348     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3349 }
3350
3351 sub _is_text_lob_type {
3352   my ($self, $data_type) = @_;
3353   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3354     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3355                         |national\s*character\s*varying))\z/xi);
3356 }
3357
3358 # Determine if a data_type is some type of a binary type
3359 sub _is_binary_type {
3360   my ($self, $data_type) = @_;
3361   $data_type && ($self->_is_binary_lob_type($data_type)
3362     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3363 }
3364
3365 1;
3366
3367 =head1 USAGE NOTES
3368
3369 =head2 DBIx::Class and AutoCommit
3370
3371 DBIx::Class can do some wonderful magic with handling exceptions,
3372 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3373 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3374 transaction support.
3375
3376 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3377 in an assumed transaction between commits, and you're telling us you'd
3378 like to manage that manually.  A lot of the magic protections offered by
3379 this module will go away.  We can't protect you from exceptions due to database
3380 disconnects because we don't know anything about how to restart your
3381 transactions.  You're on your own for handling all sorts of exceptional
3382 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3383 be with raw DBI.
3384
3385 =head1 FURTHER QUESTIONS?
3386
3387 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3388
3389 =head1 COPYRIGHT AND LICENSE
3390
3391 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3392 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3393 redistribute it and/or modify it under the same terms as the
3394 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.