lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 use base qw/DBIx::Class/;
   9
  10 __PACKAGE__->mk_classdata('class_mappings' => {});
  11 __PACKAGE__->mk_classdata('source_registrations' => {});
  12 __PACKAGE__->mk_classdata('storage_type' => '::DBI');
  13 __PACKAGE__->mk_classdata('storage');
  14
  15 =head1 NAME
  16
  17 DBIx::Class::Schema - composable schemas
  18
  19 =head1 SYNOPSIS
  20
  21   package Library::Schema;
  22   use base qw/DBIx::Class::Schema/;
  23
  24   # load Library::Schema::CD, Library::Schema::Book, Library::Schema::DVD
  25   __PACKAGE__->load_classes(qw/CD Book DVD/);
  26
  27   package Library::Schema::CD;
  28   use base qw/DBIx::Class/;
  29   __PACKAGE__->load_components(qw/PK::Auto Core/); # for example
  30   __PACKAGE__->table('cd');
  31
  32   # Elsewhere in your code:
  33   my $schema1 = Library::Schema->connect(
  34     $dsn,
  35     $user,
  36     $password,
  37     { AutoCommit => 0 },
  38   );
  39
  40   my $schema2 = Library::Schema->connect($coderef_returning_dbh);
  41
  42   # fetch objects using Library::Schema::DVD
  43   my $resultset = $schema1->resultset('DVD')->search( ... );
  44   my @dvd_objects = $schema2->resultset('DVD')->search( ... );
  45
  46 =head1 DESCRIPTION
  47
  48 Creates database classes based on a schema. This is the recommended way to
  49 use L<DBIx::Class> and allows you to use more than one concurrent connection
  50 with your classes.
  51
  52 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  53 carefully as DBIx::Class does things a little differently. Note in
  54 particular which module inherits off which.
  55
  56 =head1 METHODS
  57
  58 =head2 register_class
  59
  60 =head3 Arguments: <moniker> <component_class>
  61
  62 Registers a class which isa ResultSourceProxy; equivalent to calling
  63
  64   $schema->register_source($moniker, $component_class->result_source_instance);
  65
  66 =cut
  67
  68 sub register_class {
  69   my ($self, $moniker, $to_register) = @_;
  70   $self->register_source($moniker => $to_register->result_source_instance);
  71 }
  72
  73 =head2 register_source
  74
  75 =head3 Arguments: <moniker> <result source>
  76
  77 Registers the result source in the schema with the given moniker
  78
  79 =cut
  80
  81 sub register_source {
  82   my ($self, $moniker, $source) = @_;
  83   my %reg = %{$self->source_registrations};
  84   $reg{$moniker} = $source;
  85   $self->source_registrations(\%reg);
  86   $source->schema($self);
  87   if ($source->result_class) {
  88     my %map = %{$self->class_mappings};
  89     $map{$source->result_class} = $moniker;
  90     $self->class_mappings(\%map);
  91   }
  92 }
  93
  94 =head2 class
  95
  96   my $class = $schema->class('CD');
  97
  98 Retrieves the result class name for a given result source
  99
 100 =cut
 101
 102 sub class {
 103   my ($self, $moniker) = @_;
 104   return $self->source($moniker)->result_class;
 105 }
 106
 107 =head2 source
 108
 109   my $source = $schema->source('Book');
 110
 111 Returns the result source object for the registered name
 112
 113 =cut
 114
 115 sub source {
 116   my ($self, $moniker) = @_;
 117   my $sreg = $self->source_registrations;
 118   return $sreg->{$moniker} if exists $sreg->{$moniker};
 119
 120   # if we got here, they probably passed a full class name
 121   my $mapped = $self->class_mappings->{$moniker};
 122   $self->throw_exception("Can't find source for ${moniker}")
 123     unless $mapped && exists $sreg->{$mapped};
 124   return $sreg->{$mapped};
 125 }
 126
 127 =head2 sources
 128
 129   my @source_monikers = $schema->sources;
 130
 131 Returns the source monikers of all source registrations on this schema
 132
 133 =cut
 134
 135 sub sources { return keys %{shift->source_registrations}; }
 136
 137 =head2 resultset
 138
 139   my $rs = $schema->resultset('DVD');
 140
 141 Returns the resultset for the registered moniker
 142
 143 =cut
 144
 145 sub resultset {
 146   my ($self, $moniker) = @_;
 147   return $self->source($moniker)->resultset;
 148 }
 149
 150 =head2 load_classes
 151
 152 =head3 Arguments: @classes?, { $namespace => [ $class+ ] }+
 153
 154 Uses L<Module::Find> to find all classes under the database class' namespace,
 155 or uses the classes you select.  Then it loads the component (using L<use>),
 156 and registers them (using B<register_class>);
 157
 158 It is possible to comment out classes with a leading '#', but note that perl
 159 will think it's a mistake (trying to use a comment in a qw list) so you'll
 160 need to add "no warnings 'qw';" before your load_classes call.
 161
 162 =cut
 163
 164 sub load_classes {
 165   my ($class, @params) = @_;
 166
 167   my %comps_for;
 168
 169   if (@params) {
 170     foreach my $param (@params) {
 171       if (ref $param eq 'ARRAY') {
 172         # filter out commented entries
 173         my @modules = grep { $_ !~ /^#/ } @$param;
 174
 175         push (@{$comps_for{$class}}, @modules);
 176       }
 177       elsif (ref $param eq 'HASH') {
 178         # more than one namespace possible
 179         for my $comp ( keys %$param ) {
 180           # filter out commented entries
 181           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 182
 183           push (@{$comps_for{$comp}}, @modules);
 184         }
 185       }
 186       else {
 187         # filter out commented entries
 188         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 189       }
 190     }
 191   } else {
 192     eval "require Module::Find;";
 193     $class->throw_exception(
 194       "No arguments to load_classes and couldn't load Module::Find ($@)"
 195     ) if $@;
 196     my @comp = map { substr $_, length "${class}::"  }
 197                  Module::Find::findallmod($class);
 198     $comps_for{$class} = \@comp;
 199   }
 200
 201   my @to_register;
 202   {
 203     no warnings qw/redefine/;
 204     local *Class::C3::reinitialize = sub { };
 205     foreach my $prefix (keys %comps_for) {
 206       foreach my $comp (@{$comps_for{$prefix}||[]}) {
 207         my $comp_class = "${prefix}::${comp}";
 208         eval "use $comp_class"; # If it fails, assume the user fixed it
 209         if ($@) {
 210           $comp_class =~ s/::/\//g;
 211           die $@ unless $@ =~ /Can't locate.+$comp_class\.pm\sin\s\@INC/;
 212           warn $@ if $@;
 213         }
 214         push(@to_register, [ $comp, $comp_class ]);
 215       }
 216     }
 217   }
 218   Class::C3->reinitialize;
 219
 220   foreach my $to (@to_register) {
 221     $class->register_class(@$to);
 222     #  if $class->can('result_source_instance');
 223   }
 224 }
 225
 226 =head2 compose_connection
 227
 228 =head3 Arguments: $target_ns, @db_info
 229
 230 =head3 Return value: $new_schema
 231
 232 Calls compose_namespace to the $target_ns, calls ->connection(@db_info) on
 233 the new schema, then injects the ResultSetProxy component and a
 234 resultset_instance classdata entry on all the new classes in order to support
 235 $target_ns::Class->search(...) method calls. Primarily useful when you have
 236 a specific need for classmethod access to a connection - in normal usage
 237 ->connect is preferred.
 238
 239 =cut
 240
 241 sub compose_connection {
 242   my ($self, $target, @info) = @_;
 243   my $base = 'DBIx::Class::ResultSetProxy';
 244   eval "require ${base};";
 245   $self->throw_exception
 246     ("No arguments to load_classes and couldn't load ${base} ($@)")
 247       if $@;
 248
 249   if ($self eq $target) {
 250     # Pathological case, largely caused by the docs on early C::M::DBIC::Plain
 251     foreach my $moniker ($self->sources) {
 252       my $source = $self->source($moniker);
 253       my $class = $source->result_class;
 254       $self->inject_base($class, $base);
 255       $class->mk_classdata(resultset_instance => $source->resultset);
 256       $class->mk_classdata(class_resolver => $self);
 257     }
 258     $self->connection(@info);
 259     return $self;
 260   }
 261
 262   my $schema = $self->compose_namespace($target, $base);
 263   {
 264     no strict 'refs';
 265     *{"${target}::schema"} = sub { $schema };
 266   }
 267
 268   $schema->connection(@info);
 269   foreach my $moniker ($schema->sources) {
 270     my $source = $schema->source($moniker);
 271     my $class = $source->result_class;
 272     #warn "$moniker $class $source ".$source->storage;
 273     $class->mk_classdata(result_source_instance => $source);
 274     $class->mk_classdata(resultset_instance => $source->resultset);
 275     $class->mk_classdata(class_resolver => $schema);
 276   }
 277   return $schema;
 278 }
 279
 280 =head2 compose_namespace
 281
 282 =head3 Arguments: $target_ns, $additional_base_class?
 283
 284 =head3 Return value: $new_schema
 285
 286 For each result source in the schema, creates a class in the target
 287 namespace (e.g. $target_ns::CD, $target_ns::Artist) inheriting from the
 288 corresponding classes attached to the current schema and a result source
 289 to match attached to the new $schema object. If an additional base class is
 290 given, injects this immediately behind the corresponding classes from the
 291 current schema in the created classes' @ISA.
 292
 293 =cut
 294
 295 sub compose_namespace {
 296   my ($self, $target, $base) = @_;
 297   my %reg = %{ $self->source_registrations };
 298   my %target;
 299   my %map;
 300   my $schema = $self->clone;
 301   {
 302     no warnings qw/redefine/;
 303     local *Class::C3::reinitialize = sub { };
 304     foreach my $moniker ($schema->sources) {
 305       my $source = $schema->source($moniker);
 306       my $target_class = "${target}::${moniker}";
 307       $self->inject_base(
 308         $target_class => $source->result_class, ($base ? $base : ())
 309       );
 310       $source->result_class($target_class);
 311     }
 312   }
 313   Class::C3->reinitialize();
 314   {
 315     no strict 'refs';
 316     foreach my $meth (qw/class source resultset/) {
 317       *{"${target}::${meth}"} =
 318         sub { shift->schema->$meth(@_) };
 319     }
 320   }
 321   return $schema;
 322 }
 323
 324 =head2 setup_connection_class
 325
 326 =head3 Arguments: <$target> <@info>
 327
 328 Sets up a database connection class to inject between the schema
 329 and the subclasses the schema creates.
 330
 331 =cut
 332
 333 sub setup_connection_class {
 334   my ($class, $target, @info) = @_;
 335   $class->inject_base($target => 'DBIx::Class::DB');
 336   #$target->load_components('DB');
 337   $target->connection(@info);
 338 }
 339
 340 =head2 connection
 341
 342 =head3 Arguments: (@args)
 343
 344 Instantiates a new Storage object of type storage_type and passes the
 345 arguments to $storage->connect_info. Sets the connection in-place on
 346 the schema.
 347
 348 =cut
 349
 350 sub connection {
 351   my ($self, @info) = @_;
 352   return $self if !@info && $self->storage;
 353   my $storage_class = $self->storage_type;
 354   $storage_class = 'DBIx::Class::Storage'.$storage_class
 355     if $storage_class =~ m/^::/;
 356   eval "require ${storage_class};";
 357   $self->throw_exception(
 358     "No arguments to load_classes and couldn't load ${storage_class} ($@)"
 359   ) if $@;
 360   my $storage = $storage_class->new;
 361   $storage->connect_info(\@info);
 362   $self->storage($storage);
 363   return $self;
 364 }
 365
 366 =head2 connect
 367
 368 =head3 Arguments: (@info)
 369
 370 Conveneience method, equivalent to $schema->clone->connection(@info)
 371
 372 =cut
 373
 374 sub connect { shift->clone->connection(@_) }
 375
 376 =head2 txn_begin
 377
 378 Begins a transaction (does nothing if AutoCommit is off).
 379
 380 =cut
 381
 382 sub txn_begin { shift->storage->txn_begin }
 383
 384 =head2 txn_commit
 385
 386 Commits the current transaction.
 387
 388 =cut
 389
 390 sub txn_commit { shift->storage->txn_commit }
 391
 392 =head2 txn_rollback
 393
 394 Rolls back the current transaction.
 395
 396 =cut
 397
 398 sub txn_rollback { shift->storage->txn_rollback }
 399
 400 =head2 txn_do
 401
 402 =head3 Arguments: $coderef, @coderef_args?
 403
 404 Executes C<$coderef> with (optional) arguments C<@coderef_args>
 405 transactionally, returning its result (if any). If an exception is
 406 caught, a rollback is issued and the exception is rethrown. If the
 407 rollback fails, (i.e. throws an exception) an exception is thrown that
 408 includes a "Rollback failed" message.
 409
 410 For example,
 411
 412   my $author_rs = $schema->resultset('Author')->find(1);
 413
 414   my $coderef = sub {
 415     my ($author, @titles) = @_;
 416
 417     # If any one of these fails, the entire transaction fails
 418     $author->create_related('books', {
 419       title => $_
 420     }) foreach (@titles);
 421
 422     return $author->books;
 423   };
 424
 425   my $rs;
 426   eval {
 427     $rs = $schema->txn_do($coderef, $author_rs, qw/Night Day It/);
 428   };
 429
 430   if ($@) {
 431     my $error = $@;
 432     if ($error =~ /Rollback failed/) {
 433       die "something terrible has happened!";
 434     } else {
 435       deal_with_failed_transaction();
 436     }
 437   }
 438
 439 Nested transactions work as expected (i.e. only the outermost
 440 transaction will issue a txn_commit on the Schema's storage), and
 441 txn_do() can be called in void, scalar and list context and it will
 442 behave as expected.
 443
 444 =cut
 445
 446 sub txn_do {
 447   my ($self, $coderef, @args) = @_;
 448
 449   ref $self or $self->throw_exception
 450     ('Cannot execute txn_do as a class method');
 451   ref $coderef eq 'CODE' or $self->throw_exception
 452     ('$coderef must be a CODE reference');
 453
 454   my (@return_values, $return_value);
 455
 456   $self->txn_begin; # If this throws an exception, no rollback is needed
 457
 458   my $wantarray = wantarray; # Need to save this since it's reset in eval{}
 459
 460   eval {
 461     # Need to differentiate between scalar/list context to allow for
 462     # returning a list in scalar context to get the size of the list
 463
 464     if ($wantarray) {
 465       # list context
 466       @return_values = $coderef->(@args);
 467     } elsif (defined $wantarray) {
 468       # scalar context
 469       $return_value = $coderef->(@args);
 470     } else {
 471       # void context
 472       $coderef->(@args);
 473     }
 474     $self->txn_commit;
 475   };
 476
 477   if ($@) {
 478     my $error = $@;
 479
 480     eval {
 481       $self->txn_rollback;
 482     };
 483
 484     if ($@) {
 485       my $rollback_error = $@;
 486       my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 487       $self->throw_exception($error)  # propagate nested rollback
 488         if $rollback_error =~ /$exception_class/;
 489
 490       $self->throw_exception(
 491         "Transaction aborted: $error. Rollback failed: ${rollback_error}"
 492       );
 493     } else {
 494       $self->throw_exception($error); # txn failed but rollback succeeded
 495     }
 496   }
 497
 498   return $wantarray ? @return_values : $return_value;
 499 }
 500
 501 =head2 clone
 502
 503 Clones the schema and its associated result_source objects and returns the
 504 copy.
 505
 506 =cut
 507
 508 sub clone {
 509   my ($self) = @_;
 510   my $clone = bless({ (ref $self ? %$self : ()) }, ref $self || $self);
 511   foreach my $moniker ($self->sources) {
 512     my $source = $self->source($moniker);
 513     my $new = $source->new($source);
 514     $clone->register_source($moniker => $new);
 515   }
 516   return $clone;
 517 }
 518
 519 =head2 populate
 520
 521 =head3 Arguments: ($moniker, \@data);
 522
 523 Populates the source registered with the given moniker with the supplied data.
 524 @data should be a list of listrefs, the first containing column names, the
 525 second matching values - i.e.
 526
 527   $schema->populate('Artist', [
 528     [ qw/artistid name/ ],
 529     [ 1, 'Popular Band' ],
 530     [ 2, 'Indie Band' ],
 531     ...
 532   ]);
 533
 534 =cut
 535
 536 sub populate {
 537   my ($self, $name, $data) = @_;
 538   my $rs = $self->resultset($name);
 539   my @names = @{shift(@$data)};
 540   my @created;
 541   foreach my $item (@$data) {
 542     my %create;
 543     @create{@names} = @$item;
 544     push(@created, $rs->create(\%create));
 545   }
 546   return @created;
 547 }
 548
 549 =head2 throw_exception
 550
 551 Defaults to using Carp::Clan to report errors from user perspective.
 552
 553 =cut
 554
 555 sub throw_exception {
 556   my ($self) = shift;
 557   croak @_;
 558 }
 559
 560 =head2 deploy (EXPERIMENTAL)
 561
 562 Attempts to deploy the schema to the current storage using SQL::Translator.
 563
 564 Note that this feature is currently EXPERIMENTAL and may not work correctly
 565 across all databases, or fully handle complex relationships.
 566
 567 =cut
 568
 569 sub deploy {
 570   my ($self, $sqltargs) = @_;
 571   $self->throw_exception("Can't deploy without storage") unless $self->storage;
 572   $self->storage->deploy($self, undef, $sqltargs);
 573 }
 574
 575 1;
 576
 577 =head1 AUTHORS
 578
 579 Matt S. Trout <mst@shadowcatsystems.co.uk>
 580
 581 =head1 LICENSE
 582
 583 You may distribute this code under the same terms as Perl itself.
 584
 585 =cut
 586