lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::Class::DB;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->load_components(qw/Exception/);
  10 __PACKAGE__->mk_classdata('class_registrations' => {});
  11
  12 =head1 NAME
  13
  14 DBIx::Class::Schema - composable schemas
  15
  16 =head1 SYNOPSIS
  17
  18 in My/Schema.pm
  19
  20   package My::Schema;
  21
  22   use base qw/DBIx::Class::Schema/;
  23
  24   __PACKAGE__->load_classes(qw/Foo Bar Baz/);
  25
  26 in My/Schema/Foo.pm
  27
  28   package My::Schema::Foo;
  29
  30   use base qw/DBIx::Class/;
  31
  32   __PACKAGE__->load_components(qw/Core PK::Auto::Pg/); # for example
  33   __PACKAGE__->table('foo');
  34   ...
  35
  36 in My/DB.pm
  37
  38   use My::Schema;
  39
  40   My::Schema->compose_connection('My::DB', $dsn, $user, $pass, $attrs);
  41
  42 then in app code
  43
  44   my @obj = My::DB::Foo->search({}); # My::DB::Foo isa My::Schema::Foo My::DB
  45
  46 =head1 DESCRIPTION
  47
  48 Creates database classes based on a schema. This allows you to have more than
  49 one concurrent connection using the same database classes, by making
  50 subclasses under a new namespace for each connection. If you only need one
  51 class, you should probably use L<DBIx::Class::DB> directly instead.
  52
  53 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  54 carefully as DBIx::Class does things a little differently. Note in
  55 particular which module inherits off which.
  56
  57 =head1 METHODS
  58
  59 =head2 register_class <component> <component_class>
  60
  61 Registers the class in the schema's class_registrations. This is a hash
  62 containing database classes, keyed by their monikers. It's used by
  63 compose_connection to create/modify all the existing database classes.
  64
  65 =cut
  66
  67 sub register_class {
  68   my ($class, $name, $to_register) = @_;
  69   my %reg = %{$class->class_registrations};
  70   $reg{$name} = $to_register;
  71   $class->class_registrations(\%reg);
  72 }
  73
  74 =head2 registered_classes
  75
  76 Simple read-only accessor for the schema's registered classes. See
  77 register_class above if you want to modify it.
  78
  79
  80 =cut
  81
  82 sub registered_classes {
  83   return values %{shift->class_registrations};
  84 }
  85
  86 =head2  load_classes [<classes>, (<class>, <class>), {<namespace> => [<classes>]}]
  87
  88 Uses L<Module::Find> to find all classes under the database class' namespace,
  89 or uses the classes you select.  Then it loads the component (using L<use>),
  90 and registers them (using B<register_class>);
  91
  92 It is possible to comment out classes with a leading '#', but note that perl
  93 will think it's a mistake (trying to use a comment in a qw list) so you'll
  94 need to add "no warnings 'qw';" before your load_classes call.
  95
  96 =cut
  97
  98 sub load_classes {
  99   my ($class, @params) = @_;
 100
 101   my %comps_for;
 102
 103   if (@params) {
 104     foreach my $param (@params) {
 105       if (ref $param eq 'ARRAY') {
 106         # filter out commented entries
 107         my @modules = grep { $_ !~ /^#/ } @$param;
 108
 109         push (@{$comps_for{$class}}, @modules);
 110       }
 111       elsif (ref $param eq 'HASH') {
 112         # more than one namespace possible
 113         for my $comp ( keys %$param ) {
 114           # filter out commented entries
 115           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 116
 117           push (@{$comps_for{$comp}}, @modules);
 118         }
 119       }
 120       else {
 121         # filter out commented entries
 122         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 123       }
 124     }
 125   } else {
 126     eval "require Module::Find;";
 127     $class->throw("No arguments to load_classes and couldn't load".
 128       " Module::Find ($@)") if $@;
 129     my @comp = map { substr $_, length "${class}::"  } Module::Find::findallmod($class);
 130     $comps_for{$class} = \@comp;
 131   }
 132
 133   foreach my $prefix (keys %comps_for) {
 134     foreach my $comp (@{$comps_for{$prefix}||[]}) {
 135       my $comp_class = "${prefix}::${comp}";
 136       print "$comp_class\n";
 137       eval "use $comp_class"; # If it fails, assume the user fixed it
 138       $class->register_class($comp => $comp_class);
 139     }
 140   }
 141 }
 142
 143 =head2 compose_connection <target> <@db_info>
 144
 145 This is the most important method in this class. it takes a target namespace,
 146 as well as dbh connection info, and creates a L<DBIx::Class::DB> class as
 147 well as subclasses for each of your database classes in this namespace, using
 148 this connection.
 149
 150 It will also setup a ->table method on the target class, which lets you
 151 resolve database classes based on the schema component name, for example
 152
 153   MyApp::DB->table('Foo') # returns MyApp::DB::Foo,
 154                           # which ISA MyApp::Schema::Foo
 155
 156 This is the recommended API for accessing Schema generated classes, and
 157 using it might give you instant advantages with future versions of DBIC.
 158
 159 =cut
 160
 161 sub compose_connection {
 162   my ($class, $target, @info) = @_;
 163   my $conn_class = "${target}::_db";
 164   $class->setup_connection_class($conn_class, @info);
 165   my %reg = %{ $class->class_registrations };
 166   my %target;
 167   my %map;
 168   while (my ($comp, $comp_class) = each %reg) {
 169     my $target_class = "${target}::${comp}";
 170     $class->inject_base($target_class, $comp_class, $conn_class);
 171     $target_class->table($comp_class->table);
 172     @map{$comp, $comp_class} = ($target_class, $target_class);
 173   }
 174   {
 175     no strict 'refs';
 176     *{"${target}::class"} =
 177       sub {
 178         my ($class, $to_map) = @_;
 179         return $map{$to_map};
 180       };
 181     *{"${target}::classes"} = sub { return \%map; };
 182   }
 183   $conn_class->class_resolver($target);
 184 }
 185
 186 =head2 setup_connection_class <$target> <@info>
 187
 188 Sets up a database connection class to inject between the schema
 189 and the subclasses the schema creates.
 190
 191 =cut
 192
 193 sub setup_connection_class {
 194   my ($class, $target, @info) = @_;
 195   $class->inject_base($target => 'DBIx::Class::DB');
 196   #$target->load_components('DB');
 197   $target->connection(@info);
 198 }
 199
 200 1;
 201
 202 =head1 AUTHORS
 203
 204 Matt S. Trout <mst@shadowcatsystems.co.uk>
 205
 206 =head1 LICENSE
 207
 208 You may distribute this code under the same terms as Perl itself.
 209
 210 =cut
 211