lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Scalar::Util 'blessed';
  14
  15 __PACKAGE__->mk_group_accessors(
  16   'simple' =>
  17     qw/_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid _conn_tid
  18        disable_sth_caching cursor on_connect_do transaction_depth/
  19 );
  20
  21 BEGIN {
  22
  23 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  24
  25 use base qw/SQL::Abstract::Limit/;
  26
  27 # This prevents the caching of $dbh in S::A::L, I believe
  28 sub new {
  29   my $self = shift->SUPER::new(@_);
  30
  31   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  32   #   it with what it resolves to:
  33   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  34     if ref $self->{limit_dialect};
  35
  36   $self;
  37 }
  38
  39 sub _RowNumberOver {
  40   my ($self, $sql, $order, $rows, $offset ) = @_;
  41
  42   $offset += 1;
  43   my $last = $rows + $offset;
  44   my ( $order_by ) = $self->_order_by( $order );
  45
  46   $sql = <<"";
  47 SELECT * FROM
  48 (
  49    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  50       $sql
  51       $order_by
  52    ) Q1
  53 ) Q2
  54 WHERE ROW_NUM BETWEEN $offset AND $last
  55
  56   return $sql;
  57 }
  58
  59
  60 # While we're at it, this should make LIMIT queries more efficient,
  61 #  without digging into things too deeply
  62 use Scalar::Util 'blessed';
  63 sub _find_syntax {
  64   my ($self, $syntax) = @_;
  65   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  66   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  67     return 'RowNumberOver';
  68   }
  69
  70   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  71 }
  72
  73 sub select {
  74   my ($self, $table, $fields, $where, $order, @rest) = @_;
  75   $table = $self->_quote($table) unless ref($table);
  76   local $self->{rownum_hack_count} = 1
  77     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  78   @rest = (-1) unless defined $rest[0];
  79   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  80     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  81   local $self->{having_bind} = [];
  82   my ($sql, @ret) = $self->SUPER::select(
  83     $table, $self->_recurse_fields($fields), $where, $order, @rest
  84   );
  85   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  86 }
  87
  88 sub insert {
  89   my $self = shift;
  90   my $table = shift;
  91   $table = $self->_quote($table) unless ref($table);
  92   $self->SUPER::insert($table, @_);
  93 }
  94
  95 sub update {
  96   my $self = shift;
  97   my $table = shift;
  98   $table = $self->_quote($table) unless ref($table);
  99   $self->SUPER::update($table, @_);
 100 }
 101
 102 sub delete {
 103   my $self = shift;
 104   my $table = shift;
 105   $table = $self->_quote($table) unless ref($table);
 106   $self->SUPER::delete($table, @_);
 107 }
 108
 109 sub _emulate_limit {
 110   my $self = shift;
 111   if ($_[3] == -1) {
 112     return $_[1].$self->_order_by($_[2]);
 113   } else {
 114     return $self->SUPER::_emulate_limit(@_);
 115   }
 116 }
 117
 118 sub _recurse_fields {
 119   my ($self, $fields) = @_;
 120   my $ref = ref $fields;
 121   return $self->_quote($fields) unless $ref;
 122   return $$fields if $ref eq 'SCALAR';
 123
 124   if ($ref eq 'ARRAY') {
 125     return join(', ', map {
 126       $self->_recurse_fields($_)
 127       .(exists $self->{rownum_hack_count}
 128          ? ' AS col'.$self->{rownum_hack_count}++
 129          : '')
 130      } @$fields);
 131   } elsif ($ref eq 'HASH') {
 132     foreach my $func (keys %$fields) {
 133       return $self->_sqlcase($func)
 134         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 135     }
 136   }
 137 }
 138
 139 sub _order_by {
 140   my $self = shift;
 141   my $ret = '';
 142   my @extra;
 143   if (ref $_[0] eq 'HASH') {
 144     if (defined $_[0]->{group_by}) {
 145       $ret = $self->_sqlcase(' group by ')
 146                .$self->_recurse_fields($_[0]->{group_by});
 147     }
 148     if (defined $_[0]->{having}) {
 149       my $frag;
 150       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 151       push(@{$self->{having_bind}}, @extra);
 152       $ret .= $self->_sqlcase(' having ').$frag;
 153     }
 154     if (defined $_[0]->{order_by}) {
 155       $ret .= $self->_order_by($_[0]->{order_by});
 156     }
 157   } elsif (ref $_[0] eq 'SCALAR') {
 158     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 159   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 160     my @order = @{+shift};
 161     $ret = $self->_sqlcase(' order by ')
 162           .join(', ', map {
 163                         my $r = $self->_order_by($_, @_);
 164                         $r =~ s/^ ?ORDER BY //i;
 165                         $r;
 166                       } @order);
 167   } else {
 168     $ret = $self->SUPER::_order_by(@_);
 169   }
 170   return $ret;
 171 }
 172
 173 sub _order_directions {
 174   my ($self, $order) = @_;
 175   $order = $order->{order_by} if ref $order eq 'HASH';
 176   return $self->SUPER::_order_directions($order);
 177 }
 178
 179 sub _table {
 180   my ($self, $from) = @_;
 181   if (ref $from eq 'ARRAY') {
 182     return $self->_recurse_from(@$from);
 183   } elsif (ref $from eq 'HASH') {
 184     return $self->_make_as($from);
 185   } else {
 186     return $from; # would love to quote here but _table ends up getting called
 187                   # twice during an ->select without a limit clause due to
 188                   # the way S::A::Limit->select works. should maybe consider
 189                   # bypassing this and doing S::A::select($self, ...) in
 190                   # our select method above. meantime, quoting shims have
 191                   # been added to select/insert/update/delete here
 192   }
 193 }
 194
 195 sub _recurse_from {
 196   my ($self, $from, @join) = @_;
 197   my @sqlf;
 198   push(@sqlf, $self->_make_as($from));
 199   foreach my $j (@join) {
 200     my ($to, $on) = @$j;
 201
 202     # check whether a join type exists
 203     my $join_clause = '';
 204     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 205     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 206       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 207     } else {
 208       $join_clause = ' JOIN ';
 209     }
 210     push(@sqlf, $join_clause);
 211
 212     if (ref $to eq 'ARRAY') {
 213       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 214     } else {
 215       push(@sqlf, $self->_make_as($to));
 216     }
 217     push(@sqlf, ' ON ', $self->_join_condition($on));
 218   }
 219   return join('', @sqlf);
 220 }
 221
 222 sub _make_as {
 223   my ($self, $from) = @_;
 224   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 225                      reverse each %{$self->_skip_options($from)});
 226 }
 227
 228 sub _skip_options {
 229   my ($self, $hash) = @_;
 230   my $clean_hash = {};
 231   $clean_hash->{$_} = $hash->{$_}
 232     for grep {!/^-/} keys %$hash;
 233   return $clean_hash;
 234 }
 235
 236 sub _join_condition {
 237   my ($self, $cond) = @_;
 238   if (ref $cond eq 'HASH') {
 239     my %j;
 240     for (keys %$cond) {
 241       my $v = $cond->{$_};
 242       if (ref $v) {
 243         # XXX no throw_exception() in this package and croak() fails with strange results
 244         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 245             if ref($v) ne 'SCALAR';
 246         $j{$_} = $v;
 247       }
 248       else {
 249         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 250       }
 251     };
 252     return scalar($self->_recurse_where(\%j));
 253   } elsif (ref $cond eq 'ARRAY') {
 254     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 255   } else {
 256     die "Can't handle this yet!";
 257   }
 258 }
 259
 260 sub _quote {
 261   my ($self, $label) = @_;
 262   return '' unless defined $label;
 263   return "*" if $label eq '*';
 264   return $label unless $self->{quote_char};
 265   if(ref $self->{quote_char} eq "ARRAY"){
 266     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 267       if !defined $self->{name_sep};
 268     my $sep = $self->{name_sep};
 269     return join($self->{name_sep},
 270         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 271        split(/\Q$sep\E/,$label));
 272   }
 273   return $self->SUPER::_quote($label);
 274 }
 275
 276 sub limit_dialect {
 277     my $self = shift;
 278     $self->{limit_dialect} = shift if @_;
 279     return $self->{limit_dialect};
 280 }
 281
 282 sub quote_char {
 283     my $self = shift;
 284     $self->{quote_char} = shift if @_;
 285     return $self->{quote_char};
 286 }
 287
 288 sub name_sep {
 289     my $self = shift;
 290     $self->{name_sep} = shift if @_;
 291     return $self->{name_sep};
 292 }
 293
 294 } # End of BEGIN block
 295
 296 =head1 NAME
 297
 298 DBIx::Class::Storage::DBI - DBI storage handler
 299
 300 =head1 SYNOPSIS
 301
 302 =head1 DESCRIPTION
 303
 304 This class represents the connection to an RDBMS via L<DBI>.  See
 305 L<DBIx::Class::Storage> for general information.  This pod only
 306 documents DBI-specific methods and behaviors.
 307
 308 =head1 METHODS
 309
 310 =cut
 311
 312 sub new {
 313   my $new = shift->next::method(@_);
 314
 315   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.
 335
 336 In either case, if the final argument in your connect_info happens
 337 to be a hashref, C<connect_info> will look there for several
 338 connection-specific options:
 339
 340 =over 4
 341
 342 =item on_connect_do
 343
 344 This can be set to an arrayref of literal sql statements, which will
 345 be executed immediately after making the connection to the database
 346 every time we [re-]connect.
 347
 348 =item disable_sth_caching
 349
 350 If set to a true value, this option will disable the caching of
 351 statement handles via L<DBI/prepare_cached>.
 352
 353 =item limit_dialect
 354
 355 Sets the limit dialect. This is useful for JDBC-bridge among others
 356 where the remote SQL-dialect cannot be determined by the name of the
 357 driver alone.
 358
 359 =item quote_char
 360
 361 Specifies what characters to use to quote table and column names. If
 362 you use this you will want to specify L<name_sep> as well.
 363
 364 quote_char expects either a single character, in which case is it is placed
 365 on either side of the table/column, or an arrayref of length 2 in which case the
 366 table/column name is placed between the elements.
 367
 368 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 369 use C<quote_char =E<gt> [qw/[ ]/]>.
 370
 371 =item name_sep
 372
 373 This only needs to be used in conjunction with L<quote_char>, and is used to
 374 specify the charecter that seperates elements (schemas, tables, columns) from
 375 each other. In most cases this is simply a C<.>.
 376
 377 =back
 378
 379 These options can be mixed in with your other L<DBI> connection attributes,
 380 or placed in a seperate hashref after all other normal L<DBI> connection
 381 arguments.
 382
 383 Every time C<connect_info> is invoked, any previous settings for
 384 these options will be cleared before setting the new ones, regardless of
 385 whether any options are specified in the new C<connect_info>.
 386
 387 Important note:  DBIC expects the returned database handle provided by
 388 a subref argument to have RaiseError set on it.  If it doesn't, things
 389 might not work very well, YMMV.  If you don't use a subref, DBIC will
 390 force this setting for you anyways.  Setting HandleError to anything
 391 other than simple exception object wrapper might cause problems too.
 392
 393 Examples:
 394
 395   # Simple SQLite connection
 396   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 397
 398   # Connect via subref
 399   ->connect_info([ sub { DBI->connect(...) } ]);
 400
 401   # A bit more complicated
 402   ->connect_info(
 403     [
 404       'dbi:Pg:dbname=foo',
 405       'postgres',
 406       'my_pg_password',
 407       { AutoCommit => 0 },
 408       { quote_char => q{"}, name_sep => q{.} },
 409     ]
 410   );
 411
 412   # Equivalent to the previous example
 413   ->connect_info(
 414     [
 415       'dbi:Pg:dbname=foo',
 416       'postgres',
 417       'my_pg_password',
 418       { AutoCommit => 0, quote_char => q{"}, name_sep => q{.} },
 419     ]
 420   );
 421
 422   # Subref + DBIC-specific connection options
 423   ->connect_info(
 424     [
 425       sub { DBI->connect(...) },
 426       {
 427           quote_char => q{`},
 428           name_sep => q{@},
 429           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 430           disable_sth_caching => 1,
 431       },
 432     ]
 433   );
 434
 435 =cut
 436
 437 sub connect_info {
 438   my ($self, $info_arg) = @_;
 439
 440   return $self->_connect_info if !$info_arg;
 441
 442   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 443   #  the new set of options
 444   $self->_sql_maker(undef);
 445   $self->_sql_maker_opts({});
 446
 447   my $info = [ @$info_arg ]; # copy because we can alter it
 448   my $last_info = $info->[-1];
 449   if(ref $last_info eq 'HASH') {
 450     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 451       if(my $value = delete $last_info->{$storage_opt}) {
 452         $self->$storage_opt($value);
 453       }
 454     }
 455     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 456       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 457         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 458       }
 459     }
 460
 461     # Get rid of any trailing empty hashref
 462     pop(@$info) if !keys %$last_info;
 463   }
 464
 465   $self->_connect_info($info);
 466 }
 467
 468 =head2 on_connect_do
 469
 470 This method is deprecated in favor of setting via L</connect_info>.
 471
 472 =head2 dbh_do
 473
 474 Arguments: $subref, @extra_coderef_args?
 475
 476 Execute the given subref using the new exception-based connection management.
 477
 478 The first two arguments will be the storage object that C<dbh_do> was called
 479 on and a database handle to use.  Any additional arguments will be passed
 480 verbatim to the called subref as arguments 2 and onwards.
 481
 482 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 483 exception handling and reconnection (or failover in future subclasses).
 484
 485 Your subref should have no side-effects outside of the database, as
 486 there is the potential for your subref to be partially double-executed
 487 if the database connection was stale/dysfunctional.
 488
 489 Example:
 490
 491   my @stuff = $schema->storage->dbh_do(
 492     sub {
 493       my ($storage, $dbh, @cols) = @_;
 494       my $cols = join(q{, }, @cols);
 495       $dbh->selectrow_array("SELECT $cols FROM foo");
 496     },
 497     @column_list
 498   );
 499
 500 =cut
 501
 502 sub dbh_do {
 503   my $self = shift;
 504   my $coderef = shift;
 505
 506   ref $coderef eq 'CODE' or $self->throw_exception
 507     ('$coderef must be a CODE reference');
 508
 509   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do};
 510   local $self->{_in_dbh_do} = 1;
 511
 512   my @result;
 513   my $want_array = wantarray;
 514
 515   eval {
 516     $self->_verify_pid if $self->_dbh;
 517     $self->_populate_dbh if !$self->_dbh;
 518     if($want_array) {
 519         @result = $coderef->($self, $self->_dbh, @_);
 520     }
 521     elsif(defined $want_array) {
 522         $result[0] = $coderef->($self, $self->_dbh, @_);
 523     }
 524     else {
 525         $coderef->($self, $self->_dbh, @_);
 526     }
 527   };
 528
 529   my $exception = $@;
 530   if(!$exception) { return $want_array ? @result : $result[0] }
 531
 532   $self->throw_exception($exception) if $self->connected;
 533
 534   # We were not connected - reconnect and retry, but let any
 535   #  exception fall right through this time
 536   $self->_populate_dbh;
 537   $coderef->($self, $self->_dbh, @_);
 538 }
 539
 540 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 541 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 542 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 543 sub txn_do {
 544   my $self = shift;
 545   my $coderef = shift;
 546
 547   ref $coderef eq 'CODE' or $self->throw_exception
 548     ('$coderef must be a CODE reference');
 549
 550   local $self->{_in_dbh_do} = 1;
 551
 552   my @result;
 553   my $want_array = wantarray;
 554
 555   my $tried = 0;
 556   while(1) {
 557     eval {
 558       $self->_verify_pid if $self->_dbh;
 559       $self->_populate_dbh if !$self->_dbh;
 560
 561       $self->txn_begin;
 562       if($want_array) {
 563           @result = $coderef->(@_);
 564       }
 565       elsif(defined $want_array) {
 566           $result[0] = $coderef->(@_);
 567       }
 568       else {
 569           $coderef->(@_);
 570       }
 571       $self->txn_commit;
 572     };
 573
 574     my $exception = $@;
 575     if(!$exception) { return $want_array ? @result : $result[0] }
 576
 577     if($tried++ > 0 || $self->connected) {
 578       eval { $self->txn_rollback };
 579       my $rollback_exception = $@;
 580       if($rollback_exception) {
 581         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 582         $self->throw_exception($exception)  # propagate nested rollback
 583           if $rollback_exception =~ /$exception_class/;
 584
 585         $self->throw_exception(
 586           "Transaction aborted: ${exception}. "
 587           . "Rollback failed: ${rollback_exception}"
 588         );
 589       }
 590       $self->throw_exception($exception)
 591     }
 592
 593     # We were not connected, and was first try - reconnect and retry
 594     # via the while loop
 595     $self->_populate_dbh;
 596   }
 597 }
 598
 599 =head2 disconnect
 600
 601 Our C<disconnect> method also performs a rollback first if the
 602 database is not in C<AutoCommit> mode.
 603
 604 =cut
 605
 606 sub disconnect {
 607   my ($self) = @_;
 608
 609   if( $self->connected ) {
 610     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 611     $self->_dbh->disconnect;
 612     $self->_dbh(undef);
 613     $self->{_dbh_gen}++;
 614   }
 615 }
 616
 617 sub connected {
 618   my ($self) = @_;
 619
 620   if(my $dbh = $self->_dbh) {
 621       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 622           $self->_dbh(undef);
 623           $self->{_dbh_gen}++;
 624           return;
 625       }
 626       else {
 627           $self->_verify_pid;
 628       }
 629       return ($dbh->FETCH('Active') && $dbh->ping);
 630   }
 631
 632   return 0;
 633 }
 634
 635 # handle pid changes correctly
 636 #  NOTE: assumes $self->_dbh is a valid $dbh
 637 sub _verify_pid {
 638   my ($self) = @_;
 639
 640   return if $self->_conn_pid == $$;
 641
 642   $self->_dbh->{InactiveDestroy} = 1;
 643   $self->_dbh(undef);
 644   $self->{_dbh_gen}++;
 645
 646   return;
 647 }
 648
 649 sub ensure_connected {
 650   my ($self) = @_;
 651
 652   unless ($self->connected) {
 653     $self->_populate_dbh;
 654   }
 655 }
 656
 657 =head2 dbh
 658
 659 Returns the dbh - a data base handle of class L<DBI>.
 660
 661 =cut
 662
 663 sub dbh {
 664   my ($self) = @_;
 665
 666   $self->ensure_connected;
 667   return $self->_dbh;
 668 }
 669
 670 sub _sql_maker_args {
 671     my ($self) = @_;
 672
 673     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 674 }
 675
 676 sub sql_maker {
 677   my ($self) = @_;
 678   unless ($self->_sql_maker) {
 679     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 680   }
 681   return $self->_sql_maker;
 682 }
 683
 684 sub _populate_dbh {
 685   my ($self) = @_;
 686   my @info = @{$self->_connect_info || []};
 687   $self->_dbh($self->_connect(@info));
 688
 689   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 690     my $driver = $self->_dbh->{Driver}->{Name};
 691     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 692       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 693       $self->_rebless() if $self->can('_rebless');
 694     }
 695   }
 696
 697   # if on-connect sql statements are given execute them
 698   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 699     $self->debugobj->query_start($sql_statement) if $self->debug();
 700     $self->_dbh->do($sql_statement);
 701     $self->debugobj->query_end($sql_statement) if $self->debug();
 702   }
 703
 704   $self->_conn_pid($$);
 705   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 706 }
 707
 708 sub _connect {
 709   my ($self, @info) = @_;
 710
 711   $self->throw_exception("You failed to provide any connection info")
 712       if !@info;
 713
 714   my ($old_connect_via, $dbh);
 715
 716   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 717       $old_connect_via = $DBI::connect_via;
 718       $DBI::connect_via = 'connect';
 719   }
 720
 721   eval {
 722     if(ref $info[0] eq 'CODE') {
 723        $dbh = &{$info[0]}
 724     }
 725     else {
 726        $dbh = DBI->connect(@info);
 727        $dbh->{RaiseError} = 1;
 728        $dbh->{PrintError} = 0;
 729        $dbh->{PrintWarn} = 0;
 730     }
 731   };
 732
 733   $DBI::connect_via = $old_connect_via if $old_connect_via;
 734
 735   if (!$dbh || $@) {
 736     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 737   }
 738
 739   $dbh;
 740 }
 741
 742 sub _dbh_txn_begin {
 743   my ($self, $dbh) = @_;
 744   if ($dbh->{AutoCommit}) {
 745     $self->debugobj->txn_begin()
 746       if ($self->debug);
 747     $dbh->begin_work;
 748   }
 749 }
 750
 751 sub txn_begin {
 752   my $self = shift;
 753   $self->dbh_do($self->can('_dbh_txn_begin'))
 754     if $self->{transaction_depth}++ == 0;
 755 }
 756
 757 sub _dbh_txn_commit {
 758   my ($self, $dbh) = @_;
 759   if ($self->{transaction_depth} == 0) {
 760     unless ($dbh->{AutoCommit}) {
 761       $self->debugobj->txn_commit()
 762         if ($self->debug);
 763       $dbh->commit;
 764     }
 765   }
 766   else {
 767     if (--$self->{transaction_depth} == 0) {
 768       $self->debugobj->txn_commit()
 769         if ($self->debug);
 770       $dbh->commit;
 771     }
 772   }
 773 }
 774
 775 sub txn_commit {
 776   my $self = shift;
 777   $self->dbh_do($self->can('_dbh_txn_commit'));
 778 }
 779
 780 sub _dbh_txn_rollback {
 781   my ($self, $dbh) = @_;
 782   if ($self->{transaction_depth} == 0) {
 783     unless ($dbh->{AutoCommit}) {
 784       $self->debugobj->txn_rollback()
 785         if ($self->debug);
 786       $dbh->rollback;
 787     }
 788   }
 789   else {
 790     if (--$self->{transaction_depth} == 0) {
 791       $self->debugobj->txn_rollback()
 792         if ($self->debug);
 793       $dbh->rollback;
 794     }
 795     else {
 796       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 797     }
 798   }
 799 }
 800
 801 sub txn_rollback {
 802   my $self = shift;
 803
 804   eval { $self->dbh_do($self->can('_dbh_txn_rollback')) };
 805   if ($@) {
 806     my $error = $@;
 807     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 808     $error =~ /$exception_class/ and $self->throw_exception($error);
 809     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 810     $self->throw_exception($error);          # resets the transaction depth
 811   }
 812 }
 813
 814 # This used to be the top-half of _execute.  It was split out to make it
 815 #  easier to override in NoBindVars without duping the rest.  It takes up
 816 #  all of _execute's args, and emits $sql, @bind.
 817 sub _prep_for_execute {
 818   my ($self, $op, $extra_bind, $ident, @args) = @_;
 819
 820   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 821   unshift(@bind,
 822     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 823       if $extra_bind;
 824   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 825
 826   return ($sql, @bind);
 827 }
 828
 829 sub _execute {
 830   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 831
 832   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") )
 833   {
 834     $ident = $ident->from();
 835   }
 836
 837   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 838   unshift(@bind,
 839     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 840       if $extra_bind;
 841   if ($self->debug) {
 842       my @debug_bind =
 843         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 844       $self->debugobj->query_start($sql, @debug_bind);
 845   }
 846   my $sth = eval { $self->sth($sql,$op) };
 847
 848   if (!$sth || $@) {
 849     $self->throw_exception(
 850       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 851     );
 852   }
 853
 854   my $rv;
 855   if ($sth) {
 856     my $time = time();
 857
 858     $rv = eval {
 859
 860       my $placeholder_index = 1;
 861
 862       foreach my $bound (@bind) {
 863
 864         my $attributes = {};
 865         my($column_name, @data) = @$bound;
 866
 867         if( $bind_attributes ) {
 868           $attributes = $bind_attributes->{$column_name}
 869           if defined $bind_attributes->{$column_name};
 870         }
 871
 872                 foreach my $data (@data)
 873                 {
 874           $data = ref $data ? ''.$data : $data; # stringify args
 875
 876           $sth->bind_param($placeholder_index, $data, $attributes);
 877           $placeholder_index++;
 878                 }
 879       }
 880       $sth->execute();
 881     };
 882
 883     if ($@ || !$rv) {
 884       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 885     }
 886   } else {
 887     $self->throw_exception("'$sql' did not generate a statement.");
 888   }
 889   if ($self->debug) {
 890      my @debug_bind =
 891        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 892      $self->debugobj->query_end($sql, @debug_bind);
 893   }
 894   return (wantarray ? ($rv, $sth, @bind) : $rv);
 895 }
 896
 897 sub insert {
 898   my ($self, $source, $to_insert) = @_;
 899
 900   my $ident = $source->from;
 901   my $bind_attributes = $self->source_bind_attributes($source);
 902
 903   $self->throw_exception(
 904     "Couldn't insert ".join(', ',
 905       map "$_ => $to_insert->{$_}", keys %$to_insert
 906     )." into ${ident}"
 907   ) unless ($self->_execute('insert' => [], $source, $bind_attributes, $to_insert));
 908   return $to_insert;
 909 }
 910
 911 ## Still not quite perfect, and EXPERIMENTAL
 912 ## Currently it is assumed that all values passed will be "normal", i.e. not
 913 ## scalar refs, or at least, all the same type as the first set, the statement is
 914 ## only prepped once.
 915 sub insert_bulk {
 916   my ($self, $source, $cols, $data) = @_;
 917   my %colvalues;
 918   my $table = $source->from;
 919   @colvalues{@$cols} = (0..$#$cols);
 920   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 921
 922   if ($self->debug) {
 923       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 924       $self->debugobj->query_start($sql, @debug_bind);
 925   }
 926   my $sth = $self->sth($sql);
 927
 928 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 929
 930   my $rv;
 931
 932   ## This must be an arrayref, else nothing works!
 933
 934   my $tuple_status = [];
 935
 936   ##use Data::Dumper;
 937   ##print STDERR Dumper( $data, $sql, [@bind] );
 938
 939   if ($sth) {
 940
 941     my $time = time();
 942
 943     #$rv = eval {
 944         #
 945         #  $sth->execute_array({
 946
 947         #    ArrayTupleFetch => sub {
 948
 949         #      my $values = shift @$data;
 950     #      return if !$values;
 951     #      return [ @{$values}[@bind] ];
 952         #    },
 953
 954         #    ArrayTupleStatus => $tuple_status,
 955         #  })
 956     #};
 957
 958         ## Get the bind_attributes, if any exist
 959     my $bind_attributes = $self->source_bind_attributes($source);
 960
 961         ## Bind the values and execute
 962         $rv = eval {
 963
 964      my $placeholder_index = 1;
 965
 966         foreach my $bound (@bind) {
 967
 968           my $attributes = {};
 969           my ($column_name, $data_index) = @$bound;
 970
 971           if( $bind_attributes ) {
 972             $attributes = $bind_attributes->{$column_name}
 973             if defined $bind_attributes->{$column_name};
 974           }
 975
 976                   my @data = map { $_->[$data_index] } @$data;
 977
 978           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 979           $placeholder_index++;
 980       }
 981           $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
 982
 983         };
 984
 985     if ($@ || !defined $rv) {
 986       my $errors = '';
 987       foreach my $tuple (@$tuple_status)
 988       {
 989           $errors .= "\n" . $tuple->[1] if(ref $tuple);
 990       }
 991       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
 992     }
 993   } else {
 994     $self->throw_exception("'$sql' did not generate a statement.");
 995   }
 996   if ($self->debug) {
 997       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 998       $self->debugobj->query_end($sql, @debug_bind);
 999   }
1000   return (wantarray ? ($rv, $sth, @bind) : $rv);
1001 }
1002
1003 sub update {
1004   my $self = shift @_;
1005   my $source = shift @_;
1006   my $bind_attributes = $self->source_bind_attributes($source);
1007
1008   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1009 }
1010
1011
1012 sub delete {
1013   my $self = shift @_;
1014   my $source = shift @_;
1015
1016   my $bind_attrs = {}; ## If ever it's needed...
1017
1018   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1019 }
1020
1021 sub _select {
1022   my ($self, $ident, $select, $condition, $attrs) = @_;
1023   my $order = $attrs->{order_by};
1024   if (ref $condition eq 'SCALAR') {
1025     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1026   }
1027   if (exists $attrs->{group_by} || $attrs->{having}) {
1028     $order = {
1029       group_by => $attrs->{group_by},
1030       having => $attrs->{having},
1031       ($order ? (order_by => $order) : ())
1032     };
1033   }
1034   my $bind_attrs = {}; ## Future support
1035   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1036   if ($attrs->{software_limit} ||
1037       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1038         $attrs->{software_limit} = 1;
1039   } else {
1040     $self->throw_exception("rows attribute must be positive if present")
1041       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1042     push @args, $attrs->{rows}, $attrs->{offset};
1043   }
1044   return $self->_execute(@args);
1045 }
1046
1047 sub source_bind_attributes {
1048   my ($self, $source) = @_;
1049
1050   my $bind_attributes;
1051   foreach my $column ($source->columns) {
1052
1053     my $data_type = $source->column_info($column)->{data_type} || '';
1054     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1055          if $data_type;
1056   }
1057
1058   return $bind_attributes;
1059 }
1060
1061 =head2 select
1062
1063 =over 4
1064
1065 =item Arguments: $ident, $select, $condition, $attrs
1066
1067 =back
1068
1069 Handle a SQL select statement.
1070
1071 =cut
1072
1073 sub select {
1074   my $self = shift;
1075   my ($ident, $select, $condition, $attrs) = @_;
1076   return $self->cursor->new($self, \@_, $attrs);
1077 }
1078
1079 sub select_single {
1080   my $self = shift;
1081   my ($rv, $sth, @bind) = $self->_select(@_);
1082   my @row = $sth->fetchrow_array;
1083   # Need to call finish() to work round broken DBDs
1084   $sth->finish();
1085   return @row;
1086 }
1087
1088 =head2 sth
1089
1090 =over 4
1091
1092 =item Arguments: $sql
1093
1094 =back
1095
1096 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1097
1098 =cut
1099
1100 sub _dbh_sth {
1101   my ($self, $dbh, $sql) = @_;
1102
1103   # 3 is the if_active parameter which avoids active sth re-use
1104   my $sth = $self->disable_sth_caching
1105     ? $dbh->prepare($sql)
1106     : $dbh->prepare_cached($sql, {}, 3);
1107
1108   $self->throw_exception(
1109     'no sth generated via sql (' . ($@ || $dbh->errstr) . "): $sql"
1110   ) if !$sth;
1111
1112   $sth;
1113 }
1114
1115 sub sth {
1116   my ($self, $sql) = @_;
1117   $self->dbh_do($self->can('_dbh_sth'), $sql);
1118 }
1119
1120 sub _dbh_columns_info_for {
1121   my ($self, $dbh, $table) = @_;
1122
1123   if ($dbh->can('column_info')) {
1124     my %result;
1125     eval {
1126       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1127       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1128       $sth->execute();
1129       while ( my $info = $sth->fetchrow_hashref() ){
1130         my %column_info;
1131         $column_info{data_type}   = $info->{TYPE_NAME};
1132         $column_info{size}      = $info->{COLUMN_SIZE};
1133         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1134         $column_info{default_value} = $info->{COLUMN_DEF};
1135         my $col_name = $info->{COLUMN_NAME};
1136         $col_name =~ s/^\"(.*)\"$/$1/;
1137
1138         $result{$col_name} = \%column_info;
1139       }
1140     };
1141     return \%result if !$@ && scalar keys %result;
1142   }
1143
1144   my %result;
1145   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
1146   $sth->execute;
1147   my @columns = @{$sth->{NAME_lc}};
1148   for my $i ( 0 .. $#columns ){
1149     my %column_info;
1150     my $type_num = $sth->{TYPE}->[$i];
1151     my $type_name;
1152     if(defined $type_num && $dbh->can('type_info')) {
1153       my $type_info = $dbh->type_info($type_num);
1154       $type_name = $type_info->{TYPE_NAME} if $type_info;
1155     }
1156     $column_info{data_type} = $type_name ? $type_name : $type_num;
1157     $column_info{size} = $sth->{PRECISION}->[$i];
1158     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1159
1160     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1161       $column_info{data_type} = $1;
1162       $column_info{size}    = $2;
1163     }
1164
1165     $result{$columns[$i]} = \%column_info;
1166   }
1167
1168   return \%result;
1169 }
1170
1171 sub columns_info_for {
1172   my ($self, $table) = @_;
1173   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1174 }
1175
1176 =head2 last_insert_id
1177
1178 Return the row id of the last insert.
1179
1180 =cut
1181
1182 sub _dbh_last_insert_id {
1183     my ($self, $dbh, $source, $col) = @_;
1184     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1185     $dbh->func('last_insert_rowid');
1186 }
1187
1188 sub last_insert_id {
1189   my $self = shift;
1190   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1191 }
1192
1193 =head2 sqlt_type
1194
1195 Returns the database driver name.
1196
1197 =cut
1198
1199 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1200
1201 =head2 bind_attribute_by_data_type
1202
1203 Given a datatype from column info, returns a database specific bind attribute for
1204 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1205 just handle it.
1206
1207 Generally only needed for special case column types, like bytea in postgres.
1208
1209 =cut
1210
1211 sub bind_attribute_by_data_type {
1212     return;
1213 }
1214
1215 =head2 create_ddl_dir (EXPERIMENTAL)
1216
1217 =over 4
1218
1219 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1220
1221 =back
1222
1223 Creates a SQL file based on the Schema, for each of the specified
1224 database types, in the given directory.
1225
1226 Note that this feature is currently EXPERIMENTAL and may not work correctly
1227 across all databases, or fully handle complex relationships.
1228
1229 =cut
1230
1231 sub create_ddl_dir
1232 {
1233   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1234
1235   if(!$dir || !-d $dir)
1236   {
1237     warn "No directory given, using ./\n";
1238     $dir = "./";
1239   }
1240   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1241   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1242   $version ||= $schema->VERSION || '1.x';
1243   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1244
1245   eval "use SQL::Translator";
1246   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1247
1248   my $sqlt = SQL::Translator->new({
1249 #      debug => 1,
1250       add_drop_table => 1,
1251   });
1252   foreach my $db (@$databases)
1253   {
1254     $sqlt->reset();
1255     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1256 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1257     $sqlt = $self->configure_sqlt($sqlt, $db);
1258     $sqlt->data($schema);
1259     $sqlt->producer($db);
1260
1261     my $file;
1262     my $filename = $schema->ddl_filename($db, $dir, $version);
1263     if(-e $filename)
1264     {
1265       warn("$filename already exists, skipping $db");
1266       next;
1267     }
1268
1269     my $output = $sqlt->translate;
1270     if(!$output)
1271     {
1272       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1273       next;
1274     }
1275     if(!open($file, ">$filename"))
1276     {
1277         $self->throw_exception("Can't open $filename for writing ($!)");
1278         next;
1279     }
1280     print $file $output;
1281     close($file);
1282
1283     if($preversion)
1284     {
1285       eval "use SQL::Translator::Diff";
1286       if($@)
1287       {
1288         warn("Can't diff versions without SQL::Translator::Diff: $@");
1289         next;
1290       }
1291
1292       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1293 #      print "Previous version $prefilename\n";
1294       if(!-e $prefilename)
1295       {
1296         warn("No previous schema file found ($prefilename)");
1297         next;
1298       }
1299       #### We need to reparse the SQLite file we just wrote, so that
1300       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1301       ##   FIXME: rip Diff to pieces!
1302 #      my $target_schema = $sqlt->schema;
1303 #      unless ( $target_schema->name ) {
1304 #        $target_schema->name( $filename );
1305 #      }
1306       my @input;
1307       push @input, {file => $prefilename, parser => $db};
1308       push @input, {file => $filename, parser => $db};
1309       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1310         my $file   = $_->{'file'};
1311         my $parser = $_->{'parser'};
1312
1313         my $t = SQL::Translator->new;
1314         $t->debug( 0 );
1315         $t->trace( 0 );
1316         $t->parser( $parser )            or die $t->error;
1317         my $out = $t->translate( $file ) or die $t->error;
1318         my $schema = $t->schema;
1319         unless ( $schema->name ) {
1320           $schema->name( $file );
1321         }
1322         ($schema, $parser);
1323       } @input;
1324
1325       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1326                                                     $target_schema, $db,
1327                                                     {}
1328                                                    );
1329       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1330       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1331       if(-e $difffile)
1332       {
1333         warn("$difffile already exists, skipping");
1334         next;
1335       }
1336       if(!open $file, ">$difffile")
1337       {
1338         $self->throw_exception("Can't write to $difffile ($!)");
1339         next;
1340       }
1341       print $file $diff;
1342       close($file);
1343     }
1344   }
1345 }
1346
1347 sub configure_sqlt() {
1348   my $self = shift;
1349   my $tr = shift;
1350   my $db = shift || $self->sqlt_type;
1351   if ($db eq 'PostgreSQL') {
1352     $tr->quote_table_names(0);
1353     $tr->quote_field_names(0);
1354   }
1355   return $tr;
1356 }
1357
1358 =head2 deployment_statements
1359
1360 =over 4
1361
1362 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1363
1364 =back
1365
1366 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1367 The database driver name is given by C<$type>, though the value from
1368 L</sqlt_type> is used if it is not specified.
1369
1370 C<$directory> is used to return statements from files in a previously created
1371 L</create_ddl_dir> directory and is optional. The filenames are constructed
1372 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1373
1374 If no C<$directory> is specified then the statements are constructed on the
1375 fly using L<SQL::Translator> and C<$version> is ignored.
1376
1377 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1378
1379 =cut
1380
1381 sub deployment_statements {
1382   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1383   # Need to be connected to get the correct sqlt_type
1384   $self->ensure_connected() unless $type;
1385   $type ||= $self->sqlt_type;
1386   $version ||= $schema->VERSION || '1.x';
1387   $dir ||= './';
1388   my $filename = $schema->ddl_filename($type, $dir, $version);
1389   if(-f $filename)
1390   {
1391       my $file;
1392       open($file, "<$filename")
1393         or $self->throw_exception("Can't open $filename ($!)");
1394       my @rows = <$file>;
1395       close($file);
1396       return join('', @rows);
1397   }
1398
1399   eval "use SQL::Translator";
1400   if(!$@)
1401   {
1402     eval "use SQL::Translator::Parser::DBIx::Class;";
1403     $self->throw_exception($@) if $@;
1404     eval "use SQL::Translator::Producer::${type};";
1405     $self->throw_exception($@) if $@;
1406
1407     # sources needs to be a parser arg, but for simplicty allow at top level
1408     # coming in
1409     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1410         if exists $sqltargs->{sources};
1411
1412     my $tr = SQL::Translator->new(%$sqltargs);
1413     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1414     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1415   }
1416
1417   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1418   return;
1419
1420 }
1421
1422 sub deploy {
1423   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1424   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1425     for ( split(";\n", $statement)) {
1426       next if($_ =~ /^--/);
1427       next if(!$_);
1428 #      next if($_ =~ /^DROP/m);
1429       next if($_ =~ /^BEGIN TRANSACTION/m);
1430       next if($_ =~ /^COMMIT/m);
1431       next if $_ =~ /^\s+$/; # skip whitespace only
1432       $self->debugobj->query_start($_) if $self->debug;
1433       $self->dbh->do($_) or warn "SQL was:\n $_"; # XXX exceptions?
1434       $self->debugobj->query_end($_) if $self->debug;
1435     }
1436   }
1437 }
1438
1439 =head2 datetime_parser
1440
1441 Returns the datetime parser class
1442
1443 =cut
1444
1445 sub datetime_parser {
1446   my $self = shift;
1447   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1448 }
1449
1450 =head2 datetime_parser_type
1451
1452 Defines (returns) the datetime parser class - currently hardwired to
1453 L<DateTime::Format::MySQL>
1454
1455 =cut
1456
1457 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1458
1459 =head2 build_datetime_parser
1460
1461 See L</datetime_parser>
1462
1463 =cut
1464
1465 sub build_datetime_parser {
1466   my $self = shift;
1467   my $type = $self->datetime_parser_type(@_);
1468   eval "use ${type}";
1469   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1470   return $type;
1471 }
1472
1473 sub DESTROY {
1474   my $self = shift;
1475   return if !$self->_dbh;
1476   $self->_verify_pid;
1477   $self->_dbh(undef);
1478 }
1479
1480 1;
1481
1482 =head1 SQL METHODS
1483
1484 The module defines a set of methods within the DBIC::SQL::Abstract
1485 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1486 SQL query functions.
1487
1488 The following methods are extended:-
1489
1490 =over 4
1491
1492 =item delete
1493
1494 =item insert
1495
1496 =item select
1497
1498 =item update
1499
1500 =item limit_dialect
1501
1502 See L</connect_info> for details.
1503 For setting, this method is deprecated in favor of L</connect_info>.
1504
1505 =item quote_char
1506
1507 See L</connect_info> for details.
1508 For setting, this method is deprecated in favor of L</connect_info>.
1509
1510 =item name_sep
1511
1512 See L</connect_info> for details.
1513 For setting, this method is deprecated in favor of L</connect_info>.
1514
1515 =back
1516
1517 =head1 AUTHORS
1518
1519 Matt S. Trout <mst@shadowcatsystems.co.uk>
1520
1521 Andy Grundman <andy@hybridized.org>
1522
1523 =head1 LICENSE
1524
1525 You may distribute this code under the same terms as Perl itself.
1526
1527 =cut