lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use Carp::Clan qw/^DBIx::Class/;
  11 use DBI;
  12 use DBIx::Class::Storage::DBI::Cursor;
  13 use DBIx::Class::Storage::Statistics;
  14 use Scalar::Util();
  15 use List::Util();
  16 use Data::Dumper::Concise();
  17 use Sub::Name ();
  18 use Try::Tiny;
  19
  20 use File::Path ();
  21
  22 __PACKAGE__->mk_group_accessors('simple' =>
  23   qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid
  24      _conn_tid transaction_depth _dbh_autocommit _driver_determined savepoints
  25      _server_info_hash/
  26 );
  27
  28 # the values for these accessors are picked out (and deleted) from
  29 # the attribute hashref passed to connect_info
  30 my @storage_options = qw/
  31   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  32   disable_sth_caching unsafe auto_savepoint
  33 /;
  34 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  35
  36
  37 # default cursor class, overridable in connect_info attributes
  38 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  39
  40 __PACKAGE__->mk_group_accessors('inherited' => qw/
  41   sql_maker_class
  42   _supports_insert_returning
  43 /);
  44 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  45
  46 # Each of these methods need _determine_driver called before itself
  47 # in order to function reliably. This is a purely DRY optimization
  48 my @rdbms_specific_methods = qw/
  49   deployment_statements
  50   sqlt_type
  51   build_datetime_parser
  52   datetime_parser_type
  53
  54   insert
  55   insert_bulk
  56   update
  57   delete
  58   select
  59   select_single
  60 /;
  61
  62 for my $meth (@rdbms_specific_methods) {
  63
  64   my $orig = __PACKAGE__->can ($meth)
  65     or next;
  66
  67   no strict qw/refs/;
  68   no warnings qw/redefine/;
  69   *{__PACKAGE__ ."::$meth"} = Sub::Name::subname $meth => sub {
  70     if (not $_[0]->_driver_determined) {
  71       $_[0]->_determine_driver;
  72       goto $_[0]->can($meth);
  73     }
  74     $orig->(@_);
  75   };
  76 }
  77
  78
  79 =head1 NAME
  80
  81 DBIx::Class::Storage::DBI - DBI storage handler
  82
  83 =head1 SYNOPSIS
  84
  85   my $schema = MySchema->connect('dbi:SQLite:my.db');
  86
  87   $schema->storage->debug(1);
  88
  89   my @stuff = $schema->storage->dbh_do(
  90     sub {
  91       my ($storage, $dbh, @args) = @_;
  92       $dbh->do("DROP TABLE authors");
  93     },
  94     @column_list
  95   );
  96
  97   $schema->resultset('Book')->search({
  98      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
  99   });
 100
 101 =head1 DESCRIPTION
 102
 103 This class represents the connection to an RDBMS via L<DBI>.  See
 104 L<DBIx::Class::Storage> for general information.  This pod only
 105 documents DBI-specific methods and behaviors.
 106
 107 =head1 METHODS
 108
 109 =cut
 110
 111 sub new {
 112   my $new = shift->next::method(@_);
 113
 114   $new->transaction_depth(0);
 115   $new->_sql_maker_opts({});
 116   $new->{savepoints} = [];
 117   $new->{_in_dbh_do} = 0;
 118   $new->{_dbh_gen} = 0;
 119
 120   # read below to see what this does
 121   $new->_arm_global_destructor;
 122
 123   $new;
 124 }
 125
 126 # This is hack to work around perl shooting stuff in random
 127 # order on exit(). If we do not walk the remaining storage
 128 # objects in an END block, there is a *small but real* chance
 129 # of a fork()ed child to kill the parent's shared DBI handle,
 130 # *before perl reaches the DESTROY in this package*
 131 # Yes, it is ugly and effective.
 132 {
 133   my %seek_and_destroy;
 134
 135   sub _arm_global_destructor {
 136     my $self = shift;
 137     my $key = Scalar::Util::refaddr ($self);
 138     $seek_and_destroy{$key} = $self;
 139     Scalar::Util::weaken ($seek_and_destroy{$key});
 140   }
 141
 142   END {
 143     local $?; # just in case the DBI destructor changes it somehow
 144
 145     # destroy just the object if not native to this process/thread
 146     $_->_preserve_foreign_dbh for (grep
 147       { defined $_ }
 148       values %seek_and_destroy
 149     );
 150   }
 151 }
 152
 153 sub DESTROY {
 154   my $self = shift;
 155
 156   # destroy just the object if not native to this process/thread
 157   $self->_preserve_foreign_dbh;
 158
 159   # some databases need this to stop spewing warnings
 160   if (my $dbh = $self->_dbh) {
 161     try {
 162       %{ $dbh->{CachedKids} } = ();
 163       $dbh->disconnect;
 164     };
 165   }
 166
 167   $self->_dbh(undef);
 168 }
 169
 170 sub _preserve_foreign_dbh {
 171   my $self = shift;
 172
 173   return unless $self->_dbh;
 174
 175   $self->_verify_tid;
 176
 177   return unless $self->_dbh;
 178
 179   $self->_verify_pid;
 180
 181 }
 182
 183 # handle pid changes correctly - do not destroy parent's connection
 184 sub _verify_pid {
 185   my $self = shift;
 186
 187   return if ( defined $self->_conn_pid and $self->_conn_pid == $$ );
 188
 189   $self->_dbh->{InactiveDestroy} = 1;
 190   $self->_dbh(undef);
 191   $self->{_dbh_gen}++;
 192
 193   return;
 194 }
 195
 196 # very similar to above, but seems to FAIL if I set InactiveDestroy
 197 sub _verify_tid {
 198   my $self = shift;
 199
 200   if ( ! defined $self->_conn_tid ) {
 201     return; # no threads
 202   }
 203   elsif ( $self->_conn_tid == threads->tid ) {
 204     return; # same thread
 205   }
 206
 207   #$self->_dbh->{InactiveDestroy} = 1;  # why does t/51threads.t fail...?
 208   $self->_dbh(undef);
 209   $self->{_dbh_gen}++;
 210
 211   return;
 212 }
 213
 214
 215 =head2 connect_info
 216
 217 This method is normally called by L<DBIx::Class::Schema/connection>, which
 218 encapsulates its argument list in an arrayref before passing them here.
 219
 220 The argument list may contain:
 221
 222 =over
 223
 224 =item *
 225
 226 The same 4-element argument set one would normally pass to
 227 L<DBI/connect>, optionally followed by
 228 L<extra attributes|/DBIx::Class specific connection attributes>
 229 recognized by DBIx::Class:
 230
 231   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 232
 233 =item *
 234
 235 A single code reference which returns a connected
 236 L<DBI database handle|DBI/connect> optionally followed by
 237 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 238 by DBIx::Class:
 239
 240   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 241
 242 =item *
 243
 244 A single hashref with all the attributes and the dsn/user/password
 245 mixed together:
 246
 247   $connect_info_args = [{
 248     dsn => $dsn,
 249     user => $user,
 250     password => $pass,
 251     %dbi_attributes,
 252     %extra_attributes,
 253   }];
 254
 255   $connect_info_args = [{
 256     dbh_maker => sub { DBI->connect (...) },
 257     %dbi_attributes,
 258     %extra_attributes,
 259   }];
 260
 261 This is particularly useful for L<Catalyst> based applications, allowing the
 262 following config (L<Config::General> style):
 263
 264   <Model::DB>
 265     schema_class   App::DB
 266     <connect_info>
 267       dsn          dbi:mysql:database=test
 268       user         testuser
 269       password     TestPass
 270       AutoCommit   1
 271     </connect_info>
 272   </Model::DB>
 273
 274 The C<dsn>/C<user>/C<password> combination can be substituted by the
 275 C<dbh_maker> key whose value is a coderef that returns a connected
 276 L<DBI database handle|DBI/connect>
 277
 278 =back
 279
 280 Please note that the L<DBI> docs recommend that you always explicitly
 281 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 282 recommends that it be set to I<1>, and that you perform transactions
 283 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 284 to I<1> if you do not do explicitly set it to zero.  This is the default
 285 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 286
 287 =head3 DBIx::Class specific connection attributes
 288
 289 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 290 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 291 the following connection options. These options can be mixed in with your other
 292 L<DBI> connection attributes, or placed in a separate hashref
 293 (C<\%extra_attributes>) as shown above.
 294
 295 Every time C<connect_info> is invoked, any previous settings for
 296 these options will be cleared before setting the new ones, regardless of
 297 whether any options are specified in the new C<connect_info>.
 298
 299
 300 =over
 301
 302 =item on_connect_do
 303
 304 Specifies things to do immediately after connecting or re-connecting to
 305 the database.  Its value may contain:
 306
 307 =over
 308
 309 =item a scalar
 310
 311 This contains one SQL statement to execute.
 312
 313 =item an array reference
 314
 315 This contains SQL statements to execute in order.  Each element contains
 316 a string or a code reference that returns a string.
 317
 318 =item a code reference
 319
 320 This contains some code to execute.  Unlike code references within an
 321 array reference, its return value is ignored.
 322
 323 =back
 324
 325 =item on_disconnect_do
 326
 327 Takes arguments in the same form as L</on_connect_do> and executes them
 328 immediately before disconnecting from the database.
 329
 330 Note, this only runs if you explicitly call L</disconnect> on the
 331 storage object.
 332
 333 =item on_connect_call
 334
 335 A more generalized form of L</on_connect_do> that calls the specified
 336 C<connect_call_METHOD> methods in your storage driver.
 337
 338   on_connect_do => 'select 1'
 339
 340 is equivalent to:
 341
 342   on_connect_call => [ [ do_sql => 'select 1' ] ]
 343
 344 Its values may contain:
 345
 346 =over
 347
 348 =item a scalar
 349
 350 Will call the C<connect_call_METHOD> method.
 351
 352 =item a code reference
 353
 354 Will execute C<< $code->($storage) >>
 355
 356 =item an array reference
 357
 358 Each value can be a method name or code reference.
 359
 360 =item an array of arrays
 361
 362 For each array, the first item is taken to be the C<connect_call_> method name
 363 or code reference, and the rest are parameters to it.
 364
 365 =back
 366
 367 Some predefined storage methods you may use:
 368
 369 =over
 370
 371 =item do_sql
 372
 373 Executes a SQL string or a code reference that returns a SQL string. This is
 374 what L</on_connect_do> and L</on_disconnect_do> use.
 375
 376 It can take:
 377
 378 =over
 379
 380 =item a scalar
 381
 382 Will execute the scalar as SQL.
 383
 384 =item an arrayref
 385
 386 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 387 attributes hashref and bind values.
 388
 389 =item a code reference
 390
 391 Will execute C<< $code->($storage) >> and execute the return array refs as
 392 above.
 393
 394 =back
 395
 396 =item datetime_setup
 397
 398 Execute any statements necessary to initialize the database session to return
 399 and accept datetime/timestamp values used with
 400 L<DBIx::Class::InflateColumn::DateTime>.
 401
 402 Only necessary for some databases, see your specific storage driver for
 403 implementation details.
 404
 405 =back
 406
 407 =item on_disconnect_call
 408
 409 Takes arguments in the same form as L</on_connect_call> and executes them
 410 immediately before disconnecting from the database.
 411
 412 Calls the C<disconnect_call_METHOD> methods as opposed to the
 413 C<connect_call_METHOD> methods called by L</on_connect_call>.
 414
 415 Note, this only runs if you explicitly call L</disconnect> on the
 416 storage object.
 417
 418 =item disable_sth_caching
 419
 420 If set to a true value, this option will disable the caching of
 421 statement handles via L<DBI/prepare_cached>.
 422
 423 =item limit_dialect
 424
 425 Sets the limit dialect. This is useful for JDBC-bridge among others
 426 where the remote SQL-dialect cannot be determined by the name of the
 427 driver alone. See also L<SQL::Abstract::Limit>.
 428
 429 =item quote_char
 430
 431 Specifies what characters to use to quote table and column names. If
 432 you use this you will want to specify L</name_sep> as well.
 433
 434 C<quote_char> expects either a single character, in which case is it
 435 is placed on either side of the table/column name, or an arrayref of length
 436 2 in which case the table/column name is placed between the elements.
 437
 438 For example under MySQL you should use C<< quote_char => '`' >>, and for
 439 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 440
 441 =item name_sep
 442
 443 This only needs to be used in conjunction with C<quote_char>, and is used to
 444 specify the character that separates elements (schemas, tables, columns) from
 445 each other. In most cases this is simply a C<.>.
 446
 447 The consequences of not supplying this value is that L<SQL::Abstract>
 448 will assume DBIx::Class' uses of aliases to be complete column
 449 names. The output will look like I<"me.name"> when it should actually
 450 be I<"me"."name">.
 451
 452 =item unsafe
 453
 454 This Storage driver normally installs its own C<HandleError>, sets
 455 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 456 all database handles, including those supplied by a coderef.  It does this
 457 so that it can have consistent and useful error behavior.
 458
 459 If you set this option to a true value, Storage will not do its usual
 460 modifications to the database handle's attributes, and instead relies on
 461 the settings in your connect_info DBI options (or the values you set in
 462 your connection coderef, in the case that you are connecting via coderef).
 463
 464 Note that your custom settings can cause Storage to malfunction,
 465 especially if you set a C<HandleError> handler that suppresses exceptions
 466 and/or disable C<RaiseError>.
 467
 468 =item auto_savepoint
 469
 470 If this option is true, L<DBIx::Class> will use savepoints when nesting
 471 transactions, making it possible to recover from failure in the inner
 472 transaction without having to abort all outer transactions.
 473
 474 =item cursor_class
 475
 476 Use this argument to supply a cursor class other than the default
 477 L<DBIx::Class::Storage::DBI::Cursor>.
 478
 479 =back
 480
 481 Some real-life examples of arguments to L</connect_info> and
 482 L<DBIx::Class::Schema/connect>
 483
 484   # Simple SQLite connection
 485   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 486
 487   # Connect via subref
 488   ->connect_info([ sub { DBI->connect(...) } ]);
 489
 490   # Connect via subref in hashref
 491   ->connect_info([{
 492     dbh_maker => sub { DBI->connect(...) },
 493     on_connect_do => 'alter session ...',
 494   }]);
 495
 496   # A bit more complicated
 497   ->connect_info(
 498     [
 499       'dbi:Pg:dbname=foo',
 500       'postgres',
 501       'my_pg_password',
 502       { AutoCommit => 1 },
 503       { quote_char => q{"}, name_sep => q{.} },
 504     ]
 505   );
 506
 507   # Equivalent to the previous example
 508   ->connect_info(
 509     [
 510       'dbi:Pg:dbname=foo',
 511       'postgres',
 512       'my_pg_password',
 513       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 514     ]
 515   );
 516
 517   # Same, but with hashref as argument
 518   # See parse_connect_info for explanation
 519   ->connect_info(
 520     [{
 521       dsn         => 'dbi:Pg:dbname=foo',
 522       user        => 'postgres',
 523       password    => 'my_pg_password',
 524       AutoCommit  => 1,
 525       quote_char  => q{"},
 526       name_sep    => q{.},
 527     }]
 528   );
 529
 530   # Subref + DBIx::Class-specific connection options
 531   ->connect_info(
 532     [
 533       sub { DBI->connect(...) },
 534       {
 535           quote_char => q{`},
 536           name_sep => q{@},
 537           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 538           disable_sth_caching => 1,
 539       },
 540     ]
 541   );
 542
 543
 544
 545 =cut
 546
 547 sub connect_info {
 548   my ($self, $info) = @_;
 549
 550   return $self->_connect_info if !$info;
 551
 552   $self->_connect_info($info); # copy for _connect_info
 553
 554   $info = $self->_normalize_connect_info($info)
 555     if ref $info eq 'ARRAY';
 556
 557   for my $storage_opt (keys %{ $info->{storage_options} }) {
 558     my $value = $info->{storage_options}{$storage_opt};
 559
 560     $self->$storage_opt($value);
 561   }
 562
 563   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 564   #  the new set of options
 565   $self->_sql_maker(undef);
 566   $self->_sql_maker_opts({});
 567
 568   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 569     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 570
 571     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 572   }
 573
 574   my %attrs = (
 575     %{ $self->_default_dbi_connect_attributes || {} },
 576     %{ $info->{attributes} || {} },
 577   );
 578
 579   my @args = @{ $info->{arguments} };
 580
 581   $self->_dbi_connect_info([@args,
 582     %attrs && !(ref $args[0] eq 'CODE') ? \%attrs : ()]);
 583
 584   return $self->_connect_info;
 585 }
 586
 587 sub _normalize_connect_info {
 588   my ($self, $info_arg) = @_;
 589   my %info;
 590
 591   my @args = @$info_arg;  # take a shallow copy for further mutilation
 592
 593   # combine/pre-parse arguments depending on invocation style
 594
 595   my %attrs;
 596   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 597     %attrs = %{ $args[1] || {} };
 598     @args = $args[0];
 599   }
 600   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 601     %attrs = %{$args[0]};
 602     @args = ();
 603     if (my $code = delete $attrs{dbh_maker}) {
 604       @args = $code;
 605
 606       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 607       if (@ignored) {
 608         carp sprintf (
 609             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 610           . "to the result of 'dbh_maker'",
 611
 612           join (', ', map { "'$_'" } (@ignored) ),
 613         );
 614       }
 615     }
 616     else {
 617       @args = delete @attrs{qw/dsn user password/};
 618     }
 619   }
 620   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 621     %attrs = (
 622       % { $args[3] || {} },
 623       % { $args[4] || {} },
 624     );
 625     @args = @args[0,1,2];
 626   }
 627
 628   $info{arguments} = \@args;
 629
 630   my @storage_opts = grep exists $attrs{$_},
 631     @storage_options, 'cursor_class';
 632
 633   @{ $info{storage_options} }{@storage_opts} =
 634     delete @attrs{@storage_opts} if @storage_opts;
 635
 636   my @sql_maker_opts = grep exists $attrs{$_},
 637     qw/limit_dialect quote_char name_sep/;
 638
 639   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 640     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 641
 642   $info{attributes} = \%attrs if %attrs;
 643
 644   return \%info;
 645 }
 646
 647 sub _default_dbi_connect_attributes {
 648   return {
 649     AutoCommit => 1,
 650     RaiseError => 1,
 651     PrintError => 0,
 652   };
 653 }
 654
 655 =head2 on_connect_do
 656
 657 This method is deprecated in favour of setting via L</connect_info>.
 658
 659 =cut
 660
 661 =head2 on_disconnect_do
 662
 663 This method is deprecated in favour of setting via L</connect_info>.
 664
 665 =cut
 666
 667 sub _parse_connect_do {
 668   my ($self, $type) = @_;
 669
 670   my $val = $self->$type;
 671   return () if not defined $val;
 672
 673   my @res;
 674
 675   if (not ref($val)) {
 676     push @res, [ 'do_sql', $val ];
 677   } elsif (ref($val) eq 'CODE') {
 678     push @res, $val;
 679   } elsif (ref($val) eq 'ARRAY') {
 680     push @res, map { [ 'do_sql', $_ ] } @$val;
 681   } else {
 682     $self->throw_exception("Invalid type for $type: ".ref($val));
 683   }
 684
 685   return \@res;
 686 }
 687
 688 =head2 dbh_do
 689
 690 Arguments: ($subref | $method_name), @extra_coderef_args?
 691
 692 Execute the given $subref or $method_name using the new exception-based
 693 connection management.
 694
 695 The first two arguments will be the storage object that C<dbh_do> was called
 696 on and a database handle to use.  Any additional arguments will be passed
 697 verbatim to the called subref as arguments 2 and onwards.
 698
 699 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 700 exception handling and reconnection (or failover in future subclasses).
 701
 702 Your subref should have no side-effects outside of the database, as
 703 there is the potential for your subref to be partially double-executed
 704 if the database connection was stale/dysfunctional.
 705
 706 Example:
 707
 708   my @stuff = $schema->storage->dbh_do(
 709     sub {
 710       my ($storage, $dbh, @cols) = @_;
 711       my $cols = join(q{, }, @cols);
 712       $dbh->selectrow_array("SELECT $cols FROM foo");
 713     },
 714     @column_list
 715   );
 716
 717 =cut
 718
 719 sub dbh_do {
 720   my $self = shift;
 721   my $code = shift;
 722
 723   my $dbh = $self->_get_dbh;
 724
 725   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 726       || $self->{transaction_depth};
 727
 728   local $self->{_in_dbh_do} = 1;
 729
 730   my @result;
 731   my $want_array = wantarray;
 732
 733   eval {
 734
 735     if($want_array) {
 736         @result = $self->$code($dbh, @_);
 737     }
 738     elsif(defined $want_array) {
 739         $result[0] = $self->$code($dbh, @_);
 740     }
 741     else {
 742         $self->$code($dbh, @_);
 743     }
 744   };
 745
 746   # ->connected might unset $@ - copy
 747   my $exception = $@;
 748   if(!$exception) { return $want_array ? @result : $result[0] }
 749
 750   $self->throw_exception($exception) if $self->connected;
 751
 752   # We were not connected - reconnect and retry, but let any
 753   #  exception fall right through this time
 754   carp "Retrying $code after catching disconnected exception: $exception"
 755     if $ENV{DBIC_DBIRETRY_DEBUG};
 756   $self->_populate_dbh;
 757   $self->$code($self->_dbh, @_);
 758 }
 759
 760 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 761 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 762 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 763 sub txn_do {
 764   my $self = shift;
 765   my $coderef = shift;
 766
 767   ref $coderef eq 'CODE' or $self->throw_exception
 768     ('$coderef must be a CODE reference');
 769
 770   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 771
 772   local $self->{_in_dbh_do} = 1;
 773
 774   my @result;
 775   my $want_array = wantarray;
 776
 777   my $tried = 0;
 778   while(1) {
 779     eval {
 780       $self->_get_dbh;
 781
 782       $self->txn_begin;
 783       if($want_array) {
 784           @result = $coderef->(@_);
 785       }
 786       elsif(defined $want_array) {
 787           $result[0] = $coderef->(@_);
 788       }
 789       else {
 790           $coderef->(@_);
 791       }
 792       $self->txn_commit;
 793     };
 794
 795     # ->connected might unset $@ - copy
 796     my $exception = $@;
 797     if(!$exception) { return $want_array ? @result : $result[0] }
 798
 799     if($tried++ || $self->connected) {
 800       eval { $self->txn_rollback };
 801       my $rollback_exception = $@;
 802       if($rollback_exception) {
 803         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 804         $self->throw_exception($exception)  # propagate nested rollback
 805           if $rollback_exception =~ /$exception_class/;
 806
 807         $self->throw_exception(
 808           "Transaction aborted: ${exception}. "
 809           . "Rollback failed: ${rollback_exception}"
 810         );
 811       }
 812       $self->throw_exception($exception)
 813     }
 814
 815     # We were not connected, and was first try - reconnect and retry
 816     # via the while loop
 817     carp "Retrying $coderef after catching disconnected exception: $exception"
 818       if $ENV{DBIC_DBIRETRY_DEBUG};
 819     $self->_populate_dbh;
 820   }
 821 }
 822
 823 =head2 disconnect
 824
 825 Our C<disconnect> method also performs a rollback first if the
 826 database is not in C<AutoCommit> mode.
 827
 828 =cut
 829
 830 sub disconnect {
 831   my ($self) = @_;
 832
 833   if( $self->_dbh ) {
 834     my @actions;
 835
 836     push @actions, ( $self->on_disconnect_call || () );
 837     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 838
 839     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 840
 841     $self->_dbh_rollback unless $self->_dbh_autocommit;
 842
 843     %{ $self->_dbh->{CachedKids} } = ();
 844     $self->_dbh->disconnect;
 845     $self->_dbh(undef);
 846     $self->{_dbh_gen}++;
 847   }
 848 }
 849
 850 =head2 with_deferred_fk_checks
 851
 852 =over 4
 853
 854 =item Arguments: C<$coderef>
 855
 856 =item Return Value: The return value of $coderef
 857
 858 =back
 859
 860 Storage specific method to run the code ref with FK checks deferred or
 861 in MySQL's case disabled entirely.
 862
 863 =cut
 864
 865 # Storage subclasses should override this
 866 sub with_deferred_fk_checks {
 867   my ($self, $sub) = @_;
 868   $sub->();
 869 }
 870
 871 =head2 connected
 872
 873 =over
 874
 875 =item Arguments: none
 876
 877 =item Return Value: 1|0
 878
 879 =back
 880
 881 Verifies that the current database handle is active and ready to execute
 882 an SQL statement (e.g. the connection did not get stale, server is still
 883 answering, etc.) This method is used internally by L</dbh>.
 884
 885 =cut
 886
 887 sub connected {
 888   my $self = shift;
 889   return 0 unless $self->_seems_connected;
 890
 891   #be on the safe side
 892   local $self->_dbh->{RaiseError} = 1;
 893
 894   return $self->_ping;
 895 }
 896
 897 sub _seems_connected {
 898   my $self = shift;
 899
 900   $self->_preserve_foreign_dbh;
 901
 902   my $dbh = $self->_dbh
 903     or return 0;
 904
 905   return $dbh->FETCH('Active');
 906 }
 907
 908 sub _ping {
 909   my $self = shift;
 910
 911   my $dbh = $self->_dbh or return 0;
 912
 913   return $dbh->ping;
 914 }
 915
 916 sub ensure_connected {
 917   my ($self) = @_;
 918
 919   unless ($self->connected) {
 920     $self->_populate_dbh;
 921   }
 922 }
 923
 924 =head2 dbh
 925
 926 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 927 is guaranteed to be healthy by implicitly calling L</connected>, and if
 928 necessary performing a reconnection before returning. Keep in mind that this
 929 is very B<expensive> on some database engines. Consider using L</dbh_do>
 930 instead.
 931
 932 =cut
 933
 934 sub dbh {
 935   my ($self) = @_;
 936
 937   if (not $self->_dbh) {
 938     $self->_populate_dbh;
 939   } else {
 940     $self->ensure_connected;
 941   }
 942   return $self->_dbh;
 943 }
 944
 945 # this is the internal "get dbh or connect (don't check)" method
 946 sub _get_dbh {
 947   my $self = shift;
 948   $self->_preserve_foreign_dbh;
 949   $self->_populate_dbh unless $self->_dbh;
 950   return $self->_dbh;
 951 }
 952
 953 sub _sql_maker_args {
 954     my ($self) = @_;
 955
 956     return (
 957       bindtype=>'columns',
 958       array_datatypes => 1,
 959       limit_dialect => $self->_get_dbh,
 960       %{$self->_sql_maker_opts}
 961     );
 962 }
 963
 964 sub sql_maker {
 965   my ($self) = @_;
 966   unless ($self->_sql_maker) {
 967     my $sql_maker_class = $self->sql_maker_class;
 968     $self->ensure_class_loaded ($sql_maker_class);
 969     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 970   }
 971   return $self->_sql_maker;
 972 }
 973
 974 # nothing to do by default
 975 sub _rebless {}
 976 sub _init {}
 977
 978 sub _populate_dbh {
 979   my ($self) = @_;
 980
 981   my @info = @{$self->_dbi_connect_info || []};
 982   $self->_dbh(undef); # in case ->connected failed we might get sent here
 983   $self->_server_info_hash (undef);
 984   $self->_dbh($self->_connect(@info));
 985
 986   $self->_conn_pid($$);
 987   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 988
 989   $self->_determine_driver;
 990
 991   # Always set the transaction depth on connect, since
 992   #  there is no transaction in progress by definition
 993   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 994
 995   $self->_run_connection_actions unless $self->{_in_determine_driver};
 996 }
 997
 998 sub _run_connection_actions {
 999   my $self = shift;
1000   my @actions;
1001
1002   push @actions, ( $self->on_connect_call || () );
1003   push @actions, $self->_parse_connect_do ('on_connect_do');
1004
1005   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1006 }
1007
1008 sub _server_info {
1009   my $self = shift;
1010
1011   unless ($self->_server_info_hash) {
1012
1013     my %info;
1014
1015     my $server_version = do {
1016       local $@; # might be happenin in some sort of destructor
1017       eval { $self->_get_server_version };
1018     };
1019
1020     if (defined $server_version) {
1021       $info{dbms_version} = $server_version;
1022
1023       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1024       my @verparts = split (/\./, $numeric_version);
1025       if (
1026         @verparts
1027           &&
1028         $verparts[0] <= 999
1029       ) {
1030         # consider only up to 3 version parts, iff not more than 3 digits
1031         my @use_parts;
1032         while (@verparts && @use_parts < 3) {
1033           my $p = shift @verparts;
1034           last if $p > 999;
1035           push @use_parts, $p;
1036         }
1037         push @use_parts, 0 while @use_parts < 3;
1038
1039         $info{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1040       }
1041     }
1042
1043     $self->_server_info_hash(\%info);
1044   }
1045
1046   return $self->_server_info_hash
1047 }
1048
1049 sub _get_server_version {
1050   shift->_get_dbh->get_info(18);
1051 }
1052
1053 sub _determine_driver {
1054   my ($self) = @_;
1055
1056   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1057     my $started_connected = 0;
1058     local $self->{_in_determine_driver} = 1;
1059
1060     if (ref($self) eq __PACKAGE__) {
1061       my $driver;
1062       if ($self->_dbh) { # we are connected
1063         $driver = $self->_dbh->{Driver}{Name};
1064         $started_connected = 1;
1065       } else {
1066         # if connect_info is a CODEREF, we have no choice but to connect
1067         if (ref $self->_dbi_connect_info->[0] &&
1068             Scalar::Util::reftype($self->_dbi_connect_info->[0]) eq 'CODE') {
1069           $self->_populate_dbh;
1070           $driver = $self->_dbh->{Driver}{Name};
1071         }
1072         else {
1073           # try to use dsn to not require being connected, the driver may still
1074           # force a connection in _rebless to determine version
1075           # (dsn may not be supplied at all if all we do is make a mock-schema)
1076           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1077           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1078           $driver ||= $ENV{DBI_DRIVER};
1079         }
1080       }
1081
1082       if ($driver) {
1083         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1084         if ($self->load_optional_class($storage_class)) {
1085           mro::set_mro($storage_class, 'c3');
1086           bless $self, $storage_class;
1087           $self->_rebless();
1088         }
1089       }
1090     }
1091
1092     $self->_driver_determined(1);
1093
1094     $self->_init; # run driver-specific initializations
1095
1096     $self->_run_connection_actions
1097         if !$started_connected && defined $self->_dbh;
1098   }
1099 }
1100
1101 sub _do_connection_actions {
1102   my $self          = shift;
1103   my $method_prefix = shift;
1104   my $call          = shift;
1105
1106   if (not ref($call)) {
1107     my $method = $method_prefix . $call;
1108     $self->$method(@_);
1109   } elsif (ref($call) eq 'CODE') {
1110     $self->$call(@_);
1111   } elsif (ref($call) eq 'ARRAY') {
1112     if (ref($call->[0]) ne 'ARRAY') {
1113       $self->_do_connection_actions($method_prefix, $_) for @$call;
1114     } else {
1115       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1116     }
1117   } else {
1118     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1119   }
1120
1121   return $self;
1122 }
1123
1124 sub connect_call_do_sql {
1125   my $self = shift;
1126   $self->_do_query(@_);
1127 }
1128
1129 sub disconnect_call_do_sql {
1130   my $self = shift;
1131   $self->_do_query(@_);
1132 }
1133
1134 # override in db-specific backend when necessary
1135 sub connect_call_datetime_setup { 1 }
1136
1137 sub _do_query {
1138   my ($self, $action) = @_;
1139
1140   if (ref $action eq 'CODE') {
1141     $action = $action->($self);
1142     $self->_do_query($_) foreach @$action;
1143   }
1144   else {
1145     # Most debuggers expect ($sql, @bind), so we need to exclude
1146     # the attribute hash which is the second argument to $dbh->do
1147     # furthermore the bind values are usually to be presented
1148     # as named arrayref pairs, so wrap those here too
1149     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1150     my $sql = shift @do_args;
1151     my $attrs = shift @do_args;
1152     my @bind = map { [ undef, $_ ] } @do_args;
1153
1154     $self->_query_start($sql, @bind);
1155     $self->_get_dbh->do($sql, $attrs, @do_args);
1156     $self->_query_end($sql, @bind);
1157   }
1158
1159   return $self;
1160 }
1161
1162 sub _connect {
1163   my ($self, @info) = @_;
1164
1165   $self->throw_exception("You failed to provide any connection info")
1166     if !@info;
1167
1168   my ($old_connect_via, $dbh);
1169
1170   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1171     $old_connect_via = $DBI::connect_via;
1172     $DBI::connect_via = 'connect';
1173   }
1174
1175   eval {
1176     if(ref $info[0] eq 'CODE') {
1177        $dbh = $info[0]->();
1178     }
1179     else {
1180        $dbh = DBI->connect(@info);
1181     }
1182
1183     if($dbh && !$self->unsafe) {
1184       my $weak_self = $self;
1185       Scalar::Util::weaken($weak_self);
1186       $dbh->{HandleError} = sub {
1187           if ($weak_self) {
1188             $weak_self->throw_exception("DBI Exception: $_[0]");
1189           }
1190           else {
1191             # the handler may be invoked by something totally out of
1192             # the scope of DBIC
1193             croak ("DBI Exception: $_[0]");
1194           }
1195       };
1196       $dbh->{ShowErrorStatement} = 1;
1197       $dbh->{RaiseError} = 1;
1198       $dbh->{PrintError} = 0;
1199     }
1200   };
1201
1202   $DBI::connect_via = $old_connect_via if $old_connect_via;
1203
1204   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1205     if !$dbh || $@;
1206
1207   $self->_dbh_autocommit($dbh->{AutoCommit});
1208
1209   $dbh;
1210 }
1211
1212 sub svp_begin {
1213   my ($self, $name) = @_;
1214
1215   $name = $self->_svp_generate_name
1216     unless defined $name;
1217
1218   $self->throw_exception ("You can't use savepoints outside a transaction")
1219     if $self->{transaction_depth} == 0;
1220
1221   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1222     unless $self->can('_svp_begin');
1223
1224   push @{ $self->{savepoints} }, $name;
1225
1226   $self->debugobj->svp_begin($name) if $self->debug;
1227
1228   return $self->_svp_begin($name);
1229 }
1230
1231 sub svp_release {
1232   my ($self, $name) = @_;
1233
1234   $self->throw_exception ("You can't use savepoints outside a transaction")
1235     if $self->{transaction_depth} == 0;
1236
1237   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1238     unless $self->can('_svp_release');
1239
1240   if (defined $name) {
1241     $self->throw_exception ("Savepoint '$name' does not exist")
1242       unless grep { $_ eq $name } @{ $self->{savepoints} };
1243
1244     # Dig through the stack until we find the one we are releasing.  This keeps
1245     # the stack up to date.
1246     my $svp;
1247
1248     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1249   } else {
1250     $name = pop @{ $self->{savepoints} };
1251   }
1252
1253   $self->debugobj->svp_release($name) if $self->debug;
1254
1255   return $self->_svp_release($name);
1256 }
1257
1258 sub svp_rollback {
1259   my ($self, $name) = @_;
1260
1261   $self->throw_exception ("You can't use savepoints outside a transaction")
1262     if $self->{transaction_depth} == 0;
1263
1264   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1265     unless $self->can('_svp_rollback');
1266
1267   if (defined $name) {
1268       # If they passed us a name, verify that it exists in the stack
1269       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1270           $self->throw_exception("Savepoint '$name' does not exist!");
1271       }
1272
1273       # Dig through the stack until we find the one we are releasing.  This keeps
1274       # the stack up to date.
1275       while(my $s = pop(@{ $self->{savepoints} })) {
1276           last if($s eq $name);
1277       }
1278       # Add the savepoint back to the stack, as a rollback doesn't remove the
1279       # named savepoint, only everything after it.
1280       push(@{ $self->{savepoints} }, $name);
1281   } else {
1282       # We'll assume they want to rollback to the last savepoint
1283       $name = $self->{savepoints}->[-1];
1284   }
1285
1286   $self->debugobj->svp_rollback($name) if $self->debug;
1287
1288   return $self->_svp_rollback($name);
1289 }
1290
1291 sub _svp_generate_name {
1292     my ($self) = @_;
1293
1294     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1295 }
1296
1297 sub txn_begin {
1298   my $self = shift;
1299
1300   # this means we have not yet connected and do not know the AC status
1301   # (e.g. coderef $dbh)
1302   $self->ensure_connected if (! defined $self->_dbh_autocommit);
1303
1304   if($self->{transaction_depth} == 0) {
1305     $self->debugobj->txn_begin()
1306       if $self->debug;
1307     $self->_dbh_begin_work;
1308   }
1309   elsif ($self->auto_savepoint) {
1310     $self->svp_begin;
1311   }
1312   $self->{transaction_depth}++;
1313 }
1314
1315 sub _dbh_begin_work {
1316   my $self = shift;
1317
1318   # if the user is utilizing txn_do - good for him, otherwise we need to
1319   # ensure that the $dbh is healthy on BEGIN.
1320   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1321   # will be replaced by a failure of begin_work itself (which will be
1322   # then retried on reconnect)
1323   if ($self->{_in_dbh_do}) {
1324     $self->_dbh->begin_work;
1325   } else {
1326     $self->dbh_do(sub { $_[1]->begin_work });
1327   }
1328 }
1329
1330 sub txn_commit {
1331   my $self = shift;
1332   if ($self->{transaction_depth} == 1) {
1333     $self->debugobj->txn_commit()
1334       if ($self->debug);
1335     $self->_dbh_commit;
1336     $self->{transaction_depth} = 0
1337       if $self->_dbh_autocommit;
1338   }
1339   elsif($self->{transaction_depth} > 1) {
1340     $self->{transaction_depth}--;
1341     $self->svp_release
1342       if $self->auto_savepoint;
1343   }
1344 }
1345
1346 sub _dbh_commit {
1347   my $self = shift;
1348   my $dbh  = $self->_dbh
1349     or $self->throw_exception('cannot COMMIT on a disconnected handle');
1350   $dbh->commit;
1351 }
1352
1353 sub txn_rollback {
1354   my $self = shift;
1355   my $dbh = $self->_dbh;
1356   eval {
1357     if ($self->{transaction_depth} == 1) {
1358       $self->debugobj->txn_rollback()
1359         if ($self->debug);
1360       $self->{transaction_depth} = 0
1361         if $self->_dbh_autocommit;
1362       $self->_dbh_rollback;
1363     }
1364     elsif($self->{transaction_depth} > 1) {
1365       $self->{transaction_depth}--;
1366       if ($self->auto_savepoint) {
1367         $self->svp_rollback;
1368         $self->svp_release;
1369       }
1370     }
1371     else {
1372       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1373     }
1374   };
1375   if ($@) {
1376     my $error = $@;
1377     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1378     $error =~ /$exception_class/ and $self->throw_exception($error);
1379     # ensure that a failed rollback resets the transaction depth
1380     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1381     $self->throw_exception($error);
1382   }
1383 }
1384
1385 sub _dbh_rollback {
1386   my $self = shift;
1387   my $dbh  = $self->_dbh
1388     or $self->throw_exception('cannot ROLLBACK on a disconnected handle');
1389   $dbh->rollback;
1390 }
1391
1392 # This used to be the top-half of _execute.  It was split out to make it
1393 #  easier to override in NoBindVars without duping the rest.  It takes up
1394 #  all of _execute's args, and emits $sql, @bind.
1395 sub _prep_for_execute {
1396   my ($self, $op, $extra_bind, $ident, $args) = @_;
1397
1398   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1399     $ident = $ident->from();
1400   }
1401
1402   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1403
1404   unshift(@bind,
1405     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1406       if $extra_bind;
1407   return ($sql, \@bind);
1408 }
1409
1410
1411 sub _fix_bind_params {
1412     my ($self, @bind) = @_;
1413
1414     ### Turn @bind from something like this:
1415     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1416     ### to this:
1417     ###   ( "'1'", "'1'", "'3'" )
1418     return
1419         map {
1420             if ( defined( $_ && $_->[1] ) ) {
1421                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1422             }
1423             else { q{'NULL'}; }
1424         } @bind;
1425 }
1426
1427 sub _query_start {
1428     my ( $self, $sql, @bind ) = @_;
1429
1430     if ( $self->debug ) {
1431         @bind = $self->_fix_bind_params(@bind);
1432
1433         $self->debugobj->query_start( $sql, @bind );
1434     }
1435 }
1436
1437 sub _query_end {
1438     my ( $self, $sql, @bind ) = @_;
1439
1440     if ( $self->debug ) {
1441         @bind = $self->_fix_bind_params(@bind);
1442         $self->debugobj->query_end( $sql, @bind );
1443     }
1444 }
1445
1446 sub _dbh_execute {
1447   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1448
1449   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1450
1451   $self->_query_start( $sql, @$bind );
1452
1453   my $sth = $self->sth($sql,$op);
1454
1455   my $placeholder_index = 1;
1456
1457   foreach my $bound (@$bind) {
1458     my $attributes = {};
1459     my($column_name, @data) = @$bound;
1460
1461     if ($bind_attributes) {
1462       $attributes = $bind_attributes->{$column_name}
1463       if defined $bind_attributes->{$column_name};
1464     }
1465
1466     foreach my $data (@data) {
1467       my $ref = ref $data;
1468       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1469
1470       $sth->bind_param($placeholder_index, $data, $attributes);
1471       $placeholder_index++;
1472     }
1473   }
1474
1475   # Can this fail without throwing an exception anyways???
1476   my $rv = $sth->execute();
1477   $self->throw_exception($sth->errstr) if !$rv;
1478
1479   $self->_query_end( $sql, @$bind );
1480
1481   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1482 }
1483
1484 sub _execute {
1485     my $self = shift;
1486     $self->dbh_do('_dbh_execute', @_);  # retry over disconnects
1487 }
1488
1489 sub _prefetch_insert_auto_nextvals {
1490   my ($self, $source, $to_insert) = @_;
1491
1492   my $upd = {};
1493
1494   foreach my $col ( $source->columns ) {
1495     if ( !defined $to_insert->{$col} ) {
1496       my $col_info = $source->column_info($col);
1497
1498       if ( $col_info->{auto_nextval} ) {
1499         $upd->{$col} = $to_insert->{$col} = $self->_sequence_fetch(
1500           'nextval',
1501           $col_info->{sequence} ||=
1502             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1503         );
1504       }
1505     }
1506   }
1507
1508   return $upd;
1509 }
1510
1511 sub insert {
1512   my $self = shift;
1513   my ($source, $to_insert, $opts) = @_;
1514
1515   my $updated_cols = $self->_prefetch_insert_auto_nextvals (@_);
1516
1517   my $bind_attributes = $self->source_bind_attributes($source);
1518
1519   my ($rv, $sth) = $self->_execute('insert' => [], $source, $bind_attributes, $to_insert, $opts);
1520
1521   if ($opts->{returning}) {
1522     my @ret_cols = @{$opts->{returning}};
1523
1524     my @ret_vals = eval {
1525       local $SIG{__WARN__} = sub {};
1526       my @r = $sth->fetchrow_array;
1527       $sth->finish;
1528       @r;
1529     };
1530
1531     my %ret;
1532     @ret{@ret_cols} = @ret_vals if (@ret_vals);
1533
1534     $updated_cols = {
1535       %$updated_cols,
1536       %ret,
1537     };
1538   }
1539
1540   return $updated_cols;
1541 }
1542
1543 ## Currently it is assumed that all values passed will be "normal", i.e. not
1544 ## scalar refs, or at least, all the same type as the first set, the statement is
1545 ## only prepped once.
1546 sub insert_bulk {
1547   my ($self, $source, $cols, $data) = @_;
1548
1549   my %colvalues;
1550   @colvalues{@$cols} = (0..$#$cols);
1551
1552   for my $i (0..$#$cols) {
1553     my $first_val = $data->[0][$i];
1554     next unless ref $first_val eq 'SCALAR';
1555
1556     $colvalues{ $cols->[$i] } = $first_val;
1557   }
1558
1559   # check for bad data and stringify stringifiable objects
1560   my $bad_slice = sub {
1561     my ($msg, $col_idx, $slice_idx) = @_;
1562     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1563       $msg,
1564       $cols->[$col_idx],
1565       do {
1566         local $Data::Dumper::Maxdepth = 1; # don't dump objects, if any
1567         Data::Dumper::Concise::Dumper({
1568           map { $cols->[$_] => $data->[$slice_idx][$_] } (0 .. $#$cols)
1569         }),
1570       }
1571     );
1572   };
1573
1574   for my $datum_idx (0..$#$data) {
1575     my $datum = $data->[$datum_idx];
1576
1577     for my $col_idx (0..$#$cols) {
1578       my $val            = $datum->[$col_idx];
1579       my $sqla_bind      = $colvalues{ $cols->[$col_idx] };
1580       my $is_literal_sql = (ref $sqla_bind) eq 'SCALAR';
1581
1582       if ($is_literal_sql) {
1583         if (not ref $val) {
1584           $bad_slice->('bind found where literal SQL expected', $col_idx, $datum_idx);
1585         }
1586         elsif ((my $reftype = ref $val) ne 'SCALAR') {
1587           $bad_slice->("$reftype reference found where literal SQL expected",
1588             $col_idx, $datum_idx);
1589         }
1590         elsif ($$val ne $$sqla_bind){
1591           $bad_slice->("inconsistent literal SQL value, expecting: '$$sqla_bind'",
1592             $col_idx, $datum_idx);
1593         }
1594       }
1595       elsif (my $reftype = ref $val) {
1596         require overload;
1597         if (overload::Method($val, '""')) {
1598           $datum->[$col_idx] = "".$val;
1599         }
1600         else {
1601           $bad_slice->("$reftype reference found where bind expected",
1602             $col_idx, $datum_idx);
1603         }
1604       }
1605     }
1606   }
1607
1608   my ($sql, $bind) = $self->_prep_for_execute (
1609     'insert', undef, $source, [\%colvalues]
1610   );
1611   my @bind = @$bind;
1612
1613   my $empty_bind = 1 if (not @bind) &&
1614     (grep { ref $_ eq 'SCALAR' } values %colvalues) == @$cols;
1615
1616   if ((not @bind) && (not $empty_bind)) {
1617     $self->throw_exception(
1618       'Cannot insert_bulk without support for placeholders'
1619     );
1620   }
1621
1622   # neither _execute_array, nor _execute_inserts_with_no_binds are
1623   # atomic (even if _execute _array is a single call). Thus a safety
1624   # scope guard
1625   my $guard = $self->txn_scope_guard;
1626
1627   $self->_query_start( $sql, ['__BULK__'] );
1628   my $sth = $self->sth($sql);
1629   my $rv = do {
1630     if ($empty_bind) {
1631       # bind_param_array doesn't work if there are no binds
1632       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1633     }
1634     else {
1635 #      @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1636       $self->_execute_array( $source, $sth, \@bind, $cols, $data );
1637     }
1638   };
1639
1640   $self->_query_end( $sql, ['__BULK__'] );
1641
1642   $guard->commit;
1643
1644   return (wantarray ? ($rv, $sth, @bind) : $rv);
1645 }
1646
1647 sub _execute_array {
1648   my ($self, $source, $sth, $bind, $cols, $data, @extra) = @_;
1649
1650   ## This must be an arrayref, else nothing works!
1651   my $tuple_status = [];
1652
1653   ## Get the bind_attributes, if any exist
1654   my $bind_attributes = $self->source_bind_attributes($source);
1655
1656   ## Bind the values and execute
1657   my $placeholder_index = 1;
1658
1659   foreach my $bound (@$bind) {
1660
1661     my $attributes = {};
1662     my ($column_name, $data_index) = @$bound;
1663
1664     if( $bind_attributes ) {
1665       $attributes = $bind_attributes->{$column_name}
1666       if defined $bind_attributes->{$column_name};
1667     }
1668
1669     my @data = map { $_->[$data_index] } @$data;
1670
1671     $sth->bind_param_array(
1672       $placeholder_index,
1673       [@data],
1674       (%$attributes ?  $attributes : ()),
1675     );
1676     $placeholder_index++;
1677   }
1678
1679   my $rv = eval {
1680     $self->_dbh_execute_array($sth, $tuple_status, @extra);
1681   };
1682   my $err = $@ || $sth->errstr;
1683
1684 # Statement must finish even if there was an exception.
1685   eval { $sth->finish };
1686   $err = $@ unless $err;
1687
1688   if ($err) {
1689     my $i = 0;
1690     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1691
1692     $self->throw_exception("Unexpected populate error: $err")
1693       if ($i > $#$tuple_status);
1694
1695     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1696       ($tuple_status->[$i][1] || $err),
1697       Data::Dumper::Concise::Dumper({
1698         map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols)
1699       }),
1700     );
1701   }
1702   return $rv;
1703 }
1704
1705 sub _dbh_execute_array {
1706     my ($self, $sth, $tuple_status, @extra) = @_;
1707
1708     return $sth->execute_array({ArrayTupleStatus => $tuple_status});
1709 }
1710
1711 sub _dbh_execute_inserts_with_no_binds {
1712   my ($self, $sth, $count) = @_;
1713
1714   eval {
1715     my $dbh = $self->_get_dbh;
1716     local $dbh->{RaiseError} = 1;
1717     local $dbh->{PrintError} = 0;
1718
1719     $sth->execute foreach 1..$count;
1720   };
1721   my $exception = $@;
1722
1723 # Make sure statement is finished even if there was an exception.
1724   eval { $sth->finish };
1725   $exception = $@ unless $exception;
1726
1727   $self->throw_exception($exception) if $exception;
1728
1729   return $count;
1730 }
1731
1732 sub update {
1733   my ($self, $source, @args) = @_;
1734
1735   my $bind_attrs = $self->source_bind_attributes($source);
1736
1737   return $self->_execute('update' => [], $source, $bind_attrs, @args);
1738 }
1739
1740
1741 sub delete {
1742   my ($self, $source, @args) = @_;
1743
1744   my $bind_attrs = $self->source_bind_attributes($source);
1745
1746   return $self->_execute('delete' => [], $source, $bind_attrs, @args);
1747 }
1748
1749 # We were sent here because the $rs contains a complex search
1750 # which will require a subquery to select the correct rows
1751 # (i.e. joined or limited resultsets, or non-introspectable conditions)
1752 #
1753 # Generating a single PK column subquery is trivial and supported
1754 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1755 # Look at _multipk_update_delete()
1756 sub _subq_update_delete {
1757   my $self = shift;
1758   my ($rs, $op, $values) = @_;
1759
1760   my $rsrc = $rs->result_source;
1761
1762   # quick check if we got a sane rs on our hands
1763   my @pcols = $rsrc->_pri_cols;
1764
1765   my $sel = $rs->_resolved_attrs->{select};
1766   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1767
1768   if (
1769       join ("\x00", map { join '.', $rs->{attrs}{alias}, $_ } sort @pcols)
1770         ne
1771       join ("\x00", sort @$sel )
1772   ) {
1773     $self->throw_exception (
1774       '_subq_update_delete can not be called on resultsets selecting columns other than the primary keys'
1775     );
1776   }
1777
1778   if (@pcols == 1) {
1779     return $self->$op (
1780       $rsrc,
1781       $op eq 'update' ? $values : (),
1782       { $pcols[0] => { -in => $rs->as_query } },
1783     );
1784   }
1785
1786   else {
1787     return $self->_multipk_update_delete (@_);
1788   }
1789 }
1790
1791 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1792 # resultset update/delete involving subqueries. So by default resort
1793 # to simple (and inefficient) delete_all style per-row opearations,
1794 # while allowing specific storages to override this with a faster
1795 # implementation.
1796 #
1797 sub _multipk_update_delete {
1798   return shift->_per_row_update_delete (@_);
1799 }
1800
1801 # This is the default loop used to delete/update rows for multi PK
1802 # resultsets, and used by mysql exclusively (because it can't do anything
1803 # else).
1804 #
1805 # We do not use $row->$op style queries, because resultset update/delete
1806 # is not expected to cascade (this is what delete_all/update_all is for).
1807 #
1808 # There should be no race conditions as the entire operation is rolled
1809 # in a transaction.
1810 #
1811 sub _per_row_update_delete {
1812   my $self = shift;
1813   my ($rs, $op, $values) = @_;
1814
1815   my $rsrc = $rs->result_source;
1816   my @pcols = $rsrc->_pri_cols;
1817
1818   my $guard = $self->txn_scope_guard;
1819
1820   # emulate the return value of $sth->execute for non-selects
1821   my $row_cnt = '0E0';
1822
1823   my $subrs_cur = $rs->cursor;
1824   my @all_pk = $subrs_cur->all;
1825   for my $pks ( @all_pk) {
1826
1827     my $cond;
1828     for my $i (0.. $#pcols) {
1829       $cond->{$pcols[$i]} = $pks->[$i];
1830     }
1831
1832     $self->$op (
1833       $rsrc,
1834       $op eq 'update' ? $values : (),
1835       $cond,
1836     );
1837
1838     $row_cnt++;
1839   }
1840
1841   $guard->commit;
1842
1843   return $row_cnt;
1844 }
1845
1846 sub _select {
1847   my $self = shift;
1848   $self->_execute($self->_select_args(@_));
1849 }
1850
1851 sub _select_args_to_query {
1852   my $self = shift;
1853
1854   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $rs_attrs, $rows, $offset)
1855   #  = $self->_select_args($ident, $select, $cond, $attrs);
1856   my ($op, $bind, $ident, $bind_attrs, @args) =
1857     $self->_select_args(@_);
1858
1859   # my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
1860   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1861   $prepared_bind ||= [];
1862
1863   return wantarray
1864     ? ($sql, $prepared_bind, $bind_attrs)
1865     : \[ "($sql)", @$prepared_bind ]
1866   ;
1867 }
1868
1869 sub _select_args {
1870   my ($self, $ident, $select, $where, $attrs) = @_;
1871
1872   my $sql_maker = $self->sql_maker;
1873   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
1874
1875   $attrs = {
1876     %$attrs,
1877     select => $select,
1878     from => $ident,
1879     where => $where,
1880     $rs_alias && $alias2source->{$rs_alias}
1881       ? ( _rsroot_source_handle => $alias2source->{$rs_alias}->handle )
1882       : ()
1883     ,
1884   };
1885
1886   # calculate bind_attrs before possible $ident mangling
1887   my $bind_attrs = {};
1888   for my $alias (keys %$alias2source) {
1889     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1890     for my $col (keys %$bindtypes) {
1891
1892       my $fqcn = join ('.', $alias, $col);
1893       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1894
1895       # Unqialified column names are nice, but at the same time can be
1896       # rather ambiguous. What we do here is basically go along with
1897       # the loop, adding an unqualified column slot to $bind_attrs,
1898       # alongside the fully qualified name. As soon as we encounter
1899       # another column by that name (which would imply another table)
1900       # we unset the unqualified slot and never add any info to it
1901       # to avoid erroneous type binding. If this happens the users
1902       # only choice will be to fully qualify his column name
1903
1904       if (exists $bind_attrs->{$col}) {
1905         $bind_attrs->{$col} = {};
1906       }
1907       else {
1908         $bind_attrs->{$col} = $bind_attrs->{$fqcn};
1909       }
1910     }
1911   }
1912
1913   # adjust limits
1914   if (
1915     $attrs->{software_limit}
1916       ||
1917     $sql_maker->_default_limit_syntax eq "GenericSubQ"
1918   ) {
1919     $attrs->{software_limit} = 1;
1920   }
1921   else {
1922     $self->throw_exception("rows attribute must be positive if present")
1923       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1924
1925     # MySQL actually recommends this approach.  I cringe.
1926     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1927   }
1928
1929   my @limit;
1930
1931   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
1932   # storage, unless software limit was requested
1933   if (
1934     #limited has_many
1935     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
1936        ||
1937     # grouped prefetch (to satisfy group_by == select)
1938     ( $attrs->{group_by}
1939         &&
1940       @{$attrs->{group_by}}
1941         &&
1942       $attrs->{_prefetch_select}
1943         &&
1944       @{$attrs->{_prefetch_select}}
1945     )
1946   ) {
1947     ($ident, $select, $where, $attrs)
1948       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
1949   }
1950   elsif (! $attrs->{software_limit} ) {
1951     push @limit, $attrs->{rows}, $attrs->{offset};
1952   }
1953
1954   # try to simplify the joinmap further (prune unreferenced type-single joins)
1955   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
1956
1957 ###
1958   # This would be the point to deflate anything found in $where
1959   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1960   # expect a row object. And all we have is a resultsource (it is trivial
1961   # to extract deflator coderefs via $alias2source above).
1962   #
1963   # I don't see a way forward other than changing the way deflators are
1964   # invoked, and that's just bad...
1965 ###
1966
1967   return ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $where, $attrs, @limit);
1968 }
1969
1970 # Returns a counting SELECT for a simple count
1971 # query. Abstracted so that a storage could override
1972 # this to { count => 'firstcol' } or whatever makes
1973 # sense as a performance optimization
1974 sub _count_select {
1975   #my ($self, $source, $rs_attrs) = @_;
1976   return { count => '*' };
1977 }
1978
1979
1980 sub source_bind_attributes {
1981   my ($self, $source) = @_;
1982
1983   my $bind_attributes;
1984   foreach my $column ($source->columns) {
1985
1986     my $data_type = $source->column_info($column)->{data_type} || '';
1987     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1988      if $data_type;
1989   }
1990
1991   return $bind_attributes;
1992 }
1993
1994 =head2 select
1995
1996 =over 4
1997
1998 =item Arguments: $ident, $select, $condition, $attrs
1999
2000 =back
2001
2002 Handle a SQL select statement.
2003
2004 =cut
2005
2006 sub select {
2007   my $self = shift;
2008   my ($ident, $select, $condition, $attrs) = @_;
2009   return $self->cursor_class->new($self, \@_, $attrs);
2010 }
2011
2012 sub select_single {
2013   my $self = shift;
2014   my ($rv, $sth, @bind) = $self->_select(@_);
2015   my @row = $sth->fetchrow_array;
2016   my @nextrow = $sth->fetchrow_array if @row;
2017   if(@row && @nextrow) {
2018     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2019   }
2020   # Need to call finish() to work round broken DBDs
2021   $sth->finish();
2022   return @row;
2023 }
2024
2025 =head2 sth
2026
2027 =over 4
2028
2029 =item Arguments: $sql
2030
2031 =back
2032
2033 Returns a L<DBI> sth (statement handle) for the supplied SQL.
2034
2035 =cut
2036
2037 sub _dbh_sth {
2038   my ($self, $dbh, $sql) = @_;
2039
2040   # 3 is the if_active parameter which avoids active sth re-use
2041   my $sth = $self->disable_sth_caching
2042     ? $dbh->prepare($sql)
2043     : $dbh->prepare_cached($sql, {}, 3);
2044
2045   # XXX You would think RaiseError would make this impossible,
2046   #  but apparently that's not true :(
2047   $self->throw_exception($dbh->errstr) if !$sth;
2048
2049   $sth;
2050 }
2051
2052 sub sth {
2053   my ($self, $sql) = @_;
2054   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2055 }
2056
2057 sub _dbh_columns_info_for {
2058   my ($self, $dbh, $table) = @_;
2059
2060   if ($dbh->can('column_info')) {
2061     my %result;
2062     eval {
2063       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2064       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2065       $sth->execute();
2066       while ( my $info = $sth->fetchrow_hashref() ){
2067         my %column_info;
2068         $column_info{data_type}   = $info->{TYPE_NAME};
2069         $column_info{size}      = $info->{COLUMN_SIZE};
2070         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2071         $column_info{default_value} = $info->{COLUMN_DEF};
2072         my $col_name = $info->{COLUMN_NAME};
2073         $col_name =~ s/^\"(.*)\"$/$1/;
2074
2075         $result{$col_name} = \%column_info;
2076       }
2077     };
2078     return \%result if !$@ && scalar keys %result;
2079   }
2080
2081   my %result;
2082   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2083   $sth->execute;
2084   my @columns = @{$sth->{NAME_lc}};
2085   for my $i ( 0 .. $#columns ){
2086     my %column_info;
2087     $column_info{data_type} = $sth->{TYPE}->[$i];
2088     $column_info{size} = $sth->{PRECISION}->[$i];
2089     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2090
2091     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2092       $column_info{data_type} = $1;
2093       $column_info{size}    = $2;
2094     }
2095
2096     $result{$columns[$i]} = \%column_info;
2097   }
2098   $sth->finish;
2099
2100   foreach my $col (keys %result) {
2101     my $colinfo = $result{$col};
2102     my $type_num = $colinfo->{data_type};
2103     my $type_name;
2104     if(defined $type_num && $dbh->can('type_info')) {
2105       my $type_info = $dbh->type_info($type_num);
2106       $type_name = $type_info->{TYPE_NAME} if $type_info;
2107       $colinfo->{data_type} = $type_name if $type_name;
2108     }
2109   }
2110
2111   return \%result;
2112 }
2113
2114 sub columns_info_for {
2115   my ($self, $table) = @_;
2116   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2117 }
2118
2119 =head2 last_insert_id
2120
2121 Return the row id of the last insert.
2122
2123 =cut
2124
2125 sub _dbh_last_insert_id {
2126     my ($self, $dbh, $source, $col) = @_;
2127
2128     my $id = eval { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2129
2130     return $id if defined $id;
2131
2132     my $class = ref $self;
2133     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2134 }
2135
2136 sub last_insert_id {
2137   my $self = shift;
2138   $self->_dbh_last_insert_id ($self->_dbh, @_);
2139 }
2140
2141 =head2 _native_data_type
2142
2143 =over 4
2144
2145 =item Arguments: $type_name
2146
2147 =back
2148
2149 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2150 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2151 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2152
2153 The default implementation returns C<undef>, implement in your Storage driver if
2154 you need this functionality.
2155
2156 Should map types from other databases to the native RDBMS type, for example
2157 C<VARCHAR2> to C<VARCHAR>.
2158
2159 Types with modifiers should map to the underlying data type. For example,
2160 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2161
2162 Composite types should map to the container type, for example
2163 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2164
2165 =cut
2166
2167 sub _native_data_type {
2168   #my ($self, $data_type) = @_;
2169   return undef
2170 }
2171
2172 # Check if placeholders are supported at all
2173 sub _placeholders_supported {
2174   my $self = shift;
2175   my $dbh  = $self->_get_dbh;
2176
2177   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2178   # but it is inaccurate more often than not
2179   eval {
2180     local $dbh->{PrintError} = 0;
2181     local $dbh->{RaiseError} = 1;
2182     $dbh->do('select ?', {}, 1);
2183   };
2184   return $@ ? 0 : 1;
2185 }
2186
2187 # Check if placeholders bound to non-string types throw exceptions
2188 #
2189 sub _typeless_placeholders_supported {
2190   my $self = shift;
2191   my $dbh  = $self->_get_dbh;
2192
2193   eval {
2194     local $dbh->{PrintError} = 0;
2195     local $dbh->{RaiseError} = 1;
2196     # this specifically tests a bind that is NOT a string
2197     $dbh->do('select 1 where 1 = ?', {}, 1);
2198   };
2199   return $@ ? 0 : 1;
2200 }
2201
2202 =head2 sqlt_type
2203
2204 Returns the database driver name.
2205
2206 =cut
2207
2208 sub sqlt_type {
2209   shift->_get_dbh->{Driver}->{Name};
2210 }
2211
2212 =head2 bind_attribute_by_data_type
2213
2214 Given a datatype from column info, returns a database specific bind
2215 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2216 let the database planner just handle it.
2217
2218 Generally only needed for special case column types, like bytea in postgres.
2219
2220 =cut
2221
2222 sub bind_attribute_by_data_type {
2223     return;
2224 }
2225
2226 =head2 is_datatype_numeric
2227
2228 Given a datatype from column_info, returns a boolean value indicating if
2229 the current RDBMS considers it a numeric value. This controls how
2230 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2231 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2232 be performed instead of the usual C<eq>.
2233
2234 =cut
2235
2236 sub is_datatype_numeric {
2237   my ($self, $dt) = @_;
2238
2239   return 0 unless $dt;
2240
2241   return $dt =~ /^ (?:
2242     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2243   ) $/ix;
2244 }
2245
2246
2247 =head2 create_ddl_dir
2248
2249 =over 4
2250
2251 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2252
2253 =back
2254
2255 Creates a SQL file based on the Schema, for each of the specified
2256 database engines in C<\@databases> in the given directory.
2257 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2258
2259 Given a previous version number, this will also create a file containing
2260 the ALTER TABLE statements to transform the previous schema into the
2261 current one. Note that these statements may contain C<DROP TABLE> or
2262 C<DROP COLUMN> statements that can potentially destroy data.
2263
2264 The file names are created using the C<ddl_filename> method below, please
2265 override this method in your schema if you would like a different file
2266 name format. For the ALTER file, the same format is used, replacing
2267 $version in the name with "$preversion-$version".
2268
2269 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2270 The most common value for this would be C<< { add_drop_table => 1 } >>
2271 to have the SQL produced include a C<DROP TABLE> statement for each table
2272 created. For quoting purposes supply C<quote_table_names> and
2273 C<quote_field_names>.
2274
2275 If no arguments are passed, then the following default values are assumed:
2276
2277 =over 4
2278
2279 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2280
2281 =item version    - $schema->schema_version
2282
2283 =item directory  - './'
2284
2285 =item preversion - <none>
2286
2287 =back
2288
2289 By default, C<\%sqlt_args> will have
2290
2291  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2292
2293 merged with the hash passed in. To disable any of those features, pass in a
2294 hashref like the following
2295
2296  { ignore_constraint_names => 0, # ... other options }
2297
2298
2299 WARNING: You are strongly advised to check all SQL files created, before applying
2300 them.
2301
2302 =cut
2303
2304 sub create_ddl_dir {
2305   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2306
2307   unless ($dir) {
2308     carp "No directory given, using ./\n";
2309     $dir = './';
2310   } else {
2311       -d $dir or File::Path::mkpath($dir)
2312           or $self->throw_exception("create_ddl_dir: $! creating dir '$dir'");
2313   }
2314
2315   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2316
2317   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2318   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2319
2320   my $schema_version = $schema->schema_version || '1.x';
2321   $version ||= $schema_version;
2322
2323   $sqltargs = {
2324     add_drop_table => 1,
2325     ignore_constraint_names => 1,
2326     ignore_index_names => 1,
2327     %{$sqltargs || {}}
2328   };
2329
2330   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2331     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2332   }
2333
2334   my $sqlt = SQL::Translator->new( $sqltargs );
2335
2336   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2337   my $sqlt_schema = $sqlt->translate({ data => $schema })
2338     or $self->throw_exception ($sqlt->error);
2339
2340   foreach my $db (@$databases) {
2341     $sqlt->reset();
2342     $sqlt->{schema} = $sqlt_schema;
2343     $sqlt->producer($db);
2344
2345     my $file;
2346     my $filename = $schema->ddl_filename($db, $version, $dir);
2347     if (-e $filename && ($version eq $schema_version )) {
2348       # if we are dumping the current version, overwrite the DDL
2349       carp "Overwriting existing DDL file - $filename";
2350       unlink($filename);
2351     }
2352
2353     my $output = $sqlt->translate;
2354     if(!$output) {
2355       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2356       next;
2357     }
2358     if(!open($file, ">$filename")) {
2359       $self->throw_exception("Can't open $filename for writing ($!)");
2360       next;
2361     }
2362     print $file $output;
2363     close($file);
2364
2365     next unless ($preversion);
2366
2367     require SQL::Translator::Diff;
2368
2369     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2370     if(!-e $prefilename) {
2371       carp("No previous schema file found ($prefilename)");
2372       next;
2373     }
2374
2375     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2376     if(-e $difffile) {
2377       carp("Overwriting existing diff file - $difffile");
2378       unlink($difffile);
2379     }
2380
2381     my $source_schema;
2382     {
2383       my $t = SQL::Translator->new($sqltargs);
2384       $t->debug( 0 );
2385       $t->trace( 0 );
2386
2387       $t->parser( $db )
2388         or $self->throw_exception ($t->error);
2389
2390       my $out = $t->translate( $prefilename )
2391         or $self->throw_exception ($t->error);
2392
2393       $source_schema = $t->schema;
2394
2395       $source_schema->name( $prefilename )
2396         unless ( $source_schema->name );
2397     }
2398
2399     # The "new" style of producers have sane normalization and can support
2400     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2401     # And we have to diff parsed SQL against parsed SQL.
2402     my $dest_schema = $sqlt_schema;
2403
2404     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2405       my $t = SQL::Translator->new($sqltargs);
2406       $t->debug( 0 );
2407       $t->trace( 0 );
2408
2409       $t->parser( $db )
2410         or $self->throw_exception ($t->error);
2411
2412       my $out = $t->translate( $filename )
2413         or $self->throw_exception ($t->error);
2414
2415       $dest_schema = $t->schema;
2416
2417       $dest_schema->name( $filename )
2418         unless $dest_schema->name;
2419     }
2420
2421     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2422                                                   $dest_schema,   $db,
2423                                                   $sqltargs
2424                                                  );
2425     if(!open $file, ">$difffile") {
2426       $self->throw_exception("Can't write to $difffile ($!)");
2427       next;
2428     }
2429     print $file $diff;
2430     close($file);
2431   }
2432 }
2433
2434 =head2 deployment_statements
2435
2436 =over 4
2437
2438 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2439
2440 =back
2441
2442 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2443
2444 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2445 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2446
2447 C<$directory> is used to return statements from files in a previously created
2448 L</create_ddl_dir> directory and is optional. The filenames are constructed
2449 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2450
2451 If no C<$directory> is specified then the statements are constructed on the
2452 fly using L<SQL::Translator> and C<$version> is ignored.
2453
2454 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2455
2456 =cut
2457
2458 sub deployment_statements {
2459   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2460   $type ||= $self->sqlt_type;
2461   $version ||= $schema->schema_version || '1.x';
2462   $dir ||= './';
2463   my $filename = $schema->ddl_filename($type, $version, $dir);
2464   if(-f $filename)
2465   {
2466       my $file;
2467       open($file, "<$filename")
2468         or $self->throw_exception("Can't open $filename ($!)");
2469       my @rows = <$file>;
2470       close($file);
2471       return join('', @rows);
2472   }
2473
2474   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2475     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2476   }
2477
2478   # sources needs to be a parser arg, but for simplicty allow at top level
2479   # coming in
2480   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2481       if exists $sqltargs->{sources};
2482
2483   my $tr = SQL::Translator->new(
2484     producer => "SQL::Translator::Producer::${type}",
2485     %$sqltargs,
2486     parser => 'SQL::Translator::Parser::DBIx::Class',
2487     data => $schema,
2488   );
2489
2490   my @ret;
2491   my $wa = wantarray;
2492   if ($wa) {
2493     @ret = $tr->translate;
2494   }
2495   else {
2496     $ret[0] = $tr->translate;
2497   }
2498
2499   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2500     unless (@ret && defined $ret[0]);
2501
2502   return $wa ? @ret : $ret[0];
2503 }
2504
2505 sub deploy {
2506   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2507   my $deploy = sub {
2508     my $line = shift;
2509     return if($line =~ /^--/);
2510     return if(!$line);
2511     # next if($line =~ /^DROP/m);
2512     return if($line =~ /^BEGIN TRANSACTION/m);
2513     return if($line =~ /^COMMIT/m);
2514     return if $line =~ /^\s+$/; # skip whitespace only
2515     $self->_query_start($line);
2516     eval {
2517       # do a dbh_do cycle here, as we need some error checking in
2518       # place (even though we will ignore errors)
2519       $self->dbh_do (sub { $_[1]->do($line) });
2520     };
2521     if ($@) {
2522       carp qq{$@ (running "${line}")};
2523     }
2524     $self->_query_end($line);
2525   };
2526   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2527   if (@statements > 1) {
2528     foreach my $statement (@statements) {
2529       $deploy->( $statement );
2530     }
2531   }
2532   elsif (@statements == 1) {
2533     foreach my $line ( split(";\n", $statements[0])) {
2534       $deploy->( $line );
2535     }
2536   }
2537 }
2538
2539 =head2 datetime_parser
2540
2541 Returns the datetime parser class
2542
2543 =cut
2544
2545 sub datetime_parser {
2546   my $self = shift;
2547   return $self->{datetime_parser} ||= do {
2548     $self->build_datetime_parser(@_);
2549   };
2550 }
2551
2552 =head2 datetime_parser_type
2553
2554 Defines (returns) the datetime parser class - currently hardwired to
2555 L<DateTime::Format::MySQL>
2556
2557 =cut
2558
2559 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2560
2561 =head2 build_datetime_parser
2562
2563 See L</datetime_parser>
2564
2565 =cut
2566
2567 sub build_datetime_parser {
2568   my $self = shift;
2569   my $type = $self->datetime_parser_type(@_);
2570   $self->ensure_class_loaded ($type);
2571   return $type;
2572 }
2573
2574
2575 =head2 is_replicating
2576
2577 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2578 replicate from a master database.  Default is undef, which is the result
2579 returned by databases that don't support replication.
2580
2581 =cut
2582
2583 sub is_replicating {
2584     return;
2585
2586 }
2587
2588 =head2 lag_behind_master
2589
2590 Returns a number that represents a certain amount of lag behind a master db
2591 when a given storage is replicating.  The number is database dependent, but
2592 starts at zero and increases with the amount of lag. Default in undef
2593
2594 =cut
2595
2596 sub lag_behind_master {
2597     return;
2598 }
2599
2600 =head2 relname_to_table_alias
2601
2602 =over 4
2603
2604 =item Arguments: $relname, $join_count
2605
2606 =back
2607
2608 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2609 queries.
2610
2611 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2612 way these aliases are named.
2613
2614 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2615 otherwise C<"$relname">.
2616
2617 =cut
2618
2619 sub relname_to_table_alias {
2620   my ($self, $relname, $join_count) = @_;
2621
2622   my $alias = ($join_count && $join_count > 1 ?
2623     join('_', $relname, $join_count) : $relname);
2624
2625   return $alias;
2626 }
2627
2628 1;
2629
2630 =head1 USAGE NOTES
2631
2632 =head2 DBIx::Class and AutoCommit
2633
2634 DBIx::Class can do some wonderful magic with handling exceptions,
2635 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2636 (the default) combined with C<txn_do> for transaction support.
2637
2638 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2639 in an assumed transaction between commits, and you're telling us you'd
2640 like to manage that manually.  A lot of the magic protections offered by
2641 this module will go away.  We can't protect you from exceptions due to database
2642 disconnects because we don't know anything about how to restart your
2643 transactions.  You're on your own for handling all sorts of exceptional
2644 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2645 be with raw DBI.
2646
2647
2648 =head1 AUTHORS
2649
2650 Matt S. Trout <mst@shadowcatsystems.co.uk>
2651
2652 Andy Grundman <andy@hybridized.org>
2653
2654 =head1 LICENSE
2655
2656 You may distribute this code under the same terms as Perl itself.
2657
2658 =cut