lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  17        transaction_depth unsafe/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields, $params) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 127           ? ' AS col'.$self->{rownum_hack_count}++
 128           : '')
 129       } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.  Please note that the L<DBI> docs
 334 recommend that you always explicitly set C<AutoCommit> to either
 335 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 336 to C<1>, and that you perform transactions via our L</txn_do>
 337 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 338 set it to zero.  This is the default for most DBDs.  See below for more
 339 details.
 340
 341 In either case, if the final argument in your connect_info happens
 342 to be a hashref, C<connect_info> will look there for several
 343 connection-specific options:
 344
 345 =over 4
 346
 347 =item on_connect_do
 348
 349 This can be set to an arrayref of literal sql statements, which will
 350 be executed immediately after making the connection to the database
 351 every time we [re-]connect.
 352
 353 =item disable_sth_caching
 354
 355 If set to a true value, this option will disable the caching of
 356 statement handles via L<DBI/prepare_cached>.
 357
 358 =item limit_dialect
 359
 360 Sets the limit dialect. This is useful for JDBC-bridge among others
 361 where the remote SQL-dialect cannot be determined by the name of the
 362 driver alone.
 363
 364 =item quote_char
 365
 366 Specifies what characters to use to quote table and column names. If
 367 you use this you will want to specify L<name_sep> as well.
 368
 369 quote_char expects either a single character, in which case is it is placed
 370 on either side of the table/column, or an arrayref of length 2 in which case the
 371 table/column name is placed between the elements.
 372
 373 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 374 use C<quote_char =E<gt> [qw/[ ]/]>.
 375
 376 =item name_sep
 377
 378 This only needs to be used in conjunction with L<quote_char>, and is used to
 379 specify the charecter that seperates elements (schemas, tables, columns) from
 380 each other. In most cases this is simply a C<.>.
 381
 382 =item unsafe
 383
 384 This Storage driver normally installs its own C<HandleError>, sets
 385 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 386 all database handles, including those supplied by a coderef.  It does this
 387 so that it can have consistent and useful error behavior.
 388
 389 If you set this option to a true value, Storage will not do its usual
 390 modifications to the database handle's attributes, and instead relies on
 391 the settings in your connect_info DBI options (or the values you set in
 392 your connection coderef, in the case that you are connecting via coderef).
 393
 394 Note that your custom settings can cause Storage to malfunction,
 395 especially if you set a C<HandleError> handler that suppresses exceptions
 396 and/or disable C<RaiseError>.
 397
 398 =back
 399
 400 These options can be mixed in with your other L<DBI> connection attributes,
 401 or placed in a seperate hashref after all other normal L<DBI> connection
 402 arguments.
 403
 404 Every time C<connect_info> is invoked, any previous settings for
 405 these options will be cleared before setting the new ones, regardless of
 406 whether any options are specified in the new C<connect_info>.
 407
 408 Another Important Note:
 409
 410 DBIC can do some wonderful magic with handling exceptions,
 411 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 412 combined with C<txn_do> for transaction support.
 413
 414 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 415 in an assumed transaction between commits, and you're telling us you'd
 416 like to manage that manually.  A lot of DBIC's magic protections
 417 go away.  We can't protect you from exceptions due to database
 418 disconnects because we don't know anything about how to restart your
 419 transactions.  You're on your own for handling all sorts of exceptional
 420 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 421 be with raw DBI.
 422
 423 Examples:
 424
 425   # Simple SQLite connection
 426   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 427
 428   # Connect via subref
 429   ->connect_info([ sub { DBI->connect(...) } ]);
 430
 431   # A bit more complicated
 432   ->connect_info(
 433     [
 434       'dbi:Pg:dbname=foo',
 435       'postgres',
 436       'my_pg_password',
 437       { AutoCommit => 1 },
 438       { quote_char => q{"}, name_sep => q{.} },
 439     ]
 440   );
 441
 442   # Equivalent to the previous example
 443   ->connect_info(
 444     [
 445       'dbi:Pg:dbname=foo',
 446       'postgres',
 447       'my_pg_password',
 448       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 449     ]
 450   );
 451
 452   # Subref + DBIC-specific connection options
 453   ->connect_info(
 454     [
 455       sub { DBI->connect(...) },
 456       {
 457           quote_char => q{`},
 458           name_sep => q{@},
 459           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 460           disable_sth_caching => 1,
 461       },
 462     ]
 463   );
 464
 465 =cut
 466
 467 sub connect_info {
 468   my ($self, $info_arg) = @_;
 469
 470   return $self->_connect_info if !$info_arg;
 471
 472   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 473   #  the new set of options
 474   $self->_sql_maker(undef);
 475   $self->_sql_maker_opts({});
 476   $self->_connect_info([@$info_arg]); # copy for _connect_info
 477
 478   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 479
 480   my $last_info = $dbi_info->[-1];
 481   if(ref $last_info eq 'HASH') {
 482     $last_info = { %$last_info }; # so delete is non-destructive
 483     for my $storage_opt (qw/on_connect_do disable_sth_caching unsafe/) {
 484       if(my $value = delete $last_info->{$storage_opt}) {
 485         $self->$storage_opt($value);
 486       }
 487     }
 488     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 489       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 490         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 491       }
 492     }
 493     # re-insert modified hashref
 494     $dbi_info->[-1] = $last_info;
 495
 496     # Get rid of any trailing empty hashref
 497     pop(@$dbi_info) if !keys %$last_info;
 498   }
 499   $self->_dbi_connect_info($dbi_info);
 500
 501   $self->_connect_info;
 502 }
 503
 504 =head2 on_connect_do
 505
 506 This method is deprecated in favor of setting via L</connect_info>.
 507
 508 =head2 dbh_do
 509
 510 Arguments: $subref, @extra_coderef_args?
 511
 512 Execute the given subref using the new exception-based connection management.
 513
 514 The first two arguments will be the storage object that C<dbh_do> was called
 515 on and a database handle to use.  Any additional arguments will be passed
 516 verbatim to the called subref as arguments 2 and onwards.
 517
 518 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 519 exception handling and reconnection (or failover in future subclasses).
 520
 521 Your subref should have no side-effects outside of the database, as
 522 there is the potential for your subref to be partially double-executed
 523 if the database connection was stale/dysfunctional.
 524
 525 Example:
 526
 527   my @stuff = $schema->storage->dbh_do(
 528     sub {
 529       my ($storage, $dbh, @cols) = @_;
 530       my $cols = join(q{, }, @cols);
 531       $dbh->selectrow_array("SELECT $cols FROM foo");
 532     },
 533     @column_list
 534   );
 535
 536 =cut
 537
 538 sub dbh_do {
 539   my $self = shift;
 540   my $coderef = shift;
 541
 542   ref $coderef eq 'CODE' or $self->throw_exception
 543     ('$coderef must be a CODE reference');
 544
 545   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 546       || $self->{transaction_depth};
 547
 548   local $self->{_in_dbh_do} = 1;
 549
 550   my @result;
 551   my $want_array = wantarray;
 552
 553   eval {
 554     $self->_verify_pid if $self->_dbh;
 555     $self->_populate_dbh if !$self->_dbh;
 556     if($want_array) {
 557         @result = $coderef->($self, $self->_dbh, @_);
 558     }
 559     elsif(defined $want_array) {
 560         $result[0] = $coderef->($self, $self->_dbh, @_);
 561     }
 562     else {
 563         $coderef->($self, $self->_dbh, @_);
 564     }
 565   };
 566
 567   my $exception = $@;
 568   if(!$exception) { return $want_array ? @result : $result[0] }
 569
 570   $self->throw_exception($exception) if $self->connected;
 571
 572   # We were not connected - reconnect and retry, but let any
 573   #  exception fall right through this time
 574   $self->_populate_dbh;
 575   $coderef->($self, $self->_dbh, @_);
 576 }
 577
 578 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 579 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 580 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 581 sub txn_do {
 582   my $self = shift;
 583   my $coderef = shift;
 584
 585   ref $coderef eq 'CODE' or $self->throw_exception
 586     ('$coderef must be a CODE reference');
 587
 588   local $self->{_in_dbh_do} = 1;
 589
 590   my @result;
 591   my $want_array = wantarray;
 592
 593   my $tried = 0;
 594   while(1) {
 595     eval {
 596       $self->_verify_pid if $self->_dbh;
 597       $self->_populate_dbh if !$self->_dbh;
 598
 599       $self->txn_begin;
 600       if($want_array) {
 601           @result = $coderef->(@_);
 602       }
 603       elsif(defined $want_array) {
 604           $result[0] = $coderef->(@_);
 605       }
 606       else {
 607           $coderef->(@_);
 608       }
 609       $self->txn_commit;
 610     };
 611
 612     my $exception = $@;
 613     if(!$exception) { return $want_array ? @result : $result[0] }
 614
 615     if($tried++ > 0 || $self->connected) {
 616       eval { $self->txn_rollback };
 617       my $rollback_exception = $@;
 618       if($rollback_exception) {
 619         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 620         $self->throw_exception($exception)  # propagate nested rollback
 621           if $rollback_exception =~ /$exception_class/;
 622
 623         $self->throw_exception(
 624           "Transaction aborted: ${exception}. "
 625           . "Rollback failed: ${rollback_exception}"
 626         );
 627       }
 628       $self->throw_exception($exception)
 629     }
 630
 631     # We were not connected, and was first try - reconnect and retry
 632     # via the while loop
 633     $self->_populate_dbh;
 634   }
 635 }
 636
 637 =head2 disconnect
 638
 639 Our C<disconnect> method also performs a rollback first if the
 640 database is not in C<AutoCommit> mode.
 641
 642 =cut
 643
 644 sub disconnect {
 645   my ($self) = @_;
 646
 647   if( $self->connected ) {
 648     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 649     $self->_dbh->disconnect;
 650     $self->_dbh(undef);
 651     $self->{_dbh_gen}++;
 652   }
 653 }
 654
 655 sub connected {
 656   my ($self) = @_;
 657
 658   if(my $dbh = $self->_dbh) {
 659       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 660           $self->_dbh(undef);
 661           $self->{_dbh_gen}++;
 662           return;
 663       }
 664       else {
 665           $self->_verify_pid;
 666       }
 667       return ($dbh->FETCH('Active') && $dbh->ping);
 668   }
 669
 670   return 0;
 671 }
 672
 673 # handle pid changes correctly
 674 #  NOTE: assumes $self->_dbh is a valid $dbh
 675 sub _verify_pid {
 676   my ($self) = @_;
 677
 678   return if $self->_conn_pid == $$;
 679
 680   $self->_dbh->{InactiveDestroy} = 1;
 681   $self->_dbh(undef);
 682   $self->{_dbh_gen}++;
 683
 684   return;
 685 }
 686
 687 sub ensure_connected {
 688   my ($self) = @_;
 689
 690   unless ($self->connected) {
 691     $self->_populate_dbh;
 692   }
 693 }
 694
 695 =head2 dbh
 696
 697 Returns the dbh - a data base handle of class L<DBI>.
 698
 699 =cut
 700
 701 sub dbh {
 702   my ($self) = @_;
 703
 704   $self->ensure_connected;
 705   return $self->_dbh;
 706 }
 707
 708 sub _sql_maker_args {
 709     my ($self) = @_;
 710
 711     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 712 }
 713
 714 sub sql_maker {
 715   my ($self) = @_;
 716   unless ($self->_sql_maker) {
 717     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 718   }
 719   return $self->_sql_maker;
 720 }
 721
 722 sub _populate_dbh {
 723   my ($self) = @_;
 724   my @info = @{$self->_dbi_connect_info || []};
 725   $self->_dbh($self->_connect(@info));
 726
 727   # Always set the transaction depth on connect, since
 728   #  there is no transaction in progress by definition
 729   $self->{transaction_depth} = $self->_dbh->{AutoCommit} ? 0 : 1;
 730
 731   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 732     my $driver = $self->_dbh->{Driver}->{Name};
 733     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 734       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 735       $self->_rebless() if $self->can('_rebless');
 736     }
 737   }
 738
 739   # if on-connect sql statements are given execute them
 740   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 741     $self->debugobj->query_start($sql_statement) if $self->debug();
 742     $self->_dbh->do($sql_statement);
 743     $self->debugobj->query_end($sql_statement) if $self->debug();
 744   }
 745
 746   $self->_conn_pid($$);
 747   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 748 }
 749
 750 sub _connect {
 751   my ($self, @info) = @_;
 752
 753   $self->throw_exception("You failed to provide any connection info")
 754     if !@info;
 755
 756   my ($old_connect_via, $dbh);
 757
 758   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 759     $old_connect_via = $DBI::connect_via;
 760     $DBI::connect_via = 'connect';
 761   }
 762
 763   eval {
 764     if(ref $info[0] eq 'CODE') {
 765        $dbh = &{$info[0]}
 766     }
 767     else {
 768        $dbh = DBI->connect(@info);
 769     }
 770
 771     if(!$self->unsafe) {
 772       my $weak_self = $self;
 773       weaken($weak_self);
 774       $dbh->{HandleError} = sub {
 775           $weak_self->throw_exception("DBI Exception: $_[0]")
 776       };
 777       $dbh->{ShowErrorStatement} = 1;
 778       $dbh->{RaiseError} = 1;
 779       $dbh->{PrintError} = 0;
 780     }
 781   };
 782
 783   $DBI::connect_via = $old_connect_via if $old_connect_via;
 784
 785   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 786     if !$dbh || $@;
 787
 788   $dbh;
 789 }
 790
 791
 792 sub txn_begin {
 793   my $self = shift;
 794   $self->ensure_connected();
 795   if($self->{transaction_depth}++ == 0) {
 796     $self->debugobj->txn_begin()
 797       if $self->debug;
 798     # this isn't ->_dbh-> because
 799     #  we should reconnect on begin_work
 800     #  for AutoCommit users
 801     $self->dbh->begin_work;
 802   }
 803 }
 804
 805 sub txn_commit {
 806   my $self = shift;
 807   if ($self->{transaction_depth} == 1) {
 808     my $dbh = $self->_dbh;
 809     $self->debugobj->txn_commit()
 810       if ($self->debug);
 811     $dbh->commit;
 812     $self->{transaction_depth} = 0
 813       if $dbh->{AutoCommit};
 814   }
 815   elsif($self->{transaction_depth} > 1) {
 816     $self->{transaction_depth}--
 817   }
 818 }
 819
 820 sub txn_rollback {
 821   my $self = shift;
 822   my $dbh = $self->_dbh;
 823   my $autocommit;
 824   eval {
 825     $autocommit = $dbh->{AutoCommit};
 826     if ($self->{transaction_depth} == 1) {
 827       $self->debugobj->txn_rollback()
 828         if ($self->debug);
 829       $dbh->rollback;
 830       $self->{transaction_depth} = 0
 831         if $autocommit;
 832     }
 833     elsif($self->{transaction_depth} > 1) {
 834       $self->{transaction_depth}--;
 835     }
 836     else {
 837       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 838     }
 839   };
 840   if ($@) {
 841     my $error = $@;
 842     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 843     $error =~ /$exception_class/ and $self->throw_exception($error);
 844     # ensure that a failed rollback resets the transaction depth
 845     $self->{transaction_depth} = $autocommit ? 0 : 1;
 846     $self->throw_exception($error);
 847   }
 848 }
 849
 850 # This used to be the top-half of _execute.  It was split out to make it
 851 #  easier to override in NoBindVars without duping the rest.  It takes up
 852 #  all of _execute's args, and emits $sql, @bind.
 853 sub _prep_for_execute {
 854   my ($self, $op, $extra_bind, $ident, $args) = @_;
 855
 856   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 857   unshift(@bind,
 858     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 859       if $extra_bind;
 860
 861   return ($sql, \@bind);
 862 }
 863
 864 sub _dbh_execute {
 865   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 866
 867   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 868     $ident = $ident->from();
 869   }
 870
 871   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 872
 873   if ($self->debug) {
 874       my @debug_bind =
 875         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 876       $self->debugobj->query_start($sql, @debug_bind);
 877   }
 878
 879   my $sth = $self->sth($sql,$op);
 880
 881   my $placeholder_index = 1;
 882
 883   foreach my $bound (@$bind) {
 884     my $attributes = {};
 885     my($column_name, @data) = @$bound;
 886
 887     if ($bind_attributes) {
 888       $attributes = $bind_attributes->{$column_name}
 889       if defined $bind_attributes->{$column_name};
 890     }
 891
 892     foreach my $data (@data) {
 893       $data = ref $data ? ''.$data : $data; # stringify args
 894
 895       $sth->bind_param($placeholder_index, $data, $attributes);
 896       $placeholder_index++;
 897     }
 898   }
 899
 900   # Can this fail without throwing an exception anyways???
 901   my $rv = $sth->execute();
 902   $self->throw_exception($sth->errstr) if !$rv;
 903
 904   if ($self->debug) {
 905      my @debug_bind =
 906        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 907      $self->debugobj->query_end($sql, @debug_bind);
 908   }
 909
 910   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 911 }
 912
 913 sub _execute {
 914     my $self = shift;
 915     $self->dbh_do($self->can('_dbh_execute'), @_)
 916 }
 917
 918 sub insert {
 919   my ($self, $source, $to_insert) = @_;
 920
 921   my $ident = $source->from;
 922   my $bind_attributes = $self->source_bind_attributes($source);
 923
 924   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 925
 926   return $to_insert;
 927 }
 928
 929 ## Still not quite perfect, and EXPERIMENTAL
 930 ## Currently it is assumed that all values passed will be "normal", i.e. not
 931 ## scalar refs, or at least, all the same type as the first set, the statement is
 932 ## only prepped once.
 933 sub insert_bulk {
 934   my ($self, $source, $cols, $data) = @_;
 935   my %colvalues;
 936   my $table = $source->from;
 937   @colvalues{@$cols} = (0..$#$cols);
 938   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 939
 940   if ($self->debug) {
 941       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 942       $self->debugobj->query_start($sql, @debug_bind);
 943   }
 944   my $sth = $self->sth($sql);
 945
 946 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 947
 948   ## This must be an arrayref, else nothing works!
 949
 950   my $tuple_status = [];
 951
 952   ##use Data::Dumper;
 953   ##print STDERR Dumper( $data, $sql, [@bind] );
 954
 955   my $time = time();
 956
 957   ## Get the bind_attributes, if any exist
 958   my $bind_attributes = $self->source_bind_attributes($source);
 959
 960   ## Bind the values and execute
 961   my $placeholder_index = 1;
 962
 963   foreach my $bound (@bind) {
 964
 965     my $attributes = {};
 966     my ($column_name, $data_index) = @$bound;
 967
 968     if( $bind_attributes ) {
 969       $attributes = $bind_attributes->{$column_name}
 970       if defined $bind_attributes->{$column_name};
 971     }
 972
 973     my @data = map { $_->[$data_index] } @$data;
 974
 975     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 976     $placeholder_index++;
 977   }
 978   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
 979   $self->throw_exception($sth->errstr) if !$rv;
 980
 981   if ($self->debug) {
 982       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 983       $self->debugobj->query_end($sql, @debug_bind);
 984   }
 985   return (wantarray ? ($rv, $sth, @bind) : $rv);
 986 }
 987
 988 sub update {
 989   my $self = shift @_;
 990   my $source = shift @_;
 991   my $bind_attributes = $self->source_bind_attributes($source);
 992
 993   return $self->_execute('update' => [], $source, $bind_attributes, @_);
 994 }
 995
 996
 997 sub delete {
 998   my $self = shift @_;
 999   my $source = shift @_;
1000
1001   my $bind_attrs = {}; ## If ever it's needed...
1002
1003   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1004 }
1005
1006 sub _select {
1007   my ($self, $ident, $select, $condition, $attrs) = @_;
1008   my $order = $attrs->{order_by};
1009   if (ref $condition eq 'SCALAR') {
1010     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1011   }
1012   if (exists $attrs->{group_by} || $attrs->{having}) {
1013     $order = {
1014       group_by => $attrs->{group_by},
1015       having => $attrs->{having},
1016       ($order ? (order_by => $order) : ())
1017     };
1018   }
1019   my $bind_attrs = {}; ## Future support
1020   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1021   if ($attrs->{software_limit} ||
1022       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1023         $attrs->{software_limit} = 1;
1024   } else {
1025     $self->throw_exception("rows attribute must be positive if present")
1026       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1027     push @args, $attrs->{rows}, $attrs->{offset};
1028   }
1029   return $self->_execute(@args);
1030 }
1031
1032 sub source_bind_attributes {
1033   my ($self, $source) = @_;
1034
1035   my $bind_attributes;
1036   foreach my $column ($source->columns) {
1037
1038     my $data_type = $source->column_info($column)->{data_type} || '';
1039     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1040      if $data_type;
1041   }
1042
1043   return $bind_attributes;
1044 }
1045
1046 =head2 select
1047
1048 =over 4
1049
1050 =item Arguments: $ident, $select, $condition, $attrs
1051
1052 =back
1053
1054 Handle a SQL select statement.
1055
1056 =cut
1057
1058 sub select {
1059   my $self = shift;
1060   my ($ident, $select, $condition, $attrs) = @_;
1061   return $self->cursor->new($self, \@_, $attrs);
1062 }
1063
1064 sub select_single {
1065   my $self = shift;
1066   my ($rv, $sth, @bind) = $self->_select(@_);
1067   my @row = $sth->fetchrow_array;
1068   # Need to call finish() to work round broken DBDs
1069   $sth->finish();
1070   return @row;
1071 }
1072
1073 =head2 sth
1074
1075 =over 4
1076
1077 =item Arguments: $sql
1078
1079 =back
1080
1081 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1082
1083 =cut
1084
1085 sub _dbh_sth {
1086   my ($self, $dbh, $sql) = @_;
1087
1088   # 3 is the if_active parameter which avoids active sth re-use
1089   my $sth = $self->disable_sth_caching
1090     ? $dbh->prepare($sql)
1091     : $dbh->prepare_cached($sql, {}, 3);
1092
1093   # XXX You would think RaiseError would make this impossible,
1094   #  but apparently that's not true :(
1095   $self->throw_exception($dbh->errstr) if !$sth;
1096
1097   $sth;
1098 }
1099
1100 sub sth {
1101   my ($self, $sql) = @_;
1102   $self->dbh_do($self->can('_dbh_sth'), $sql);
1103 }
1104
1105 sub _dbh_columns_info_for {
1106   my ($self, $dbh, $table) = @_;
1107
1108   if ($dbh->can('column_info')) {
1109     my %result;
1110     eval {
1111       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1112       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1113       $sth->execute();
1114       while ( my $info = $sth->fetchrow_hashref() ){
1115         my %column_info;
1116         $column_info{data_type}   = $info->{TYPE_NAME};
1117         $column_info{size}      = $info->{COLUMN_SIZE};
1118         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1119         $column_info{default_value} = $info->{COLUMN_DEF};
1120         my $col_name = $info->{COLUMN_NAME};
1121         $col_name =~ s/^\"(.*)\"$/$1/;
1122
1123         $result{$col_name} = \%column_info;
1124       }
1125     };
1126     return \%result if !$@ && scalar keys %result;
1127   }
1128
1129   my %result;
1130   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1131   $sth->execute;
1132   my @columns = @{$sth->{NAME_lc}};
1133   for my $i ( 0 .. $#columns ){
1134     my %column_info;
1135     $column_info{data_type} = $sth->{TYPE}->[$i];
1136     $column_info{size} = $sth->{PRECISION}->[$i];
1137     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1138
1139     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1140       $column_info{data_type} = $1;
1141       $column_info{size}    = $2;
1142     }
1143
1144     $result{$columns[$i]} = \%column_info;
1145   }
1146   $sth->finish;
1147
1148   foreach my $col (keys %result) {
1149     my $colinfo = $result{$col};
1150     my $type_num = $colinfo->{data_type};
1151     my $type_name;
1152     if(defined $type_num && $dbh->can('type_info')) {
1153       my $type_info = $dbh->type_info($type_num);
1154       $type_name = $type_info->{TYPE_NAME} if $type_info;
1155       $colinfo->{data_type} = $type_name if $type_name;
1156     }
1157   }
1158
1159   return \%result;
1160 }
1161
1162 sub columns_info_for {
1163   my ($self, $table) = @_;
1164   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1165 }
1166
1167 =head2 last_insert_id
1168
1169 Return the row id of the last insert.
1170
1171 =cut
1172
1173 sub _dbh_last_insert_id {
1174     my ($self, $dbh, $source, $col) = @_;
1175     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1176     $dbh->func('last_insert_rowid');
1177 }
1178
1179 sub last_insert_id {
1180   my $self = shift;
1181   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1182 }
1183
1184 =head2 sqlt_type
1185
1186 Returns the database driver name.
1187
1188 =cut
1189
1190 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1191
1192 =head2 bind_attribute_by_data_type
1193
1194 Given a datatype from column info, returns a database specific bind attribute for
1195 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1196 just handle it.
1197
1198 Generally only needed for special case column types, like bytea in postgres.
1199
1200 =cut
1201
1202 sub bind_attribute_by_data_type {
1203     return;
1204 }
1205
1206 =head2 create_ddl_dir
1207
1208 =over 4
1209
1210 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1211
1212 =back
1213
1214 Creates a SQL file based on the Schema, for each of the specified
1215 database types, in the given directory.
1216
1217 =cut
1218
1219 sub create_ddl_dir
1220 {
1221   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1222
1223   if(!$dir || !-d $dir)
1224   {
1225     warn "No directory given, using ./\n";
1226     $dir = "./";
1227   }
1228   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1229   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1230   $version ||= $schema->VERSION || '1.x';
1231   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1232
1233   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1234       . $self->_check_sqlt_message . q{'})
1235           if !$self->_check_sqlt_version;
1236
1237   my $sqlt = SQL::Translator->new({
1238 #      debug => 1,
1239       add_drop_table => 1,
1240   });
1241   foreach my $db (@$databases)
1242   {
1243     $sqlt->reset();
1244     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1245 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1246     $sqlt = $self->configure_sqlt($sqlt, $db);
1247     $sqlt->data($schema);
1248     $sqlt->producer($db);
1249
1250     my $file;
1251     my $filename = $schema->ddl_filename($db, $dir, $version);
1252     if(-e $filename)
1253     {
1254       warn("$filename already exists, skipping $db");
1255       next;
1256     }
1257
1258     my $output = $sqlt->translate;
1259     if(!$output)
1260     {
1261       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1262       next;
1263     }
1264     if(!open($file, ">$filename"))
1265     {
1266         $self->throw_exception("Can't open $filename for writing ($!)");
1267         next;
1268     }
1269     print $file $output;
1270     close($file);
1271
1272     if($preversion)
1273     {
1274       require SQL::Translator::Diff;
1275
1276       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1277 #      print "Previous version $prefilename\n";
1278       if(!-e $prefilename)
1279       {
1280         warn("No previous schema file found ($prefilename)");
1281         next;
1282       }
1283       #### We need to reparse the SQLite file we just wrote, so that
1284       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1285       ##   FIXME: rip Diff to pieces!
1286 #      my $target_schema = $sqlt->schema;
1287 #      unless ( $target_schema->name ) {
1288 #        $target_schema->name( $filename );
1289 #      }
1290       my @input;
1291       push @input, {file => $prefilename, parser => $db};
1292       push @input, {file => $filename, parser => $db};
1293       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1294         my $file   = $_->{'file'};
1295         my $parser = $_->{'parser'};
1296
1297         my $t = SQL::Translator->new;
1298         $t->debug( 0 );
1299         $t->trace( 0 );
1300         $t->parser( $parser )            or die $t->error;
1301         my $out = $t->translate( $file ) or die $t->error;
1302         my $schema = $t->schema;
1303         unless ( $schema->name ) {
1304           $schema->name( $file );
1305         }
1306         ($schema, $parser);
1307       } @input;
1308
1309       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1310                                                     $target_schema, $db,
1311                                                     {}
1312                                                    );
1313       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1314       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1315       if(-e $difffile)
1316       {
1317         warn("$difffile already exists, skipping");
1318         next;
1319       }
1320       if(!open $file, ">$difffile")
1321       {
1322         $self->throw_exception("Can't write to $difffile ($!)");
1323         next;
1324       }
1325       print $file $diff;
1326       close($file);
1327     }
1328   }
1329 }
1330
1331 sub configure_sqlt() {
1332   my $self = shift;
1333   my $tr = shift;
1334   my $db = shift || $self->sqlt_type;
1335   if ($db eq 'PostgreSQL') {
1336     $tr->quote_table_names(0);
1337     $tr->quote_field_names(0);
1338   }
1339   return $tr;
1340 }
1341
1342 =head2 deployment_statements
1343
1344 =over 4
1345
1346 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1347
1348 =back
1349
1350 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1351 The database driver name is given by C<$type>, though the value from
1352 L</sqlt_type> is used if it is not specified.
1353
1354 C<$directory> is used to return statements from files in a previously created
1355 L</create_ddl_dir> directory and is optional. The filenames are constructed
1356 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1357
1358 If no C<$directory> is specified then the statements are constructed on the
1359 fly using L<SQL::Translator> and C<$version> is ignored.
1360
1361 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1362
1363 =cut
1364
1365 sub deployment_statements {
1366   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1367   # Need to be connected to get the correct sqlt_type
1368   $self->ensure_connected() unless $type;
1369   $type ||= $self->sqlt_type;
1370   $version ||= $schema->VERSION || '1.x';
1371   $dir ||= './';
1372   my $filename = $schema->ddl_filename($type, $dir, $version);
1373   if(-f $filename)
1374   {
1375       my $file;
1376       open($file, "<$filename")
1377         or $self->throw_exception("Can't open $filename ($!)");
1378       my @rows = <$file>;
1379       close($file);
1380       return join('', @rows);
1381   }
1382
1383   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1384       . $self->_check_sqlt_message . q{'})
1385           if !$self->_check_sqlt_version;
1386
1387   require SQL::Translator::Parser::DBIx::Class;
1388   eval qq{use SQL::Translator::Producer::${type}};
1389   $self->throw_exception($@) if $@;
1390
1391   # sources needs to be a parser arg, but for simplicty allow at top level
1392   # coming in
1393   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1394       if exists $sqltargs->{sources};
1395
1396   my $tr = SQL::Translator->new(%$sqltargs);
1397   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1398   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1399
1400   return;
1401
1402 }
1403
1404 sub deploy {
1405   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1406   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1407     foreach my $line ( split(";\n", $statement)) {
1408       next if($line =~ /^--/);
1409       next if(!$line);
1410 #      next if($line =~ /^DROP/m);
1411       next if($line =~ /^BEGIN TRANSACTION/m);
1412       next if($line =~ /^COMMIT/m);
1413       next if $line =~ /^\s+$/; # skip whitespace only
1414       $self->debugobj->query_start($line) if $self->debug;
1415       eval {
1416         $self->dbh->do($line); # shouldn't be using ->dbh ?
1417       };
1418       if ($@) {
1419         warn qq{$@ (running "${line}")};
1420       }
1421       $self->debugobj->query_end($line) if $self->debug;
1422     }
1423   }
1424 }
1425
1426 =head2 datetime_parser
1427
1428 Returns the datetime parser class
1429
1430 =cut
1431
1432 sub datetime_parser {
1433   my $self = shift;
1434   return $self->{datetime_parser} ||= do {
1435     $self->ensure_connected;
1436     $self->build_datetime_parser(@_);
1437   };
1438 }
1439
1440 =head2 datetime_parser_type
1441
1442 Defines (returns) the datetime parser class - currently hardwired to
1443 L<DateTime::Format::MySQL>
1444
1445 =cut
1446
1447 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1448
1449 =head2 build_datetime_parser
1450
1451 See L</datetime_parser>
1452
1453 =cut
1454
1455 sub build_datetime_parser {
1456   my $self = shift;
1457   my $type = $self->datetime_parser_type(@_);
1458   eval "use ${type}";
1459   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1460   return $type;
1461 }
1462
1463 {
1464     my $_check_sqlt_version; # private
1465     my $_check_sqlt_message; # private
1466     sub _check_sqlt_version {
1467         return $_check_sqlt_version if defined $_check_sqlt_version;
1468         eval 'use SQL::Translator 0.08';
1469         $_check_sqlt_message = $@ ? $@ : '';
1470         $_check_sqlt_version = $@ ? 0 : 1;
1471     }
1472
1473     sub _check_sqlt_message {
1474         _check_sqlt_version if !defined $_check_sqlt_message;
1475         $_check_sqlt_message;
1476     }
1477 }
1478
1479 sub DESTROY {
1480   my $self = shift;
1481   return if !$self->_dbh;
1482   $self->_verify_pid;
1483   $self->_dbh(undef);
1484 }
1485
1486 1;
1487
1488 =head1 SQL METHODS
1489
1490 The module defines a set of methods within the DBIC::SQL::Abstract
1491 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1492 SQL query functions.
1493
1494 The following methods are extended:-
1495
1496 =over 4
1497
1498 =item delete
1499
1500 =item insert
1501
1502 =item select
1503
1504 =item update
1505
1506 =item limit_dialect
1507
1508 See L</connect_info> for details.
1509 For setting, this method is deprecated in favor of L</connect_info>.
1510
1511 =item quote_char
1512
1513 See L</connect_info> for details.
1514 For setting, this method is deprecated in favor of L</connect_info>.
1515
1516 =item name_sep
1517
1518 See L</connect_info> for details.
1519 For setting, this method is deprecated in favor of L</connect_info>.
1520
1521 =back
1522
1523 =head1 AUTHORS
1524
1525 Matt S. Trout <mst@shadowcatsystems.co.uk>
1526
1527 Andy Grundman <andy@hybridized.org>
1528
1529 =head1 LICENSE
1530
1531 You may distribute this code under the same terms as Perl itself.
1532
1533 =cut