lib/DBIx/Class/Schema/Versioned.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::Version::Table;
   3 use base 'DBIx::Class::Core';
   4 use strict;
   5 use warnings;
   6
   7 __PACKAGE__->table('dbix_class_schema_versions');
   8
   9 __PACKAGE__->add_columns
  10     ( 'version' => {
  11         'data_type' => 'VARCHAR',
  12         'is_auto_increment' => 0,
  13         'default_value' => undef,
  14         'is_foreign_key' => 0,
  15         'name' => 'version',
  16         'is_nullable' => 0,
  17         'size' => '10'
  18         },
  19       'installed' => {
  20           'data_type' => 'VARCHAR',
  21           'is_auto_increment' => 0,
  22           'default_value' => undef,
  23           'is_foreign_key' => 0,
  24           'name' => 'installed',
  25           'is_nullable' => 0,
  26           'size' => '20'
  27           },
  28       );
  29 __PACKAGE__->set_primary_key('version');
  30
  31 package # Hide from PAUSE
  32   DBIx::Class::Version::TableCompat;
  33 use base 'DBIx::Class::Core';
  34 __PACKAGE__->table('SchemaVersions');
  35
  36 __PACKAGE__->add_columns
  37     ( 'Version' => {
  38         'data_type' => 'VARCHAR',
  39         },
  40       'Installed' => {
  41           'data_type' => 'VARCHAR',
  42           },
  43       );
  44 __PACKAGE__->set_primary_key('Version');
  45
  46 package # Hide from PAUSE
  47   DBIx::Class::Version;
  48 use base 'DBIx::Class::Schema';
  49 use strict;
  50 use warnings;
  51
  52 __PACKAGE__->register_class('Table', 'DBIx::Class::Version::Table');
  53
  54 package # Hide from PAUSE
  55   DBIx::Class::VersionCompat;
  56 use base 'DBIx::Class::Schema';
  57 use strict;
  58 use warnings;
  59
  60 __PACKAGE__->register_class('TableCompat', 'DBIx::Class::Version::TableCompat');
  61
  62
  63 # ---------------------------------------------------------------------------
  64
  65 =head1 NAME
  66
  67 DBIx::Class::Schema::Versioned - DBIx::Class::Schema plugin for Schema upgrades
  68
  69 =head1 SYNOPSIS
  70
  71   package MyApp::Schema;
  72   use base qw/DBIx::Class::Schema/;
  73
  74   our $VERSION = 0.001;
  75
  76   # load MyApp::Schema::CD, MyApp::Schema::Book, MyApp::Schema::DVD
  77   __PACKAGE__->load_classes(qw/CD Book DVD/);
  78
  79   __PACKAGE__->load_components(qw/Schema::Versioned/);
  80   __PACKAGE__->upgrade_directory('/path/to/upgrades/');
  81
  82
  83 =head1 DESCRIPTION
  84
  85 This module provides methods to apply DDL changes to your database using SQL
  86 diff files. Normally these diff files would be created using
  87 L<DBIx::Class::Schema/create_ddl_dir>.
  88
  89 A table called I<dbix_class_schema_versions> is created and maintained by the
  90 module. This is used to determine which version your database is currently at.
  91 Similarly the $VERSION in your DBIC schema class is used to determine the
  92 current DBIC schema version.
  93
  94 The upgrade is initiated manually by calling C<upgrade> on your schema object,
  95 this will attempt to upgrade the database from its current version to the current
  96 schema version using a diff from your I<upgrade_directory>. If a suitable diff is
  97 not found then no upgrade is possible.
  98
  99 NB: At the moment, only SQLite and MySQL are supported. This is due to
 100 spotty behaviour in the SQL::Translator producers, please help us by
 101 enhancing them. Ask on the mailing list or IRC channel for details (community details
 102 in L<DBIx::Class>).
 103
 104 =head1 GETTING STARTED
 105
 106 Firstly you need to setup your schema class as per the L</SYNOPSIS>, make sure
 107 you have specified an upgrade_directory and an initial $VERSION.
 108
 109 Then you'll need two scripts, one to create DDL files and diffs and another to perform
 110 upgrades. Your creation script might look like a bit like this:
 111
 112   use strict;
 113   use Pod::Usage;
 114   use Getopt::Long;
 115   use MyApp::Schema;
 116
 117   my ( $preversion, $help );
 118   GetOptions(
 119     'p|preversion:s'  => \$preversion,
 120   ) or die pod2usage;
 121
 122   my $schema = MyApp::Schema->connect(
 123     $dsn,
 124     $user,
 125     $password,
 126   );
 127   my $sql_dir = './sql';
 128   my $version = $schema->schema_version();
 129   $schema->create_ddl_dir( 'MySQL', $version, $sql_dir, $preversion );
 130
 131 Then your upgrade script might look like so:
 132
 133   use strict;
 134   use MyApp::Schema;
 135
 136   my $schema = MyApp::Schema->connect(
 137     $dsn,
 138     $user,
 139     $password,
 140   );
 141
 142   if (!$schema->get_db_version()) {
 143     # schema is unversioned
 144     $schema->deploy();
 145   } else {
 146     $schema->upgrade();
 147   }
 148
 149 The script above assumes that if the database is unversioned then it is empty
 150 and we can safely deploy the DDL to it. However things are not always so simple.
 151
 152 if you want to initialise a pre-existing database where the DDL is not the same
 153 as the DDL for your current schema version then you will need a diff which
 154 converts the database's DDL to the current DDL. The best way to do this is
 155 to get a dump of the database schema (without data) and save that in your
 156 SQL directory as version 0.000 (the filename must be as with
 157 L<DBIx::Class::Schema/ddl_filename>) then create a diff using your create DDL
 158 script given above from version 0.000 to the current version. Then hand check
 159 and if necessary edit the resulting diff to ensure that it will apply. Once you have
 160 done all that you can do this:
 161
 162   if (!$schema->get_db_version()) {
 163     # schema is unversioned
 164     $schema->install("0.000");
 165   }
 166
 167   # this will now apply the 0.000 to current version diff
 168   $schema->upgrade();
 169
 170 In the case of an unversioned database the above code will create the
 171 dbix_class_schema_versions table and write version 0.000 to it, then
 172 upgrade will then apply the diff we talked about creating in the previous paragraph
 173 and then you're good to go.
 174
 175 =cut
 176
 177 package DBIx::Class::Schema::Versioned;
 178
 179 use strict;
 180 use warnings;
 181 use base 'DBIx::Class::Schema';
 182
 183 use Carp::Clan qw/^DBIx::Class/;
 184 use Time::HiRes qw/gettimeofday/;
 185 use Try::Tiny;
 186 use namespace::clean;
 187
 188 __PACKAGE__->mk_classdata('_filedata');
 189 __PACKAGE__->mk_classdata('upgrade_directory');
 190 __PACKAGE__->mk_classdata('backup_directory');
 191 __PACKAGE__->mk_classdata('do_backup');
 192 __PACKAGE__->mk_classdata('do_diff_on_init');
 193
 194
 195 =head1 METHODS
 196
 197 =head2 upgrade_directory
 198
 199 Use this to set the directory your upgrade files are stored in.
 200
 201 =head2 backup_directory
 202
 203 Use this to set the directory you want your backups stored in (note that backups
 204 are disabled by default).
 205
 206 =cut
 207
 208 =head2 install
 209
 210 =over 4
 211
 212 =item Arguments: $db_version
 213
 214 =back
 215
 216 Call this to initialise a previously unversioned database. The table 'dbix_class_schema_versions' will be created which will be used to store the database version.
 217
 218 Takes one argument which should be the version that the database is currently at. Defaults to the return value of L</schema_version>.
 219
 220 See L</getting_started> for more details.
 221
 222 =cut
 223
 224 sub install
 225 {
 226   my ($self, $new_version) = @_;
 227
 228   # must be called on a fresh database
 229   if ($self->get_db_version()) {
 230       $self->throw_exception("A versioned schema has already been deployed, try upgrade instead.\n");
 231   }
 232
 233   # default to current version if none passed
 234   $new_version ||= $self->schema_version();
 235
 236   if ($new_version) {
 237     # create versions table and version row
 238     $self->{vschema}->deploy;
 239     $self->_set_db_version({ version => $new_version });
 240   }
 241 }
 242
 243 =head2 deploy
 244
 245 Same as L<DBIx::Class::Schema/deploy> but also calls C<install>.
 246
 247 =cut
 248
 249 sub deploy {
 250   my $self = shift;
 251   $self->next::method(@_);
 252   $self->install();
 253 }
 254
 255 =head2 create_upgrade_path
 256
 257 =over 4
 258
 259 =item Arguments: { upgrade_file => $file }
 260
 261 =back
 262
 263 Virtual method that should be overridden to create an upgrade file.
 264 This is useful in the case of upgrading across multiple versions
 265 to concatenate several files to create one upgrade file.
 266
 267 You'll probably want the db_version retrieved via $self->get_db_version
 268 and the schema_version which is retrieved via $self->schema_version
 269
 270 =cut
 271
 272 sub create_upgrade_path {
 273   ## override this method
 274 }
 275
 276 =head2 ordered_schema_versions
 277
 278 =over 4
 279
 280 =item Returns: a list of version numbers, ordered from lowest to highest
 281
 282 =back
 283
 284 Virtual method that should be overridden to return an ordered list
 285 of schema versions. This is then used to produce a set of steps to
 286 upgrade through to achieve the required schema version.
 287
 288 You may want the db_version retrieved via $self->get_db_version
 289 and the schema_version which is retrieved via $self->schema_version
 290
 291 =cut
 292
 293 sub ordered_schema_versions {
 294   ## override this method
 295 }
 296
 297 =head2 upgrade
 298
 299 Call this to attempt to upgrade your database from the version it
 300 is at to the version this DBIC schema is at. If they are the same
 301 it does nothing.
 302
 303 It will call L</ordered_schema_versions> to retrieve an ordered
 304 list of schema versions (if ordered_schema_versions returns nothing
 305 then it is assumed you can do the upgrade as a single step). It
 306 then iterates through the list of versions between the current db
 307 version and the schema version applying one update at a time until
 308 all relevant updates are applied.
 309
 310 The individual update steps are performed by using
 311 L</upgrade_single_step>, which will apply the update and also
 312 update the dbix_class_schema_versions table.
 313
 314 =cut
 315
 316 sub upgrade {
 317     my ($self) = @_;
 318     my $db_version = $self->get_db_version();
 319
 320     # db unversioned
 321     unless ($db_version) {
 322         carp 'Upgrade not possible as database is unversioned. Please call install first.';
 323         return;
 324     }
 325
 326     # db and schema at same version. do nothing
 327     if ( $db_version eq $self->schema_version ) {
 328         carp "Upgrade not necessary\n";
 329         return;
 330     }
 331
 332     my @version_list = $self->ordered_schema_versions;
 333
 334     # if nothing returned then we preload with min/max
 335     @version_list = ( $db_version, $self->schema_version )
 336       unless ( scalar(@version_list) );
 337
 338     # catch the case of someone returning an arrayref
 339     @version_list = @{ $version_list[0] }
 340       if ( ref( $version_list[0] ) eq 'ARRAY' );
 341
 342     # remove all versions in list above the required version
 343     while ( scalar(@version_list)
 344         && ( $version_list[-1] ne $self->schema_version ) )
 345     {
 346         pop @version_list;
 347     }
 348
 349     # remove all versions in list below the current version
 350     while ( scalar(@version_list) && ( $version_list[0] ne $db_version ) ) {
 351         shift @version_list;
 352     }
 353
 354     # check we have an appropriate list of versions
 355     if ( scalar(@version_list) < 2 ) {
 356         die;
 357     }
 358
 359     # do sets of upgrade
 360     while ( scalar(@version_list) >= 2 ) {
 361         $self->upgrade_single_step( $version_list[0], $version_list[1] );
 362         shift @version_list;
 363     }
 364 }
 365
 366 =head2 upgrade_single_step
 367
 368 =over 4
 369
 370 =item Arguments: db_version - the version currently within the db
 371
 372 =item Arguments: target_version - the version to upgrade to
 373
 374 =back
 375
 376 Call this to attempt to upgrade your database from the
 377 I<db_version> to the I<target_version>. If they are the same it
 378 does nothing.
 379
 380 It requires an SQL diff file to exist in your I<upgrade_directory>,
 381 normally you will have created this using L<DBIx::Class::Schema/create_ddl_dir>.
 382
 383 If successful the dbix_class_schema_versions table is updated with
 384 the I<target_version>.
 385
 386 This method may be called repeatedly by the upgrade method to
 387 upgrade through a series of updates.
 388
 389 =cut
 390
 391 sub upgrade_single_step
 392 {
 393   my ($self,
 394       $db_version,
 395       $target_version) = @_;
 396
 397   # db and schema at same version. do nothing
 398   if ($db_version eq $target_version) {
 399     carp "Upgrade not necessary\n";
 400     return;
 401   }
 402
 403   # strangely the first time this is called can
 404   # differ to subsequent times. so we call it
 405   # here to be sure.
 406   # XXX - just fix it
 407   $self->storage->sqlt_type;
 408
 409   my $upgrade_file = $self->ddl_filename(
 410                                          $self->storage->sqlt_type,
 411                                          $target_version,
 412                                          $self->upgrade_directory,
 413                                          $db_version,
 414                                         );
 415
 416   $self->create_upgrade_path({ upgrade_file => $upgrade_file });
 417
 418   unless (-f $upgrade_file) {
 419     carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 420     return;
 421   }
 422
 423   carp "DB version ($db_version) is lower than the schema version (".$self->schema_version."). Attempting upgrade.\n";
 424
 425   # backup if necessary then apply upgrade
 426   $self->_filedata($self->_read_sql_file($upgrade_file));
 427   $self->backup() if($self->do_backup);
 428   $self->txn_do(sub { $self->do_upgrade() });
 429
 430   # set row in dbix_class_schema_versions table
 431   $self->_set_db_version({version => $target_version});
 432 }
 433
 434 =head2 do_upgrade
 435
 436 This is an overwritable method used to run your upgrade. The freeform method
 437 allows you to run your upgrade any way you please, you can call C<run_upgrade>
 438 any number of times to run the actual SQL commands, and in between you can
 439 sandwich your data upgrading. For example, first run all the B<CREATE>
 440 commands, then migrate your data from old to new tables/formats, then
 441 issue the DROP commands when you are finished. Will run the whole file as it is by default.
 442
 443 =cut
 444
 445 sub do_upgrade
 446 {
 447   my ($self) = @_;
 448
 449   # just run all the commands (including inserts) in order
 450   $self->run_upgrade(qr/.*?/);
 451 }
 452
 453 =head2 run_upgrade
 454
 455  $self->run_upgrade(qr/create/i);
 456
 457 Runs a set of SQL statements matching a passed in regular expression. The
 458 idea is that this method can be called any number of times from your
 459 C<do_upgrade> method, running whichever commands you specify via the
 460 regex in the parameter. Probably won't work unless called from the overridable
 461 do_upgrade method.
 462
 463 =cut
 464
 465 sub run_upgrade
 466 {
 467     my ($self, $stm) = @_;
 468
 469     return unless ($self->_filedata);
 470     my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 471     $self->_filedata([ grep { $_ !~ /$stm/i } @{$self->_filedata} ]);
 472
 473     for (@statements)
 474     {
 475         $self->storage->debugobj->query_start($_) if $self->storage->debug;
 476         $self->apply_statement($_);
 477         $self->storage->debugobj->query_end($_) if $self->storage->debug;
 478     }
 479
 480     return 1;
 481 }
 482
 483 =head2 apply_statement
 484
 485 Takes an SQL statement and runs it. Override this if you want to handle errors
 486 differently.
 487
 488 =cut
 489
 490 sub apply_statement {
 491     my ($self, $statement) = @_;
 492
 493     $self->storage->dbh->do($_) or carp "SQL was: $_";
 494 }
 495
 496 =head2 get_db_version
 497
 498 Returns the version that your database is currently at. This is determined by the values in the
 499 dbix_class_schema_versions table that C<upgrade> and C<install> write to.
 500
 501 =cut
 502
 503 sub get_db_version
 504 {
 505     my ($self, $rs) = @_;
 506
 507     my $vtable = $self->{vschema}->resultset('Table');
 508     my $version = try {
 509       $vtable->search({}, { order_by => { -desc => 'installed' }, rows => 1 } )
 510               ->get_column ('version')
 511                ->next;
 512     };
 513     return $version || 0;
 514 }
 515
 516 =head2 schema_version
 517
 518 Returns the current schema class' $VERSION
 519
 520 =cut
 521
 522 =head2 backup
 523
 524 This is an overwritable method which is called just before the upgrade, to
 525 allow you to make a backup of the database. Per default this method attempts
 526 to call C<< $self->storage->backup >>, to run the standard backup on each
 527 database type.
 528
 529 This method should return the name of the backup file, if appropriate..
 530
 531 This method is disabled by default. Set $schema->do_backup(1) to enable it.
 532
 533 =cut
 534
 535 sub backup
 536 {
 537     my ($self) = @_;
 538     ## Make each ::DBI::Foo do this
 539     $self->storage->backup($self->backup_directory());
 540 }
 541
 542 =head2 connection
 543
 544 Overloaded method. This checks the DBIC schema version against the DB version and
 545 warns if they are not the same or if the DB is unversioned. It also provides
 546 compatibility between the old versions table (SchemaVersions) and the new one
 547 (dbix_class_schema_versions).
 548
 549 To avoid the checks on connect, set the environment var DBIC_NO_VERSION_CHECK or alternatively you can set the ignore_version attr in the forth argument like so:
 550
 551   my $schema = MyApp::Schema->connect(
 552     $dsn,
 553     $user,
 554     $password,
 555     { ignore_version => 1 },
 556   );
 557
 558 =cut
 559
 560 sub connection {
 561   my $self = shift;
 562   $self->next::method(@_);
 563   $self->_on_connect();
 564   return $self;
 565 }
 566
 567 sub _on_connect
 568 {
 569   my ($self) = @_;
 570
 571   my $conn_info = $self->storage->connect_info;
 572   $self->{vschema} = DBIx::Class::Version->connect(@$conn_info);
 573   my $conn_attrs = $self->{vschema}->storage->_dbic_connect_attributes || {};
 574
 575   my $vtable = $self->{vschema}->resultset('Table');
 576
 577   # useful when connecting from scripts etc
 578   return if ($conn_attrs->{ignore_version} || ($ENV{DBIC_NO_VERSION_CHECK} && !exists $conn_attrs->{ignore_version}));
 579
 580   # check for legacy versions table and move to new if exists
 581   unless ($self->_source_exists($vtable)) {
 582     my $vtable_compat = DBIx::Class::VersionCompat->connect(@$conn_info)->resultset('TableCompat');
 583     if ($self->_source_exists($vtable_compat)) {
 584       $self->{vschema}->deploy;
 585       map { $vtable->create({ installed => $_->Installed, version => $_->Version }) } $vtable_compat->all;
 586       $self->storage->_get_dbh->do("DROP TABLE " . $vtable_compat->result_source->from);
 587     }
 588   }
 589
 590   my $pversion = $self->get_db_version();
 591
 592   if($pversion eq $self->schema_version)
 593     {
 594 #         carp "This version is already installed\n";
 595         return 1;
 596     }
 597
 598   if(!$pversion)
 599     {
 600         carp "Your DB is currently unversioned. Please call upgrade on your schema to sync the DB.\n";
 601         return 1;
 602     }
 603
 604   carp "Versions out of sync. This is " . $self->schema_version .
 605     ", your database contains version $pversion, please call upgrade on your Schema.\n";
 606 }
 607
 608 # is this just a waste of time? if not then merge with DBI.pm
 609 sub _create_db_to_schema_diff {
 610   my $self = shift;
 611
 612   my %driver_to_db_map = (
 613                           'mysql' => 'MySQL'
 614                          );
 615
 616   my $db = $driver_to_db_map{$self->storage->dbh->{Driver}->{Name}};
 617   unless ($db) {
 618     print "Sorry, this is an unsupported DB\n";
 619     return;
 620   }
 621
 622   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
 623     $self->throw_exception("Unable to proceed without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
 624   }
 625
 626   my $db_tr = SQL::Translator->new({
 627                                     add_drop_table => 1,
 628                                     parser => 'DBI',
 629                                     parser_args => { dbh => $self->storage->dbh }
 630                                    });
 631
 632   $db_tr->producer($db);
 633   my $dbic_tr = SQL::Translator->new;
 634   $dbic_tr->parser('SQL::Translator::Parser::DBIx::Class');
 635   $dbic_tr->data($self);
 636   $dbic_tr->producer($db);
 637
 638   $db_tr->schema->name('db_schema');
 639   $dbic_tr->schema->name('dbic_schema');
 640
 641   # is this really necessary?
 642   foreach my $tr ($db_tr, $dbic_tr) {
 643     my $data = $tr->data;
 644     $tr->parser->($tr, $$data);
 645   }
 646
 647   my $diff = SQL::Translator::Diff::schema_diff($db_tr->schema, $db,
 648                                                 $dbic_tr->schema, $db,
 649                                                 { ignore_constraint_names => 1, ignore_index_names => 1, caseopt => 1 });
 650
 651   my $filename = $self->ddl_filename(
 652                                          $db,
 653                                          $self->schema_version,
 654                                          $self->upgrade_directory,
 655                                          'PRE',
 656                                     );
 657   my $file;
 658   if(!open($file, ">$filename"))
 659     {
 660       $self->throw_exception("Can't open $filename for writing ($!)");
 661       next;
 662     }
 663   print $file $diff;
 664   close($file);
 665
 666   carp "WARNING: There may be differences between your DB and your DBIC schema. Please review and if necessary run the SQL in $filename to sync your DB.\n";
 667 }
 668
 669
 670 sub _set_db_version {
 671   my $self = shift;
 672   my ($params) = @_;
 673   $params ||= {};
 674
 675   my $version = $params->{version} ? $params->{version} : $self->schema_version;
 676   my $vtable = $self->{vschema}->resultset('Table');
 677
 678   ##############################################################################
 679   #                             !!! NOTE !!!
 680   ##############################################################################
 681   #
 682   # The travesty below replaces the old nice timestamp format of %Y-%m-%d %H:%M:%S
 683   # This is necessary since there are legitimate cases when upgrades can happen
 684   # back to back within the same second. This breaks things since we relay on the
 685   # ability to sort by the 'installed' value. The logical choice of an autoinc
 686   # is not possible, as it will break multiple legacy installations. Also it is
 687   # not possible to format the string sanely, as the column is a varchar(20).
 688   # The 'v' character is added to the front of the string, so that any version
 689   # formatted by this new function will sort _after_ any existing 200... strings.
 690   my @tm = gettimeofday();
 691   my @dt = gmtime ($tm[0]);
 692   my $o = $vtable->create({
 693     version => $version,
 694     installed => sprintf("v%04d%02d%02d_%02d%02d%02d.%03.0f",
 695       $dt[5] + 1900,
 696       $dt[4] + 1,
 697       $dt[3],
 698       $dt[2],
 699       $dt[1],
 700       $dt[0],
 701       $tm[1] / 1000, # convert to millisecs, format as up/down rounded int above
 702     ),
 703   });
 704 }
 705
 706 sub _read_sql_file {
 707   my $self = shift;
 708   my $file = shift || return;
 709
 710   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 711   my @data = split /\n/, join '', <$fh>;
 712   close $fh;
 713
 714   @data = split /;/,
 715      join '',
 716        grep { $_ &&
 717               !/^--/  &&
 718               !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/mi }
 719          @data;
 720
 721   return \@data;
 722 }
 723
 724 sub _source_exists
 725 {
 726     my ($self, $rs) = @_;
 727
 728     return try {
 729       $rs->search(\'1=0')->cursor->next;
 730       1;
 731     } catch {
 732       0;
 733     };
 734 }
 735
 736 1;
 737
 738
 739 =head1 AUTHORS
 740
 741 Jess Robinson <castaway@desert-island.me.uk>
 742 Luke Saunders <luke@shadowcatsystems.co.uk>
 743
 744 =head1 LICENSE
 745
 746 You may distribute this code under the same terms as Perl itself.