lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching on_connect_do
  18        on_disconnect_do transaction_depth unsafe _dbh_autocommit
  19        auto_savepoint savepoints/
  20 );
  21
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  25 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  26
  27 BEGIN {
  28
  29 package # Hide from PAUSE
  30   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  31
  32 use base qw/SQL::Abstract::Limit/;
  33
  34 # This prevents the caching of $dbh in S::A::L, I believe
  35 sub new {
  36   my $self = shift->SUPER::new(@_);
  37
  38   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  39   #   it with what it resolves to:
  40   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  41     if ref $self->{limit_dialect};
  42
  43   $self;
  44 }
  45
  46 sub _RowNumberOver {
  47   my ($self, $sql, $order, $rows, $offset ) = @_;
  48
  49   $offset += 1;
  50   my $last = $rows + $offset;
  51   my ( $order_by ) = $self->_order_by( $order );
  52
  53   $sql = <<"";
  54 SELECT * FROM
  55 (
  56    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  57       $sql
  58       $order_by
  59    ) Q1
  60 ) Q2
  61 WHERE ROW_NUM BETWEEN $offset AND $last
  62
  63   return $sql;
  64 }
  65
  66
  67 # While we're at it, this should make LIMIT queries more efficient,
  68 #  without digging into things too deeply
  69 use Scalar::Util 'blessed';
  70 sub _find_syntax {
  71   my ($self, $syntax) = @_;
  72   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  73   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  74     return 'RowNumberOver';
  75   }
  76
  77   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  78 }
  79
  80 sub select {
  81   my ($self, $table, $fields, $where, $order, @rest) = @_;
  82   $table = $self->_quote($table) unless ref($table);
  83   local $self->{rownum_hack_count} = 1
  84     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  85   @rest = (-1) unless defined $rest[0];
  86   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  87     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  88   local $self->{having_bind} = [];
  89   my ($sql, @ret) = $self->SUPER::select(
  90     $table, $self->_recurse_fields($fields), $where, $order, @rest
  91   );
  92   $sql .=
  93     $self->{for} ?
  94     (
  95       $self->{for} eq 'update' ? ' FOR UPDATE' :
  96       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  97       ''
  98     ) :
  99     ''
 100   ;
 101   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 102 }
 103
 104 sub insert {
 105   my $self = shift;
 106   my $table = shift;
 107   $table = $self->_quote($table) unless ref($table);
 108   $self->SUPER::insert($table, @_);
 109 }
 110
 111 sub update {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::update($table, @_);
 116 }
 117
 118 sub delete {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::delete($table, @_);
 123 }
 124
 125 sub _emulate_limit {
 126   my $self = shift;
 127   if ($_[3] == -1) {
 128     return $_[1].$self->_order_by($_[2]);
 129   } else {
 130     return $self->SUPER::_emulate_limit(@_);
 131   }
 132 }
 133
 134 sub _recurse_fields {
 135   my ($self, $fields, $params) = @_;
 136   my $ref = ref $fields;
 137   return $self->_quote($fields) unless $ref;
 138   return $$fields if $ref eq 'SCALAR';
 139
 140   if ($ref eq 'ARRAY') {
 141     return join(', ', map {
 142       $self->_recurse_fields($_)
 143         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 144           ? ' AS col'.$self->{rownum_hack_count}++
 145           : '')
 146       } @$fields);
 147   } elsif ($ref eq 'HASH') {
 148     foreach my $func (keys %$fields) {
 149       return $self->_sqlcase($func)
 150         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 151     }
 152   }
 153 }
 154
 155 sub _order_by {
 156   my $self = shift;
 157   my $ret = '';
 158   my @extra;
 159   if (ref $_[0] eq 'HASH') {
 160     if (defined $_[0]->{group_by}) {
 161       $ret = $self->_sqlcase(' group by ')
 162         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 163     }
 164     if (defined $_[0]->{having}) {
 165       my $frag;
 166       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 167       push(@{$self->{having_bind}}, @extra);
 168       $ret .= $self->_sqlcase(' having ').$frag;
 169     }
 170     if (defined $_[0]->{order_by}) {
 171       $ret .= $self->_order_by($_[0]->{order_by});
 172     }
 173   } elsif (ref $_[0] eq 'SCALAR') {
 174     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 175   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 176     my @order = @{+shift};
 177     $ret = $self->_sqlcase(' order by ')
 178           .join(', ', map {
 179                         my $r = $self->_order_by($_, @_);
 180                         $r =~ s/^ ?ORDER BY //i;
 181                         $r;
 182                       } @order);
 183   } else {
 184     $ret = $self->SUPER::_order_by(@_);
 185   }
 186   return $ret;
 187 }
 188
 189 sub _order_directions {
 190   my ($self, $order) = @_;
 191   $order = $order->{order_by} if ref $order eq 'HASH';
 192   return $self->SUPER::_order_directions($order);
 193 }
 194
 195 sub _table {
 196   my ($self, $from) = @_;
 197   if (ref $from eq 'ARRAY') {
 198     return $self->_recurse_from(@$from);
 199   } elsif (ref $from eq 'HASH') {
 200     return $self->_make_as($from);
 201   } else {
 202     return $from; # would love to quote here but _table ends up getting called
 203                   # twice during an ->select without a limit clause due to
 204                   # the way S::A::Limit->select works. should maybe consider
 205                   # bypassing this and doing S::A::select($self, ...) in
 206                   # our select method above. meantime, quoting shims have
 207                   # been added to select/insert/update/delete here
 208   }
 209 }
 210
 211 sub _recurse_from {
 212   my ($self, $from, @join) = @_;
 213   my @sqlf;
 214   push(@sqlf, $self->_make_as($from));
 215   foreach my $j (@join) {
 216     my ($to, $on) = @$j;
 217
 218     # check whether a join type exists
 219     my $join_clause = '';
 220     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 221     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 222       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 223     } else {
 224       $join_clause = ' JOIN ';
 225     }
 226     push(@sqlf, $join_clause);
 227
 228     if (ref $to eq 'ARRAY') {
 229       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 230     } else {
 231       push(@sqlf, $self->_make_as($to));
 232     }
 233     push(@sqlf, ' ON ', $self->_join_condition($on));
 234   }
 235   return join('', @sqlf);
 236 }
 237
 238 sub _make_as {
 239   my ($self, $from) = @_;
 240   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 241                      reverse each %{$self->_skip_options($from)});
 242 }
 243
 244 sub _skip_options {
 245   my ($self, $hash) = @_;
 246   my $clean_hash = {};
 247   $clean_hash->{$_} = $hash->{$_}
 248     for grep {!/^-/} keys %$hash;
 249   return $clean_hash;
 250 }
 251
 252 sub _join_condition {
 253   my ($self, $cond) = @_;
 254   if (ref $cond eq 'HASH') {
 255     my %j;
 256     for (keys %$cond) {
 257       my $v = $cond->{$_};
 258       if (ref $v) {
 259         # XXX no throw_exception() in this package and croak() fails with strange results
 260         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 261             if ref($v) ne 'SCALAR';
 262         $j{$_} = $v;
 263       }
 264       else {
 265         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 266       }
 267     };
 268     return scalar($self->_recurse_where(\%j));
 269   } elsif (ref $cond eq 'ARRAY') {
 270     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 271   } else {
 272     die "Can't handle this yet!";
 273   }
 274 }
 275
 276 sub _quote {
 277   my ($self, $label) = @_;
 278   return '' unless defined $label;
 279   return "*" if $label eq '*';
 280   return $label unless $self->{quote_char};
 281   if(ref $self->{quote_char} eq "ARRAY"){
 282     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 283       if !defined $self->{name_sep};
 284     my $sep = $self->{name_sep};
 285     return join($self->{name_sep},
 286         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 287        split(/\Q$sep\E/,$label));
 288   }
 289   return $self->SUPER::_quote($label);
 290 }
 291
 292 sub limit_dialect {
 293     my $self = shift;
 294     $self->{limit_dialect} = shift if @_;
 295     return $self->{limit_dialect};
 296 }
 297
 298 sub quote_char {
 299     my $self = shift;
 300     $self->{quote_char} = shift if @_;
 301     return $self->{quote_char};
 302 }
 303
 304 sub name_sep {
 305     my $self = shift;
 306     $self->{name_sep} = shift if @_;
 307     return $self->{name_sep};
 308 }
 309
 310 } # End of BEGIN block
 311
 312 =head1 NAME
 313
 314 DBIx::Class::Storage::DBI - DBI storage handler
 315
 316 =head1 SYNOPSIS
 317
 318 =head1 DESCRIPTION
 319
 320 This class represents the connection to an RDBMS via L<DBI>.  See
 321 L<DBIx::Class::Storage> for general information.  This pod only
 322 documents DBI-specific methods and behaviors.
 323
 324 =head1 METHODS
 325
 326 =cut
 327
 328 sub new {
 329   my $new = shift->next::method(@_);
 330
 331   $new->transaction_depth(0);
 332   $new->_sql_maker_opts({});
 333   $new->{savepoints} = [];
 334   $new->{_in_dbh_do} = 0;
 335   $new->{_dbh_gen} = 0;
 336
 337   $new;
 338 }
 339
 340 =head2 connect_info
 341
 342 The arguments of C<connect_info> are always a single array reference.
 343
 344 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 345 encapsulates its argument list in an arrayref before calling
 346 C<connect_info> here.
 347
 348 The arrayref can either contain the same set of arguments one would
 349 normally pass to L<DBI/connect>, or a lone code reference which returns
 350 a connected database handle.  Please note that the L<DBI> docs
 351 recommend that you always explicitly set C<AutoCommit> to either
 352 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 353 to C<1>, and that you perform transactions via our L</txn_do>
 354 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 355 set it to zero.  This is the default for most DBDs.  See below for more
 356 details.
 357
 358 In either case, if the final argument in your connect_info happens
 359 to be a hashref, C<connect_info> will look there for several
 360 connection-specific options:
 361
 362 =over 4
 363
 364 =item on_connect_do
 365
 366 Specifies things to do immediately after connecting or re-connecting to
 367 the database.  Its value may contain:
 368
 369 =over
 370
 371 =item an array reference
 372
 373 This contains SQL statements to execute in order.  Each element contains
 374 a string or a code reference that returns a string.
 375
 376 =item a code reference
 377
 378 This contains some code to execute.  Unlike code references within an
 379 array reference, its return value is ignored.
 380
 381 =back
 382
 383 =item on_disconnect_do
 384
 385 Takes arguments in the same form as L<on_connect_do> and executes them
 386 immediately before disconnecting from the database.
 387
 388 Note, this only runs if you explicitly call L<disconnect> on the
 389 storage object.
 390
 391 =item disable_sth_caching
 392
 393 If set to a true value, this option will disable the caching of
 394 statement handles via L<DBI/prepare_cached>.
 395
 396 =item limit_dialect
 397
 398 Sets the limit dialect. This is useful for JDBC-bridge among others
 399 where the remote SQL-dialect cannot be determined by the name of the
 400 driver alone.
 401
 402 =item quote_char
 403
 404 Specifies what characters to use to quote table and column names. If
 405 you use this you will want to specify L<name_sep> as well.
 406
 407 quote_char expects either a single character, in which case is it is placed
 408 on either side of the table/column, or an arrayref of length 2 in which case the
 409 table/column name is placed between the elements.
 410
 411 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 412 use C<quote_char =E<gt> [qw/[ ]/]>.
 413
 414 =item name_sep
 415
 416 This only needs to be used in conjunction with L<quote_char>, and is used to
 417 specify the charecter that seperates elements (schemas, tables, columns) from
 418 each other. In most cases this is simply a C<.>.
 419
 420 =item unsafe
 421
 422 This Storage driver normally installs its own C<HandleError>, sets
 423 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 424 all database handles, including those supplied by a coderef.  It does this
 425 so that it can have consistent and useful error behavior.
 426
 427 If you set this option to a true value, Storage will not do its usual
 428 modifications to the database handle's attributes, and instead relies on
 429 the settings in your connect_info DBI options (or the values you set in
 430 your connection coderef, in the case that you are connecting via coderef).
 431
 432 Note that your custom settings can cause Storage to malfunction,
 433 especially if you set a C<HandleError> handler that suppresses exceptions
 434 and/or disable C<RaiseError>.
 435
 436 =item auto_savepoint
 437
 438 If this option is true, L<DBIx::Class> will use savepoints when nesting
 439 transactions, making it possible to recover from failure in the inner
 440 transaction without having to abort all outer transactions.
 441
 442 =back
 443
 444 These options can be mixed in with your other L<DBI> connection attributes,
 445 or placed in a seperate hashref after all other normal L<DBI> connection
 446 arguments.
 447
 448 Every time C<connect_info> is invoked, any previous settings for
 449 these options will be cleared before setting the new ones, regardless of
 450 whether any options are specified in the new C<connect_info>.
 451
 452 Another Important Note:
 453
 454 DBIC can do some wonderful magic with handling exceptions,
 455 disconnections, and transactions when you use C<< AutoCommit => 1 >>
 456 combined with C<txn_do> for transaction support.
 457
 458 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
 459 in an assumed transaction between commits, and you're telling us you'd
 460 like to manage that manually.  A lot of DBIC's magic protections
 461 go away.  We can't protect you from exceptions due to database
 462 disconnects because we don't know anything about how to restart your
 463 transactions.  You're on your own for handling all sorts of exceptional
 464 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
 465 be with raw DBI.
 466
 467 Examples:
 468
 469   # Simple SQLite connection
 470   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 471
 472   # Connect via subref
 473   ->connect_info([ sub { DBI->connect(...) } ]);
 474
 475   # A bit more complicated
 476   ->connect_info(
 477     [
 478       'dbi:Pg:dbname=foo',
 479       'postgres',
 480       'my_pg_password',
 481       { AutoCommit => 1 },
 482       { quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Equivalent to the previous example
 487   ->connect_info(
 488     [
 489       'dbi:Pg:dbname=foo',
 490       'postgres',
 491       'my_pg_password',
 492       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 493     ]
 494   );
 495
 496   # Subref + DBIC-specific connection options
 497   ->connect_info(
 498     [
 499       sub { DBI->connect(...) },
 500       {
 501           quote_char => q{`},
 502           name_sep => q{@},
 503           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 504           disable_sth_caching => 1,
 505       },
 506     ]
 507   );
 508
 509 =cut
 510
 511 sub connect_info {
 512   my ($self, $info_arg) = @_;
 513
 514   return $self->_connect_info if !$info_arg;
 515
 516   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 517   #  the new set of options
 518   $self->_sql_maker(undef);
 519   $self->_sql_maker_opts({});
 520   $self->_connect_info([@$info_arg]); # copy for _connect_info
 521
 522   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 523
 524   my $last_info = $dbi_info->[-1];
 525   if(ref $last_info eq 'HASH') {
 526     $last_info = { %$last_info }; # so delete is non-destructive
 527     my @storage_option = qw(
 528       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 529       auto_savepoint
 530     );
 531     for my $storage_opt (@storage_option) {
 532       if(my $value = delete $last_info->{$storage_opt}) {
 533         $self->$storage_opt($value);
 534       }
 535     }
 536     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 537       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 538         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 539       }
 540     }
 541     # re-insert modified hashref
 542     $dbi_info->[-1] = $last_info;
 543
 544     # Get rid of any trailing empty hashref
 545     pop(@$dbi_info) if !keys %$last_info;
 546   }
 547   $self->_dbi_connect_info($dbi_info);
 548
 549   $self->_connect_info;
 550 }
 551
 552 =head2 on_connect_do
 553
 554 This method is deprecated in favor of setting via L</connect_info>.
 555
 556 =head2 dbh_do
 557
 558 Arguments: ($subref | $method_name), @extra_coderef_args?
 559
 560 Execute the given $subref or $method_name using the new exception-based
 561 connection management.
 562
 563 The first two arguments will be the storage object that C<dbh_do> was called
 564 on and a database handle to use.  Any additional arguments will be passed
 565 verbatim to the called subref as arguments 2 and onwards.
 566
 567 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 568 exception handling and reconnection (or failover in future subclasses).
 569
 570 Your subref should have no side-effects outside of the database, as
 571 there is the potential for your subref to be partially double-executed
 572 if the database connection was stale/dysfunctional.
 573
 574 Example:
 575
 576   my @stuff = $schema->storage->dbh_do(
 577     sub {
 578       my ($storage, $dbh, @cols) = @_;
 579       my $cols = join(q{, }, @cols);
 580       $dbh->selectrow_array("SELECT $cols FROM foo");
 581     },
 582     @column_list
 583   );
 584
 585 =cut
 586
 587 sub dbh_do {
 588   my $self = shift;
 589   my $code = shift;
 590
 591   my $dbh = $self->_dbh;
 592
 593   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 594       || $self->{transaction_depth};
 595
 596   local $self->{_in_dbh_do} = 1;
 597
 598   my @result;
 599   my $want_array = wantarray;
 600
 601   eval {
 602     $self->_verify_pid if $dbh;
 603     if(!$self->_dbh) {
 604         $self->_populate_dbh;
 605         $dbh = $self->_dbh;
 606     }
 607
 608     if($want_array) {
 609         @result = $self->$code($dbh, @_);
 610     }
 611     elsif(defined $want_array) {
 612         $result[0] = $self->$code($dbh, @_);
 613     }
 614     else {
 615         $self->$code($dbh, @_);
 616     }
 617   };
 618
 619   my $exception = $@;
 620   if(!$exception) { return $want_array ? @result : $result[0] }
 621
 622   $self->throw_exception($exception) if $self->connected;
 623
 624   # We were not connected - reconnect and retry, but let any
 625   #  exception fall right through this time
 626   $self->_populate_dbh;
 627   $self->$code($self->_dbh, @_);
 628 }
 629
 630 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 631 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 632 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 633 sub txn_do {
 634   my $self = shift;
 635   my $coderef = shift;
 636
 637   ref $coderef eq 'CODE' or $self->throw_exception
 638     ('$coderef must be a CODE reference');
 639
 640   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 641
 642   local $self->{_in_dbh_do} = 1;
 643
 644   my @result;
 645   my $want_array = wantarray;
 646
 647   my $tried = 0;
 648   while(1) {
 649     eval {
 650       $self->_verify_pid if $self->_dbh;
 651       $self->_populate_dbh if !$self->_dbh;
 652
 653       $self->txn_begin;
 654       if($want_array) {
 655           @result = $coderef->(@_);
 656       }
 657       elsif(defined $want_array) {
 658           $result[0] = $coderef->(@_);
 659       }
 660       else {
 661           $coderef->(@_);
 662       }
 663       $self->txn_commit;
 664     };
 665
 666     my $exception = $@;
 667     if(!$exception) { return $want_array ? @result : $result[0] }
 668
 669     if($tried++ > 0 || $self->connected) {
 670       eval { $self->txn_rollback };
 671       my $rollback_exception = $@;
 672       if($rollback_exception) {
 673         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 674         $self->throw_exception($exception)  # propagate nested rollback
 675           if $rollback_exception =~ /$exception_class/;
 676
 677         $self->throw_exception(
 678           "Transaction aborted: ${exception}. "
 679           . "Rollback failed: ${rollback_exception}"
 680         );
 681       }
 682       $self->throw_exception($exception)
 683     }
 684
 685     # We were not connected, and was first try - reconnect and retry
 686     # via the while loop
 687     $self->_populate_dbh;
 688   }
 689 }
 690
 691 =head2 disconnect
 692
 693 Our C<disconnect> method also performs a rollback first if the
 694 database is not in C<AutoCommit> mode.
 695
 696 =cut
 697
 698 sub disconnect {
 699   my ($self) = @_;
 700
 701   if( $self->connected ) {
 702     my $connection_do = $self->on_disconnect_do;
 703     $self->_do_connection_actions($connection_do) if ref($connection_do);
 704
 705     $self->_dbh->rollback unless $self->_dbh_autocommit;
 706     $self->_dbh->disconnect;
 707     $self->_dbh(undef);
 708     $self->{_dbh_gen}++;
 709   }
 710 }
 711
 712 =head2 with_deferred_fk_checks
 713
 714 =over 4
 715
 716 =item Arguments: C<$coderef>
 717
 718 =item Return Value: The return value of $coderef
 719
 720 =back
 721
 722 Storage specific method to run the code ref with FK checks deferred or
 723 in MySQL's case disabled entirely.
 724
 725 =cut
 726
 727 # Storage subclasses should override this
 728 sub with_deferred_fk_checks {
 729   my ($self, $sub) = @_;
 730
 731   $sub->();
 732 }
 733
 734 sub connected {
 735   my ($self) = @_;
 736
 737   if(my $dbh = $self->_dbh) {
 738       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 739           $self->_dbh(undef);
 740           $self->{_dbh_gen}++;
 741           return;
 742       }
 743       else {
 744           $self->_verify_pid;
 745           return 0 if !$self->_dbh;
 746       }
 747       return ($dbh->FETCH('Active') && $dbh->ping);
 748   }
 749
 750   return 0;
 751 }
 752
 753 # handle pid changes correctly
 754 #  NOTE: assumes $self->_dbh is a valid $dbh
 755 sub _verify_pid {
 756   my ($self) = @_;
 757
 758   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 759
 760   $self->_dbh->{InactiveDestroy} = 1;
 761   $self->_dbh(undef);
 762   $self->{_dbh_gen}++;
 763
 764   return;
 765 }
 766
 767 sub ensure_connected {
 768   my ($self) = @_;
 769
 770   unless ($self->connected) {
 771     $self->_populate_dbh;
 772   }
 773 }
 774
 775 =head2 dbh
 776
 777 Returns the dbh - a data base handle of class L<DBI>.
 778
 779 =cut
 780
 781 sub dbh {
 782   my ($self) = @_;
 783
 784   $self->ensure_connected;
 785   return $self->_dbh;
 786 }
 787
 788 sub _sql_maker_args {
 789     my ($self) = @_;
 790
 791     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 792 }
 793
 794 sub sql_maker {
 795   my ($self) = @_;
 796   unless ($self->_sql_maker) {
 797     my $sql_maker_class = $self->sql_maker_class;
 798     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 799   }
 800   return $self->_sql_maker;
 801 }
 802
 803 sub _rebless {}
 804
 805 sub _populate_dbh {
 806   my ($self) = @_;
 807   my @info = @{$self->_dbi_connect_info || []};
 808   $self->_dbh($self->_connect(@info));
 809
 810   # Always set the transaction depth on connect, since
 811   #  there is no transaction in progress by definition
 812   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 813
 814   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 815     my $driver = $self->_dbh->{Driver}->{Name};
 816     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 817       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 818       $self->_rebless();
 819     }
 820   }
 821
 822   my $connection_do = $self->on_connect_do;
 823   $self->_do_connection_actions($connection_do) if ref($connection_do);
 824
 825   $self->_conn_pid($$);
 826   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 827 }
 828
 829 sub _do_connection_actions {
 830   my $self = shift;
 831   my $connection_do = shift;
 832
 833   if (ref $connection_do eq 'ARRAY') {
 834     $self->_do_query($_) foreach @$connection_do;
 835   }
 836   elsif (ref $connection_do eq 'CODE') {
 837     $connection_do->();
 838   }
 839
 840   return $self;
 841 }
 842
 843 sub _do_query {
 844   my ($self, $action) = @_;
 845
 846   if (ref $action eq 'CODE') {
 847     $action = $action->($self);
 848     $self->_do_query($_) foreach @$action;
 849   }
 850   else {
 851     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 852     $self->_query_start(@to_run);
 853     $self->_dbh->do(@to_run);
 854     $self->_query_end(@to_run);
 855   }
 856
 857   return $self;
 858 }
 859
 860 sub _connect {
 861   my ($self, @info) = @_;
 862
 863   $self->throw_exception("You failed to provide any connection info")
 864     if !@info;
 865
 866   my ($old_connect_via, $dbh);
 867
 868   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 869     $old_connect_via = $DBI::connect_via;
 870     $DBI::connect_via = 'connect';
 871   }
 872
 873   eval {
 874     if(ref $info[0] eq 'CODE') {
 875        $dbh = &{$info[0]}
 876     }
 877     else {
 878        $dbh = DBI->connect(@info);
 879     }
 880
 881     if($dbh && !$self->unsafe) {
 882       my $weak_self = $self;
 883       weaken($weak_self);
 884       $dbh->{HandleError} = sub {
 885           $weak_self->throw_exception("DBI Exception: $_[0]")
 886       };
 887       $dbh->{ShowErrorStatement} = 1;
 888       $dbh->{RaiseError} = 1;
 889       $dbh->{PrintError} = 0;
 890     }
 891   };
 892
 893   $DBI::connect_via = $old_connect_via if $old_connect_via;
 894
 895   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 896     if !$dbh || $@;
 897
 898   $self->_dbh_autocommit($dbh->{AutoCommit});
 899
 900   $dbh;
 901 }
 902
 903 sub svp_begin {
 904   my ($self, $name) = @_;
 905
 906   $name = $self->_svp_generate_name
 907     unless defined $name;
 908
 909   $self->throw_exception ("You can't use savepoints outside a transaction")
 910     if $self->{transaction_depth} == 0;
 911
 912   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 913     unless $self->can('_svp_begin');
 914
 915   push @{ $self->{savepoints} }, $name;
 916
 917   $self->debugobj->svp_begin($name) if $self->debug;
 918
 919   return $self->_svp_begin($name);
 920 }
 921
 922 sub svp_release {
 923   my ($self, $name) = @_;
 924
 925   $self->throw_exception ("You can't use savepoints outside a transaction")
 926     if $self->{transaction_depth} == 0;
 927
 928   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 929     unless $self->can('_svp_release');
 930
 931   if (defined $name) {
 932     $self->throw_exception ("Savepoint '$name' does not exist")
 933       unless grep { $_ eq $name } @{ $self->{savepoints} };
 934
 935     # Dig through the stack until we find the one we are releasing.  This keeps
 936     # the stack up to date.
 937     my $svp;
 938
 939     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 940   } else {
 941     $name = pop @{ $self->{savepoints} };
 942   }
 943
 944   $self->debugobj->svp_release($name) if $self->debug;
 945
 946   return $self->_svp_release($name);
 947 }
 948
 949 sub svp_rollback {
 950   my ($self, $name) = @_;
 951
 952   $self->throw_exception ("You can't use savepoints outside a transaction")
 953     if $self->{transaction_depth} == 0;
 954
 955   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 956     unless $self->can('_svp_rollback');
 957
 958   if (defined $name) {
 959       # If they passed us a name, verify that it exists in the stack
 960       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 961           $self->throw_exception("Savepoint '$name' does not exist!");
 962       }
 963
 964       # Dig through the stack until we find the one we are releasing.  This keeps
 965       # the stack up to date.
 966       while(my $s = pop(@{ $self->{savepoints} })) {
 967           last if($s eq $name);
 968       }
 969       # Add the savepoint back to the stack, as a rollback doesn't remove the
 970       # named savepoint, only everything after it.
 971       push(@{ $self->{savepoints} }, $name);
 972   } else {
 973       # We'll assume they want to rollback to the last savepoint
 974       $name = $self->{savepoints}->[-1];
 975   }
 976
 977   $self->debugobj->svp_rollback($name) if $self->debug;
 978
 979   return $self->_svp_rollback($name);
 980 }
 981
 982 sub _svp_generate_name {
 983     my ($self) = @_;
 984
 985     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 986 }
 987
 988 sub txn_begin {
 989   my $self = shift;
 990   $self->ensure_connected();
 991   if($self->{transaction_depth} == 0) {
 992     $self->debugobj->txn_begin()
 993       if $self->debug;
 994     # this isn't ->_dbh-> because
 995     #  we should reconnect on begin_work
 996     #  for AutoCommit users
 997     $self->dbh->begin_work;
 998   } elsif ($self->auto_savepoint) {
 999     $self->svp_begin;
1000   }
1001   $self->{transaction_depth}++;
1002 }
1003
1004 sub txn_commit {
1005   my $self = shift;
1006   if ($self->{transaction_depth} == 1) {
1007     my $dbh = $self->_dbh;
1008     $self->debugobj->txn_commit()
1009       if ($self->debug);
1010     $dbh->commit;
1011     $self->{transaction_depth} = 0
1012       if $self->_dbh_autocommit;
1013   }
1014   elsif($self->{transaction_depth} > 1) {
1015     $self->{transaction_depth}--;
1016     $self->svp_release
1017       if $self->auto_savepoint;
1018   }
1019 }
1020
1021 sub txn_rollback {
1022   my $self = shift;
1023   my $dbh = $self->_dbh;
1024   eval {
1025     if ($self->{transaction_depth} == 1) {
1026       $self->debugobj->txn_rollback()
1027         if ($self->debug);
1028       $self->{transaction_depth} = 0
1029         if $self->_dbh_autocommit;
1030       $dbh->rollback;
1031     }
1032     elsif($self->{transaction_depth} > 1) {
1033       $self->{transaction_depth}--;
1034       if ($self->auto_savepoint) {
1035         $self->svp_rollback;
1036         $self->svp_release;
1037       }
1038     }
1039     else {
1040       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1041     }
1042   };
1043   if ($@) {
1044     my $error = $@;
1045     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1046     $error =~ /$exception_class/ and $self->throw_exception($error);
1047     # ensure that a failed rollback resets the transaction depth
1048     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1049     $self->throw_exception($error);
1050   }
1051 }
1052
1053 # This used to be the top-half of _execute.  It was split out to make it
1054 #  easier to override in NoBindVars without duping the rest.  It takes up
1055 #  all of _execute's args, and emits $sql, @bind.
1056 sub _prep_for_execute {
1057   my ($self, $op, $extra_bind, $ident, $args) = @_;
1058
1059   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1060   unshift(@bind,
1061     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1062       if $extra_bind;
1063
1064   return ($sql, \@bind);
1065 }
1066
1067 sub _fix_bind_params {
1068     my ($self, @bind) = @_;
1069
1070     ### Turn @bind from something like this:
1071     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1072     ### to this:
1073     ###   ( "'1'", "'1'", "'3'" )
1074     return
1075         map {
1076             if ( defined( $_ && $_->[1] ) ) {
1077                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1078             }
1079             else { q{'NULL'}; }
1080         } @bind;
1081 }
1082
1083 sub _query_start {
1084     my ( $self, $sql, @bind ) = @_;
1085
1086     if ( $self->debug ) {
1087         @bind = $self->_fix_bind_params(@bind);
1088
1089         $self->debugobj->query_start( $sql, @bind );
1090     }
1091 }
1092
1093 sub _query_end {
1094     my ( $self, $sql, @bind ) = @_;
1095
1096     if ( $self->debug ) {
1097         @bind = $self->_fix_bind_params(@bind);
1098         $self->debugobj->query_end( $sql, @bind );
1099     }
1100 }
1101
1102 sub _dbh_execute {
1103   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1104
1105   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1106     $ident = $ident->from();
1107   }
1108
1109   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1110
1111   $self->_query_start( $sql, @$bind );
1112
1113   my $sth = $self->sth($sql,$op);
1114
1115   my $placeholder_index = 1;
1116
1117   foreach my $bound (@$bind) {
1118     my $attributes = {};
1119     my($column_name, @data) = @$bound;
1120
1121     if ($bind_attributes) {
1122       $attributes = $bind_attributes->{$column_name}
1123       if defined $bind_attributes->{$column_name};
1124     }
1125
1126     foreach my $data (@data) {
1127       $data = ref $data ? ''.$data : $data; # stringify args
1128
1129       $sth->bind_param($placeholder_index, $data, $attributes);
1130       $placeholder_index++;
1131     }
1132   }
1133
1134   # Can this fail without throwing an exception anyways???
1135   my $rv = $sth->execute();
1136   $self->throw_exception($sth->errstr) if !$rv;
1137
1138   $self->_query_end( $sql, @$bind );
1139
1140   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1141 }
1142
1143 sub _execute {
1144     my $self = shift;
1145     $self->dbh_do('_dbh_execute', @_)
1146 }
1147
1148 sub insert {
1149   my ($self, $source, $to_insert) = @_;
1150
1151   my $ident = $source->from;
1152   my $bind_attributes = $self->source_bind_attributes($source);
1153
1154   $self->ensure_connected;
1155   foreach my $col ( $source->columns ) {
1156     if ( !defined $to_insert->{$col} ) {
1157       my $col_info = $source->column_info($col);
1158
1159       if ( $col_info->{auto_nextval} ) {
1160         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1161       }
1162     }
1163   }
1164
1165   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1166
1167   return $to_insert;
1168 }
1169
1170 ## Still not quite perfect, and EXPERIMENTAL
1171 ## Currently it is assumed that all values passed will be "normal", i.e. not
1172 ## scalar refs, or at least, all the same type as the first set, the statement is
1173 ## only prepped once.
1174 sub insert_bulk {
1175   my ($self, $source, $cols, $data) = @_;
1176   my %colvalues;
1177   my $table = $source->from;
1178   @colvalues{@$cols} = (0..$#$cols);
1179   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1180
1181   $self->_query_start( $sql, @bind );
1182   my $sth = $self->sth($sql);
1183
1184 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1185
1186   ## This must be an arrayref, else nothing works!
1187
1188   my $tuple_status = [];
1189
1190   ##use Data::Dumper;
1191   ##print STDERR Dumper( $data, $sql, [@bind] );
1192
1193   my $time = time();
1194
1195   ## Get the bind_attributes, if any exist
1196   my $bind_attributes = $self->source_bind_attributes($source);
1197
1198   ## Bind the values and execute
1199   my $placeholder_index = 1;
1200
1201   foreach my $bound (@bind) {
1202
1203     my $attributes = {};
1204     my ($column_name, $data_index) = @$bound;
1205
1206     if( $bind_attributes ) {
1207       $attributes = $bind_attributes->{$column_name}
1208       if defined $bind_attributes->{$column_name};
1209     }
1210
1211     my @data = map { $_->[$data_index] } @$data;
1212
1213     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1214     $placeholder_index++;
1215   }
1216   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1217   $self->throw_exception($sth->errstr) if !$rv;
1218
1219   $self->_query_end( $sql, @bind );
1220   return (wantarray ? ($rv, $sth, @bind) : $rv);
1221 }
1222
1223 sub update {
1224   my $self = shift @_;
1225   my $source = shift @_;
1226   my $bind_attributes = $self->source_bind_attributes($source);
1227
1228   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1229 }
1230
1231
1232 sub delete {
1233   my $self = shift @_;
1234   my $source = shift @_;
1235
1236   my $bind_attrs = {}; ## If ever it's needed...
1237
1238   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1239 }
1240
1241 sub _select {
1242   my ($self, $ident, $select, $condition, $attrs) = @_;
1243   my $order = $attrs->{order_by};
1244
1245   if (ref $condition eq 'SCALAR') {
1246     my $unwrap = ${$condition};
1247     if ($unwrap =~ s/ORDER BY (.*)$//i) {
1248       $order = $1;
1249       $condition = \$unwrap;
1250     }
1251   }
1252
1253   my $for = delete $attrs->{for};
1254   my $sql_maker = $self->sql_maker;
1255   local $sql_maker->{for} = $for;
1256
1257   if (exists $attrs->{group_by} || $attrs->{having}) {
1258     $order = {
1259       group_by => $attrs->{group_by},
1260       having => $attrs->{having},
1261       ($order ? (order_by => $order) : ())
1262     };
1263   }
1264   my $bind_attrs = {}; ## Future support
1265   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1266   if ($attrs->{software_limit} ||
1267       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1268         $attrs->{software_limit} = 1;
1269   } else {
1270     $self->throw_exception("rows attribute must be positive if present")
1271       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1272
1273     # MySQL actually recommends this approach.  I cringe.
1274     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1275     push @args, $attrs->{rows}, $attrs->{offset};
1276   }
1277
1278   return $self->_execute(@args);
1279 }
1280
1281 sub source_bind_attributes {
1282   my ($self, $source) = @_;
1283
1284   my $bind_attributes;
1285   foreach my $column ($source->columns) {
1286
1287     my $data_type = $source->column_info($column)->{data_type} || '';
1288     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1289      if $data_type;
1290   }
1291
1292   return $bind_attributes;
1293 }
1294
1295 =head2 select
1296
1297 =over 4
1298
1299 =item Arguments: $ident, $select, $condition, $attrs
1300
1301 =back
1302
1303 Handle a SQL select statement.
1304
1305 =cut
1306
1307 sub select {
1308   my $self = shift;
1309   my ($ident, $select, $condition, $attrs) = @_;
1310   return $self->cursor_class->new($self, \@_, $attrs);
1311 }
1312
1313 sub select_single {
1314   my $self = shift;
1315   my ($rv, $sth, @bind) = $self->_select(@_);
1316   my @row = $sth->fetchrow_array;
1317   if(@row && $sth->fetchrow_array) {
1318     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1319   }
1320   # Need to call finish() to work round broken DBDs
1321   $sth->finish();
1322   return @row;
1323 }
1324
1325 =head2 sth
1326
1327 =over 4
1328
1329 =item Arguments: $sql
1330
1331 =back
1332
1333 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1334
1335 =cut
1336
1337 sub _dbh_sth {
1338   my ($self, $dbh, $sql) = @_;
1339
1340   # 3 is the if_active parameter which avoids active sth re-use
1341   my $sth = $self->disable_sth_caching
1342     ? $dbh->prepare($sql)
1343     : $dbh->prepare_cached($sql, {}, 3);
1344
1345   # XXX You would think RaiseError would make this impossible,
1346   #  but apparently that's not true :(
1347   $self->throw_exception($dbh->errstr) if !$sth;
1348
1349   $sth;
1350 }
1351
1352 sub sth {
1353   my ($self, $sql) = @_;
1354   $self->dbh_do('_dbh_sth', $sql);
1355 }
1356
1357 sub _dbh_columns_info_for {
1358   my ($self, $dbh, $table) = @_;
1359
1360   if ($dbh->can('column_info')) {
1361     my %result;
1362     eval {
1363       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1364       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1365       $sth->execute();
1366       while ( my $info = $sth->fetchrow_hashref() ){
1367         my %column_info;
1368         $column_info{data_type}   = $info->{TYPE_NAME};
1369         $column_info{size}      = $info->{COLUMN_SIZE};
1370         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1371         $column_info{default_value} = $info->{COLUMN_DEF};
1372         my $col_name = $info->{COLUMN_NAME};
1373         $col_name =~ s/^\"(.*)\"$/$1/;
1374
1375         $result{$col_name} = \%column_info;
1376       }
1377     };
1378     return \%result if !$@ && scalar keys %result;
1379   }
1380
1381   my %result;
1382   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1383   $sth->execute;
1384   my @columns = @{$sth->{NAME_lc}};
1385   for my $i ( 0 .. $#columns ){
1386     my %column_info;
1387     $column_info{data_type} = $sth->{TYPE}->[$i];
1388     $column_info{size} = $sth->{PRECISION}->[$i];
1389     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1390
1391     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1392       $column_info{data_type} = $1;
1393       $column_info{size}    = $2;
1394     }
1395
1396     $result{$columns[$i]} = \%column_info;
1397   }
1398   $sth->finish;
1399
1400   foreach my $col (keys %result) {
1401     my $colinfo = $result{$col};
1402     my $type_num = $colinfo->{data_type};
1403     my $type_name;
1404     if(defined $type_num && $dbh->can('type_info')) {
1405       my $type_info = $dbh->type_info($type_num);
1406       $type_name = $type_info->{TYPE_NAME} if $type_info;
1407       $colinfo->{data_type} = $type_name if $type_name;
1408     }
1409   }
1410
1411   return \%result;
1412 }
1413
1414 sub columns_info_for {
1415   my ($self, $table) = @_;
1416   $self->dbh_do('_dbh_columns_info_for', $table);
1417 }
1418
1419 =head2 last_insert_id
1420
1421 Return the row id of the last insert.
1422
1423 =cut
1424
1425 sub _dbh_last_insert_id {
1426     my ($self, $dbh, $source, $col) = @_;
1427     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1428     $dbh->func('last_insert_rowid');
1429 }
1430
1431 sub last_insert_id {
1432   my $self = shift;
1433   $self->dbh_do('_dbh_last_insert_id', @_);
1434 }
1435
1436 =head2 sqlt_type
1437
1438 Returns the database driver name.
1439
1440 =cut
1441
1442 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1443
1444 =head2 bind_attribute_by_data_type
1445
1446 Given a datatype from column info, returns a database specific bind attribute for
1447 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1448 just handle it.
1449
1450 Generally only needed for special case column types, like bytea in postgres.
1451
1452 =cut
1453
1454 sub bind_attribute_by_data_type {
1455     return;
1456 }
1457
1458 =head2 create_ddl_dir
1459
1460 =over 4
1461
1462 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1463
1464 =back
1465
1466 Creates a SQL file based on the Schema, for each of the specified
1467 database types, in the given directory.
1468
1469 By default, C<\%sqlt_args> will have
1470
1471  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1472
1473 merged with the hash passed in. To disable any of those features, pass in a
1474 hashref like the following
1475
1476  { ignore_constraint_names => 0, # ... other options }
1477
1478 =cut
1479
1480 sub create_ddl_dir {
1481   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1482
1483   if(!$dir || !-d $dir) {
1484     warn "No directory given, using ./\n";
1485     $dir = "./";
1486   }
1487   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1488   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1489   $version ||= $schema->VERSION || '1.x';
1490   $sqltargs = {
1491     add_drop_table => 1,
1492     ignore_constraint_names => 1,
1493     ignore_index_names => 1,
1494     %{$sqltargs || {}}
1495   };
1496
1497   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1498       . $self->_check_sqlt_message . q{'})
1499           if !$self->_check_sqlt_version;
1500
1501   my $sqlt = SQL::Translator->new( $sqltargs );
1502
1503   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1504   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1505
1506   foreach my $db (@$databases) {
1507     $sqlt->reset();
1508     $sqlt = $self->configure_sqlt($sqlt, $db);
1509     $sqlt->{schema} = $sqlt_schema;
1510     $sqlt->producer($db);
1511
1512     my $file;
1513     my $filename = $schema->ddl_filename($db, $version, $dir);
1514     if (-e $filename && (!$version || ($version == $schema->schema_version()))) {
1515       # if we are dumping the current version, overwrite the DDL
1516       warn "Overwriting existing DDL file - $filename";
1517       unlink($filename);
1518     }
1519
1520     my $output = $sqlt->translate;
1521     if(!$output) {
1522       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1523       next;
1524     }
1525     if(!open($file, ">$filename")) {
1526       $self->throw_exception("Can't open $filename for writing ($!)");
1527       next;
1528     }
1529     print $file $output;
1530     close($file);
1531
1532     next unless ($preversion);
1533
1534     require SQL::Translator::Diff;
1535
1536     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1537     if(!-e $prefilename) {
1538       warn("No previous schema file found ($prefilename)");
1539       next;
1540     }
1541
1542     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1543     if(-e $difffile) {
1544       warn("Overwriting existing diff file - $difffile");
1545       unlink($difffile);
1546     }
1547
1548     my $source_schema;
1549     {
1550       my $t = SQL::Translator->new($sqltargs);
1551       $t->debug( 0 );
1552       $t->trace( 0 );
1553       $t->parser( $db )                       or die $t->error;
1554       $t = $self->configure_sqlt($t, $db);
1555       my $out = $t->translate( $prefilename ) or die $t->error;
1556       $source_schema = $t->schema;
1557       unless ( $source_schema->name ) {
1558         $source_schema->name( $prefilename );
1559       }
1560     }
1561
1562     # The "new" style of producers have sane normalization and can support
1563     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1564     # And we have to diff parsed SQL against parsed SQL.
1565     my $dest_schema = $sqlt_schema;
1566
1567     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1568       my $t = SQL::Translator->new($sqltargs);
1569       $t->debug( 0 );
1570       $t->trace( 0 );
1571       $t->parser( $db )                    or die $t->error;
1572       $t = $self->configure_sqlt($t, $db);
1573       my $out = $t->translate( $filename ) or die $t->error;
1574       $dest_schema = $t->schema;
1575       $dest_schema->name( $filename )
1576         unless $dest_schema->name;
1577     }
1578
1579     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1580                                                   $dest_schema,   $db,
1581                                                   $sqltargs
1582                                                  );
1583     if(!open $file, ">$difffile") {
1584       $self->throw_exception("Can't write to $difffile ($!)");
1585       next;
1586     }
1587     print $file $diff;
1588     close($file);
1589   }
1590 }
1591
1592 sub configure_sqlt() {
1593   my $self = shift;
1594   my $tr = shift;
1595   my $db = shift || $self->sqlt_type;
1596   if ($db eq 'PostgreSQL') {
1597     $tr->quote_table_names(0);
1598     $tr->quote_field_names(0);
1599   }
1600   return $tr;
1601 }
1602
1603 =head2 deployment_statements
1604
1605 =over 4
1606
1607 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1608
1609 =back
1610
1611 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1612 The database driver name is given by C<$type>, though the value from
1613 L</sqlt_type> is used if it is not specified.
1614
1615 C<$directory> is used to return statements from files in a previously created
1616 L</create_ddl_dir> directory and is optional. The filenames are constructed
1617 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1618
1619 If no C<$directory> is specified then the statements are constructed on the
1620 fly using L<SQL::Translator> and C<$version> is ignored.
1621
1622 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1623
1624 =cut
1625
1626 sub deployment_statements {
1627   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1628   # Need to be connected to get the correct sqlt_type
1629   $self->ensure_connected() unless $type;
1630   $type ||= $self->sqlt_type;
1631   $version ||= $schema->VERSION || '1.x';
1632   $dir ||= './';
1633   my $filename = $schema->ddl_filename($type, $dir, $version);
1634   if(-f $filename)
1635   {
1636       my $file;
1637       open($file, "<$filename")
1638         or $self->throw_exception("Can't open $filename ($!)");
1639       my @rows = <$file>;
1640       close($file);
1641       return join('', @rows);
1642   }
1643
1644   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1645       . $self->_check_sqlt_message . q{'})
1646           if !$self->_check_sqlt_version;
1647
1648   require SQL::Translator::Parser::DBIx::Class;
1649   eval qq{use SQL::Translator::Producer::${type}};
1650   $self->throw_exception($@) if $@;
1651
1652   # sources needs to be a parser arg, but for simplicty allow at top level
1653   # coming in
1654   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1655       if exists $sqltargs->{sources};
1656
1657   my $tr = SQL::Translator->new(%$sqltargs);
1658   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1659   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1660 }
1661
1662 sub deploy {
1663   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1664   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1665     foreach my $line ( split(";\n", $statement)) {
1666       next if($line =~ /^--/);
1667       next if(!$line);
1668 #      next if($line =~ /^DROP/m);
1669       next if($line =~ /^BEGIN TRANSACTION/m);
1670       next if($line =~ /^COMMIT/m);
1671       next if $line =~ /^\s+$/; # skip whitespace only
1672       $self->_query_start($line);
1673       eval {
1674         $self->dbh->do($line); # shouldn't be using ->dbh ?
1675       };
1676       if ($@) {
1677         warn qq{$@ (running "${line}")};
1678       }
1679       $self->_query_end($line);
1680     }
1681   }
1682 }
1683
1684 =head2 datetime_parser
1685
1686 Returns the datetime parser class
1687
1688 =cut
1689
1690 sub datetime_parser {
1691   my $self = shift;
1692   return $self->{datetime_parser} ||= do {
1693     $self->ensure_connected;
1694     $self->build_datetime_parser(@_);
1695   };
1696 }
1697
1698 =head2 datetime_parser_type
1699
1700 Defines (returns) the datetime parser class - currently hardwired to
1701 L<DateTime::Format::MySQL>
1702
1703 =cut
1704
1705 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1706
1707 =head2 build_datetime_parser
1708
1709 See L</datetime_parser>
1710
1711 =cut
1712
1713 sub build_datetime_parser {
1714   my $self = shift;
1715   my $type = $self->datetime_parser_type(@_);
1716   eval "use ${type}";
1717   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1718   return $type;
1719 }
1720
1721 {
1722     my $_check_sqlt_version; # private
1723     my $_check_sqlt_message; # private
1724     sub _check_sqlt_version {
1725         return $_check_sqlt_version if defined $_check_sqlt_version;
1726         eval 'use SQL::Translator "0.09"';
1727         $_check_sqlt_message = $@ || '';
1728         $_check_sqlt_version = !$@;
1729     }
1730
1731     sub _check_sqlt_message {
1732         _check_sqlt_version if !defined $_check_sqlt_message;
1733         $_check_sqlt_message;
1734     }
1735 }
1736
1737 =head2 is_replicating
1738
1739 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1740 replicate from a master database.  Default is undef, which is the result
1741 returned by databases that don't support replication.
1742
1743 =cut
1744
1745 sub is_replicating {
1746     return;
1747
1748 }
1749
1750 =head2 lag_behind_master
1751
1752 Returns a number that represents a certain amount of lag behind a master db
1753 when a given storage is replicating.  The number is database dependent, but
1754 starts at zero and increases with the amount of lag. Default in undef
1755
1756 =cut
1757
1758 sub lag_behind_master {
1759     return;
1760 }
1761
1762 sub DESTROY {
1763   my $self = shift;
1764   return if !$self->_dbh;
1765   $self->_verify_pid;
1766   $self->_dbh(undef);
1767 }
1768
1769 1;
1770
1771 =head1 SQL METHODS
1772
1773 The module defines a set of methods within the DBIC::SQL::Abstract
1774 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1775 SQL query functions.
1776
1777 The following methods are extended:-
1778
1779 =over 4
1780
1781 =item delete
1782
1783 =item insert
1784
1785 =item select
1786
1787 =item update
1788
1789 =item limit_dialect
1790
1791 See L</connect_info> for details.
1792 For setting, this method is deprecated in favor of L</connect_info>.
1793
1794 =item quote_char
1795
1796 See L</connect_info> for details.
1797 For setting, this method is deprecated in favor of L</connect_info>.
1798
1799 =item name_sep
1800
1801 See L</connect_info> for details.
1802 For setting, this method is deprecated in favor of L</connect_info>.
1803
1804 =back
1805
1806 =head1 AUTHORS
1807
1808 Matt S. Trout <mst@shadowcatsystems.co.uk>
1809
1810 Andy Grundman <andy@hybridized.org>
1811
1812 =head1 LICENSE
1813
1814 You may distribute this code under the same terms as Perl itself.
1815
1816 =cut