lib/DBIx/Class/Schema/Versioned.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::Version::Table;
   3 use base 'DBIx::Class::Core';
   4 use strict;
   5 use warnings;
   6
   7 __PACKAGE__->table('dbix_class_schema_versions');
   8
   9 __PACKAGE__->add_columns
  10     ( 'version' => {
  11         'data_type' => 'VARCHAR',
  12         'is_auto_increment' => 0,
  13         'default_value' => undef,
  14         'is_foreign_key' => 0,
  15         'name' => 'version',
  16         'is_nullable' => 0,
  17         'size' => '10'
  18         },
  19       'installed' => {
  20           'data_type' => 'VARCHAR',
  21           'is_auto_increment' => 0,
  22           'default_value' => undef,
  23           'is_foreign_key' => 0,
  24           'name' => 'installed',
  25           'is_nullable' => 0,
  26           'size' => '20'
  27           },
  28       );
  29 __PACKAGE__->set_primary_key('version');
  30
  31 package # Hide from PAUSE
  32   DBIx::Class::Version::TableCompat;
  33 use base 'DBIx::Class::Core';
  34 __PACKAGE__->table('SchemaVersions');
  35
  36 __PACKAGE__->add_columns
  37     ( 'Version' => {
  38         'data_type' => 'VARCHAR',
  39         },
  40       'Installed' => {
  41           'data_type' => 'VARCHAR',
  42           },
  43       );
  44 __PACKAGE__->set_primary_key('Version');
  45
  46 package # Hide from PAUSE
  47   DBIx::Class::Version;
  48 use base 'DBIx::Class::Schema';
  49 use strict;
  50 use warnings;
  51
  52 __PACKAGE__->register_class('Table', 'DBIx::Class::Version::Table');
  53
  54 package # Hide from PAUSE
  55   DBIx::Class::VersionCompat;
  56 use base 'DBIx::Class::Schema';
  57 use strict;
  58 use warnings;
  59
  60 __PACKAGE__->register_class('TableCompat', 'DBIx::Class::Version::TableCompat');
  61
  62
  63 # ---------------------------------------------------------------------------
  64
  65 =head1 NAME
  66
  67 DBIx::Class::Schema::Versioned - DBIx::Class::Schema plugin for Schema upgrades
  68
  69 =head1 SYNOPSIS
  70
  71   package MyApp::Schema;
  72   use base qw/DBIx::Class::Schema/;
  73
  74   our $VERSION = 0.001;
  75
  76   # load MyApp::Schema::CD, MyApp::Schema::Book, MyApp::Schema::DVD
  77   __PACKAGE__->load_classes(qw/CD Book DVD/);
  78
  79   __PACKAGE__->load_components(qw/Schema::Versioned/);
  80   __PACKAGE__->upgrade_directory('/path/to/upgrades/');
  81
  82
  83 =head1 DESCRIPTION
  84
  85 This module provides methods to apply DDL changes to your database using SQL
  86 diff files. Normally these diff files would be created using
  87 L<DBIx::Class::Schema/create_ddl_dir>.
  88
  89 A table called I<dbix_class_schema_versions> is created and maintained by the
  90 module. This is used to determine which version your database is currently at.
  91 Similarly the $VERSION in your DBIC schema class is used to determine the
  92 current DBIC schema version.
  93
  94 The upgrade is initiated manually by calling C<upgrade> on your schema object,
  95 this will attempt to upgrade the database from its current version to the current
  96 schema version using a diff from your I<upgrade_directory>. If a suitable diff is
  97 not found then no upgrade is possible.
  98
  99 NB: At the moment, only SQLite and MySQL are supported. This is due to
 100 spotty behaviour in the SQL::Translator producers, please help us by
 101 enhancing them. Ask on the mailing list or IRC channel for details (community details
 102 in L<DBIx::Class>).
 103
 104 =head1 GETTING STARTED
 105
 106 Firstly you need to setup your schema class as per the L</SYNOPSIS>, make sure
 107 you have specified an upgrade_directory and an initial $VERSION.
 108
 109 Then you'll need two scripts, one to create DDL files and diffs and another to perform
 110 upgrades. Your creation script might look like a bit like this:
 111
 112   use strict;
 113   use Pod::Usage;
 114   use Getopt::Long;
 115   use MyApp::Schema;
 116
 117   my ( $preversion, $help );
 118   GetOptions(
 119     'p|preversion:s'  => \$preversion,
 120   ) or die pod2usage;
 121
 122   my $schema = MyApp::Schema->connect(
 123     $dsn,
 124     $user,
 125     $password,
 126   );
 127   my $sql_dir = './sql';
 128   my $version = $schema->schema_version();
 129   $schema->create_ddl_dir( 'MySQL', $version, $sql_dir, $preversion );
 130
 131 Then your upgrade script might look like so:
 132
 133   use strict;
 134   use MyApp::Schema;
 135
 136   my $schema = MyApp::Schema->connect(
 137     $dsn,
 138     $user,
 139     $password,
 140   );
 141
 142   if (!$schema->get_db_version()) {
 143     # schema is unversioned
 144     $schema->deploy();
 145   } else {
 146     $schema->upgrade();
 147   }
 148
 149 The script above assumes that if the database is unversioned then it is empty
 150 and we can safely deploy the DDL to it. However things are not always so simple.
 151
 152 if you want to initialise a pre-existing database where the DDL is not the same
 153 as the DDL for your current schema version then you will need a diff which
 154 converts the database's DDL to the current DDL. The best way to do this is
 155 to get a dump of the database schema (without data) and save that in your
 156 SQL directory as version 0.000 (the filename must be as with
 157 L<DBIx::Class::Schema/ddl_filename>) then create a diff using your create DDL
 158 script given above from version 0.000 to the current version. Then hand check
 159 and if necessary edit the resulting diff to ensure that it will apply. Once you have
 160 done all that you can do this:
 161
 162   if (!$schema->get_db_version()) {
 163     # schema is unversioned
 164     $schema->install("0.000");
 165   }
 166
 167   # this will now apply the 0.000 to current version diff
 168   $schema->upgrade();
 169
 170 In the case of an unversioned database the above code will create the
 171 dbix_class_schema_versions table and write version 0.000 to it, then
 172 upgrade will then apply the diff we talked about creating in the previous paragraph
 173 and then you're good to go.
 174
 175 =cut
 176
 177 package DBIx::Class::Schema::Versioned;
 178
 179 use strict;
 180 use warnings;
 181 use base 'DBIx::Class::Schema';
 182
 183 use Carp::Clan qw/^DBIx::Class/;
 184 use Time::HiRes qw/gettimeofday/;
 185
 186 __PACKAGE__->mk_classdata('_filedata');
 187 __PACKAGE__->mk_classdata('upgrade_directory');
 188 __PACKAGE__->mk_classdata('backup_directory');
 189 __PACKAGE__->mk_classdata('do_backup');
 190 __PACKAGE__->mk_classdata('do_diff_on_init');
 191
 192
 193 =head1 METHODS
 194
 195 =head2 upgrade_directory
 196
 197 Use this to set the directory your upgrade files are stored in.
 198
 199 =head2 backup_directory
 200
 201 Use this to set the directory you want your backups stored in (note that backups
 202 are disabled by default).
 203
 204 =cut
 205
 206 =head2 install
 207
 208 =over 4
 209
 210 =item Arguments: $db_version
 211
 212 =back
 213
 214 Call this to initialise a previously unversioned database. The table 'dbix_class_schema_versions' will be created which will be used to store the database version.
 215
 216 Takes one argument which should be the version that the database is currently at. Defaults to the return value of L</schema_version>.
 217
 218 See L</getting_started> for more details.
 219
 220 =cut
 221
 222 sub install
 223 {
 224   my ($self, $new_version) = @_;
 225
 226   # must be called on a fresh database
 227   if ($self->get_db_version()) {
 228     carp 'Install not possible as versions table already exists in database';
 229   }
 230
 231   # default to current version if none passed
 232   $new_version ||= $self->schema_version();
 233
 234   if ($new_version) {
 235     # create versions table and version row
 236     $self->{vschema}->deploy;
 237     $self->_set_db_version({ version => $new_version });
 238   }
 239 }
 240
 241 =head2 deploy
 242
 243 Same as L<DBIx::Class::Schema/deploy> but also calls C<install>.
 244
 245 =cut
 246
 247 sub deploy {
 248   my $self = shift;
 249   $self->next::method(@_);
 250   $self->install();
 251 }
 252
 253 =head2 create_upgrade_path
 254
 255 =over 4
 256
 257 =item Arguments: { upgrade_file => $file }
 258
 259 =back
 260
 261 Virtual method that should be overridden to create an upgrade file.
 262 This is useful in the case of upgrading across multiple versions
 263 to concatenate several files to create one upgrade file.
 264
 265 You'll probably want the db_version retrieved via $self->get_db_version
 266 and the schema_version which is retrieved via $self->schema_version
 267
 268 =cut
 269
 270 sub create_upgrade_path {
 271   ## override this method
 272 }
 273
 274 =head2 ordered_schema_versions
 275
 276 =over 4
 277
 278 =item Returns: a list of version numbers, ordered from lowest to highest
 279
 280 =back
 281
 282 Virtual method that should be overridden to return an ordered list
 283 of schema versions. This is then used to produce a set of steps to
 284 upgrade through to achieve the required schema version.
 285
 286 You may want the db_version retrieved via $self->get_db_version
 287 and the schema_version which is retrieved via $self->schema_version
 288
 289 =cut
 290
 291 sub ordered_schema_versions {
 292   ## override this method
 293 }
 294
 295 =head2 upgrade
 296
 297 Call this to attempt to upgrade your database from the version it
 298 is at to the version this DBIC schema is at. If they are the same
 299 it does nothing.
 300
 301 It will call L</ordered_schema_versions> to retrieve an ordered
 302 list of schema versions (if ordered_schema_versions returns nothing
 303 then it is assumed you can do the upgrade as a single step). It
 304 then iterates through the list of versions between the current db
 305 version and the schema version applying one update at a time until
 306 all relevant updates are applied.
 307
 308 The individual update steps are performed by using
 309 L</upgrade_single_step>, which will apply the update and also
 310 update the dbix_class_schema_versions table.
 311
 312 =cut
 313
 314 sub upgrade {
 315     my ($self) = @_;
 316     my $db_version = $self->get_db_version();
 317
 318     # db unversioned
 319     unless ($db_version) {
 320         carp 'Upgrade not possible as database is unversioned. Please call install first.';
 321         return;
 322     }
 323
 324     # db and schema at same version. do nothing
 325     if ( $db_version eq $self->schema_version ) {
 326         carp "Upgrade not necessary\n";
 327         return;
 328     }
 329
 330     my @version_list = $self->ordered_schema_versions;
 331
 332     # if nothing returned then we preload with min/max
 333     @version_list = ( $db_version, $self->schema_version )
 334       unless ( scalar(@version_list) );
 335
 336     # catch the case of someone returning an arrayref
 337     @version_list = @{ $version_list[0] }
 338       if ( ref( $version_list[0] ) eq 'ARRAY' );
 339
 340     # remove all versions in list above the required version
 341     while ( scalar(@version_list)
 342         && ( $version_list[-1] ne $self->schema_version ) )
 343     {
 344         pop @version_list;
 345     }
 346
 347     # remove all versions in list below the current version
 348     while ( scalar(@version_list) && ( $version_list[0] ne $db_version ) ) {
 349         shift @version_list;
 350     }
 351
 352     # check we have an appropriate list of versions
 353     if ( scalar(@version_list) < 2 ) {
 354         die;
 355     }
 356
 357     # do sets of upgrade
 358     while ( scalar(@version_list) >= 2 ) {
 359         $self->upgrade_single_step( $version_list[0], $version_list[1] );
 360         shift @version_list;
 361     }
 362 }
 363
 364 =head2 upgrade_single_step
 365
 366 =over 4
 367
 368 =item Arguments: db_version - the version currently within the db
 369
 370 =item Arguments: target_version - the version to upgrade to
 371
 372 =back
 373
 374 Call this to attempt to upgrade your database from the
 375 I<db_version> to the I<target_version>. If they are the same it
 376 does nothing.
 377
 378 It requires an SQL diff file to exist in your I<upgrade_directory>,
 379 normally you will have created this using L<DBIx::Class::Schema/create_ddl_dir>.
 380
 381 If successful the dbix_class_schema_versions table is updated with
 382 the I<target_version>.
 383
 384 This method may be called repeatedly by the upgrade method to
 385 upgrade through a series of updates.
 386
 387 =cut
 388
 389 sub upgrade_single_step
 390 {
 391   my ($self,
 392       $db_version,
 393       $target_version) = @_;
 394
 395   # db and schema at same version. do nothing
 396   if ($db_version eq $target_version) {
 397     carp "Upgrade not necessary\n";
 398     return;
 399   }
 400
 401   # strangely the first time this is called can
 402   # differ to subsequent times. so we call it
 403   # here to be sure.
 404   # XXX - just fix it
 405   $self->storage->sqlt_type;
 406
 407   my $upgrade_file = $self->ddl_filename(
 408                                          $self->storage->sqlt_type,
 409                                          $target_version,
 410                                          $self->upgrade_directory,
 411                                          $db_version,
 412                                         );
 413
 414   $self->create_upgrade_path({ upgrade_file => $upgrade_file });
 415
 416   unless (-f $upgrade_file) {
 417     carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 418     return;
 419   }
 420
 421   carp "DB version ($db_version) is lower than the schema version (".$self->schema_version."). Attempting upgrade.\n";
 422
 423   # backup if necessary then apply upgrade
 424   $self->_filedata($self->_read_sql_file($upgrade_file));
 425   $self->backup() if($self->do_backup);
 426   $self->txn_do(sub { $self->do_upgrade() });
 427
 428   # set row in dbix_class_schema_versions table
 429   $self->_set_db_version({version => $target_version});
 430 }
 431
 432 =head2 do_upgrade
 433
 434 This is an overwritable method used to run your upgrade. The freeform method
 435 allows you to run your upgrade any way you please, you can call C<run_upgrade>
 436 any number of times to run the actual SQL commands, and in between you can
 437 sandwich your data upgrading. For example, first run all the B<CREATE>
 438 commands, then migrate your data from old to new tables/formats, then
 439 issue the DROP commands when you are finished. Will run the whole file as it is by default.
 440
 441 =cut
 442
 443 sub do_upgrade
 444 {
 445   my ($self) = @_;
 446
 447   # just run all the commands (including inserts) in order
 448   $self->run_upgrade(qr/.*?/);
 449 }
 450
 451 =head2 run_upgrade
 452
 453  $self->run_upgrade(qr/create/i);
 454
 455 Runs a set of SQL statements matching a passed in regular expression. The
 456 idea is that this method can be called any number of times from your
 457 C<do_upgrade> method, running whichever commands you specify via the
 458 regex in the parameter. Probably won't work unless called from the overridable
 459 do_upgrade method.
 460
 461 =cut
 462
 463 sub run_upgrade
 464 {
 465     my ($self, $stm) = @_;
 466
 467     return unless ($self->_filedata);
 468     my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 469     $self->_filedata([ grep { $_ !~ /$stm/i } @{$self->_filedata} ]);
 470
 471     for (@statements)
 472     {
 473         $self->storage->debugobj->query_start($_) if $self->storage->debug;
 474         $self->apply_statement($_);
 475         $self->storage->debugobj->query_end($_) if $self->storage->debug;
 476     }
 477
 478     return 1;
 479 }
 480
 481 =head2 apply_statement
 482
 483 Takes an SQL statement and runs it. Override this if you want to handle errors
 484 differently.
 485
 486 =cut
 487
 488 sub apply_statement {
 489     my ($self, $statement) = @_;
 490
 491     $self->storage->dbh->do($_) or carp "SQL was: $_";
 492 }
 493
 494 =head2 get_db_version
 495
 496 Returns the version that your database is currently at. This is determined by the values in the
 497 dbix_class_schema_versions table that C<upgrade> and C<install> write to.
 498
 499 =cut
 500
 501 sub get_db_version
 502 {
 503     my ($self, $rs) = @_;
 504
 505     my $vtable = $self->{vschema}->resultset('Table');
 506     my $version;
 507     try {
 508       $version = $vtable->search({}, { order_by => { -desc => 'installed' }, rows => 1 } )
 509               ->get_column ('version')
 510                ->next;
 511     };
 512     return $version || 0;
 513 }
 514
 515 =head2 schema_version
 516
 517 Returns the current schema class' $VERSION
 518
 519 =cut
 520
 521 =head2 backup
 522
 523 This is an overwritable method which is called just before the upgrade, to
 524 allow you to make a backup of the database. Per default this method attempts
 525 to call C<< $self->storage->backup >>, to run the standard backup on each
 526 database type.
 527
 528 This method should return the name of the backup file, if appropriate..
 529
 530 This method is disabled by default. Set $schema->do_backup(1) to enable it.
 531
 532 =cut
 533
 534 sub backup
 535 {
 536     my ($self) = @_;
 537     ## Make each ::DBI::Foo do this
 538     $self->storage->backup($self->backup_directory());
 539 }
 540
 541 =head2 connection
 542
 543 Overloaded method. This checks the DBIC schema version against the DB version and
 544 warns if they are not the same or if the DB is unversioned. It also provides
 545 compatibility between the old versions table (SchemaVersions) and the new one
 546 (dbix_class_schema_versions).
 547
 548 To avoid the checks on connect, set the environment var DBIC_NO_VERSION_CHECK or alternatively you can set the ignore_version attr in the forth argument like so:
 549
 550   my $schema = MyApp::Schema->connect(
 551     $dsn,
 552     $user,
 553     $password,
 554     { ignore_version => 1 },
 555   );
 556
 557 =cut
 558
 559 sub connection {
 560   my $self = shift;
 561   $self->next::method(@_);
 562   $self->_on_connect($_[3]);
 563   return $self;
 564 }
 565
 566 sub _on_connect
 567 {
 568   my ($self, $args) = @_;
 569
 570   $args = {} unless $args;
 571
 572   $self->{vschema} = DBIx::Class::Version->connect(@{$self->storage->connect_info()});
 573   my $vtable = $self->{vschema}->resultset('Table');
 574
 575   # useful when connecting from scripts etc
 576   return if ($args->{ignore_version} || ($ENV{DBIC_NO_VERSION_CHECK} && !exists $args->{ignore_version}));
 577
 578   # check for legacy versions table and move to new if exists
 579   my $vschema_compat = DBIx::Class::VersionCompat->connect(@{$self->storage->connect_info()});
 580   unless ($self->_source_exists($vtable)) {
 581     my $vtable_compat = $vschema_compat->resultset('TableCompat');
 582     if ($self->_source_exists($vtable_compat)) {
 583       $self->{vschema}->deploy;
 584       map { $vtable->create({ installed => $_->Installed, version => $_->Version }) } $vtable_compat->all;
 585       $self->storage->dbh->do("DROP TABLE " . $vtable_compat->result_source->from);
 586     }
 587   }
 588
 589   my $pversion = $self->get_db_version();
 590
 591   if($pversion eq $self->schema_version)
 592     {
 593 #         carp "This version is already installed\n";
 594         return 1;
 595     }
 596
 597   if(!$pversion)
 598     {
 599         carp "Your DB is currently unversioned. Please call upgrade on your schema to sync the DB.\n";
 600         return 1;
 601     }
 602
 603   carp "Versions out of sync. This is " . $self->schema_version .
 604     ", your database contains version $pversion, please call upgrade on your Schema.\n";
 605 }
 606
 607 # is this just a waste of time? if not then merge with DBI.pm
 608 sub _create_db_to_schema_diff {
 609   my $self = shift;
 610
 611   my %driver_to_db_map = (
 612                           'mysql' => 'MySQL'
 613                          );
 614
 615   my $db = $driver_to_db_map{$self->storage->dbh->{Driver}->{Name}};
 616   unless ($db) {
 617     print "Sorry, this is an unsupported DB\n";
 618     return;
 619   }
 620
 621   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
 622     $self->throw_exception("Unable to proceed without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
 623   }
 624
 625   my $db_tr = SQL::Translator->new({
 626                                     add_drop_table => 1,
 627                                     parser => 'DBI',
 628                                     parser_args => { dbh => $self->storage->dbh }
 629                                    });
 630
 631   $db_tr->producer($db);
 632   my $dbic_tr = SQL::Translator->new;
 633   $dbic_tr->parser('SQL::Translator::Parser::DBIx::Class');
 634   $dbic_tr->data($self);
 635   $dbic_tr->producer($db);
 636
 637   $db_tr->schema->name('db_schema');
 638   $dbic_tr->schema->name('dbic_schema');
 639
 640   # is this really necessary?
 641   foreach my $tr ($db_tr, $dbic_tr) {
 642     my $data = $tr->data;
 643     $tr->parser->($tr, $$data);
 644   }
 645
 646   my $diff = SQL::Translator::Diff::schema_diff($db_tr->schema, $db,
 647                                                 $dbic_tr->schema, $db,
 648                                                 { ignore_constraint_names => 1, ignore_index_names => 1, caseopt => 1 });
 649
 650   my $filename = $self->ddl_filename(
 651                                          $db,
 652                                          $self->schema_version,
 653                                          $self->upgrade_directory,
 654                                          'PRE',
 655                                     );
 656   my $file;
 657   if(!open($file, ">$filename"))
 658     {
 659       $self->throw_exception("Can't open $filename for writing ($!)");
 660       next;
 661     }
 662   print $file $diff;
 663   close($file);
 664
 665   carp "WARNING: There may be differences between your DB and your DBIC schema. Please review and if necessary run the SQL in $filename to sync your DB.\n";
 666 }
 667
 668
 669 sub _set_db_version {
 670   my $self = shift;
 671   my ($params) = @_;
 672   $params ||= {};
 673
 674   my $version = $params->{version} ? $params->{version} : $self->schema_version;
 675   my $vtable = $self->{vschema}->resultset('Table');
 676
 677   ##############################################################################
 678   #                             !!! NOTE !!!
 679   ##############################################################################
 680   #
 681   # The travesty below replaces the old nice timestamp format of %Y-%m-%d %H:%M:%S
 682   # This is necessary since there are legitimate cases when upgrades can happen
 683   # back to back within the same second. This breaks things since we relay on the
 684   # ability to sort by the 'installed' value. The logical choice of an autoinc
 685   # is not possible, as it will break multiple legacy installations. Also it is
 686   # not possible to format the string sanely, as the column is a varchar(20).
 687   # The 'v' character is added to the front of the string, so that any version
 688   # formatted by this new function will sort _after_ any existing 200... strings.
 689   my @tm = gettimeofday();
 690   my @dt = gmtime ($tm[0]);
 691   my $o = $vtable->create({
 692     version => $version,
 693     installed => sprintf("v%04d%02d%02d_%02d%02d%02d.%03.0f",
 694       $dt[5] + 1900,
 695       $dt[4] + 1,
 696       $dt[3],
 697       $dt[2],
 698       $dt[1],
 699       $dt[0],
 700       $tm[1] / 1000, # convert to millisecs, format as up/down rounded int above
 701     ),
 702   });
 703 }
 704
 705 sub _read_sql_file {
 706   my $self = shift;
 707   my $file = shift || return;
 708
 709   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 710   my @data = split /\n/, join '', <$fh>;
 711   close $fh;
 712
 713   @data = split /;/,
 714      join '',
 715        grep { $_ &&
 716               !/^--/  &&
 717               !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/mi }
 718          @data;
 719
 720   return \@data;
 721 }
 722
 723 sub _source_exists
 724 {
 725     my ($self, $rs) = @_;
 726
 727     my $c;
 728     my $exception;
 729     try {
 730         $c = $rs->search({ 1, 0 })->count;
 731     } catch {
 732         $exception=1;
 733     };
 734     return 0 if $exception || !defined $c;
 735
 736     return 1;
 737 }
 738
 739 1;
 740
 741
 742 =head1 AUTHORS
 743
 744 Jess Robinson <castaway@desert-island.me.uk>
 745 Luke Saunders <luke@shadowcatsystems.co.uk>
 746
 747 =head1 LICENSE
 748
 749 You may distribute this code under the same terms as Perl itself.