lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use base 'DBIx::Class::Storage';
   4
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use SQL::Abstract::Limit;
   9 use DBIx::Class::Storage::DBI::Cursor;
  10 use IO::File;
  11 use Carp::Clan qw/DBIx::Class/;
  12
  13 BEGIN {
  14
  15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  16
  17 use base qw/SQL::Abstract::Limit/;
  18
  19 sub select {
  20   my ($self, $table, $fields, $where, $order, @rest) = @_;
  21   $table = $self->_quote($table) unless ref($table);
  22   @rest = (-1) unless defined $rest[0];
  23   local $self->{having_bind} = [];
  24   my ($sql, @ret) = $self->SUPER::select(
  25     $table, $self->_recurse_fields($fields), $where, $order, @rest
  26   );
  27   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  28 }
  29
  30 sub insert {
  31   my $self = shift;
  32   my $table = shift;
  33   $table = $self->_quote($table) unless ref($table);
  34   $self->SUPER::insert($table, @_);
  35 }
  36
  37 sub update {
  38   my $self = shift;
  39   my $table = shift;
  40   $table = $self->_quote($table) unless ref($table);
  41   $self->SUPER::update($table, @_);
  42 }
  43
  44 sub delete {
  45   my $self = shift;
  46   my $table = shift;
  47   $table = $self->_quote($table) unless ref($table);
  48   $self->SUPER::delete($table, @_);
  49 }
  50
  51 sub _emulate_limit {
  52   my $self = shift;
  53   if ($_[3] == -1) {
  54     return $_[1].$self->_order_by($_[2]);
  55   } else {
  56     return $self->SUPER::_emulate_limit(@_);
  57   }
  58 }
  59
  60 sub _recurse_fields {
  61   my ($self, $fields) = @_;
  62   my $ref = ref $fields;
  63   return $self->_quote($fields) unless $ref;
  64   return $$fields if $ref eq 'SCALAR';
  65
  66   if ($ref eq 'ARRAY') {
  67     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  68   } elsif ($ref eq 'HASH') {
  69     foreach my $func (keys %$fields) {
  70       return $self->_sqlcase($func)
  71         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  72     }
  73   }
  74 }
  75
  76 sub _order_by {
  77   my $self = shift;
  78   my $ret = '';
  79   my @extra;
  80   if (ref $_[0] eq 'HASH') {
  81     if (defined $_[0]->{group_by}) {
  82       $ret = $self->_sqlcase(' group by ')
  83                .$self->_recurse_fields($_[0]->{group_by});
  84     }
  85     if (defined $_[0]->{having}) {
  86       my $frag;
  87       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  88       push(@{$self->{having_bind}}, @extra);
  89       $ret .= $self->_sqlcase(' having ').$frag;
  90     }
  91     if (defined $_[0]->{order_by}) {
  92       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  93     }
  94   } elsif(ref $_[0] eq 'SCALAR') {
  95     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  96   } else {
  97     $ret = $self->SUPER::_order_by(@_);
  98   }
  99   return $ret;
 100 }
 101
 102 sub _order_directions {
 103   my ($self, $order) = @_;
 104   $order = $order->{order_by} if ref $order eq 'HASH';
 105   return $self->SUPER::_order_directions($order);
 106 }
 107
 108 sub _table {
 109   my ($self, $from) = @_;
 110   if (ref $from eq 'ARRAY') {
 111     return $self->_recurse_from(@$from);
 112   } elsif (ref $from eq 'HASH') {
 113     return $self->_make_as($from);
 114   } else {
 115     return $from; # would love to quote here but _table ends up getting called
 116                   # twice during an ->select without a limit clause due to
 117                   # the way S::A::Limit->select works. should maybe consider
 118                   # bypassing this and doing S::A::select($self, ...) in
 119                   # our select method above. meantime, quoting shims have
 120                   # been added to select/insert/update/delete here
 121   }
 122 }
 123
 124 sub _recurse_from {
 125   my ($self, $from, @join) = @_;
 126   my @sqlf;
 127   push(@sqlf, $self->_make_as($from));
 128   foreach my $j (@join) {
 129     my ($to, $on) = @$j;
 130
 131     # check whether a join type exists
 132     my $join_clause = '';
 133     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 134       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 135     } else {
 136       $join_clause = ' JOIN ';
 137     }
 138     push(@sqlf, $join_clause);
 139
 140     if (ref $to eq 'ARRAY') {
 141       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 142     } else {
 143       push(@sqlf, $self->_make_as($to));
 144     }
 145     push(@sqlf, ' ON ', $self->_join_condition($on));
 146   }
 147   return join('', @sqlf);
 148 }
 149
 150 sub _make_as {
 151   my ($self, $from) = @_;
 152   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 153                      reverse each %{$self->_skip_options($from)});
 154 }
 155
 156 sub _skip_options {
 157   my ($self, $hash) = @_;
 158   my $clean_hash = {};
 159   $clean_hash->{$_} = $hash->{$_}
 160     for grep {!/^-/} keys %$hash;
 161   return $clean_hash;
 162 }
 163
 164 sub _join_condition {
 165   my ($self, $cond) = @_;
 166   if (ref $cond eq 'HASH') {
 167     my %j;
 168     for (keys %$cond) {
 169       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 170     };
 171     return $self->_recurse_where(\%j);
 172   } elsif (ref $cond eq 'ARRAY') {
 173     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 174   } else {
 175     die "Can't handle this yet!";
 176   }
 177 }
 178
 179 sub _quote {
 180   my ($self, $label) = @_;
 181   return '' unless defined $label;
 182   return "*" if $label eq '*';
 183   return $label unless $self->{quote_char};
 184   if(ref $self->{quote_char} eq "ARRAY"){
 185     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 186       if !defined $self->{name_sep};
 187     my $sep = $self->{name_sep};
 188     return join($self->{name_sep},
 189         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 190        split(/\Q$sep\E/,$label));
 191   }
 192   return $self->SUPER::_quote($label);
 193 }
 194
 195 sub _RowNum {
 196    my $self = shift;
 197    my $c;
 198    $_[0] =~ s/SELECT (.*?) FROM/
 199      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 200    $self->SUPER::_RowNum(@_);
 201 }
 202
 203 # Accessor for setting limit dialect. This is useful
 204 # for JDBC-bridge among others where the remote SQL-dialect cannot
 205 # be determined by the name of the driver alone.
 206 #
 207 sub limit_dialect {
 208     my $self = shift;
 209     $self->{limit_dialect} = shift if @_;
 210     return $self->{limit_dialect};
 211 }
 212
 213 sub quote_char {
 214     my $self = shift;
 215     $self->{quote_char} = shift if @_;
 216     return $self->{quote_char};
 217 }
 218
 219 sub name_sep {
 220     my $self = shift;
 221     $self->{name_sep} = shift if @_;
 222     return $self->{name_sep};
 223 }
 224
 225
 226
 227
 228 package DBIx::Class::Storage::DBI::DebugCallback;
 229
 230 sub print {
 231   my ($self, $string) = @_;
 232   $string =~ m/^(\w+)/;
 233   ${$self}->($1, $string);
 234 }
 235
 236 } # End of BEGIN block
 237
 238 use base qw/DBIx::Class/;
 239
 240 __PACKAGE__->load_components(qw/AccessorGroup/);
 241
 242 __PACKAGE__->mk_group_accessors('simple' =>
 243   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugfh
 244      cursor on_connect_do transaction_depth/);
 245
 246 sub new {
 247   my $new = bless({}, ref $_[0] || $_[0]);
 248   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 249   $new->transaction_depth(0);
 250   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 251      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 252     $new->debugfh(IO::File->new($1, 'w'))
 253       or $new->throw_exception("Cannot open trace file $1");
 254   } else {
 255     $new->debugfh(IO::File->new('>&STDERR'));
 256   }
 257   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 258   return $new;
 259 }
 260
 261 sub throw_exception {
 262   my ($self, $msg) = @_;
 263   croak($msg);
 264 }
 265
 266 =head1 NAME
 267
 268 DBIx::Class::Storage::DBI - DBI storage handler
 269
 270 =head1 SYNOPSIS
 271
 272 =head1 DESCRIPTION
 273
 274 This class represents the connection to the database
 275
 276 =head1 METHODS
 277
 278 =cut
 279
 280 =head2 connect_info
 281
 282 Connection information arrayref.  Can either be the same arguments
 283 one would pass to DBI->connect, or a code-reference which returns
 284 a connected database handle.  In either case, there is an optional
 285 final element in the arrayref, which can hold a hashref of
 286 connection-specific Storage::DBI options.  These include
 287 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 288 C<quote_char>, and C<name_sep>.  Examples:
 289
 290   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 291   ->connect_info(sub { DBI->connect(...) });
 292   ->connect_info([ 'dbi:Pg:dbname=foo',
 293                    'postgres',
 294                    '',
 295                    { AutoCommit => 0 },
 296                    { quote_char => q{`}, name_sep => q{@} },
 297                  ]);
 298
 299 =head2 on_connect_do
 300
 301 Executes the sql statements given as a listref on every db connect.
 302
 303 =head2 debug
 304
 305 Causes SQL trace information to be emitted on C<debugfh> filehandle
 306 (or C<STDERR> if C<debugfh> has not specifically been set).
 307
 308 =head2 debugfh
 309
 310 Sets or retrieves the filehandle used for trace/debug output.  This
 311 should be an IO::Handle compatible object (only the C<print> method is
 312 used).  Initially set to be STDERR - although see information on the
 313 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 314
 315 =head2 debugcb
 316
 317 Sets a callback to be executed each time a statement is run; takes a sub
 318 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 319 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 320 be printed.
 321
 322 =cut
 323
 324 sub debugcb {
 325   my ($self, $cb) = @_;
 326   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 327   $self->debugfh($cb_obj);
 328 }
 329
 330 sub disconnect {
 331   my ($self) = @_;
 332
 333   if( $self->connected ) {
 334     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 335     $self->_dbh->disconnect;
 336     $self->_dbh(undef);
 337   }
 338 }
 339
 340 sub connected {
 341   my ($self) = @_;
 342
 343   if(my $dbh = $self->_dbh) {
 344       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 345           $self->_sql_maker(undef);
 346           return $self->_dbh(undef);
 347       }
 348       elsif($self->_conn_pid != $$) {
 349           $self->_dbh->{InactiveDestroy} = 1;
 350           $self->_sql_maker(undef);
 351           return $self->_dbh(undef)
 352       }
 353       return ($dbh->FETCH('Active') && $dbh->ping);
 354   }
 355
 356   return 0;
 357 }
 358
 359 sub ensure_connected {
 360   my ($self) = @_;
 361
 362   unless ($self->connected) {
 363     $self->_populate_dbh;
 364   }
 365 }
 366
 367 =head2 dbh
 368
 369 Returns the dbh - a data base handle of class L<DBI>.
 370
 371 =cut
 372
 373 sub dbh {
 374   my ($self) = @_;
 375
 376   $self->ensure_connected;
 377   return $self->_dbh;
 378 }
 379
 380 sub sql_maker {
 381   my ($self) = @_;
 382   unless ($self->_sql_maker) {
 383     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 384   }
 385   return $self->_sql_maker;
 386 }
 387
 388 sub connect_info {
 389     my ($self, $info_arg) = @_;
 390
 391     if($info_arg) {
 392         my $info = [ @$info_arg ]; # copy because we can alter it
 393         my $last_info = $info->[-1];
 394         if(ref $last_info eq 'HASH') {
 395             my $used;
 396             if(my $on_connect_do = $last_info->{on_connect_do}) {
 397                $used = 1;
 398                $self->on_connect_do($on_connect_do);
 399             }
 400             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 401                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 402                     $used = 1;
 403                     $self->sql_maker->$sql_maker_opt($opt_val);
 404                 }
 405             }
 406
 407             # remove our options hashref if it was there, to avoid confusing
 408             #   DBI in the case the user didn't use all 4 DBI options, as in:
 409             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 410             pop(@$info) if $used;
 411         }
 412
 413         $self->_connect_info($info);
 414     }
 415
 416     $self->_connect_info;
 417 }
 418
 419 sub _populate_dbh {
 420   my ($self) = @_;
 421   my @info = @{$self->_connect_info || []};
 422   $self->_dbh($self->_connect(@info));
 423   my $driver = $self->_dbh->{Driver}->{Name};
 424   eval "require DBIx::Class::Storage::DBI::${driver}";
 425   unless ($@) {
 426     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 427   }
 428   # if on-connect sql statements are given execute them
 429   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 430     $self->_dbh->do($sql_statement);
 431   }
 432
 433   $self->_conn_pid($$);
 434   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 435 }
 436
 437 sub _connect {
 438   my ($self, @info) = @_;
 439
 440   $self->throw_exception("You failed to provide any connection info")
 441       if !@info;
 442
 443   my ($old_connect_via, $dbh);
 444
 445   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 446       $old_connect_via = $DBI::connect_via;
 447       $DBI::connect_via = 'connect';
 448   }
 449
 450   eval {
 451     if(ref $info[0] eq 'CODE') {
 452         $dbh = &{$info[0]};
 453     }
 454     else {
 455         $dbh = DBI->connect(@info);
 456     }
 457   };
 458
 459   $DBI::connect_via = $old_connect_via if $old_connect_via;
 460
 461   if (!$dbh || $@) {
 462     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 463   }
 464
 465   $dbh;
 466 }
 467
 468 =head2 txn_begin
 469
 470 Calls begin_work on the current dbh.
 471
 472 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 473 an entire code block to be executed transactionally.
 474
 475 =cut
 476
 477 sub txn_begin {
 478   my $self = shift;
 479   if ($self->{transaction_depth}++ == 0) {
 480     my $dbh = $self->dbh;
 481     if ($dbh->{AutoCommit}) {
 482       $self->debugfh->print("BEGIN WORK\n")
 483         if ($self->debug);
 484       $dbh->begin_work;
 485     }
 486   }
 487 }
 488
 489 =head2 txn_commit
 490
 491 Issues a commit against the current dbh.
 492
 493 =cut
 494
 495 sub txn_commit {
 496   my $self = shift;
 497   if ($self->{transaction_depth} == 0) {
 498     my $dbh = $self->dbh;
 499     unless ($dbh->{AutoCommit}) {
 500       $self->debugfh->print("COMMIT\n")
 501         if ($self->debug);
 502       $dbh->commit;
 503     }
 504   }
 505   else {
 506     if (--$self->{transaction_depth} == 0) {
 507       $self->debugfh->print("COMMIT\n")
 508         if ($self->debug);
 509       $self->dbh->commit;
 510     }
 511   }
 512 }
 513
 514 =head2 txn_rollback
 515
 516 Issues a rollback against the current dbh. A nested rollback will
 517 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 518 which allows the rollback to propagate to the outermost transaction.
 519
 520 =cut
 521
 522 sub txn_rollback {
 523   my $self = shift;
 524
 525   eval {
 526     if ($self->{transaction_depth} == 0) {
 527       my $dbh = $self->dbh;
 528       unless ($dbh->{AutoCommit}) {
 529         $self->debugfh->print("ROLLBACK\n")
 530           if ($self->debug);
 531         $dbh->rollback;
 532       }
 533     }
 534     else {
 535       if (--$self->{transaction_depth} == 0) {
 536         $self->debugfh->print("ROLLBACK\n")
 537           if ($self->debug);
 538         $self->dbh->rollback;
 539       }
 540       else {
 541         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 542       }
 543     }
 544   };
 545
 546   if ($@) {
 547     my $error = $@;
 548     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 549     $error =~ /$exception_class/ and $self->throw_exception($error);
 550     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 551     $self->throw_exception($error);          # resets the transaction depth
 552   }
 553 }
 554
 555 sub _execute {
 556   my ($self, $op, $extra_bind, $ident, @args) = @_;
 557   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 558   unshift(@bind, @$extra_bind) if $extra_bind;
 559   if ($self->debug) {
 560       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 561       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 562   }
 563   my $sth = eval { $self->sth($sql,$op) };
 564
 565   if (!$sth || $@) {
 566     $self->throw_exception('no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql");
 567   }
 568
 569   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 570   my $rv;
 571   if ($sth) {
 572     $rv = eval { $sth->execute(@bind) };
 573
 574     if ($@ || !$rv) {
 575       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 576     }
 577   } else {
 578     $self->throw_exception("'$sql' did not generate a statement.");
 579   }
 580   return (wantarray ? ($rv, $sth, @bind) : $rv);
 581 }
 582
 583 sub insert {
 584   my ($self, $ident, $to_insert) = @_;
 585   $self->throw_exception(
 586     "Couldn't insert ".join(', ',
 587       map "$_ => $to_insert->{$_}", keys %$to_insert
 588     )." into ${ident}"
 589   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 590   return $to_insert;
 591 }
 592
 593 sub update {
 594   return shift->_execute('update' => [], @_);
 595 }
 596
 597 sub delete {
 598   return shift->_execute('delete' => [], @_);
 599 }
 600
 601 sub _select {
 602   my ($self, $ident, $select, $condition, $attrs) = @_;
 603   my $order = $attrs->{order_by};
 604   if (ref $condition eq 'SCALAR') {
 605     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 606   }
 607   if (exists $attrs->{group_by} || $attrs->{having}) {
 608     $order = {
 609       group_by => $attrs->{group_by},
 610       having => $attrs->{having},
 611       ($order ? (order_by => $order) : ())
 612     };
 613   }
 614   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 615   if ($attrs->{software_limit} ||
 616       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 617         $attrs->{software_limit} = 1;
 618   } else {
 619     push @args, $attrs->{rows}, $attrs->{offset};
 620   }
 621   return $self->_execute(@args);
 622 }
 623
 624 sub select {
 625   my $self = shift;
 626   my ($ident, $select, $condition, $attrs) = @_;
 627   return $self->cursor->new($self, \@_, $attrs);
 628 }
 629
 630 # Need to call finish() to work round broken DBDs
 631
 632 sub select_single {
 633   my $self = shift;
 634   my ($rv, $sth, @bind) = $self->_select(@_);
 635   my @row = $sth->fetchrow_array;
 636   $sth->finish();
 637   return @row;
 638 }
 639
 640 sub sth {
 641   my ($self, $sql) = @_;
 642   # 3 is the if_active parameter which avoids active sth re-use
 643   return $self->dbh->prepare_cached($sql, {}, 3);
 644 }
 645
 646 =head2 columns_info_for
 647
 648 Returns database type info for a given table columns.
 649
 650 =cut
 651
 652 sub columns_info_for {
 653   my ($self, $table) = @_;
 654
 655   my $dbh = $self->dbh;
 656
 657   if ($dbh->can('column_info')) {
 658     my %result;
 659     my $old_raise_err = $dbh->{RaiseError};
 660     my $old_print_err = $dbh->{PrintError};
 661     $dbh->{RaiseError} = 1;
 662     $dbh->{PrintError} = 0;
 663     eval {
 664       my $sth = $dbh->column_info( undef, undef, $table, '%' );
 665       $sth->execute();
 666       while ( my $info = $sth->fetchrow_hashref() ){
 667         my %column_info;
 668         $column_info{data_type}   = $info->{TYPE_NAME};
 669         $column_info{size}      = $info->{COLUMN_SIZE};
 670         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 671         $column_info{default_value} = $info->{COLUMN_DEF};
 672
 673         $result{$info->{COLUMN_NAME}} = \%column_info;
 674       }
 675     };
 676     $dbh->{RaiseError} = $old_raise_err;
 677     $dbh->{PrintError} = $old_print_err;
 678     return \%result if !$@;
 679   }
 680
 681   my %result;
 682   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 683   $sth->execute;
 684   my @columns = @{$sth->{NAME_lc}};
 685   for my $i ( 0 .. $#columns ){
 686     my %column_info;
 687     my $type_num = $sth->{TYPE}->[$i];
 688     my $type_name;
 689     if(defined $type_num && $dbh->can('type_info')) {
 690       my $type_info = $dbh->type_info($type_num);
 691       $type_name = $type_info->{TYPE_NAME} if $type_info;
 692     }
 693     $column_info{data_type} = $type_name ? $type_name : $type_num;
 694     $column_info{size} = $sth->{PRECISION}->[$i];
 695     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 696
 697     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 698       $column_info{data_type} = $1;
 699       $column_info{size}    = $2;
 700     }
 701
 702     $result{$columns[$i]} = \%column_info;
 703   }
 704
 705   return \%result;
 706 }
 707
 708 sub last_insert_id {
 709   my ($self, $row) = @_;
 710
 711   return $self->dbh->func('last_insert_rowid');
 712
 713 }
 714
 715 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 716
 717 sub deployment_statements {
 718   my ($self, $schema, $type, $sqltargs) = @_;
 719   $type ||= $self->sqlt_type;
 720   eval "use SQL::Translator";
 721   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 722   eval "use SQL::Translator::Parser::DBIx::Class;";
 723   $self->throw_exception($@) if $@;
 724   eval "use SQL::Translator::Producer::${type};";
 725   $self->throw_exception($@) if $@;
 726   my $tr = SQL::Translator->new(%$sqltargs);
 727   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 728   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 729 }
 730
 731 sub deploy {
 732   my ($self, $schema, $type, $sqltargs) = @_;
 733   foreach my $statement ( $self->deployment_statements($schema, $type, $sqltargs) ) {
 734     for ( split(";\n", $statement)) {
 735       $self->debugfh->print("$_\n") if $self->debug;
 736       $self->dbh->do($_) or warn "SQL was:\n $_";
 737     }
 738   }
 739 }
 740
 741 sub DESTROY { shift->disconnect }
 742
 743 1;
 744
 745 =head1 ENVIRONMENT VARIABLES
 746
 747 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 748
 749 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 750 is produced (as when the L<debug> method is set).
 751
 752 If the value is of the form C<1=/path/name> then the trace output is
 753 written to the file C</path/name>.
 754
 755 =head1 AUTHORS
 756
 757 Matt S. Trout <mst@shadowcatsystems.co.uk>
 758
 759 Andy Grundman <andy@hybridized.org>
 760
 761 =head1 LICENSE
 762
 763 You may distribute this code under the same terms as Perl itself.
 764
 765 =cut
 766