lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use base 'DBIx::Class::Storage';
   4
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use SQL::Abstract::Limit;
   9 use DBIx::Class::Storage::DBI::Cursor;
  10 use IO::File;
  11 use Carp::Clan qw/DBIx::Class/;
  12
  13 BEGIN {
  14
  15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  16
  17 use base qw/SQL::Abstract::Limit/;
  18
  19 sub select {
  20   my ($self, $table, $fields, $where, $order, @rest) = @_;
  21   @rest = (-1) unless defined $rest[0];
  22   local $self->{having_bind} = [];
  23   my ($sql, @ret) = $self->SUPER::select($table,
  24                       $self->_recurse_fields($fields), $where, $order, @rest);
  25   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  26 }
  27
  28 sub _emulate_limit {
  29   my $self = shift;
  30   if ($_[3] == -1) {
  31     return $_[1].$self->_order_by($_[2]);
  32   } else {
  33     return $self->SUPER::_emulate_limit(@_);
  34   }
  35 }
  36
  37 sub _recurse_fields {
  38   my ($self, $fields) = @_;
  39   my $ref = ref $fields;
  40   return $self->_quote($fields) unless $ref;
  41   return $$fields if $ref eq 'SCALAR';
  42
  43   if ($ref eq 'ARRAY') {
  44     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  45   } elsif ($ref eq 'HASH') {
  46     foreach my $func (keys %$fields) {
  47       return $self->_sqlcase($func)
  48         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  49     }
  50   }
  51 }
  52
  53 sub _order_by {
  54   my $self = shift;
  55   my $ret = '';
  56   my @extra;
  57   if (ref $_[0] eq 'HASH') {
  58     if (defined $_[0]->{group_by}) {
  59       $ret = $self->_sqlcase(' group by ')
  60                .$self->_recurse_fields($_[0]->{group_by});
  61     }
  62     if (defined $_[0]->{having}) {
  63       my $frag;
  64       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  65       push(@{$self->{having_bind}}, @extra);
  66       $ret .= $self->_sqlcase(' having ').$frag;
  67     }
  68     if (defined $_[0]->{order_by}) {
  69       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  70     }
  71   } else {
  72     $ret = $self->SUPER::_order_by(@_);
  73   }
  74   return $ret;
  75 }
  76
  77 sub _order_directions {
  78   my ($self, $order) = @_;
  79   $order = $order->{order_by} if ref $order eq 'HASH';
  80   return $self->SUPER::_order_directions($order);
  81 }
  82
  83 sub _table {
  84   my ($self, $from) = @_;
  85   if (ref $from eq 'ARRAY') {
  86     return $self->_recurse_from(@$from);
  87   } elsif (ref $from eq 'HASH') {
  88     return $self->_make_as($from);
  89   } else {
  90     return $from;
  91   }
  92 }
  93
  94 sub _recurse_from {
  95   my ($self, $from, @join) = @_;
  96   my @sqlf;
  97   push(@sqlf, $self->_make_as($from));
  98   foreach my $j (@join) {
  99     my ($to, $on) = @$j;
 100
 101     # check whether a join type exists
 102     my $join_clause = '';
 103     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 104       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 105     } else {
 106       $join_clause = ' JOIN ';
 107     }
 108     push(@sqlf, $join_clause);
 109
 110     if (ref $to eq 'ARRAY') {
 111       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 112     } else {
 113       push(@sqlf, $self->_make_as($to));
 114     }
 115     push(@sqlf, ' ON ', $self->_join_condition($on));
 116   }
 117   return join('', @sqlf);
 118 }
 119
 120 sub _make_as {
 121   my ($self, $from) = @_;
 122   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 123                            reverse each %{$self->_skip_options($from)});
 124 }
 125
 126 sub _skip_options {
 127   my ($self, $hash) = @_;
 128   my $clean_hash = {};
 129   $clean_hash->{$_} = $hash->{$_}
 130     for grep {!/^-/} keys %$hash;
 131   return $clean_hash;
 132 }
 133
 134 sub _join_condition {
 135   my ($self, $cond) = @_;
 136   if (ref $cond eq 'HASH') {
 137     my %j;
 138     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 139     return $self->_recurse_where(\%j);
 140   } elsif (ref $cond eq 'ARRAY') {
 141     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 142   } else {
 143     die "Can't handle this yet!";
 144   }
 145 }
 146
 147 sub _quote {
 148   my ($self, $label) = @_;
 149   return '' unless defined $label;
 150   return $label unless $self->{quote_char};
 151   return $self->SUPER::_quote($label);
 152 }
 153
 154 sub _RowNum {
 155    my $self = shift;
 156    my $c;
 157    $_[0] =~ s/SELECT (.*?) FROM/
 158      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 159    $self->SUPER::_RowNum(@_);
 160 }
 161
 162 # Accessor for setting limit dialect. This is useful
 163 # for JDBC-bridge among others where the remote SQL-dialect cannot
 164 # be determined by the name of the driver alone.
 165 #
 166 sub limit_dialect {
 167     my $self = shift;
 168     $self->{limit_dialect} = shift if @_;
 169     return $self->{limit_dialect};
 170 }
 171
 172 sub quote_char {
 173     my $self = shift;
 174     $self->{quote_char} = shift if @_;
 175     return $self->{quote_char};
 176 }
 177
 178 sub name_sep {
 179     my $self = shift;
 180     $self->{name_sep} = shift if @_;
 181     return $self->{name_sep};
 182 }
 183
 184
 185
 186
 187 package DBIx::Class::Storage::DBI::DebugCallback;
 188
 189 sub print {
 190   my ($self, $string) = @_;
 191   $string =~ m/^(\w+)/;
 192   ${$self}->($1, $string);
 193 }
 194
 195 } # End of BEGIN block
 196
 197 use base qw/DBIx::Class/;
 198
 199 __PACKAGE__->load_components(qw/AccessorGroup/);
 200
 201 __PACKAGE__->mk_group_accessors('simple' =>
 202   qw/connect_info _dbh _sql_maker _connection_pid debug debugfh cursor
 203      on_connect_do transaction_depth/);
 204
 205 sub new {
 206   my $new = bless({}, ref $_[0] || $_[0]);
 207   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 208   $new->transaction_depth(0);
 209   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 210      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 211     $new->debugfh(IO::File->new($1, 'w')) || $new->throw_exception("Cannot open trace file $1");
 212   } else {
 213     $new->debugfh(IO::File->new('>&STDERR'));
 214   }
 215   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 216   return $new;
 217 }
 218
 219 sub throw_exception {
 220   my ($self, $msg) = @_;
 221   croak($msg);
 222 }
 223
 224 =head1 NAME
 225
 226 DBIx::Class::Storage::DBI - DBI storage handler
 227
 228 =head1 SYNOPSIS
 229
 230 =head1 DESCRIPTION
 231
 232 This class represents the connection to the database
 233
 234 =head1 METHODS
 235
 236 =cut
 237
 238 =head2 on_connect_do
 239
 240 Executes the sql statements given as a listref on every db connect.
 241
 242 =head2 debug
 243
 244 Causes SQL trace information to be emitted on C<debugfh> filehandle
 245 (or C<STDERR> if C<debugfh> has not specifically been set).
 246
 247 =head2 debugfh
 248
 249 Sets or retrieves the filehandle used for trace/debug output.  This
 250 should be an IO::Handle compatible object (only the C<print> method is
 251 used).  Initially set to be STDERR - although see information on the
 252 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 253
 254 =head2 debugcb
 255
 256 Sets a callback to be executed each time a statement is run; takes a sub
 257 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 258 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 259 be printed.
 260
 261 =cut
 262
 263 sub debugcb {
 264   my ($self, $cb) = @_;
 265   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 266   $self->debugfh($cb_obj);
 267 }
 268
 269 sub disconnect {
 270   my ($self) = @_;
 271
 272   if( $self->connected ) {
 273     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 274     $self->_dbh->disconnect;
 275     $self->_dbh(undef);
 276   }
 277 }
 278
 279 sub connected {
 280   my ($self) = @_;
 281
 282   my $dbh;
 283   (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping)
 284 }
 285
 286 sub ensure_connected {
 287   my ($self) = @_;
 288
 289   unless ($self->connected) {
 290     $self->_populate_dbh;
 291   }
 292 }
 293
 294 sub dbh {
 295   my ($self) = @_;
 296
 297   if($self->_connection_pid && $self->_connection_pid != $$) {
 298       $self->_dbh->{InactiveDestroy} = 1;
 299       $self->_dbh(undef)
 300   }
 301   $self->ensure_connected;
 302   return $self->_dbh;
 303 }
 304
 305 sub sql_maker {
 306   my ($self) = @_;
 307   unless ($self->_sql_maker) {
 308     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 309   }
 310   return $self->_sql_maker;
 311 }
 312
 313 sub _populate_dbh {
 314   my ($self) = @_;
 315   my @info = @{$self->connect_info || []};
 316   $self->_dbh($self->_connect(@info));
 317   my $driver = $self->_dbh->{Driver}->{Name};
 318   eval "require DBIx::Class::Storage::DBI::${driver}";
 319   unless ($@) {
 320     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 321   }
 322   # if on-connect sql statements are given execute them
 323   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 324     $self->_dbh->do($sql_statement);
 325   }
 326
 327   $self->_connection_pid($$);
 328 }
 329
 330 sub _connect {
 331   my ($self, @info) = @_;
 332
 333   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 334       my $old_connect_via = $DBI::connect_via;
 335       $DBI::connect_via = 'connect';
 336       my $dbh = DBI->connect(@info);
 337       $DBI::connect_via = $old_connect_via;
 338       return $dbh;
 339   }
 340
 341   my $dbh = DBI->connect(@info);
 342   $self->throw_exception("DBI Connection failed: $DBI::errstr")
 343       unless $dbh;
 344   $dbh;
 345 }
 346
 347 =head2 txn_begin
 348
 349 Calls begin_work on the current dbh.
 350
 351 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 352 an entire code block to be executed transactionally.
 353
 354 =cut
 355
 356 sub txn_begin {
 357   my $self = shift;
 358   $self->dbh->begin_work
 359     if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 360 }
 361
 362 =head2 txn_commit
 363
 364 Issues a commit against the current dbh.
 365
 366 =cut
 367
 368 sub txn_commit {
 369   my $self = shift;
 370   if ($self->{transaction_depth} == 0) {
 371     $self->dbh->commit unless $self->dbh->{AutoCommit};
 372   }
 373   else {
 374     $self->dbh->commit if --$self->{transaction_depth} == 0;
 375   }
 376 }
 377
 378 =head2 txn_rollback
 379
 380 Issues a rollback against the current dbh. A nested rollback will
 381 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 382 which allows the rollback to propagate to the outermost transaction.
 383
 384 =cut
 385
 386 sub txn_rollback {
 387   my $self = shift;
 388
 389   eval {
 390     if ($self->{transaction_depth} == 0) {
 391       $self->dbh->rollback unless $self->dbh->{AutoCommit};
 392     }
 393     else {
 394       --$self->{transaction_depth} == 0 ?
 395         $self->dbh->rollback :
 396         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 397     }
 398   };
 399
 400   if ($@) {
 401     my $error = $@;
 402     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 403     $error =~ /$exception_class/ and $self->throw_exception($error);
 404     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 405     $self->throw_exception($error);          # resets the transaction depth
 406   }
 407 }
 408
 409 sub _execute {
 410   my ($self, $op, $extra_bind, $ident, @args) = @_;
 411   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 412   unshift(@bind, @$extra_bind) if $extra_bind;
 413   if ($self->debug) {
 414       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 415       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 416   }
 417   my $sth = $self->sth($sql,$op);
 418   $self->throw_exception("no sth generated via sql: $sql") unless $sth;
 419   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 420   my $rv;
 421   if ($sth) {
 422     $rv = $sth->execute(@bind);
 423   } else {
 424     $self->throw_exception("'$sql' did not generate a statement.");
 425   }
 426   return (wantarray ? ($rv, $sth, @bind) : $rv);
 427 }
 428
 429 sub insert {
 430   my ($self, $ident, $to_insert) = @_;
 431   $self->throw_exception( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 432     unless ($self->_execute('insert' => [], $ident, $to_insert));
 433   return $to_insert;
 434 }
 435
 436 sub update {
 437   return shift->_execute('update' => [], @_);
 438 }
 439
 440 sub delete {
 441   return shift->_execute('delete' => [], @_);
 442 }
 443
 444 sub _select {
 445   my ($self, $ident, $select, $condition, $attrs) = @_;
 446   my $order = $attrs->{order_by};
 447   if (ref $condition eq 'SCALAR') {
 448     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 449   }
 450   if (exists $attrs->{group_by} || $attrs->{having}) {
 451     $order = { group_by => $attrs->{group_by},
 452                having => $attrs->{having},
 453                ($order ? (order_by => $order) : ()) };
 454   }
 455   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 456   if ($attrs->{software_limit} ||
 457       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 458         $attrs->{software_limit} = 1;
 459   } else {
 460     push @args, $attrs->{rows}, $attrs->{offset};
 461   }
 462   return $self->_execute(@args);
 463 }
 464
 465 sub select {
 466   my $self = shift;
 467   my ($ident, $select, $condition, $attrs) = @_;
 468   return $self->cursor->new($self, \@_, $attrs);
 469 }
 470
 471 # Need to call finish() to work round broken DBDs
 472
 473 sub select_single {
 474   my $self = shift;
 475   my ($rv, $sth, @bind) = $self->_select(@_);
 476   my @row = $sth->fetchrow_array;
 477   $sth->finish();
 478   return @row;
 479 }
 480
 481 sub sth {
 482   my ($self, $sql) = @_;
 483   # 3 is the if_active parameter which avoids active sth re-use
 484   return $self->dbh->prepare_cached($sql, {}, 3);
 485 }
 486
 487 =head2 columns_info_for
 488
 489 Returns database type info for a given table columns.
 490
 491 =cut
 492
 493 sub columns_info_for {
 494     my ($self, $table) = @_;
 495     my %result;
 496     if ( $self->dbh->can( 'column_info' ) ){
 497         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 498         $sth->execute();
 499         while ( my $info = $sth->fetchrow_hashref() ){
 500             my %column_info;
 501             $column_info{data_type} = $info->{TYPE_NAME};
 502             $column_info{size} = $info->{COLUMN_SIZE};
 503             $column_info{is_nullable} = $info->{NULLABLE};
 504             $result{$info->{COLUMN_NAME}} = \%column_info;
 505         }
 506     } else {
 507         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 508         $sth->execute;
 509         my @columns = @{$sth->{NAME}};
 510         for my $i ( 0 .. $#columns ){
 511             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 512         }
 513     }
 514     return \%result;
 515 }
 516
 517 sub last_insert_id {
 518   my ($self, $row) = @_;
 519
 520   return $self->dbh->func('last_insert_rowid');
 521
 522 }
 523
 524 sub sqlt_type {
 525   my ($self) = @_;
 526   my $dsn = $self->connect_info->[0];
 527   $dsn =~ /^dbi:(.*?)\d*:/;
 528   return $1;
 529 }
 530
 531 sub deployment_statements {
 532   my ($self, $schema, $type) = @_;
 533   $type ||= $self->sqlt_type;
 534   eval "use SQL::Translator";
 535   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 536   eval "use SQL::Translator::Parser::DBIx::Class;";
 537   $self->throw_exception($@) if $@;
 538   eval "use SQL::Translator::Producer::${type};";
 539   $self->throw_exception($@) if $@;
 540   my $tr = SQL::Translator->new();
 541   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 542   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 543 }
 544
 545 sub deploy {
 546   my ($self, $schema, $type) = @_;
 547   foreach(split(";\n", $self->deployment_statements($schema, $type))) {
 548           $self->dbh->do($_) or warn "SQL was:\n $_";
 549   }
 550 }
 551
 552 sub DESTROY { shift->disconnect }
 553
 554 1;
 555
 556 =head1 ENVIRONMENT VARIABLES
 557
 558 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 559
 560 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 561 is produced (as when the L<debug> method is set).
 562
 563 If the value is of the form C<1=/path/name> then the trace output is
 564 written to the file C</path/name>.
 565
 566 =head1 AUTHORS
 567
 568 Matt S. Trout <mst@shadowcatsystems.co.uk>
 569
 570 Andy Grundman <andy@hybridized.org>
 571
 572 =head1 LICENSE
 573
 574 You may distribute this code under the same terms as Perl itself.
 575
 576 =cut
 577