lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Context::Preserve 'preserve_context';
  16 use Try::Tiny;
  17 use overload ();
  18 use Data::Compare (); # no imports!!! guard against insane architecture
  19 use DBI::Const::GetInfoType (); # no import of retarded global hash
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. This is a purely DRY optimization
  85 #
  86 # get_(use)_dbms_capability need to be called on the correct Storage
  87 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  88 # _determine_supports_X which obv. needs a correct driver as well
  89 my @rdbms_specific_methods = qw/
  90   deployment_statements
  91   sqlt_type
  92   sql_maker
  93   build_datetime_parser
  94   datetime_parser_type
  95
  96   txn_begin
  97   insert
  98   insert_bulk
  99   update
 100   delete
 101   select
 102   select_single
 103   with_deferred_fk_checks
 104
 105   get_use_dbms_capability
 106   get_dbms_capability
 107
 108   _server_info
 109   _get_server_version
 110 /;
 111
 112 for my $meth (@rdbms_specific_methods) {
 113
 114   my $orig = __PACKAGE__->can ($meth)
 115     or die "$meth is not a ::Storage::DBI method!";
 116
 117   no strict qw/refs/;
 118   no warnings qw/redefine/;
 119   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 120     if (
 121       # only fire when invoked on an instance, a valid class-based invocation
 122       # would e.g. be setting a default for an inherited accessor
 123       ref $_[0]
 124         and
 125       ! $_[0]->_driver_determined
 126         and
 127       ! $_[0]->{_in_determine_driver}
 128     ) {
 129       $_[0]->_determine_driver;
 130
 131       # This for some reason crashes and burns on perl 5.8.1
 132       # IFF the method ends up throwing an exception
 133       #goto $_[0]->can ($meth);
 134
 135       my $cref = $_[0]->can ($meth);
 136       goto $cref;
 137     }
 138
 139     goto $orig;
 140   };
 141 }
 142
 143 =head1 NAME
 144
 145 DBIx::Class::Storage::DBI - DBI storage handler
 146
 147 =head1 SYNOPSIS
 148
 149   my $schema = MySchema->connect('dbi:SQLite:my.db');
 150
 151   $schema->storage->debug(1);
 152
 153   my @stuff = $schema->storage->dbh_do(
 154     sub {
 155       my ($storage, $dbh, @args) = @_;
 156       $dbh->do("DROP TABLE authors");
 157     },
 158     @column_list
 159   );
 160
 161   $schema->resultset('Book')->search({
 162      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 163   });
 164
 165 =head1 DESCRIPTION
 166
 167 This class represents the connection to an RDBMS via L<DBI>.  See
 168 L<DBIx::Class::Storage> for general information.  This pod only
 169 documents DBI-specific methods and behaviors.
 170
 171 =head1 METHODS
 172
 173 =cut
 174
 175 sub new {
 176   my $new = shift->next::method(@_);
 177
 178   $new->_sql_maker_opts({});
 179   $new->_dbh_details({});
 180   $new->{_in_do_block} = 0;
 181   $new->{_dbh_gen} = 0;
 182
 183   # read below to see what this does
 184   $new->_arm_global_destructor;
 185
 186   $new;
 187 }
 188
 189 # This is hack to work around perl shooting stuff in random
 190 # order on exit(). If we do not walk the remaining storage
 191 # objects in an END block, there is a *small but real* chance
 192 # of a fork()ed child to kill the parent's shared DBI handle,
 193 # *before perl reaches the DESTROY in this package*
 194 # Yes, it is ugly and effective.
 195 # Additionally this registry is used by the CLONE method to
 196 # make sure no handles are shared between threads
 197 {
 198   my %seek_and_destroy;
 199
 200   sub _arm_global_destructor {
 201     weaken (
 202       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 203     );
 204   }
 205
 206   END {
 207     local $?; # just in case the DBI destructor changes it somehow
 208
 209     # destroy just the object if not native to this process
 210     $_->_verify_pid for (grep
 211       { defined $_ }
 212       values %seek_and_destroy
 213     );
 214   }
 215
 216   sub CLONE {
 217     # As per DBI's recommendation, DBIC disconnects all handles as
 218     # soon as possible (DBIC will reconnect only on demand from within
 219     # the thread)
 220     my @instances = grep { defined $_ } values %seek_and_destroy;
 221     for (@instances) {
 222       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 223       $_->_dbh(undef);
 224
 225       $_->transaction_depth(0);
 226       $_->savepoints([]);
 227     }
 228
 229     # properly renumber all existing refs
 230     %seek_and_destroy = ();
 231     $_->_arm_global_destructor for @instances;
 232   }
 233 }
 234
 235 sub DESTROY {
 236   my $self = shift;
 237
 238   # some databases spew warnings on implicit disconnect
 239   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 240   local $SIG{__WARN__} = sub {};
 241   $self->_dbh(undef);
 242
 243   # this op is necessary, since the very last perl runtime statement
 244   # triggers a global destruction shootout, and the $SIG localization
 245   # may very well be destroyed before perl actually gets to do the
 246   # $dbh undef
 247   1;
 248 }
 249
 250 # handle pid changes correctly - do not destroy parent's connection
 251 sub _verify_pid {
 252   my $self = shift;
 253
 254   my $pid = $self->_conn_pid;
 255   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 256     $dbh->{InactiveDestroy} = 1;
 257     $self->{_dbh_gen}++;
 258     $self->_dbh(undef);
 259     $self->transaction_depth(0);
 260     $self->savepoints([]);
 261   }
 262
 263   return;
 264 }
 265
 266 =head2 connect_info
 267
 268 This method is normally called by L<DBIx::Class::Schema/connection>, which
 269 encapsulates its argument list in an arrayref before passing them here.
 270
 271 The argument list may contain:
 272
 273 =over
 274
 275 =item *
 276
 277 The same 4-element argument set one would normally pass to
 278 L<DBI/connect>, optionally followed by
 279 L<extra attributes|/DBIx::Class specific connection attributes>
 280 recognized by DBIx::Class:
 281
 282   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 283
 284 =item *
 285
 286 A single code reference which returns a connected
 287 L<DBI database handle|DBI/connect> optionally followed by
 288 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 289 by DBIx::Class:
 290
 291   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 292
 293 =item *
 294
 295 A single hashref with all the attributes and the dsn/user/password
 296 mixed together:
 297
 298   $connect_info_args = [{
 299     dsn => $dsn,
 300     user => $user,
 301     password => $pass,
 302     %dbi_attributes,
 303     %extra_attributes,
 304   }];
 305
 306   $connect_info_args = [{
 307     dbh_maker => sub { DBI->connect (...) },
 308     %dbi_attributes,
 309     %extra_attributes,
 310   }];
 311
 312 This is particularly useful for L<Catalyst> based applications, allowing the
 313 following config (L<Config::General> style):
 314
 315   <Model::DB>
 316     schema_class   App::DB
 317     <connect_info>
 318       dsn          dbi:mysql:database=test
 319       user         testuser
 320       password     TestPass
 321       AutoCommit   1
 322     </connect_info>
 323   </Model::DB>
 324
 325 The C<dsn>/C<user>/C<password> combination can be substituted by the
 326 C<dbh_maker> key whose value is a coderef that returns a connected
 327 L<DBI database handle|DBI/connect>
 328
 329 =back
 330
 331 Please note that the L<DBI> docs recommend that you always explicitly
 332 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 333 recommends that it be set to I<1>, and that you perform transactions
 334 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 335 to I<1> if you do not do explicitly set it to zero.  This is the default
 336 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 337
 338 =head3 DBIx::Class specific connection attributes
 339
 340 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 341 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 342 the following connection options. These options can be mixed in with your other
 343 L<DBI> connection attributes, or placed in a separate hashref
 344 (C<\%extra_attributes>) as shown above.
 345
 346 Every time C<connect_info> is invoked, any previous settings for
 347 these options will be cleared before setting the new ones, regardless of
 348 whether any options are specified in the new C<connect_info>.
 349
 350
 351 =over
 352
 353 =item on_connect_do
 354
 355 Specifies things to do immediately after connecting or re-connecting to
 356 the database.  Its value may contain:
 357
 358 =over
 359
 360 =item a scalar
 361
 362 This contains one SQL statement to execute.
 363
 364 =item an array reference
 365
 366 This contains SQL statements to execute in order.  Each element contains
 367 a string or a code reference that returns a string.
 368
 369 =item a code reference
 370
 371 This contains some code to execute.  Unlike code references within an
 372 array reference, its return value is ignored.
 373
 374 =back
 375
 376 =item on_disconnect_do
 377
 378 Takes arguments in the same form as L</on_connect_do> and executes them
 379 immediately before disconnecting from the database.
 380
 381 Note, this only runs if you explicitly call L</disconnect> on the
 382 storage object.
 383
 384 =item on_connect_call
 385
 386 A more generalized form of L</on_connect_do> that calls the specified
 387 C<connect_call_METHOD> methods in your storage driver.
 388
 389   on_connect_do => 'select 1'
 390
 391 is equivalent to:
 392
 393   on_connect_call => [ [ do_sql => 'select 1' ] ]
 394
 395 Its values may contain:
 396
 397 =over
 398
 399 =item a scalar
 400
 401 Will call the C<connect_call_METHOD> method.
 402
 403 =item a code reference
 404
 405 Will execute C<< $code->($storage) >>
 406
 407 =item an array reference
 408
 409 Each value can be a method name or code reference.
 410
 411 =item an array of arrays
 412
 413 For each array, the first item is taken to be the C<connect_call_> method name
 414 or code reference, and the rest are parameters to it.
 415
 416 =back
 417
 418 Some predefined storage methods you may use:
 419
 420 =over
 421
 422 =item do_sql
 423
 424 Executes a SQL string or a code reference that returns a SQL string. This is
 425 what L</on_connect_do> and L</on_disconnect_do> use.
 426
 427 It can take:
 428
 429 =over
 430
 431 =item a scalar
 432
 433 Will execute the scalar as SQL.
 434
 435 =item an arrayref
 436
 437 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 438 attributes hashref and bind values.
 439
 440 =item a code reference
 441
 442 Will execute C<< $code->($storage) >> and execute the return array refs as
 443 above.
 444
 445 =back
 446
 447 =item datetime_setup
 448
 449 Execute any statements necessary to initialize the database session to return
 450 and accept datetime/timestamp values used with
 451 L<DBIx::Class::InflateColumn::DateTime>.
 452
 453 Only necessary for some databases, see your specific storage driver for
 454 implementation details.
 455
 456 =back
 457
 458 =item on_disconnect_call
 459
 460 Takes arguments in the same form as L</on_connect_call> and executes them
 461 immediately before disconnecting from the database.
 462
 463 Calls the C<disconnect_call_METHOD> methods as opposed to the
 464 C<connect_call_METHOD> methods called by L</on_connect_call>.
 465
 466 Note, this only runs if you explicitly call L</disconnect> on the
 467 storage object.
 468
 469 =item disable_sth_caching
 470
 471 If set to a true value, this option will disable the caching of
 472 statement handles via L<DBI/prepare_cached>.
 473
 474 =item limit_dialect
 475
 476 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 477 default L</sql_limit_dialect> setting of the storage (if any). For a list
 478 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 479
 480 =item quote_names
 481
 482 When true automatically sets L</quote_char> and L</name_sep> to the characters
 483 appropriate for your particular RDBMS. This option is preferred over specifying
 484 L</quote_char> directly.
 485
 486 =item quote_char
 487
 488 Specifies what characters to use to quote table and column names.
 489
 490 C<quote_char> expects either a single character, in which case is it
 491 is placed on either side of the table/column name, or an arrayref of length
 492 2 in which case the table/column name is placed between the elements.
 493
 494 For example under MySQL you should use C<< quote_char => '`' >>, and for
 495 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 496
 497 =item name_sep
 498
 499 This parameter is only useful in conjunction with C<quote_char>, and is used to
 500 specify the character that separates elements (schemas, tables, columns) from
 501 each other. If unspecified it defaults to the most commonly used C<.>.
 502
 503 =item unsafe
 504
 505 This Storage driver normally installs its own C<HandleError>, sets
 506 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 507 all database handles, including those supplied by a coderef.  It does this
 508 so that it can have consistent and useful error behavior.
 509
 510 If you set this option to a true value, Storage will not do its usual
 511 modifications to the database handle's attributes, and instead relies on
 512 the settings in your connect_info DBI options (or the values you set in
 513 your connection coderef, in the case that you are connecting via coderef).
 514
 515 Note that your custom settings can cause Storage to malfunction,
 516 especially if you set a C<HandleError> handler that suppresses exceptions
 517 and/or disable C<RaiseError>.
 518
 519 =item auto_savepoint
 520
 521 If this option is true, L<DBIx::Class> will use savepoints when nesting
 522 transactions, making it possible to recover from failure in the inner
 523 transaction without having to abort all outer transactions.
 524
 525 =item cursor_class
 526
 527 Use this argument to supply a cursor class other than the default
 528 L<DBIx::Class::Storage::DBI::Cursor>.
 529
 530 =back
 531
 532 Some real-life examples of arguments to L</connect_info> and
 533 L<DBIx::Class::Schema/connect>
 534
 535   # Simple SQLite connection
 536   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 537
 538   # Connect via subref
 539   ->connect_info([ sub { DBI->connect(...) } ]);
 540
 541   # Connect via subref in hashref
 542   ->connect_info([{
 543     dbh_maker => sub { DBI->connect(...) },
 544     on_connect_do => 'alter session ...',
 545   }]);
 546
 547   # A bit more complicated
 548   ->connect_info(
 549     [
 550       'dbi:Pg:dbname=foo',
 551       'postgres',
 552       'my_pg_password',
 553       { AutoCommit => 1 },
 554       { quote_char => q{"} },
 555     ]
 556   );
 557
 558   # Equivalent to the previous example
 559   ->connect_info(
 560     [
 561       'dbi:Pg:dbname=foo',
 562       'postgres',
 563       'my_pg_password',
 564       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 565     ]
 566   );
 567
 568   # Same, but with hashref as argument
 569   # See parse_connect_info for explanation
 570   ->connect_info(
 571     [{
 572       dsn         => 'dbi:Pg:dbname=foo',
 573       user        => 'postgres',
 574       password    => 'my_pg_password',
 575       AutoCommit  => 1,
 576       quote_char  => q{"},
 577       name_sep    => q{.},
 578     }]
 579   );
 580
 581   # Subref + DBIx::Class-specific connection options
 582   ->connect_info(
 583     [
 584       sub { DBI->connect(...) },
 585       {
 586           quote_char => q{`},
 587           name_sep => q{@},
 588           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 589           disable_sth_caching => 1,
 590       },
 591     ]
 592   );
 593
 594
 595
 596 =cut
 597
 598 sub connect_info {
 599   my ($self, $info) = @_;
 600
 601   return $self->_connect_info if !$info;
 602
 603   $self->_connect_info($info); # copy for _connect_info
 604
 605   $info = $self->_normalize_connect_info($info)
 606     if ref $info eq 'ARRAY';
 607
 608   for my $storage_opt (keys %{ $info->{storage_options} }) {
 609     my $value = $info->{storage_options}{$storage_opt};
 610
 611     $self->$storage_opt($value);
 612   }
 613
 614   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 615   #  the new set of options
 616   $self->_sql_maker(undef);
 617   $self->_sql_maker_opts({});
 618
 619   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 620     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 621
 622     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 623   }
 624
 625   my %attrs = (
 626     %{ $self->_default_dbi_connect_attributes || {} },
 627     %{ $info->{attributes} || {} },
 628   );
 629
 630   my @args = @{ $info->{arguments} };
 631
 632   if (keys %attrs and ref $args[0] ne 'CODE') {
 633     carp
 634         'You provided explicit AutoCommit => 0 in your connection_info. '
 635       . 'This is almost universally a bad idea (see the footnotes of '
 636       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 637       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 638       . 'this warning.'
 639       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 640
 641     push @args, \%attrs if keys %attrs;
 642   }
 643   $self->_dbi_connect_info(\@args);
 644
 645   # FIXME - dirty:
 646   # save attributes them in a separate accessor so they are always
 647   # introspectable, even in case of a CODE $dbhmaker
 648   $self->_dbic_connect_attributes (\%attrs);
 649
 650   return $self->_connect_info;
 651 }
 652
 653 sub _normalize_connect_info {
 654   my ($self, $info_arg) = @_;
 655   my %info;
 656
 657   my @args = @$info_arg;  # take a shallow copy for further mutilation
 658
 659   # combine/pre-parse arguments depending on invocation style
 660
 661   my %attrs;
 662   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 663     %attrs = %{ $args[1] || {} };
 664     @args = $args[0];
 665   }
 666   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 667     %attrs = %{$args[0]};
 668     @args = ();
 669     if (my $code = delete $attrs{dbh_maker}) {
 670       @args = $code;
 671
 672       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 673       if (@ignored) {
 674         carp sprintf (
 675             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 676           . "to the result of 'dbh_maker'",
 677
 678           join (', ', map { "'$_'" } (@ignored) ),
 679         );
 680       }
 681     }
 682     else {
 683       @args = delete @attrs{qw/dsn user password/};
 684     }
 685   }
 686   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 687     %attrs = (
 688       % { $args[3] || {} },
 689       % { $args[4] || {} },
 690     );
 691     @args = @args[0,1,2];
 692   }
 693
 694   $info{arguments} = \@args;
 695
 696   my @storage_opts = grep exists $attrs{$_},
 697     @storage_options, 'cursor_class';
 698
 699   @{ $info{storage_options} }{@storage_opts} =
 700     delete @attrs{@storage_opts} if @storage_opts;
 701
 702   my @sql_maker_opts = grep exists $attrs{$_},
 703     qw/limit_dialect quote_char name_sep quote_names/;
 704
 705   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 706     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 707
 708   $info{attributes} = \%attrs if %attrs;
 709
 710   return \%info;
 711 }
 712
 713 sub _default_dbi_connect_attributes () {
 714   +{
 715     AutoCommit => 1,
 716     PrintError => 0,
 717     RaiseError => 1,
 718     ShowErrorStatement => 1,
 719   };
 720 }
 721
 722 =head2 on_connect_do
 723
 724 This method is deprecated in favour of setting via L</connect_info>.
 725
 726 =cut
 727
 728 =head2 on_disconnect_do
 729
 730 This method is deprecated in favour of setting via L</connect_info>.
 731
 732 =cut
 733
 734 sub _parse_connect_do {
 735   my ($self, $type) = @_;
 736
 737   my $val = $self->$type;
 738   return () if not defined $val;
 739
 740   my @res;
 741
 742   if (not ref($val)) {
 743     push @res, [ 'do_sql', $val ];
 744   } elsif (ref($val) eq 'CODE') {
 745     push @res, $val;
 746   } elsif (ref($val) eq 'ARRAY') {
 747     push @res, map { [ 'do_sql', $_ ] } @$val;
 748   } else {
 749     $self->throw_exception("Invalid type for $type: ".ref($val));
 750   }
 751
 752   return \@res;
 753 }
 754
 755 =head2 dbh_do
 756
 757 Arguments: ($subref | $method_name), @extra_coderef_args?
 758
 759 Execute the given $subref or $method_name using the new exception-based
 760 connection management.
 761
 762 The first two arguments will be the storage object that C<dbh_do> was called
 763 on and a database handle to use.  Any additional arguments will be passed
 764 verbatim to the called subref as arguments 2 and onwards.
 765
 766 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 767 exception handling and reconnection (or failover in future subclasses).
 768
 769 Your subref should have no side-effects outside of the database, as
 770 there is the potential for your subref to be partially double-executed
 771 if the database connection was stale/dysfunctional.
 772
 773 Example:
 774
 775   my @stuff = $schema->storage->dbh_do(
 776     sub {
 777       my ($storage, $dbh, @cols) = @_;
 778       my $cols = join(q{, }, @cols);
 779       $dbh->selectrow_array("SELECT $cols FROM foo");
 780     },
 781     @column_list
 782   );
 783
 784 =cut
 785
 786 sub dbh_do {
 787   my $self = shift;
 788   my $run_target = shift;
 789
 790   # short circuit when we know there is no need for a runner
 791   #
 792   # FIXME - asumption may be wrong
 793   # the rationale for the txn_depth check is that if this block is a part
 794   # of a larger transaction, everything up to that point is screwed anyway
 795   return $self->$run_target($self->_get_dbh, @_)
 796     if $self->{_in_do_block} or $self->transaction_depth;
 797
 798   my $args = \@_;
 799
 800   DBIx::Class::Storage::BlockRunner->new(
 801     storage => $self,
 802     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 803     wrap_txn => 0,
 804     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 805   )->run;
 806 }
 807
 808 sub txn_do {
 809   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 810   shift->next::method(@_);
 811 }
 812
 813 =head2 disconnect
 814
 815 Our C<disconnect> method also performs a rollback first if the
 816 database is not in C<AutoCommit> mode.
 817
 818 =cut
 819
 820 sub disconnect {
 821   my ($self) = @_;
 822
 823   if( $self->_dbh ) {
 824     my @actions;
 825
 826     push @actions, ( $self->on_disconnect_call || () );
 827     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 828
 829     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 830
 831     # stops the "implicit rollback on disconnect" warning
 832     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 833
 834     %{ $self->_dbh->{CachedKids} } = ();
 835     $self->_dbh->disconnect;
 836     $self->_dbh(undef);
 837     $self->{_dbh_gen}++;
 838   }
 839 }
 840
 841 =head2 with_deferred_fk_checks
 842
 843 =over 4
 844
 845 =item Arguments: C<$coderef>
 846
 847 =item Return Value: The return value of $coderef
 848
 849 =back
 850
 851 Storage specific method to run the code ref with FK checks deferred or
 852 in MySQL's case disabled entirely.
 853
 854 =cut
 855
 856 # Storage subclasses should override this
 857 sub with_deferred_fk_checks {
 858   my ($self, $sub) = @_;
 859   $sub->();
 860 }
 861
 862 =head2 connected
 863
 864 =over
 865
 866 =item Arguments: none
 867
 868 =item Return Value: 1|0
 869
 870 =back
 871
 872 Verifies that the current database handle is active and ready to execute
 873 an SQL statement (e.g. the connection did not get stale, server is still
 874 answering, etc.) This method is used internally by L</dbh>.
 875
 876 =cut
 877
 878 sub connected {
 879   my $self = shift;
 880   return 0 unless $self->_seems_connected;
 881
 882   #be on the safe side
 883   local $self->_dbh->{RaiseError} = 1;
 884
 885   return $self->_ping;
 886 }
 887
 888 sub _seems_connected {
 889   my $self = shift;
 890
 891   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 892
 893   my $dbh = $self->_dbh
 894     or return 0;
 895
 896   return $dbh->FETCH('Active');
 897 }
 898
 899 sub _ping {
 900   my $self = shift;
 901
 902   my $dbh = $self->_dbh or return 0;
 903
 904   return $dbh->ping;
 905 }
 906
 907 sub ensure_connected {
 908   my ($self) = @_;
 909
 910   unless ($self->connected) {
 911     $self->_populate_dbh;
 912   }
 913 }
 914
 915 =head2 dbh
 916
 917 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 918 is guaranteed to be healthy by implicitly calling L</connected>, and if
 919 necessary performing a reconnection before returning. Keep in mind that this
 920 is very B<expensive> on some database engines. Consider using L</dbh_do>
 921 instead.
 922
 923 =cut
 924
 925 sub dbh {
 926   my ($self) = @_;
 927
 928   if (not $self->_dbh) {
 929     $self->_populate_dbh;
 930   } else {
 931     $self->ensure_connected;
 932   }
 933   return $self->_dbh;
 934 }
 935
 936 # this is the internal "get dbh or connect (don't check)" method
 937 sub _get_dbh {
 938   my $self = shift;
 939   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 940   $self->_populate_dbh unless $self->_dbh;
 941   return $self->_dbh;
 942 }
 943
 944 sub sql_maker {
 945   my ($self) = @_;
 946   unless ($self->_sql_maker) {
 947     my $sql_maker_class = $self->sql_maker_class;
 948
 949     my %opts = %{$self->_sql_maker_opts||{}};
 950     my $dialect =
 951       $opts{limit_dialect}
 952         ||
 953       $self->sql_limit_dialect
 954         ||
 955       do {
 956         my $s_class = (ref $self) || $self;
 957         carp (
 958           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 959         . 'have not supplied an explicit limit_dialect in your connection_info. '
 960         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 961         . 'databases but can be (and often is) painfully slow. '
 962         . "Please file an RT ticket against '$s_class' ."
 963         );
 964
 965         'GenericSubQ';
 966       }
 967     ;
 968
 969     my ($quote_char, $name_sep);
 970
 971     if ($opts{quote_names}) {
 972       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 973         my $s_class = (ref $self) || $self;
 974         carp (
 975           "You requested 'quote_names' but your storage class ($s_class) does "
 976         . 'not explicitly define a default sql_quote_char and you have not '
 977         . 'supplied a quote_char as part of your connection_info. DBIC will '
 978         .q{default to the ANSI SQL standard quote '"', which works most of }
 979         . "the time. Please file an RT ticket against '$s_class'."
 980         );
 981
 982         '"'; # RV
 983       };
 984
 985       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 986     }
 987
 988     $self->_sql_maker($sql_maker_class->new(
 989       bindtype=>'columns',
 990       array_datatypes => 1,
 991       limit_dialect => $dialect,
 992       ($quote_char ? (quote_char => $quote_char) : ()),
 993       name_sep => ($name_sep || '.'),
 994       %opts,
 995     ));
 996   }
 997   return $self->_sql_maker;
 998 }
 999
1000 # nothing to do by default
1001 sub _rebless {}
1002 sub _init {}
1003
1004 sub _populate_dbh {
1005   my ($self) = @_;
1006
1007   my @info = @{$self->_dbi_connect_info || []};
1008   $self->_dbh(undef); # in case ->connected failed we might get sent here
1009   $self->_dbh_details({}); # reset everything we know
1010
1011   $self->_dbh($self->_connect(@info));
1012
1013   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1014
1015   $self->_determine_driver;
1016
1017   # Always set the transaction depth on connect, since
1018   #  there is no transaction in progress by definition
1019   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1020
1021   $self->_run_connection_actions unless $self->{_in_determine_driver};
1022 }
1023
1024 sub _run_connection_actions {
1025   my $self = shift;
1026   my @actions;
1027
1028   push @actions, ( $self->on_connect_call || () );
1029   push @actions, $self->_parse_connect_do ('on_connect_do');
1030
1031   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1032 }
1033
1034
1035
1036 sub set_use_dbms_capability {
1037   $_[0]->set_inherited ($_[1], $_[2]);
1038 }
1039
1040 sub get_use_dbms_capability {
1041   my ($self, $capname) = @_;
1042
1043   my $use = $self->get_inherited ($capname);
1044   return defined $use
1045     ? $use
1046     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1047   ;
1048 }
1049
1050 sub set_dbms_capability {
1051   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1052 }
1053
1054 sub get_dbms_capability {
1055   my ($self, $capname) = @_;
1056
1057   my $cap = $self->_dbh_details->{capability}{$capname};
1058
1059   unless (defined $cap) {
1060     if (my $meth = $self->can ("_determine$capname")) {
1061       $cap = $self->$meth ? 1 : 0;
1062     }
1063     else {
1064       $cap = 0;
1065     }
1066
1067     $self->set_dbms_capability ($capname, $cap);
1068   }
1069
1070   return $cap;
1071 }
1072
1073 sub _server_info {
1074   my $self = shift;
1075
1076   my $info;
1077   unless ($info = $self->_dbh_details->{info}) {
1078
1079     $info = {};
1080
1081     my $server_version = try {
1082       $self->_get_server_version
1083     } catch {
1084       # driver determination *may* use this codepath
1085       # in which case we must rethrow
1086       $self->throw_exception($_) if $self->{_in_determine_driver};
1087
1088       # $server_version on failure
1089       undef;
1090     };
1091
1092     if (defined $server_version) {
1093       $info->{dbms_version} = $server_version;
1094
1095       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1096       my @verparts = split (/\./, $numeric_version);
1097       if (
1098         @verparts
1099           &&
1100         $verparts[0] <= 999
1101       ) {
1102         # consider only up to 3 version parts, iff not more than 3 digits
1103         my @use_parts;
1104         while (@verparts && @use_parts < 3) {
1105           my $p = shift @verparts;
1106           last if $p > 999;
1107           push @use_parts, $p;
1108         }
1109         push @use_parts, 0 while @use_parts < 3;
1110
1111         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1112       }
1113     }
1114
1115     $self->_dbh_details->{info} = $info;
1116   }
1117
1118   return $info;
1119 }
1120
1121 sub _get_server_version {
1122   shift->_dbh_get_info('SQL_DBMS_VER');
1123 }
1124
1125 sub _dbh_get_info {
1126   my ($self, $info) = @_;
1127
1128   if ($info =~ /[^0-9]/) {
1129     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1130     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1131       unless defined $info;
1132   }
1133
1134   return $self->_get_dbh->get_info($info);
1135 }
1136
1137 sub _describe_connection {
1138   require DBI::Const::GetInfoReturn;
1139
1140   my $self = shift;
1141   $self->ensure_connected;
1142
1143   my $res = {
1144     DBIC_DSN => $self->_dbi_connect_info->[0],
1145     DBI_VER => DBI->VERSION,
1146     DBIC_VER => DBIx::Class->VERSION,
1147     DBIC_DRIVER => ref $self,
1148   };
1149
1150   for my $inf (
1151     #keys %DBI::Const::GetInfoType::GetInfoType,
1152     qw/
1153       SQL_CURSOR_COMMIT_BEHAVIOR
1154       SQL_CURSOR_ROLLBACK_BEHAVIOR
1155       SQL_CURSOR_SENSITIVITY
1156       SQL_DATA_SOURCE_NAME
1157       SQL_DBMS_NAME
1158       SQL_DBMS_VER
1159       SQL_DEFAULT_TXN_ISOLATION
1160       SQL_DM_VER
1161       SQL_DRIVER_NAME
1162       SQL_DRIVER_ODBC_VER
1163       SQL_DRIVER_VER
1164       SQL_EXPRESSIONS_IN_ORDERBY
1165       SQL_GROUP_BY
1166       SQL_IDENTIFIER_CASE
1167       SQL_IDENTIFIER_QUOTE_CHAR
1168       SQL_MAX_CATALOG_NAME_LEN
1169       SQL_MAX_COLUMN_NAME_LEN
1170       SQL_MAX_IDENTIFIER_LEN
1171       SQL_MAX_TABLE_NAME_LEN
1172       SQL_MULTIPLE_ACTIVE_TXN
1173       SQL_MULT_RESULT_SETS
1174       SQL_NEED_LONG_DATA_LEN
1175       SQL_NON_NULLABLE_COLUMNS
1176       SQL_ODBC_VER
1177       SQL_QUALIFIER_NAME_SEPARATOR
1178       SQL_QUOTED_IDENTIFIER_CASE
1179       SQL_TXN_CAPABLE
1180       SQL_TXN_ISOLATION_OPTION
1181     /
1182   ) {
1183     my $v = $self->_dbh_get_info($inf);
1184     next unless defined $v;
1185
1186     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1187     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1188     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1189   }
1190
1191   $res;
1192 }
1193
1194 sub _determine_driver {
1195   my ($self) = @_;
1196
1197   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1198     my $started_connected = 0;
1199     local $self->{_in_determine_driver} = 1;
1200
1201     if (ref($self) eq __PACKAGE__) {
1202       my $driver;
1203       if ($self->_dbh) { # we are connected
1204         $driver = $self->_dbh->{Driver}{Name};
1205         $started_connected = 1;
1206       }
1207       else {
1208         # if connect_info is a CODEREF, we have no choice but to connect
1209         if (ref $self->_dbi_connect_info->[0] &&
1210             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1211           $self->_populate_dbh;
1212           $driver = $self->_dbh->{Driver}{Name};
1213         }
1214         else {
1215           # try to use dsn to not require being connected, the driver may still
1216           # force a connection in _rebless to determine version
1217           # (dsn may not be supplied at all if all we do is make a mock-schema)
1218           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1219           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1220           $driver ||= $ENV{DBI_DRIVER};
1221         }
1222       }
1223
1224       if ($driver) {
1225         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1226         if ($self->load_optional_class($storage_class)) {
1227           mro::set_mro($storage_class, 'c3');
1228           bless $self, $storage_class;
1229           $self->_rebless();
1230         }
1231         else {
1232           $self->_warn_undetermined_driver(
1233             'This version of DBIC does not yet seem to supply a driver for '
1234           . "your particular RDBMS and/or connection method ('$driver')."
1235           );
1236         }
1237       }
1238       else {
1239         $self->_warn_undetermined_driver(
1240           'Unable to extract a driver name from connect info - this '
1241         . 'should not have happened.'
1242         );
1243       }
1244     }
1245
1246     $self->_driver_determined(1);
1247
1248     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1249
1250     $self->_init; # run driver-specific initializations
1251
1252     $self->_run_connection_actions
1253         if !$started_connected && defined $self->_dbh;
1254   }
1255 }
1256
1257 sub _determine_connector_driver {
1258   my ($self, $conn) = @_;
1259
1260   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1261
1262   if (not $dbtype) {
1263     $self->_warn_undetermined_driver(
1264       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1265     . "$conn connector - this should not have happened."
1266     );
1267     return;
1268   }
1269
1270   $dbtype =~ s/\W/_/gi;
1271
1272   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1273   return if $self->isa($subclass);
1274
1275   if ($self->load_optional_class($subclass)) {
1276     bless $self, $subclass;
1277     $self->_rebless;
1278   }
1279   else {
1280     $self->_warn_undetermined_driver(
1281       'This version of DBIC does not yet seem to supply a driver for '
1282     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1283     );
1284   }
1285 }
1286
1287 sub _warn_undetermined_driver {
1288   my ($self, $msg) = @_;
1289
1290   require Data::Dumper::Concise;
1291
1292   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1293   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1294   . "does not go away, file a bugreport including the following info:\n"
1295   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1296   );
1297 }
1298
1299 sub _do_connection_actions {
1300   my $self          = shift;
1301   my $method_prefix = shift;
1302   my $call          = shift;
1303
1304   if (not ref($call)) {
1305     my $method = $method_prefix . $call;
1306     $self->$method(@_);
1307   } elsif (ref($call) eq 'CODE') {
1308     $self->$call(@_);
1309   } elsif (ref($call) eq 'ARRAY') {
1310     if (ref($call->[0]) ne 'ARRAY') {
1311       $self->_do_connection_actions($method_prefix, $_) for @$call;
1312     } else {
1313       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1314     }
1315   } else {
1316     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1317   }
1318
1319   return $self;
1320 }
1321
1322 sub connect_call_do_sql {
1323   my $self = shift;
1324   $self->_do_query(@_);
1325 }
1326
1327 sub disconnect_call_do_sql {
1328   my $self = shift;
1329   $self->_do_query(@_);
1330 }
1331
1332 # override in db-specific backend when necessary
1333 sub connect_call_datetime_setup { 1 }
1334
1335 sub _do_query {
1336   my ($self, $action) = @_;
1337
1338   if (ref $action eq 'CODE') {
1339     $action = $action->($self);
1340     $self->_do_query($_) foreach @$action;
1341   }
1342   else {
1343     # Most debuggers expect ($sql, @bind), so we need to exclude
1344     # the attribute hash which is the second argument to $dbh->do
1345     # furthermore the bind values are usually to be presented
1346     # as named arrayref pairs, so wrap those here too
1347     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1348     my $sql = shift @do_args;
1349     my $attrs = shift @do_args;
1350     my @bind = map { [ undef, $_ ] } @do_args;
1351
1352     $self->dbh_do(sub {
1353       $_[0]->_query_start($sql, \@bind);
1354       $_[1]->do($sql, $attrs, @do_args);
1355       $_[0]->_query_end($sql, \@bind);
1356     });
1357   }
1358
1359   return $self;
1360 }
1361
1362 sub _connect {
1363   my ($self, @info) = @_;
1364
1365   $self->throw_exception("You failed to provide any connection info")
1366     if !@info;
1367
1368   my ($old_connect_via, $dbh);
1369
1370   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1371
1372   try {
1373     if(ref $info[0] eq 'CODE') {
1374       $dbh = $info[0]->();
1375     }
1376     else {
1377       require DBI;
1378       $dbh = DBI->connect(@info);
1379     }
1380
1381     if (!$dbh) {
1382       die $DBI::errstr;
1383     }
1384
1385     unless ($self->unsafe) {
1386
1387       $self->throw_exception(
1388         'Refusing clobbering of {HandleError} installed on externally supplied '
1389        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1390       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1391
1392       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1393       # request, or an external handle. Complain and set anyway
1394       unless ($dbh->{RaiseError}) {
1395         carp( ref $info[0] eq 'CODE'
1396
1397           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1398            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1399            .'attribute has been supplied'
1400
1401           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1402            .'unsafe => 1. Toggling RaiseError back to true'
1403         );
1404
1405         $dbh->{RaiseError} = 1;
1406       }
1407
1408       # this odd anonymous coderef dereference is in fact really
1409       # necessary to avoid the unwanted effect described in perl5
1410       # RT#75792
1411       sub {
1412         my $weak_self = $_[0];
1413         weaken $weak_self;
1414
1415         # the coderef is blessed so we can distinguish it from externally
1416         # supplied handles (which must be preserved)
1417         $_[1]->{HandleError} = bless sub {
1418           if ($weak_self) {
1419             $weak_self->throw_exception("DBI Exception: $_[0]");
1420           }
1421           else {
1422             # the handler may be invoked by something totally out of
1423             # the scope of DBIC
1424             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1425           }
1426         }, '__DBIC__DBH__ERROR__HANDLER__';
1427       }->($self, $dbh);
1428     }
1429   }
1430   catch {
1431     $self->throw_exception("DBI Connection failed: $_")
1432   };
1433
1434   $self->_dbh_autocommit($dbh->{AutoCommit});
1435   $dbh;
1436 }
1437
1438 sub txn_begin {
1439   my $self = shift;
1440
1441   # this means we have not yet connected and do not know the AC status
1442   # (e.g. coderef $dbh), need a full-fledged connection check
1443   if (! defined $self->_dbh_autocommit) {
1444     $self->ensure_connected;
1445   }
1446   # Otherwise simply connect or re-connect on pid changes
1447   else {
1448     $self->_get_dbh;
1449   }
1450
1451   $self->next::method(@_);
1452 }
1453
1454 sub _exec_txn_begin {
1455   my $self = shift;
1456
1457   # if the user is utilizing txn_do - good for him, otherwise we need to
1458   # ensure that the $dbh is healthy on BEGIN.
1459   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1460   # will be replaced by a failure of begin_work itself (which will be
1461   # then retried on reconnect)
1462   if ($self->{_in_do_block}) {
1463     $self->_dbh->begin_work;
1464   } else {
1465     $self->dbh_do(sub { $_[1]->begin_work });
1466   }
1467 }
1468
1469 sub txn_commit {
1470   my $self = shift;
1471
1472   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1473   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1474     unless $self->_dbh;
1475
1476   # esoteric case for folks using external $dbh handles
1477   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1478     carp "Storage transaction_depth 0 does not match "
1479         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1480     $self->transaction_depth(1);
1481   }
1482
1483   $self->next::method(@_);
1484
1485   # if AutoCommit is disabled txn_depth never goes to 0
1486   # as a new txn is started immediately on commit
1487   $self->transaction_depth(1) if (
1488     !$self->transaction_depth
1489       and
1490     defined $self->_dbh_autocommit
1491       and
1492     ! $self->_dbh_autocommit
1493   );
1494 }
1495
1496 sub _exec_txn_commit {
1497   shift->_dbh->commit;
1498 }
1499
1500 sub txn_rollback {
1501   my $self = shift;
1502
1503   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1504   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1505     unless $self->_dbh;
1506
1507   # esoteric case for folks using external $dbh handles
1508   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1509     carp "Storage transaction_depth 0 does not match "
1510         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1511     $self->transaction_depth(1);
1512   }
1513
1514   $self->next::method(@_);
1515
1516   # if AutoCommit is disabled txn_depth never goes to 0
1517   # as a new txn is started immediately on commit
1518   $self->transaction_depth(1) if (
1519     !$self->transaction_depth
1520       and
1521     defined $self->_dbh_autocommit
1522       and
1523     ! $self->_dbh_autocommit
1524   );
1525 }
1526
1527 sub _exec_txn_rollback {
1528   shift->_dbh->rollback;
1529 }
1530
1531 # generate some identical methods
1532 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1533   no strict qw/refs/;
1534   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1535     my $self = shift;
1536     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1537     $self->throw_exception("Unable to $meth() on a disconnected storage")
1538       unless $self->_dbh;
1539     $self->next::method(@_);
1540   };
1541 }
1542
1543 # This used to be the top-half of _execute.  It was split out to make it
1544 #  easier to override in NoBindVars without duping the rest.  It takes up
1545 #  all of _execute's args, and emits $sql, @bind.
1546 sub _prep_for_execute {
1547   #my ($self, $op, $ident, $args) = @_;
1548   return shift->_gen_sql_bind(@_)
1549 }
1550
1551 sub _gen_sql_bind {
1552   my ($self, $op, $ident, $args) = @_;
1553
1554   my ($sql, @bind) = $self->sql_maker->$op(
1555     blessed($ident) ? $ident->from : $ident,
1556     @$args,
1557   );
1558
1559   if (
1560     ! $ENV{DBIC_DT_SEARCH_OK}
1561       and
1562     $op eq 'select'
1563       and
1564     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1565   ) {
1566     carp_unique 'DateTime objects passed to search() are not supported '
1567       . 'properly (InflateColumn::DateTime formats and settings are not '
1568       . 'respected.) See "Formatting DateTime objects in queries" in '
1569       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1570       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1571   }
1572
1573   return( $sql, $self->_resolve_bindattrs(
1574     $ident, [ @{$args->[2]{bind}||[]}, @bind ]
1575   ));
1576 }
1577
1578 sub _resolve_bindattrs {
1579   my ($self, $ident, $bind, $colinfos) = @_;
1580
1581   $colinfos ||= {};
1582
1583   my $resolve_bindinfo = sub {
1584     #my $infohash = shift;
1585
1586     %$colinfos = %{ $self->_resolve_column_info($ident) }
1587       unless keys %$colinfos;
1588
1589     my $ret;
1590     if (my $col = $_[0]->{dbic_colname}) {
1591       $ret = { %{$_[0]} };
1592
1593       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1594         if $colinfos->{$col}{data_type};
1595
1596       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1597         if $colinfos->{$col}{size};
1598     }
1599
1600     $ret || $_[0];
1601   };
1602
1603   return [ map {
1604     if (ref $_ ne 'ARRAY') {
1605       [{}, $_]
1606     }
1607     elsif (! defined $_->[0]) {
1608       [{}, $_->[1]]
1609     }
1610     elsif (ref $_->[0] eq 'HASH') {
1611       [
1612         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1613         $_->[1]
1614       ]
1615     }
1616     elsif (ref $_->[0] eq 'SCALAR') {
1617       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1618     }
1619     else {
1620       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1621     }
1622   } @$bind ];
1623 }
1624
1625 sub _format_for_trace {
1626   #my ($self, $bind) = @_;
1627
1628   ### Turn @bind from something like this:
1629   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1630   ### to this:
1631   ###   ( "'1'", "'3'" )
1632
1633   map {
1634     defined( $_ && $_->[1] )
1635       ? qq{'$_->[1]'}
1636       : q{NULL}
1637   } @{$_[1] || []};
1638 }
1639
1640 sub _query_start {
1641   my ( $self, $sql, $bind ) = @_;
1642
1643   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1644     if $self->debug;
1645 }
1646
1647 sub _query_end {
1648   my ( $self, $sql, $bind ) = @_;
1649
1650   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1651     if $self->debug;
1652 }
1653
1654 my $sba_compat;
1655 sub _dbi_attrs_for_bind {
1656   my ($self, $ident, $bind) = @_;
1657
1658   if (! defined $sba_compat) {
1659     $self->_determine_driver;
1660     $sba_compat = $self->can('source_bind_attributes') == \&source_bind_attributes
1661       ? 0
1662       : 1
1663     ;
1664   }
1665
1666   my $sba_attrs;
1667   if ($sba_compat) {
1668     my $class = ref $self;
1669     carp_unique (
1670       "The source_bind_attributes() override in $class relies on a deprecated codepath. "
1671      .'You are strongly advised to switch your code to override bind_attribute_by_datatype() '
1672      .'instead. This legacy compat shim will also disappear some time before DBIC 0.09'
1673     );
1674
1675     my $sba_attrs = $self->source_bind_attributes
1676   }
1677
1678   my @attrs;
1679
1680   for (map { $_->[0] } @$bind) {
1681     push @attrs, do {
1682       if (exists $_->{dbd_attrs}) {
1683         $_->{dbd_attrs}
1684       }
1685       elsif($_->{sqlt_datatype}) {
1686         # cache the result in the dbh_details hash, as it can not change unless
1687         # we connect to something else
1688         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1689         if (not exists $cache->{$_->{sqlt_datatype}}) {
1690           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1691         }
1692         $cache->{$_->{sqlt_datatype}};
1693       }
1694       elsif ($sba_attrs and $_->{dbic_colname}) {
1695         $sba_attrs->{$_->{dbic_colname}} || undef;
1696       }
1697       else {
1698         undef;  # always push something at this position
1699       }
1700     }
1701   }
1702
1703   return \@attrs;
1704 }
1705
1706 sub _execute {
1707   my ($self, $op, $ident, @args) = @_;
1708
1709   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1710
1711   shift->dbh_do(    # retry over disconnects
1712     '_dbh_execute',
1713     $sql,
1714     $bind,
1715     $self->_dbi_attrs_for_bind($ident, $bind)
1716   );
1717 }
1718
1719 sub _dbh_execute {
1720   my ($self, undef, $sql, $bind, $bind_attrs) = @_;
1721
1722   $self->_query_start( $sql, $bind );
1723   my $sth = $self->_sth($sql);
1724
1725   for my $i (0 .. $#$bind) {
1726     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1727       $sth->bind_param_inout(
1728         $i + 1, # bind params counts are 1-based
1729         $bind->[$i][1],
1730         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1731         $bind_attrs->[$i],
1732       );
1733     }
1734     else {
1735       $sth->bind_param(
1736         $i + 1,
1737         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1738           ? "$bind->[$i][1]"
1739           : $bind->[$i][1]
1740         ,
1741         $bind_attrs->[$i],
1742       );
1743     }
1744   }
1745
1746   # Can this fail without throwing an exception anyways???
1747   my $rv = $sth->execute();
1748   $self->throw_exception(
1749     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1750   ) if !$rv;
1751
1752   $self->_query_end( $sql, $bind );
1753
1754   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1755 }
1756
1757 sub _prefetch_autovalues {
1758   my ($self, $source, $to_insert) = @_;
1759
1760   my $colinfo = $source->columns_info;
1761
1762   my %values;
1763   for my $col (keys %$colinfo) {
1764     if (
1765       $colinfo->{$col}{auto_nextval}
1766         and
1767       (
1768         ! exists $to_insert->{$col}
1769           or
1770         ref $to_insert->{$col} eq 'SCALAR'
1771           or
1772         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1773       )
1774     ) {
1775       $values{$col} = $self->_sequence_fetch(
1776         'NEXTVAL',
1777         ( $colinfo->{$col}{sequence} ||=
1778             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1779         ),
1780       );
1781     }
1782   }
1783
1784   \%values;
1785 }
1786
1787 sub insert {
1788   my ($self, $source, $to_insert) = @_;
1789
1790   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1791
1792   # fuse the values, but keep a separate list of prefetched_values so that
1793   # they can be fused once again with the final return
1794   $to_insert = { %$to_insert, %$prefetched_values };
1795
1796   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1797   # Investigate what does it take to s/defined/exists/
1798   my $col_infos = $source->columns_info;
1799   my %pcols = map { $_ => 1 } $source->primary_columns;
1800   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1801   for my $col ($source->columns) {
1802     if ($col_infos->{$col}{is_auto_increment}) {
1803       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1804       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1805     }
1806
1807     # nothing to retrieve when explicit values are supplied
1808     next if (defined $to_insert->{$col} and ! (
1809       ref $to_insert->{$col} eq 'SCALAR'
1810         or
1811       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1812     ));
1813
1814     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1815     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1816       $pcols{$col}
1817         or
1818       $col_infos->{$col}{retrieve_on_insert}
1819     );
1820   };
1821
1822   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1823   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1824
1825   my ($sqla_opts, @ir_container);
1826   if (%retrieve_cols and $self->_use_insert_returning) {
1827     $sqla_opts->{returning_container} = \@ir_container
1828       if $self->_use_insert_returning_bound;
1829
1830     $sqla_opts->{returning} = [
1831       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1832     ];
1833   }
1834
1835   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1836
1837   my %returned_cols = %$to_insert;
1838   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1839     @ir_container = try {
1840       local $SIG{__WARN__} = sub {};
1841       my @r = $sth->fetchrow_array;
1842       $sth->finish;
1843       @r;
1844     } unless @ir_container;
1845
1846     @returned_cols{@$retlist} = @ir_container if @ir_container;
1847   }
1848   else {
1849     # pull in PK if needed and then everything else
1850     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1851
1852       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1853         unless $self->can('last_insert_id');
1854
1855       my @pri_values = $self->last_insert_id($source, @missing_pri);
1856
1857       $self->throw_exception( "Can't get last insert id" )
1858         unless (@pri_values == @missing_pri);
1859
1860       @returned_cols{@missing_pri} = @pri_values;
1861       delete $retrieve_cols{$_} for @missing_pri;
1862     }
1863
1864     # if there is more left to pull
1865     if (%retrieve_cols) {
1866       $self->throw_exception(
1867         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1868       ) unless %pcols;
1869
1870       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1871
1872       my $cur = DBIx::Class::ResultSet->new($source, {
1873         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1874         select => \@left_to_fetch,
1875       })->cursor;
1876
1877       @returned_cols{@left_to_fetch} = $cur->next;
1878
1879       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1880         if scalar $cur->next;
1881     }
1882   }
1883
1884   return { %$prefetched_values, %returned_cols };
1885 }
1886
1887 sub insert_bulk {
1888   my ($self, $source, $cols, $data) = @_;
1889
1890   my @col_range = (0..$#$cols);
1891
1892   # FIXME - perhaps this is not even needed? does DBI stringify?
1893   #
1894   # forcibly stringify whatever is stringifiable
1895   # ResultSet::populate() hands us a copy - safe to mangle
1896   for my $r (0 .. $#$data) {
1897     for my $c (0 .. $#{$data->[$r]}) {
1898       $data->[$r][$c] = "$data->[$r][$c]"
1899         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1900     }
1901   }
1902
1903   my $colinfos = $source->columns_info($cols);
1904
1905   local $self->{_autoinc_supplied_for_op} =
1906     (first { $_->{is_auto_increment} } values %$colinfos)
1907       ? 1
1908       : 0
1909   ;
1910
1911   # get a slice type index based on first row of data
1912   # a "column" in this context may refer to more than one bind value
1913   # e.g. \[ '?, ?', [...], [...] ]
1914   #
1915   # construct the value type index - a description of values types for every
1916   # per-column slice of $data:
1917   #
1918   # nonexistent - nonbind literal
1919   # 0 - regular value
1920   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1921   #
1922   # also construct the column hash to pass to the SQL generator. For plain
1923   # (non literal) values - convert the members of the first row into a
1924   # literal+bind combo, with extra positional info in the bind attr hashref.
1925   # This will allow us to match the order properly, and is so contrived
1926   # because a user-supplied literal/bind (or something else specific to a
1927   # resultsource and/or storage driver) can inject extra binds along the
1928   # way, so one can't rely on "shift positions" ordering at all. Also we
1929   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1930   # can be later matched up by address), because we want to supply a real
1931   # value on which perhaps e.g. datatype checks will be performed
1932   my ($proto_data, $value_type_idx);
1933   for my $i (@col_range) {
1934     my $colname = $cols->[$i];
1935     if (ref $data->[0][$i] eq 'SCALAR') {
1936       # no bind value at all - no type
1937
1938       $proto_data->{$colname} = $data->[0][$i];
1939     }
1940     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1941       # repack, so we don't end up mangling the original \[]
1942       my ($sql, @bind) = @${$data->[0][$i]};
1943
1944       # normalization of user supplied stuff
1945       my $resolved_bind = $self->_resolve_bindattrs(
1946         $source, \@bind, $colinfos,
1947       );
1948
1949       # store value-less (attrs only) bind info - we will be comparing all
1950       # supplied binds against this for sanity
1951       $value_type_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1952
1953       $proto_data->{$colname} = \[ $sql, map { [
1954         # inject slice order to use for $proto_bind construction
1955           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i }
1956             =>
1957           $resolved_bind->[$_][1]
1958         ] } (0 .. $#bind)
1959       ];
1960     }
1961     else {
1962       $value_type_idx->{$i} = 0;
1963
1964       $proto_data->{$colname} = \[ '?', [
1965         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1966           =>
1967         $data->[0][$i]
1968       ] ];
1969     }
1970   }
1971
1972   my ($sql, $proto_bind) = $self->_prep_for_execute (
1973     'insert',
1974     $source,
1975     [ $proto_data ],
1976   );
1977
1978   if (! @$proto_bind and keys %$value_type_idx) {
1979     # if the bindlist is empty and we had some dynamic binds, this means the
1980     # storage ate them away (e.g. the NoBindVars component) and interpolated
1981     # them directly into the SQL. This obviously can't be good for multi-inserts
1982     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1983   }
1984
1985   # sanity checks
1986   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1987   #
1988   # use an error reporting closure for convenience (less to pass)
1989   my $bad_slice_report_cref = sub {
1990     my ($msg, $r_idx, $c_idx) = @_;
1991     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1992       $msg,
1993       $cols->[$c_idx],
1994       do {
1995         require Data::Dumper::Concise;
1996         local $Data::Dumper::Maxdepth = 5;
1997         Data::Dumper::Concise::Dumper ({
1998           map { $cols->[$_] =>
1999             $data->[$r_idx][$_]
2000           } @col_range
2001         }),
2002       }
2003     );
2004   };
2005
2006   for my $col_idx (@col_range) {
2007     my $reference_val = $data->[0][$col_idx];
2008
2009     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2010       my $val = $data->[$row_idx][$col_idx];
2011
2012       if (! exists $value_type_idx->{$col_idx}) { # literal no binds
2013         if (ref $val ne 'SCALAR') {
2014           $bad_slice_report_cref->(
2015             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2016             $row_idx,
2017             $col_idx,
2018           );
2019         }
2020         elsif ($$val ne $$reference_val) {
2021           $bad_slice_report_cref->(
2022             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2023             $row_idx,
2024             $col_idx,
2025           );
2026         }
2027       }
2028       elsif (! $value_type_idx->{$col_idx} ) {  # regular non-literal value
2029         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2030           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2031         }
2032       }
2033       else {  # binds from a \[], compare type and attrs
2034         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2035           $bad_slice_report_cref->(
2036             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2037             $row_idx,
2038             $col_idx,
2039           );
2040         }
2041         # start drilling down and bail out early on identical refs
2042         elsif (
2043           $reference_val != $val
2044             or
2045           $$reference_val != $$val
2046         ) {
2047           if (${$val}->[0] ne ${$reference_val}->[0]) {
2048             $bad_slice_report_cref->(
2049               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2050               $row_idx,
2051               $col_idx,
2052             );
2053           }
2054           # need to check the bind attrs - a bind will happen only once for
2055           # the entire dataset, so any changes further down will be ignored.
2056           elsif (! Data::Compare::Compare(
2057             $value_type_idx->{$col_idx},
2058             [
2059               map
2060               { $_->[0] }
2061               @{$self->_resolve_bindattrs(
2062                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2063               )}
2064             ],
2065           )) {
2066             $bad_slice_report_cref->(
2067               'Differing bind attributes on literal/bind values not supported',
2068               $row_idx,
2069               $col_idx,
2070             );
2071           }
2072         }
2073       }
2074     }
2075   }
2076
2077   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2078   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2079   # scope guard
2080   my $guard = $self->txn_scope_guard;
2081
2082   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2083   my $sth = $self->_sth($sql);
2084   my $rv = do {
2085     if (@$proto_bind) {
2086       # proto bind contains the information on which pieces of $data to pull
2087       # $cols is passed in only for prettier error-reporting
2088       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2089     }
2090     else {
2091       # bind_param_array doesn't work if there are no binds
2092       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2093     }
2094   };
2095
2096   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2097
2098   $guard->commit;
2099
2100   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2101 }
2102
2103 # execute_for_fetch is capable of returning data just fine (it means it
2104 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2105 # is the void-populate fast-path we will just ignore this altogether
2106 # for the time being.
2107 sub _dbh_execute_for_fetch {
2108   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2109
2110   my @idx_range = ( 0 .. $#$proto_bind );
2111
2112   # If we have any bind attributes to take care of, we will bind the
2113   # proto-bind data (which will never be used by execute_for_fetch)
2114   # However since column bindtypes are "sticky", this is sufficient
2115   # to get the DBD to apply the bindtype to all values later on
2116
2117   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2118
2119   for my $i (@idx_range) {
2120     $sth->bind_param (
2121       $i+1, # DBI bind indexes are 1-based
2122       $proto_bind->[$i][1],
2123       $bind_attrs->[$i],
2124     ) if defined $bind_attrs->[$i];
2125   }
2126
2127   # At this point $data slots named in the _bind_data_slice_idx of
2128   # each piece of $proto_bind are either \[]s or plain values to be
2129   # passed in. Construct the dispensing coderef. *NOTE* the order
2130   # of $data will differ from this of the ?s in the SQL (due to
2131   # alphabetical ordering by colname). We actually do want to
2132   # preserve this behavior so that prepare_cached has a better
2133   # chance of matching on unrelated calls
2134   my %data_reorder = map { $proto_bind->[$_][0]{_bind_data_slice_idx} => $_ } @idx_range;
2135
2136   my $fetch_row_idx = -1; # saner loop this way
2137   my $fetch_tuple = sub {
2138     return undef if ++$fetch_row_idx > $#$data;
2139
2140     return [ map
2141       { (ref $_ eq 'REF' and ref $$_ eq 'ARRAY')
2142         ? map { $_->[-1] } @{$$_}[1 .. $#$$_]
2143         : $_
2144       }
2145       map
2146         { $data->[$fetch_row_idx][$_]}
2147         sort
2148           { $data_reorder{$a} <=> $data_reorder{$b} }
2149           keys %data_reorder
2150     ];
2151   };
2152
2153   my $tuple_status = [];
2154   my ($rv, $err);
2155   try {
2156     $rv = $sth->execute_for_fetch(
2157       $fetch_tuple,
2158       $tuple_status,
2159     );
2160   }
2161   catch {
2162     $err = shift;
2163   };
2164
2165   # Not all DBDs are create equal. Some throw on error, some return
2166   # an undef $rv, and some set $sth->err - try whatever we can
2167   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2168     ! defined $err
2169       and
2170     ( !defined $rv or $sth->err )
2171   );
2172
2173   # Statement must finish even if there was an exception.
2174   try {
2175     $sth->finish
2176   }
2177   catch {
2178     $err = shift unless defined $err
2179   };
2180
2181   if (defined $err) {
2182     my $i = 0;
2183     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2184
2185     $self->throw_exception("Unexpected populate error: $err")
2186       if ($i > $#$tuple_status);
2187
2188     require Data::Dumper::Concise;
2189     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2190       ($tuple_status->[$i][1] || $err),
2191       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2192     );
2193   }
2194
2195   return $rv;
2196 }
2197
2198 sub _dbh_execute_inserts_with_no_binds {
2199   my ($self, $sth, $count) = @_;
2200
2201   my $err;
2202   try {
2203     my $dbh = $self->_get_dbh;
2204     local $dbh->{RaiseError} = 1;
2205     local $dbh->{PrintError} = 0;
2206
2207     $sth->execute foreach 1..$count;
2208   }
2209   catch {
2210     $err = shift;
2211   };
2212
2213   # Make sure statement is finished even if there was an exception.
2214   try {
2215     $sth->finish
2216   }
2217   catch {
2218     $err = shift unless defined $err;
2219   };
2220
2221   $self->throw_exception($err) if defined $err;
2222
2223   return $count;
2224 }
2225
2226 sub update {
2227   #my ($self, $source, @args) = @_;
2228   shift->_execute('update', @_);
2229 }
2230
2231
2232 sub delete {
2233   #my ($self, $source, @args) = @_;
2234   shift->_execute('delete', @_);
2235 }
2236
2237 sub _select {
2238   my $self = shift;
2239   $self->_execute($self->_select_args(@_));
2240 }
2241
2242 sub _select_args_to_query {
2243   my $self = shift;
2244
2245   $self->throw_exception(
2246     "Unable to generate limited query representation with 'software_limit' enabled"
2247   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2248
2249   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2250   #  = $self->_select_args($ident, $select, $cond, $attrs);
2251   my ($op, $ident, @args) =
2252     $self->_select_args(@_);
2253
2254   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2255   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2256   $prepared_bind ||= [];
2257
2258   return wantarray
2259     ? ($sql, $prepared_bind)
2260     : \[ "($sql)", @$prepared_bind ]
2261   ;
2262 }
2263
2264 sub _select_args {
2265   my ($self, $ident, $select, $where, $attrs) = @_;
2266
2267   my $sql_maker = $self->sql_maker;
2268   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2269
2270   $attrs = {
2271     %$attrs,
2272     select => $select,
2273     from => $ident,
2274     where => $where,
2275     $rs_alias && $alias2source->{$rs_alias}
2276       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2277       : ()
2278     ,
2279   };
2280
2281   # Sanity check the attributes (SQLMaker does it too, but
2282   # in case of a software_limit we'll never reach there)
2283   if (defined $attrs->{offset}) {
2284     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2285       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2286   }
2287
2288   if (defined $attrs->{rows}) {
2289     $self->throw_exception("The rows attribute must be a positive integer if present")
2290       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2291   }
2292   elsif ($attrs->{offset}) {
2293     # MySQL actually recommends this approach.  I cringe.
2294     $attrs->{rows} = $sql_maker->__max_int;
2295   }
2296
2297   my @limit;
2298
2299   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2300   # storage, unless software limit was requested
2301   if (
2302     #limited has_many
2303     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2304        ||
2305     # grouped prefetch (to satisfy group_by == select)
2306     ( $attrs->{group_by}
2307         &&
2308       @{$attrs->{group_by}}
2309         &&
2310       $attrs->{_prefetch_selector_range}
2311     )
2312   ) {
2313     ($ident, $select, $where, $attrs)
2314       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2315   }
2316   elsif (! $attrs->{software_limit} ) {
2317     push @limit, (
2318       $attrs->{rows} || (),
2319       $attrs->{offset} || (),
2320     );
2321   }
2322
2323   # try to simplify the joinmap further (prune unreferenced type-single joins)
2324   if (
2325     ref $ident
2326       and
2327     reftype $ident eq 'ARRAY'
2328       and
2329     @$ident != 1
2330   ) {
2331     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2332   }
2333
2334 ###
2335   # This would be the point to deflate anything found in $where
2336   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2337   # expect a row object. And all we have is a resultsource (it is trivial
2338   # to extract deflator coderefs via $alias2source above).
2339   #
2340   # I don't see a way forward other than changing the way deflators are
2341   # invoked, and that's just bad...
2342 ###
2343
2344   return ('select', $ident, $select, $where, $attrs, @limit);
2345 }
2346
2347 # Returns a counting SELECT for a simple count
2348 # query. Abstracted so that a storage could override
2349 # this to { count => 'firstcol' } or whatever makes
2350 # sense as a performance optimization
2351 sub _count_select {
2352   #my ($self, $source, $rs_attrs) = @_;
2353   return { count => '*' };
2354 }
2355
2356 sub source_bind_attributes {
2357   shift->throw_exception(
2358     'source_bind_attributes() was never meant to be a callable public method - '
2359    .'please contact the DBIC dev-team and describe your use case so that a reasonable '
2360    .'solution can be provided'
2361    ."\nhttp://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT"
2362   );
2363 }
2364
2365 =head2 select
2366
2367 =over 4
2368
2369 =item Arguments: $ident, $select, $condition, $attrs
2370
2371 =back
2372
2373 Handle a SQL select statement.
2374
2375 =cut
2376
2377 sub select {
2378   my $self = shift;
2379   my ($ident, $select, $condition, $attrs) = @_;
2380   return $self->cursor_class->new($self, \@_, $attrs);
2381 }
2382
2383 sub select_single {
2384   my $self = shift;
2385   my ($rv, $sth, @bind) = $self->_select(@_);
2386   my @row = $sth->fetchrow_array;
2387   my @nextrow = $sth->fetchrow_array if @row;
2388   if(@row && @nextrow) {
2389     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2390   }
2391   # Need to call finish() to work round broken DBDs
2392   $sth->finish();
2393   return @row;
2394 }
2395
2396 =head2 sql_limit_dialect
2397
2398 This is an accessor for the default SQL limit dialect used by a particular
2399 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2400 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2401 see L<DBIx::Class::SQLMaker::LimitDialects>.
2402
2403 =cut
2404
2405 sub _dbh_sth {
2406   my ($self, $dbh, $sql) = @_;
2407
2408   # 3 is the if_active parameter which avoids active sth re-use
2409   my $sth = $self->disable_sth_caching
2410     ? $dbh->prepare($sql)
2411     : $dbh->prepare_cached($sql, {}, 3);
2412
2413   # XXX You would think RaiseError would make this impossible,
2414   #  but apparently that's not true :(
2415   $self->throw_exception(
2416     $dbh->errstr
2417       ||
2418     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2419             .'an exception and/or setting $dbh->errstr',
2420       length ($sql) > 20
2421         ? substr($sql, 0, 20) . '...'
2422         : $sql
2423       ,
2424       'DBD::' . $dbh->{Driver}{Name},
2425     )
2426   ) if !$sth;
2427
2428   $sth;
2429 }
2430
2431 sub sth {
2432   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2433   shift->_sth(@_);
2434 }
2435
2436 sub _sth {
2437   my ($self, $sql) = @_;
2438   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2439 }
2440
2441 sub _dbh_columns_info_for {
2442   my ($self, $dbh, $table) = @_;
2443
2444   if ($dbh->can('column_info')) {
2445     my %result;
2446     my $caught;
2447     try {
2448       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2449       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2450       $sth->execute();
2451       while ( my $info = $sth->fetchrow_hashref() ){
2452         my %column_info;
2453         $column_info{data_type}   = $info->{TYPE_NAME};
2454         $column_info{size}      = $info->{COLUMN_SIZE};
2455         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2456         $column_info{default_value} = $info->{COLUMN_DEF};
2457         my $col_name = $info->{COLUMN_NAME};
2458         $col_name =~ s/^\"(.*)\"$/$1/;
2459
2460         $result{$col_name} = \%column_info;
2461       }
2462     } catch {
2463       $caught = 1;
2464     };
2465     return \%result if !$caught && scalar keys %result;
2466   }
2467
2468   my %result;
2469   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2470   $sth->execute;
2471   my @columns = @{$sth->{NAME_lc}};
2472   for my $i ( 0 .. $#columns ){
2473     my %column_info;
2474     $column_info{data_type} = $sth->{TYPE}->[$i];
2475     $column_info{size} = $sth->{PRECISION}->[$i];
2476     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2477
2478     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2479       $column_info{data_type} = $1;
2480       $column_info{size}    = $2;
2481     }
2482
2483     $result{$columns[$i]} = \%column_info;
2484   }
2485   $sth->finish;
2486
2487   foreach my $col (keys %result) {
2488     my $colinfo = $result{$col};
2489     my $type_num = $colinfo->{data_type};
2490     my $type_name;
2491     if(defined $type_num && $dbh->can('type_info')) {
2492       my $type_info = $dbh->type_info($type_num);
2493       $type_name = $type_info->{TYPE_NAME} if $type_info;
2494       $colinfo->{data_type} = $type_name if $type_name;
2495     }
2496   }
2497
2498   return \%result;
2499 }
2500
2501 sub columns_info_for {
2502   my ($self, $table) = @_;
2503   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2504 }
2505
2506 =head2 last_insert_id
2507
2508 Return the row id of the last insert.
2509
2510 =cut
2511
2512 sub _dbh_last_insert_id {
2513     my ($self, $dbh, $source, $col) = @_;
2514
2515     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2516
2517     return $id if defined $id;
2518
2519     my $class = ref $self;
2520     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2521 }
2522
2523 sub last_insert_id {
2524   my $self = shift;
2525   $self->_dbh_last_insert_id ($self->_dbh, @_);
2526 }
2527
2528 =head2 _native_data_type
2529
2530 =over 4
2531
2532 =item Arguments: $type_name
2533
2534 =back
2535
2536 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2537 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2538 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2539
2540 The default implementation returns C<undef>, implement in your Storage driver if
2541 you need this functionality.
2542
2543 Should map types from other databases to the native RDBMS type, for example
2544 C<VARCHAR2> to C<VARCHAR>.
2545
2546 Types with modifiers should map to the underlying data type. For example,
2547 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2548
2549 Composite types should map to the container type, for example
2550 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2551
2552 =cut
2553
2554 sub _native_data_type {
2555   #my ($self, $data_type) = @_;
2556   return undef
2557 }
2558
2559 # Check if placeholders are supported at all
2560 sub _determine_supports_placeholders {
2561   my $self = shift;
2562   my $dbh  = $self->_get_dbh;
2563
2564   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2565   # but it is inaccurate more often than not
2566   return try {
2567     local $dbh->{PrintError} = 0;
2568     local $dbh->{RaiseError} = 1;
2569     $dbh->do('select ?', {}, 1);
2570     1;
2571   }
2572   catch {
2573     0;
2574   };
2575 }
2576
2577 # Check if placeholders bound to non-string types throw exceptions
2578 #
2579 sub _determine_supports_typeless_placeholders {
2580   my $self = shift;
2581   my $dbh  = $self->_get_dbh;
2582
2583   return try {
2584     local $dbh->{PrintError} = 0;
2585     local $dbh->{RaiseError} = 1;
2586     # this specifically tests a bind that is NOT a string
2587     $dbh->do('select 1 where 1 = ?', {}, 1);
2588     1;
2589   }
2590   catch {
2591     0;
2592   };
2593 }
2594
2595 =head2 sqlt_type
2596
2597 Returns the database driver name.
2598
2599 =cut
2600
2601 sub sqlt_type {
2602   shift->_get_dbh->{Driver}->{Name};
2603 }
2604
2605 =head2 bind_attribute_by_data_type
2606
2607 Given a datatype from column info, returns a database specific bind
2608 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2609 let the database planner just handle it.
2610
2611 Generally only needed for special case column types, like bytea in postgres.
2612
2613 =cut
2614
2615 sub bind_attribute_by_data_type {
2616     return;
2617 }
2618
2619 =head2 is_datatype_numeric
2620
2621 Given a datatype from column_info, returns a boolean value indicating if
2622 the current RDBMS considers it a numeric value. This controls how
2623 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2624 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2625 be performed instead of the usual C<eq>.
2626
2627 =cut
2628
2629 sub is_datatype_numeric {
2630   #my ($self, $dt) = @_;
2631
2632   return 0 unless $_[1];
2633
2634   $_[1] =~ /^ (?:
2635     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2636   ) $/ix;
2637 }
2638
2639
2640 =head2 create_ddl_dir
2641
2642 =over 4
2643
2644 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2645
2646 =back
2647
2648 Creates a SQL file based on the Schema, for each of the specified
2649 database engines in C<\@databases> in the given directory.
2650 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2651
2652 Given a previous version number, this will also create a file containing
2653 the ALTER TABLE statements to transform the previous schema into the
2654 current one. Note that these statements may contain C<DROP TABLE> or
2655 C<DROP COLUMN> statements that can potentially destroy data.
2656
2657 The file names are created using the C<ddl_filename> method below, please
2658 override this method in your schema if you would like a different file
2659 name format. For the ALTER file, the same format is used, replacing
2660 $version in the name with "$preversion-$version".
2661
2662 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2663 The most common value for this would be C<< { add_drop_table => 1 } >>
2664 to have the SQL produced include a C<DROP TABLE> statement for each table
2665 created. For quoting purposes supply C<quote_table_names> and
2666 C<quote_field_names>.
2667
2668 If no arguments are passed, then the following default values are assumed:
2669
2670 =over 4
2671
2672 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2673
2674 =item version    - $schema->schema_version
2675
2676 =item directory  - './'
2677
2678 =item preversion - <none>
2679
2680 =back
2681
2682 By default, C<\%sqlt_args> will have
2683
2684  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2685
2686 merged with the hash passed in. To disable any of those features, pass in a
2687 hashref like the following
2688
2689  { ignore_constraint_names => 0, # ... other options }
2690
2691
2692 WARNING: You are strongly advised to check all SQL files created, before applying
2693 them.
2694
2695 =cut
2696
2697 sub create_ddl_dir {
2698   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2699
2700   unless ($dir) {
2701     carp "No directory given, using ./\n";
2702     $dir = './';
2703   } else {
2704       -d $dir
2705         or
2706       (require File::Path and File::Path::make_path ("$dir"))  # make_path does not like objects (i.e. Path::Class::Dir)
2707         or
2708       $self->throw_exception(
2709         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2710       );
2711   }
2712
2713   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2714
2715   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2716   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2717
2718   my $schema_version = $schema->schema_version || '1.x';
2719   $version ||= $schema_version;
2720
2721   $sqltargs = {
2722     add_drop_table => 1,
2723     ignore_constraint_names => 1,
2724     ignore_index_names => 1,
2725     %{$sqltargs || {}}
2726   };
2727
2728   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2729     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2730   }
2731
2732   my $sqlt = SQL::Translator->new( $sqltargs );
2733
2734   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2735   my $sqlt_schema = $sqlt->translate({ data => $schema })
2736     or $self->throw_exception ($sqlt->error);
2737
2738   foreach my $db (@$databases) {
2739     $sqlt->reset();
2740     $sqlt->{schema} = $sqlt_schema;
2741     $sqlt->producer($db);
2742
2743     my $file;
2744     my $filename = $schema->ddl_filename($db, $version, $dir);
2745     if (-e $filename && ($version eq $schema_version )) {
2746       # if we are dumping the current version, overwrite the DDL
2747       carp "Overwriting existing DDL file - $filename";
2748       unlink($filename);
2749     }
2750
2751     my $output = $sqlt->translate;
2752     if(!$output) {
2753       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2754       next;
2755     }
2756     if(!open($file, ">$filename")) {
2757       $self->throw_exception("Can't open $filename for writing ($!)");
2758       next;
2759     }
2760     print $file $output;
2761     close($file);
2762
2763     next unless ($preversion);
2764
2765     require SQL::Translator::Diff;
2766
2767     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2768     if(!-e $prefilename) {
2769       carp("No previous schema file found ($prefilename)");
2770       next;
2771     }
2772
2773     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2774     if(-e $difffile) {
2775       carp("Overwriting existing diff file - $difffile");
2776       unlink($difffile);
2777     }
2778
2779     my $source_schema;
2780     {
2781       my $t = SQL::Translator->new($sqltargs);
2782       $t->debug( 0 );
2783       $t->trace( 0 );
2784
2785       $t->parser( $db )
2786         or $self->throw_exception ($t->error);
2787
2788       my $out = $t->translate( $prefilename )
2789         or $self->throw_exception ($t->error);
2790
2791       $source_schema = $t->schema;
2792
2793       $source_schema->name( $prefilename )
2794         unless ( $source_schema->name );
2795     }
2796
2797     # The "new" style of producers have sane normalization and can support
2798     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2799     # And we have to diff parsed SQL against parsed SQL.
2800     my $dest_schema = $sqlt_schema;
2801
2802     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2803       my $t = SQL::Translator->new($sqltargs);
2804       $t->debug( 0 );
2805       $t->trace( 0 );
2806
2807       $t->parser( $db )
2808         or $self->throw_exception ($t->error);
2809
2810       my $out = $t->translate( $filename )
2811         or $self->throw_exception ($t->error);
2812
2813       $dest_schema = $t->schema;
2814
2815       $dest_schema->name( $filename )
2816         unless $dest_schema->name;
2817     }
2818
2819     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2820                                                   $dest_schema,   $db,
2821                                                   $sqltargs
2822                                                  );
2823     if(!open $file, ">$difffile") {
2824       $self->throw_exception("Can't write to $difffile ($!)");
2825       next;
2826     }
2827     print $file $diff;
2828     close($file);
2829   }
2830 }
2831
2832 =head2 deployment_statements
2833
2834 =over 4
2835
2836 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2837
2838 =back
2839
2840 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2841
2842 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2843 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2844
2845 C<$directory> is used to return statements from files in a previously created
2846 L</create_ddl_dir> directory and is optional. The filenames are constructed
2847 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2848
2849 If no C<$directory> is specified then the statements are constructed on the
2850 fly using L<SQL::Translator> and C<$version> is ignored.
2851
2852 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2853
2854 =cut
2855
2856 sub deployment_statements {
2857   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2858   $type ||= $self->sqlt_type;
2859   $version ||= $schema->schema_version || '1.x';
2860   $dir ||= './';
2861   my $filename = $schema->ddl_filename($type, $version, $dir);
2862   if(-f $filename)
2863   {
2864       # FIXME replace this block when a proper sane sql parser is available
2865       my $file;
2866       open($file, "<$filename")
2867         or $self->throw_exception("Can't open $filename ($!)");
2868       my @rows = <$file>;
2869       close($file);
2870       return join('', @rows);
2871   }
2872
2873   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2874     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2875   }
2876
2877   # sources needs to be a parser arg, but for simplicty allow at top level
2878   # coming in
2879   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2880       if exists $sqltargs->{sources};
2881
2882   my $tr = SQL::Translator->new(
2883     producer => "SQL::Translator::Producer::${type}",
2884     %$sqltargs,
2885     parser => 'SQL::Translator::Parser::DBIx::Class',
2886     data => $schema,
2887   );
2888
2889   return preserve_context {
2890     $tr->translate
2891   } after => sub {
2892     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2893       unless defined $_[0];
2894   };
2895 }
2896
2897 # FIXME deploy() currently does not accurately report sql errors
2898 # Will always return true while errors are warned
2899 sub deploy {
2900   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2901   my $deploy = sub {
2902     my $line = shift;
2903     return if(!$line);
2904     return if($line =~ /^--/);
2905     # next if($line =~ /^DROP/m);
2906     return if($line =~ /^BEGIN TRANSACTION/m);
2907     return if($line =~ /^COMMIT/m);
2908     return if $line =~ /^\s+$/; # skip whitespace only
2909     $self->_query_start($line);
2910     try {
2911       # do a dbh_do cycle here, as we need some error checking in
2912       # place (even though we will ignore errors)
2913       $self->dbh_do (sub { $_[1]->do($line) });
2914     } catch {
2915       carp qq{$_ (running "${line}")};
2916     };
2917     $self->_query_end($line);
2918   };
2919   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2920   if (@statements > 1) {
2921     foreach my $statement (@statements) {
2922       $deploy->( $statement );
2923     }
2924   }
2925   elsif (@statements == 1) {
2926     # split on single line comments and end of statements
2927     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2928       $deploy->( $line );
2929     }
2930   }
2931 }
2932
2933 =head2 datetime_parser
2934
2935 Returns the datetime parser class
2936
2937 =cut
2938
2939 sub datetime_parser {
2940   my $self = shift;
2941   return $self->{datetime_parser} ||= do {
2942     $self->build_datetime_parser(@_);
2943   };
2944 }
2945
2946 =head2 datetime_parser_type
2947
2948 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2949
2950 =head2 build_datetime_parser
2951
2952 See L</datetime_parser>
2953
2954 =cut
2955
2956 sub build_datetime_parser {
2957   my $self = shift;
2958   my $type = $self->datetime_parser_type(@_);
2959   return $type;
2960 }
2961
2962
2963 =head2 is_replicating
2964
2965 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2966 replicate from a master database.  Default is undef, which is the result
2967 returned by databases that don't support replication.
2968
2969 =cut
2970
2971 sub is_replicating {
2972     return;
2973
2974 }
2975
2976 =head2 lag_behind_master
2977
2978 Returns a number that represents a certain amount of lag behind a master db
2979 when a given storage is replicating.  The number is database dependent, but
2980 starts at zero and increases with the amount of lag. Default in undef
2981
2982 =cut
2983
2984 sub lag_behind_master {
2985     return;
2986 }
2987
2988 =head2 relname_to_table_alias
2989
2990 =over 4
2991
2992 =item Arguments: $relname, $join_count
2993
2994 =back
2995
2996 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2997 queries.
2998
2999 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3000 way these aliases are named.
3001
3002 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3003 otherwise C<"$relname">.
3004
3005 =cut
3006
3007 sub relname_to_table_alias {
3008   my ($self, $relname, $join_count) = @_;
3009
3010   my $alias = ($join_count && $join_count > 1 ?
3011     join('_', $relname, $join_count) : $relname);
3012
3013   return $alias;
3014 }
3015
3016 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3017 # version and it may be necessary to amend or override it for a specific storage
3018 # if such binds are necessary.
3019 sub _max_column_bytesize {
3020   my ($self, $attr) = @_;
3021
3022   my $max_size;
3023
3024   if ($attr->{sqlt_datatype}) {
3025     my $data_type = lc($attr->{sqlt_datatype});
3026
3027     if ($attr->{sqlt_size}) {
3028
3029       # String/sized-binary types
3030       if ($data_type =~ /^(?:
3031           l? (?:var)? char(?:acter)? (?:\s*varying)?
3032             |
3033           (?:var)? binary (?:\s*varying)?
3034             |
3035           raw
3036         )\b/x
3037       ) {
3038         $max_size = $attr->{sqlt_size};
3039       }
3040       # Other charset/unicode types, assume scale of 4
3041       elsif ($data_type =~ /^(?:
3042           national \s* character (?:\s*varying)?
3043             |
3044           nchar
3045             |
3046           univarchar
3047             |
3048           nvarchar
3049         )\b/x
3050       ) {
3051         $max_size = $attr->{sqlt_size} * 4;
3052       }
3053     }
3054
3055     if (!$max_size and !$self->_is_lob_type($data_type)) {
3056       $max_size = 100 # for all other (numeric?) datatypes
3057     }
3058   }
3059
3060   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3061 }
3062
3063 # Determine if a data_type is some type of BLOB
3064 sub _is_lob_type {
3065   my ($self, $data_type) = @_;
3066   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3067     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3068                                   |varchar|character\s*varying|nvarchar
3069                                   |national\s*character\s*varying))?\z/xi);
3070 }
3071
3072 sub _is_binary_lob_type {
3073   my ($self, $data_type) = @_;
3074   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3075     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3076 }
3077
3078 sub _is_text_lob_type {
3079   my ($self, $data_type) = @_;
3080   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3081     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3082                         |national\s*character\s*varying))\z/xi);
3083 }
3084
3085 # Determine if a data_type is some type of a binary type
3086 sub _is_binary_type {
3087   my ($self, $data_type) = @_;
3088   $data_type && ($self->_is_binary_lob_type($data_type)
3089     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3090 }
3091
3092 1;
3093
3094 =head1 USAGE NOTES
3095
3096 =head2 DBIx::Class and AutoCommit
3097
3098 DBIx::Class can do some wonderful magic with handling exceptions,
3099 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3100 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3101 transaction support.
3102
3103 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3104 in an assumed transaction between commits, and you're telling us you'd
3105 like to manage that manually.  A lot of the magic protections offered by
3106 this module will go away.  We can't protect you from exceptions due to database
3107 disconnects because we don't know anything about how to restart your
3108 transactions.  You're on your own for handling all sorts of exceptional
3109 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3110 be with raw DBI.
3111
3112
3113 =head1 AUTHORS
3114
3115 Matt S. Trout <mst@shadowcatsystems.co.uk>
3116
3117 Andy Grundman <andy@hybridized.org>
3118
3119 =head1 LICENSE
3120
3121 You may distribute this code under the same terms as Perl itself.
3122
3123 =cut