lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8 use IO::File;
   9
  10 BEGIN {
  11
  12 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  13
  14 use base qw/SQL::Abstract::Limit/;
  15
  16 sub select {
  17   my ($self, $table, $fields, $where, $order, @rest) = @_;
  18   @rest = (-1) unless defined $rest[0];
  19   $self->SUPER::select($table, $self->_recurse_fields($fields),
  20                          $where, $order, @rest);
  21 }
  22
  23 sub _emulate_limit {
  24   my $self = shift;
  25   if ($_[3] == -1) {
  26     return $_[1].$self->_order_by($_[2]);
  27   } else {
  28     return $self->SUPER::_emulate_limit(@_);
  29   }
  30 }
  31
  32 sub _recurse_fields {
  33   my ($self, $fields) = @_;
  34   my $ref = ref $fields;
  35   return $self->_quote($fields) unless $ref;
  36   return $$fields if $ref eq 'SCALAR';
  37
  38   if ($ref eq 'ARRAY') {
  39     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  40   } elsif ($ref eq 'HASH') {
  41     foreach my $func (keys %$fields) {
  42       return $self->_sqlcase($func)
  43         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  44     }
  45   }
  46 }
  47
  48 sub _order_by {
  49   my $self = shift;
  50   my $ret = '';
  51   if (ref $_[0] eq 'HASH') {
  52     if (defined $_[0]->{group_by}) {
  53       $ret = $self->_sqlcase(' group by ')
  54                .$self->_recurse_fields($_[0]->{group_by});
  55     }
  56     if (defined $_[0]->{order_by}) {
  57       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  58     }
  59   } else {
  60     $ret = $self->SUPER::_order_by(@_);
  61   }
  62   return $ret;
  63 }
  64
  65 sub _table {
  66   my ($self, $from) = @_;
  67   if (ref $from eq 'ARRAY') {
  68     return $self->_recurse_from(@$from);
  69   } elsif (ref $from eq 'HASH') {
  70     return $self->_make_as($from);
  71   } else {
  72     return $from;
  73   }
  74 }
  75
  76 sub _recurse_from {
  77   my ($self, $from, @join) = @_;
  78   my @sqlf;
  79   push(@sqlf, $self->_make_as($from));
  80   foreach my $j (@join) {
  81     my ($to, $on) = @$j;
  82
  83     # check whether a join type exists
  84     my $join_clause = '';
  85     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
  86       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
  87     } else {
  88       $join_clause = ' JOIN ';
  89     }
  90     push(@sqlf, $join_clause);
  91
  92     if (ref $to eq 'ARRAY') {
  93       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
  94     } else {
  95       push(@sqlf, $self->_make_as($to));
  96     }
  97     push(@sqlf, ' ON ', $self->_join_condition($on));
  98   }
  99   return join('', @sqlf);
 100 }
 101
 102 sub _make_as {
 103   my ($self, $from) = @_;
 104   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 105                            reverse each %{$self->_skip_options($from)});
 106 }
 107
 108 sub _skip_options {
 109   my ($self, $hash) = @_;
 110   my $clean_hash = {};
 111   $clean_hash->{$_} = $hash->{$_}
 112     for grep {!/^-/} keys %$hash;
 113   return $clean_hash;
 114 }
 115
 116 sub _join_condition {
 117   my ($self, $cond) = @_;
 118   if (ref $cond eq 'HASH') {
 119     my %j;
 120     for (keys %$cond) { my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x; };
 121     return $self->_recurse_where(\%j);
 122   } elsif (ref $cond eq 'ARRAY') {
 123     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 124   } else {
 125     die "Can't handle this yet!";
 126   }
 127 }
 128
 129 sub _quote {
 130   my ($self, $label) = @_;
 131   return '' unless defined $label;
 132   return $self->SUPER::_quote($label);
 133 }
 134
 135 } # End of BEGIN block
 136
 137 use base qw/DBIx::Class/;
 138
 139 __PACKAGE__->load_components(qw/Exception AccessorGroup/);
 140
 141 __PACKAGE__->mk_group_accessors('simple' =>
 142   qw/connect_info _dbh _sql_maker debug debugfh cursor on_connect_do transaction_depth/);
 143
 144 sub new {
 145   my $new = bless({}, ref $_[0] || $_[0]);
 146   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 147   $new->transaction_depth(0);
 148   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 149      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 150     $new->debugfh(IO::File->new($1, 'w')||die "Cannot open trace file $1");
 151   } else {
 152     $new->debugfh(IO::File->new('>&STDERR'));
 153   }
 154   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 155   return $new;
 156 }
 157
 158 =head1 NAME
 159
 160 DBIx::Class::Storage::DBI - DBI storage handler
 161
 162 =head1 SYNOPSIS
 163
 164 =head1 DESCRIPTION
 165
 166 This class represents the connection to the database
 167
 168 =head1 METHODS
 169
 170 =cut
 171
 172 =head2 on_connect_do
 173
 174 Executes the sql statements given as a listref on every db connect.
 175
 176 =head2 debug
 177
 178 Causes SQL trace information to be emitted on C<debugfh> filehandle
 179 (or C<STDERR> if C<debugfh> has not specifically been set).
 180
 181 =head2 debugfh
 182
 183 Sets or retrieves the filehandle used for trace/debug output.  This
 184 should be an IO::Handle compatible object (only the C<print> method is
 185 used).  Initially set to be STDERR - although see information on the
 186 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 187
 188 =cut
 189
 190 sub dbh {
 191   my ($self) = @_;
 192   my $dbh;
 193   unless (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping) {
 194     $self->_populate_dbh;
 195   }
 196   return $self->_dbh;
 197 }
 198
 199 sub sql_maker {
 200   my ($self) = @_;
 201   unless ($self->_sql_maker) {
 202     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 203   }
 204   return $self->_sql_maker;
 205 }
 206
 207 sub _populate_dbh {
 208   my ($self) = @_;
 209   my @info = @{$self->connect_info || []};
 210   $self->_dbh($self->_connect(@info));
 211
 212   # if on-connect sql statements are given execute them
 213   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 214     $self->_dbh->do($sql_statement);
 215   }
 216 }
 217
 218 sub _connect {
 219   my ($self, @info) = @_;
 220   return DBI->connect(@info);
 221 }
 222
 223 =head2 txn_begin
 224
 225 Calls begin_work on the current dbh.
 226
 227 =cut
 228
 229 sub txn_begin {
 230   my $self = shift;
 231   $self->dbh->begin_work if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 232 }
 233
 234 =head2 txn_commit
 235
 236 Issues a commit against the current dbh.
 237
 238 =cut
 239
 240 sub txn_commit {
 241   my $self = shift;
 242   if ($self->{transaction_depth} == 0) {
 243     $self->dbh->commit unless $self->dbh->{AutoCommit};
 244   }
 245   else {
 246     $self->dbh->commit if --$self->{transaction_depth} == 0;
 247   }
 248 }
 249
 250 =head2 txn_rollback
 251
 252 Issues a rollback against the current dbh.
 253
 254 =cut
 255
 256 sub txn_rollback {
 257   my $self = shift;
 258   if ($self->{transaction_depth} == 0) {
 259     $self->dbh->rollback unless $self->dbh->{AutoCommit};
 260   }
 261   else {
 262     --$self->{transaction_depth} == 0 ? $self->dbh->rollback : die $@;
 263   }
 264 }
 265
 266 sub _execute {
 267   my ($self, $op, $extra_bind, $ident, @args) = @_;
 268   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 269   unshift(@bind, @$extra_bind) if $extra_bind;
 270   $self->debugfh->print("$sql: @bind\n") if $self->debug;
 271   my $sth = $self->sth($sql,$op);
 272   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 273   my $rv = $sth->execute(@bind);
 274   return (wantarray ? ($rv, $sth, @bind) : $rv);
 275 }
 276
 277 sub insert {
 278   my ($self, $ident, $to_insert) = @_;
 279   $self->throw( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 280     unless ($self->_execute('insert' => [], $ident, $to_insert));
 281   return $to_insert;
 282 }
 283
 284 sub update {
 285   return shift->_execute('update' => [], @_);
 286 }
 287
 288 sub delete {
 289   return shift->_execute('delete' => [], @_);
 290 }
 291
 292 sub _select {
 293   my ($self, $ident, $select, $condition, $attrs) = @_;
 294   my $order = $attrs->{order_by};
 295   if (ref $condition eq 'SCALAR') {
 296     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 297   }
 298   if (exists $attrs->{group_by}) {
 299     $order = { group_by => $attrs->{group_by},
 300                ($order ? (order_by => $order) : ()) };
 301   }
 302   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 303   if ($attrs->{software_limit} ||
 304       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 305         $attrs->{software_limit} = 1;
 306   } else {
 307     push @args, $attrs->{rows}, $attrs->{offset};
 308   }
 309   return $self->_execute(@args);
 310 }
 311
 312 sub select {
 313   my $self = shift;
 314   my ($ident, $select, $condition, $attrs) = @_;
 315   return $self->cursor->new($self, \@_, $attrs);
 316 }
 317
 318 sub select_single {
 319   my $self = shift;
 320   my ($rv, $sth, @bind) = $self->_select(@_);
 321   return $sth->fetchrow_array;
 322 }
 323
 324 sub sth {
 325   my ($self, $sql) = @_;
 326   # 3 is the if_active parameter which avoids active sth re-use
 327   return $self->dbh->prepare_cached($sql, {}, 3);
 328 }
 329
 330 =head2 columns_info_for
 331
 332 Returns database type info for a given table columns.
 333
 334 =cut
 335
 336 sub columns_info_for {
 337     my ($self, $table) = @_;
 338     my %result;
 339     if ( $self->dbh->can( 'column_info' ) ){
 340         my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 341         $sth->execute();
 342         while ( my $info = $sth->fetchrow_hashref() ){
 343             my %column_info;
 344             $column_info{data_type} = $info->{TYPE_NAME};
 345             $column_info{size} = $info->{COLUMN_SIZE};
 346             $column_info{is_nullable} = $info->{NULLABLE};
 347             $result{$info->{COLUMN_NAME}} = \%column_info;
 348         }
 349     }else{
 350         my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 351         $sth->execute;
 352         my @columns = @{$sth->{NAME}};
 353         for my $i ( 0 .. $#columns ){
 354             $result{$columns[$i]}{data_type} = $sth->{TYPE}->[$i];
 355         }
 356     }
 357     return \%result;
 358 }
 359
 360 1;
 361
 362 =head1 ENVIRONMENT VARIABLES
 363
 364 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 365
 366 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 367 is produced (as when the L<debug> method is set).
 368
 369 If the value is of the form C<1=/path/name> then the trace output is
 370 written to the file C</path/name>.
 371
 372 =head1 AUTHORS
 373
 374 Matt S. Trout <mst@shadowcatsystems.co.uk>
 375
 376 Andy Grundman <andy@hybridized.org>
 377
 378 =head1 LICENSE
 379
 380 You may distribute this code under the same terms as Perl itself.
 381
 382 =cut
 383