lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::Class::DB;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->load_components(qw/Exception/);
  10 __PACKAGE__->mk_classdata('class_registrations' => {});
  11 __PACKAGE__->mk_classdata('storage_type' => 'DBI');
  12 __PACKAGE__->mk_classdata('storage');
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema - composable schemas
  17
  18 =head1 SYNOPSIS
  19
  20 in My/Schema.pm
  21
  22   package My::Schema;
  23
  24   use base qw/DBIx::Class::Schema/;
  25
  26   __PACKAGE__->load_classes(qw/Foo Bar Baz/);
  27
  28 in My/Schema/Foo.pm
  29
  30   package My::Schema::Foo;
  31
  32   use base qw/DBIx::Class/;
  33
  34   __PACKAGE__->load_components(qw/PK::Auto::Pg Core/); # for example
  35   __PACKAGE__->table('foo');
  36   ...
  37
  38 in My/DB.pm
  39
  40   use My::Schema;
  41
  42   My::Schema->compose_connection('My::DB', $dsn, $user, $pass, $attrs);
  43
  44 then in app code
  45
  46   my @obj = My::DB::Foo->search({}); # My::DB::Foo isa My::Schema::Foo My::DB
  47
  48 =head1 DESCRIPTION
  49
  50 Creates database classes based on a schema. This allows you to have more than
  51 one concurrent connection using the same database classes, by making
  52 subclasses under a new namespace for each connection. If you only need one
  53 class, you should probably use L<DBIx::Class::DB> directly instead.
  54
  55 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  56 carefully as DBIx::Class does things a little differently. Note in
  57 particular which module inherits off which.
  58
  59 =head1 METHODS
  60
  61 =head2 register_class <component> <component_class>
  62
  63 Registers the class in the schema's class_registrations. This is a hash
  64 containing database classes, keyed by their monikers. It's used by
  65 compose_connection to create/modify all the existing database classes.
  66
  67 =cut
  68
  69 sub register_class {
  70   my ($class, $name, $to_register) = @_;
  71   my %reg = %{$class->class_registrations};
  72   $reg{$name} = $to_register;
  73   $class->class_registrations(\%reg);
  74 }
  75
  76 =head2 registered_classes
  77
  78 Simple read-only accessor for the schema's registered classes. See
  79 register_class above if you want to modify it.
  80
  81
  82 =cut
  83
  84 sub registered_classes {
  85   return values %{shift->class_registrations};
  86 }
  87
  88 =head2  load_classes [<classes>, (<class>, <class>), {<namespace> => [<classes>]}]
  89
  90 Uses L<Module::Find> to find all classes under the database class' namespace,
  91 or uses the classes you select.  Then it loads the component (using L<use>),
  92 and registers them (using B<register_class>);
  93
  94 It is possible to comment out classes with a leading '#', but note that perl
  95 will think it's a mistake (trying to use a comment in a qw list) so you'll
  96 need to add "no warnings 'qw';" before your load_classes call.
  97
  98 =cut
  99
 100 sub load_classes {
 101   my ($class, @params) = @_;
 102
 103   my %comps_for;
 104
 105   if (@params) {
 106     foreach my $param (@params) {
 107       if (ref $param eq 'ARRAY') {
 108         # filter out commented entries
 109         my @modules = grep { $_ !~ /^#/ } @$param;
 110
 111         push (@{$comps_for{$class}}, @modules);
 112       }
 113       elsif (ref $param eq 'HASH') {
 114         # more than one namespace possible
 115         for my $comp ( keys %$param ) {
 116           # filter out commented entries
 117           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 118
 119           push (@{$comps_for{$comp}}, @modules);
 120         }
 121       }
 122       else {
 123         # filter out commented entries
 124         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 125       }
 126     }
 127   } else {
 128     eval "require Module::Find;";
 129     $class->throw("No arguments to load_classes and couldn't load".
 130       " Module::Find ($@)") if $@;
 131     my @comp = map { substr $_, length "${class}::"  } Module::Find::findallmod($class);
 132     $comps_for{$class} = \@comp;
 133   }
 134
 135   foreach my $prefix (keys %comps_for) {
 136     foreach my $comp (@{$comps_for{$prefix}||[]}) {
 137       my $comp_class = "${prefix}::${comp}";
 138       eval "use $comp_class"; # If it fails, assume the user fixed it
 139       $class->register_class($comp => $comp_class);
 140     }
 141   }
 142 }
 143
 144 =head2 compose_connection <target> <@db_info>
 145
 146 This is the most important method in this class. it takes a target namespace,
 147 as well as dbh connection info, and creates a L<DBIx::Class::DB> class as
 148 well as subclasses for each of your database classes in this namespace, using
 149 this connection.
 150
 151 It will also setup a ->class method on the target class, which lets you
 152 resolve database classes based on the schema component name, for example
 153
 154   MyApp::DB->class('Foo') # returns MyApp::DB::Foo,
 155                           # which ISA MyApp::Schema::Foo
 156
 157 This is the recommended API for accessing Schema generated classes, and
 158 using it might give you instant advantages with future versions of DBIC.
 159
 160 WARNING: Loading components into Schema classes after compose_connection
 161 may not cause them to be seen by the classes in your target namespace due
 162 to the dispatch table approach used by Class::C3. If you do this you may find
 163 you need to call Class::C3->reinitialize() afterwards to get the behaviour
 164 you expect.
 165
 166 =cut
 167
 168 sub compose_connection {
 169   my ($class, $target, @info) = @_;
 170   my $conn_class = "${target}::_db";
 171   $class->setup_connection_class($conn_class, @info);
 172   $class->compose_namespace($target, $conn_class);
 173 }
 174
 175 sub compose_namespace {
 176   my ($class, $target, $base) = @_;
 177   my %reg = %{ $class->class_registrations };
 178   my %target;
 179   my %map;
 180   while (my ($comp, $comp_class) = each %reg) {
 181     my $target_class = "${target}::${comp}";
 182     $class->inject_base($target_class, $comp_class, $base);
 183     @map{$comp, $comp_class} = ($target_class, $target_class);
 184   }
 185   {
 186     no strict 'refs';
 187     *{"${target}::class"} =
 188       sub {
 189         my ($class, $to_map) = @_;
 190         return $map{$to_map};
 191       };
 192     *{"${target}::classes"} = sub { return \%map; };
 193   }
 194   $base->class_resolver($target);
 195 }
 196
 197 =head2 setup_connection_class <$target> <@info>
 198
 199 Sets up a database connection class to inject between the schema
 200 and the subclasses the schema creates.
 201
 202 =cut
 203
 204 sub setup_connection_class {
 205   my ($class, $target, @info) = @_;
 206   $class->inject_base($target => 'DBIx::Class::DB');
 207   #$target->load_components('DB');
 208   $target->connection(@info);
 209 }
 210
 211 1;
 212
 213 =head1 AUTHORS
 214
 215 Matt S. Trout <mst@shadowcatsystems.co.uk>
 216
 217 =head1 LICENSE
 218
 219 You may distribute this code under the same terms as Perl itself.
 220
 221 =cut
 222