lib/DBIx/Class/Serialize/Storable.pm

   1 package DBIx::Class::Serialize::Storable;
   2 use strict;
   3 use warnings;
   4 use Storable;
   5
   6 sub STORABLE_freeze {
   7     my ($self, $cloning) = @_;
   8     my $to_serialize = { %$self };
   9
  10     delete $to_serialize->{result_source};
  11     delete $to_serialize->{related_resultsets};
  12     delete $to_serialize->{_inflated_column};
  13
  14     return('', $to_serialize);
  15 }
  16
  17 sub STORABLE_thaw {
  18     my ($self, $cloning, $junk, $obj) = @_;
  19
  20     %$self = %{ $obj };
  21     $self->result_source($self->result_source_instance)
  22       if $self->can('result_source_instance');
  23 }
  24
  25 1;
  26
  27 __END__
  28
  29 =head1 NAME
  30
  31     DBIx::Class::Serialize::Storable - hooks for Storable freeze/thaw
  32
  33 =head1 SYNOPSIS
  34
  35     # in a table class definition
  36     __PACKAGE__->load_components(qw/Serialize::Storable/);
  37
  38     # meanwhile, in a nearby piece of code
  39     my $cd = $schema->resultset('CD')->find(12);
  40     # if the cache uses Storable, this will work automatically
  41     $cache->set($cd->ID, $cd);
  42
  43 =head1 DESCRIPTION
  44
  45 This component adds hooks for Storable so that row objects can be
  46 serialized. It assumes that your row object class (C<result_class>) is
  47 the same as your table class, which is the normal situation.
  48
  49 =head1 HOOKS
  50
  51 The following hooks are defined for L<Storable> - see the
  52 documentation for L<Storable/Hooks> for detailed information on these
  53 hooks.
  54
  55 =head2 STORABLE_freeze
  56
  57 The serializing hook, called on the object during serialization. It
  58 can be inherited, or defined in the class itself, like any other
  59 method.
  60
  61 =head2 STORABLE_thaw
  62
  63 The deserializing hook called on the object during deserialization.
  64
  65 =head1 AUTHORS
  66
  67 David Kamholz <dkamholz@cpan.org>
  68
  69 =head1 LICENSE
  70
  71 You may distribute this code under the same terms as Perl itself.
  72
  73 =cut