lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use Data::Compare (); # no imports!!! guard against insane architecture
  16 use SQL::Abstract qw(is_plain_value is_literal_value);
  17 use DBIx::Class::_Util qw(quote_sub perlstring);
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. We also need to separate accessors
  83 # from plain old method calls, since an accessor called as a setter
  84 # does *not* need the driver determination loop fired (and in fact
  85 # can produce hard to find bugs, like e.g. losing on_connect_*
  86 # semantics on fresh connections)
  87 #
  88 # The construct below is simply a parameterized around()
  89 my $storage_accessor_idx = { map { $_ => 1 } qw(
  90   sqlt_type
  91   datetime_parser_type
  92
  93   sql_maker
  94   cursor_class
  95 )};
  96 for my $meth (keys %$storage_accessor_idx, qw(
  97   deployment_statements
  98
  99   build_datetime_parser
 100
 101   txn_begin
 102
 103   insert
 104   update
 105   delete
 106   select
 107   select_single
 108
 109   _insert_bulk
 110
 111   with_deferred_fk_checks
 112
 113   get_use_dbms_capability
 114   get_dbms_capability
 115
 116   _server_info
 117   _get_server_version
 118 )) {
 119
 120   my $orig = __PACKAGE__->can ($meth)
 121     or die "$meth is not a ::Storage::DBI method!";
 122
 123   my $is_getter = $storage_accessor_idx->{$meth} ? 0 : 1;
 124
 125   quote_sub
 126     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $is_getter, perlstring $meth ), { '$orig' => \$orig };
 127
 128     if (
 129       # only fire when invoked on an instance, a valid class-based invocation
 130       # would e.g. be setting a default for an inherited accessor
 131       ref $_[0]
 132         and
 133       ! $_[0]->{_driver_determined}
 134         and
 135       ! $_[0]->{_in_determine_driver}
 136         and
 137       # if this is a known *setter* - just set it, no need to connect
 138       # and determine the driver
 139       ( %1$s or @_ <= 1 )
 140         and
 141       # Only try to determine stuff if we have *something* that either is or can
 142       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 143       # to still be marginally useful
 144       $_[0]->_dbi_connect_info->[0]
 145     ) {
 146       $_[0]->_determine_driver;
 147
 148       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 149       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 150
 151       my $cref = $_[0]->can(%2$s);
 152       goto $cref;
 153     }
 154
 155     goto $orig;
 156 EOC
 157 }
 158
 159 =head1 NAME
 160
 161 DBIx::Class::Storage::DBI - DBI storage handler
 162
 163 =head1 SYNOPSIS
 164
 165   my $schema = MySchema->connect('dbi:SQLite:my.db');
 166
 167   $schema->storage->debug(1);
 168
 169   my @stuff = $schema->storage->dbh_do(
 170     sub {
 171       my ($storage, $dbh, @args) = @_;
 172       $dbh->do("DROP TABLE authors");
 173     },
 174     @column_list
 175   );
 176
 177   $schema->resultset('Book')->search({
 178      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 179   });
 180
 181 =head1 DESCRIPTION
 182
 183 This class represents the connection to an RDBMS via L<DBI>.  See
 184 L<DBIx::Class::Storage> for general information.  This pod only
 185 documents DBI-specific methods and behaviors.
 186
 187 =head1 METHODS
 188
 189 =cut
 190
 191 sub new {
 192   my $new = shift->next::method(@_);
 193
 194   $new->_sql_maker_opts({});
 195   $new->_dbh_details({});
 196   $new->{_in_do_block} = 0;
 197
 198   # read below to see what this does
 199   $new->_arm_global_destructor;
 200
 201   $new;
 202 }
 203
 204 # This is hack to work around perl shooting stuff in random
 205 # order on exit(). If we do not walk the remaining storage
 206 # objects in an END block, there is a *small but real* chance
 207 # of a fork()ed child to kill the parent's shared DBI handle,
 208 # *before perl reaches the DESTROY in this package*
 209 # Yes, it is ugly and effective.
 210 # Additionally this registry is used by the CLONE method to
 211 # make sure no handles are shared between threads
 212 {
 213   my %seek_and_destroy;
 214
 215   sub _arm_global_destructor {
 216
 217     # quick "garbage collection" pass - prevents the registry
 218     # from slowly growing with a bunch of undef-valued keys
 219     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 220       for keys %seek_and_destroy;
 221
 222     weaken (
 223       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 224     );
 225   }
 226
 227   END {
 228     local $?; # just in case the DBI destructor changes it somehow
 229
 230     # destroy just the object if not native to this process
 231     $_->_verify_pid for (grep
 232       { defined $_ }
 233       values %seek_and_destroy
 234     );
 235   }
 236
 237   sub CLONE {
 238     # As per DBI's recommendation, DBIC disconnects all handles as
 239     # soon as possible (DBIC will reconnect only on demand from within
 240     # the thread)
 241     my @instances = grep { defined $_ } values %seek_and_destroy;
 242     %seek_and_destroy = ();
 243
 244     for (@instances) {
 245       $_->_dbh(undef);
 246
 247       $_->transaction_depth(0);
 248       $_->savepoints([]);
 249
 250       # properly renumber existing refs
 251       $_->_arm_global_destructor
 252     }
 253   }
 254 }
 255
 256 sub DESTROY {
 257   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 258   # some databases spew warnings on implicit disconnect
 259   local $SIG{__WARN__} = sub {};
 260   $_[0]->_dbh(undef);
 261
 262   # this op is necessary, since the very last perl runtime statement
 263   # triggers a global destruction shootout, and the $SIG localization
 264   # may very well be destroyed before perl actually gets to do the
 265   # $dbh undef
 266   1;
 267 }
 268
 269 # handle pid changes correctly - do not destroy parent's connection
 270 sub _verify_pid {
 271
 272   my $pid = $_[0]->_conn_pid;
 273
 274   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 275     $dbh->{InactiveDestroy} = 1;
 276     $_[0]->_dbh(undef);
 277     $_[0]->transaction_depth(0);
 278     $_[0]->savepoints([]);
 279   }
 280
 281   return;
 282 }
 283
 284 =head2 connect_info
 285
 286 This method is normally called by L<DBIx::Class::Schema/connection>, which
 287 encapsulates its argument list in an arrayref before passing them here.
 288
 289 The argument list may contain:
 290
 291 =over
 292
 293 =item *
 294
 295 The same 4-element argument set one would normally pass to
 296 L<DBI/connect>, optionally followed by
 297 L<extra attributes|/DBIx::Class specific connection attributes>
 298 recognized by DBIx::Class:
 299
 300   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 301
 302 =item *
 303
 304 A single code reference which returns a connected
 305 L<DBI database handle|DBI/connect> optionally followed by
 306 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 307 by DBIx::Class:
 308
 309   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 310
 311 =item *
 312
 313 A single hashref with all the attributes and the dsn/user/password
 314 mixed together:
 315
 316   $connect_info_args = [{
 317     dsn => $dsn,
 318     user => $user,
 319     password => $pass,
 320     %dbi_attributes,
 321     %extra_attributes,
 322   }];
 323
 324   $connect_info_args = [{
 325     dbh_maker => sub { DBI->connect (...) },
 326     %dbi_attributes,
 327     %extra_attributes,
 328   }];
 329
 330 This is particularly useful for L<Catalyst> based applications, allowing the
 331 following config (L<Config::General> style):
 332
 333   <Model::DB>
 334     schema_class   App::DB
 335     <connect_info>
 336       dsn          dbi:mysql:database=test
 337       user         testuser
 338       password     TestPass
 339       AutoCommit   1
 340     </connect_info>
 341   </Model::DB>
 342
 343 The C<dsn>/C<user>/C<password> combination can be substituted by the
 344 C<dbh_maker> key whose value is a coderef that returns a connected
 345 L<DBI database handle|DBI/connect>
 346
 347 =back
 348
 349 Please note that the L<DBI> docs recommend that you always explicitly
 350 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 351 recommends that it be set to I<1>, and that you perform transactions
 352 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 353 to I<1> if you do not do explicitly set it to zero.  This is the default
 354 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 355
 356 =head3 DBIx::Class specific connection attributes
 357
 358 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 359 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 360 the following connection options. These options can be mixed in with your other
 361 L<DBI> connection attributes, or placed in a separate hashref
 362 (C<\%extra_attributes>) as shown above.
 363
 364 Every time C<connect_info> is invoked, any previous settings for
 365 these options will be cleared before setting the new ones, regardless of
 366 whether any options are specified in the new C<connect_info>.
 367
 368
 369 =over
 370
 371 =item on_connect_do
 372
 373 Specifies things to do immediately after connecting or re-connecting to
 374 the database.  Its value may contain:
 375
 376 =over
 377
 378 =item a scalar
 379
 380 This contains one SQL statement to execute.
 381
 382 =item an array reference
 383
 384 This contains SQL statements to execute in order.  Each element contains
 385 a string or a code reference that returns a string.
 386
 387 =item a code reference
 388
 389 This contains some code to execute.  Unlike code references within an
 390 array reference, its return value is ignored.
 391
 392 =back
 393
 394 =item on_disconnect_do
 395
 396 Takes arguments in the same form as L</on_connect_do> and executes them
 397 immediately before disconnecting from the database.
 398
 399 Note, this only runs if you explicitly call L</disconnect> on the
 400 storage object.
 401
 402 =item on_connect_call
 403
 404 A more generalized form of L</on_connect_do> that calls the specified
 405 C<connect_call_METHOD> methods in your storage driver.
 406
 407   on_connect_do => 'select 1'
 408
 409 is equivalent to:
 410
 411   on_connect_call => [ [ do_sql => 'select 1' ] ]
 412
 413 Its values may contain:
 414
 415 =over
 416
 417 =item a scalar
 418
 419 Will call the C<connect_call_METHOD> method.
 420
 421 =item a code reference
 422
 423 Will execute C<< $code->($storage) >>
 424
 425 =item an array reference
 426
 427 Each value can be a method name or code reference.
 428
 429 =item an array of arrays
 430
 431 For each array, the first item is taken to be the C<connect_call_> method name
 432 or code reference, and the rest are parameters to it.
 433
 434 =back
 435
 436 Some predefined storage methods you may use:
 437
 438 =over
 439
 440 =item do_sql
 441
 442 Executes a SQL string or a code reference that returns a SQL string. This is
 443 what L</on_connect_do> and L</on_disconnect_do> use.
 444
 445 It can take:
 446
 447 =over
 448
 449 =item a scalar
 450
 451 Will execute the scalar as SQL.
 452
 453 =item an arrayref
 454
 455 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 456 attributes hashref and bind values.
 457
 458 =item a code reference
 459
 460 Will execute C<< $code->($storage) >> and execute the return array refs as
 461 above.
 462
 463 =back
 464
 465 =item datetime_setup
 466
 467 Execute any statements necessary to initialize the database session to return
 468 and accept datetime/timestamp values used with
 469 L<DBIx::Class::InflateColumn::DateTime>.
 470
 471 Only necessary for some databases, see your specific storage driver for
 472 implementation details.
 473
 474 =back
 475
 476 =item on_disconnect_call
 477
 478 Takes arguments in the same form as L</on_connect_call> and executes them
 479 immediately before disconnecting from the database.
 480
 481 Calls the C<disconnect_call_METHOD> methods as opposed to the
 482 C<connect_call_METHOD> methods called by L</on_connect_call>.
 483
 484 Note, this only runs if you explicitly call L</disconnect> on the
 485 storage object.
 486
 487 =item disable_sth_caching
 488
 489 If set to a true value, this option will disable the caching of
 490 statement handles via L<DBI/prepare_cached>.
 491
 492 =item limit_dialect
 493
 494 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 495 default L</sql_limit_dialect> setting of the storage (if any). For a list
 496 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 497
 498 =item quote_names
 499
 500 When true automatically sets L</quote_char> and L</name_sep> to the characters
 501 appropriate for your particular RDBMS. This option is preferred over specifying
 502 L</quote_char> directly.
 503
 504 =item quote_char
 505
 506 Specifies what characters to use to quote table and column names.
 507
 508 C<quote_char> expects either a single character, in which case is it
 509 is placed on either side of the table/column name, or an arrayref of length
 510 2 in which case the table/column name is placed between the elements.
 511
 512 For example under MySQL you should use C<< quote_char => '`' >>, and for
 513 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 514
 515 =item name_sep
 516
 517 This parameter is only useful in conjunction with C<quote_char>, and is used to
 518 specify the character that separates elements (schemas, tables, columns) from
 519 each other. If unspecified it defaults to the most commonly used C<.>.
 520
 521 =item unsafe
 522
 523 This Storage driver normally installs its own C<HandleError>, sets
 524 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 525 all database handles, including those supplied by a coderef.  It does this
 526 so that it can have consistent and useful error behavior.
 527
 528 If you set this option to a true value, Storage will not do its usual
 529 modifications to the database handle's attributes, and instead relies on
 530 the settings in your connect_info DBI options (or the values you set in
 531 your connection coderef, in the case that you are connecting via coderef).
 532
 533 Note that your custom settings can cause Storage to malfunction,
 534 especially if you set a C<HandleError> handler that suppresses exceptions
 535 and/or disable C<RaiseError>.
 536
 537 =item auto_savepoint
 538
 539 If this option is true, L<DBIx::Class> will use savepoints when nesting
 540 transactions, making it possible to recover from failure in the inner
 541 transaction without having to abort all outer transactions.
 542
 543 =item cursor_class
 544
 545 Use this argument to supply a cursor class other than the default
 546 L<DBIx::Class::Storage::DBI::Cursor>.
 547
 548 =back
 549
 550 Some real-life examples of arguments to L</connect_info> and
 551 L<DBIx::Class::Schema/connect>
 552
 553   # Simple SQLite connection
 554   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 555
 556   # Connect via subref
 557   ->connect_info([ sub { DBI->connect(...) } ]);
 558
 559   # Connect via subref in hashref
 560   ->connect_info([{
 561     dbh_maker => sub { DBI->connect(...) },
 562     on_connect_do => 'alter session ...',
 563   }]);
 564
 565   # A bit more complicated
 566   ->connect_info(
 567     [
 568       'dbi:Pg:dbname=foo',
 569       'postgres',
 570       'my_pg_password',
 571       { AutoCommit => 1 },
 572       { quote_char => q{"} },
 573     ]
 574   );
 575
 576   # Equivalent to the previous example
 577   ->connect_info(
 578     [
 579       'dbi:Pg:dbname=foo',
 580       'postgres',
 581       'my_pg_password',
 582       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 583     ]
 584   );
 585
 586   # Same, but with hashref as argument
 587   # See parse_connect_info for explanation
 588   ->connect_info(
 589     [{
 590       dsn         => 'dbi:Pg:dbname=foo',
 591       user        => 'postgres',
 592       password    => 'my_pg_password',
 593       AutoCommit  => 1,
 594       quote_char  => q{"},
 595       name_sep    => q{.},
 596     }]
 597   );
 598
 599   # Subref + DBIx::Class-specific connection options
 600   ->connect_info(
 601     [
 602       sub { DBI->connect(...) },
 603       {
 604           quote_char => q{`},
 605           name_sep => q{@},
 606           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 607           disable_sth_caching => 1,
 608       },
 609     ]
 610   );
 611
 612
 613
 614 =cut
 615
 616 sub connect_info {
 617   my ($self, $info) = @_;
 618
 619   return $self->_connect_info if !$info;
 620
 621   $self->_connect_info($info); # copy for _connect_info
 622
 623   $info = $self->_normalize_connect_info($info)
 624     if ref $info eq 'ARRAY';
 625
 626   my %attrs = (
 627     %{ $self->_default_dbi_connect_attributes || {} },
 628     %{ $info->{attributes} || {} },
 629   );
 630
 631   my @args = @{ $info->{arguments} };
 632
 633   if (keys %attrs and ref $args[0] ne 'CODE') {
 634     carp_unique (
 635         'You provided explicit AutoCommit => 0 in your connection_info. '
 636       . 'This is almost universally a bad idea (see the footnotes of '
 637       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 638       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 639       . 'this warning.'
 640     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 641
 642     push @args, \%attrs if keys %attrs;
 643   }
 644
 645   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 646   # OR a single-element coderef-based $dbh factory
 647   $self->_dbi_connect_info(\@args);
 648
 649   # extract the individual storage options
 650   for my $storage_opt (keys %{ $info->{storage_options} }) {
 651     my $value = $info->{storage_options}{$storage_opt};
 652
 653     $self->$storage_opt($value);
 654   }
 655
 656   # Extract the individual sqlmaker options
 657   #
 658   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 659   #  the new set of options
 660   $self->_sql_maker(undef);
 661   $self->_sql_maker_opts({});
 662
 663   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 664     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 665
 666     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 667   }
 668
 669   # FIXME - dirty:
 670   # save attributes in a separate accessor so they are always
 671   # introspectable, even in case of a CODE $dbhmaker
 672   $self->_dbic_connect_attributes (\%attrs);
 673
 674   return $self->_connect_info;
 675 }
 676
 677 sub _dbi_connect_info {
 678   my $self = shift;
 679
 680   return $self->{_dbi_connect_info} = $_[0]
 681     if @_;
 682
 683   my $conninfo = $self->{_dbi_connect_info} || [];
 684
 685   # last ditch effort to grab a DSN
 686   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 687     my @new_conninfo = @$conninfo;
 688     $new_conninfo[0] = $ENV{DBI_DSN};
 689     $conninfo = \@new_conninfo;
 690   }
 691
 692   return $conninfo;
 693 }
 694
 695
 696 sub _normalize_connect_info {
 697   my ($self, $info_arg) = @_;
 698   my %info;
 699
 700   my @args = @$info_arg;  # take a shallow copy for further mutilation
 701
 702   # combine/pre-parse arguments depending on invocation style
 703
 704   my %attrs;
 705   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 706     %attrs = %{ $args[1] || {} };
 707     @args = $args[0];
 708   }
 709   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 710     %attrs = %{$args[0]};
 711     @args = ();
 712     if (my $code = delete $attrs{dbh_maker}) {
 713       @args = $code;
 714
 715       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 716       if (@ignored) {
 717         carp sprintf (
 718             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 719           . "to the result of 'dbh_maker'",
 720
 721           join (', ', map { "'$_'" } (@ignored) ),
 722         );
 723       }
 724     }
 725     else {
 726       @args = delete @attrs{qw/dsn user password/};
 727     }
 728   }
 729   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 730     %attrs = (
 731       % { $args[3] || {} },
 732       % { $args[4] || {} },
 733     );
 734     @args = @args[0,1,2];
 735   }
 736
 737   $info{arguments} = \@args;
 738
 739   my @storage_opts = grep exists $attrs{$_},
 740     @storage_options, 'cursor_class';
 741
 742   @{ $info{storage_options} }{@storage_opts} =
 743     delete @attrs{@storage_opts} if @storage_opts;
 744
 745   my @sql_maker_opts = grep exists $attrs{$_},
 746     qw/limit_dialect quote_char name_sep quote_names/;
 747
 748   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 749     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 750
 751   $info{attributes} = \%attrs if %attrs;
 752
 753   return \%info;
 754 }
 755
 756 sub _default_dbi_connect_attributes () {
 757   +{
 758     AutoCommit => 1,
 759     PrintError => 0,
 760     RaiseError => 1,
 761     ShowErrorStatement => 1,
 762   };
 763 }
 764
 765 =head2 on_connect_do
 766
 767 This method is deprecated in favour of setting via L</connect_info>.
 768
 769 =cut
 770
 771 =head2 on_disconnect_do
 772
 773 This method is deprecated in favour of setting via L</connect_info>.
 774
 775 =cut
 776
 777 sub _parse_connect_do {
 778   my ($self, $type) = @_;
 779
 780   my $val = $self->$type;
 781   return () if not defined $val;
 782
 783   my @res;
 784
 785   if (not ref($val)) {
 786     push @res, [ 'do_sql', $val ];
 787   } elsif (ref($val) eq 'CODE') {
 788     push @res, $val;
 789   } elsif (ref($val) eq 'ARRAY') {
 790     push @res, map { [ 'do_sql', $_ ] } @$val;
 791   } else {
 792     $self->throw_exception("Invalid type for $type: ".ref($val));
 793   }
 794
 795   return \@res;
 796 }
 797
 798 =head2 dbh_do
 799
 800 Arguments: ($subref | $method_name), @extra_coderef_args?
 801
 802 Execute the given $subref or $method_name using the new exception-based
 803 connection management.
 804
 805 The first two arguments will be the storage object that C<dbh_do> was called
 806 on and a database handle to use.  Any additional arguments will be passed
 807 verbatim to the called subref as arguments 2 and onwards.
 808
 809 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 810 exception handling and reconnection (or failover in future subclasses).
 811
 812 Your subref should have no side-effects outside of the database, as
 813 there is the potential for your subref to be partially double-executed
 814 if the database connection was stale/dysfunctional.
 815
 816 Example:
 817
 818   my @stuff = $schema->storage->dbh_do(
 819     sub {
 820       my ($storage, $dbh, @cols) = @_;
 821       my $cols = join(q{, }, @cols);
 822       $dbh->selectrow_array("SELECT $cols FROM foo");
 823     },
 824     @column_list
 825   );
 826
 827 =cut
 828
 829 sub dbh_do {
 830   my $self = shift;
 831   my $run_target = shift; # either a coderef or a method name
 832
 833   # short circuit when we know there is no need for a runner
 834   #
 835   # FIXME - assumption may be wrong
 836   # the rationale for the txn_depth check is that if this block is a part
 837   # of a larger transaction, everything up to that point is screwed anyway
 838   return $self->$run_target($self->_get_dbh, @_)
 839     if $self->{_in_do_block} or $self->transaction_depth;
 840
 841   # take a ref instead of a copy, to preserve @_ aliasing
 842   # semantics within the coderef, but only if needed
 843   # (pseudoforking doesn't like this trick much)
 844   my $args = @_ ? \@_ : [];
 845
 846   DBIx::Class::Storage::BlockRunner->new(
 847     storage => $self,
 848     wrap_txn => 0,
 849     retry_handler => sub {
 850       $_[0]->failed_attempt_count == 1
 851         and
 852       ! $_[0]->storage->connected
 853     },
 854   )->run(sub {
 855     $self->$run_target ($self->_get_dbh, @$args )
 856   });
 857 }
 858
 859 sub txn_do {
 860   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 861   shift->next::method(@_);
 862 }
 863
 864 =head2 disconnect
 865
 866 Our C<disconnect> method also performs a rollback first if the
 867 database is not in C<AutoCommit> mode.
 868
 869 =cut
 870
 871 sub disconnect {
 872
 873   if( my $dbh = $_[0]->_dbh ) {
 874
 875     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 876       ( $_[0]->on_disconnect_call || () ),
 877       $_[0]->_parse_connect_do ('on_disconnect_do')
 878     );
 879
 880     # stops the "implicit rollback on disconnect" warning
 881     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 882
 883     %{ $dbh->{CachedKids} } = ();
 884     $dbh->disconnect;
 885     $_[0]->_dbh(undef);
 886   }
 887 }
 888
 889 =head2 with_deferred_fk_checks
 890
 891 =over 4
 892
 893 =item Arguments: C<$coderef>
 894
 895 =item Return Value: The return value of $coderef
 896
 897 =back
 898
 899 Storage specific method to run the code ref with FK checks deferred or
 900 in MySQL's case disabled entirely.
 901
 902 =cut
 903
 904 # Storage subclasses should override this
 905 sub with_deferred_fk_checks {
 906   #my ($self, $sub) = @_;
 907   $_[1]->();
 908 }
 909
 910 =head2 connected
 911
 912 =over
 913
 914 =item Arguments: none
 915
 916 =item Return Value: 1|0
 917
 918 =back
 919
 920 Verifies that the current database handle is active and ready to execute
 921 an SQL statement (e.g. the connection did not get stale, server is still
 922 answering, etc.) This method is used internally by L</dbh>.
 923
 924 =cut
 925
 926 sub connected {
 927   return 0 unless $_[0]->_seems_connected;
 928
 929   #be on the safe side
 930   local $_[0]->_dbh->{RaiseError} = 1;
 931
 932   return $_[0]->_ping;
 933 }
 934
 935 sub _seems_connected {
 936   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 937
 938   ($_[0]->_dbh || return 0)->FETCH('Active');
 939 }
 940
 941 sub _ping {
 942   ($_[0]->_dbh || return 0)->ping;
 943 }
 944
 945 sub ensure_connected {
 946   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 947 }
 948
 949 =head2 dbh
 950
 951 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 952 is guaranteed to be healthy by implicitly calling L</connected>, and if
 953 necessary performing a reconnection before returning. Keep in mind that this
 954 is very B<expensive> on some database engines. Consider using L</dbh_do>
 955 instead.
 956
 957 =cut
 958
 959 sub dbh {
 960   # maybe save a ping call
 961   $_[0]->_dbh
 962     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 963     : $_[0]->_populate_dbh
 964   ;
 965 }
 966
 967 # this is the internal "get dbh or connect (don't check)" method
 968 sub _get_dbh {
 969   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 970   $_[0]->_dbh || $_[0]->_populate_dbh;
 971 }
 972
 973 # *DELIBERATELY* not a setter (for the time being)
 974 # Too intertwined with everything else for any kind of sanity
 975 sub sql_maker {
 976   my $self = shift;
 977
 978   $self->throw_exception('sql_maker() is not a setter method') if @_;
 979
 980   unless ($self->_sql_maker) {
 981     my $sql_maker_class = $self->sql_maker_class;
 982
 983     my %opts = %{$self->_sql_maker_opts||{}};
 984     my $dialect =
 985       $opts{limit_dialect}
 986         ||
 987       $self->sql_limit_dialect
 988         ||
 989       do {
 990         my $s_class = (ref $self) || $self;
 991         carp_unique (
 992           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 993         . 'have not supplied an explicit limit_dialect in your connection_info. '
 994         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 995         . 'databases but can be (and often is) painfully slow. '
 996         . "Please file an RT ticket against '$s_class'"
 997         ) if $self->_dbi_connect_info->[0];
 998
 999         'GenericSubQ';
1000       }
1001     ;
1002
1003     my ($quote_char, $name_sep);
1004
1005     if ($opts{quote_names}) {
1006       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1007         my $s_class = (ref $self) || $self;
1008         carp_unique (
1009           "You requested 'quote_names' but your storage class ($s_class) does "
1010         . 'not explicitly define a default sql_quote_char and you have not '
1011         . 'supplied a quote_char as part of your connection_info. DBIC will '
1012         .q{default to the ANSI SQL standard quote '"', which works most of }
1013         . "the time. Please file an RT ticket against '$s_class'."
1014         );
1015
1016         '"'; # RV
1017       };
1018
1019       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1020     }
1021
1022     $self->_sql_maker($sql_maker_class->new(
1023       bindtype=>'columns',
1024       array_datatypes => 1,
1025       limit_dialect => $dialect,
1026       ($quote_char ? (quote_char => $quote_char) : ()),
1027       name_sep => ($name_sep || '.'),
1028       %opts,
1029     ));
1030   }
1031   return $self->_sql_maker;
1032 }
1033
1034 # nothing to do by default
1035 sub _rebless {}
1036 sub _init {}
1037
1038 sub _populate_dbh {
1039
1040   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1041
1042   $_[0]->_dbh_details({}); # reset everything we know
1043
1044   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1045   #$_[0]->_sql_maker(undef); # this may also end up being different
1046
1047   $_[0]->_dbh($_[0]->_connect);
1048
1049   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1050
1051   $_[0]->_determine_driver;
1052
1053   # Always set the transaction depth on connect, since
1054   #  there is no transaction in progress by definition
1055   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1056
1057   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1058
1059   $_[0]->_dbh;
1060 }
1061
1062 sub _run_connection_actions {
1063
1064   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1065     ( $_[0]->on_connect_call || () ),
1066     $_[0]->_parse_connect_do ('on_connect_do'),
1067   );
1068 }
1069
1070
1071
1072 sub set_use_dbms_capability {
1073   $_[0]->set_inherited ($_[1], $_[2]);
1074 }
1075
1076 sub get_use_dbms_capability {
1077   my ($self, $capname) = @_;
1078
1079   my $use = $self->get_inherited ($capname);
1080   return defined $use
1081     ? $use
1082     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1083   ;
1084 }
1085
1086 sub set_dbms_capability {
1087   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1088 }
1089
1090 sub get_dbms_capability {
1091   my ($self, $capname) = @_;
1092
1093   my $cap = $self->_dbh_details->{capability}{$capname};
1094
1095   unless (defined $cap) {
1096     if (my $meth = $self->can ("_determine$capname")) {
1097       $cap = $self->$meth ? 1 : 0;
1098     }
1099     else {
1100       $cap = 0;
1101     }
1102
1103     $self->set_dbms_capability ($capname, $cap);
1104   }
1105
1106   return $cap;
1107 }
1108
1109 sub _server_info {
1110   my $self = shift;
1111
1112   my $info;
1113   unless ($info = $self->_dbh_details->{info}) {
1114
1115     $info = {};
1116
1117     my $server_version = try {
1118       $self->_get_server_version
1119     } catch {
1120       # driver determination *may* use this codepath
1121       # in which case we must rethrow
1122       $self->throw_exception($_) if $self->{_in_determine_driver};
1123
1124       # $server_version on failure
1125       undef;
1126     };
1127
1128     if (defined $server_version) {
1129       $info->{dbms_version} = $server_version;
1130
1131       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1132       my @verparts = split (/\./, $numeric_version);
1133       if (
1134         @verparts
1135           &&
1136         $verparts[0] <= 999
1137       ) {
1138         # consider only up to 3 version parts, iff not more than 3 digits
1139         my @use_parts;
1140         while (@verparts && @use_parts < 3) {
1141           my $p = shift @verparts;
1142           last if $p > 999;
1143           push @use_parts, $p;
1144         }
1145         push @use_parts, 0 while @use_parts < 3;
1146
1147         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1148       }
1149     }
1150
1151     $self->_dbh_details->{info} = $info;
1152   }
1153
1154   return $info;
1155 }
1156
1157 sub _get_server_version {
1158   shift->_dbh_get_info('SQL_DBMS_VER');
1159 }
1160
1161 sub _dbh_get_info {
1162   my ($self, $info) = @_;
1163
1164   if ($info =~ /[^0-9]/) {
1165     require DBI::Const::GetInfoType;
1166     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1167     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1168       unless defined $info;
1169   }
1170
1171   $self->_get_dbh->get_info($info);
1172 }
1173
1174 sub _describe_connection {
1175   require DBI::Const::GetInfoReturn;
1176
1177   my $self = shift;
1178
1179   my $drv;
1180   try {
1181     $drv = $self->_extract_driver_from_connect_info;
1182     $self->ensure_connected;
1183   };
1184
1185   $drv = "DBD::$drv" if $drv;
1186
1187   my $res = {
1188     DBIC_DSN => $self->_dbi_connect_info->[0],
1189     DBI_VER => DBI->VERSION,
1190     DBIC_VER => DBIx::Class->VERSION,
1191     DBIC_DRIVER => ref $self,
1192     $drv ? (
1193       DBD => $drv,
1194       DBD_VER => try { $drv->VERSION },
1195     ) : (),
1196   };
1197
1198   # try to grab data even if we never managed to connect
1199   # will cover us in cases of an oddly broken half-connect
1200   for my $inf (
1201     #keys %DBI::Const::GetInfoType::GetInfoType,
1202     qw/
1203       SQL_CURSOR_COMMIT_BEHAVIOR
1204       SQL_CURSOR_ROLLBACK_BEHAVIOR
1205       SQL_CURSOR_SENSITIVITY
1206       SQL_DATA_SOURCE_NAME
1207       SQL_DBMS_NAME
1208       SQL_DBMS_VER
1209       SQL_DEFAULT_TXN_ISOLATION
1210       SQL_DM_VER
1211       SQL_DRIVER_NAME
1212       SQL_DRIVER_ODBC_VER
1213       SQL_DRIVER_VER
1214       SQL_EXPRESSIONS_IN_ORDERBY
1215       SQL_GROUP_BY
1216       SQL_IDENTIFIER_CASE
1217       SQL_IDENTIFIER_QUOTE_CHAR
1218       SQL_MAX_CATALOG_NAME_LEN
1219       SQL_MAX_COLUMN_NAME_LEN
1220       SQL_MAX_IDENTIFIER_LEN
1221       SQL_MAX_TABLE_NAME_LEN
1222       SQL_MULTIPLE_ACTIVE_TXN
1223       SQL_MULT_RESULT_SETS
1224       SQL_NEED_LONG_DATA_LEN
1225       SQL_NON_NULLABLE_COLUMNS
1226       SQL_ODBC_VER
1227       SQL_QUALIFIER_NAME_SEPARATOR
1228       SQL_QUOTED_IDENTIFIER_CASE
1229       SQL_TXN_CAPABLE
1230       SQL_TXN_ISOLATION_OPTION
1231     /
1232   ) {
1233     # some drivers barf on things they do not know about instead
1234     # of returning undef
1235     my $v = try { $self->_dbh_get_info($inf) };
1236     next unless defined $v;
1237
1238     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1239     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1240     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1241   }
1242
1243   $res;
1244 }
1245
1246 sub _determine_driver {
1247   my ($self) = @_;
1248
1249   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1250     my $started_connected = 0;
1251     local $self->{_in_determine_driver} = 1;
1252
1253     if (ref($self) eq __PACKAGE__) {
1254       my $driver;
1255       if ($self->_dbh) { # we are connected
1256         $driver = $self->_dbh->{Driver}{Name};
1257         $started_connected = 1;
1258       }
1259       else {
1260         $driver = $self->_extract_driver_from_connect_info;
1261       }
1262
1263       if ($driver) {
1264         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1265         if ($self->load_optional_class($storage_class)) {
1266           mro::set_mro($storage_class, 'c3');
1267           bless $self, $storage_class;
1268           $self->_rebless();
1269         }
1270         else {
1271           $self->_warn_undetermined_driver(
1272             'This version of DBIC does not yet seem to supply a driver for '
1273           . "your particular RDBMS and/or connection method ('$driver')."
1274           );
1275         }
1276       }
1277       else {
1278         $self->_warn_undetermined_driver(
1279           'Unable to extract a driver name from connect info - this '
1280         . 'should not have happened.'
1281         );
1282       }
1283     }
1284
1285     $self->_driver_determined(1);
1286
1287     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1288
1289     if ($self->can('source_bind_attributes')) {
1290       $self->throw_exception(
1291         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1292       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1293       . 'If you are not sure how to proceed please contact the development team via '
1294       . DBIx::Class::_ENV_::HELP_URL
1295       );
1296     }
1297
1298     $self->_init; # run driver-specific initializations
1299
1300     $self->_run_connection_actions
1301         if !$started_connected && defined $self->_dbh;
1302   }
1303 }
1304
1305 sub _extract_driver_from_connect_info {
1306   my $self = shift;
1307
1308   my $drv;
1309
1310   # if connect_info is a CODEREF, we have no choice but to connect
1311   if (
1312     ref $self->_dbi_connect_info->[0]
1313       and
1314     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1315   ) {
1316     $self->_populate_dbh;
1317     $drv = $self->_dbh->{Driver}{Name};
1318   }
1319   else {
1320     # try to use dsn to not require being connected, the driver may still
1321     # force a connection later in _rebless to determine version
1322     # (dsn may not be supplied at all if all we do is make a mock-schema)
1323     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1324     $drv ||= $ENV{DBI_DRIVER};
1325   }
1326
1327   return $drv;
1328 }
1329
1330 sub _determine_connector_driver {
1331   my ($self, $conn) = @_;
1332
1333   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1334
1335   if (not $dbtype) {
1336     $self->_warn_undetermined_driver(
1337       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1338     . "$conn connector - this should not have happened."
1339     );
1340     return;
1341   }
1342
1343   $dbtype =~ s/\W/_/gi;
1344
1345   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1346   return if $self->isa($subclass);
1347
1348   if ($self->load_optional_class($subclass)) {
1349     bless $self, $subclass;
1350     $self->_rebless;
1351   }
1352   else {
1353     $self->_warn_undetermined_driver(
1354       'This version of DBIC does not yet seem to supply a driver for '
1355     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1356     );
1357   }
1358 }
1359
1360 sub _warn_undetermined_driver {
1361   my ($self, $msg) = @_;
1362
1363   require Data::Dumper::Concise;
1364
1365   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1366   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1367   . "does not go away, file a bugreport including the following info:\n"
1368   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1369   );
1370 }
1371
1372 sub _do_connection_actions {
1373   my $self          = shift;
1374   my $method_prefix = shift;
1375   my $call          = shift;
1376
1377   if (not ref($call)) {
1378     my $method = $method_prefix . $call;
1379     $self->$method(@_);
1380   } elsif (ref($call) eq 'CODE') {
1381     $self->$call(@_);
1382   } elsif (ref($call) eq 'ARRAY') {
1383     if (ref($call->[0]) ne 'ARRAY') {
1384       $self->_do_connection_actions($method_prefix, $_) for @$call;
1385     } else {
1386       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1387     }
1388   } else {
1389     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1390   }
1391
1392   return $self;
1393 }
1394
1395 sub connect_call_do_sql {
1396   my $self = shift;
1397   $self->_do_query(@_);
1398 }
1399
1400 sub disconnect_call_do_sql {
1401   my $self = shift;
1402   $self->_do_query(@_);
1403 }
1404
1405 # override in db-specific backend when necessary
1406 sub connect_call_datetime_setup { 1 }
1407
1408 sub _do_query {
1409   my ($self, $action) = @_;
1410
1411   if (ref $action eq 'CODE') {
1412     $action = $action->($self);
1413     $self->_do_query($_) foreach @$action;
1414   }
1415   else {
1416     # Most debuggers expect ($sql, @bind), so we need to exclude
1417     # the attribute hash which is the second argument to $dbh->do
1418     # furthermore the bind values are usually to be presented
1419     # as named arrayref pairs, so wrap those here too
1420     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1421     my $sql = shift @do_args;
1422     my $attrs = shift @do_args;
1423     my @bind = map { [ undef, $_ ] } @do_args;
1424
1425     $self->dbh_do(sub {
1426       $_[0]->_query_start($sql, \@bind);
1427       $_[1]->do($sql, $attrs, @do_args);
1428       $_[0]->_query_end($sql, \@bind);
1429     });
1430   }
1431
1432   return $self;
1433 }
1434
1435 sub _connect {
1436   my $self = shift;
1437
1438   my $info = $self->_dbi_connect_info;
1439
1440   $self->throw_exception("You did not provide any connection_info")
1441     unless defined $info->[0];
1442
1443   my ($old_connect_via, $dbh);
1444
1445   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1446
1447   # this odd anonymous coderef dereference is in fact really
1448   # necessary to avoid the unwanted effect described in perl5
1449   # RT#75792
1450   #
1451   # in addition the coderef itself can't reside inside the try{} block below
1452   # as it somehow triggers a leak under perl -d
1453   my $dbh_error_handler_installer = sub {
1454     weaken (my $weak_self = $_[0]);
1455
1456     # the coderef is blessed so we can distinguish it from externally
1457     # supplied handles (which must be preserved)
1458     $_[1]->{HandleError} = bless sub {
1459       if ($weak_self) {
1460         $weak_self->throw_exception("DBI Exception: $_[0]");
1461       }
1462       else {
1463         # the handler may be invoked by something totally out of
1464         # the scope of DBIC
1465         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1466       }
1467     }, '__DBIC__DBH__ERROR__HANDLER__';
1468   };
1469
1470   try {
1471     if(ref $info->[0] eq 'CODE') {
1472       $dbh = $info->[0]->();
1473     }
1474     else {
1475       require DBI;
1476       $dbh = DBI->connect(@$info);
1477     }
1478
1479     die $DBI::errstr unless $dbh;
1480
1481     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1482       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1483       . 'not continue',
1484       ref $info->[0] eq 'CODE'
1485         ? "Connection coderef $info->[0] returned a"
1486         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1487     ) unless $dbh->FETCH('Active');
1488
1489     # sanity checks unless asked otherwise
1490     unless ($self->unsafe) {
1491
1492       $self->throw_exception(
1493         'Refusing clobbering of {HandleError} installed on externally supplied '
1494        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1495       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1496
1497       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1498       # request, or an external handle. Complain and set anyway
1499       unless ($dbh->{RaiseError}) {
1500         carp( ref $info->[0] eq 'CODE'
1501
1502           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1503            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1504            .'attribute has been supplied'
1505
1506           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1507            .'unsafe => 1. Toggling RaiseError back to true'
1508         );
1509
1510         $dbh->{RaiseError} = 1;
1511       }
1512
1513       $dbh_error_handler_installer->($self, $dbh);
1514     }
1515   }
1516   catch {
1517     $self->throw_exception("DBI Connection failed: $_")
1518   };
1519
1520   $self->_dbh_autocommit($dbh->{AutoCommit});
1521   return $dbh;
1522 }
1523
1524 sub txn_begin {
1525   # this means we have not yet connected and do not know the AC status
1526   # (e.g. coderef $dbh), need a full-fledged connection check
1527   if (! defined $_[0]->_dbh_autocommit) {
1528     $_[0]->ensure_connected;
1529   }
1530   # Otherwise simply connect or re-connect on pid changes
1531   else {
1532     $_[0]->_get_dbh;
1533   }
1534
1535   shift->next::method(@_);
1536 }
1537
1538 sub _exec_txn_begin {
1539   my $self = shift;
1540
1541   # if the user is utilizing txn_do - good for him, otherwise we need to
1542   # ensure that the $dbh is healthy on BEGIN.
1543   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1544   # will be replaced by a failure of begin_work itself (which will be
1545   # then retried on reconnect)
1546   if ($self->{_in_do_block}) {
1547     $self->_dbh->begin_work;
1548   } else {
1549     $self->dbh_do(sub { $_[1]->begin_work });
1550   }
1551 }
1552
1553 sub txn_commit {
1554   my $self = shift;
1555
1556   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1557     unless $self->_seems_connected;
1558
1559   # esoteric case for folks using external $dbh handles
1560   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1561     carp "Storage transaction_depth 0 does not match "
1562         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1563     $self->transaction_depth(1);
1564   }
1565
1566   $self->next::method(@_);
1567
1568   # if AutoCommit is disabled txn_depth never goes to 0
1569   # as a new txn is started immediately on commit
1570   $self->transaction_depth(1) if (
1571     !$self->transaction_depth
1572       and
1573     defined $self->_dbh_autocommit
1574       and
1575     ! $self->_dbh_autocommit
1576   );
1577 }
1578
1579 sub _exec_txn_commit {
1580   shift->_dbh->commit;
1581 }
1582
1583 sub txn_rollback {
1584   my $self = shift;
1585
1586   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1587     unless $self->_seems_connected;
1588
1589   # esoteric case for folks using external $dbh handles
1590   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1591     carp "Storage transaction_depth 0 does not match "
1592         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1593     $self->transaction_depth(1);
1594   }
1595
1596   $self->next::method(@_);
1597
1598   # if AutoCommit is disabled txn_depth never goes to 0
1599   # as a new txn is started immediately on commit
1600   $self->transaction_depth(1) if (
1601     !$self->transaction_depth
1602       and
1603     defined $self->_dbh_autocommit
1604       and
1605     ! $self->_dbh_autocommit
1606   );
1607 }
1608
1609 sub _exec_txn_rollback {
1610   shift->_dbh->rollback;
1611 }
1612
1613 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1614 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1615   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1616     unless $_[0]->_seems_connected;
1617   shift->next::method(@_);
1618 EOS
1619
1620 # This used to be the top-half of _execute.  It was split out to make it
1621 #  easier to override in NoBindVars without duping the rest.  It takes up
1622 #  all of _execute's args, and emits $sql, @bind.
1623 sub _prep_for_execute {
1624   #my ($self, $op, $ident, $args) = @_;
1625   return shift->_gen_sql_bind(@_)
1626 }
1627
1628 sub _gen_sql_bind {
1629   my ($self, $op, $ident, $args) = @_;
1630
1631   my ($colinfos, $from);
1632   if ( blessed($ident) ) {
1633     $from = $ident->from;
1634     $colinfos = $ident->columns_info;
1635   }
1636
1637   my ($sql, $bind);
1638   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1639
1640   $bind = $self->_resolve_bindattrs(
1641     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1642   );
1643
1644   if (
1645     ! $ENV{DBIC_DT_SEARCH_OK}
1646       and
1647     $op eq 'select'
1648       and
1649     first {
1650       length ref $_->[1]
1651         and
1652       blessed($_->[1])
1653         and
1654       $_->[1]->isa('DateTime')
1655     } @$bind
1656   ) {
1657     carp_unique 'DateTime objects passed to search() are not supported '
1658       . 'properly (InflateColumn::DateTime formats and settings are not '
1659       . 'respected.) See "Formatting DateTime objects in queries" in '
1660       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1661       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1662   }
1663
1664   return( $sql, $bind );
1665 }
1666
1667 sub _resolve_bindattrs {
1668   my ($self, $ident, $bind, $colinfos) = @_;
1669
1670   my $resolve_bindinfo = sub {
1671     #my $infohash = shift;
1672
1673     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1674
1675     my $ret;
1676     if (my $col = $_[0]->{dbic_colname}) {
1677       $ret = { %{$_[0]} };
1678
1679       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1680         if $colinfos->{$col}{data_type};
1681
1682       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1683         if $colinfos->{$col}{size};
1684     }
1685
1686     $ret || $_[0];
1687   };
1688
1689   return [ map {
1690     my $resolved =
1691       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1692     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1693     : (ref $_->[0] eq 'HASH')           ? [(
1694                                             ! keys %{$_->[0]}
1695                                               or
1696                                             exists $_->[0]{dbd_attrs}
1697                                               or
1698                                             $_->[0]{sqlt_datatype}
1699                                            ) ? $_->[0]
1700                                              : $resolve_bindinfo->($_->[0])
1701                                            , $_->[1]
1702                                           ]
1703     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1704     :                                     [ $resolve_bindinfo->(
1705                                               { dbic_colname => $_->[0] }
1706                                             ), $_->[1] ]
1707     ;
1708
1709     if (
1710       ! exists $resolved->[0]{dbd_attrs}
1711         and
1712       ! $resolved->[0]{sqlt_datatype}
1713         and
1714       length ref $resolved->[1]
1715         and
1716       ! is_plain_value $resolved->[1]
1717     ) {
1718       require Data::Dumper;
1719       local $Data::Dumper::Maxdepth = 1;
1720       local $Data::Dumper::Terse = 1;
1721       local $Data::Dumper::Useqq = 1;
1722       local $Data::Dumper::Indent = 0;
1723       local $Data::Dumper::Pad = ' ';
1724       $self->throw_exception(
1725         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1726       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1727       );
1728     }
1729
1730     $resolved;
1731
1732   } @$bind ];
1733 }
1734
1735 sub _format_for_trace {
1736   #my ($self, $bind) = @_;
1737
1738   ### Turn @bind from something like this:
1739   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1740   ### to this:
1741   ###   ( "'1'", "'3'" )
1742
1743   map {
1744     defined( $_ && $_->[1] )
1745       ? qq{'$_->[1]'}
1746       : q{NULL}
1747   } @{$_[1] || []};
1748 }
1749
1750 sub _query_start {
1751   my ( $self, $sql, $bind ) = @_;
1752
1753   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1754     if $self->debug;
1755 }
1756
1757 sub _query_end {
1758   my ( $self, $sql, $bind ) = @_;
1759
1760   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1761     if $self->debug;
1762 }
1763
1764 sub _dbi_attrs_for_bind {
1765   my ($self, $ident, $bind) = @_;
1766
1767   my @attrs;
1768
1769   for (map { $_->[0] } @$bind) {
1770     push @attrs, do {
1771       if (exists $_->{dbd_attrs}) {
1772         $_->{dbd_attrs}
1773       }
1774       elsif($_->{sqlt_datatype}) {
1775         # cache the result in the dbh_details hash, as it can not change unless
1776         # we connect to something else
1777         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1778         if (not exists $cache->{$_->{sqlt_datatype}}) {
1779           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1780         }
1781         $cache->{$_->{sqlt_datatype}};
1782       }
1783       else {
1784         undef;  # always push something at this position
1785       }
1786     }
1787   }
1788
1789   return \@attrs;
1790 }
1791
1792 sub _execute {
1793   my ($self, $op, $ident, @args) = @_;
1794
1795   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1796
1797   # not even a PID check - we do not care about the state of the _dbh.
1798   # All we need is to get the appropriate drivers loaded if they aren't
1799   # already so that the assumption in ad7c50fc26e holds
1800   $self->_populate_dbh unless $self->_dbh;
1801
1802   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1803     $sql,
1804     $bind,
1805     $self->_dbi_attrs_for_bind($ident, $bind),
1806   );
1807 }
1808
1809 sub _dbh_execute {
1810   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1811
1812   $self->_query_start( $sql, $bind );
1813
1814   my $sth = $self->_bind_sth_params(
1815     $self->_prepare_sth($dbh, $sql),
1816     $bind,
1817     $bind_attrs,
1818   );
1819
1820   # Can this fail without throwing an exception anyways???
1821   my $rv = $sth->execute();
1822   $self->throw_exception(
1823     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1824   ) if !$rv;
1825
1826   $self->_query_end( $sql, $bind );
1827
1828   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1829 }
1830
1831 sub _prepare_sth {
1832   my ($self, $dbh, $sql) = @_;
1833
1834   # 3 is the if_active parameter which avoids active sth re-use
1835   my $sth = $self->disable_sth_caching
1836     ? $dbh->prepare($sql)
1837     : $dbh->prepare_cached($sql, {}, 3);
1838
1839   # XXX You would think RaiseError would make this impossible,
1840   #  but apparently that's not true :(
1841   $self->throw_exception(
1842     $dbh->errstr
1843       ||
1844     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1845             .'an exception and/or setting $dbh->errstr',
1846       length ($sql) > 20
1847         ? substr($sql, 0, 20) . '...'
1848         : $sql
1849       ,
1850       'DBD::' . $dbh->{Driver}{Name},
1851     )
1852   ) if !$sth;
1853
1854   $sth;
1855 }
1856
1857 sub _bind_sth_params {
1858   my ($self, $sth, $bind, $bind_attrs) = @_;
1859
1860   for my $i (0 .. $#$bind) {
1861     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1862       $sth->bind_param_inout(
1863         $i + 1, # bind params counts are 1-based
1864         $bind->[$i][1],
1865         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1866         $bind_attrs->[$i],
1867       );
1868     }
1869     else {
1870       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1871       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1872         ? "$bind->[$i][1]"
1873         : $bind->[$i][1]
1874       ;
1875
1876       $sth->bind_param(
1877         $i + 1,
1878         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1879         $v,
1880         $bind_attrs->[$i],
1881       );
1882     }
1883   }
1884
1885   $sth;
1886 }
1887
1888 sub _prefetch_autovalues {
1889   my ($self, $source, $colinfo, $to_insert) = @_;
1890
1891   my %values;
1892   for my $col (keys %$colinfo) {
1893     if (
1894       $colinfo->{$col}{auto_nextval}
1895         and
1896       (
1897         ! exists $to_insert->{$col}
1898           or
1899         is_literal_value($to_insert->{$col})
1900       )
1901     ) {
1902       $values{$col} = $self->_sequence_fetch(
1903         'NEXTVAL',
1904         ( $colinfo->{$col}{sequence} ||=
1905             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1906         ),
1907       );
1908     }
1909   }
1910
1911   \%values;
1912 }
1913
1914 sub insert {
1915   my ($self, $source, $to_insert) = @_;
1916
1917   my $col_infos = $source->columns_info;
1918
1919   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1920
1921   # fuse the values, but keep a separate list of prefetched_values so that
1922   # they can be fused once again with the final return
1923   $to_insert = { %$to_insert, %$prefetched_values };
1924
1925   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1926   # Investigate what does it take to s/defined/exists/
1927   my %pcols = map { $_ => 1 } $source->primary_columns;
1928   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1929   for my $col ($source->columns) {
1930     if ($col_infos->{$col}{is_auto_increment}) {
1931       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1932       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1933     }
1934
1935     # nothing to retrieve when explicit values are supplied
1936     next if (
1937       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1938     );
1939
1940     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1941     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1942       $pcols{$col}
1943         or
1944       $col_infos->{$col}{retrieve_on_insert}
1945     );
1946   };
1947
1948   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1949   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1950
1951   my ($sqla_opts, @ir_container);
1952   if (%retrieve_cols and $self->_use_insert_returning) {
1953     $sqla_opts->{returning_container} = \@ir_container
1954       if $self->_use_insert_returning_bound;
1955
1956     $sqla_opts->{returning} = [
1957       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1958     ];
1959   }
1960
1961   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1962
1963   my %returned_cols = %$to_insert;
1964   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1965     @ir_container = try {
1966       local $SIG{__WARN__} = sub {};
1967       my @r = $sth->fetchrow_array;
1968       $sth->finish;
1969       @r;
1970     } unless @ir_container;
1971
1972     @returned_cols{@$retlist} = @ir_container if @ir_container;
1973   }
1974   else {
1975     # pull in PK if needed and then everything else
1976     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1977
1978       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1979         unless $self->can('last_insert_id');
1980
1981       my @pri_values = $self->last_insert_id($source, @missing_pri);
1982
1983       $self->throw_exception( "Can't get last insert id" )
1984         unless (@pri_values == @missing_pri);
1985
1986       @returned_cols{@missing_pri} = @pri_values;
1987       delete @retrieve_cols{@missing_pri};
1988     }
1989
1990     # if there is more left to pull
1991     if (%retrieve_cols) {
1992       $self->throw_exception(
1993         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1994       ) unless %pcols;
1995
1996       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1997
1998       my $cur = DBIx::Class::ResultSet->new($source, {
1999         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2000         select => \@left_to_fetch,
2001       })->cursor;
2002
2003       @returned_cols{@left_to_fetch} = $cur->next;
2004
2005       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2006         if scalar $cur->next;
2007     }
2008   }
2009
2010   return { %$prefetched_values, %returned_cols };
2011 }
2012
2013 sub insert_bulk {
2014   carp_unique(
2015     'insert_bulk() should have never been exposed as a public method and '
2016   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2017   . 'use for this method please contact the development team via '
2018   . DBIx::Class::_ENV_::HELP_URL
2019   );
2020
2021   return '0E0' unless @{$_[3]||[]};
2022
2023   shift->_insert_bulk(@_);
2024 }
2025
2026 sub _insert_bulk {
2027   my ($self, $source, $cols, $data) = @_;
2028
2029   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2030     unless @{$data||[]};
2031
2032   my $colinfos = $source->columns_info($cols);
2033
2034   local $self->{_autoinc_supplied_for_op} =
2035     (grep { $_->{is_auto_increment} } values %$colinfos)
2036       ? 1
2037       : 0
2038   ;
2039
2040   # get a slice type index based on first row of data
2041   # a "column" in this context may refer to more than one bind value
2042   # e.g. \[ '?, ?', [...], [...] ]
2043   #
2044   # construct the value type index - a description of values types for every
2045   # per-column slice of $data:
2046   #
2047   # nonexistent - nonbind literal
2048   # 0 - regular value
2049   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2050   #
2051   # also construct the column hash to pass to the SQL generator. For plain
2052   # (non literal) values - convert the members of the first row into a
2053   # literal+bind combo, with extra positional info in the bind attr hashref.
2054   # This will allow us to match the order properly, and is so contrived
2055   # because a user-supplied literal/bind (or something else specific to a
2056   # resultsource and/or storage driver) can inject extra binds along the
2057   # way, so one can't rely on "shift positions" ordering at all. Also we
2058   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2059   # can be later matched up by address), because we want to supply a real
2060   # value on which perhaps e.g. datatype checks will be performed
2061   my ($proto_data, $value_type_by_col_idx);
2062   for my $col_idx (0..$#$cols) {
2063     my $colname = $cols->[$col_idx];
2064     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2065       # no bind value at all - no type
2066
2067       $proto_data->{$colname} = $data->[0][$col_idx];
2068     }
2069     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2070       # repack, so we don't end up mangling the original \[]
2071       my ($sql, @bind) = @${$data->[0][$col_idx]};
2072
2073       # normalization of user supplied stuff
2074       my $resolved_bind = $self->_resolve_bindattrs(
2075         $source, \@bind, $colinfos,
2076       );
2077
2078       # store value-less (attrs only) bind info - we will be comparing all
2079       # supplied binds against this for sanity
2080       $value_type_by_col_idx->{$col_idx} = [ map { $_->[0] } @$resolved_bind ];
2081
2082       $proto_data->{$colname} = \[ $sql, map { [
2083         # inject slice order to use for $proto_bind construction
2084           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2085             =>
2086           $resolved_bind->[$_][1]
2087         ] } (0 .. $#bind)
2088       ];
2089     }
2090     else {
2091       $value_type_by_col_idx->{$col_idx} = undef;
2092
2093       $proto_data->{$colname} = \[ '?', [
2094         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2095           =>
2096         $data->[0][$col_idx]
2097       ] ];
2098     }
2099   }
2100
2101   my ($sql, $proto_bind) = $self->_prep_for_execute (
2102     'insert',
2103     $source,
2104     [ $proto_data ],
2105   );
2106
2107   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2108     # if the bindlist is empty and we had some dynamic binds, this means the
2109     # storage ate them away (e.g. the NoBindVars component) and interpolated
2110     # them directly into the SQL. This obviously can't be good for multi-inserts
2111     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2112   }
2113
2114   # sanity checks
2115   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2116   #
2117   # use an error reporting closure for convenience (less to pass)
2118   my $bad_slice_report_cref = sub {
2119     my ($msg, $r_idx, $c_idx) = @_;
2120     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2121       $msg,
2122       $cols->[$c_idx],
2123       do {
2124         require Data::Dumper::Concise;
2125         local $Data::Dumper::Maxdepth = 5;
2126         Data::Dumper::Concise::Dumper ({
2127           map { $cols->[$_] =>
2128             $data->[$r_idx][$_]
2129           } 0..$#$cols
2130         }),
2131       }
2132     );
2133   };
2134
2135   for my $col_idx (0..$#$cols) {
2136     my $reference_val = $data->[0][$col_idx];
2137
2138     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2139       my $val = $data->[$row_idx][$col_idx];
2140
2141       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2142         if (ref $val ne 'SCALAR') {
2143           $bad_slice_report_cref->(
2144             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2145             $row_idx,
2146             $col_idx,
2147           );
2148         }
2149         elsif ($$val ne $$reference_val) {
2150           $bad_slice_report_cref->(
2151             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2152             $row_idx,
2153             $col_idx,
2154           );
2155         }
2156       }
2157       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2158         if (is_literal_value($val)) {
2159           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2160         }
2161       }
2162       else {  # binds from a \[], compare type and attrs
2163         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2164           $bad_slice_report_cref->(
2165             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2166             $row_idx,
2167             $col_idx,
2168           );
2169         }
2170         # start drilling down and bail out early on identical refs
2171         elsif (
2172           $reference_val != $val
2173             or
2174           $$reference_val != $$val
2175         ) {
2176           if (${$val}->[0] ne ${$reference_val}->[0]) {
2177             $bad_slice_report_cref->(
2178               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2179               $row_idx,
2180               $col_idx,
2181             );
2182           }
2183           # need to check the bind attrs - a bind will happen only once for
2184           # the entire dataset, so any changes further down will be ignored.
2185           elsif (! Data::Compare::Compare(
2186             $value_type_by_col_idx->{$col_idx},
2187             [
2188               map
2189               { $_->[0] }
2190               @{$self->_resolve_bindattrs(
2191                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2192               )}
2193             ],
2194           )) {
2195             $bad_slice_report_cref->(
2196               'Differing bind attributes on literal/bind values not supported',
2197               $row_idx,
2198               $col_idx,
2199             );
2200           }
2201         }
2202       }
2203     }
2204   }
2205
2206   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2207   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2208   # scope guard
2209   my $guard = $self->txn_scope_guard;
2210
2211   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2212   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2213   my $rv = do {
2214     if (@$proto_bind) {
2215       # proto bind contains the information on which pieces of $data to pull
2216       # $cols is passed in only for prettier error-reporting
2217       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2218     }
2219     else {
2220       # bind_param_array doesn't work if there are no binds
2221       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2222     }
2223   };
2224
2225   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2226
2227   $guard->commit;
2228
2229   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2230 }
2231
2232 # execute_for_fetch is capable of returning data just fine (it means it
2233 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2234 # is the void-populate fast-path we will just ignore this altogether
2235 # for the time being.
2236 sub _dbh_execute_for_fetch {
2237   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2238
2239   # If we have any bind attributes to take care of, we will bind the
2240   # proto-bind data (which will never be used by execute_for_fetch)
2241   # However since column bindtypes are "sticky", this is sufficient
2242   # to get the DBD to apply the bindtype to all values later on
2243   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2244
2245   for my $i (0 .. $#$proto_bind) {
2246     $sth->bind_param (
2247       $i+1, # DBI bind indexes are 1-based
2248       $proto_bind->[$i][1],
2249       $bind_attrs->[$i],
2250     ) if defined $bind_attrs->[$i];
2251   }
2252
2253   # At this point $data slots named in the _bind_data_slice_idx of
2254   # each piece of $proto_bind are either \[]s or plain values to be
2255   # passed in. Construct the dispensing coderef. *NOTE* the order
2256   # of $data will differ from this of the ?s in the SQL (due to
2257   # alphabetical ordering by colname). We actually do want to
2258   # preserve this behavior so that prepare_cached has a better
2259   # chance of matching on unrelated calls
2260
2261   my $fetch_row_idx = -1; # saner loop this way
2262   my $fetch_tuple = sub {
2263     return undef if ++$fetch_row_idx > $#$data;
2264
2265     return [ map {
2266       my $v = ! defined $_->{_literal_bind_subindex}
2267
2268         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2269
2270         # There are no attributes to resolve here - we already did everything
2271         # when we constructed proto_bind. However we still want to sanity-check
2272         # what the user supplied, so pass stuff through to the resolver *anyway*
2273         : $self->_resolve_bindattrs (
2274             undef,  # a fake rsrc
2275             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2276             {},     # a fake column_info bag
2277           )->[0][1]
2278       ;
2279
2280       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2281       # For the time being forcibly stringify whatever is stringifiable
2282       (length ref $v and is_plain_value $v)
2283         ? "$v"
2284         : $v
2285       ;
2286     } map { $_->[0] } @$proto_bind ];
2287   };
2288
2289   my $tuple_status = [];
2290   my ($rv, $err);
2291   try {
2292     $rv = $sth->execute_for_fetch(
2293       $fetch_tuple,
2294       $tuple_status,
2295     );
2296   }
2297   catch {
2298     $err = shift;
2299   };
2300
2301   # Not all DBDs are create equal. Some throw on error, some return
2302   # an undef $rv, and some set $sth->err - try whatever we can
2303   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2304     ! defined $err
2305       and
2306     ( !defined $rv or $sth->err )
2307   );
2308
2309   # Statement must finish even if there was an exception.
2310   try {
2311     $sth->finish
2312   }
2313   catch {
2314     $err = shift unless defined $err
2315   };
2316
2317   if (defined $err) {
2318     my $i = 0;
2319     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2320
2321     $self->throw_exception("Unexpected populate error: $err")
2322       if ($i > $#$tuple_status);
2323
2324     require Data::Dumper::Concise;
2325     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2326       ($tuple_status->[$i][1] || $err),
2327       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2328     );
2329   }
2330
2331   return $rv;
2332 }
2333
2334 sub _dbh_execute_inserts_with_no_binds {
2335   my ($self, $sth, $count) = @_;
2336
2337   my $err;
2338   try {
2339     my $dbh = $self->_get_dbh;
2340     local $dbh->{RaiseError} = 1;
2341     local $dbh->{PrintError} = 0;
2342
2343     $sth->execute foreach 1..$count;
2344   }
2345   catch {
2346     $err = shift;
2347   };
2348
2349   # Make sure statement is finished even if there was an exception.
2350   try {
2351     $sth->finish
2352   }
2353   catch {
2354     $err = shift unless defined $err;
2355   };
2356
2357   $self->throw_exception($err) if defined $err;
2358
2359   return $count;
2360 }
2361
2362 sub update {
2363   #my ($self, $source, @args) = @_;
2364   shift->_execute('update', @_);
2365 }
2366
2367
2368 sub delete {
2369   #my ($self, $source, @args) = @_;
2370   shift->_execute('delete', @_);
2371 }
2372
2373 sub _select {
2374   my $self = shift;
2375   $self->_execute($self->_select_args(@_));
2376 }
2377
2378 sub _select_args_to_query {
2379   my $self = shift;
2380
2381   $self->throw_exception(
2382     "Unable to generate limited query representation with 'software_limit' enabled"
2383   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2384
2385   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2386   #  = $self->_select_args($ident, $select, $cond, $attrs);
2387   my ($op, $ident, @args) =
2388     $self->_select_args(@_);
2389
2390   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2391   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2392
2393   # reuse the bind arrayref
2394   unshift @{$bind}, "($sql)";
2395   \$bind;
2396 }
2397
2398 sub _select_args {
2399   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2400
2401   # FIXME - that kind of caching would be nice to have
2402   # however currently we *may* pass the same $orig_attrs
2403   # with different ident/select/where
2404   # the whole interface needs to be rethought, since it
2405   # was centered around the flawed SQLA API. We can do
2406   # soooooo much better now. But that is also another
2407   # battle...
2408   #return (
2409   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2410   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2411
2412   my $sql_maker = $self->sql_maker;
2413
2414   my $attrs = {
2415     %$orig_attrs,
2416     select => $select,
2417     from => $ident,
2418     where => $where,
2419   };
2420
2421   # Sanity check the attributes (SQLMaker does it too, but
2422   # in case of a software_limit we'll never reach there)
2423   if (defined $attrs->{offset}) {
2424     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2425       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2426   }
2427
2428   if (defined $attrs->{rows}) {
2429     $self->throw_exception("The rows attribute must be a positive integer if present")
2430       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2431   }
2432   elsif ($attrs->{offset}) {
2433     # MySQL actually recommends this approach.  I cringe.
2434     $attrs->{rows} = $sql_maker->__max_int;
2435   }
2436
2437   # see if we will need to tear the prefetch apart to satisfy group_by == select
2438   # this is *extremely tricky* to get right, I am still not sure I did
2439   #
2440   my ($prefetch_needs_subquery, @limit_args);
2441
2442   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2443     # we already know there is a valid group_by (we made it) and we know it is
2444     # intended to be based *only* on non-multi stuff
2445     # short circuit the group_by parsing below
2446     $prefetch_needs_subquery = 1;
2447   }
2448   elsif (
2449     # The rationale is that even if we do *not* have collapse, we still
2450     # need to wrap the core grouped select/group_by in a subquery
2451     # so that databases that care about group_by/select equivalence
2452     # are happy (this includes MySQL in strict_mode)
2453     # If any of the other joined tables are referenced in the group_by
2454     # however - the user is on their own
2455     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2456       and
2457     $attrs->{group_by}
2458       and
2459     @{$attrs->{group_by}}
2460       and
2461     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2462       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2463     }
2464   ) {
2465     # no aliases other than our own in group_by
2466     # if there are - do not allow subquery even if limit is present
2467     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2468   }
2469   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2470     # active collapse with a limit - that one is a no-brainer unless
2471     # overruled by a group_by above
2472     $prefetch_needs_subquery = 1;
2473   }
2474
2475   if ($prefetch_needs_subquery) {
2476     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2477   }
2478   elsif (! $attrs->{software_limit} ) {
2479     push @limit_args, (
2480       $attrs->{rows} || (),
2481       $attrs->{offset} || (),
2482     );
2483   }
2484
2485   # try to simplify the joinmap further (prune unreferenced type-single joins)
2486   if (
2487     ! $prefetch_needs_subquery  # already pruned
2488       and
2489     ref $attrs->{from}
2490       and
2491     reftype $attrs->{from} eq 'ARRAY'
2492       and
2493     @{$attrs->{from}} != 1
2494   ) {
2495     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2496   }
2497
2498   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2499   # during the result inflation stage we *need* to know what was the aliastype
2500   # map as sqla saw it when the final pieces of SQL were being assembled
2501   # Originally we simply carried around the entirety of $attrs, but this
2502   # resulted in resultsets that are being reused growing continuously, as
2503   # the hash in question grew deeper and deeper.
2504   # Instead hand-pick what to take with us here (we actually don't need much
2505   # at this point just the map itself)
2506   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2507
2508 ###
2509   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2510   #
2511   # This would be the point to deflate anything found in $attrs->{where}
2512   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2513   # expect a result object. And all we have is a resultsource (it is trivial
2514   # to extract deflator coderefs via $alias2source above).
2515   #
2516   # I don't see a way forward other than changing the way deflators are
2517   # invoked, and that's just bad...
2518 ###
2519
2520   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2521 }
2522
2523 # Returns a counting SELECT for a simple count
2524 # query. Abstracted so that a storage could override
2525 # this to { count => 'firstcol' } or whatever makes
2526 # sense as a performance optimization
2527 sub _count_select {
2528   #my ($self, $source, $rs_attrs) = @_;
2529   return { count => '*' };
2530 }
2531
2532 =head2 select
2533
2534 =over 4
2535
2536 =item Arguments: $ident, $select, $condition, $attrs
2537
2538 =back
2539
2540 Handle a SQL select statement.
2541
2542 =cut
2543
2544 sub select {
2545   my $self = shift;
2546   my ($ident, $select, $condition, $attrs) = @_;
2547   return $self->cursor_class->new($self, \@_, $attrs);
2548 }
2549
2550 sub select_single {
2551   my $self = shift;
2552   my ($rv, $sth, @bind) = $self->_select(@_);
2553   my @row = $sth->fetchrow_array;
2554   my @nextrow = $sth->fetchrow_array if @row;
2555   if(@row && @nextrow) {
2556     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2557   }
2558   # Need to call finish() to work round broken DBDs
2559   $sth->finish();
2560   return @row;
2561 }
2562
2563 =head2 sql_limit_dialect
2564
2565 This is an accessor for the default SQL limit dialect used by a particular
2566 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2567 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2568 see L<DBIx::Class::SQLMaker::LimitDialects>.
2569
2570 =cut
2571
2572 sub _dbh_columns_info_for {
2573   my ($self, $dbh, $table) = @_;
2574
2575   if ($dbh->can('column_info')) {
2576     my %result;
2577     my $caught;
2578     try {
2579       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2580       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2581       $sth->execute();
2582       while ( my $info = $sth->fetchrow_hashref() ){
2583         my %column_info;
2584         $column_info{data_type}   = $info->{TYPE_NAME};
2585         $column_info{size}      = $info->{COLUMN_SIZE};
2586         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2587         $column_info{default_value} = $info->{COLUMN_DEF};
2588         my $col_name = $info->{COLUMN_NAME};
2589         $col_name =~ s/^\"(.*)\"$/$1/;
2590
2591         $result{$col_name} = \%column_info;
2592       }
2593     } catch {
2594       $caught = 1;
2595     };
2596     return \%result if !$caught && scalar keys %result;
2597   }
2598
2599   my %result;
2600   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2601   $sth->execute;
2602   my @columns = @{$sth->{NAME_lc}};
2603   for my $i ( 0 .. $#columns ){
2604     my %column_info;
2605     $column_info{data_type} = $sth->{TYPE}->[$i];
2606     $column_info{size} = $sth->{PRECISION}->[$i];
2607     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2608
2609     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2610       $column_info{data_type} = $1;
2611       $column_info{size}    = $2;
2612     }
2613
2614     $result{$columns[$i]} = \%column_info;
2615   }
2616   $sth->finish;
2617
2618   foreach my $col (keys %result) {
2619     my $colinfo = $result{$col};
2620     my $type_num = $colinfo->{data_type};
2621     my $type_name;
2622     if(defined $type_num && $dbh->can('type_info')) {
2623       my $type_info = $dbh->type_info($type_num);
2624       $type_name = $type_info->{TYPE_NAME} if $type_info;
2625       $colinfo->{data_type} = $type_name if $type_name;
2626     }
2627   }
2628
2629   return \%result;
2630 }
2631
2632 sub columns_info_for {
2633   my ($self, $table) = @_;
2634   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2635 }
2636
2637 =head2 last_insert_id
2638
2639 Return the row id of the last insert.
2640
2641 =cut
2642
2643 sub _dbh_last_insert_id {
2644     my ($self, $dbh, $source, $col) = @_;
2645
2646     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2647
2648     return $id if defined $id;
2649
2650     my $class = ref $self;
2651     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2652 }
2653
2654 sub last_insert_id {
2655   my $self = shift;
2656   $self->_dbh_last_insert_id ($self->_dbh, @_);
2657 }
2658
2659 =head2 _native_data_type
2660
2661 =over 4
2662
2663 =item Arguments: $type_name
2664
2665 =back
2666
2667 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2668 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2669 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2670
2671 The default implementation returns C<undef>, implement in your Storage driver if
2672 you need this functionality.
2673
2674 Should map types from other databases to the native RDBMS type, for example
2675 C<VARCHAR2> to C<VARCHAR>.
2676
2677 Types with modifiers should map to the underlying data type. For example,
2678 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2679
2680 Composite types should map to the container type, for example
2681 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2682
2683 =cut
2684
2685 sub _native_data_type {
2686   #my ($self, $data_type) = @_;
2687   return undef
2688 }
2689
2690 # Check if placeholders are supported at all
2691 sub _determine_supports_placeholders {
2692   my $self = shift;
2693   my $dbh  = $self->_get_dbh;
2694
2695   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2696   # but it is inaccurate more often than not
2697   return try {
2698     local $dbh->{PrintError} = 0;
2699     local $dbh->{RaiseError} = 1;
2700     $dbh->do('select ?', {}, 1);
2701     1;
2702   }
2703   catch {
2704     0;
2705   };
2706 }
2707
2708 # Check if placeholders bound to non-string types throw exceptions
2709 #
2710 sub _determine_supports_typeless_placeholders {
2711   my $self = shift;
2712   my $dbh  = $self->_get_dbh;
2713
2714   return try {
2715     local $dbh->{PrintError} = 0;
2716     local $dbh->{RaiseError} = 1;
2717     # this specifically tests a bind that is NOT a string
2718     $dbh->do('select 1 where 1 = ?', {}, 1);
2719     1;
2720   }
2721   catch {
2722     0;
2723   };
2724 }
2725
2726 =head2 sqlt_type
2727
2728 Returns the database driver name.
2729
2730 =cut
2731
2732 sub sqlt_type {
2733   shift->_get_dbh->{Driver}->{Name};
2734 }
2735
2736 =head2 bind_attribute_by_data_type
2737
2738 Given a datatype from column info, returns a database specific bind
2739 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2740 let the database planner just handle it.
2741
2742 This method is always called after the driver has been determined and a DBI
2743 connection has been established. Therefore you can refer to C<DBI::$constant>
2744 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2745 the correct modules.
2746
2747 =cut
2748
2749 sub bind_attribute_by_data_type {
2750     return;
2751 }
2752
2753 =head2 is_datatype_numeric
2754
2755 Given a datatype from column_info, returns a boolean value indicating if
2756 the current RDBMS considers it a numeric value. This controls how
2757 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2758 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2759 be performed instead of the usual C<eq>.
2760
2761 =cut
2762
2763 sub is_datatype_numeric {
2764   #my ($self, $dt) = @_;
2765
2766   return 0 unless $_[1];
2767
2768   $_[1] =~ /^ (?:
2769     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2770   ) $/ix;
2771 }
2772
2773
2774 =head2 create_ddl_dir
2775
2776 =over 4
2777
2778 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2779
2780 =back
2781
2782 Creates a SQL file based on the Schema, for each of the specified
2783 database engines in C<\@databases> in the given directory.
2784 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2785
2786 Given a previous version number, this will also create a file containing
2787 the ALTER TABLE statements to transform the previous schema into the
2788 current one. Note that these statements may contain C<DROP TABLE> or
2789 C<DROP COLUMN> statements that can potentially destroy data.
2790
2791 The file names are created using the C<ddl_filename> method below, please
2792 override this method in your schema if you would like a different file
2793 name format. For the ALTER file, the same format is used, replacing
2794 $version in the name with "$preversion-$version".
2795
2796 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2797 The most common value for this would be C<< { add_drop_table => 1 } >>
2798 to have the SQL produced include a C<DROP TABLE> statement for each table
2799 created. For quoting purposes supply C<quote_identifiers>.
2800
2801 If no arguments are passed, then the following default values are assumed:
2802
2803 =over 4
2804
2805 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2806
2807 =item version    - $schema->schema_version
2808
2809 =item directory  - './'
2810
2811 =item preversion - <none>
2812
2813 =back
2814
2815 By default, C<\%sqlt_args> will have
2816
2817  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2818
2819 merged with the hash passed in. To disable any of those features, pass in a
2820 hashref like the following
2821
2822  { ignore_constraint_names => 0, # ... other options }
2823
2824
2825 WARNING: You are strongly advised to check all SQL files created, before applying
2826 them.
2827
2828 =cut
2829
2830 sub create_ddl_dir {
2831   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2832
2833   unless ($dir) {
2834     carp "No directory given, using ./\n";
2835     $dir = './';
2836   } else {
2837       -d $dir
2838         or
2839       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2840         or
2841       $self->throw_exception(
2842         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2843       );
2844   }
2845
2846   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2847
2848   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2849   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2850
2851   my $schema_version = $schema->schema_version || '1.x';
2852   $version ||= $schema_version;
2853
2854   $sqltargs = {
2855     add_drop_table => 1,
2856     ignore_constraint_names => 1,
2857     ignore_index_names => 1,
2858     quote_identifiers => $self->sql_maker->_quoting_enabled,
2859     %{$sqltargs || {}}
2860   };
2861
2862   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2863     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2864   }
2865
2866   my $sqlt = SQL::Translator->new( $sqltargs );
2867
2868   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2869   my $sqlt_schema = $sqlt->translate({ data => $schema })
2870     or $self->throw_exception ($sqlt->error);
2871
2872   foreach my $db (@$databases) {
2873     $sqlt->reset();
2874     $sqlt->{schema} = $sqlt_schema;
2875     $sqlt->producer($db);
2876
2877     my $file;
2878     my $filename = $schema->ddl_filename($db, $version, $dir);
2879     if (-e $filename && ($version eq $schema_version )) {
2880       # if we are dumping the current version, overwrite the DDL
2881       carp "Overwriting existing DDL file - $filename";
2882       unlink($filename);
2883     }
2884
2885     my $output = $sqlt->translate;
2886     if(!$output) {
2887       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2888       next;
2889     }
2890     if(!open($file, ">$filename")) {
2891       $self->throw_exception("Can't open $filename for writing ($!)");
2892       next;
2893     }
2894     print $file $output;
2895     close($file);
2896
2897     next unless ($preversion);
2898
2899     require SQL::Translator::Diff;
2900
2901     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2902     if(!-e $prefilename) {
2903       carp("No previous schema file found ($prefilename)");
2904       next;
2905     }
2906
2907     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2908     if(-e $difffile) {
2909       carp("Overwriting existing diff file - $difffile");
2910       unlink($difffile);
2911     }
2912
2913     my $source_schema;
2914     {
2915       my $t = SQL::Translator->new($sqltargs);
2916       $t->debug( 0 );
2917       $t->trace( 0 );
2918
2919       $t->parser( $db )
2920         or $self->throw_exception ($t->error);
2921
2922       my $out = $t->translate( $prefilename )
2923         or $self->throw_exception ($t->error);
2924
2925       $source_schema = $t->schema;
2926
2927       $source_schema->name( $prefilename )
2928         unless ( $source_schema->name );
2929     }
2930
2931     # The "new" style of producers have sane normalization and can support
2932     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2933     # And we have to diff parsed SQL against parsed SQL.
2934     my $dest_schema = $sqlt_schema;
2935
2936     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2937       my $t = SQL::Translator->new($sqltargs);
2938       $t->debug( 0 );
2939       $t->trace( 0 );
2940
2941       $t->parser( $db )
2942         or $self->throw_exception ($t->error);
2943
2944       my $out = $t->translate( $filename )
2945         or $self->throw_exception ($t->error);
2946
2947       $dest_schema = $t->schema;
2948
2949       $dest_schema->name( $filename )
2950         unless $dest_schema->name;
2951     }
2952
2953     my $diff = do {
2954       # FIXME - this is a terrible workaround for
2955       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
2956       # Fixing it in this sloppy manner so that we don't hve to
2957       # lockstep an SQLT release as well. Needs to be removed at
2958       # some point, and SQLT dep bumped
2959       local $SQL::Translator::Producer::SQLite::NO_QUOTES
2960         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
2961
2962       SQL::Translator::Diff::schema_diff($source_schema, $db,
2963                                          $dest_schema,   $db,
2964                                          $sqltargs
2965                                        );
2966     };
2967
2968     if(!open $file, ">$difffile") {
2969       $self->throw_exception("Can't write to $difffile ($!)");
2970       next;
2971     }
2972     print $file $diff;
2973     close($file);
2974   }
2975 }
2976
2977 =head2 deployment_statements
2978
2979 =over 4
2980
2981 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2982
2983 =back
2984
2985 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2986
2987 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2988 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2989
2990 C<$directory> is used to return statements from files in a previously created
2991 L</create_ddl_dir> directory and is optional. The filenames are constructed
2992 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2993
2994 If no C<$directory> is specified then the statements are constructed on the
2995 fly using L<SQL::Translator> and C<$version> is ignored.
2996
2997 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2998
2999 =cut
3000
3001 sub deployment_statements {
3002   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3003   $type ||= $self->sqlt_type;
3004   $version ||= $schema->schema_version || '1.x';
3005   $dir ||= './';
3006   my $filename = $schema->ddl_filename($type, $version, $dir);
3007   if(-f $filename)
3008   {
3009       # FIXME replace this block when a proper sane sql parser is available
3010       my $file;
3011       open($file, "<$filename")
3012         or $self->throw_exception("Can't open $filename ($!)");
3013       my @rows = <$file>;
3014       close($file);
3015       return join('', @rows);
3016   }
3017
3018   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
3019     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
3020   }
3021
3022   # sources needs to be a parser arg, but for simplicity allow at top level
3023   # coming in
3024   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3025       if exists $sqltargs->{sources};
3026
3027   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3028     unless exists $sqltargs->{quote_identifiers};
3029
3030   my $tr = SQL::Translator->new(
3031     producer => "SQL::Translator::Producer::${type}",
3032     %$sqltargs,
3033     parser => 'SQL::Translator::Parser::DBIx::Class',
3034     data => $schema,
3035   );
3036
3037   return preserve_context {
3038     $tr->translate
3039   } after => sub {
3040     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3041       unless defined $_[0];
3042   };
3043 }
3044
3045 # FIXME deploy() currently does not accurately report sql errors
3046 # Will always return true while errors are warned
3047 sub deploy {
3048   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3049   my $deploy = sub {
3050     my $line = shift;
3051     return if(!$line);
3052     return if($line =~ /^--/);
3053     # next if($line =~ /^DROP/m);
3054     return if($line =~ /^BEGIN TRANSACTION/m);
3055     return if($line =~ /^COMMIT/m);
3056     return if $line =~ /^\s+$/; # skip whitespace only
3057     $self->_query_start($line);
3058     try {
3059       # do a dbh_do cycle here, as we need some error checking in
3060       # place (even though we will ignore errors)
3061       $self->dbh_do (sub { $_[1]->do($line) });
3062     } catch {
3063       carp qq{$_ (running "${line}")};
3064     };
3065     $self->_query_end($line);
3066   };
3067   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3068   if (@statements > 1) {
3069     foreach my $statement (@statements) {
3070       $deploy->( $statement );
3071     }
3072   }
3073   elsif (@statements == 1) {
3074     # split on single line comments and end of statements
3075     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3076       $deploy->( $line );
3077     }
3078   }
3079 }
3080
3081 =head2 datetime_parser
3082
3083 Returns the datetime parser class
3084
3085 =cut
3086
3087 sub datetime_parser {
3088   my $self = shift;
3089   return $self->{datetime_parser} ||= do {
3090     $self->build_datetime_parser(@_);
3091   };
3092 }
3093
3094 =head2 datetime_parser_type
3095
3096 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3097
3098 =head2 build_datetime_parser
3099
3100 See L</datetime_parser>
3101
3102 =cut
3103
3104 sub build_datetime_parser {
3105   my $self = shift;
3106   my $type = $self->datetime_parser_type(@_);
3107   return $type;
3108 }
3109
3110
3111 =head2 is_replicating
3112
3113 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3114 replicate from a master database.  Default is undef, which is the result
3115 returned by databases that don't support replication.
3116
3117 =cut
3118
3119 sub is_replicating {
3120     return;
3121
3122 }
3123
3124 =head2 lag_behind_master
3125
3126 Returns a number that represents a certain amount of lag behind a master db
3127 when a given storage is replicating.  The number is database dependent, but
3128 starts at zero and increases with the amount of lag. Default in undef
3129
3130 =cut
3131
3132 sub lag_behind_master {
3133     return;
3134 }
3135
3136 =head2 relname_to_table_alias
3137
3138 =over 4
3139
3140 =item Arguments: $relname, $join_count
3141
3142 =item Return Value: $alias
3143
3144 =back
3145
3146 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3147 queries.
3148
3149 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3150 way these aliases are named.
3151
3152 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3153 otherwise C<"$relname">.
3154
3155 =cut
3156
3157 sub relname_to_table_alias {
3158   my ($self, $relname, $join_count) = @_;
3159
3160   my $alias = ($join_count && $join_count > 1 ?
3161     join('_', $relname, $join_count) : $relname);
3162
3163   return $alias;
3164 }
3165
3166 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3167 # version and it may be necessary to amend or override it for a specific storage
3168 # if such binds are necessary.
3169 sub _max_column_bytesize {
3170   my ($self, $attr) = @_;
3171
3172   my $max_size;
3173
3174   if ($attr->{sqlt_datatype}) {
3175     my $data_type = lc($attr->{sqlt_datatype});
3176
3177     if ($attr->{sqlt_size}) {
3178
3179       # String/sized-binary types
3180       if ($data_type =~ /^(?:
3181           l? (?:var)? char(?:acter)? (?:\s*varying)?
3182             |
3183           (?:var)? binary (?:\s*varying)?
3184             |
3185           raw
3186         )\b/x
3187       ) {
3188         $max_size = $attr->{sqlt_size};
3189       }
3190       # Other charset/unicode types, assume scale of 4
3191       elsif ($data_type =~ /^(?:
3192           national \s* character (?:\s*varying)?
3193             |
3194           nchar
3195             |
3196           univarchar
3197             |
3198           nvarchar
3199         )\b/x
3200       ) {
3201         $max_size = $attr->{sqlt_size} * 4;
3202       }
3203     }
3204
3205     if (!$max_size and !$self->_is_lob_type($data_type)) {
3206       $max_size = 100 # for all other (numeric?) datatypes
3207     }
3208   }
3209
3210   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3211 }
3212
3213 # Determine if a data_type is some type of BLOB
3214 sub _is_lob_type {
3215   my ($self, $data_type) = @_;
3216   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3217     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3218                                   |varchar|character\s*varying|nvarchar
3219                                   |national\s*character\s*varying))?\z/xi);
3220 }
3221
3222 sub _is_binary_lob_type {
3223   my ($self, $data_type) = @_;
3224   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3225     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3226 }
3227
3228 sub _is_text_lob_type {
3229   my ($self, $data_type) = @_;
3230   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3231     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3232                         |national\s*character\s*varying))\z/xi);
3233 }
3234
3235 # Determine if a data_type is some type of a binary type
3236 sub _is_binary_type {
3237   my ($self, $data_type) = @_;
3238   $data_type && ($self->_is_binary_lob_type($data_type)
3239     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3240 }
3241
3242 1;
3243
3244 =head1 USAGE NOTES
3245
3246 =head2 DBIx::Class and AutoCommit
3247
3248 DBIx::Class can do some wonderful magic with handling exceptions,
3249 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3250 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3251 transaction support.
3252
3253 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3254 in an assumed transaction between commits, and you're telling us you'd
3255 like to manage that manually.  A lot of the magic protections offered by
3256 this module will go away.  We can't protect you from exceptions due to database
3257 disconnects because we don't know anything about how to restart your
3258 transactions.  You're on your own for handling all sorts of exceptional
3259 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3260 be with raw DBI.
3261
3262
3263 =head1 AUTHOR AND CONTRIBUTORS
3264
3265 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3266
3267 =head1 LICENSE
3268
3269 You may distribute this code under the same terms as Perl itself.
3270
3271 =cut