lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use Context::Preserve 'preserve_context';
  13 use SQL::Abstract qw(is_plain_value is_literal_value);
  14 use DBIx::Class::_Util qw(
  15   quote_sub perlstring serialize dump_value
  16   dbic_internal_try dbic_internal_catch
  17   detected_reinvoked_destructor scope_guard
  18   mkdir_p
  19 );
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. We also need to separate accessors
  85 # from plain old method calls, since an accessor called as a setter
  86 # does *not* need the driver determination loop fired (and in fact
  87 # can produce hard to find bugs, like e.g. losing on_connect_*
  88 # semantics on fresh connections)
  89 #
  90 # The construct below is simply a parameterized around()
  91 my $storage_accessor_idx = { map { $_ => 1 } qw(
  92   sqlt_type
  93   datetime_parser_type
  94
  95   sql_maker
  96   cursor_class
  97 )};
  98 for my $meth (keys %$storage_accessor_idx, qw(
  99   deployment_statements
 100
 101   build_datetime_parser
 102
 103   txn_begin
 104
 105   insert
 106   update
 107   delete
 108   select
 109   select_single
 110
 111   _insert_bulk
 112
 113   with_deferred_fk_checks
 114
 115   get_use_dbms_capability
 116   get_dbms_capability
 117
 118   _server_info
 119   _get_server_version
 120 )) {
 121
 122   my $orig = __PACKAGE__->can ($meth)
 123     or die "$meth is not a ::Storage::DBI method!";
 124
 125   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 126
 127   quote_sub
 128     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 129
 130     if (
 131       # if this is an actual *setter* - just set it, no need to connect
 132       # and determine the driver
 133       !( %1$s and @_ > 1 )
 134         and
 135       # only fire when invoked on an instance, a valid class-based invocation
 136       # would e.g. be setting a default for an inherited accessor
 137       ref $_[0]
 138         and
 139       ! $_[0]->{_driver_determined}
 140         and
 141       ! $_[0]->{_in_determine_driver}
 142         and
 143       # Only try to determine stuff if we have *something* that either is or can
 144       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 145       # to still be marginally useful
 146       $_[0]->_dbi_connect_info->[0]
 147     ) {
 148       $_[0]->_determine_driver;
 149
 150       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 151       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 152
 153       my $cref = $_[0]->can(%2$s);
 154       goto $cref;
 155     }
 156
 157     goto $orig;
 158 EOC
 159 }
 160
 161 =head1 NAME
 162
 163 DBIx::Class::Storage::DBI - DBI storage handler
 164
 165 =head1 SYNOPSIS
 166
 167   my $schema = MySchema->connect('dbi:SQLite:my.db');
 168
 169   $schema->storage->debug(1);
 170
 171   my @stuff = $schema->storage->dbh_do(
 172     sub {
 173       my ($storage, $dbh, @args) = @_;
 174       $dbh->do("DROP TABLE authors");
 175     },
 176     @column_list
 177   );
 178
 179   $schema->resultset('Book')->search({
 180      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 181   });
 182
 183 =head1 DESCRIPTION
 184
 185 This class represents the connection to an RDBMS via L<DBI>.  See
 186 L<DBIx::Class::Storage> for general information.  This pod only
 187 documents DBI-specific methods and behaviors.
 188
 189 =head1 METHODS
 190
 191 =cut
 192
 193 sub new {
 194   my $new = shift->next::method(@_);
 195
 196   $new->_sql_maker_opts({});
 197   $new->_dbh_details({});
 198   $new->{_in_do_block} = 0;
 199
 200   # read below to see what this does
 201   $new->_arm_global_destructor;
 202
 203   $new;
 204 }
 205
 206 # This is hack to work around perl shooting stuff in random
 207 # order on exit(). If we do not walk the remaining storage
 208 # objects in an END block, there is a *small but real* chance
 209 # of a fork()ed child to kill the parent's shared DBI handle,
 210 # *before perl reaches the DESTROY in this package*
 211 # Yes, it is ugly and effective.
 212 # Additionally this registry is used by the CLONE method to
 213 # make sure no handles are shared between threads
 214 {
 215   my %seek_and_destroy;
 216
 217   sub _arm_global_destructor {
 218
 219     # quick "garbage collection" pass - prevents the registry
 220     # from slowly growing with a bunch of undef-valued keys
 221     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 222       for keys %seek_and_destroy;
 223
 224     weaken (
 225       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 226     );
 227
 228     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 229     # collected before leaving this scope. Depending on the code above, this
 230     # may very well be just a preventive measure guarding future modifications
 231     undef;
 232   }
 233
 234   END {
 235
 236     if(
 237       ! DBIx::Class::_ENV_::BROKEN_FORK
 238         and
 239       my @instances = grep { defined $_ } values %seek_and_destroy
 240     ) {
 241       local $?; # just in case the DBI destructor changes it somehow
 242
 243       # disarm the handle if not native to this process (see comment on top)
 244       $_->_verify_pid for @instances;
 245     }
 246
 247     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 248     # collected before leaving this scope. Depending on the code above, this
 249     # may very well be just a preventive measure guarding future modifications
 250     undef;
 251   }
 252
 253   sub DBIx::Class::__DBI_Storage_iThreads_handler__::CLONE {
 254     # As per DBI's recommendation, DBIC disconnects all handles as
 255     # soon as possible (DBIC will reconnect only on demand from within
 256     # the thread)
 257     my @instances = grep { defined $_ } values %seek_and_destroy;
 258     %seek_and_destroy = ();
 259
 260     for (@instances) {
 261       $_->_dbh(undef);
 262       $_->disconnect;
 263
 264       # properly renumber existing refs
 265       $_->_arm_global_destructor
 266     }
 267
 268     # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 269     # collected before leaving this scope. Depending on the code above, this
 270     # may very well be just a preventive measure guarding future modifications
 271     undef;
 272   }
 273 }
 274
 275 sub DESTROY {
 276   return if &detected_reinvoked_destructor;
 277
 278   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 279
 280   # some databases spew warnings on implicit disconnect
 281   return unless defined $_[0]->_dbh;
 282
 283   local $SIG{__WARN__} = sub {};
 284   $_[0]->_dbh(undef);
 285   # not calling ->disconnect here - we are being destroyed - nothing to reset
 286
 287   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 288   # collected before leaving this scope. Depending on the code above, this
 289   # may very well be just a preventive measure guarding future modifications
 290   undef;
 291 }
 292
 293 # handle pid changes correctly - do not destroy parent's connection
 294 sub _verify_pid {
 295
 296   my $pid = $_[0]->_conn_pid;
 297
 298   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 299     $dbh->{InactiveDestroy} = 1;
 300     $_[0]->_dbh(undef);
 301     $_[0]->disconnect;
 302   }
 303
 304   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 305   # collected before leaving this scope. Depending on the code above, this
 306   # may very well be just a preventive measure guarding future modifications
 307   undef;
 308 }
 309
 310 =head2 connect_info
 311
 312 This method is normally called by L<DBIx::Class::Schema/connection>, which
 313 encapsulates its argument list in an arrayref before passing them here.
 314
 315 The argument list may contain:
 316
 317 =over
 318
 319 =item *
 320
 321 The same 4-element argument set one would normally pass to
 322 L<DBI/connect>, optionally followed by
 323 L<extra attributes|/DBIx::Class specific connection attributes>
 324 recognized by DBIx::Class:
 325
 326   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 327
 328 =item *
 329
 330 A single code reference which returns a connected
 331 L<DBI database handle|DBI/connect> optionally followed by
 332 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 333 by DBIx::Class:
 334
 335   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 336
 337 =item *
 338
 339 A single hashref with all the attributes and the dsn/user/password
 340 mixed together:
 341
 342   $connect_info_args = [{
 343     dsn => $dsn,
 344     user => $user,
 345     password => $pass,
 346     %dbi_attributes,
 347     %extra_attributes,
 348   }];
 349
 350   $connect_info_args = [{
 351     dbh_maker => sub { DBI->connect (...) },
 352     %dbi_attributes,
 353     %extra_attributes,
 354   }];
 355
 356 This is particularly useful for L<Catalyst> based applications, allowing the
 357 following config (L<Config::General> style):
 358
 359   <Model::DB>
 360     schema_class   App::DB
 361     <connect_info>
 362       dsn          dbi:mysql:database=test
 363       user         testuser
 364       password     TestPass
 365       AutoCommit   1
 366     </connect_info>
 367   </Model::DB>
 368
 369 The C<dsn>/C<user>/C<password> combination can be substituted by the
 370 C<dbh_maker> key whose value is a coderef that returns a connected
 371 L<DBI database handle|DBI/connect>
 372
 373 =back
 374
 375 Please note that the L<DBI> docs recommend that you always explicitly
 376 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 377 recommends that it be set to I<1>, and that you perform transactions
 378 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 379 to I<1> if you do not do explicitly set it to zero.  This is the default
 380 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 381
 382 =head3 DBIx::Class specific connection attributes
 383
 384 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 385 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 386 the following connection options. These options can be mixed in with your other
 387 L<DBI> connection attributes, or placed in a separate hashref
 388 (C<\%extra_attributes>) as shown above.
 389
 390 Every time C<connect_info> is invoked, any previous settings for
 391 these options will be cleared before setting the new ones, regardless of
 392 whether any options are specified in the new C<connect_info>.
 393
 394
 395 =over
 396
 397 =item on_connect_do
 398
 399 Specifies things to do immediately after connecting or re-connecting to
 400 the database.  Its value may contain:
 401
 402 =over
 403
 404 =item a scalar
 405
 406 This contains one SQL statement to execute.
 407
 408 =item an array reference
 409
 410 This contains SQL statements to execute in order.  Each element contains
 411 a string or a code reference that returns a string.
 412
 413 =item a code reference
 414
 415 This contains some code to execute.  Unlike code references within an
 416 array reference, its return value is ignored.
 417
 418 =back
 419
 420 =item on_disconnect_do
 421
 422 Takes arguments in the same form as L</on_connect_do> and executes them
 423 immediately before disconnecting from the database.
 424
 425 Note, this only runs if you explicitly call L</disconnect> on the
 426 storage object.
 427
 428 =item on_connect_call
 429
 430 A more generalized form of L</on_connect_do> that calls the specified
 431 C<connect_call_METHOD> methods in your storage driver.
 432
 433   on_connect_do => 'select 1'
 434
 435 is equivalent to:
 436
 437   on_connect_call => [ [ do_sql => 'select 1' ] ]
 438
 439 Its values may contain:
 440
 441 =over
 442
 443 =item a scalar
 444
 445 Will call the C<connect_call_METHOD> method.
 446
 447 =item a code reference
 448
 449 Will execute C<< $code->($storage) >>
 450
 451 =item an array reference
 452
 453 Each value can be a method name or code reference.
 454
 455 =item an array of arrays
 456
 457 For each array, the first item is taken to be the C<connect_call_> method name
 458 or code reference, and the rest are parameters to it.
 459
 460 =back
 461
 462 Some predefined storage methods you may use:
 463
 464 =over
 465
 466 =item do_sql
 467
 468 Executes a SQL string or a code reference that returns a SQL string. This is
 469 what L</on_connect_do> and L</on_disconnect_do> use.
 470
 471 It can take:
 472
 473 =over
 474
 475 =item a scalar
 476
 477 Will execute the scalar as SQL.
 478
 479 =item an arrayref
 480
 481 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 482 attributes hashref and bind values.
 483
 484 =item a code reference
 485
 486 Will execute C<< $code->($storage) >> and execute the return array refs as
 487 above.
 488
 489 =back
 490
 491 =item datetime_setup
 492
 493 Execute any statements necessary to initialize the database session to return
 494 and accept datetime/timestamp values used with
 495 L<DBIx::Class::InflateColumn::DateTime>.
 496
 497 Only necessary for some databases, see your specific storage driver for
 498 implementation details.
 499
 500 =back
 501
 502 =item on_disconnect_call
 503
 504 Takes arguments in the same form as L</on_connect_call> and executes them
 505 immediately before disconnecting from the database.
 506
 507 Calls the C<disconnect_call_METHOD> methods as opposed to the
 508 C<connect_call_METHOD> methods called by L</on_connect_call>.
 509
 510 Note, this only runs if you explicitly call L</disconnect> on the
 511 storage object.
 512
 513 =item disable_sth_caching
 514
 515 If set to a true value, this option will disable the caching of
 516 statement handles via L<DBI/prepare_cached>.
 517
 518 =item limit_dialect
 519
 520 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 521 default L</sql_limit_dialect> setting of the storage (if any). For a list
 522 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 523
 524 =item quote_names
 525
 526 When true automatically sets L</quote_char> and L</name_sep> to the characters
 527 appropriate for your particular RDBMS. This option is preferred over specifying
 528 L</quote_char> directly.
 529
 530 =item quote_char
 531
 532 Specifies what characters to use to quote table and column names.
 533
 534 C<quote_char> expects either a single character, in which case is it
 535 is placed on either side of the table/column name, or an arrayref of length
 536 2 in which case the table/column name is placed between the elements.
 537
 538 For example under MySQL you should use C<< quote_char => '`' >>, and for
 539 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 540
 541 =item name_sep
 542
 543 This parameter is only useful in conjunction with C<quote_char>, and is used to
 544 specify the character that separates elements (schemas, tables, columns) from
 545 each other. If unspecified it defaults to the most commonly used C<.>.
 546
 547 =item unsafe
 548
 549 This Storage driver normally installs its own C<HandleError>, sets
 550 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 551 all database handles, including those supplied by a coderef.  It does this
 552 so that it can have consistent and useful error behavior.
 553
 554 If you set this option to a true value, Storage will not do its usual
 555 modifications to the database handle's attributes, and instead relies on
 556 the settings in your connect_info DBI options (or the values you set in
 557 your connection coderef, in the case that you are connecting via coderef).
 558
 559 Note that your custom settings can cause Storage to malfunction,
 560 especially if you set a C<HandleError> handler that suppresses exceptions
 561 and/or disable C<RaiseError>.
 562
 563 =item auto_savepoint
 564
 565 If this option is true, L<DBIx::Class> will use savepoints when nesting
 566 transactions, making it possible to recover from failure in the inner
 567 transaction without having to abort all outer transactions.
 568
 569 =item cursor_class
 570
 571 Use this argument to supply a cursor class other than the default
 572 L<DBIx::Class::Storage::DBI::Cursor>.
 573
 574 =back
 575
 576 Some real-life examples of arguments to L</connect_info> and
 577 L<DBIx::Class::Schema/connect>
 578
 579   # Simple SQLite connection
 580   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 581
 582   # Connect via subref
 583   ->connect_info([ sub { DBI->connect(...) } ]);
 584
 585   # Connect via subref in hashref
 586   ->connect_info([{
 587     dbh_maker => sub { DBI->connect(...) },
 588     on_connect_do => 'alter session ...',
 589   }]);
 590
 591   # A bit more complicated
 592   ->connect_info(
 593     [
 594       'dbi:Pg:dbname=foo',
 595       'postgres',
 596       'my_pg_password',
 597       { AutoCommit => 1 },
 598       { quote_char => q{"} },
 599     ]
 600   );
 601
 602   # Equivalent to the previous example
 603   ->connect_info(
 604     [
 605       'dbi:Pg:dbname=foo',
 606       'postgres',
 607       'my_pg_password',
 608       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 609     ]
 610   );
 611
 612   # Same, but with hashref as argument
 613   # See parse_connect_info for explanation
 614   ->connect_info(
 615     [{
 616       dsn         => 'dbi:Pg:dbname=foo',
 617       user        => 'postgres',
 618       password    => 'my_pg_password',
 619       AutoCommit  => 1,
 620       quote_char  => q{"},
 621       name_sep    => q{.},
 622     }]
 623   );
 624
 625   # Subref + DBIx::Class-specific connection options
 626   ->connect_info(
 627     [
 628       sub { DBI->connect(...) },
 629       {
 630           quote_char => q{`},
 631           name_sep => q{@},
 632           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 633           disable_sth_caching => 1,
 634       },
 635     ]
 636   );
 637
 638
 639
 640 =cut
 641
 642 sub connect_info {
 643   my ($self, $info) = @_;
 644
 645   return $self->_connect_info if !$info;
 646
 647   $self->_connect_info($info); # copy for _connect_info
 648
 649   $info = $self->_normalize_connect_info($info)
 650     if ref $info eq 'ARRAY';
 651
 652   my %attrs = (
 653     %{ $self->_default_dbi_connect_attributes || {} },
 654     %{ $info->{attributes} || {} },
 655   );
 656
 657   my @args = @{ $info->{arguments} };
 658
 659   if (keys %attrs and ref $args[0] ne 'CODE') {
 660     carp_unique (
 661         'You provided explicit AutoCommit => 0 in your connection_info. '
 662       . 'This is almost universally a bad idea (see the footnotes of '
 663       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 664       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 665       . 'this warning.'
 666     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 667
 668     push @args, \%attrs if keys %attrs;
 669   }
 670
 671   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 672   # OR a single-element coderef-based $dbh factory
 673   $self->_dbi_connect_info(\@args);
 674
 675   # extract the individual storage options
 676   for my $storage_opt (keys %{ $info->{storage_options} }) {
 677     my $value = $info->{storage_options}{$storage_opt};
 678
 679     $self->$storage_opt($value);
 680   }
 681
 682   # Extract the individual sqlmaker options
 683   #
 684   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 685   #  the new set of options
 686   $self->_sql_maker(undef);
 687   $self->_sql_maker_opts({});
 688
 689   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 690     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 691
 692     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 693   }
 694
 695   # FIXME - dirty:
 696   # save attributes in a separate accessor so they are always
 697   # introspectable, even in case of a CODE $dbhmaker
 698   $self->_dbic_connect_attributes (\%attrs);
 699
 700   return $self->_connect_info;
 701 }
 702
 703 sub _dbi_connect_info {
 704   my $self = shift;
 705
 706   return $self->{_dbi_connect_info} = $_[0]
 707     if @_;
 708
 709   my $conninfo = $self->{_dbi_connect_info} || [];
 710
 711   # last ditch effort to grab a DSN
 712   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 713     my @new_conninfo = @$conninfo;
 714     $new_conninfo[0] = $ENV{DBI_DSN};
 715     $conninfo = \@new_conninfo;
 716   }
 717
 718   return $conninfo;
 719 }
 720
 721
 722 sub _normalize_connect_info {
 723   my ($self, $info_arg) = @_;
 724   my %info;
 725
 726   my @args = @$info_arg;  # take a shallow copy for further mutilation
 727
 728   # combine/pre-parse arguments depending on invocation style
 729
 730   my %attrs;
 731   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 732     %attrs = %{ $args[1] || {} };
 733     @args = $args[0];
 734   }
 735   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 736     %attrs = %{$args[0]};
 737     @args = ();
 738     if (my $code = delete $attrs{dbh_maker}) {
 739       @args = $code;
 740
 741       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 742       if (@ignored) {
 743         carp sprintf (
 744             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 745           . "to the result of 'dbh_maker'",
 746
 747           join (', ', map { "'$_'" } (@ignored) ),
 748         );
 749       }
 750     }
 751     else {
 752       @args = delete @attrs{qw/dsn user password/};
 753     }
 754   }
 755   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 756     %attrs = (
 757       % { $args[3] || {} },
 758       % { $args[4] || {} },
 759     );
 760     @args = @args[0,1,2];
 761   }
 762
 763   $info{arguments} = \@args;
 764
 765   my @storage_opts = grep exists $attrs{$_},
 766     @storage_options, 'cursor_class';
 767
 768   @{ $info{storage_options} }{@storage_opts} =
 769     delete @attrs{@storage_opts} if @storage_opts;
 770
 771   my @sql_maker_opts = grep exists $attrs{$_},
 772     qw/limit_dialect quote_char name_sep quote_names/;
 773
 774   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 775     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 776
 777   $info{attributes} = \%attrs if %attrs;
 778
 779   return \%info;
 780 }
 781
 782 sub _default_dbi_connect_attributes () {
 783   +{
 784     AutoCommit => 1,
 785     PrintError => 0,
 786     RaiseError => 1,
 787     ShowErrorStatement => 1,
 788   };
 789 }
 790
 791 =head2 on_connect_do
 792
 793 This method is deprecated in favour of setting via L</connect_info>.
 794
 795 =cut
 796
 797 =head2 on_disconnect_do
 798
 799 This method is deprecated in favour of setting via L</connect_info>.
 800
 801 =cut
 802
 803 sub _parse_connect_do {
 804   my ($self, $type) = @_;
 805
 806   my $val = $self->$type;
 807   return () if not defined $val;
 808
 809   my @res;
 810
 811   if (not ref($val)) {
 812     push @res, [ 'do_sql', $val ];
 813   } elsif (ref($val) eq 'CODE') {
 814     push @res, $val;
 815   } elsif (ref($val) eq 'ARRAY') {
 816     push @res, map { [ 'do_sql', $_ ] } @$val;
 817   } else {
 818     $self->throw_exception("Invalid type for $type: ".ref($val));
 819   }
 820
 821   return \@res;
 822 }
 823
 824 =head2 dbh_do
 825
 826 Arguments: ($subref | $method_name), @extra_coderef_args?
 827
 828 Execute the given $subref or $method_name using the new exception-based
 829 connection management.
 830
 831 The first two arguments will be the storage object that C<dbh_do> was called
 832 on and a database handle to use.  Any additional arguments will be passed
 833 verbatim to the called subref as arguments 2 and onwards.
 834
 835 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 836 exception handling and reconnection (or failover in future subclasses).
 837
 838 Your subref should have no side-effects outside of the database, as
 839 there is the potential for your subref to be partially double-executed
 840 if the database connection was stale/dysfunctional.
 841
 842 Example:
 843
 844   my @stuff = $schema->storage->dbh_do(
 845     sub {
 846       my ($storage, $dbh, @cols) = @_;
 847       my $cols = join(q{, }, @cols);
 848       $dbh->selectrow_array("SELECT $cols FROM foo");
 849     },
 850     @column_list
 851   );
 852
 853 =cut
 854
 855 sub dbh_do {
 856   my $self = shift;
 857   my $run_target = shift; # either a coderef or a method name
 858
 859   # short circuit when we know there is no need for a runner
 860   #
 861   # FIXME - assumption may be wrong
 862   # the rationale for the txn_depth check is that if this block is a part
 863   # of a larger transaction, everything up to that point is screwed anyway
 864   return $self->$run_target($self->_get_dbh, @_)
 865     if $self->{_in_do_block} or $self->transaction_depth;
 866
 867   # take a ref instead of a copy, to preserve @_ aliasing
 868   # semantics within the coderef, but only if needed
 869   # (pseudoforking doesn't like this trick much)
 870   my $args = @_ ? \@_ : [];
 871
 872   DBIx::Class::Storage::BlockRunner->new(
 873     storage => $self,
 874     wrap_txn => 0,
 875     retry_handler => sub {
 876       $_[0]->failed_attempt_count == 1
 877         and
 878       ! $_[0]->storage->connected
 879     },
 880   )->run(sub {
 881     $self->$run_target ($self->_get_dbh, @$args )
 882   });
 883 }
 884
 885 sub txn_do {
 886   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 887   shift->next::method(@_);
 888 }
 889
 890 =head2 disconnect
 891
 892 Our C<disconnect> method also performs a rollback first if the
 893 database is not in C<AutoCommit> mode.
 894
 895 =cut
 896
 897 sub disconnect {
 898   my $self = shift;
 899
 900   # this physical disconnect below might very well throw
 901   # in order to unambiguously reset the state - do the cleanup in guard
 902
 903   my $g = scope_guard {
 904
 905     defined( $self->_dbh )
 906       and dbic_internal_try { $self->_dbh->disconnect };
 907
 908     $self->_dbh(undef);
 909     $self->_dbh_details({});
 910     $self->transaction_depth(undef);
 911     $self->_dbh_autocommit(undef);
 912     $self->savepoints([]);
 913
 914     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 915     #$self->_sql_maker(undef); # this may also end up being different
 916   };
 917
 918   if( $self->_dbh ) {
 919
 920     $self->_do_connection_actions(disconnect_call_ => $_) for (
 921       ( $self->on_disconnect_call || () ),
 922       $self->_parse_connect_do ('on_disconnect_do')
 923     );
 924
 925     # stops the "implicit rollback on disconnect" warning
 926     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 927   }
 928
 929   # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
 930   # collected before leaving this scope. Depending on the code above, this
 931   # may very well be just a preventive measure guarding future modifications
 932   undef;
 933 }
 934
 935 =head2 with_deferred_fk_checks
 936
 937 =over 4
 938
 939 =item Arguments: C<$coderef>
 940
 941 =item Return Value: The return value of $coderef
 942
 943 =back
 944
 945 Storage specific method to run the code ref with FK checks deferred or
 946 in MySQL's case disabled entirely.
 947
 948 =cut
 949
 950 # Storage subclasses should override this
 951 sub with_deferred_fk_checks {
 952   #my ($self, $sub) = @_;
 953   $_[1]->();
 954 }
 955
 956 =head2 connected
 957
 958 =over
 959
 960 =item Arguments: none
 961
 962 =item Return Value: 1|0
 963
 964 =back
 965
 966 Verifies that the current database handle is active and ready to execute
 967 an SQL statement (e.g. the connection did not get stale, server is still
 968 answering, etc.) This method is used internally by L</dbh>.
 969
 970 =cut
 971
 972 sub connected {
 973   return 0 unless $_[0]->_seems_connected;
 974
 975   #be on the safe side
 976   local $_[0]->_dbh->{RaiseError} = 1;
 977
 978   return $_[0]->_ping;
 979 }
 980
 981 sub _seems_connected {
 982   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 983
 984   $_[0]->_dbh
 985     and
 986   $_[0]->_dbh->FETCH('Active')
 987     and
 988   return 1;
 989
 990   # explicitly reset all state
 991   $_[0]->disconnect;
 992   return 0;
 993 }
 994
 995 sub _ping {
 996   ($_[0]->_dbh || return 0)->ping;
 997 }
 998
 999 sub ensure_connected {
1000   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
1001 }
1002
1003 =head2 dbh
1004
1005 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
1006 is guaranteed to be healthy by implicitly calling L</connected>, and if
1007 necessary performing a reconnection before returning. Keep in mind that this
1008 is very B<expensive> on some database engines. Consider using L</dbh_do>
1009 instead.
1010
1011 =cut
1012
1013 sub dbh {
1014   # maybe save a ping call
1015   $_[0]->_dbh
1016     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
1017     : $_[0]->_populate_dbh
1018   ;
1019 }
1020
1021 # this is the internal "get dbh or connect (don't check)" method
1022 sub _get_dbh {
1023   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1024   $_[0]->_dbh || $_[0]->_populate_dbh;
1025 }
1026
1027 # *DELIBERATELY* not a setter (for the time being)
1028 # Too intertwined with everything else for any kind of sanity
1029 sub sql_maker {
1030   my $self = shift;
1031
1032   $self->throw_exception('sql_maker() is not a setter method') if @_;
1033
1034   unless ($self->_sql_maker) {
1035     my $sql_maker_class = $self->sql_maker_class;
1036
1037     my %opts = %{$self->_sql_maker_opts||{}};
1038     my $dialect =
1039       $opts{limit_dialect}
1040         ||
1041       $self->sql_limit_dialect
1042         ||
1043       do {
1044         my $s_class = (ref $self) || $self;
1045         carp_unique (
1046           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1047         . 'have not supplied an explicit limit_dialect in your connection_info. '
1048         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1049         . 'databases but can be (and often is) painfully slow. '
1050         . "Please file an RT ticket against '$s_class'"
1051         ) if $self->_dbi_connect_info->[0];
1052
1053         'GenericSubQ';
1054       }
1055     ;
1056
1057     my ($quote_char, $name_sep);
1058
1059     if ($opts{quote_names}) {
1060       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1061         my $s_class = (ref $self) || $self;
1062         carp_unique (
1063           "You requested 'quote_names' but your storage class ($s_class) does "
1064         . 'not explicitly define a default sql_quote_char and you have not '
1065         . 'supplied a quote_char as part of your connection_info. DBIC will '
1066         .q{default to the ANSI SQL standard quote '"', which works most of }
1067         . "the time. Please file an RT ticket against '$s_class'."
1068         );
1069
1070         '"'; # RV
1071       };
1072
1073       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1074     }
1075
1076     $self->_sql_maker($sql_maker_class->new(
1077       bindtype=>'columns',
1078       array_datatypes => 1,
1079       limit_dialect => $dialect,
1080       ($quote_char ? (quote_char => $quote_char) : ()),
1081       name_sep => ($name_sep || '.'),
1082       %opts,
1083     ));
1084   }
1085   return $self->_sql_maker;
1086 }
1087
1088 # nothing to do by default
1089 sub _rebless {}
1090 sub _init {}
1091
1092 sub _populate_dbh {
1093
1094   # reset internal states
1095   # also in case ->connected failed we might get sent here
1096   $_[0]->disconnect;
1097
1098   $_[0]->_dbh($_[0]->_connect);
1099
1100   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1101
1102   $_[0]->_determine_driver;
1103
1104   # Always set the transaction depth on connect, since
1105   #  there is no transaction in progress by definition
1106   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1107
1108   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1109
1110   $_[0]->_dbh;
1111 }
1112
1113 sub _run_connection_actions {
1114
1115   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1116     ( $_[0]->on_connect_call || () ),
1117     $_[0]->_parse_connect_do ('on_connect_do'),
1118   );
1119 }
1120
1121
1122
1123 sub set_use_dbms_capability {
1124   $_[0]->set_inherited ($_[1], $_[2]);
1125 }
1126
1127 sub get_use_dbms_capability {
1128   my ($self, $capname) = @_;
1129
1130   my $use = $self->get_inherited ($capname);
1131   return defined $use
1132     ? $use
1133     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1134   ;
1135 }
1136
1137 sub set_dbms_capability {
1138   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1139 }
1140
1141 sub get_dbms_capability {
1142   my ($self, $capname) = @_;
1143
1144   my $cap = $self->_dbh_details->{capability}{$capname};
1145
1146   unless (defined $cap) {
1147     if (my $meth = $self->can ("_determine$capname")) {
1148       $cap = $self->$meth ? 1 : 0;
1149     }
1150     else {
1151       $cap = 0;
1152     }
1153
1154     $self->set_dbms_capability ($capname, $cap);
1155   }
1156
1157   return $cap;
1158 }
1159
1160 sub _server_info {
1161   my $self = shift;
1162
1163   # FIXME - ideally this needs to be an ||= assignment, and the final
1164   # assignment at the end of this do{} should be gone entirely. However
1165   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1166   $self->_dbh_details->{info} || do {
1167
1168     # this guarantees that problematic conninfo won't be hidden
1169     # by the try{} below
1170     $self->ensure_connected;
1171
1172     my $info = {};
1173
1174     my $server_version = dbic_internal_try {
1175       $self->_get_server_version
1176     } dbic_internal_catch {
1177       # driver determination *may* use this codepath
1178       # in which case we must rethrow
1179       $self->throw_exception($_) if $self->{_in_determine_driver};
1180
1181       # $server_version on failure
1182       undef;
1183     };
1184
1185     if (defined $server_version) {
1186       $info->{dbms_version} = $server_version;
1187
1188       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1189       my @verparts = split (/\./, $numeric_version);
1190       if (
1191         @verparts
1192           &&
1193         $verparts[0] <= 999
1194       ) {
1195         # consider only up to 3 version parts, iff not more than 3 digits
1196         my @use_parts;
1197         while (@verparts && @use_parts < 3) {
1198           my $p = shift @verparts;
1199           last if $p > 999;
1200           push @use_parts, $p;
1201         }
1202         push @use_parts, 0 while @use_parts < 3;
1203
1204         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1205       }
1206     }
1207
1208     $self->_dbh_details->{info} = $info;
1209   };
1210 }
1211
1212 sub _get_server_version {
1213   shift->_dbh_get_info('SQL_DBMS_VER');
1214 }
1215
1216 sub _dbh_get_info {
1217   my ($self, $info) = @_;
1218
1219   if ($info =~ /[^0-9]/) {
1220     require DBI::Const::GetInfoType;
1221     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1222     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1223       unless defined $info;
1224   }
1225
1226   $self->_get_dbh->get_info($info);
1227 }
1228
1229 sub _describe_connection {
1230   require DBI::Const::GetInfoReturn;
1231
1232   my $self = shift;
1233
1234   my $drv;
1235   dbic_internal_try {
1236     $drv = $self->_extract_driver_from_connect_info;
1237     $self->ensure_connected;
1238   };
1239
1240   $drv = "DBD::$drv" if $drv;
1241
1242   my $res = {
1243     DBIC_DSN => $self->_dbi_connect_info->[0],
1244     DBI_VER => DBI->VERSION,
1245     DBIC_VER => DBIx::Class->VERSION,
1246     DBIC_DRIVER => ref $self,
1247     $drv ? (
1248       DBD => $drv,
1249       DBD_VER => dbic_internal_try { $drv->VERSION },
1250     ) : (),
1251   };
1252
1253   # try to grab data even if we never managed to connect
1254   # will cover us in cases of an oddly broken half-connect
1255   for my $inf (
1256     #keys %DBI::Const::GetInfoType::GetInfoType,
1257     qw/
1258       SQL_CURSOR_COMMIT_BEHAVIOR
1259       SQL_CURSOR_ROLLBACK_BEHAVIOR
1260       SQL_CURSOR_SENSITIVITY
1261       SQL_DATA_SOURCE_NAME
1262       SQL_DBMS_NAME
1263       SQL_DBMS_VER
1264       SQL_DEFAULT_TXN_ISOLATION
1265       SQL_DM_VER
1266       SQL_DRIVER_NAME
1267       SQL_DRIVER_ODBC_VER
1268       SQL_DRIVER_VER
1269       SQL_EXPRESSIONS_IN_ORDERBY
1270       SQL_GROUP_BY
1271       SQL_IDENTIFIER_CASE
1272       SQL_IDENTIFIER_QUOTE_CHAR
1273       SQL_MAX_CATALOG_NAME_LEN
1274       SQL_MAX_COLUMN_NAME_LEN
1275       SQL_MAX_IDENTIFIER_LEN
1276       SQL_MAX_TABLE_NAME_LEN
1277       SQL_MULTIPLE_ACTIVE_TXN
1278       SQL_MULT_RESULT_SETS
1279       SQL_NEED_LONG_DATA_LEN
1280       SQL_NON_NULLABLE_COLUMNS
1281       SQL_ODBC_VER
1282       SQL_QUALIFIER_NAME_SEPARATOR
1283       SQL_QUOTED_IDENTIFIER_CASE
1284       SQL_TXN_CAPABLE
1285       SQL_TXN_ISOLATION_OPTION
1286     /
1287   ) {
1288     # some drivers barf on things they do not know about instead
1289     # of returning undef
1290     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1291     next unless defined $v;
1292
1293     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1294     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1295     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1296   }
1297
1298   $res;
1299 }
1300
1301 sub _determine_driver {
1302   my ($self) = @_;
1303
1304   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1305     my $started_connected = 0;
1306
1307     local $self->{_in_determine_driver} = 1
1308       unless $self->{_in_determine_driver};
1309
1310     if (ref($self) eq __PACKAGE__) {
1311       my $driver;
1312       if ($self->_dbh) { # we are connected
1313         $driver = $self->_dbh->{Driver}{Name};
1314         $started_connected = 1;
1315       }
1316       else {
1317         $driver = $self->_extract_driver_from_connect_info;
1318       }
1319
1320       if ($driver) {
1321         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1322         if ($self->load_optional_class($storage_class)) {
1323
1324           no strict 'refs';
1325           mro::set_mro($storage_class, 'c3') if
1326             (
1327               ${"${storage_class}::__INITIAL_MRO_UPON_DBIC_LOAD__"}
1328                 ||= mro::get_mro($storage_class)
1329             )
1330               ne
1331             'c3'
1332           ;
1333
1334           bless $self, $storage_class;
1335           $self->_rebless();
1336         }
1337         else {
1338           $self->_warn_undetermined_driver(
1339             'This version of DBIC does not yet seem to supply a driver for '
1340           . "your particular RDBMS and/or connection method ('$driver')."
1341           );
1342         }
1343       }
1344       else {
1345         $self->_warn_undetermined_driver(
1346           'Unable to extract a driver name from connect info - this '
1347         . 'should not have happened.'
1348         );
1349       }
1350     }
1351
1352     $self->_driver_determined(1);
1353
1354     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1355
1356     if ($self->can('source_bind_attributes')) {
1357       $self->throw_exception(
1358         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1359       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1360       . 'If you are not sure how to proceed please contact the development team via '
1361       . DBIx::Class::_ENV_::HELP_URL
1362       );
1363     }
1364
1365     $self->_init; # run driver-specific initializations
1366
1367     $self->_run_connection_actions
1368         if !$started_connected && defined $self->_dbh;
1369   }
1370 }
1371
1372 sub _extract_driver_from_connect_info {
1373   my $self = shift;
1374
1375   my $drv;
1376
1377   # if connect_info is a CODEREF, we have no choice but to connect
1378   if (
1379     ref $self->_dbi_connect_info->[0]
1380       and
1381     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1382   ) {
1383     $self->_populate_dbh;
1384     $drv = $self->_dbh->{Driver}{Name};
1385   }
1386   else {
1387     # try to use dsn to not require being connected, the driver may still
1388     # force a connection later in _rebless to determine version
1389     # (dsn may not be supplied at all if all we do is make a mock-schema)
1390     #
1391     # Use the same regex as the one used by DBI itself (even if the use of
1392     # \w is odd given unicode):
1393     # https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L621
1394     #
1395     # DO NOT use https://metacpan.org/source/TIMB/DBI-1.634/DBI.pm#L559-566
1396     # as there is a long-standing precedent of not loading DBI.pm until the
1397     # very moment we are actually connecting
1398     #
1399     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:(\w*)/i;
1400     $drv ||= $ENV{DBI_DRIVER};
1401   }
1402
1403   return $drv;
1404 }
1405
1406 sub _determine_connector_driver {
1407   my ($self, $conn) = @_;
1408
1409   my $dbtype = $self->_get_rdbms_name;
1410
1411   if (not $dbtype) {
1412     $self->_warn_undetermined_driver(
1413       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1414     . "$conn connector - this should not have happened."
1415     );
1416     return;
1417   }
1418
1419   $dbtype =~ s/\W/_/gi;
1420
1421   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1422   return if $self->isa($subclass);
1423
1424   if ($self->load_optional_class($subclass)) {
1425     bless $self, $subclass;
1426     $self->_rebless;
1427   }
1428   else {
1429     $self->_warn_undetermined_driver(
1430       'This version of DBIC does not yet seem to supply a driver for '
1431     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1432     );
1433   }
1434 }
1435
1436 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1437
1438 sub _warn_undetermined_driver {
1439   my ($self, $msg) = @_;
1440
1441   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1442   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1443   . "does not go away, file a bugreport including the following info:\n"
1444   . dump_value $self->_describe_connection
1445   );
1446 }
1447
1448 sub _do_connection_actions {
1449   my ($self, $method_prefix, $call, @args) = @_;
1450
1451   dbic_internal_try {
1452     if (not ref($call)) {
1453       my $method = $method_prefix . $call;
1454       $self->$method(@args);
1455     }
1456     elsif (ref($call) eq 'CODE') {
1457       $self->$call(@args);
1458     }
1459     elsif (ref($call) eq 'ARRAY') {
1460       if (ref($call->[0]) ne 'ARRAY') {
1461         $self->_do_connection_actions($method_prefix, $_) for @$call;
1462       }
1463       else {
1464         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1465       }
1466     }
1467     else {
1468       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1469     }
1470   }
1471   dbic_internal_catch {
1472     if ( $method_prefix =~ /^connect/ ) {
1473       # this is an on_connect cycle - we can't just throw while leaving
1474       # a handle in an undefined state in our storage object
1475       # kill it with fire and rethrow
1476       $self->_dbh(undef);
1477       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1478       $self->throw_exception( $_[0] );
1479     }
1480     else {
1481       carp "Disconnect action failed: $_[0]";
1482     }
1483   };
1484
1485   return $self;
1486 }
1487
1488 sub connect_call_do_sql {
1489   my $self = shift;
1490   $self->_do_query(@_);
1491 }
1492
1493 sub disconnect_call_do_sql {
1494   my $self = shift;
1495   $self->_do_query(@_);
1496 }
1497
1498 =head2 connect_call_datetime_setup
1499
1500 A no-op stub method, provided so that one can always safely supply the
1501 L<connection option|/DBIx::Class specific connection attributes>
1502
1503  on_connect_call => 'datetime_setup'
1504
1505 This way one does not need to know in advance whether the underlying
1506 storage requires any sort of hand-holding when dealing with calendar
1507 data.
1508
1509 =cut
1510
1511 sub connect_call_datetime_setup { 1 }
1512
1513 sub _do_query {
1514   my ($self, $action) = @_;
1515
1516   if (ref $action eq 'CODE') {
1517     $action = $action->($self);
1518     $self->_do_query($_) foreach @$action;
1519   }
1520   else {
1521     # Most debuggers expect ($sql, @bind), so we need to exclude
1522     # the attribute hash which is the second argument to $dbh->do
1523     # furthermore the bind values are usually to be presented
1524     # as named arrayref pairs, so wrap those here too
1525     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1526     my $sql = shift @do_args;
1527     my $attrs = shift @do_args;
1528     my @bind = map { [ undef, $_ ] } @do_args;
1529
1530     $self->dbh_do(sub {
1531       $_[0]->_query_start($sql, \@bind);
1532       $_[1]->do($sql, $attrs, @do_args);
1533       $_[0]->_query_end($sql, \@bind);
1534     });
1535   }
1536
1537   return $self;
1538 }
1539
1540 sub _connect {
1541   my $self = shift;
1542
1543   my $info = $self->_dbi_connect_info;
1544
1545   $self->throw_exception("You did not provide any connection_info")
1546     unless defined $info->[0];
1547
1548   my ($old_connect_via, $dbh);
1549
1550   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1551
1552   # this odd anonymous coderef dereference is in fact really
1553   # necessary to avoid the unwanted effect described in perl5
1554   # RT#75792
1555   #
1556   # in addition the coderef itself can't reside inside the try{} block below
1557   # as it somehow triggers a leak under perl -d
1558   my $dbh_error_handler_installer = sub {
1559     weaken (my $weak_self = $_[0]);
1560
1561     # the coderef is blessed so we can distinguish it from externally
1562     # supplied handles (which must be preserved)
1563     $_[1]->{HandleError} = bless sub {
1564       if ($weak_self) {
1565         $weak_self->throw_exception("DBI Exception: $_[0]");
1566       }
1567       else {
1568         # the handler may be invoked by something totally out of
1569         # the scope of DBIC
1570         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1571       }
1572     }, '__DBIC__DBH__ERROR__HANDLER__';
1573   };
1574
1575   dbic_internal_try {
1576     if(ref $info->[0] eq 'CODE') {
1577       $dbh = $info->[0]->();
1578     }
1579     else {
1580       require DBI;
1581       $dbh = DBI->connect(@$info);
1582     }
1583
1584     die $DBI::errstr unless $dbh;
1585
1586     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1587       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1588       . 'not continue',
1589       ref $info->[0] eq 'CODE'
1590         ? "Connection coderef $info->[0] returned a"
1591         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1592     ) unless $dbh->FETCH('Active');
1593
1594     # sanity checks unless asked otherwise
1595     unless ($self->unsafe) {
1596
1597       $self->throw_exception(
1598         'Refusing clobbering of {HandleError} installed on externally supplied '
1599        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1600       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1601
1602       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1603       # request, or an external handle. Complain and set anyway
1604       unless ($dbh->{RaiseError}) {
1605         carp( ref $info->[0] eq 'CODE'
1606
1607           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1608            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1609            .'attribute has been supplied'
1610
1611           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1612            .'unsafe => 1. Toggling RaiseError back to true'
1613         );
1614
1615         $dbh->{RaiseError} = 1;
1616       }
1617
1618       $dbh_error_handler_installer->($self, $dbh);
1619     }
1620   }
1621   dbic_internal_catch {
1622     $self->throw_exception("DBI Connection failed: $_")
1623   };
1624
1625   $self->_dbh_autocommit($dbh->{AutoCommit});
1626   return $dbh;
1627 }
1628
1629 sub txn_begin {
1630   # this means we have not yet connected and do not know the AC status
1631   # (e.g. coderef $dbh), need a full-fledged connection check
1632   if (! defined $_[0]->_dbh_autocommit) {
1633     $_[0]->ensure_connected;
1634   }
1635   # Otherwise simply connect or re-connect on pid changes
1636   else {
1637     $_[0]->_get_dbh;
1638   }
1639
1640   shift->next::method(@_);
1641 }
1642
1643 sub _exec_txn_begin {
1644   my $self = shift;
1645
1646   # if the user is utilizing txn_do - good for him, otherwise we need to
1647   # ensure that the $dbh is healthy on BEGIN.
1648   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1649   # will be replaced by a failure of begin_work itself (which will be
1650   # then retried on reconnect)
1651   if ($self->{_in_do_block}) {
1652     $self->_dbh->begin_work;
1653   } else {
1654     $self->dbh_do(sub { $_[1]->begin_work });
1655   }
1656 }
1657
1658 sub txn_commit {
1659   my $self = shift;
1660
1661   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1662     unless $self->_seems_connected;
1663
1664   # esoteric case for folks using external $dbh handles
1665   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1666     carp "Storage transaction_depth 0 does not match "
1667         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1668     $self->transaction_depth(1);
1669   }
1670
1671   $self->next::method(@_);
1672
1673   # if AutoCommit is disabled txn_depth never goes to 0
1674   # as a new txn is started immediately on commit
1675   $self->transaction_depth(1) if (
1676     !$self->transaction_depth
1677       and
1678     defined $self->_dbh_autocommit
1679       and
1680     ! $self->_dbh_autocommit
1681   );
1682 }
1683
1684 sub _exec_txn_commit {
1685   shift->_dbh->commit;
1686 }
1687
1688 sub txn_rollback {
1689   my $self = shift;
1690
1691   # do a minimal connectivity check due to weird shit like
1692   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1693   $self->throw_exception("lost connection to storage")
1694     unless $self->_seems_connected;
1695
1696   # esoteric case for folks using external $dbh handles
1697   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1698     carp "Storage transaction_depth 0 does not match "
1699         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1700     $self->transaction_depth(1);
1701   }
1702
1703   $self->next::method(@_);
1704
1705   # if AutoCommit is disabled txn_depth never goes to 0
1706   # as a new txn is started immediately on commit
1707   $self->transaction_depth(1) if (
1708     !$self->transaction_depth
1709       and
1710     defined $self->_dbh_autocommit
1711       and
1712     ! $self->_dbh_autocommit
1713   );
1714 }
1715
1716 sub _exec_txn_rollback {
1717   shift->_dbh->rollback;
1718 }
1719
1720 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1721 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1722   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1723     unless $_[0]->_seems_connected;
1724   shift->next::method(@_);
1725 EOS
1726
1727 # This used to be the top-half of _execute.  It was split out to make it
1728 #  easier to override in NoBindVars without duping the rest.  It takes up
1729 #  all of _execute's args, and emits $sql, @bind.
1730 sub _prep_for_execute {
1731   #my ($self, $op, $ident, $args) = @_;
1732   return shift->_gen_sql_bind(@_)
1733 }
1734
1735 sub _gen_sql_bind {
1736   my ($self, $op, $ident, $args) = @_;
1737
1738   my ($colinfos, $from);
1739   if ( blessed($ident) ) {
1740     $from = $ident->from;
1741     $colinfos = $ident->columns_info;
1742   }
1743
1744   my ($sql, $bind);
1745   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1746
1747   $bind = $self->_resolve_bindattrs(
1748     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1749   );
1750
1751   if (
1752     ! $ENV{DBIC_DT_SEARCH_OK}
1753       and
1754     $op eq 'select'
1755       and
1756     grep {
1757       length ref $_->[1]
1758         and
1759       blessed($_->[1])
1760         and
1761       $_->[1]->isa('DateTime')
1762     } @$bind
1763   ) {
1764     carp_unique 'DateTime objects passed to search() are not supported '
1765       . 'properly (InflateColumn::DateTime formats and settings are not '
1766       . 'respected.) See ".. format a DateTime object for searching?" in '
1767       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1768       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1769   }
1770
1771   return( $sql, $bind );
1772 }
1773
1774 sub _resolve_bindattrs {
1775   my ($self, $ident, $bind, $colinfos) = @_;
1776
1777   my $resolve_bindinfo = sub {
1778     #my $infohash = shift;
1779
1780     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1781
1782     my $ret;
1783     if (my $col = $_[0]->{dbic_colname}) {
1784       $ret = { %{$_[0]} };
1785
1786       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1787         if $colinfos->{$col}{data_type};
1788
1789       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1790         if $colinfos->{$col}{size};
1791     }
1792
1793     $ret || $_[0];
1794   };
1795
1796   return [ map {
1797       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1798     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1799     : (ref $_->[0] eq 'HASH')           ? [(
1800                                             ! keys %{$_->[0]}
1801                                               or
1802                                             exists $_->[0]{dbd_attrs}
1803                                               or
1804                                             $_->[0]{sqlt_datatype}
1805                                            ) ? $_->[0]
1806                                              : $resolve_bindinfo->($_->[0])
1807                                            , $_->[1]
1808                                           ]
1809     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1810     :                                     [ $resolve_bindinfo->(
1811                                               { dbic_colname => $_->[0] }
1812                                             ), $_->[1] ]
1813   } @$bind ];
1814 }
1815
1816 sub _format_for_trace {
1817   #my ($self, $bind) = @_;
1818
1819   ### Turn @bind from something like this:
1820   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1821   ### to this:
1822   ###   ( "'1'", "'3'" )
1823
1824   map {
1825     defined( $_ && $_->[1] )
1826       ? sprintf( "'%s'", "$_->[1]" )  # because overload
1827       : q{NULL}
1828   } @{$_[1] || []};
1829 }
1830
1831 sub _query_start {
1832   my ( $self, $sql, $bind ) = @_;
1833
1834   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1835     if $self->debug;
1836 }
1837
1838 sub _query_end {
1839   my ( $self, $sql, $bind ) = @_;
1840
1841   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1842     if $self->debug;
1843 }
1844
1845 sub _dbi_attrs_for_bind {
1846   #my ($self, $ident, $bind) = @_;
1847
1848   return [ map {
1849
1850     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1851
1852   : ! $_->{sqlt_datatype}   ? undef
1853
1854   :                           do {
1855
1856     # cache the result in the dbh_details hash, as it (usually) can not change
1857     # unless we connect to something else
1858     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1859     # the LOB storage
1860     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1861
1862     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1863       if ! exists $cache->{$_->{sqlt_datatype}};
1864
1865     $cache->{$_->{sqlt_datatype}};
1866
1867   } } map { $_->[0] } @{$_[2]} ];
1868 }
1869
1870 sub _execute {
1871   my ($self, $op, $ident, @args) = @_;
1872
1873   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1874
1875   # not even a PID check - we do not care about the state of the _dbh.
1876   # All we need is to get the appropriate drivers loaded if they aren't
1877   # already so that the assumption in ad7c50fc26e holds
1878   $self->_populate_dbh unless $self->_dbh;
1879
1880   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1881     $sql,
1882     $bind,
1883     $self->_dbi_attrs_for_bind($ident, $bind),
1884   );
1885 }
1886
1887 sub _dbh_execute {
1888   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1889
1890   $self->_query_start( $sql, $bind );
1891
1892   my $sth = $self->_bind_sth_params(
1893     $self->_prepare_sth($dbh, $sql),
1894     $bind,
1895     $bind_attrs,
1896   );
1897
1898   # Can this fail without throwing an exception anyways???
1899   my $rv = $sth->execute();
1900   $self->throw_exception(
1901     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1902   ) if !$rv;
1903
1904   $self->_query_end( $sql, $bind );
1905
1906   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1907 }
1908
1909 sub _prepare_sth {
1910   my ($self, $dbh, $sql) = @_;
1911
1912   # 3 is the if_active parameter which avoids active sth re-use
1913   my $sth = $self->disable_sth_caching
1914     ? $dbh->prepare($sql)
1915     : $dbh->prepare_cached($sql, {}, 3);
1916
1917   # XXX You would think RaiseError would make this impossible,
1918   #  but apparently that's not true :(
1919   $self->throw_exception(
1920     $dbh->errstr
1921       ||
1922     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1923             .'an exception and/or setting $dbh->errstr',
1924       length ($sql) > 20
1925         ? substr($sql, 0, 20) . '...'
1926         : $sql
1927       ,
1928       'DBD::' . $dbh->{Driver}{Name},
1929     )
1930   ) if !$sth;
1931
1932   $sth;
1933 }
1934
1935 sub _bind_sth_params {
1936   my ($self, $sth, $bind, $bind_attrs) = @_;
1937
1938   for my $i (0 .. $#$bind) {
1939     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1940       $sth->bind_param_inout(
1941         $i + 1, # bind params counts are 1-based
1942         $bind->[$i][1],
1943         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1944         $bind_attrs->[$i],
1945       );
1946     }
1947     else {
1948       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1949       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1950         ? "$bind->[$i][1]"
1951         : $bind->[$i][1]
1952       ;
1953
1954       $sth->bind_param(
1955         $i + 1,
1956         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1957         $v,
1958         $bind_attrs->[$i],
1959       );
1960     }
1961   }
1962
1963   $sth;
1964 }
1965
1966 sub _prefetch_autovalues {
1967   my ($self, $source, $colinfo, $to_insert) = @_;
1968
1969   my %values;
1970   for my $col (keys %$colinfo) {
1971     if (
1972       $colinfo->{$col}{auto_nextval}
1973         and
1974       (
1975         ! exists $to_insert->{$col}
1976           or
1977         is_literal_value($to_insert->{$col})
1978       )
1979     ) {
1980       $values{$col} = $self->_sequence_fetch(
1981         'NEXTVAL',
1982         ( $colinfo->{$col}{sequence} ||=
1983             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1984         ),
1985       );
1986     }
1987   }
1988
1989   \%values;
1990 }
1991
1992 sub insert {
1993   my ($self, $source, $to_insert) = @_;
1994
1995   my $col_infos = $source->columns_info;
1996
1997   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1998
1999   # fuse the values, but keep a separate list of prefetched_values so that
2000   # they can be fused once again with the final return
2001   $to_insert = { %$to_insert, %$prefetched_values };
2002
2003   my %pcols = map { $_ => 1 } $source->primary_columns;
2004
2005   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
2006
2007   for my $col ($source->columns) {
2008
2009     # first autoinc wins - this is why ->columns() in-order iteration is important
2010     #
2011     # FIXME - there ought to be a sanity-check for multiple is_auto_increment settings
2012     # or something...
2013     #
2014     if ($col_infos->{$col}{is_auto_increment}) {
2015
2016       # FIXME - we seem to assume undef values as non-supplied.
2017       # This is wrong.
2018       # Investigate what does it take to s/defined/exists/
2019       # ( fails t/cdbi/copy.t amoong other things )
2020       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
2021
2022       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
2023     }
2024
2025     # nothing to retrieve when explicit values are supplied
2026     next if (
2027       # FIXME - we seem to assume undef values as non-supplied.
2028       # This is wrong.
2029       # Investigate what does it take to s/defined/exists/
2030       # ( fails t/cdbi/copy.t amoong other things )
2031       defined $to_insert->{$col}
2032         and
2033       (
2034         # not a ref - cheaper to check before a call to is_literal_value()
2035         ! length ref $to_insert->{$col}
2036           or
2037         # not a literal we *MAY* need to pull out ( see check below )
2038         ! is_literal_value( $to_insert->{$col} )
2039       )
2040     );
2041
2042     # the 'scalar keys' is a trick to preserve the ->columns declaration order
2043     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
2044       $pcols{$col}
2045         or
2046       $col_infos->{$col}{retrieve_on_insert}
2047     );
2048   };
2049
2050   # corner case of a non-supplied PK which is *not* declared as autoinc
2051   if (
2052     ! $autoinc_supplied
2053       and
2054     ! defined $retrieve_autoinc_col
2055       and
2056     # FIXME - first come-first serve, suboptimal...
2057     ($retrieve_autoinc_col) = ( grep
2058       {
2059         $pcols{$_}
2060           and
2061         ! $col_infos->{$_}{retrieve_on_insert}
2062           and
2063         ! defined $col_infos->{$_}{is_auto_increment}
2064       }
2065       sort
2066         { $retrieve_cols{$a} <=> $retrieve_cols{$b} }
2067         keys %retrieve_cols
2068     )
2069   ) {
2070     carp_unique(
2071       "Missing value for primary key column '$retrieve_autoinc_col' on "
2072     . "@{[ $source->source_name ]} - perhaps you forgot to set its "
2073     . "'is_auto_increment' attribute during add_columns()? Treating "
2074     . "'$retrieve_autoinc_col' implicitly as an autoinc, and attempting "
2075     . 'value retrieval'
2076     );
2077   }
2078
2079   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
2080   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
2081
2082   my ($sqla_opts, @ir_container);
2083   if (%retrieve_cols and $self->_use_insert_returning) {
2084     $sqla_opts->{returning_container} = \@ir_container
2085       if $self->_use_insert_returning_bound;
2086
2087     $sqla_opts->{returning} = [
2088       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
2089     ];
2090   }
2091
2092   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
2093
2094   my %returned_cols = %$to_insert;
2095   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2096
2097     unless( @ir_container ) {
2098       dbic_internal_try {
2099
2100         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2101         local $SIG{__WARN__} = sub {};
2102
2103         @ir_container = $sth->fetchrow_array;
2104         $sth->finish;
2105
2106       } dbic_internal_catch {
2107         # Evict the $sth from the cache in case we got here, since the finish()
2108         # is crucial, at least on older Firebirds, possibly on other engines too
2109         #
2110         # It would be too complex to make this a proper subclass override,
2111         # and besides we already take the try{} penalty, adding a catch that
2112         # triggers infrequently is a no-brainer
2113         #
2114         if( my $kids = $self->_dbh->{CachedKids} ) {
2115           $kids->{$_} == $sth and delete $kids->{$_}
2116             for keys %$kids
2117         }
2118       };
2119     }
2120
2121     @returned_cols{@$retlist} = @ir_container if @ir_container;
2122   }
2123   else {
2124     # pull in PK if needed and then everything else
2125     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2126
2127       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2128         unless $self->can('last_insert_id');
2129
2130       my @pri_values = $self->last_insert_id($source, @missing_pri);
2131
2132       $self->throw_exception( "Can't get last insert id" )
2133         unless (@pri_values == @missing_pri);
2134
2135       @returned_cols{@missing_pri} = @pri_values;
2136       delete @retrieve_cols{@missing_pri};
2137     }
2138
2139     # if there is more left to pull
2140     if (%retrieve_cols) {
2141       $self->throw_exception(
2142         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2143       ) unless %pcols;
2144
2145       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2146
2147       my $cur = DBIx::Class::ResultSet->new($source, {
2148         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2149         select => \@left_to_fetch,
2150       })->cursor;
2151
2152       @returned_cols{@left_to_fetch} = $cur->next;
2153
2154       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2155         if scalar $cur->next;
2156     }
2157   }
2158
2159   return { %$prefetched_values, %returned_cols };
2160 }
2161
2162 sub insert_bulk {
2163   carp_unique(
2164     'insert_bulk() should have never been exposed as a public method and '
2165   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2166   . 'use for this method please contact the development team via '
2167   . DBIx::Class::_ENV_::HELP_URL
2168   );
2169
2170   return '0E0' unless @{$_[3]||[]};
2171
2172   shift->_insert_bulk(@_);
2173 }
2174
2175 sub _insert_bulk {
2176   my ($self, $source, $cols, $data) = @_;
2177
2178   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2179     unless @{$data||[]};
2180
2181   my $colinfos = $source->columns_info($cols);
2182
2183   local $self->{_autoinc_supplied_for_op} =
2184     (grep { $_->{is_auto_increment} } values %$colinfos)
2185       ? 1
2186       : 0
2187   ;
2188
2189   # get a slice type index based on first row of data
2190   # a "column" in this context may refer to more than one bind value
2191   # e.g. \[ '?, ?', [...], [...] ]
2192   #
2193   # construct the value type index - a description of values types for every
2194   # per-column slice of $data:
2195   #
2196   # nonexistent - nonbind literal
2197   # 0 - regular value
2198   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2199   #
2200   # also construct the column hash to pass to the SQL generator. For plain
2201   # (non literal) values - convert the members of the first row into a
2202   # literal+bind combo, with extra positional info in the bind attr hashref.
2203   # This will allow us to match the order properly, and is so contrived
2204   # because a user-supplied literal/bind (or something else specific to a
2205   # resultsource and/or storage driver) can inject extra binds along the
2206   # way, so one can't rely on "shift positions" ordering at all. Also we
2207   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2208   # can be later matched up by address), because we want to supply a real
2209   # value on which perhaps e.g. datatype checks will be performed
2210   my ($proto_data, $serialized_bind_type_by_col_idx);
2211   for my $col_idx (0..$#$cols) {
2212     my $colname = $cols->[$col_idx];
2213     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2214       # no bind value at all - no type
2215
2216       $proto_data->{$colname} = $data->[0][$col_idx];
2217     }
2218     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2219       # repack, so we don't end up mangling the original \[]
2220       my ($sql, @bind) = @${$data->[0][$col_idx]};
2221
2222       # normalization of user supplied stuff
2223       my $resolved_bind = $self->_resolve_bindattrs(
2224         $source, \@bind, $colinfos,
2225       );
2226
2227       # store value-less (attrs only) bind info - we will be comparing all
2228       # supplied binds against this for sanity
2229       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2230
2231       $proto_data->{$colname} = \[ $sql, map { [
2232         # inject slice order to use for $proto_bind construction
2233           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2234             =>
2235           $resolved_bind->[$_][1]
2236         ] } (0 .. $#bind)
2237       ];
2238     }
2239     else {
2240       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2241
2242       $proto_data->{$colname} = \[ '?', [
2243         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2244           =>
2245         $data->[0][$col_idx]
2246       ] ];
2247     }
2248   }
2249
2250   my ($sql, $proto_bind) = $self->_prep_for_execute (
2251     'insert',
2252     $source,
2253     [ $proto_data ],
2254   );
2255
2256   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2257     # if the bindlist is empty and we had some dynamic binds, this means the
2258     # storage ate them away (e.g. the NoBindVars component) and interpolated
2259     # them directly into the SQL. This obviously can't be good for multi-inserts
2260     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2261   }
2262
2263   # sanity checks
2264   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2265   #
2266   # use an error reporting closure for convenience (less to pass)
2267   my $bad_slice_report_cref = sub {
2268     my ($msg, $r_idx, $c_idx) = @_;
2269     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2270       $msg,
2271       $cols->[$c_idx],
2272       do {
2273         local $Data::Dumper::Maxdepth = 5;
2274         dump_value {
2275           map { $cols->[$_] =>
2276             $data->[$r_idx][$_]
2277           } 0..$#$cols
2278         };
2279       }
2280     );
2281   };
2282
2283   for my $col_idx (0..$#$cols) {
2284     my $reference_val = $data->[0][$col_idx];
2285
2286     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2287       my $val = $data->[$row_idx][$col_idx];
2288
2289       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2290         if (ref $val ne 'SCALAR') {
2291           $bad_slice_report_cref->(
2292             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2293             $row_idx,
2294             $col_idx,
2295           );
2296         }
2297         elsif ($$val ne $$reference_val) {
2298           $bad_slice_report_cref->(
2299             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2300             $row_idx,
2301             $col_idx,
2302           );
2303         }
2304       }
2305       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2306         if (is_literal_value($val)) {
2307           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2308         }
2309       }
2310       else {  # binds from a \[], compare type and attrs
2311         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2312           $bad_slice_report_cref->(
2313             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2314             $row_idx,
2315             $col_idx,
2316           );
2317         }
2318         # start drilling down and bail out early on identical refs
2319         elsif (
2320           $reference_val != $val
2321             or
2322           $$reference_val != $$val
2323         ) {
2324           if (${$val}->[0] ne ${$reference_val}->[0]) {
2325             $bad_slice_report_cref->(
2326               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2327               $row_idx,
2328               $col_idx,
2329             );
2330           }
2331           # need to check the bind attrs - a bind will happen only once for
2332           # the entire dataset, so any changes further down will be ignored.
2333           elsif (
2334             $serialized_bind_type_by_col_idx->{$col_idx}
2335               ne
2336             serialize [
2337               map
2338               { $_->[0] }
2339               @{$self->_resolve_bindattrs(
2340                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2341               )}
2342             ]
2343           ) {
2344             $bad_slice_report_cref->(
2345               'Differing bind attributes on literal/bind values not supported',
2346               $row_idx,
2347               $col_idx,
2348             );
2349           }
2350         }
2351       }
2352     }
2353   }
2354
2355   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2356   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2357   # scope guard
2358   my $guard = $self->txn_scope_guard;
2359
2360   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2361   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2362   my $rv = do {
2363     if (@$proto_bind) {
2364       # proto bind contains the information on which pieces of $data to pull
2365       # $cols is passed in only for prettier error-reporting
2366       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2367     }
2368     else {
2369       # bind_param_array doesn't work if there are no binds
2370       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2371     }
2372   };
2373
2374   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2375
2376   $guard->commit;
2377
2378   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2379 }
2380
2381 # execute_for_fetch is capable of returning data just fine (it means it
2382 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2383 # is the void-populate fast-path we will just ignore this altogether
2384 # for the time being.
2385 sub _dbh_execute_for_fetch {
2386   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2387
2388   # If we have any bind attributes to take care of, we will bind the
2389   # proto-bind data (which will never be used by execute_for_fetch)
2390   # However since column bindtypes are "sticky", this is sufficient
2391   # to get the DBD to apply the bindtype to all values later on
2392   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2393
2394   for my $i (0 .. $#$proto_bind) {
2395     $sth->bind_param (
2396       $i+1, # DBI bind indexes are 1-based
2397       $proto_bind->[$i][1],
2398       $bind_attrs->[$i],
2399     ) if defined $bind_attrs->[$i];
2400   }
2401
2402   # At this point $data slots named in the _bind_data_slice_idx of
2403   # each piece of $proto_bind are either \[]s or plain values to be
2404   # passed in. Construct the dispensing coderef. *NOTE* the order
2405   # of $data will differ from this of the ?s in the SQL (due to
2406   # alphabetical ordering by colname). We actually do want to
2407   # preserve this behavior so that prepare_cached has a better
2408   # chance of matching on unrelated calls
2409
2410   my $fetch_row_idx = -1; # saner loop this way
2411   my $fetch_tuple = sub {
2412     return undef if ++$fetch_row_idx > $#$data;
2413
2414     return [ map {
2415       my $v = ! defined $_->{_literal_bind_subindex}
2416
2417         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2418
2419         # There are no attributes to resolve here - we already did everything
2420         # when we constructed proto_bind. However we still want to sanity-check
2421         # what the user supplied, so pass stuff through to the resolver *anyway*
2422         : $self->_resolve_bindattrs (
2423             undef,  # a fake rsrc
2424             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2425             {},     # a fake column_info bag
2426           )->[0][1]
2427       ;
2428
2429       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2430       # For the time being forcibly stringify whatever is stringifiable
2431       my $vref;
2432
2433       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2434     : defined blessed( $$vref )                             ? "$$vref"
2435                                                             : $$vref
2436     ;
2437     } map { $_->[0] } @$proto_bind ];
2438   };
2439
2440   my $tuple_status = [];
2441   my ($rv, $err);
2442   dbic_internal_try {
2443     $rv = $sth->execute_for_fetch(
2444       $fetch_tuple,
2445       $tuple_status,
2446     );
2447   }
2448   dbic_internal_catch {
2449     $err = shift;
2450   };
2451
2452   # Not all DBDs are create equal. Some throw on error, some return
2453   # an undef $rv, and some set $sth->err - try whatever we can
2454   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2455     ! defined $err
2456       and
2457     ( !defined $rv or $sth->err )
2458   );
2459
2460   # Statement must finish even if there was an exception.
2461   dbic_internal_try {
2462     $sth->finish
2463   }
2464   dbic_internal_catch {
2465     $err = shift unless defined $err
2466   };
2467
2468   if (defined $err) {
2469     my $i = 0;
2470     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2471
2472     $self->throw_exception("Unexpected populate error: $err")
2473       if ($i > $#$tuple_status);
2474
2475     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2476       ($tuple_status->[$i][1] || $err),
2477       dump_value { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) },
2478     );
2479   }
2480
2481   return $rv;
2482 }
2483
2484 sub _dbh_execute_inserts_with_no_binds {
2485   my ($self, $sth, $count) = @_;
2486
2487   my $err;
2488   dbic_internal_try {
2489     my $dbh = $self->_get_dbh;
2490     local $dbh->{RaiseError} = 1;
2491     local $dbh->{PrintError} = 0;
2492
2493     $sth->execute foreach 1..$count;
2494   }
2495   dbic_internal_catch {
2496     $err = shift;
2497   };
2498
2499   # Make sure statement is finished even if there was an exception.
2500   dbic_internal_try {
2501     $sth->finish
2502   }
2503   dbic_internal_catch {
2504     $err = shift unless defined $err;
2505   };
2506
2507   $self->throw_exception($err) if defined $err;
2508
2509   return $count;
2510 }
2511
2512 sub update {
2513   #my ($self, $source, @args) = @_;
2514   shift->_execute('update', @_);
2515 }
2516
2517
2518 sub delete {
2519   #my ($self, $source, @args) = @_;
2520   shift->_execute('delete', @_);
2521 }
2522
2523 sub _select {
2524   my $self = shift;
2525   $self->_execute($self->_select_args(@_));
2526 }
2527
2528 sub _select_args_to_query {
2529   my $self = shift;
2530
2531   $self->throw_exception(
2532     "Unable to generate limited query representation with 'software_limit' enabled"
2533   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2534
2535   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2536   #  = $self->_select_args($ident, $select, $cond, $attrs);
2537   my ($op, $ident, @args) =
2538     $self->_select_args(@_);
2539
2540   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2541   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2542
2543   # reuse the bind arrayref
2544   unshift @{$bind}, "($sql)";
2545   \$bind;
2546 }
2547
2548 sub _select_args {
2549   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2550
2551   # FIXME - that kind of caching would be nice to have
2552   # however currently we *may* pass the same $orig_attrs
2553   # with different ident/select/where
2554   # the whole interface needs to be rethought, since it
2555   # was centered around the flawed SQLA API. We can do
2556   # soooooo much better now. But that is also another
2557   # battle...
2558   #return (
2559   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2560   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2561
2562   my $sql_maker = $self->sql_maker;
2563
2564   my $attrs = {
2565     %$orig_attrs,
2566     select => $select,
2567     from => $ident,
2568     where => $where,
2569   };
2570
2571   # MySQL actually recommends this approach.  I cringe.
2572   $attrs->{rows} ||= $sql_maker->__max_int
2573     if $attrs->{offset};
2574
2575   # see if we will need to tear the prefetch apart to satisfy group_by == select
2576   # this is *extremely tricky* to get right, I am still not sure I did
2577   #
2578   my ($prefetch_needs_subquery, @limit_args);
2579
2580   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2581     # we already know there is a valid group_by (we made it) and we know it is
2582     # intended to be based *only* on non-multi stuff
2583     # short circuit the group_by parsing below
2584     $prefetch_needs_subquery = 1;
2585   }
2586   elsif (
2587     # The rationale is that even if we do *not* have collapse, we still
2588     # need to wrap the core grouped select/group_by in a subquery
2589     # so that databases that care about group_by/select equivalence
2590     # are happy (this includes MySQL in strict_mode)
2591     # If any of the other joined tables are referenced in the group_by
2592     # however - the user is on their own
2593     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2594       and
2595     $attrs->{group_by}
2596       and
2597     @{$attrs->{group_by}}
2598       and
2599     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2600       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2601     }
2602   ) {
2603     # no aliases other than our own in group_by
2604     # if there are - do not allow subquery even if limit is present
2605     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2606   }
2607   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2608     # active collapse with a limit - that one is a no-brainer unless
2609     # overruled by a group_by above
2610     $prefetch_needs_subquery = 1;
2611   }
2612
2613   if ($prefetch_needs_subquery) {
2614     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2615   }
2616   elsif (! $attrs->{software_limit} ) {
2617     push @limit_args, (
2618       $attrs->{rows} || (),
2619       $attrs->{offset} || (),
2620     );
2621   }
2622
2623   # try to simplify the joinmap further (prune unreferenced type-single joins)
2624   if (
2625     ! $prefetch_needs_subquery  # already pruned
2626       and
2627     ref $attrs->{from}
2628       and
2629     reftype $attrs->{from} eq 'ARRAY'
2630       and
2631     @{$attrs->{from}} != 1
2632   ) {
2633     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2634   }
2635
2636   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2637   # during the result inflation stage we *need* to know what was the aliastype
2638   # map as sqla saw it when the final pieces of SQL were being assembled
2639   # Originally we simply carried around the entirety of $attrs, but this
2640   # resulted in resultsets that are being reused growing continuously, as
2641   # the hash in question grew deeper and deeper.
2642   # Instead hand-pick what to take with us here (we actually don't need much
2643   # at this point just the map itself)
2644   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2645
2646 ###
2647   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2648   #
2649   # This would be the point to deflate anything found in $attrs->{where}
2650   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2651   # expect a result object. And all we have is a resultsource (it is trivial
2652   # to extract deflator coderefs via $alias2source above).
2653   #
2654   # I don't see a way forward other than changing the way deflators are
2655   # invoked, and that's just bad...
2656 ###
2657
2658   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2659 }
2660
2661 # Returns a counting SELECT for a simple count
2662 # query. Abstracted so that a storage could override
2663 # this to { count => 'firstcol' } or whatever makes
2664 # sense as a performance optimization
2665 sub _count_select {
2666   #my ($self, $source, $rs_attrs) = @_;
2667   return { count => '*' };
2668 }
2669
2670 =head2 select
2671
2672 =over 4
2673
2674 =item Arguments: $ident, $select, $condition, $attrs
2675
2676 =back
2677
2678 Handle a SQL select statement.
2679
2680 =cut
2681
2682 sub select {
2683   my $self = shift;
2684   my ($ident, $select, $condition, $attrs) = @_;
2685   return $self->cursor_class->new($self, \@_, $attrs);
2686 }
2687
2688 sub select_single {
2689   my $self = shift;
2690   my ($rv, $sth, @bind) = $self->_select(@_);
2691   my @row = $sth->fetchrow_array;
2692   my @nextrow = $sth->fetchrow_array if @row;
2693   if(@row && @nextrow) {
2694     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2695   }
2696   # Need to call finish() to work round broken DBDs
2697   $sth->finish();
2698   return @row;
2699 }
2700
2701 =head2 sql_limit_dialect
2702
2703 This is an accessor for the default SQL limit dialect used by a particular
2704 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2705 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2706 see L<DBIx::Class::SQLMaker::LimitDialects>.
2707
2708 =cut
2709
2710 sub _dbh_columns_info_for {
2711   my ($self, $dbh, $table) = @_;
2712
2713   my %result;
2714
2715   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2716     dbic_internal_try {
2717       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2718       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2719       $sth->execute();
2720       while ( my $info = $sth->fetchrow_hashref() ){
2721         my %column_info;
2722         $column_info{data_type}   = $info->{TYPE_NAME};
2723         $column_info{size}      = $info->{COLUMN_SIZE};
2724         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2725         $column_info{default_value} = $info->{COLUMN_DEF};
2726         my $col_name = $info->{COLUMN_NAME};
2727         $col_name =~ s/^\"(.*)\"$/$1/;
2728
2729         $result{$col_name} = \%column_info;
2730       }
2731     } dbic_internal_catch {
2732       %result = ();
2733     };
2734
2735     return \%result if keys %result;
2736   }
2737
2738   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2739   $sth->execute;
2740
2741 ### The acrobatics with lc names is necessary to support both the legacy
2742 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2743 ### with column names differing in cas eonly (thanks pg!)
2744
2745   my ($columns, $seen_lcs);
2746
2747   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2748     idx => scalar keys %$columns,
2749     name => $_,
2750     lc_name => lc($_),
2751   } for @{$sth->{NAME}};
2752
2753   $seen_lcs->{$_->{lc_name}} == 1
2754     and
2755   $_->{name} = $_->{lc_name}
2756     for values %$columns;
2757
2758   for ( values %$columns ) {
2759     my $inf = {
2760       data_type => $sth->{TYPE}->[$_->{idx}],
2761       size => $sth->{PRECISION}->[$_->{idx}],
2762       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2763     };
2764
2765     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2766       @{$inf}{qw( data_type  size)} = ($1, $2);
2767     }
2768
2769     $result{$_->{name}} = $inf;
2770   }
2771
2772   $sth->finish;
2773
2774   if ($dbh->can('type_info')) {
2775     for my $inf (values %result) {
2776       next if ! defined $inf->{data_type};
2777
2778       $inf->{data_type} = (
2779         (
2780           (
2781             $dbh->type_info( $inf->{data_type} )
2782               ||
2783             next
2784           )
2785             ||
2786           next
2787         )->{TYPE_NAME}
2788           ||
2789         next
2790       );
2791
2792       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2793       # needs more testing in the future...
2794       $inf->{size} -= 4 if (
2795         ( $inf->{size}||0 > 4 )
2796           and
2797         $inf->{data_type} =~ qr/^text$/i
2798       );
2799     }
2800
2801   }
2802
2803   return \%result;
2804 }
2805
2806 sub columns_info_for {
2807   my ($self, $table) = @_;
2808   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2809 }
2810
2811 =head2 last_insert_id
2812
2813 Return the row id of the last insert.
2814
2815 =cut
2816
2817 sub _dbh_last_insert_id {
2818     my ($self, $dbh, $source, $col) = @_;
2819
2820     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2821
2822     return $id if defined $id;
2823
2824     my $class = ref $self;
2825     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2826 }
2827
2828 sub last_insert_id {
2829   my $self = shift;
2830   $self->_dbh_last_insert_id ($self->_dbh, @_);
2831 }
2832
2833 =head2 _native_data_type
2834
2835 =over 4
2836
2837 =item Arguments: $type_name
2838
2839 =back
2840
2841 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2842 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2843 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2844
2845 The default implementation returns C<undef>, implement in your Storage driver if
2846 you need this functionality.
2847
2848 Should map types from other databases to the native RDBMS type, for example
2849 C<VARCHAR2> to C<VARCHAR>.
2850
2851 Types with modifiers should map to the underlying data type. For example,
2852 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2853
2854 Composite types should map to the container type, for example
2855 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2856
2857 =cut
2858
2859 sub _native_data_type {
2860   #my ($self, $data_type) = @_;
2861   return undef
2862 }
2863
2864 # Check if placeholders are supported at all
2865 sub _determine_supports_placeholders {
2866   my $self = shift;
2867   my $dbh  = $self->_get_dbh;
2868
2869   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2870   # but it is inaccurate more often than not
2871   ( dbic_internal_try {
2872     local $dbh->{PrintError} = 0;
2873     local $dbh->{RaiseError} = 1;
2874     $dbh->do('select ?', {}, 1);
2875     1;
2876   } )
2877     ? 1
2878     : 0
2879   ;
2880 }
2881
2882 # Check if placeholders bound to non-string types throw exceptions
2883 #
2884 sub _determine_supports_typeless_placeholders {
2885   my $self = shift;
2886   my $dbh  = $self->_get_dbh;
2887
2888   ( dbic_internal_try {
2889     local $dbh->{PrintError} = 0;
2890     local $dbh->{RaiseError} = 1;
2891     # this specifically tests a bind that is NOT a string
2892     $dbh->do('select 1 where 1 = ?', {}, 1);
2893     1;
2894   } )
2895     ? 1
2896     : 0
2897   ;
2898 }
2899
2900 =head2 sqlt_type
2901
2902 Returns the database driver name.
2903
2904 =cut
2905
2906 sub sqlt_type {
2907   shift->_get_dbh->{Driver}->{Name};
2908 }
2909
2910 =head2 bind_attribute_by_data_type
2911
2912 Given a datatype from column info, returns a database specific bind
2913 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2914 let the database planner just handle it.
2915
2916 This method is always called after the driver has been determined and a DBI
2917 connection has been established. Therefore you can refer to C<DBI::$constant>
2918 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2919 the correct modules.
2920
2921 =cut
2922
2923 sub bind_attribute_by_data_type {
2924     return;
2925 }
2926
2927 =head2 is_datatype_numeric
2928
2929 Given a datatype from column_info, returns a boolean value indicating if
2930 the current RDBMS considers it a numeric value. This controls how
2931 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2932 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2933 be performed instead of the usual C<eq>.
2934
2935 =cut
2936
2937 sub is_datatype_numeric {
2938   #my ($self, $dt) = @_;
2939
2940   return 0 unless $_[1];
2941
2942   $_[1] =~ /^ (?:
2943     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2944   ) $/ix;
2945 }
2946
2947
2948 =head2 create_ddl_dir
2949
2950 =over 4
2951
2952 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2953
2954 =back
2955
2956 Creates a SQL file based on the Schema, for each of the specified
2957 database engines in C<\@databases> in the given directory.
2958 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2959
2960 Given a previous version number, this will also create a file containing
2961 the ALTER TABLE statements to transform the previous schema into the
2962 current one. Note that these statements may contain C<DROP TABLE> or
2963 C<DROP COLUMN> statements that can potentially destroy data.
2964
2965 The file names are created using the C<ddl_filename> method below, please
2966 override this method in your schema if you would like a different file
2967 name format. For the ALTER file, the same format is used, replacing
2968 $version in the name with "$preversion-$version".
2969
2970 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2971 The most common value for this would be C<< { add_drop_table => 1 } >>
2972 to have the SQL produced include a C<DROP TABLE> statement for each table
2973 created. For quoting purposes supply C<quote_identifiers>.
2974
2975 If no arguments are passed, then the following default values are assumed:
2976
2977 =over 4
2978
2979 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2980
2981 =item version    - $schema->schema_version
2982
2983 =item directory  - './'
2984
2985 =item preversion - <none>
2986
2987 =back
2988
2989 By default, C<\%sqlt_args> will have
2990
2991  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2992
2993 merged with the hash passed in. To disable any of those features, pass in a
2994 hashref like the following
2995
2996  { ignore_constraint_names => 0, # ... other options }
2997
2998
2999 WARNING: You are strongly advised to check all SQL files created, before applying
3000 them.
3001
3002 =cut
3003
3004 sub create_ddl_dir {
3005   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
3006
3007   require DBIx::Class::Optional::Dependencies;
3008   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
3009     $self->throw_exception("Can't create a ddl file without $missing");
3010   }
3011
3012   if (!$dir) {
3013     carp "No directory given, using ./\n";
3014     $dir = './';
3015   }
3016   else {
3017     mkdir_p( $dir ) unless -d $dir;
3018   }
3019
3020   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
3021   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
3022
3023   my $schema_version = $schema->schema_version || '1.x';
3024   $version ||= $schema_version;
3025
3026   $sqltargs = {
3027     add_drop_table => 1,
3028     ignore_constraint_names => 1,
3029     ignore_index_names => 1,
3030     quote_identifiers => $self->sql_maker->_quoting_enabled,
3031     %{$sqltargs || {}}
3032   };
3033
3034   my $sqlt = SQL::Translator->new( $sqltargs );
3035
3036   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
3037   my $sqlt_schema = $sqlt->translate({ data => $schema })
3038     or $self->throw_exception ($sqlt->error);
3039
3040   foreach my $db (@$databases) {
3041     $sqlt->reset();
3042     $sqlt->{schema} = $sqlt_schema;
3043     $sqlt->producer($db);
3044
3045     my $file;
3046     my $filename = $schema->ddl_filename($db, $version, $dir);
3047     if (-e $filename && ($version eq $schema_version )) {
3048       # if we are dumping the current version, overwrite the DDL
3049       carp "Overwriting existing DDL file - $filename";
3050       unlink($filename);
3051     }
3052
3053     my $output = $sqlt->translate;
3054     if(!$output) {
3055       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
3056       next;
3057     }
3058     if(!open($file, ">$filename")) {
3059       $self->throw_exception("Can't open $filename for writing ($!)");
3060       next;
3061     }
3062     print $file $output;
3063     close($file);
3064
3065     next unless ($preversion);
3066
3067     require SQL::Translator::Diff;
3068
3069     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
3070     if(!-e $prefilename) {
3071       carp("No previous schema file found ($prefilename)");
3072       next;
3073     }
3074
3075     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
3076     if(-e $difffile) {
3077       carp("Overwriting existing diff file - $difffile");
3078       unlink($difffile);
3079     }
3080
3081     my $source_schema;
3082     {
3083       my $t = SQL::Translator->new($sqltargs);
3084       $t->debug( 0 );
3085       $t->trace( 0 );
3086
3087       $t->parser( $db )
3088         or $self->throw_exception ($t->error);
3089
3090       my $out = $t->translate( $prefilename )
3091         or $self->throw_exception ($t->error);
3092
3093       $source_schema = $t->schema;
3094
3095       $source_schema->name( $prefilename )
3096         unless ( $source_schema->name );
3097     }
3098
3099     # The "new" style of producers have sane normalization and can support
3100     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3101     # And we have to diff parsed SQL against parsed SQL.
3102     my $dest_schema = $sqlt_schema;
3103
3104     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3105       my $t = SQL::Translator->new($sqltargs);
3106       $t->debug( 0 );
3107       $t->trace( 0 );
3108
3109       $t->parser( $db )
3110         or $self->throw_exception ($t->error);
3111
3112       my $out = $t->translate( $filename )
3113         or $self->throw_exception ($t->error);
3114
3115       $dest_schema = $t->schema;
3116
3117       $dest_schema->name( $filename )
3118         unless $dest_schema->name;
3119     }
3120
3121     my $diff = do {
3122       # FIXME - this is a terrible workaround for
3123       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3124       # Fixing it in this sloppy manner so that we don't hve to
3125       # lockstep an SQLT release as well. Needs to be removed at
3126       # some point, and SQLT dep bumped
3127       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3128         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3129
3130       SQL::Translator::Diff::schema_diff($source_schema, $db,
3131                                          $dest_schema,   $db,
3132                                          $sqltargs
3133                                        );
3134     };
3135
3136     if(!open $file, ">$difffile") {
3137       $self->throw_exception("Can't write to $difffile ($!)");
3138       next;
3139     }
3140     print $file $diff;
3141     close($file);
3142   }
3143 }
3144
3145 =head2 deployment_statements
3146
3147 =over 4
3148
3149 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3150
3151 =back
3152
3153 Returns the statements used by L<DBIx::Class::Storage/deploy>
3154 and L<DBIx::Class::Schema/deploy>.
3155
3156 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3157 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3158
3159 C<$directory> is used to return statements from files in a previously created
3160 L</create_ddl_dir> directory and is optional. The filenames are constructed
3161 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3162
3163 If no C<$directory> is specified then the statements are constructed on the
3164 fly using L<SQL::Translator> and C<$version> is ignored.
3165
3166 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3167
3168 =cut
3169
3170 sub deployment_statements {
3171   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3172
3173   $self->throw_exception(
3174     'Calling deployment_statements() in void context makes no sense'
3175   ) unless defined wantarray;
3176
3177   $type ||= $self->sqlt_type;
3178   $version ||= $schema->schema_version || '1.x';
3179   $dir ||= './';
3180   my $filename = $schema->ddl_filename($type, $version, $dir);
3181   if(-f $filename)
3182   {
3183       # FIXME replace this block when a proper sane sql parser is available
3184       my $file;
3185       open($file, "<$filename")
3186         or $self->throw_exception("Can't open $filename ($!)");
3187       my @rows = <$file>;
3188       close($file);
3189       return join('', @rows);
3190   }
3191
3192   require DBIx::Class::Optional::Dependencies;
3193   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3194     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3195   }
3196
3197   # sources needs to be a parser arg, but for simplicity allow at top level
3198   # coming in
3199   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3200       if exists $sqltargs->{sources};
3201
3202   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3203     unless exists $sqltargs->{quote_identifiers};
3204
3205   my $tr = SQL::Translator->new(
3206     producer => "SQL::Translator::Producer::${type}",
3207     %$sqltargs,
3208     parser => 'SQL::Translator::Parser::DBIx::Class',
3209     data => $schema,
3210   );
3211
3212   return preserve_context {
3213     $tr->translate
3214   } after => sub {
3215     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3216       unless defined $_[0];
3217   };
3218 }
3219
3220 # FIXME deploy() currently does not accurately report sql errors
3221 # Will always return true while errors are warned
3222 sub deploy {
3223   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3224   my $deploy = sub {
3225     my $line = shift;
3226     return if(!$line);
3227     return if($line =~ /^--/);
3228     # next if($line =~ /^DROP/m);
3229     return if($line =~ /^BEGIN TRANSACTION/m);
3230     return if($line =~ /^COMMIT/m);
3231     return if $line =~ /^\s+$/; # skip whitespace only
3232     $self->_query_start($line);
3233     dbic_internal_try {
3234       # do a dbh_do cycle here, as we need some error checking in
3235       # place (even though we will ignore errors)
3236       $self->dbh_do (sub { $_[1]->do($line) });
3237     } dbic_internal_catch {
3238       carp qq{$_ (running "${line}")};
3239     };
3240     $self->_query_end($line);
3241   };
3242   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3243   if (@statements > 1) {
3244     foreach my $statement (@statements) {
3245       $deploy->( $statement );
3246     }
3247   }
3248   elsif (@statements == 1) {
3249     # split on single line comments and end of statements
3250     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3251       $deploy->( $line );
3252     }
3253   }
3254 }
3255
3256 =head2 datetime_parser
3257
3258 Returns the datetime parser class
3259
3260 =cut
3261
3262 sub datetime_parser {
3263   my $self = shift;
3264   return $self->{datetime_parser} ||= do {
3265     $self->build_datetime_parser(@_);
3266   };
3267 }
3268
3269 =head2 datetime_parser_type
3270
3271 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3272
3273 =head2 build_datetime_parser
3274
3275 See L</datetime_parser>
3276
3277 =cut
3278
3279 sub build_datetime_parser {
3280   my $self = shift;
3281   my $type = $self->datetime_parser_type(@_);
3282   return $type;
3283 }
3284
3285
3286 =head2 is_replicating
3287
3288 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3289 replicate from a master database.  Default is undef, which is the result
3290 returned by databases that don't support replication.
3291
3292 =cut
3293
3294 sub is_replicating {
3295     return;
3296
3297 }
3298
3299 =head2 lag_behind_master
3300
3301 Returns a number that represents a certain amount of lag behind a master db
3302 when a given storage is replicating.  The number is database dependent, but
3303 starts at zero and increases with the amount of lag. Default in undef
3304
3305 =cut
3306
3307 sub lag_behind_master {
3308     return;
3309 }
3310
3311 =head2 relname_to_table_alias
3312
3313 =over 4
3314
3315 =item Arguments: $relname, $join_count
3316
3317 =item Return Value: $alias
3318
3319 =back
3320
3321 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3322 queries.
3323
3324 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3325 way these aliases are named.
3326
3327 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3328 otherwise C<"$relname">.
3329
3330 =cut
3331
3332 sub relname_to_table_alias {
3333   my ($self, $relname, $join_count) = @_;
3334
3335   my $alias = ($join_count && $join_count > 1 ?
3336     join('_', $relname, $join_count) : $relname);
3337
3338   return $alias;
3339 }
3340
3341 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3342 # version and it may be necessary to amend or override it for a specific storage
3343 # if such binds are necessary.
3344 sub _max_column_bytesize {
3345   my ($self, $attr) = @_;
3346
3347   my $max_size;
3348
3349   if ($attr->{sqlt_datatype}) {
3350     my $data_type = lc($attr->{sqlt_datatype});
3351
3352     if ($attr->{sqlt_size}) {
3353
3354       # String/sized-binary types
3355       if ($data_type =~ /^(?:
3356           l? (?:var)? char(?:acter)? (?:\s*varying)?
3357             |
3358           (?:var)? binary (?:\s*varying)?
3359             |
3360           raw
3361         )\b/x
3362       ) {
3363         $max_size = $attr->{sqlt_size};
3364       }
3365       # Other charset/unicode types, assume scale of 4
3366       elsif ($data_type =~ /^(?:
3367           national \s* character (?:\s*varying)?
3368             |
3369           nchar
3370             |
3371           univarchar
3372             |
3373           nvarchar
3374         )\b/x
3375       ) {
3376         $max_size = $attr->{sqlt_size} * 4;
3377       }
3378     }
3379
3380     if (!$max_size and !$self->_is_lob_type($data_type)) {
3381       $max_size = 100 # for all other (numeric?) datatypes
3382     }
3383   }
3384
3385   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3386 }
3387
3388 # Determine if a data_type is some type of BLOB
3389 sub _is_lob_type {
3390   my ($self, $data_type) = @_;
3391   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3392     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3393                                   |varchar|character\s*varying|nvarchar
3394                                   |national\s*character\s*varying))?\z/xi);
3395 }
3396
3397 sub _is_binary_lob_type {
3398   my ($self, $data_type) = @_;
3399   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3400     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3401 }
3402
3403 sub _is_text_lob_type {
3404   my ($self, $data_type) = @_;
3405   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3406     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3407                         |national\s*character\s*varying))\z/xi);
3408 }
3409
3410 # Determine if a data_type is some type of a binary type
3411 sub _is_binary_type {
3412   my ($self, $data_type) = @_;
3413   $data_type && ($self->_is_binary_lob_type($data_type)
3414     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3415 }
3416
3417 1;
3418
3419 =head1 USAGE NOTES
3420
3421 =head2 DBIx::Class and AutoCommit
3422
3423 DBIx::Class can do some wonderful magic with handling exceptions,
3424 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3425 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3426 transaction support.
3427
3428 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3429 in an assumed transaction between commits, and you're telling us you'd
3430 like to manage that manually.  A lot of the magic protections offered by
3431 this module will go away.  We can't protect you from exceptions due to database
3432 disconnects because we don't know anything about how to restart your
3433 transactions.  You're on your own for handling all sorts of exceptional
3434 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3435 be with raw DBI.
3436
3437 =head1 FURTHER QUESTIONS?
3438
3439 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3440
3441 =head1 COPYRIGHT AND LICENSE
3442
3443 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3444 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3445 redistribute it and/or modify it under the same terms as the
3446 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.