lib/DBIx/Class/Schema/Versioned.pm

   1 package # Hide from PAUSE
   2   DBIx::Class::Version::Table;
   3 use base 'DBIx::Class';
   4 use strict;
   5 use warnings;
   6
   7 __PACKAGE__->load_components(qw/ Core/);
   8 __PACKAGE__->table('dbix_class_schema_versions');
   9
  10 __PACKAGE__->add_columns
  11     ( 'version' => {
  12         'data_type' => 'VARCHAR',
  13         'is_auto_increment' => 0,
  14         'default_value' => undef,
  15         'is_foreign_key' => 0,
  16         'name' => 'version',
  17         'is_nullable' => 0,
  18         'size' => '10'
  19         },
  20       'installed' => {
  21           'data_type' => 'VARCHAR',
  22           'is_auto_increment' => 0,
  23           'default_value' => undef,
  24           'is_foreign_key' => 0,
  25           'name' => 'installed',
  26           'is_nullable' => 0,
  27           'size' => '20'
  28           },
  29       );
  30 __PACKAGE__->set_primary_key('version');
  31
  32 package # Hide from PAUSE
  33   DBIx::Class::Version::TableCompat;
  34 use base 'DBIx::Class';
  35 __PACKAGE__->load_components(qw/ Core/);
  36 __PACKAGE__->table('SchemaVersions');
  37
  38 __PACKAGE__->add_columns
  39     ( 'Version' => {
  40         'data_type' => 'VARCHAR',
  41         },
  42       'Installed' => {
  43           'data_type' => 'VARCHAR',
  44           },
  45       );
  46 __PACKAGE__->set_primary_key('Version');
  47
  48 package # Hide from PAUSE
  49   DBIx::Class::Version;
  50 use base 'DBIx::Class::Schema';
  51 use strict;
  52 use warnings;
  53
  54 __PACKAGE__->register_class('Table', 'DBIx::Class::Version::Table');
  55
  56 package # Hide from PAUSE
  57   DBIx::Class::VersionCompat;
  58 use base 'DBIx::Class::Schema';
  59 use strict;
  60 use warnings;
  61
  62 __PACKAGE__->register_class('TableCompat', 'DBIx::Class::Version::TableCompat');
  63
  64
  65 # ---------------------------------------------------------------------------
  66
  67 =head1 NAME
  68
  69 DBIx::Class::Schema::Versioned - DBIx::Class::Schema plugin for Schema upgrades
  70
  71 =head1 SYNOPSIS
  72
  73   package Library::Schema;
  74   use base qw/DBIx::Class::Schema/;
  75
  76   our $VERSION = 0.001;
  77
  78   # load Library::Schema::CD, Library::Schema::Book, Library::Schema::DVD
  79   __PACKAGE__->load_classes(qw/CD Book DVD/);
  80
  81   __PACKAGE__->load_components(qw/Schema::Versioned/);
  82   __PACKAGE__->upgrade_directory('/path/to/upgrades/');
  83
  84
  85 =head1 DESCRIPTION
  86
  87 This module provides methods to apply DDL changes to your database using SQL
  88 diff files. Normally these diff files would be created using
  89 L<DBIx::Class::Schema/create_ddl_dir>.
  90
  91 A table called I<dbix_class_schema_versions> is created and maintained by the
  92 module. This is used to determine which version your database is currently at.
  93 Similarly the $VERSION in your DBIC schema class is used to determine the
  94 current DBIC schema version.
  95
  96 The upgrade is initiated manually by calling C<upgrade> on your schema object,
  97 this will attempt to upgrade the database from its current version to the current
  98 schema version using a diff from your I<upgrade_directory>. If a suitable diff is
  99 not found then no upgrade is possible.
 100
 101 NB: At the moment, only SQLite and MySQL are supported. This is due to
 102 spotty behaviour in the SQL::Translator producers, please help us by
 103 enhancing them. Ask on the mailing list or IRC channel for details (community details
 104 in L<DBIx::Class>).
 105
 106 =head1 GETTING STARTED
 107
 108 Firstly you need to setup your schema class as per the L</SYNOPSIS>, make sure
 109 you have specified an upgrade_directory and an initial $VERSION.
 110
 111 Then you'll need two scripts, one to create DDL files and diffs and another to perform
 112 upgrades. Your creation script might look like a bit like this:
 113
 114   use strict;
 115   use Pod::Usage;
 116   use Getopt::Long;
 117   use MyApp::Schema;
 118
 119   my ( $preversion, $help );
 120   GetOptions(
 121     'p|preversion:s'  => \$preversion,
 122   ) or die pod2usage;
 123
 124   my $schema = MyApp::Schema->connect(
 125     $dsn,
 126     $user,
 127     $password,
 128   );
 129   my $sql_dir = './sql';
 130   my $version = $schema->schema_version();
 131   $schema->create_ddl_dir( 'MySQL', $version, $sql_dir, $preversion );
 132
 133 Then your upgrade script might look like so:
 134
 135   use strict;
 136   use MyApp::Schema;
 137
 138   my $schema = MyApp::Schema->connect(
 139     $dsn,
 140     $user,
 141     $password,
 142   );
 143
 144   if (!$schema->get_db_version()) {
 145     # schema is unversioned
 146     $schema->deploy();
 147   } else {
 148     $schema->upgrade();
 149   }
 150
 151 The script above assumes that if the database is unversioned then it is empty
 152 and we can safely deploy the DDL to it. However things are not always so simple.
 153
 154 if you want to initialise a pre-existing database where the DDL is not the same
 155 as the DDL for your current schema version then you will need a diff which
 156 converts the database's DDL to the current DDL. The best way to do this is
 157 to get a dump of the database schema (without data) and save that in your
 158 SQL directory as version 0.000 (the filename must be as with
 159 L<DBIx::Class::Schema/ddl_filename>) then create a diff using your create DDL
 160 script given above from version 0.000 to the current version. Then hand check
 161 and if necessary edit the resulting diff to ensure that it will apply. Once you have
 162 done all that you can do this:
 163
 164   if (!$schema->get_db_version()) {
 165     # schema is unversioned
 166     $schema->install("0.000");
 167   }
 168
 169   # this will now apply the 0.000 to current version diff
 170   $schema->upgrade();
 171
 172 In the case of an unversioned database the above code will create the
 173 dbix_class_schema_versions table and write version 0.000 to it, then
 174 upgrade will then apply the diff we talked about creating in the previous paragraph
 175 and then you're good to go.
 176
 177 =cut
 178
 179 package DBIx::Class::Schema::Versioned;
 180
 181 use strict;
 182 use warnings;
 183 use base 'DBIx::Class';
 184 use POSIX 'strftime';
 185
 186 __PACKAGE__->mk_classdata('_filedata');
 187 __PACKAGE__->mk_classdata('upgrade_directory');
 188 __PACKAGE__->mk_classdata('backup_directory');
 189 __PACKAGE__->mk_classdata('do_backup');
 190 __PACKAGE__->mk_classdata('do_diff_on_init');
 191
 192
 193 =head1 METHODS
 194
 195 =head2 upgrade_directory
 196
 197 Use this to set the directory your upgrade files are stored in.
 198
 199 =head2 backup_directory
 200
 201 Use this to set the directory you want your backups stored in (note that backups
 202 are disabled by default).
 203
 204 =cut
 205
 206 =head2 install
 207
 208 =over 4
 209
 210 =item Arguments: $db_version
 211
 212 =back
 213
 214 Call this to initialise a previously unversioned database. The table 'dbix_class_schema_versions' will be created which will be used to store the database version.
 215
 216 Takes one argument which should be the version that the database is currently at. Defaults to the return value of L</schema_version>.
 217
 218 See L</getting_started> for more details.
 219
 220 =cut
 221
 222 sub install
 223 {
 224   my ($self, $new_version) = @_;
 225
 226   # must be called on a fresh database
 227   if ($self->get_db_version()) {
 228     warn 'Install not possible as versions table already exists in database';
 229   }
 230
 231   # default to current version if none passed
 232   $new_version ||= $self->schema_version();
 233
 234   if ($new_version) {
 235     # create versions table and version row
 236     $self->{vschema}->deploy;
 237     $self->_set_db_version({ version => $new_version });
 238   }
 239 }
 240
 241 =head2 deploy
 242
 243 Same as L<DBIx::Class::Schema/deploy> but also calls C<install>.
 244
 245 =cut
 246
 247 sub deploy {
 248   my $self = shift;
 249   $self->next::method(@_);
 250   $self->install();
 251 }
 252
 253 =head2 create_upgrade_path
 254
 255 =over 4
 256
 257 =item Arguments: { upgrade_file => $file }
 258
 259 =back
 260
 261 Virtual method that should be overriden to create an upgrade file.
 262 This is useful in the case of upgrading across multiple versions
 263 to concatenate several files to create one upgrade file.
 264
 265 You'll probably want the db_version retrieved via $self->get_db_version
 266 and the schema_version which is retrieved via $self->schema_version
 267
 268 =cut
 269
 270 sub create_upgrade_path {
 271         ## override this method
 272 }
 273
 274 =head2 upgrade
 275
 276 Call this to attempt to upgrade your database from the version it is at to the version
 277 this DBIC schema is at. If they are the same it does nothing.
 278
 279 It requires an SQL diff file to exist in you I<upgrade_directory>, normally you will
 280 have created this using L<DBIx::Class::Schema/create_ddl_dir>.
 281
 282 If successful the dbix_class_schema_versions table is updated with the current
 283 DBIC schema version.
 284
 285 =cut
 286
 287 sub upgrade
 288 {
 289   my ($self) = @_;
 290   my $db_version = $self->get_db_version();
 291
 292   # db unversioned
 293   unless ($db_version) {
 294     warn 'Upgrade not possible as database is unversioned. Please call install first.';
 295     return;
 296   }
 297
 298   # db and schema at same version. do nothing
 299   if ($db_version eq $self->schema_version) {
 300     print "Upgrade not necessary\n";
 301     return;
 302   }
 303
 304   # strangely the first time this is called can
 305   # differ to subsequent times. so we call it
 306   # here to be sure.
 307   # XXX - just fix it
 308   $self->storage->sqlt_type;
 309
 310   my $upgrade_file = $self->ddl_filename(
 311                                          $self->storage->sqlt_type,
 312                                          $self->schema_version,
 313                                          $self->upgrade_directory,
 314                                          $db_version,
 315                                         );
 316
 317   $self->create_upgrade_path({ upgrade_file => $upgrade_file });
 318
 319   unless (-f $upgrade_file) {
 320     warn "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 321     return;
 322   }
 323
 324   warn "\nDB version ($db_version) is lower than the schema version (".$self->schema_version."). Attempting upgrade.\n";
 325
 326   # backup if necessary then apply upgrade
 327   $self->_filedata($self->_read_sql_file($upgrade_file));
 328   $self->backup() if($self->do_backup);
 329   $self->txn_do(sub { $self->do_upgrade() });
 330
 331   # set row in dbix_class_schema_versions table
 332   $self->_set_db_version;
 333 }
 334
 335 =head2 do_upgrade
 336
 337 This is an overwritable method used to run your upgrade. The freeform method
 338 allows you to run your upgrade any way you please, you can call C<run_upgrade>
 339 any number of times to run the actual SQL commands, and in between you can
 340 sandwich your data upgrading. For example, first run all the B<CREATE>
 341 commands, then migrate your data from old to new tables/formats, then
 342 issue the DROP commands when you are finished. Will run the whole file as it is by default.
 343
 344 =cut
 345
 346 sub do_upgrade
 347 {
 348   my ($self) = @_;
 349
 350   # just run all the commands (including inserts) in order
 351   $self->run_upgrade(qr/.*?/);
 352 }
 353
 354 =head2 run_upgrade
 355
 356  $self->run_upgrade(qr/create/i);
 357
 358 Runs a set of SQL statements matching a passed in regular expression. The
 359 idea is that this method can be called any number of times from your
 360 C<do_upgrade> method, running whichever commands you specify via the
 361 regex in the parameter. Probably won't work unless called from the overridable
 362 do_upgrade method.
 363
 364 =cut
 365
 366 sub run_upgrade
 367 {
 368     my ($self, $stm) = @_;
 369
 370     return unless ($self->_filedata);
 371     my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 372     $self->_filedata([ grep { $_ !~ /$stm/i } @{$self->_filedata} ]);
 373
 374     for (@statements)
 375     {
 376         $self->storage->debugobj->query_start($_) if $self->storage->debug;
 377         $self->apply_statement($_);
 378         $self->storage->debugobj->query_end($_) if $self->storage->debug;
 379     }
 380
 381     return 1;
 382 }
 383
 384 =head2 apply_statement
 385
 386 Takes an SQL statement and runs it. Override this if you want to handle errors
 387 differently.
 388
 389 =cut
 390
 391 sub apply_statement {
 392     my ($self, $statement) = @_;
 393
 394     $self->storage->dbh->do($_) or warn "SQL was:\n $_";
 395 }
 396
 397 =head2 get_db_version
 398
 399 Returns the version that your database is currently at. This is determined by the values in the
 400 dbix_class_schema_versions table that C<upgrade> and C<install> write to.
 401
 402 =cut
 403
 404 sub get_db_version
 405 {
 406     my ($self, $rs) = @_;
 407
 408     my $vtable = $self->{vschema}->resultset('Table');
 409     my $version = 0;
 410     eval {
 411       my $stamp = $vtable->get_column('installed')->max;
 412       $version = $vtable->search({ installed => $stamp })->first->version;
 413     };
 414     return $version;
 415 }
 416
 417 =head2 schema_version
 418
 419 Returns the current schema class' $VERSION
 420
 421 =cut
 422
 423 =head2 backup
 424
 425 This is an overwritable method which is called just before the upgrade, to
 426 allow you to make a backup of the database. Per default this method attempts
 427 to call C<< $self->storage->backup >>, to run the standard backup on each
 428 database type.
 429
 430 This method should return the name of the backup file, if appropriate..
 431
 432 This method is disabled by default. Set $schema->do_backup(1) to enable it.
 433
 434 =cut
 435
 436 sub backup
 437 {
 438     my ($self) = @_;
 439     ## Make each ::DBI::Foo do this
 440     $self->storage->backup($self->backup_directory());
 441 }
 442
 443 =head2 connection
 444
 445 Overloaded method. This checks the DBIC schema version against the DB version and
 446 warns if they are not the same or if the DB is unversioned. It also provides
 447 compatibility between the old versions table (SchemaVersions) and the new one
 448 (dbix_class_schema_versions).
 449
 450 To avoid the checks on connect, set the env var DBIC_NO_VERSION_CHECK or alternatively you can set the ignore_version attr in the forth argument like so:
 451
 452   my $schema = MyApp::Schema->connect(
 453     $dsn,
 454     $user,
 455     $password,
 456     { ignore_version => 1 },
 457   );
 458
 459 =cut
 460
 461 sub connection {
 462   my $self = shift;
 463   $self->next::method(@_);
 464   $self->_on_connect($_[3]);
 465   return $self;
 466 }
 467
 468 sub _on_connect
 469 {
 470   my ($self, $args) = @_;
 471
 472   $args = {} unless $args;
 473   $self->{vschema} = DBIx::Class::Version->connect(@{$self->storage->connect_info()});
 474   my $vtable = $self->{vschema}->resultset('Table');
 475
 476   # check for legacy versions table and move to new if exists
 477   my $vschema_compat = DBIx::Class::VersionCompat->connect(@{$self->storage->connect_info()});
 478   unless ($self->_source_exists($vtable)) {
 479     my $vtable_compat = $vschema_compat->resultset('TableCompat');
 480     if ($self->_source_exists($vtable_compat)) {
 481       $self->{vschema}->deploy;
 482       map { $vtable->create({ installed => $_->Installed, version => $_->Version }) } $vtable_compat->all;
 483       $self->storage->dbh->do("DROP TABLE " . $vtable_compat->result_source->from);
 484     }
 485   }
 486
 487   # useful when connecting from scripts etc
 488   return if ($args->{ignore_version} || ($ENV{DBIC_NO_VERSION_CHECK} && !exists $args->{ignore_version}));
 489   my $pversion = $self->get_db_version();
 490
 491   if($pversion eq $self->schema_version)
 492     {
 493 #         warn "This version is already installed\n";
 494         return 1;
 495     }
 496
 497   if(!$pversion)
 498     {
 499         warn "Your DB is currently unversioned. Please call upgrade on your schema to sync the DB.\n";
 500         return 1;
 501     }
 502
 503   warn "Versions out of sync. This is " . $self->schema_version .
 504     ", your database contains version $pversion, please call upgrade on your Schema.\n";
 505 }
 506
 507 # is this just a waste of time? if not then merge with DBI.pm
 508 sub _create_db_to_schema_diff {
 509   my $self = shift;
 510
 511   my %driver_to_db_map = (
 512                           'mysql' => 'MySQL'
 513                          );
 514
 515   my $db = $driver_to_db_map{$self->storage->dbh->{Driver}->{Name}};
 516   unless ($db) {
 517     print "Sorry, this is an unsupported DB\n";
 518     return;
 519   }
 520
 521   eval 'require SQL::Translator "0.09003"';
 522   if ($@) {
 523     $self->throw_exception("SQL::Translator 0.09003 required");
 524   }
 525
 526   my $db_tr = SQL::Translator->new({
 527                                     add_drop_table => 1,
 528                                     parser => 'DBI',
 529                                     parser_args => { dbh => $self->storage->dbh }
 530                                    });
 531
 532   $db_tr->producer($db);
 533   my $dbic_tr = SQL::Translator->new;
 534   $dbic_tr->parser('SQL::Translator::Parser::DBIx::Class');
 535   $dbic_tr->data($self);
 536   $dbic_tr->producer($db);
 537
 538   $db_tr->schema->name('db_schema');
 539   $dbic_tr->schema->name('dbic_schema');
 540
 541   # is this really necessary?
 542   foreach my $tr ($db_tr, $dbic_tr) {
 543     my $data = $tr->data;
 544     $tr->parser->($tr, $$data);
 545   }
 546
 547   my $diff = SQL::Translator::Diff::schema_diff($db_tr->schema, $db,
 548                                                 $dbic_tr->schema, $db,
 549                                                 { ignore_constraint_names => 1, ignore_index_names => 1, caseopt => 1 });
 550
 551   my $filename = $self->ddl_filename(
 552                                          $db,
 553                                          $self->schema_version,
 554                                          $self->upgrade_directory,
 555                                          'PRE',
 556                                     );
 557   my $file;
 558   if(!open($file, ">$filename"))
 559     {
 560       $self->throw_exception("Can't open $filename for writing ($!)");
 561       next;
 562     }
 563   print $file $diff;
 564   close($file);
 565
 566   print "WARNING: There may be differences between your DB and your DBIC schema. Please review and if necessary run the SQL in $filename to sync your DB.\n";
 567 }
 568
 569
 570 sub _set_db_version {
 571   my $self = shift;
 572   my ($params) = @_;
 573   $params ||= {};
 574
 575   my $version = $params->{version} ? $params->{version} : $self->schema_version;
 576   my $vtable = $self->{vschema}->resultset('Table');
 577   $vtable->create({ version => $version,
 578                       installed => strftime("%Y-%m-%d %H:%M:%S", gmtime())
 579                       });
 580
 581 }
 582
 583 sub _read_sql_file {
 584   my $self = shift;
 585   my $file = shift || return;
 586
 587   my $fh;
 588   open $fh, "<$file" or warn("Can't open upgrade file, $file ($!)");
 589   my @data = split(/\n/, join('', <$fh>));
 590   @data = grep(!/^--/, @data);
 591   @data = split(/;/, join('', @data));
 592   close($fh);
 593   @data = grep { $_ && $_ !~ /^-- / } @data;
 594   @data = grep { $_ !~ /^(BEGIN|BEGIN TRANSACTION|COMMIT)/m } @data;
 595   return \@data;
 596 }
 597
 598 sub _source_exists
 599 {
 600     my ($self, $rs) = @_;
 601
 602     my $c = eval {
 603         $rs->search({ 1, 0 })->count;
 604     };
 605     return 0 if $@ || !defined $c;
 606
 607     return 1;
 608 }
 609
 610 1;
 611
 612
 613 =head1 AUTHORS
 614
 615 Jess Robinson <castaway@desert-island.me.uk>
 616 Luke Saunders <luke@shadowcatsystems.co.uk>
 617
 618 =head1 LICENSE
 619
 620 You may distribute this code under the same terms as Perl itself.