lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Context::Preserve 'preserve_context';
  16 use Try::Tiny;
  17 use overload ();
  18 use Data::Compare (); # no imports!!! guard against insane architecture
  19 use DBI::Const::GetInfoType (); # no import of retarded global hash
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. This is a purely DRY optimization
  85 #
  86 # get_(use)_dbms_capability need to be called on the correct Storage
  87 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  88 # _determine_supports_X which obv. needs a correct driver as well
  89 my @rdbms_specific_methods = qw/
  90   sqlt_type
  91   sql_maker
  92   build_datetime_parser
  93   datetime_parser_type
  94
  95   txn_begin
  96   insert
  97   insert_bulk
  98   update
  99   delete
 100   select
 101   select_single
 102   with_deferred_fk_checks
 103
 104   get_use_dbms_capability
 105   get_dbms_capability
 106
 107   _server_info
 108   _get_server_version
 109 /;
 110
 111 for my $meth (@rdbms_specific_methods) {
 112
 113   my $orig = __PACKAGE__->can ($meth)
 114     or die "$meth is not a ::Storage::DBI method!";
 115
 116   no strict qw/refs/;
 117   no warnings qw/redefine/;
 118   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 119     if (
 120       # only fire when invoked on an instance, a valid class-based invocation
 121       # would e.g. be setting a default for an inherited accessor
 122       ref $_[0]
 123         and
 124       ! $_[0]->_driver_determined
 125         and
 126       ! $_[0]->{_in_determine_driver}
 127     ) {
 128       $_[0]->_determine_driver;
 129
 130       # This for some reason crashes and burns on perl 5.8.1
 131       # IFF the method ends up throwing an exception
 132       #goto $_[0]->can ($meth);
 133
 134       my $cref = $_[0]->can ($meth);
 135       goto $cref;
 136     }
 137
 138     goto $orig;
 139   };
 140 }
 141
 142 =head1 NAME
 143
 144 DBIx::Class::Storage::DBI - DBI storage handler
 145
 146 =head1 SYNOPSIS
 147
 148   my $schema = MySchema->connect('dbi:SQLite:my.db');
 149
 150   $schema->storage->debug(1);
 151
 152   my @stuff = $schema->storage->dbh_do(
 153     sub {
 154       my ($storage, $dbh, @args) = @_;
 155       $dbh->do("DROP TABLE authors");
 156     },
 157     @column_list
 158   );
 159
 160   $schema->resultset('Book')->search({
 161      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 162   });
 163
 164 =head1 DESCRIPTION
 165
 166 This class represents the connection to an RDBMS via L<DBI>.  See
 167 L<DBIx::Class::Storage> for general information.  This pod only
 168 documents DBI-specific methods and behaviors.
 169
 170 =head1 METHODS
 171
 172 =cut
 173
 174 sub new {
 175   my $new = shift->next::method(@_);
 176
 177   $new->_sql_maker_opts({});
 178   $new->_dbh_details({});
 179   $new->{_in_do_block} = 0;
 180   $new->{_dbh_gen} = 0;
 181
 182   # read below to see what this does
 183   $new->_arm_global_destructor;
 184
 185   $new;
 186 }
 187
 188 # This is hack to work around perl shooting stuff in random
 189 # order on exit(). If we do not walk the remaining storage
 190 # objects in an END block, there is a *small but real* chance
 191 # of a fork()ed child to kill the parent's shared DBI handle,
 192 # *before perl reaches the DESTROY in this package*
 193 # Yes, it is ugly and effective.
 194 # Additionally this registry is used by the CLONE method to
 195 # make sure no handles are shared between threads
 196 {
 197   my %seek_and_destroy;
 198
 199   sub _arm_global_destructor {
 200     weaken (
 201       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 202     );
 203   }
 204
 205   END {
 206     local $?; # just in case the DBI destructor changes it somehow
 207
 208     # destroy just the object if not native to this process
 209     $_->_verify_pid for (grep
 210       { defined $_ }
 211       values %seek_and_destroy
 212     );
 213   }
 214
 215   sub CLONE {
 216     # As per DBI's recommendation, DBIC disconnects all handles as
 217     # soon as possible (DBIC will reconnect only on demand from within
 218     # the thread)
 219     my @instances = grep { defined $_ } values %seek_and_destroy;
 220     for (@instances) {
 221       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 222       $_->_dbh(undef);
 223
 224       $_->transaction_depth(0);
 225       $_->savepoints([]);
 226     }
 227
 228     # properly renumber all existing refs
 229     %seek_and_destroy = ();
 230     $_->_arm_global_destructor for @instances;
 231   }
 232 }
 233
 234 sub DESTROY {
 235   my $self = shift;
 236
 237   # some databases spew warnings on implicit disconnect
 238   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 239   local $SIG{__WARN__} = sub {};
 240   $self->_dbh(undef);
 241
 242   # this op is necessary, since the very last perl runtime statement
 243   # triggers a global destruction shootout, and the $SIG localization
 244   # may very well be destroyed before perl actually gets to do the
 245   # $dbh undef
 246   1;
 247 }
 248
 249 # handle pid changes correctly - do not destroy parent's connection
 250 sub _verify_pid {
 251   my $self = shift;
 252
 253   my $pid = $self->_conn_pid;
 254   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 255     $dbh->{InactiveDestroy} = 1;
 256     $self->{_dbh_gen}++;
 257     $self->_dbh(undef);
 258     $self->transaction_depth(0);
 259     $self->savepoints([]);
 260   }
 261
 262   return;
 263 }
 264
 265 =head2 connect_info
 266
 267 This method is normally called by L<DBIx::Class::Schema/connection>, which
 268 encapsulates its argument list in an arrayref before passing them here.
 269
 270 The argument list may contain:
 271
 272 =over
 273
 274 =item *
 275
 276 The same 4-element argument set one would normally pass to
 277 L<DBI/connect>, optionally followed by
 278 L<extra attributes|/DBIx::Class specific connection attributes>
 279 recognized by DBIx::Class:
 280
 281   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 282
 283 =item *
 284
 285 A single code reference which returns a connected
 286 L<DBI database handle|DBI/connect> optionally followed by
 287 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 288 by DBIx::Class:
 289
 290   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 291
 292 =item *
 293
 294 A single hashref with all the attributes and the dsn/user/password
 295 mixed together:
 296
 297   $connect_info_args = [{
 298     dsn => $dsn,
 299     user => $user,
 300     password => $pass,
 301     %dbi_attributes,
 302     %extra_attributes,
 303   }];
 304
 305   $connect_info_args = [{
 306     dbh_maker => sub { DBI->connect (...) },
 307     %dbi_attributes,
 308     %extra_attributes,
 309   }];
 310
 311 This is particularly useful for L<Catalyst> based applications, allowing the
 312 following config (L<Config::General> style):
 313
 314   <Model::DB>
 315     schema_class   App::DB
 316     <connect_info>
 317       dsn          dbi:mysql:database=test
 318       user         testuser
 319       password     TestPass
 320       AutoCommit   1
 321     </connect_info>
 322   </Model::DB>
 323
 324 The C<dsn>/C<user>/C<password> combination can be substituted by the
 325 C<dbh_maker> key whose value is a coderef that returns a connected
 326 L<DBI database handle|DBI/connect>
 327
 328 =back
 329
 330 Please note that the L<DBI> docs recommend that you always explicitly
 331 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 332 recommends that it be set to I<1>, and that you perform transactions
 333 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 334 to I<1> if you do not do explicitly set it to zero.  This is the default
 335 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 336
 337 =head3 DBIx::Class specific connection attributes
 338
 339 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 340 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 341 the following connection options. These options can be mixed in with your other
 342 L<DBI> connection attributes, or placed in a separate hashref
 343 (C<\%extra_attributes>) as shown above.
 344
 345 Every time C<connect_info> is invoked, any previous settings for
 346 these options will be cleared before setting the new ones, regardless of
 347 whether any options are specified in the new C<connect_info>.
 348
 349
 350 =over
 351
 352 =item on_connect_do
 353
 354 Specifies things to do immediately after connecting or re-connecting to
 355 the database.  Its value may contain:
 356
 357 =over
 358
 359 =item a scalar
 360
 361 This contains one SQL statement to execute.
 362
 363 =item an array reference
 364
 365 This contains SQL statements to execute in order.  Each element contains
 366 a string or a code reference that returns a string.
 367
 368 =item a code reference
 369
 370 This contains some code to execute.  Unlike code references within an
 371 array reference, its return value is ignored.
 372
 373 =back
 374
 375 =item on_disconnect_do
 376
 377 Takes arguments in the same form as L</on_connect_do> and executes them
 378 immediately before disconnecting from the database.
 379
 380 Note, this only runs if you explicitly call L</disconnect> on the
 381 storage object.
 382
 383 =item on_connect_call
 384
 385 A more generalized form of L</on_connect_do> that calls the specified
 386 C<connect_call_METHOD> methods in your storage driver.
 387
 388   on_connect_do => 'select 1'
 389
 390 is equivalent to:
 391
 392   on_connect_call => [ [ do_sql => 'select 1' ] ]
 393
 394 Its values may contain:
 395
 396 =over
 397
 398 =item a scalar
 399
 400 Will call the C<connect_call_METHOD> method.
 401
 402 =item a code reference
 403
 404 Will execute C<< $code->($storage) >>
 405
 406 =item an array reference
 407
 408 Each value can be a method name or code reference.
 409
 410 =item an array of arrays
 411
 412 For each array, the first item is taken to be the C<connect_call_> method name
 413 or code reference, and the rest are parameters to it.
 414
 415 =back
 416
 417 Some predefined storage methods you may use:
 418
 419 =over
 420
 421 =item do_sql
 422
 423 Executes a SQL string or a code reference that returns a SQL string. This is
 424 what L</on_connect_do> and L</on_disconnect_do> use.
 425
 426 It can take:
 427
 428 =over
 429
 430 =item a scalar
 431
 432 Will execute the scalar as SQL.
 433
 434 =item an arrayref
 435
 436 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 437 attributes hashref and bind values.
 438
 439 =item a code reference
 440
 441 Will execute C<< $code->($storage) >> and execute the return array refs as
 442 above.
 443
 444 =back
 445
 446 =item datetime_setup
 447
 448 Execute any statements necessary to initialize the database session to return
 449 and accept datetime/timestamp values used with
 450 L<DBIx::Class::InflateColumn::DateTime>.
 451
 452 Only necessary for some databases, see your specific storage driver for
 453 implementation details.
 454
 455 =back
 456
 457 =item on_disconnect_call
 458
 459 Takes arguments in the same form as L</on_connect_call> and executes them
 460 immediately before disconnecting from the database.
 461
 462 Calls the C<disconnect_call_METHOD> methods as opposed to the
 463 C<connect_call_METHOD> methods called by L</on_connect_call>.
 464
 465 Note, this only runs if you explicitly call L</disconnect> on the
 466 storage object.
 467
 468 =item disable_sth_caching
 469
 470 If set to a true value, this option will disable the caching of
 471 statement handles via L<DBI/prepare_cached>.
 472
 473 =item limit_dialect
 474
 475 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 476 default L</sql_limit_dialect> setting of the storage (if any). For a list
 477 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 478
 479 =item quote_names
 480
 481 When true automatically sets L</quote_char> and L</name_sep> to the characters
 482 appropriate for your particular RDBMS. This option is preferred over specifying
 483 L</quote_char> directly.
 484
 485 =item quote_char
 486
 487 Specifies what characters to use to quote table and column names.
 488
 489 C<quote_char> expects either a single character, in which case is it
 490 is placed on either side of the table/column name, or an arrayref of length
 491 2 in which case the table/column name is placed between the elements.
 492
 493 For example under MySQL you should use C<< quote_char => '`' >>, and for
 494 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 495
 496 =item name_sep
 497
 498 This parameter is only useful in conjunction with C<quote_char>, and is used to
 499 specify the character that separates elements (schemas, tables, columns) from
 500 each other. If unspecified it defaults to the most commonly used C<.>.
 501
 502 =item unsafe
 503
 504 This Storage driver normally installs its own C<HandleError>, sets
 505 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 506 all database handles, including those supplied by a coderef.  It does this
 507 so that it can have consistent and useful error behavior.
 508
 509 If you set this option to a true value, Storage will not do its usual
 510 modifications to the database handle's attributes, and instead relies on
 511 the settings in your connect_info DBI options (or the values you set in
 512 your connection coderef, in the case that you are connecting via coderef).
 513
 514 Note that your custom settings can cause Storage to malfunction,
 515 especially if you set a C<HandleError> handler that suppresses exceptions
 516 and/or disable C<RaiseError>.
 517
 518 =item auto_savepoint
 519
 520 If this option is true, L<DBIx::Class> will use savepoints when nesting
 521 transactions, making it possible to recover from failure in the inner
 522 transaction without having to abort all outer transactions.
 523
 524 =item cursor_class
 525
 526 Use this argument to supply a cursor class other than the default
 527 L<DBIx::Class::Storage::DBI::Cursor>.
 528
 529 =back
 530
 531 Some real-life examples of arguments to L</connect_info> and
 532 L<DBIx::Class::Schema/connect>
 533
 534   # Simple SQLite connection
 535   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 536
 537   # Connect via subref
 538   ->connect_info([ sub { DBI->connect(...) } ]);
 539
 540   # Connect via subref in hashref
 541   ->connect_info([{
 542     dbh_maker => sub { DBI->connect(...) },
 543     on_connect_do => 'alter session ...',
 544   }]);
 545
 546   # A bit more complicated
 547   ->connect_info(
 548     [
 549       'dbi:Pg:dbname=foo',
 550       'postgres',
 551       'my_pg_password',
 552       { AutoCommit => 1 },
 553       { quote_char => q{"} },
 554     ]
 555   );
 556
 557   # Equivalent to the previous example
 558   ->connect_info(
 559     [
 560       'dbi:Pg:dbname=foo',
 561       'postgres',
 562       'my_pg_password',
 563       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 564     ]
 565   );
 566
 567   # Same, but with hashref as argument
 568   # See parse_connect_info for explanation
 569   ->connect_info(
 570     [{
 571       dsn         => 'dbi:Pg:dbname=foo',
 572       user        => 'postgres',
 573       password    => 'my_pg_password',
 574       AutoCommit  => 1,
 575       quote_char  => q{"},
 576       name_sep    => q{.},
 577     }]
 578   );
 579
 580   # Subref + DBIx::Class-specific connection options
 581   ->connect_info(
 582     [
 583       sub { DBI->connect(...) },
 584       {
 585           quote_char => q{`},
 586           name_sep => q{@},
 587           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 588           disable_sth_caching => 1,
 589       },
 590     ]
 591   );
 592
 593
 594
 595 =cut
 596
 597 sub connect_info {
 598   my ($self, $info) = @_;
 599
 600   return $self->_connect_info if !$info;
 601
 602   $self->_connect_info($info); # copy for _connect_info
 603
 604   $info = $self->_normalize_connect_info($info)
 605     if ref $info eq 'ARRAY';
 606
 607   for my $storage_opt (keys %{ $info->{storage_options} }) {
 608     my $value = $info->{storage_options}{$storage_opt};
 609
 610     $self->$storage_opt($value);
 611   }
 612
 613   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 614   #  the new set of options
 615   $self->_sql_maker(undef);
 616   $self->_sql_maker_opts({});
 617
 618   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 619     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 620
 621     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 622   }
 623
 624   my %attrs = (
 625     %{ $self->_default_dbi_connect_attributes || {} },
 626     %{ $info->{attributes} || {} },
 627   );
 628
 629   my @args = @{ $info->{arguments} };
 630
 631   if (keys %attrs and ref $args[0] ne 'CODE') {
 632     carp
 633         'You provided explicit AutoCommit => 0 in your connection_info. '
 634       . 'This is almost universally a bad idea (see the footnotes of '
 635       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 636       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 637       . 'this warning.'
 638       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 639
 640     push @args, \%attrs if keys %attrs;
 641   }
 642   $self->_dbi_connect_info(\@args);
 643
 644   # FIXME - dirty:
 645   # save attributes them in a separate accessor so they are always
 646   # introspectable, even in case of a CODE $dbhmaker
 647   $self->_dbic_connect_attributes (\%attrs);
 648
 649   return $self->_connect_info;
 650 }
 651
 652 sub _normalize_connect_info {
 653   my ($self, $info_arg) = @_;
 654   my %info;
 655
 656   my @args = @$info_arg;  # take a shallow copy for further mutilation
 657
 658   # combine/pre-parse arguments depending on invocation style
 659
 660   my %attrs;
 661   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 662     %attrs = %{ $args[1] || {} };
 663     @args = $args[0];
 664   }
 665   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 666     %attrs = %{$args[0]};
 667     @args = ();
 668     if (my $code = delete $attrs{dbh_maker}) {
 669       @args = $code;
 670
 671       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 672       if (@ignored) {
 673         carp sprintf (
 674             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 675           . "to the result of 'dbh_maker'",
 676
 677           join (', ', map { "'$_'" } (@ignored) ),
 678         );
 679       }
 680     }
 681     else {
 682       @args = delete @attrs{qw/dsn user password/};
 683     }
 684   }
 685   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 686     %attrs = (
 687       % { $args[3] || {} },
 688       % { $args[4] || {} },
 689     );
 690     @args = @args[0,1,2];
 691   }
 692
 693   $info{arguments} = \@args;
 694
 695   my @storage_opts = grep exists $attrs{$_},
 696     @storage_options, 'cursor_class';
 697
 698   @{ $info{storage_options} }{@storage_opts} =
 699     delete @attrs{@storage_opts} if @storage_opts;
 700
 701   my @sql_maker_opts = grep exists $attrs{$_},
 702     qw/limit_dialect quote_char name_sep quote_names/;
 703
 704   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 705     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 706
 707   $info{attributes} = \%attrs if %attrs;
 708
 709   return \%info;
 710 }
 711
 712 sub _default_dbi_connect_attributes () {
 713   +{
 714     AutoCommit => 1,
 715     PrintError => 0,
 716     RaiseError => 1,
 717     ShowErrorStatement => 1,
 718   };
 719 }
 720
 721 =head2 on_connect_do
 722
 723 This method is deprecated in favour of setting via L</connect_info>.
 724
 725 =cut
 726
 727 =head2 on_disconnect_do
 728
 729 This method is deprecated in favour of setting via L</connect_info>.
 730
 731 =cut
 732
 733 sub _parse_connect_do {
 734   my ($self, $type) = @_;
 735
 736   my $val = $self->$type;
 737   return () if not defined $val;
 738
 739   my @res;
 740
 741   if (not ref($val)) {
 742     push @res, [ 'do_sql', $val ];
 743   } elsif (ref($val) eq 'CODE') {
 744     push @res, $val;
 745   } elsif (ref($val) eq 'ARRAY') {
 746     push @res, map { [ 'do_sql', $_ ] } @$val;
 747   } else {
 748     $self->throw_exception("Invalid type for $type: ".ref($val));
 749   }
 750
 751   return \@res;
 752 }
 753
 754 =head2 dbh_do
 755
 756 Arguments: ($subref | $method_name), @extra_coderef_args?
 757
 758 Execute the given $subref or $method_name using the new exception-based
 759 connection management.
 760
 761 The first two arguments will be the storage object that C<dbh_do> was called
 762 on and a database handle to use.  Any additional arguments will be passed
 763 verbatim to the called subref as arguments 2 and onwards.
 764
 765 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 766 exception handling and reconnection (or failover in future subclasses).
 767
 768 Your subref should have no side-effects outside of the database, as
 769 there is the potential for your subref to be partially double-executed
 770 if the database connection was stale/dysfunctional.
 771
 772 Example:
 773
 774   my @stuff = $schema->storage->dbh_do(
 775     sub {
 776       my ($storage, $dbh, @cols) = @_;
 777       my $cols = join(q{, }, @cols);
 778       $dbh->selectrow_array("SELECT $cols FROM foo");
 779     },
 780     @column_list
 781   );
 782
 783 =cut
 784
 785 sub dbh_do {
 786   my $self = shift;
 787   my $run_target = shift;
 788
 789   # short circuit when we know there is no need for a runner
 790   #
 791   # FIXME - asumption may be wrong
 792   # the rationale for the txn_depth check is that if this block is a part
 793   # of a larger transaction, everything up to that point is screwed anyway
 794   return $self->$run_target($self->_get_dbh, @_)
 795     if $self->{_in_do_block} or $self->transaction_depth;
 796
 797   my $cref = (ref $run_target eq 'CODE')
 798     ? $run_target
 799     : $self->can($run_target) || $self->throw_exception(sprintf (
 800       'Can\'t locate object method "%s" via package "%s"',
 801       $run_target,
 802       (ref $self || $self),
 803     ))
 804   ;
 805
 806   # take a ref instead of a copy, to preserve @_ aliasing
 807   # semantics within the coderef, but only if needed
 808   # (pseudoforking doesn't like this trick much)
 809   my $args = @_ ? \@_ : [];
 810   unshift @$args, $self, $self->_get_dbh;
 811
 812   DBIx::Class::Storage::BlockRunner->new(
 813     storage => $self,
 814     run_code => $cref,
 815     run_args => $args,
 816     wrap_txn => 0,
 817     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 818   )->run;
 819 }
 820
 821 sub txn_do {
 822   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 823   shift->next::method(@_);
 824 }
 825
 826 =head2 disconnect
 827
 828 Our C<disconnect> method also performs a rollback first if the
 829 database is not in C<AutoCommit> mode.
 830
 831 =cut
 832
 833 sub disconnect {
 834   my ($self) = @_;
 835
 836   if( $self->_dbh ) {
 837     my @actions;
 838
 839     push @actions, ( $self->on_disconnect_call || () );
 840     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 841
 842     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 843
 844     # stops the "implicit rollback on disconnect" warning
 845     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 846
 847     %{ $self->_dbh->{CachedKids} } = ();
 848     $self->_dbh->disconnect;
 849     $self->_dbh(undef);
 850     $self->{_dbh_gen}++;
 851   }
 852 }
 853
 854 =head2 with_deferred_fk_checks
 855
 856 =over 4
 857
 858 =item Arguments: C<$coderef>
 859
 860 =item Return Value: The return value of $coderef
 861
 862 =back
 863
 864 Storage specific method to run the code ref with FK checks deferred or
 865 in MySQL's case disabled entirely.
 866
 867 =cut
 868
 869 # Storage subclasses should override this
 870 sub with_deferred_fk_checks {
 871   my ($self, $sub) = @_;
 872   $sub->();
 873 }
 874
 875 =head2 connected
 876
 877 =over
 878
 879 =item Arguments: none
 880
 881 =item Return Value: 1|0
 882
 883 =back
 884
 885 Verifies that the current database handle is active and ready to execute
 886 an SQL statement (e.g. the connection did not get stale, server is still
 887 answering, etc.) This method is used internally by L</dbh>.
 888
 889 =cut
 890
 891 sub connected {
 892   my $self = shift;
 893   return 0 unless $self->_seems_connected;
 894
 895   #be on the safe side
 896   local $self->_dbh->{RaiseError} = 1;
 897
 898   return $self->_ping;
 899 }
 900
 901 sub _seems_connected {
 902   my $self = shift;
 903
 904   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 905
 906   my $dbh = $self->_dbh
 907     or return 0;
 908
 909   return $dbh->FETCH('Active');
 910 }
 911
 912 sub _ping {
 913   my $self = shift;
 914
 915   my $dbh = $self->_dbh or return 0;
 916
 917   return $dbh->ping;
 918 }
 919
 920 sub ensure_connected {
 921   my ($self) = @_;
 922
 923   unless ($self->connected) {
 924     $self->_populate_dbh;
 925   }
 926 }
 927
 928 =head2 dbh
 929
 930 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 931 is guaranteed to be healthy by implicitly calling L</connected>, and if
 932 necessary performing a reconnection before returning. Keep in mind that this
 933 is very B<expensive> on some database engines. Consider using L</dbh_do>
 934 instead.
 935
 936 =cut
 937
 938 sub dbh {
 939   my ($self) = @_;
 940
 941   if (not $self->_dbh) {
 942     $self->_populate_dbh;
 943   } else {
 944     $self->ensure_connected;
 945   }
 946   return $self->_dbh;
 947 }
 948
 949 # this is the internal "get dbh or connect (don't check)" method
 950 sub _get_dbh {
 951   my $self = shift;
 952   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 953   $self->_populate_dbh unless $self->_dbh;
 954   return $self->_dbh;
 955 }
 956
 957 sub sql_maker {
 958   my ($self) = @_;
 959   unless ($self->_sql_maker) {
 960     my $sql_maker_class = $self->sql_maker_class;
 961
 962     my %opts = %{$self->_sql_maker_opts||{}};
 963     my $dialect =
 964       $opts{limit_dialect}
 965         ||
 966       $self->sql_limit_dialect
 967         ||
 968       do {
 969         my $s_class = (ref $self) || $self;
 970         carp (
 971           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 972         . 'have not supplied an explicit limit_dialect in your connection_info. '
 973         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 974         . 'databases but can be (and often is) painfully slow. '
 975         . "Please file an RT ticket against '$s_class' ."
 976         );
 977
 978         'GenericSubQ';
 979       }
 980     ;
 981
 982     my ($quote_char, $name_sep);
 983
 984     if ($opts{quote_names}) {
 985       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 986         my $s_class = (ref $self) || $self;
 987         carp (
 988           "You requested 'quote_names' but your storage class ($s_class) does "
 989         . 'not explicitly define a default sql_quote_char and you have not '
 990         . 'supplied a quote_char as part of your connection_info. DBIC will '
 991         .q{default to the ANSI SQL standard quote '"', which works most of }
 992         . "the time. Please file an RT ticket against '$s_class'."
 993         );
 994
 995         '"'; # RV
 996       };
 997
 998       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 999     }
1000
1001     $self->_sql_maker($sql_maker_class->new(
1002       bindtype=>'columns',
1003       array_datatypes => 1,
1004       limit_dialect => $dialect,
1005       ($quote_char ? (quote_char => $quote_char) : ()),
1006       name_sep => ($name_sep || '.'),
1007       %opts,
1008     ));
1009   }
1010   return $self->_sql_maker;
1011 }
1012
1013 # nothing to do by default
1014 sub _rebless {}
1015 sub _init {}
1016
1017 sub _populate_dbh {
1018   my ($self) = @_;
1019
1020   my @info = @{$self->_dbi_connect_info || []};
1021   $self->_dbh(undef); # in case ->connected failed we might get sent here
1022   $self->_dbh_details({}); # reset everything we know
1023
1024   $self->_dbh($self->_connect(@info));
1025
1026   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1027
1028   $self->_determine_driver;
1029
1030   # Always set the transaction depth on connect, since
1031   #  there is no transaction in progress by definition
1032   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1033
1034   $self->_run_connection_actions unless $self->{_in_determine_driver};
1035 }
1036
1037 sub _run_connection_actions {
1038   my $self = shift;
1039   my @actions;
1040
1041   push @actions, ( $self->on_connect_call || () );
1042   push @actions, $self->_parse_connect_do ('on_connect_do');
1043
1044   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1045 }
1046
1047
1048
1049 sub set_use_dbms_capability {
1050   $_[0]->set_inherited ($_[1], $_[2]);
1051 }
1052
1053 sub get_use_dbms_capability {
1054   my ($self, $capname) = @_;
1055
1056   my $use = $self->get_inherited ($capname);
1057   return defined $use
1058     ? $use
1059     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1060   ;
1061 }
1062
1063 sub set_dbms_capability {
1064   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1065 }
1066
1067 sub get_dbms_capability {
1068   my ($self, $capname) = @_;
1069
1070   my $cap = $self->_dbh_details->{capability}{$capname};
1071
1072   unless (defined $cap) {
1073     if (my $meth = $self->can ("_determine$capname")) {
1074       $cap = $self->$meth ? 1 : 0;
1075     }
1076     else {
1077       $cap = 0;
1078     }
1079
1080     $self->set_dbms_capability ($capname, $cap);
1081   }
1082
1083   return $cap;
1084 }
1085
1086 sub _server_info {
1087   my $self = shift;
1088
1089   my $info;
1090   unless ($info = $self->_dbh_details->{info}) {
1091
1092     $info = {};
1093
1094     my $server_version = try {
1095       $self->_get_server_version
1096     } catch {
1097       # driver determination *may* use this codepath
1098       # in which case we must rethrow
1099       $self->throw_exception($_) if $self->{_in_determine_driver};
1100
1101       # $server_version on failure
1102       undef;
1103     };
1104
1105     if (defined $server_version) {
1106       $info->{dbms_version} = $server_version;
1107
1108       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1109       my @verparts = split (/\./, $numeric_version);
1110       if (
1111         @verparts
1112           &&
1113         $verparts[0] <= 999
1114       ) {
1115         # consider only up to 3 version parts, iff not more than 3 digits
1116         my @use_parts;
1117         while (@verparts && @use_parts < 3) {
1118           my $p = shift @verparts;
1119           last if $p > 999;
1120           push @use_parts, $p;
1121         }
1122         push @use_parts, 0 while @use_parts < 3;
1123
1124         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1125       }
1126     }
1127
1128     $self->_dbh_details->{info} = $info;
1129   }
1130
1131   return $info;
1132 }
1133
1134 sub _get_server_version {
1135   shift->_dbh_get_info('SQL_DBMS_VER');
1136 }
1137
1138 sub _dbh_get_info {
1139   my ($self, $info) = @_;
1140
1141   if ($info =~ /[^0-9]/) {
1142     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1143     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1144       unless defined $info;
1145   }
1146
1147   return $self->_get_dbh->get_info($info);
1148 }
1149
1150 sub _describe_connection {
1151   require DBI::Const::GetInfoReturn;
1152
1153   my $self = shift;
1154   $self->ensure_connected;
1155
1156   my $res = {
1157     DBIC_DSN => $self->_dbi_connect_info->[0],
1158     DBI_VER => DBI->VERSION,
1159     DBIC_VER => DBIx::Class->VERSION,
1160     DBIC_DRIVER => ref $self,
1161   };
1162
1163   for my $inf (
1164     #keys %DBI::Const::GetInfoType::GetInfoType,
1165     qw/
1166       SQL_CURSOR_COMMIT_BEHAVIOR
1167       SQL_CURSOR_ROLLBACK_BEHAVIOR
1168       SQL_CURSOR_SENSITIVITY
1169       SQL_DATA_SOURCE_NAME
1170       SQL_DBMS_NAME
1171       SQL_DBMS_VER
1172       SQL_DEFAULT_TXN_ISOLATION
1173       SQL_DM_VER
1174       SQL_DRIVER_NAME
1175       SQL_DRIVER_ODBC_VER
1176       SQL_DRIVER_VER
1177       SQL_EXPRESSIONS_IN_ORDERBY
1178       SQL_GROUP_BY
1179       SQL_IDENTIFIER_CASE
1180       SQL_IDENTIFIER_QUOTE_CHAR
1181       SQL_MAX_CATALOG_NAME_LEN
1182       SQL_MAX_COLUMN_NAME_LEN
1183       SQL_MAX_IDENTIFIER_LEN
1184       SQL_MAX_TABLE_NAME_LEN
1185       SQL_MULTIPLE_ACTIVE_TXN
1186       SQL_MULT_RESULT_SETS
1187       SQL_NEED_LONG_DATA_LEN
1188       SQL_NON_NULLABLE_COLUMNS
1189       SQL_ODBC_VER
1190       SQL_QUALIFIER_NAME_SEPARATOR
1191       SQL_QUOTED_IDENTIFIER_CASE
1192       SQL_TXN_CAPABLE
1193       SQL_TXN_ISOLATION_OPTION
1194     /
1195   ) {
1196     my $v = $self->_dbh_get_info($inf);
1197     next unless defined $v;
1198
1199     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1200     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1201     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1202   }
1203
1204   $res;
1205 }
1206
1207 sub _determine_driver {
1208   my ($self) = @_;
1209
1210   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1211     my $started_connected = 0;
1212     local $self->{_in_determine_driver} = 1;
1213
1214     if (ref($self) eq __PACKAGE__) {
1215       my $driver;
1216       if ($self->_dbh) { # we are connected
1217         $driver = $self->_dbh->{Driver}{Name};
1218         $started_connected = 1;
1219       }
1220       else {
1221         # if connect_info is a CODEREF, we have no choice but to connect
1222         if (ref $self->_dbi_connect_info->[0] &&
1223             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1224           $self->_populate_dbh;
1225           $driver = $self->_dbh->{Driver}{Name};
1226         }
1227         else {
1228           # try to use dsn to not require being connected, the driver may still
1229           # force a connection in _rebless to determine version
1230           # (dsn may not be supplied at all if all we do is make a mock-schema)
1231           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1232           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1233           $driver ||= $ENV{DBI_DRIVER};
1234         }
1235       }
1236
1237       if ($driver) {
1238         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1239         if ($self->load_optional_class($storage_class)) {
1240           mro::set_mro($storage_class, 'c3');
1241           bless $self, $storage_class;
1242           $self->_rebless();
1243         }
1244         else {
1245           $self->_warn_undetermined_driver(
1246             'This version of DBIC does not yet seem to supply a driver for '
1247           . "your particular RDBMS and/or connection method ('$driver')."
1248           );
1249         }
1250       }
1251       else {
1252         $self->_warn_undetermined_driver(
1253           'Unable to extract a driver name from connect info - this '
1254         . 'should not have happened.'
1255         );
1256       }
1257     }
1258
1259     $self->_driver_determined(1);
1260
1261     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1262
1263     if ($self->can('source_bind_attributes')) {
1264       $self->throw_exception(
1265         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1266       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1267       . 'If you are not sure how to proceed please contact the development team via '
1268       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1269       );
1270     }
1271
1272     $self->_init; # run driver-specific initializations
1273
1274     $self->_run_connection_actions
1275         if !$started_connected && defined $self->_dbh;
1276   }
1277 }
1278
1279 sub _determine_connector_driver {
1280   my ($self, $conn) = @_;
1281
1282   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1283
1284   if (not $dbtype) {
1285     $self->_warn_undetermined_driver(
1286       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1287     . "$conn connector - this should not have happened."
1288     );
1289     return;
1290   }
1291
1292   $dbtype =~ s/\W/_/gi;
1293
1294   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1295   return if $self->isa($subclass);
1296
1297   if ($self->load_optional_class($subclass)) {
1298     bless $self, $subclass;
1299     $self->_rebless;
1300   }
1301   else {
1302     $self->_warn_undetermined_driver(
1303       'This version of DBIC does not yet seem to supply a driver for '
1304     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1305     );
1306   }
1307 }
1308
1309 sub _warn_undetermined_driver {
1310   my ($self, $msg) = @_;
1311
1312   require Data::Dumper::Concise;
1313
1314   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1315   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1316   . "does not go away, file a bugreport including the following info:\n"
1317   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1318   );
1319 }
1320
1321 sub _do_connection_actions {
1322   my $self          = shift;
1323   my $method_prefix = shift;
1324   my $call          = shift;
1325
1326   if (not ref($call)) {
1327     my $method = $method_prefix . $call;
1328     $self->$method(@_);
1329   } elsif (ref($call) eq 'CODE') {
1330     $self->$call(@_);
1331   } elsif (ref($call) eq 'ARRAY') {
1332     if (ref($call->[0]) ne 'ARRAY') {
1333       $self->_do_connection_actions($method_prefix, $_) for @$call;
1334     } else {
1335       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1336     }
1337   } else {
1338     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1339   }
1340
1341   return $self;
1342 }
1343
1344 sub connect_call_do_sql {
1345   my $self = shift;
1346   $self->_do_query(@_);
1347 }
1348
1349 sub disconnect_call_do_sql {
1350   my $self = shift;
1351   $self->_do_query(@_);
1352 }
1353
1354 # override in db-specific backend when necessary
1355 sub connect_call_datetime_setup { 1 }
1356
1357 sub _do_query {
1358   my ($self, $action) = @_;
1359
1360   if (ref $action eq 'CODE') {
1361     $action = $action->($self);
1362     $self->_do_query($_) foreach @$action;
1363   }
1364   else {
1365     # Most debuggers expect ($sql, @bind), so we need to exclude
1366     # the attribute hash which is the second argument to $dbh->do
1367     # furthermore the bind values are usually to be presented
1368     # as named arrayref pairs, so wrap those here too
1369     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1370     my $sql = shift @do_args;
1371     my $attrs = shift @do_args;
1372     my @bind = map { [ undef, $_ ] } @do_args;
1373
1374     $self->dbh_do(sub {
1375       $_[0]->_query_start($sql, \@bind);
1376       $_[1]->do($sql, $attrs, @do_args);
1377       $_[0]->_query_end($sql, \@bind);
1378     });
1379   }
1380
1381   return $self;
1382 }
1383
1384 sub _connect {
1385   my ($self, @info) = @_;
1386
1387   $self->throw_exception("You failed to provide any connection info")
1388     if !@info;
1389
1390   my ($old_connect_via, $dbh);
1391
1392   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1393
1394   try {
1395     if(ref $info[0] eq 'CODE') {
1396       $dbh = $info[0]->();
1397     }
1398     else {
1399       require DBI;
1400       $dbh = DBI->connect(@info);
1401     }
1402
1403     if (!$dbh) {
1404       die $DBI::errstr;
1405     }
1406
1407     unless ($self->unsafe) {
1408
1409       $self->throw_exception(
1410         'Refusing clobbering of {HandleError} installed on externally supplied '
1411        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1412       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1413
1414       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1415       # request, or an external handle. Complain and set anyway
1416       unless ($dbh->{RaiseError}) {
1417         carp( ref $info[0] eq 'CODE'
1418
1419           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1420            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1421            .'attribute has been supplied'
1422
1423           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1424            .'unsafe => 1. Toggling RaiseError back to true'
1425         );
1426
1427         $dbh->{RaiseError} = 1;
1428       }
1429
1430       # this odd anonymous coderef dereference is in fact really
1431       # necessary to avoid the unwanted effect described in perl5
1432       # RT#75792
1433       sub {
1434         my $weak_self = $_[0];
1435         weaken $weak_self;
1436
1437         # the coderef is blessed so we can distinguish it from externally
1438         # supplied handles (which must be preserved)
1439         $_[1]->{HandleError} = bless sub {
1440           if ($weak_self) {
1441             $weak_self->throw_exception("DBI Exception: $_[0]");
1442           }
1443           else {
1444             # the handler may be invoked by something totally out of
1445             # the scope of DBIC
1446             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1447           }
1448         }, '__DBIC__DBH__ERROR__HANDLER__';
1449       }->($self, $dbh);
1450     }
1451   }
1452   catch {
1453     $self->throw_exception("DBI Connection failed: $_")
1454   };
1455
1456   $self->_dbh_autocommit($dbh->{AutoCommit});
1457   $dbh;
1458 }
1459
1460 sub txn_begin {
1461   my $self = shift;
1462
1463   # this means we have not yet connected and do not know the AC status
1464   # (e.g. coderef $dbh), need a full-fledged connection check
1465   if (! defined $self->_dbh_autocommit) {
1466     $self->ensure_connected;
1467   }
1468   # Otherwise simply connect or re-connect on pid changes
1469   else {
1470     $self->_get_dbh;
1471   }
1472
1473   $self->next::method(@_);
1474 }
1475
1476 sub _exec_txn_begin {
1477   my $self = shift;
1478
1479   # if the user is utilizing txn_do - good for him, otherwise we need to
1480   # ensure that the $dbh is healthy on BEGIN.
1481   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1482   # will be replaced by a failure of begin_work itself (which will be
1483   # then retried on reconnect)
1484   if ($self->{_in_do_block}) {
1485     $self->_dbh->begin_work;
1486   } else {
1487     $self->dbh_do(sub { $_[1]->begin_work });
1488   }
1489 }
1490
1491 sub txn_commit {
1492   my $self = shift;
1493
1494   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1495   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1496     unless $self->_dbh;
1497
1498   # esoteric case for folks using external $dbh handles
1499   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1500     carp "Storage transaction_depth 0 does not match "
1501         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1502     $self->transaction_depth(1);
1503   }
1504
1505   $self->next::method(@_);
1506
1507   # if AutoCommit is disabled txn_depth never goes to 0
1508   # as a new txn is started immediately on commit
1509   $self->transaction_depth(1) if (
1510     !$self->transaction_depth
1511       and
1512     defined $self->_dbh_autocommit
1513       and
1514     ! $self->_dbh_autocommit
1515   );
1516 }
1517
1518 sub _exec_txn_commit {
1519   shift->_dbh->commit;
1520 }
1521
1522 sub txn_rollback {
1523   my $self = shift;
1524
1525   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1526   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1527     unless $self->_dbh;
1528
1529   # esoteric case for folks using external $dbh handles
1530   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1531     carp "Storage transaction_depth 0 does not match "
1532         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1533     $self->transaction_depth(1);
1534   }
1535
1536   $self->next::method(@_);
1537
1538   # if AutoCommit is disabled txn_depth never goes to 0
1539   # as a new txn is started immediately on commit
1540   $self->transaction_depth(1) if (
1541     !$self->transaction_depth
1542       and
1543     defined $self->_dbh_autocommit
1544       and
1545     ! $self->_dbh_autocommit
1546   );
1547 }
1548
1549 sub _exec_txn_rollback {
1550   shift->_dbh->rollback;
1551 }
1552
1553 # generate some identical methods
1554 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1555   no strict qw/refs/;
1556   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1557     my $self = shift;
1558     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1559     $self->throw_exception("Unable to $meth() on a disconnected storage")
1560       unless $self->_dbh;
1561     $self->next::method(@_);
1562   };
1563 }
1564
1565 # This used to be the top-half of _execute.  It was split out to make it
1566 #  easier to override in NoBindVars without duping the rest.  It takes up
1567 #  all of _execute's args, and emits $sql, @bind.
1568 sub _prep_for_execute {
1569   #my ($self, $op, $ident, $args) = @_;
1570   return shift->_gen_sql_bind(@_)
1571 }
1572
1573 sub _gen_sql_bind {
1574   my ($self, $op, $ident, $args) = @_;
1575
1576   my ($colinfos, $from);
1577   if ( blessed($ident) ) {
1578     $from = $ident->from;
1579     $colinfos = $ident->columns_info;
1580   }
1581
1582   my ($sql, @bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1583
1584   if (
1585     ! $ENV{DBIC_DT_SEARCH_OK}
1586       and
1587     $op eq 'select'
1588       and
1589     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1590   ) {
1591     carp_unique 'DateTime objects passed to search() are not supported '
1592       . 'properly (InflateColumn::DateTime formats and settings are not '
1593       . 'respected.) See "Formatting DateTime objects in queries" in '
1594       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1595       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1596   }
1597
1598   return( $sql, $self->_resolve_bindattrs(
1599     $ident, [ @{$args->[2]{bind}||[]}, @bind ], $colinfos
1600   ));
1601 }
1602
1603 sub _resolve_bindattrs {
1604   my ($self, $ident, $bind, $colinfos) = @_;
1605
1606   $colinfos ||= {};
1607
1608   my $resolve_bindinfo = sub {
1609     #my $infohash = shift;
1610
1611     %$colinfos = %{ $self->_resolve_column_info($ident) }
1612       unless keys %$colinfos;
1613
1614     my $ret;
1615     if (my $col = $_[0]->{dbic_colname}) {
1616       $ret = { %{$_[0]} };
1617
1618       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1619         if $colinfos->{$col}{data_type};
1620
1621       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1622         if $colinfos->{$col}{size};
1623     }
1624
1625     $ret || $_[0];
1626   };
1627
1628   return [ map {
1629     if (ref $_ ne 'ARRAY') {
1630       [{}, $_]
1631     }
1632     elsif (! defined $_->[0]) {
1633       [{}, $_->[1]]
1634     }
1635     elsif (ref $_->[0] eq 'HASH') {
1636       [
1637         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1638         $_->[1]
1639       ]
1640     }
1641     elsif (ref $_->[0] eq 'SCALAR') {
1642       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1643     }
1644     else {
1645       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1646     }
1647   } @$bind ];
1648 }
1649
1650 sub _format_for_trace {
1651   #my ($self, $bind) = @_;
1652
1653   ### Turn @bind from something like this:
1654   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1655   ### to this:
1656   ###   ( "'1'", "'3'" )
1657
1658   map {
1659     defined( $_ && $_->[1] )
1660       ? qq{'$_->[1]'}
1661       : q{NULL}
1662   } @{$_[1] || []};
1663 }
1664
1665 sub _query_start {
1666   my ( $self, $sql, $bind ) = @_;
1667
1668   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1669     if $self->debug;
1670 }
1671
1672 sub _query_end {
1673   my ( $self, $sql, $bind ) = @_;
1674
1675   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1676     if $self->debug;
1677 }
1678
1679 sub _dbi_attrs_for_bind {
1680   my ($self, $ident, $bind) = @_;
1681
1682   my @attrs;
1683
1684   for (map { $_->[0] } @$bind) {
1685     push @attrs, do {
1686       if (exists $_->{dbd_attrs}) {
1687         $_->{dbd_attrs}
1688       }
1689       elsif($_->{sqlt_datatype}) {
1690         # cache the result in the dbh_details hash, as it can not change unless
1691         # we connect to something else
1692         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1693         if (not exists $cache->{$_->{sqlt_datatype}}) {
1694           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1695         }
1696         $cache->{$_->{sqlt_datatype}};
1697       }
1698       else {
1699         undef;  # always push something at this position
1700       }
1701     }
1702   }
1703
1704   return \@attrs;
1705 }
1706
1707 sub _execute {
1708   my ($self, $op, $ident, @args) = @_;
1709
1710   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1711
1712   shift->dbh_do(    # retry over disconnects
1713     '_dbh_execute',
1714     $sql,
1715     $bind,
1716     $ident,
1717   );
1718 }
1719
1720 sub _dbh_execute {
1721   my ($self, undef, $sql, $bind, $ident) = @_;
1722
1723   $self->_query_start( $sql, $bind );
1724
1725   my $bind_attrs = $self->_dbi_attrs_for_bind($ident, $bind);
1726
1727   my $sth = $self->_sth($sql);
1728
1729   for my $i (0 .. $#$bind) {
1730     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1731       $sth->bind_param_inout(
1732         $i + 1, # bind params counts are 1-based
1733         $bind->[$i][1],
1734         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1735         $bind_attrs->[$i],
1736       );
1737     }
1738     else {
1739       $sth->bind_param(
1740         $i + 1,
1741         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1742           ? "$bind->[$i][1]"
1743           : $bind->[$i][1]
1744         ,
1745         $bind_attrs->[$i],
1746       );
1747     }
1748   }
1749
1750   # Can this fail without throwing an exception anyways???
1751   my $rv = $sth->execute();
1752   $self->throw_exception(
1753     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1754   ) if !$rv;
1755
1756   $self->_query_end( $sql, $bind );
1757
1758   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1759 }
1760
1761 sub _prefetch_autovalues {
1762   my ($self, $source, $colinfo, $to_insert) = @_;
1763
1764   my %values;
1765   for my $col (keys %$colinfo) {
1766     if (
1767       $colinfo->{$col}{auto_nextval}
1768         and
1769       (
1770         ! exists $to_insert->{$col}
1771           or
1772         ref $to_insert->{$col} eq 'SCALAR'
1773           or
1774         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1775       )
1776     ) {
1777       $values{$col} = $self->_sequence_fetch(
1778         'NEXTVAL',
1779         ( $colinfo->{$col}{sequence} ||=
1780             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1781         ),
1782       );
1783     }
1784   }
1785
1786   \%values;
1787 }
1788
1789 sub insert {
1790   my ($self, $source, $to_insert) = @_;
1791
1792   my $col_infos = $source->columns_info;
1793
1794   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1795
1796   # fuse the values, but keep a separate list of prefetched_values so that
1797   # they can be fused once again with the final return
1798   $to_insert = { %$to_insert, %$prefetched_values };
1799
1800   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1801   # Investigate what does it take to s/defined/exists/
1802   my %pcols = map { $_ => 1 } $source->primary_columns;
1803   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1804   for my $col ($source->columns) {
1805     if ($col_infos->{$col}{is_auto_increment}) {
1806       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1807       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1808     }
1809
1810     # nothing to retrieve when explicit values are supplied
1811     next if (defined $to_insert->{$col} and ! (
1812       ref $to_insert->{$col} eq 'SCALAR'
1813         or
1814       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1815     ));
1816
1817     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1818     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1819       $pcols{$col}
1820         or
1821       $col_infos->{$col}{retrieve_on_insert}
1822     );
1823   };
1824
1825   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1826   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1827
1828   my ($sqla_opts, @ir_container);
1829   if (%retrieve_cols and $self->_use_insert_returning) {
1830     $sqla_opts->{returning_container} = \@ir_container
1831       if $self->_use_insert_returning_bound;
1832
1833     $sqla_opts->{returning} = [
1834       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1835     ];
1836   }
1837
1838   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1839
1840   my %returned_cols = %$to_insert;
1841   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1842     @ir_container = try {
1843       local $SIG{__WARN__} = sub {};
1844       my @r = $sth->fetchrow_array;
1845       $sth->finish;
1846       @r;
1847     } unless @ir_container;
1848
1849     @returned_cols{@$retlist} = @ir_container if @ir_container;
1850   }
1851   else {
1852     # pull in PK if needed and then everything else
1853     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1854
1855       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1856         unless $self->can('last_insert_id');
1857
1858       my @pri_values = $self->last_insert_id($source, @missing_pri);
1859
1860       $self->throw_exception( "Can't get last insert id" )
1861         unless (@pri_values == @missing_pri);
1862
1863       @returned_cols{@missing_pri} = @pri_values;
1864       delete $retrieve_cols{$_} for @missing_pri;
1865     }
1866
1867     # if there is more left to pull
1868     if (%retrieve_cols) {
1869       $self->throw_exception(
1870         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1871       ) unless %pcols;
1872
1873       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1874
1875       my $cur = DBIx::Class::ResultSet->new($source, {
1876         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1877         select => \@left_to_fetch,
1878       })->cursor;
1879
1880       @returned_cols{@left_to_fetch} = $cur->next;
1881
1882       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1883         if scalar $cur->next;
1884     }
1885   }
1886
1887   return { %$prefetched_values, %returned_cols };
1888 }
1889
1890 sub insert_bulk {
1891   my ($self, $source, $cols, $data) = @_;
1892
1893   my @col_range = (0..$#$cols);
1894
1895   # FIXME - perhaps this is not even needed? does DBI stringify?
1896   #
1897   # forcibly stringify whatever is stringifiable
1898   # ResultSet::populate() hands us a copy - safe to mangle
1899   for my $r (0 .. $#$data) {
1900     for my $c (0 .. $#{$data->[$r]}) {
1901       $data->[$r][$c] = "$data->[$r][$c]"
1902         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1903     }
1904   }
1905
1906   my $colinfos = $source->columns_info($cols);
1907
1908   local $self->{_autoinc_supplied_for_op} =
1909     (first { $_->{is_auto_increment} } values %$colinfos)
1910       ? 1
1911       : 0
1912   ;
1913
1914   # get a slice type index based on first row of data
1915   # a "column" in this context may refer to more than one bind value
1916   # e.g. \[ '?, ?', [...], [...] ]
1917   #
1918   # construct the value type index - a description of values types for every
1919   # per-column slice of $data:
1920   #
1921   # nonexistent - nonbind literal
1922   # 0 - regular value
1923   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1924   #
1925   # also construct the column hash to pass to the SQL generator. For plain
1926   # (non literal) values - convert the members of the first row into a
1927   # literal+bind combo, with extra positional info in the bind attr hashref.
1928   # This will allow us to match the order properly, and is so contrived
1929   # because a user-supplied literal/bind (or something else specific to a
1930   # resultsource and/or storage driver) can inject extra binds along the
1931   # way, so one can't rely on "shift positions" ordering at all. Also we
1932   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1933   # can be later matched up by address), because we want to supply a real
1934   # value on which perhaps e.g. datatype checks will be performed
1935   my ($proto_data, $value_type_by_col_idx);
1936   for my $i (@col_range) {
1937     my $colname = $cols->[$i];
1938     if (ref $data->[0][$i] eq 'SCALAR') {
1939       # no bind value at all - no type
1940
1941       $proto_data->{$colname} = $data->[0][$i];
1942     }
1943     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1944       # repack, so we don't end up mangling the original \[]
1945       my ($sql, @bind) = @${$data->[0][$i]};
1946
1947       # normalization of user supplied stuff
1948       my $resolved_bind = $self->_resolve_bindattrs(
1949         $source, \@bind, $colinfos,
1950       );
1951
1952       # store value-less (attrs only) bind info - we will be comparing all
1953       # supplied binds against this for sanity
1954       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1955
1956       $proto_data->{$colname} = \[ $sql, map { [
1957         # inject slice order to use for $proto_bind construction
1958           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
1959             =>
1960           $resolved_bind->[$_][1]
1961         ] } (0 .. $#bind)
1962       ];
1963     }
1964     else {
1965       $value_type_by_col_idx->{$i} = undef;
1966
1967       $proto_data->{$colname} = \[ '?', [
1968         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1969           =>
1970         $data->[0][$i]
1971       ] ];
1972     }
1973   }
1974
1975   my ($sql, $proto_bind) = $self->_prep_for_execute (
1976     'insert',
1977     $source,
1978     [ $proto_data ],
1979   );
1980
1981   if (! @$proto_bind and keys %$value_type_by_col_idx) {
1982     # if the bindlist is empty and we had some dynamic binds, this means the
1983     # storage ate them away (e.g. the NoBindVars component) and interpolated
1984     # them directly into the SQL. This obviously can't be good for multi-inserts
1985     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1986   }
1987
1988   # sanity checks
1989   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1990   #
1991   # use an error reporting closure for convenience (less to pass)
1992   my $bad_slice_report_cref = sub {
1993     my ($msg, $r_idx, $c_idx) = @_;
1994     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1995       $msg,
1996       $cols->[$c_idx],
1997       do {
1998         require Data::Dumper::Concise;
1999         local $Data::Dumper::Maxdepth = 5;
2000         Data::Dumper::Concise::Dumper ({
2001           map { $cols->[$_] =>
2002             $data->[$r_idx][$_]
2003           } @col_range
2004         }),
2005       }
2006     );
2007   };
2008
2009   for my $col_idx (@col_range) {
2010     my $reference_val = $data->[0][$col_idx];
2011
2012     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2013       my $val = $data->[$row_idx][$col_idx];
2014
2015       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2016         if (ref $val ne 'SCALAR') {
2017           $bad_slice_report_cref->(
2018             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2019             $row_idx,
2020             $col_idx,
2021           );
2022         }
2023         elsif ($$val ne $$reference_val) {
2024           $bad_slice_report_cref->(
2025             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2026             $row_idx,
2027             $col_idx,
2028           );
2029         }
2030       }
2031       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2032         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2033           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2034         }
2035       }
2036       else {  # binds from a \[], compare type and attrs
2037         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2038           $bad_slice_report_cref->(
2039             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2040             $row_idx,
2041             $col_idx,
2042           );
2043         }
2044         # start drilling down and bail out early on identical refs
2045         elsif (
2046           $reference_val != $val
2047             or
2048           $$reference_val != $$val
2049         ) {
2050           if (${$val}->[0] ne ${$reference_val}->[0]) {
2051             $bad_slice_report_cref->(
2052               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2053               $row_idx,
2054               $col_idx,
2055             );
2056           }
2057           # need to check the bind attrs - a bind will happen only once for
2058           # the entire dataset, so any changes further down will be ignored.
2059           elsif (! Data::Compare::Compare(
2060             $value_type_by_col_idx->{$col_idx},
2061             [
2062               map
2063               { $_->[0] }
2064               @{$self->_resolve_bindattrs(
2065                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2066               )}
2067             ],
2068           )) {
2069             $bad_slice_report_cref->(
2070               'Differing bind attributes on literal/bind values not supported',
2071               $row_idx,
2072               $col_idx,
2073             );
2074           }
2075         }
2076       }
2077     }
2078   }
2079
2080   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2081   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2082   # scope guard
2083   my $guard = $self->txn_scope_guard;
2084
2085   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2086   my $sth = $self->_sth($sql);
2087   my $rv = do {
2088     if (@$proto_bind) {
2089       # proto bind contains the information on which pieces of $data to pull
2090       # $cols is passed in only for prettier error-reporting
2091       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2092     }
2093     else {
2094       # bind_param_array doesn't work if there are no binds
2095       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2096     }
2097   };
2098
2099   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2100
2101   $guard->commit;
2102
2103   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2104 }
2105
2106 # execute_for_fetch is capable of returning data just fine (it means it
2107 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2108 # is the void-populate fast-path we will just ignore this altogether
2109 # for the time being.
2110 sub _dbh_execute_for_fetch {
2111   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2112
2113   my @idx_range = ( 0 .. $#$proto_bind );
2114
2115   # If we have any bind attributes to take care of, we will bind the
2116   # proto-bind data (which will never be used by execute_for_fetch)
2117   # However since column bindtypes are "sticky", this is sufficient
2118   # to get the DBD to apply the bindtype to all values later on
2119
2120   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2121
2122   for my $i (@idx_range) {
2123     $sth->bind_param (
2124       $i+1, # DBI bind indexes are 1-based
2125       $proto_bind->[$i][1],
2126       $bind_attrs->[$i],
2127     ) if defined $bind_attrs->[$i];
2128   }
2129
2130   # At this point $data slots named in the _bind_data_slice_idx of
2131   # each piece of $proto_bind are either \[]s or plain values to be
2132   # passed in. Construct the dispensing coderef. *NOTE* the order
2133   # of $data will differ from this of the ?s in the SQL (due to
2134   # alphabetical ordering by colname). We actually do want to
2135   # preserve this behavior so that prepare_cached has a better
2136   # chance of matching on unrelated calls
2137
2138   my $fetch_row_idx = -1; # saner loop this way
2139   my $fetch_tuple = sub {
2140     return undef if ++$fetch_row_idx > $#$data;
2141
2142     return [ map { defined $_->{_literal_bind_subindex}
2143       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2144          ->[ $_->{_literal_bind_subindex} ]
2145           ->[1]
2146       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2147     } map { $_->[0] } @$proto_bind];
2148   };
2149
2150   my $tuple_status = [];
2151   my ($rv, $err);
2152   try {
2153     $rv = $sth->execute_for_fetch(
2154       $fetch_tuple,
2155       $tuple_status,
2156     );
2157   }
2158   catch {
2159     $err = shift;
2160   };
2161
2162   # Not all DBDs are create equal. Some throw on error, some return
2163   # an undef $rv, and some set $sth->err - try whatever we can
2164   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2165     ! defined $err
2166       and
2167     ( !defined $rv or $sth->err )
2168   );
2169
2170   # Statement must finish even if there was an exception.
2171   try {
2172     $sth->finish
2173   }
2174   catch {
2175     $err = shift unless defined $err
2176   };
2177
2178   if (defined $err) {
2179     my $i = 0;
2180     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2181
2182     $self->throw_exception("Unexpected populate error: $err")
2183       if ($i > $#$tuple_status);
2184
2185     require Data::Dumper::Concise;
2186     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2187       ($tuple_status->[$i][1] || $err),
2188       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2189     );
2190   }
2191
2192   return $rv;
2193 }
2194
2195 sub _dbh_execute_inserts_with_no_binds {
2196   my ($self, $sth, $count) = @_;
2197
2198   my $err;
2199   try {
2200     my $dbh = $self->_get_dbh;
2201     local $dbh->{RaiseError} = 1;
2202     local $dbh->{PrintError} = 0;
2203
2204     $sth->execute foreach 1..$count;
2205   }
2206   catch {
2207     $err = shift;
2208   };
2209
2210   # Make sure statement is finished even if there was an exception.
2211   try {
2212     $sth->finish
2213   }
2214   catch {
2215     $err = shift unless defined $err;
2216   };
2217
2218   $self->throw_exception($err) if defined $err;
2219
2220   return $count;
2221 }
2222
2223 sub update {
2224   #my ($self, $source, @args) = @_;
2225   shift->_execute('update', @_);
2226 }
2227
2228
2229 sub delete {
2230   #my ($self, $source, @args) = @_;
2231   shift->_execute('delete', @_);
2232 }
2233
2234 sub _select {
2235   my $self = shift;
2236   $self->_execute($self->_select_args(@_));
2237 }
2238
2239 sub _select_args_to_query {
2240   my $self = shift;
2241
2242   $self->throw_exception(
2243     "Unable to generate limited query representation with 'software_limit' enabled"
2244   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2245
2246   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2247   #  = $self->_select_args($ident, $select, $cond, $attrs);
2248   my ($op, $ident, @args) =
2249     $self->_select_args(@_);
2250
2251   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2252   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2253   $prepared_bind ||= [];
2254
2255   return wantarray
2256     ? ($sql, $prepared_bind)
2257     : \[ "($sql)", @$prepared_bind ]
2258   ;
2259 }
2260
2261 sub _select_args {
2262   my ($self, $ident, $select, $where, $attrs) = @_;
2263
2264   my $sql_maker = $self->sql_maker;
2265   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2266
2267   $attrs = {
2268     %$attrs,
2269     select => $select,
2270     from => $ident,
2271     where => $where,
2272     $rs_alias && $alias2source->{$rs_alias}
2273       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2274       : ()
2275     ,
2276   };
2277
2278   # Sanity check the attributes (SQLMaker does it too, but
2279   # in case of a software_limit we'll never reach there)
2280   if (defined $attrs->{offset}) {
2281     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2282       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2283   }
2284
2285   if (defined $attrs->{rows}) {
2286     $self->throw_exception("The rows attribute must be a positive integer if present")
2287       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2288   }
2289   elsif ($attrs->{offset}) {
2290     # MySQL actually recommends this approach.  I cringe.
2291     $attrs->{rows} = $sql_maker->__max_int;
2292   }
2293
2294   my @limit;
2295
2296   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2297   # storage, unless software limit was requested
2298   if (
2299     #limited has_many
2300     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2301        ||
2302     # grouped prefetch (to satisfy group_by == select)
2303     ( $attrs->{group_by}
2304         &&
2305       @{$attrs->{group_by}}
2306         &&
2307       $attrs->{_prefetch_selector_range}
2308     )
2309   ) {
2310     ($ident, $select, $where, $attrs)
2311       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2312   }
2313   elsif (! $attrs->{software_limit} ) {
2314     push @limit, (
2315       $attrs->{rows} || (),
2316       $attrs->{offset} || (),
2317     );
2318   }
2319
2320   # try to simplify the joinmap further (prune unreferenced type-single joins)
2321   if (
2322     ref $ident
2323       and
2324     reftype $ident eq 'ARRAY'
2325       and
2326     @$ident != 1
2327   ) {
2328     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2329   }
2330
2331 ###
2332   # This would be the point to deflate anything found in $where
2333   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2334   # expect a result object. And all we have is a resultsource (it is trivial
2335   # to extract deflator coderefs via $alias2source above).
2336   #
2337   # I don't see a way forward other than changing the way deflators are
2338   # invoked, and that's just bad...
2339 ###
2340
2341   return ('select', $ident, $select, $where, $attrs, @limit);
2342 }
2343
2344 # Returns a counting SELECT for a simple count
2345 # query. Abstracted so that a storage could override
2346 # this to { count => 'firstcol' } or whatever makes
2347 # sense as a performance optimization
2348 sub _count_select {
2349   #my ($self, $source, $rs_attrs) = @_;
2350   return { count => '*' };
2351 }
2352
2353 =head2 select
2354
2355 =over 4
2356
2357 =item Arguments: $ident, $select, $condition, $attrs
2358
2359 =back
2360
2361 Handle a SQL select statement.
2362
2363 =cut
2364
2365 sub select {
2366   my $self = shift;
2367   my ($ident, $select, $condition, $attrs) = @_;
2368   return $self->cursor_class->new($self, \@_, $attrs);
2369 }
2370
2371 sub select_single {
2372   my $self = shift;
2373   my ($rv, $sth, @bind) = $self->_select(@_);
2374   my @row = $sth->fetchrow_array;
2375   my @nextrow = $sth->fetchrow_array if @row;
2376   if(@row && @nextrow) {
2377     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2378   }
2379   # Need to call finish() to work round broken DBDs
2380   $sth->finish();
2381   return @row;
2382 }
2383
2384 =head2 sql_limit_dialect
2385
2386 This is an accessor for the default SQL limit dialect used by a particular
2387 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2388 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2389 see L<DBIx::Class::SQLMaker::LimitDialects>.
2390
2391 =cut
2392
2393 sub _dbh_sth {
2394   my ($self, $dbh, $sql) = @_;
2395
2396   # 3 is the if_active parameter which avoids active sth re-use
2397   my $sth = $self->disable_sth_caching
2398     ? $dbh->prepare($sql)
2399     : $dbh->prepare_cached($sql, {}, 3);
2400
2401   # XXX You would think RaiseError would make this impossible,
2402   #  but apparently that's not true :(
2403   $self->throw_exception(
2404     $dbh->errstr
2405       ||
2406     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2407             .'an exception and/or setting $dbh->errstr',
2408       length ($sql) > 20
2409         ? substr($sql, 0, 20) . '...'
2410         : $sql
2411       ,
2412       'DBD::' . $dbh->{Driver}{Name},
2413     )
2414   ) if !$sth;
2415
2416   $sth;
2417 }
2418
2419 sub sth {
2420   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2421   shift->_sth(@_);
2422 }
2423
2424 sub _sth {
2425   my ($self, $sql) = @_;
2426   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2427 }
2428
2429 sub _dbh_columns_info_for {
2430   my ($self, $dbh, $table) = @_;
2431
2432   if ($dbh->can('column_info')) {
2433     my %result;
2434     my $caught;
2435     try {
2436       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2437       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2438       $sth->execute();
2439       while ( my $info = $sth->fetchrow_hashref() ){
2440         my %column_info;
2441         $column_info{data_type}   = $info->{TYPE_NAME};
2442         $column_info{size}      = $info->{COLUMN_SIZE};
2443         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2444         $column_info{default_value} = $info->{COLUMN_DEF};
2445         my $col_name = $info->{COLUMN_NAME};
2446         $col_name =~ s/^\"(.*)\"$/$1/;
2447
2448         $result{$col_name} = \%column_info;
2449       }
2450     } catch {
2451       $caught = 1;
2452     };
2453     return \%result if !$caught && scalar keys %result;
2454   }
2455
2456   my %result;
2457   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2458   $sth->execute;
2459   my @columns = @{$sth->{NAME_lc}};
2460   for my $i ( 0 .. $#columns ){
2461     my %column_info;
2462     $column_info{data_type} = $sth->{TYPE}->[$i];
2463     $column_info{size} = $sth->{PRECISION}->[$i];
2464     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2465
2466     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2467       $column_info{data_type} = $1;
2468       $column_info{size}    = $2;
2469     }
2470
2471     $result{$columns[$i]} = \%column_info;
2472   }
2473   $sth->finish;
2474
2475   foreach my $col (keys %result) {
2476     my $colinfo = $result{$col};
2477     my $type_num = $colinfo->{data_type};
2478     my $type_name;
2479     if(defined $type_num && $dbh->can('type_info')) {
2480       my $type_info = $dbh->type_info($type_num);
2481       $type_name = $type_info->{TYPE_NAME} if $type_info;
2482       $colinfo->{data_type} = $type_name if $type_name;
2483     }
2484   }
2485
2486   return \%result;
2487 }
2488
2489 sub columns_info_for {
2490   my ($self, $table) = @_;
2491   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2492 }
2493
2494 =head2 last_insert_id
2495
2496 Return the row id of the last insert.
2497
2498 =cut
2499
2500 sub _dbh_last_insert_id {
2501     my ($self, $dbh, $source, $col) = @_;
2502
2503     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2504
2505     return $id if defined $id;
2506
2507     my $class = ref $self;
2508     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2509 }
2510
2511 sub last_insert_id {
2512   my $self = shift;
2513   $self->_dbh_last_insert_id ($self->_dbh, @_);
2514 }
2515
2516 =head2 _native_data_type
2517
2518 =over 4
2519
2520 =item Arguments: $type_name
2521
2522 =back
2523
2524 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2525 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2526 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2527
2528 The default implementation returns C<undef>, implement in your Storage driver if
2529 you need this functionality.
2530
2531 Should map types from other databases to the native RDBMS type, for example
2532 C<VARCHAR2> to C<VARCHAR>.
2533
2534 Types with modifiers should map to the underlying data type. For example,
2535 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2536
2537 Composite types should map to the container type, for example
2538 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2539
2540 =cut
2541
2542 sub _native_data_type {
2543   #my ($self, $data_type) = @_;
2544   return undef
2545 }
2546
2547 # Check if placeholders are supported at all
2548 sub _determine_supports_placeholders {
2549   my $self = shift;
2550   my $dbh  = $self->_get_dbh;
2551
2552   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2553   # but it is inaccurate more often than not
2554   return try {
2555     local $dbh->{PrintError} = 0;
2556     local $dbh->{RaiseError} = 1;
2557     $dbh->do('select ?', {}, 1);
2558     1;
2559   }
2560   catch {
2561     0;
2562   };
2563 }
2564
2565 # Check if placeholders bound to non-string types throw exceptions
2566 #
2567 sub _determine_supports_typeless_placeholders {
2568   my $self = shift;
2569   my $dbh  = $self->_get_dbh;
2570
2571   return try {
2572     local $dbh->{PrintError} = 0;
2573     local $dbh->{RaiseError} = 1;
2574     # this specifically tests a bind that is NOT a string
2575     $dbh->do('select 1 where 1 = ?', {}, 1);
2576     1;
2577   }
2578   catch {
2579     0;
2580   };
2581 }
2582
2583 =head2 sqlt_type
2584
2585 Returns the database driver name.
2586
2587 =cut
2588
2589 sub sqlt_type {
2590   shift->_get_dbh->{Driver}->{Name};
2591 }
2592
2593 =head2 bind_attribute_by_data_type
2594
2595 Given a datatype from column info, returns a database specific bind
2596 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2597 let the database planner just handle it.
2598
2599 This method is always called after the driver has been determined and a DBI
2600 connection has been established. Therefore you can refer to C<DBI::$constant>
2601 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2602 the correct modules.
2603
2604 =cut
2605
2606 sub bind_attribute_by_data_type {
2607     return;
2608 }
2609
2610 =head2 is_datatype_numeric
2611
2612 Given a datatype from column_info, returns a boolean value indicating if
2613 the current RDBMS considers it a numeric value. This controls how
2614 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2615 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2616 be performed instead of the usual C<eq>.
2617
2618 =cut
2619
2620 sub is_datatype_numeric {
2621   #my ($self, $dt) = @_;
2622
2623   return 0 unless $_[1];
2624
2625   $_[1] =~ /^ (?:
2626     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2627   ) $/ix;
2628 }
2629
2630
2631 =head2 create_ddl_dir
2632
2633 =over 4
2634
2635 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2636
2637 =back
2638
2639 Creates a SQL file based on the Schema, for each of the specified
2640 database engines in C<\@databases> in the given directory.
2641 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2642
2643 Given a previous version number, this will also create a file containing
2644 the ALTER TABLE statements to transform the previous schema into the
2645 current one. Note that these statements may contain C<DROP TABLE> or
2646 C<DROP COLUMN> statements that can potentially destroy data.
2647
2648 The file names are created using the C<ddl_filename> method below, please
2649 override this method in your schema if you would like a different file
2650 name format. For the ALTER file, the same format is used, replacing
2651 $version in the name with "$preversion-$version".
2652
2653 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2654 The most common value for this would be C<< { add_drop_table => 1 } >>
2655 to have the SQL produced include a C<DROP TABLE> statement for each table
2656 created. For quoting purposes supply C<quote_table_names> and
2657 C<quote_field_names>.
2658
2659 If no arguments are passed, then the following default values are assumed:
2660
2661 =over 4
2662
2663 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2664
2665 =item version    - $schema->schema_version
2666
2667 =item directory  - './'
2668
2669 =item preversion - <none>
2670
2671 =back
2672
2673 By default, C<\%sqlt_args> will have
2674
2675  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2676
2677 merged with the hash passed in. To disable any of those features, pass in a
2678 hashref like the following
2679
2680  { ignore_constraint_names => 0, # ... other options }
2681
2682
2683 WARNING: You are strongly advised to check all SQL files created, before applying
2684 them.
2685
2686 =cut
2687
2688 sub create_ddl_dir {
2689   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2690
2691   unless ($dir) {
2692     carp "No directory given, using ./\n";
2693     $dir = './';
2694   } else {
2695       -d $dir
2696         or
2697       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2698         or
2699       $self->throw_exception(
2700         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2701       );
2702   }
2703
2704   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2705
2706   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2707   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2708
2709   my $schema_version = $schema->schema_version || '1.x';
2710   $version ||= $schema_version;
2711
2712   $sqltargs = {
2713     add_drop_table => 1,
2714     ignore_constraint_names => 1,
2715     ignore_index_names => 1,
2716     %{$sqltargs || {}}
2717   };
2718
2719   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2720     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2721   }
2722
2723   my $sqlt = SQL::Translator->new( $sqltargs );
2724
2725   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2726   my $sqlt_schema = $sqlt->translate({ data => $schema })
2727     or $self->throw_exception ($sqlt->error);
2728
2729   foreach my $db (@$databases) {
2730     $sqlt->reset();
2731     $sqlt->{schema} = $sqlt_schema;
2732     $sqlt->producer($db);
2733
2734     my $file;
2735     my $filename = $schema->ddl_filename($db, $version, $dir);
2736     if (-e $filename && ($version eq $schema_version )) {
2737       # if we are dumping the current version, overwrite the DDL
2738       carp "Overwriting existing DDL file - $filename";
2739       unlink($filename);
2740     }
2741
2742     my $output = $sqlt->translate;
2743     if(!$output) {
2744       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2745       next;
2746     }
2747     if(!open($file, ">$filename")) {
2748       $self->throw_exception("Can't open $filename for writing ($!)");
2749       next;
2750     }
2751     print $file $output;
2752     close($file);
2753
2754     next unless ($preversion);
2755
2756     require SQL::Translator::Diff;
2757
2758     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2759     if(!-e $prefilename) {
2760       carp("No previous schema file found ($prefilename)");
2761       next;
2762     }
2763
2764     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2765     if(-e $difffile) {
2766       carp("Overwriting existing diff file - $difffile");
2767       unlink($difffile);
2768     }
2769
2770     my $source_schema;
2771     {
2772       my $t = SQL::Translator->new($sqltargs);
2773       $t->debug( 0 );
2774       $t->trace( 0 );
2775
2776       $t->parser( $db )
2777         or $self->throw_exception ($t->error);
2778
2779       my $out = $t->translate( $prefilename )
2780         or $self->throw_exception ($t->error);
2781
2782       $source_schema = $t->schema;
2783
2784       $source_schema->name( $prefilename )
2785         unless ( $source_schema->name );
2786     }
2787
2788     # The "new" style of producers have sane normalization and can support
2789     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2790     # And we have to diff parsed SQL against parsed SQL.
2791     my $dest_schema = $sqlt_schema;
2792
2793     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2794       my $t = SQL::Translator->new($sqltargs);
2795       $t->debug( 0 );
2796       $t->trace( 0 );
2797
2798       $t->parser( $db )
2799         or $self->throw_exception ($t->error);
2800
2801       my $out = $t->translate( $filename )
2802         or $self->throw_exception ($t->error);
2803
2804       $dest_schema = $t->schema;
2805
2806       $dest_schema->name( $filename )
2807         unless $dest_schema->name;
2808     }
2809
2810     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2811                                                   $dest_schema,   $db,
2812                                                   $sqltargs
2813                                                  );
2814     if(!open $file, ">$difffile") {
2815       $self->throw_exception("Can't write to $difffile ($!)");
2816       next;
2817     }
2818     print $file $diff;
2819     close($file);
2820   }
2821 }
2822
2823 =head2 deployment_statements
2824
2825 =over 4
2826
2827 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2828
2829 =back
2830
2831 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2832
2833 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2834 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2835
2836 C<$directory> is used to return statements from files in a previously created
2837 L</create_ddl_dir> directory and is optional. The filenames are constructed
2838 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2839
2840 If no C<$directory> is specified then the statements are constructed on the
2841 fly using L<SQL::Translator> and C<$version> is ignored.
2842
2843 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2844
2845 =cut
2846
2847 sub deployment_statements {
2848   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2849   $type ||= $self->sqlt_type;
2850   $version ||= $schema->schema_version || '1.x';
2851   $dir ||= './';
2852   my $filename = $schema->ddl_filename($type, $version, $dir);
2853   if(-f $filename)
2854   {
2855       # FIXME replace this block when a proper sane sql parser is available
2856       my $file;
2857       open($file, "<$filename")
2858         or $self->throw_exception("Can't open $filename ($!)");
2859       my @rows = <$file>;
2860       close($file);
2861       return join('', @rows);
2862   }
2863
2864   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2865     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2866   }
2867
2868   # sources needs to be a parser arg, but for simplicty allow at top level
2869   # coming in
2870   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2871       if exists $sqltargs->{sources};
2872
2873   my $tr = SQL::Translator->new(
2874     producer => "SQL::Translator::Producer::${type}",
2875     %$sqltargs,
2876     parser => 'SQL::Translator::Parser::DBIx::Class',
2877     data => $schema,
2878   );
2879
2880   return preserve_context {
2881     $tr->translate
2882   } after => sub {
2883     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2884       unless defined $_[0];
2885   };
2886 }
2887
2888 # FIXME deploy() currently does not accurately report sql errors
2889 # Will always return true while errors are warned
2890 sub deploy {
2891   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2892   my $deploy = sub {
2893     my $line = shift;
2894     return if(!$line);
2895     return if($line =~ /^--/);
2896     # next if($line =~ /^DROP/m);
2897     return if($line =~ /^BEGIN TRANSACTION/m);
2898     return if($line =~ /^COMMIT/m);
2899     return if $line =~ /^\s+$/; # skip whitespace only
2900     $self->_query_start($line);
2901     try {
2902       # do a dbh_do cycle here, as we need some error checking in
2903       # place (even though we will ignore errors)
2904       $self->dbh_do (sub { $_[1]->do($line) });
2905     } catch {
2906       carp qq{$_ (running "${line}")};
2907     };
2908     $self->_query_end($line);
2909   };
2910   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2911   if (@statements > 1) {
2912     foreach my $statement (@statements) {
2913       $deploy->( $statement );
2914     }
2915   }
2916   elsif (@statements == 1) {
2917     # split on single line comments and end of statements
2918     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2919       $deploy->( $line );
2920     }
2921   }
2922 }
2923
2924 =head2 datetime_parser
2925
2926 Returns the datetime parser class
2927
2928 =cut
2929
2930 sub datetime_parser {
2931   my $self = shift;
2932   return $self->{datetime_parser} ||= do {
2933     $self->build_datetime_parser(@_);
2934   };
2935 }
2936
2937 =head2 datetime_parser_type
2938
2939 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2940
2941 =head2 build_datetime_parser
2942
2943 See L</datetime_parser>
2944
2945 =cut
2946
2947 sub build_datetime_parser {
2948   my $self = shift;
2949   my $type = $self->datetime_parser_type(@_);
2950   return $type;
2951 }
2952
2953
2954 =head2 is_replicating
2955
2956 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2957 replicate from a master database.  Default is undef, which is the result
2958 returned by databases that don't support replication.
2959
2960 =cut
2961
2962 sub is_replicating {
2963     return;
2964
2965 }
2966
2967 =head2 lag_behind_master
2968
2969 Returns a number that represents a certain amount of lag behind a master db
2970 when a given storage is replicating.  The number is database dependent, but
2971 starts at zero and increases with the amount of lag. Default in undef
2972
2973 =cut
2974
2975 sub lag_behind_master {
2976     return;
2977 }
2978
2979 =head2 relname_to_table_alias
2980
2981 =over 4
2982
2983 =item Arguments: $relname, $join_count
2984
2985 =item Return Value: $alias
2986
2987 =back
2988
2989 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2990 queries.
2991
2992 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2993 way these aliases are named.
2994
2995 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2996 otherwise C<"$relname">.
2997
2998 =cut
2999
3000 sub relname_to_table_alias {
3001   my ($self, $relname, $join_count) = @_;
3002
3003   my $alias = ($join_count && $join_count > 1 ?
3004     join('_', $relname, $join_count) : $relname);
3005
3006   return $alias;
3007 }
3008
3009 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3010 # version and it may be necessary to amend or override it for a specific storage
3011 # if such binds are necessary.
3012 sub _max_column_bytesize {
3013   my ($self, $attr) = @_;
3014
3015   my $max_size;
3016
3017   if ($attr->{sqlt_datatype}) {
3018     my $data_type = lc($attr->{sqlt_datatype});
3019
3020     if ($attr->{sqlt_size}) {
3021
3022       # String/sized-binary types
3023       if ($data_type =~ /^(?:
3024           l? (?:var)? char(?:acter)? (?:\s*varying)?
3025             |
3026           (?:var)? binary (?:\s*varying)?
3027             |
3028           raw
3029         )\b/x
3030       ) {
3031         $max_size = $attr->{sqlt_size};
3032       }
3033       # Other charset/unicode types, assume scale of 4
3034       elsif ($data_type =~ /^(?:
3035           national \s* character (?:\s*varying)?
3036             |
3037           nchar
3038             |
3039           univarchar
3040             |
3041           nvarchar
3042         )\b/x
3043       ) {
3044         $max_size = $attr->{sqlt_size} * 4;
3045       }
3046     }
3047
3048     if (!$max_size and !$self->_is_lob_type($data_type)) {
3049       $max_size = 100 # for all other (numeric?) datatypes
3050     }
3051   }
3052
3053   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3054 }
3055
3056 # Determine if a data_type is some type of BLOB
3057 sub _is_lob_type {
3058   my ($self, $data_type) = @_;
3059   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3060     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3061                                   |varchar|character\s*varying|nvarchar
3062                                   |national\s*character\s*varying))?\z/xi);
3063 }
3064
3065 sub _is_binary_lob_type {
3066   my ($self, $data_type) = @_;
3067   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3068     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3069 }
3070
3071 sub _is_text_lob_type {
3072   my ($self, $data_type) = @_;
3073   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3074     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3075                         |national\s*character\s*varying))\z/xi);
3076 }
3077
3078 # Determine if a data_type is some type of a binary type
3079 sub _is_binary_type {
3080   my ($self, $data_type) = @_;
3081   $data_type && ($self->_is_binary_lob_type($data_type)
3082     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3083 }
3084
3085 1;
3086
3087 =head1 USAGE NOTES
3088
3089 =head2 DBIx::Class and AutoCommit
3090
3091 DBIx::Class can do some wonderful magic with handling exceptions,
3092 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3093 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3094 transaction support.
3095
3096 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3097 in an assumed transaction between commits, and you're telling us you'd
3098 like to manage that manually.  A lot of the magic protections offered by
3099 this module will go away.  We can't protect you from exceptions due to database
3100 disconnects because we don't know anything about how to restart your
3101 transactions.  You're on your own for handling all sorts of exceptional
3102 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3103 be with raw DBI.
3104
3105
3106 =head1 AUTHOR AND CONTRIBUTORS
3107
3108 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3109
3110 =head1 LICENSE
3111
3112 You may distribute this code under the same terms as Perl itself.
3113
3114 =cut