lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. We also need to separate accessors
  83 # from plain old method calls, since an accessor called as a setter
  84 # does *not* need the driver determination loop fired (and in fact
  85 # can produce hard to find bugs, like e.g. losing on_connect_*
  86 # semantics on fresh connections)
  87 #
  88 # The construct below is simply a parameterized around()
  89 my $storage_accessor_idx = { map { $_ => 1 } qw(
  90   sqlt_type
  91   datetime_parser_type
  92
  93   sql_maker
  94   cursor_class
  95 )};
  96 for my $meth (keys %$storage_accessor_idx, qw(
  97   deployment_statements
  98
  99   build_datetime_parser
 100
 101   txn_begin
 102
 103   insert
 104   insert_bulk
 105   update
 106   delete
 107   select
 108   select_single
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   no strict 'refs';
 123   no warnings 'redefine';
 124   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 125     if (
 126       # only fire when invoked on an instance, a valid class-based invocation
 127       # would e.g. be setting a default for an inherited accessor
 128       ref $_[0]
 129         and
 130       ! $_[0]->{_driver_determined}
 131         and
 132       ! $_[0]->{_in_determine_driver}
 133         and
 134       # if this is a known *setter* - just set it, no need to connect
 135       # and determine the driver
 136       ! ( $storage_accessor_idx->{$meth} and @_ > 1 )
 137         and
 138       # Only try to determine stuff if we have *something* that either is or can
 139       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 140       # to still be marginally useful
 141       $_[0]->_dbi_connect_info->[0]
 142     ) {
 143       $_[0]->_determine_driver;
 144
 145       # This for some reason crashes and burns on perl 5.8.1
 146       # IFF the method ends up throwing an exception
 147       #goto $_[0]->can ($meth);
 148
 149       my $cref = $_[0]->can ($meth);
 150       goto $cref;
 151     }
 152
 153     goto $orig;
 154   };
 155 }
 156
 157 sub perl_renderer {
 158   my ($self) = @_;
 159   $self->{perl_renderer} ||= do {
 160     require DBIx::Class::PerlRenderer;
 161     DBIx::Class::PerlRenderer->new;
 162   };
 163 }
 164
 165 =head1 NAME
 166
 167 DBIx::Class::Storage::DBI - DBI storage handler
 168
 169 =head1 SYNOPSIS
 170
 171   my $schema = MySchema->connect('dbi:SQLite:my.db');
 172
 173   $schema->storage->debug(1);
 174
 175   my @stuff = $schema->storage->dbh_do(
 176     sub {
 177       my ($storage, $dbh, @args) = @_;
 178       $dbh->do("DROP TABLE authors");
 179     },
 180     @column_list
 181   );
 182
 183   $schema->resultset('Book')->search({
 184      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 185   });
 186
 187 =head1 DESCRIPTION
 188
 189 This class represents the connection to an RDBMS via L<DBI>.  See
 190 L<DBIx::Class::Storage> for general information.  This pod only
 191 documents DBI-specific methods and behaviors.
 192
 193 =head1 METHODS
 194
 195 =cut
 196
 197 sub new {
 198   my $new = shift->next::method(@_);
 199
 200   $new->_sql_maker_opts({});
 201   $new->_dbh_details({});
 202   $new->{_in_do_block} = 0;
 203
 204   # read below to see what this does
 205   $new->_arm_global_destructor;
 206
 207   $new;
 208 }
 209
 210 # This is hack to work around perl shooting stuff in random
 211 # order on exit(). If we do not walk the remaining storage
 212 # objects in an END block, there is a *small but real* chance
 213 # of a fork()ed child to kill the parent's shared DBI handle,
 214 # *before perl reaches the DESTROY in this package*
 215 # Yes, it is ugly and effective.
 216 # Additionally this registry is used by the CLONE method to
 217 # make sure no handles are shared between threads
 218 {
 219   my %seek_and_destroy;
 220
 221   sub _arm_global_destructor {
 222
 223     # quick "garbage collection" pass - prevents the registry
 224     # from slowly growing with a bunch of undef-valued keys
 225     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 226       for keys %seek_and_destroy;
 227
 228     weaken (
 229       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 230     );
 231   }
 232
 233   END {
 234     local $?; # just in case the DBI destructor changes it somehow
 235
 236     # destroy just the object if not native to this process
 237     $_->_verify_pid for (grep
 238       { defined $_ }
 239       values %seek_and_destroy
 240     );
 241   }
 242
 243   sub CLONE {
 244     # As per DBI's recommendation, DBIC disconnects all handles as
 245     # soon as possible (DBIC will reconnect only on demand from within
 246     # the thread)
 247     my @instances = grep { defined $_ } values %seek_and_destroy;
 248     %seek_and_destroy = ();
 249
 250     for (@instances) {
 251       $_->_dbh(undef);
 252
 253       $_->transaction_depth(0);
 254       $_->savepoints([]);
 255
 256       # properly renumber existing refs
 257       $_->_arm_global_destructor
 258     }
 259   }
 260 }
 261
 262 sub DESTROY {
 263   my $self = shift;
 264
 265   # some databases spew warnings on implicit disconnect
 266   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 267   local $SIG{__WARN__} = sub {};
 268   $self->_dbh(undef);
 269
 270   # this op is necessary, since the very last perl runtime statement
 271   # triggers a global destruction shootout, and the $SIG localization
 272   # may very well be destroyed before perl actually gets to do the
 273   # $dbh undef
 274   1;
 275 }
 276
 277 # handle pid changes correctly - do not destroy parent's connection
 278 sub _verify_pid {
 279   my $self = shift;
 280
 281   my $pid = $self->_conn_pid;
 282   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 283     $dbh->{InactiveDestroy} = 1;
 284     $self->_dbh(undef);
 285     $self->transaction_depth(0);
 286     $self->savepoints([]);
 287   }
 288
 289   return;
 290 }
 291
 292 =head2 connect_info
 293
 294 This method is normally called by L<DBIx::Class::Schema/connection>, which
 295 encapsulates its argument list in an arrayref before passing them here.
 296
 297 The argument list may contain:
 298
 299 =over
 300
 301 =item *
 302
 303 The same 4-element argument set one would normally pass to
 304 L<DBI/connect>, optionally followed by
 305 L<extra attributes|/DBIx::Class specific connection attributes>
 306 recognized by DBIx::Class:
 307
 308   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 309
 310 =item *
 311
 312 A single code reference which returns a connected
 313 L<DBI database handle|DBI/connect> optionally followed by
 314 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 315 by DBIx::Class:
 316
 317   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 318
 319 =item *
 320
 321 A single hashref with all the attributes and the dsn/user/password
 322 mixed together:
 323
 324   $connect_info_args = [{
 325     dsn => $dsn,
 326     user => $user,
 327     password => $pass,
 328     %dbi_attributes,
 329     %extra_attributes,
 330   }];
 331
 332   $connect_info_args = [{
 333     dbh_maker => sub { DBI->connect (...) },
 334     %dbi_attributes,
 335     %extra_attributes,
 336   }];
 337
 338 This is particularly useful for L<Catalyst> based applications, allowing the
 339 following config (L<Config::General> style):
 340
 341   <Model::DB>
 342     schema_class   App::DB
 343     <connect_info>
 344       dsn          dbi:mysql:database=test
 345       user         testuser
 346       password     TestPass
 347       AutoCommit   1
 348     </connect_info>
 349   </Model::DB>
 350
 351 The C<dsn>/C<user>/C<password> combination can be substituted by the
 352 C<dbh_maker> key whose value is a coderef that returns a connected
 353 L<DBI database handle|DBI/connect>
 354
 355 =back
 356
 357 Please note that the L<DBI> docs recommend that you always explicitly
 358 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 359 recommends that it be set to I<1>, and that you perform transactions
 360 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 361 to I<1> if you do not do explicitly set it to zero.  This is the default
 362 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 363
 364 =head3 DBIx::Class specific connection attributes
 365
 366 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 367 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 368 the following connection options. These options can be mixed in with your other
 369 L<DBI> connection attributes, or placed in a separate hashref
 370 (C<\%extra_attributes>) as shown above.
 371
 372 Every time C<connect_info> is invoked, any previous settings for
 373 these options will be cleared before setting the new ones, regardless of
 374 whether any options are specified in the new C<connect_info>.
 375
 376
 377 =over
 378
 379 =item on_connect_do
 380
 381 Specifies things to do immediately after connecting or re-connecting to
 382 the database.  Its value may contain:
 383
 384 =over
 385
 386 =item a scalar
 387
 388 This contains one SQL statement to execute.
 389
 390 =item an array reference
 391
 392 This contains SQL statements to execute in order.  Each element contains
 393 a string or a code reference that returns a string.
 394
 395 =item a code reference
 396
 397 This contains some code to execute.  Unlike code references within an
 398 array reference, its return value is ignored.
 399
 400 =back
 401
 402 =item on_disconnect_do
 403
 404 Takes arguments in the same form as L</on_connect_do> and executes them
 405 immediately before disconnecting from the database.
 406
 407 Note, this only runs if you explicitly call L</disconnect> on the
 408 storage object.
 409
 410 =item on_connect_call
 411
 412 A more generalized form of L</on_connect_do> that calls the specified
 413 C<connect_call_METHOD> methods in your storage driver.
 414
 415   on_connect_do => 'select 1'
 416
 417 is equivalent to:
 418
 419   on_connect_call => [ [ do_sql => 'select 1' ] ]
 420
 421 Its values may contain:
 422
 423 =over
 424
 425 =item a scalar
 426
 427 Will call the C<connect_call_METHOD> method.
 428
 429 =item a code reference
 430
 431 Will execute C<< $code->($storage) >>
 432
 433 =item an array reference
 434
 435 Each value can be a method name or code reference.
 436
 437 =item an array of arrays
 438
 439 For each array, the first item is taken to be the C<connect_call_> method name
 440 or code reference, and the rest are parameters to it.
 441
 442 =back
 443
 444 Some predefined storage methods you may use:
 445
 446 =over
 447
 448 =item do_sql
 449
 450 Executes a SQL string or a code reference that returns a SQL string. This is
 451 what L</on_connect_do> and L</on_disconnect_do> use.
 452
 453 It can take:
 454
 455 =over
 456
 457 =item a scalar
 458
 459 Will execute the scalar as SQL.
 460
 461 =item an arrayref
 462
 463 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 464 attributes hashref and bind values.
 465
 466 =item a code reference
 467
 468 Will execute C<< $code->($storage) >> and execute the return array refs as
 469 above.
 470
 471 =back
 472
 473 =item datetime_setup
 474
 475 Execute any statements necessary to initialize the database session to return
 476 and accept datetime/timestamp values used with
 477 L<DBIx::Class::InflateColumn::DateTime>.
 478
 479 Only necessary for some databases, see your specific storage driver for
 480 implementation details.
 481
 482 =back
 483
 484 =item on_disconnect_call
 485
 486 Takes arguments in the same form as L</on_connect_call> and executes them
 487 immediately before disconnecting from the database.
 488
 489 Calls the C<disconnect_call_METHOD> methods as opposed to the
 490 C<connect_call_METHOD> methods called by L</on_connect_call>.
 491
 492 Note, this only runs if you explicitly call L</disconnect> on the
 493 storage object.
 494
 495 =item disable_sth_caching
 496
 497 If set to a true value, this option will disable the caching of
 498 statement handles via L<DBI/prepare_cached>.
 499
 500 =item limit_dialect
 501
 502 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 503 default L</sql_limit_dialect> setting of the storage (if any). For a list
 504 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 505
 506 =item quote_names
 507
 508 When true automatically sets L</quote_char> and L</name_sep> to the characters
 509 appropriate for your particular RDBMS. This option is preferred over specifying
 510 L</quote_char> directly.
 511
 512 =item quote_char
 513
 514 Specifies what characters to use to quote table and column names.
 515
 516 C<quote_char> expects either a single character, in which case is it
 517 is placed on either side of the table/column name, or an arrayref of length
 518 2 in which case the table/column name is placed between the elements.
 519
 520 For example under MySQL you should use C<< quote_char => '`' >>, and for
 521 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 522
 523 =item name_sep
 524
 525 This parameter is only useful in conjunction with C<quote_char>, and is used to
 526 specify the character that separates elements (schemas, tables, columns) from
 527 each other. If unspecified it defaults to the most commonly used C<.>.
 528
 529 =item unsafe
 530
 531 This Storage driver normally installs its own C<HandleError>, sets
 532 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 533 all database handles, including those supplied by a coderef.  It does this
 534 so that it can have consistent and useful error behavior.
 535
 536 If you set this option to a true value, Storage will not do its usual
 537 modifications to the database handle's attributes, and instead relies on
 538 the settings in your connect_info DBI options (or the values you set in
 539 your connection coderef, in the case that you are connecting via coderef).
 540
 541 Note that your custom settings can cause Storage to malfunction,
 542 especially if you set a C<HandleError> handler that suppresses exceptions
 543 and/or disable C<RaiseError>.
 544
 545 =item auto_savepoint
 546
 547 If this option is true, L<DBIx::Class> will use savepoints when nesting
 548 transactions, making it possible to recover from failure in the inner
 549 transaction without having to abort all outer transactions.
 550
 551 =item cursor_class
 552
 553 Use this argument to supply a cursor class other than the default
 554 L<DBIx::Class::Storage::DBI::Cursor>.
 555
 556 =back
 557
 558 Some real-life examples of arguments to L</connect_info> and
 559 L<DBIx::Class::Schema/connect>
 560
 561   # Simple SQLite connection
 562   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 563
 564   # Connect via subref
 565   ->connect_info([ sub { DBI->connect(...) } ]);
 566
 567   # Connect via subref in hashref
 568   ->connect_info([{
 569     dbh_maker => sub { DBI->connect(...) },
 570     on_connect_do => 'alter session ...',
 571   }]);
 572
 573   # A bit more complicated
 574   ->connect_info(
 575     [
 576       'dbi:Pg:dbname=foo',
 577       'postgres',
 578       'my_pg_password',
 579       { AutoCommit => 1 },
 580       { quote_char => q{"} },
 581     ]
 582   );
 583
 584   # Equivalent to the previous example
 585   ->connect_info(
 586     [
 587       'dbi:Pg:dbname=foo',
 588       'postgres',
 589       'my_pg_password',
 590       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 591     ]
 592   );
 593
 594   # Same, but with hashref as argument
 595   # See parse_connect_info for explanation
 596   ->connect_info(
 597     [{
 598       dsn         => 'dbi:Pg:dbname=foo',
 599       user        => 'postgres',
 600       password    => 'my_pg_password',
 601       AutoCommit  => 1,
 602       quote_char  => q{"},
 603       name_sep    => q{.},
 604     }]
 605   );
 606
 607   # Subref + DBIx::Class-specific connection options
 608   ->connect_info(
 609     [
 610       sub { DBI->connect(...) },
 611       {
 612           quote_char => q{`},
 613           name_sep => q{@},
 614           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 615           disable_sth_caching => 1,
 616       },
 617     ]
 618   );
 619
 620
 621
 622 =cut
 623
 624 sub connect_info {
 625   my ($self, $info) = @_;
 626
 627   return $self->_connect_info if !$info;
 628
 629   $self->_connect_info($info); # copy for _connect_info
 630
 631   $info = $self->_normalize_connect_info($info)
 632     if ref $info eq 'ARRAY';
 633
 634   my %attrs = (
 635     %{ $self->_default_dbi_connect_attributes || {} },
 636     %{ $info->{attributes} || {} },
 637   );
 638
 639   my @args = @{ $info->{arguments} };
 640
 641   if (keys %attrs and ref $args[0] ne 'CODE') {
 642     carp_unique (
 643         'You provided explicit AutoCommit => 0 in your connection_info. '
 644       . 'This is almost universally a bad idea (see the footnotes of '
 645       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 646       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 647       . 'this warning.'
 648     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 649
 650     push @args, \%attrs if keys %attrs;
 651   }
 652
 653   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 654   # OR a single-element coderef-based $dbh factory
 655   $self->_dbi_connect_info(\@args);
 656
 657   # extract the individual storage options
 658   for my $storage_opt (keys %{ $info->{storage_options} }) {
 659     my $value = $info->{storage_options}{$storage_opt};
 660
 661     $self->$storage_opt($value);
 662   }
 663
 664   # Extract the individual sqlmaker options
 665   #
 666   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 667   #  the new set of options
 668   $self->_sql_maker(undef);
 669   $self->_sql_maker_opts({});
 670
 671   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 672     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 673
 674     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 675   }
 676
 677   # FIXME - dirty:
 678   # save attributes in a separate accessor so they are always
 679   # introspectable, even in case of a CODE $dbhmaker
 680   $self->_dbic_connect_attributes (\%attrs);
 681
 682   return $self->_connect_info;
 683 }
 684
 685 sub _dbi_connect_info {
 686   my $self = shift;
 687
 688   return $self->{_dbi_connect_info} = $_[0]
 689     if @_;
 690
 691   my $conninfo = $self->{_dbi_connect_info} || [];
 692
 693   # last ditch effort to grab a DSN
 694   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 695     my @new_conninfo = @$conninfo;
 696     $new_conninfo[0] = $ENV{DBI_DSN};
 697     $conninfo = \@new_conninfo;
 698   }
 699
 700   return $conninfo;
 701 }
 702
 703
 704 sub _normalize_connect_info {
 705   my ($self, $info_arg) = @_;
 706   my %info;
 707
 708   my @args = @$info_arg;  # take a shallow copy for further mutilation
 709
 710   # combine/pre-parse arguments depending on invocation style
 711
 712   my %attrs;
 713   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 714     %attrs = %{ $args[1] || {} };
 715     @args = $args[0];
 716   }
 717   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 718     %attrs = %{$args[0]};
 719     @args = ();
 720     if (my $code = delete $attrs{dbh_maker}) {
 721       @args = $code;
 722
 723       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 724       if (@ignored) {
 725         carp sprintf (
 726             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 727           . "to the result of 'dbh_maker'",
 728
 729           join (', ', map { "'$_'" } (@ignored) ),
 730         );
 731       }
 732     }
 733     else {
 734       @args = delete @attrs{qw/dsn user password/};
 735     }
 736   }
 737   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 738     %attrs = (
 739       % { $args[3] || {} },
 740       % { $args[4] || {} },
 741     );
 742     @args = @args[0,1,2];
 743   }
 744
 745   $info{arguments} = \@args;
 746
 747   my @storage_opts = grep exists $attrs{$_},
 748     @storage_options, 'cursor_class';
 749
 750   @{ $info{storage_options} }{@storage_opts} =
 751     delete @attrs{@storage_opts} if @storage_opts;
 752
 753   my @sql_maker_opts = grep exists $attrs{$_},
 754     qw/limit_dialect quote_char name_sep quote_names/;
 755
 756   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 757     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 758
 759   $info{attributes} = \%attrs if %attrs;
 760
 761   return \%info;
 762 }
 763
 764 sub _default_dbi_connect_attributes () {
 765   +{
 766     AutoCommit => 1,
 767     PrintError => 0,
 768     RaiseError => 1,
 769     ShowErrorStatement => 1,
 770   };
 771 }
 772
 773 =head2 on_connect_do
 774
 775 This method is deprecated in favour of setting via L</connect_info>.
 776
 777 =cut
 778
 779 =head2 on_disconnect_do
 780
 781 This method is deprecated in favour of setting via L</connect_info>.
 782
 783 =cut
 784
 785 sub _parse_connect_do {
 786   my ($self, $type) = @_;
 787
 788   my $val = $self->$type;
 789   return () if not defined $val;
 790
 791   my @res;
 792
 793   if (not ref($val)) {
 794     push @res, [ 'do_sql', $val ];
 795   } elsif (ref($val) eq 'CODE') {
 796     push @res, $val;
 797   } elsif (ref($val) eq 'ARRAY') {
 798     push @res, map { [ 'do_sql', $_ ] } @$val;
 799   } else {
 800     $self->throw_exception("Invalid type for $type: ".ref($val));
 801   }
 802
 803   return \@res;
 804 }
 805
 806 =head2 dbh_do
 807
 808 Arguments: ($subref | $method_name), @extra_coderef_args?
 809
 810 Execute the given $subref or $method_name using the new exception-based
 811 connection management.
 812
 813 The first two arguments will be the storage object that C<dbh_do> was called
 814 on and a database handle to use.  Any additional arguments will be passed
 815 verbatim to the called subref as arguments 2 and onwards.
 816
 817 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 818 exception handling and reconnection (or failover in future subclasses).
 819
 820 Your subref should have no side-effects outside of the database, as
 821 there is the potential for your subref to be partially double-executed
 822 if the database connection was stale/dysfunctional.
 823
 824 Example:
 825
 826   my @stuff = $schema->storage->dbh_do(
 827     sub {
 828       my ($storage, $dbh, @cols) = @_;
 829       my $cols = join(q{, }, @cols);
 830       $dbh->selectrow_array("SELECT $cols FROM foo");
 831     },
 832     @column_list
 833   );
 834
 835 =cut
 836
 837 sub dbh_do {
 838   my $self = shift;
 839   my $run_target = shift; # either a coderef or a method name
 840
 841   # short circuit when we know there is no need for a runner
 842   #
 843   # FIXME - assumption may be wrong
 844   # the rationale for the txn_depth check is that if this block is a part
 845   # of a larger transaction, everything up to that point is screwed anyway
 846   return $self->$run_target($self->_get_dbh, @_)
 847     if $self->{_in_do_block} or $self->transaction_depth;
 848
 849   # take a ref instead of a copy, to preserve @_ aliasing
 850   # semantics within the coderef, but only if needed
 851   # (pseudoforking doesn't like this trick much)
 852   my $args = @_ ? \@_ : [];
 853
 854   DBIx::Class::Storage::BlockRunner->new(
 855     storage => $self,
 856     wrap_txn => 0,
 857     retry_handler => sub {
 858       $_[0]->failed_attempt_count == 1
 859         and
 860       ! $_[0]->storage->connected
 861     },
 862   )->run(sub {
 863     $self->$run_target ($self->_get_dbh, @$args )
 864   });
 865 }
 866
 867 sub txn_do {
 868   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 869   shift->next::method(@_);
 870 }
 871
 872 =head2 disconnect
 873
 874 Our C<disconnect> method also performs a rollback first if the
 875 database is not in C<AutoCommit> mode.
 876
 877 =cut
 878
 879 sub disconnect {
 880   my ($self) = @_;
 881
 882   if( $self->_dbh ) {
 883     my @actions;
 884
 885     push @actions, ( $self->on_disconnect_call || () );
 886     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 887
 888     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 889
 890     # stops the "implicit rollback on disconnect" warning
 891     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 892
 893     %{ $self->_dbh->{CachedKids} } = ();
 894     $self->_dbh->disconnect;
 895     $self->_dbh(undef);
 896   }
 897 }
 898
 899 =head2 with_deferred_fk_checks
 900
 901 =over 4
 902
 903 =item Arguments: C<$coderef>
 904
 905 =item Return Value: The return value of $coderef
 906
 907 =back
 908
 909 Storage specific method to run the code ref with FK checks deferred or
 910 in MySQL's case disabled entirely.
 911
 912 =cut
 913
 914 # Storage subclasses should override this
 915 sub with_deferred_fk_checks {
 916   my ($self, $sub) = @_;
 917   $sub->();
 918 }
 919
 920 =head2 connected
 921
 922 =over
 923
 924 =item Arguments: none
 925
 926 =item Return Value: 1|0
 927
 928 =back
 929
 930 Verifies that the current database handle is active and ready to execute
 931 an SQL statement (e.g. the connection did not get stale, server is still
 932 answering, etc.) This method is used internally by L</dbh>.
 933
 934 =cut
 935
 936 sub connected {
 937   my $self = shift;
 938   return 0 unless $self->_seems_connected;
 939
 940   #be on the safe side
 941   local $self->_dbh->{RaiseError} = 1;
 942
 943   return $self->_ping;
 944 }
 945
 946 sub _seems_connected {
 947   my $self = shift;
 948
 949   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 950
 951   my $dbh = $self->_dbh
 952     or return 0;
 953
 954   return $dbh->FETCH('Active');
 955 }
 956
 957 sub _ping {
 958   my $self = shift;
 959
 960   my $dbh = $self->_dbh or return 0;
 961
 962   return $dbh->ping;
 963 }
 964
 965 sub ensure_connected {
 966   my ($self) = @_;
 967
 968   unless ($self->connected) {
 969     $self->_populate_dbh;
 970   }
 971 }
 972
 973 =head2 dbh
 974
 975 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 976 is guaranteed to be healthy by implicitly calling L</connected>, and if
 977 necessary performing a reconnection before returning. Keep in mind that this
 978 is very B<expensive> on some database engines. Consider using L</dbh_do>
 979 instead.
 980
 981 =cut
 982
 983 sub dbh {
 984   my ($self) = @_;
 985
 986   if (not $self->_dbh) {
 987     $self->_populate_dbh;
 988   } else {
 989     $self->ensure_connected;
 990   }
 991   return $self->_dbh;
 992 }
 993
 994 # this is the internal "get dbh or connect (don't check)" method
 995 sub _get_dbh {
 996   my $self = shift;
 997   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 998   $self->_populate_dbh unless $self->_dbh;
 999   return $self->_dbh;
1000 }
1001
1002 # *DELIBERATELY* not a setter (for the time being)
1003 # Too intertwined with everything else for any kind of sanity
1004 sub sql_maker {
1005   my $self = shift;
1006
1007   $self->throw_exception('sql_maker() is not a setter method') if @_;
1008
1009   unless ($self->_sql_maker) {
1010     my $sql_maker_class = $self->sql_maker_class;
1011
1012     my %opts = %{$self->_sql_maker_opts||{}};
1013     my $dialect =
1014       $opts{limit_dialect}
1015         ||
1016       $self->sql_limit_dialect
1017         ||
1018       do {
1019         my $s_class = (ref $self) || $self;
1020         carp_unique (
1021           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1022         . 'have not supplied an explicit limit_dialect in your connection_info. '
1023         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1024         . 'databases but can be (and often is) painfully slow. '
1025         . "Please file an RT ticket against '$s_class'"
1026         ) if $self->_dbi_connect_info->[0];
1027
1028         'GenericSubQ';
1029       }
1030     ;
1031
1032     my ($quote_char, $name_sep);
1033
1034     if ($opts{quote_names}) {
1035       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1036         my $s_class = (ref $self) || $self;
1037         carp_unique (
1038           "You requested 'quote_names' but your storage class ($s_class) does "
1039         . 'not explicitly define a default sql_quote_char and you have not '
1040         . 'supplied a quote_char as part of your connection_info. DBIC will '
1041         .q{default to the ANSI SQL standard quote '"', which works most of }
1042         . "the time. Please file an RT ticket against '$s_class'."
1043         );
1044
1045         '"'; # RV
1046       };
1047
1048       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1049     }
1050
1051     $self->_sql_maker($sql_maker_class->new(
1052       bindtype=>'columns',
1053       array_datatypes => 1,
1054       limit_dialect => $dialect,
1055       ($quote_char ? (quote_char => $quote_char) : ()),
1056       name_sep => ($name_sep || '.'),
1057       %opts,
1058     ));
1059   }
1060   return $self->_sql_maker;
1061 }
1062
1063 # nothing to do by default
1064 sub _rebless {}
1065 sub _init {}
1066
1067 sub _populate_dbh {
1068   my ($self) = @_;
1069
1070   $self->_dbh(undef); # in case ->connected failed we might get sent here
1071   $self->_dbh_details({}); # reset everything we know
1072   $self->_sql_maker(undef); # this may also end up being different
1073
1074   $self->_dbh($self->_connect);
1075
1076   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1077
1078   $self->_determine_driver;
1079
1080   # Always set the transaction depth on connect, since
1081   #  there is no transaction in progress by definition
1082   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1083
1084   $self->_run_connection_actions unless $self->{_in_determine_driver};
1085 }
1086
1087 sub _run_connection_actions {
1088   my $self = shift;
1089   my @actions;
1090
1091   push @actions, ( $self->on_connect_call || () );
1092   push @actions, $self->_parse_connect_do ('on_connect_do');
1093
1094   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1095 }
1096
1097
1098
1099 sub set_use_dbms_capability {
1100   $_[0]->set_inherited ($_[1], $_[2]);
1101 }
1102
1103 sub get_use_dbms_capability {
1104   my ($self, $capname) = @_;
1105
1106   my $use = $self->get_inherited ($capname);
1107   return defined $use
1108     ? $use
1109     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1110   ;
1111 }
1112
1113 sub set_dbms_capability {
1114   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1115 }
1116
1117 sub get_dbms_capability {
1118   my ($self, $capname) = @_;
1119
1120   my $cap = $self->_dbh_details->{capability}{$capname};
1121
1122   unless (defined $cap) {
1123     if (my $meth = $self->can ("_determine$capname")) {
1124       $cap = $self->$meth ? 1 : 0;
1125     }
1126     else {
1127       $cap = 0;
1128     }
1129
1130     $self->set_dbms_capability ($capname, $cap);
1131   }
1132
1133   return $cap;
1134 }
1135
1136 sub _server_info {
1137   my $self = shift;
1138
1139   my $info;
1140   unless ($info = $self->_dbh_details->{info}) {
1141
1142     $info = {};
1143
1144     my $server_version = try {
1145       $self->_get_server_version
1146     } catch {
1147       # driver determination *may* use this codepath
1148       # in which case we must rethrow
1149       $self->throw_exception($_) if $self->{_in_determine_driver};
1150
1151       # $server_version on failure
1152       undef;
1153     };
1154
1155     if (defined $server_version) {
1156       $info->{dbms_version} = $server_version;
1157
1158       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1159       my @verparts = split (/\./, $numeric_version);
1160       if (
1161         @verparts
1162           &&
1163         $verparts[0] <= 999
1164       ) {
1165         # consider only up to 3 version parts, iff not more than 3 digits
1166         my @use_parts;
1167         while (@verparts && @use_parts < 3) {
1168           my $p = shift @verparts;
1169           last if $p > 999;
1170           push @use_parts, $p;
1171         }
1172         push @use_parts, 0 while @use_parts < 3;
1173
1174         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1175       }
1176     }
1177
1178     $self->_dbh_details->{info} = $info;
1179   }
1180
1181   return $info;
1182 }
1183
1184 sub _get_server_version {
1185   shift->_dbh_get_info('SQL_DBMS_VER');
1186 }
1187
1188 sub _dbh_get_info {
1189   my ($self, $info) = @_;
1190
1191   if ($info =~ /[^0-9]/) {
1192     require DBI::Const::GetInfoType;
1193     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1194     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1195       unless defined $info;
1196   }
1197
1198   $self->_get_dbh->get_info($info);
1199 }
1200
1201 sub _describe_connection {
1202   require DBI::Const::GetInfoReturn;
1203
1204   my $self = shift;
1205
1206   my $drv;
1207   try {
1208     $drv = $self->_extract_driver_from_connect_info;
1209     $self->ensure_connected;
1210   };
1211
1212   $drv = "DBD::$drv" if $drv;
1213
1214   my $res = {
1215     DBIC_DSN => $self->_dbi_connect_info->[0],
1216     DBI_VER => DBI->VERSION,
1217     DBIC_VER => DBIx::Class->VERSION,
1218     DBIC_DRIVER => ref $self,
1219     $drv ? (
1220       DBD => $drv,
1221       DBD_VER => try { $drv->VERSION },
1222     ) : (),
1223   };
1224
1225   # try to grab data even if we never managed to connect
1226   # will cover us in cases of an oddly broken half-connect
1227   for my $inf (
1228     #keys %DBI::Const::GetInfoType::GetInfoType,
1229     qw/
1230       SQL_CURSOR_COMMIT_BEHAVIOR
1231       SQL_CURSOR_ROLLBACK_BEHAVIOR
1232       SQL_CURSOR_SENSITIVITY
1233       SQL_DATA_SOURCE_NAME
1234       SQL_DBMS_NAME
1235       SQL_DBMS_VER
1236       SQL_DEFAULT_TXN_ISOLATION
1237       SQL_DM_VER
1238       SQL_DRIVER_NAME
1239       SQL_DRIVER_ODBC_VER
1240       SQL_DRIVER_VER
1241       SQL_EXPRESSIONS_IN_ORDERBY
1242       SQL_GROUP_BY
1243       SQL_IDENTIFIER_CASE
1244       SQL_IDENTIFIER_QUOTE_CHAR
1245       SQL_MAX_CATALOG_NAME_LEN
1246       SQL_MAX_COLUMN_NAME_LEN
1247       SQL_MAX_IDENTIFIER_LEN
1248       SQL_MAX_TABLE_NAME_LEN
1249       SQL_MULTIPLE_ACTIVE_TXN
1250       SQL_MULT_RESULT_SETS
1251       SQL_NEED_LONG_DATA_LEN
1252       SQL_NON_NULLABLE_COLUMNS
1253       SQL_ODBC_VER
1254       SQL_QUALIFIER_NAME_SEPARATOR
1255       SQL_QUOTED_IDENTIFIER_CASE
1256       SQL_TXN_CAPABLE
1257       SQL_TXN_ISOLATION_OPTION
1258     /
1259   ) {
1260     # some drivers barf on things they do not know about instead
1261     # of returning undef
1262     my $v = try { $self->_dbh_get_info($inf) };
1263     next unless defined $v;
1264
1265     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1266     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1267     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1268   }
1269
1270   $res;
1271 }
1272
1273 sub _determine_driver {
1274   my ($self) = @_;
1275
1276   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1277     my $started_connected = 0;
1278     local $self->{_in_determine_driver} = 1;
1279
1280     if (ref($self) eq __PACKAGE__) {
1281       my $driver;
1282       if ($self->_dbh) { # we are connected
1283         $driver = $self->_dbh->{Driver}{Name};
1284         $started_connected = 1;
1285       }
1286       else {
1287         $driver = $self->_extract_driver_from_connect_info;
1288       }
1289
1290       if ($driver) {
1291         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1292         if ($self->load_optional_class($storage_class)) {
1293           mro::set_mro($storage_class, 'c3');
1294           bless $self, $storage_class;
1295           $self->_rebless();
1296         }
1297         else {
1298           $self->_warn_undetermined_driver(
1299             'This version of DBIC does not yet seem to supply a driver for '
1300           . "your particular RDBMS and/or connection method ('$driver')."
1301           );
1302         }
1303       }
1304       else {
1305         $self->_warn_undetermined_driver(
1306           'Unable to extract a driver name from connect info - this '
1307         . 'should not have happened.'
1308         );
1309       }
1310     }
1311
1312     $self->_driver_determined(1);
1313
1314     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1315
1316     if ($self->can('source_bind_attributes')) {
1317       $self->throw_exception(
1318         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1319       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1320       . 'If you are not sure how to proceed please contact the development team via '
1321       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1322       );
1323     }
1324
1325     $self->_init; # run driver-specific initializations
1326
1327     $self->_run_connection_actions
1328         if !$started_connected && defined $self->_dbh;
1329   }
1330 }
1331
1332 sub _extract_driver_from_connect_info {
1333   my $self = shift;
1334
1335   my $drv;
1336
1337   # if connect_info is a CODEREF, we have no choice but to connect
1338   if (
1339     ref $self->_dbi_connect_info->[0]
1340       and
1341     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1342   ) {
1343     $self->_populate_dbh;
1344     $drv = $self->_dbh->{Driver}{Name};
1345   }
1346   else {
1347     # try to use dsn to not require being connected, the driver may still
1348     # force a connection later in _rebless to determine version
1349     # (dsn may not be supplied at all if all we do is make a mock-schema)
1350     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1351     $drv ||= $ENV{DBI_DRIVER};
1352   }
1353
1354   return $drv;
1355 }
1356
1357 sub _determine_connector_driver {
1358   my ($self, $conn) = @_;
1359
1360   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1361
1362   if (not $dbtype) {
1363     $self->_warn_undetermined_driver(
1364       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1365     . "$conn connector - this should not have happened."
1366     );
1367     return;
1368   }
1369
1370   $dbtype =~ s/\W/_/gi;
1371
1372   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1373   return if $self->isa($subclass);
1374
1375   if ($self->load_optional_class($subclass)) {
1376     bless $self, $subclass;
1377     $self->_rebless;
1378   }
1379   else {
1380     $self->_warn_undetermined_driver(
1381       'This version of DBIC does not yet seem to supply a driver for '
1382     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1383     );
1384   }
1385 }
1386
1387 sub _warn_undetermined_driver {
1388   my ($self, $msg) = @_;
1389
1390   require Data::Dumper::Concise;
1391
1392   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1393   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1394   . "does not go away, file a bugreport including the following info:\n"
1395   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1396   );
1397 }
1398
1399 sub _do_connection_actions {
1400   my $self          = shift;
1401   my $method_prefix = shift;
1402   my $call          = shift;
1403
1404   if (not ref($call)) {
1405     my $method = $method_prefix . $call;
1406     $self->$method(@_);
1407   } elsif (ref($call) eq 'CODE') {
1408     $self->$call(@_);
1409   } elsif (ref($call) eq 'ARRAY') {
1410     if (ref($call->[0]) ne 'ARRAY') {
1411       $self->_do_connection_actions($method_prefix, $_) for @$call;
1412     } else {
1413       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1414     }
1415   } else {
1416     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1417   }
1418
1419   return $self;
1420 }
1421
1422 sub connect_call_do_sql {
1423   my $self = shift;
1424   $self->_do_query(@_);
1425 }
1426
1427 sub disconnect_call_do_sql {
1428   my $self = shift;
1429   $self->_do_query(@_);
1430 }
1431
1432 # override in db-specific backend when necessary
1433 sub connect_call_datetime_setup { 1 }
1434
1435 sub _do_query {
1436   my ($self, $action) = @_;
1437
1438   if (ref $action eq 'CODE') {
1439     $action = $action->($self);
1440     $self->_do_query($_) foreach @$action;
1441   }
1442   else {
1443     # Most debuggers expect ($sql, @bind), so we need to exclude
1444     # the attribute hash which is the second argument to $dbh->do
1445     # furthermore the bind values are usually to be presented
1446     # as named arrayref pairs, so wrap those here too
1447     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1448     my $sql = shift @do_args;
1449     my $attrs = shift @do_args;
1450     my @bind = map { [ undef, $_ ] } @do_args;
1451
1452     $self->dbh_do(sub {
1453       $_[0]->_query_start($sql, \@bind);
1454       $_[1]->do($sql, $attrs, @do_args);
1455       $_[0]->_query_end($sql, \@bind);
1456     });
1457   }
1458
1459   return $self;
1460 }
1461
1462 sub _connect {
1463   my $self = shift;
1464
1465   my $info = $self->_dbi_connect_info;
1466
1467   $self->throw_exception("You did not provide any connection_info")
1468     unless defined $info->[0];
1469
1470   my ($old_connect_via, $dbh);
1471
1472   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1473
1474   # this odd anonymous coderef dereference is in fact really
1475   # necessary to avoid the unwanted effect described in perl5
1476   # RT#75792
1477   #
1478   # in addition the coderef itself can't reside inside the try{} block below
1479   # as it somehow triggers a leak under perl -d
1480   my $dbh_error_handler_installer = sub {
1481     weaken (my $weak_self = $_[0]);
1482
1483     # the coderef is blessed so we can distinguish it from externally
1484     # supplied handles (which must be preserved)
1485     $_[1]->{HandleError} = bless sub {
1486       if ($weak_self) {
1487         $weak_self->throw_exception("DBI Exception: $_[0]");
1488       }
1489       else {
1490         # the handler may be invoked by something totally out of
1491         # the scope of DBIC
1492         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1493       }
1494     }, '__DBIC__DBH__ERROR__HANDLER__';
1495   };
1496
1497   try {
1498     if(ref $info->[0] eq 'CODE') {
1499       $dbh = $info->[0]->();
1500     }
1501     else {
1502       require DBI;
1503       $dbh = DBI->connect(@$info);
1504     }
1505
1506     die $DBI::errstr unless $dbh;
1507
1508     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1509       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1510       . 'not continue',
1511       ref $info->[0] eq 'CODE'
1512         ? "Connection coderef $info->[0] returned a"
1513         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1514     ) unless $dbh->FETCH('Active');
1515
1516     # sanity checks unless asked otherwise
1517     unless ($self->unsafe) {
1518
1519       $self->throw_exception(
1520         'Refusing clobbering of {HandleError} installed on externally supplied '
1521        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1522       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1523
1524       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1525       # request, or an external handle. Complain and set anyway
1526       unless ($dbh->{RaiseError}) {
1527         carp( ref $info->[0] eq 'CODE'
1528
1529           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1530            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1531            .'attribute has been supplied'
1532
1533           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1534            .'unsafe => 1. Toggling RaiseError back to true'
1535         );
1536
1537         $dbh->{RaiseError} = 1;
1538       }
1539
1540       $dbh_error_handler_installer->($self, $dbh);
1541     }
1542   }
1543   catch {
1544     $self->throw_exception("DBI Connection failed: $_")
1545   };
1546
1547   $self->_dbh_autocommit($dbh->{AutoCommit});
1548   return $dbh;
1549 }
1550
1551 sub txn_begin {
1552   my $self = shift;
1553
1554   # this means we have not yet connected and do not know the AC status
1555   # (e.g. coderef $dbh), need a full-fledged connection check
1556   if (! defined $self->_dbh_autocommit) {
1557     $self->ensure_connected;
1558   }
1559   # Otherwise simply connect or re-connect on pid changes
1560   else {
1561     $self->_get_dbh;
1562   }
1563
1564   $self->next::method(@_);
1565 }
1566
1567 sub _exec_txn_begin {
1568   my $self = shift;
1569
1570   # if the user is utilizing txn_do - good for him, otherwise we need to
1571   # ensure that the $dbh is healthy on BEGIN.
1572   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1573   # will be replaced by a failure of begin_work itself (which will be
1574   # then retried on reconnect)
1575   if ($self->{_in_do_block}) {
1576     $self->_dbh->begin_work;
1577   } else {
1578     $self->dbh_do(sub { $_[1]->begin_work });
1579   }
1580 }
1581
1582 sub txn_commit {
1583   my $self = shift;
1584
1585   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1586   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1587     unless $self->_dbh;
1588
1589   # esoteric case for folks using external $dbh handles
1590   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1591     carp "Storage transaction_depth 0 does not match "
1592         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1593     $self->transaction_depth(1);
1594   }
1595
1596   $self->next::method(@_);
1597
1598   # if AutoCommit is disabled txn_depth never goes to 0
1599   # as a new txn is started immediately on commit
1600   $self->transaction_depth(1) if (
1601     !$self->transaction_depth
1602       and
1603     defined $self->_dbh_autocommit
1604       and
1605     ! $self->_dbh_autocommit
1606   );
1607 }
1608
1609 sub _exec_txn_commit {
1610   shift->_dbh->commit;
1611 }
1612
1613 sub txn_rollback {
1614   my $self = shift;
1615
1616   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1617   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1618     unless $self->_dbh;
1619
1620   # esoteric case for folks using external $dbh handles
1621   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1622     carp "Storage transaction_depth 0 does not match "
1623         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1624     $self->transaction_depth(1);
1625   }
1626
1627   $self->next::method(@_);
1628
1629   # if AutoCommit is disabled txn_depth never goes to 0
1630   # as a new txn is started immediately on commit
1631   $self->transaction_depth(1) if (
1632     !$self->transaction_depth
1633       and
1634     defined $self->_dbh_autocommit
1635       and
1636     ! $self->_dbh_autocommit
1637   );
1638 }
1639
1640 sub _exec_txn_rollback {
1641   shift->_dbh->rollback;
1642 }
1643
1644 # generate some identical methods
1645 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1646   no strict qw/refs/;
1647   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1648     my $self = shift;
1649     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1650     $self->throw_exception("Unable to $meth() on a disconnected storage")
1651       unless $self->_dbh;
1652     $self->next::method(@_);
1653   };
1654 }
1655
1656 # This used to be the top-half of _execute.  It was split out to make it
1657 #  easier to override in NoBindVars without duping the rest.  It takes up
1658 #  all of _execute's args, and emits $sql, @bind.
1659 sub _prep_for_execute {
1660   #my ($self, $op, $ident, $args) = @_;
1661   return shift->_gen_sql_bind(@_)
1662 }
1663
1664 sub _gen_sql_bind {
1665   my ($self, $op, $ident, $args) = @_;
1666
1667   my ($colinfos, $from);
1668   if ( blessed($ident) ) {
1669     $from = $ident->from;
1670     $colinfos = $ident->columns_info;
1671   }
1672
1673   my ($sql, $bind);
1674   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1675
1676   $bind = $self->_resolve_bindattrs(
1677     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1678   );
1679
1680   if (
1681     ! $ENV{DBIC_DT_SEARCH_OK}
1682       and
1683     $op eq 'select'
1684       and
1685     first {
1686       length ref $_->[1]
1687         and
1688       blessed($_->[1])
1689         and
1690       $_->[1]->isa('DateTime')
1691     } @$bind
1692   ) {
1693     carp_unique 'DateTime objects passed to search() are not supported '
1694       . 'properly (InflateColumn::DateTime formats and settings are not '
1695       . 'respected.) See "Formatting DateTime objects in queries" in '
1696       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1697       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1698   }
1699
1700   return( $sql, $bind );
1701 }
1702
1703 sub _resolve_bindattrs {
1704   my ($self, $ident, $bind, $colinfos) = @_;
1705
1706   $colinfos ||= {};
1707
1708   my $resolve_bindinfo = sub {
1709     #my $infohash = shift;
1710
1711     %$colinfos = %{ $self->_resolve_column_info($ident) }
1712       unless keys %$colinfos;
1713
1714     my $ret;
1715     if (my $col = $_[0]->{dbic_colname}) {
1716       $ret = { %{$_[0]} };
1717
1718       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1719         if $colinfos->{$col}{data_type};
1720
1721       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1722         if $colinfos->{$col}{size};
1723     }
1724
1725     $ret || $_[0];
1726   };
1727
1728   return [ map {
1729     my $resolved =
1730       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1731     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1732     : (ref $_->[0] eq 'HASH')           ? [ (exists $_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype})
1733                                               ? $_->[0]
1734                                               : $resolve_bindinfo->($_->[0])
1735                                             , $_->[1] ]
1736     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1737     :                                     [ $resolve_bindinfo->(
1738                                               { dbic_colname => $_->[0] }
1739                                             ), $_->[1] ]
1740     ;
1741
1742     if (
1743       ! exists $resolved->[0]{dbd_attrs}
1744         and
1745       ! $resolved->[0]{sqlt_datatype}
1746         and
1747       length ref $resolved->[1]
1748         and
1749       ! overload::Method($resolved->[1], '""')
1750     ) {
1751       require Data::Dumper;
1752       local $Data::Dumper::Maxdepth = 1;
1753       local $Data::Dumper::Terse = 1;
1754       local $Data::Dumper::Useqq = 1;
1755       local $Data::Dumper::Indent = 0;
1756       local $Data::Dumper::Pad = ' ';
1757       $self->throw_exception(
1758         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1759       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1760       );
1761     }
1762
1763     $resolved;
1764
1765   } @$bind ];
1766 }
1767
1768 sub _format_for_trace {
1769   #my ($self, $bind) = @_;
1770
1771   ### Turn @bind from something like this:
1772   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1773   ### to this:
1774   ###   ( "'1'", "'3'" )
1775
1776   map {
1777     defined( $_ && $_->[1] )
1778       ? qq{'$_->[1]'}
1779       : q{NULL}
1780   } @{$_[1] || []};
1781 }
1782
1783 sub _query_start {
1784   my ( $self, $sql, $bind ) = @_;
1785
1786   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1787     if $self->debug;
1788 }
1789
1790 sub _query_end {
1791   my ( $self, $sql, $bind ) = @_;
1792
1793   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1794     if $self->debug;
1795 }
1796
1797 sub _dbi_attrs_for_bind {
1798   my ($self, $ident, $bind) = @_;
1799
1800   my @attrs;
1801
1802   for (map { $_->[0] } @$bind) {
1803     push @attrs, do {
1804       if (exists $_->{dbd_attrs}) {
1805         $_->{dbd_attrs}
1806       }
1807       elsif($_->{sqlt_datatype}) {
1808         # cache the result in the dbh_details hash, as it can not change unless
1809         # we connect to something else
1810         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1811         if (not exists $cache->{$_->{sqlt_datatype}}) {
1812           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1813         }
1814         $cache->{$_->{sqlt_datatype}};
1815       }
1816       else {
1817         undef;  # always push something at this position
1818       }
1819     }
1820   }
1821
1822   return \@attrs;
1823 }
1824
1825 sub _execute {
1826   my ($self, $op, $ident, @args) = @_;
1827
1828   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1829
1830   # not even a PID check - we do not care about the state of the _dbh.
1831   # All we need is to get the appropriate drivers loaded if they aren't
1832   # already so that the assumption in ad7c50fc26e holds
1833   $self->_populate_dbh unless $self->_dbh;
1834
1835   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1836     $sql,
1837     $bind,
1838     $self->_dbi_attrs_for_bind($ident, $bind),
1839   );
1840 }
1841
1842 sub _dbh_execute {
1843   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1844
1845   $self->_query_start( $sql, $bind );
1846
1847   my $sth = $self->_bind_sth_params(
1848     $self->_prepare_sth($dbh, $sql),
1849     $bind,
1850     $bind_attrs,
1851   );
1852
1853   # Can this fail without throwing an exception anyways???
1854   my $rv = $sth->execute();
1855   $self->throw_exception(
1856     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1857   ) if !$rv;
1858
1859   $self->_query_end( $sql, $bind );
1860
1861   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1862 }
1863
1864 sub _prepare_sth {
1865   my ($self, $dbh, $sql) = @_;
1866
1867   # 3 is the if_active parameter which avoids active sth re-use
1868   my $sth = $self->disable_sth_caching
1869     ? $dbh->prepare($sql)
1870     : $dbh->prepare_cached($sql, {}, 3);
1871
1872   # XXX You would think RaiseError would make this impossible,
1873   #  but apparently that's not true :(
1874   $self->throw_exception(
1875     $dbh->errstr
1876       ||
1877     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1878             .'an exception and/or setting $dbh->errstr',
1879       length ($sql) > 20
1880         ? substr($sql, 0, 20) . '...'
1881         : $sql
1882       ,
1883       'DBD::' . $dbh->{Driver}{Name},
1884     )
1885   ) if !$sth;
1886
1887   $sth;
1888 }
1889
1890 sub _bind_sth_params {
1891   my ($self, $sth, $bind, $bind_attrs) = @_;
1892
1893   for my $i (0 .. $#$bind) {
1894     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1895       $sth->bind_param_inout(
1896         $i + 1, # bind params counts are 1-based
1897         $bind->[$i][1],
1898         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1899         $bind_attrs->[$i],
1900       );
1901     }
1902     else {
1903       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1904       # confirm with dbi-dev whether explicit stringification is needed
1905       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1906         ? "$bind->[$i][1]"
1907         : $bind->[$i][1]
1908       ;
1909       $sth->bind_param(
1910         $i + 1,
1911         $v,
1912         $bind_attrs->[$i],
1913       );
1914     }
1915   }
1916
1917   $sth;
1918 }
1919
1920 sub _prefetch_autovalues {
1921   my ($self, $source, $colinfo, $to_insert) = @_;
1922
1923   my %values;
1924   for my $col (keys %$colinfo) {
1925     if (
1926       $colinfo->{$col}{auto_nextval}
1927         and
1928       (
1929         ! exists $to_insert->{$col}
1930           or
1931         ref $to_insert->{$col} eq 'SCALAR'
1932           or
1933         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1934       )
1935     ) {
1936       $values{$col} = $self->_sequence_fetch(
1937         'NEXTVAL',
1938         ( $colinfo->{$col}{sequence} ||=
1939             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1940         ),
1941       );
1942     }
1943   }
1944
1945   \%values;
1946 }
1947
1948 sub insert {
1949   my ($self, $source, $to_insert) = @_;
1950
1951   my $col_infos = $source->columns_info;
1952
1953   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1954
1955   # fuse the values, but keep a separate list of prefetched_values so that
1956   # they can be fused once again with the final return
1957   $to_insert = { %$to_insert, %$prefetched_values };
1958
1959   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1960   # Investigate what does it take to s/defined/exists/
1961   my %pcols = map { $_ => 1 } $source->primary_columns;
1962   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1963   for my $col ($source->columns) {
1964     if ($col_infos->{$col}{is_auto_increment}) {
1965       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1966       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1967     }
1968
1969     # nothing to retrieve when explicit values are supplied
1970     next if (defined $to_insert->{$col} and ! (
1971       ref $to_insert->{$col} eq 'SCALAR'
1972         or
1973       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1974     ));
1975
1976     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1977     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1978       $pcols{$col}
1979         or
1980       $col_infos->{$col}{retrieve_on_insert}
1981     );
1982   };
1983
1984   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1985   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1986
1987   my ($sqla_opts, @ir_container);
1988   if (%retrieve_cols and $self->_use_insert_returning) {
1989     $sqla_opts->{returning_container} = \@ir_container
1990       if $self->_use_insert_returning_bound;
1991
1992     $sqla_opts->{returning} = [
1993       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1994     ];
1995   }
1996
1997   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1998
1999   my %returned_cols = %$to_insert;
2000   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2001     @ir_container = try {
2002       local $SIG{__WARN__} = sub {};
2003       my @r = $sth->fetchrow_array;
2004       $sth->finish;
2005       @r;
2006     } unless @ir_container;
2007
2008     @returned_cols{@$retlist} = @ir_container if @ir_container;
2009   }
2010   else {
2011     # pull in PK if needed and then everything else
2012     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2013
2014       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2015         unless $self->can('last_insert_id');
2016
2017       my @pri_values = $self->last_insert_id($source, @missing_pri);
2018
2019       $self->throw_exception( "Can't get last insert id" )
2020         unless (@pri_values == @missing_pri);
2021
2022       @returned_cols{@missing_pri} = @pri_values;
2023       delete @retrieve_cols{@missing_pri};
2024     }
2025
2026     # if there is more left to pull
2027     if (%retrieve_cols) {
2028       $self->throw_exception(
2029         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2030       ) unless %pcols;
2031
2032       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2033
2034       my $cur = DBIx::Class::ResultSet->new($source, {
2035         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2036         select => \@left_to_fetch,
2037       })->cursor;
2038
2039       @returned_cols{@left_to_fetch} = $cur->next;
2040
2041       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2042         if scalar $cur->next;
2043     }
2044   }
2045
2046   return { %$prefetched_values, %returned_cols };
2047 }
2048
2049 sub insert_bulk {
2050   my ($self, $source, $cols, $data) = @_;
2051
2052   my @col_range = (0..$#$cols);
2053
2054   # FIXME SUBOPTIMAL - most likely this is not necessary at all
2055   # confirm with dbi-dev whether explicit stringification is needed
2056   #
2057   # forcibly stringify whatever is stringifiable
2058   # ResultSet::populate() hands us a copy - safe to mangle
2059   for my $r (0 .. $#$data) {
2060     for my $c (0 .. $#{$data->[$r]}) {
2061       $data->[$r][$c] = "$data->[$r][$c]"
2062         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
2063     }
2064   }
2065
2066   my $colinfos = $source->columns_info($cols);
2067
2068   local $self->{_autoinc_supplied_for_op} =
2069     (first { $_->{is_auto_increment} } values %$colinfos)
2070       ? 1
2071       : 0
2072   ;
2073
2074   # get a slice type index based on first row of data
2075   # a "column" in this context may refer to more than one bind value
2076   # e.g. \[ '?, ?', [...], [...] ]
2077   #
2078   # construct the value type index - a description of values types for every
2079   # per-column slice of $data:
2080   #
2081   # nonexistent - nonbind literal
2082   # 0 - regular value
2083   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2084   #
2085   # also construct the column hash to pass to the SQL generator. For plain
2086   # (non literal) values - convert the members of the first row into a
2087   # literal+bind combo, with extra positional info in the bind attr hashref.
2088   # This will allow us to match the order properly, and is so contrived
2089   # because a user-supplied literal/bind (or something else specific to a
2090   # resultsource and/or storage driver) can inject extra binds along the
2091   # way, so one can't rely on "shift positions" ordering at all. Also we
2092   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2093   # can be later matched up by address), because we want to supply a real
2094   # value on which perhaps e.g. datatype checks will be performed
2095   my ($proto_data, $value_type_by_col_idx);
2096   for my $i (@col_range) {
2097     my $colname = $cols->[$i];
2098     if (ref $data->[0][$i] eq 'SCALAR') {
2099       # no bind value at all - no type
2100
2101       $proto_data->{$colname} = $data->[0][$i];
2102     }
2103     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
2104       # repack, so we don't end up mangling the original \[]
2105       my ($sql, @bind) = @${$data->[0][$i]};
2106
2107       # normalization of user supplied stuff
2108       my $resolved_bind = $self->_resolve_bindattrs(
2109         $source, \@bind, $colinfos,
2110       );
2111
2112       # store value-less (attrs only) bind info - we will be comparing all
2113       # supplied binds against this for sanity
2114       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
2115
2116       $proto_data->{$colname} = \[ $sql, map { [
2117         # inject slice order to use for $proto_bind construction
2118           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
2119             =>
2120           $resolved_bind->[$_][1]
2121         ] } (0 .. $#bind)
2122       ];
2123     }
2124     else {
2125       $value_type_by_col_idx->{$i} = undef;
2126
2127       $proto_data->{$colname} = \[ '?', [
2128         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2129           =>
2130         $data->[0][$i]
2131       ] ];
2132     }
2133   }
2134
2135   my ($sql, $proto_bind) = $self->_prep_for_execute (
2136     'insert',
2137     $source,
2138     [ $proto_data ],
2139   );
2140
2141   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2142     # if the bindlist is empty and we had some dynamic binds, this means the
2143     # storage ate them away (e.g. the NoBindVars component) and interpolated
2144     # them directly into the SQL. This obviously can't be good for multi-inserts
2145     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2146   }
2147
2148   # sanity checks
2149   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2150   #
2151   # use an error reporting closure for convenience (less to pass)
2152   my $bad_slice_report_cref = sub {
2153     my ($msg, $r_idx, $c_idx) = @_;
2154     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2155       $msg,
2156       $cols->[$c_idx],
2157       do {
2158         require Data::Dumper::Concise;
2159         local $Data::Dumper::Maxdepth = 5;
2160         Data::Dumper::Concise::Dumper ({
2161           map { $cols->[$_] =>
2162             $data->[$r_idx][$_]
2163           } @col_range
2164         }),
2165       }
2166     );
2167   };
2168
2169   for my $col_idx (@col_range) {
2170     my $reference_val = $data->[0][$col_idx];
2171
2172     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2173       my $val = $data->[$row_idx][$col_idx];
2174
2175       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2176         if (ref $val ne 'SCALAR') {
2177           $bad_slice_report_cref->(
2178             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2179             $row_idx,
2180             $col_idx,
2181           );
2182         }
2183         elsif ($$val ne $$reference_val) {
2184           $bad_slice_report_cref->(
2185             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2186             $row_idx,
2187             $col_idx,
2188           );
2189         }
2190       }
2191       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2192         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2193           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2194         }
2195       }
2196       else {  # binds from a \[], compare type and attrs
2197         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2198           $bad_slice_report_cref->(
2199             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2200             $row_idx,
2201             $col_idx,
2202           );
2203         }
2204         # start drilling down and bail out early on identical refs
2205         elsif (
2206           $reference_val != $val
2207             or
2208           $$reference_val != $$val
2209         ) {
2210           if (${$val}->[0] ne ${$reference_val}->[0]) {
2211             $bad_slice_report_cref->(
2212               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2213               $row_idx,
2214               $col_idx,
2215             );
2216           }
2217           # need to check the bind attrs - a bind will happen only once for
2218           # the entire dataset, so any changes further down will be ignored.
2219           elsif (! Data::Compare::Compare(
2220             $value_type_by_col_idx->{$col_idx},
2221             [
2222               map
2223               { $_->[0] }
2224               @{$self->_resolve_bindattrs(
2225                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2226               )}
2227             ],
2228           )) {
2229             $bad_slice_report_cref->(
2230               'Differing bind attributes on literal/bind values not supported',
2231               $row_idx,
2232               $col_idx,
2233             );
2234           }
2235         }
2236       }
2237     }
2238   }
2239
2240   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2241   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2242   # scope guard
2243   my $guard = $self->txn_scope_guard;
2244
2245   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2246   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2247   my $rv = do {
2248     if (@$proto_bind) {
2249       # proto bind contains the information on which pieces of $data to pull
2250       # $cols is passed in only for prettier error-reporting
2251       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2252     }
2253     else {
2254       # bind_param_array doesn't work if there are no binds
2255       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2256     }
2257   };
2258
2259   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2260
2261   $guard->commit;
2262
2263   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2264 }
2265
2266 # execute_for_fetch is capable of returning data just fine (it means it
2267 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2268 # is the void-populate fast-path we will just ignore this altogether
2269 # for the time being.
2270 sub _dbh_execute_for_fetch {
2271   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2272
2273   my @idx_range = ( 0 .. $#$proto_bind );
2274
2275   # If we have any bind attributes to take care of, we will bind the
2276   # proto-bind data (which will never be used by execute_for_fetch)
2277   # However since column bindtypes are "sticky", this is sufficient
2278   # to get the DBD to apply the bindtype to all values later on
2279
2280   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2281
2282   for my $i (@idx_range) {
2283     $sth->bind_param (
2284       $i+1, # DBI bind indexes are 1-based
2285       $proto_bind->[$i][1],
2286       $bind_attrs->[$i],
2287     ) if defined $bind_attrs->[$i];
2288   }
2289
2290   # At this point $data slots named in the _bind_data_slice_idx of
2291   # each piece of $proto_bind are either \[]s or plain values to be
2292   # passed in. Construct the dispensing coderef. *NOTE* the order
2293   # of $data will differ from this of the ?s in the SQL (due to
2294   # alphabetical ordering by colname). We actually do want to
2295   # preserve this behavior so that prepare_cached has a better
2296   # chance of matching on unrelated calls
2297
2298   my $fetch_row_idx = -1; # saner loop this way
2299   my $fetch_tuple = sub {
2300     return undef if ++$fetch_row_idx > $#$data;
2301
2302     return [ map { defined $_->{_literal_bind_subindex}
2303       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2304          ->[ $_->{_literal_bind_subindex} ]
2305           ->[1]
2306       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2307     } map { $_->[0] } @$proto_bind];
2308   };
2309
2310   my $tuple_status = [];
2311   my ($rv, $err);
2312   try {
2313     $rv = $sth->execute_for_fetch(
2314       $fetch_tuple,
2315       $tuple_status,
2316     );
2317   }
2318   catch {
2319     $err = shift;
2320   };
2321
2322   # Not all DBDs are create equal. Some throw on error, some return
2323   # an undef $rv, and some set $sth->err - try whatever we can
2324   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2325     ! defined $err
2326       and
2327     ( !defined $rv or $sth->err )
2328   );
2329
2330   # Statement must finish even if there was an exception.
2331   try {
2332     $sth->finish
2333   }
2334   catch {
2335     $err = shift unless defined $err
2336   };
2337
2338   if (defined $err) {
2339     my $i = 0;
2340     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2341
2342     $self->throw_exception("Unexpected populate error: $err")
2343       if ($i > $#$tuple_status);
2344
2345     require Data::Dumper::Concise;
2346     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2347       ($tuple_status->[$i][1] || $err),
2348       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2349     );
2350   }
2351
2352   return $rv;
2353 }
2354
2355 sub _dbh_execute_inserts_with_no_binds {
2356   my ($self, $sth, $count) = @_;
2357
2358   my $err;
2359   try {
2360     my $dbh = $self->_get_dbh;
2361     local $dbh->{RaiseError} = 1;
2362     local $dbh->{PrintError} = 0;
2363
2364     $sth->execute foreach 1..$count;
2365   }
2366   catch {
2367     $err = shift;
2368   };
2369
2370   # Make sure statement is finished even if there was an exception.
2371   try {
2372     $sth->finish
2373   }
2374   catch {
2375     $err = shift unless defined $err;
2376   };
2377
2378   $self->throw_exception($err) if defined $err;
2379
2380   return $count;
2381 }
2382
2383 sub update {
2384   #my ($self, $source, @args) = @_;
2385   shift->_execute('update', @_);
2386 }
2387
2388
2389 sub delete {
2390   #my ($self, $source, @args) = @_;
2391   shift->_execute('delete', @_);
2392 }
2393
2394 sub _select {
2395   my $self = shift;
2396   $self->_execute($self->_select_args(@_));
2397 }
2398
2399 sub _select_args_to_query {
2400   my $self = shift;
2401
2402   $self->throw_exception(
2403     "Unable to generate limited query representation with 'software_limit' enabled"
2404   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2405
2406   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2407   #  = $self->_select_args($ident, $select, $cond, $attrs);
2408   my ($op, $ident, @args) =
2409     $self->_select_args(@_);
2410
2411   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2412   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2413
2414   # reuse the bind arrayref
2415   unshift @{$bind}, "($sql)";
2416   \$bind;
2417 }
2418
2419 sub _select_args {
2420   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2421
2422   # FIXME - that kind of caching would be nice to have
2423   # however currently we *may* pass the same $orig_attrs
2424   # with different ident/select/where
2425   # the whole interface needs to be rethought, since it
2426   # was centered around the flawed SQLA API. We can do
2427   # soooooo much better now. But that is also another
2428   # battle...
2429   #return (
2430   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2431   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2432
2433   my $sql_maker = $self->sql_maker;
2434   my $alias2source = $self->_resolve_ident_sources ($ident);
2435
2436   my $attrs = {
2437     %$orig_attrs,
2438     select => $select,
2439     from => $ident,
2440     where => $where,
2441
2442     # limit dialects use this stuff
2443     # yes, some CDBICompat crap does not supply an {alias} >.<
2444     ( $orig_attrs->{alias} and $alias2source->{$orig_attrs->{alias}} )
2445       ? ( _rsroot_rsrc => $alias2source->{$orig_attrs->{alias}} )
2446       : ()
2447     ,
2448   };
2449
2450   # Sanity check the attributes (SQLMaker does it too, but
2451   # in case of a software_limit we'll never reach there)
2452   if (defined $attrs->{offset}) {
2453     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2454       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2455   }
2456
2457   if (defined $attrs->{rows}) {
2458     $self->throw_exception("The rows attribute must be a positive integer if present")
2459       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2460   }
2461   elsif ($attrs->{offset}) {
2462     # MySQL actually recommends this approach.  I cringe.
2463     $attrs->{rows} = $sql_maker->__max_int;
2464   }
2465
2466   # see if we will need to tear the prefetch apart to satisfy group_by == select
2467   # this is *extremely tricky* to get right, I am still not sure I did
2468   #
2469   my ($prefetch_needs_subquery, @limit_args);
2470
2471   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2472     # we already know there is a valid group_by (we made it) and we know it is
2473     # intended to be based *only* on non-multi stuff
2474     # short circuit the group_by parsing below
2475     $prefetch_needs_subquery = 1;
2476   }
2477   elsif (
2478     # The rationale is that even if we do *not* have collapse, we still
2479     # need to wrap the core grouped select/group_by in a subquery
2480     # so that databases that care about group_by/select equivalence
2481     # are happy (this includes MySQL in strict_mode)
2482     # If any of the other joined tables are referenced in the group_by
2483     # however - the user is on their own
2484     ( $prefetch_needs_subquery or $attrs->{_related_results_construction} )
2485       and
2486     $attrs->{group_by}
2487       and
2488     @{$attrs->{group_by}}
2489       and
2490     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2491       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2492     }
2493   ) {
2494     # no aliases other than our own in group_by
2495     # if there are - do not allow subquery even if limit is present
2496     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2497   }
2498   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2499     # active collapse with a limit - that one is a no-brainer unless
2500     # overruled by a group_by above
2501     $prefetch_needs_subquery = 1;
2502   }
2503
2504   if ($prefetch_needs_subquery) {
2505     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2506   }
2507   elsif (! $attrs->{software_limit} ) {
2508     push @limit_args, (
2509       $attrs->{rows} || (),
2510       $attrs->{offset} || (),
2511     );
2512   }
2513
2514   # try to simplify the joinmap further (prune unreferenced type-single joins)
2515   if (
2516     ! $prefetch_needs_subquery  # already pruned
2517       and
2518     ref $attrs->{from}
2519       and
2520     reftype $attrs->{from} eq 'ARRAY'
2521       and
2522     @{$attrs->{from}} != 1
2523   ) {
2524     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2525   }
2526
2527   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2528   # during the result inflation stage we *need* to know what was the aliastype
2529   # map as sqla saw it when the final pieces of SQL were being assembled
2530   # Originally we simply carried around the entirety of $attrs, but this
2531   # resulted in resultsets that are being reused growing continuously, as
2532   # the hash in question grew deeper and deeper.
2533   # Instead hand-pick what to take with us here (we actually don't need much
2534   # at this point just the map itself)
2535   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2536
2537 ###
2538   # This would be the point to deflate anything found in $attrs->{where}
2539   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2540   # expect a result object. And all we have is a resultsource (it is trivial
2541   # to extract deflator coderefs via $alias2source above).
2542   #
2543   # I don't see a way forward other than changing the way deflators are
2544   # invoked, and that's just bad...
2545 ###
2546
2547   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2548 }
2549
2550 # Returns a counting SELECT for a simple count
2551 # query. Abstracted so that a storage could override
2552 # this to { count => 'firstcol' } or whatever makes
2553 # sense as a performance optimization
2554 sub _count_select {
2555   #my ($self, $source, $rs_attrs) = @_;
2556   return { count => '*' };
2557 }
2558
2559 =head2 select
2560
2561 =over 4
2562
2563 =item Arguments: $ident, $select, $condition, $attrs
2564
2565 =back
2566
2567 Handle a SQL select statement.
2568
2569 =cut
2570
2571 sub select {
2572   my $self = shift;
2573   my ($ident, $select, $condition, $attrs) = @_;
2574   return $self->cursor_class->new($self, \@_, $attrs);
2575 }
2576
2577 sub select_single {
2578   my $self = shift;
2579   my ($rv, $sth, @bind) = $self->_select(@_);
2580   my @row = $sth->fetchrow_array;
2581   my @nextrow = $sth->fetchrow_array if @row;
2582   if(@row && @nextrow) {
2583     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2584   }
2585   # Need to call finish() to work round broken DBDs
2586   $sth->finish();
2587   return @row;
2588 }
2589
2590 =head2 sql_limit_dialect
2591
2592 This is an accessor for the default SQL limit dialect used by a particular
2593 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2594 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2595 see L<DBIx::Class::SQLMaker::LimitDialects>.
2596
2597 =cut
2598
2599 sub _dbh_columns_info_for {
2600   my ($self, $dbh, $table) = @_;
2601
2602   if ($dbh->can('column_info')) {
2603     my %result;
2604     my $caught;
2605     try {
2606       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2607       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2608       $sth->execute();
2609       while ( my $info = $sth->fetchrow_hashref() ){
2610         my %column_info;
2611         $column_info{data_type}   = $info->{TYPE_NAME};
2612         $column_info{size}      = $info->{COLUMN_SIZE};
2613         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2614         $column_info{default_value} = $info->{COLUMN_DEF};
2615         my $col_name = $info->{COLUMN_NAME};
2616         $col_name =~ s/^\"(.*)\"$/$1/;
2617
2618         $result{$col_name} = \%column_info;
2619       }
2620     } catch {
2621       $caught = 1;
2622     };
2623     return \%result if !$caught && scalar keys %result;
2624   }
2625
2626   my %result;
2627   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2628   $sth->execute;
2629   my @columns = @{$sth->{NAME_lc}};
2630   for my $i ( 0 .. $#columns ){
2631     my %column_info;
2632     $column_info{data_type} = $sth->{TYPE}->[$i];
2633     $column_info{size} = $sth->{PRECISION}->[$i];
2634     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2635
2636     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2637       $column_info{data_type} = $1;
2638       $column_info{size}    = $2;
2639     }
2640
2641     $result{$columns[$i]} = \%column_info;
2642   }
2643   $sth->finish;
2644
2645   foreach my $col (keys %result) {
2646     my $colinfo = $result{$col};
2647     my $type_num = $colinfo->{data_type};
2648     my $type_name;
2649     if(defined $type_num && $dbh->can('type_info')) {
2650       my $type_info = $dbh->type_info($type_num);
2651       $type_name = $type_info->{TYPE_NAME} if $type_info;
2652       $colinfo->{data_type} = $type_name if $type_name;
2653     }
2654   }
2655
2656   return \%result;
2657 }
2658
2659 sub columns_info_for {
2660   my ($self, $table) = @_;
2661   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2662 }
2663
2664 =head2 last_insert_id
2665
2666 Return the row id of the last insert.
2667
2668 =cut
2669
2670 sub _dbh_last_insert_id {
2671     my ($self, $dbh, $source, $col) = @_;
2672
2673     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2674
2675     return $id if defined $id;
2676
2677     my $class = ref $self;
2678     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2679 }
2680
2681 sub last_insert_id {
2682   my $self = shift;
2683   $self->_dbh_last_insert_id ($self->_dbh, @_);
2684 }
2685
2686 =head2 _native_data_type
2687
2688 =over 4
2689
2690 =item Arguments: $type_name
2691
2692 =back
2693
2694 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2695 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2696 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2697
2698 The default implementation returns C<undef>, implement in your Storage driver if
2699 you need this functionality.
2700
2701 Should map types from other databases to the native RDBMS type, for example
2702 C<VARCHAR2> to C<VARCHAR>.
2703
2704 Types with modifiers should map to the underlying data type. For example,
2705 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2706
2707 Composite types should map to the container type, for example
2708 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2709
2710 =cut
2711
2712 sub _native_data_type {
2713   #my ($self, $data_type) = @_;
2714   return undef
2715 }
2716
2717 # Check if placeholders are supported at all
2718 sub _determine_supports_placeholders {
2719   my $self = shift;
2720   my $dbh  = $self->_get_dbh;
2721
2722   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2723   # but it is inaccurate more often than not
2724   return try {
2725     local $dbh->{PrintError} = 0;
2726     local $dbh->{RaiseError} = 1;
2727     $dbh->do('select ?', {}, 1);
2728     1;
2729   }
2730   catch {
2731     0;
2732   };
2733 }
2734
2735 # Check if placeholders bound to non-string types throw exceptions
2736 #
2737 sub _determine_supports_typeless_placeholders {
2738   my $self = shift;
2739   my $dbh  = $self->_get_dbh;
2740
2741   return try {
2742     local $dbh->{PrintError} = 0;
2743     local $dbh->{RaiseError} = 1;
2744     # this specifically tests a bind that is NOT a string
2745     $dbh->do('select 1 where 1 = ?', {}, 1);
2746     1;
2747   }
2748   catch {
2749     0;
2750   };
2751 }
2752
2753 =head2 sqlt_type
2754
2755 Returns the database driver name.
2756
2757 =cut
2758
2759 sub sqlt_type {
2760   shift->_get_dbh->{Driver}->{Name};
2761 }
2762
2763 =head2 bind_attribute_by_data_type
2764
2765 Given a datatype from column info, returns a database specific bind
2766 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2767 let the database planner just handle it.
2768
2769 This method is always called after the driver has been determined and a DBI
2770 connection has been established. Therefore you can refer to C<DBI::$constant>
2771 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2772 the correct modules.
2773
2774 =cut
2775
2776 sub bind_attribute_by_data_type {
2777     return;
2778 }
2779
2780 =head2 is_datatype_numeric
2781
2782 Given a datatype from column_info, returns a boolean value indicating if
2783 the current RDBMS considers it a numeric value. This controls how
2784 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2785 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2786 be performed instead of the usual C<eq>.
2787
2788 =cut
2789
2790 sub is_datatype_numeric {
2791   #my ($self, $dt) = @_;
2792
2793   return 0 unless $_[1];
2794
2795   $_[1] =~ /^ (?:
2796     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2797   ) $/ix;
2798 }
2799
2800
2801 =head2 create_ddl_dir
2802
2803 =over 4
2804
2805 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2806
2807 =back
2808
2809 Creates a SQL file based on the Schema, for each of the specified
2810 database engines in C<\@databases> in the given directory.
2811 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2812
2813 Given a previous version number, this will also create a file containing
2814 the ALTER TABLE statements to transform the previous schema into the
2815 current one. Note that these statements may contain C<DROP TABLE> or
2816 C<DROP COLUMN> statements that can potentially destroy data.
2817
2818 The file names are created using the C<ddl_filename> method below, please
2819 override this method in your schema if you would like a different file
2820 name format. For the ALTER file, the same format is used, replacing
2821 $version in the name with "$preversion-$version".
2822
2823 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2824 The most common value for this would be C<< { add_drop_table => 1 } >>
2825 to have the SQL produced include a C<DROP TABLE> statement for each table
2826 created. For quoting purposes supply C<quote_identifiers>.
2827
2828 If no arguments are passed, then the following default values are assumed:
2829
2830 =over 4
2831
2832 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2833
2834 =item version    - $schema->schema_version
2835
2836 =item directory  - './'
2837
2838 =item preversion - <none>
2839
2840 =back
2841
2842 By default, C<\%sqlt_args> will have
2843
2844  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2845
2846 merged with the hash passed in. To disable any of those features, pass in a
2847 hashref like the following
2848
2849  { ignore_constraint_names => 0, # ... other options }
2850
2851
2852 WARNING: You are strongly advised to check all SQL files created, before applying
2853 them.
2854
2855 =cut
2856
2857 sub create_ddl_dir {
2858   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2859
2860   unless ($dir) {
2861     carp "No directory given, using ./\n";
2862     $dir = './';
2863   } else {
2864       -d $dir
2865         or
2866       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2867         or
2868       $self->throw_exception(
2869         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2870       );
2871   }
2872
2873   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2874
2875   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2876   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2877
2878   my $schema_version = $schema->schema_version || '1.x';
2879   $version ||= $schema_version;
2880
2881   $sqltargs = {
2882     add_drop_table => 1,
2883     ignore_constraint_names => 1,
2884     ignore_index_names => 1,
2885     %{$sqltargs || {}}
2886   };
2887
2888   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2889     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2890   }
2891
2892   my $sqlt = SQL::Translator->new( $sqltargs );
2893
2894   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2895   my $sqlt_schema = $sqlt->translate({ data => $schema })
2896     or $self->throw_exception ($sqlt->error);
2897
2898   foreach my $db (@$databases) {
2899     $sqlt->reset();
2900     $sqlt->{schema} = $sqlt_schema;
2901     $sqlt->producer($db);
2902
2903     my $file;
2904     my $filename = $schema->ddl_filename($db, $version, $dir);
2905     if (-e $filename && ($version eq $schema_version )) {
2906       # if we are dumping the current version, overwrite the DDL
2907       carp "Overwriting existing DDL file - $filename";
2908       unlink($filename);
2909     }
2910
2911     my $output = $sqlt->translate;
2912     if(!$output) {
2913       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2914       next;
2915     }
2916     if(!open($file, ">$filename")) {
2917       $self->throw_exception("Can't open $filename for writing ($!)");
2918       next;
2919     }
2920     print $file $output;
2921     close($file);
2922
2923     next unless ($preversion);
2924
2925     require SQL::Translator::Diff;
2926
2927     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2928     if(!-e $prefilename) {
2929       carp("No previous schema file found ($prefilename)");
2930       next;
2931     }
2932
2933     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2934     if(-e $difffile) {
2935       carp("Overwriting existing diff file - $difffile");
2936       unlink($difffile);
2937     }
2938
2939     my $source_schema;
2940     {
2941       my $t = SQL::Translator->new($sqltargs);
2942       $t->debug( 0 );
2943       $t->trace( 0 );
2944
2945       $t->parser( $db )
2946         or $self->throw_exception ($t->error);
2947
2948       my $out = $t->translate( $prefilename )
2949         or $self->throw_exception ($t->error);
2950
2951       $source_schema = $t->schema;
2952
2953       $source_schema->name( $prefilename )
2954         unless ( $source_schema->name );
2955     }
2956
2957     # The "new" style of producers have sane normalization and can support
2958     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2959     # And we have to diff parsed SQL against parsed SQL.
2960     my $dest_schema = $sqlt_schema;
2961
2962     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2963       my $t = SQL::Translator->new($sqltargs);
2964       $t->debug( 0 );
2965       $t->trace( 0 );
2966
2967       $t->parser( $db )
2968         or $self->throw_exception ($t->error);
2969
2970       my $out = $t->translate( $filename )
2971         or $self->throw_exception ($t->error);
2972
2973       $dest_schema = $t->schema;
2974
2975       $dest_schema->name( $filename )
2976         unless $dest_schema->name;
2977     }
2978
2979     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2980                                                   $dest_schema,   $db,
2981                                                   $sqltargs
2982                                                  );
2983     if(!open $file, ">$difffile") {
2984       $self->throw_exception("Can't write to $difffile ($!)");
2985       next;
2986     }
2987     print $file $diff;
2988     close($file);
2989   }
2990 }
2991
2992 =head2 deployment_statements
2993
2994 =over 4
2995
2996 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2997
2998 =back
2999
3000 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
3001
3002 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3003 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3004
3005 C<$directory> is used to return statements from files in a previously created
3006 L</create_ddl_dir> directory and is optional. The filenames are constructed
3007 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3008
3009 If no C<$directory> is specified then the statements are constructed on the
3010 fly using L<SQL::Translator> and C<$version> is ignored.
3011
3012 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3013
3014 =cut
3015
3016 sub deployment_statements {
3017   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3018   $type ||= $self->sqlt_type;
3019   $version ||= $schema->schema_version || '1.x';
3020   $dir ||= './';
3021   my $filename = $schema->ddl_filename($type, $version, $dir);
3022   if(-f $filename)
3023   {
3024       # FIXME replace this block when a proper sane sql parser is available
3025       my $file;
3026       open($file, "<$filename")
3027         or $self->throw_exception("Can't open $filename ($!)");
3028       my @rows = <$file>;
3029       close($file);
3030       return join('', @rows);
3031   }
3032
3033   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
3034     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
3035   }
3036
3037   # sources needs to be a parser arg, but for simplicity allow at top level
3038   # coming in
3039   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3040       if exists $sqltargs->{sources};
3041
3042   my $tr = SQL::Translator->new(
3043     producer => "SQL::Translator::Producer::${type}",
3044     %$sqltargs,
3045     parser => 'SQL::Translator::Parser::DBIx::Class',
3046     data => $schema,
3047   );
3048
3049   return preserve_context {
3050     $tr->translate
3051   } after => sub {
3052     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3053       unless defined $_[0];
3054   };
3055 }
3056
3057 # FIXME deploy() currently does not accurately report sql errors
3058 # Will always return true while errors are warned
3059 sub deploy {
3060   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3061   my $deploy = sub {
3062     my $line = shift;
3063     return if(!$line);
3064     return if($line =~ /^--/);
3065     # next if($line =~ /^DROP/m);
3066     return if($line =~ /^BEGIN TRANSACTION/m);
3067     return if($line =~ /^COMMIT/m);
3068     return if $line =~ /^\s+$/; # skip whitespace only
3069     $self->_query_start($line);
3070     try {
3071       # do a dbh_do cycle here, as we need some error checking in
3072       # place (even though we will ignore errors)
3073       $self->dbh_do (sub { $_[1]->do($line) });
3074     } catch {
3075       carp qq{$_ (running "${line}")};
3076     };
3077     $self->_query_end($line);
3078   };
3079   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3080   if (@statements > 1) {
3081     foreach my $statement (@statements) {
3082       $deploy->( $statement );
3083     }
3084   }
3085   elsif (@statements == 1) {
3086     # split on single line comments and end of statements
3087     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3088       $deploy->( $line );
3089     }
3090   }
3091 }
3092
3093 =head2 datetime_parser
3094
3095 Returns the datetime parser class
3096
3097 =cut
3098
3099 sub datetime_parser {
3100   my $self = shift;
3101   return $self->{datetime_parser} ||= do {
3102     $self->build_datetime_parser(@_);
3103   };
3104 }
3105
3106 =head2 datetime_parser_type
3107
3108 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3109
3110 =head2 build_datetime_parser
3111
3112 See L</datetime_parser>
3113
3114 =cut
3115
3116 sub build_datetime_parser {
3117   my $self = shift;
3118   my $type = $self->datetime_parser_type(@_);
3119   return $type;
3120 }
3121
3122
3123 =head2 is_replicating
3124
3125 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3126 replicate from a master database.  Default is undef, which is the result
3127 returned by databases that don't support replication.
3128
3129 =cut
3130
3131 sub is_replicating {
3132     return;
3133
3134 }
3135
3136 =head2 lag_behind_master
3137
3138 Returns a number that represents a certain amount of lag behind a master db
3139 when a given storage is replicating.  The number is database dependent, but
3140 starts at zero and increases with the amount of lag. Default in undef
3141
3142 =cut
3143
3144 sub lag_behind_master {
3145     return;
3146 }
3147
3148 =head2 relname_to_table_alias
3149
3150 =over 4
3151
3152 =item Arguments: $relname, $join_count
3153
3154 =item Return Value: $alias
3155
3156 =back
3157
3158 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3159 queries.
3160
3161 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3162 way these aliases are named.
3163
3164 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3165 otherwise C<"$relname">.
3166
3167 =cut
3168
3169 sub relname_to_table_alias {
3170   my ($self, $relname, $join_count) = @_;
3171
3172   my $alias = ($join_count && $join_count > 1 ?
3173     join('_', $relname, $join_count) : $relname);
3174
3175   return $alias;
3176 }
3177
3178 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3179 # version and it may be necessary to amend or override it for a specific storage
3180 # if such binds are necessary.
3181 sub _max_column_bytesize {
3182   my ($self, $attr) = @_;
3183
3184   my $max_size;
3185
3186   if ($attr->{sqlt_datatype}) {
3187     my $data_type = lc($attr->{sqlt_datatype});
3188
3189     if ($attr->{sqlt_size}) {
3190
3191       # String/sized-binary types
3192       if ($data_type =~ /^(?:
3193           l? (?:var)? char(?:acter)? (?:\s*varying)?
3194             |
3195           (?:var)? binary (?:\s*varying)?
3196             |
3197           raw
3198         )\b/x
3199       ) {
3200         $max_size = $attr->{sqlt_size};
3201       }
3202       # Other charset/unicode types, assume scale of 4
3203       elsif ($data_type =~ /^(?:
3204           national \s* character (?:\s*varying)?
3205             |
3206           nchar
3207             |
3208           univarchar
3209             |
3210           nvarchar
3211         )\b/x
3212       ) {
3213         $max_size = $attr->{sqlt_size} * 4;
3214       }
3215     }
3216
3217     if (!$max_size and !$self->_is_lob_type($data_type)) {
3218       $max_size = 100 # for all other (numeric?) datatypes
3219     }
3220   }
3221
3222   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3223 }
3224
3225 # Determine if a data_type is some type of BLOB
3226 sub _is_lob_type {
3227   my ($self, $data_type) = @_;
3228   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3229     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3230                                   |varchar|character\s*varying|nvarchar
3231                                   |national\s*character\s*varying))?\z/xi);
3232 }
3233
3234 sub _is_binary_lob_type {
3235   my ($self, $data_type) = @_;
3236   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3237     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3238 }
3239
3240 sub _is_text_lob_type {
3241   my ($self, $data_type) = @_;
3242   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3243     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3244                         |national\s*character\s*varying))\z/xi);
3245 }
3246
3247 # Determine if a data_type is some type of a binary type
3248 sub _is_binary_type {
3249   my ($self, $data_type) = @_;
3250   $data_type && ($self->_is_binary_lob_type($data_type)
3251     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3252 }
3253
3254 1;
3255
3256 =head1 USAGE NOTES
3257
3258 =head2 DBIx::Class and AutoCommit
3259
3260 DBIx::Class can do some wonderful magic with handling exceptions,
3261 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3262 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3263 transaction support.
3264
3265 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3266 in an assumed transaction between commits, and you're telling us you'd
3267 like to manage that manually.  A lot of the magic protections offered by
3268 this module will go away.  We can't protect you from exceptions due to database
3269 disconnects because we don't know anything about how to restart your
3270 transactions.  You're on your own for handling all sorts of exceptional
3271 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3272 be with raw DBI.
3273
3274
3275 =head1 AUTHOR AND CONTRIBUTORS
3276
3277 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3278
3279 =head1 LICENSE
3280
3281 You may distribute this code under the same terms as Perl itself.
3282
3283 =cut