lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5
   6 use DBIx::Class::Exception;
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util qw/weaken/;
   9 use File::Spec;
  10 require Module::Find;
  11
  12 use base qw/DBIx::Class/;
  13
  14 __PACKAGE__->mk_classdata('class_mappings' => {});
  15 __PACKAGE__->mk_classdata('source_registrations' => {});
  16 __PACKAGE__->mk_classdata('storage_type' => '::DBI');
  17 __PACKAGE__->mk_classdata('storage');
  18 __PACKAGE__->mk_classdata('exception_action');
  19 __PACKAGE__->mk_classdata('stacktrace' => $ENV{DBIC_TRACE} || 0);
  20 __PACKAGE__->mk_classdata('default_resultset_attributes' => {});
  21
  22 =head1 NAME
  23
  24 DBIx::Class::Schema - composable schemas
  25
  26 =head1 SYNOPSIS
  27
  28   package Library::Schema;
  29   use base qw/DBIx::Class::Schema/;
  30
  31   # load Library::Schema::CD, Library::Schema::Book, Library::Schema::DVD
  32   __PACKAGE__->load_classes(qw/CD Book DVD/);
  33
  34   package Library::Schema::CD;
  35   use base qw/DBIx::Class/;
  36   __PACKAGE__->load_components(qw/PK::Auto Core/); # for example
  37   __PACKAGE__->table('cd');
  38
  39   # Elsewhere in your code:
  40   my $schema1 = Library::Schema->connect(
  41     $dsn,
  42     $user,
  43     $password,
  44     { AutoCommit => 0 },
  45   );
  46
  47   my $schema2 = Library::Schema->connect($coderef_returning_dbh);
  48
  49   # fetch objects using Library::Schema::DVD
  50   my $resultset = $schema1->resultset('DVD')->search( ... );
  51   my @dvd_objects = $schema2->resultset('DVD')->search( ... );
  52
  53 =head1 DESCRIPTION
  54
  55 Creates database classes based on a schema. This is the recommended way to
  56 use L<DBIx::Class> and allows you to use more than one concurrent connection
  57 with your classes.
  58
  59 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  60 carefully, as DBIx::Class does things a little differently. Note in
  61 particular which module inherits off which.
  62
  63 =head1 METHODS
  64
  65 =head2 register_class
  66
  67 =over 4
  68
  69 =item Arguments: $moniker, $component_class
  70
  71 =back
  72
  73 Registers a class which isa DBIx::Class::ResultSourceProxy. Equivalent to
  74 calling:
  75
  76   $schema->register_source($moniker, $component_class->result_source_instance);
  77
  78 =cut
  79
  80 sub register_class {
  81   my ($self, $moniker, $to_register) = @_;
  82   $self->register_source($moniker => $to_register->result_source_instance);
  83 }
  84
  85 =head2 register_source
  86
  87 =over 4
  88
  89 =item Arguments: $moniker, $result_source
  90
  91 =back
  92
  93 Registers the L<DBIx::Class::ResultSource> in the schema with the given
  94 moniker.
  95
  96 =cut
  97
  98 sub register_source {
  99   my ($self, $moniker, $source) = @_;
 100
 101   %$source = %{ $source->new( { %$source, source_name => $moniker }) };
 102
 103   my %reg = %{$self->source_registrations};
 104   $reg{$moniker} = $source;
 105   $self->source_registrations(\%reg);
 106
 107   $source->schema($self);
 108
 109   weaken($source->{schema}) if ref($self);
 110   if ($source->result_class) {
 111     my %map = %{$self->class_mappings};
 112     $map{$source->result_class} = $moniker;
 113     $self->class_mappings(\%map);
 114   }
 115 }
 116
 117 sub _unregister_source {
 118     my ($self, $moniker) = @_;
 119     my %reg = %{$self->source_registrations};
 120
 121     my $source = delete $reg{$moniker};
 122     $self->source_registrations(\%reg);
 123     if ($source->result_class) {
 124         my %map = %{$self->class_mappings};
 125         delete $map{$source->result_class};
 126         $self->class_mappings(\%map);
 127     }
 128 }
 129
 130 =head2 class
 131
 132 =over 4
 133
 134 =item Arguments: $moniker
 135
 136 =item Return Value: $classname
 137
 138 =back
 139
 140 Retrieves the result class name for the given moniker. For example:
 141
 142   my $class = $schema->class('CD');
 143
 144 =cut
 145
 146 sub class {
 147   my ($self, $moniker) = @_;
 148   return $self->source($moniker)->result_class;
 149 }
 150
 151 =head2 source
 152
 153 =over 4
 154
 155 =item Arguments: $moniker
 156
 157 =item Return Value: $result_source
 158
 159 =back
 160
 161   my $source = $schema->source('Book');
 162
 163 Returns the L<DBIx::Class::ResultSource> object for the registered moniker.
 164
 165 =cut
 166
 167 sub source {
 168   my ($self, $moniker) = @_;
 169   my $sreg = $self->source_registrations;
 170   return $sreg->{$moniker} if exists $sreg->{$moniker};
 171
 172   # if we got here, they probably passed a full class name
 173   my $mapped = $self->class_mappings->{$moniker};
 174   $self->throw_exception("Can't find source for ${moniker}")
 175     unless $mapped && exists $sreg->{$mapped};
 176   return $sreg->{$mapped};
 177 }
 178
 179 =head2 sources
 180
 181 =over 4
 182
 183 =item Return Value: @source_monikers
 184
 185 =back
 186
 187 Returns the source monikers of all source registrations on this schema.
 188 For example:
 189
 190   my @source_monikers = $schema->sources;
 191
 192 =cut
 193
 194 sub sources { return keys %{shift->source_registrations}; }
 195
 196 =head2 storage
 197
 198   my $storage = $schema->storage;
 199
 200 Returns the L<DBIx::Class::Storage> object for this Schema.
 201
 202 =head2 resultset
 203
 204 =over 4
 205
 206 =item Arguments: $moniker
 207
 208 =item Return Value: $result_set
 209
 210 =back
 211
 212   my $rs = $schema->resultset('DVD');
 213
 214 Returns the L<DBIx::Class::ResultSet> object for the registered moniker.
 215
 216 =cut
 217
 218 sub resultset {
 219   my ($self, $moniker) = @_;
 220   return $self->source($moniker)->resultset;
 221 }
 222
 223 =head2 load_classes
 224
 225 =over 4
 226
 227 =item Arguments: @classes?, { $namespace => [ @classes ] }+
 228
 229 =back
 230
 231 With no arguments, this method uses L<Module::Find> to find all classes under
 232 the schema's namespace. Otherwise, this method loads the classes you specify
 233 (using L<use>), and registers them (using L</"register_class">).
 234
 235 It is possible to comment out classes with a leading C<#>, but note that perl
 236 will think it's a mistake (trying to use a comment in a qw list), so you'll
 237 need to add C<no warnings 'qw';> before your load_classes call.
 238
 239 Example:
 240
 241   My::Schema->load_classes(); # loads My::Schema::CD, My::Schema::Artist,
 242                               # etc. (anything under the My::Schema namespace)
 243
 244   # loads My::Schema::CD, My::Schema::Artist, Other::Namespace::Producer but
 245   # not Other::Namespace::LinerNotes nor My::Schema::Track
 246   My::Schema->load_classes(qw/ CD Artist #Track /, {
 247     Other::Namespace => [qw/ Producer #LinerNotes /],
 248   });
 249
 250 =cut
 251
 252 sub load_classes {
 253   my ($class, @params) = @_;
 254
 255   my %comps_for;
 256
 257   if (@params) {
 258     foreach my $param (@params) {
 259       if (ref $param eq 'ARRAY') {
 260         # filter out commented entries
 261         my @modules = grep { $_ !~ /^#/ } @$param;
 262
 263         push (@{$comps_for{$class}}, @modules);
 264       }
 265       elsif (ref $param eq 'HASH') {
 266         # more than one namespace possible
 267         for my $comp ( keys %$param ) {
 268           # filter out commented entries
 269           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 270
 271           push (@{$comps_for{$comp}}, @modules);
 272         }
 273       }
 274       else {
 275         # filter out commented entries
 276         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 277       }
 278     }
 279   } else {
 280     my @comp = map { substr $_, length "${class}::"  }
 281                  Module::Find::findallmod($class);
 282     $comps_for{$class} = \@comp;
 283   }
 284
 285   my @to_register;
 286   {
 287     no warnings qw/redefine/;
 288     local *Class::C3::reinitialize = sub { };
 289     foreach my $prefix (keys %comps_for) {
 290       foreach my $comp (@{$comps_for{$prefix}||[]}) {
 291         my $comp_class = "${prefix}::${comp}";
 292         { # try to untaint module name. mods where this fails
 293           # are left alone so we don't have to change the old behavior
 294           no locale; # localized \w doesn't untaint expression
 295           if ( $comp_class =~ m/^( (?:\w+::)* \w+ )$/x ) {
 296             $comp_class = $1;
 297           }
 298         }
 299         $class->ensure_class_loaded($comp_class);
 300
 301         $comp = $comp_class->source_name || $comp;
 302 #  $DB::single = 1;
 303         push(@to_register, [ $comp, $comp_class ]);
 304       }
 305     }
 306   }
 307   Class::C3->reinitialize;
 308
 309   foreach my $to (@to_register) {
 310     $class->register_class(@$to);
 311     #  if $class->can('result_source_instance');
 312   }
 313 }
 314
 315 =head2 load_namespaces
 316
 317 =over 4
 318
 319 =item Arguments: %options?
 320
 321 =back
 322
 323 This is an alternative to L</load_classes> above which assumes an alternative
 324 layout for automatic class loading.  It assumes that all result
 325 classes are underneath a sub-namespace of the schema called C<Result>, any
 326 corresponding ResultSet classes are underneath a sub-namespace of the schema
 327 called C<ResultSet>.
 328
 329 Both of the sub-namespaces are configurable if you don't like the defaults,
 330 via the options C<result_namespace> and C<resultset_namespace>.
 331
 332 If (and only if) you specify the option C<default_resultset_class>, any found
 333 Result classes for which we do not find a corresponding
 334 ResultSet class will have their C<resultset_class> set to
 335 C<default_resultset_class>.
 336
 337 C<load_namespaces> takes care of calling C<resultset_class> for you where
 338 neccessary if you didn't do it for yourself.
 339
 340 All of the namespace and classname options to this method are relative to
 341 the schema classname by default.  To specify a fully-qualified name, prefix
 342 it with a literal C<+>.
 343
 344 Examples:
 345
 346   # load My::Schema::Result::CD, My::Schema::Result::Artist,
 347   #    My::Schema::ResultSet::CD, etc...
 348   My::Schema->load_namespaces;
 349
 350   # Override everything to use ugly names.
 351   # In this example, if there is a My::Schema::Res::Foo, but no matching
 352   #   My::Schema::RSets::Foo, then Foo will have its
 353   #   resultset_class set to My::Schema::RSetBase
 354   My::Schema->load_namespaces(
 355     result_namespace => 'Res',
 356     resultset_namespace => 'RSets',
 357     default_resultset_class => 'RSetBase',
 358   );
 359
 360   # Put things in other namespaces
 361   My::Schema->load_namespaces(
 362     result_namespace => '+Some::Place::Results',
 363     resultset_namespace => '+Another::Place::RSets',
 364   );
 365
 366 If you'd like to use multiple namespaces of each type, simply use an arrayref
 367 of namespaces for that option.  In the case that the same result
 368 (or resultset) class exists in multiple namespaces, the latter entries in
 369 your list of namespaces will override earlier ones.
 370
 371   My::Schema->load_namespaces(
 372     # My::Schema::Results_C::Foo takes precedence over My::Schema::Results_B::Foo :
 373     result_namespace => [ 'Results_A', 'Results_B', 'Results_C' ],
 374     resultset_namespace => [ '+Some::Place::RSets', 'RSets' ],
 375   );
 376
 377 =cut
 378
 379 # Pre-pends our classname to the given relative classname or
 380 #   class namespace, unless there is a '+' prefix, which will
 381 #   be stripped.
 382 sub _expand_relative_name {
 383   my ($class, $name) = @_;
 384   return if !$name;
 385   $name = $class . '::' . $name if ! ($name =~ s/^\+//);
 386   return $name;
 387 }
 388
 389 # returns a hash of $shortname => $fullname for every package
 390 #  found in the given namespaces ($shortname is with the $fullname's
 391 #  namespace stripped off)
 392 sub _map_namespaces {
 393   my ($class, @namespaces) = @_;
 394
 395   my @results_hash;
 396   foreach my $namespace (@namespaces) {
 397     push(
 398       @results_hash,
 399       map { (substr($_, length "${namespace}::"), $_) }
 400       Module::Find::findallmod($namespace)
 401     );
 402   }
 403
 404   @results_hash;
 405 }
 406
 407 sub load_namespaces {
 408   my ($class, %args) = @_;
 409
 410   my $result_namespace = delete $args{result_namespace} || 'Result';
 411   my $resultset_namespace = delete $args{resultset_namespace} || 'ResultSet';
 412   my $default_resultset_class = delete $args{default_resultset_class};
 413
 414   $class->throw_exception('load_namespaces: unknown option(s): '
 415     . join(q{,}, map { qq{'$_'} } keys %args))
 416       if scalar keys %args;
 417
 418   $default_resultset_class
 419     = $class->_expand_relative_name($default_resultset_class);
 420
 421   for my $arg ($result_namespace, $resultset_namespace) {
 422     $arg = [ $arg ] if !ref($arg) && $arg;
 423
 424     $class->throw_exception('load_namespaces: namespace arguments must be '
 425       . 'a simple string or an arrayref')
 426         if ref($arg) ne 'ARRAY';
 427
 428     $_ = $class->_expand_relative_name($_) for (@$arg);
 429   }
 430
 431   my %results = $class->_map_namespaces(@$result_namespace);
 432   my %resultsets = $class->_map_namespaces(@$resultset_namespace);
 433
 434   my @to_register;
 435   {
 436     no warnings 'redefine';
 437     local *Class::C3::reinitialize = sub { };
 438     use warnings 'redefine';
 439
 440     foreach my $result (keys %results) {
 441       my $result_class = $results{$result};
 442       $class->ensure_class_loaded($result_class);
 443       $result_class->source_name($result) unless $result_class->source_name;
 444
 445       my $rs_class = delete $resultsets{$result};
 446       my $rs_set = $result_class->resultset_class;
 447       if($rs_set && $rs_set ne 'DBIx::Class::ResultSet') {
 448         if($rs_class && $rs_class ne $rs_set) {
 449           warn "We found ResultSet class '$rs_class' for '$result', but it seems "
 450              . "that you had already set '$result' to use '$rs_set' instead";
 451         }
 452       }
 453       elsif($rs_class ||= $default_resultset_class) {
 454         $class->ensure_class_loaded($rs_class);
 455         $result_class->resultset_class($rs_class);
 456       }
 457
 458       push(@to_register, [ $result_class->source_name, $result_class ]);
 459     }
 460   }
 461
 462   foreach (sort keys %resultsets) {
 463     warn "load_namespaces found ResultSet class $_ with no "
 464       . 'corresponding Result class';
 465   }
 466
 467   Class::C3->reinitialize;
 468   $class->register_class(@$_) for (@to_register);
 469
 470   return;
 471 }
 472
 473 =head2 compose_connection (DEPRECATED)
 474
 475 =over 4
 476
 477 =item Arguments: $target_namespace, @db_info
 478
 479 =item Return Value: $new_schema
 480
 481 =back
 482
 483 DEPRECATED. You probably wanted compose_namespace.
 484
 485 Actually, you probably just wanted to call connect.
 486
 487 =begin hidden
 488
 489 (hidden due to deprecation)
 490
 491 Calls L<DBIx::Class::Schema/"compose_namespace"> to the target namespace,
 492 calls L<DBIx::Class::Schema/connection> with @db_info on the new schema,
 493 then injects the L<DBix::Class::ResultSetProxy> component and a
 494 resultset_instance classdata entry on all the new classes, in order to support
 495 $target_namespaces::$class->search(...) method calls.
 496
 497 This is primarily useful when you have a specific need for class method access
 498 to a connection. In normal usage it is preferred to call
 499 L<DBIx::Class::Schema/connect> and use the resulting schema object to operate
 500 on L<DBIx::Class::ResultSet> objects with L<DBIx::Class::Schema/resultset> for
 501 more information.
 502
 503 =end hidden
 504
 505 =cut
 506
 507 {
 508   my $warn;
 509
 510   sub compose_connection {
 511     my ($self, $target, @info) = @_;
 512
 513     warn "compose_connection deprecated as of 0.08000"
 514       unless ($INC{"DBIx/Class/CDBICompat.pm"} || $warn++);
 515
 516     my $base = 'DBIx::Class::ResultSetProxy';
 517     eval "require ${base};";
 518     $self->throw_exception
 519       ("No arguments to load_classes and couldn't load ${base} ($@)")
 520         if $@;
 521
 522     if ($self eq $target) {
 523       # Pathological case, largely caused by the docs on early C::M::DBIC::Plain
 524       foreach my $moniker ($self->sources) {
 525         my $source = $self->source($moniker);
 526         my $class = $source->result_class;
 527         $self->inject_base($class, $base);
 528         $class->mk_classdata(resultset_instance => $source->resultset);
 529         $class->mk_classdata(class_resolver => $self);
 530       }
 531       $self->connection(@info);
 532       return $self;
 533     }
 534
 535     my $schema = $self->compose_namespace($target, $base);
 536     {
 537       no strict 'refs';
 538       *{"${target}::schema"} = sub { $schema };
 539     }
 540
 541     $schema->connection(@info);
 542     foreach my $moniker ($schema->sources) {
 543       my $source = $schema->source($moniker);
 544       my $class = $source->result_class;
 545       #warn "$moniker $class $source ".$source->storage;
 546       $class->mk_classdata(result_source_instance => $source);
 547       $class->mk_classdata(resultset_instance => $source->resultset);
 548       $class->mk_classdata(class_resolver => $schema);
 549     }
 550     return $schema;
 551   }
 552 }
 553
 554 =head2 compose_namespace
 555
 556 =over 4
 557
 558 =item Arguments: $target_namespace, $additional_base_class?
 559
 560 =item Return Value: $new_schema
 561
 562 =back
 563
 564 For each L<DBIx::Class::ResultSource> in the schema, this method creates a
 565 class in the target namespace (e.g. $target_namespace::CD,
 566 $target_namespace::Artist) that inherits from the corresponding classes
 567 attached to the current schema.
 568
 569 It also attaches a corresponding L<DBIx::Class::ResultSource> object to the
 570 new $schema object. If C<$additional_base_class> is given, the new composed
 571 classes will inherit from first the corresponding classe from the current
 572 schema then the base class.
 573
 574 For example, for a schema with My::Schema::CD and My::Schema::Artist classes,
 575
 576   $schema->compose_namespace('My::DB', 'Base::Class');
 577   print join (', ', @My::DB::CD::ISA) . "\n";
 578   print join (', ', @My::DB::Artist::ISA) ."\n";
 579
 580 will produce the output
 581
 582   My::Schema::CD, Base::Class
 583   My::Schema::Artist, Base::Class
 584
 585 =cut
 586
 587 sub compose_namespace {
 588   my ($self, $target, $base) = @_;
 589   my $schema = $self->clone;
 590   {
 591     no warnings qw/redefine/;
 592     local *Class::C3::reinitialize = sub { };
 593     foreach my $moniker ($schema->sources) {
 594       my $source = $schema->source($moniker);
 595       my $target_class = "${target}::${moniker}";
 596       $self->inject_base(
 597         $target_class => $source->result_class, ($base ? $base : ())
 598       );
 599       $source->result_class($target_class);
 600       $target_class->result_source_instance($source)
 601         if $target_class->can('result_source_instance');
 602     }
 603   }
 604   Class::C3->reinitialize();
 605   {
 606     no strict 'refs';
 607     no warnings 'redefine';
 608     foreach my $meth (qw/class source resultset/) {
 609       *{"${target}::${meth}"} =
 610         sub { shift->schema->$meth(@_) };
 611     }
 612   }
 613   return $schema;
 614 }
 615
 616 sub setup_connection_class {
 617   my ($class, $target, @info) = @_;
 618   $class->inject_base($target => 'DBIx::Class::DB');
 619   #$target->load_components('DB');
 620   $target->connection(@info);
 621 }
 622
 623 =head2 storage_type
 624
 625 =over 4
 626
 627 =item Arguments: $storage_type
 628
 629 =item Return Value: $storage_type
 630
 631 =back
 632
 633 Set the storage class that will be instantiated when L</connect> is called.
 634 If the classname starts with C<::>, the prefix C<DBIx::Class::Storage> is
 635 assumed by L</connect>.  Defaults to C<::DBI>,
 636 which is L<DBIx::Class::Storage::DBI>.
 637
 638 You want to use this to hardcoded subclasses of L<DBIx::Class::Storage::DBI>
 639 in cases where the appropriate subclass is not autodetected, such as when
 640 dealing with MSSQL via L<DBD::Sybase>, in which case you'd set it to
 641 C<::DBI::Sybase::MSSQL>.
 642
 643 =head2 connection
 644
 645 =over 4
 646
 647 =item Arguments: @args
 648
 649 =item Return Value: $new_schema
 650
 651 =back
 652
 653 Instantiates a new Storage object of type
 654 L<DBIx::Class::Schema/"storage_type"> and passes the arguments to
 655 $storage->connect_info. Sets the connection in-place on the schema.
 656
 657 See L<DBIx::Class::Storage::DBI/"connect_info"> for DBI-specific syntax,
 658 or L<DBIx::Class::Storage> in general.
 659
 660 =cut
 661
 662 sub connection {
 663   my ($self, @info) = @_;
 664   return $self if !@info && $self->storage;
 665   my $storage_class = $self->storage_type;
 666   $storage_class = 'DBIx::Class::Storage'.$storage_class
 667     if $storage_class =~ m/^::/;
 668   eval "require ${storage_class};";
 669   $self->throw_exception(
 670     "No arguments to load_classes and couldn't load ${storage_class} ($@)"
 671   ) if $@;
 672   my $storage = $storage_class->new($self);
 673   $storage->connect_info(\@info);
 674   $self->storage($storage);
 675   return $self;
 676 }
 677
 678 =head2 connect
 679
 680 =over 4
 681
 682 =item Arguments: @info
 683
 684 =item Return Value: $new_schema
 685
 686 =back
 687
 688 This is a convenience method. It is equivalent to calling
 689 $schema->clone->connection(@info). See L</connection> and L</clone> for more
 690 information.
 691
 692 =cut
 693
 694 sub connect { shift->clone->connection(@_) }
 695
 696 =head2 txn_do
 697
 698 =over 4
 699
 700 =item Arguments: C<$coderef>, @coderef_args?
 701
 702 =item Return Value: The return value of $coderef
 703
 704 =back
 705
 706 Executes C<$coderef> with (optional) arguments C<@coderef_args> atomically,
 707 returning its result (if any). Equivalent to calling $schema->storage->txn_do.
 708 See L<DBIx::Class::Storage/"txn_do"> for more information.
 709
 710 This interface is preferred over using the individual methods L</txn_begin>,
 711 L</txn_commit>, and L</txn_rollback> below.
 712
 713 =cut
 714
 715 sub txn_do {
 716   my $self = shift;
 717
 718   $self->storage or $self->throw_exception
 719     ('txn_do called on $schema without storage');
 720
 721   $self->storage->txn_do(@_);
 722 }
 723
 724 =head2 txn_scope_guard
 725
 726 Runs C<txn_scope_guard> on the schema's storage.
 727
 728 =cut
 729
 730 sub txn_scope_guard {
 731   my $self = shift;
 732
 733   $self->storage or $self->throw_exception
 734     ('txn_scope_guard called on $schema without storage');
 735
 736   $self->storage->txn_scope_guard(@_);
 737 }
 738
 739 =head2 txn_begin
 740
 741 Begins a transaction (does nothing if AutoCommit is off). Equivalent to
 742 calling $schema->storage->txn_begin. See
 743 L<DBIx::Class::Storage::DBI/"txn_begin"> for more information.
 744
 745 =cut
 746
 747 sub txn_begin {
 748   my $self = shift;
 749
 750   $self->storage or $self->throw_exception
 751     ('txn_begin called on $schema without storage');
 752
 753   $self->storage->txn_begin;
 754 }
 755
 756 =head2 txn_commit
 757
 758 Commits the current transaction. Equivalent to calling
 759 $schema->storage->txn_commit. See L<DBIx::Class::Storage::DBI/"txn_commit">
 760 for more information.
 761
 762 =cut
 763
 764 sub txn_commit {
 765   my $self = shift;
 766
 767   $self->storage or $self->throw_exception
 768     ('txn_commit called on $schema without storage');
 769
 770   $self->storage->txn_commit;
 771 }
 772
 773 =head2 txn_rollback
 774
 775 Rolls back the current transaction. Equivalent to calling
 776 $schema->storage->txn_rollback. See
 777 L<DBIx::Class::Storage::DBI/"txn_rollback"> for more information.
 778
 779 =cut
 780
 781 sub txn_rollback {
 782   my $self = shift;
 783
 784   $self->storage or $self->throw_exception
 785     ('txn_rollback called on $schema without storage');
 786
 787   $self->storage->txn_rollback;
 788 }
 789
 790 =head2 svp_begin
 791
 792 Creates a new savepoint (does nothing outside a transaction).
 793 Equivalent to calling $schema->storage->svp_begin.  See
 794 L<DBIx::Class::Storage::DBI/"svp_begin"> for more information.
 795
 796 =cut
 797
 798 sub svp_begin {
 799   my ($self, $name) = @_;
 800
 801   $self->storage or $self->throw_exception
 802     ('svp_begin called on $schema without storage');
 803
 804   $self->storage->svp_begin($name);
 805 }
 806
 807 =head2 svp_release
 808
 809 Releases a savepoint (does nothing outside a transaction).
 810 Equivalent to calling $schema->storage->svp_release.  See
 811 L<DBIx::Class::Storage::DBI/"svp_release"> for more information.
 812
 813 =cut
 814
 815 sub svp_release {
 816   my ($self, $name) = @_;
 817
 818   $self->storage or $self->throw_exception
 819     ('svp_release called on $schema without storage');
 820
 821   $self->storage->svp_release($name);
 822 }
 823
 824 =head2 svp_rollback
 825
 826 Rollback to a savepoint (does nothing outside a transaction).
 827 Equivalent to calling $schema->storage->svp_rollback.  See
 828 L<DBIx::Class::Storage::DBI/"svp_rollback"> for more information.
 829
 830 =cut
 831
 832 sub svp_rollback {
 833   my ($self, $name) = @_;
 834
 835   $self->storage or $self->throw_exception
 836     ('svp_rollback called on $schema without storage');
 837
 838   $self->storage->svp_rollback($name);
 839 }
 840
 841 =head2 clone
 842
 843 =over 4
 844
 845 =item Return Value: $new_schema
 846
 847 =back
 848
 849 Clones the schema and its associated result_source objects and returns the
 850 copy.
 851
 852 =cut
 853
 854 sub clone {
 855   my ($self) = @_;
 856   my $clone = { (ref $self ? %$self : ()) };
 857   bless $clone, (ref $self || $self);
 858
 859   foreach my $moniker ($self->sources) {
 860     my $source = $self->source($moniker);
 861     my $new = $source->new($source);
 862     $clone->register_source($moniker => $new);
 863   }
 864   $clone->storage->set_schema($clone) if $clone->storage;
 865   return $clone;
 866 }
 867
 868 =head2 populate
 869
 870 =over 4
 871
 872 =item Arguments: $source_name, \@data;
 873
 874 =back
 875
 876 Pass this method a resultsource name, and an arrayref of
 877 arrayrefs. The arrayrefs should contain a list of column names,
 878 followed by one or many sets of matching data for the given columns.
 879
 880 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
 881 to insert the data, as this is a fast method. However, insert_bulk currently
 882 assumes that your datasets all contain the same type of values, using scalar
 883 references in a column in one row, and not in another will probably not work.
 884
 885 Otherwise, each set of data is inserted into the database using
 886 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
 887 objects is returned.
 888
 889 i.e.,
 890
 891   $schema->populate('Artist', [
 892     [ qw/artistid name/ ],
 893     [ 1, 'Popular Band' ],
 894     [ 2, 'Indie Band' ],
 895     ...
 896   ]);
 897
 898 Since wantarray context is basically the same as looping over $rs->create(...)
 899 you won't see any performance benefits and in this case the method is more for
 900 convenience. Void context sends the column information directly to storage
 901 using <DBI>s bulk insert method. So the performance will be much better for
 902 storages that support this method.
 903
 904 Because of this difference in the way void context inserts rows into your
 905 database you need to note how this will effect any loaded components that
 906 override or augment insert.  For example if you are using a component such
 907 as L<DBIx::Class::UUIDColumns> to populate your primary keys you MUST use
 908 wantarray context if you want the PKs automatically created.
 909
 910 =cut
 911
 912 sub populate {
 913   my ($self, $name, $data) = @_;
 914   my $rs = $self->resultset($name);
 915   my @names = @{shift(@$data)};
 916   if(defined wantarray) {
 917     my @created;
 918     foreach my $item (@$data) {
 919       my %create;
 920       @create{@names} = @$item;
 921       push(@created, $rs->create(\%create));
 922     }
 923     return @created;
 924   }
 925   my @results_to_create;
 926   foreach my $datum (@$data) {
 927     my %result_to_create;
 928     foreach my $index (0..$#names) {
 929       $result_to_create{$names[$index]} = $$datum[$index];
 930     }
 931     push @results_to_create, \%result_to_create;
 932   }
 933   $rs->populate(\@results_to_create);
 934 }
 935
 936 =head2 exception_action
 937
 938 =over 4
 939
 940 =item Arguments: $code_reference
 941
 942 =back
 943
 944 If C<exception_action> is set for this class/object, L</throw_exception>
 945 will prefer to call this code reference with the exception as an argument,
 946 rather than its normal C<croak> or C<confess> action.
 947
 948 Your subroutine should probably just wrap the error in the exception
 949 object/class of your choosing and rethrow.  If, against all sage advice,
 950 you'd like your C<exception_action> to suppress a particular exception
 951 completely, simply have it return true.
 952
 953 Example:
 954
 955    package My::Schema;
 956    use base qw/DBIx::Class::Schema/;
 957    use My::ExceptionClass;
 958    __PACKAGE__->exception_action(sub { My::ExceptionClass->throw(@_) });
 959    __PACKAGE__->load_classes;
 960
 961    # or:
 962    my $schema_obj = My::Schema->connect( .... );
 963    $schema_obj->exception_action(sub { My::ExceptionClass->throw(@_) });
 964
 965    # suppress all exceptions, like a moron:
 966    $schema_obj->exception_action(sub { 1 });
 967
 968 =head2 stacktrace
 969
 970 =over 4
 971
 972 =item Arguments: boolean
 973
 974 =back
 975
 976 Whether L</throw_exception> should include stack trace information.
 977 Defaults to false normally, but defaults to true if C<$ENV{DBIC_TRACE}>
 978 is true.
 979
 980 =head2 throw_exception
 981
 982 =over 4
 983
 984 =item Arguments: $message
 985
 986 =back
 987
 988 Throws an exception. Defaults to using L<Carp::Clan> to report errors from
 989 user's perspective.  See L</exception_action> for details on overriding
 990 this method's behavior.  If L</stacktrace> is turned on, C<throw_exception>'s
 991 default behavior will provide a detailed stack trace.
 992
 993 =cut
 994
 995 sub throw_exception {
 996   my $self = shift;
 997
 998   DBIx::Class::Exception->throw($_[0], $self->stacktrace)
 999     if !$self->exception_action || !$self->exception_action->(@_);
1000 }
1001
1002 =head2 deploy
1003
1004 =over 4
1005
1006 =item Arguments: $sqlt_args, $dir
1007
1008 =back
1009
1010 Attempts to deploy the schema to the current storage using L<SQL::Translator>.
1011
1012 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>. The most
1013 common value for this would be C<< { add_drop_table => 1, } >> to have the SQL
1014 produced include a DROP TABLE statement for each table created.
1015
1016 Additionally, the DBIx::Class parser accepts a C<sources> parameter as a hash
1017 ref or an array ref, containing a list of source to deploy. If present, then
1018 only the sources listed will get deployed. Furthermore, you can use the
1019 C<add_fk_index> parser parameter to prevent the parser from creating an index for each
1020 FK.
1021
1022 =cut
1023
1024 sub deploy {
1025   my ($self, $sqltargs, $dir) = @_;
1026   $self->throw_exception("Can't deploy without storage") unless $self->storage;
1027   $self->storage->deploy($self, undef, $sqltargs, $dir);
1028 }
1029
1030 =head2 deployment_statements
1031
1032 =over 4
1033
1034 =item Arguments: $rdbms_type
1035
1036 =back
1037
1038 Returns the SQL statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1039 C<$rdbms_type> provides the DBI database driver name for which the SQL
1040 statements are produced. If not supplied, the type of the current schema storage
1041 will be used.
1042
1043 =cut
1044
1045 sub deployment_statements {
1046   my ($self, $rdbms_type) = @_;
1047
1048   $self->throw_exception("Can't generate deployment statements without a storage")
1049     if not $self->storage;
1050
1051   $self->storage->deployment_statements($self, $rdbms_type);
1052 }
1053
1054 =head2 create_ddl_dir (EXPERIMENTAL)
1055
1056 =over 4
1057
1058 =item Arguments: \@databases, $version, $directory, $preversion, $sqlt_args
1059
1060 =back
1061
1062 Creates an SQL file based on the Schema, for each of the specified
1063 database types, in the given directory. Given a previous version number,
1064 this will also create a file containing the ALTER TABLE statements to
1065 transform the previous schema into the current one. Note that these
1066 statements may contain DROP TABLE or DROP COLUMN statements that can
1067 potentially destroy data.
1068
1069 The file names are created using the C<ddl_filename> method below, please
1070 override this method in your schema if you would like a different file
1071 name format. For the ALTER file, the same format is used, replacing
1072 $version in the name with "$preversion-$version".
1073
1074 See L<DBIx::Class::Schema/deploy> for details of $sqlt_args.
1075
1076 If no arguments are passed, then the following default values are used:
1077
1078 =over 4
1079
1080 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
1081
1082 =item version    - $schema->VERSION
1083
1084 =item directory  - './'
1085
1086 =item preversion - <none>
1087
1088 =back
1089
1090 Note that this feature is currently EXPERIMENTAL and may not work correctly
1091 across all databases, or fully handle complex relationships.
1092
1093 WARNING: Please check all SQL files created, before applying them.
1094
1095 =cut
1096
1097 sub create_ddl_dir {
1098   my $self = shift;
1099
1100   $self->throw_exception("Can't create_ddl_dir without storage") unless $self->storage;
1101   $self->storage->create_ddl_dir($self, @_);
1102 }
1103
1104 =head2 ddl_filename (EXPERIMENTAL)
1105
1106 =over 4
1107
1108 =item Arguments: $database-type, $version, $directory, $preversion
1109
1110 =back
1111
1112   my $filename = $table->ddl_filename($type, $version, $dir, $preversion)
1113
1114 This method is called by C<create_ddl_dir> to compose a file name out of
1115 the supplied directory, database type and version number. The default file
1116 name format is: C<$dir$schema-$version-$type.sql>.
1117
1118 You may override this method in your schema if you wish to use a different
1119 format.
1120
1121 =cut
1122
1123 sub ddl_filename {
1124   my ($self, $type, $version, $dir, $preversion) = @_;
1125
1126   my $filename = ref($self);
1127   $filename =~ s/::/-/g;
1128   $filename = File::Spec->catfile($dir, "$filename-$version-$type.sql");
1129   $filename =~ s/$version/$preversion-$version/ if($preversion);
1130
1131   return $filename;
1132 }
1133
1134 =head2 sqlt_deploy_hook($sqlt_schema)
1135
1136 An optional sub which you can declare in your own Schema class that will get
1137 passed the L<SQL::Translator::Schema> object when you deploy the schema via
1138 L</create_ddl_dir> or L</deploy>.
1139
1140 For an example of what you can do with this, see
1141 L<DBIx::Class::Manual::Cookbook/Adding Indexes And Functions To Your SQL>.
1142
1143 =head2 thaw
1144
1145 Provided as the recommened way of thawing schema objects. You can call
1146 C<Storable::thaw> directly if you wish, but the thawed objects will not have a
1147 reference to any schema, so are rather useless
1148
1149 =cut
1150
1151 sub thaw {
1152   my ($self, $obj) = @_;
1153   local $DBIx::Class::ResultSourceHandle::thaw_schema = $self;
1154   return Storable::thaw($obj);
1155 }
1156
1157 =head2 freeze
1158
1159 This doesn't actualy do anything more than call L<Storable/freeze>, it is just
1160 provided here for symetry.
1161
1162 =cut
1163
1164 sub freeze {
1165   return Storable::freeze($_[1]);
1166 }
1167
1168 =head2 dclone
1169
1170 Recommeneded way of dcloning objects. This is needed to properly maintain
1171 references to the schema object (which itself is B<not> cloned.)
1172
1173 =cut
1174
1175 sub dclone {
1176   my ($self, $obj) = @_;
1177   local $DBIx::Class::ResultSourceHandle::thaw_schema = $self;
1178   return Storable::dclone($obj);
1179 }
1180
1181 1;
1182
1183 =head1 AUTHORS
1184
1185 Matt S. Trout <mst@shadowcatsystems.co.uk>
1186
1187 =head1 LICENSE
1188
1189 You may distribute this code under the same terms as Perl itself.
1190
1191 =cut