lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use DBI::Const::GetInfoType (); # no import of retarded global hash
  19 use namespace::clean;
  20
  21 # default cursor class, overridable in connect_info attributes
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/
  25   sql_limit_dialect sql_quote_char sql_name_sep
  26 /);
  27
  28 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  29
  30 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  31 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  32
  33 __PACKAGE__->sql_name_sep('.');
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/
  36   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  37   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  38   _perform_autoinc_retrieval _autoinc_supplied_for_op
  39 /);
  40
  41 # the values for these accessors are picked out (and deleted) from
  42 # the attribute hashref passed to connect_info
  43 my @storage_options = qw/
  44   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  45   disable_sth_caching unsafe auto_savepoint
  46 /;
  47 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  48
  49
  50 # capability definitions, using a 2-tiered accessor system
  51 # The rationale is:
  52 #
  53 # A driver/user may define _use_X, which blindly without any checks says:
  54 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  55 # type accessor)
  56 #
  57 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  58 # accessor, which in turn calls _determine_supports_X, and stores the return
  59 # in a special slot on the storage object, which is wiped every time a $dbh
  60 # reconnection takes place (it is not guaranteed that upon reconnection we
  61 # will get the same rdbms version). _determine_supports_X does not need to
  62 # exist on a driver, as we ->can for it before calling.
  63
  64 my @capabilities = (qw/
  65   insert_returning
  66   insert_returning_bound
  67
  68   multicolumn_in
  69
  70   placeholders
  71   typeless_placeholders
  72
  73   join_optimizer
  74 /);
  75 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  76 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  77
  78 # on by default, not strictly a capability (pending rewrite)
  79 __PACKAGE__->_use_join_optimizer (1);
  80 sub _determine_supports_join_optimizer { 1 };
  81
  82 # Each of these methods need _determine_driver called before itself
  83 # in order to function reliably. This is a purely DRY optimization
  84 #
  85 # get_(use)_dbms_capability need to be called on the correct Storage
  86 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  87 # _determine_supports_X which obv. needs a correct driver as well
  88 my @rdbms_specific_methods = qw/
  89   sqlt_type
  90   sql_maker
  91   build_datetime_parser
  92   datetime_parser_type
  93
  94   txn_begin
  95   insert
  96   insert_bulk
  97   update
  98   delete
  99   select
 100   select_single
 101   with_deferred_fk_checks
 102
 103   get_use_dbms_capability
 104   get_dbms_capability
 105
 106   _server_info
 107   _get_server_version
 108 /;
 109
 110 for my $meth (@rdbms_specific_methods) {
 111
 112   my $orig = __PACKAGE__->can ($meth)
 113     or die "$meth is not a ::Storage::DBI method!";
 114
 115   no strict qw/refs/;
 116   no warnings qw/redefine/;
 117   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 118     if (
 119       # only fire when invoked on an instance, a valid class-based invocation
 120       # would e.g. be setting a default for an inherited accessor
 121       ref $_[0]
 122         and
 123       ! $_[0]->_driver_determined
 124         and
 125       ! $_[0]->{_in_determine_driver}
 126     ) {
 127       $_[0]->_determine_driver;
 128
 129       # This for some reason crashes and burns on perl 5.8.1
 130       # IFF the method ends up throwing an exception
 131       #goto $_[0]->can ($meth);
 132
 133       my $cref = $_[0]->can ($meth);
 134       goto $cref;
 135     }
 136
 137     goto $orig;
 138   };
 139 }
 140
 141 =head1 NAME
 142
 143 DBIx::Class::Storage::DBI - DBI storage handler
 144
 145 =head1 SYNOPSIS
 146
 147   my $schema = MySchema->connect('dbi:SQLite:my.db');
 148
 149   $schema->storage->debug(1);
 150
 151   my @stuff = $schema->storage->dbh_do(
 152     sub {
 153       my ($storage, $dbh, @args) = @_;
 154       $dbh->do("DROP TABLE authors");
 155     },
 156     @column_list
 157   );
 158
 159   $schema->resultset('Book')->search({
 160      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 161   });
 162
 163 =head1 DESCRIPTION
 164
 165 This class represents the connection to an RDBMS via L<DBI>.  See
 166 L<DBIx::Class::Storage> for general information.  This pod only
 167 documents DBI-specific methods and behaviors.
 168
 169 =head1 METHODS
 170
 171 =cut
 172
 173 sub new {
 174   my $new = shift->next::method(@_);
 175
 176   $new->_sql_maker_opts({});
 177   $new->_dbh_details({});
 178   $new->{_in_do_block} = 0;
 179   $new->{_dbh_gen} = 0;
 180
 181   # read below to see what this does
 182   $new->_arm_global_destructor;
 183
 184   $new;
 185 }
 186
 187 # This is hack to work around perl shooting stuff in random
 188 # order on exit(). If we do not walk the remaining storage
 189 # objects in an END block, there is a *small but real* chance
 190 # of a fork()ed child to kill the parent's shared DBI handle,
 191 # *before perl reaches the DESTROY in this package*
 192 # Yes, it is ugly and effective.
 193 # Additionally this registry is used by the CLONE method to
 194 # make sure no handles are shared between threads
 195 {
 196   my %seek_and_destroy;
 197
 198   sub _arm_global_destructor {
 199     weaken (
 200       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 201     );
 202   }
 203
 204   END {
 205     local $?; # just in case the DBI destructor changes it somehow
 206
 207     # destroy just the object if not native to this process
 208     $_->_verify_pid for (grep
 209       { defined $_ }
 210       values %seek_and_destroy
 211     );
 212   }
 213
 214   sub CLONE {
 215     # As per DBI's recommendation, DBIC disconnects all handles as
 216     # soon as possible (DBIC will reconnect only on demand from within
 217     # the thread)
 218     my @instances = grep { defined $_ } values %seek_and_destroy;
 219     for (@instances) {
 220       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 221       $_->_dbh(undef);
 222
 223       $_->transaction_depth(0);
 224       $_->savepoints([]);
 225     }
 226
 227     # properly renumber all existing refs
 228     %seek_and_destroy = ();
 229     $_->_arm_global_destructor for @instances;
 230   }
 231 }
 232
 233 sub DESTROY {
 234   my $self = shift;
 235
 236   # some databases spew warnings on implicit disconnect
 237   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 238   local $SIG{__WARN__} = sub {};
 239   $self->_dbh(undef);
 240
 241   # this op is necessary, since the very last perl runtime statement
 242   # triggers a global destruction shootout, and the $SIG localization
 243   # may very well be destroyed before perl actually gets to do the
 244   # $dbh undef
 245   1;
 246 }
 247
 248 # handle pid changes correctly - do not destroy parent's connection
 249 sub _verify_pid {
 250   my $self = shift;
 251
 252   my $pid = $self->_conn_pid;
 253   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 254     $dbh->{InactiveDestroy} = 1;
 255     $self->{_dbh_gen}++;
 256     $self->_dbh(undef);
 257     $self->transaction_depth(0);
 258     $self->savepoints([]);
 259   }
 260
 261   return;
 262 }
 263
 264 =head2 connect_info
 265
 266 This method is normally called by L<DBIx::Class::Schema/connection>, which
 267 encapsulates its argument list in an arrayref before passing them here.
 268
 269 The argument list may contain:
 270
 271 =over
 272
 273 =item *
 274
 275 The same 4-element argument set one would normally pass to
 276 L<DBI/connect>, optionally followed by
 277 L<extra attributes|/DBIx::Class specific connection attributes>
 278 recognized by DBIx::Class:
 279
 280   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 281
 282 =item *
 283
 284 A single code reference which returns a connected
 285 L<DBI database handle|DBI/connect> optionally followed by
 286 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 287 by DBIx::Class:
 288
 289   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 290
 291 =item *
 292
 293 A single hashref with all the attributes and the dsn/user/password
 294 mixed together:
 295
 296   $connect_info_args = [{
 297     dsn => $dsn,
 298     user => $user,
 299     password => $pass,
 300     %dbi_attributes,
 301     %extra_attributes,
 302   }];
 303
 304   $connect_info_args = [{
 305     dbh_maker => sub { DBI->connect (...) },
 306     %dbi_attributes,
 307     %extra_attributes,
 308   }];
 309
 310 This is particularly useful for L<Catalyst> based applications, allowing the
 311 following config (L<Config::General> style):
 312
 313   <Model::DB>
 314     schema_class   App::DB
 315     <connect_info>
 316       dsn          dbi:mysql:database=test
 317       user         testuser
 318       password     TestPass
 319       AutoCommit   1
 320     </connect_info>
 321   </Model::DB>
 322
 323 The C<dsn>/C<user>/C<password> combination can be substituted by the
 324 C<dbh_maker> key whose value is a coderef that returns a connected
 325 L<DBI database handle|DBI/connect>
 326
 327 =back
 328
 329 Please note that the L<DBI> docs recommend that you always explicitly
 330 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 331 recommends that it be set to I<1>, and that you perform transactions
 332 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 333 to I<1> if you do not do explicitly set it to zero.  This is the default
 334 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 335
 336 =head3 DBIx::Class specific connection attributes
 337
 338 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 339 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 340 the following connection options. These options can be mixed in with your other
 341 L<DBI> connection attributes, or placed in a separate hashref
 342 (C<\%extra_attributes>) as shown above.
 343
 344 Every time C<connect_info> is invoked, any previous settings for
 345 these options will be cleared before setting the new ones, regardless of
 346 whether any options are specified in the new C<connect_info>.
 347
 348
 349 =over
 350
 351 =item on_connect_do
 352
 353 Specifies things to do immediately after connecting or re-connecting to
 354 the database.  Its value may contain:
 355
 356 =over
 357
 358 =item a scalar
 359
 360 This contains one SQL statement to execute.
 361
 362 =item an array reference
 363
 364 This contains SQL statements to execute in order.  Each element contains
 365 a string or a code reference that returns a string.
 366
 367 =item a code reference
 368
 369 This contains some code to execute.  Unlike code references within an
 370 array reference, its return value is ignored.
 371
 372 =back
 373
 374 =item on_disconnect_do
 375
 376 Takes arguments in the same form as L</on_connect_do> and executes them
 377 immediately before disconnecting from the database.
 378
 379 Note, this only runs if you explicitly call L</disconnect> on the
 380 storage object.
 381
 382 =item on_connect_call
 383
 384 A more generalized form of L</on_connect_do> that calls the specified
 385 C<connect_call_METHOD> methods in your storage driver.
 386
 387   on_connect_do => 'select 1'
 388
 389 is equivalent to:
 390
 391   on_connect_call => [ [ do_sql => 'select 1' ] ]
 392
 393 Its values may contain:
 394
 395 =over
 396
 397 =item a scalar
 398
 399 Will call the C<connect_call_METHOD> method.
 400
 401 =item a code reference
 402
 403 Will execute C<< $code->($storage) >>
 404
 405 =item an array reference
 406
 407 Each value can be a method name or code reference.
 408
 409 =item an array of arrays
 410
 411 For each array, the first item is taken to be the C<connect_call_> method name
 412 or code reference, and the rest are parameters to it.
 413
 414 =back
 415
 416 Some predefined storage methods you may use:
 417
 418 =over
 419
 420 =item do_sql
 421
 422 Executes a SQL string or a code reference that returns a SQL string. This is
 423 what L</on_connect_do> and L</on_disconnect_do> use.
 424
 425 It can take:
 426
 427 =over
 428
 429 =item a scalar
 430
 431 Will execute the scalar as SQL.
 432
 433 =item an arrayref
 434
 435 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 436 attributes hashref and bind values.
 437
 438 =item a code reference
 439
 440 Will execute C<< $code->($storage) >> and execute the return array refs as
 441 above.
 442
 443 =back
 444
 445 =item datetime_setup
 446
 447 Execute any statements necessary to initialize the database session to return
 448 and accept datetime/timestamp values used with
 449 L<DBIx::Class::InflateColumn::DateTime>.
 450
 451 Only necessary for some databases, see your specific storage driver for
 452 implementation details.
 453
 454 =back
 455
 456 =item on_disconnect_call
 457
 458 Takes arguments in the same form as L</on_connect_call> and executes them
 459 immediately before disconnecting from the database.
 460
 461 Calls the C<disconnect_call_METHOD> methods as opposed to the
 462 C<connect_call_METHOD> methods called by L</on_connect_call>.
 463
 464 Note, this only runs if you explicitly call L</disconnect> on the
 465 storage object.
 466
 467 =item disable_sth_caching
 468
 469 If set to a true value, this option will disable the caching of
 470 statement handles via L<DBI/prepare_cached>.
 471
 472 =item limit_dialect
 473
 474 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 475 default L</sql_limit_dialect> setting of the storage (if any). For a list
 476 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 477
 478 =item quote_names
 479
 480 When true automatically sets L</quote_char> and L</name_sep> to the characters
 481 appropriate for your particular RDBMS. This option is preferred over specifying
 482 L</quote_char> directly.
 483
 484 =item quote_char
 485
 486 Specifies what characters to use to quote table and column names.
 487
 488 C<quote_char> expects either a single character, in which case is it
 489 is placed on either side of the table/column name, or an arrayref of length
 490 2 in which case the table/column name is placed between the elements.
 491
 492 For example under MySQL you should use C<< quote_char => '`' >>, and for
 493 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 494
 495 =item name_sep
 496
 497 This parameter is only useful in conjunction with C<quote_char>, and is used to
 498 specify the character that separates elements (schemas, tables, columns) from
 499 each other. If unspecified it defaults to the most commonly used C<.>.
 500
 501 =item unsafe
 502
 503 This Storage driver normally installs its own C<HandleError>, sets
 504 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 505 all database handles, including those supplied by a coderef.  It does this
 506 so that it can have consistent and useful error behavior.
 507
 508 If you set this option to a true value, Storage will not do its usual
 509 modifications to the database handle's attributes, and instead relies on
 510 the settings in your connect_info DBI options (or the values you set in
 511 your connection coderef, in the case that you are connecting via coderef).
 512
 513 Note that your custom settings can cause Storage to malfunction,
 514 especially if you set a C<HandleError> handler that suppresses exceptions
 515 and/or disable C<RaiseError>.
 516
 517 =item auto_savepoint
 518
 519 If this option is true, L<DBIx::Class> will use savepoints when nesting
 520 transactions, making it possible to recover from failure in the inner
 521 transaction without having to abort all outer transactions.
 522
 523 =item cursor_class
 524
 525 Use this argument to supply a cursor class other than the default
 526 L<DBIx::Class::Storage::DBI::Cursor>.
 527
 528 =back
 529
 530 Some real-life examples of arguments to L</connect_info> and
 531 L<DBIx::Class::Schema/connect>
 532
 533   # Simple SQLite connection
 534   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 535
 536   # Connect via subref
 537   ->connect_info([ sub { DBI->connect(...) } ]);
 538
 539   # Connect via subref in hashref
 540   ->connect_info([{
 541     dbh_maker => sub { DBI->connect(...) },
 542     on_connect_do => 'alter session ...',
 543   }]);
 544
 545   # A bit more complicated
 546   ->connect_info(
 547     [
 548       'dbi:Pg:dbname=foo',
 549       'postgres',
 550       'my_pg_password',
 551       { AutoCommit => 1 },
 552       { quote_char => q{"} },
 553     ]
 554   );
 555
 556   # Equivalent to the previous example
 557   ->connect_info(
 558     [
 559       'dbi:Pg:dbname=foo',
 560       'postgres',
 561       'my_pg_password',
 562       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 563     ]
 564   );
 565
 566   # Same, but with hashref as argument
 567   # See parse_connect_info for explanation
 568   ->connect_info(
 569     [{
 570       dsn         => 'dbi:Pg:dbname=foo',
 571       user        => 'postgres',
 572       password    => 'my_pg_password',
 573       AutoCommit  => 1,
 574       quote_char  => q{"},
 575       name_sep    => q{.},
 576     }]
 577   );
 578
 579   # Subref + DBIx::Class-specific connection options
 580   ->connect_info(
 581     [
 582       sub { DBI->connect(...) },
 583       {
 584           quote_char => q{`},
 585           name_sep => q{@},
 586           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 587           disable_sth_caching => 1,
 588       },
 589     ]
 590   );
 591
 592
 593
 594 =cut
 595
 596 sub connect_info {
 597   my ($self, $info) = @_;
 598
 599   return $self->_connect_info if !$info;
 600
 601   $self->_connect_info($info); # copy for _connect_info
 602
 603   $info = $self->_normalize_connect_info($info)
 604     if ref $info eq 'ARRAY';
 605
 606   for my $storage_opt (keys %{ $info->{storage_options} }) {
 607     my $value = $info->{storage_options}{$storage_opt};
 608
 609     $self->$storage_opt($value);
 610   }
 611
 612   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 613   #  the new set of options
 614   $self->_sql_maker(undef);
 615   $self->_sql_maker_opts({});
 616
 617   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 618     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 619
 620     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 621   }
 622
 623   my %attrs = (
 624     %{ $self->_default_dbi_connect_attributes || {} },
 625     %{ $info->{attributes} || {} },
 626   );
 627
 628   my @args = @{ $info->{arguments} };
 629
 630   if (keys %attrs and ref $args[0] ne 'CODE') {
 631     carp
 632         'You provided explicit AutoCommit => 0 in your connection_info. '
 633       . 'This is almost universally a bad idea (see the footnotes of '
 634       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 635       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 636       . 'this warning.'
 637       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 638
 639     push @args, \%attrs if keys %attrs;
 640   }
 641   $self->_dbi_connect_info(\@args);
 642
 643   # FIXME - dirty:
 644   # save attributes them in a separate accessor so they are always
 645   # introspectable, even in case of a CODE $dbhmaker
 646   $self->_dbic_connect_attributes (\%attrs);
 647
 648   return $self->_connect_info;
 649 }
 650
 651 sub _normalize_connect_info {
 652   my ($self, $info_arg) = @_;
 653   my %info;
 654
 655   my @args = @$info_arg;  # take a shallow copy for further mutilation
 656
 657   # combine/pre-parse arguments depending on invocation style
 658
 659   my %attrs;
 660   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 661     %attrs = %{ $args[1] || {} };
 662     @args = $args[0];
 663   }
 664   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 665     %attrs = %{$args[0]};
 666     @args = ();
 667     if (my $code = delete $attrs{dbh_maker}) {
 668       @args = $code;
 669
 670       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 671       if (@ignored) {
 672         carp sprintf (
 673             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 674           . "to the result of 'dbh_maker'",
 675
 676           join (', ', map { "'$_'" } (@ignored) ),
 677         );
 678       }
 679     }
 680     else {
 681       @args = delete @attrs{qw/dsn user password/};
 682     }
 683   }
 684   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 685     %attrs = (
 686       % { $args[3] || {} },
 687       % { $args[4] || {} },
 688     );
 689     @args = @args[0,1,2];
 690   }
 691
 692   $info{arguments} = \@args;
 693
 694   my @storage_opts = grep exists $attrs{$_},
 695     @storage_options, 'cursor_class';
 696
 697   @{ $info{storage_options} }{@storage_opts} =
 698     delete @attrs{@storage_opts} if @storage_opts;
 699
 700   my @sql_maker_opts = grep exists $attrs{$_},
 701     qw/limit_dialect quote_char name_sep quote_names/;
 702
 703   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 704     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 705
 706   $info{attributes} = \%attrs if %attrs;
 707
 708   return \%info;
 709 }
 710
 711 sub _default_dbi_connect_attributes () {
 712   +{
 713     AutoCommit => 1,
 714     PrintError => 0,
 715     RaiseError => 1,
 716     ShowErrorStatement => 1,
 717   };
 718 }
 719
 720 =head2 on_connect_do
 721
 722 This method is deprecated in favour of setting via L</connect_info>.
 723
 724 =cut
 725
 726 =head2 on_disconnect_do
 727
 728 This method is deprecated in favour of setting via L</connect_info>.
 729
 730 =cut
 731
 732 sub _parse_connect_do {
 733   my ($self, $type) = @_;
 734
 735   my $val = $self->$type;
 736   return () if not defined $val;
 737
 738   my @res;
 739
 740   if (not ref($val)) {
 741     push @res, [ 'do_sql', $val ];
 742   } elsif (ref($val) eq 'CODE') {
 743     push @res, $val;
 744   } elsif (ref($val) eq 'ARRAY') {
 745     push @res, map { [ 'do_sql', $_ ] } @$val;
 746   } else {
 747     $self->throw_exception("Invalid type for $type: ".ref($val));
 748   }
 749
 750   return \@res;
 751 }
 752
 753 =head2 dbh_do
 754
 755 Arguments: ($subref | $method_name), @extra_coderef_args?
 756
 757 Execute the given $subref or $method_name using the new exception-based
 758 connection management.
 759
 760 The first two arguments will be the storage object that C<dbh_do> was called
 761 on and a database handle to use.  Any additional arguments will be passed
 762 verbatim to the called subref as arguments 2 and onwards.
 763
 764 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 765 exception handling and reconnection (or failover in future subclasses).
 766
 767 Your subref should have no side-effects outside of the database, as
 768 there is the potential for your subref to be partially double-executed
 769 if the database connection was stale/dysfunctional.
 770
 771 Example:
 772
 773   my @stuff = $schema->storage->dbh_do(
 774     sub {
 775       my ($storage, $dbh, @cols) = @_;
 776       my $cols = join(q{, }, @cols);
 777       $dbh->selectrow_array("SELECT $cols FROM foo");
 778     },
 779     @column_list
 780   );
 781
 782 =cut
 783
 784 sub dbh_do {
 785   my $self = shift;
 786   my $run_target = shift;
 787
 788   # short circuit when we know there is no need for a runner
 789   #
 790   # FIXME - asumption may be wrong
 791   # the rationale for the txn_depth check is that if this block is a part
 792   # of a larger transaction, everything up to that point is screwed anyway
 793   return $self->$run_target($self->_get_dbh, @_)
 794     if $self->{_in_do_block} or $self->transaction_depth;
 795
 796   # take a ref instead of a copy, to preserve @_ aliasing
 797   # semantics within the coderef, but only if needed
 798   # (pseudoforking doesn't like this trick much)
 799   my $args = @_ ? \@_ : [];
 800
 801   DBIx::Class::Storage::BlockRunner->new(
 802     storage => $self,
 803     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 804     wrap_txn => 0,
 805     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 806   )->run;
 807 }
 808
 809 sub txn_do {
 810   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 811   shift->next::method(@_);
 812 }
 813
 814 =head2 disconnect
 815
 816 Our C<disconnect> method also performs a rollback first if the
 817 database is not in C<AutoCommit> mode.
 818
 819 =cut
 820
 821 sub disconnect {
 822   my ($self) = @_;
 823
 824   if( $self->_dbh ) {
 825     my @actions;
 826
 827     push @actions, ( $self->on_disconnect_call || () );
 828     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 829
 830     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 831
 832     # stops the "implicit rollback on disconnect" warning
 833     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 834
 835     %{ $self->_dbh->{CachedKids} } = ();
 836     $self->_dbh->disconnect;
 837     $self->_dbh(undef);
 838     $self->{_dbh_gen}++;
 839   }
 840 }
 841
 842 =head2 with_deferred_fk_checks
 843
 844 =over 4
 845
 846 =item Arguments: C<$coderef>
 847
 848 =item Return Value: The return value of $coderef
 849
 850 =back
 851
 852 Storage specific method to run the code ref with FK checks deferred or
 853 in MySQL's case disabled entirely.
 854
 855 =cut
 856
 857 # Storage subclasses should override this
 858 sub with_deferred_fk_checks {
 859   my ($self, $sub) = @_;
 860   $sub->();
 861 }
 862
 863 =head2 connected
 864
 865 =over
 866
 867 =item Arguments: none
 868
 869 =item Return Value: 1|0
 870
 871 =back
 872
 873 Verifies that the current database handle is active and ready to execute
 874 an SQL statement (e.g. the connection did not get stale, server is still
 875 answering, etc.) This method is used internally by L</dbh>.
 876
 877 =cut
 878
 879 sub connected {
 880   my $self = shift;
 881   return 0 unless $self->_seems_connected;
 882
 883   #be on the safe side
 884   local $self->_dbh->{RaiseError} = 1;
 885
 886   return $self->_ping;
 887 }
 888
 889 sub _seems_connected {
 890   my $self = shift;
 891
 892   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 893
 894   my $dbh = $self->_dbh
 895     or return 0;
 896
 897   return $dbh->FETCH('Active');
 898 }
 899
 900 sub _ping {
 901   my $self = shift;
 902
 903   my $dbh = $self->_dbh or return 0;
 904
 905   return $dbh->ping;
 906 }
 907
 908 sub ensure_connected {
 909   my ($self) = @_;
 910
 911   unless ($self->connected) {
 912     $self->_populate_dbh;
 913   }
 914 }
 915
 916 =head2 dbh
 917
 918 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 919 is guaranteed to be healthy by implicitly calling L</connected>, and if
 920 necessary performing a reconnection before returning. Keep in mind that this
 921 is very B<expensive> on some database engines. Consider using L</dbh_do>
 922 instead.
 923
 924 =cut
 925
 926 sub dbh {
 927   my ($self) = @_;
 928
 929   if (not $self->_dbh) {
 930     $self->_populate_dbh;
 931   } else {
 932     $self->ensure_connected;
 933   }
 934   return $self->_dbh;
 935 }
 936
 937 # this is the internal "get dbh or connect (don't check)" method
 938 sub _get_dbh {
 939   my $self = shift;
 940   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 941   $self->_populate_dbh unless $self->_dbh;
 942   return $self->_dbh;
 943 }
 944
 945 sub sql_maker {
 946   my ($self) = @_;
 947   unless ($self->_sql_maker) {
 948     my $sql_maker_class = $self->sql_maker_class;
 949
 950     my %opts = %{$self->_sql_maker_opts||{}};
 951     my $dialect =
 952       $opts{limit_dialect}
 953         ||
 954       $self->sql_limit_dialect
 955         ||
 956       do {
 957         my $s_class = (ref $self) || $self;
 958         carp (
 959           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 960         . 'have not supplied an explicit limit_dialect in your connection_info. '
 961         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 962         . 'databases but can be (and often is) painfully slow. '
 963         . "Please file an RT ticket against '$s_class' ."
 964         );
 965
 966         'GenericSubQ';
 967       }
 968     ;
 969
 970     my ($quote_char, $name_sep);
 971
 972     if ($opts{quote_names}) {
 973       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 974         my $s_class = (ref $self) || $self;
 975         carp (
 976           "You requested 'quote_names' but your storage class ($s_class) does "
 977         . 'not explicitly define a default sql_quote_char and you have not '
 978         . 'supplied a quote_char as part of your connection_info. DBIC will '
 979         .q{default to the ANSI SQL standard quote '"', which works most of }
 980         . "the time. Please file an RT ticket against '$s_class'."
 981         );
 982
 983         '"'; # RV
 984       };
 985
 986       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 987     }
 988
 989     $self->_sql_maker($sql_maker_class->new(
 990       bindtype=>'columns',
 991       array_datatypes => 1,
 992       limit_dialect => $dialect,
 993       ($quote_char ? (quote_char => $quote_char) : ()),
 994       name_sep => ($name_sep || '.'),
 995       %opts,
 996     ));
 997   }
 998   return $self->_sql_maker;
 999 }
1000
1001 # nothing to do by default
1002 sub _rebless {}
1003 sub _init {}
1004
1005 sub _populate_dbh {
1006   my ($self) = @_;
1007
1008   my @info = @{$self->_dbi_connect_info || []};
1009   $self->_dbh(undef); # in case ->connected failed we might get sent here
1010   $self->_dbh_details({}); # reset everything we know
1011
1012   $self->_dbh($self->_connect(@info));
1013
1014   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1015
1016   $self->_determine_driver;
1017
1018   # Always set the transaction depth on connect, since
1019   #  there is no transaction in progress by definition
1020   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1021
1022   $self->_run_connection_actions unless $self->{_in_determine_driver};
1023 }
1024
1025 sub _run_connection_actions {
1026   my $self = shift;
1027   my @actions;
1028
1029   push @actions, ( $self->on_connect_call || () );
1030   push @actions, $self->_parse_connect_do ('on_connect_do');
1031
1032   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1033 }
1034
1035
1036
1037 sub set_use_dbms_capability {
1038   $_[0]->set_inherited ($_[1], $_[2]);
1039 }
1040
1041 sub get_use_dbms_capability {
1042   my ($self, $capname) = @_;
1043
1044   my $use = $self->get_inherited ($capname);
1045   return defined $use
1046     ? $use
1047     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1048   ;
1049 }
1050
1051 sub set_dbms_capability {
1052   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1053 }
1054
1055 sub get_dbms_capability {
1056   my ($self, $capname) = @_;
1057
1058   my $cap = $self->_dbh_details->{capability}{$capname};
1059
1060   unless (defined $cap) {
1061     if (my $meth = $self->can ("_determine$capname")) {
1062       $cap = $self->$meth ? 1 : 0;
1063     }
1064     else {
1065       $cap = 0;
1066     }
1067
1068     $self->set_dbms_capability ($capname, $cap);
1069   }
1070
1071   return $cap;
1072 }
1073
1074 sub _server_info {
1075   my $self = shift;
1076
1077   my $info;
1078   unless ($info = $self->_dbh_details->{info}) {
1079
1080     $info = {};
1081
1082     my $server_version = try {
1083       $self->_get_server_version
1084     } catch {
1085       # driver determination *may* use this codepath
1086       # in which case we must rethrow
1087       $self->throw_exception($_) if $self->{_in_determine_driver};
1088
1089       # $server_version on failure
1090       undef;
1091     };
1092
1093     if (defined $server_version) {
1094       $info->{dbms_version} = $server_version;
1095
1096       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1097       my @verparts = split (/\./, $numeric_version);
1098       if (
1099         @verparts
1100           &&
1101         $verparts[0] <= 999
1102       ) {
1103         # consider only up to 3 version parts, iff not more than 3 digits
1104         my @use_parts;
1105         while (@verparts && @use_parts < 3) {
1106           my $p = shift @verparts;
1107           last if $p > 999;
1108           push @use_parts, $p;
1109         }
1110         push @use_parts, 0 while @use_parts < 3;
1111
1112         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1113       }
1114     }
1115
1116     $self->_dbh_details->{info} = $info;
1117   }
1118
1119   return $info;
1120 }
1121
1122 sub _get_server_version {
1123   shift->_dbh_get_info('SQL_DBMS_VER');
1124 }
1125
1126 sub _dbh_get_info {
1127   my ($self, $info) = @_;
1128
1129   if ($info =~ /[^0-9]/) {
1130     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1131     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1132       unless defined $info;
1133   }
1134
1135   return $self->_get_dbh->get_info($info);
1136 }
1137
1138 sub _describe_connection {
1139   require DBI::Const::GetInfoReturn;
1140
1141   my $self = shift;
1142   $self->ensure_connected;
1143
1144   my $res = {
1145     DBIC_DSN => $self->_dbi_connect_info->[0],
1146     DBI_VER => DBI->VERSION,
1147     DBIC_VER => DBIx::Class->VERSION,
1148     DBIC_DRIVER => ref $self,
1149   };
1150
1151   for my $inf (
1152     #keys %DBI::Const::GetInfoType::GetInfoType,
1153     qw/
1154       SQL_CURSOR_COMMIT_BEHAVIOR
1155       SQL_CURSOR_ROLLBACK_BEHAVIOR
1156       SQL_CURSOR_SENSITIVITY
1157       SQL_DATA_SOURCE_NAME
1158       SQL_DBMS_NAME
1159       SQL_DBMS_VER
1160       SQL_DEFAULT_TXN_ISOLATION
1161       SQL_DM_VER
1162       SQL_DRIVER_NAME
1163       SQL_DRIVER_ODBC_VER
1164       SQL_DRIVER_VER
1165       SQL_EXPRESSIONS_IN_ORDERBY
1166       SQL_GROUP_BY
1167       SQL_IDENTIFIER_CASE
1168       SQL_IDENTIFIER_QUOTE_CHAR
1169       SQL_MAX_CATALOG_NAME_LEN
1170       SQL_MAX_COLUMN_NAME_LEN
1171       SQL_MAX_IDENTIFIER_LEN
1172       SQL_MAX_TABLE_NAME_LEN
1173       SQL_MULTIPLE_ACTIVE_TXN
1174       SQL_MULT_RESULT_SETS
1175       SQL_NEED_LONG_DATA_LEN
1176       SQL_NON_NULLABLE_COLUMNS
1177       SQL_ODBC_VER
1178       SQL_QUALIFIER_NAME_SEPARATOR
1179       SQL_QUOTED_IDENTIFIER_CASE
1180       SQL_TXN_CAPABLE
1181       SQL_TXN_ISOLATION_OPTION
1182     /
1183   ) {
1184     # some drivers barf on things they do not know about instead
1185     # of returning undef
1186     my $v = try { $self->_dbh_get_info($inf) };
1187     next unless defined $v;
1188
1189     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1190     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1191     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1192   }
1193
1194   $res;
1195 }
1196
1197 sub _determine_driver {
1198   my ($self) = @_;
1199
1200   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1201     my $started_connected = 0;
1202     local $self->{_in_determine_driver} = 1;
1203
1204     if (ref($self) eq __PACKAGE__) {
1205       my $driver;
1206       if ($self->_dbh) { # we are connected
1207         $driver = $self->_dbh->{Driver}{Name};
1208         $started_connected = 1;
1209       }
1210       else {
1211         # if connect_info is a CODEREF, we have no choice but to connect
1212         if (ref $self->_dbi_connect_info->[0] &&
1213             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1214           $self->_populate_dbh;
1215           $driver = $self->_dbh->{Driver}{Name};
1216         }
1217         else {
1218           # try to use dsn to not require being connected, the driver may still
1219           # force a connection in _rebless to determine version
1220           # (dsn may not be supplied at all if all we do is make a mock-schema)
1221           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1222           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1223           $driver ||= $ENV{DBI_DRIVER};
1224         }
1225       }
1226
1227       if ($driver) {
1228         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1229         if ($self->load_optional_class($storage_class)) {
1230           mro::set_mro($storage_class, 'c3');
1231           bless $self, $storage_class;
1232           $self->_rebless();
1233         }
1234         else {
1235           $self->_warn_undetermined_driver(
1236             'This version of DBIC does not yet seem to supply a driver for '
1237           . "your particular RDBMS and/or connection method ('$driver')."
1238           );
1239         }
1240       }
1241       else {
1242         $self->_warn_undetermined_driver(
1243           'Unable to extract a driver name from connect info - this '
1244         . 'should not have happened.'
1245         );
1246       }
1247     }
1248
1249     $self->_driver_determined(1);
1250
1251     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1252
1253     if ($self->can('source_bind_attributes')) {
1254       $self->throw_exception(
1255         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1256       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1257       . 'If you are not sure how to proceed please contact the development team via '
1258       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1259       );
1260     }
1261
1262     $self->_init; # run driver-specific initializations
1263
1264     $self->_run_connection_actions
1265         if !$started_connected && defined $self->_dbh;
1266   }
1267 }
1268
1269 sub _determine_connector_driver {
1270   my ($self, $conn) = @_;
1271
1272   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1273
1274   if (not $dbtype) {
1275     $self->_warn_undetermined_driver(
1276       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1277     . "$conn connector - this should not have happened."
1278     );
1279     return;
1280   }
1281
1282   $dbtype =~ s/\W/_/gi;
1283
1284   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1285   return if $self->isa($subclass);
1286
1287   if ($self->load_optional_class($subclass)) {
1288     bless $self, $subclass;
1289     $self->_rebless;
1290   }
1291   else {
1292     $self->_warn_undetermined_driver(
1293       'This version of DBIC does not yet seem to supply a driver for '
1294     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1295     );
1296   }
1297 }
1298
1299 sub _warn_undetermined_driver {
1300   my ($self, $msg) = @_;
1301
1302   require Data::Dumper::Concise;
1303
1304   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1305   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1306   . "does not go away, file a bugreport including the following info:\n"
1307   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1308   );
1309 }
1310
1311 sub _do_connection_actions {
1312   my $self          = shift;
1313   my $method_prefix = shift;
1314   my $call          = shift;
1315
1316   if (not ref($call)) {
1317     my $method = $method_prefix . $call;
1318     $self->$method(@_);
1319   } elsif (ref($call) eq 'CODE') {
1320     $self->$call(@_);
1321   } elsif (ref($call) eq 'ARRAY') {
1322     if (ref($call->[0]) ne 'ARRAY') {
1323       $self->_do_connection_actions($method_prefix, $_) for @$call;
1324     } else {
1325       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1326     }
1327   } else {
1328     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1329   }
1330
1331   return $self;
1332 }
1333
1334 sub connect_call_do_sql {
1335   my $self = shift;
1336   $self->_do_query(@_);
1337 }
1338
1339 sub disconnect_call_do_sql {
1340   my $self = shift;
1341   $self->_do_query(@_);
1342 }
1343
1344 # override in db-specific backend when necessary
1345 sub connect_call_datetime_setup { 1 }
1346
1347 sub _do_query {
1348   my ($self, $action) = @_;
1349
1350   if (ref $action eq 'CODE') {
1351     $action = $action->($self);
1352     $self->_do_query($_) foreach @$action;
1353   }
1354   else {
1355     # Most debuggers expect ($sql, @bind), so we need to exclude
1356     # the attribute hash which is the second argument to $dbh->do
1357     # furthermore the bind values are usually to be presented
1358     # as named arrayref pairs, so wrap those here too
1359     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1360     my $sql = shift @do_args;
1361     my $attrs = shift @do_args;
1362     my @bind = map { [ undef, $_ ] } @do_args;
1363
1364     $self->dbh_do(sub {
1365       $_[0]->_query_start($sql, \@bind);
1366       $_[1]->do($sql, $attrs, @do_args);
1367       $_[0]->_query_end($sql, \@bind);
1368     });
1369   }
1370
1371   return $self;
1372 }
1373
1374 sub _connect {
1375   my ($self, @info) = @_;
1376
1377   $self->throw_exception("You failed to provide any connection info")
1378     if !@info;
1379
1380   my ($old_connect_via, $dbh);
1381
1382   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1383
1384   try {
1385     if(ref $info[0] eq 'CODE') {
1386       $dbh = $info[0]->();
1387     }
1388     else {
1389       require DBI;
1390       $dbh = DBI->connect(@info);
1391     }
1392
1393     die $DBI::errstr unless $dbh;
1394
1395     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1396       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1397       . 'not continue',
1398       ref $info[0] eq 'CODE'
1399         ? "Connection coderef $info[0] returned a"
1400         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1401     ) unless $dbh->FETCH('Active');
1402
1403     # sanity checks unless asked otherwise
1404     unless ($self->unsafe) {
1405
1406       $self->throw_exception(
1407         'Refusing clobbering of {HandleError} installed on externally supplied '
1408        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1409       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1410
1411       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1412       # request, or an external handle. Complain and set anyway
1413       unless ($dbh->{RaiseError}) {
1414         carp( ref $info[0] eq 'CODE'
1415
1416           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1417            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1418            .'attribute has been supplied'
1419
1420           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1421            .'unsafe => 1. Toggling RaiseError back to true'
1422         );
1423
1424         $dbh->{RaiseError} = 1;
1425       }
1426
1427       # this odd anonymous coderef dereference is in fact really
1428       # necessary to avoid the unwanted effect described in perl5
1429       # RT#75792
1430       sub {
1431         my $weak_self = $_[0];
1432         weaken $weak_self;
1433
1434         # the coderef is blessed so we can distinguish it from externally
1435         # supplied handles (which must be preserved)
1436         $_[1]->{HandleError} = bless sub {
1437           if ($weak_self) {
1438             $weak_self->throw_exception("DBI Exception: $_[0]");
1439           }
1440           else {
1441             # the handler may be invoked by something totally out of
1442             # the scope of DBIC
1443             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1444           }
1445         }, '__DBIC__DBH__ERROR__HANDLER__';
1446       }->($self, $dbh);
1447     }
1448   }
1449   catch {
1450     $self->throw_exception("DBI Connection failed: $_")
1451   };
1452
1453   $self->_dbh_autocommit($dbh->{AutoCommit});
1454   $dbh;
1455 }
1456
1457 sub txn_begin {
1458   my $self = shift;
1459
1460   # this means we have not yet connected and do not know the AC status
1461   # (e.g. coderef $dbh), need a full-fledged connection check
1462   if (! defined $self->_dbh_autocommit) {
1463     $self->ensure_connected;
1464   }
1465   # Otherwise simply connect or re-connect on pid changes
1466   else {
1467     $self->_get_dbh;
1468   }
1469
1470   $self->next::method(@_);
1471 }
1472
1473 sub _exec_txn_begin {
1474   my $self = shift;
1475
1476   # if the user is utilizing txn_do - good for him, otherwise we need to
1477   # ensure that the $dbh is healthy on BEGIN.
1478   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1479   # will be replaced by a failure of begin_work itself (which will be
1480   # then retried on reconnect)
1481   if ($self->{_in_do_block}) {
1482     $self->_dbh->begin_work;
1483   } else {
1484     $self->dbh_do(sub { $_[1]->begin_work });
1485   }
1486 }
1487
1488 sub txn_commit {
1489   my $self = shift;
1490
1491   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1492   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1493     unless $self->_dbh;
1494
1495   # esoteric case for folks using external $dbh handles
1496   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1497     carp "Storage transaction_depth 0 does not match "
1498         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1499     $self->transaction_depth(1);
1500   }
1501
1502   $self->next::method(@_);
1503
1504   # if AutoCommit is disabled txn_depth never goes to 0
1505   # as a new txn is started immediately on commit
1506   $self->transaction_depth(1) if (
1507     !$self->transaction_depth
1508       and
1509     defined $self->_dbh_autocommit
1510       and
1511     ! $self->_dbh_autocommit
1512   );
1513 }
1514
1515 sub _exec_txn_commit {
1516   shift->_dbh->commit;
1517 }
1518
1519 sub txn_rollback {
1520   my $self = shift;
1521
1522   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1523   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1524     unless $self->_dbh;
1525
1526   # esoteric case for folks using external $dbh handles
1527   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1528     carp "Storage transaction_depth 0 does not match "
1529         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1530     $self->transaction_depth(1);
1531   }
1532
1533   $self->next::method(@_);
1534
1535   # if AutoCommit is disabled txn_depth never goes to 0
1536   # as a new txn is started immediately on commit
1537   $self->transaction_depth(1) if (
1538     !$self->transaction_depth
1539       and
1540     defined $self->_dbh_autocommit
1541       and
1542     ! $self->_dbh_autocommit
1543   );
1544 }
1545
1546 sub _exec_txn_rollback {
1547   shift->_dbh->rollback;
1548 }
1549
1550 # generate some identical methods
1551 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1552   no strict qw/refs/;
1553   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1554     my $self = shift;
1555     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1556     $self->throw_exception("Unable to $meth() on a disconnected storage")
1557       unless $self->_dbh;
1558     $self->next::method(@_);
1559   };
1560 }
1561
1562 # This used to be the top-half of _execute.  It was split out to make it
1563 #  easier to override in NoBindVars without duping the rest.  It takes up
1564 #  all of _execute's args, and emits $sql, @bind.
1565 sub _prep_for_execute {
1566   #my ($self, $op, $ident, $args) = @_;
1567   return shift->_gen_sql_bind(@_)
1568 }
1569
1570 sub _gen_sql_bind {
1571   my ($self, $op, $ident, $args) = @_;
1572
1573   my ($colinfos, $from);
1574   if ( blessed($ident) ) {
1575     $from = $ident->from;
1576     $colinfos = $ident->columns_info;
1577   }
1578
1579   my ($sql, @bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1580
1581   if (
1582     ! $ENV{DBIC_DT_SEARCH_OK}
1583       and
1584     $op eq 'select'
1585       and
1586     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1587   ) {
1588     carp_unique 'DateTime objects passed to search() are not supported '
1589       . 'properly (InflateColumn::DateTime formats and settings are not '
1590       . 'respected.) See "Formatting DateTime objects in queries" in '
1591       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1592       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1593   }
1594
1595   return( $sql, $self->_resolve_bindattrs(
1596     $ident, [ @{$args->[2]{bind}||[]}, @bind ], $colinfos
1597   ));
1598 }
1599
1600 sub _resolve_bindattrs {
1601   my ($self, $ident, $bind, $colinfos) = @_;
1602
1603   $colinfos ||= {};
1604
1605   my $resolve_bindinfo = sub {
1606     #my $infohash = shift;
1607
1608     %$colinfos = %{ $self->_resolve_column_info($ident) }
1609       unless keys %$colinfos;
1610
1611     my $ret;
1612     if (my $col = $_[0]->{dbic_colname}) {
1613       $ret = { %{$_[0]} };
1614
1615       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1616         if $colinfos->{$col}{data_type};
1617
1618       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1619         if $colinfos->{$col}{size};
1620     }
1621
1622     $ret || $_[0];
1623   };
1624
1625   return [ map {
1626     if (ref $_ ne 'ARRAY') {
1627       [{}, $_]
1628     }
1629     elsif (! defined $_->[0]) {
1630       [{}, $_->[1]]
1631     }
1632     elsif (ref $_->[0] eq 'HASH') {
1633       [
1634         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1635         $_->[1]
1636       ]
1637     }
1638     elsif (ref $_->[0] eq 'SCALAR') {
1639       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1640     }
1641     else {
1642       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1643     }
1644   } @$bind ];
1645 }
1646
1647 sub _format_for_trace {
1648   #my ($self, $bind) = @_;
1649
1650   ### Turn @bind from something like this:
1651   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1652   ### to this:
1653   ###   ( "'1'", "'3'" )
1654
1655   map {
1656     defined( $_ && $_->[1] )
1657       ? qq{'$_->[1]'}
1658       : q{NULL}
1659   } @{$_[1] || []};
1660 }
1661
1662 sub _query_start {
1663   my ( $self, $sql, $bind ) = @_;
1664
1665   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1666     if $self->debug;
1667 }
1668
1669 sub _query_end {
1670   my ( $self, $sql, $bind ) = @_;
1671
1672   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1673     if $self->debug;
1674 }
1675
1676 sub _dbi_attrs_for_bind {
1677   my ($self, $ident, $bind) = @_;
1678
1679   my @attrs;
1680
1681   for (map { $_->[0] } @$bind) {
1682     push @attrs, do {
1683       if (exists $_->{dbd_attrs}) {
1684         $_->{dbd_attrs}
1685       }
1686       elsif($_->{sqlt_datatype}) {
1687         # cache the result in the dbh_details hash, as it can not change unless
1688         # we connect to something else
1689         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1690         if (not exists $cache->{$_->{sqlt_datatype}}) {
1691           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1692         }
1693         $cache->{$_->{sqlt_datatype}};
1694       }
1695       else {
1696         undef;  # always push something at this position
1697       }
1698     }
1699   }
1700
1701   return \@attrs;
1702 }
1703
1704 sub _execute {
1705   my ($self, $op, $ident, @args) = @_;
1706
1707   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1708
1709   shift->dbh_do( _dbh_execute =>     # retry over disconnects
1710     $sql,
1711     $bind,
1712     $self->_dbi_attrs_for_bind($ident, $bind),
1713   );
1714 }
1715
1716 sub _dbh_execute {
1717   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1718
1719   $self->_query_start( $sql, $bind );
1720
1721   my $sth = $self->_bind_sth_params(
1722     $self->_prepare_sth($dbh, $sql),
1723     $bind,
1724     $bind_attrs,
1725   );
1726
1727   # Can this fail without throwing an exception anyways???
1728   my $rv = $sth->execute();
1729   $self->throw_exception(
1730     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1731   ) if !$rv;
1732
1733   $self->_query_end( $sql, $bind );
1734
1735   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1736 }
1737
1738 sub _prepare_sth {
1739   my ($self, $dbh, $sql) = @_;
1740
1741   # 3 is the if_active parameter which avoids active sth re-use
1742   my $sth = $self->disable_sth_caching
1743     ? $dbh->prepare($sql)
1744     : $dbh->prepare_cached($sql, {}, 3);
1745
1746   # XXX You would think RaiseError would make this impossible,
1747   #  but apparently that's not true :(
1748   $self->throw_exception(
1749     $dbh->errstr
1750       ||
1751     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1752             .'an exception and/or setting $dbh->errstr',
1753       length ($sql) > 20
1754         ? substr($sql, 0, 20) . '...'
1755         : $sql
1756       ,
1757       'DBD::' . $dbh->{Driver}{Name},
1758     )
1759   ) if !$sth;
1760
1761   $sth;
1762 }
1763
1764 sub _bind_sth_params {
1765   my ($self, $sth, $bind, $bind_attrs) = @_;
1766
1767   for my $i (0 .. $#$bind) {
1768     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1769       $sth->bind_param_inout(
1770         $i + 1, # bind params counts are 1-based
1771         $bind->[$i][1],
1772         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1773         $bind_attrs->[$i],
1774       );
1775     }
1776     else {
1777       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1778       # confirm with dbi-dev whether explicit stringification is needed
1779       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1780         ? "$bind->[$i][1]"
1781         : $bind->[$i][1]
1782       ;
1783       $sth->bind_param(
1784         $i + 1,
1785         $v,
1786         $bind_attrs->[$i],
1787       );
1788     }
1789   }
1790
1791   $sth;
1792 }
1793
1794 sub _prefetch_autovalues {
1795   my ($self, $source, $colinfo, $to_insert) = @_;
1796
1797   my %values;
1798   for my $col (keys %$colinfo) {
1799     if (
1800       $colinfo->{$col}{auto_nextval}
1801         and
1802       (
1803         ! exists $to_insert->{$col}
1804           or
1805         ref $to_insert->{$col} eq 'SCALAR'
1806           or
1807         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1808       )
1809     ) {
1810       $values{$col} = $self->_sequence_fetch(
1811         'NEXTVAL',
1812         ( $colinfo->{$col}{sequence} ||=
1813             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1814         ),
1815       );
1816     }
1817   }
1818
1819   \%values;
1820 }
1821
1822 sub insert {
1823   my ($self, $source, $to_insert) = @_;
1824
1825   my $col_infos = $source->columns_info;
1826
1827   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1828
1829   # fuse the values, but keep a separate list of prefetched_values so that
1830   # they can be fused once again with the final return
1831   $to_insert = { %$to_insert, %$prefetched_values };
1832
1833   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1834   # Investigate what does it take to s/defined/exists/
1835   my %pcols = map { $_ => 1 } $source->primary_columns;
1836   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1837   for my $col ($source->columns) {
1838     if ($col_infos->{$col}{is_auto_increment}) {
1839       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1840       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1841     }
1842
1843     # nothing to retrieve when explicit values are supplied
1844     next if (defined $to_insert->{$col} and ! (
1845       ref $to_insert->{$col} eq 'SCALAR'
1846         or
1847       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1848     ));
1849
1850     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1851     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1852       $pcols{$col}
1853         or
1854       $col_infos->{$col}{retrieve_on_insert}
1855     );
1856   };
1857
1858   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1859   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1860
1861   my ($sqla_opts, @ir_container);
1862   if (%retrieve_cols and $self->_use_insert_returning) {
1863     $sqla_opts->{returning_container} = \@ir_container
1864       if $self->_use_insert_returning_bound;
1865
1866     $sqla_opts->{returning} = [
1867       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1868     ];
1869   }
1870
1871   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1872
1873   my %returned_cols = %$to_insert;
1874   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1875     @ir_container = try {
1876       local $SIG{__WARN__} = sub {};
1877       my @r = $sth->fetchrow_array;
1878       $sth->finish;
1879       @r;
1880     } unless @ir_container;
1881
1882     @returned_cols{@$retlist} = @ir_container if @ir_container;
1883   }
1884   else {
1885     # pull in PK if needed and then everything else
1886     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1887
1888       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1889         unless $self->can('last_insert_id');
1890
1891       my @pri_values = $self->last_insert_id($source, @missing_pri);
1892
1893       $self->throw_exception( "Can't get last insert id" )
1894         unless (@pri_values == @missing_pri);
1895
1896       @returned_cols{@missing_pri} = @pri_values;
1897       delete $retrieve_cols{$_} for @missing_pri;
1898     }
1899
1900     # if there is more left to pull
1901     if (%retrieve_cols) {
1902       $self->throw_exception(
1903         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1904       ) unless %pcols;
1905
1906       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1907
1908       my $cur = DBIx::Class::ResultSet->new($source, {
1909         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1910         select => \@left_to_fetch,
1911       })->cursor;
1912
1913       @returned_cols{@left_to_fetch} = $cur->next;
1914
1915       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1916         if scalar $cur->next;
1917     }
1918   }
1919
1920   return { %$prefetched_values, %returned_cols };
1921 }
1922
1923 sub insert_bulk {
1924   my ($self, $source, $cols, $data) = @_;
1925
1926   my @col_range = (0..$#$cols);
1927
1928   # FIXME SUBOPTIMAL - most likely this is not necessary at all
1929   # confirm with dbi-dev whether explicit stringification is needed
1930   #
1931   # forcibly stringify whatever is stringifiable
1932   # ResultSet::populate() hands us a copy - safe to mangle
1933   for my $r (0 .. $#$data) {
1934     for my $c (0 .. $#{$data->[$r]}) {
1935       $data->[$r][$c] = "$data->[$r][$c]"
1936         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1937     }
1938   }
1939
1940   my $colinfos = $source->columns_info($cols);
1941
1942   local $self->{_autoinc_supplied_for_op} =
1943     (first { $_->{is_auto_increment} } values %$colinfos)
1944       ? 1
1945       : 0
1946   ;
1947
1948   # get a slice type index based on first row of data
1949   # a "column" in this context may refer to more than one bind value
1950   # e.g. \[ '?, ?', [...], [...] ]
1951   #
1952   # construct the value type index - a description of values types for every
1953   # per-column slice of $data:
1954   #
1955   # nonexistent - nonbind literal
1956   # 0 - regular value
1957   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1958   #
1959   # also construct the column hash to pass to the SQL generator. For plain
1960   # (non literal) values - convert the members of the first row into a
1961   # literal+bind combo, with extra positional info in the bind attr hashref.
1962   # This will allow us to match the order properly, and is so contrived
1963   # because a user-supplied literal/bind (or something else specific to a
1964   # resultsource and/or storage driver) can inject extra binds along the
1965   # way, so one can't rely on "shift positions" ordering at all. Also we
1966   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1967   # can be later matched up by address), because we want to supply a real
1968   # value on which perhaps e.g. datatype checks will be performed
1969   my ($proto_data, $value_type_by_col_idx);
1970   for my $i (@col_range) {
1971     my $colname = $cols->[$i];
1972     if (ref $data->[0][$i] eq 'SCALAR') {
1973       # no bind value at all - no type
1974
1975       $proto_data->{$colname} = $data->[0][$i];
1976     }
1977     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1978       # repack, so we don't end up mangling the original \[]
1979       my ($sql, @bind) = @${$data->[0][$i]};
1980
1981       # normalization of user supplied stuff
1982       my $resolved_bind = $self->_resolve_bindattrs(
1983         $source, \@bind, $colinfos,
1984       );
1985
1986       # store value-less (attrs only) bind info - we will be comparing all
1987       # supplied binds against this for sanity
1988       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1989
1990       $proto_data->{$colname} = \[ $sql, map { [
1991         # inject slice order to use for $proto_bind construction
1992           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
1993             =>
1994           $resolved_bind->[$_][1]
1995         ] } (0 .. $#bind)
1996       ];
1997     }
1998     else {
1999       $value_type_by_col_idx->{$i} = undef;
2000
2001       $proto_data->{$colname} = \[ '?', [
2002         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2003           =>
2004         $data->[0][$i]
2005       ] ];
2006     }
2007   }
2008
2009   my ($sql, $proto_bind) = $self->_prep_for_execute (
2010     'insert',
2011     $source,
2012     [ $proto_data ],
2013   );
2014
2015   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2016     # if the bindlist is empty and we had some dynamic binds, this means the
2017     # storage ate them away (e.g. the NoBindVars component) and interpolated
2018     # them directly into the SQL. This obviously can't be good for multi-inserts
2019     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2020   }
2021
2022   # sanity checks
2023   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2024   #
2025   # use an error reporting closure for convenience (less to pass)
2026   my $bad_slice_report_cref = sub {
2027     my ($msg, $r_idx, $c_idx) = @_;
2028     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2029       $msg,
2030       $cols->[$c_idx],
2031       do {
2032         require Data::Dumper::Concise;
2033         local $Data::Dumper::Maxdepth = 5;
2034         Data::Dumper::Concise::Dumper ({
2035           map { $cols->[$_] =>
2036             $data->[$r_idx][$_]
2037           } @col_range
2038         }),
2039       }
2040     );
2041   };
2042
2043   for my $col_idx (@col_range) {
2044     my $reference_val = $data->[0][$col_idx];
2045
2046     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2047       my $val = $data->[$row_idx][$col_idx];
2048
2049       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2050         if (ref $val ne 'SCALAR') {
2051           $bad_slice_report_cref->(
2052             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2053             $row_idx,
2054             $col_idx,
2055           );
2056         }
2057         elsif ($$val ne $$reference_val) {
2058           $bad_slice_report_cref->(
2059             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2060             $row_idx,
2061             $col_idx,
2062           );
2063         }
2064       }
2065       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2066         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2067           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2068         }
2069       }
2070       else {  # binds from a \[], compare type and attrs
2071         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2072           $bad_slice_report_cref->(
2073             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2074             $row_idx,
2075             $col_idx,
2076           );
2077         }
2078         # start drilling down and bail out early on identical refs
2079         elsif (
2080           $reference_val != $val
2081             or
2082           $$reference_val != $$val
2083         ) {
2084           if (${$val}->[0] ne ${$reference_val}->[0]) {
2085             $bad_slice_report_cref->(
2086               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2087               $row_idx,
2088               $col_idx,
2089             );
2090           }
2091           # need to check the bind attrs - a bind will happen only once for
2092           # the entire dataset, so any changes further down will be ignored.
2093           elsif (! Data::Compare::Compare(
2094             $value_type_by_col_idx->{$col_idx},
2095             [
2096               map
2097               { $_->[0] }
2098               @{$self->_resolve_bindattrs(
2099                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2100               )}
2101             ],
2102           )) {
2103             $bad_slice_report_cref->(
2104               'Differing bind attributes on literal/bind values not supported',
2105               $row_idx,
2106               $col_idx,
2107             );
2108           }
2109         }
2110       }
2111     }
2112   }
2113
2114   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2115   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2116   # scope guard
2117   my $guard = $self->txn_scope_guard;
2118
2119   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2120   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2121   my $rv = do {
2122     if (@$proto_bind) {
2123       # proto bind contains the information on which pieces of $data to pull
2124       # $cols is passed in only for prettier error-reporting
2125       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2126     }
2127     else {
2128       # bind_param_array doesn't work if there are no binds
2129       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2130     }
2131   };
2132
2133   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2134
2135   $guard->commit;
2136
2137   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2138 }
2139
2140 # execute_for_fetch is capable of returning data just fine (it means it
2141 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2142 # is the void-populate fast-path we will just ignore this altogether
2143 # for the time being.
2144 sub _dbh_execute_for_fetch {
2145   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2146
2147   my @idx_range = ( 0 .. $#$proto_bind );
2148
2149   # If we have any bind attributes to take care of, we will bind the
2150   # proto-bind data (which will never be used by execute_for_fetch)
2151   # However since column bindtypes are "sticky", this is sufficient
2152   # to get the DBD to apply the bindtype to all values later on
2153
2154   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2155
2156   for my $i (@idx_range) {
2157     $sth->bind_param (
2158       $i+1, # DBI bind indexes are 1-based
2159       $proto_bind->[$i][1],
2160       $bind_attrs->[$i],
2161     ) if defined $bind_attrs->[$i];
2162   }
2163
2164   # At this point $data slots named in the _bind_data_slice_idx of
2165   # each piece of $proto_bind are either \[]s or plain values to be
2166   # passed in. Construct the dispensing coderef. *NOTE* the order
2167   # of $data will differ from this of the ?s in the SQL (due to
2168   # alphabetical ordering by colname). We actually do want to
2169   # preserve this behavior so that prepare_cached has a better
2170   # chance of matching on unrelated calls
2171
2172   my $fetch_row_idx = -1; # saner loop this way
2173   my $fetch_tuple = sub {
2174     return undef if ++$fetch_row_idx > $#$data;
2175
2176     return [ map { defined $_->{_literal_bind_subindex}
2177       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2178          ->[ $_->{_literal_bind_subindex} ]
2179           ->[1]
2180       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2181     } map { $_->[0] } @$proto_bind];
2182   };
2183
2184   my $tuple_status = [];
2185   my ($rv, $err);
2186   try {
2187     $rv = $sth->execute_for_fetch(
2188       $fetch_tuple,
2189       $tuple_status,
2190     );
2191   }
2192   catch {
2193     $err = shift;
2194   };
2195
2196   # Not all DBDs are create equal. Some throw on error, some return
2197   # an undef $rv, and some set $sth->err - try whatever we can
2198   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2199     ! defined $err
2200       and
2201     ( !defined $rv or $sth->err )
2202   );
2203
2204   # Statement must finish even if there was an exception.
2205   try {
2206     $sth->finish
2207   }
2208   catch {
2209     $err = shift unless defined $err
2210   };
2211
2212   if (defined $err) {
2213     my $i = 0;
2214     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2215
2216     $self->throw_exception("Unexpected populate error: $err")
2217       if ($i > $#$tuple_status);
2218
2219     require Data::Dumper::Concise;
2220     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2221       ($tuple_status->[$i][1] || $err),
2222       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2223     );
2224   }
2225
2226   return $rv;
2227 }
2228
2229 sub _dbh_execute_inserts_with_no_binds {
2230   my ($self, $sth, $count) = @_;
2231
2232   my $err;
2233   try {
2234     my $dbh = $self->_get_dbh;
2235     local $dbh->{RaiseError} = 1;
2236     local $dbh->{PrintError} = 0;
2237
2238     $sth->execute foreach 1..$count;
2239   }
2240   catch {
2241     $err = shift;
2242   };
2243
2244   # Make sure statement is finished even if there was an exception.
2245   try {
2246     $sth->finish
2247   }
2248   catch {
2249     $err = shift unless defined $err;
2250   };
2251
2252   $self->throw_exception($err) if defined $err;
2253
2254   return $count;
2255 }
2256
2257 sub update {
2258   #my ($self, $source, @args) = @_;
2259   shift->_execute('update', @_);
2260 }
2261
2262
2263 sub delete {
2264   #my ($self, $source, @args) = @_;
2265   shift->_execute('delete', @_);
2266 }
2267
2268 sub _select {
2269   my $self = shift;
2270   $self->_execute($self->_select_args(@_));
2271 }
2272
2273 sub _select_args_to_query {
2274   my $self = shift;
2275
2276   $self->throw_exception(
2277     "Unable to generate limited query representation with 'software_limit' enabled"
2278   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2279
2280   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2281   #  = $self->_select_args($ident, $select, $cond, $attrs);
2282   my ($op, $ident, @args) =
2283     $self->_select_args(@_);
2284
2285   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2286   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2287
2288   # reuse the bind arrayref
2289   unshift @{$bind}, "($sql)";
2290   \$bind;
2291 }
2292
2293 sub _select_args {
2294   my ($self, $ident, $select, $where, $attrs) = @_;
2295
2296   my $sql_maker = $self->sql_maker;
2297   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2298
2299   $attrs = {
2300     %$attrs,
2301     select => $select,
2302     from => $ident,
2303     where => $where,
2304     $rs_alias && $alias2source->{$rs_alias}
2305       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2306       : ()
2307     ,
2308   };
2309
2310   # Sanity check the attributes (SQLMaker does it too, but
2311   # in case of a software_limit we'll never reach there)
2312   if (defined $attrs->{offset}) {
2313     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2314       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2315   }
2316
2317   if (defined $attrs->{rows}) {
2318     $self->throw_exception("The rows attribute must be a positive integer if present")
2319       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2320   }
2321   elsif ($attrs->{offset}) {
2322     # MySQL actually recommends this approach.  I cringe.
2323     $attrs->{rows} = $sql_maker->__max_int;
2324   }
2325
2326   my @limit;
2327
2328   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2329   # storage, unless software limit was requested
2330   if (
2331     #limited has_many
2332     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2333        ||
2334     # grouped prefetch (to satisfy group_by == select)
2335     ( $attrs->{group_by}
2336         &&
2337       @{$attrs->{group_by}}
2338         &&
2339       $attrs->{_prefetch_selector_range}
2340     )
2341   ) {
2342     ($ident, $select, $where, $attrs)
2343       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2344   }
2345   elsif (! $attrs->{software_limit} ) {
2346     push @limit, (
2347       $attrs->{rows} || (),
2348       $attrs->{offset} || (),
2349     );
2350   }
2351
2352   # try to simplify the joinmap further (prune unreferenced type-single joins)
2353   if (
2354     ref $ident
2355       and
2356     reftype $ident eq 'ARRAY'
2357       and
2358     @$ident != 1
2359   ) {
2360     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2361   }
2362
2363 ###
2364   # This would be the point to deflate anything found in $where
2365   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2366   # expect a result object. And all we have is a resultsource (it is trivial
2367   # to extract deflator coderefs via $alias2source above).
2368   #
2369   # I don't see a way forward other than changing the way deflators are
2370   # invoked, and that's just bad...
2371 ###
2372
2373   return ('select', $ident, $select, $where, $attrs, @limit);
2374 }
2375
2376 # Returns a counting SELECT for a simple count
2377 # query. Abstracted so that a storage could override
2378 # this to { count => 'firstcol' } or whatever makes
2379 # sense as a performance optimization
2380 sub _count_select {
2381   #my ($self, $source, $rs_attrs) = @_;
2382   return { count => '*' };
2383 }
2384
2385 =head2 select
2386
2387 =over 4
2388
2389 =item Arguments: $ident, $select, $condition, $attrs
2390
2391 =back
2392
2393 Handle a SQL select statement.
2394
2395 =cut
2396
2397 sub select {
2398   my $self = shift;
2399   my ($ident, $select, $condition, $attrs) = @_;
2400   return $self->cursor_class->new($self, \@_, $attrs);
2401 }
2402
2403 sub select_single {
2404   my $self = shift;
2405   my ($rv, $sth, @bind) = $self->_select(@_);
2406   my @row = $sth->fetchrow_array;
2407   my @nextrow = $sth->fetchrow_array if @row;
2408   if(@row && @nextrow) {
2409     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2410   }
2411   # Need to call finish() to work round broken DBDs
2412   $sth->finish();
2413   return @row;
2414 }
2415
2416 =head2 sql_limit_dialect
2417
2418 This is an accessor for the default SQL limit dialect used by a particular
2419 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2420 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2421 see L<DBIx::Class::SQLMaker::LimitDialects>.
2422
2423 =cut
2424
2425 sub _dbh_columns_info_for {
2426   my ($self, $dbh, $table) = @_;
2427
2428   if ($dbh->can('column_info')) {
2429     my %result;
2430     my $caught;
2431     try {
2432       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2433       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2434       $sth->execute();
2435       while ( my $info = $sth->fetchrow_hashref() ){
2436         my %column_info;
2437         $column_info{data_type}   = $info->{TYPE_NAME};
2438         $column_info{size}      = $info->{COLUMN_SIZE};
2439         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2440         $column_info{default_value} = $info->{COLUMN_DEF};
2441         my $col_name = $info->{COLUMN_NAME};
2442         $col_name =~ s/^\"(.*)\"$/$1/;
2443
2444         $result{$col_name} = \%column_info;
2445       }
2446     } catch {
2447       $caught = 1;
2448     };
2449     return \%result if !$caught && scalar keys %result;
2450   }
2451
2452   my %result;
2453   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2454   $sth->execute;
2455   my @columns = @{$sth->{NAME_lc}};
2456   for my $i ( 0 .. $#columns ){
2457     my %column_info;
2458     $column_info{data_type} = $sth->{TYPE}->[$i];
2459     $column_info{size} = $sth->{PRECISION}->[$i];
2460     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2461
2462     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2463       $column_info{data_type} = $1;
2464       $column_info{size}    = $2;
2465     }
2466
2467     $result{$columns[$i]} = \%column_info;
2468   }
2469   $sth->finish;
2470
2471   foreach my $col (keys %result) {
2472     my $colinfo = $result{$col};
2473     my $type_num = $colinfo->{data_type};
2474     my $type_name;
2475     if(defined $type_num && $dbh->can('type_info')) {
2476       my $type_info = $dbh->type_info($type_num);
2477       $type_name = $type_info->{TYPE_NAME} if $type_info;
2478       $colinfo->{data_type} = $type_name if $type_name;
2479     }
2480   }
2481
2482   return \%result;
2483 }
2484
2485 sub columns_info_for {
2486   my ($self, $table) = @_;
2487   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2488 }
2489
2490 =head2 last_insert_id
2491
2492 Return the row id of the last insert.
2493
2494 =cut
2495
2496 sub _dbh_last_insert_id {
2497     my ($self, $dbh, $source, $col) = @_;
2498
2499     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2500
2501     return $id if defined $id;
2502
2503     my $class = ref $self;
2504     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2505 }
2506
2507 sub last_insert_id {
2508   my $self = shift;
2509   $self->_dbh_last_insert_id ($self->_dbh, @_);
2510 }
2511
2512 =head2 _native_data_type
2513
2514 =over 4
2515
2516 =item Arguments: $type_name
2517
2518 =back
2519
2520 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2521 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2522 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2523
2524 The default implementation returns C<undef>, implement in your Storage driver if
2525 you need this functionality.
2526
2527 Should map types from other databases to the native RDBMS type, for example
2528 C<VARCHAR2> to C<VARCHAR>.
2529
2530 Types with modifiers should map to the underlying data type. For example,
2531 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2532
2533 Composite types should map to the container type, for example
2534 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2535
2536 =cut
2537
2538 sub _native_data_type {
2539   #my ($self, $data_type) = @_;
2540   return undef
2541 }
2542
2543 # Check if placeholders are supported at all
2544 sub _determine_supports_placeholders {
2545   my $self = shift;
2546   my $dbh  = $self->_get_dbh;
2547
2548   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2549   # but it is inaccurate more often than not
2550   return try {
2551     local $dbh->{PrintError} = 0;
2552     local $dbh->{RaiseError} = 1;
2553     $dbh->do('select ?', {}, 1);
2554     1;
2555   }
2556   catch {
2557     0;
2558   };
2559 }
2560
2561 # Check if placeholders bound to non-string types throw exceptions
2562 #
2563 sub _determine_supports_typeless_placeholders {
2564   my $self = shift;
2565   my $dbh  = $self->_get_dbh;
2566
2567   return try {
2568     local $dbh->{PrintError} = 0;
2569     local $dbh->{RaiseError} = 1;
2570     # this specifically tests a bind that is NOT a string
2571     $dbh->do('select 1 where 1 = ?', {}, 1);
2572     1;
2573   }
2574   catch {
2575     0;
2576   };
2577 }
2578
2579 =head2 sqlt_type
2580
2581 Returns the database driver name.
2582
2583 =cut
2584
2585 sub sqlt_type {
2586   shift->_get_dbh->{Driver}->{Name};
2587 }
2588
2589 =head2 bind_attribute_by_data_type
2590
2591 Given a datatype from column info, returns a database specific bind
2592 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2593 let the database planner just handle it.
2594
2595 This method is always called after the driver has been determined and a DBI
2596 connection has been established. Therefore you can refer to C<DBI::$constant>
2597 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2598 the correct modules.
2599
2600 =cut
2601
2602 sub bind_attribute_by_data_type {
2603     return;
2604 }
2605
2606 =head2 is_datatype_numeric
2607
2608 Given a datatype from column_info, returns a boolean value indicating if
2609 the current RDBMS considers it a numeric value. This controls how
2610 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2611 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2612 be performed instead of the usual C<eq>.
2613
2614 =cut
2615
2616 sub is_datatype_numeric {
2617   #my ($self, $dt) = @_;
2618
2619   return 0 unless $_[1];
2620
2621   $_[1] =~ /^ (?:
2622     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2623   ) $/ix;
2624 }
2625
2626
2627 =head2 create_ddl_dir
2628
2629 =over 4
2630
2631 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2632
2633 =back
2634
2635 Creates a SQL file based on the Schema, for each of the specified
2636 database engines in C<\@databases> in the given directory.
2637 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2638
2639 Given a previous version number, this will also create a file containing
2640 the ALTER TABLE statements to transform the previous schema into the
2641 current one. Note that these statements may contain C<DROP TABLE> or
2642 C<DROP COLUMN> statements that can potentially destroy data.
2643
2644 The file names are created using the C<ddl_filename> method below, please
2645 override this method in your schema if you would like a different file
2646 name format. For the ALTER file, the same format is used, replacing
2647 $version in the name with "$preversion-$version".
2648
2649 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2650 The most common value for this would be C<< { add_drop_table => 1 } >>
2651 to have the SQL produced include a C<DROP TABLE> statement for each table
2652 created. For quoting purposes supply C<quote_table_names> and
2653 C<quote_field_names>.
2654
2655 If no arguments are passed, then the following default values are assumed:
2656
2657 =over 4
2658
2659 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2660
2661 =item version    - $schema->schema_version
2662
2663 =item directory  - './'
2664
2665 =item preversion - <none>
2666
2667 =back
2668
2669 By default, C<\%sqlt_args> will have
2670
2671  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2672
2673 merged with the hash passed in. To disable any of those features, pass in a
2674 hashref like the following
2675
2676  { ignore_constraint_names => 0, # ... other options }
2677
2678
2679 WARNING: You are strongly advised to check all SQL files created, before applying
2680 them.
2681
2682 =cut
2683
2684 sub create_ddl_dir {
2685   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2686
2687   unless ($dir) {
2688     carp "No directory given, using ./\n";
2689     $dir = './';
2690   } else {
2691       -d $dir
2692         or
2693       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2694         or
2695       $self->throw_exception(
2696         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2697       );
2698   }
2699
2700   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2701
2702   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2703   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2704
2705   my $schema_version = $schema->schema_version || '1.x';
2706   $version ||= $schema_version;
2707
2708   $sqltargs = {
2709     add_drop_table => 1,
2710     ignore_constraint_names => 1,
2711     ignore_index_names => 1,
2712     %{$sqltargs || {}}
2713   };
2714
2715   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2716     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2717   }
2718
2719   my $sqlt = SQL::Translator->new( $sqltargs );
2720
2721   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2722   my $sqlt_schema = $sqlt->translate({ data => $schema })
2723     or $self->throw_exception ($sqlt->error);
2724
2725   foreach my $db (@$databases) {
2726     $sqlt->reset();
2727     $sqlt->{schema} = $sqlt_schema;
2728     $sqlt->producer($db);
2729
2730     my $file;
2731     my $filename = $schema->ddl_filename($db, $version, $dir);
2732     if (-e $filename && ($version eq $schema_version )) {
2733       # if we are dumping the current version, overwrite the DDL
2734       carp "Overwriting existing DDL file - $filename";
2735       unlink($filename);
2736     }
2737
2738     my $output = $sqlt->translate;
2739     if(!$output) {
2740       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2741       next;
2742     }
2743     if(!open($file, ">$filename")) {
2744       $self->throw_exception("Can't open $filename for writing ($!)");
2745       next;
2746     }
2747     print $file $output;
2748     close($file);
2749
2750     next unless ($preversion);
2751
2752     require SQL::Translator::Diff;
2753
2754     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2755     if(!-e $prefilename) {
2756       carp("No previous schema file found ($prefilename)");
2757       next;
2758     }
2759
2760     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2761     if(-e $difffile) {
2762       carp("Overwriting existing diff file - $difffile");
2763       unlink($difffile);
2764     }
2765
2766     my $source_schema;
2767     {
2768       my $t = SQL::Translator->new($sqltargs);
2769       $t->debug( 0 );
2770       $t->trace( 0 );
2771
2772       $t->parser( $db )
2773         or $self->throw_exception ($t->error);
2774
2775       my $out = $t->translate( $prefilename )
2776         or $self->throw_exception ($t->error);
2777
2778       $source_schema = $t->schema;
2779
2780       $source_schema->name( $prefilename )
2781         unless ( $source_schema->name );
2782     }
2783
2784     # The "new" style of producers have sane normalization and can support
2785     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2786     # And we have to diff parsed SQL against parsed SQL.
2787     my $dest_schema = $sqlt_schema;
2788
2789     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2790       my $t = SQL::Translator->new($sqltargs);
2791       $t->debug( 0 );
2792       $t->trace( 0 );
2793
2794       $t->parser( $db )
2795         or $self->throw_exception ($t->error);
2796
2797       my $out = $t->translate( $filename )
2798         or $self->throw_exception ($t->error);
2799
2800       $dest_schema = $t->schema;
2801
2802       $dest_schema->name( $filename )
2803         unless $dest_schema->name;
2804     }
2805
2806     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2807                                                   $dest_schema,   $db,
2808                                                   $sqltargs
2809                                                  );
2810     if(!open $file, ">$difffile") {
2811       $self->throw_exception("Can't write to $difffile ($!)");
2812       next;
2813     }
2814     print $file $diff;
2815     close($file);
2816   }
2817 }
2818
2819 =head2 deployment_statements
2820
2821 =over 4
2822
2823 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2824
2825 =back
2826
2827 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2828
2829 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2830 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2831
2832 C<$directory> is used to return statements from files in a previously created
2833 L</create_ddl_dir> directory and is optional. The filenames are constructed
2834 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2835
2836 If no C<$directory> is specified then the statements are constructed on the
2837 fly using L<SQL::Translator> and C<$version> is ignored.
2838
2839 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2840
2841 =cut
2842
2843 sub deployment_statements {
2844   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2845   $type ||= $self->sqlt_type;
2846   $version ||= $schema->schema_version || '1.x';
2847   $dir ||= './';
2848   my $filename = $schema->ddl_filename($type, $version, $dir);
2849   if(-f $filename)
2850   {
2851       # FIXME replace this block when a proper sane sql parser is available
2852       my $file;
2853       open($file, "<$filename")
2854         or $self->throw_exception("Can't open $filename ($!)");
2855       my @rows = <$file>;
2856       close($file);
2857       return join('', @rows);
2858   }
2859
2860   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2861     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2862   }
2863
2864   # sources needs to be a parser arg, but for simplicty allow at top level
2865   # coming in
2866   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2867       if exists $sqltargs->{sources};
2868
2869   my $tr = SQL::Translator->new(
2870     producer => "SQL::Translator::Producer::${type}",
2871     %$sqltargs,
2872     parser => 'SQL::Translator::Parser::DBIx::Class',
2873     data => $schema,
2874   );
2875
2876   return preserve_context {
2877     $tr->translate
2878   } after => sub {
2879     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2880       unless defined $_[0];
2881   };
2882 }
2883
2884 # FIXME deploy() currently does not accurately report sql errors
2885 # Will always return true while errors are warned
2886 sub deploy {
2887   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2888   my $deploy = sub {
2889     my $line = shift;
2890     return if(!$line);
2891     return if($line =~ /^--/);
2892     # next if($line =~ /^DROP/m);
2893     return if($line =~ /^BEGIN TRANSACTION/m);
2894     return if($line =~ /^COMMIT/m);
2895     return if $line =~ /^\s+$/; # skip whitespace only
2896     $self->_query_start($line);
2897     try {
2898       # do a dbh_do cycle here, as we need some error checking in
2899       # place (even though we will ignore errors)
2900       $self->dbh_do (sub { $_[1]->do($line) });
2901     } catch {
2902       carp qq{$_ (running "${line}")};
2903     };
2904     $self->_query_end($line);
2905   };
2906   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2907   if (@statements > 1) {
2908     foreach my $statement (@statements) {
2909       $deploy->( $statement );
2910     }
2911   }
2912   elsif (@statements == 1) {
2913     # split on single line comments and end of statements
2914     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2915       $deploy->( $line );
2916     }
2917   }
2918 }
2919
2920 =head2 datetime_parser
2921
2922 Returns the datetime parser class
2923
2924 =cut
2925
2926 sub datetime_parser {
2927   my $self = shift;
2928   return $self->{datetime_parser} ||= do {
2929     $self->build_datetime_parser(@_);
2930   };
2931 }
2932
2933 =head2 datetime_parser_type
2934
2935 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2936
2937 =head2 build_datetime_parser
2938
2939 See L</datetime_parser>
2940
2941 =cut
2942
2943 sub build_datetime_parser {
2944   my $self = shift;
2945   my $type = $self->datetime_parser_type(@_);
2946   return $type;
2947 }
2948
2949
2950 =head2 is_replicating
2951
2952 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2953 replicate from a master database.  Default is undef, which is the result
2954 returned by databases that don't support replication.
2955
2956 =cut
2957
2958 sub is_replicating {
2959     return;
2960
2961 }
2962
2963 =head2 lag_behind_master
2964
2965 Returns a number that represents a certain amount of lag behind a master db
2966 when a given storage is replicating.  The number is database dependent, but
2967 starts at zero and increases with the amount of lag. Default in undef
2968
2969 =cut
2970
2971 sub lag_behind_master {
2972     return;
2973 }
2974
2975 =head2 relname_to_table_alias
2976
2977 =over 4
2978
2979 =item Arguments: $relname, $join_count
2980
2981 =item Return Value: $alias
2982
2983 =back
2984
2985 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2986 queries.
2987
2988 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2989 way these aliases are named.
2990
2991 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2992 otherwise C<"$relname">.
2993
2994 =cut
2995
2996 sub relname_to_table_alias {
2997   my ($self, $relname, $join_count) = @_;
2998
2999   my $alias = ($join_count && $join_count > 1 ?
3000     join('_', $relname, $join_count) : $relname);
3001
3002   return $alias;
3003 }
3004
3005 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3006 # version and it may be necessary to amend or override it for a specific storage
3007 # if such binds are necessary.
3008 sub _max_column_bytesize {
3009   my ($self, $attr) = @_;
3010
3011   my $max_size;
3012
3013   if ($attr->{sqlt_datatype}) {
3014     my $data_type = lc($attr->{sqlt_datatype});
3015
3016     if ($attr->{sqlt_size}) {
3017
3018       # String/sized-binary types
3019       if ($data_type =~ /^(?:
3020           l? (?:var)? char(?:acter)? (?:\s*varying)?
3021             |
3022           (?:var)? binary (?:\s*varying)?
3023             |
3024           raw
3025         )\b/x
3026       ) {
3027         $max_size = $attr->{sqlt_size};
3028       }
3029       # Other charset/unicode types, assume scale of 4
3030       elsif ($data_type =~ /^(?:
3031           national \s* character (?:\s*varying)?
3032             |
3033           nchar
3034             |
3035           univarchar
3036             |
3037           nvarchar
3038         )\b/x
3039       ) {
3040         $max_size = $attr->{sqlt_size} * 4;
3041       }
3042     }
3043
3044     if (!$max_size and !$self->_is_lob_type($data_type)) {
3045       $max_size = 100 # for all other (numeric?) datatypes
3046     }
3047   }
3048
3049   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3050 }
3051
3052 # Determine if a data_type is some type of BLOB
3053 sub _is_lob_type {
3054   my ($self, $data_type) = @_;
3055   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3056     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3057                                   |varchar|character\s*varying|nvarchar
3058                                   |national\s*character\s*varying))?\z/xi);
3059 }
3060
3061 sub _is_binary_lob_type {
3062   my ($self, $data_type) = @_;
3063   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3064     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3065 }
3066
3067 sub _is_text_lob_type {
3068   my ($self, $data_type) = @_;
3069   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3070     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3071                         |national\s*character\s*varying))\z/xi);
3072 }
3073
3074 # Determine if a data_type is some type of a binary type
3075 sub _is_binary_type {
3076   my ($self, $data_type) = @_;
3077   $data_type && ($self->_is_binary_lob_type($data_type)
3078     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3079 }
3080
3081 1;
3082
3083 =head1 USAGE NOTES
3084
3085 =head2 DBIx::Class and AutoCommit
3086
3087 DBIx::Class can do some wonderful magic with handling exceptions,
3088 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3089 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3090 transaction support.
3091
3092 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3093 in an assumed transaction between commits, and you're telling us you'd
3094 like to manage that manually.  A lot of the magic protections offered by
3095 this module will go away.  We can't protect you from exceptions due to database
3096 disconnects because we don't know anything about how to restart your
3097 transactions.  You're on your own for handling all sorts of exceptional
3098 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3099 be with raw DBI.
3100
3101
3102 =head1 AUTHOR AND CONTRIBUTORS
3103
3104 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3105
3106 =head1 LICENSE
3107
3108 You may distribute this code under the same terms as Perl itself.
3109
3110 =cut