lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(quote_sub perlstring serialize detected_reinvoked_destructor);
  17 use namespace::clean;
  18
  19 # default cursor class, overridable in connect_info attributes
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/
  23   sql_limit_dialect sql_quote_char sql_name_sep
  24 /);
  25
  26 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  27
  28 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  29 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  30
  31 __PACKAGE__->sql_name_sep('.');
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/
  34   _connect_info _dbic_connect_attributes _driver_determined
  35   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  36   _perform_autoinc_retrieval _autoinc_supplied_for_op
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. We also need to separate accessors
  82 # from plain old method calls, since an accessor called as a setter
  83 # does *not* need the driver determination loop fired (and in fact
  84 # can produce hard to find bugs, like e.g. losing on_connect_*
  85 # semantics on fresh connections)
  86 #
  87 # The construct below is simply a parameterized around()
  88 my $storage_accessor_idx = { map { $_ => 1 } qw(
  89   sqlt_type
  90   datetime_parser_type
  91
  92   sql_maker
  93   cursor_class
  94 )};
  95 for my $meth (keys %$storage_accessor_idx, qw(
  96   deployment_statements
  97
  98   build_datetime_parser
  99
 100   txn_begin
 101
 102   insert
 103   update
 104   delete
 105   select
 106   select_single
 107
 108   _insert_bulk
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 123
 124   quote_sub
 125     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 126
 127     if (
 128       # if this is an actual *setter* - just set it, no need to connect
 129       # and determine the driver
 130       !( %1$s and @_ > 1 )
 131         and
 132       # only fire when invoked on an instance, a valid class-based invocation
 133       # would e.g. be setting a default for an inherited accessor
 134       ref $_[0]
 135         and
 136       ! $_[0]->{_driver_determined}
 137         and
 138       ! $_[0]->{_in_determine_driver}
 139         and
 140       # Only try to determine stuff if we have *something* that either is or can
 141       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 142       # to still be marginally useful
 143       $_[0]->_dbi_connect_info->[0]
 144     ) {
 145       $_[0]->_determine_driver;
 146
 147       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 148       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 149
 150       my $cref = $_[0]->can(%2$s);
 151       goto $cref;
 152     }
 153
 154     goto $orig;
 155 EOC
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164   my $schema = MySchema->connect('dbi:SQLite:my.db');
 165
 166   $schema->storage->debug(1);
 167
 168   my @stuff = $schema->storage->dbh_do(
 169     sub {
 170       my ($storage, $dbh, @args) = @_;
 171       $dbh->do("DROP TABLE authors");
 172     },
 173     @column_list
 174   );
 175
 176   $schema->resultset('Book')->search({
 177      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 178   });
 179
 180 =head1 DESCRIPTION
 181
 182 This class represents the connection to an RDBMS via L<DBI>.  See
 183 L<DBIx::Class::Storage> for general information.  This pod only
 184 documents DBI-specific methods and behaviors.
 185
 186 =head1 METHODS
 187
 188 =cut
 189
 190 sub new {
 191   my $new = shift->next::method(@_);
 192
 193   $new->_sql_maker_opts({});
 194   $new->_dbh_details({});
 195   $new->{_in_do_block} = 0;
 196
 197   # read below to see what this does
 198   $new->_arm_global_destructor;
 199
 200   $new;
 201 }
 202
 203 # This is hack to work around perl shooting stuff in random
 204 # order on exit(). If we do not walk the remaining storage
 205 # objects in an END block, there is a *small but real* chance
 206 # of a fork()ed child to kill the parent's shared DBI handle,
 207 # *before perl reaches the DESTROY in this package*
 208 # Yes, it is ugly and effective.
 209 # Additionally this registry is used by the CLONE method to
 210 # make sure no handles are shared between threads
 211 {
 212   my %seek_and_destroy;
 213
 214   sub _arm_global_destructor {
 215
 216     # quick "garbage collection" pass - prevents the registry
 217     # from slowly growing with a bunch of undef-valued keys
 218     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 219       for keys %seek_and_destroy;
 220
 221     weaken (
 222       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 223     );
 224   }
 225
 226   END {
 227     local $?; # just in case the DBI destructor changes it somehow
 228
 229     # destroy just the object if not native to this process
 230     $_->_verify_pid for (grep
 231       { defined $_ }
 232       values %seek_and_destroy
 233     );
 234   }
 235
 236   sub CLONE {
 237     # As per DBI's recommendation, DBIC disconnects all handles as
 238     # soon as possible (DBIC will reconnect only on demand from within
 239     # the thread)
 240     my @instances = grep { defined $_ } values %seek_and_destroy;
 241     %seek_and_destroy = ();
 242
 243     for (@instances) {
 244       $_->_dbh(undef);
 245
 246       $_->transaction_depth(0);
 247       $_->savepoints([]);
 248
 249       # properly renumber existing refs
 250       $_->_arm_global_destructor
 251     }
 252   }
 253 }
 254
 255 sub DESTROY {
 256   return if &detected_reinvoked_destructor;
 257
 258   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 259   # some databases spew warnings on implicit disconnect
 260   local $SIG{__WARN__} = sub {};
 261   $_[0]->_dbh(undef);
 262
 263   # this op is necessary, since the very last perl runtime statement
 264   # triggers a global destruction shootout, and the $SIG localization
 265   # may very well be destroyed before perl actually gets to do the
 266   # $dbh undef
 267   1;
 268 }
 269
 270 # handle pid changes correctly - do not destroy parent's connection
 271 sub _verify_pid {
 272
 273   my $pid = $_[0]->_conn_pid;
 274
 275   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 276     $dbh->{InactiveDestroy} = 1;
 277     $_[0]->_dbh(undef);
 278     $_[0]->transaction_depth(0);
 279     $_[0]->savepoints([]);
 280   }
 281
 282   return;
 283 }
 284
 285 =head2 connect_info
 286
 287 This method is normally called by L<DBIx::Class::Schema/connection>, which
 288 encapsulates its argument list in an arrayref before passing them here.
 289
 290 The argument list may contain:
 291
 292 =over
 293
 294 =item *
 295
 296 The same 4-element argument set one would normally pass to
 297 L<DBI/connect>, optionally followed by
 298 L<extra attributes|/DBIx::Class specific connection attributes>
 299 recognized by DBIx::Class:
 300
 301   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 302
 303 =item *
 304
 305 A single code reference which returns a connected
 306 L<DBI database handle|DBI/connect> optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 308 by DBIx::Class:
 309
 310   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single hashref with all the attributes and the dsn/user/password
 315 mixed together:
 316
 317   $connect_info_args = [{
 318     dsn => $dsn,
 319     user => $user,
 320     password => $pass,
 321     %dbi_attributes,
 322     %extra_attributes,
 323   }];
 324
 325   $connect_info_args = [{
 326     dbh_maker => sub { DBI->connect (...) },
 327     %dbi_attributes,
 328     %extra_attributes,
 329   }];
 330
 331 This is particularly useful for L<Catalyst> based applications, allowing the
 332 following config (L<Config::General> style):
 333
 334   <Model::DB>
 335     schema_class   App::DB
 336     <connect_info>
 337       dsn          dbi:mysql:database=test
 338       user         testuser
 339       password     TestPass
 340       AutoCommit   1
 341     </connect_info>
 342   </Model::DB>
 343
 344 The C<dsn>/C<user>/C<password> combination can be substituted by the
 345 C<dbh_maker> key whose value is a coderef that returns a connected
 346 L<DBI database handle|DBI/connect>
 347
 348 =back
 349
 350 Please note that the L<DBI> docs recommend that you always explicitly
 351 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 352 recommends that it be set to I<1>, and that you perform transactions
 353 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 354 to I<1> if you do not do explicitly set it to zero.  This is the default
 355 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 356
 357 =head3 DBIx::Class specific connection attributes
 358
 359 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 360 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 361 the following connection options. These options can be mixed in with your other
 362 L<DBI> connection attributes, or placed in a separate hashref
 363 (C<\%extra_attributes>) as shown above.
 364
 365 Every time C<connect_info> is invoked, any previous settings for
 366 these options will be cleared before setting the new ones, regardless of
 367 whether any options are specified in the new C<connect_info>.
 368
 369
 370 =over
 371
 372 =item on_connect_do
 373
 374 Specifies things to do immediately after connecting or re-connecting to
 375 the database.  Its value may contain:
 376
 377 =over
 378
 379 =item a scalar
 380
 381 This contains one SQL statement to execute.
 382
 383 =item an array reference
 384
 385 This contains SQL statements to execute in order.  Each element contains
 386 a string or a code reference that returns a string.
 387
 388 =item a code reference
 389
 390 This contains some code to execute.  Unlike code references within an
 391 array reference, its return value is ignored.
 392
 393 =back
 394
 395 =item on_disconnect_do
 396
 397 Takes arguments in the same form as L</on_connect_do> and executes them
 398 immediately before disconnecting from the database.
 399
 400 Note, this only runs if you explicitly call L</disconnect> on the
 401 storage object.
 402
 403 =item on_connect_call
 404
 405 A more generalized form of L</on_connect_do> that calls the specified
 406 C<connect_call_METHOD> methods in your storage driver.
 407
 408   on_connect_do => 'select 1'
 409
 410 is equivalent to:
 411
 412   on_connect_call => [ [ do_sql => 'select 1' ] ]
 413
 414 Its values may contain:
 415
 416 =over
 417
 418 =item a scalar
 419
 420 Will call the C<connect_call_METHOD> method.
 421
 422 =item a code reference
 423
 424 Will execute C<< $code->($storage) >>
 425
 426 =item an array reference
 427
 428 Each value can be a method name or code reference.
 429
 430 =item an array of arrays
 431
 432 For each array, the first item is taken to be the C<connect_call_> method name
 433 or code reference, and the rest are parameters to it.
 434
 435 =back
 436
 437 Some predefined storage methods you may use:
 438
 439 =over
 440
 441 =item do_sql
 442
 443 Executes a SQL string or a code reference that returns a SQL string. This is
 444 what L</on_connect_do> and L</on_disconnect_do> use.
 445
 446 It can take:
 447
 448 =over
 449
 450 =item a scalar
 451
 452 Will execute the scalar as SQL.
 453
 454 =item an arrayref
 455
 456 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 457 attributes hashref and bind values.
 458
 459 =item a code reference
 460
 461 Will execute C<< $code->($storage) >> and execute the return array refs as
 462 above.
 463
 464 =back
 465
 466 =item datetime_setup
 467
 468 Execute any statements necessary to initialize the database session to return
 469 and accept datetime/timestamp values used with
 470 L<DBIx::Class::InflateColumn::DateTime>.
 471
 472 Only necessary for some databases, see your specific storage driver for
 473 implementation details.
 474
 475 =back
 476
 477 =item on_disconnect_call
 478
 479 Takes arguments in the same form as L</on_connect_call> and executes them
 480 immediately before disconnecting from the database.
 481
 482 Calls the C<disconnect_call_METHOD> methods as opposed to the
 483 C<connect_call_METHOD> methods called by L</on_connect_call>.
 484
 485 Note, this only runs if you explicitly call L</disconnect> on the
 486 storage object.
 487
 488 =item disable_sth_caching
 489
 490 If set to a true value, this option will disable the caching of
 491 statement handles via L<DBI/prepare_cached>.
 492
 493 =item limit_dialect
 494
 495 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 496 default L</sql_limit_dialect> setting of the storage (if any). For a list
 497 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 498
 499 =item quote_names
 500
 501 When true automatically sets L</quote_char> and L</name_sep> to the characters
 502 appropriate for your particular RDBMS. This option is preferred over specifying
 503 L</quote_char> directly.
 504
 505 =item quote_char
 506
 507 Specifies what characters to use to quote table and column names.
 508
 509 C<quote_char> expects either a single character, in which case is it
 510 is placed on either side of the table/column name, or an arrayref of length
 511 2 in which case the table/column name is placed between the elements.
 512
 513 For example under MySQL you should use C<< quote_char => '`' >>, and for
 514 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 515
 516 =item name_sep
 517
 518 This parameter is only useful in conjunction with C<quote_char>, and is used to
 519 specify the character that separates elements (schemas, tables, columns) from
 520 each other. If unspecified it defaults to the most commonly used C<.>.
 521
 522 =item unsafe
 523
 524 This Storage driver normally installs its own C<HandleError>, sets
 525 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 526 all database handles, including those supplied by a coderef.  It does this
 527 so that it can have consistent and useful error behavior.
 528
 529 If you set this option to a true value, Storage will not do its usual
 530 modifications to the database handle's attributes, and instead relies on
 531 the settings in your connect_info DBI options (or the values you set in
 532 your connection coderef, in the case that you are connecting via coderef).
 533
 534 Note that your custom settings can cause Storage to malfunction,
 535 especially if you set a C<HandleError> handler that suppresses exceptions
 536 and/or disable C<RaiseError>.
 537
 538 =item auto_savepoint
 539
 540 If this option is true, L<DBIx::Class> will use savepoints when nesting
 541 transactions, making it possible to recover from failure in the inner
 542 transaction without having to abort all outer transactions.
 543
 544 =item cursor_class
 545
 546 Use this argument to supply a cursor class other than the default
 547 L<DBIx::Class::Storage::DBI::Cursor>.
 548
 549 =back
 550
 551 Some real-life examples of arguments to L</connect_info> and
 552 L<DBIx::Class::Schema/connect>
 553
 554   # Simple SQLite connection
 555   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 556
 557   # Connect via subref
 558   ->connect_info([ sub { DBI->connect(...) } ]);
 559
 560   # Connect via subref in hashref
 561   ->connect_info([{
 562     dbh_maker => sub { DBI->connect(...) },
 563     on_connect_do => 'alter session ...',
 564   }]);
 565
 566   # A bit more complicated
 567   ->connect_info(
 568     [
 569       'dbi:Pg:dbname=foo',
 570       'postgres',
 571       'my_pg_password',
 572       { AutoCommit => 1 },
 573       { quote_char => q{"} },
 574     ]
 575   );
 576
 577   # Equivalent to the previous example
 578   ->connect_info(
 579     [
 580       'dbi:Pg:dbname=foo',
 581       'postgres',
 582       'my_pg_password',
 583       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 584     ]
 585   );
 586
 587   # Same, but with hashref as argument
 588   # See parse_connect_info for explanation
 589   ->connect_info(
 590     [{
 591       dsn         => 'dbi:Pg:dbname=foo',
 592       user        => 'postgres',
 593       password    => 'my_pg_password',
 594       AutoCommit  => 1,
 595       quote_char  => q{"},
 596       name_sep    => q{.},
 597     }]
 598   );
 599
 600   # Subref + DBIx::Class-specific connection options
 601   ->connect_info(
 602     [
 603       sub { DBI->connect(...) },
 604       {
 605           quote_char => q{`},
 606           name_sep => q{@},
 607           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 608           disable_sth_caching => 1,
 609       },
 610     ]
 611   );
 612
 613
 614
 615 =cut
 616
 617 sub connect_info {
 618   my ($self, $info) = @_;
 619
 620   return $self->_connect_info if !$info;
 621
 622   $self->_connect_info($info); # copy for _connect_info
 623
 624   $info = $self->_normalize_connect_info($info)
 625     if ref $info eq 'ARRAY';
 626
 627   my %attrs = (
 628     %{ $self->_default_dbi_connect_attributes || {} },
 629     %{ $info->{attributes} || {} },
 630   );
 631
 632   my @args = @{ $info->{arguments} };
 633
 634   if (keys %attrs and ref $args[0] ne 'CODE') {
 635     carp_unique (
 636         'You provided explicit AutoCommit => 0 in your connection_info. '
 637       . 'This is almost universally a bad idea (see the footnotes of '
 638       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 639       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 640       . 'this warning.'
 641     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 642
 643     push @args, \%attrs if keys %attrs;
 644   }
 645
 646   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 647   # OR a single-element coderef-based $dbh factory
 648   $self->_dbi_connect_info(\@args);
 649
 650   # extract the individual storage options
 651   for my $storage_opt (keys %{ $info->{storage_options} }) {
 652     my $value = $info->{storage_options}{$storage_opt};
 653
 654     $self->$storage_opt($value);
 655   }
 656
 657   # Extract the individual sqlmaker options
 658   #
 659   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 660   #  the new set of options
 661   $self->_sql_maker(undef);
 662   $self->_sql_maker_opts({});
 663
 664   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 665     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 666
 667     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 668   }
 669
 670   # FIXME - dirty:
 671   # save attributes in a separate accessor so they are always
 672   # introspectable, even in case of a CODE $dbhmaker
 673   $self->_dbic_connect_attributes (\%attrs);
 674
 675   return $self->_connect_info;
 676 }
 677
 678 sub _dbi_connect_info {
 679   my $self = shift;
 680
 681   return $self->{_dbi_connect_info} = $_[0]
 682     if @_;
 683
 684   my $conninfo = $self->{_dbi_connect_info} || [];
 685
 686   # last ditch effort to grab a DSN
 687   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 688     my @new_conninfo = @$conninfo;
 689     $new_conninfo[0] = $ENV{DBI_DSN};
 690     $conninfo = \@new_conninfo;
 691   }
 692
 693   return $conninfo;
 694 }
 695
 696
 697 sub _normalize_connect_info {
 698   my ($self, $info_arg) = @_;
 699   my %info;
 700
 701   my @args = @$info_arg;  # take a shallow copy for further mutilation
 702
 703   # combine/pre-parse arguments depending on invocation style
 704
 705   my %attrs;
 706   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 707     %attrs = %{ $args[1] || {} };
 708     @args = $args[0];
 709   }
 710   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 711     %attrs = %{$args[0]};
 712     @args = ();
 713     if (my $code = delete $attrs{dbh_maker}) {
 714       @args = $code;
 715
 716       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 717       if (@ignored) {
 718         carp sprintf (
 719             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 720           . "to the result of 'dbh_maker'",
 721
 722           join (', ', map { "'$_'" } (@ignored) ),
 723         );
 724       }
 725     }
 726     else {
 727       @args = delete @attrs{qw/dsn user password/};
 728     }
 729   }
 730   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 731     %attrs = (
 732       % { $args[3] || {} },
 733       % { $args[4] || {} },
 734     );
 735     @args = @args[0,1,2];
 736   }
 737
 738   $info{arguments} = \@args;
 739
 740   my @storage_opts = grep exists $attrs{$_},
 741     @storage_options, 'cursor_class';
 742
 743   @{ $info{storage_options} }{@storage_opts} =
 744     delete @attrs{@storage_opts} if @storage_opts;
 745
 746   my @sql_maker_opts = grep exists $attrs{$_},
 747     qw/limit_dialect quote_char name_sep quote_names/;
 748
 749   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 750     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 751
 752   $info{attributes} = \%attrs if %attrs;
 753
 754   return \%info;
 755 }
 756
 757 sub _default_dbi_connect_attributes () {
 758   +{
 759     AutoCommit => 1,
 760     PrintError => 0,
 761     RaiseError => 1,
 762     ShowErrorStatement => 1,
 763   };
 764 }
 765
 766 =head2 on_connect_do
 767
 768 This method is deprecated in favour of setting via L</connect_info>.
 769
 770 =cut
 771
 772 =head2 on_disconnect_do
 773
 774 This method is deprecated in favour of setting via L</connect_info>.
 775
 776 =cut
 777
 778 sub _parse_connect_do {
 779   my ($self, $type) = @_;
 780
 781   my $val = $self->$type;
 782   return () if not defined $val;
 783
 784   my @res;
 785
 786   if (not ref($val)) {
 787     push @res, [ 'do_sql', $val ];
 788   } elsif (ref($val) eq 'CODE') {
 789     push @res, $val;
 790   } elsif (ref($val) eq 'ARRAY') {
 791     push @res, map { [ 'do_sql', $_ ] } @$val;
 792   } else {
 793     $self->throw_exception("Invalid type for $type: ".ref($val));
 794   }
 795
 796   return \@res;
 797 }
 798
 799 =head2 dbh_do
 800
 801 Arguments: ($subref | $method_name), @extra_coderef_args?
 802
 803 Execute the given $subref or $method_name using the new exception-based
 804 connection management.
 805
 806 The first two arguments will be the storage object that C<dbh_do> was called
 807 on and a database handle to use.  Any additional arguments will be passed
 808 verbatim to the called subref as arguments 2 and onwards.
 809
 810 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 811 exception handling and reconnection (or failover in future subclasses).
 812
 813 Your subref should have no side-effects outside of the database, as
 814 there is the potential for your subref to be partially double-executed
 815 if the database connection was stale/dysfunctional.
 816
 817 Example:
 818
 819   my @stuff = $schema->storage->dbh_do(
 820     sub {
 821       my ($storage, $dbh, @cols) = @_;
 822       my $cols = join(q{, }, @cols);
 823       $dbh->selectrow_array("SELECT $cols FROM foo");
 824     },
 825     @column_list
 826   );
 827
 828 =cut
 829
 830 sub dbh_do {
 831   my $self = shift;
 832   my $run_target = shift; # either a coderef or a method name
 833
 834   # short circuit when we know there is no need for a runner
 835   #
 836   # FIXME - assumption may be wrong
 837   # the rationale for the txn_depth check is that if this block is a part
 838   # of a larger transaction, everything up to that point is screwed anyway
 839   return $self->$run_target($self->_get_dbh, @_)
 840     if $self->{_in_do_block} or $self->transaction_depth;
 841
 842   # take a ref instead of a copy, to preserve @_ aliasing
 843   # semantics within the coderef, but only if needed
 844   # (pseudoforking doesn't like this trick much)
 845   my $args = @_ ? \@_ : [];
 846
 847   DBIx::Class::Storage::BlockRunner->new(
 848     storage => $self,
 849     wrap_txn => 0,
 850     retry_handler => sub {
 851       $_[0]->failed_attempt_count == 1
 852         and
 853       ! $_[0]->storage->connected
 854     },
 855   )->run(sub {
 856     $self->$run_target ($self->_get_dbh, @$args )
 857   });
 858 }
 859
 860 sub txn_do {
 861   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 862   shift->next::method(@_);
 863 }
 864
 865 =head2 disconnect
 866
 867 Our C<disconnect> method also performs a rollback first if the
 868 database is not in C<AutoCommit> mode.
 869
 870 =cut
 871
 872 sub disconnect {
 873
 874   if( my $dbh = $_[0]->_dbh ) {
 875
 876     $_[0]->_do_connection_actions(disconnect_call_ => $_) for (
 877       ( $_[0]->on_disconnect_call || () ),
 878       $_[0]->_parse_connect_do ('on_disconnect_do')
 879     );
 880
 881     # stops the "implicit rollback on disconnect" warning
 882     $_[0]->_exec_txn_rollback unless $_[0]->_dbh_autocommit;
 883
 884     %{ $dbh->{CachedKids} } = ();
 885     $dbh->disconnect;
 886     $_[0]->_dbh(undef);
 887   }
 888 }
 889
 890 =head2 with_deferred_fk_checks
 891
 892 =over 4
 893
 894 =item Arguments: C<$coderef>
 895
 896 =item Return Value: The return value of $coderef
 897
 898 =back
 899
 900 Storage specific method to run the code ref with FK checks deferred or
 901 in MySQL's case disabled entirely.
 902
 903 =cut
 904
 905 # Storage subclasses should override this
 906 sub with_deferred_fk_checks {
 907   #my ($self, $sub) = @_;
 908   $_[1]->();
 909 }
 910
 911 =head2 connected
 912
 913 =over
 914
 915 =item Arguments: none
 916
 917 =item Return Value: 1|0
 918
 919 =back
 920
 921 Verifies that the current database handle is active and ready to execute
 922 an SQL statement (e.g. the connection did not get stale, server is still
 923 answering, etc.) This method is used internally by L</dbh>.
 924
 925 =cut
 926
 927 sub connected {
 928   return 0 unless $_[0]->_seems_connected;
 929
 930   #be on the safe side
 931   local $_[0]->_dbh->{RaiseError} = 1;
 932
 933   return $_[0]->_ping;
 934 }
 935
 936 sub _seems_connected {
 937   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 938
 939   ($_[0]->_dbh || return 0)->FETCH('Active');
 940 }
 941
 942 sub _ping {
 943   ($_[0]->_dbh || return 0)->ping;
 944 }
 945
 946 sub ensure_connected {
 947   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 948 }
 949
 950 =head2 dbh
 951
 952 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 953 is guaranteed to be healthy by implicitly calling L</connected>, and if
 954 necessary performing a reconnection before returning. Keep in mind that this
 955 is very B<expensive> on some database engines. Consider using L</dbh_do>
 956 instead.
 957
 958 =cut
 959
 960 sub dbh {
 961   # maybe save a ping call
 962   $_[0]->_dbh
 963     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 964     : $_[0]->_populate_dbh
 965   ;
 966 }
 967
 968 # this is the internal "get dbh or connect (don't check)" method
 969 sub _get_dbh {
 970   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 971   $_[0]->_dbh || $_[0]->_populate_dbh;
 972 }
 973
 974 # *DELIBERATELY* not a setter (for the time being)
 975 # Too intertwined with everything else for any kind of sanity
 976 sub sql_maker {
 977   my $self = shift;
 978
 979   $self->throw_exception('sql_maker() is not a setter method') if @_;
 980
 981   unless ($self->_sql_maker) {
 982     my $sql_maker_class = $self->sql_maker_class;
 983
 984     my %opts = %{$self->_sql_maker_opts||{}};
 985     my $dialect =
 986       $opts{limit_dialect}
 987         ||
 988       $self->sql_limit_dialect
 989         ||
 990       do {
 991         my $s_class = (ref $self) || $self;
 992         carp_unique (
 993           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 994         . 'have not supplied an explicit limit_dialect in your connection_info. '
 995         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 996         . 'databases but can be (and often is) painfully slow. '
 997         . "Please file an RT ticket against '$s_class'"
 998         ) if $self->_dbi_connect_info->[0];
 999
1000         'GenericSubQ';
1001       }
1002     ;
1003
1004     my ($quote_char, $name_sep);
1005
1006     if ($opts{quote_names}) {
1007       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1008         my $s_class = (ref $self) || $self;
1009         carp_unique (
1010           "You requested 'quote_names' but your storage class ($s_class) does "
1011         . 'not explicitly define a default sql_quote_char and you have not '
1012         . 'supplied a quote_char as part of your connection_info. DBIC will '
1013         .q{default to the ANSI SQL standard quote '"', which works most of }
1014         . "the time. Please file an RT ticket against '$s_class'."
1015         );
1016
1017         '"'; # RV
1018       };
1019
1020       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1021     }
1022
1023     $self->_sql_maker($sql_maker_class->new(
1024       bindtype=>'columns',
1025       array_datatypes => 1,
1026       limit_dialect => $dialect,
1027       ($quote_char ? (quote_char => $quote_char) : ()),
1028       name_sep => ($name_sep || '.'),
1029       %opts,
1030     ));
1031   }
1032   return $self->_sql_maker;
1033 }
1034
1035 # nothing to do by default
1036 sub _rebless {}
1037 sub _init {}
1038
1039 sub _populate_dbh {
1040
1041   $_[0]->_dbh(undef); # in case ->connected failed we might get sent here
1042
1043   $_[0]->_dbh_details({}); # reset everything we know
1044
1045   # FIXME - this needs reenabling with the proper "no reset on same DSN" check
1046   #$_[0]->_sql_maker(undef); # this may also end up being different
1047
1048   $_[0]->_dbh($_[0]->_connect);
1049
1050   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1051
1052   $_[0]->_determine_driver;
1053
1054   # Always set the transaction depth on connect, since
1055   #  there is no transaction in progress by definition
1056   $_[0]->{transaction_depth} = $_[0]->_dbh_autocommit ? 0 : 1;
1057
1058   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1059
1060   $_[0]->_dbh;
1061 }
1062
1063 sub _run_connection_actions {
1064
1065   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1066     ( $_[0]->on_connect_call || () ),
1067     $_[0]->_parse_connect_do ('on_connect_do'),
1068   );
1069 }
1070
1071
1072
1073 sub set_use_dbms_capability {
1074   $_[0]->set_inherited ($_[1], $_[2]);
1075 }
1076
1077 sub get_use_dbms_capability {
1078   my ($self, $capname) = @_;
1079
1080   my $use = $self->get_inherited ($capname);
1081   return defined $use
1082     ? $use
1083     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1084   ;
1085 }
1086
1087 sub set_dbms_capability {
1088   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1089 }
1090
1091 sub get_dbms_capability {
1092   my ($self, $capname) = @_;
1093
1094   my $cap = $self->_dbh_details->{capability}{$capname};
1095
1096   unless (defined $cap) {
1097     if (my $meth = $self->can ("_determine$capname")) {
1098       $cap = $self->$meth ? 1 : 0;
1099     }
1100     else {
1101       $cap = 0;
1102     }
1103
1104     $self->set_dbms_capability ($capname, $cap);
1105   }
1106
1107   return $cap;
1108 }
1109
1110 sub _server_info {
1111   my $self = shift;
1112
1113   # FIXME - ideally this needs to be an ||= assignment, and the final
1114   # assignment at the end of this do{} should be gone entirely. However
1115   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1116   $self->_dbh_details->{info} || do {
1117
1118     # this guarantees that problematic conninfo won't be hidden
1119     # by the try{} below
1120     $self->ensure_connected;
1121
1122     my $info = {};
1123
1124     my $server_version = try {
1125       $self->_get_server_version
1126     } catch {
1127       # driver determination *may* use this codepath
1128       # in which case we must rethrow
1129       $self->throw_exception($_) if $self->{_in_determine_driver};
1130
1131       # $server_version on failure
1132       undef;
1133     };
1134
1135     if (defined $server_version) {
1136       $info->{dbms_version} = $server_version;
1137
1138       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1139       my @verparts = split (/\./, $numeric_version);
1140       if (
1141         @verparts
1142           &&
1143         $verparts[0] <= 999
1144       ) {
1145         # consider only up to 3 version parts, iff not more than 3 digits
1146         my @use_parts;
1147         while (@verparts && @use_parts < 3) {
1148           my $p = shift @verparts;
1149           last if $p > 999;
1150           push @use_parts, $p;
1151         }
1152         push @use_parts, 0 while @use_parts < 3;
1153
1154         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1155       }
1156     }
1157
1158     $self->_dbh_details->{info} = $info;
1159   };
1160 }
1161
1162 sub _get_server_version {
1163   shift->_dbh_get_info('SQL_DBMS_VER');
1164 }
1165
1166 sub _dbh_get_info {
1167   my ($self, $info) = @_;
1168
1169   if ($info =~ /[^0-9]/) {
1170     require DBI::Const::GetInfoType;
1171     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1172     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1173       unless defined $info;
1174   }
1175
1176   $self->_get_dbh->get_info($info);
1177 }
1178
1179 sub _describe_connection {
1180   require DBI::Const::GetInfoReturn;
1181
1182   my $self = shift;
1183
1184   my $drv;
1185   try {
1186     $drv = $self->_extract_driver_from_connect_info;
1187     $self->ensure_connected;
1188   };
1189
1190   $drv = "DBD::$drv" if $drv;
1191
1192   my $res = {
1193     DBIC_DSN => $self->_dbi_connect_info->[0],
1194     DBI_VER => DBI->VERSION,
1195     DBIC_VER => DBIx::Class->VERSION,
1196     DBIC_DRIVER => ref $self,
1197     $drv ? (
1198       DBD => $drv,
1199       DBD_VER => try { $drv->VERSION },
1200     ) : (),
1201   };
1202
1203   # try to grab data even if we never managed to connect
1204   # will cover us in cases of an oddly broken half-connect
1205   for my $inf (
1206     #keys %DBI::Const::GetInfoType::GetInfoType,
1207     qw/
1208       SQL_CURSOR_COMMIT_BEHAVIOR
1209       SQL_CURSOR_ROLLBACK_BEHAVIOR
1210       SQL_CURSOR_SENSITIVITY
1211       SQL_DATA_SOURCE_NAME
1212       SQL_DBMS_NAME
1213       SQL_DBMS_VER
1214       SQL_DEFAULT_TXN_ISOLATION
1215       SQL_DM_VER
1216       SQL_DRIVER_NAME
1217       SQL_DRIVER_ODBC_VER
1218       SQL_DRIVER_VER
1219       SQL_EXPRESSIONS_IN_ORDERBY
1220       SQL_GROUP_BY
1221       SQL_IDENTIFIER_CASE
1222       SQL_IDENTIFIER_QUOTE_CHAR
1223       SQL_MAX_CATALOG_NAME_LEN
1224       SQL_MAX_COLUMN_NAME_LEN
1225       SQL_MAX_IDENTIFIER_LEN
1226       SQL_MAX_TABLE_NAME_LEN
1227       SQL_MULTIPLE_ACTIVE_TXN
1228       SQL_MULT_RESULT_SETS
1229       SQL_NEED_LONG_DATA_LEN
1230       SQL_NON_NULLABLE_COLUMNS
1231       SQL_ODBC_VER
1232       SQL_QUALIFIER_NAME_SEPARATOR
1233       SQL_QUOTED_IDENTIFIER_CASE
1234       SQL_TXN_CAPABLE
1235       SQL_TXN_ISOLATION_OPTION
1236     /
1237   ) {
1238     # some drivers barf on things they do not know about instead
1239     # of returning undef
1240     my $v = try { $self->_dbh_get_info($inf) };
1241     next unless defined $v;
1242
1243     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1244     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1245     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1246   }
1247
1248   $res;
1249 }
1250
1251 sub _determine_driver {
1252   my ($self) = @_;
1253
1254   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1255     my $started_connected = 0;
1256     local $self->{_in_determine_driver} = 1;
1257
1258     if (ref($self) eq __PACKAGE__) {
1259       my $driver;
1260       if ($self->_dbh) { # we are connected
1261         $driver = $self->_dbh->{Driver}{Name};
1262         $started_connected = 1;
1263       }
1264       else {
1265         $driver = $self->_extract_driver_from_connect_info;
1266       }
1267
1268       if ($driver) {
1269         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1270         if ($self->load_optional_class($storage_class)) {
1271           mro::set_mro($storage_class, 'c3');
1272           bless $self, $storage_class;
1273           $self->_rebless();
1274         }
1275         else {
1276           $self->_warn_undetermined_driver(
1277             'This version of DBIC does not yet seem to supply a driver for '
1278           . "your particular RDBMS and/or connection method ('$driver')."
1279           );
1280         }
1281       }
1282       else {
1283         $self->_warn_undetermined_driver(
1284           'Unable to extract a driver name from connect info - this '
1285         . 'should not have happened.'
1286         );
1287       }
1288     }
1289
1290     $self->_driver_determined(1);
1291
1292     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1293
1294     if ($self->can('source_bind_attributes')) {
1295       $self->throw_exception(
1296         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1297       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1298       . 'If you are not sure how to proceed please contact the development team via '
1299       . DBIx::Class::_ENV_::HELP_URL
1300       );
1301     }
1302
1303     $self->_init; # run driver-specific initializations
1304
1305     $self->_run_connection_actions
1306         if !$started_connected && defined $self->_dbh;
1307   }
1308 }
1309
1310 sub _extract_driver_from_connect_info {
1311   my $self = shift;
1312
1313   my $drv;
1314
1315   # if connect_info is a CODEREF, we have no choice but to connect
1316   if (
1317     ref $self->_dbi_connect_info->[0]
1318       and
1319     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1320   ) {
1321     $self->_populate_dbh;
1322     $drv = $self->_dbh->{Driver}{Name};
1323   }
1324   else {
1325     # try to use dsn to not require being connected, the driver may still
1326     # force a connection later in _rebless to determine version
1327     # (dsn may not be supplied at all if all we do is make a mock-schema)
1328     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1329     $drv ||= $ENV{DBI_DRIVER};
1330   }
1331
1332   return $drv;
1333 }
1334
1335 sub _determine_connector_driver {
1336   my ($self, $conn) = @_;
1337
1338   my $dbtype = $self->_get_rdbms_name;
1339
1340   if (not $dbtype) {
1341     $self->_warn_undetermined_driver(
1342       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1343     . "$conn connector - this should not have happened."
1344     );
1345     return;
1346   }
1347
1348   $dbtype =~ s/\W/_/gi;
1349
1350   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1351   return if $self->isa($subclass);
1352
1353   if ($self->load_optional_class($subclass)) {
1354     bless $self, $subclass;
1355     $self->_rebless;
1356   }
1357   else {
1358     $self->_warn_undetermined_driver(
1359       'This version of DBIC does not yet seem to supply a driver for '
1360     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1361     );
1362   }
1363 }
1364
1365 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1366
1367 sub _warn_undetermined_driver {
1368   my ($self, $msg) = @_;
1369
1370   require Data::Dumper::Concise;
1371
1372   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1373   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1374   . "does not go away, file a bugreport including the following info:\n"
1375   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1376   );
1377 }
1378
1379 sub _do_connection_actions {
1380   my ($self, $method_prefix, $call, @args) = @_;
1381
1382   try {
1383     if (not ref($call)) {
1384       my $method = $method_prefix . $call;
1385       $self->$method(@args);
1386     }
1387     elsif (ref($call) eq 'CODE') {
1388       $self->$call(@args);
1389     }
1390     elsif (ref($call) eq 'ARRAY') {
1391       if (ref($call->[0]) ne 'ARRAY') {
1392         $self->_do_connection_actions($method_prefix, $_) for @$call;
1393       }
1394       else {
1395         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1396       }
1397     }
1398     else {
1399       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1400     }
1401   }
1402   catch {
1403     if ( $method_prefix =~ /^connect/ ) {
1404       # this is an on_connect cycle - we can't just throw while leaving
1405       # a handle in an undefined state in our storage object
1406       # kill it with fire and rethrow
1407       $self->_dbh(undef);
1408       $self->throw_exception( $_[0] );
1409     }
1410     else {
1411       carp "Disconnect action failed: $_[0]";
1412     }
1413   };
1414
1415   return $self;
1416 }
1417
1418 sub connect_call_do_sql {
1419   my $self = shift;
1420   $self->_do_query(@_);
1421 }
1422
1423 sub disconnect_call_do_sql {
1424   my $self = shift;
1425   $self->_do_query(@_);
1426 }
1427
1428 =head2 connect_call_datetime_setup
1429
1430 A no-op stub method, provided so that one can always safely supply the
1431 L<connection option|/DBIx::Class specific connection attributes>
1432
1433  on_connect_call => 'datetime_setup'
1434
1435 This way one does not need to know in advance whether the underlying
1436 storage requires any sort of hand-holding when dealing with calendar
1437 data.
1438
1439 =cut
1440
1441 sub connect_call_datetime_setup { 1 }
1442
1443 sub _do_query {
1444   my ($self, $action) = @_;
1445
1446   if (ref $action eq 'CODE') {
1447     $action = $action->($self);
1448     $self->_do_query($_) foreach @$action;
1449   }
1450   else {
1451     # Most debuggers expect ($sql, @bind), so we need to exclude
1452     # the attribute hash which is the second argument to $dbh->do
1453     # furthermore the bind values are usually to be presented
1454     # as named arrayref pairs, so wrap those here too
1455     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1456     my $sql = shift @do_args;
1457     my $attrs = shift @do_args;
1458     my @bind = map { [ undef, $_ ] } @do_args;
1459
1460     $self->dbh_do(sub {
1461       $_[0]->_query_start($sql, \@bind);
1462       $_[1]->do($sql, $attrs, @do_args);
1463       $_[0]->_query_end($sql, \@bind);
1464     });
1465   }
1466
1467   return $self;
1468 }
1469
1470 sub _connect {
1471   my $self = shift;
1472
1473   my $info = $self->_dbi_connect_info;
1474
1475   $self->throw_exception("You did not provide any connection_info")
1476     unless defined $info->[0];
1477
1478   my ($old_connect_via, $dbh);
1479
1480   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1481
1482   # this odd anonymous coderef dereference is in fact really
1483   # necessary to avoid the unwanted effect described in perl5
1484   # RT#75792
1485   #
1486   # in addition the coderef itself can't reside inside the try{} block below
1487   # as it somehow triggers a leak under perl -d
1488   my $dbh_error_handler_installer = sub {
1489     weaken (my $weak_self = $_[0]);
1490
1491     # the coderef is blessed so we can distinguish it from externally
1492     # supplied handles (which must be preserved)
1493     $_[1]->{HandleError} = bless sub {
1494       if ($weak_self) {
1495         $weak_self->throw_exception("DBI Exception: $_[0]");
1496       }
1497       else {
1498         # the handler may be invoked by something totally out of
1499         # the scope of DBIC
1500         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1501       }
1502     }, '__DBIC__DBH__ERROR__HANDLER__';
1503   };
1504
1505   try {
1506     if(ref $info->[0] eq 'CODE') {
1507       $dbh = $info->[0]->();
1508     }
1509     else {
1510       require DBI;
1511       $dbh = DBI->connect(@$info);
1512     }
1513
1514     die $DBI::errstr unless $dbh;
1515
1516     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1517       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1518       . 'not continue',
1519       ref $info->[0] eq 'CODE'
1520         ? "Connection coderef $info->[0] returned a"
1521         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1522     ) unless $dbh->FETCH('Active');
1523
1524     # sanity checks unless asked otherwise
1525     unless ($self->unsafe) {
1526
1527       $self->throw_exception(
1528         'Refusing clobbering of {HandleError} installed on externally supplied '
1529        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1530       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1531
1532       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1533       # request, or an external handle. Complain and set anyway
1534       unless ($dbh->{RaiseError}) {
1535         carp( ref $info->[0] eq 'CODE'
1536
1537           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1538            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1539            .'attribute has been supplied'
1540
1541           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1542            .'unsafe => 1. Toggling RaiseError back to true'
1543         );
1544
1545         $dbh->{RaiseError} = 1;
1546       }
1547
1548       $dbh_error_handler_installer->($self, $dbh);
1549     }
1550   }
1551   catch {
1552     $self->throw_exception("DBI Connection failed: $_")
1553   };
1554
1555   $self->_dbh_autocommit($dbh->{AutoCommit});
1556   return $dbh;
1557 }
1558
1559 sub txn_begin {
1560   # this means we have not yet connected and do not know the AC status
1561   # (e.g. coderef $dbh), need a full-fledged connection check
1562   if (! defined $_[0]->_dbh_autocommit) {
1563     $_[0]->ensure_connected;
1564   }
1565   # Otherwise simply connect or re-connect on pid changes
1566   else {
1567     $_[0]->_get_dbh;
1568   }
1569
1570   shift->next::method(@_);
1571 }
1572
1573 sub _exec_txn_begin {
1574   my $self = shift;
1575
1576   # if the user is utilizing txn_do - good for him, otherwise we need to
1577   # ensure that the $dbh is healthy on BEGIN.
1578   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1579   # will be replaced by a failure of begin_work itself (which will be
1580   # then retried on reconnect)
1581   if ($self->{_in_do_block}) {
1582     $self->_dbh->begin_work;
1583   } else {
1584     $self->dbh_do(sub { $_[1]->begin_work });
1585   }
1586 }
1587
1588 sub txn_commit {
1589   my $self = shift;
1590
1591   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1592     unless $self->_seems_connected;
1593
1594   # esoteric case for folks using external $dbh handles
1595   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1596     carp "Storage transaction_depth 0 does not match "
1597         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1598     $self->transaction_depth(1);
1599   }
1600
1601   $self->next::method(@_);
1602
1603   # if AutoCommit is disabled txn_depth never goes to 0
1604   # as a new txn is started immediately on commit
1605   $self->transaction_depth(1) if (
1606     !$self->transaction_depth
1607       and
1608     defined $self->_dbh_autocommit
1609       and
1610     ! $self->_dbh_autocommit
1611   );
1612 }
1613
1614 sub _exec_txn_commit {
1615   shift->_dbh->commit;
1616 }
1617
1618 sub txn_rollback {
1619   my $self = shift;
1620
1621   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1622     unless $self->_seems_connected;
1623
1624   # esoteric case for folks using external $dbh handles
1625   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1626     carp "Storage transaction_depth 0 does not match "
1627         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1628     $self->transaction_depth(1);
1629   }
1630
1631   $self->next::method(@_);
1632
1633   # if AutoCommit is disabled txn_depth never goes to 0
1634   # as a new txn is started immediately on commit
1635   $self->transaction_depth(1) if (
1636     !$self->transaction_depth
1637       and
1638     defined $self->_dbh_autocommit
1639       and
1640     ! $self->_dbh_autocommit
1641   );
1642 }
1643
1644 sub _exec_txn_rollback {
1645   shift->_dbh->rollback;
1646 }
1647
1648 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1649 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1650   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1651     unless $_[0]->_seems_connected;
1652   shift->next::method(@_);
1653 EOS
1654
1655 # This used to be the top-half of _execute.  It was split out to make it
1656 #  easier to override in NoBindVars without duping the rest.  It takes up
1657 #  all of _execute's args, and emits $sql, @bind.
1658 sub _prep_for_execute {
1659   #my ($self, $op, $ident, $args) = @_;
1660   return shift->_gen_sql_bind(@_)
1661 }
1662
1663 sub _gen_sql_bind {
1664   my ($self, $op, $ident, $args) = @_;
1665
1666   my ($colinfos, $from);
1667   if ( blessed($ident) ) {
1668     $from = $ident->from;
1669     $colinfos = $ident->columns_info;
1670   }
1671
1672   my ($sql, $bind);
1673   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1674
1675   $bind = $self->_resolve_bindattrs(
1676     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1677   );
1678
1679   if (
1680     ! $ENV{DBIC_DT_SEARCH_OK}
1681       and
1682     $op eq 'select'
1683       and
1684     first {
1685       length ref $_->[1]
1686         and
1687       blessed($_->[1])
1688         and
1689       $_->[1]->isa('DateTime')
1690     } @$bind
1691   ) {
1692     carp_unique 'DateTime objects passed to search() are not supported '
1693       . 'properly (InflateColumn::DateTime formats and settings are not '
1694       . 'respected.) See ".. format a DateTime object for searching?" in '
1695       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1696       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1697   }
1698
1699   return( $sql, $bind );
1700 }
1701
1702 sub _resolve_bindattrs {
1703   my ($self, $ident, $bind, $colinfos) = @_;
1704
1705   my $resolve_bindinfo = sub {
1706     #my $infohash = shift;
1707
1708     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1709
1710     my $ret;
1711     if (my $col = $_[0]->{dbic_colname}) {
1712       $ret = { %{$_[0]} };
1713
1714       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1715         if $colinfos->{$col}{data_type};
1716
1717       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1718         if $colinfos->{$col}{size};
1719     }
1720
1721     $ret || $_[0];
1722   };
1723
1724   return [ map {
1725       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1726     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1727     : (ref $_->[0] eq 'HASH')           ? [(
1728                                             ! keys %{$_->[0]}
1729                                               or
1730                                             exists $_->[0]{dbd_attrs}
1731                                               or
1732                                             $_->[0]{sqlt_datatype}
1733                                            ) ? $_->[0]
1734                                              : $resolve_bindinfo->($_->[0])
1735                                            , $_->[1]
1736                                           ]
1737     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1738     :                                     [ $resolve_bindinfo->(
1739                                               { dbic_colname => $_->[0] }
1740                                             ), $_->[1] ]
1741   } @$bind ];
1742 }
1743
1744 sub _format_for_trace {
1745   #my ($self, $bind) = @_;
1746
1747   ### Turn @bind from something like this:
1748   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1749   ### to this:
1750   ###   ( "'1'", "'3'" )
1751
1752   map {
1753     defined( $_ && $_->[1] )
1754       ? qq{'$_->[1]'}
1755       : q{NULL}
1756   } @{$_[1] || []};
1757 }
1758
1759 sub _query_start {
1760   my ( $self, $sql, $bind ) = @_;
1761
1762   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1763     if $self->debug;
1764 }
1765
1766 sub _query_end {
1767   my ( $self, $sql, $bind ) = @_;
1768
1769   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1770     if $self->debug;
1771 }
1772
1773 sub _dbi_attrs_for_bind {
1774   #my ($self, $ident, $bind) = @_;
1775
1776   return [ map {
1777
1778     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1779
1780   : ! $_->{sqlt_datatype}   ? undef
1781
1782   :                           do {
1783
1784     # cache the result in the dbh_details hash, as it (usually) can not change
1785     # unless we connect to something else
1786     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1787     # the LOB storage
1788     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1789
1790     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1791       if ! exists $cache->{$_->{sqlt_datatype}};
1792
1793     $cache->{$_->{sqlt_datatype}};
1794
1795   } } map { $_->[0] } @{$_[2]} ];
1796 }
1797
1798 sub _execute {
1799   my ($self, $op, $ident, @args) = @_;
1800
1801   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1802
1803   # not even a PID check - we do not care about the state of the _dbh.
1804   # All we need is to get the appropriate drivers loaded if they aren't
1805   # already so that the assumption in ad7c50fc26e holds
1806   $self->_populate_dbh unless $self->_dbh;
1807
1808   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1809     $sql,
1810     $bind,
1811     $self->_dbi_attrs_for_bind($ident, $bind),
1812   );
1813 }
1814
1815 sub _dbh_execute {
1816   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1817
1818   $self->_query_start( $sql, $bind );
1819
1820   my $sth = $self->_bind_sth_params(
1821     $self->_prepare_sth($dbh, $sql),
1822     $bind,
1823     $bind_attrs,
1824   );
1825
1826   # Can this fail without throwing an exception anyways???
1827   my $rv = $sth->execute();
1828   $self->throw_exception(
1829     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1830   ) if !$rv;
1831
1832   $self->_query_end( $sql, $bind );
1833
1834   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1835 }
1836
1837 sub _prepare_sth {
1838   my ($self, $dbh, $sql) = @_;
1839
1840   # 3 is the if_active parameter which avoids active sth re-use
1841   my $sth = $self->disable_sth_caching
1842     ? $dbh->prepare($sql)
1843     : $dbh->prepare_cached($sql, {}, 3);
1844
1845   # XXX You would think RaiseError would make this impossible,
1846   #  but apparently that's not true :(
1847   $self->throw_exception(
1848     $dbh->errstr
1849       ||
1850     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1851             .'an exception and/or setting $dbh->errstr',
1852       length ($sql) > 20
1853         ? substr($sql, 0, 20) . '...'
1854         : $sql
1855       ,
1856       'DBD::' . $dbh->{Driver}{Name},
1857     )
1858   ) if !$sth;
1859
1860   $sth;
1861 }
1862
1863 sub _bind_sth_params {
1864   my ($self, $sth, $bind, $bind_attrs) = @_;
1865
1866   for my $i (0 .. $#$bind) {
1867     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1868       $sth->bind_param_inout(
1869         $i + 1, # bind params counts are 1-based
1870         $bind->[$i][1],
1871         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1872         $bind_attrs->[$i],
1873       );
1874     }
1875     else {
1876       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1877       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1878         ? "$bind->[$i][1]"
1879         : $bind->[$i][1]
1880       ;
1881
1882       $sth->bind_param(
1883         $i + 1,
1884         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1885         $v,
1886         $bind_attrs->[$i],
1887       );
1888     }
1889   }
1890
1891   $sth;
1892 }
1893
1894 sub _prefetch_autovalues {
1895   my ($self, $source, $colinfo, $to_insert) = @_;
1896
1897   my %values;
1898   for my $col (keys %$colinfo) {
1899     if (
1900       $colinfo->{$col}{auto_nextval}
1901         and
1902       (
1903         ! exists $to_insert->{$col}
1904           or
1905         is_literal_value($to_insert->{$col})
1906       )
1907     ) {
1908       $values{$col} = $self->_sequence_fetch(
1909         'NEXTVAL',
1910         ( $colinfo->{$col}{sequence} ||=
1911             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1912         ),
1913       );
1914     }
1915   }
1916
1917   \%values;
1918 }
1919
1920 sub insert {
1921   my ($self, $source, $to_insert) = @_;
1922
1923   my $col_infos = $source->columns_info;
1924
1925   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1926
1927   # fuse the values, but keep a separate list of prefetched_values so that
1928   # they can be fused once again with the final return
1929   $to_insert = { %$to_insert, %$prefetched_values };
1930
1931   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1932   # Investigate what does it take to s/defined/exists/
1933   my %pcols = map { $_ => 1 } $source->primary_columns;
1934   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1935   for my $col ($source->columns) {
1936     if ($col_infos->{$col}{is_auto_increment}) {
1937       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1938       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1939     }
1940
1941     # nothing to retrieve when explicit values are supplied
1942     next if (
1943       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1944     );
1945
1946     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1947     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1948       $pcols{$col}
1949         or
1950       $col_infos->{$col}{retrieve_on_insert}
1951     );
1952   };
1953
1954   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1955   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1956
1957   my ($sqla_opts, @ir_container);
1958   if (%retrieve_cols and $self->_use_insert_returning) {
1959     $sqla_opts->{returning_container} = \@ir_container
1960       if $self->_use_insert_returning_bound;
1961
1962     $sqla_opts->{returning} = [
1963       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1964     ];
1965   }
1966
1967   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1968
1969   my %returned_cols = %$to_insert;
1970   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1971     @ir_container = try {
1972       local $SIG{__WARN__} = sub {};
1973       my @r = $sth->fetchrow_array;
1974       $sth->finish;
1975       @r;
1976     } unless @ir_container;
1977
1978     @returned_cols{@$retlist} = @ir_container if @ir_container;
1979   }
1980   else {
1981     # pull in PK if needed and then everything else
1982     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1983
1984       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1985         unless $self->can('last_insert_id');
1986
1987       my @pri_values = $self->last_insert_id($source, @missing_pri);
1988
1989       $self->throw_exception( "Can't get last insert id" )
1990         unless (@pri_values == @missing_pri);
1991
1992       @returned_cols{@missing_pri} = @pri_values;
1993       delete @retrieve_cols{@missing_pri};
1994     }
1995
1996     # if there is more left to pull
1997     if (%retrieve_cols) {
1998       $self->throw_exception(
1999         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2000       ) unless %pcols;
2001
2002       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2003
2004       my $cur = DBIx::Class::ResultSet->new($source, {
2005         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2006         select => \@left_to_fetch,
2007       })->cursor;
2008
2009       @returned_cols{@left_to_fetch} = $cur->next;
2010
2011       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2012         if scalar $cur->next;
2013     }
2014   }
2015
2016   return { %$prefetched_values, %returned_cols };
2017 }
2018
2019 sub insert_bulk {
2020   carp_unique(
2021     'insert_bulk() should have never been exposed as a public method and '
2022   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2023   . 'use for this method please contact the development team via '
2024   . DBIx::Class::_ENV_::HELP_URL
2025   );
2026
2027   return '0E0' unless @{$_[3]||[]};
2028
2029   shift->_insert_bulk(@_);
2030 }
2031
2032 sub _insert_bulk {
2033   my ($self, $source, $cols, $data) = @_;
2034
2035   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2036     unless @{$data||[]};
2037
2038   my $colinfos = $source->columns_info($cols);
2039
2040   local $self->{_autoinc_supplied_for_op} =
2041     (grep { $_->{is_auto_increment} } values %$colinfos)
2042       ? 1
2043       : 0
2044   ;
2045
2046   # get a slice type index based on first row of data
2047   # a "column" in this context may refer to more than one bind value
2048   # e.g. \[ '?, ?', [...], [...] ]
2049   #
2050   # construct the value type index - a description of values types for every
2051   # per-column slice of $data:
2052   #
2053   # nonexistent - nonbind literal
2054   # 0 - regular value
2055   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2056   #
2057   # also construct the column hash to pass to the SQL generator. For plain
2058   # (non literal) values - convert the members of the first row into a
2059   # literal+bind combo, with extra positional info in the bind attr hashref.
2060   # This will allow us to match the order properly, and is so contrived
2061   # because a user-supplied literal/bind (or something else specific to a
2062   # resultsource and/or storage driver) can inject extra binds along the
2063   # way, so one can't rely on "shift positions" ordering at all. Also we
2064   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2065   # can be later matched up by address), because we want to supply a real
2066   # value on which perhaps e.g. datatype checks will be performed
2067   my ($proto_data, $serialized_bind_type_by_col_idx);
2068   for my $col_idx (0..$#$cols) {
2069     my $colname = $cols->[$col_idx];
2070     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2071       # no bind value at all - no type
2072
2073       $proto_data->{$colname} = $data->[0][$col_idx];
2074     }
2075     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2076       # repack, so we don't end up mangling the original \[]
2077       my ($sql, @bind) = @${$data->[0][$col_idx]};
2078
2079       # normalization of user supplied stuff
2080       my $resolved_bind = $self->_resolve_bindattrs(
2081         $source, \@bind, $colinfos,
2082       );
2083
2084       # store value-less (attrs only) bind info - we will be comparing all
2085       # supplied binds against this for sanity
2086       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2087
2088       $proto_data->{$colname} = \[ $sql, map { [
2089         # inject slice order to use for $proto_bind construction
2090           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2091             =>
2092           $resolved_bind->[$_][1]
2093         ] } (0 .. $#bind)
2094       ];
2095     }
2096     else {
2097       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2098
2099       $proto_data->{$colname} = \[ '?', [
2100         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2101           =>
2102         $data->[0][$col_idx]
2103       ] ];
2104     }
2105   }
2106
2107   my ($sql, $proto_bind) = $self->_prep_for_execute (
2108     'insert',
2109     $source,
2110     [ $proto_data ],
2111   );
2112
2113   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2114     # if the bindlist is empty and we had some dynamic binds, this means the
2115     # storage ate them away (e.g. the NoBindVars component) and interpolated
2116     # them directly into the SQL. This obviously can't be good for multi-inserts
2117     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2118   }
2119
2120   # sanity checks
2121   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2122   #
2123   # use an error reporting closure for convenience (less to pass)
2124   my $bad_slice_report_cref = sub {
2125     my ($msg, $r_idx, $c_idx) = @_;
2126     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2127       $msg,
2128       $cols->[$c_idx],
2129       do {
2130         require Data::Dumper::Concise;
2131         local $Data::Dumper::Maxdepth = 5;
2132         Data::Dumper::Concise::Dumper ({
2133           map { $cols->[$_] =>
2134             $data->[$r_idx][$_]
2135           } 0..$#$cols
2136         }),
2137       }
2138     );
2139   };
2140
2141   for my $col_idx (0..$#$cols) {
2142     my $reference_val = $data->[0][$col_idx];
2143
2144     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2145       my $val = $data->[$row_idx][$col_idx];
2146
2147       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2148         if (ref $val ne 'SCALAR') {
2149           $bad_slice_report_cref->(
2150             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2151             $row_idx,
2152             $col_idx,
2153           );
2154         }
2155         elsif ($$val ne $$reference_val) {
2156           $bad_slice_report_cref->(
2157             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2158             $row_idx,
2159             $col_idx,
2160           );
2161         }
2162       }
2163       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2164         if (is_literal_value($val)) {
2165           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2166         }
2167       }
2168       else {  # binds from a \[], compare type and attrs
2169         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2170           $bad_slice_report_cref->(
2171             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2172             $row_idx,
2173             $col_idx,
2174           );
2175         }
2176         # start drilling down and bail out early on identical refs
2177         elsif (
2178           $reference_val != $val
2179             or
2180           $$reference_val != $$val
2181         ) {
2182           if (${$val}->[0] ne ${$reference_val}->[0]) {
2183             $bad_slice_report_cref->(
2184               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2185               $row_idx,
2186               $col_idx,
2187             );
2188           }
2189           # need to check the bind attrs - a bind will happen only once for
2190           # the entire dataset, so any changes further down will be ignored.
2191           elsif (
2192             $serialized_bind_type_by_col_idx->{$col_idx}
2193               ne
2194             serialize [
2195               map
2196               { $_->[0] }
2197               @{$self->_resolve_bindattrs(
2198                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2199               )}
2200             ]
2201           ) {
2202             $bad_slice_report_cref->(
2203               'Differing bind attributes on literal/bind values not supported',
2204               $row_idx,
2205               $col_idx,
2206             );
2207           }
2208         }
2209       }
2210     }
2211   }
2212
2213   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2214   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2215   # scope guard
2216   my $guard = $self->txn_scope_guard;
2217
2218   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2219   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2220   my $rv = do {
2221     if (@$proto_bind) {
2222       # proto bind contains the information on which pieces of $data to pull
2223       # $cols is passed in only for prettier error-reporting
2224       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2225     }
2226     else {
2227       # bind_param_array doesn't work if there are no binds
2228       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2229     }
2230   };
2231
2232   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2233
2234   $guard->commit;
2235
2236   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2237 }
2238
2239 # execute_for_fetch is capable of returning data just fine (it means it
2240 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2241 # is the void-populate fast-path we will just ignore this altogether
2242 # for the time being.
2243 sub _dbh_execute_for_fetch {
2244   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2245
2246   # If we have any bind attributes to take care of, we will bind the
2247   # proto-bind data (which will never be used by execute_for_fetch)
2248   # However since column bindtypes are "sticky", this is sufficient
2249   # to get the DBD to apply the bindtype to all values later on
2250   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2251
2252   for my $i (0 .. $#$proto_bind) {
2253     $sth->bind_param (
2254       $i+1, # DBI bind indexes are 1-based
2255       $proto_bind->[$i][1],
2256       $bind_attrs->[$i],
2257     ) if defined $bind_attrs->[$i];
2258   }
2259
2260   # At this point $data slots named in the _bind_data_slice_idx of
2261   # each piece of $proto_bind are either \[]s or plain values to be
2262   # passed in. Construct the dispensing coderef. *NOTE* the order
2263   # of $data will differ from this of the ?s in the SQL (due to
2264   # alphabetical ordering by colname). We actually do want to
2265   # preserve this behavior so that prepare_cached has a better
2266   # chance of matching on unrelated calls
2267
2268   my $fetch_row_idx = -1; # saner loop this way
2269   my $fetch_tuple = sub {
2270     return undef if ++$fetch_row_idx > $#$data;
2271
2272     return [ map {
2273       my $v = ! defined $_->{_literal_bind_subindex}
2274
2275         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2276
2277         # There are no attributes to resolve here - we already did everything
2278         # when we constructed proto_bind. However we still want to sanity-check
2279         # what the user supplied, so pass stuff through to the resolver *anyway*
2280         : $self->_resolve_bindattrs (
2281             undef,  # a fake rsrc
2282             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2283             {},     # a fake column_info bag
2284           )->[0][1]
2285       ;
2286
2287       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2288       # For the time being forcibly stringify whatever is stringifiable
2289       my $vref;
2290
2291       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2292     : defined blessed( $$vref )                             ? "$$vref"
2293                                                             : $$vref
2294     ;
2295     } map { $_->[0] } @$proto_bind ];
2296   };
2297
2298   my $tuple_status = [];
2299   my ($rv, $err);
2300   try {
2301     $rv = $sth->execute_for_fetch(
2302       $fetch_tuple,
2303       $tuple_status,
2304     );
2305   }
2306   catch {
2307     $err = shift;
2308   };
2309
2310   # Not all DBDs are create equal. Some throw on error, some return
2311   # an undef $rv, and some set $sth->err - try whatever we can
2312   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2313     ! defined $err
2314       and
2315     ( !defined $rv or $sth->err )
2316   );
2317
2318   # Statement must finish even if there was an exception.
2319   try {
2320     $sth->finish
2321   }
2322   catch {
2323     $err = shift unless defined $err
2324   };
2325
2326   if (defined $err) {
2327     my $i = 0;
2328     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2329
2330     $self->throw_exception("Unexpected populate error: $err")
2331       if ($i > $#$tuple_status);
2332
2333     require Data::Dumper::Concise;
2334     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2335       ($tuple_status->[$i][1] || $err),
2336       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2337     );
2338   }
2339
2340   return $rv;
2341 }
2342
2343 sub _dbh_execute_inserts_with_no_binds {
2344   my ($self, $sth, $count) = @_;
2345
2346   my $err;
2347   try {
2348     my $dbh = $self->_get_dbh;
2349     local $dbh->{RaiseError} = 1;
2350     local $dbh->{PrintError} = 0;
2351
2352     $sth->execute foreach 1..$count;
2353   }
2354   catch {
2355     $err = shift;
2356   };
2357
2358   # Make sure statement is finished even if there was an exception.
2359   try {
2360     $sth->finish
2361   }
2362   catch {
2363     $err = shift unless defined $err;
2364   };
2365
2366   $self->throw_exception($err) if defined $err;
2367
2368   return $count;
2369 }
2370
2371 sub update {
2372   #my ($self, $source, @args) = @_;
2373   shift->_execute('update', @_);
2374 }
2375
2376
2377 sub delete {
2378   #my ($self, $source, @args) = @_;
2379   shift->_execute('delete', @_);
2380 }
2381
2382 sub _select {
2383   my $self = shift;
2384   $self->_execute($self->_select_args(@_));
2385 }
2386
2387 sub _select_args_to_query {
2388   my $self = shift;
2389
2390   $self->throw_exception(
2391     "Unable to generate limited query representation with 'software_limit' enabled"
2392   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2393
2394   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2395   #  = $self->_select_args($ident, $select, $cond, $attrs);
2396   my ($op, $ident, @args) =
2397     $self->_select_args(@_);
2398
2399   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2400   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2401
2402   # reuse the bind arrayref
2403   unshift @{$bind}, "($sql)";
2404   \$bind;
2405 }
2406
2407 sub _select_args {
2408   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2409
2410   # FIXME - that kind of caching would be nice to have
2411   # however currently we *may* pass the same $orig_attrs
2412   # with different ident/select/where
2413   # the whole interface needs to be rethought, since it
2414   # was centered around the flawed SQLA API. We can do
2415   # soooooo much better now. But that is also another
2416   # battle...
2417   #return (
2418   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2419   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2420
2421   my $sql_maker = $self->sql_maker;
2422
2423   my $attrs = {
2424     %$orig_attrs,
2425     select => $select,
2426     from => $ident,
2427     where => $where,
2428   };
2429
2430   # Sanity check the attributes (SQLMaker does it too, but
2431   # in case of a software_limit we'll never reach there)
2432   if (defined $attrs->{offset}) {
2433     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2434       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2435   }
2436
2437   if (defined $attrs->{rows}) {
2438     $self->throw_exception("The rows attribute must be a positive integer if present")
2439       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2440   }
2441   elsif ($attrs->{offset}) {
2442     # MySQL actually recommends this approach.  I cringe.
2443     $attrs->{rows} = $sql_maker->__max_int;
2444   }
2445
2446   # see if we will need to tear the prefetch apart to satisfy group_by == select
2447   # this is *extremely tricky* to get right, I am still not sure I did
2448   #
2449   my ($prefetch_needs_subquery, @limit_args);
2450
2451   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2452     # we already know there is a valid group_by (we made it) and we know it is
2453     # intended to be based *only* on non-multi stuff
2454     # short circuit the group_by parsing below
2455     $prefetch_needs_subquery = 1;
2456   }
2457   elsif (
2458     # The rationale is that even if we do *not* have collapse, we still
2459     # need to wrap the core grouped select/group_by in a subquery
2460     # so that databases that care about group_by/select equivalence
2461     # are happy (this includes MySQL in strict_mode)
2462     # If any of the other joined tables are referenced in the group_by
2463     # however - the user is on their own
2464     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2465       and
2466     $attrs->{group_by}
2467       and
2468     @{$attrs->{group_by}}
2469       and
2470     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2471       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2472     }
2473   ) {
2474     # no aliases other than our own in group_by
2475     # if there are - do not allow subquery even if limit is present
2476     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2477   }
2478   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2479     # active collapse with a limit - that one is a no-brainer unless
2480     # overruled by a group_by above
2481     $prefetch_needs_subquery = 1;
2482   }
2483
2484   if ($prefetch_needs_subquery) {
2485     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2486   }
2487   elsif (! $attrs->{software_limit} ) {
2488     push @limit_args, (
2489       $attrs->{rows} || (),
2490       $attrs->{offset} || (),
2491     );
2492   }
2493
2494   # try to simplify the joinmap further (prune unreferenced type-single joins)
2495   if (
2496     ! $prefetch_needs_subquery  # already pruned
2497       and
2498     ref $attrs->{from}
2499       and
2500     reftype $attrs->{from} eq 'ARRAY'
2501       and
2502     @{$attrs->{from}} != 1
2503   ) {
2504     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2505   }
2506
2507   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2508   # during the result inflation stage we *need* to know what was the aliastype
2509   # map as sqla saw it when the final pieces of SQL were being assembled
2510   # Originally we simply carried around the entirety of $attrs, but this
2511   # resulted in resultsets that are being reused growing continuously, as
2512   # the hash in question grew deeper and deeper.
2513   # Instead hand-pick what to take with us here (we actually don't need much
2514   # at this point just the map itself)
2515   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2516
2517 ###
2518   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2519   #
2520   # This would be the point to deflate anything found in $attrs->{where}
2521   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2522   # expect a result object. And all we have is a resultsource (it is trivial
2523   # to extract deflator coderefs via $alias2source above).
2524   #
2525   # I don't see a way forward other than changing the way deflators are
2526   # invoked, and that's just bad...
2527 ###
2528
2529   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2530 }
2531
2532 # Returns a counting SELECT for a simple count
2533 # query. Abstracted so that a storage could override
2534 # this to { count => 'firstcol' } or whatever makes
2535 # sense as a performance optimization
2536 sub _count_select {
2537   #my ($self, $source, $rs_attrs) = @_;
2538   return { count => '*' };
2539 }
2540
2541 =head2 select
2542
2543 =over 4
2544
2545 =item Arguments: $ident, $select, $condition, $attrs
2546
2547 =back
2548
2549 Handle a SQL select statement.
2550
2551 =cut
2552
2553 sub select {
2554   my $self = shift;
2555   my ($ident, $select, $condition, $attrs) = @_;
2556   return $self->cursor_class->new($self, \@_, $attrs);
2557 }
2558
2559 sub select_single {
2560   my $self = shift;
2561   my ($rv, $sth, @bind) = $self->_select(@_);
2562   my @row = $sth->fetchrow_array;
2563   my @nextrow = $sth->fetchrow_array if @row;
2564   if(@row && @nextrow) {
2565     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2566   }
2567   # Need to call finish() to work round broken DBDs
2568   $sth->finish();
2569   return @row;
2570 }
2571
2572 =head2 sql_limit_dialect
2573
2574 This is an accessor for the default SQL limit dialect used by a particular
2575 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2576 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2577 see L<DBIx::Class::SQLMaker::LimitDialects>.
2578
2579 =cut
2580
2581 sub _dbh_columns_info_for {
2582   my ($self, $dbh, $table) = @_;
2583
2584   my %result;
2585
2586   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2587     try {
2588       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2589       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2590       $sth->execute();
2591       while ( my $info = $sth->fetchrow_hashref() ){
2592         my %column_info;
2593         $column_info{data_type}   = $info->{TYPE_NAME};
2594         $column_info{size}      = $info->{COLUMN_SIZE};
2595         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2596         $column_info{default_value} = $info->{COLUMN_DEF};
2597         my $col_name = $info->{COLUMN_NAME};
2598         $col_name =~ s/^\"(.*)\"$/$1/;
2599
2600         $result{$col_name} = \%column_info;
2601       }
2602     } catch {
2603       %result = ();
2604     };
2605
2606     return \%result if keys %result;
2607   }
2608
2609   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2610   $sth->execute;
2611
2612 ### The acrobatics with lc names is necessary to support both the legacy
2613 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2614 ### with column names differing in cas eonly (thanks pg!)
2615
2616   my ($columns, $seen_lcs);
2617
2618   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2619     idx => scalar keys %$columns,
2620     name => $_,
2621     lc_name => lc($_),
2622   } for @{$sth->{NAME}};
2623
2624   $seen_lcs->{$_->{lc_name}} == 1
2625     and
2626   $_->{name} = $_->{lc_name}
2627     for values %$columns;
2628
2629   for ( values %$columns ) {
2630     my $inf = {
2631       data_type => $sth->{TYPE}->[$_->{idx}],
2632       size => $sth->{PRECISION}->[$_->{idx}],
2633       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2634     };
2635
2636     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2637       @{$inf}{qw( data_type  size)} = ($1, $2);
2638     }
2639
2640     $result{$_->{name}} = $inf;
2641   }
2642
2643   $sth->finish;
2644
2645   if ($dbh->can('type_info')) {
2646     for my $inf (values %result) {
2647       next if ! defined $inf->{data_type};
2648
2649       $inf->{data_type} = (
2650         (
2651           (
2652             $dbh->type_info( $inf->{data_type} )
2653               ||
2654             next
2655           )
2656             ||
2657           next
2658         )->{TYPE_NAME}
2659           ||
2660         next
2661       );
2662
2663       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2664       # needs more testing in the future...
2665       $inf->{size} -= 4 if (
2666         ( $inf->{size}||0 > 4 )
2667           and
2668         $inf->{data_type} =~ qr/^text$/i
2669       );
2670     }
2671
2672   }
2673
2674   return \%result;
2675 }
2676
2677 sub columns_info_for {
2678   my ($self, $table) = @_;
2679   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2680 }
2681
2682 =head2 last_insert_id
2683
2684 Return the row id of the last insert.
2685
2686 =cut
2687
2688 sub _dbh_last_insert_id {
2689     my ($self, $dbh, $source, $col) = @_;
2690
2691     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2692
2693     return $id if defined $id;
2694
2695     my $class = ref $self;
2696     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2697 }
2698
2699 sub last_insert_id {
2700   my $self = shift;
2701   $self->_dbh_last_insert_id ($self->_dbh, @_);
2702 }
2703
2704 =head2 _native_data_type
2705
2706 =over 4
2707
2708 =item Arguments: $type_name
2709
2710 =back
2711
2712 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2713 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2714 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2715
2716 The default implementation returns C<undef>, implement in your Storage driver if
2717 you need this functionality.
2718
2719 Should map types from other databases to the native RDBMS type, for example
2720 C<VARCHAR2> to C<VARCHAR>.
2721
2722 Types with modifiers should map to the underlying data type. For example,
2723 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2724
2725 Composite types should map to the container type, for example
2726 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2727
2728 =cut
2729
2730 sub _native_data_type {
2731   #my ($self, $data_type) = @_;
2732   return undef
2733 }
2734
2735 # Check if placeholders are supported at all
2736 sub _determine_supports_placeholders {
2737   my $self = shift;
2738   my $dbh  = $self->_get_dbh;
2739
2740   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2741   # but it is inaccurate more often than not
2742   return try {
2743     local $dbh->{PrintError} = 0;
2744     local $dbh->{RaiseError} = 1;
2745     $dbh->do('select ?', {}, 1);
2746     1;
2747   }
2748   catch {
2749     0;
2750   };
2751 }
2752
2753 # Check if placeholders bound to non-string types throw exceptions
2754 #
2755 sub _determine_supports_typeless_placeholders {
2756   my $self = shift;
2757   my $dbh  = $self->_get_dbh;
2758
2759   return try {
2760     local $dbh->{PrintError} = 0;
2761     local $dbh->{RaiseError} = 1;
2762     # this specifically tests a bind that is NOT a string
2763     $dbh->do('select 1 where 1 = ?', {}, 1);
2764     1;
2765   }
2766   catch {
2767     0;
2768   };
2769 }
2770
2771 =head2 sqlt_type
2772
2773 Returns the database driver name.
2774
2775 =cut
2776
2777 sub sqlt_type {
2778   shift->_get_dbh->{Driver}->{Name};
2779 }
2780
2781 =head2 bind_attribute_by_data_type
2782
2783 Given a datatype from column info, returns a database specific bind
2784 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2785 let the database planner just handle it.
2786
2787 This method is always called after the driver has been determined and a DBI
2788 connection has been established. Therefore you can refer to C<DBI::$constant>
2789 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2790 the correct modules.
2791
2792 =cut
2793
2794 sub bind_attribute_by_data_type {
2795     return;
2796 }
2797
2798 =head2 is_datatype_numeric
2799
2800 Given a datatype from column_info, returns a boolean value indicating if
2801 the current RDBMS considers it a numeric value. This controls how
2802 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2803 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2804 be performed instead of the usual C<eq>.
2805
2806 =cut
2807
2808 sub is_datatype_numeric {
2809   #my ($self, $dt) = @_;
2810
2811   return 0 unless $_[1];
2812
2813   $_[1] =~ /^ (?:
2814     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2815   ) $/ix;
2816 }
2817
2818
2819 =head2 create_ddl_dir
2820
2821 =over 4
2822
2823 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2824
2825 =back
2826
2827 Creates a SQL file based on the Schema, for each of the specified
2828 database engines in C<\@databases> in the given directory.
2829 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2830
2831 Given a previous version number, this will also create a file containing
2832 the ALTER TABLE statements to transform the previous schema into the
2833 current one. Note that these statements may contain C<DROP TABLE> or
2834 C<DROP COLUMN> statements that can potentially destroy data.
2835
2836 The file names are created using the C<ddl_filename> method below, please
2837 override this method in your schema if you would like a different file
2838 name format. For the ALTER file, the same format is used, replacing
2839 $version in the name with "$preversion-$version".
2840
2841 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2842 The most common value for this would be C<< { add_drop_table => 1 } >>
2843 to have the SQL produced include a C<DROP TABLE> statement for each table
2844 created. For quoting purposes supply C<quote_identifiers>.
2845
2846 If no arguments are passed, then the following default values are assumed:
2847
2848 =over 4
2849
2850 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2851
2852 =item version    - $schema->schema_version
2853
2854 =item directory  - './'
2855
2856 =item preversion - <none>
2857
2858 =back
2859
2860 By default, C<\%sqlt_args> will have
2861
2862  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2863
2864 merged with the hash passed in. To disable any of those features, pass in a
2865 hashref like the following
2866
2867  { ignore_constraint_names => 0, # ... other options }
2868
2869
2870 WARNING: You are strongly advised to check all SQL files created, before applying
2871 them.
2872
2873 =cut
2874
2875 sub create_ddl_dir {
2876   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2877
2878   unless ($dir) {
2879     carp "No directory given, using ./\n";
2880     $dir = './';
2881   } else {
2882       -d $dir
2883         or
2884       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2885         or
2886       $self->throw_exception(
2887         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2888       );
2889   }
2890
2891   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2892
2893   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2894   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2895
2896   my $schema_version = $schema->schema_version || '1.x';
2897   $version ||= $schema_version;
2898
2899   $sqltargs = {
2900     add_drop_table => 1,
2901     ignore_constraint_names => 1,
2902     ignore_index_names => 1,
2903     quote_identifiers => $self->sql_maker->_quoting_enabled,
2904     %{$sqltargs || {}}
2905   };
2906
2907   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2908     $self->throw_exception("Can't create a ddl file without $missing");
2909   }
2910
2911   my $sqlt = SQL::Translator->new( $sqltargs );
2912
2913   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2914   my $sqlt_schema = $sqlt->translate({ data => $schema })
2915     or $self->throw_exception ($sqlt->error);
2916
2917   foreach my $db (@$databases) {
2918     $sqlt->reset();
2919     $sqlt->{schema} = $sqlt_schema;
2920     $sqlt->producer($db);
2921
2922     my $file;
2923     my $filename = $schema->ddl_filename($db, $version, $dir);
2924     if (-e $filename && ($version eq $schema_version )) {
2925       # if we are dumping the current version, overwrite the DDL
2926       carp "Overwriting existing DDL file - $filename";
2927       unlink($filename);
2928     }
2929
2930     my $output = $sqlt->translate;
2931     if(!$output) {
2932       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2933       next;
2934     }
2935     if(!open($file, ">$filename")) {
2936       $self->throw_exception("Can't open $filename for writing ($!)");
2937       next;
2938     }
2939     print $file $output;
2940     close($file);
2941
2942     next unless ($preversion);
2943
2944     require SQL::Translator::Diff;
2945
2946     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2947     if(!-e $prefilename) {
2948       carp("No previous schema file found ($prefilename)");
2949       next;
2950     }
2951
2952     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2953     if(-e $difffile) {
2954       carp("Overwriting existing diff file - $difffile");
2955       unlink($difffile);
2956     }
2957
2958     my $source_schema;
2959     {
2960       my $t = SQL::Translator->new($sqltargs);
2961       $t->debug( 0 );
2962       $t->trace( 0 );
2963
2964       $t->parser( $db )
2965         or $self->throw_exception ($t->error);
2966
2967       my $out = $t->translate( $prefilename )
2968         or $self->throw_exception ($t->error);
2969
2970       $source_schema = $t->schema;
2971
2972       $source_schema->name( $prefilename )
2973         unless ( $source_schema->name );
2974     }
2975
2976     # The "new" style of producers have sane normalization and can support
2977     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2978     # And we have to diff parsed SQL against parsed SQL.
2979     my $dest_schema = $sqlt_schema;
2980
2981     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2982       my $t = SQL::Translator->new($sqltargs);
2983       $t->debug( 0 );
2984       $t->trace( 0 );
2985
2986       $t->parser( $db )
2987         or $self->throw_exception ($t->error);
2988
2989       my $out = $t->translate( $filename )
2990         or $self->throw_exception ($t->error);
2991
2992       $dest_schema = $t->schema;
2993
2994       $dest_schema->name( $filename )
2995         unless $dest_schema->name;
2996     }
2997
2998     my $diff = do {
2999       # FIXME - this is a terrible workaround for
3000       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3001       # Fixing it in this sloppy manner so that we don't hve to
3002       # lockstep an SQLT release as well. Needs to be removed at
3003       # some point, and SQLT dep bumped
3004       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3005         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3006
3007       SQL::Translator::Diff::schema_diff($source_schema, $db,
3008                                          $dest_schema,   $db,
3009                                          $sqltargs
3010                                        );
3011     };
3012
3013     if(!open $file, ">$difffile") {
3014       $self->throw_exception("Can't write to $difffile ($!)");
3015       next;
3016     }
3017     print $file $diff;
3018     close($file);
3019   }
3020 }
3021
3022 =head2 deployment_statements
3023
3024 =over 4
3025
3026 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3027
3028 =back
3029
3030 Returns the statements used by L<DBIx::Class::Storage/deploy>
3031 and L<DBIx::Class::Schema/deploy>.
3032
3033 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3034 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3035
3036 C<$directory> is used to return statements from files in a previously created
3037 L</create_ddl_dir> directory and is optional. The filenames are constructed
3038 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3039
3040 If no C<$directory> is specified then the statements are constructed on the
3041 fly using L<SQL::Translator> and C<$version> is ignored.
3042
3043 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3044
3045 =cut
3046
3047 sub deployment_statements {
3048   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3049   $type ||= $self->sqlt_type;
3050   $version ||= $schema->schema_version || '1.x';
3051   $dir ||= './';
3052   my $filename = $schema->ddl_filename($type, $version, $dir);
3053   if(-f $filename)
3054   {
3055       # FIXME replace this block when a proper sane sql parser is available
3056       my $file;
3057       open($file, "<$filename")
3058         or $self->throw_exception("Can't open $filename ($!)");
3059       my @rows = <$file>;
3060       close($file);
3061       return join('', @rows);
3062   }
3063
3064   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3065     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3066   }
3067
3068   # sources needs to be a parser arg, but for simplicity allow at top level
3069   # coming in
3070   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3071       if exists $sqltargs->{sources};
3072
3073   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3074     unless exists $sqltargs->{quote_identifiers};
3075
3076   my $tr = SQL::Translator->new(
3077     producer => "SQL::Translator::Producer::${type}",
3078     %$sqltargs,
3079     parser => 'SQL::Translator::Parser::DBIx::Class',
3080     data => $schema,
3081   );
3082
3083   return preserve_context {
3084     $tr->translate
3085   } after => sub {
3086     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3087       unless defined $_[0];
3088   };
3089 }
3090
3091 # FIXME deploy() currently does not accurately report sql errors
3092 # Will always return true while errors are warned
3093 sub deploy {
3094   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3095   my $deploy = sub {
3096     my $line = shift;
3097     return if(!$line);
3098     return if($line =~ /^--/);
3099     # next if($line =~ /^DROP/m);
3100     return if($line =~ /^BEGIN TRANSACTION/m);
3101     return if($line =~ /^COMMIT/m);
3102     return if $line =~ /^\s+$/; # skip whitespace only
3103     $self->_query_start($line);
3104     try {
3105       # do a dbh_do cycle here, as we need some error checking in
3106       # place (even though we will ignore errors)
3107       $self->dbh_do (sub { $_[1]->do($line) });
3108     } catch {
3109       carp qq{$_ (running "${line}")};
3110     };
3111     $self->_query_end($line);
3112   };
3113   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3114   if (@statements > 1) {
3115     foreach my $statement (@statements) {
3116       $deploy->( $statement );
3117     }
3118   }
3119   elsif (@statements == 1) {
3120     # split on single line comments and end of statements
3121     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3122       $deploy->( $line );
3123     }
3124   }
3125 }
3126
3127 =head2 datetime_parser
3128
3129 Returns the datetime parser class
3130
3131 =cut
3132
3133 sub datetime_parser {
3134   my $self = shift;
3135   return $self->{datetime_parser} ||= do {
3136     $self->build_datetime_parser(@_);
3137   };
3138 }
3139
3140 =head2 datetime_parser_type
3141
3142 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3143
3144 =head2 build_datetime_parser
3145
3146 See L</datetime_parser>
3147
3148 =cut
3149
3150 sub build_datetime_parser {
3151   my $self = shift;
3152   my $type = $self->datetime_parser_type(@_);
3153   return $type;
3154 }
3155
3156
3157 =head2 is_replicating
3158
3159 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3160 replicate from a master database.  Default is undef, which is the result
3161 returned by databases that don't support replication.
3162
3163 =cut
3164
3165 sub is_replicating {
3166     return;
3167
3168 }
3169
3170 =head2 lag_behind_master
3171
3172 Returns a number that represents a certain amount of lag behind a master db
3173 when a given storage is replicating.  The number is database dependent, but
3174 starts at zero and increases with the amount of lag. Default in undef
3175
3176 =cut
3177
3178 sub lag_behind_master {
3179     return;
3180 }
3181
3182 =head2 relname_to_table_alias
3183
3184 =over 4
3185
3186 =item Arguments: $relname, $join_count
3187
3188 =item Return Value: $alias
3189
3190 =back
3191
3192 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3193 queries.
3194
3195 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3196 way these aliases are named.
3197
3198 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3199 otherwise C<"$relname">.
3200
3201 =cut
3202
3203 sub relname_to_table_alias {
3204   my ($self, $relname, $join_count) = @_;
3205
3206   my $alias = ($join_count && $join_count > 1 ?
3207     join('_', $relname, $join_count) : $relname);
3208
3209   return $alias;
3210 }
3211
3212 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3213 # version and it may be necessary to amend or override it for a specific storage
3214 # if such binds are necessary.
3215 sub _max_column_bytesize {
3216   my ($self, $attr) = @_;
3217
3218   my $max_size;
3219
3220   if ($attr->{sqlt_datatype}) {
3221     my $data_type = lc($attr->{sqlt_datatype});
3222
3223     if ($attr->{sqlt_size}) {
3224
3225       # String/sized-binary types
3226       if ($data_type =~ /^(?:
3227           l? (?:var)? char(?:acter)? (?:\s*varying)?
3228             |
3229           (?:var)? binary (?:\s*varying)?
3230             |
3231           raw
3232         )\b/x
3233       ) {
3234         $max_size = $attr->{sqlt_size};
3235       }
3236       # Other charset/unicode types, assume scale of 4
3237       elsif ($data_type =~ /^(?:
3238           national \s* character (?:\s*varying)?
3239             |
3240           nchar
3241             |
3242           univarchar
3243             |
3244           nvarchar
3245         )\b/x
3246       ) {
3247         $max_size = $attr->{sqlt_size} * 4;
3248       }
3249     }
3250
3251     if (!$max_size and !$self->_is_lob_type($data_type)) {
3252       $max_size = 100 # for all other (numeric?) datatypes
3253     }
3254   }
3255
3256   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3257 }
3258
3259 # Determine if a data_type is some type of BLOB
3260 sub _is_lob_type {
3261   my ($self, $data_type) = @_;
3262   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3263     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3264                                   |varchar|character\s*varying|nvarchar
3265                                   |national\s*character\s*varying))?\z/xi);
3266 }
3267
3268 sub _is_binary_lob_type {
3269   my ($self, $data_type) = @_;
3270   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3271     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3272 }
3273
3274 sub _is_text_lob_type {
3275   my ($self, $data_type) = @_;
3276   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3277     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3278                         |national\s*character\s*varying))\z/xi);
3279 }
3280
3281 # Determine if a data_type is some type of a binary type
3282 sub _is_binary_type {
3283   my ($self, $data_type) = @_;
3284   $data_type && ($self->_is_binary_lob_type($data_type)
3285     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3286 }
3287
3288 1;
3289
3290 =head1 USAGE NOTES
3291
3292 =head2 DBIx::Class and AutoCommit
3293
3294 DBIx::Class can do some wonderful magic with handling exceptions,
3295 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3296 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3297 transaction support.
3298
3299 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3300 in an assumed transaction between commits, and you're telling us you'd
3301 like to manage that manually.  A lot of the magic protections offered by
3302 this module will go away.  We can't protect you from exceptions due to database
3303 disconnects because we don't know anything about how to restart your
3304 transactions.  You're on your own for handling all sorts of exceptional
3305 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3306 be with raw DBI.
3307
3308 =head1 FURTHER QUESTIONS?
3309
3310 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3311
3312 =head1 COPYRIGHT AND LICENSE
3313
3314 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3315 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3316 redistribute it and/or modify it under the same terms as the
3317 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.