lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize detected_reinvoked_destructor scope_guard);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # if this is an actual *setter* - just set it, no need to connect
 129       # and determine the driver
 130       !( %1$s and @_ > 1 )
 131         and
 132       # only fire when invoked on an instance, a valid class-based invocation
 133       # would e.g. be setting a default for an inherited accessor
 134       ref $_[0]
 135         and
 136       ! $_[0]->{_driver_determined}
 137         and
 138       ! $_[0]->{_in_determine_driver}
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227
 228     if(
 229       ! DBIx::Class::_ENV_::BROKEN_FORK
 230         and
 231       my @instances = grep { defined $_ } values %seek_and_destroy
 232     ) {
 233       local $?; # just in case the DBI destructor changes it somehow
 234
 235       # disarm the handle if not native to this process (see comment on top)
 236       $_->_verify_pid for @instances;
 237     }
 238   }
 239
 240   sub CLONE {
 241     # As per DBI's recommendation, DBIC disconnects all handles as
 242     # soon as possible (DBIC will reconnect only on demand from within
 243     # the thread)
 244     my @instances = grep { defined $_ } values %seek_and_destroy;
 245     %seek_and_destroy = ();
 246
 247     for (@instances) {
 248       $_->_dbh(undef);
 249       $_->disconnect;
 250
 251       # properly renumber existing refs
 252       $_->_arm_global_destructor
 253     }
 254   }
 255 }
 256
 257 sub DESTROY {
 258   return if &detected_reinvoked_destructor;
 259
 260   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 261
 262   # some databases spew warnings on implicit disconnect
 263   return unless defined $_[0]->_dbh;
 264
 265   local $SIG{__WARN__} = sub {};
 266   $_[0]->_dbh(undef);
 267   # not calling ->disconnect here - we are being destroyed - nothing to reset
 268
 269   # this op is necessary, since the very last perl runtime statement
 270   # triggers a global destruction shootout, and the $SIG localization
 271   # may very well be destroyed before perl actually gets to do the
 272   # $dbh undef
 273   1;
 274 }
 275
 276 # handle pid changes correctly - do not destroy parent's connection
 277 sub _verify_pid {
 278
 279   my $pid = $_[0]->_conn_pid;
 280
 281   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 282     $dbh->{InactiveDestroy} = 1;
 283     $_[0]->_dbh(undef);
 284     $_[0]->disconnect;
 285   }
 286
 287   return;
 288 }
 289
 290 =head2 connect_info
 291
 292 This method is normally called by L<DBIx::Class::Schema/connection>, which
 293 encapsulates its argument list in an arrayref before passing them here.
 294
 295 The argument list may contain:
 296
 297 =over
 298
 299 =item *
 300
 301 The same 4-element argument set one would normally pass to
 302 L<DBI/connect>, optionally followed by
 303 L<extra attributes|/DBIx::Class specific connection attributes>
 304 recognized by DBIx::Class:
 305
 306   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 307
 308 =item *
 309
 310 A single code reference which returns a connected
 311 L<DBI database handle|DBI/connect> optionally followed by
 312 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 313 by DBIx::Class:
 314
 315   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 316
 317 =item *
 318
 319 A single hashref with all the attributes and the dsn/user/password
 320 mixed together:
 321
 322   $connect_info_args = [{
 323     dsn => $dsn,
 324     user => $user,
 325     password => $pass,
 326     %dbi_attributes,
 327     %extra_attributes,
 328   }];
 329
 330   $connect_info_args = [{
 331     dbh_maker => sub { DBI->connect (...) },
 332     %dbi_attributes,
 333     %extra_attributes,
 334   }];
 335
 336 This is particularly useful for L<Catalyst> based applications, allowing the
 337 following config (L<Config::General> style):
 338
 339   <Model::DB>
 340     schema_class   App::DB
 341     <connect_info>
 342       dsn          dbi:mysql:database=test
 343       user         testuser
 344       password     TestPass
 345       AutoCommit   1
 346     </connect_info>
 347   </Model::DB>
 348
 349 The C<dsn>/C<user>/C<password> combination can be substituted by the
 350 C<dbh_maker> key whose value is a coderef that returns a connected
 351 L<DBI database handle|DBI/connect>
 352
 353 =back
 354
 355 Please note that the L<DBI> docs recommend that you always explicitly
 356 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 357 recommends that it be set to I<1>, and that you perform transactions
 358 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 359 to I<1> if you do not do explicitly set it to zero.  This is the default
 360 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 361
 362 =head3 DBIx::Class specific connection attributes
 363
 364 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 365 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 366 the following connection options. These options can be mixed in with your other
 367 L<DBI> connection attributes, or placed in a separate hashref
 368 (C<\%extra_attributes>) as shown above.
 369
 370 Every time C<connect_info> is invoked, any previous settings for
 371 these options will be cleared before setting the new ones, regardless of
 372 whether any options are specified in the new C<connect_info>.
 373
 374
 375 =over
 376
 377 =item on_connect_do
 378
 379 Specifies things to do immediately after connecting or re-connecting to
 380 the database.  Its value may contain:
 381
 382 =over
 383
 384 =item a scalar
 385
 386 This contains one SQL statement to execute.
 387
 388 =item an array reference
 389
 390 This contains SQL statements to execute in order.  Each element contains
 391 a string or a code reference that returns a string.
 392
 393 =item a code reference
 394
 395 This contains some code to execute.  Unlike code references within an
 396 array reference, its return value is ignored.
 397
 398 =back
 399
 400 =item on_disconnect_do
 401
 402 Takes arguments in the same form as L</on_connect_do> and executes them
 403 immediately before disconnecting from the database.
 404
 405 Note, this only runs if you explicitly call L</disconnect> on the
 406 storage object.
 407
 408 =item on_connect_call
 409
 410 A more generalized form of L</on_connect_do> that calls the specified
 411 C<connect_call_METHOD> methods in your storage driver.
 412
 413   on_connect_do => 'select 1'
 414
 415 is equivalent to:
 416
 417   on_connect_call => [ [ do_sql => 'select 1' ] ]
 418
 419 Its values may contain:
 420
 421 =over
 422
 423 =item a scalar
 424
 425 Will call the C<connect_call_METHOD> method.
 426
 427 =item a code reference
 428
 429 Will execute C<< $code->($storage) >>
 430
 431 =item an array reference
 432
 433 Each value can be a method name or code reference.
 434
 435 =item an array of arrays
 436
 437 For each array, the first item is taken to be the C<connect_call_> method name
 438 or code reference, and the rest are parameters to it.
 439
 440 =back
 441
 442 Some predefined storage methods you may use:
 443
 444 =over
 445
 446 =item do_sql
 447
 448 Executes a SQL string or a code reference that returns a SQL string. This is
 449 what L</on_connect_do> and L</on_disconnect_do> use.
 450
 451 It can take:
 452
 453 =over
 454
 455 =item a scalar
 456
 457 Will execute the scalar as SQL.
 458
 459 =item an arrayref
 460
 461 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 462 attributes hashref and bind values.
 463
 464 =item a code reference
 465
 466 Will execute C<< $code->($storage) >> and execute the return array refs as
 467 above.
 468
 469 =back
 470
 471 =item datetime_setup
 472
 473 Execute any statements necessary to initialize the database session to return
 474 and accept datetime/timestamp values used with
 475 L<DBIx::Class::InflateColumn::DateTime>.
 476
 477 Only necessary for some databases, see your specific storage driver for
 478 implementation details.
 479
 480 =back
 481
 482 =item on_disconnect_call
 483
 484 Takes arguments in the same form as L</on_connect_call> and executes them
 485 immediately before disconnecting from the database.
 486
 487 Calls the C<disconnect_call_METHOD> methods as opposed to the
 488 C<connect_call_METHOD> methods called by L</on_connect_call>.
 489
 490 Note, this only runs if you explicitly call L</disconnect> on the
 491 storage object.
 492
 493 =item disable_sth_caching
 494
 495 If set to a true value, this option will disable the caching of
 496 statement handles via L<DBI/prepare_cached>.
 497
 498 =item limit_dialect
 499
 500 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 501 default L</sql_limit_dialect> setting of the storage (if any). For a list
 502 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 503
 504 =item quote_names
 505
 506 When true automatically sets L</quote_char> and L</name_sep> to the characters
 507 appropriate for your particular RDBMS. This option is preferred over specifying
 508 L</quote_char> directly.
 509
 510 =item quote_char
 511
 512 Specifies what characters to use to quote table and column names.
 513
 514 C<quote_char> expects either a single character, in which case is it
 515 is placed on either side of the table/column name, or an arrayref of length
 516 2 in which case the table/column name is placed between the elements.
 517
 518 For example under MySQL you should use C<< quote_char => '`' >>, and for
 519 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 520
 521 =item name_sep
 522
 523 This parameter is only useful in conjunction with C<quote_char>, and is used to
 524 specify the character that separates elements (schemas, tables, columns) from
 525 each other. If unspecified it defaults to the most commonly used C<.>.
 526
 527 =item unsafe
 528
 529 This Storage driver normally installs its own C<HandleError>, sets
 530 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 531 all database handles, including those supplied by a coderef.  It does this
 532 so that it can have consistent and useful error behavior.
 533
 534 If you set this option to a true value, Storage will not do its usual
 535 modifications to the database handle's attributes, and instead relies on
 536 the settings in your connect_info DBI options (or the values you set in
 537 your connection coderef, in the case that you are connecting via coderef).
 538
 539 Note that your custom settings can cause Storage to malfunction,
 540 especially if you set a C<HandleError> handler that suppresses exceptions
 541 and/or disable C<RaiseError>.
 542
 543 =item auto_savepoint
 544
 545 If this option is true, L<DBIx::Class> will use savepoints when nesting
 546 transactions, making it possible to recover from failure in the inner
 547 transaction without having to abort all outer transactions.
 548
 549 =item cursor_class
 550
 551 Use this argument to supply a cursor class other than the default
 552 L<DBIx::Class::Storage::DBI::Cursor>.
 553
 554 =back
 555
 556 Some real-life examples of arguments to L</connect_info> and
 557 L<DBIx::Class::Schema/connect>
 558
 559   # Simple SQLite connection
 560   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 561
 562   # Connect via subref
 563   ->connect_info([ sub { DBI->connect(...) } ]);
 564
 565   # Connect via subref in hashref
 566   ->connect_info([{
 567     dbh_maker => sub { DBI->connect(...) },
 568     on_connect_do => 'alter session ...',
 569   }]);
 570
 571   # A bit more complicated
 572   ->connect_info(
 573     [
 574       'dbi:Pg:dbname=foo',
 575       'postgres',
 576       'my_pg_password',
 577       { AutoCommit => 1 },
 578       { quote_char => q{"} },
 579     ]
 580   );
 581
 582   # Equivalent to the previous example
 583   ->connect_info(
 584     [
 585       'dbi:Pg:dbname=foo',
 586       'postgres',
 587       'my_pg_password',
 588       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 589     ]
 590   );
 591
 592   # Same, but with hashref as argument
 593   # See parse_connect_info for explanation
 594   ->connect_info(
 595     [{
 596       dsn         => 'dbi:Pg:dbname=foo',
 597       user        => 'postgres',
 598       password    => 'my_pg_password',
 599       AutoCommit  => 1,
 600       quote_char  => q{"},
 601       name_sep    => q{.},
 602     }]
 603   );
 604
 605   # Subref + DBIx::Class-specific connection options
 606   ->connect_info(
 607     [
 608       sub { DBI->connect(...) },
 609       {
 610           quote_char => q{`},
 611           name_sep => q{@},
 612           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 613           disable_sth_caching => 1,
 614       },
 615     ]
 616   );
 617
 618
 619
 620 =cut
 621
 622 sub connect_info {
 623   my ($self, $info) = @_;
 624
 625   return $self->_connect_info if !$info;
 626
 627   $self->_connect_info($info); # copy for _connect_info
 628
 629   $info = $self->_normalize_connect_info($info)
 630     if ref $info eq 'ARRAY';
 631
 632   my %attrs = (
 633     %{ $self->_default_dbi_connect_attributes || {} },
 634     %{ $info->{attributes} || {} },
 635   );
 636
 637   my @args = @{ $info->{arguments} };
 638
 639   if (keys %attrs and ref $args[0] ne 'CODE') {
 640     carp_unique (
 641         'You provided explicit AutoCommit => 0 in your connection_info. '
 642       . 'This is almost universally a bad idea (see the footnotes of '
 643       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 644       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 645       . 'this warning.'
 646     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 647
 648     push @args, \%attrs if keys %attrs;
 649   }
 650
 651   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 652   # OR a single-element coderef-based $dbh factory
 653   $self->_dbi_connect_info(\@args);
 654
 655   # extract the individual storage options
 656   for my $storage_opt (keys %{ $info->{storage_options} }) {
 657     my $value = $info->{storage_options}{$storage_opt};
 658
 659     $self->$storage_opt($value);
 660   }
 661
 662   # Extract the individual sqlmaker options
 663   #
 664   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 665   #  the new set of options
 666   $self->_sql_maker(undef);
 667   $self->_sql_maker_opts({});
 668
 669   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 670     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 671
 672     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 673   }
 674
 675   # FIXME - dirty:
 676   # save attributes in a separate accessor so they are always
 677   # introspectable, even in case of a CODE $dbhmaker
 678   $self->_dbic_connect_attributes (\%attrs);
 679
 680   return $self->_connect_info;
 681 }
 682
 683 sub _dbi_connect_info {
 684   my $self = shift;
 685
 686   return $self->{_dbi_connect_info} = $_[0]
 687     if @_;
 688
 689   my $conninfo = $self->{_dbi_connect_info} || [];
 690
 691   # last ditch effort to grab a DSN
 692   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 693     my @new_conninfo = @$conninfo;
 694     $new_conninfo[0] = $ENV{DBI_DSN};
 695     $conninfo = \@new_conninfo;
 696   }
 697
 698   return $conninfo;
 699 }
 700
 701
 702 sub _normalize_connect_info {
 703   my ($self, $info_arg) = @_;
 704   my %info;
 705
 706   my @args = @$info_arg;  # take a shallow copy for further mutilation
 707
 708   # combine/pre-parse arguments depending on invocation style
 709
 710   my %attrs;
 711   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 712     %attrs = %{ $args[1] || {} };
 713     @args = $args[0];
 714   }
 715   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 716     %attrs = %{$args[0]};
 717     @args = ();
 718     if (my $code = delete $attrs{dbh_maker}) {
 719       @args = $code;
 720
 721       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 722       if (@ignored) {
 723         carp sprintf (
 724             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 725           . "to the result of 'dbh_maker'",
 726
 727           join (', ', map { "'$_'" } (@ignored) ),
 728         );
 729       }
 730     }
 731     else {
 732       @args = delete @attrs{qw/dsn user password/};
 733     }
 734   }
 735   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 736     %attrs = (
 737       % { $args[3] || {} },
 738       % { $args[4] || {} },
 739     );
 740     @args = @args[0,1,2];
 741   }
 742
 743   $info{arguments} = \@args;
 744
 745   my @storage_opts = grep exists $attrs{$_},
 746     @storage_options, 'cursor_class';
 747
 748   @{ $info{storage_options} }{@storage_opts} =
 749     delete @attrs{@storage_opts} if @storage_opts;
 750
 751   my @sql_maker_opts = grep exists $attrs{$_},
 752     qw/limit_dialect quote_char name_sep quote_names/;
 753
 754   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 755     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 756
 757   $info{attributes} = \%attrs if %attrs;
 758
 759   return \%info;
 760 }
 761
 762 sub _default_dbi_connect_attributes () {
 763   +{
 764     AutoCommit => 1,
 765     PrintError => 0,
 766     RaiseError => 1,
 767     ShowErrorStatement => 1,
 768   };
 769 }
 770
 771 =head2 on_connect_do
 772
 773 This method is deprecated in favour of setting via L</connect_info>.
 774
 775 =cut
 776
 777 =head2 on_disconnect_do
 778
 779 This method is deprecated in favour of setting via L</connect_info>.
 780
 781 =cut
 782
 783 sub _parse_connect_do {
 784   my ($self, $type) = @_;
 785
 786   my $val = $self->$type;
 787   return () if not defined $val;
 788
 789   my @res;
 790
 791   if (not ref($val)) {
 792     push @res, [ 'do_sql', $val ];
 793   } elsif (ref($val) eq 'CODE') {
 794     push @res, $val;
 795   } elsif (ref($val) eq 'ARRAY') {
 796     push @res, map { [ 'do_sql', $_ ] } @$val;
 797   } else {
 798     $self->throw_exception("Invalid type for $type: ".ref($val));
 799   }
 800
 801   return \@res;
 802 }
 803
 804 =head2 dbh_do
 805
 806 Arguments: ($subref | $method_name), @extra_coderef_args?
 807
 808 Execute the given $subref or $method_name using the new exception-based
 809 connection management.
 810
 811 The first two arguments will be the storage object that C<dbh_do> was called
 812 on and a database handle to use.  Any additional arguments will be passed
 813 verbatim to the called subref as arguments 2 and onwards.
 814
 815 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 816 exception handling and reconnection (or failover in future subclasses).
 817
 818 Your subref should have no side-effects outside of the database, as
 819 there is the potential for your subref to be partially double-executed
 820 if the database connection was stale/dysfunctional.
 821
 822 Example:
 823
 824   my @stuff = $schema->storage->dbh_do(
 825     sub {
 826       my ($storage, $dbh, @cols) = @_;
 827       my $cols = join(q{, }, @cols);
 828       $dbh->selectrow_array("SELECT $cols FROM foo");
 829     },
 830     @column_list
 831   );
 832
 833 =cut
 834
 835 sub dbh_do {
 836   my $self = shift;
 837   my $run_target = shift; # either a coderef or a method name
 838
 839   # short circuit when we know there is no need for a runner
 840   #
 841   # FIXME - assumption may be wrong
 842   # the rationale for the txn_depth check is that if this block is a part
 843   # of a larger transaction, everything up to that point is screwed anyway
 844   return $self->$run_target($self->_get_dbh, @_)
 845     if $self->{_in_do_block} or $self->transaction_depth;
 846
 847   # take a ref instead of a copy, to preserve @_ aliasing
 848   # semantics within the coderef, but only if needed
 849   # (pseudoforking doesn't like this trick much)
 850   my $args = @_ ? \@_ : [];
 851
 852   DBIx::Class::Storage::BlockRunner->new(
 853     storage => $self,
 854     wrap_txn => 0,
 855     retry_handler => sub {
 856       $_[0]->failed_attempt_count == 1
 857         and
 858       ! $_[0]->storage->connected
 859     },
 860   )->run(sub {
 861     $self->$run_target ($self->_get_dbh, @$args )
 862   });
 863 }
 864
 865 sub txn_do {
 866   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 867   shift->next::method(@_);
 868 }
 869
 870 =head2 disconnect
 871
 872 Our C<disconnect> method also performs a rollback first if the
 873 database is not in C<AutoCommit> mode.
 874
 875 =cut
 876
 877 sub disconnect {
 878   my $self = shift;
 879
 880   # this physical disconnect below might very well throw
 881   # in order to unambiguously reset the state - do the cleanup in guard
 882
 883   my $g = scope_guard {
 884     $self->_dbh(undef);
 885     $self->_dbh_details({});
 886     $self->transaction_depth(undef);
 887     $self->_dbh_autocommit(undef);
 888     $self->savepoints([]);
 889
 890     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 891     #$self->_sql_maker(undef); # this may also end up being different
 892   };
 893
 894   if( my $dbh = $self->_dbh ) {
 895
 896     $self->_do_connection_actions(disconnect_call_ => $_) for (
 897       ( $self->on_disconnect_call || () ),
 898       $self->_parse_connect_do ('on_disconnect_do')
 899     );
 900
 901     # stops the "implicit rollback on disconnect" warning
 902     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 903
 904     %{ $dbh->{CachedKids} } = ();
 905
 906     $dbh->disconnect;
 907   }
 908 }
 909
 910 =head2 with_deferred_fk_checks
 911
 912 =over 4
 913
 914 =item Arguments: C<$coderef>
 915
 916 =item Return Value: The return value of $coderef
 917
 918 =back
 919
 920 Storage specific method to run the code ref with FK checks deferred or
 921 in MySQL's case disabled entirely.
 922
 923 =cut
 924
 925 # Storage subclasses should override this
 926 sub with_deferred_fk_checks {
 927   #my ($self, $sub) = @_;
 928   $_[1]->();
 929 }
 930
 931 =head2 connected
 932
 933 =over
 934
 935 =item Arguments: none
 936
 937 =item Return Value: 1|0
 938
 939 =back
 940
 941 Verifies that the current database handle is active and ready to execute
 942 an SQL statement (e.g. the connection did not get stale, server is still
 943 answering, etc.) This method is used internally by L</dbh>.
 944
 945 =cut
 946
 947 sub connected {
 948   return 0 unless $_[0]->_seems_connected;
 949
 950   #be on the safe side
 951   local $_[0]->_dbh->{RaiseError} = 1;
 952
 953   return $_[0]->_ping;
 954 }
 955
 956 sub _seems_connected {
 957   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 958
 959   $_[0]->_dbh
 960     and
 961   $_[0]->_dbh->FETCH('Active')
 962     and
 963   return 1;
 964
 965   # explicitly reset all state
 966   $_[0]->disconnect;
 967   return 0;
 968 }
 969
 970 sub _ping {
 971   ($_[0]->_dbh || return 0)->ping;
 972 }
 973
 974 sub ensure_connected {
 975   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 976 }
 977
 978 =head2 dbh
 979
 980 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 981 is guaranteed to be healthy by implicitly calling L</connected>, and if
 982 necessary performing a reconnection before returning. Keep in mind that this
 983 is very B<expensive> on some database engines. Consider using L</dbh_do>
 984 instead.
 985
 986 =cut
 987
 988 sub dbh {
 989   # maybe save a ping call
 990   $_[0]->_dbh
 991     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 992     : $_[0]->_populate_dbh
 993   ;
 994 }
 995
 996 # this is the internal "get dbh or connect (don't check)" method
 997 sub _get_dbh {
 998   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 999   $_[0]->_dbh || $_[0]->_populate_dbh;
1000 }
1001
1002 # *DELIBERATELY* not a setter (for the time being)
1003 # Too intertwined with everything else for any kind of sanity
1004 sub sql_maker {
1005   my $self = shift;
1006
1007   $self->throw_exception('sql_maker() is not a setter method') if @_;
1008
1009   unless ($self->_sql_maker) {
1010     my $sql_maker_class = $self->sql_maker_class;
1011
1012     my %opts = %{$self->_sql_maker_opts||{}};
1013     my $dialect =
1014       $opts{limit_dialect}
1015         ||
1016       $self->sql_limit_dialect
1017         ||
1018       do {
1019         my $s_class = (ref $self) || $self;
1020         carp_unique (
1021           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1022         . 'have not supplied an explicit limit_dialect in your connection_info. '
1023         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1024         . 'databases but can be (and often is) painfully slow. '
1025         . "Please file an RT ticket against '$s_class'"
1026         ) if $self->_dbi_connect_info->[0];
1027
1028         'GenericSubQ';
1029       }
1030     ;
1031
1032     my ($quote_char, $name_sep);
1033
1034     if ($opts{quote_names}) {
1035       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1036         my $s_class = (ref $self) || $self;
1037         carp_unique (
1038           "You requested 'quote_names' but your storage class ($s_class) does "
1039         . 'not explicitly define a default sql_quote_char and you have not '
1040         . 'supplied a quote_char as part of your connection_info. DBIC will '
1041         .q{default to the ANSI SQL standard quote '"', which works most of }
1042         . "the time. Please file an RT ticket against '$s_class'."
1043         );
1044
1045         '"'; # RV
1046       };
1047
1048       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1049     }
1050
1051     $self->_sql_maker($sql_maker_class->new(
1052       bindtype=>'columns',
1053       array_datatypes => 1,
1054       limit_dialect => $dialect,
1055       ($quote_char ? (quote_char => $quote_char) : ()),
1056       name_sep => ($name_sep || '.'),
1057       %opts,
1058     ));
1059   }
1060   return $self->_sql_maker;
1061 }
1062
1063 # nothing to do by default
1064 sub _rebless {}
1065 sub _init {}
1066
1067 sub _populate_dbh {
1068
1069   # reset internal states
1070   # also in case ->connected failed we might get sent here
1071   $_[0]->disconnect;
1072
1073   $_[0]->_dbh($_[0]->_connect);
1074
1075   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1076
1077   $_[0]->_determine_driver;
1078
1079   # Always set the transaction depth on connect, since
1080   #  there is no transaction in progress by definition
1081   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1082
1083   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1084
1085   $_[0]->_dbh;
1086 }
1087
1088 sub _run_connection_actions {
1089
1090   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1091     ( $_[0]->on_connect_call || () ),
1092     $_[0]->_parse_connect_do ('on_connect_do'),
1093   );
1094 }
1095
1096
1097
1098 sub set_use_dbms_capability {
1099   $_[0]->set_inherited ($_[1], $_[2]);
1100 }
1101
1102 sub get_use_dbms_capability {
1103   my ($self, $capname) = @_;
1104
1105   my $use = $self->get_inherited ($capname);
1106   return defined $use
1107     ? $use
1108     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1109   ;
1110 }
1111
1112 sub set_dbms_capability {
1113   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1114 }
1115
1116 sub get_dbms_capability {
1117   my ($self, $capname) = @_;
1118
1119   my $cap = $self->_dbh_details->{capability}{$capname};
1120
1121   unless (defined $cap) {
1122     if (my $meth = $self->can ("_determine$capname")) {
1123       $cap = $self->$meth ? 1 : 0;
1124     }
1125     else {
1126       $cap = 0;
1127     }
1128
1129     $self->set_dbms_capability ($capname, $cap);
1130   }
1131
1132   return $cap;
1133 }
1134
1135 sub _server_info {
1136   my $self = shift;
1137
1138   # FIXME - ideally this needs to be an ||= assignment, and the final
1139   # assignment at the end of this do{} should be gone entirely. However
1140   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1141   $self->_dbh_details->{info} || do {
1142
1143     # this guarantees that problematic conninfo won't be hidden
1144     # by the try{} below
1145     $self->ensure_connected;
1146
1147     my $info = {};
1148
1149     my $server_version = try {
1150       $self->_get_server_version
1151     } catch {
1152       # driver determination *may* use this codepath
1153       # in which case we must rethrow
1154       $self->throw_exception($_) if $self->{_in_determine_driver};
1155
1156       # $server_version on failure
1157       undef;
1158     };
1159
1160     if (defined $server_version) {
1161       $info->{dbms_version} = $server_version;
1162
1163       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1164       my @verparts = split (/\./, $numeric_version);
1165       if (
1166         @verparts
1167           &&
1168         $verparts[0] <= 999
1169       ) {
1170         # consider only up to 3 version parts, iff not more than 3 digits
1171         my @use_parts;
1172         while (@verparts && @use_parts < 3) {
1173           my $p = shift @verparts;
1174           last if $p > 999;
1175           push @use_parts, $p;
1176         }
1177         push @use_parts, 0 while @use_parts < 3;
1178
1179         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1180       }
1181     }
1182
1183     $self->_dbh_details->{info} = $info;
1184   };
1185 }
1186
1187 sub _get_server_version {
1188   shift->_dbh_get_info('SQL_DBMS_VER');
1189 }
1190
1191 sub _dbh_get_info {
1192   my ($self, $info) = @_;
1193
1194   if ($info =~ /[^0-9]/) {
1195     require DBI::Const::GetInfoType;
1196     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1197     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1198       unless defined $info;
1199   }
1200
1201   $self->_get_dbh->get_info($info);
1202 }
1203
1204 sub _describe_connection {
1205   require DBI::Const::GetInfoReturn;
1206
1207   my $self = shift;
1208
1209   my $drv;
1210   try {
1211     $drv = $self->_extract_driver_from_connect_info;
1212     $self->ensure_connected;
1213   };
1214
1215   $drv = "DBD::$drv" if $drv;
1216
1217   my $res = {
1218     DBIC_DSN => $self->_dbi_connect_info->[0],
1219     DBI_VER => DBI->VERSION,
1220     DBIC_VER => DBIx::Class->VERSION,
1221     DBIC_DRIVER => ref $self,
1222     $drv ? (
1223       DBD => $drv,
1224       DBD_VER => try { $drv->VERSION },
1225     ) : (),
1226   };
1227
1228   # try to grab data even if we never managed to connect
1229   # will cover us in cases of an oddly broken half-connect
1230   for my $inf (
1231     #keys %DBI::Const::GetInfoType::GetInfoType,
1232     qw/
1233       SQL_CURSOR_COMMIT_BEHAVIOR
1234       SQL_CURSOR_ROLLBACK_BEHAVIOR
1235       SQL_CURSOR_SENSITIVITY
1236       SQL_DATA_SOURCE_NAME
1237       SQL_DBMS_NAME
1238       SQL_DBMS_VER
1239       SQL_DEFAULT_TXN_ISOLATION
1240       SQL_DM_VER
1241       SQL_DRIVER_NAME
1242       SQL_DRIVER_ODBC_VER
1243       SQL_DRIVER_VER
1244       SQL_EXPRESSIONS_IN_ORDERBY
1245       SQL_GROUP_BY
1246       SQL_IDENTIFIER_CASE
1247       SQL_IDENTIFIER_QUOTE_CHAR
1248       SQL_MAX_CATALOG_NAME_LEN
1249       SQL_MAX_COLUMN_NAME_LEN
1250       SQL_MAX_IDENTIFIER_LEN
1251       SQL_MAX_TABLE_NAME_LEN
1252       SQL_MULTIPLE_ACTIVE_TXN
1253       SQL_MULT_RESULT_SETS
1254       SQL_NEED_LONG_DATA_LEN
1255       SQL_NON_NULLABLE_COLUMNS
1256       SQL_ODBC_VER
1257       SQL_QUALIFIER_NAME_SEPARATOR
1258       SQL_QUOTED_IDENTIFIER_CASE
1259       SQL_TXN_CAPABLE
1260       SQL_TXN_ISOLATION_OPTION
1261     /
1262   ) {
1263     # some drivers barf on things they do not know about instead
1264     # of returning undef
1265     my $v = try { $self->_dbh_get_info($inf) };
1266     next unless defined $v;
1267
1268     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1269     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1270     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1271   }
1272
1273   $res;
1274 }
1275
1276 sub _determine_driver {
1277   my ($self) = @_;
1278
1279   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1280     my $started_connected = 0;
1281     local $self->{_in_determine_driver} = 1;
1282
1283     if (ref($self) eq __PACKAGE__) {
1284       my $driver;
1285       if ($self->_dbh) { # we are connected
1286         $driver = $self->_dbh->{Driver}{Name};
1287         $started_connected = 1;
1288       }
1289       else {
1290         $driver = $self->_extract_driver_from_connect_info;
1291       }
1292
1293       if ($driver) {
1294         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1295         if ($self->load_optional_class($storage_class)) {
1296           mro::set_mro($storage_class, 'c3');
1297           bless $self, $storage_class;
1298           $self->_rebless();
1299         }
1300         else {
1301           $self->_warn_undetermined_driver(
1302             'This version of DBIC does not yet seem to supply a driver for '
1303           . "your particular RDBMS and/or connection method ('$driver')."
1304           );
1305         }
1306       }
1307       else {
1308         $self->_warn_undetermined_driver(
1309           'Unable to extract a driver name from connect info - this '
1310         . 'should not have happened.'
1311         );
1312       }
1313     }
1314
1315     $self->_driver_determined(1);
1316
1317     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1318
1319     if ($self->can('source_bind_attributes')) {
1320       $self->throw_exception(
1321         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1322       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1323       . 'If you are not sure how to proceed please contact the development team via '
1324       . DBIx::Class::_ENV_::HELP_URL
1325       );
1326     }
1327
1328     $self->_init; # run driver-specific initializations
1329
1330     $self->_run_connection_actions
1331         if !$started_connected && defined $self->_dbh;
1332   }
1333 }
1334
1335 sub _extract_driver_from_connect_info {
1336   my $self = shift;
1337
1338   my $drv;
1339
1340   # if connect_info is a CODEREF, we have no choice but to connect
1341   if (
1342     ref $self->_dbi_connect_info->[0]
1343       and
1344     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1345   ) {
1346     $self->_populate_dbh;
1347     $drv = $self->_dbh->{Driver}{Name};
1348   }
1349   else {
1350     # try to use dsn to not require being connected, the driver may still
1351     # force a connection later in _rebless to determine version
1352     # (dsn may not be supplied at all if all we do is make a mock-schema)
1353     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1354     $drv ||= $ENV{DBI_DRIVER};
1355   }
1356
1357   return $drv;
1358 }
1359
1360 sub _determine_connector_driver {
1361   my ($self, $conn) = @_;
1362
1363   my $dbtype = $self->_get_rdbms_name;
1364
1365   if (not $dbtype) {
1366     $self->_warn_undetermined_driver(
1367       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1368     . "$conn connector - this should not have happened."
1369     );
1370     return;
1371   }
1372
1373   $dbtype =~ s/\W/_/gi;
1374
1375   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1376   return if $self->isa($subclass);
1377
1378   if ($self->load_optional_class($subclass)) {
1379     bless $self, $subclass;
1380     $self->_rebless;
1381   }
1382   else {
1383     $self->_warn_undetermined_driver(
1384       'This version of DBIC does not yet seem to supply a driver for '
1385     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1386     );
1387   }
1388 }
1389
1390 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1391
1392 sub _warn_undetermined_driver {
1393   my ($self, $msg) = @_;
1394
1395   require Data::Dumper::Concise;
1396
1397   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1398   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1399   . "does not go away, file a bugreport including the following info:\n"
1400   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1401   );
1402 }
1403
1404 sub _do_connection_actions {
1405   my ($self, $method_prefix, $call, @args) = @_;
1406
1407   try {
1408     if (not ref($call)) {
1409       my $method = $method_prefix . $call;
1410       $self->$method(@args);
1411     }
1412     elsif (ref($call) eq 'CODE') {
1413       $self->$call(@args);
1414     }
1415     elsif (ref($call) eq 'ARRAY') {
1416       if (ref($call->[0]) ne 'ARRAY') {
1417         $self->_do_connection_actions($method_prefix, $_) for @$call;
1418       }
1419       else {
1420         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1421       }
1422     }
1423     else {
1424       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1425     }
1426   }
1427   catch {
1428     if ( $method_prefix =~ /^connect/ ) {
1429       # this is an on_connect cycle - we can't just throw while leaving
1430       # a handle in an undefined state in our storage object
1431       # kill it with fire and rethrow
1432       $self->_dbh(undef);
1433       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1434       $self->throw_exception( $_[0] );
1435     }
1436     else {
1437       carp "Disconnect action failed: $_[0]";
1438     }
1439   };
1440
1441   return $self;
1442 }
1443
1444 sub connect_call_do_sql {
1445   my $self = shift;
1446   $self->_do_query(@_);
1447 }
1448
1449 sub disconnect_call_do_sql {
1450   my $self = shift;
1451   $self->_do_query(@_);
1452 }
1453
1454 =head2 connect_call_datetime_setup
1455
1456 A no-op stub method, provided so that one can always safely supply the
1457 L<connection option|/DBIx::Class specific connection attributes>
1458
1459  on_connect_call => 'datetime_setup'
1460
1461 This way one does not need to know in advance whether the underlying
1462 storage requires any sort of hand-holding when dealing with calendar
1463 data.
1464
1465 =cut
1466
1467 sub connect_call_datetime_setup { 1 }
1468
1469 sub _do_query {
1470   my ($self, $action) = @_;
1471
1472   if (ref $action eq 'CODE') {
1473     $action = $action->($self);
1474     $self->_do_query($_) foreach @$action;
1475   }
1476   else {
1477     # Most debuggers expect ($sql, @bind), so we need to exclude
1478     # the attribute hash which is the second argument to $dbh->do
1479     # furthermore the bind values are usually to be presented
1480     # as named arrayref pairs, so wrap those here too
1481     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1482     my $sql = shift @do_args;
1483     my $attrs = shift @do_args;
1484     my @bind = map { [ undef, $_ ] } @do_args;
1485
1486     $self->dbh_do(sub {
1487       $_[0]->_query_start($sql, \@bind);
1488       $_[1]->do($sql, $attrs, @do_args);
1489       $_[0]->_query_end($sql, \@bind);
1490     });
1491   }
1492
1493   return $self;
1494 }
1495
1496 sub _connect {
1497   my $self = shift;
1498
1499   my $info = $self->_dbi_connect_info;
1500
1501   $self->throw_exception("You did not provide any connection_info")
1502     unless defined $info->[0];
1503
1504   my ($old_connect_via, $dbh);
1505
1506   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1507
1508   # this odd anonymous coderef dereference is in fact really
1509   # necessary to avoid the unwanted effect described in perl5
1510   # RT#75792
1511   #
1512   # in addition the coderef itself can't reside inside the try{} block below
1513   # as it somehow triggers a leak under perl -d
1514   my $dbh_error_handler_installer = sub {
1515     weaken (my $weak_self = $_[0]);
1516
1517     # the coderef is blessed so we can distinguish it from externally
1518     # supplied handles (which must be preserved)
1519     $_[1]->{HandleError} = bless sub {
1520       if ($weak_self) {
1521         $weak_self->throw_exception("DBI Exception: $_[0]");
1522       }
1523       else {
1524         # the handler may be invoked by something totally out of
1525         # the scope of DBIC
1526         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1527       }
1528     }, '__DBIC__DBH__ERROR__HANDLER__';
1529   };
1530
1531   try {
1532     if(ref $info->[0] eq 'CODE') {
1533       $dbh = $info->[0]->();
1534     }
1535     else {
1536       require DBI;
1537       $dbh = DBI->connect(@$info);
1538     }
1539
1540     die $DBI::errstr unless $dbh;
1541
1542     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1543       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1544       . 'not continue',
1545       ref $info->[0] eq 'CODE'
1546         ? "Connection coderef $info->[0] returned a"
1547         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1548     ) unless $dbh->FETCH('Active');
1549
1550     # sanity checks unless asked otherwise
1551     unless ($self->unsafe) {
1552
1553       $self->throw_exception(
1554         'Refusing clobbering of {HandleError} installed on externally supplied '
1555        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1556       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1557
1558       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1559       # request, or an external handle. Complain and set anyway
1560       unless ($dbh->{RaiseError}) {
1561         carp( ref $info->[0] eq 'CODE'
1562
1563           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1564            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1565            .'attribute has been supplied'
1566
1567           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1568            .'unsafe => 1. Toggling RaiseError back to true'
1569         );
1570
1571         $dbh->{RaiseError} = 1;
1572       }
1573
1574       $dbh_error_handler_installer->($self, $dbh);
1575     }
1576   }
1577   catch {
1578     $self->throw_exception("DBI Connection failed: $_")
1579   };
1580
1581   $self->_dbh_autocommit($dbh->{AutoCommit});
1582   return $dbh;
1583 }
1584
1585 sub txn_begin {
1586   # this means we have not yet connected and do not know the AC status
1587   # (e.g. coderef $dbh), need a full-fledged connection check
1588   if (! defined $_[0]->_dbh_autocommit) {
1589     $_[0]->ensure_connected;
1590   }
1591   # Otherwise simply connect or re-connect on pid changes
1592   else {
1593     $_[0]->_get_dbh;
1594   }
1595
1596   shift->next::method(@_);
1597 }
1598
1599 sub _exec_txn_begin {
1600   my $self = shift;
1601
1602   # if the user is utilizing txn_do - good for him, otherwise we need to
1603   # ensure that the $dbh is healthy on BEGIN.
1604   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1605   # will be replaced by a failure of begin_work itself (which will be
1606   # then retried on reconnect)
1607   if ($self->{_in_do_block}) {
1608     $self->_dbh->begin_work;
1609   } else {
1610     $self->dbh_do(sub { $_[1]->begin_work });
1611   }
1612 }
1613
1614 sub txn_commit {
1615   my $self = shift;
1616
1617   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1618     unless $self->_seems_connected;
1619
1620   # esoteric case for folks using external $dbh handles
1621   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1622     carp "Storage transaction_depth 0 does not match "
1623         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1624     $self->transaction_depth(1);
1625   }
1626
1627   $self->next::method(@_);
1628
1629   # if AutoCommit is disabled txn_depth never goes to 0
1630   # as a new txn is started immediately on commit
1631   $self->transaction_depth(1) if (
1632     !$self->transaction_depth
1633       and
1634     defined $self->_dbh_autocommit
1635       and
1636     ! $self->_dbh_autocommit
1637   );
1638 }
1639
1640 sub _exec_txn_commit {
1641   shift->_dbh->commit;
1642 }
1643
1644 sub txn_rollback {
1645   my $self = shift;
1646
1647   # do a minimal connectivity check due to weird shit like
1648   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1649   $self->throw_exception("lost connection to storage")
1650     unless $self->_seems_connected;
1651
1652   # esoteric case for folks using external $dbh handles
1653   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1654     carp "Storage transaction_depth 0 does not match "
1655         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1656     $self->transaction_depth(1);
1657   }
1658
1659   $self->next::method(@_);
1660
1661   # if AutoCommit is disabled txn_depth never goes to 0
1662   # as a new txn is started immediately on commit
1663   $self->transaction_depth(1) if (
1664     !$self->transaction_depth
1665       and
1666     defined $self->_dbh_autocommit
1667       and
1668     ! $self->_dbh_autocommit
1669   );
1670 }
1671
1672 sub _exec_txn_rollback {
1673   shift->_dbh->rollback;
1674 }
1675
1676 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1677 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1678   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1679     unless $_[0]->_seems_connected;
1680   shift->next::method(@_);
1681 EOS
1682
1683 # This used to be the top-half of _execute.  It was split out to make it
1684 #  easier to override in NoBindVars without duping the rest.  It takes up
1685 #  all of _execute's args, and emits $sql, @bind.
1686 sub _prep_for_execute {
1687   #my ($self, $op, $ident, $args) = @_;
1688   return shift->_gen_sql_bind(@_)
1689 }
1690
1691 sub _gen_sql_bind {
1692   my ($self, $op, $ident, $args) = @_;
1693
1694   my ($colinfos, $from);
1695   if ( blessed($ident) ) {
1696     $from = $ident->from;
1697     $colinfos = $ident->columns_info;
1698   }
1699
1700   my ($sql, $bind);
1701   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1702
1703   $bind = $self->_resolve_bindattrs(
1704     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1705   );
1706
1707   if (
1708     ! $ENV{DBIC_DT_SEARCH_OK}
1709       and
1710     $op eq 'select'
1711       and
1712     first {
1713       length ref $_->[1]
1714         and
1715       blessed($_->[1])
1716         and
1717       $_->[1]->isa('DateTime')
1718     } @$bind
1719   ) {
1720     carp_unique 'DateTime objects passed to search() are not supported '
1721       . 'properly (InflateColumn::DateTime formats and settings are not '
1722       . 'respected.) See ".. format a DateTime object for searching?" in '
1723       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1724       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1725   }
1726
1727   return( $sql, $bind );
1728 }
1729
1730 sub _resolve_bindattrs {
1731   my ($self, $ident, $bind, $colinfos) = @_;
1732
1733   my $resolve_bindinfo = sub {
1734     #my $infohash = shift;
1735
1736     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1737
1738     my $ret;
1739     if (my $col = $_[0]->{dbic_colname}) {
1740       $ret = { %{$_[0]} };
1741
1742       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1743         if $colinfos->{$col}{data_type};
1744
1745       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1746         if $colinfos->{$col}{size};
1747     }
1748
1749     $ret || $_[0];
1750   };
1751
1752   return [ map {
1753       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1754     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1755     : (ref $_->[0] eq 'HASH')           ? [(
1756                                             ! keys %{$_->[0]}
1757                                               or
1758                                             exists $_->[0]{dbd_attrs}
1759                                               or
1760                                             $_->[0]{sqlt_datatype}
1761                                            ) ? $_->[0]
1762                                              : $resolve_bindinfo->($_->[0])
1763                                            , $_->[1]
1764                                           ]
1765     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1766     :                                     [ $resolve_bindinfo->(
1767                                               { dbic_colname => $_->[0] }
1768                                             ), $_->[1] ]
1769   } @$bind ];
1770 }
1771
1772 sub _format_for_trace {
1773   #my ($self, $bind) = @_;
1774
1775   ### Turn @bind from something like this:
1776   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1777   ### to this:
1778   ###   ( "'1'", "'3'" )
1779
1780   map {
1781     defined( $_ && $_->[1] )
1782       ? qq{'$_->[1]'}
1783       : q{NULL}
1784   } @{$_[1] || []};
1785 }
1786
1787 sub _query_start {
1788   my ( $self, $sql, $bind ) = @_;
1789
1790   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1791     if $self->debug;
1792 }
1793
1794 sub _query_end {
1795   my ( $self, $sql, $bind ) = @_;
1796
1797   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1798     if $self->debug;
1799 }
1800
1801 sub _dbi_attrs_for_bind {
1802   #my ($self, $ident, $bind) = @_;
1803
1804   return [ map {
1805
1806     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1807
1808   : ! $_->{sqlt_datatype}   ? undef
1809
1810   :                           do {
1811
1812     # cache the result in the dbh_details hash, as it (usually) can not change
1813     # unless we connect to something else
1814     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1815     # the LOB storage
1816     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1817
1818     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1819       if ! exists $cache->{$_->{sqlt_datatype}};
1820
1821     $cache->{$_->{sqlt_datatype}};
1822
1823   } } map { $_->[0] } @{$_[2]} ];
1824 }
1825
1826 sub _execute {
1827   my ($self, $op, $ident, @args) = @_;
1828
1829   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1830
1831   # not even a PID check - we do not care about the state of the _dbh.
1832   # All we need is to get the appropriate drivers loaded if they aren't
1833   # already so that the assumption in ad7c50fc26e holds
1834   $self->_populate_dbh unless $self->_dbh;
1835
1836   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1837     $sql,
1838     $bind,
1839     $self->_dbi_attrs_for_bind($ident, $bind),
1840   );
1841 }
1842
1843 sub _dbh_execute {
1844   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1845
1846   $self->_query_start( $sql, $bind );
1847
1848   my $sth = $self->_bind_sth_params(
1849     $self->_prepare_sth($dbh, $sql),
1850     $bind,
1851     $bind_attrs,
1852   );
1853
1854   # Can this fail without throwing an exception anyways???
1855   my $rv = $sth->execute();
1856   $self->throw_exception(
1857     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1858   ) if !$rv;
1859
1860   $self->_query_end( $sql, $bind );
1861
1862   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1863 }
1864
1865 sub _prepare_sth {
1866   my ($self, $dbh, $sql) = @_;
1867
1868   # 3 is the if_active parameter which avoids active sth re-use
1869   my $sth = $self->disable_sth_caching
1870     ? $dbh->prepare($sql)
1871     : $dbh->prepare_cached($sql, {}, 3);
1872
1873   # XXX You would think RaiseError would make this impossible,
1874   #  but apparently that's not true :(
1875   $self->throw_exception(
1876     $dbh->errstr
1877       ||
1878     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1879             .'an exception and/or setting $dbh->errstr',
1880       length ($sql) > 20
1881         ? substr($sql, 0, 20) . '...'
1882         : $sql
1883       ,
1884       'DBD::' . $dbh->{Driver}{Name},
1885     )
1886   ) if !$sth;
1887
1888   $sth;
1889 }
1890
1891 sub _bind_sth_params {
1892   my ($self, $sth, $bind, $bind_attrs) = @_;
1893
1894   for my $i (0 .. $#$bind) {
1895     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1896       $sth->bind_param_inout(
1897         $i + 1, # bind params counts are 1-based
1898         $bind->[$i][1],
1899         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1900         $bind_attrs->[$i],
1901       );
1902     }
1903     else {
1904       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1905       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1906         ? "$bind->[$i][1]"
1907         : $bind->[$i][1]
1908       ;
1909
1910       $sth->bind_param(
1911         $i + 1,
1912         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1913         $v,
1914         $bind_attrs->[$i],
1915       );
1916     }
1917   }
1918
1919   $sth;
1920 }
1921
1922 sub _prefetch_autovalues {
1923   my ($self, $source, $colinfo, $to_insert) = @_;
1924
1925   my %values;
1926   for my $col (keys %$colinfo) {
1927     if (
1928       $colinfo->{$col}{auto_nextval}
1929         and
1930       (
1931         ! exists $to_insert->{$col}
1932           or
1933         is_literal_value($to_insert->{$col})
1934       )
1935     ) {
1936       $values{$col} = $self->_sequence_fetch(
1937         'NEXTVAL',
1938         ( $colinfo->{$col}{sequence} ||=
1939             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1940         ),
1941       );
1942     }
1943   }
1944
1945   \%values;
1946 }
1947
1948 sub insert {
1949   my ($self, $source, $to_insert) = @_;
1950
1951   my $col_infos = $source->columns_info;
1952
1953   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1954
1955   # fuse the values, but keep a separate list of prefetched_values so that
1956   # they can be fused once again with the final return
1957   $to_insert = { %$to_insert, %$prefetched_values };
1958
1959   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1960   # Investigate what does it take to s/defined/exists/
1961   my %pcols = map { $_ => 1 } $source->primary_columns;
1962   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1963   for my $col ($source->columns) {
1964     if ($col_infos->{$col}{is_auto_increment}) {
1965       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1966       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1967     }
1968
1969     # nothing to retrieve when explicit values are supplied
1970     next if (
1971       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1972     );
1973
1974     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1975     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1976       $pcols{$col}
1977         or
1978       $col_infos->{$col}{retrieve_on_insert}
1979     );
1980   };
1981
1982   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1983   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1984
1985   my ($sqla_opts, @ir_container);
1986   if (%retrieve_cols and $self->_use_insert_returning) {
1987     $sqla_opts->{returning_container} = \@ir_container
1988       if $self->_use_insert_returning_bound;
1989
1990     $sqla_opts->{returning} = [
1991       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1992     ];
1993   }
1994
1995   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1996
1997   my %returned_cols = %$to_insert;
1998   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1999
2000     unless( @ir_container ) {
2001       try {
2002
2003         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2004         local $SIG{__WARN__} = sub {};
2005
2006         @ir_container = $sth->fetchrow_array;
2007         $sth->finish;
2008
2009       } catch {
2010         # Evict the $sth from the cache in case we got here, since the finish()
2011         # is crucial, at least on older Firebirds, possibly on other engines too
2012         #
2013         # It would be too complex to make this a proper subclass override,
2014         # and besides we already take the try{} penalty, adding a catch that
2015         # triggers infrequently is a no-brainer
2016         #
2017         if( my $kids = $self->_dbh->{CachedKids} ) {
2018           $kids->{$_} == $sth and delete $kids->{$_}
2019             for keys %$kids
2020         }
2021       };
2022     }
2023
2024     @returned_cols{@$retlist} = @ir_container if @ir_container;
2025   }
2026   else {
2027     # pull in PK if needed and then everything else
2028     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2029
2030       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2031         unless $self->can('last_insert_id');
2032
2033       my @pri_values = $self->last_insert_id($source, @missing_pri);
2034
2035       $self->throw_exception( "Can't get last insert id" )
2036         unless (@pri_values == @missing_pri);
2037
2038       @returned_cols{@missing_pri} = @pri_values;
2039       delete @retrieve_cols{@missing_pri};
2040     }
2041
2042     # if there is more left to pull
2043     if (%retrieve_cols) {
2044       $self->throw_exception(
2045         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2046       ) unless %pcols;
2047
2048       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2049
2050       my $cur = DBIx::Class::ResultSet->new($source, {
2051         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2052         select => \@left_to_fetch,
2053       })->cursor;
2054
2055       @returned_cols{@left_to_fetch} = $cur->next;
2056
2057       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2058         if scalar $cur->next;
2059     }
2060   }
2061
2062   return { %$prefetched_values, %returned_cols };
2063 }
2064
2065 sub insert_bulk {
2066   carp_unique(
2067     'insert_bulk() should have never been exposed as a public method and '
2068   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2069   . 'use for this method please contact the development team via '
2070   . DBIx::Class::_ENV_::HELP_URL
2071   );
2072
2073   return '0E0' unless @{$_[3]||[]};
2074
2075   shift->_insert_bulk(@_);
2076 }
2077
2078 sub _insert_bulk {
2079   my ($self, $source, $cols, $data) = @_;
2080
2081   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2082     unless @{$data||[]};
2083
2084   my $colinfos = $source->columns_info($cols);
2085
2086   local $self->{_autoinc_supplied_for_op} =
2087     (grep { $_->{is_auto_increment} } values %$colinfos)
2088       ? 1
2089       : 0
2090   ;
2091
2092   # get a slice type index based on first row of data
2093   # a "column" in this context may refer to more than one bind value
2094   # e.g. \[ '?, ?', [...], [...] ]
2095   #
2096   # construct the value type index - a description of values types for every
2097   # per-column slice of $data:
2098   #
2099   # nonexistent - nonbind literal
2100   # 0 - regular value
2101   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2102   #
2103   # also construct the column hash to pass to the SQL generator. For plain
2104   # (non literal) values - convert the members of the first row into a
2105   # literal+bind combo, with extra positional info in the bind attr hashref.
2106   # This will allow us to match the order properly, and is so contrived
2107   # because a user-supplied literal/bind (or something else specific to a
2108   # resultsource and/or storage driver) can inject extra binds along the
2109   # way, so one can't rely on "shift positions" ordering at all. Also we
2110   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2111   # can be later matched up by address), because we want to supply a real
2112   # value on which perhaps e.g. datatype checks will be performed
2113   my ($proto_data, $serialized_bind_type_by_col_idx);
2114   for my $col_idx (0..$#$cols) {
2115     my $colname = $cols->[$col_idx];
2116     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2117       # no bind value at all - no type
2118
2119       $proto_data->{$colname} = $data->[0][$col_idx];
2120     }
2121     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2122       # repack, so we don't end up mangling the original \[]
2123       my ($sql, @bind) = @${$data->[0][$col_idx]};
2124
2125       # normalization of user supplied stuff
2126       my $resolved_bind = $self->_resolve_bindattrs(
2127         $source, \@bind, $colinfos,
2128       );
2129
2130       # store value-less (attrs only) bind info - we will be comparing all
2131       # supplied binds against this for sanity
2132       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2133
2134       $proto_data->{$colname} = \[ $sql, map { [
2135         # inject slice order to use for $proto_bind construction
2136           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2137             =>
2138           $resolved_bind->[$_][1]
2139         ] } (0 .. $#bind)
2140       ];
2141     }
2142     else {
2143       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2144
2145       $proto_data->{$colname} = \[ '?', [
2146         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2147           =>
2148         $data->[0][$col_idx]
2149       ] ];
2150     }
2151   }
2152
2153   my ($sql, $proto_bind) = $self->_prep_for_execute (
2154     'insert',
2155     $source,
2156     [ $proto_data ],
2157   );
2158
2159   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2160     # if the bindlist is empty and we had some dynamic binds, this means the
2161     # storage ate them away (e.g. the NoBindVars component) and interpolated
2162     # them directly into the SQL. This obviously can't be good for multi-inserts
2163     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2164   }
2165
2166   # sanity checks
2167   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2168   #
2169   # use an error reporting closure for convenience (less to pass)
2170   my $bad_slice_report_cref = sub {
2171     my ($msg, $r_idx, $c_idx) = @_;
2172     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2173       $msg,
2174       $cols->[$c_idx],
2175       do {
2176         require Data::Dumper::Concise;
2177         local $Data::Dumper::Maxdepth = 5;
2178         Data::Dumper::Concise::Dumper ({
2179           map { $cols->[$_] =>
2180             $data->[$r_idx][$_]
2181           } 0..$#$cols
2182         }),
2183       }
2184     );
2185   };
2186
2187   for my $col_idx (0..$#$cols) {
2188     my $reference_val = $data->[0][$col_idx];
2189
2190     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2191       my $val = $data->[$row_idx][$col_idx];
2192
2193       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2194         if (ref $val ne 'SCALAR') {
2195           $bad_slice_report_cref->(
2196             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2197             $row_idx,
2198             $col_idx,
2199           );
2200         }
2201         elsif ($$val ne $$reference_val) {
2202           $bad_slice_report_cref->(
2203             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2204             $row_idx,
2205             $col_idx,
2206           );
2207         }
2208       }
2209       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2210         if (is_literal_value($val)) {
2211           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2212         }
2213       }
2214       else {  # binds from a \[], compare type and attrs
2215         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2216           $bad_slice_report_cref->(
2217             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2218             $row_idx,
2219             $col_idx,
2220           );
2221         }
2222         # start drilling down and bail out early on identical refs
2223         elsif (
2224           $reference_val != $val
2225             or
2226           $$reference_val != $$val
2227         ) {
2228           if (${$val}->[0] ne ${$reference_val}->[0]) {
2229             $bad_slice_report_cref->(
2230               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2231               $row_idx,
2232               $col_idx,
2233             );
2234           }
2235           # need to check the bind attrs - a bind will happen only once for
2236           # the entire dataset, so any changes further down will be ignored.
2237           elsif (
2238             $serialized_bind_type_by_col_idx->{$col_idx}
2239               ne
2240             serialize [
2241               map
2242               { $_->[0] }
2243               @{$self->_resolve_bindattrs(
2244                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2245               )}
2246             ]
2247           ) {
2248             $bad_slice_report_cref->(
2249               'Differing bind attributes on literal/bind values not supported',
2250               $row_idx,
2251               $col_idx,
2252             );
2253           }
2254         }
2255       }
2256     }
2257   }
2258
2259   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2260   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2261   # scope guard
2262   my $guard = $self->txn_scope_guard;
2263
2264   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2265   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2266   my $rv = do {
2267     if (@$proto_bind) {
2268       # proto bind contains the information on which pieces of $data to pull
2269       # $cols is passed in only for prettier error-reporting
2270       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2271     }
2272     else {
2273       # bind_param_array doesn't work if there are no binds
2274       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2275     }
2276   };
2277
2278   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2279
2280   $guard->commit;
2281
2282   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2283 }
2284
2285 # execute_for_fetch is capable of returning data just fine (it means it
2286 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2287 # is the void-populate fast-path we will just ignore this altogether
2288 # for the time being.
2289 sub _dbh_execute_for_fetch {
2290   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2291
2292   # If we have any bind attributes to take care of, we will bind the
2293   # proto-bind data (which will never be used by execute_for_fetch)
2294   # However since column bindtypes are "sticky", this is sufficient
2295   # to get the DBD to apply the bindtype to all values later on
2296   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2297
2298   for my $i (0 .. $#$proto_bind) {
2299     $sth->bind_param (
2300       $i+1, # DBI bind indexes are 1-based
2301       $proto_bind->[$i][1],
2302       $bind_attrs->[$i],
2303     ) if defined $bind_attrs->[$i];
2304   }
2305
2306   # At this point $data slots named in the _bind_data_slice_idx of
2307   # each piece of $proto_bind are either \[]s or plain values to be
2308   # passed in. Construct the dispensing coderef. *NOTE* the order
2309   # of $data will differ from this of the ?s in the SQL (due to
2310   # alphabetical ordering by colname). We actually do want to
2311   # preserve this behavior so that prepare_cached has a better
2312   # chance of matching on unrelated calls
2313
2314   my $fetch_row_idx = -1; # saner loop this way
2315   my $fetch_tuple = sub {
2316     return undef if ++$fetch_row_idx > $#$data;
2317
2318     return [ map {
2319       my $v = ! defined $_->{_literal_bind_subindex}
2320
2321         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2322
2323         # There are no attributes to resolve here - we already did everything
2324         # when we constructed proto_bind. However we still want to sanity-check
2325         # what the user supplied, so pass stuff through to the resolver *anyway*
2326         : $self->_resolve_bindattrs (
2327             undef,  # a fake rsrc
2328             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2329             {},     # a fake column_info bag
2330           )->[0][1]
2331       ;
2332
2333       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2334       # For the time being forcibly stringify whatever is stringifiable
2335       my $vref;
2336
2337       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2338     : defined blessed( $$vref )                             ? "$$vref"
2339                                                             : $$vref
2340     ;
2341     } map { $_->[0] } @$proto_bind ];
2342   };
2343
2344   my $tuple_status = [];
2345   my ($rv, $err);
2346   try {
2347     $rv = $sth->execute_for_fetch(
2348       $fetch_tuple,
2349       $tuple_status,
2350     );
2351   }
2352   catch {
2353     $err = shift;
2354   };
2355
2356   # Not all DBDs are create equal. Some throw on error, some return
2357   # an undef $rv, and some set $sth->err - try whatever we can
2358   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2359     ! defined $err
2360       and
2361     ( !defined $rv or $sth->err )
2362   );
2363
2364   # Statement must finish even if there was an exception.
2365   try {
2366     $sth->finish
2367   }
2368   catch {
2369     $err = shift unless defined $err
2370   };
2371
2372   if (defined $err) {
2373     my $i = 0;
2374     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2375
2376     $self->throw_exception("Unexpected populate error: $err")
2377       if ($i > $#$tuple_status);
2378
2379     require Data::Dumper::Concise;
2380     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2381       ($tuple_status->[$i][1] || $err),
2382       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2383     );
2384   }
2385
2386   return $rv;
2387 }
2388
2389 sub _dbh_execute_inserts_with_no_binds {
2390   my ($self, $sth, $count) = @_;
2391
2392   my $err;
2393   try {
2394     my $dbh = $self->_get_dbh;
2395     local $dbh->{RaiseError} = 1;
2396     local $dbh->{PrintError} = 0;
2397
2398     $sth->execute foreach 1..$count;
2399   }
2400   catch {
2401     $err = shift;
2402   };
2403
2404   # Make sure statement is finished even if there was an exception.
2405   try {
2406     $sth->finish
2407   }
2408   catch {
2409     $err = shift unless defined $err;
2410   };
2411
2412   $self->throw_exception($err) if defined $err;
2413
2414   return $count;
2415 }
2416
2417 sub update {
2418   #my ($self, $source, @args) = @_;
2419   shift->_execute('update', @_);
2420 }
2421
2422
2423 sub delete {
2424   #my ($self, $source, @args) = @_;
2425   shift->_execute('delete', @_);
2426 }
2427
2428 sub _select {
2429   my $self = shift;
2430   $self->_execute($self->_select_args(@_));
2431 }
2432
2433 sub _select_args_to_query {
2434   my $self = shift;
2435
2436   $self->throw_exception(
2437     "Unable to generate limited query representation with 'software_limit' enabled"
2438   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2439
2440   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2441   #  = $self->_select_args($ident, $select, $cond, $attrs);
2442   my ($op, $ident, @args) =
2443     $self->_select_args(@_);
2444
2445   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2446   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2447
2448   # reuse the bind arrayref
2449   unshift @{$bind}, "($sql)";
2450   \$bind;
2451 }
2452
2453 sub _select_args {
2454   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2455
2456   # FIXME - that kind of caching would be nice to have
2457   # however currently we *may* pass the same $orig_attrs
2458   # with different ident/select/where
2459   # the whole interface needs to be rethought, since it
2460   # was centered around the flawed SQLA API. We can do
2461   # soooooo much better now. But that is also another
2462   # battle...
2463   #return (
2464   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2465   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2466
2467   my $sql_maker = $self->sql_maker;
2468
2469   my $attrs = {
2470     %$orig_attrs,
2471     select => $select,
2472     from => $ident,
2473     where => $where,
2474   };
2475
2476   # MySQL actually recommends this approach.  I cringe.
2477   $attrs->{rows} ||= $sql_maker->__max_int
2478     if $attrs->{offset};
2479
2480   # see if we will need to tear the prefetch apart to satisfy group_by == select
2481   # this is *extremely tricky* to get right, I am still not sure I did
2482   #
2483   my ($prefetch_needs_subquery, @limit_args);
2484
2485   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2486     # we already know there is a valid group_by (we made it) and we know it is
2487     # intended to be based *only* on non-multi stuff
2488     # short circuit the group_by parsing below
2489     $prefetch_needs_subquery = 1;
2490   }
2491   elsif (
2492     # The rationale is that even if we do *not* have collapse, we still
2493     # need to wrap the core grouped select/group_by in a subquery
2494     # so that databases that care about group_by/select equivalence
2495     # are happy (this includes MySQL in strict_mode)
2496     # If any of the other joined tables are referenced in the group_by
2497     # however - the user is on their own
2498     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2499       and
2500     $attrs->{group_by}
2501       and
2502     @{$attrs->{group_by}}
2503       and
2504     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2505       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2506     }
2507   ) {
2508     # no aliases other than our own in group_by
2509     # if there are - do not allow subquery even if limit is present
2510     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2511   }
2512   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2513     # active collapse with a limit - that one is a no-brainer unless
2514     # overruled by a group_by above
2515     $prefetch_needs_subquery = 1;
2516   }
2517
2518   if ($prefetch_needs_subquery) {
2519     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2520   }
2521   elsif (! $attrs->{software_limit} ) {
2522     push @limit_args, (
2523       $attrs->{rows} || (),
2524       $attrs->{offset} || (),
2525     );
2526   }
2527
2528   # try to simplify the joinmap further (prune unreferenced type-single joins)
2529   if (
2530     ! $prefetch_needs_subquery  # already pruned
2531       and
2532     ref $attrs->{from}
2533       and
2534     reftype $attrs->{from} eq 'ARRAY'
2535       and
2536     @{$attrs->{from}} != 1
2537   ) {
2538     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2539   }
2540
2541   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2542   # during the result inflation stage we *need* to know what was the aliastype
2543   # map as sqla saw it when the final pieces of SQL were being assembled
2544   # Originally we simply carried around the entirety of $attrs, but this
2545   # resulted in resultsets that are being reused growing continuously, as
2546   # the hash in question grew deeper and deeper.
2547   # Instead hand-pick what to take with us here (we actually don't need much
2548   # at this point just the map itself)
2549   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2550
2551 ###
2552   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2553   #
2554   # This would be the point to deflate anything found in $attrs->{where}
2555   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2556   # expect a result object. And all we have is a resultsource (it is trivial
2557   # to extract deflator coderefs via $alias2source above).
2558   #
2559   # I don't see a way forward other than changing the way deflators are
2560   # invoked, and that's just bad...
2561 ###
2562
2563   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2564 }
2565
2566 # Returns a counting SELECT for a simple count
2567 # query. Abstracted so that a storage could override
2568 # this to { count => 'firstcol' } or whatever makes
2569 # sense as a performance optimization
2570 sub _count_select {
2571   #my ($self, $source, $rs_attrs) = @_;
2572   return { count => '*' };
2573 }
2574
2575 =head2 select
2576
2577 =over 4
2578
2579 =item Arguments: $ident, $select, $condition, $attrs
2580
2581 =back
2582
2583 Handle a SQL select statement.
2584
2585 =cut
2586
2587 sub select {
2588   my $self = shift;
2589   my ($ident, $select, $condition, $attrs) = @_;
2590   return $self->cursor_class->new($self, \@_, $attrs);
2591 }
2592
2593 sub select_single {
2594   my $self = shift;
2595   my ($rv, $sth, @bind) = $self->_select(@_);
2596   my @row = $sth->fetchrow_array;
2597   my @nextrow = $sth->fetchrow_array if @row;
2598   if(@row && @nextrow) {
2599     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2600   }
2601   # Need to call finish() to work round broken DBDs
2602   $sth->finish();
2603   return @row;
2604 }
2605
2606 =head2 sql_limit_dialect
2607
2608 This is an accessor for the default SQL limit dialect used by a particular
2609 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2610 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2611 see L<DBIx::Class::SQLMaker::LimitDialects>.
2612
2613 =cut
2614
2615 sub _dbh_columns_info_for {
2616   my ($self, $dbh, $table) = @_;
2617
2618   my %result;
2619
2620   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2621     try {
2622       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2623       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2624       $sth->execute();
2625       while ( my $info = $sth->fetchrow_hashref() ){
2626         my %column_info;
2627         $column_info{data_type}   = $info->{TYPE_NAME};
2628         $column_info{size}      = $info->{COLUMN_SIZE};
2629         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2630         $column_info{default_value} = $info->{COLUMN_DEF};
2631         my $col_name = $info->{COLUMN_NAME};
2632         $col_name =~ s/^\"(.*)\"$/$1/;
2633
2634         $result{$col_name} = \%column_info;
2635       }
2636     } catch {
2637       %result = ();
2638     };
2639
2640     return \%result if keys %result;
2641   }
2642
2643   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2644   $sth->execute;
2645
2646 ### The acrobatics with lc names is necessary to support both the legacy
2647 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2648 ### with column names differing in cas eonly (thanks pg!)
2649
2650   my ($columns, $seen_lcs);
2651
2652   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2653     idx => scalar keys %$columns,
2654     name => $_,
2655     lc_name => lc($_),
2656   } for @{$sth->{NAME}};
2657
2658   $seen_lcs->{$_->{lc_name}} == 1
2659     and
2660   $_->{name} = $_->{lc_name}
2661     for values %$columns;
2662
2663   for ( values %$columns ) {
2664     my $inf = {
2665       data_type => $sth->{TYPE}->[$_->{idx}],
2666       size => $sth->{PRECISION}->[$_->{idx}],
2667       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2668     };
2669
2670     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2671       @{$inf}{qw( data_type  size)} = ($1, $2);
2672     }
2673
2674     $result{$_->{name}} = $inf;
2675   }
2676
2677   $sth->finish;
2678
2679   if ($dbh->can('type_info')) {
2680     for my $inf (values %result) {
2681       next if ! defined $inf->{data_type};
2682
2683       $inf->{data_type} = (
2684         (
2685           (
2686             $dbh->type_info( $inf->{data_type} )
2687               ||
2688             next
2689           )
2690             ||
2691           next
2692         )->{TYPE_NAME}
2693           ||
2694         next
2695       );
2696
2697       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2698       # needs more testing in the future...
2699       $inf->{size} -= 4 if (
2700         ( $inf->{size}||0 > 4 )
2701           and
2702         $inf->{data_type} =~ qr/^text$/i
2703       );
2704     }
2705
2706   }
2707
2708   return \%result;
2709 }
2710
2711 sub columns_info_for {
2712   my ($self, $table) = @_;
2713   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2714 }
2715
2716 =head2 last_insert_id
2717
2718 Return the row id of the last insert.
2719
2720 =cut
2721
2722 sub _dbh_last_insert_id {
2723     my ($self, $dbh, $source, $col) = @_;
2724
2725     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2726
2727     return $id if defined $id;
2728
2729     my $class = ref $self;
2730     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2731 }
2732
2733 sub last_insert_id {
2734   my $self = shift;
2735   $self->_dbh_last_insert_id ($self->_dbh, @_);
2736 }
2737
2738 =head2 _native_data_type
2739
2740 =over 4
2741
2742 =item Arguments: $type_name
2743
2744 =back
2745
2746 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2747 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2748 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2749
2750 The default implementation returns C<undef>, implement in your Storage driver if
2751 you need this functionality.
2752
2753 Should map types from other databases to the native RDBMS type, for example
2754 C<VARCHAR2> to C<VARCHAR>.
2755
2756 Types with modifiers should map to the underlying data type. For example,
2757 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2758
2759 Composite types should map to the container type, for example
2760 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2761
2762 =cut
2763
2764 sub _native_data_type {
2765   #my ($self, $data_type) = @_;
2766   return undef
2767 }
2768
2769 # Check if placeholders are supported at all
2770 sub _determine_supports_placeholders {
2771   my $self = shift;
2772   my $dbh  = $self->_get_dbh;
2773
2774   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2775   # but it is inaccurate more often than not
2776   return try {
2777     local $dbh->{PrintError} = 0;
2778     local $dbh->{RaiseError} = 1;
2779     $dbh->do('select ?', {}, 1);
2780     1;
2781   }
2782   catch {
2783     0;
2784   };
2785 }
2786
2787 # Check if placeholders bound to non-string types throw exceptions
2788 #
2789 sub _determine_supports_typeless_placeholders {
2790   my $self = shift;
2791   my $dbh  = $self->_get_dbh;
2792
2793   return try {
2794     local $dbh->{PrintError} = 0;
2795     local $dbh->{RaiseError} = 1;
2796     # this specifically tests a bind that is NOT a string
2797     $dbh->do('select 1 where 1 = ?', {}, 1);
2798     1;
2799   }
2800   catch {
2801     0;
2802   };
2803 }
2804
2805 =head2 sqlt_type
2806
2807 Returns the database driver name.
2808
2809 =cut
2810
2811 sub sqlt_type {
2812   shift->_get_dbh->{Driver}->{Name};
2813 }
2814
2815 =head2 bind_attribute_by_data_type
2816
2817 Given a datatype from column info, returns a database specific bind
2818 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2819 let the database planner just handle it.
2820
2821 This method is always called after the driver has been determined and a DBI
2822 connection has been established. Therefore you can refer to C<DBI::$constant>
2823 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2824 the correct modules.
2825
2826 =cut
2827
2828 sub bind_attribute_by_data_type {
2829     return;
2830 }
2831
2832 =head2 is_datatype_numeric
2833
2834 Given a datatype from column_info, returns a boolean value indicating if
2835 the current RDBMS considers it a numeric value. This controls how
2836 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2837 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2838 be performed instead of the usual C<eq>.
2839
2840 =cut
2841
2842 sub is_datatype_numeric {
2843   #my ($self, $dt) = @_;
2844
2845   return 0 unless $_[1];
2846
2847   $_[1] =~ /^ (?:
2848     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2849   ) $/ix;
2850 }
2851
2852
2853 =head2 create_ddl_dir
2854
2855 =over 4
2856
2857 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2858
2859 =back
2860
2861 Creates a SQL file based on the Schema, for each of the specified
2862 database engines in C<\@databases> in the given directory.
2863 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2864
2865 Given a previous version number, this will also create a file containing
2866 the ALTER TABLE statements to transform the previous schema into the
2867 current one. Note that these statements may contain C<DROP TABLE> or
2868 C<DROP COLUMN> statements that can potentially destroy data.
2869
2870 The file names are created using the C<ddl_filename> method below, please
2871 override this method in your schema if you would like a different file
2872 name format. For the ALTER file, the same format is used, replacing
2873 $version in the name with "$preversion-$version".
2874
2875 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2876 The most common value for this would be C<< { add_drop_table => 1 } >>
2877 to have the SQL produced include a C<DROP TABLE> statement for each table
2878 created. For quoting purposes supply C<quote_identifiers>.
2879
2880 If no arguments are passed, then the following default values are assumed:
2881
2882 =over 4
2883
2884 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2885
2886 =item version    - $schema->schema_version
2887
2888 =item directory  - './'
2889
2890 =item preversion - <none>
2891
2892 =back
2893
2894 By default, C<\%sqlt_args> will have
2895
2896  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2897
2898 merged with the hash passed in. To disable any of those features, pass in a
2899 hashref like the following
2900
2901  { ignore_constraint_names => 0, # ... other options }
2902
2903
2904 WARNING: You are strongly advised to check all SQL files created, before applying
2905 them.
2906
2907 =cut
2908
2909 sub create_ddl_dir {
2910   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2911
2912   unless ($dir) {
2913     carp "No directory given, using ./\n";
2914     $dir = './';
2915   } else {
2916       -d $dir
2917         or
2918       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2919         or
2920       $self->throw_exception(
2921         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2922       );
2923   }
2924
2925   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2926
2927   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2928   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2929
2930   my $schema_version = $schema->schema_version || '1.x';
2931   $version ||= $schema_version;
2932
2933   $sqltargs = {
2934     add_drop_table => 1,
2935     ignore_constraint_names => 1,
2936     ignore_index_names => 1,
2937     quote_identifiers => $self->sql_maker->_quoting_enabled,
2938     %{$sqltargs || {}}
2939   };
2940
2941   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2942     $self->throw_exception("Can't create a ddl file without $missing");
2943   }
2944
2945   my $sqlt = SQL::Translator->new( $sqltargs );
2946
2947   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2948   my $sqlt_schema = $sqlt->translate({ data => $schema })
2949     or $self->throw_exception ($sqlt->error);
2950
2951   foreach my $db (@$databases) {
2952     $sqlt->reset();
2953     $sqlt->{schema} = $sqlt_schema;
2954     $sqlt->producer($db);
2955
2956     my $file;
2957     my $filename = $schema->ddl_filename($db, $version, $dir);
2958     if (-e $filename && ($version eq $schema_version )) {
2959       # if we are dumping the current version, overwrite the DDL
2960       carp "Overwriting existing DDL file - $filename";
2961       unlink($filename);
2962     }
2963
2964     my $output = $sqlt->translate;
2965     if(!$output) {
2966       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2967       next;
2968     }
2969     if(!open($file, ">$filename")) {
2970       $self->throw_exception("Can't open $filename for writing ($!)");
2971       next;
2972     }
2973     print $file $output;
2974     close($file);
2975
2976     next unless ($preversion);
2977
2978     require SQL::Translator::Diff;
2979
2980     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2981     if(!-e $prefilename) {
2982       carp("No previous schema file found ($prefilename)");
2983       next;
2984     }
2985
2986     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2987     if(-e $difffile) {
2988       carp("Overwriting existing diff file - $difffile");
2989       unlink($difffile);
2990     }
2991
2992     my $source_schema;
2993     {
2994       my $t = SQL::Translator->new($sqltargs);
2995       $t->debug( 0 );
2996       $t->trace( 0 );
2997
2998       $t->parser( $db )
2999         or $self->throw_exception ($t->error);
3000
3001       my $out = $t->translate( $prefilename )
3002         or $self->throw_exception ($t->error);
3003
3004       $source_schema = $t->schema;
3005
3006       $source_schema->name( $prefilename )
3007         unless ( $source_schema->name );
3008     }
3009
3010     # The "new" style of producers have sane normalization and can support
3011     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3012     # And we have to diff parsed SQL against parsed SQL.
3013     my $dest_schema = $sqlt_schema;
3014
3015     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3016       my $t = SQL::Translator->new($sqltargs);
3017       $t->debug( 0 );
3018       $t->trace( 0 );
3019
3020       $t->parser( $db )
3021         or $self->throw_exception ($t->error);
3022
3023       my $out = $t->translate( $filename )
3024         or $self->throw_exception ($t->error);
3025
3026       $dest_schema = $t->schema;
3027
3028       $dest_schema->name( $filename )
3029         unless $dest_schema->name;
3030     }
3031
3032     my $diff = do {
3033       # FIXME - this is a terrible workaround for
3034       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3035       # Fixing it in this sloppy manner so that we don't hve to
3036       # lockstep an SQLT release as well. Needs to be removed at
3037       # some point, and SQLT dep bumped
3038       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3039         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3040
3041       SQL::Translator::Diff::schema_diff($source_schema, $db,
3042                                          $dest_schema,   $db,
3043                                          $sqltargs
3044                                        );
3045     };
3046
3047     if(!open $file, ">$difffile") {
3048       $self->throw_exception("Can't write to $difffile ($!)");
3049       next;
3050     }
3051     print $file $diff;
3052     close($file);
3053   }
3054 }
3055
3056 =head2 deployment_statements
3057
3058 =over 4
3059
3060 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3061
3062 =back
3063
3064 Returns the statements used by L<DBIx::Class::Storage/deploy>
3065 and L<DBIx::Class::Schema/deploy>.
3066
3067 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3068 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3069
3070 C<$directory> is used to return statements from files in a previously created
3071 L</create_ddl_dir> directory and is optional. The filenames are constructed
3072 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3073
3074 If no C<$directory> is specified then the statements are constructed on the
3075 fly using L<SQL::Translator> and C<$version> is ignored.
3076
3077 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3078
3079 =cut
3080
3081 sub deployment_statements {
3082   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3083   $type ||= $self->sqlt_type;
3084   $version ||= $schema->schema_version || '1.x';
3085   $dir ||= './';
3086   my $filename = $schema->ddl_filename($type, $version, $dir);
3087   if(-f $filename)
3088   {
3089       # FIXME replace this block when a proper sane sql parser is available
3090       my $file;
3091       open($file, "<$filename")
3092         or $self->throw_exception("Can't open $filename ($!)");
3093       my @rows = <$file>;
3094       close($file);
3095       return join('', @rows);
3096   }
3097
3098   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3099     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3100   }
3101
3102   # sources needs to be a parser arg, but for simplicity allow at top level
3103   # coming in
3104   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3105       if exists $sqltargs->{sources};
3106
3107   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3108     unless exists $sqltargs->{quote_identifiers};
3109
3110   my $tr = SQL::Translator->new(
3111     producer => "SQL::Translator::Producer::${type}",
3112     %$sqltargs,
3113     parser => 'SQL::Translator::Parser::DBIx::Class',
3114     data => $schema,
3115   );
3116
3117   return preserve_context {
3118     $tr->translate
3119   } after => sub {
3120     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3121       unless defined $_[0];
3122   };
3123 }
3124
3125 # FIXME deploy() currently does not accurately report sql errors
3126 # Will always return true while errors are warned
3127 sub deploy {
3128   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3129   my $deploy = sub {
3130     my $line = shift;
3131     return if(!$line);
3132     return if($line =~ /^--/);
3133     # next if($line =~ /^DROP/m);
3134     return if($line =~ /^BEGIN TRANSACTION/m);
3135     return if($line =~ /^COMMIT/m);
3136     return if $line =~ /^\s+$/; # skip whitespace only
3137     $self->_query_start($line);
3138     try {
3139       # do a dbh_do cycle here, as we need some error checking in
3140       # place (even though we will ignore errors)
3141       $self->dbh_do (sub { $_[1]->do($line) });
3142     } catch {
3143       carp qq{$_ (running "${line}")};
3144     };
3145     $self->_query_end($line);
3146   };
3147   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3148   if (@statements > 1) {
3149     foreach my $statement (@statements) {
3150       $deploy->( $statement );
3151     }
3152   }
3153   elsif (@statements == 1) {
3154     # split on single line comments and end of statements
3155     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3156       $deploy->( $line );
3157     }
3158   }
3159 }
3160
3161 =head2 datetime_parser
3162
3163 Returns the datetime parser class
3164
3165 =cut
3166
3167 sub datetime_parser {
3168   my $self = shift;
3169   return $self->{datetime_parser} ||= do {
3170     $self->build_datetime_parser(@_);
3171   };
3172 }
3173
3174 =head2 datetime_parser_type
3175
3176 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3177
3178 =head2 build_datetime_parser
3179
3180 See L</datetime_parser>
3181
3182 =cut
3183
3184 sub build_datetime_parser {
3185   my $self = shift;
3186   my $type = $self->datetime_parser_type(@_);
3187   return $type;
3188 }
3189
3190
3191 =head2 is_replicating
3192
3193 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3194 replicate from a master database.  Default is undef, which is the result
3195 returned by databases that don't support replication.
3196
3197 =cut
3198
3199 sub is_replicating {
3200     return;
3201
3202 }
3203
3204 =head2 lag_behind_master
3205
3206 Returns a number that represents a certain amount of lag behind a master db
3207 when a given storage is replicating.  The number is database dependent, but
3208 starts at zero and increases with the amount of lag. Default in undef
3209
3210 =cut
3211
3212 sub lag_behind_master {
3213     return;
3214 }
3215
3216 =head2 relname_to_table_alias
3217
3218 =over 4
3219
3220 =item Arguments: $relname, $join_count
3221
3222 =item Return Value: $alias
3223
3224 =back
3225
3226 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3227 queries.
3228
3229 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3230 way these aliases are named.
3231
3232 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3233 otherwise C<"$relname">.
3234
3235 =cut
3236
3237 sub relname_to_table_alias {
3238   my ($self, $relname, $join_count) = @_;
3239
3240   my $alias = ($join_count && $join_count > 1 ?
3241     join('_', $relname, $join_count) : $relname);
3242
3243   return $alias;
3244 }
3245
3246 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3247 # version and it may be necessary to amend or override it for a specific storage
3248 # if such binds are necessary.
3249 sub _max_column_bytesize {
3250   my ($self, $attr) = @_;
3251
3252   my $max_size;
3253
3254   if ($attr->{sqlt_datatype}) {
3255     my $data_type = lc($attr->{sqlt_datatype});
3256
3257     if ($attr->{sqlt_size}) {
3258
3259       # String/sized-binary types
3260       if ($data_type =~ /^(?:
3261           l? (?:var)? char(?:acter)? (?:\s*varying)?
3262             |
3263           (?:var)? binary (?:\s*varying)?
3264             |
3265           raw
3266         )\b/x
3267       ) {
3268         $max_size = $attr->{sqlt_size};
3269       }
3270       # Other charset/unicode types, assume scale of 4
3271       elsif ($data_type =~ /^(?:
3272           national \s* character (?:\s*varying)?
3273             |
3274           nchar
3275             |
3276           univarchar
3277             |
3278           nvarchar
3279         )\b/x
3280       ) {
3281         $max_size = $attr->{sqlt_size} * 4;
3282       }
3283     }
3284
3285     if (!$max_size and !$self->_is_lob_type($data_type)) {
3286       $max_size = 100 # for all other (numeric?) datatypes
3287     }
3288   }
3289
3290   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3291 }
3292
3293 # Determine if a data_type is some type of BLOB
3294 sub _is_lob_type {
3295   my ($self, $data_type) = @_;
3296   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3297     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3298                                   |varchar|character\s*varying|nvarchar
3299                                   |national\s*character\s*varying))?\z/xi);
3300 }
3301
3302 sub _is_binary_lob_type {
3303   my ($self, $data_type) = @_;
3304   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3305     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3306 }
3307
3308 sub _is_text_lob_type {
3309   my ($self, $data_type) = @_;
3310   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3311     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3312                         |national\s*character\s*varying))\z/xi);
3313 }
3314
3315 # Determine if a data_type is some type of a binary type
3316 sub _is_binary_type {
3317   my ($self, $data_type) = @_;
3318   $data_type && ($self->_is_binary_lob_type($data_type)
3319     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3320 }
3321
3322 1;
3323
3324 =head1 USAGE NOTES
3325
3326 =head2 DBIx::Class and AutoCommit
3327
3328 DBIx::Class can do some wonderful magic with handling exceptions,
3329 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3330 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3331 transaction support.
3332
3333 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3334 in an assumed transaction between commits, and you're telling us you'd
3335 like to manage that manually.  A lot of the magic protections offered by
3336 this module will go away.  We can't protect you from exceptions due to database
3337 disconnects because we don't know anything about how to restart your
3338 transactions.  You're on your own for handling all sorts of exceptional
3339 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3340 be with raw DBI.
3341
3342 =head1 FURTHER QUESTIONS?
3343
3344 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3345
3346 =head1 COPYRIGHT AND LICENSE
3347
3348 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3349 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3350 redistribute it and/or modify it under the same terms as the
3351 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.