lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::Class::DB;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->load_components(qw/Exception/);
  10 __PACKAGE__->mk_classdata('class_registrations' => {});
  11 __PACKAGE__->mk_classdata('storage_type' => 'DBI');
  12 __PACKAGE__->mk_classdata('storage');
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema - composable schemas
  17
  18 =head1 SYNOPSIS
  19
  20 in My/Schema.pm
  21
  22   package My::Schema;
  23
  24   use base qw/DBIx::Class::Schema/;
  25
  26   __PACKAGE__->load_classes(qw/Foo Bar Baz/);
  27
  28 in My/Schema/Foo.pm
  29
  30   package My::Schema::Foo;
  31
  32   use base qw/DBIx::Class/;
  33
  34   __PACKAGE__->load_components(qw/PK::Auto::Pg Core/); # for example
  35   __PACKAGE__->table('foo');
  36   ...
  37
  38 in My/DB.pm
  39
  40   use My::Schema;
  41
  42   My::Schema->compose_connection('My::DB', $dsn, $user, $pass, $attrs);
  43
  44 then in app code
  45
  46   my @obj = My::DB::Foo->search({}); # My::DB::Foo isa My::Schema::Foo My::DB
  47
  48 =head1 DESCRIPTION
  49
  50 Creates database classes based on a schema. This allows you to have more than
  51 one concurrent connection using the same database classes, by making
  52 subclasses under a new namespace for each connection. If you only need one
  53 class, you should probably use L<DBIx::Class::DB> directly instead.
  54
  55 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  56 carefully as DBIx::Class does things a little differently. Note in
  57 particular which module inherits off which.
  58
  59 =head1 METHODS
  60
  61 =head2 register_class <component> <component_class>
  62
  63 Registers the class in the schema's class_registrations. This is a hash
  64 containing database classes, keyed by their monikers. It's used by
  65 compose_connection to create/modify all the existing database classes.
  66
  67 =cut
  68
  69 sub register_class {
  70   my ($self, $name, $to_register) = @_;
  71   my %reg = %{$self->class_registrations};
  72   $reg{$name} = $to_register;
  73   $self->class_registrations(\%reg);
  74   $to_register->result_source->schema($self);
  75 }
  76
  77 =head2 registered_classes
  78
  79 Simple read-only accessor for the schema's registered classes. See
  80 register_class above if you want to modify it.
  81
  82
  83 =cut
  84
  85 sub registered_classes {
  86   return values %{shift->class_registrations};
  87 }
  88
  89 =head2 class
  90
  91   my $class = $schema->class('Foo');
  92
  93 Shortcut to retrieve a single class by its registered name
  94
  95 =cut
  96
  97 sub class {
  98   my ($self, $class) = @_;
  99   return $self->class_registrations->{$class};
 100 }
 101
 102 =head2 source
 103
 104   my $source = $schema->source('Foo');
 105
 106 Returns the result source object for the registered name
 107
 108 =cut
 109
 110 sub source {
 111   my ($self, $class) = @_;
 112   return $self->class_registrations->{$class}->result_source
 113     if $self->class_registrations->{$class};
 114 }
 115
 116 =head2 resultset
 117
 118   my $rs = $schema->resultset('Foo');
 119
 120 Returns the resultset for the registered name
 121
 122 =cut
 123
 124 sub resultset {
 125   my ($self, $class) = @_;
 126   return $self->class_registrations->{$class}->result_source->resultset;
 127 }
 128
 129
 130 =head2  load_classes [<classes>, (<class>, <class>), {<namespace> => [<classes>]}]
 131
 132 Uses L<Module::Find> to find all classes under the database class' namespace,
 133 or uses the classes you select.  Then it loads the component (using L<use>),
 134 and registers them (using B<register_class>);
 135
 136 It is possible to comment out classes with a leading '#', but note that perl
 137 will think it's a mistake (trying to use a comment in a qw list) so you'll
 138 need to add "no warnings 'qw';" before your load_classes call.
 139
 140 =cut
 141
 142 sub load_classes {
 143   my ($class, @params) = @_;
 144
 145   my %comps_for;
 146
 147   if (@params) {
 148     foreach my $param (@params) {
 149       if (ref $param eq 'ARRAY') {
 150         # filter out commented entries
 151         my @modules = grep { $_ !~ /^#/ } @$param;
 152
 153         push (@{$comps_for{$class}}, @modules);
 154       }
 155       elsif (ref $param eq 'HASH') {
 156         # more than one namespace possible
 157         for my $comp ( keys %$param ) {
 158           # filter out commented entries
 159           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 160
 161           push (@{$comps_for{$comp}}, @modules);
 162         }
 163       }
 164       else {
 165         # filter out commented entries
 166         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 167       }
 168     }
 169   } else {
 170     eval "require Module::Find;";
 171     $class->throw("No arguments to load_classes and couldn't load".
 172       " Module::Find ($@)") if $@;
 173     my @comp = map { substr $_, length "${class}::"  } Module::Find::findallmod($class);
 174     $comps_for{$class} = \@comp;
 175   }
 176
 177   foreach my $prefix (keys %comps_for) {
 178     foreach my $comp (@{$comps_for{$prefix}||[]}) {
 179       my $comp_class = "${prefix}::${comp}";
 180       eval "use $comp_class"; # If it fails, assume the user fixed it
 181       if ($@) {
 182         die $@ unless $@ =~ /Can't locate/;
 183       }
 184       $class->register_class($comp => $comp_class);
 185       #$class->register_class($comp_class => $comp_class);
 186     }
 187   }
 188 }
 189
 190 =head2 compose_connection <target> <@db_info>
 191
 192 This is the most important method in this class. it takes a target namespace,
 193 as well as dbh connection info, and creates a L<DBIx::Class::DB> class as
 194 well as subclasses for each of your database classes in this namespace, using
 195 this connection.
 196
 197 It will also setup a ->class method on the target class, which lets you
 198 resolve database classes based on the schema component name, for example
 199
 200   MyApp::DB->class('Foo') # returns MyApp::DB::Foo,
 201                           # which ISA MyApp::Schema::Foo
 202
 203 This is the recommended API for accessing Schema generated classes, and
 204 using it might give you instant advantages with future versions of DBIC.
 205
 206 WARNING: Loading components into Schema classes after compose_connection
 207 may not cause them to be seen by the classes in your target namespace due
 208 to the dispatch table approach used by Class::C3. If you do this you may find
 209 you need to call Class::C3->reinitialize() afterwards to get the behaviour
 210 you expect.
 211
 212 =cut
 213
 214 sub compose_connection {
 215   my ($self, $target, @info) = @_;
 216   my $conn_class = "${target}::_db";
 217   $self->setup_connection_class($conn_class, @info);
 218   my $schema = $self->compose_namespace($target, $conn_class);
 219   $schema->storage($conn_class->storage);
 220   foreach my $class ($schema->registered_classes) {
 221     my $source = $class->result_source;
 222     $source = $source->new($source);
 223     $source->schema($schema);
 224     $source->result_class($class);
 225     $class->mk_classdata(result_source => $source);
 226     $class->mk_classdata(resultset_instance => $source->resultset);
 227   }
 228   return $schema;
 229 }
 230
 231 sub compose_namespace {
 232   my ($class, $target, $base) = @_;
 233   my %reg = %{ $class->class_registrations };
 234   my %target;
 235   my %map;
 236   my $schema = bless({ }, $class);
 237   while (my ($comp, $comp_class) = each %reg) {
 238     my $target_class = "${target}::${comp}";
 239     $class->inject_base($target_class, $comp_class, ($base ? $base : ()));
 240     @map{$comp, $comp_class} = ($target_class, $target_class);
 241   }
 242   $schema->class_registrations(\%map);
 243   {
 244     no strict 'refs';
 245     *{"${target}::schema"} =
 246       sub { $schema };
 247     *{"${target}::class"} =
 248       sub { shift->schema->class(@_) };
 249   }
 250   $base->class_resolver($target);
 251   return $schema;
 252 }
 253
 254 =head2 setup_connection_class <$target> <@info>
 255
 256 Sets up a database connection class to inject between the schema
 257 and the subclasses the schema creates.
 258
 259 =cut
 260
 261 sub setup_connection_class {
 262   my ($class, $target, @info) = @_;
 263   $class->inject_base($target => 'DBIx::Class::DB');
 264   #$target->load_components('DB');
 265   $target->connection(@info);
 266 }
 267
 268 1;
 269
 270 =head1 AUTHORS
 271
 272 Matt S. Trout <mst@shadowcatsystems.co.uk>
 273
 274 =head1 LICENSE
 275
 276 You may distribute this code under the same terms as Perl itself.
 277
 278 =cut
 279