lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use Context::Preserve 'preserve_context';
  13 use Try::Tiny;
  14 use SQL::Abstract qw(is_plain_value is_literal_value);
  15 use DBIx::Class::_Util qw(
  16   quote_sub perlstring serialize dump_value
  17   dbic_internal_try
  18   detected_reinvoked_destructor scope_guard
  19   mkdir_p
  20 );
  21 use namespace::clean;
  22
  23 # default cursor class, overridable in connect_info attributes
  24 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  25
  26 __PACKAGE__->mk_group_accessors('inherited' => qw/
  27   sql_limit_dialect sql_quote_char sql_name_sep
  28 /);
  29
  30 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  31
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  33 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  34
  35 __PACKAGE__->sql_name_sep('.');
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/
  38   _connect_info _dbic_connect_attributes _driver_determined
  39   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  40   _perform_autoinc_retrieval _autoinc_supplied_for_op
  41 /);
  42
  43 # the values for these accessors are picked out (and deleted) from
  44 # the attribute hashref passed to connect_info
  45 my @storage_options = qw/
  46   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  47   disable_sth_caching unsafe auto_savepoint
  48 /;
  49 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  50
  51
  52 # capability definitions, using a 2-tiered accessor system
  53 # The rationale is:
  54 #
  55 # A driver/user may define _use_X, which blindly without any checks says:
  56 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  57 # type accessor)
  58 #
  59 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  60 # accessor, which in turn calls _determine_supports_X, and stores the return
  61 # in a special slot on the storage object, which is wiped every time a $dbh
  62 # reconnection takes place (it is not guaranteed that upon reconnection we
  63 # will get the same rdbms version). _determine_supports_X does not need to
  64 # exist on a driver, as we ->can for it before calling.
  65
  66 my @capabilities = (qw/
  67   insert_returning
  68   insert_returning_bound
  69
  70   multicolumn_in
  71
  72   placeholders
  73   typeless_placeholders
  74
  75   join_optimizer
  76 /);
  77 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  78 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  79
  80 # on by default, not strictly a capability (pending rewrite)
  81 __PACKAGE__->_use_join_optimizer (1);
  82 sub _determine_supports_join_optimizer { 1 };
  83
  84 # Each of these methods need _determine_driver called before itself
  85 # in order to function reliably. We also need to separate accessors
  86 # from plain old method calls, since an accessor called as a setter
  87 # does *not* need the driver determination loop fired (and in fact
  88 # can produce hard to find bugs, like e.g. losing on_connect_*
  89 # semantics on fresh connections)
  90 #
  91 # The construct below is simply a parameterized around()
  92 my $storage_accessor_idx = { map { $_ => 1 } qw(
  93   sqlt_type
  94   datetime_parser_type
  95
  96   sql_maker
  97   cursor_class
  98 )};
  99 for my $meth (keys %$storage_accessor_idx, qw(
 100   deployment_statements
 101
 102   build_datetime_parser
 103
 104   txn_begin
 105
 106   insert
 107   update
 108   delete
 109   select
 110   select_single
 111
 112   _insert_bulk
 113
 114   with_deferred_fk_checks
 115
 116   get_use_dbms_capability
 117   get_dbms_capability
 118
 119   _server_info
 120   _get_server_version
 121 )) {
 122
 123   my $orig = __PACKAGE__->can ($meth)
 124     or die "$meth is not a ::Storage::DBI method!";
 125
 126   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 127
 128   quote_sub
 129     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 130
 131     if (
 132       # if this is an actual *setter* - just set it, no need to connect
 133       # and determine the driver
 134       !( %1$s and @_ > 1 )
 135         and
 136       # only fire when invoked on an instance, a valid class-based invocation
 137       # would e.g. be setting a default for an inherited accessor
 138       ref $_[0]
 139         and
 140       ! $_[0]->{_driver_determined}
 141         and
 142       ! $_[0]->{_in_determine_driver}
 143         and
 144       # Only try to determine stuff if we have *something* that either is or can
 145       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 146       # to still be marginally useful
 147       $_[0]->_dbi_connect_info->[0]
 148     ) {
 149       $_[0]->_determine_driver;
 150
 151       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 152       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 153
 154       my $cref = $_[0]->can(%2$s);
 155       goto $cref;
 156     }
 157
 158     goto $orig;
 159 EOC
 160 }
 161
 162 =head1 NAME
 163
 164 DBIx::Class::Storage::DBI - DBI storage handler
 165
 166 =head1 SYNOPSIS
 167
 168   my $schema = MySchema->connect('dbi:SQLite:my.db');
 169
 170   $schema->storage->debug(1);
 171
 172   my @stuff = $schema->storage->dbh_do(
 173     sub {
 174       my ($storage, $dbh, @args) = @_;
 175       $dbh->do("DROP TABLE authors");
 176     },
 177     @column_list
 178   );
 179
 180   $schema->resultset('Book')->search({
 181      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 182   });
 183
 184 =head1 DESCRIPTION
 185
 186 This class represents the connection to an RDBMS via L<DBI>.  See
 187 L<DBIx::Class::Storage> for general information.  This pod only
 188 documents DBI-specific methods and behaviors.
 189
 190 =head1 METHODS
 191
 192 =cut
 193
 194 sub new {
 195   my $new = shift->next::method(@_);
 196
 197   $new->_sql_maker_opts({});
 198   $new->_dbh_details({});
 199   $new->{_in_do_block} = 0;
 200
 201   # read below to see what this does
 202   $new->_arm_global_destructor;
 203
 204   $new;
 205 }
 206
 207 # This is hack to work around perl shooting stuff in random
 208 # order on exit(). If we do not walk the remaining storage
 209 # objects in an END block, there is a *small but real* chance
 210 # of a fork()ed child to kill the parent's shared DBI handle,
 211 # *before perl reaches the DESTROY in this package*
 212 # Yes, it is ugly and effective.
 213 # Additionally this registry is used by the CLONE method to
 214 # make sure no handles are shared between threads
 215 {
 216   my %seek_and_destroy;
 217
 218   sub _arm_global_destructor {
 219
 220     # quick "garbage collection" pass - prevents the registry
 221     # from slowly growing with a bunch of undef-valued keys
 222     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 223       for keys %seek_and_destroy;
 224
 225     weaken (
 226       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 227     );
 228
 229     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 230     # collected before leaving this scope. Depending on the code above, this
 231     # may very well be just a preventive measure guarding future modifications
 232     undef;
 233   }
 234
 235   END {
 236
 237     if(
 238       ! DBIx::Class::_ENV_::BROKEN_FORK
 239         and
 240       my @instances = grep { defined $_ } values %seek_and_destroy
 241     ) {
 242       local $?; # just in case the DBI destructor changes it somehow
 243
 244       # disarm the handle if not native to this process (see comment on top)
 245       $_->_verify_pid for @instances;
 246     }
 247
 248     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 249     # collected before leaving this scope. Depending on the code above, this
 250     # may very well be just a preventive measure guarding future modifications
 251     undef;
 252   }
 253
 254   sub CLONE {
 255     # As per DBI's recommendation, DBIC disconnects all handles as
 256     # soon as possible (DBIC will reconnect only on demand from within
 257     # the thread)
 258     my @instances = grep { defined $_ } values %seek_and_destroy;
 259     %seek_and_destroy = ();
 260
 261     for (@instances) {
 262       $_->_dbh(undef);
 263       $_->disconnect;
 264
 265       # properly renumber existing refs
 266       $_->_arm_global_destructor
 267     }
 268
 269     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 270     # collected before leaving this scope. Depending on the code above, this
 271     # may very well be just a preventive measure guarding future modifications
 272     undef;
 273   }
 274 }
 275
 276 sub DESTROY {
 277   return if &detected_reinvoked_destructor;
 278
 279   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 280
 281   # some databases spew warnings on implicit disconnect
 282   return unless defined $_[0]->_dbh;
 283
 284   local $SIG{__WARN__} = sub {};
 285   $_[0]->_dbh(undef);
 286   # not calling ->disconnect here - we are being destroyed - nothing to reset
 287
 288   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 289   # collected before leaving this scope. Depending on the code above, this
 290   # may very well be just a preventive measure guarding future modifications
 291   undef;
 292 }
 293
 294 # handle pid changes correctly - do not destroy parent's connection
 295 sub _verify_pid {
 296
 297   my $pid = $_[0]->_conn_pid;
 298
 299   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 300     $dbh->{InactiveDestroy} = 1;
 301     $_[0]->_dbh(undef);
 302     $_[0]->disconnect;
 303   }
 304
 305   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 306   # collected before leaving this scope. Depending on the code above, this
 307   # may very well be just a preventive measure guarding future modifications
 308   undef;
 309 }
 310
 311 =head2 connect_info
 312
 313 This method is normally called by L<DBIx::Class::Schema/connection>, which
 314 encapsulates its argument list in an arrayref before passing them here.
 315
 316 The argument list may contain:
 317
 318 =over
 319
 320 =item *
 321
 322 The same 4-element argument set one would normally pass to
 323 L<DBI/connect>, optionally followed by
 324 L<extra attributes|/DBIx::Class specific connection attributes>
 325 recognized by DBIx::Class:
 326
 327   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 328
 329 =item *
 330
 331 A single code reference which returns a connected
 332 L<DBI database handle|DBI/connect> optionally followed by
 333 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 334 by DBIx::Class:
 335
 336   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 337
 338 =item *
 339
 340 A single hashref with all the attributes and the dsn/user/password
 341 mixed together:
 342
 343   $connect_info_args = [{
 344     dsn => $dsn,
 345     user => $user,
 346     password => $pass,
 347     %dbi_attributes,
 348     %extra_attributes,
 349   }];
 350
 351   $connect_info_args = [{
 352     dbh_maker => sub { DBI->connect (...) },
 353     %dbi_attributes,
 354     %extra_attributes,
 355   }];
 356
 357 This is particularly useful for L<Catalyst> based applications, allowing the
 358 following config (L<Config::General> style):
 359
 360   <Model::DB>
 361     schema_class   App::DB
 362     <connect_info>
 363       dsn          dbi:mysql:database=test
 364       user         testuser
 365       password     TestPass
 366       AutoCommit   1
 367     </connect_info>
 368   </Model::DB>
 369
 370 The C<dsn>/C<user>/C<password> combination can be substituted by the
 371 C<dbh_maker> key whose value is a coderef that returns a connected
 372 L<DBI database handle|DBI/connect>
 373
 374 =back
 375
 376 Please note that the L<DBI> docs recommend that you always explicitly
 377 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 378 recommends that it be set to I<1>, and that you perform transactions
 379 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 380 to I<1> if you do not do explicitly set it to zero.  This is the default
 381 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 382
 383 =head3 DBIx::Class specific connection attributes
 384
 385 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 386 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 387 the following connection options. These options can be mixed in with your other
 388 L<DBI> connection attributes, or placed in a separate hashref
 389 (C<\%extra_attributes>) as shown above.
 390
 391 Every time C<connect_info> is invoked, any previous settings for
 392 these options will be cleared before setting the new ones, regardless of
 393 whether any options are specified in the new C<connect_info>.
 394
 395
 396 =over
 397
 398 =item on_connect_do
 399
 400 Specifies things to do immediately after connecting or re-connecting to
 401 the database.  Its value may contain:
 402
 403 =over
 404
 405 =item a scalar
 406
 407 This contains one SQL statement to execute.
 408
 409 =item an array reference
 410
 411 This contains SQL statements to execute in order.  Each element contains
 412 a string or a code reference that returns a string.
 413
 414 =item a code reference
 415
 416 This contains some code to execute.  Unlike code references within an
 417 array reference, its return value is ignored.
 418
 419 =back
 420
 421 =item on_disconnect_do
 422
 423 Takes arguments in the same form as L</on_connect_do> and executes them
 424 immediately before disconnecting from the database.
 425
 426 Note, this only runs if you explicitly call L</disconnect> on the
 427 storage object.
 428
 429 =item on_connect_call
 430
 431 A more generalized form of L</on_connect_do> that calls the specified
 432 C<connect_call_METHOD> methods in your storage driver.
 433
 434   on_connect_do => 'select 1'
 435
 436 is equivalent to:
 437
 438   on_connect_call => [ [ do_sql => 'select 1' ] ]
 439
 440 Its values may contain:
 441
 442 =over
 443
 444 =item a scalar
 445
 446 Will call the C<connect_call_METHOD> method.
 447
 448 =item a code reference
 449
 450 Will execute C<< $code->($storage) >>
 451
 452 =item an array reference
 453
 454 Each value can be a method name or code reference.
 455
 456 =item an array of arrays
 457
 458 For each array, the first item is taken to be the C<connect_call_> method name
 459 or code reference, and the rest are parameters to it.
 460
 461 =back
 462
 463 Some predefined storage methods you may use:
 464
 465 =over
 466
 467 =item do_sql
 468
 469 Executes a SQL string or a code reference that returns a SQL string. This is
 470 what L</on_connect_do> and L</on_disconnect_do> use.
 471
 472 It can take:
 473
 474 =over
 475
 476 =item a scalar
 477
 478 Will execute the scalar as SQL.
 479
 480 =item an arrayref
 481
 482 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 483 attributes hashref and bind values.
 484
 485 =item a code reference
 486
 487 Will execute C<< $code->($storage) >> and execute the return array refs as
 488 above.
 489
 490 =back
 491
 492 =item datetime_setup
 493
 494 Execute any statements necessary to initialize the database session to return
 495 and accept datetime/timestamp values used with
 496 L<DBIx::Class::InflateColumn::DateTime>.
 497
 498 Only necessary for some databases, see your specific storage driver for
 499 implementation details.
 500
 501 =back
 502
 503 =item on_disconnect_call
 504
 505 Takes arguments in the same form as L</on_connect_call> and executes them
 506 immediately before disconnecting from the database.
 507
 508 Calls the C<disconnect_call_METHOD> methods as opposed to the
 509 C<connect_call_METHOD> methods called by L</on_connect_call>.
 510
 511 Note, this only runs if you explicitly call L</disconnect> on the
 512 storage object.
 513
 514 =item disable_sth_caching
 515
 516 If set to a true value, this option will disable the caching of
 517 statement handles via L<DBI/prepare_cached>.
 518
 519 =item limit_dialect
 520
 521 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 522 default L</sql_limit_dialect> setting of the storage (if any). For a list
 523 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 524
 525 =item quote_names
 526
 527 When true automatically sets L</quote_char> and L</name_sep> to the characters
 528 appropriate for your particular RDBMS. This option is preferred over specifying
 529 L</quote_char> directly.
 530
 531 =item quote_char
 532
 533 Specifies what characters to use to quote table and column names.
 534
 535 C<quote_char> expects either a single character, in which case is it
 536 is placed on either side of the table/column name, or an arrayref of length
 537 2 in which case the table/column name is placed between the elements.
 538
 539 For example under MySQL you should use C<< quote_char => '`' >>, and for
 540 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 541
 542 =item name_sep
 543
 544 This parameter is only useful in conjunction with C<quote_char>, and is used to
 545 specify the character that separates elements (schemas, tables, columns) from
 546 each other. If unspecified it defaults to the most commonly used C<.>.
 547
 548 =item unsafe
 549
 550 This Storage driver normally installs its own C<HandleError>, sets
 551 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 552 all database handles, including those supplied by a coderef.  It does this
 553 so that it can have consistent and useful error behavior.
 554
 555 If you set this option to a true value, Storage will not do its usual
 556 modifications to the database handle's attributes, and instead relies on
 557 the settings in your connect_info DBI options (or the values you set in
 558 your connection coderef, in the case that you are connecting via coderef).
 559
 560 Note that your custom settings can cause Storage to malfunction,
 561 especially if you set a C<HandleError> handler that suppresses exceptions
 562 and/or disable C<RaiseError>.
 563
 564 =item auto_savepoint
 565
 566 If this option is true, L<DBIx::Class> will use savepoints when nesting
 567 transactions, making it possible to recover from failure in the inner
 568 transaction without having to abort all outer transactions.
 569
 570 =item cursor_class
 571
 572 Use this argument to supply a cursor class other than the default
 573 L<DBIx::Class::Storage::DBI::Cursor>.
 574
 575 =back
 576
 577 Some real-life examples of arguments to L</connect_info> and
 578 L<DBIx::Class::Schema/connect>
 579
 580   # Simple SQLite connection
 581   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 582
 583   # Connect via subref
 584   ->connect_info([ sub { DBI->connect(...) } ]);
 585
 586   # Connect via subref in hashref
 587   ->connect_info([{
 588     dbh_maker => sub { DBI->connect(...) },
 589     on_connect_do => 'alter session ...',
 590   }]);
 591
 592   # A bit more complicated
 593   ->connect_info(
 594     [
 595       'dbi:Pg:dbname=foo',
 596       'postgres',
 597       'my_pg_password',
 598       { AutoCommit => 1 },
 599       { quote_char => q{"} },
 600     ]
 601   );
 602
 603   # Equivalent to the previous example
 604   ->connect_info(
 605     [
 606       'dbi:Pg:dbname=foo',
 607       'postgres',
 608       'my_pg_password',
 609       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 610     ]
 611   );
 612
 613   # Same, but with hashref as argument
 614   # See parse_connect_info for explanation
 615   ->connect_info(
 616     [{
 617       dsn         => 'dbi:Pg:dbname=foo',
 618       user        => 'postgres',
 619       password    => 'my_pg_password',
 620       AutoCommit  => 1,
 621       quote_char  => q{"},
 622       name_sep    => q{.},
 623     }]
 624   );
 625
 626   # Subref + DBIx::Class-specific connection options
 627   ->connect_info(
 628     [
 629       sub { DBI->connect(...) },
 630       {
 631           quote_char => q{`},
 632           name_sep => q{@},
 633           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 634           disable_sth_caching => 1,
 635       },
 636     ]
 637   );
 638
 639
 640
 641 =cut
 642
 643 sub connect_info {
 644   my ($self, $info) = @_;
 645
 646   return $self->_connect_info if !$info;
 647
 648   $self->_connect_info($info); # copy for _connect_info
 649
 650   $info = $self->_normalize_connect_info($info)
 651     if ref $info eq 'ARRAY';
 652
 653   my %attrs = (
 654     %{ $self->_default_dbi_connect_attributes || {} },
 655     %{ $info->{attributes} || {} },
 656   );
 657
 658   my @args = @{ $info->{arguments} };
 659
 660   if (keys %attrs and ref $args[0] ne 'CODE') {
 661     carp_unique (
 662         'You provided explicit AutoCommit => 0 in your connection_info. '
 663       . 'This is almost universally a bad idea (see the footnotes of '
 664       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 665       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 666       . 'this warning.'
 667     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 668
 669     push @args, \%attrs if keys %attrs;
 670   }
 671
 672   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 673   # OR a single-element coderef-based $dbh factory
 674   $self->_dbi_connect_info(\@args);
 675
 676   # extract the individual storage options
 677   for my $storage_opt (keys %{ $info->{storage_options} }) {
 678     my $value = $info->{storage_options}{$storage_opt};
 679
 680     $self->$storage_opt($value);
 681   }
 682
 683   # Extract the individual sqlmaker options
 684   #
 685   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 686   #  the new set of options
 687   $self->_sql_maker(undef);
 688   $self->_sql_maker_opts({});
 689
 690   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 691     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 692
 693     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 694   }
 695
 696   # FIXME - dirty:
 697   # save attributes in a separate accessor so they are always
 698   # introspectable, even in case of a CODE $dbhmaker
 699   $self->_dbic_connect_attributes (\%attrs);
 700
 701   return $self->_connect_info;
 702 }
 703
 704 sub _dbi_connect_info {
 705   my $self = shift;
 706
 707   return $self->{_dbi_connect_info} = $_[0]
 708     if @_;
 709
 710   my $conninfo = $self->{_dbi_connect_info} || [];
 711
 712   # last ditch effort to grab a DSN
 713   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 714     my @new_conninfo = @$conninfo;
 715     $new_conninfo[0] = $ENV{DBI_DSN};
 716     $conninfo = \@new_conninfo;
 717   }
 718
 719   return $conninfo;
 720 }
 721
 722
 723 sub _normalize_connect_info {
 724   my ($self, $info_arg) = @_;
 725   my %info;
 726
 727   my @args = @$info_arg;  # take a shallow copy for further mutilation
 728
 729   # combine/pre-parse arguments depending on invocation style
 730
 731   my %attrs;
 732   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 733     %attrs = %{ $args[1] || {} };
 734     @args = $args[0];
 735   }
 736   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 737     %attrs = %{$args[0]};
 738     @args = ();
 739     if (my $code = delete $attrs{dbh_maker}) {
 740       @args = $code;
 741
 742       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 743       if (@ignored) {
 744         carp sprintf (
 745             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 746           . "to the result of 'dbh_maker'",
 747
 748           join (', ', map { "'$_'" } (@ignored) ),
 749         );
 750       }
 751     }
 752     else {
 753       @args = delete @attrs{qw/dsn user password/};
 754     }
 755   }
 756   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 757     %attrs = (
 758       % { $args[3] || {} },
 759       % { $args[4] || {} },
 760     );
 761     @args = @args[0,1,2];
 762   }
 763
 764   $info{arguments} = \@args;
 765
 766   my @storage_opts = grep exists $attrs{$_},
 767     @storage_options, 'cursor_class';
 768
 769   @{ $info{storage_options} }{@storage_opts} =
 770     delete @attrs{@storage_opts} if @storage_opts;
 771
 772   my @sql_maker_opts = grep exists $attrs{$_},
 773     qw/limit_dialect quote_char name_sep quote_names/;
 774
 775   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 776     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 777
 778   $info{attributes} = \%attrs if %attrs;
 779
 780   return \%info;
 781 }
 782
 783 sub _default_dbi_connect_attributes () {
 784   +{
 785     AutoCommit => 1,
 786     PrintError => 0,
 787     RaiseError => 1,
 788     ShowErrorStatement => 1,
 789   };
 790 }
 791
 792 =head2 on_connect_do
 793
 794 This method is deprecated in favour of setting via L</connect_info>.
 795
 796 =cut
 797
 798 =head2 on_disconnect_do
 799
 800 This method is deprecated in favour of setting via L</connect_info>.
 801
 802 =cut
 803
 804 sub _parse_connect_do {
 805   my ($self, $type) = @_;
 806
 807   my $val = $self->$type;
 808   return () if not defined $val;
 809
 810   my @res;
 811
 812   if (not ref($val)) {
 813     push @res, [ 'do_sql', $val ];
 814   } elsif (ref($val) eq 'CODE') {
 815     push @res, $val;
 816   } elsif (ref($val) eq 'ARRAY') {
 817     push @res, map { [ 'do_sql', $_ ] } @$val;
 818   } else {
 819     $self->throw_exception("Invalid type for $type: ".ref($val));
 820   }
 821
 822   return \@res;
 823 }
 824
 825 =head2 dbh_do
 826
 827 Arguments: ($subref | $method_name), @extra_coderef_args?
 828
 829 Execute the given $subref or $method_name using the new exception-based
 830 connection management.
 831
 832 The first two arguments will be the storage object that C<dbh_do> was called
 833 on and a database handle to use.  Any additional arguments will be passed
 834 verbatim to the called subref as arguments 2 and onwards.
 835
 836 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 837 exception handling and reconnection (or failover in future subclasses).
 838
 839 Your subref should have no side-effects outside of the database, as
 840 there is the potential for your subref to be partially double-executed
 841 if the database connection was stale/dysfunctional.
 842
 843 Example:
 844
 845   my @stuff = $schema->storage->dbh_do(
 846     sub {
 847       my ($storage, $dbh, @cols) = @_;
 848       my $cols = join(q{, }, @cols);
 849       $dbh->selectrow_array("SELECT $cols FROM foo");
 850     },
 851     @column_list
 852   );
 853
 854 =cut
 855
 856 sub dbh_do {
 857   my $self = shift;
 858   my $run_target = shift; # either a coderef or a method name
 859
 860   # short circuit when we know there is no need for a runner
 861   #
 862   # FIXME - assumption may be wrong
 863   # the rationale for the txn_depth check is that if this block is a part
 864   # of a larger transaction, everything up to that point is screwed anyway
 865   return $self->$run_target($self->_get_dbh, @_)
 866     if $self->{_in_do_block} or $self->transaction_depth;
 867
 868   # take a ref instead of a copy, to preserve @_ aliasing
 869   # semantics within the coderef, but only if needed
 870   # (pseudoforking doesn't like this trick much)
 871   my $args = @_ ? \@_ : [];
 872
 873   DBIx::Class::Storage::BlockRunner->new(
 874     storage => $self,
 875     wrap_txn => 0,
 876     retry_handler => sub {
 877       $_[0]->failed_attempt_count == 1
 878         and
 879       ! $_[0]->storage->connected
 880     },
 881   )->run(sub {
 882     $self->$run_target ($self->_get_dbh, @$args )
 883   });
 884 }
 885
 886 sub txn_do {
 887   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 888   shift->next::method(@_);
 889 }
 890
 891 =head2 disconnect
 892
 893 Our C<disconnect> method also performs a rollback first if the
 894 database is not in C<AutoCommit> mode.
 895
 896 =cut
 897
 898 sub disconnect {
 899   my $self = shift;
 900
 901   # this physical disconnect below might very well throw
 902   # in order to unambiguously reset the state - do the cleanup in guard
 903
 904   my $g = scope_guard {
 905
 906     defined( $self->_dbh )
 907       and dbic_internal_try { $self->_dbh->disconnect };
 908
 909     $self->_dbh(undef);
 910     $self->_dbh_details({});
 911     $self->transaction_depth(undef);
 912     $self->_dbh_autocommit(undef);
 913     $self->savepoints([]);
 914
 915     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 916     #$self->_sql_maker(undef); # this may also end up being different
 917   };
 918
 919   if( $self->_dbh ) {
 920
 921     $self->_do_connection_actions(disconnect_call_ => $_) for (
 922       ( $self->on_disconnect_call || () ),
 923       $self->_parse_connect_do ('on_disconnect_do')
 924     );
 925
 926     # stops the "implicit rollback on disconnect" warning
 927     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 928   }
 929
 930   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 931   # collected before leaving this scope. Depending on the code above, this
 932   # may very well be just a preventive measure guarding future modifications
 933   undef;
 934 }
 935
 936 =head2 with_deferred_fk_checks
 937
 938 =over 4
 939
 940 =item Arguments: C<$coderef>
 941
 942 =item Return Value: The return value of $coderef
 943
 944 =back
 945
 946 Storage specific method to run the code ref with FK checks deferred or
 947 in MySQL's case disabled entirely.
 948
 949 =cut
 950
 951 # Storage subclasses should override this
 952 sub with_deferred_fk_checks {
 953   #my ($self, $sub) = @_;
 954   $_[1]->();
 955 }
 956
 957 =head2 connected
 958
 959 =over
 960
 961 =item Arguments: none
 962
 963 =item Return Value: 1|0
 964
 965 =back
 966
 967 Verifies that the current database handle is active and ready to execute
 968 an SQL statement (e.g. the connection did not get stale, server is still
 969 answering, etc.) This method is used internally by L</dbh>.
 970
 971 =cut
 972
 973 sub connected {
 974   return 0 unless $_[0]->_seems_connected;
 975
 976   #be on the safe side
 977   local $_[0]->_dbh->{RaiseError} = 1;
 978
 979   return $_[0]->_ping;
 980 }
 981
 982 sub _seems_connected {
 983   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 984
 985   $_[0]->_dbh
 986     and
 987   $_[0]->_dbh->FETCH('Active')
 988     and
 989   return 1;
 990
 991   # explicitly reset all state
 992   $_[0]->disconnect;
 993   return 0;
 994 }
 995
 996 sub _ping {
 997   ($_[0]->_dbh || return 0)->ping;
 998 }
 999
1000 sub ensure_connected {
1001   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
1002 }
1003
1004 =head2 dbh
1005
1006 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
1007 is guaranteed to be healthy by implicitly calling L</connected>, and if
1008 necessary performing a reconnection before returning. Keep in mind that this
1009 is very B<expensive> on some database engines. Consider using L</dbh_do>
1010 instead.
1011
1012 =cut
1013
1014 sub dbh {
1015   # maybe save a ping call
1016   $_[0]->_dbh
1017     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
1018     : $_[0]->_populate_dbh
1019   ;
1020 }
1021
1022 # this is the internal "get dbh or connect (don't check)" method
1023 sub _get_dbh {
1024   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1025   $_[0]->_dbh || $_[0]->_populate_dbh;
1026 }
1027
1028 # *DELIBERATELY* not a setter (for the time being)
1029 # Too intertwined with everything else for any kind of sanity
1030 sub sql_maker {
1031   my $self = shift;
1032
1033   $self->throw_exception('sql_maker() is not a setter method') if @_;
1034
1035   unless ($self->_sql_maker) {
1036     my $sql_maker_class = $self->sql_maker_class;
1037
1038     my %opts = %{$self->_sql_maker_opts||{}};
1039     my $dialect =
1040       $opts{limit_dialect}
1041         ||
1042       $self->sql_limit_dialect
1043         ||
1044       do {
1045         my $s_class = (ref $self) || $self;
1046         carp_unique (
1047           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1048         . 'have not supplied an explicit limit_dialect in your connection_info. '
1049         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1050         . 'databases but can be (and often is) painfully slow. '
1051         . "Please file an RT ticket against '$s_class'"
1052         ) if $self->_dbi_connect_info->[0];
1053
1054         'GenericSubQ';
1055       }
1056     ;
1057
1058     my ($quote_char, $name_sep);
1059
1060     if ($opts{quote_names}) {
1061       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1062         my $s_class = (ref $self) || $self;
1063         carp_unique (
1064           "You requested 'quote_names' but your storage class ($s_class) does "
1065         . 'not explicitly define a default sql_quote_char and you have not '
1066         . 'supplied a quote_char as part of your connection_info. DBIC will '
1067         .q{default to the ANSI SQL standard quote '"', which works most of }
1068         . "the time. Please file an RT ticket against '$s_class'."
1069         );
1070
1071         '"'; # RV
1072       };
1073
1074       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1075     }
1076
1077     $self->_sql_maker($sql_maker_class->new(
1078       bindtype=>'columns',
1079       array_datatypes => 1,
1080       limit_dialect => $dialect,
1081       ($quote_char ? (quote_char => $quote_char) : ()),
1082       name_sep => ($name_sep || '.'),
1083       %opts,
1084     ));
1085   }
1086   return $self->_sql_maker;
1087 }
1088
1089 # nothing to do by default
1090 sub _rebless {}
1091 sub _init {}
1092
1093 sub _populate_dbh {
1094
1095   # reset internal states
1096   # also in case ->connected failed we might get sent here
1097   $_[0]->disconnect;
1098
1099   $_[0]->_dbh($_[0]->_connect);
1100
1101   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1102
1103   $_[0]->_determine_driver;
1104
1105   # Always set the transaction depth on connect, since
1106   #  there is no transaction in progress by definition
1107   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1108
1109   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1110
1111   $_[0]->_dbh;
1112 }
1113
1114 sub _run_connection_actions {
1115
1116   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1117     ( $_[0]->on_connect_call || () ),
1118     $_[0]->_parse_connect_do ('on_connect_do'),
1119   );
1120 }
1121
1122
1123
1124 sub set_use_dbms_capability {
1125   $_[0]->set_inherited ($_[1], $_[2]);
1126 }
1127
1128 sub get_use_dbms_capability {
1129   my ($self, $capname) = @_;
1130
1131   my $use = $self->get_inherited ($capname);
1132   return defined $use
1133     ? $use
1134     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1135   ;
1136 }
1137
1138 sub set_dbms_capability {
1139   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1140 }
1141
1142 sub get_dbms_capability {
1143   my ($self, $capname) = @_;
1144
1145   my $cap = $self->_dbh_details->{capability}{$capname};
1146
1147   unless (defined $cap) {
1148     if (my $meth = $self->can ("_determine$capname")) {
1149       $cap = $self->$meth ? 1 : 0;
1150     }
1151     else {
1152       $cap = 0;
1153     }
1154
1155     $self->set_dbms_capability ($capname, $cap);
1156   }
1157
1158   return $cap;
1159 }
1160
1161 sub _server_info {
1162   my $self = shift;
1163
1164   # FIXME - ideally this needs to be an ||= assignment, and the final
1165   # assignment at the end of this do{} should be gone entirely. However
1166   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1167   $self->_dbh_details->{info} || do {
1168
1169     # this guarantees that problematic conninfo won't be hidden
1170     # by the try{} below
1171     $self->ensure_connected;
1172
1173     my $info = {};
1174
1175     my $server_version = dbic_internal_try {
1176       $self->_get_server_version
1177     } catch {
1178       # driver determination *may* use this codepath
1179       # in which case we must rethrow
1180       $self->throw_exception($_) if $self->{_in_determine_driver};
1181
1182       # $server_version on failure
1183       undef;
1184     };
1185
1186     if (defined $server_version) {
1187       $info->{dbms_version} = $server_version;
1188
1189       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1190       my @verparts = split (/\./, $numeric_version);
1191       if (
1192         @verparts
1193           &&
1194         $verparts[0] <= 999
1195       ) {
1196         # consider only up to 3 version parts, iff not more than 3 digits
1197         my @use_parts;
1198         while (@verparts && @use_parts < 3) {
1199           my $p = shift @verparts;
1200           last if $p > 999;
1201           push @use_parts, $p;
1202         }
1203         push @use_parts, 0 while @use_parts < 3;
1204
1205         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1206       }
1207     }
1208
1209     $self->_dbh_details->{info} = $info;
1210   };
1211 }
1212
1213 sub _get_server_version {
1214   shift->_dbh_get_info('SQL_DBMS_VER');
1215 }
1216
1217 sub _dbh_get_info {
1218   my ($self, $info) = @_;
1219
1220   if ($info =~ /[^0-9]/) {
1221     require DBI::Const::GetInfoType;
1222     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1223     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1224       unless defined $info;
1225   }
1226
1227   $self->_get_dbh->get_info($info);
1228 }
1229
1230 sub _describe_connection {
1231   require DBI::Const::GetInfoReturn;
1232
1233   my $self = shift;
1234
1235   my $drv;
1236   dbic_internal_try {
1237     $drv = $self->_extract_driver_from_connect_info;
1238     $self->ensure_connected;
1239   };
1240
1241   $drv = "DBD::$drv" if $drv;
1242
1243   my $res = {
1244     DBIC_DSN => $self->_dbi_connect_info->[0],
1245     DBI_VER => DBI->VERSION,
1246     DBIC_VER => DBIx::Class->VERSION,
1247     DBIC_DRIVER => ref $self,
1248     $drv ? (
1249       DBD => $drv,
1250       DBD_VER => dbic_internal_try { $drv->VERSION },
1251     ) : (),
1252   };
1253
1254   # try to grab data even if we never managed to connect
1255   # will cover us in cases of an oddly broken half-connect
1256   for my $inf (
1257     #keys %DBI::Const::GetInfoType::GetInfoType,
1258     qw/
1259       SQL_CURSOR_COMMIT_BEHAVIOR
1260       SQL_CURSOR_ROLLBACK_BEHAVIOR
1261       SQL_CURSOR_SENSITIVITY
1262       SQL_DATA_SOURCE_NAME
1263       SQL_DBMS_NAME
1264       SQL_DBMS_VER
1265       SQL_DEFAULT_TXN_ISOLATION
1266       SQL_DM_VER
1267       SQL_DRIVER_NAME
1268       SQL_DRIVER_ODBC_VER
1269       SQL_DRIVER_VER
1270       SQL_EXPRESSIONS_IN_ORDERBY
1271       SQL_GROUP_BY
1272       SQL_IDENTIFIER_CASE
1273       SQL_IDENTIFIER_QUOTE_CHAR
1274       SQL_MAX_CATALOG_NAME_LEN
1275       SQL_MAX_COLUMN_NAME_LEN
1276       SQL_MAX_IDENTIFIER_LEN
1277       SQL_MAX_TABLE_NAME_LEN
1278       SQL_MULTIPLE_ACTIVE_TXN
1279       SQL_MULT_RESULT_SETS
1280       SQL_NEED_LONG_DATA_LEN
1281       SQL_NON_NULLABLE_COLUMNS
1282       SQL_ODBC_VER
1283       SQL_QUALIFIER_NAME_SEPARATOR
1284       SQL_QUOTED_IDENTIFIER_CASE
1285       SQL_TXN_CAPABLE
1286       SQL_TXN_ISOLATION_OPTION
1287     /
1288   ) {
1289     # some drivers barf on things they do not know about instead
1290     # of returning undef
1291     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1292     next unless defined $v;
1293
1294     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1295     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1296     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1297   }
1298
1299   $res;
1300 }
1301
1302 sub _determine_driver {
1303   my ($self) = @_;
1304
1305   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1306     my $started_connected = 0;
1307     local $self->{_in_determine_driver} = 1;
1308
1309     if (ref($self) eq __PACKAGE__) {
1310       my $driver;
1311       if ($self->_dbh) { # we are connected
1312         $driver = $self->_dbh->{Driver}{Name};
1313         $started_connected = 1;
1314       }
1315       else {
1316         $driver = $self->_extract_driver_from_connect_info;
1317       }
1318
1319       if ($driver) {
1320         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1321         if ($self->load_optional_class($storage_class)) {
1322           mro::set_mro($storage_class, 'c3');
1323           bless $self, $storage_class;
1324           $self->_rebless();
1325         }
1326         else {
1327           $self->_warn_undetermined_driver(
1328             'This version of DBIC does not yet seem to supply a driver for '
1329           . "your particular RDBMS and/or connection method ('$driver')."
1330           );
1331         }
1332       }
1333       else {
1334         $self->_warn_undetermined_driver(
1335           'Unable to extract a driver name from connect info - this '
1336         . 'should not have happened.'
1337         );
1338       }
1339     }
1340
1341     $self->_driver_determined(1);
1342
1343     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1344
1345     if ($self->can('source_bind_attributes')) {
1346       $self->throw_exception(
1347         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1348       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1349       . 'If you are not sure how to proceed please contact the development team via '
1350       . DBIx::Class::_ENV_::HELP_URL
1351       );
1352     }
1353
1354     $self->_init; # run driver-specific initializations
1355
1356     $self->_run_connection_actions
1357         if !$started_connected && defined $self->_dbh;
1358   }
1359 }
1360
1361 sub _extract_driver_from_connect_info {
1362   my $self = shift;
1363
1364   my $drv;
1365
1366   # if connect_info is a CODEREF, we have no choice but to connect
1367   if (
1368     ref $self->_dbi_connect_info->[0]
1369       and
1370     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1371   ) {
1372     $self->_populate_dbh;
1373     $drv = $self->_dbh->{Driver}{Name};
1374   }
1375   else {
1376     # try to use dsn to not require being connected, the driver may still
1377     # force a connection later in _rebless to determine version
1378     # (dsn may not be supplied at all if all we do is make a mock-schema)
1379     #
1380     # Use the same regex as the one used by DBI itself (even if the use of
1381     # \w is odd given unicode):
1382     # https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L621
1383     #
1384     # DO NOT use https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L559-566
1385     # as there is a long-standing precedent of not loading DBI.pm until the
1386     # very moment we are actually connecting
1387     #
1388     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:(\w*)/i;
1389     $drv ||= $ENV{DBI_DRIVER};
1390   }
1391
1392   return $drv;
1393 }
1394
1395 sub _determine_connector_driver {
1396   my ($self, $conn) = @_;
1397
1398   my $dbtype = $self->_get_rdbms_name;
1399
1400   if (not $dbtype) {
1401     $self->_warn_undetermined_driver(
1402       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1403     . "$conn connector - this should not have happened."
1404     );
1405     return;
1406   }
1407
1408   $dbtype =~ s/\W/_/gi;
1409
1410   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1411   return if $self->isa($subclass);
1412
1413   if ($self->load_optional_class($subclass)) {
1414     bless $self, $subclass;
1415     $self->_rebless;
1416   }
1417   else {
1418     $self->_warn_undetermined_driver(
1419       'This version of DBIC does not yet seem to supply a driver for '
1420     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1421     );
1422   }
1423 }
1424
1425 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1426
1427 sub _warn_undetermined_driver {
1428   my ($self, $msg) = @_;
1429
1430   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1431   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1432   . "does not go away, file a bugreport including the following info:\n"
1433   . dump_value $self->_describe_connection
1434   );
1435 }
1436
1437 sub _do_connection_actions {
1438   my ($self, $method_prefix, $call, @args) = @_;
1439
1440   dbic_internal_try {
1441     if (not ref($call)) {
1442       my $method = $method_prefix . $call;
1443       $self->$method(@args);
1444     }
1445     elsif (ref($call) eq 'CODE') {
1446       $self->$call(@args);
1447     }
1448     elsif (ref($call) eq 'ARRAY') {
1449       if (ref($call->[0]) ne 'ARRAY') {
1450         $self->_do_connection_actions($method_prefix, $_) for @$call;
1451       }
1452       else {
1453         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1454       }
1455     }
1456     else {
1457       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1458     }
1459   }
1460   catch {
1461     if ( $method_prefix =~ /^connect/ ) {
1462       # this is an on_connect cycle - we can't just throw while leaving
1463       # a handle in an undefined state in our storage object
1464       # kill it with fire and rethrow
1465       $self->_dbh(undef);
1466       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1467       $self->throw_exception( $_[0] );
1468     }
1469     else {
1470       carp "Disconnect action failed: $_[0]";
1471     }
1472   };
1473
1474   return $self;
1475 }
1476
1477 sub connect_call_do_sql {
1478   my $self = shift;
1479   $self->_do_query(@_);
1480 }
1481
1482 sub disconnect_call_do_sql {
1483   my $self = shift;
1484   $self->_do_query(@_);
1485 }
1486
1487 =head2 connect_call_datetime_setup
1488
1489 A no-op stub method, provided so that one can always safely supply the
1490 L<connection option|/DBIx::Class specific connection attributes>
1491
1492  on_connect_call => 'datetime_setup'
1493
1494 This way one does not need to know in advance whether the underlying
1495 storage requires any sort of hand-holding when dealing with calendar
1496 data.
1497
1498 =cut
1499
1500 sub connect_call_datetime_setup { 1 }
1501
1502 sub _do_query {
1503   my ($self, $action) = @_;
1504
1505   if (ref $action eq 'CODE') {
1506     $action = $action->($self);
1507     $self->_do_query($_) foreach @$action;
1508   }
1509   else {
1510     # Most debuggers expect ($sql, @bind), so we need to exclude
1511     # the attribute hash which is the second argument to $dbh->do
1512     # furthermore the bind values are usually to be presented
1513     # as named arrayref pairs, so wrap those here too
1514     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1515     my $sql = shift @do_args;
1516     my $attrs = shift @do_args;
1517     my @bind = map { [ undef, $_ ] } @do_args;
1518
1519     $self->dbh_do(sub {
1520       $_[0]->_query_start($sql, \@bind);
1521       $_[1]->do($sql, $attrs, @do_args);
1522       $_[0]->_query_end($sql, \@bind);
1523     });
1524   }
1525
1526   return $self;
1527 }
1528
1529 sub _connect {
1530   my $self = shift;
1531
1532   my $info = $self->_dbi_connect_info;
1533
1534   $self->throw_exception("You did not provide any connection_info")
1535     unless defined $info->[0];
1536
1537   my ($old_connect_via, $dbh);
1538
1539   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1540
1541   # this odd anonymous coderef dereference is in fact really
1542   # necessary to avoid the unwanted effect described in perl5
1543   # RT#75792
1544   #
1545   # in addition the coderef itself can't reside inside the try{} block below
1546   # as it somehow triggers a leak under perl -d
1547   my $dbh_error_handler_installer = sub {
1548     weaken (my $weak_self = $_[0]);
1549
1550     # the coderef is blessed so we can distinguish it from externally
1551     # supplied handles (which must be preserved)
1552     $_[1]->{HandleError} = bless sub {
1553       if ($weak_self) {
1554         $weak_self->throw_exception("DBI Exception: $_[0]");
1555       }
1556       else {
1557         # the handler may be invoked by something totally out of
1558         # the scope of DBIC
1559         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1560       }
1561     }, '__DBIC__DBH__ERROR__HANDLER__';
1562   };
1563
1564   dbic_internal_try {
1565     if(ref $info->[0] eq 'CODE') {
1566       $dbh = $info->[0]->();
1567     }
1568     else {
1569       require DBI;
1570       $dbh = DBI->connect(@$info);
1571     }
1572
1573     die $DBI::errstr unless $dbh;
1574
1575     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1576       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1577       . 'not continue',
1578       ref $info->[0] eq 'CODE'
1579         ? "Connection coderef $info->[0] returned a"
1580         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1581     ) unless $dbh->FETCH('Active');
1582
1583     # sanity checks unless asked otherwise
1584     unless ($self->unsafe) {
1585
1586       $self->throw_exception(
1587         'Refusing clobbering of {HandleError} installed on externally supplied '
1588        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1589       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1590
1591       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1592       # request, or an external handle. Complain and set anyway
1593       unless ($dbh->{RaiseError}) {
1594         carp( ref $info->[0] eq 'CODE'
1595
1596           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1597            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1598            .'attribute has been supplied'
1599
1600           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1601            .'unsafe => 1. Toggling RaiseError back to true'
1602         );
1603
1604         $dbh->{RaiseError} = 1;
1605       }
1606
1607       $dbh_error_handler_installer->($self, $dbh);
1608     }
1609   }
1610   catch {
1611     $self->throw_exception("DBI Connection failed: $_")
1612   };
1613
1614   $self->_dbh_autocommit($dbh->{AutoCommit});
1615   return $dbh;
1616 }
1617
1618 sub txn_begin {
1619   # this means we have not yet connected and do not know the AC status
1620   # (e.g. coderef $dbh), need a full-fledged connection check
1621   if (! defined $_[0]->_dbh_autocommit) {
1622     $_[0]->ensure_connected;
1623   }
1624   # Otherwise simply connect or re-connect on pid changes
1625   else {
1626     $_[0]->_get_dbh;
1627   }
1628
1629   shift->next::method(@_);
1630 }
1631
1632 sub _exec_txn_begin {
1633   my $self = shift;
1634
1635   # if the user is utilizing txn_do - good for him, otherwise we need to
1636   # ensure that the $dbh is healthy on BEGIN.
1637   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1638   # will be replaced by a failure of begin_work itself (which will be
1639   # then retried on reconnect)
1640   if ($self->{_in_do_block}) {
1641     $self->_dbh->begin_work;
1642   } else {
1643     $self->dbh_do(sub { $_[1]->begin_work });
1644   }
1645 }
1646
1647 sub txn_commit {
1648   my $self = shift;
1649
1650   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1651     unless $self->_seems_connected;
1652
1653   # esoteric case for folks using external $dbh handles
1654   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1655     carp "Storage transaction_depth 0 does not match "
1656         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1657     $self->transaction_depth(1);
1658   }
1659
1660   $self->next::method(@_);
1661
1662   # if AutoCommit is disabled txn_depth never goes to 0
1663   # as a new txn is started immediately on commit
1664   $self->transaction_depth(1) if (
1665     !$self->transaction_depth
1666       and
1667     defined $self->_dbh_autocommit
1668       and
1669     ! $self->_dbh_autocommit
1670   );
1671 }
1672
1673 sub _exec_txn_commit {
1674   shift->_dbh->commit;
1675 }
1676
1677 sub txn_rollback {
1678   my $self = shift;
1679
1680   # do a minimal connectivity check due to weird shit like
1681   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1682   $self->throw_exception("lost connection to storage")
1683     unless $self->_seems_connected;
1684
1685   # esoteric case for folks using external $dbh handles
1686   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1687     carp "Storage transaction_depth 0 does not match "
1688         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1689     $self->transaction_depth(1);
1690   }
1691
1692   $self->next::method(@_);
1693
1694   # if AutoCommit is disabled txn_depth never goes to 0
1695   # as a new txn is started immediately on commit
1696   $self->transaction_depth(1) if (
1697     !$self->transaction_depth
1698       and
1699     defined $self->_dbh_autocommit
1700       and
1701     ! $self->_dbh_autocommit
1702   );
1703 }
1704
1705 sub _exec_txn_rollback {
1706   shift->_dbh->rollback;
1707 }
1708
1709 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1710 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1711   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1712     unless $_[0]->_seems_connected;
1713   shift->next::method(@_);
1714 EOS
1715
1716 # This used to be the top-half of _execute.  It was split out to make it
1717 #  easier to override in NoBindVars without duping the rest.  It takes up
1718 #  all of _execute's args, and emits $sql, @bind.
1719 sub _prep_for_execute {
1720   #my ($self, $op, $ident, $args) = @_;
1721   return shift->_gen_sql_bind(@_)
1722 }
1723
1724 sub _gen_sql_bind {
1725   my ($self, $op, $ident, $args) = @_;
1726
1727   my ($colinfos, $from);
1728   if ( blessed($ident) ) {
1729     $from = $ident->from;
1730     $colinfos = $ident->columns_info;
1731   }
1732
1733   my ($sql, $bind);
1734   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1735
1736   $bind = $self->_resolve_bindattrs(
1737     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1738   );
1739
1740   if (
1741     ! $ENV{DBIC_DT_SEARCH_OK}
1742       and
1743     $op eq 'select'
1744       and
1745     grep {
1746       length ref $_->[1]
1747         and
1748       blessed($_->[1])
1749         and
1750       $_->[1]->isa('DateTime')
1751     } @$bind
1752   ) {
1753     carp_unique 'DateTime objects passed to search() are not supported '
1754       . 'properly (InflateColumn::DateTime formats and settings are not '
1755       . 'respected.) See ".. format a DateTime object for searching?" in '
1756       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1757       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1758   }
1759
1760   return( $sql, $bind );
1761 }
1762
1763 sub _resolve_bindattrs {
1764   my ($self, $ident, $bind, $colinfos) = @_;
1765
1766   my $resolve_bindinfo = sub {
1767     #my $infohash = shift;
1768
1769     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1770
1771     my $ret;
1772     if (my $col = $_[0]->{dbic_colname}) {
1773       $ret = { %{$_[0]} };
1774
1775       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1776         if $colinfos->{$col}{data_type};
1777
1778       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1779         if $colinfos->{$col}{size};
1780     }
1781
1782     $ret || $_[0];
1783   };
1784
1785   return [ map {
1786       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1787     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1788     : (ref $_->[0] eq 'HASH')           ? [(
1789                                             ! keys %{$_->[0]}
1790                                               or
1791                                             exists $_->[0]{dbd_attrs}
1792                                               or
1793                                             $_->[0]{sqlt_datatype}
1794                                            ) ? $_->[0]
1795                                              : $resolve_bindinfo->($_->[0])
1796                                            , $_->[1]
1797                                           ]
1798     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1799     :                                     [ $resolve_bindinfo->(
1800                                               { dbic_colname => $_->[0] }
1801                                             ), $_->[1] ]
1802   } @$bind ];
1803 }
1804
1805 sub _format_for_trace {
1806   #my ($self, $bind) = @_;
1807
1808   ### Turn @bind from something like this:
1809   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1810   ### to this:
1811   ###   ( "'1'", "'3'" )
1812
1813   map {
1814     defined( $_ && $_->[1] )
1815       ? qq{'$_->[1]'}
1816       : q{NULL}
1817   } @{$_[1] || []};
1818 }
1819
1820 sub _query_start {
1821   my ( $self, $sql, $bind ) = @_;
1822
1823   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1824     if $self->debug;
1825 }
1826
1827 sub _query_end {
1828   my ( $self, $sql, $bind ) = @_;
1829
1830   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1831     if $self->debug;
1832 }
1833
1834 sub _dbi_attrs_for_bind {
1835   #my ($self, $ident, $bind) = @_;
1836
1837   return [ map {
1838
1839     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1840
1841   : ! $_->{sqlt_datatype}   ? undef
1842
1843   :                           do {
1844
1845     # cache the result in the dbh_details hash, as it (usually) can not change
1846     # unless we connect to something else
1847     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1848     # the LOB storage
1849     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1850
1851     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1852       if ! exists $cache->{$_->{sqlt_datatype}};
1853
1854     $cache->{$_->{sqlt_datatype}};
1855
1856   } } map { $_->[0] } @{$_[2]} ];
1857 }
1858
1859 sub _execute {
1860   my ($self, $op, $ident, @args) = @_;
1861
1862   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1863
1864   # not even a PID check - we do not care about the state of the _dbh.
1865   # All we need is to get the appropriate drivers loaded if they aren't
1866   # already so that the assumption in ad7c50fc26e holds
1867   $self->_populate_dbh unless $self->_dbh;
1868
1869   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1870     $sql,
1871     $bind,
1872     $self->_dbi_attrs_for_bind($ident, $bind),
1873   );
1874 }
1875
1876 sub _dbh_execute {
1877   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1878
1879   $self->_query_start( $sql, $bind );
1880
1881   my $sth = $self->_bind_sth_params(
1882     $self->_prepare_sth($dbh, $sql),
1883     $bind,
1884     $bind_attrs,
1885   );
1886
1887   # Can this fail without throwing an exception anyways???
1888   my $rv = $sth->execute();
1889   $self->throw_exception(
1890     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1891   ) if !$rv;
1892
1893   $self->_query_end( $sql, $bind );
1894
1895   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1896 }
1897
1898 sub _prepare_sth {
1899   my ($self, $dbh, $sql) = @_;
1900
1901   # 3 is the if_active parameter which avoids active sth re-use
1902   my $sth = $self->disable_sth_caching
1903     ? $dbh->prepare($sql)
1904     : $dbh->prepare_cached($sql, {}, 3);
1905
1906   # XXX You would think RaiseError would make this impossible,
1907   #  but apparently that's not true :(
1908   $self->throw_exception(
1909     $dbh->errstr
1910       ||
1911     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1912             .'an exception and/or setting $dbh->errstr',
1913       length ($sql) > 20
1914         ? substr($sql, 0, 20) . '...'
1915         : $sql
1916       ,
1917       'DBD::' . $dbh->{Driver}{Name},
1918     )
1919   ) if !$sth;
1920
1921   $sth;
1922 }
1923
1924 sub _bind_sth_params {
1925   my ($self, $sth, $bind, $bind_attrs) = @_;
1926
1927   for my $i (0 .. $#$bind) {
1928     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1929       $sth->bind_param_inout(
1930         $i + 1, # bind params counts are 1-based
1931         $bind->[$i][1],
1932         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1933         $bind_attrs->[$i],
1934       );
1935     }
1936     else {
1937       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1938       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1939         ? "$bind->[$i][1]"
1940         : $bind->[$i][1]
1941       ;
1942
1943       $sth->bind_param(
1944         $i + 1,
1945         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1946         $v,
1947         $bind_attrs->[$i],
1948       );
1949     }
1950   }
1951
1952   $sth;
1953 }
1954
1955 sub _prefetch_autovalues {
1956   my ($self, $source, $colinfo, $to_insert) = @_;
1957
1958   my %values;
1959   for my $col (keys %$colinfo) {
1960     if (
1961       $colinfo->{$col}{auto_nextval}
1962         and
1963       (
1964         ! exists $to_insert->{$col}
1965           or
1966         is_literal_value($to_insert->{$col})
1967       )
1968     ) {
1969       $values{$col} = $self->_sequence_fetch(
1970         'NEXTVAL',
1971         ( $colinfo->{$col}{sequence} ||=
1972             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1973         ),
1974       );
1975     }
1976   }
1977
1978   \%values;
1979 }
1980
1981 sub insert {
1982   my ($self, $source, $to_insert) = @_;
1983
1984   my $col_infos = $source->columns_info;
1985
1986   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1987
1988   # fuse the values, but keep a separate list of prefetched_values so that
1989   # they can be fused once again with the final return
1990   $to_insert = { %$to_insert, %$prefetched_values };
1991
1992   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1993   # Investigate what does it take to s/defined/exists/
1994   my %pcols = map { $_ => 1 } $source->primary_columns;
1995   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1996   for my $col ($source->columns) {
1997     if ($col_infos->{$col}{is_auto_increment}) {
1998       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1999       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
2000     }
2001
2002     # nothing to retrieve when explicit values are supplied
2003     next if (
2004       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
2005     );
2006
2007     # the 'scalar keys' is a trick to preserve the ->columns declaration order
2008     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
2009       $pcols{$col}
2010         or
2011       $col_infos->{$col}{retrieve_on_insert}
2012     );
2013   };
2014
2015   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
2016   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
2017
2018   my ($sqla_opts, @ir_container);
2019   if (%retrieve_cols and $self->_use_insert_returning) {
2020     $sqla_opts->{returning_container} = \@ir_container
2021       if $self->_use_insert_returning_bound;
2022
2023     $sqla_opts->{returning} = [
2024       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
2025     ];
2026   }
2027
2028   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2029
2030   my %returned_cols = %$to_insert;
2031   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2032
2033     unless( @ir_container ) {
2034       dbic_internal_try {
2035
2036         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2037         local $SIG{__WARN__} = sub {};
2038
2039         @ir_container = $sth->fetchrow_array;
2040         $sth->finish;
2041
2042       } catch {
2043         # Evict the $sth from the cache in case we got here, since the finish()
2044         # is crucial, at least on older Firebirds, possibly on other engines too
2045         #
2046         # It would be too complex to make this a proper subclass override,
2047         # and besides we already take the try{} penalty, adding a catch that
2048         # triggers infrequently is a no-brainer
2049         #
2050         if( my $kids = $self->_dbh->{CachedKids} ) {
2051           $kids->{$_} == $sth and delete $kids->{$_}
2052             for keys %$kids
2053         }
2054       };
2055     }
2056
2057     @returned_cols{@$retlist} = @ir_container if @ir_container;
2058   }
2059   else {
2060     # pull in PK if needed and then everything else
2061     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2062
2063       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2064         unless $self->can('last_insert_id');
2065
2066       my @pri_values = $self->last_insert_id($source, @missing_pri);
2067
2068       $self->throw_exception( "Can't get last insert id" )
2069         unless (@pri_values == @missing_pri);
2070
2071       @returned_cols{@missing_pri} = @pri_values;
2072       delete @retrieve_cols{@missing_pri};
2073     }
2074
2075     # if there is more left to pull
2076     if (%retrieve_cols) {
2077       $self->throw_exception(
2078         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2079       ) unless %pcols;
2080
2081       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2082
2083       my $cur = DBIx::Class::ResultSet->new($source, {
2084         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2085         select => \@left_to_fetch,
2086       })->cursor;
2087
2088       @returned_cols{@left_to_fetch} = $cur->next;
2089
2090       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2091         if scalar $cur->next;
2092     }
2093   }
2094
2095   return { %$prefetched_values, %returned_cols };
2096 }
2097
2098 sub insert_bulk {
2099   carp_unique(
2100     'insert_bulk() should have never been exposed as a public method and '
2101   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2102   . 'use for this method please contact the development team via '
2103   . DBIx::Class::_ENV_::HELP_URL
2104   );
2105
2106   return '0E0' unless @{$_[3]||[]};
2107
2108   shift->_insert_bulk(@_);
2109 }
2110
2111 sub _insert_bulk {
2112   my ($self, $source, $cols, $data) = @_;
2113
2114   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2115     unless @{$data||[]};
2116
2117   my $colinfos = $source->columns_info($cols);
2118
2119   local $self->{_autoinc_supplied_for_op} =
2120     (grep { $_->{is_auto_increment} } values %$colinfos)
2121       ? 1
2122       : 0
2123   ;
2124
2125   # get a slice type index based on first row of data
2126   # a "column" in this context may refer to more than one bind value
2127   # e.g. \[ '?, ?', [...], [...] ]
2128   #
2129   # construct the value type index - a description of values types for every
2130   # per-column slice of $data:
2131   #
2132   # nonexistent - nonbind literal
2133   # 0 - regular value
2134   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2135   #
2136   # also construct the column hash to pass to the SQL generator. For plain
2137   # (non literal) values - convert the members of the first row into a
2138   # literal+bind combo, with extra positional info in the bind attr hashref.
2139   # This will allow us to match the order properly, and is so contrived
2140   # because a user-supplied literal/bind (or something else specific to a
2141   # resultsource and/or storage driver) can inject extra binds along the
2142   # way, so one can't rely on "shift positions" ordering at all. Also we
2143   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2144   # can be later matched up by address), because we want to supply a real
2145   # value on which perhaps e.g. datatype checks will be performed
2146   my ($proto_data, $serialized_bind_type_by_col_idx);
2147   for my $col_idx (0..$#$cols) {
2148     my $colname = $cols->[$col_idx];
2149     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2150       # no bind value at all - no type
2151
2152       $proto_data->{$colname} = $data->[0][$col_idx];
2153     }
2154     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2155       # repack, so we don't end up mangling the original \[]
2156       my ($sql, @bind) = @${$data->[0][$col_idx]};
2157
2158       # normalization of user supplied stuff
2159       my $resolved_bind = $self->_resolve_bindattrs(
2160         $source, \@bind, $colinfos,
2161       );
2162
2163       # store value-less (attrs only) bind info - we will be comparing all
2164       # supplied binds against this for sanity
2165       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2166
2167       $proto_data->{$colname} = \[ $sql, map { [
2168         # inject slice order to use for $proto_bind construction
2169           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2170             =>
2171           $resolved_bind->[$_][1]
2172         ] } (0 .. $#bind)
2173       ];
2174     }
2175     else {
2176       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2177
2178       $proto_data->{$colname} = \[ '?', [
2179         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2180           =>
2181         $data->[0][$col_idx]
2182       ] ];
2183     }
2184   }
2185
2186   my ($sql, $proto_bind) = $self->_prep_for_execute (
2187     'insert',
2188     $source,
2189     [ $proto_data ],
2190   );
2191
2192   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2193     # if the bindlist is empty and we had some dynamic binds, this means the
2194     # storage ate them away (e.g. the NoBindVars component) and interpolated
2195     # them directly into the SQL. This obviously can't be good for multi-inserts
2196     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2197   }
2198
2199   # sanity checks
2200   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2201   #
2202   # use an error reporting closure for convenience (less to pass)
2203   my $bad_slice_report_cref = sub {
2204     my ($msg, $r_idx, $c_idx) = @_;
2205     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2206       $msg,
2207       $cols->[$c_idx],
2208       do {
2209         local $Data::Dumper::Maxdepth = 5;
2210         dump_value {
2211           map { $cols->[$_] =>
2212             $data->[$r_idx][$_]
2213           } 0..$#$cols
2214         };
2215       }
2216     );
2217   };
2218
2219   for my $col_idx (0..$#$cols) {
2220     my $reference_val = $data->[0][$col_idx];
2221
2222     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2223       my $val = $data->[$row_idx][$col_idx];
2224
2225       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2226         if (ref $val ne 'SCALAR') {
2227           $bad_slice_report_cref->(
2228             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2229             $row_idx,
2230             $col_idx,
2231           );
2232         }
2233         elsif ($$val ne $$reference_val) {
2234           $bad_slice_report_cref->(
2235             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2236             $row_idx,
2237             $col_idx,
2238           );
2239         }
2240       }
2241       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2242         if (is_literal_value($val)) {
2243           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2244         }
2245       }
2246       else {  # binds from a \[], compare type and attrs
2247         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2248           $bad_slice_report_cref->(
2249             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2250             $row_idx,
2251             $col_idx,
2252           );
2253         }
2254         # start drilling down and bail out early on identical refs
2255         elsif (
2256           $reference_val != $val
2257             or
2258           $$reference_val != $$val
2259         ) {
2260           if (${$val}->[0] ne ${$reference_val}->[0]) {
2261             $bad_slice_report_cref->(
2262               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2263               $row_idx,
2264               $col_idx,
2265             );
2266           }
2267           # need to check the bind attrs - a bind will happen only once for
2268           # the entire dataset, so any changes further down will be ignored.
2269           elsif (
2270             $serialized_bind_type_by_col_idx->{$col_idx}
2271               ne
2272             serialize [
2273               map
2274               { $_->[0] }
2275               @{$self->_resolve_bindattrs(
2276                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2277               )}
2278             ]
2279           ) {
2280             $bad_slice_report_cref->(
2281               'Differing bind attributes on literal/bind values not supported',
2282               $row_idx,
2283               $col_idx,
2284             );
2285           }
2286         }
2287       }
2288     }
2289   }
2290
2291   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2292   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2293   # scope guard
2294   my $guard = $self->txn_scope_guard;
2295
2296   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2297   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2298   my $rv = do {
2299     if (@$proto_bind) {
2300       # proto bind contains the information on which pieces of $data to pull
2301       # $cols is passed in only for prettier error-reporting
2302       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2303     }
2304     else {
2305       # bind_param_array doesn't work if there are no binds
2306       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2307     }
2308   };
2309
2310   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2311
2312   $guard->commit;
2313
2314   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2315 }
2316
2317 # execute_for_fetch is capable of returning data just fine (it means it
2318 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2319 # is the void-populate fast-path we will just ignore this altogether
2320 # for the time being.
2321 sub _dbh_execute_for_fetch {
2322   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2323
2324   # If we have any bind attributes to take care of, we will bind the
2325   # proto-bind data (which will never be used by execute_for_fetch)
2326   # However since column bindtypes are "sticky", this is sufficient
2327   # to get the DBD to apply the bindtype to all values later on
2328   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2329
2330   for my $i (0 .. $#$proto_bind) {
2331     $sth->bind_param (
2332       $i+1, # DBI bind indexes are 1-based
2333       $proto_bind->[$i][1],
2334       $bind_attrs->[$i],
2335     ) if defined $bind_attrs->[$i];
2336   }
2337
2338   # At this point $data slots named in the _bind_data_slice_idx of
2339   # each piece of $proto_bind are either \[]s or plain values to be
2340   # passed in. Construct the dispensing coderef. *NOTE* the order
2341   # of $data will differ from this of the ?s in the SQL (due to
2342   # alphabetical ordering by colname). We actually do want to
2343   # preserve this behavior so that prepare_cached has a better
2344   # chance of matching on unrelated calls
2345
2346   my $fetch_row_idx = -1; # saner loop this way
2347   my $fetch_tuple = sub {
2348     return undef if ++$fetch_row_idx > $#$data;
2349
2350     return [ map {
2351       my $v = ! defined $_->{_literal_bind_subindex}
2352
2353         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2354
2355         # There are no attributes to resolve here - we already did everything
2356         # when we constructed proto_bind. However we still want to sanity-check
2357         # what the user supplied, so pass stuff through to the resolver *anyway*
2358         : $self->_resolve_bindattrs (
2359             undef,  # a fake rsrc
2360             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2361             {},     # a fake column_info bag
2362           )->[0][1]
2363       ;
2364
2365       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2366       # For the time being forcibly stringify whatever is stringifiable
2367       my $vref;
2368
2369       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2370     : defined blessed( $$vref )                             ? "$$vref"
2371                                                             : $$vref
2372     ;
2373     } map { $_->[0] } @$proto_bind ];
2374   };
2375
2376   my $tuple_status = [];
2377   my ($rv, $err);
2378   dbic_internal_try {
2379     $rv = $sth->execute_for_fetch(
2380       $fetch_tuple,
2381       $tuple_status,
2382     );
2383   }
2384   catch {
2385     $err = shift;
2386   };
2387
2388   # Not all DBDs are create equal. Some throw on error, some return
2389   # an undef $rv, and some set $sth->err - try whatever we can
2390   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2391     ! defined $err
2392       and
2393     ( !defined $rv or $sth->err )
2394   );
2395
2396   # Statement must finish even if there was an exception.
2397   dbic_internal_try {
2398     $sth->finish
2399   }
2400   catch {
2401     $err = shift unless defined $err
2402   };
2403
2404   if (defined $err) {
2405     my $i = 0;
2406     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2407
2408     $self->throw_exception("Unexpected populate error: $err")
2409       if ($i > $#$tuple_status);
2410
2411     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2412       ($tuple_status->[$i][1] || $err),
2413       dump_value { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) },
2414     );
2415   }
2416
2417   return $rv;
2418 }
2419
2420 sub _dbh_execute_inserts_with_no_binds {
2421   my ($self, $sth, $count) = @_;
2422
2423   my $err;
2424   dbic_internal_try {
2425     my $dbh = $self->_get_dbh;
2426     local $dbh->{RaiseError} = 1;
2427     local $dbh->{PrintError} = 0;
2428
2429     $sth->execute foreach 1..$count;
2430   }
2431   catch {
2432     $err = shift;
2433   };
2434
2435   # Make sure statement is finished even if there was an exception.
2436   dbic_internal_try {
2437     $sth->finish
2438   }
2439   catch {
2440     $err = shift unless defined $err;
2441   };
2442
2443   $self->throw_exception($err) if defined $err;
2444
2445   return $count;
2446 }
2447
2448 sub update {
2449   #my ($self, $source, @args) = @_;
2450   shift->_execute('update', @_);
2451 }
2452
2453
2454 sub delete {
2455   #my ($self, $source, @args) = @_;
2456   shift->_execute('delete', @_);
2457 }
2458
2459 sub _select {
2460   my $self = shift;
2461   $self->_execute($self->_select_args(@_));
2462 }
2463
2464 sub _select_args_to_query {
2465   my $self = shift;
2466
2467   $self->throw_exception(
2468     "Unable to generate limited query representation with 'software_limit' enabled"
2469   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2470
2471   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2472   #  = $self->_select_args($ident, $select, $cond, $attrs);
2473   my ($op, $ident, @args) =
2474     $self->_select_args(@_);
2475
2476   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2477   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2478
2479   # reuse the bind arrayref
2480   unshift @{$bind}, "($sql)";
2481   \$bind;
2482 }
2483
2484 sub _select_args {
2485   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2486
2487   # FIXME - that kind of caching would be nice to have
2488   # however currently we *may* pass the same $orig_attrs
2489   # with different ident/select/where
2490   # the whole interface needs to be rethought, since it
2491   # was centered around the flawed SQLA API. We can do
2492   # soooooo much better now. But that is also another
2493   # battle...
2494   #return (
2495   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2496   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2497
2498   my $sql_maker = $self->sql_maker;
2499
2500   my $attrs = {
2501     %$orig_attrs,
2502     select => $select,
2503     from => $ident,
2504     where => $where,
2505   };
2506
2507   # MySQL actually recommends this approach.  I cringe.
2508   $attrs->{rows} ||= $sql_maker->__max_int
2509     if $attrs->{offset};
2510
2511   # see if we will need to tear the prefetch apart to satisfy group_by == select
2512   # this is *extremely tricky* to get right, I am still not sure I did
2513   #
2514   my ($prefetch_needs_subquery, @limit_args);
2515
2516   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2517     # we already know there is a valid group_by (we made it) and we know it is
2518     # intended to be based *only* on non-multi stuff
2519     # short circuit the group_by parsing below
2520     $prefetch_needs_subquery = 1;
2521   }
2522   elsif (
2523     # The rationale is that even if we do *not* have collapse, we still
2524     # need to wrap the core grouped select/group_by in a subquery
2525     # so that databases that care about group_by/select equivalence
2526     # are happy (this includes MySQL in strict_mode)
2527     # If any of the other joined tables are referenced in the group_by
2528     # however - the user is on their own
2529     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2530       and
2531     $attrs->{group_by}
2532       and
2533     @{$attrs->{group_by}}
2534       and
2535     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2536       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2537     }
2538   ) {
2539     # no aliases other than our own in group_by
2540     # if there are - do not allow subquery even if limit is present
2541     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2542   }
2543   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2544     # active collapse with a limit - that one is a no-brainer unless
2545     # overruled by a group_by above
2546     $prefetch_needs_subquery = 1;
2547   }
2548
2549   if ($prefetch_needs_subquery) {
2550     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2551   }
2552   elsif (! $attrs->{software_limit} ) {
2553     push @limit_args, (
2554       $attrs->{rows} || (),
2555       $attrs->{offset} || (),
2556     );
2557   }
2558
2559   # try to simplify the joinmap further (prune unreferenced type-single joins)
2560   if (
2561     ! $prefetch_needs_subquery  # already pruned
2562       and
2563     ref $attrs->{from}
2564       and
2565     reftype $attrs->{from} eq 'ARRAY'
2566       and
2567     @{$attrs->{from}} != 1
2568   ) {
2569     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2570   }
2571
2572   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2573   # during the result inflation stage we *need* to know what was the aliastype
2574   # map as sqla saw it when the final pieces of SQL were being assembled
2575   # Originally we simply carried around the entirety of $attrs, but this
2576   # resulted in resultsets that are being reused growing continuously, as
2577   # the hash in question grew deeper and deeper.
2578   # Instead hand-pick what to take with us here (we actually don't need much
2579   # at this point just the map itself)
2580   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2581
2582 ###
2583   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2584   #
2585   # This would be the point to deflate anything found in $attrs->{where}
2586   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2587   # expect a result object. And all we have is a resultsource (it is trivial
2588   # to extract deflator coderefs via $alias2source above).
2589   #
2590   # I don't see a way forward other than changing the way deflators are
2591   # invoked, and that's just bad...
2592 ###
2593
2594   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2595 }
2596
2597 # Returns a counting SELECT for a simple count
2598 # query. Abstracted so that a storage could override
2599 # this to { count => 'firstcol' } or whatever makes
2600 # sense as a performance optimization
2601 sub _count_select {
2602   #my ($self, $source, $rs_attrs) = @_;
2603   return { count => '*' };
2604 }
2605
2606 =head2 select
2607
2608 =over 4
2609
2610 =item Arguments: $ident, $select, $condition, $attrs
2611
2612 =back
2613
2614 Handle a SQL select statement.
2615
2616 =cut
2617
2618 sub select {
2619   my $self = shift;
2620   my ($ident, $select, $condition, $attrs) = @_;
2621   return $self->cursor_class->new($self, \@_, $attrs);
2622 }
2623
2624 sub select_single {
2625   my $self = shift;
2626   my ($rv, $sth, @bind) = $self->_select(@_);
2627   my @row = $sth->fetchrow_array;
2628   my @nextrow = $sth->fetchrow_array if @row;
2629   if(@row && @nextrow) {
2630     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2631   }
2632   # Need to call finish() to work round broken DBDs
2633   $sth->finish();
2634   return @row;
2635 }
2636
2637 =head2 sql_limit_dialect
2638
2639 This is an accessor for the default SQL limit dialect used by a particular
2640 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2641 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2642 see L<DBIx::Class::SQLMaker::LimitDialects>.
2643
2644 =cut
2645
2646 sub _dbh_columns_info_for {
2647   my ($self, $dbh, $table) = @_;
2648
2649   my %result;
2650
2651   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2652     dbic_internal_try {
2653       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2654       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2655       $sth->execute();
2656       while ( my $info = $sth->fetchrow_hashref() ){
2657         my %column_info;
2658         $column_info{data_type}   = $info->{TYPE_NAME};
2659         $column_info{size}      = $info->{COLUMN_SIZE};
2660         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2661         $column_info{default_value} = $info->{COLUMN_DEF};
2662         my $col_name = $info->{COLUMN_NAME};
2663         $col_name =~ s/^\"(.*)\"$/$1/;
2664
2665         $result{$col_name} = \%column_info;
2666       }
2667     } catch {
2668       %result = ();
2669     };
2670
2671     return \%result if keys %result;
2672   }
2673
2674   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2675   $sth->execute;
2676
2677 ### The acrobatics with lc names is necessary to support both the legacy
2678 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2679 ### with column names differing in cas eonly (thanks pg!)
2680
2681   my ($columns, $seen_lcs);
2682
2683   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2684     idx => scalar keys %$columns,
2685     name => $_,
2686     lc_name => lc($_),
2687   } for @{$sth->{NAME}};
2688
2689   $seen_lcs->{$_->{lc_name}} == 1
2690     and
2691   $_->{name} = $_->{lc_name}
2692     for values %$columns;
2693
2694   for ( values %$columns ) {
2695     my $inf = {
2696       data_type => $sth->{TYPE}->[$_->{idx}],
2697       size => $sth->{PRECISION}->[$_->{idx}],
2698       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2699     };
2700
2701     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2702       @{$inf}{qw( data_type  size)} = ($1, $2);
2703     }
2704
2705     $result{$_->{name}} = $inf;
2706   }
2707
2708   $sth->finish;
2709
2710   if ($dbh->can('type_info')) {
2711     for my $inf (values %result) {
2712       next if ! defined $inf->{data_type};
2713
2714       $inf->{data_type} = (
2715         (
2716           (
2717             $dbh->type_info( $inf->{data_type} )
2718               ||
2719             next
2720           )
2721             ||
2722           next
2723         )->{TYPE_NAME}
2724           ||
2725         next
2726       );
2727
2728       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2729       # needs more testing in the future...
2730       $inf->{size} -= 4 if (
2731         ( $inf->{size}||0 > 4 )
2732           and
2733         $inf->{data_type} =~ qr/^text$/i
2734       );
2735     }
2736
2737   }
2738
2739   return \%result;
2740 }
2741
2742 sub columns_info_for {
2743   my ($self, $table) = @_;
2744   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2745 }
2746
2747 =head2 last_insert_id
2748
2749 Return the row id of the last insert.
2750
2751 =cut
2752
2753 sub _dbh_last_insert_id {
2754     my ($self, $dbh, $source, $col) = @_;
2755
2756     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2757
2758     return $id if defined $id;
2759
2760     my $class = ref $self;
2761     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2762 }
2763
2764 sub last_insert_id {
2765   my $self = shift;
2766   $self->_dbh_last_insert_id ($self->_dbh, @_);
2767 }
2768
2769 =head2 _native_data_type
2770
2771 =over 4
2772
2773 =item Arguments: $type_name
2774
2775 =back
2776
2777 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2778 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2779 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2780
2781 The default implementation returns C<undef>, implement in your Storage driver if
2782 you need this functionality.
2783
2784 Should map types from other databases to the native RDBMS type, for example
2785 C<VARCHAR2> to C<VARCHAR>.
2786
2787 Types with modifiers should map to the underlying data type. For example,
2788 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2789
2790 Composite types should map to the container type, for example
2791 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2792
2793 =cut
2794
2795 sub _native_data_type {
2796   #my ($self, $data_type) = @_;
2797   return undef
2798 }
2799
2800 # Check if placeholders are supported at all
2801 sub _determine_supports_placeholders {
2802   my $self = shift;
2803   my $dbh  = $self->_get_dbh;
2804
2805   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2806   # but it is inaccurate more often than not
2807   ( dbic_internal_try {
2808     local $dbh->{PrintError} = 0;
2809     local $dbh->{RaiseError} = 1;
2810     $dbh->do('select ?', {}, 1);
2811     1;
2812   } )
2813     ? 1
2814     : 0
2815   ;
2816 }
2817
2818 # Check if placeholders bound to non-string types throw exceptions
2819 #
2820 sub _determine_supports_typeless_placeholders {
2821   my $self = shift;
2822   my $dbh  = $self->_get_dbh;
2823
2824   ( dbic_internal_try {
2825     local $dbh->{PrintError} = 0;
2826     local $dbh->{RaiseError} = 1;
2827     # this specifically tests a bind that is NOT a string
2828     $dbh->do('select 1 where 1 = ?', {}, 1);
2829     1;
2830   } )
2831     ? 1
2832     : 0
2833   ;
2834 }
2835
2836 =head2 sqlt_type
2837
2838 Returns the database driver name.
2839
2840 =cut
2841
2842 sub sqlt_type {
2843   shift->_get_dbh->{Driver}->{Name};
2844 }
2845
2846 =head2 bind_attribute_by_data_type
2847
2848 Given a datatype from column info, returns a database specific bind
2849 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2850 let the database planner just handle it.
2851
2852 This method is always called after the driver has been determined and a DBI
2853 connection has been established. Therefore you can refer to C<DBI::$constant>
2854 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2855 the correct modules.
2856
2857 =cut
2858
2859 sub bind_attribute_by_data_type {
2860     return;
2861 }
2862
2863 =head2 is_datatype_numeric
2864
2865 Given a datatype from column_info, returns a boolean value indicating if
2866 the current RDBMS considers it a numeric value. This controls how
2867 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2868 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2869 be performed instead of the usual C<eq>.
2870
2871 =cut
2872
2873 sub is_datatype_numeric {
2874   #my ($self, $dt) = @_;
2875
2876   return 0 unless $_[1];
2877
2878   $_[1] =~ /^ (?:
2879     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2880   ) $/ix;
2881 }
2882
2883
2884 =head2 create_ddl_dir
2885
2886 =over 4
2887
2888 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2889
2890 =back
2891
2892 Creates a SQL file based on the Schema, for each of the specified
2893 database engines in C<\@databases> in the given directory.
2894 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2895
2896 Given a previous version number, this will also create a file containing
2897 the ALTER TABLE statements to transform the previous schema into the
2898 current one. Note that these statements may contain C<DROP TABLE> or
2899 C<DROP COLUMN> statements that can potentially destroy data.
2900
2901 The file names are created using the C<ddl_filename> method below, please
2902 override this method in your schema if you would like a different file
2903 name format. For the ALTER file, the same format is used, replacing
2904 $version in the name with "$preversion-$version".
2905
2906 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2907 The most common value for this would be C<< { add_drop_table => 1 } >>
2908 to have the SQL produced include a C<DROP TABLE> statement for each table
2909 created. For quoting purposes supply C<quote_identifiers>.
2910
2911 If no arguments are passed, then the following default values are assumed:
2912
2913 =over 4
2914
2915 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2916
2917 =item version    - $schema->schema_version
2918
2919 =item directory  - './'
2920
2921 =item preversion - <none>
2922
2923 =back
2924
2925 By default, C<\%sqlt_args> will have
2926
2927  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2928
2929 merged with the hash passed in. To disable any of those features, pass in a
2930 hashref like the following
2931
2932  { ignore_constraint_names => 0, # ... other options }
2933
2934
2935 WARNING: You are strongly advised to check all SQL files created, before applying
2936 them.
2937
2938 =cut
2939
2940 sub create_ddl_dir {
2941   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2942
2943   require DBIx::Class::Optional::Dependencies;
2944   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2945     $self->throw_exception("Can't create a ddl file without $missing");
2946   }
2947
2948   if (!$dir) {
2949     carp "No directory given, using ./\n";
2950     $dir = './';
2951   }
2952   else {
2953     mkdir_p( $dir ) unless -d $dir;
2954   }
2955
2956   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2957   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2958
2959   my $schema_version = $schema->schema_version || '1.x';
2960   $version ||= $schema_version;
2961
2962   $sqltargs = {
2963     add_drop_table => 1,
2964     ignore_constraint_names => 1,
2965     ignore_index_names => 1,
2966     quote_identifiers => $self->sql_maker->_quoting_enabled,
2967     %{$sqltargs || {}}
2968   };
2969
2970   my $sqlt = SQL::Translator->new( $sqltargs );
2971
2972   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2973   my $sqlt_schema = $sqlt->translate({ data => $schema })
2974     or $self->throw_exception ($sqlt->error);
2975
2976   foreach my $db (@$databases) {
2977     $sqlt->reset();
2978     $sqlt->{schema} = $sqlt_schema;
2979     $sqlt->producer($db);
2980
2981     my $file;
2982     my $filename = $schema->ddl_filename($db, $version, $dir);
2983     if (-e $filename && ($version eq $schema_version )) {
2984       # if we are dumping the current version, overwrite the DDL
2985       carp "Overwriting existing DDL file - $filename";
2986       unlink($filename);
2987     }
2988
2989     my $output = $sqlt->translate;
2990     if(!$output) {
2991       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2992       next;
2993     }
2994     if(!open($file, ">$filename")) {
2995       $self->throw_exception("Can't open $filename for writing ($!)");
2996       next;
2997     }
2998     print $file $output;
2999     close($file);
3000
3001     next unless ($preversion);
3002
3003     require SQL::Translator::Diff;
3004
3005     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
3006     if(!-e $prefilename) {
3007       carp("No previous schema file found ($prefilename)");
3008       next;
3009     }
3010
3011     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
3012     if(-e $difffile) {
3013       carp("Overwriting existing diff file - $difffile");
3014       unlink($difffile);
3015     }
3016
3017     my $source_schema;
3018     {
3019       my $t = SQL::Translator->new($sqltargs);
3020       $t->debug( 0 );
3021       $t->trace( 0 );
3022
3023       $t->parser( $db )
3024         or $self->throw_exception ($t->error);
3025
3026       my $out = $t->translate( $prefilename )
3027         or $self->throw_exception ($t->error);
3028
3029       $source_schema = $t->schema;
3030
3031       $source_schema->name( $prefilename )
3032         unless ( $source_schema->name );
3033     }
3034
3035     # The "new" style of producers have sane normalization and can support
3036     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3037     # And we have to diff parsed SQL against parsed SQL.
3038     my $dest_schema = $sqlt_schema;
3039
3040     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3041       my $t = SQL::Translator->new($sqltargs);
3042       $t->debug( 0 );
3043       $t->trace( 0 );
3044
3045       $t->parser( $db )
3046         or $self->throw_exception ($t->error);
3047
3048       my $out = $t->translate( $filename )
3049         or $self->throw_exception ($t->error);
3050
3051       $dest_schema = $t->schema;
3052
3053       $dest_schema->name( $filename )
3054         unless $dest_schema->name;
3055     }
3056
3057     my $diff = do {
3058       # FIXME - this is a terrible workaround for
3059       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3060       # Fixing it in this sloppy manner so that we don't hve to
3061       # lockstep an SQLT release as well. Needs to be removed at
3062       # some point, and SQLT dep bumped
3063       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3064         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3065
3066       SQL::Translator::Diff::schema_diff($source_schema, $db,
3067                                          $dest_schema,   $db,
3068                                          $sqltargs
3069                                        );
3070     };
3071
3072     if(!open $file, ">$difffile") {
3073       $self->throw_exception("Can't write to $difffile ($!)");
3074       next;
3075     }
3076     print $file $diff;
3077     close($file);
3078   }
3079 }
3080
3081 =head2 deployment_statements
3082
3083 =over 4
3084
3085 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3086
3087 =back
3088
3089 Returns the statements used by L<DBIx::Class::Storage/deploy>
3090 and L<DBIx::Class::Schema/deploy>.
3091
3092 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3093 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3094
3095 C<$directory> is used to return statements from files in a previously created
3096 L</create_ddl_dir> directory and is optional. The filenames are constructed
3097 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3098
3099 If no C<$directory> is specified then the statements are constructed on the
3100 fly using L<SQL::Translator> and C<$version> is ignored.
3101
3102 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3103
3104 =cut
3105
3106 sub deployment_statements {
3107   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3108   $type ||= $self->sqlt_type;
3109   $version ||= $schema->schema_version || '1.x';
3110   $dir ||= './';
3111   my $filename = $schema->ddl_filename($type, $version, $dir);
3112   if(-f $filename)
3113   {
3114       # FIXME replace this block when a proper sane sql parser is available
3115       my $file;
3116       open($file, "<$filename")
3117         or $self->throw_exception("Can't open $filename ($!)");
3118       my @rows = <$file>;
3119       close($file);
3120       return join('', @rows);
3121   }
3122
3123   require DBIx::Class::Optional::Dependencies;
3124   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3125     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3126   }
3127
3128   # sources needs to be a parser arg, but for simplicity allow at top level
3129   # coming in
3130   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3131       if exists $sqltargs->{sources};
3132
3133   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3134     unless exists $sqltargs->{quote_identifiers};
3135
3136   my $tr = SQL::Translator->new(
3137     producer => "SQL::Translator::Producer::${type}",
3138     %$sqltargs,
3139     parser => 'SQL::Translator::Parser::DBIx::Class',
3140     data => $schema,
3141   );
3142
3143   return preserve_context {
3144     $tr->translate
3145   } after => sub {
3146     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3147       unless defined $_[0];
3148   };
3149 }
3150
3151 # FIXME deploy() currently does not accurately report sql errors
3152 # Will always return true while errors are warned
3153 sub deploy {
3154   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3155   my $deploy = sub {
3156     my $line = shift;
3157     return if(!$line);
3158     return if($line =~ /^--/);
3159     # next if($line =~ /^DROP/m);
3160     return if($line =~ /^BEGIN TRANSACTION/m);
3161     return if($line =~ /^COMMIT/m);
3162     return if $line =~ /^\s+$/; # skip whitespace only
3163     $self->_query_start($line);
3164     dbic_internal_try {
3165       # do a dbh_do cycle here, as we need some error checking in
3166       # place (even though we will ignore errors)
3167       $self->dbh_do (sub { $_[1]->do($line) });
3168     } catch {
3169       carp qq{$_ (running "${line}")};
3170     };
3171     $self->_query_end($line);
3172   };
3173   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3174   if (@statements > 1) {
3175     foreach my $statement (@statements) {
3176       $deploy->( $statement );
3177     }
3178   }
3179   elsif (@statements == 1) {
3180     # split on single line comments and end of statements
3181     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3182       $deploy->( $line );
3183     }
3184   }
3185 }
3186
3187 =head2 datetime_parser
3188
3189 Returns the datetime parser class
3190
3191 =cut
3192
3193 sub datetime_parser {
3194   my $self = shift;
3195   return $self->{datetime_parser} ||= do {
3196     $self->build_datetime_parser(@_);
3197   };
3198 }
3199
3200 =head2 datetime_parser_type
3201
3202 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3203
3204 =head2 build_datetime_parser
3205
3206 See L</datetime_parser>
3207
3208 =cut
3209
3210 sub build_datetime_parser {
3211   my $self = shift;
3212   my $type = $self->datetime_parser_type(@_);
3213   return $type;
3214 }
3215
3216
3217 =head2 is_replicating
3218
3219 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3220 replicate from a master database.  Default is undef, which is the result
3221 returned by databases that don't support replication.
3222
3223 =cut
3224
3225 sub is_replicating {
3226     return;
3227
3228 }
3229
3230 =head2 lag_behind_master
3231
3232 Returns a number that represents a certain amount of lag behind a master db
3233 when a given storage is replicating.  The number is database dependent, but
3234 starts at zero and increases with the amount of lag. Default in undef
3235
3236 =cut
3237
3238 sub lag_behind_master {
3239     return;
3240 }
3241
3242 =head2 relname_to_table_alias
3243
3244 =over 4
3245
3246 =item Arguments: $relname, $join_count
3247
3248 =item Return Value: $alias
3249
3250 =back
3251
3252 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3253 queries.
3254
3255 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3256 way these aliases are named.
3257
3258 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3259 otherwise C<"$relname">.
3260
3261 =cut
3262
3263 sub relname_to_table_alias {
3264   my ($self, $relname, $join_count) = @_;
3265
3266   my $alias = ($join_count && $join_count > 1 ?
3267     join('_', $relname, $join_count) : $relname);
3268
3269   return $alias;
3270 }
3271
3272 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3273 # version and it may be necessary to amend or override it for a specific storage
3274 # if such binds are necessary.
3275 sub _max_column_bytesize {
3276   my ($self, $attr) = @_;
3277
3278   my $max_size;
3279
3280   if ($attr->{sqlt_datatype}) {
3281     my $data_type = lc($attr->{sqlt_datatype});
3282
3283     if ($attr->{sqlt_size}) {
3284
3285       # String/sized-binary types
3286       if ($data_type =~ /^(?:
3287           l? (?:var)? char(?:acter)? (?:\s*varying)?
3288             |
3289           (?:var)? binary (?:\s*varying)?
3290             |
3291           raw
3292         )\b/x
3293       ) {
3294         $max_size = $attr->{sqlt_size};
3295       }
3296       # Other charset/unicode types, assume scale of 4
3297       elsif ($data_type =~ /^(?:
3298           national \s* character (?:\s*varying)?
3299             |
3300           nchar
3301             |
3302           univarchar
3303             |
3304           nvarchar
3305         )\b/x
3306       ) {
3307         $max_size = $attr->{sqlt_size} * 4;
3308       }
3309     }
3310
3311     if (!$max_size and !$self->_is_lob_type($data_type)) {
3312       $max_size = 100 # for all other (numeric?) datatypes
3313     }
3314   }
3315
3316   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3317 }
3318
3319 # Determine if a data_type is some type of BLOB
3320 sub _is_lob_type {
3321   my ($self, $data_type) = @_;
3322   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3323     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3324                                   |varchar|character\s*varying|nvarchar
3325                                   |national\s*character\s*varying))?\z/xi);
3326 }
3327
3328 sub _is_binary_lob_type {
3329   my ($self, $data_type) = @_;
3330   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3331     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3332 }
3333
3334 sub _is_text_lob_type {
3335   my ($self, $data_type) = @_;
3336   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3337     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3338                         |national\s*character\s*varying))\z/xi);
3339 }
3340
3341 # Determine if a data_type is some type of a binary type
3342 sub _is_binary_type {
3343   my ($self, $data_type) = @_;
3344   $data_type && ($self->_is_binary_lob_type($data_type)
3345     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3346 }
3347
3348 1;
3349
3350 =head1 USAGE NOTES
3351
3352 =head2 DBIx::Class and AutoCommit
3353
3354 DBIx::Class can do some wonderful magic with handling exceptions,
3355 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3356 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3357 transaction support.
3358
3359 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3360 in an assumed transaction between commits, and you're telling us you'd
3361 like to manage that manually.  A lot of the magic protections offered by
3362 this module will go away.  We can't protect you from exceptions due to database
3363 disconnects because we don't know anything about how to restart your
3364 transactions.  You're on your own for handling all sorts of exceptional
3365 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3366 be with raw DBI.
3367
3368 =head1 FURTHER QUESTIONS?
3369
3370 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3371
3372 =head1 COPYRIGHT AND LICENSE
3373
3374 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3375 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3376 redistribute it and/or modify it under the same terms as the
3377 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.