lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Context::Preserve 'preserve_context';
  14 use Try::Tiny;
  15 use SQL::Abstract qw(is_plain_value is_literal_value);
  16 use DBIx::Class::_Util qw(
  17   quote_sub perlstring serialize
  18   dbic_internal_try
  19   detected_reinvoked_destructor scope_guard
  20 );
  21 use namespace::clean;
  22
  23 # default cursor class, overridable in connect_info attributes
  24 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  25
  26 __PACKAGE__->mk_group_accessors('inherited' => qw/
  27   sql_limit_dialect sql_quote_char sql_name_sep
  28 /);
  29
  30 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  31
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  33 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  34
  35 __PACKAGE__->sql_name_sep('.');
  36
  37 __PACKAGE__->mk_group_accessors('simple' => qw/
  38   _connect_info _dbic_connect_attributes _driver_determined
  39   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  40   _perform_autoinc_retrieval _autoinc_supplied_for_op
  41 /);
  42
  43 # the values for these accessors are picked out (and deleted) from
  44 # the attribute hashref passed to connect_info
  45 my @storage_options = qw/
  46   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  47   disable_sth_caching unsafe auto_savepoint
  48 /;
  49 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  50
  51
  52 # capability definitions, using a 2-tiered accessor system
  53 # The rationale is:
  54 #
  55 # A driver/user may define _use_X, which blindly without any checks says:
  56 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  57 # type accessor)
  58 #
  59 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  60 # accessor, which in turn calls _determine_supports_X, and stores the return
  61 # in a special slot on the storage object, which is wiped every time a $dbh
  62 # reconnection takes place (it is not guaranteed that upon reconnection we
  63 # will get the same rdbms version). _determine_supports_X does not need to
  64 # exist on a driver, as we ->can for it before calling.
  65
  66 my @capabilities = (qw/
  67   insert_returning
  68   insert_returning_bound
  69
  70   multicolumn_in
  71
  72   placeholders
  73   typeless_placeholders
  74
  75   join_optimizer
  76 /);
  77 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  78 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  79
  80 # on by default, not strictly a capability (pending rewrite)
  81 __PACKAGE__->_use_join_optimizer (1);
  82 sub _determine_supports_join_optimizer { 1 };
  83
  84 # Each of these methods need _determine_driver called before itself
  85 # in order to function reliably. We also need to separate accessors
  86 # from plain old method calls, since an accessor called as a setter
  87 # does *not* need the driver determination loop fired (and in fact
  88 # can produce hard to find bugs, like e.g. losing on_connect_*
  89 # semantics on fresh connections)
  90 #
  91 # The construct below is simply a parameterized around()
  92 my $storage_accessor_idx = { map { $_ => 1 } qw(
  93   sqlt_type
  94   datetime_parser_type
  95
  96   sql_maker
  97   cursor_class
  98 )};
  99 for my $meth (keys %$storage_accessor_idx, qw(
 100   deployment_statements
 101
 102   build_datetime_parser
 103
 104   txn_begin
 105
 106   insert
 107   update
 108   delete
 109   select
 110   select_single
 111
 112   _insert_bulk
 113
 114   with_deferred_fk_checks
 115
 116   get_use_dbms_capability
 117   get_dbms_capability
 118
 119   _server_info
 120   _get_server_version
 121 )) {
 122
 123   my $orig = __PACKAGE__->can ($meth)
 124     or die "$meth is not a ::Storage::DBI method!";
 125
 126   my $possibly_a_setter = $storage_accessor_idx->{$meth} ? 1 : 0;
 127
 128   quote_sub
 129     __PACKAGE__ ."::$meth", sprintf( <<'EOC', $possibly_a_setter, perlstring $meth ), { '$orig' => \$orig };
 130
 131     if (
 132       # if this is an actual *setter* - just set it, no need to connect
 133       # and determine the driver
 134       !( %1$s and @_ > 1 )
 135         and
 136       # only fire when invoked on an instance, a valid class-based invocation
 137       # would e.g. be setting a default for an inherited accessor
 138       ref $_[0]
 139         and
 140       ! $_[0]->{_driver_determined}
 141         and
 142       ! $_[0]->{_in_determine_driver}
 143         and
 144       # Only try to determine stuff if we have *something* that either is or can
 145       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 146       # to still be marginally useful
 147       $_[0]->_dbi_connect_info->[0]
 148     ) {
 149       $_[0]->_determine_driver;
 150
 151       # work around http://rt.perl.org/rt3/Public/Bug/Display.html?id=35878
 152       goto $_[0]->can(%2$s) unless DBIx::Class::_ENV_::BROKEN_GOTO;
 153
 154       my $cref = $_[0]->can(%2$s);
 155       goto $cref;
 156     }
 157
 158     goto $orig;
 159 EOC
 160 }
 161
 162 =head1 NAME
 163
 164 DBIx::Class::Storage::DBI - DBI storage handler
 165
 166 =head1 SYNOPSIS
 167
 168   my $schema = MySchema->connect('dbi:SQLite:my.db');
 169
 170   $schema->storage->debug(1);
 171
 172   my @stuff = $schema->storage->dbh_do(
 173     sub {
 174       my ($storage, $dbh, @args) = @_;
 175       $dbh->do("DROP TABLE authors");
 176     },
 177     @column_list
 178   );
 179
 180   $schema->resultset('Book')->search({
 181      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 182   });
 183
 184 =head1 DESCRIPTION
 185
 186 This class represents the connection to an RDBMS via L<DBI>.  See
 187 L<DBIx::Class::Storage> for general information.  This pod only
 188 documents DBI-specific methods and behaviors.
 189
 190 =head1 METHODS
 191
 192 =cut
 193
 194 sub new {
 195   my $new = shift->next::method(@_);
 196
 197   $new->_sql_maker_opts({});
 198   $new->_dbh_details({});
 199   $new->{_in_do_block} = 0;
 200
 201   # read below to see what this does
 202   $new->_arm_global_destructor;
 203
 204   $new;
 205 }
 206
 207 # This is hack to work around perl shooting stuff in random
 208 # order on exit(). If we do not walk the remaining storage
 209 # objects in an END block, there is a *small but real* chance
 210 # of a fork()ed child to kill the parent's shared DBI handle,
 211 # *before perl reaches the DESTROY in this package*
 212 # Yes, it is ugly and effective.
 213 # Additionally this registry is used by the CLONE method to
 214 # make sure no handles are shared between threads
 215 {
 216   my %seek_and_destroy;
 217
 218   sub _arm_global_destructor {
 219
 220     # quick "garbage collection" pass - prevents the registry
 221     # from slowly growing with a bunch of undef-valued keys
 222     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 223       for keys %seek_and_destroy;
 224
 225     weaken (
 226       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 227     );
 228   }
 229
 230   END {
 231
 232     if(
 233       ! DBIx::Class::_ENV_::BROKEN_FORK
 234         and
 235       my @instances = grep { defined $_ } values %seek_and_destroy
 236     ) {
 237       local $?; # just in case the DBI destructor changes it somehow
 238
 239       # disarm the handle if not native to this process (see comment on top)
 240       $_->_verify_pid for @instances;
 241     }
 242   }
 243
 244   sub CLONE {
 245     # As per DBI's recommendation, DBIC disconnects all handles as
 246     # soon as possible (DBIC will reconnect only on demand from within
 247     # the thread)
 248     my @instances = grep { defined $_ } values %seek_and_destroy;
 249     %seek_and_destroy = ();
 250
 251     for (@instances) {
 252       $_->_dbh(undef);
 253       $_->disconnect;
 254
 255       # properly renumber existing refs
 256       $_->_arm_global_destructor
 257     }
 258   }
 259 }
 260
 261 sub DESTROY {
 262   return if &detected_reinvoked_destructor;
 263
 264   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 265
 266   # some databases spew warnings on implicit disconnect
 267   return unless defined $_[0]->_dbh;
 268
 269   local $SIG{__WARN__} = sub {};
 270   $_[0]->_dbh(undef);
 271   # not calling ->disconnect here - we are being destroyed - nothing to reset
 272
 273   # this op is necessary, since the very last perl runtime statement
 274   # triggers a global destruction shootout, and the $SIG localization
 275   # may very well be destroyed before perl actually gets to do the
 276   # $dbh undef
 277   1;
 278 }
 279
 280 # handle pid changes correctly - do not destroy parent's connection
 281 sub _verify_pid {
 282
 283   my $pid = $_[0]->_conn_pid;
 284
 285   if( defined $pid and $pid != $$ and my $dbh = $_[0]->_dbh ) {
 286     $dbh->{InactiveDestroy} = 1;
 287     $_[0]->_dbh(undef);
 288     $_[0]->disconnect;
 289   }
 290
 291   return;
 292 }
 293
 294 =head2 connect_info
 295
 296 This method is normally called by L<DBIx::Class::Schema/connection>, which
 297 encapsulates its argument list in an arrayref before passing them here.
 298
 299 The argument list may contain:
 300
 301 =over
 302
 303 =item *
 304
 305 The same 4-element argument set one would normally pass to
 306 L<DBI/connect>, optionally followed by
 307 L<extra attributes|/DBIx::Class specific connection attributes>
 308 recognized by DBIx::Class:
 309
 310   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 311
 312 =item *
 313
 314 A single code reference which returns a connected
 315 L<DBI database handle|DBI/connect> optionally followed by
 316 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 317 by DBIx::Class:
 318
 319   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 320
 321 =item *
 322
 323 A single hashref with all the attributes and the dsn/user/password
 324 mixed together:
 325
 326   $connect_info_args = [{
 327     dsn => $dsn,
 328     user => $user,
 329     password => $pass,
 330     %dbi_attributes,
 331     %extra_attributes,
 332   }];
 333
 334   $connect_info_args = [{
 335     dbh_maker => sub { DBI->connect (...) },
 336     %dbi_attributes,
 337     %extra_attributes,
 338   }];
 339
 340 This is particularly useful for L<Catalyst> based applications, allowing the
 341 following config (L<Config::General> style):
 342
 343   <Model::DB>
 344     schema_class   App::DB
 345     <connect_info>
 346       dsn          dbi:mysql:database=test
 347       user         testuser
 348       password     TestPass
 349       AutoCommit   1
 350     </connect_info>
 351   </Model::DB>
 352
 353 The C<dsn>/C<user>/C<password> combination can be substituted by the
 354 C<dbh_maker> key whose value is a coderef that returns a connected
 355 L<DBI database handle|DBI/connect>
 356
 357 =back
 358
 359 Please note that the L<DBI> docs recommend that you always explicitly
 360 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 361 recommends that it be set to I<1>, and that you perform transactions
 362 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 363 to I<1> if you do not do explicitly set it to zero.  This is the default
 364 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 365
 366 =head3 DBIx::Class specific connection attributes
 367
 368 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 369 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 370 the following connection options. These options can be mixed in with your other
 371 L<DBI> connection attributes, or placed in a separate hashref
 372 (C<\%extra_attributes>) as shown above.
 373
 374 Every time C<connect_info> is invoked, any previous settings for
 375 these options will be cleared before setting the new ones, regardless of
 376 whether any options are specified in the new C<connect_info>.
 377
 378
 379 =over
 380
 381 =item on_connect_do
 382
 383 Specifies things to do immediately after connecting or re-connecting to
 384 the database.  Its value may contain:
 385
 386 =over
 387
 388 =item a scalar
 389
 390 This contains one SQL statement to execute.
 391
 392 =item an array reference
 393
 394 This contains SQL statements to execute in order.  Each element contains
 395 a string or a code reference that returns a string.
 396
 397 =item a code reference
 398
 399 This contains some code to execute.  Unlike code references within an
 400 array reference, its return value is ignored.
 401
 402 =back
 403
 404 =item on_disconnect_do
 405
 406 Takes arguments in the same form as L</on_connect_do> and executes them
 407 immediately before disconnecting from the database.
 408
 409 Note, this only runs if you explicitly call L</disconnect> on the
 410 storage object.
 411
 412 =item on_connect_call
 413
 414 A more generalized form of L</on_connect_do> that calls the specified
 415 C<connect_call_METHOD> methods in your storage driver.
 416
 417   on_connect_do => 'select 1'
 418
 419 is equivalent to:
 420
 421   on_connect_call => [ [ do_sql => 'select 1' ] ]
 422
 423 Its values may contain:
 424
 425 =over
 426
 427 =item a scalar
 428
 429 Will call the C<connect_call_METHOD> method.
 430
 431 =item a code reference
 432
 433 Will execute C<< $code->($storage) >>
 434
 435 =item an array reference
 436
 437 Each value can be a method name or code reference.
 438
 439 =item an array of arrays
 440
 441 For each array, the first item is taken to be the C<connect_call_> method name
 442 or code reference, and the rest are parameters to it.
 443
 444 =back
 445
 446 Some predefined storage methods you may use:
 447
 448 =over
 449
 450 =item do_sql
 451
 452 Executes a SQL string or a code reference that returns a SQL string. This is
 453 what L</on_connect_do> and L</on_disconnect_do> use.
 454
 455 It can take:
 456
 457 =over
 458
 459 =item a scalar
 460
 461 Will execute the scalar as SQL.
 462
 463 =item an arrayref
 464
 465 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 466 attributes hashref and bind values.
 467
 468 =item a code reference
 469
 470 Will execute C<< $code->($storage) >> and execute the return array refs as
 471 above.
 472
 473 =back
 474
 475 =item datetime_setup
 476
 477 Execute any statements necessary to initialize the database session to return
 478 and accept datetime/timestamp values used with
 479 L<DBIx::Class::InflateColumn::DateTime>.
 480
 481 Only necessary for some databases, see your specific storage driver for
 482 implementation details.
 483
 484 =back
 485
 486 =item on_disconnect_call
 487
 488 Takes arguments in the same form as L</on_connect_call> and executes them
 489 immediately before disconnecting from the database.
 490
 491 Calls the C<disconnect_call_METHOD> methods as opposed to the
 492 C<connect_call_METHOD> methods called by L</on_connect_call>.
 493
 494 Note, this only runs if you explicitly call L</disconnect> on the
 495 storage object.
 496
 497 =item disable_sth_caching
 498
 499 If set to a true value, this option will disable the caching of
 500 statement handles via L<DBI/prepare_cached>.
 501
 502 =item limit_dialect
 503
 504 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 505 default L</sql_limit_dialect> setting of the storage (if any). For a list
 506 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 507
 508 =item quote_names
 509
 510 When true automatically sets L</quote_char> and L</name_sep> to the characters
 511 appropriate for your particular RDBMS. This option is preferred over specifying
 512 L</quote_char> directly.
 513
 514 =item quote_char
 515
 516 Specifies what characters to use to quote table and column names.
 517
 518 C<quote_char> expects either a single character, in which case is it
 519 is placed on either side of the table/column name, or an arrayref of length
 520 2 in which case the table/column name is placed between the elements.
 521
 522 For example under MySQL you should use C<< quote_char => '`' >>, and for
 523 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 524
 525 =item name_sep
 526
 527 This parameter is only useful in conjunction with C<quote_char>, and is used to
 528 specify the character that separates elements (schemas, tables, columns) from
 529 each other. If unspecified it defaults to the most commonly used C<.>.
 530
 531 =item unsafe
 532
 533 This Storage driver normally installs its own C<HandleError>, sets
 534 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 535 all database handles, including those supplied by a coderef.  It does this
 536 so that it can have consistent and useful error behavior.
 537
 538 If you set this option to a true value, Storage will not do its usual
 539 modifications to the database handle's attributes, and instead relies on
 540 the settings in your connect_info DBI options (or the values you set in
 541 your connection coderef, in the case that you are connecting via coderef).
 542
 543 Note that your custom settings can cause Storage to malfunction,
 544 especially if you set a C<HandleError> handler that suppresses exceptions
 545 and/or disable C<RaiseError>.
 546
 547 =item auto_savepoint
 548
 549 If this option is true, L<DBIx::Class> will use savepoints when nesting
 550 transactions, making it possible to recover from failure in the inner
 551 transaction without having to abort all outer transactions.
 552
 553 =item cursor_class
 554
 555 Use this argument to supply a cursor class other than the default
 556 L<DBIx::Class::Storage::DBI::Cursor>.
 557
 558 =back
 559
 560 Some real-life examples of arguments to L</connect_info> and
 561 L<DBIx::Class::Schema/connect>
 562
 563   # Simple SQLite connection
 564   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 565
 566   # Connect via subref
 567   ->connect_info([ sub { DBI->connect(...) } ]);
 568
 569   # Connect via subref in hashref
 570   ->connect_info([{
 571     dbh_maker => sub { DBI->connect(...) },
 572     on_connect_do => 'alter session ...',
 573   }]);
 574
 575   # A bit more complicated
 576   ->connect_info(
 577     [
 578       'dbi:Pg:dbname=foo',
 579       'postgres',
 580       'my_pg_password',
 581       { AutoCommit => 1 },
 582       { quote_char => q{"} },
 583     ]
 584   );
 585
 586   # Equivalent to the previous example
 587   ->connect_info(
 588     [
 589       'dbi:Pg:dbname=foo',
 590       'postgres',
 591       'my_pg_password',
 592       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 593     ]
 594   );
 595
 596   # Same, but with hashref as argument
 597   # See parse_connect_info for explanation
 598   ->connect_info(
 599     [{
 600       dsn         => 'dbi:Pg:dbname=foo',
 601       user        => 'postgres',
 602       password    => 'my_pg_password',
 603       AutoCommit  => 1,
 604       quote_char  => q{"},
 605       name_sep    => q{.},
 606     }]
 607   );
 608
 609   # Subref + DBIx::Class-specific connection options
 610   ->connect_info(
 611     [
 612       sub { DBI->connect(...) },
 613       {
 614           quote_char => q{`},
 615           name_sep => q{@},
 616           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 617           disable_sth_caching => 1,
 618       },
 619     ]
 620   );
 621
 622
 623
 624 =cut
 625
 626 sub connect_info {
 627   my ($self, $info) = @_;
 628
 629   return $self->_connect_info if !$info;
 630
 631   $self->_connect_info($info); # copy for _connect_info
 632
 633   $info = $self->_normalize_connect_info($info)
 634     if ref $info eq 'ARRAY';
 635
 636   my %attrs = (
 637     %{ $self->_default_dbi_connect_attributes || {} },
 638     %{ $info->{attributes} || {} },
 639   );
 640
 641   my @args = @{ $info->{arguments} };
 642
 643   if (keys %attrs and ref $args[0] ne 'CODE') {
 644     carp_unique (
 645         'You provided explicit AutoCommit => 0 in your connection_info. '
 646       . 'This is almost universally a bad idea (see the footnotes of '
 647       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 648       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 649       . 'this warning.'
 650     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 651
 652     push @args, \%attrs if keys %attrs;
 653   }
 654
 655   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 656   # OR a single-element coderef-based $dbh factory
 657   $self->_dbi_connect_info(\@args);
 658
 659   # extract the individual storage options
 660   for my $storage_opt (keys %{ $info->{storage_options} }) {
 661     my $value = $info->{storage_options}{$storage_opt};
 662
 663     $self->$storage_opt($value);
 664   }
 665
 666   # Extract the individual sqlmaker options
 667   #
 668   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 669   #  the new set of options
 670   $self->_sql_maker(undef);
 671   $self->_sql_maker_opts({});
 672
 673   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 674     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 675
 676     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 677   }
 678
 679   # FIXME - dirty:
 680   # save attributes in a separate accessor so they are always
 681   # introspectable, even in case of a CODE $dbhmaker
 682   $self->_dbic_connect_attributes (\%attrs);
 683
 684   return $self->_connect_info;
 685 }
 686
 687 sub _dbi_connect_info {
 688   my $self = shift;
 689
 690   return $self->{_dbi_connect_info} = $_[0]
 691     if @_;
 692
 693   my $conninfo = $self->{_dbi_connect_info} || [];
 694
 695   # last ditch effort to grab a DSN
 696   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 697     my @new_conninfo = @$conninfo;
 698     $new_conninfo[0] = $ENV{DBI_DSN};
 699     $conninfo = \@new_conninfo;
 700   }
 701
 702   return $conninfo;
 703 }
 704
 705
 706 sub _normalize_connect_info {
 707   my ($self, $info_arg) = @_;
 708   my %info;
 709
 710   my @args = @$info_arg;  # take a shallow copy for further mutilation
 711
 712   # combine/pre-parse arguments depending on invocation style
 713
 714   my %attrs;
 715   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 716     %attrs = %{ $args[1] || {} };
 717     @args = $args[0];
 718   }
 719   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 720     %attrs = %{$args[0]};
 721     @args = ();
 722     if (my $code = delete $attrs{dbh_maker}) {
 723       @args = $code;
 724
 725       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 726       if (@ignored) {
 727         carp sprintf (
 728             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 729           . "to the result of 'dbh_maker'",
 730
 731           join (', ', map { "'$_'" } (@ignored) ),
 732         );
 733       }
 734     }
 735     else {
 736       @args = delete @attrs{qw/dsn user password/};
 737     }
 738   }
 739   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 740     %attrs = (
 741       % { $args[3] || {} },
 742       % { $args[4] || {} },
 743     );
 744     @args = @args[0,1,2];
 745   }
 746
 747   $info{arguments} = \@args;
 748
 749   my @storage_opts = grep exists $attrs{$_},
 750     @storage_options, 'cursor_class';
 751
 752   @{ $info{storage_options} }{@storage_opts} =
 753     delete @attrs{@storage_opts} if @storage_opts;
 754
 755   my @sql_maker_opts = grep exists $attrs{$_},
 756     qw/limit_dialect quote_char name_sep quote_names/;
 757
 758   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 759     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 760
 761   $info{attributes} = \%attrs if %attrs;
 762
 763   return \%info;
 764 }
 765
 766 sub _default_dbi_connect_attributes () {
 767   +{
 768     AutoCommit => 1,
 769     PrintError => 0,
 770     RaiseError => 1,
 771     ShowErrorStatement => 1,
 772   };
 773 }
 774
 775 =head2 on_connect_do
 776
 777 This method is deprecated in favour of setting via L</connect_info>.
 778
 779 =cut
 780
 781 =head2 on_disconnect_do
 782
 783 This method is deprecated in favour of setting via L</connect_info>.
 784
 785 =cut
 786
 787 sub _parse_connect_do {
 788   my ($self, $type) = @_;
 789
 790   my $val = $self->$type;
 791   return () if not defined $val;
 792
 793   my @res;
 794
 795   if (not ref($val)) {
 796     push @res, [ 'do_sql', $val ];
 797   } elsif (ref($val) eq 'CODE') {
 798     push @res, $val;
 799   } elsif (ref($val) eq 'ARRAY') {
 800     push @res, map { [ 'do_sql', $_ ] } @$val;
 801   } else {
 802     $self->throw_exception("Invalid type for $type: ".ref($val));
 803   }
 804
 805   return \@res;
 806 }
 807
 808 =head2 dbh_do
 809
 810 Arguments: ($subref | $method_name), @extra_coderef_args?
 811
 812 Execute the given $subref or $method_name using the new exception-based
 813 connection management.
 814
 815 The first two arguments will be the storage object that C<dbh_do> was called
 816 on and a database handle to use.  Any additional arguments will be passed
 817 verbatim to the called subref as arguments 2 and onwards.
 818
 819 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 820 exception handling and reconnection (or failover in future subclasses).
 821
 822 Your subref should have no side-effects outside of the database, as
 823 there is the potential for your subref to be partially double-executed
 824 if the database connection was stale/dysfunctional.
 825
 826 Example:
 827
 828   my @stuff = $schema->storage->dbh_do(
 829     sub {
 830       my ($storage, $dbh, @cols) = @_;
 831       my $cols = join(q{, }, @cols);
 832       $dbh->selectrow_array("SELECT $cols FROM foo");
 833     },
 834     @column_list
 835   );
 836
 837 =cut
 838
 839 sub dbh_do {
 840   my $self = shift;
 841   my $run_target = shift; # either a coderef or a method name
 842
 843   # short circuit when we know there is no need for a runner
 844   #
 845   # FIXME - assumption may be wrong
 846   # the rationale for the txn_depth check is that if this block is a part
 847   # of a larger transaction, everything up to that point is screwed anyway
 848   return $self->$run_target($self->_get_dbh, @_)
 849     if $self->{_in_do_block} or $self->transaction_depth;
 850
 851   # take a ref instead of a copy, to preserve @_ aliasing
 852   # semantics within the coderef, but only if needed
 853   # (pseudoforking doesn't like this trick much)
 854   my $args = @_ ? \@_ : [];
 855
 856   DBIx::Class::Storage::BlockRunner->new(
 857     storage => $self,
 858     wrap_txn => 0,
 859     retry_handler => sub {
 860       $_[0]->failed_attempt_count == 1
 861         and
 862       ! $_[0]->storage->connected
 863     },
 864   )->run(sub {
 865     $self->$run_target ($self->_get_dbh, @$args )
 866   });
 867 }
 868
 869 sub txn_do {
 870   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 871   shift->next::method(@_);
 872 }
 873
 874 =head2 disconnect
 875
 876 Our C<disconnect> method also performs a rollback first if the
 877 database is not in C<AutoCommit> mode.
 878
 879 =cut
 880
 881 sub disconnect {
 882   my $self = shift;
 883
 884   # this physical disconnect below might very well throw
 885   # in order to unambiguously reset the state - do the cleanup in guard
 886
 887   my $g = scope_guard {
 888     $self->_dbh(undef);
 889     $self->_dbh_details({});
 890     $self->transaction_depth(undef);
 891     $self->_dbh_autocommit(undef);
 892     $self->savepoints([]);
 893
 894     # FIXME - this needs reenabling with the proper "no reset on same DSN" check
 895     #$self->_sql_maker(undef); # this may also end up being different
 896   };
 897
 898   if( my $dbh = $self->_dbh ) {
 899
 900     $self->_do_connection_actions(disconnect_call_ => $_) for (
 901       ( $self->on_disconnect_call || () ),
 902       $self->_parse_connect_do ('on_disconnect_do')
 903     );
 904
 905     # stops the "implicit rollback on disconnect" warning
 906     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 907
 908     $dbh->disconnect;
 909   }
 910 }
 911
 912 =head2 with_deferred_fk_checks
 913
 914 =over 4
 915
 916 =item Arguments: C<$coderef>
 917
 918 =item Return Value: The return value of $coderef
 919
 920 =back
 921
 922 Storage specific method to run the code ref with FK checks deferred or
 923 in MySQL's case disabled entirely.
 924
 925 =cut
 926
 927 # Storage subclasses should override this
 928 sub with_deferred_fk_checks {
 929   #my ($self, $sub) = @_;
 930   $_[1]->();
 931 }
 932
 933 =head2 connected
 934
 935 =over
 936
 937 =item Arguments: none
 938
 939 =item Return Value: 1|0
 940
 941 =back
 942
 943 Verifies that the current database handle is active and ready to execute
 944 an SQL statement (e.g. the connection did not get stale, server is still
 945 answering, etc.) This method is used internally by L</dbh>.
 946
 947 =cut
 948
 949 sub connected {
 950   return 0 unless $_[0]->_seems_connected;
 951
 952   #be on the safe side
 953   local $_[0]->_dbh->{RaiseError} = 1;
 954
 955   return $_[0]->_ping;
 956 }
 957
 958 sub _seems_connected {
 959   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 960
 961   $_[0]->_dbh
 962     and
 963   $_[0]->_dbh->FETCH('Active')
 964     and
 965   return 1;
 966
 967   # explicitly reset all state
 968   $_[0]->disconnect;
 969   return 0;
 970 }
 971
 972 sub _ping {
 973   ($_[0]->_dbh || return 0)->ping;
 974 }
 975
 976 sub ensure_connected {
 977   $_[0]->connected || ( $_[0]->_populate_dbh && 1 );
 978 }
 979
 980 =head2 dbh
 981
 982 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 983 is guaranteed to be healthy by implicitly calling L</connected>, and if
 984 necessary performing a reconnection before returning. Keep in mind that this
 985 is very B<expensive> on some database engines. Consider using L</dbh_do>
 986 instead.
 987
 988 =cut
 989
 990 sub dbh {
 991   # maybe save a ping call
 992   $_[0]->_dbh
 993     ? ( $_[0]->ensure_connected and $_[0]->_dbh )
 994     : $_[0]->_populate_dbh
 995   ;
 996 }
 997
 998 # this is the internal "get dbh or connect (don't check)" method
 999 sub _get_dbh {
1000   $_[0]->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1001   $_[0]->_dbh || $_[0]->_populate_dbh;
1002 }
1003
1004 # *DELIBERATELY* not a setter (for the time being)
1005 # Too intertwined with everything else for any kind of sanity
1006 sub sql_maker {
1007   my $self = shift;
1008
1009   $self->throw_exception('sql_maker() is not a setter method') if @_;
1010
1011   unless ($self->_sql_maker) {
1012     my $sql_maker_class = $self->sql_maker_class;
1013
1014     my %opts = %{$self->_sql_maker_opts||{}};
1015     my $dialect =
1016       $opts{limit_dialect}
1017         ||
1018       $self->sql_limit_dialect
1019         ||
1020       do {
1021         my $s_class = (ref $self) || $self;
1022         carp_unique (
1023           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1024         . 'have not supplied an explicit limit_dialect in your connection_info. '
1025         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1026         . 'databases but can be (and often is) painfully slow. '
1027         . "Please file an RT ticket against '$s_class'"
1028         ) if $self->_dbi_connect_info->[0];
1029
1030         'GenericSubQ';
1031       }
1032     ;
1033
1034     my ($quote_char, $name_sep);
1035
1036     if ($opts{quote_names}) {
1037       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1038         my $s_class = (ref $self) || $self;
1039         carp_unique (
1040           "You requested 'quote_names' but your storage class ($s_class) does "
1041         . 'not explicitly define a default sql_quote_char and you have not '
1042         . 'supplied a quote_char as part of your connection_info. DBIC will '
1043         .q{default to the ANSI SQL standard quote '"', which works most of }
1044         . "the time. Please file an RT ticket against '$s_class'."
1045         );
1046
1047         '"'; # RV
1048       };
1049
1050       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1051     }
1052
1053     $self->_sql_maker($sql_maker_class->new(
1054       bindtype=>'columns',
1055       array_datatypes => 1,
1056       limit_dialect => $dialect,
1057       ($quote_char ? (quote_char => $quote_char) : ()),
1058       name_sep => ($name_sep || '.'),
1059       %opts,
1060     ));
1061   }
1062   return $self->_sql_maker;
1063 }
1064
1065 # nothing to do by default
1066 sub _rebless {}
1067 sub _init {}
1068
1069 sub _populate_dbh {
1070
1071   # reset internal states
1072   # also in case ->connected failed we might get sent here
1073   $_[0]->disconnect;
1074
1075   $_[0]->_dbh($_[0]->_connect);
1076
1077   $_[0]->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1078
1079   $_[0]->_determine_driver;
1080
1081   # Always set the transaction depth on connect, since
1082   #  there is no transaction in progress by definition
1083   $_[0]->transaction_depth( $_[0]->_dbh_autocommit ? 0 : 1 );
1084
1085   $_[0]->_run_connection_actions unless $_[0]->{_in_determine_driver};
1086
1087   $_[0]->_dbh;
1088 }
1089
1090 sub _run_connection_actions {
1091
1092   $_[0]->_do_connection_actions(connect_call_ => $_) for (
1093     ( $_[0]->on_connect_call || () ),
1094     $_[0]->_parse_connect_do ('on_connect_do'),
1095   );
1096 }
1097
1098
1099
1100 sub set_use_dbms_capability {
1101   $_[0]->set_inherited ($_[1], $_[2]);
1102 }
1103
1104 sub get_use_dbms_capability {
1105   my ($self, $capname) = @_;
1106
1107   my $use = $self->get_inherited ($capname);
1108   return defined $use
1109     ? $use
1110     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1111   ;
1112 }
1113
1114 sub set_dbms_capability {
1115   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1116 }
1117
1118 sub get_dbms_capability {
1119   my ($self, $capname) = @_;
1120
1121   my $cap = $self->_dbh_details->{capability}{$capname};
1122
1123   unless (defined $cap) {
1124     if (my $meth = $self->can ("_determine$capname")) {
1125       $cap = $self->$meth ? 1 : 0;
1126     }
1127     else {
1128       $cap = 0;
1129     }
1130
1131     $self->set_dbms_capability ($capname, $cap);
1132   }
1133
1134   return $cap;
1135 }
1136
1137 sub _server_info {
1138   my $self = shift;
1139
1140   # FIXME - ideally this needs to be an ||= assignment, and the final
1141   # assignment at the end of this do{} should be gone entirely. However
1142   # this confuses CXSA: https://rt.cpan.org/Ticket/Display.html?id=103296
1143   $self->_dbh_details->{info} || do {
1144
1145     # this guarantees that problematic conninfo won't be hidden
1146     # by the try{} below
1147     $self->ensure_connected;
1148
1149     my $info = {};
1150
1151     my $server_version = dbic_internal_try {
1152       $self->_get_server_version
1153     } catch {
1154       # driver determination *may* use this codepath
1155       # in which case we must rethrow
1156       $self->throw_exception($_) if $self->{_in_determine_driver};
1157
1158       # $server_version on failure
1159       undef;
1160     };
1161
1162     if (defined $server_version) {
1163       $info->{dbms_version} = $server_version;
1164
1165       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1166       my @verparts = split (/\./, $numeric_version);
1167       if (
1168         @verparts
1169           &&
1170         $verparts[0] <= 999
1171       ) {
1172         # consider only up to 3 version parts, iff not more than 3 digits
1173         my @use_parts;
1174         while (@verparts && @use_parts < 3) {
1175           my $p = shift @verparts;
1176           last if $p > 999;
1177           push @use_parts, $p;
1178         }
1179         push @use_parts, 0 while @use_parts < 3;
1180
1181         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1182       }
1183     }
1184
1185     $self->_dbh_details->{info} = $info;
1186   };
1187 }
1188
1189 sub _get_server_version {
1190   shift->_dbh_get_info('SQL_DBMS_VER');
1191 }
1192
1193 sub _dbh_get_info {
1194   my ($self, $info) = @_;
1195
1196   if ($info =~ /[^0-9]/) {
1197     require DBI::Const::GetInfoType;
1198     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1199     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1200       unless defined $info;
1201   }
1202
1203   $self->_get_dbh->get_info($info);
1204 }
1205
1206 sub _describe_connection {
1207   require DBI::Const::GetInfoReturn;
1208
1209   my $self = shift;
1210
1211   my $drv;
1212   dbic_internal_try {
1213     $drv = $self->_extract_driver_from_connect_info;
1214     $self->ensure_connected;
1215   };
1216
1217   $drv = "DBD::$drv" if $drv;
1218
1219   my $res = {
1220     DBIC_DSN => $self->_dbi_connect_info->[0],
1221     DBI_VER => DBI->VERSION,
1222     DBIC_VER => DBIx::Class->VERSION,
1223     DBIC_DRIVER => ref $self,
1224     $drv ? (
1225       DBD => $drv,
1226       DBD_VER => dbic_internal_try { $drv->VERSION },
1227     ) : (),
1228   };
1229
1230   # try to grab data even if we never managed to connect
1231   # will cover us in cases of an oddly broken half-connect
1232   for my $inf (
1233     #keys %DBI::Const::GetInfoType::GetInfoType,
1234     qw/
1235       SQL_CURSOR_COMMIT_BEHAVIOR
1236       SQL_CURSOR_ROLLBACK_BEHAVIOR
1237       SQL_CURSOR_SENSITIVITY
1238       SQL_DATA_SOURCE_NAME
1239       SQL_DBMS_NAME
1240       SQL_DBMS_VER
1241       SQL_DEFAULT_TXN_ISOLATION
1242       SQL_DM_VER
1243       SQL_DRIVER_NAME
1244       SQL_DRIVER_ODBC_VER
1245       SQL_DRIVER_VER
1246       SQL_EXPRESSIONS_IN_ORDERBY
1247       SQL_GROUP_BY
1248       SQL_IDENTIFIER_CASE
1249       SQL_IDENTIFIER_QUOTE_CHAR
1250       SQL_MAX_CATALOG_NAME_LEN
1251       SQL_MAX_COLUMN_NAME_LEN
1252       SQL_MAX_IDENTIFIER_LEN
1253       SQL_MAX_TABLE_NAME_LEN
1254       SQL_MULTIPLE_ACTIVE_TXN
1255       SQL_MULT_RESULT_SETS
1256       SQL_NEED_LONG_DATA_LEN
1257       SQL_NON_NULLABLE_COLUMNS
1258       SQL_ODBC_VER
1259       SQL_QUALIFIER_NAME_SEPARATOR
1260       SQL_QUOTED_IDENTIFIER_CASE
1261       SQL_TXN_CAPABLE
1262       SQL_TXN_ISOLATION_OPTION
1263     /
1264   ) {
1265     # some drivers barf on things they do not know about instead
1266     # of returning undef
1267     my $v = dbic_internal_try { $self->_dbh_get_info($inf) };
1268     next unless defined $v;
1269
1270     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1271     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1272     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1273   }
1274
1275   $res;
1276 }
1277
1278 sub _determine_driver {
1279   my ($self) = @_;
1280
1281   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1282     my $started_connected = 0;
1283     local $self->{_in_determine_driver} = 1;
1284
1285     if (ref($self) eq __PACKAGE__) {
1286       my $driver;
1287       if ($self->_dbh) { # we are connected
1288         $driver = $self->_dbh->{Driver}{Name};
1289         $started_connected = 1;
1290       }
1291       else {
1292         $driver = $self->_extract_driver_from_connect_info;
1293       }
1294
1295       if ($driver) {
1296         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1297         if ($self->load_optional_class($storage_class)) {
1298           mro::set_mro($storage_class, 'c3');
1299           bless $self, $storage_class;
1300           $self->_rebless();
1301         }
1302         else {
1303           $self->_warn_undetermined_driver(
1304             'This version of DBIC does not yet seem to supply a driver for '
1305           . "your particular RDBMS and/or connection method ('$driver')."
1306           );
1307         }
1308       }
1309       else {
1310         $self->_warn_undetermined_driver(
1311           'Unable to extract a driver name from connect info - this '
1312         . 'should not have happened.'
1313         );
1314       }
1315     }
1316
1317     $self->_driver_determined(1);
1318
1319     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1320
1321     if ($self->can('source_bind_attributes')) {
1322       $self->throw_exception(
1323         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1324       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1325       . 'If you are not sure how to proceed please contact the development team via '
1326       . DBIx::Class::_ENV_::HELP_URL
1327       );
1328     }
1329
1330     $self->_init; # run driver-specific initializations
1331
1332     $self->_run_connection_actions
1333         if !$started_connected && defined $self->_dbh;
1334   }
1335 }
1336
1337 sub _extract_driver_from_connect_info {
1338   my $self = shift;
1339
1340   my $drv;
1341
1342   # if connect_info is a CODEREF, we have no choice but to connect
1343   if (
1344     ref $self->_dbi_connect_info->[0]
1345       and
1346     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1347   ) {
1348     $self->_populate_dbh;
1349     $drv = $self->_dbh->{Driver}{Name};
1350   }
1351   else {
1352     # try to use dsn to not require being connected, the driver may still
1353     # force a connection later in _rebless to determine version
1354     # (dsn may not be supplied at all if all we do is make a mock-schema)
1355     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1356     $drv ||= $ENV{DBI_DRIVER};
1357   }
1358
1359   return $drv;
1360 }
1361
1362 sub _determine_connector_driver {
1363   my ($self, $conn) = @_;
1364
1365   my $dbtype = $self->_get_rdbms_name;
1366
1367   if (not $dbtype) {
1368     $self->_warn_undetermined_driver(
1369       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1370     . "$conn connector - this should not have happened."
1371     );
1372     return;
1373   }
1374
1375   $dbtype =~ s/\W/_/gi;
1376
1377   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1378   return if $self->isa($subclass);
1379
1380   if ($self->load_optional_class($subclass)) {
1381     bless $self, $subclass;
1382     $self->_rebless;
1383   }
1384   else {
1385     $self->_warn_undetermined_driver(
1386       'This version of DBIC does not yet seem to supply a driver for '
1387     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1388     );
1389   }
1390 }
1391
1392 sub _get_rdbms_name { shift->_dbh_get_info('SQL_DBMS_NAME') }
1393
1394 sub _warn_undetermined_driver {
1395   my ($self, $msg) = @_;
1396
1397   require Data::Dumper::Concise;
1398
1399   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1400   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1401   . "does not go away, file a bugreport including the following info:\n"
1402   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1403   );
1404 }
1405
1406 sub _do_connection_actions {
1407   my ($self, $method_prefix, $call, @args) = @_;
1408
1409   dbic_internal_try {
1410     if (not ref($call)) {
1411       my $method = $method_prefix . $call;
1412       $self->$method(@args);
1413     }
1414     elsif (ref($call) eq 'CODE') {
1415       $self->$call(@args);
1416     }
1417     elsif (ref($call) eq 'ARRAY') {
1418       if (ref($call->[0]) ne 'ARRAY') {
1419         $self->_do_connection_actions($method_prefix, $_) for @$call;
1420       }
1421       else {
1422         $self->_do_connection_actions($method_prefix, @$_) for @$call;
1423       }
1424     }
1425     else {
1426       $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1427     }
1428   }
1429   catch {
1430     if ( $method_prefix =~ /^connect/ ) {
1431       # this is an on_connect cycle - we can't just throw while leaving
1432       # a handle in an undefined state in our storage object
1433       # kill it with fire and rethrow
1434       $self->_dbh(undef);
1435       $self->disconnect;  # the $dbh is gone, but we still need to reset the rest
1436       $self->throw_exception( $_[0] );
1437     }
1438     else {
1439       carp "Disconnect action failed: $_[0]";
1440     }
1441   };
1442
1443   return $self;
1444 }
1445
1446 sub connect_call_do_sql {
1447   my $self = shift;
1448   $self->_do_query(@_);
1449 }
1450
1451 sub disconnect_call_do_sql {
1452   my $self = shift;
1453   $self->_do_query(@_);
1454 }
1455
1456 =head2 connect_call_datetime_setup
1457
1458 A no-op stub method, provided so that one can always safely supply the
1459 L<connection option|/DBIx::Class specific connection attributes>
1460
1461  on_connect_call => 'datetime_setup'
1462
1463 This way one does not need to know in advance whether the underlying
1464 storage requires any sort of hand-holding when dealing with calendar
1465 data.
1466
1467 =cut
1468
1469 sub connect_call_datetime_setup { 1 }
1470
1471 sub _do_query {
1472   my ($self, $action) = @_;
1473
1474   if (ref $action eq 'CODE') {
1475     $action = $action->($self);
1476     $self->_do_query($_) foreach @$action;
1477   }
1478   else {
1479     # Most debuggers expect ($sql, @bind), so we need to exclude
1480     # the attribute hash which is the second argument to $dbh->do
1481     # furthermore the bind values are usually to be presented
1482     # as named arrayref pairs, so wrap those here too
1483     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1484     my $sql = shift @do_args;
1485     my $attrs = shift @do_args;
1486     my @bind = map { [ undef, $_ ] } @do_args;
1487
1488     $self->dbh_do(sub {
1489       $_[0]->_query_start($sql, \@bind);
1490       $_[1]->do($sql, $attrs, @do_args);
1491       $_[0]->_query_end($sql, \@bind);
1492     });
1493   }
1494
1495   return $self;
1496 }
1497
1498 sub _connect {
1499   my $self = shift;
1500
1501   my $info = $self->_dbi_connect_info;
1502
1503   $self->throw_exception("You did not provide any connection_info")
1504     unless defined $info->[0];
1505
1506   my ($old_connect_via, $dbh);
1507
1508   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1509
1510   # this odd anonymous coderef dereference is in fact really
1511   # necessary to avoid the unwanted effect described in perl5
1512   # RT#75792
1513   #
1514   # in addition the coderef itself can't reside inside the try{} block below
1515   # as it somehow triggers a leak under perl -d
1516   my $dbh_error_handler_installer = sub {
1517     weaken (my $weak_self = $_[0]);
1518
1519     # the coderef is blessed so we can distinguish it from externally
1520     # supplied handles (which must be preserved)
1521     $_[1]->{HandleError} = bless sub {
1522       if ($weak_self) {
1523         $weak_self->throw_exception("DBI Exception: $_[0]");
1524       }
1525       else {
1526         # the handler may be invoked by something totally out of
1527         # the scope of DBIC
1528         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1529       }
1530     }, '__DBIC__DBH__ERROR__HANDLER__';
1531   };
1532
1533   dbic_internal_try {
1534     if(ref $info->[0] eq 'CODE') {
1535       $dbh = $info->[0]->();
1536     }
1537     else {
1538       require DBI;
1539       $dbh = DBI->connect(@$info);
1540     }
1541
1542     die $DBI::errstr unless $dbh;
1543
1544     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1545       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1546       . 'not continue',
1547       ref $info->[0] eq 'CODE'
1548         ? "Connection coderef $info->[0] returned a"
1549         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1550     ) unless $dbh->FETCH('Active');
1551
1552     # sanity checks unless asked otherwise
1553     unless ($self->unsafe) {
1554
1555       $self->throw_exception(
1556         'Refusing clobbering of {HandleError} installed on externally supplied '
1557        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1558       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1559
1560       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1561       # request, or an external handle. Complain and set anyway
1562       unless ($dbh->{RaiseError}) {
1563         carp( ref $info->[0] eq 'CODE'
1564
1565           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1566            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1567            .'attribute has been supplied'
1568
1569           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1570            .'unsafe => 1. Toggling RaiseError back to true'
1571         );
1572
1573         $dbh->{RaiseError} = 1;
1574       }
1575
1576       $dbh_error_handler_installer->($self, $dbh);
1577     }
1578   }
1579   catch {
1580     $self->throw_exception("DBI Connection failed: $_")
1581   };
1582
1583   $self->_dbh_autocommit($dbh->{AutoCommit});
1584   return $dbh;
1585 }
1586
1587 sub txn_begin {
1588   # this means we have not yet connected and do not know the AC status
1589   # (e.g. coderef $dbh), need a full-fledged connection check
1590   if (! defined $_[0]->_dbh_autocommit) {
1591     $_[0]->ensure_connected;
1592   }
1593   # Otherwise simply connect or re-connect on pid changes
1594   else {
1595     $_[0]->_get_dbh;
1596   }
1597
1598   shift->next::method(@_);
1599 }
1600
1601 sub _exec_txn_begin {
1602   my $self = shift;
1603
1604   # if the user is utilizing txn_do - good for him, otherwise we need to
1605   # ensure that the $dbh is healthy on BEGIN.
1606   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1607   # will be replaced by a failure of begin_work itself (which will be
1608   # then retried on reconnect)
1609   if ($self->{_in_do_block}) {
1610     $self->_dbh->begin_work;
1611   } else {
1612     $self->dbh_do(sub { $_[1]->begin_work });
1613   }
1614 }
1615
1616 sub txn_commit {
1617   my $self = shift;
1618
1619   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1620     unless $self->_seems_connected;
1621
1622   # esoteric case for folks using external $dbh handles
1623   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1624     carp "Storage transaction_depth 0 does not match "
1625         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1626     $self->transaction_depth(1);
1627   }
1628
1629   $self->next::method(@_);
1630
1631   # if AutoCommit is disabled txn_depth never goes to 0
1632   # as a new txn is started immediately on commit
1633   $self->transaction_depth(1) if (
1634     !$self->transaction_depth
1635       and
1636     defined $self->_dbh_autocommit
1637       and
1638     ! $self->_dbh_autocommit
1639   );
1640 }
1641
1642 sub _exec_txn_commit {
1643   shift->_dbh->commit;
1644 }
1645
1646 sub txn_rollback {
1647   my $self = shift;
1648
1649   # do a minimal connectivity check due to weird shit like
1650   # https://rt.cpan.org/Public/Bug/Display.html?id=62370
1651   $self->throw_exception("lost connection to storage")
1652     unless $self->_seems_connected;
1653
1654   # esoteric case for folks using external $dbh handles
1655   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1656     carp "Storage transaction_depth 0 does not match "
1657         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1658     $self->transaction_depth(1);
1659   }
1660
1661   $self->next::method(@_);
1662
1663   # if AutoCommit is disabled txn_depth never goes to 0
1664   # as a new txn is started immediately on commit
1665   $self->transaction_depth(1) if (
1666     !$self->transaction_depth
1667       and
1668     defined $self->_dbh_autocommit
1669       and
1670     ! $self->_dbh_autocommit
1671   );
1672 }
1673
1674 sub _exec_txn_rollback {
1675   shift->_dbh->rollback;
1676 }
1677
1678 # generate the DBI-specific stubs, which then fallback to ::Storage proper
1679 quote_sub __PACKAGE__ . "::$_" => sprintf (<<'EOS', $_) for qw(svp_begin svp_release svp_rollback);
1680   $_[0]->throw_exception('Unable to %s() on a disconnected storage')
1681     unless $_[0]->_seems_connected;
1682   shift->next::method(@_);
1683 EOS
1684
1685 # This used to be the top-half of _execute.  It was split out to make it
1686 #  easier to override in NoBindVars without duping the rest.  It takes up
1687 #  all of _execute's args, and emits $sql, @bind.
1688 sub _prep_for_execute {
1689   #my ($self, $op, $ident, $args) = @_;
1690   return shift->_gen_sql_bind(@_)
1691 }
1692
1693 sub _gen_sql_bind {
1694   my ($self, $op, $ident, $args) = @_;
1695
1696   my ($colinfos, $from);
1697   if ( blessed($ident) ) {
1698     $from = $ident->from;
1699     $colinfos = $ident->columns_info;
1700   }
1701
1702   my ($sql, $bind);
1703   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1704
1705   $bind = $self->_resolve_bindattrs(
1706     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1707   );
1708
1709   if (
1710     ! $ENV{DBIC_DT_SEARCH_OK}
1711       and
1712     $op eq 'select'
1713       and
1714     first {
1715       length ref $_->[1]
1716         and
1717       blessed($_->[1])
1718         and
1719       $_->[1]->isa('DateTime')
1720     } @$bind
1721   ) {
1722     carp_unique 'DateTime objects passed to search() are not supported '
1723       . 'properly (InflateColumn::DateTime formats and settings are not '
1724       . 'respected.) See ".. format a DateTime object for searching?" in '
1725       . 'DBIx::Class::Manual::FAQ. To disable this warning for good '
1726       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1727   }
1728
1729   return( $sql, $bind );
1730 }
1731
1732 sub _resolve_bindattrs {
1733   my ($self, $ident, $bind, $colinfos) = @_;
1734
1735   my $resolve_bindinfo = sub {
1736     #my $infohash = shift;
1737
1738     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1739
1740     my $ret;
1741     if (my $col = $_[0]->{dbic_colname}) {
1742       $ret = { %{$_[0]} };
1743
1744       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1745         if $colinfos->{$col}{data_type};
1746
1747       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1748         if $colinfos->{$col}{size};
1749     }
1750
1751     $ret || $_[0];
1752   };
1753
1754   return [ map {
1755       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1756     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1757     : (ref $_->[0] eq 'HASH')           ? [(
1758                                             ! keys %{$_->[0]}
1759                                               or
1760                                             exists $_->[0]{dbd_attrs}
1761                                               or
1762                                             $_->[0]{sqlt_datatype}
1763                                            ) ? $_->[0]
1764                                              : $resolve_bindinfo->($_->[0])
1765                                            , $_->[1]
1766                                           ]
1767     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1768     :                                     [ $resolve_bindinfo->(
1769                                               { dbic_colname => $_->[0] }
1770                                             ), $_->[1] ]
1771   } @$bind ];
1772 }
1773
1774 sub _format_for_trace {
1775   #my ($self, $bind) = @_;
1776
1777   ### Turn @bind from something like this:
1778   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1779   ### to this:
1780   ###   ( "'1'", "'3'" )
1781
1782   map {
1783     defined( $_ && $_->[1] )
1784       ? qq{'$_->[1]'}
1785       : q{NULL}
1786   } @{$_[1] || []};
1787 }
1788
1789 sub _query_start {
1790   my ( $self, $sql, $bind ) = @_;
1791
1792   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1793     if $self->debug;
1794 }
1795
1796 sub _query_end {
1797   my ( $self, $sql, $bind ) = @_;
1798
1799   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1800     if $self->debug;
1801 }
1802
1803 sub _dbi_attrs_for_bind {
1804   #my ($self, $ident, $bind) = @_;
1805
1806   return [ map {
1807
1808     exists $_->{dbd_attrs}  ?  $_->{dbd_attrs}
1809
1810   : ! $_->{sqlt_datatype}   ? undef
1811
1812   :                           do {
1813
1814     # cache the result in the dbh_details hash, as it (usually) can not change
1815     # unless we connect to something else
1816     # FIXME: for the time being Oracle is an exception, pending a rewrite of
1817     # the LOB storage
1818     my $cache = $_[0]->_dbh_details->{_datatype_map_cache} ||= {};
1819
1820     $cache->{$_->{sqlt_datatype}} = $_[0]->bind_attribute_by_data_type($_->{sqlt_datatype})
1821       if ! exists $cache->{$_->{sqlt_datatype}};
1822
1823     $cache->{$_->{sqlt_datatype}};
1824
1825   } } map { $_->[0] } @{$_[2]} ];
1826 }
1827
1828 sub _execute {
1829   my ($self, $op, $ident, @args) = @_;
1830
1831   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1832
1833   # not even a PID check - we do not care about the state of the _dbh.
1834   # All we need is to get the appropriate drivers loaded if they aren't
1835   # already so that the assumption in ad7c50fc26e holds
1836   $self->_populate_dbh unless $self->_dbh;
1837
1838   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1839     $sql,
1840     $bind,
1841     $self->_dbi_attrs_for_bind($ident, $bind),
1842   );
1843 }
1844
1845 sub _dbh_execute {
1846   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1847
1848   $self->_query_start( $sql, $bind );
1849
1850   my $sth = $self->_bind_sth_params(
1851     $self->_prepare_sth($dbh, $sql),
1852     $bind,
1853     $bind_attrs,
1854   );
1855
1856   # Can this fail without throwing an exception anyways???
1857   my $rv = $sth->execute();
1858   $self->throw_exception(
1859     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1860   ) if !$rv;
1861
1862   $self->_query_end( $sql, $bind );
1863
1864   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1865 }
1866
1867 sub _prepare_sth {
1868   my ($self, $dbh, $sql) = @_;
1869
1870   # 3 is the if_active parameter which avoids active sth re-use
1871   my $sth = $self->disable_sth_caching
1872     ? $dbh->prepare($sql)
1873     : $dbh->prepare_cached($sql, {}, 3);
1874
1875   # XXX You would think RaiseError would make this impossible,
1876   #  but apparently that's not true :(
1877   $self->throw_exception(
1878     $dbh->errstr
1879       ||
1880     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1881             .'an exception and/or setting $dbh->errstr',
1882       length ($sql) > 20
1883         ? substr($sql, 0, 20) . '...'
1884         : $sql
1885       ,
1886       'DBD::' . $dbh->{Driver}{Name},
1887     )
1888   ) if !$sth;
1889
1890   $sth;
1891 }
1892
1893 sub _bind_sth_params {
1894   my ($self, $sth, $bind, $bind_attrs) = @_;
1895
1896   for my $i (0 .. $#$bind) {
1897     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1898       $sth->bind_param_inout(
1899         $i + 1, # bind params counts are 1-based
1900         $bind->[$i][1],
1901         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1902         $bind_attrs->[$i],
1903       );
1904     }
1905     else {
1906       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
1907       my $v = ( length ref $bind->[$i][1] and is_plain_value $bind->[$i][1] )
1908         ? "$bind->[$i][1]"
1909         : $bind->[$i][1]
1910       ;
1911
1912       $sth->bind_param(
1913         $i + 1,
1914         # The temp-var is CRUCIAL - DO NOT REMOVE IT, breaks older DBD::SQLite RT#79576
1915         $v,
1916         $bind_attrs->[$i],
1917       );
1918     }
1919   }
1920
1921   $sth;
1922 }
1923
1924 sub _prefetch_autovalues {
1925   my ($self, $source, $colinfo, $to_insert) = @_;
1926
1927   my %values;
1928   for my $col (keys %$colinfo) {
1929     if (
1930       $colinfo->{$col}{auto_nextval}
1931         and
1932       (
1933         ! exists $to_insert->{$col}
1934           or
1935         is_literal_value($to_insert->{$col})
1936       )
1937     ) {
1938       $values{$col} = $self->_sequence_fetch(
1939         'NEXTVAL',
1940         ( $colinfo->{$col}{sequence} ||=
1941             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1942         ),
1943       );
1944     }
1945   }
1946
1947   \%values;
1948 }
1949
1950 sub insert {
1951   my ($self, $source, $to_insert) = @_;
1952
1953   my $col_infos = $source->columns_info;
1954
1955   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1956
1957   # fuse the values, but keep a separate list of prefetched_values so that
1958   # they can be fused once again with the final return
1959   $to_insert = { %$to_insert, %$prefetched_values };
1960
1961   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1962   # Investigate what does it take to s/defined/exists/
1963   my %pcols = map { $_ => 1 } $source->primary_columns;
1964   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1965   for my $col ($source->columns) {
1966     if ($col_infos->{$col}{is_auto_increment}) {
1967       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1968       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1969     }
1970
1971     # nothing to retrieve when explicit values are supplied
1972     next if (
1973       defined $to_insert->{$col} and ! is_literal_value($to_insert->{$col})
1974     );
1975
1976     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1977     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1978       $pcols{$col}
1979         or
1980       $col_infos->{$col}{retrieve_on_insert}
1981     );
1982   };
1983
1984   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1985   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1986
1987   my ($sqla_opts, @ir_container);
1988   if (%retrieve_cols and $self->_use_insert_returning) {
1989     $sqla_opts->{returning_container} = \@ir_container
1990       if $self->_use_insert_returning_bound;
1991
1992     $sqla_opts->{returning} = [
1993       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1994     ];
1995   }
1996
1997   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1998
1999   my %returned_cols = %$to_insert;
2000   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
2001
2002     unless( @ir_container ) {
2003       dbic_internal_try {
2004
2005         # FIXME - need to investigate why Caelum silenced this in 4d4dc518
2006         local $SIG{__WARN__} = sub {};
2007
2008         @ir_container = $sth->fetchrow_array;
2009         $sth->finish;
2010
2011       } catch {
2012         # Evict the $sth from the cache in case we got here, since the finish()
2013         # is crucial, at least on older Firebirds, possibly on other engines too
2014         #
2015         # It would be too complex to make this a proper subclass override,
2016         # and besides we already take the try{} penalty, adding a catch that
2017         # triggers infrequently is a no-brainer
2018         #
2019         if( my $kids = $self->_dbh->{CachedKids} ) {
2020           $kids->{$_} == $sth and delete $kids->{$_}
2021             for keys %$kids
2022         }
2023       };
2024     }
2025
2026     @returned_cols{@$retlist} = @ir_container if @ir_container;
2027   }
2028   else {
2029     # pull in PK if needed and then everything else
2030     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2031
2032       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2033         unless $self->can('last_insert_id');
2034
2035       my @pri_values = $self->last_insert_id($source, @missing_pri);
2036
2037       $self->throw_exception( "Can't get last insert id" )
2038         unless (@pri_values == @missing_pri);
2039
2040       @returned_cols{@missing_pri} = @pri_values;
2041       delete @retrieve_cols{@missing_pri};
2042     }
2043
2044     # if there is more left to pull
2045     if (%retrieve_cols) {
2046       $self->throw_exception(
2047         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2048       ) unless %pcols;
2049
2050       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2051
2052       my $cur = DBIx::Class::ResultSet->new($source, {
2053         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2054         select => \@left_to_fetch,
2055       })->cursor;
2056
2057       @returned_cols{@left_to_fetch} = $cur->next;
2058
2059       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2060         if scalar $cur->next;
2061     }
2062   }
2063
2064   return { %$prefetched_values, %returned_cols };
2065 }
2066
2067 sub insert_bulk {
2068   carp_unique(
2069     'insert_bulk() should have never been exposed as a public method and '
2070   . 'calling it is depecated as of Aug 2014. If you believe having a genuine '
2071   . 'use for this method please contact the development team via '
2072   . DBIx::Class::_ENV_::HELP_URL
2073   );
2074
2075   return '0E0' unless @{$_[3]||[]};
2076
2077   shift->_insert_bulk(@_);
2078 }
2079
2080 sub _insert_bulk {
2081   my ($self, $source, $cols, $data) = @_;
2082
2083   $self->throw_exception('Calling _insert_bulk without a dataset to process makes no sense')
2084     unless @{$data||[]};
2085
2086   my $colinfos = $source->columns_info($cols);
2087
2088   local $self->{_autoinc_supplied_for_op} =
2089     (grep { $_->{is_auto_increment} } values %$colinfos)
2090       ? 1
2091       : 0
2092   ;
2093
2094   # get a slice type index based on first row of data
2095   # a "column" in this context may refer to more than one bind value
2096   # e.g. \[ '?, ?', [...], [...] ]
2097   #
2098   # construct the value type index - a description of values types for every
2099   # per-column slice of $data:
2100   #
2101   # nonexistent - nonbind literal
2102   # 0 - regular value
2103   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2104   #
2105   # also construct the column hash to pass to the SQL generator. For plain
2106   # (non literal) values - convert the members of the first row into a
2107   # literal+bind combo, with extra positional info in the bind attr hashref.
2108   # This will allow us to match the order properly, and is so contrived
2109   # because a user-supplied literal/bind (or something else specific to a
2110   # resultsource and/or storage driver) can inject extra binds along the
2111   # way, so one can't rely on "shift positions" ordering at all. Also we
2112   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2113   # can be later matched up by address), because we want to supply a real
2114   # value on which perhaps e.g. datatype checks will be performed
2115   my ($proto_data, $serialized_bind_type_by_col_idx);
2116   for my $col_idx (0..$#$cols) {
2117     my $colname = $cols->[$col_idx];
2118     if (ref $data->[0][$col_idx] eq 'SCALAR') {
2119       # no bind value at all - no type
2120
2121       $proto_data->{$colname} = $data->[0][$col_idx];
2122     }
2123     elsif (ref $data->[0][$col_idx] eq 'REF' and ref ${$data->[0][$col_idx]} eq 'ARRAY' ) {
2124       # repack, so we don't end up mangling the original \[]
2125       my ($sql, @bind) = @${$data->[0][$col_idx]};
2126
2127       # normalization of user supplied stuff
2128       my $resolved_bind = $self->_resolve_bindattrs(
2129         $source, \@bind, $colinfos,
2130       );
2131
2132       # store value-less (attrs only) bind info - we will be comparing all
2133       # supplied binds against this for sanity
2134       $serialized_bind_type_by_col_idx->{$col_idx} = serialize [ map { $_->[0] } @$resolved_bind ];
2135
2136       $proto_data->{$colname} = \[ $sql, map { [
2137         # inject slice order to use for $proto_bind construction
2138           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $col_idx, _literal_bind_subindex => $_+1 }
2139             =>
2140           $resolved_bind->[$_][1]
2141         ] } (0 .. $#bind)
2142       ];
2143     }
2144     else {
2145       $serialized_bind_type_by_col_idx->{$col_idx} = undef;
2146
2147       $proto_data->{$colname} = \[ '?', [
2148         { dbic_colname => $colname, _bind_data_slice_idx => $col_idx }
2149           =>
2150         $data->[0][$col_idx]
2151       ] ];
2152     }
2153   }
2154
2155   my ($sql, $proto_bind) = $self->_prep_for_execute (
2156     'insert',
2157     $source,
2158     [ $proto_data ],
2159   );
2160
2161   if (! @$proto_bind and keys %$serialized_bind_type_by_col_idx) {
2162     # if the bindlist is empty and we had some dynamic binds, this means the
2163     # storage ate them away (e.g. the NoBindVars component) and interpolated
2164     # them directly into the SQL. This obviously can't be good for multi-inserts
2165     $self->throw_exception('Unable to invoke fast-path insert without storage placeholder support');
2166   }
2167
2168   # sanity checks
2169   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2170   #
2171   # use an error reporting closure for convenience (less to pass)
2172   my $bad_slice_report_cref = sub {
2173     my ($msg, $r_idx, $c_idx) = @_;
2174     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2175       $msg,
2176       $cols->[$c_idx],
2177       do {
2178         require Data::Dumper::Concise;
2179         local $Data::Dumper::Maxdepth = 5;
2180         Data::Dumper::Concise::Dumper ({
2181           map { $cols->[$_] =>
2182             $data->[$r_idx][$_]
2183           } 0..$#$cols
2184         }),
2185       }
2186     );
2187   };
2188
2189   for my $col_idx (0..$#$cols) {
2190     my $reference_val = $data->[0][$col_idx];
2191
2192     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2193       my $val = $data->[$row_idx][$col_idx];
2194
2195       if (! exists $serialized_bind_type_by_col_idx->{$col_idx}) { # literal no binds
2196         if (ref $val ne 'SCALAR') {
2197           $bad_slice_report_cref->(
2198             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2199             $row_idx,
2200             $col_idx,
2201           );
2202         }
2203         elsif ($$val ne $$reference_val) {
2204           $bad_slice_report_cref->(
2205             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2206             $row_idx,
2207             $col_idx,
2208           );
2209         }
2210       }
2211       elsif (! defined $serialized_bind_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2212         if (is_literal_value($val)) {
2213           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2214         }
2215       }
2216       else {  # binds from a \[], compare type and attrs
2217         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2218           $bad_slice_report_cref->(
2219             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2220             $row_idx,
2221             $col_idx,
2222           );
2223         }
2224         # start drilling down and bail out early on identical refs
2225         elsif (
2226           $reference_val != $val
2227             or
2228           $$reference_val != $$val
2229         ) {
2230           if (${$val}->[0] ne ${$reference_val}->[0]) {
2231             $bad_slice_report_cref->(
2232               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2233               $row_idx,
2234               $col_idx,
2235             );
2236           }
2237           # need to check the bind attrs - a bind will happen only once for
2238           # the entire dataset, so any changes further down will be ignored.
2239           elsif (
2240             $serialized_bind_type_by_col_idx->{$col_idx}
2241               ne
2242             serialize [
2243               map
2244               { $_->[0] }
2245               @{$self->_resolve_bindattrs(
2246                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2247               )}
2248             ]
2249           ) {
2250             $bad_slice_report_cref->(
2251               'Differing bind attributes on literal/bind values not supported',
2252               $row_idx,
2253               $col_idx,
2254             );
2255           }
2256         }
2257       }
2258     }
2259   }
2260
2261   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2262   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2263   # scope guard
2264   my $guard = $self->txn_scope_guard;
2265
2266   $self->_query_start( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2267   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2268   my $rv = do {
2269     if (@$proto_bind) {
2270       # proto bind contains the information on which pieces of $data to pull
2271       # $cols is passed in only for prettier error-reporting
2272       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2273     }
2274     else {
2275       # bind_param_array doesn't work if there are no binds
2276       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2277     }
2278   };
2279
2280   $self->_query_end( $sql, @$proto_bind ? [[ {} => '__BULK_INSERT__' ]] : () );
2281
2282   $guard->commit;
2283
2284   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2285 }
2286
2287 # execute_for_fetch is capable of returning data just fine (it means it
2288 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2289 # is the void-populate fast-path we will just ignore this altogether
2290 # for the time being.
2291 sub _dbh_execute_for_fetch {
2292   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2293
2294   # If we have any bind attributes to take care of, we will bind the
2295   # proto-bind data (which will never be used by execute_for_fetch)
2296   # However since column bindtypes are "sticky", this is sufficient
2297   # to get the DBD to apply the bindtype to all values later on
2298   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2299
2300   for my $i (0 .. $#$proto_bind) {
2301     $sth->bind_param (
2302       $i+1, # DBI bind indexes are 1-based
2303       $proto_bind->[$i][1],
2304       $bind_attrs->[$i],
2305     ) if defined $bind_attrs->[$i];
2306   }
2307
2308   # At this point $data slots named in the _bind_data_slice_idx of
2309   # each piece of $proto_bind are either \[]s or plain values to be
2310   # passed in. Construct the dispensing coderef. *NOTE* the order
2311   # of $data will differ from this of the ?s in the SQL (due to
2312   # alphabetical ordering by colname). We actually do want to
2313   # preserve this behavior so that prepare_cached has a better
2314   # chance of matching on unrelated calls
2315
2316   my $fetch_row_idx = -1; # saner loop this way
2317   my $fetch_tuple = sub {
2318     return undef if ++$fetch_row_idx > $#$data;
2319
2320     return [ map {
2321       my $v = ! defined $_->{_literal_bind_subindex}
2322
2323         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2324
2325         # There are no attributes to resolve here - we already did everything
2326         # when we constructed proto_bind. However we still want to sanity-check
2327         # what the user supplied, so pass stuff through to the resolver *anyway*
2328         : $self->_resolve_bindattrs (
2329             undef,  # a fake rsrc
2330             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2331             {},     # a fake column_info bag
2332           )->[0][1]
2333       ;
2334
2335       # FIXME SUBOPTIMAL - DBI needs fixing to always stringify regardless of DBD
2336       # For the time being forcibly stringify whatever is stringifiable
2337       my $vref;
2338
2339       ( !length ref $v or ! ($vref = is_plain_value $v) )   ? $v
2340     : defined blessed( $$vref )                             ? "$$vref"
2341                                                             : $$vref
2342     ;
2343     } map { $_->[0] } @$proto_bind ];
2344   };
2345
2346   my $tuple_status = [];
2347   my ($rv, $err);
2348   dbic_internal_try {
2349     $rv = $sth->execute_for_fetch(
2350       $fetch_tuple,
2351       $tuple_status,
2352     );
2353   }
2354   catch {
2355     $err = shift;
2356   };
2357
2358   # Not all DBDs are create equal. Some throw on error, some return
2359   # an undef $rv, and some set $sth->err - try whatever we can
2360   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2361     ! defined $err
2362       and
2363     ( !defined $rv or $sth->err )
2364   );
2365
2366   # Statement must finish even if there was an exception.
2367   dbic_internal_try {
2368     $sth->finish
2369   }
2370   catch {
2371     $err = shift unless defined $err
2372   };
2373
2374   if (defined $err) {
2375     my $i = 0;
2376     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2377
2378     $self->throw_exception("Unexpected populate error: $err")
2379       if ($i > $#$tuple_status);
2380
2381     require Data::Dumper::Concise;
2382     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2383       ($tuple_status->[$i][1] || $err),
2384       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2385     );
2386   }
2387
2388   return $rv;
2389 }
2390
2391 sub _dbh_execute_inserts_with_no_binds {
2392   my ($self, $sth, $count) = @_;
2393
2394   my $err;
2395   dbic_internal_try {
2396     my $dbh = $self->_get_dbh;
2397     local $dbh->{RaiseError} = 1;
2398     local $dbh->{PrintError} = 0;
2399
2400     $sth->execute foreach 1..$count;
2401   }
2402   catch {
2403     $err = shift;
2404   };
2405
2406   # Make sure statement is finished even if there was an exception.
2407   dbic_internal_try {
2408     $sth->finish
2409   }
2410   catch {
2411     $err = shift unless defined $err;
2412   };
2413
2414   $self->throw_exception($err) if defined $err;
2415
2416   return $count;
2417 }
2418
2419 sub update {
2420   #my ($self, $source, @args) = @_;
2421   shift->_execute('update', @_);
2422 }
2423
2424
2425 sub delete {
2426   #my ($self, $source, @args) = @_;
2427   shift->_execute('delete', @_);
2428 }
2429
2430 sub _select {
2431   my $self = shift;
2432   $self->_execute($self->_select_args(@_));
2433 }
2434
2435 sub _select_args_to_query {
2436   my $self = shift;
2437
2438   $self->throw_exception(
2439     "Unable to generate limited query representation with 'software_limit' enabled"
2440   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2441
2442   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2443   #  = $self->_select_args($ident, $select, $cond, $attrs);
2444   my ($op, $ident, @args) =
2445     $self->_select_args(@_);
2446
2447   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2448   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2449
2450   # reuse the bind arrayref
2451   unshift @{$bind}, "($sql)";
2452   \$bind;
2453 }
2454
2455 sub _select_args {
2456   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2457
2458   # FIXME - that kind of caching would be nice to have
2459   # however currently we *may* pass the same $orig_attrs
2460   # with different ident/select/where
2461   # the whole interface needs to be rethought, since it
2462   # was centered around the flawed SQLA API. We can do
2463   # soooooo much better now. But that is also another
2464   # battle...
2465   #return (
2466   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2467   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2468
2469   my $sql_maker = $self->sql_maker;
2470
2471   my $attrs = {
2472     %$orig_attrs,
2473     select => $select,
2474     from => $ident,
2475     where => $where,
2476   };
2477
2478   # MySQL actually recommends this approach.  I cringe.
2479   $attrs->{rows} ||= $sql_maker->__max_int
2480     if $attrs->{offset};
2481
2482   # see if we will need to tear the prefetch apart to satisfy group_by == select
2483   # this is *extremely tricky* to get right, I am still not sure I did
2484   #
2485   my ($prefetch_needs_subquery, @limit_args);
2486
2487   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2488     # we already know there is a valid group_by (we made it) and we know it is
2489     # intended to be based *only* on non-multi stuff
2490     # short circuit the group_by parsing below
2491     $prefetch_needs_subquery = 1;
2492   }
2493   elsif (
2494     # The rationale is that even if we do *not* have collapse, we still
2495     # need to wrap the core grouped select/group_by in a subquery
2496     # so that databases that care about group_by/select equivalence
2497     # are happy (this includes MySQL in strict_mode)
2498     # If any of the other joined tables are referenced in the group_by
2499     # however - the user is on their own
2500     ( $prefetch_needs_subquery or ! $attrs->{_simple_passthrough_construction} )
2501       and
2502     $attrs->{group_by}
2503       and
2504     @{$attrs->{group_by}}
2505       and
2506     my $grp_aliases = dbic_internal_try { # internal_try{} because $attrs->{from} may be unreadable
2507       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2508     }
2509   ) {
2510     # no aliases other than our own in group_by
2511     # if there are - do not allow subquery even if limit is present
2512     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2513   }
2514   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2515     # active collapse with a limit - that one is a no-brainer unless
2516     # overruled by a group_by above
2517     $prefetch_needs_subquery = 1;
2518   }
2519
2520   if ($prefetch_needs_subquery) {
2521     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2522   }
2523   elsif (! $attrs->{software_limit} ) {
2524     push @limit_args, (
2525       $attrs->{rows} || (),
2526       $attrs->{offset} || (),
2527     );
2528   }
2529
2530   # try to simplify the joinmap further (prune unreferenced type-single joins)
2531   if (
2532     ! $prefetch_needs_subquery  # already pruned
2533       and
2534     ref $attrs->{from}
2535       and
2536     reftype $attrs->{from} eq 'ARRAY'
2537       and
2538     @{$attrs->{from}} != 1
2539   ) {
2540     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2541   }
2542
2543   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2544   # during the result inflation stage we *need* to know what was the aliastype
2545   # map as sqla saw it when the final pieces of SQL were being assembled
2546   # Originally we simply carried around the entirety of $attrs, but this
2547   # resulted in resultsets that are being reused growing continuously, as
2548   # the hash in question grew deeper and deeper.
2549   # Instead hand-pick what to take with us here (we actually don't need much
2550   # at this point just the map itself)
2551   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2552
2553 ###
2554   #   my $alias2source = $self->_resolve_ident_sources ($ident);
2555   #
2556   # This would be the point to deflate anything found in $attrs->{where}
2557   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2558   # expect a result object. And all we have is a resultsource (it is trivial
2559   # to extract deflator coderefs via $alias2source above).
2560   #
2561   # I don't see a way forward other than changing the way deflators are
2562   # invoked, and that's just bad...
2563 ###
2564
2565   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2566 }
2567
2568 # Returns a counting SELECT for a simple count
2569 # query. Abstracted so that a storage could override
2570 # this to { count => 'firstcol' } or whatever makes
2571 # sense as a performance optimization
2572 sub _count_select {
2573   #my ($self, $source, $rs_attrs) = @_;
2574   return { count => '*' };
2575 }
2576
2577 =head2 select
2578
2579 =over 4
2580
2581 =item Arguments: $ident, $select, $condition, $attrs
2582
2583 =back
2584
2585 Handle a SQL select statement.
2586
2587 =cut
2588
2589 sub select {
2590   my $self = shift;
2591   my ($ident, $select, $condition, $attrs) = @_;
2592   return $self->cursor_class->new($self, \@_, $attrs);
2593 }
2594
2595 sub select_single {
2596   my $self = shift;
2597   my ($rv, $sth, @bind) = $self->_select(@_);
2598   my @row = $sth->fetchrow_array;
2599   my @nextrow = $sth->fetchrow_array if @row;
2600   if(@row && @nextrow) {
2601     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2602   }
2603   # Need to call finish() to work round broken DBDs
2604   $sth->finish();
2605   return @row;
2606 }
2607
2608 =head2 sql_limit_dialect
2609
2610 This is an accessor for the default SQL limit dialect used by a particular
2611 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2612 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2613 see L<DBIx::Class::SQLMaker::LimitDialects>.
2614
2615 =cut
2616
2617 sub _dbh_columns_info_for {
2618   my ($self, $dbh, $table) = @_;
2619
2620   my %result;
2621
2622   if (! DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE and $dbh->can('column_info')) {
2623     dbic_internal_try {
2624       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2625       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2626       $sth->execute();
2627       while ( my $info = $sth->fetchrow_hashref() ){
2628         my %column_info;
2629         $column_info{data_type}   = $info->{TYPE_NAME};
2630         $column_info{size}      = $info->{COLUMN_SIZE};
2631         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2632         $column_info{default_value} = $info->{COLUMN_DEF};
2633         my $col_name = $info->{COLUMN_NAME};
2634         $col_name =~ s/^\"(.*)\"$/$1/;
2635
2636         $result{$col_name} = \%column_info;
2637       }
2638     } catch {
2639       %result = ();
2640     };
2641
2642     return \%result if keys %result;
2643   }
2644
2645   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2646   $sth->execute;
2647
2648 ### The acrobatics with lc names is necessary to support both the legacy
2649 ### API that used NAME_lc exclusively, *AND* at the same time work properly
2650 ### with column names differing in cas eonly (thanks pg!)
2651
2652   my ($columns, $seen_lcs);
2653
2654   ++$seen_lcs->{lc($_)} and $columns->{$_} = {
2655     idx => scalar keys %$columns,
2656     name => $_,
2657     lc_name => lc($_),
2658   } for @{$sth->{NAME}};
2659
2660   $seen_lcs->{$_->{lc_name}} == 1
2661     and
2662   $_->{name} = $_->{lc_name}
2663     for values %$columns;
2664
2665   for ( values %$columns ) {
2666     my $inf = {
2667       data_type => $sth->{TYPE}->[$_->{idx}],
2668       size => $sth->{PRECISION}->[$_->{idx}],
2669       is_nullable => $sth->{NULLABLE}->[$_->{idx}] ? 1 : 0,
2670     };
2671
2672     if ($inf->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2673       @{$inf}{qw( data_type  size)} = ($1, $2);
2674     }
2675
2676     $result{$_->{name}} = $inf;
2677   }
2678
2679   $sth->finish;
2680
2681   if ($dbh->can('type_info')) {
2682     for my $inf (values %result) {
2683       next if ! defined $inf->{data_type};
2684
2685       $inf->{data_type} = (
2686         (
2687           (
2688             $dbh->type_info( $inf->{data_type} )
2689               ||
2690             next
2691           )
2692             ||
2693           next
2694         )->{TYPE_NAME}
2695           ||
2696         next
2697       );
2698
2699       # FIXME - this may be an artifact of the DBD::Pg implmentation alone
2700       # needs more testing in the future...
2701       $inf->{size} -= 4 if (
2702         ( $inf->{size}||0 > 4 )
2703           and
2704         $inf->{data_type} =~ qr/^text$/i
2705       );
2706     }
2707
2708   }
2709
2710   return \%result;
2711 }
2712
2713 sub columns_info_for {
2714   my ($self, $table) = @_;
2715   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2716 }
2717
2718 =head2 last_insert_id
2719
2720 Return the row id of the last insert.
2721
2722 =cut
2723
2724 sub _dbh_last_insert_id {
2725     my ($self, $dbh, $source, $col) = @_;
2726
2727     my $id = dbic_internal_try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2728
2729     return $id if defined $id;
2730
2731     my $class = ref $self;
2732     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2733 }
2734
2735 sub last_insert_id {
2736   my $self = shift;
2737   $self->_dbh_last_insert_id ($self->_dbh, @_);
2738 }
2739
2740 =head2 _native_data_type
2741
2742 =over 4
2743
2744 =item Arguments: $type_name
2745
2746 =back
2747
2748 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2749 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2750 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2751
2752 The default implementation returns C<undef>, implement in your Storage driver if
2753 you need this functionality.
2754
2755 Should map types from other databases to the native RDBMS type, for example
2756 C<VARCHAR2> to C<VARCHAR>.
2757
2758 Types with modifiers should map to the underlying data type. For example,
2759 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2760
2761 Composite types should map to the container type, for example
2762 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2763
2764 =cut
2765
2766 sub _native_data_type {
2767   #my ($self, $data_type) = @_;
2768   return undef
2769 }
2770
2771 # Check if placeholders are supported at all
2772 sub _determine_supports_placeholders {
2773   my $self = shift;
2774   my $dbh  = $self->_get_dbh;
2775
2776   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2777   # but it is inaccurate more often than not
2778   ( dbic_internal_try {
2779     local $dbh->{PrintError} = 0;
2780     local $dbh->{RaiseError} = 1;
2781     $dbh->do('select ?', {}, 1);
2782     1;
2783   } )
2784     ? 1
2785     : 0
2786   ;
2787 }
2788
2789 # Check if placeholders bound to non-string types throw exceptions
2790 #
2791 sub _determine_supports_typeless_placeholders {
2792   my $self = shift;
2793   my $dbh  = $self->_get_dbh;
2794
2795   ( dbic_internal_try {
2796     local $dbh->{PrintError} = 0;
2797     local $dbh->{RaiseError} = 1;
2798     # this specifically tests a bind that is NOT a string
2799     $dbh->do('select 1 where 1 = ?', {}, 1);
2800     1;
2801   } )
2802     ? 1
2803     : 0
2804   ;
2805 }
2806
2807 =head2 sqlt_type
2808
2809 Returns the database driver name.
2810
2811 =cut
2812
2813 sub sqlt_type {
2814   shift->_get_dbh->{Driver}->{Name};
2815 }
2816
2817 =head2 bind_attribute_by_data_type
2818
2819 Given a datatype from column info, returns a database specific bind
2820 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2821 let the database planner just handle it.
2822
2823 This method is always called after the driver has been determined and a DBI
2824 connection has been established. Therefore you can refer to C<DBI::$constant>
2825 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2826 the correct modules.
2827
2828 =cut
2829
2830 sub bind_attribute_by_data_type {
2831     return;
2832 }
2833
2834 =head2 is_datatype_numeric
2835
2836 Given a datatype from column_info, returns a boolean value indicating if
2837 the current RDBMS considers it a numeric value. This controls how
2838 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2839 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2840 be performed instead of the usual C<eq>.
2841
2842 =cut
2843
2844 sub is_datatype_numeric {
2845   #my ($self, $dt) = @_;
2846
2847   return 0 unless $_[1];
2848
2849   $_[1] =~ /^ (?:
2850     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2851   ) $/ix;
2852 }
2853
2854
2855 =head2 create_ddl_dir
2856
2857 =over 4
2858
2859 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2860
2861 =back
2862
2863 Creates a SQL file based on the Schema, for each of the specified
2864 database engines in C<\@databases> in the given directory.
2865 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2866
2867 Given a previous version number, this will also create a file containing
2868 the ALTER TABLE statements to transform the previous schema into the
2869 current one. Note that these statements may contain C<DROP TABLE> or
2870 C<DROP COLUMN> statements that can potentially destroy data.
2871
2872 The file names are created using the C<ddl_filename> method below, please
2873 override this method in your schema if you would like a different file
2874 name format. For the ALTER file, the same format is used, replacing
2875 $version in the name with "$preversion-$version".
2876
2877 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2878 The most common value for this would be C<< { add_drop_table => 1 } >>
2879 to have the SQL produced include a C<DROP TABLE> statement for each table
2880 created. For quoting purposes supply C<quote_identifiers>.
2881
2882 If no arguments are passed, then the following default values are assumed:
2883
2884 =over 4
2885
2886 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2887
2888 =item version    - $schema->schema_version
2889
2890 =item directory  - './'
2891
2892 =item preversion - <none>
2893
2894 =back
2895
2896 By default, C<\%sqlt_args> will have
2897
2898  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2899
2900 merged with the hash passed in. To disable any of those features, pass in a
2901 hashref like the following
2902
2903  { ignore_constraint_names => 0, # ... other options }
2904
2905
2906 WARNING: You are strongly advised to check all SQL files created, before applying
2907 them.
2908
2909 =cut
2910
2911 sub create_ddl_dir {
2912   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2913
2914   unless ($dir) {
2915     carp "No directory given, using ./\n";
2916     $dir = './';
2917   } else {
2918       -d $dir
2919         or
2920       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2921         or
2922       $self->throw_exception(
2923         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2924       );
2925   }
2926
2927   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2928
2929   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2930   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2931
2932   my $schema_version = $schema->schema_version || '1.x';
2933   $version ||= $schema_version;
2934
2935   $sqltargs = {
2936     add_drop_table => 1,
2937     ignore_constraint_names => 1,
2938     ignore_index_names => 1,
2939     quote_identifiers => $self->sql_maker->_quoting_enabled,
2940     %{$sqltargs || {}}
2941   };
2942
2943   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')) {
2944     $self->throw_exception("Can't create a ddl file without $missing");
2945   }
2946
2947   my $sqlt = SQL::Translator->new( $sqltargs );
2948
2949   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2950   my $sqlt_schema = $sqlt->translate({ data => $schema })
2951     or $self->throw_exception ($sqlt->error);
2952
2953   foreach my $db (@$databases) {
2954     $sqlt->reset();
2955     $sqlt->{schema} = $sqlt_schema;
2956     $sqlt->producer($db);
2957
2958     my $file;
2959     my $filename = $schema->ddl_filename($db, $version, $dir);
2960     if (-e $filename && ($version eq $schema_version )) {
2961       # if we are dumping the current version, overwrite the DDL
2962       carp "Overwriting existing DDL file - $filename";
2963       unlink($filename);
2964     }
2965
2966     my $output = $sqlt->translate;
2967     if(!$output) {
2968       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2969       next;
2970     }
2971     if(!open($file, ">$filename")) {
2972       $self->throw_exception("Can't open $filename for writing ($!)");
2973       next;
2974     }
2975     print $file $output;
2976     close($file);
2977
2978     next unless ($preversion);
2979
2980     require SQL::Translator::Diff;
2981
2982     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2983     if(!-e $prefilename) {
2984       carp("No previous schema file found ($prefilename)");
2985       next;
2986     }
2987
2988     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2989     if(-e $difffile) {
2990       carp("Overwriting existing diff file - $difffile");
2991       unlink($difffile);
2992     }
2993
2994     my $source_schema;
2995     {
2996       my $t = SQL::Translator->new($sqltargs);
2997       $t->debug( 0 );
2998       $t->trace( 0 );
2999
3000       $t->parser( $db )
3001         or $self->throw_exception ($t->error);
3002
3003       my $out = $t->translate( $prefilename )
3004         or $self->throw_exception ($t->error);
3005
3006       $source_schema = $t->schema;
3007
3008       $source_schema->name( $prefilename )
3009         unless ( $source_schema->name );
3010     }
3011
3012     # The "new" style of producers have sane normalization and can support
3013     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
3014     # And we have to diff parsed SQL against parsed SQL.
3015     my $dest_schema = $sqlt_schema;
3016
3017     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
3018       my $t = SQL::Translator->new($sqltargs);
3019       $t->debug( 0 );
3020       $t->trace( 0 );
3021
3022       $t->parser( $db )
3023         or $self->throw_exception ($t->error);
3024
3025       my $out = $t->translate( $filename )
3026         or $self->throw_exception ($t->error);
3027
3028       $dest_schema = $t->schema;
3029
3030       $dest_schema->name( $filename )
3031         unless $dest_schema->name;
3032     }
3033
3034     my $diff = do {
3035       # FIXME - this is a terrible workaround for
3036       # https://github.com/dbsrgits/sql-translator/commit/2d23c1e
3037       # Fixing it in this sloppy manner so that we don't hve to
3038       # lockstep an SQLT release as well. Needs to be removed at
3039       # some point, and SQLT dep bumped
3040       local $SQL::Translator::Producer::SQLite::NO_QUOTES
3041         if $SQL::Translator::Producer::SQLite::NO_QUOTES;
3042
3043       SQL::Translator::Diff::schema_diff($source_schema, $db,
3044                                          $dest_schema,   $db,
3045                                          $sqltargs
3046                                        );
3047     };
3048
3049     if(!open $file, ">$difffile") {
3050       $self->throw_exception("Can't write to $difffile ($!)");
3051       next;
3052     }
3053     print $file $diff;
3054     close($file);
3055   }
3056 }
3057
3058 =head2 deployment_statements
3059
3060 =over 4
3061
3062 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3063
3064 =back
3065
3066 Returns the statements used by L<DBIx::Class::Storage/deploy>
3067 and L<DBIx::Class::Schema/deploy>.
3068
3069 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3070 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3071
3072 C<$directory> is used to return statements from files in a previously created
3073 L</create_ddl_dir> directory and is optional. The filenames are constructed
3074 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3075
3076 If no C<$directory> is specified then the statements are constructed on the
3077 fly using L<SQL::Translator> and C<$version> is ignored.
3078
3079 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3080
3081 =cut
3082
3083 sub deployment_statements {
3084   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3085   $type ||= $self->sqlt_type;
3086   $version ||= $schema->schema_version || '1.x';
3087   $dir ||= './';
3088   my $filename = $schema->ddl_filename($type, $version, $dir);
3089   if(-f $filename)
3090   {
3091       # FIXME replace this block when a proper sane sql parser is available
3092       my $file;
3093       open($file, "<$filename")
3094         or $self->throw_exception("Can't open $filename ($!)");
3095       my @rows = <$file>;
3096       close($file);
3097       return join('', @rows);
3098   }
3099
3100   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') ) {
3101     $self->throw_exception("Can't deploy without a pregenerated 'ddl_dir' directory or $missing");
3102   }
3103
3104   # sources needs to be a parser arg, but for simplicity allow at top level
3105   # coming in
3106   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3107       if exists $sqltargs->{sources};
3108
3109   $sqltargs->{quote_identifiers} = $self->sql_maker->_quoting_enabled
3110     unless exists $sqltargs->{quote_identifiers};
3111
3112   my $tr = SQL::Translator->new(
3113     producer => "SQL::Translator::Producer::${type}",
3114     %$sqltargs,
3115     parser => 'SQL::Translator::Parser::DBIx::Class',
3116     data => $schema,
3117   );
3118
3119   return preserve_context {
3120     $tr->translate
3121   } after => sub {
3122     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3123       unless defined $_[0];
3124   };
3125 }
3126
3127 # FIXME deploy() currently does not accurately report sql errors
3128 # Will always return true while errors are warned
3129 sub deploy {
3130   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3131   my $deploy = sub {
3132     my $line = shift;
3133     return if(!$line);
3134     return if($line =~ /^--/);
3135     # next if($line =~ /^DROP/m);
3136     return if($line =~ /^BEGIN TRANSACTION/m);
3137     return if($line =~ /^COMMIT/m);
3138     return if $line =~ /^\s+$/; # skip whitespace only
3139     $self->_query_start($line);
3140     dbic_internal_try {
3141       # do a dbh_do cycle here, as we need some error checking in
3142       # place (even though we will ignore errors)
3143       $self->dbh_do (sub { $_[1]->do($line) });
3144     } catch {
3145       carp qq{$_ (running "${line}")};
3146     };
3147     $self->_query_end($line);
3148   };
3149   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3150   if (@statements > 1) {
3151     foreach my $statement (@statements) {
3152       $deploy->( $statement );
3153     }
3154   }
3155   elsif (@statements == 1) {
3156     # split on single line comments and end of statements
3157     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3158       $deploy->( $line );
3159     }
3160   }
3161 }
3162
3163 =head2 datetime_parser
3164
3165 Returns the datetime parser class
3166
3167 =cut
3168
3169 sub datetime_parser {
3170   my $self = shift;
3171   return $self->{datetime_parser} ||= do {
3172     $self->build_datetime_parser(@_);
3173   };
3174 }
3175
3176 =head2 datetime_parser_type
3177
3178 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3179
3180 =head2 build_datetime_parser
3181
3182 See L</datetime_parser>
3183
3184 =cut
3185
3186 sub build_datetime_parser {
3187   my $self = shift;
3188   my $type = $self->datetime_parser_type(@_);
3189   return $type;
3190 }
3191
3192
3193 =head2 is_replicating
3194
3195 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3196 replicate from a master database.  Default is undef, which is the result
3197 returned by databases that don't support replication.
3198
3199 =cut
3200
3201 sub is_replicating {
3202     return;
3203
3204 }
3205
3206 =head2 lag_behind_master
3207
3208 Returns a number that represents a certain amount of lag behind a master db
3209 when a given storage is replicating.  The number is database dependent, but
3210 starts at zero and increases with the amount of lag. Default in undef
3211
3212 =cut
3213
3214 sub lag_behind_master {
3215     return;
3216 }
3217
3218 =head2 relname_to_table_alias
3219
3220 =over 4
3221
3222 =item Arguments: $relname, $join_count
3223
3224 =item Return Value: $alias
3225
3226 =back
3227
3228 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3229 queries.
3230
3231 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3232 way these aliases are named.
3233
3234 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3235 otherwise C<"$relname">.
3236
3237 =cut
3238
3239 sub relname_to_table_alias {
3240   my ($self, $relname, $join_count) = @_;
3241
3242   my $alias = ($join_count && $join_count > 1 ?
3243     join('_', $relname, $join_count) : $relname);
3244
3245   return $alias;
3246 }
3247
3248 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3249 # version and it may be necessary to amend or override it for a specific storage
3250 # if such binds are necessary.
3251 sub _max_column_bytesize {
3252   my ($self, $attr) = @_;
3253
3254   my $max_size;
3255
3256   if ($attr->{sqlt_datatype}) {
3257     my $data_type = lc($attr->{sqlt_datatype});
3258
3259     if ($attr->{sqlt_size}) {
3260
3261       # String/sized-binary types
3262       if ($data_type =~ /^(?:
3263           l? (?:var)? char(?:acter)? (?:\s*varying)?
3264             |
3265           (?:var)? binary (?:\s*varying)?
3266             |
3267           raw
3268         )\b/x
3269       ) {
3270         $max_size = $attr->{sqlt_size};
3271       }
3272       # Other charset/unicode types, assume scale of 4
3273       elsif ($data_type =~ /^(?:
3274           national \s* character (?:\s*varying)?
3275             |
3276           nchar
3277             |
3278           univarchar
3279             |
3280           nvarchar
3281         )\b/x
3282       ) {
3283         $max_size = $attr->{sqlt_size} * 4;
3284       }
3285     }
3286
3287     if (!$max_size and !$self->_is_lob_type($data_type)) {
3288       $max_size = 100 # for all other (numeric?) datatypes
3289     }
3290   }
3291
3292   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3293 }
3294
3295 # Determine if a data_type is some type of BLOB
3296 sub _is_lob_type {
3297   my ($self, $data_type) = @_;
3298   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3299     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3300                                   |varchar|character\s*varying|nvarchar
3301                                   |national\s*character\s*varying))?\z/xi);
3302 }
3303
3304 sub _is_binary_lob_type {
3305   my ($self, $data_type) = @_;
3306   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3307     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3308 }
3309
3310 sub _is_text_lob_type {
3311   my ($self, $data_type) = @_;
3312   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3313     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3314                         |national\s*character\s*varying))\z/xi);
3315 }
3316
3317 # Determine if a data_type is some type of a binary type
3318 sub _is_binary_type {
3319   my ($self, $data_type) = @_;
3320   $data_type && ($self->_is_binary_lob_type($data_type)
3321     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3322 }
3323
3324 1;
3325
3326 =head1 USAGE NOTES
3327
3328 =head2 DBIx::Class and AutoCommit
3329
3330 DBIx::Class can do some wonderful magic with handling exceptions,
3331 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3332 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3333 transaction support.
3334
3335 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3336 in an assumed transaction between commits, and you're telling us you'd
3337 like to manage that manually.  A lot of the magic protections offered by
3338 this module will go away.  We can't protect you from exceptions due to database
3339 disconnects because we don't know anything about how to restart your
3340 transactions.  You're on your own for handling all sorts of exceptional
3341 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3342 be with raw DBI.
3343
3344 =head1 FURTHER QUESTIONS?
3345
3346 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
3347
3348 =head1 COPYRIGHT AND LICENSE
3349
3350 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
3351 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
3352 redistribute it and/or modify it under the same terms as the
3353 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.