lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. We also need to separate accessors
  83 # from plain old method calls, since an accessor called as a setter
  84 # does *not* need the driver determination loop fired (and in fact
  85 # can produce hard to find bugs, like e.g. losing on_connect_*
  86 # semantics on fresh connections)
  87 #
  88 # The construct below is simply a parameterized around()
  89 my $storage_accessor_idx = { map { $_ => 1 } qw(
  90   sqlt_type
  91   datetime_parser_type
  92
  93   sql_maker
  94   cursor_class
  95 )};
  96 for my $meth (keys %$storage_accessor_idx, qw(
  97   deployment_statements
  98
  99   build_datetime_parser
 100
 101   txn_begin
 102
 103   insert
 104   insert_bulk
 105   update
 106   delete
 107   select
 108   select_single
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   no strict 'refs';
 123   no warnings 'redefine';
 124   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 125     if (
 126       # only fire when invoked on an instance, a valid class-based invocation
 127       # would e.g. be setting a default for an inherited accessor
 128       ref $_[0]
 129         and
 130       ! $_[0]->{_driver_determined}
 131         and
 132       ! $_[0]->{_in_determine_driver}
 133         and
 134       # if this is a known *setter* - just set it, no need to connect
 135       # and determine the driver
 136       ! ( $storage_accessor_idx->{$meth} and @_ > 1 )
 137         and
 138       # Only try to determine stuff if we have *something* that either is or can
 139       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 140       # to still be marginally useful
 141       $_[0]->_dbi_connect_info->[0]
 142     ) {
 143       $_[0]->_determine_driver;
 144
 145       # This for some reason crashes and burns on perl 5.8.1
 146       # IFF the method ends up throwing an exception
 147       #goto $_[0]->can ($meth);
 148
 149       my $cref = $_[0]->can ($meth);
 150       goto $cref;
 151     }
 152
 153     goto $orig;
 154   };
 155 }
 156
 157 =head1 NAME
 158
 159 DBIx::Class::Storage::DBI - DBI storage handler
 160
 161 =head1 SYNOPSIS
 162
 163   my $schema = MySchema->connect('dbi:SQLite:my.db');
 164
 165   $schema->storage->debug(1);
 166
 167   my @stuff = $schema->storage->dbh_do(
 168     sub {
 169       my ($storage, $dbh, @args) = @_;
 170       $dbh->do("DROP TABLE authors");
 171     },
 172     @column_list
 173   );
 174
 175   $schema->resultset('Book')->search({
 176      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 177   });
 178
 179 =head1 DESCRIPTION
 180
 181 This class represents the connection to an RDBMS via L<DBI>.  See
 182 L<DBIx::Class::Storage> for general information.  This pod only
 183 documents DBI-specific methods and behaviors.
 184
 185 =head1 METHODS
 186
 187 =cut
 188
 189 sub new {
 190   my $new = shift->next::method(@_);
 191
 192   $new->_sql_maker_opts({});
 193   $new->_dbh_details({});
 194   $new->{_in_do_block} = 0;
 195
 196   # read below to see what this does
 197   $new->_arm_global_destructor;
 198
 199   $new;
 200 }
 201
 202 # This is hack to work around perl shooting stuff in random
 203 # order on exit(). If we do not walk the remaining storage
 204 # objects in an END block, there is a *small but real* chance
 205 # of a fork()ed child to kill the parent's shared DBI handle,
 206 # *before perl reaches the DESTROY in this package*
 207 # Yes, it is ugly and effective.
 208 # Additionally this registry is used by the CLONE method to
 209 # make sure no handles are shared between threads
 210 {
 211   my %seek_and_destroy;
 212
 213   sub _arm_global_destructor {
 214
 215     # quick "garbage collection" pass - prevents the registry
 216     # from slowly growing with a bunch of undef-valued keys
 217     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 218       for keys %seek_and_destroy;
 219
 220     weaken (
 221       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 222     );
 223   }
 224
 225   END {
 226     local $?; # just in case the DBI destructor changes it somehow
 227
 228     # destroy just the object if not native to this process
 229     $_->_verify_pid for (grep
 230       { defined $_ }
 231       values %seek_and_destroy
 232     );
 233   }
 234
 235   sub CLONE {
 236     # As per DBI's recommendation, DBIC disconnects all handles as
 237     # soon as possible (DBIC will reconnect only on demand from within
 238     # the thread)
 239     my @instances = grep { defined $_ } values %seek_and_destroy;
 240     %seek_and_destroy = ();
 241
 242     for (@instances) {
 243       $_->_dbh(undef);
 244
 245       $_->transaction_depth(0);
 246       $_->savepoints([]);
 247
 248       # properly renumber existing refs
 249       $_->_arm_global_destructor
 250     }
 251   }
 252 }
 253
 254 sub DESTROY {
 255   my $self = shift;
 256
 257   # some databases spew warnings on implicit disconnect
 258   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 259   local $SIG{__WARN__} = sub {};
 260   $self->_dbh(undef);
 261
 262   # this op is necessary, since the very last perl runtime statement
 263   # triggers a global destruction shootout, and the $SIG localization
 264   # may very well be destroyed before perl actually gets to do the
 265   # $dbh undef
 266   1;
 267 }
 268
 269 # handle pid changes correctly - do not destroy parent's connection
 270 sub _verify_pid {
 271   my $self = shift;
 272
 273   my $pid = $self->_conn_pid;
 274   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 275     $dbh->{InactiveDestroy} = 1;
 276     $self->_dbh(undef);
 277     $self->transaction_depth(0);
 278     $self->savepoints([]);
 279   }
 280
 281   return;
 282 }
 283
 284 =head2 connect_info
 285
 286 This method is normally called by L<DBIx::Class::Schema/connection>, which
 287 encapsulates its argument list in an arrayref before passing them here.
 288
 289 The argument list may contain:
 290
 291 =over
 292
 293 =item *
 294
 295 The same 4-element argument set one would normally pass to
 296 L<DBI/connect>, optionally followed by
 297 L<extra attributes|/DBIx::Class specific connection attributes>
 298 recognized by DBIx::Class:
 299
 300   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 301
 302 =item *
 303
 304 A single code reference which returns a connected
 305 L<DBI database handle|DBI/connect> optionally followed by
 306 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 307 by DBIx::Class:
 308
 309   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 310
 311 =item *
 312
 313 A single hashref with all the attributes and the dsn/user/password
 314 mixed together:
 315
 316   $connect_info_args = [{
 317     dsn => $dsn,
 318     user => $user,
 319     password => $pass,
 320     %dbi_attributes,
 321     %extra_attributes,
 322   }];
 323
 324   $connect_info_args = [{
 325     dbh_maker => sub { DBI->connect (...) },
 326     %dbi_attributes,
 327     %extra_attributes,
 328   }];
 329
 330 This is particularly useful for L<Catalyst> based applications, allowing the
 331 following config (L<Config::General> style):
 332
 333   <Model::DB>
 334     schema_class   App::DB
 335     <connect_info>
 336       dsn          dbi:mysql:database=test
 337       user         testuser
 338       password     TestPass
 339       AutoCommit   1
 340     </connect_info>
 341   </Model::DB>
 342
 343 The C<dsn>/C<user>/C<password> combination can be substituted by the
 344 C<dbh_maker> key whose value is a coderef that returns a connected
 345 L<DBI database handle|DBI/connect>
 346
 347 =back
 348
 349 Please note that the L<DBI> docs recommend that you always explicitly
 350 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 351 recommends that it be set to I<1>, and that you perform transactions
 352 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 353 to I<1> if you do not do explicitly set it to zero.  This is the default
 354 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 355
 356 =head3 DBIx::Class specific connection attributes
 357
 358 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 359 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 360 the following connection options. These options can be mixed in with your other
 361 L<DBI> connection attributes, or placed in a separate hashref
 362 (C<\%extra_attributes>) as shown above.
 363
 364 Every time C<connect_info> is invoked, any previous settings for
 365 these options will be cleared before setting the new ones, regardless of
 366 whether any options are specified in the new C<connect_info>.
 367
 368
 369 =over
 370
 371 =item on_connect_do
 372
 373 Specifies things to do immediately after connecting or re-connecting to
 374 the database.  Its value may contain:
 375
 376 =over
 377
 378 =item a scalar
 379
 380 This contains one SQL statement to execute.
 381
 382 =item an array reference
 383
 384 This contains SQL statements to execute in order.  Each element contains
 385 a string or a code reference that returns a string.
 386
 387 =item a code reference
 388
 389 This contains some code to execute.  Unlike code references within an
 390 array reference, its return value is ignored.
 391
 392 =back
 393
 394 =item on_disconnect_do
 395
 396 Takes arguments in the same form as L</on_connect_do> and executes them
 397 immediately before disconnecting from the database.
 398
 399 Note, this only runs if you explicitly call L</disconnect> on the
 400 storage object.
 401
 402 =item on_connect_call
 403
 404 A more generalized form of L</on_connect_do> that calls the specified
 405 C<connect_call_METHOD> methods in your storage driver.
 406
 407   on_connect_do => 'select 1'
 408
 409 is equivalent to:
 410
 411   on_connect_call => [ [ do_sql => 'select 1' ] ]
 412
 413 Its values may contain:
 414
 415 =over
 416
 417 =item a scalar
 418
 419 Will call the C<connect_call_METHOD> method.
 420
 421 =item a code reference
 422
 423 Will execute C<< $code->($storage) >>
 424
 425 =item an array reference
 426
 427 Each value can be a method name or code reference.
 428
 429 =item an array of arrays
 430
 431 For each array, the first item is taken to be the C<connect_call_> method name
 432 or code reference, and the rest are parameters to it.
 433
 434 =back
 435
 436 Some predefined storage methods you may use:
 437
 438 =over
 439
 440 =item do_sql
 441
 442 Executes a SQL string or a code reference that returns a SQL string. This is
 443 what L</on_connect_do> and L</on_disconnect_do> use.
 444
 445 It can take:
 446
 447 =over
 448
 449 =item a scalar
 450
 451 Will execute the scalar as SQL.
 452
 453 =item an arrayref
 454
 455 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 456 attributes hashref and bind values.
 457
 458 =item a code reference
 459
 460 Will execute C<< $code->($storage) >> and execute the return array refs as
 461 above.
 462
 463 =back
 464
 465 =item datetime_setup
 466
 467 Execute any statements necessary to initialize the database session to return
 468 and accept datetime/timestamp values used with
 469 L<DBIx::Class::InflateColumn::DateTime>.
 470
 471 Only necessary for some databases, see your specific storage driver for
 472 implementation details.
 473
 474 =back
 475
 476 =item on_disconnect_call
 477
 478 Takes arguments in the same form as L</on_connect_call> and executes them
 479 immediately before disconnecting from the database.
 480
 481 Calls the C<disconnect_call_METHOD> methods as opposed to the
 482 C<connect_call_METHOD> methods called by L</on_connect_call>.
 483
 484 Note, this only runs if you explicitly call L</disconnect> on the
 485 storage object.
 486
 487 =item disable_sth_caching
 488
 489 If set to a true value, this option will disable the caching of
 490 statement handles via L<DBI/prepare_cached>.
 491
 492 =item limit_dialect
 493
 494 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 495 default L</sql_limit_dialect> setting of the storage (if any). For a list
 496 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 497
 498 =item quote_names
 499
 500 When true automatically sets L</quote_char> and L</name_sep> to the characters
 501 appropriate for your particular RDBMS. This option is preferred over specifying
 502 L</quote_char> directly.
 503
 504 =item quote_char
 505
 506 Specifies what characters to use to quote table and column names.
 507
 508 C<quote_char> expects either a single character, in which case is it
 509 is placed on either side of the table/column name, or an arrayref of length
 510 2 in which case the table/column name is placed between the elements.
 511
 512 For example under MySQL you should use C<< quote_char => '`' >>, and for
 513 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 514
 515 =item name_sep
 516
 517 This parameter is only useful in conjunction with C<quote_char>, and is used to
 518 specify the character that separates elements (schemas, tables, columns) from
 519 each other. If unspecified it defaults to the most commonly used C<.>.
 520
 521 =item unsafe
 522
 523 This Storage driver normally installs its own C<HandleError>, sets
 524 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 525 all database handles, including those supplied by a coderef.  It does this
 526 so that it can have consistent and useful error behavior.
 527
 528 If you set this option to a true value, Storage will not do its usual
 529 modifications to the database handle's attributes, and instead relies on
 530 the settings in your connect_info DBI options (or the values you set in
 531 your connection coderef, in the case that you are connecting via coderef).
 532
 533 Note that your custom settings can cause Storage to malfunction,
 534 especially if you set a C<HandleError> handler that suppresses exceptions
 535 and/or disable C<RaiseError>.
 536
 537 =item auto_savepoint
 538
 539 If this option is true, L<DBIx::Class> will use savepoints when nesting
 540 transactions, making it possible to recover from failure in the inner
 541 transaction without having to abort all outer transactions.
 542
 543 =item cursor_class
 544
 545 Use this argument to supply a cursor class other than the default
 546 L<DBIx::Class::Storage::DBI::Cursor>.
 547
 548 =back
 549
 550 Some real-life examples of arguments to L</connect_info> and
 551 L<DBIx::Class::Schema/connect>
 552
 553   # Simple SQLite connection
 554   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 555
 556   # Connect via subref
 557   ->connect_info([ sub { DBI->connect(...) } ]);
 558
 559   # Connect via subref in hashref
 560   ->connect_info([{
 561     dbh_maker => sub { DBI->connect(...) },
 562     on_connect_do => 'alter session ...',
 563   }]);
 564
 565   # A bit more complicated
 566   ->connect_info(
 567     [
 568       'dbi:Pg:dbname=foo',
 569       'postgres',
 570       'my_pg_password',
 571       { AutoCommit => 1 },
 572       { quote_char => q{"} },
 573     ]
 574   );
 575
 576   # Equivalent to the previous example
 577   ->connect_info(
 578     [
 579       'dbi:Pg:dbname=foo',
 580       'postgres',
 581       'my_pg_password',
 582       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 583     ]
 584   );
 585
 586   # Same, but with hashref as argument
 587   # See parse_connect_info for explanation
 588   ->connect_info(
 589     [{
 590       dsn         => 'dbi:Pg:dbname=foo',
 591       user        => 'postgres',
 592       password    => 'my_pg_password',
 593       AutoCommit  => 1,
 594       quote_char  => q{"},
 595       name_sep    => q{.},
 596     }]
 597   );
 598
 599   # Subref + DBIx::Class-specific connection options
 600   ->connect_info(
 601     [
 602       sub { DBI->connect(...) },
 603       {
 604           quote_char => q{`},
 605           name_sep => q{@},
 606           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 607           disable_sth_caching => 1,
 608       },
 609     ]
 610   );
 611
 612
 613
 614 =cut
 615
 616 sub connect_info {
 617   my ($self, $info) = @_;
 618
 619   return $self->_connect_info if !$info;
 620
 621   $self->_connect_info($info); # copy for _connect_info
 622
 623   $info = $self->_normalize_connect_info($info)
 624     if ref $info eq 'ARRAY';
 625
 626   my %attrs = (
 627     %{ $self->_default_dbi_connect_attributes || {} },
 628     %{ $info->{attributes} || {} },
 629   );
 630
 631   my @args = @{ $info->{arguments} };
 632
 633   if (keys %attrs and ref $args[0] ne 'CODE') {
 634     carp_unique (
 635         'You provided explicit AutoCommit => 0 in your connection_info. '
 636       . 'This is almost universally a bad idea (see the footnotes of '
 637       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 638       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 639       . 'this warning.'
 640     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 641
 642     push @args, \%attrs if keys %attrs;
 643   }
 644
 645   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 646   # OR a single-element coderef-based $dbh factory
 647   $self->_dbi_connect_info(\@args);
 648
 649   # extract the individual storage options
 650   for my $storage_opt (keys %{ $info->{storage_options} }) {
 651     my $value = $info->{storage_options}{$storage_opt};
 652
 653     $self->$storage_opt($value);
 654   }
 655
 656   # Extract the individual sqlmaker options
 657   #
 658   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 659   #  the new set of options
 660   $self->_sql_maker(undef);
 661   $self->_sql_maker_opts({});
 662
 663   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 664     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 665
 666     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 667   }
 668
 669   # FIXME - dirty:
 670   # save attributes in a separate accessor so they are always
 671   # introspectable, even in case of a CODE $dbhmaker
 672   $self->_dbic_connect_attributes (\%attrs);
 673
 674   return $self->_connect_info;
 675 }
 676
 677 sub _dbi_connect_info {
 678   my $self = shift;
 679
 680   return $self->{_dbi_connect_info} = $_[0]
 681     if @_;
 682
 683   my $conninfo = $self->{_dbi_connect_info} || [];
 684
 685   # last ditch effort to grab a DSN
 686   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 687     my @new_conninfo = @$conninfo;
 688     $new_conninfo[0] = $ENV{DBI_DSN};
 689     $conninfo = \@new_conninfo;
 690   }
 691
 692   return $conninfo;
 693 }
 694
 695
 696 sub _normalize_connect_info {
 697   my ($self, $info_arg) = @_;
 698   my %info;
 699
 700   my @args = @$info_arg;  # take a shallow copy for further mutilation
 701
 702   # combine/pre-parse arguments depending on invocation style
 703
 704   my %attrs;
 705   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 706     %attrs = %{ $args[1] || {} };
 707     @args = $args[0];
 708   }
 709   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 710     %attrs = %{$args[0]};
 711     @args = ();
 712     if (my $code = delete $attrs{dbh_maker}) {
 713       @args = $code;
 714
 715       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 716       if (@ignored) {
 717         carp sprintf (
 718             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 719           . "to the result of 'dbh_maker'",
 720
 721           join (', ', map { "'$_'" } (@ignored) ),
 722         );
 723       }
 724     }
 725     else {
 726       @args = delete @attrs{qw/dsn user password/};
 727     }
 728   }
 729   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 730     %attrs = (
 731       % { $args[3] || {} },
 732       % { $args[4] || {} },
 733     );
 734     @args = @args[0,1,2];
 735   }
 736
 737   $info{arguments} = \@args;
 738
 739   my @storage_opts = grep exists $attrs{$_},
 740     @storage_options, 'cursor_class';
 741
 742   @{ $info{storage_options} }{@storage_opts} =
 743     delete @attrs{@storage_opts} if @storage_opts;
 744
 745   my @sql_maker_opts = grep exists $attrs{$_},
 746     qw/limit_dialect quote_char name_sep quote_names/;
 747
 748   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 749     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 750
 751   $info{attributes} = \%attrs if %attrs;
 752
 753   return \%info;
 754 }
 755
 756 sub _default_dbi_connect_attributes () {
 757   +{
 758     AutoCommit => 1,
 759     PrintError => 0,
 760     RaiseError => 1,
 761     ShowErrorStatement => 1,
 762   };
 763 }
 764
 765 =head2 on_connect_do
 766
 767 This method is deprecated in favour of setting via L</connect_info>.
 768
 769 =cut
 770
 771 =head2 on_disconnect_do
 772
 773 This method is deprecated in favour of setting via L</connect_info>.
 774
 775 =cut
 776
 777 sub _parse_connect_do {
 778   my ($self, $type) = @_;
 779
 780   my $val = $self->$type;
 781   return () if not defined $val;
 782
 783   my @res;
 784
 785   if (not ref($val)) {
 786     push @res, [ 'do_sql', $val ];
 787   } elsif (ref($val) eq 'CODE') {
 788     push @res, $val;
 789   } elsif (ref($val) eq 'ARRAY') {
 790     push @res, map { [ 'do_sql', $_ ] } @$val;
 791   } else {
 792     $self->throw_exception("Invalid type for $type: ".ref($val));
 793   }
 794
 795   return \@res;
 796 }
 797
 798 =head2 dbh_do
 799
 800 Arguments: ($subref | $method_name), @extra_coderef_args?
 801
 802 Execute the given $subref or $method_name using the new exception-based
 803 connection management.
 804
 805 The first two arguments will be the storage object that C<dbh_do> was called
 806 on and a database handle to use.  Any additional arguments will be passed
 807 verbatim to the called subref as arguments 2 and onwards.
 808
 809 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 810 exception handling and reconnection (or failover in future subclasses).
 811
 812 Your subref should have no side-effects outside of the database, as
 813 there is the potential for your subref to be partially double-executed
 814 if the database connection was stale/dysfunctional.
 815
 816 Example:
 817
 818   my @stuff = $schema->storage->dbh_do(
 819     sub {
 820       my ($storage, $dbh, @cols) = @_;
 821       my $cols = join(q{, }, @cols);
 822       $dbh->selectrow_array("SELECT $cols FROM foo");
 823     },
 824     @column_list
 825   );
 826
 827 =cut
 828
 829 sub dbh_do {
 830   my $self = shift;
 831   my $run_target = shift; # either a coderef or a method name
 832
 833   # short circuit when we know there is no need for a runner
 834   #
 835   # FIXME - assumption may be wrong
 836   # the rationale for the txn_depth check is that if this block is a part
 837   # of a larger transaction, everything up to that point is screwed anyway
 838   return $self->$run_target($self->_get_dbh, @_)
 839     if $self->{_in_do_block} or $self->transaction_depth;
 840
 841   # take a ref instead of a copy, to preserve @_ aliasing
 842   # semantics within the coderef, but only if needed
 843   # (pseudoforking doesn't like this trick much)
 844   my $args = @_ ? \@_ : [];
 845
 846   DBIx::Class::Storage::BlockRunner->new(
 847     storage => $self,
 848     wrap_txn => 0,
 849     retry_handler => sub {
 850       $_[0]->failed_attempt_count == 1
 851         and
 852       ! $_[0]->storage->connected
 853     },
 854   )->run(sub {
 855     $self->$run_target ($self->_get_dbh, @$args )
 856   });
 857 }
 858
 859 sub txn_do {
 860   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 861   shift->next::method(@_);
 862 }
 863
 864 =head2 disconnect
 865
 866 Our C<disconnect> method also performs a rollback first if the
 867 database is not in C<AutoCommit> mode.
 868
 869 =cut
 870
 871 sub disconnect {
 872   my ($self) = @_;
 873
 874   if( $self->_dbh ) {
 875     my @actions;
 876
 877     push @actions, ( $self->on_disconnect_call || () );
 878     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 879
 880     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 881
 882     # stops the "implicit rollback on disconnect" warning
 883     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 884
 885     %{ $self->_dbh->{CachedKids} } = ();
 886     $self->_dbh->disconnect;
 887     $self->_dbh(undef);
 888   }
 889 }
 890
 891 =head2 with_deferred_fk_checks
 892
 893 =over 4
 894
 895 =item Arguments: C<$coderef>
 896
 897 =item Return Value: The return value of $coderef
 898
 899 =back
 900
 901 Storage specific method to run the code ref with FK checks deferred or
 902 in MySQL's case disabled entirely.
 903
 904 =cut
 905
 906 # Storage subclasses should override this
 907 sub with_deferred_fk_checks {
 908   my ($self, $sub) = @_;
 909   $sub->();
 910 }
 911
 912 =head2 connected
 913
 914 =over
 915
 916 =item Arguments: none
 917
 918 =item Return Value: 1|0
 919
 920 =back
 921
 922 Verifies that the current database handle is active and ready to execute
 923 an SQL statement (e.g. the connection did not get stale, server is still
 924 answering, etc.) This method is used internally by L</dbh>.
 925
 926 =cut
 927
 928 sub connected {
 929   my $self = shift;
 930   return 0 unless $self->_seems_connected;
 931
 932   #be on the safe side
 933   local $self->_dbh->{RaiseError} = 1;
 934
 935   return $self->_ping;
 936 }
 937
 938 sub _seems_connected {
 939   my $self = shift;
 940
 941   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 942
 943   my $dbh = $self->_dbh
 944     or return 0;
 945
 946   return $dbh->FETCH('Active');
 947 }
 948
 949 sub _ping {
 950   my $self = shift;
 951
 952   my $dbh = $self->_dbh or return 0;
 953
 954   return $dbh->ping;
 955 }
 956
 957 sub ensure_connected {
 958   my ($self) = @_;
 959
 960   unless ($self->connected) {
 961     $self->_populate_dbh;
 962   }
 963 }
 964
 965 =head2 dbh
 966
 967 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 968 is guaranteed to be healthy by implicitly calling L</connected>, and if
 969 necessary performing a reconnection before returning. Keep in mind that this
 970 is very B<expensive> on some database engines. Consider using L</dbh_do>
 971 instead.
 972
 973 =cut
 974
 975 sub dbh {
 976   my ($self) = @_;
 977
 978   if (not $self->_dbh) {
 979     $self->_populate_dbh;
 980   } else {
 981     $self->ensure_connected;
 982   }
 983   return $self->_dbh;
 984 }
 985
 986 # this is the internal "get dbh or connect (don't check)" method
 987 sub _get_dbh {
 988   my $self = shift;
 989   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 990   $self->_populate_dbh unless $self->_dbh;
 991   return $self->_dbh;
 992 }
 993
 994 sub sql_maker {
 995   my ($self) = @_;
 996   unless ($self->_sql_maker) {
 997     my $sql_maker_class = $self->sql_maker_class;
 998
 999     my %opts = %{$self->_sql_maker_opts||{}};
1000     my $dialect =
1001       $opts{limit_dialect}
1002         ||
1003       $self->sql_limit_dialect
1004         ||
1005       do {
1006         my $s_class = (ref $self) || $self;
1007         carp_unique (
1008           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1009         . 'have not supplied an explicit limit_dialect in your connection_info. '
1010         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1011         . 'databases but can be (and often is) painfully slow. '
1012         . "Please file an RT ticket against '$s_class'"
1013         ) if $self->_dbi_connect_info->[0];
1014
1015         'GenericSubQ';
1016       }
1017     ;
1018
1019     my ($quote_char, $name_sep);
1020
1021     if ($opts{quote_names}) {
1022       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1023         my $s_class = (ref $self) || $self;
1024         carp_unique (
1025           "You requested 'quote_names' but your storage class ($s_class) does "
1026         . 'not explicitly define a default sql_quote_char and you have not '
1027         . 'supplied a quote_char as part of your connection_info. DBIC will '
1028         .q{default to the ANSI SQL standard quote '"', which works most of }
1029         . "the time. Please file an RT ticket against '$s_class'."
1030         );
1031
1032         '"'; # RV
1033       };
1034
1035       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1036     }
1037
1038     $self->_sql_maker($sql_maker_class->new(
1039       bindtype=>'columns',
1040       array_datatypes => 1,
1041       limit_dialect => $dialect,
1042       ($quote_char ? (quote_char => $quote_char) : ()),
1043       name_sep => ($name_sep || '.'),
1044       %opts,
1045     ));
1046   }
1047   return $self->_sql_maker;
1048 }
1049
1050 # nothing to do by default
1051 sub _rebless {}
1052 sub _init {}
1053
1054 sub _populate_dbh {
1055   my ($self) = @_;
1056
1057   $self->_dbh(undef); # in case ->connected failed we might get sent here
1058   $self->_dbh_details({}); # reset everything we know
1059
1060   $self->_dbh($self->_connect);
1061
1062   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1063
1064   $self->_determine_driver;
1065
1066   # Always set the transaction depth on connect, since
1067   #  there is no transaction in progress by definition
1068   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1069
1070   $self->_run_connection_actions unless $self->{_in_determine_driver};
1071 }
1072
1073 sub _run_connection_actions {
1074   my $self = shift;
1075   my @actions;
1076
1077   push @actions, ( $self->on_connect_call || () );
1078   push @actions, $self->_parse_connect_do ('on_connect_do');
1079
1080   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1081 }
1082
1083
1084
1085 sub set_use_dbms_capability {
1086   $_[0]->set_inherited ($_[1], $_[2]);
1087 }
1088
1089 sub get_use_dbms_capability {
1090   my ($self, $capname) = @_;
1091
1092   my $use = $self->get_inherited ($capname);
1093   return defined $use
1094     ? $use
1095     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1096   ;
1097 }
1098
1099 sub set_dbms_capability {
1100   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1101 }
1102
1103 sub get_dbms_capability {
1104   my ($self, $capname) = @_;
1105
1106   my $cap = $self->_dbh_details->{capability}{$capname};
1107
1108   unless (defined $cap) {
1109     if (my $meth = $self->can ("_determine$capname")) {
1110       $cap = $self->$meth ? 1 : 0;
1111     }
1112     else {
1113       $cap = 0;
1114     }
1115
1116     $self->set_dbms_capability ($capname, $cap);
1117   }
1118
1119   return $cap;
1120 }
1121
1122 sub _server_info {
1123   my $self = shift;
1124
1125   my $info;
1126   unless ($info = $self->_dbh_details->{info}) {
1127
1128     $info = {};
1129
1130     my $server_version = try {
1131       $self->_get_server_version
1132     } catch {
1133       # driver determination *may* use this codepath
1134       # in which case we must rethrow
1135       $self->throw_exception($_) if $self->{_in_determine_driver};
1136
1137       # $server_version on failure
1138       undef;
1139     };
1140
1141     if (defined $server_version) {
1142       $info->{dbms_version} = $server_version;
1143
1144       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1145       my @verparts = split (/\./, $numeric_version);
1146       if (
1147         @verparts
1148           &&
1149         $verparts[0] <= 999
1150       ) {
1151         # consider only up to 3 version parts, iff not more than 3 digits
1152         my @use_parts;
1153         while (@verparts && @use_parts < 3) {
1154           my $p = shift @verparts;
1155           last if $p > 999;
1156           push @use_parts, $p;
1157         }
1158         push @use_parts, 0 while @use_parts < 3;
1159
1160         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1161       }
1162     }
1163
1164     $self->_dbh_details->{info} = $info;
1165   }
1166
1167   return $info;
1168 }
1169
1170 sub _get_server_version {
1171   shift->_dbh_get_info('SQL_DBMS_VER');
1172 }
1173
1174 sub _dbh_get_info {
1175   my ($self, $info) = @_;
1176
1177   if ($info =~ /[^0-9]/) {
1178     require DBI::Const::GetInfoType;
1179     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1180     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1181       unless defined $info;
1182   }
1183
1184   $self->_get_dbh->get_info($info);
1185 }
1186
1187 sub _describe_connection {
1188   require DBI::Const::GetInfoReturn;
1189
1190   my $self = shift;
1191
1192   my $drv;
1193   try {
1194     $drv = $self->_extract_driver_from_connect_info;
1195     $self->ensure_connected;
1196   };
1197
1198   $drv = "DBD::$drv" if $drv;
1199
1200   my $res = {
1201     DBIC_DSN => $self->_dbi_connect_info->[0],
1202     DBI_VER => DBI->VERSION,
1203     DBIC_VER => DBIx::Class->VERSION,
1204     DBIC_DRIVER => ref $self,
1205     $drv ? (
1206       DBD => $drv,
1207       DBD_VER => try { $drv->VERSION },
1208     ) : (),
1209   };
1210
1211   # try to grab data even if we never managed to connect
1212   # will cover us in cases of an oddly broken half-connect
1213   for my $inf (
1214     #keys %DBI::Const::GetInfoType::GetInfoType,
1215     qw/
1216       SQL_CURSOR_COMMIT_BEHAVIOR
1217       SQL_CURSOR_ROLLBACK_BEHAVIOR
1218       SQL_CURSOR_SENSITIVITY
1219       SQL_DATA_SOURCE_NAME
1220       SQL_DBMS_NAME
1221       SQL_DBMS_VER
1222       SQL_DEFAULT_TXN_ISOLATION
1223       SQL_DM_VER
1224       SQL_DRIVER_NAME
1225       SQL_DRIVER_ODBC_VER
1226       SQL_DRIVER_VER
1227       SQL_EXPRESSIONS_IN_ORDERBY
1228       SQL_GROUP_BY
1229       SQL_IDENTIFIER_CASE
1230       SQL_IDENTIFIER_QUOTE_CHAR
1231       SQL_MAX_CATALOG_NAME_LEN
1232       SQL_MAX_COLUMN_NAME_LEN
1233       SQL_MAX_IDENTIFIER_LEN
1234       SQL_MAX_TABLE_NAME_LEN
1235       SQL_MULTIPLE_ACTIVE_TXN
1236       SQL_MULT_RESULT_SETS
1237       SQL_NEED_LONG_DATA_LEN
1238       SQL_NON_NULLABLE_COLUMNS
1239       SQL_ODBC_VER
1240       SQL_QUALIFIER_NAME_SEPARATOR
1241       SQL_QUOTED_IDENTIFIER_CASE
1242       SQL_TXN_CAPABLE
1243       SQL_TXN_ISOLATION_OPTION
1244     /
1245   ) {
1246     # some drivers barf on things they do not know about instead
1247     # of returning undef
1248     my $v = try { $self->_dbh_get_info($inf) };
1249     next unless defined $v;
1250
1251     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1252     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1253     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1254   }
1255
1256   $res;
1257 }
1258
1259 sub _determine_driver {
1260   my ($self) = @_;
1261
1262   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1263     my $started_connected = 0;
1264     local $self->{_in_determine_driver} = 1;
1265
1266     if (ref($self) eq __PACKAGE__) {
1267       my $driver;
1268       if ($self->_dbh) { # we are connected
1269         $driver = $self->_dbh->{Driver}{Name};
1270         $started_connected = 1;
1271       }
1272       else {
1273         $driver = $self->_extract_driver_from_connect_info;
1274       }
1275
1276       if ($driver) {
1277         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1278         if ($self->load_optional_class($storage_class)) {
1279           mro::set_mro($storage_class, 'c3');
1280           bless $self, $storage_class;
1281           $self->_rebless();
1282         }
1283         else {
1284           $self->_warn_undetermined_driver(
1285             'This version of DBIC does not yet seem to supply a driver for '
1286           . "your particular RDBMS and/or connection method ('$driver')."
1287           );
1288         }
1289       }
1290       else {
1291         $self->_warn_undetermined_driver(
1292           'Unable to extract a driver name from connect info - this '
1293         . 'should not have happened.'
1294         );
1295       }
1296     }
1297
1298     $self->_driver_determined(1);
1299
1300     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1301
1302     if ($self->can('source_bind_attributes')) {
1303       $self->throw_exception(
1304         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1305       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1306       . 'If you are not sure how to proceed please contact the development team via '
1307       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1308       );
1309     }
1310
1311     $self->_init; # run driver-specific initializations
1312
1313     $self->_run_connection_actions
1314         if !$started_connected && defined $self->_dbh;
1315   }
1316 }
1317
1318 sub _extract_driver_from_connect_info {
1319   my $self = shift;
1320
1321   my $drv;
1322
1323   # if connect_info is a CODEREF, we have no choice but to connect
1324   if (
1325     ref $self->_dbi_connect_info->[0]
1326       and
1327     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1328   ) {
1329     $self->_populate_dbh;
1330     $drv = $self->_dbh->{Driver}{Name};
1331   }
1332   else {
1333     # try to use dsn to not require being connected, the driver may still
1334     # force a connection later in _rebless to determine version
1335     # (dsn may not be supplied at all if all we do is make a mock-schema)
1336     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1337     $drv ||= $ENV{DBI_DRIVER};
1338   }
1339
1340   return $drv;
1341 }
1342
1343 sub _determine_connector_driver {
1344   my ($self, $conn) = @_;
1345
1346   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1347
1348   if (not $dbtype) {
1349     $self->_warn_undetermined_driver(
1350       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1351     . "$conn connector - this should not have happened."
1352     );
1353     return;
1354   }
1355
1356   $dbtype =~ s/\W/_/gi;
1357
1358   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1359   return if $self->isa($subclass);
1360
1361   if ($self->load_optional_class($subclass)) {
1362     bless $self, $subclass;
1363     $self->_rebless;
1364   }
1365   else {
1366     $self->_warn_undetermined_driver(
1367       'This version of DBIC does not yet seem to supply a driver for '
1368     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1369     );
1370   }
1371 }
1372
1373 sub _warn_undetermined_driver {
1374   my ($self, $msg) = @_;
1375
1376   require Data::Dumper::Concise;
1377
1378   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1379   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1380   . "does not go away, file a bugreport including the following info:\n"
1381   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1382   );
1383 }
1384
1385 sub _do_connection_actions {
1386   my $self          = shift;
1387   my $method_prefix = shift;
1388   my $call          = shift;
1389
1390   if (not ref($call)) {
1391     my $method = $method_prefix . $call;
1392     $self->$method(@_);
1393   } elsif (ref($call) eq 'CODE') {
1394     $self->$call(@_);
1395   } elsif (ref($call) eq 'ARRAY') {
1396     if (ref($call->[0]) ne 'ARRAY') {
1397       $self->_do_connection_actions($method_prefix, $_) for @$call;
1398     } else {
1399       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1400     }
1401   } else {
1402     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1403   }
1404
1405   return $self;
1406 }
1407
1408 sub connect_call_do_sql {
1409   my $self = shift;
1410   $self->_do_query(@_);
1411 }
1412
1413 sub disconnect_call_do_sql {
1414   my $self = shift;
1415   $self->_do_query(@_);
1416 }
1417
1418 # override in db-specific backend when necessary
1419 sub connect_call_datetime_setup { 1 }
1420
1421 sub _do_query {
1422   my ($self, $action) = @_;
1423
1424   if (ref $action eq 'CODE') {
1425     $action = $action->($self);
1426     $self->_do_query($_) foreach @$action;
1427   }
1428   else {
1429     # Most debuggers expect ($sql, @bind), so we need to exclude
1430     # the attribute hash which is the second argument to $dbh->do
1431     # furthermore the bind values are usually to be presented
1432     # as named arrayref pairs, so wrap those here too
1433     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1434     my $sql = shift @do_args;
1435     my $attrs = shift @do_args;
1436     my @bind = map { [ undef, $_ ] } @do_args;
1437
1438     $self->dbh_do(sub {
1439       $_[0]->_query_start($sql, \@bind);
1440       $_[1]->do($sql, $attrs, @do_args);
1441       $_[0]->_query_end($sql, \@bind);
1442     });
1443   }
1444
1445   return $self;
1446 }
1447
1448 sub _connect {
1449   my $self = shift;
1450
1451   my $info = $self->_dbi_connect_info;
1452
1453   $self->throw_exception("You did not provide any connection_info")
1454     unless defined $info->[0];
1455
1456   my ($old_connect_via, $dbh);
1457
1458   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1459
1460   # this odd anonymous coderef dereference is in fact really
1461   # necessary to avoid the unwanted effect described in perl5
1462   # RT#75792
1463   #
1464   # in addition the coderef itself can't reside inside the try{} block below
1465   # as it somehow triggers a leak under perl -d
1466   my $dbh_error_handler_installer = sub {
1467     weaken (my $weak_self = $_[0]);
1468
1469     # the coderef is blessed so we can distinguish it from externally
1470     # supplied handles (which must be preserved)
1471     $_[1]->{HandleError} = bless sub {
1472       if ($weak_self) {
1473         $weak_self->throw_exception("DBI Exception: $_[0]");
1474       }
1475       else {
1476         # the handler may be invoked by something totally out of
1477         # the scope of DBIC
1478         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1479       }
1480     }, '__DBIC__DBH__ERROR__HANDLER__';
1481   };
1482
1483   try {
1484     if(ref $info->[0] eq 'CODE') {
1485       $dbh = $info->[0]->();
1486     }
1487     else {
1488       require DBI;
1489       $dbh = DBI->connect(@$info);
1490     }
1491
1492     die $DBI::errstr unless $dbh;
1493
1494     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1495       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1496       . 'not continue',
1497       ref $info->[0] eq 'CODE'
1498         ? "Connection coderef $info->[0] returned a"
1499         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1500     ) unless $dbh->FETCH('Active');
1501
1502     # sanity checks unless asked otherwise
1503     unless ($self->unsafe) {
1504
1505       $self->throw_exception(
1506         'Refusing clobbering of {HandleError} installed on externally supplied '
1507        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1508       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1509
1510       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1511       # request, or an external handle. Complain and set anyway
1512       unless ($dbh->{RaiseError}) {
1513         carp( ref $info->[0] eq 'CODE'
1514
1515           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1516            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1517            .'attribute has been supplied'
1518
1519           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1520            .'unsafe => 1. Toggling RaiseError back to true'
1521         );
1522
1523         $dbh->{RaiseError} = 1;
1524       }
1525
1526       $dbh_error_handler_installer->($self, $dbh);
1527     }
1528   }
1529   catch {
1530     $self->throw_exception("DBI Connection failed: $_")
1531   };
1532
1533   $self->_dbh_autocommit($dbh->{AutoCommit});
1534   return $dbh;
1535 }
1536
1537 sub txn_begin {
1538   my $self = shift;
1539
1540   # this means we have not yet connected and do not know the AC status
1541   # (e.g. coderef $dbh), need a full-fledged connection check
1542   if (! defined $self->_dbh_autocommit) {
1543     $self->ensure_connected;
1544   }
1545   # Otherwise simply connect or re-connect on pid changes
1546   else {
1547     $self->_get_dbh;
1548   }
1549
1550   $self->next::method(@_);
1551 }
1552
1553 sub _exec_txn_begin {
1554   my $self = shift;
1555
1556   # if the user is utilizing txn_do - good for him, otherwise we need to
1557   # ensure that the $dbh is healthy on BEGIN.
1558   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1559   # will be replaced by a failure of begin_work itself (which will be
1560   # then retried on reconnect)
1561   if ($self->{_in_do_block}) {
1562     $self->_dbh->begin_work;
1563   } else {
1564     $self->dbh_do(sub { $_[1]->begin_work });
1565   }
1566 }
1567
1568 sub txn_commit {
1569   my $self = shift;
1570
1571   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1572   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1573     unless $self->_dbh;
1574
1575   # esoteric case for folks using external $dbh handles
1576   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1577     carp "Storage transaction_depth 0 does not match "
1578         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1579     $self->transaction_depth(1);
1580   }
1581
1582   $self->next::method(@_);
1583
1584   # if AutoCommit is disabled txn_depth never goes to 0
1585   # as a new txn is started immediately on commit
1586   $self->transaction_depth(1) if (
1587     !$self->transaction_depth
1588       and
1589     defined $self->_dbh_autocommit
1590       and
1591     ! $self->_dbh_autocommit
1592   );
1593 }
1594
1595 sub _exec_txn_commit {
1596   shift->_dbh->commit;
1597 }
1598
1599 sub txn_rollback {
1600   my $self = shift;
1601
1602   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1603   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1604     unless $self->_dbh;
1605
1606   # esoteric case for folks using external $dbh handles
1607   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1608     carp "Storage transaction_depth 0 does not match "
1609         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1610     $self->transaction_depth(1);
1611   }
1612
1613   $self->next::method(@_);
1614
1615   # if AutoCommit is disabled txn_depth never goes to 0
1616   # as a new txn is started immediately on commit
1617   $self->transaction_depth(1) if (
1618     !$self->transaction_depth
1619       and
1620     defined $self->_dbh_autocommit
1621       and
1622     ! $self->_dbh_autocommit
1623   );
1624 }
1625
1626 sub _exec_txn_rollback {
1627   shift->_dbh->rollback;
1628 }
1629
1630 # generate some identical methods
1631 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1632   no strict qw/refs/;
1633   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1634     my $self = shift;
1635     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1636     $self->throw_exception("Unable to $meth() on a disconnected storage")
1637       unless $self->_dbh;
1638     $self->next::method(@_);
1639   };
1640 }
1641
1642 # This used to be the top-half of _execute.  It was split out to make it
1643 #  easier to override in NoBindVars without duping the rest.  It takes up
1644 #  all of _execute's args, and emits $sql, @bind.
1645 sub _prep_for_execute {
1646   #my ($self, $op, $ident, $args) = @_;
1647   return shift->_gen_sql_bind(@_)
1648 }
1649
1650 sub _gen_sql_bind {
1651   my ($self, $op, $ident, $args) = @_;
1652
1653   my ($colinfos, $from);
1654   if ( blessed($ident) ) {
1655     $from = $ident->from;
1656     $colinfos = $ident->columns_info;
1657   }
1658
1659   my ($sql, $bind);
1660   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1661
1662   $bind = $self->_resolve_bindattrs(
1663     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1664   );
1665
1666   if (
1667     ! $ENV{DBIC_DT_SEARCH_OK}
1668       and
1669     $op eq 'select'
1670       and
1671     first {
1672       length ref $_->[1]
1673         and
1674       blessed($_->[1])
1675         and
1676       $_->[1]->isa('DateTime')
1677     } @$bind
1678   ) {
1679     carp_unique 'DateTime objects passed to search() are not supported '
1680       . 'properly (InflateColumn::DateTime formats and settings are not '
1681       . 'respected.) See "Formatting DateTime objects in queries" in '
1682       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1683       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1684   }
1685
1686   return( $sql, $bind );
1687 }
1688
1689 sub _resolve_bindattrs {
1690   my ($self, $ident, $bind, $colinfos) = @_;
1691
1692   $colinfos ||= {};
1693
1694   my $resolve_bindinfo = sub {
1695     #my $infohash = shift;
1696
1697     %$colinfos = %{ $self->_resolve_column_info($ident) }
1698       unless keys %$colinfos;
1699
1700     my $ret;
1701     if (my $col = $_[0]->{dbic_colname}) {
1702       $ret = { %{$_[0]} };
1703
1704       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1705         if $colinfos->{$col}{data_type};
1706
1707       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1708         if $colinfos->{$col}{size};
1709     }
1710
1711     $ret || $_[0];
1712   };
1713
1714   return [ map {
1715     my $resolved =
1716       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1717     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1718     : (ref $_->[0] eq 'HASH')           ? [ (exists $_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype})
1719                                               ? $_->[0]
1720                                               : $resolve_bindinfo->($_->[0])
1721                                             , $_->[1] ]
1722     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1723     :                                     [ $resolve_bindinfo->(
1724                                               { dbic_colname => $_->[0] }
1725                                             ), $_->[1] ]
1726     ;
1727
1728     if (
1729       ! exists $resolved->[0]{dbd_attrs}
1730         and
1731       ! $resolved->[0]{sqlt_datatype}
1732         and
1733       length ref $resolved->[1]
1734         and
1735       ! overload::Method($resolved->[1], '""')
1736     ) {
1737       require Data::Dumper;
1738       local $Data::Dumper::Maxdepth = 1;
1739       local $Data::Dumper::Terse = 1;
1740       local $Data::Dumper::Useqq = 1;
1741       local $Data::Dumper::Indent = 0;
1742       local $Data::Dumper::Pad = ' ';
1743       $self->throw_exception(
1744         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1745       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1746       );
1747     }
1748
1749     $resolved;
1750
1751   } @$bind ];
1752 }
1753
1754 sub _format_for_trace {
1755   #my ($self, $bind) = @_;
1756
1757   ### Turn @bind from something like this:
1758   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1759   ### to this:
1760   ###   ( "'1'", "'3'" )
1761
1762   map {
1763     defined( $_ && $_->[1] )
1764       ? qq{'$_->[1]'}
1765       : q{NULL}
1766   } @{$_[1] || []};
1767 }
1768
1769 sub _query_start {
1770   my ( $self, $sql, $bind ) = @_;
1771
1772   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1773     if $self->debug;
1774 }
1775
1776 sub _query_end {
1777   my ( $self, $sql, $bind ) = @_;
1778
1779   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1780     if $self->debug;
1781 }
1782
1783 sub _dbi_attrs_for_bind {
1784   my ($self, $ident, $bind) = @_;
1785
1786   my @attrs;
1787
1788   for (map { $_->[0] } @$bind) {
1789     push @attrs, do {
1790       if (exists $_->{dbd_attrs}) {
1791         $_->{dbd_attrs}
1792       }
1793       elsif($_->{sqlt_datatype}) {
1794         # cache the result in the dbh_details hash, as it can not change unless
1795         # we connect to something else
1796         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1797         if (not exists $cache->{$_->{sqlt_datatype}}) {
1798           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1799         }
1800         $cache->{$_->{sqlt_datatype}};
1801       }
1802       else {
1803         undef;  # always push something at this position
1804       }
1805     }
1806   }
1807
1808   return \@attrs;
1809 }
1810
1811 sub _execute {
1812   my ($self, $op, $ident, @args) = @_;
1813
1814   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1815
1816   # not even a PID check - we do not care about the state of the _dbh.
1817   # All we need is to get the appropriate drivers loaded if they aren't
1818   # already so that the assumption in ad7c50fc26e holds
1819   $self->_populate_dbh unless $self->_dbh;
1820
1821   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1822     $sql,
1823     $bind,
1824     $self->_dbi_attrs_for_bind($ident, $bind),
1825   );
1826 }
1827
1828 sub _dbh_execute {
1829   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1830
1831   $self->_query_start( $sql, $bind );
1832
1833   my $sth = $self->_bind_sth_params(
1834     $self->_prepare_sth($dbh, $sql),
1835     $bind,
1836     $bind_attrs,
1837   );
1838
1839   # Can this fail without throwing an exception anyways???
1840   my $rv = $sth->execute();
1841   $self->throw_exception(
1842     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1843   ) if !$rv;
1844
1845   $self->_query_end( $sql, $bind );
1846
1847   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1848 }
1849
1850 sub _prepare_sth {
1851   my ($self, $dbh, $sql) = @_;
1852
1853   # 3 is the if_active parameter which avoids active sth re-use
1854   my $sth = $self->disable_sth_caching
1855     ? $dbh->prepare($sql)
1856     : $dbh->prepare_cached($sql, {}, 3);
1857
1858   # XXX You would think RaiseError would make this impossible,
1859   #  but apparently that's not true :(
1860   $self->throw_exception(
1861     $dbh->errstr
1862       ||
1863     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1864             .'an exception and/or setting $dbh->errstr',
1865       length ($sql) > 20
1866         ? substr($sql, 0, 20) . '...'
1867         : $sql
1868       ,
1869       'DBD::' . $dbh->{Driver}{Name},
1870     )
1871   ) if !$sth;
1872
1873   $sth;
1874 }
1875
1876 sub _bind_sth_params {
1877   my ($self, $sth, $bind, $bind_attrs) = @_;
1878
1879   for my $i (0 .. $#$bind) {
1880     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1881       $sth->bind_param_inout(
1882         $i + 1, # bind params counts are 1-based
1883         $bind->[$i][1],
1884         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1885         $bind_attrs->[$i],
1886       );
1887     }
1888     else {
1889       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1890       # confirm with dbi-dev whether explicit stringification is needed
1891       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1892         ? "$bind->[$i][1]"
1893         : $bind->[$i][1]
1894       ;
1895       $sth->bind_param(
1896         $i + 1,
1897         $v,
1898         $bind_attrs->[$i],
1899       );
1900     }
1901   }
1902
1903   $sth;
1904 }
1905
1906 sub _prefetch_autovalues {
1907   my ($self, $source, $colinfo, $to_insert) = @_;
1908
1909   my %values;
1910   for my $col (keys %$colinfo) {
1911     if (
1912       $colinfo->{$col}{auto_nextval}
1913         and
1914       (
1915         ! exists $to_insert->{$col}
1916           or
1917         ref $to_insert->{$col} eq 'SCALAR'
1918           or
1919         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1920       )
1921     ) {
1922       $values{$col} = $self->_sequence_fetch(
1923         'NEXTVAL',
1924         ( $colinfo->{$col}{sequence} ||=
1925             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1926         ),
1927       );
1928     }
1929   }
1930
1931   \%values;
1932 }
1933
1934 sub insert {
1935   my ($self, $source, $to_insert) = @_;
1936
1937   my $col_infos = $source->columns_info;
1938
1939   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1940
1941   # fuse the values, but keep a separate list of prefetched_values so that
1942   # they can be fused once again with the final return
1943   $to_insert = { %$to_insert, %$prefetched_values };
1944
1945   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1946   # Investigate what does it take to s/defined/exists/
1947   my %pcols = map { $_ => 1 } $source->primary_columns;
1948   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1949   for my $col ($source->columns) {
1950     if ($col_infos->{$col}{is_auto_increment}) {
1951       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1952       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1953     }
1954
1955     # nothing to retrieve when explicit values are supplied
1956     next if (defined $to_insert->{$col} and ! (
1957       ref $to_insert->{$col} eq 'SCALAR'
1958         or
1959       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1960     ));
1961
1962     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1963     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1964       $pcols{$col}
1965         or
1966       $col_infos->{$col}{retrieve_on_insert}
1967     );
1968   };
1969
1970   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1971   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1972
1973   my ($sqla_opts, @ir_container);
1974   if (%retrieve_cols and $self->_use_insert_returning) {
1975     $sqla_opts->{returning_container} = \@ir_container
1976       if $self->_use_insert_returning_bound;
1977
1978     $sqla_opts->{returning} = [
1979       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1980     ];
1981   }
1982
1983   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1984
1985   my %returned_cols = %$to_insert;
1986   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1987     @ir_container = try {
1988       local $SIG{__WARN__} = sub {};
1989       my @r = $sth->fetchrow_array;
1990       $sth->finish;
1991       @r;
1992     } unless @ir_container;
1993
1994     @returned_cols{@$retlist} = @ir_container if @ir_container;
1995   }
1996   else {
1997     # pull in PK if needed and then everything else
1998     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1999
2000       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2001         unless $self->can('last_insert_id');
2002
2003       my @pri_values = $self->last_insert_id($source, @missing_pri);
2004
2005       $self->throw_exception( "Can't get last insert id" )
2006         unless (@pri_values == @missing_pri);
2007
2008       @returned_cols{@missing_pri} = @pri_values;
2009       delete @retrieve_cols{@missing_pri};
2010     }
2011
2012     # if there is more left to pull
2013     if (%retrieve_cols) {
2014       $self->throw_exception(
2015         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2016       ) unless %pcols;
2017
2018       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2019
2020       my $cur = DBIx::Class::ResultSet->new($source, {
2021         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2022         select => \@left_to_fetch,
2023       })->cursor;
2024
2025       @returned_cols{@left_to_fetch} = $cur->next;
2026
2027       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2028         if scalar $cur->next;
2029     }
2030   }
2031
2032   return { %$prefetched_values, %returned_cols };
2033 }
2034
2035 sub insert_bulk {
2036   my ($self, $source, $cols, $data) = @_;
2037
2038   my @col_range = (0..$#$cols);
2039
2040   # FIXME SUBOPTIMAL - most likely this is not necessary at all
2041   # confirm with dbi-dev whether explicit stringification is needed
2042   #
2043   # forcibly stringify whatever is stringifiable
2044   # ResultSet::populate() hands us a copy - safe to mangle
2045   for my $r (0 .. $#$data) {
2046     for my $c (0 .. $#{$data->[$r]}) {
2047       $data->[$r][$c] = "$data->[$r][$c]"
2048         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
2049     }
2050   }
2051
2052   my $colinfos = $source->columns_info($cols);
2053
2054   local $self->{_autoinc_supplied_for_op} =
2055     (first { $_->{is_auto_increment} } values %$colinfos)
2056       ? 1
2057       : 0
2058   ;
2059
2060   # get a slice type index based on first row of data
2061   # a "column" in this context may refer to more than one bind value
2062   # e.g. \[ '?, ?', [...], [...] ]
2063   #
2064   # construct the value type index - a description of values types for every
2065   # per-column slice of $data:
2066   #
2067   # nonexistent - nonbind literal
2068   # 0 - regular value
2069   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2070   #
2071   # also construct the column hash to pass to the SQL generator. For plain
2072   # (non literal) values - convert the members of the first row into a
2073   # literal+bind combo, with extra positional info in the bind attr hashref.
2074   # This will allow us to match the order properly, and is so contrived
2075   # because a user-supplied literal/bind (or something else specific to a
2076   # resultsource and/or storage driver) can inject extra binds along the
2077   # way, so one can't rely on "shift positions" ordering at all. Also we
2078   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2079   # can be later matched up by address), because we want to supply a real
2080   # value on which perhaps e.g. datatype checks will be performed
2081   my ($proto_data, $value_type_by_col_idx);
2082   for my $i (@col_range) {
2083     my $colname = $cols->[$i];
2084     if (ref $data->[0][$i] eq 'SCALAR') {
2085       # no bind value at all - no type
2086
2087       $proto_data->{$colname} = $data->[0][$i];
2088     }
2089     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
2090       # repack, so we don't end up mangling the original \[]
2091       my ($sql, @bind) = @${$data->[0][$i]};
2092
2093       # normalization of user supplied stuff
2094       my $resolved_bind = $self->_resolve_bindattrs(
2095         $source, \@bind, $colinfos,
2096       );
2097
2098       # store value-less (attrs only) bind info - we will be comparing all
2099       # supplied binds against this for sanity
2100       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
2101
2102       $proto_data->{$colname} = \[ $sql, map { [
2103         # inject slice order to use for $proto_bind construction
2104           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
2105             =>
2106           $resolved_bind->[$_][1]
2107         ] } (0 .. $#bind)
2108       ];
2109     }
2110     else {
2111       $value_type_by_col_idx->{$i} = undef;
2112
2113       $proto_data->{$colname} = \[ '?', [
2114         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2115           =>
2116         $data->[0][$i]
2117       ] ];
2118     }
2119   }
2120
2121   my ($sql, $proto_bind) = $self->_prep_for_execute (
2122     'insert',
2123     $source,
2124     [ $proto_data ],
2125   );
2126
2127   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2128     # if the bindlist is empty and we had some dynamic binds, this means the
2129     # storage ate them away (e.g. the NoBindVars component) and interpolated
2130     # them directly into the SQL. This obviously can't be good for multi-inserts
2131     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2132   }
2133
2134   # sanity checks
2135   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2136   #
2137   # use an error reporting closure for convenience (less to pass)
2138   my $bad_slice_report_cref = sub {
2139     my ($msg, $r_idx, $c_idx) = @_;
2140     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2141       $msg,
2142       $cols->[$c_idx],
2143       do {
2144         require Data::Dumper::Concise;
2145         local $Data::Dumper::Maxdepth = 5;
2146         Data::Dumper::Concise::Dumper ({
2147           map { $cols->[$_] =>
2148             $data->[$r_idx][$_]
2149           } @col_range
2150         }),
2151       }
2152     );
2153   };
2154
2155   for my $col_idx (@col_range) {
2156     my $reference_val = $data->[0][$col_idx];
2157
2158     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2159       my $val = $data->[$row_idx][$col_idx];
2160
2161       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2162         if (ref $val ne 'SCALAR') {
2163           $bad_slice_report_cref->(
2164             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2165             $row_idx,
2166             $col_idx,
2167           );
2168         }
2169         elsif ($$val ne $$reference_val) {
2170           $bad_slice_report_cref->(
2171             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2172             $row_idx,
2173             $col_idx,
2174           );
2175         }
2176       }
2177       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2178         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2179           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2180         }
2181       }
2182       else {  # binds from a \[], compare type and attrs
2183         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2184           $bad_slice_report_cref->(
2185             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2186             $row_idx,
2187             $col_idx,
2188           );
2189         }
2190         # start drilling down and bail out early on identical refs
2191         elsif (
2192           $reference_val != $val
2193             or
2194           $$reference_val != $$val
2195         ) {
2196           if (${$val}->[0] ne ${$reference_val}->[0]) {
2197             $bad_slice_report_cref->(
2198               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2199               $row_idx,
2200               $col_idx,
2201             );
2202           }
2203           # need to check the bind attrs - a bind will happen only once for
2204           # the entire dataset, so any changes further down will be ignored.
2205           elsif (! Data::Compare::Compare(
2206             $value_type_by_col_idx->{$col_idx},
2207             [
2208               map
2209               { $_->[0] }
2210               @{$self->_resolve_bindattrs(
2211                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2212               )}
2213             ],
2214           )) {
2215             $bad_slice_report_cref->(
2216               'Differing bind attributes on literal/bind values not supported',
2217               $row_idx,
2218               $col_idx,
2219             );
2220           }
2221         }
2222       }
2223     }
2224   }
2225
2226   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2227   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2228   # scope guard
2229   my $guard = $self->txn_scope_guard;
2230
2231   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2232   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2233   my $rv = do {
2234     if (@$proto_bind) {
2235       # proto bind contains the information on which pieces of $data to pull
2236       # $cols is passed in only for prettier error-reporting
2237       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2238     }
2239     else {
2240       # bind_param_array doesn't work if there are no binds
2241       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2242     }
2243   };
2244
2245   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2246
2247   $guard->commit;
2248
2249   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2250 }
2251
2252 # execute_for_fetch is capable of returning data just fine (it means it
2253 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2254 # is the void-populate fast-path we will just ignore this altogether
2255 # for the time being.
2256 sub _dbh_execute_for_fetch {
2257   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2258
2259   my @idx_range = ( 0 .. $#$proto_bind );
2260
2261   # If we have any bind attributes to take care of, we will bind the
2262   # proto-bind data (which will never be used by execute_for_fetch)
2263   # However since column bindtypes are "sticky", this is sufficient
2264   # to get the DBD to apply the bindtype to all values later on
2265
2266   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2267
2268   for my $i (@idx_range) {
2269     $sth->bind_param (
2270       $i+1, # DBI bind indexes are 1-based
2271       $proto_bind->[$i][1],
2272       $bind_attrs->[$i],
2273     ) if defined $bind_attrs->[$i];
2274   }
2275
2276   # At this point $data slots named in the _bind_data_slice_idx of
2277   # each piece of $proto_bind are either \[]s or plain values to be
2278   # passed in. Construct the dispensing coderef. *NOTE* the order
2279   # of $data will differ from this of the ?s in the SQL (due to
2280   # alphabetical ordering by colname). We actually do want to
2281   # preserve this behavior so that prepare_cached has a better
2282   # chance of matching on unrelated calls
2283
2284   my $fetch_row_idx = -1; # saner loop this way
2285   my $fetch_tuple = sub {
2286     return undef if ++$fetch_row_idx > $#$data;
2287
2288     return [ map { defined $_->{_literal_bind_subindex}
2289       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2290          ->[ $_->{_literal_bind_subindex} ]
2291           ->[1]
2292       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2293     } map { $_->[0] } @$proto_bind];
2294   };
2295
2296   my $tuple_status = [];
2297   my ($rv, $err);
2298   try {
2299     $rv = $sth->execute_for_fetch(
2300       $fetch_tuple,
2301       $tuple_status,
2302     );
2303   }
2304   catch {
2305     $err = shift;
2306   };
2307
2308   # Not all DBDs are create equal. Some throw on error, some return
2309   # an undef $rv, and some set $sth->err - try whatever we can
2310   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2311     ! defined $err
2312       and
2313     ( !defined $rv or $sth->err )
2314   );
2315
2316   # Statement must finish even if there was an exception.
2317   try {
2318     $sth->finish
2319   }
2320   catch {
2321     $err = shift unless defined $err
2322   };
2323
2324   if (defined $err) {
2325     my $i = 0;
2326     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2327
2328     $self->throw_exception("Unexpected populate error: $err")
2329       if ($i > $#$tuple_status);
2330
2331     require Data::Dumper::Concise;
2332     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2333       ($tuple_status->[$i][1] || $err),
2334       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2335     );
2336   }
2337
2338   return $rv;
2339 }
2340
2341 sub _dbh_execute_inserts_with_no_binds {
2342   my ($self, $sth, $count) = @_;
2343
2344   my $err;
2345   try {
2346     my $dbh = $self->_get_dbh;
2347     local $dbh->{RaiseError} = 1;
2348     local $dbh->{PrintError} = 0;
2349
2350     $sth->execute foreach 1..$count;
2351   }
2352   catch {
2353     $err = shift;
2354   };
2355
2356   # Make sure statement is finished even if there was an exception.
2357   try {
2358     $sth->finish
2359   }
2360   catch {
2361     $err = shift unless defined $err;
2362   };
2363
2364   $self->throw_exception($err) if defined $err;
2365
2366   return $count;
2367 }
2368
2369 sub update {
2370   #my ($self, $source, @args) = @_;
2371   shift->_execute('update', @_);
2372 }
2373
2374
2375 sub delete {
2376   #my ($self, $source, @args) = @_;
2377   shift->_execute('delete', @_);
2378 }
2379
2380 sub _select {
2381   my $self = shift;
2382   $self->_execute($self->_select_args(@_));
2383 }
2384
2385 sub _select_args_to_query {
2386   my $self = shift;
2387
2388   $self->throw_exception(
2389     "Unable to generate limited query representation with 'software_limit' enabled"
2390   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2391
2392   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2393   #  = $self->_select_args($ident, $select, $cond, $attrs);
2394   my ($op, $ident, @args) =
2395     $self->_select_args(@_);
2396
2397   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2398   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2399
2400   # reuse the bind arrayref
2401   unshift @{$bind}, "($sql)";
2402   \$bind;
2403 }
2404
2405 sub _select_args {
2406   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2407
2408   # FIXME - that kind of caching would be nice to have
2409   # however currently we *may* pass the same $orig_attrs
2410   # with different ident/select/where
2411   # the whole interface needs to be rethought, since it
2412   # was centered around the flawed SQLA API. We can do
2413   # soooooo much better now. But that is also another
2414   # battle...
2415   #return (
2416   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2417   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2418
2419   my $sql_maker = $self->sql_maker;
2420   my $alias2source = $self->_resolve_ident_sources ($ident);
2421
2422   my $attrs = {
2423     %$orig_attrs,
2424     select => $select,
2425     from => $ident,
2426     where => $where,
2427
2428     # limit dialects use this stuff
2429     # yes, some CDBICompat crap does not supply an {alias} >.<
2430     ( $orig_attrs->{alias} and $alias2source->{$orig_attrs->{alias}} )
2431       ? ( _rsroot_rsrc => $alias2source->{$orig_attrs->{alias}} )
2432       : ()
2433     ,
2434   };
2435
2436   # Sanity check the attributes (SQLMaker does it too, but
2437   # in case of a software_limit we'll never reach there)
2438   if (defined $attrs->{offset}) {
2439     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2440       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2441   }
2442
2443   if (defined $attrs->{rows}) {
2444     $self->throw_exception("The rows attribute must be a positive integer if present")
2445       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2446   }
2447   elsif ($attrs->{offset}) {
2448     # MySQL actually recommends this approach.  I cringe.
2449     $attrs->{rows} = $sql_maker->__max_int;
2450   }
2451
2452   # see if we will need to tear the prefetch apart to satisfy group_by == select
2453   # this is *extremely tricky* to get right, I am still not sure I did
2454   #
2455   my ($prefetch_needs_subquery, @limit_args);
2456
2457   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2458     # we already know there is a valid group_by (we made it) and we know it is
2459     # intended to be based *only* on non-multi stuff
2460     # short circuit the group_by parsing below
2461     $prefetch_needs_subquery = 1;
2462   }
2463   elsif (
2464     # The rationale is that even if we do *not* have collapse, we still
2465     # need to wrap the core grouped select/group_by in a subquery
2466     # so that databases that care about group_by/select equivalence
2467     # are happy (this includes MySQL in strict_mode)
2468     # If any of the other joined tables are referenced in the group_by
2469     # however - the user is on their own
2470     ( $prefetch_needs_subquery or $attrs->{_related_results_construction} )
2471       and
2472     $attrs->{group_by}
2473       and
2474     @{$attrs->{group_by}}
2475       and
2476     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2477       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2478     }
2479   ) {
2480     # no aliases other than our own in group_by
2481     # if there are - do not allow subquery even if limit is present
2482     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2483   }
2484   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2485     # active collapse with a limit - that one is a no-brainer unless
2486     # overruled by a group_by above
2487     $prefetch_needs_subquery = 1;
2488   }
2489
2490   if ($prefetch_needs_subquery) {
2491     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2492   }
2493   elsif (! $attrs->{software_limit} ) {
2494     push @limit_args, (
2495       $attrs->{rows} || (),
2496       $attrs->{offset} || (),
2497     );
2498   }
2499
2500   # try to simplify the joinmap further (prune unreferenced type-single joins)
2501   if (
2502     ! $prefetch_needs_subquery  # already pruned
2503       and
2504     ref $attrs->{from}
2505       and
2506     reftype $attrs->{from} eq 'ARRAY'
2507       and
2508     @{$attrs->{from}} != 1
2509   ) {
2510     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2511   }
2512
2513   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2514   # during the result inflation stage we *need* to know what was the aliastype
2515   # map as sqla saw it when the final pieces of SQL were being assembled
2516   # Originally we simply carried around the entirety of $attrs, but this
2517   # resulted in resultsets that are being reused growing continuously, as
2518   # the hash in question grew deeper and deeper.
2519   # Instead hand-pick what to take with us here (we actually don't need much
2520   # at this point just the map itself)
2521   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2522
2523 ###
2524   # This would be the point to deflate anything found in $attrs->{where}
2525   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2526   # expect a result object. And all we have is a resultsource (it is trivial
2527   # to extract deflator coderefs via $alias2source above).
2528   #
2529   # I don't see a way forward other than changing the way deflators are
2530   # invoked, and that's just bad...
2531 ###
2532
2533   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2534 }
2535
2536 # Returns a counting SELECT for a simple count
2537 # query. Abstracted so that a storage could override
2538 # this to { count => 'firstcol' } or whatever makes
2539 # sense as a performance optimization
2540 sub _count_select {
2541   #my ($self, $source, $rs_attrs) = @_;
2542   return { count => '*' };
2543 }
2544
2545 =head2 select
2546
2547 =over 4
2548
2549 =item Arguments: $ident, $select, $condition, $attrs
2550
2551 =back
2552
2553 Handle a SQL select statement.
2554
2555 =cut
2556
2557 sub select {
2558   my $self = shift;
2559   my ($ident, $select, $condition, $attrs) = @_;
2560   return $self->cursor_class->new($self, \@_, $attrs);
2561 }
2562
2563 sub select_single {
2564   my $self = shift;
2565   my ($rv, $sth, @bind) = $self->_select(@_);
2566   my @row = $sth->fetchrow_array;
2567   my @nextrow = $sth->fetchrow_array if @row;
2568   if(@row && @nextrow) {
2569     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2570   }
2571   # Need to call finish() to work round broken DBDs
2572   $sth->finish();
2573   return @row;
2574 }
2575
2576 =head2 sql_limit_dialect
2577
2578 This is an accessor for the default SQL limit dialect used by a particular
2579 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2580 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2581 see L<DBIx::Class::SQLMaker::LimitDialects>.
2582
2583 =cut
2584
2585 sub _dbh_columns_info_for {
2586   my ($self, $dbh, $table) = @_;
2587
2588   if ($dbh->can('column_info')) {
2589     my %result;
2590     my $caught;
2591     try {
2592       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2593       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2594       $sth->execute();
2595       while ( my $info = $sth->fetchrow_hashref() ){
2596         my %column_info;
2597         $column_info{data_type}   = $info->{TYPE_NAME};
2598         $column_info{size}      = $info->{COLUMN_SIZE};
2599         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2600         $column_info{default_value} = $info->{COLUMN_DEF};
2601         my $col_name = $info->{COLUMN_NAME};
2602         $col_name =~ s/^\"(.*)\"$/$1/;
2603
2604         $result{$col_name} = \%column_info;
2605       }
2606     } catch {
2607       $caught = 1;
2608     };
2609     return \%result if !$caught && scalar keys %result;
2610   }
2611
2612   my %result;
2613   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2614   $sth->execute;
2615   my @columns = @{$sth->{NAME_lc}};
2616   for my $i ( 0 .. $#columns ){
2617     my %column_info;
2618     $column_info{data_type} = $sth->{TYPE}->[$i];
2619     $column_info{size} = $sth->{PRECISION}->[$i];
2620     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2621
2622     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2623       $column_info{data_type} = $1;
2624       $column_info{size}    = $2;
2625     }
2626
2627     $result{$columns[$i]} = \%column_info;
2628   }
2629   $sth->finish;
2630
2631   foreach my $col (keys %result) {
2632     my $colinfo = $result{$col};
2633     my $type_num = $colinfo->{data_type};
2634     my $type_name;
2635     if(defined $type_num && $dbh->can('type_info')) {
2636       my $type_info = $dbh->type_info($type_num);
2637       $type_name = $type_info->{TYPE_NAME} if $type_info;
2638       $colinfo->{data_type} = $type_name if $type_name;
2639     }
2640   }
2641
2642   return \%result;
2643 }
2644
2645 sub columns_info_for {
2646   my ($self, $table) = @_;
2647   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2648 }
2649
2650 =head2 last_insert_id
2651
2652 Return the row id of the last insert.
2653
2654 =cut
2655
2656 sub _dbh_last_insert_id {
2657     my ($self, $dbh, $source, $col) = @_;
2658
2659     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2660
2661     return $id if defined $id;
2662
2663     my $class = ref $self;
2664     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2665 }
2666
2667 sub last_insert_id {
2668   my $self = shift;
2669   $self->_dbh_last_insert_id ($self->_dbh, @_);
2670 }
2671
2672 =head2 _native_data_type
2673
2674 =over 4
2675
2676 =item Arguments: $type_name
2677
2678 =back
2679
2680 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2681 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2682 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2683
2684 The default implementation returns C<undef>, implement in your Storage driver if
2685 you need this functionality.
2686
2687 Should map types from other databases to the native RDBMS type, for example
2688 C<VARCHAR2> to C<VARCHAR>.
2689
2690 Types with modifiers should map to the underlying data type. For example,
2691 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2692
2693 Composite types should map to the container type, for example
2694 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2695
2696 =cut
2697
2698 sub _native_data_type {
2699   #my ($self, $data_type) = @_;
2700   return undef
2701 }
2702
2703 # Check if placeholders are supported at all
2704 sub _determine_supports_placeholders {
2705   my $self = shift;
2706   my $dbh  = $self->_get_dbh;
2707
2708   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2709   # but it is inaccurate more often than not
2710   return try {
2711     local $dbh->{PrintError} = 0;
2712     local $dbh->{RaiseError} = 1;
2713     $dbh->do('select ?', {}, 1);
2714     1;
2715   }
2716   catch {
2717     0;
2718   };
2719 }
2720
2721 # Check if placeholders bound to non-string types throw exceptions
2722 #
2723 sub _determine_supports_typeless_placeholders {
2724   my $self = shift;
2725   my $dbh  = $self->_get_dbh;
2726
2727   return try {
2728     local $dbh->{PrintError} = 0;
2729     local $dbh->{RaiseError} = 1;
2730     # this specifically tests a bind that is NOT a string
2731     $dbh->do('select 1 where 1 = ?', {}, 1);
2732     1;
2733   }
2734   catch {
2735     0;
2736   };
2737 }
2738
2739 =head2 sqlt_type
2740
2741 Returns the database driver name.
2742
2743 =cut
2744
2745 sub sqlt_type {
2746   shift->_get_dbh->{Driver}->{Name};
2747 }
2748
2749 =head2 bind_attribute_by_data_type
2750
2751 Given a datatype from column info, returns a database specific bind
2752 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2753 let the database planner just handle it.
2754
2755 This method is always called after the driver has been determined and a DBI
2756 connection has been established. Therefore you can refer to C<DBI::$constant>
2757 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2758 the correct modules.
2759
2760 =cut
2761
2762 sub bind_attribute_by_data_type {
2763     return;
2764 }
2765
2766 =head2 is_datatype_numeric
2767
2768 Given a datatype from column_info, returns a boolean value indicating if
2769 the current RDBMS considers it a numeric value. This controls how
2770 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2771 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2772 be performed instead of the usual C<eq>.
2773
2774 =cut
2775
2776 sub is_datatype_numeric {
2777   #my ($self, $dt) = @_;
2778
2779   return 0 unless $_[1];
2780
2781   $_[1] =~ /^ (?:
2782     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2783   ) $/ix;
2784 }
2785
2786
2787 =head2 create_ddl_dir
2788
2789 =over 4
2790
2791 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2792
2793 =back
2794
2795 Creates a SQL file based on the Schema, for each of the specified
2796 database engines in C<\@databases> in the given directory.
2797 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2798
2799 Given a previous version number, this will also create a file containing
2800 the ALTER TABLE statements to transform the previous schema into the
2801 current one. Note that these statements may contain C<DROP TABLE> or
2802 C<DROP COLUMN> statements that can potentially destroy data.
2803
2804 The file names are created using the C<ddl_filename> method below, please
2805 override this method in your schema if you would like a different file
2806 name format. For the ALTER file, the same format is used, replacing
2807 $version in the name with "$preversion-$version".
2808
2809 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2810 The most common value for this would be C<< { add_drop_table => 1 } >>
2811 to have the SQL produced include a C<DROP TABLE> statement for each table
2812 created. For quoting purposes supply C<quote_identifiers>.
2813
2814 If no arguments are passed, then the following default values are assumed:
2815
2816 =over 4
2817
2818 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2819
2820 =item version    - $schema->schema_version
2821
2822 =item directory  - './'
2823
2824 =item preversion - <none>
2825
2826 =back
2827
2828 By default, C<\%sqlt_args> will have
2829
2830  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2831
2832 merged with the hash passed in. To disable any of those features, pass in a
2833 hashref like the following
2834
2835  { ignore_constraint_names => 0, # ... other options }
2836
2837
2838 WARNING: You are strongly advised to check all SQL files created, before applying
2839 them.
2840
2841 =cut
2842
2843 sub create_ddl_dir {
2844   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2845
2846   unless ($dir) {
2847     carp "No directory given, using ./\n";
2848     $dir = './';
2849   } else {
2850       -d $dir
2851         or
2852       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2853         or
2854       $self->throw_exception(
2855         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2856       );
2857   }
2858
2859   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2860
2861   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2862   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2863
2864   my $schema_version = $schema->schema_version || '1.x';
2865   $version ||= $schema_version;
2866
2867   $sqltargs = {
2868     add_drop_table => 1,
2869     ignore_constraint_names => 1,
2870     ignore_index_names => 1,
2871     %{$sqltargs || {}}
2872   };
2873
2874   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2875     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2876   }
2877
2878   my $sqlt = SQL::Translator->new( $sqltargs );
2879
2880   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2881   my $sqlt_schema = $sqlt->translate({ data => $schema })
2882     or $self->throw_exception ($sqlt->error);
2883
2884   foreach my $db (@$databases) {
2885     $sqlt->reset();
2886     $sqlt->{schema} = $sqlt_schema;
2887     $sqlt->producer($db);
2888
2889     my $file;
2890     my $filename = $schema->ddl_filename($db, $version, $dir);
2891     if (-e $filename && ($version eq $schema_version )) {
2892       # if we are dumping the current version, overwrite the DDL
2893       carp "Overwriting existing DDL file - $filename";
2894       unlink($filename);
2895     }
2896
2897     my $output = $sqlt->translate;
2898     if(!$output) {
2899       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2900       next;
2901     }
2902     if(!open($file, ">$filename")) {
2903       $self->throw_exception("Can't open $filename for writing ($!)");
2904       next;
2905     }
2906     print $file $output;
2907     close($file);
2908
2909     next unless ($preversion);
2910
2911     require SQL::Translator::Diff;
2912
2913     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2914     if(!-e $prefilename) {
2915       carp("No previous schema file found ($prefilename)");
2916       next;
2917     }
2918
2919     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2920     if(-e $difffile) {
2921       carp("Overwriting existing diff file - $difffile");
2922       unlink($difffile);
2923     }
2924
2925     my $source_schema;
2926     {
2927       my $t = SQL::Translator->new($sqltargs);
2928       $t->debug( 0 );
2929       $t->trace( 0 );
2930
2931       $t->parser( $db )
2932         or $self->throw_exception ($t->error);
2933
2934       my $out = $t->translate( $prefilename )
2935         or $self->throw_exception ($t->error);
2936
2937       $source_schema = $t->schema;
2938
2939       $source_schema->name( $prefilename )
2940         unless ( $source_schema->name );
2941     }
2942
2943     # The "new" style of producers have sane normalization and can support
2944     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2945     # And we have to diff parsed SQL against parsed SQL.
2946     my $dest_schema = $sqlt_schema;
2947
2948     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2949       my $t = SQL::Translator->new($sqltargs);
2950       $t->debug( 0 );
2951       $t->trace( 0 );
2952
2953       $t->parser( $db )
2954         or $self->throw_exception ($t->error);
2955
2956       my $out = $t->translate( $filename )
2957         or $self->throw_exception ($t->error);
2958
2959       $dest_schema = $t->schema;
2960
2961       $dest_schema->name( $filename )
2962         unless $dest_schema->name;
2963     }
2964
2965     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2966                                                   $dest_schema,   $db,
2967                                                   $sqltargs
2968                                                  );
2969     if(!open $file, ">$difffile") {
2970       $self->throw_exception("Can't write to $difffile ($!)");
2971       next;
2972     }
2973     print $file $diff;
2974     close($file);
2975   }
2976 }
2977
2978 =head2 deployment_statements
2979
2980 =over 4
2981
2982 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2983
2984 =back
2985
2986 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2987
2988 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2989 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2990
2991 C<$directory> is used to return statements from files in a previously created
2992 L</create_ddl_dir> directory and is optional. The filenames are constructed
2993 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2994
2995 If no C<$directory> is specified then the statements are constructed on the
2996 fly using L<SQL::Translator> and C<$version> is ignored.
2997
2998 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2999
3000 =cut
3001
3002 sub deployment_statements {
3003   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3004   $type ||= $self->sqlt_type;
3005   $version ||= $schema->schema_version || '1.x';
3006   $dir ||= './';
3007   my $filename = $schema->ddl_filename($type, $version, $dir);
3008   if(-f $filename)
3009   {
3010       # FIXME replace this block when a proper sane sql parser is available
3011       my $file;
3012       open($file, "<$filename")
3013         or $self->throw_exception("Can't open $filename ($!)");
3014       my @rows = <$file>;
3015       close($file);
3016       return join('', @rows);
3017   }
3018
3019   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
3020     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
3021   }
3022
3023   # sources needs to be a parser arg, but for simplicity allow at top level
3024   # coming in
3025   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3026       if exists $sqltargs->{sources};
3027
3028   my $tr = SQL::Translator->new(
3029     producer => "SQL::Translator::Producer::${type}",
3030     %$sqltargs,
3031     parser => 'SQL::Translator::Parser::DBIx::Class',
3032     data => $schema,
3033   );
3034
3035   return preserve_context {
3036     $tr->translate
3037   } after => sub {
3038     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3039       unless defined $_[0];
3040   };
3041 }
3042
3043 # FIXME deploy() currently does not accurately report sql errors
3044 # Will always return true while errors are warned
3045 sub deploy {
3046   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3047   my $deploy = sub {
3048     my $line = shift;
3049     return if(!$line);
3050     return if($line =~ /^--/);
3051     # next if($line =~ /^DROP/m);
3052     return if($line =~ /^BEGIN TRANSACTION/m);
3053     return if($line =~ /^COMMIT/m);
3054     return if $line =~ /^\s+$/; # skip whitespace only
3055     $self->_query_start($line);
3056     try {
3057       # do a dbh_do cycle here, as we need some error checking in
3058       # place (even though we will ignore errors)
3059       $self->dbh_do (sub { $_[1]->do($line) });
3060     } catch {
3061       carp qq{$_ (running "${line}")};
3062     };
3063     $self->_query_end($line);
3064   };
3065   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3066   if (@statements > 1) {
3067     foreach my $statement (@statements) {
3068       $deploy->( $statement );
3069     }
3070   }
3071   elsif (@statements == 1) {
3072     # split on single line comments and end of statements
3073     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3074       $deploy->( $line );
3075     }
3076   }
3077 }
3078
3079 =head2 datetime_parser
3080
3081 Returns the datetime parser class
3082
3083 =cut
3084
3085 sub datetime_parser {
3086   my $self = shift;
3087   return $self->{datetime_parser} ||= do {
3088     $self->build_datetime_parser(@_);
3089   };
3090 }
3091
3092 =head2 datetime_parser_type
3093
3094 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3095
3096 =head2 build_datetime_parser
3097
3098 See L</datetime_parser>
3099
3100 =cut
3101
3102 sub build_datetime_parser {
3103   my $self = shift;
3104   my $type = $self->datetime_parser_type(@_);
3105   return $type;
3106 }
3107
3108
3109 =head2 is_replicating
3110
3111 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3112 replicate from a master database.  Default is undef, which is the result
3113 returned by databases that don't support replication.
3114
3115 =cut
3116
3117 sub is_replicating {
3118     return;
3119
3120 }
3121
3122 =head2 lag_behind_master
3123
3124 Returns a number that represents a certain amount of lag behind a master db
3125 when a given storage is replicating.  The number is database dependent, but
3126 starts at zero and increases with the amount of lag. Default in undef
3127
3128 =cut
3129
3130 sub lag_behind_master {
3131     return;
3132 }
3133
3134 =head2 relname_to_table_alias
3135
3136 =over 4
3137
3138 =item Arguments: $relname, $join_count
3139
3140 =item Return Value: $alias
3141
3142 =back
3143
3144 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3145 queries.
3146
3147 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3148 way these aliases are named.
3149
3150 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3151 otherwise C<"$relname">.
3152
3153 =cut
3154
3155 sub relname_to_table_alias {
3156   my ($self, $relname, $join_count) = @_;
3157
3158   my $alias = ($join_count && $join_count > 1 ?
3159     join('_', $relname, $join_count) : $relname);
3160
3161   return $alias;
3162 }
3163
3164 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3165 # version and it may be necessary to amend or override it for a specific storage
3166 # if such binds are necessary.
3167 sub _max_column_bytesize {
3168   my ($self, $attr) = @_;
3169
3170   my $max_size;
3171
3172   if ($attr->{sqlt_datatype}) {
3173     my $data_type = lc($attr->{sqlt_datatype});
3174
3175     if ($attr->{sqlt_size}) {
3176
3177       # String/sized-binary types
3178       if ($data_type =~ /^(?:
3179           l? (?:var)? char(?:acter)? (?:\s*varying)?
3180             |
3181           (?:var)? binary (?:\s*varying)?
3182             |
3183           raw
3184         )\b/x
3185       ) {
3186         $max_size = $attr->{sqlt_size};
3187       }
3188       # Other charset/unicode types, assume scale of 4
3189       elsif ($data_type =~ /^(?:
3190           national \s* character (?:\s*varying)?
3191             |
3192           nchar
3193             |
3194           univarchar
3195             |
3196           nvarchar
3197         )\b/x
3198       ) {
3199         $max_size = $attr->{sqlt_size} * 4;
3200       }
3201     }
3202
3203     if (!$max_size and !$self->_is_lob_type($data_type)) {
3204       $max_size = 100 # for all other (numeric?) datatypes
3205     }
3206   }
3207
3208   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3209 }
3210
3211 # Determine if a data_type is some type of BLOB
3212 sub _is_lob_type {
3213   my ($self, $data_type) = @_;
3214   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3215     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3216                                   |varchar|character\s*varying|nvarchar
3217                                   |national\s*character\s*varying))?\z/xi);
3218 }
3219
3220 sub _is_binary_lob_type {
3221   my ($self, $data_type) = @_;
3222   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3223     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3224 }
3225
3226 sub _is_text_lob_type {
3227   my ($self, $data_type) = @_;
3228   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3229     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3230                         |national\s*character\s*varying))\z/xi);
3231 }
3232
3233 # Determine if a data_type is some type of a binary type
3234 sub _is_binary_type {
3235   my ($self, $data_type) = @_;
3236   $data_type && ($self->_is_binary_lob_type($data_type)
3237     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3238 }
3239
3240 1;
3241
3242 =head1 USAGE NOTES
3243
3244 =head2 DBIx::Class and AutoCommit
3245
3246 DBIx::Class can do some wonderful magic with handling exceptions,
3247 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3248 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3249 transaction support.
3250
3251 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3252 in an assumed transaction between commits, and you're telling us you'd
3253 like to manage that manually.  A lot of the magic protections offered by
3254 this module will go away.  We can't protect you from exceptions due to database
3255 disconnects because we don't know anything about how to restart your
3256 transactions.  You're on your own for handling all sorts of exceptional
3257 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3258 be with raw DBI.
3259
3260
3261 =head1 AUTHOR AND CONTRIBUTORS
3262
3263 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3264
3265 =head1 LICENSE
3266
3267 You may distribute this code under the same terms as Perl itself.
3268
3269 =cut